rt/share/html/Search/Elements/ResultsStructuredView

   1 %# BEGIN BPS TAGGED BLOCK {{{
   2 %#
   3 %# COPYRIGHT:
   4 %#
   5 %# This software is Copyright (c) 1996-2009 Best Practical Solutions, LLC
   6 %#                                          <jesse@bestpractical.com>
   7 %#
   8 %# (Except where explicitly superseded by other copyright notices)
   9 %#
  10 %#
  11 %# LICENSE:
  12 %#
  13 %# This work is made available to you under the terms of Version 2 of
  14 %# the GNU General Public License. A copy of that license should have
  15 %# been provided with this software, but in any event can be snarfed
  16 %# from www.gnu.org.
  17 %#
  18 %# This work is distributed in the hope that it will be useful, but
  19 %# WITHOUT ANY WARRANTY; without even the implied warranty of
  20 %# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 %# General Public License for more details.
  22 %#
  23 %# You should have received a copy of the GNU General Public License
  24 %# along with this program; if not, write to the Free Software
  25 %# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 %# 02110-1301 or visit their web page on the internet at
  27 %# http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 %#
  29 %#
  30 %# CONTRIBUTION SUBMISSION POLICY:
  31 %#
  32 %# (The following paragraph is not intended to limit the rights granted
  33 %# to you to modify and distribute this software under the terms of
  34 %# the GNU General Public License and is only of importance to you if
  35 %# you choose to contribute your changes and enhancements to the
  36 %# community by submitting them to Best Practical Solutions, LLC.)
  37 %#
  38 %# By intentionally submitting any modifications, corrections or
  39 %# derivatives to this work, or any other work intended for use with
  40 %# Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 %# you are the copyright holder for those contributions and you grant
  42 %# Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 %# royalty-free, perpetual, license to use, copy, create derivative
  44 %# works based on those contributions, and sublicense and distribute
  45 %# those contributions and any derivatives thereof.
  46 %#
  47 %# END BPS TAGGED BLOCK }}}
  48 <%ARGS>
  49 $Query => undef
  50 $OrderBy => 'id'
  51 $Order => 'ASC'
  52 $Format => undef
  53
  54 #Callbacks
  55 $WriteHeader => sub { $RT::Logger->error('WriteHeader callback required'); '' }
  56 $WriteRow    => sub { $RT::Logger->error('WriteRow callback required'); '' }
  57 $FormatDate  => sub { $_[0]->AsString }
  58 </%ARGS>
  59 <%INIT>
  60
  61 use HTML::TreeBuilder;
  62 use HTML::FormatText;
  63
  64 my $Tickets = RT::Tickets->new( $session{'CurrentUser'} );
  65 $Tickets->FromSQL( $Query );
  66 if ( $OrderBy =~ /\|/ ) {
  67     # Multiple Sorts
  68     my @OrderBy = split /\|/, $OrderBy;
  69     my @Order   = split /\|/, $Order;
  70     $Tickets->OrderByCols(
  71         map { { FIELD => $OrderBy[$_], ORDER => $Order[$_] } }
  72         ( 0 .. $#OrderBy )
  73     );
  74 }
  75 else {
  76     $Tickets->OrderBy( FIELD => $OrderBy, ORDER => $Order );
  77 }
  78
  79 # Convert the format string to column info
  80 $Format = $m->comp('/Elements/ScrubHTML', Content => $Format);
  81 my @Format = $m->comp('/Elements/CollectionAsTable/ParseFormat',
  82                       Format => $Format);
  83
  84 # Generate the header row
  85 my $item = 0;
  86 my @header;
  87 foreach my $column (@Format) {
  88 # see /Element/CollectionAsTable/Header
  89     my $title = $column->{'title'} || '';
  90     if ( $title eq 'NEWLINE' ) {
  91         # ignore these for now
  92         undef $column;
  93         next;
  94     }
  95     $title = '' if $title eq 'NBSP';
  96
  97     if ( !defined $column->{'title'} ) {
  98         my $attr = $column->{'attribute'} || $column->{'last_attribute'};
  99         my $tmp = $m->comp( '/Elements/ColumnMap',
 100                 Class => 'RT__Ticket',
 101                 Name  => $attr,
 102                 Attr  => 'title'
 103                 );
 104         $title = ProcessColumnMapValue($tmp, Arguments => [ $attr ]);
 105     }
 106
 107     push @header, $title;
 108
 109 } #foreach $column
 110
 111 &{ $WriteHeader }(@header);
 112
 113 my $plaintext = HTML::FormatText->new;
 114 my $row = 1;
 115 my $ColumnMap = {};
 116 while ( my $Ticket = $Tickets->Next()) {
 117     my $height = 0;
 118     my @row = ();
 119     foreach my $column ( @Format ) {
 120         next if !defined $column;
 121
 122         my $value = '';
 123         my @out;
 124         # Ignore almost all formatting here.
 125         foreach my $subcol ( @{ $column->{output} } ) {
 126             my ($col) = ($subcol =~ /^__(.*?)__$/ );
 127
 128             if ( !$col ) {
 129                 push @out, $subcol;
 130                 next;
 131             }
 132
 133             if ( !exists $ColumnMap->{$col}{'value'} ) {
 134                 my $map = {};
 135                 foreach ('attribute', 'value') {
 136                     $map->{$_} = $m->comp(
 137                         '/Elements/ColumnMap',
 138                         Class => 'RT__Ticket',
 139                         Name  => $col,
 140                         Attr  => $_,
 141                     );
 142                 }
 143                 $ColumnMap->{$col} = $map;
 144             }
 145
 146             push @out, ProcessColumnMapValue(
 147                 $ColumnMap->{$col}{'value'},
 148                 Arguments => [ $Ticket, $row ],
 149                 FormatDate => $FormatDate,
 150             );
 151         } #foreach $subcol
 152         $value = join('', '<span>', @out, '</span>');
 153         # strip out all HTML except line breaks
 154         my $tree = HTML::TreeBuilder->new->parse($value);
 155         my $text = $plaintext->format($tree);
 156         # along with leading/trailing whitespace
 157         my @lines = map { s/^\s*//; s/\s*$//; $_ } split("\n", $text);
 158
 159         # then provide separate lines to the callback
 160         push @row, \@lines;
 161     } #foreach $column
 162
 163     &{ $WriteRow }(@row);
 164
 165 } # while $Tickets->Next
 166
 167 </%INIT>