rt/t/ticket/search_by_queue.t

   1 use strict;
   2 use warnings;
   3
   4 use RT::Test nodata => 1, tests => 34;
   5 use RT::Ticket;
   6
   7 my $qa = RT::Test->load_or_create_queue( Name => 'Queue A' );
   8 ok $qa && $qa->id, 'loaded or created queue';
   9
  10 my $qb = RT::Test->load_or_create_queue( Name => 'Queue B' );
  11 ok $qb && $qb->id, 'loaded or created queue';
  12
  13 my @tickets = RT::Test->create_tickets(
  14     {},
  15     { Queue => $qa->id, Subject => 'a1', },
  16     { Queue => $qa->id, Subject => 'a2', },
  17     { Queue => $qb->id, Subject => 'b1', },
  18     { Queue => $qb->id, Subject => 'b2', },
  19 );
  20
  21 run_tests( \@tickets,
  22     'Queue = "Queue A"' => { a1 => 1, a2 => 1, b1 => 0, b2 => 0 },
  23     'Queue = '. $qa->id => { a1 => 1, a2 => 1, b1 => 0, b2 => 0 },
  24     'Queue != "Queue A"' => { a1 => 0, a2 => 0, b1 => 1, b2 => 1 },
  25     'Queue != '. $qa->id => { a1 => 0, a2 => 0, b1 => 1, b2 => 1 },
  26
  27     'Queue = "Queue B"' => { a1 => 0, a2 => 0, b1 => 1, b2 => 1 },
  28     'Queue = '. $qb->id => { a1 => 0, a2 => 0, b1 => 1, b2 => 1 },
  29     'Queue != "Queue B"' => { a1 => 1, a2 => 1, b1 => 0, b2 => 0 },
  30     'Queue != '. $qb->id => { a1 => 1, a2 => 1, b1 => 0, b2 => 0 },
  31
  32     'Queue = "Bad Queue"' => { a1 => 0, a2 => 0, b1 => 0, b2 => 0 },
  33     'Queue != "Bad Queue"' => { a1 => 1, a2 => 1, b1 => 1, b2 => 1 },
  34 );
  35
  36 sub run_tests {
  37     my @tickets = @{ shift() };
  38     my %test = @_;
  39     my $query_prefix = join ' OR ', map 'id = '. $_->id, @tickets;
  40     foreach my $key ( sort keys %test ) {
  41         my $tix = RT::Tickets->new(RT->SystemUser);
  42         $tix->FromSQL( "( $query_prefix ) AND ( $key )" );
  43
  44         my $error = 0;
  45
  46         my $count = 0;
  47         $count++ foreach grep $_, values %{ $test{$key} };
  48         is($tix->Count, $count, "found correct number of ticket(s) by '$key'") or $error = 1;
  49
  50         my $good_tickets = 1;
  51         while ( my $ticket = $tix->Next ) {
  52             next if $test{$key}->{ $ticket->Subject };
  53             diag $ticket->Subject ." ticket has been found when it's not expected";
  54             $good_tickets = 0;
  55         }
  56         ok( $good_tickets, "all tickets are good with '$key'" ) or $error = 1;
  57
  58         diag "Wrong SQL query for '$key':". $tix->BuildSelectQuery if $error;
  59     }
  60 }