rt/sbin/rt-preferences-viewer

   1 #!/usr/bin/perl
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2014 Best Practical Solutions, LLC
   7 #                                          <sales@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 use strict;
  50 use warnings;
  51
  52 # fix lib paths, some may be relative
  53 BEGIN {
  54     require File::Spec;
  55     my @libs = ("/opt/rt3/lib", "/opt/rt3/local/lib");
  56     my $bin_path;
  57
  58     for my $lib (@libs) {
  59         unless ( File::Spec->file_name_is_absolute($lib) ) {
  60             unless ($bin_path) {
  61                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
  62                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
  63                 }
  64                 else {
  65                     require FindBin;
  66                     no warnings "once";
  67                     $bin_path = $FindBin::Bin;
  68                 }
  69             }
  70             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
  71         }
  72         unshift @INC, $lib;
  73     }
  74 }
  75
  76 use Getopt::Long;
  77 my %opt;
  78 GetOptions( \%opt, 'help|h', 'user|u=s', 'option|o=s' );
  79
  80 if ( $opt{help} ) {
  81     require Pod::Usage;
  82     Pod::Usage::pod2usage({ verbose => 2 });
  83     exit;
  84 }
  85
  86 require RT;
  87 RT::LoadConfig();
  88 RT::Init();
  89
  90 require RT::Attributes;
  91 my $attrs = RT::Attributes->new( RT->SystemUser );
  92 $attrs->Limit( FIELD => 'Name', VALUE => 'Pref-RT::System-1' );
  93 $attrs->Limit( FIELD => 'ObjectType', VALUE => 'RT::User' );
  94
  95 if ($opt{user}) {
  96     my $user = RT::User->new( RT->SystemUser );
  97     my ($val, $msg) = $user->Load($opt{user});
  98     unless ($val) {
  99         RT->Logger->error("Unable to load $opt{user}: $msg");
 100         exit(1);
 101     }
 102     $attrs->Limit( FIELD => 'ObjectId', VALUE => $user->Id );
 103 }
 104
 105 use Data::Dumper;
 106 $Data::Dumper::Terse = 1;
 107
 108 while (my $attr = $attrs->Next ) {
 109     my $user = RT::User->new( RT->SystemUser );
 110     my ($val, $msg) = $user->Load($attr->ObjectId);
 111     unless ($val) {
 112         RT->Logger->warn("Unable to load User ".$attr->ObjectId." $msg");
 113         next;
 114     }
 115     next if $user->Disabled;
 116
 117     my $content = $attr->Content;
 118     if ( my $config_name = $opt{option} ) {
 119         if ( exists $content->{$config_name} ) {
 120             my $setting = $content->{$config_name};
 121             print $user->Name, "\t$config_name: $setting\n";
 122         }
 123     } else {
 124         print $user->Name, " => ", Dumper($content);
 125     }
 126
 127 }
 128
 129 __END__
 130
 131 =head1 NAME
 132
 133 rt-preferences-viewer - show user defined preferences
 134
 135 =head1 SYNOPSIS
 136
 137     rt-preferences-viewer
 138
 139     rt-preferences-viewer --user=falcone
 140         show only the falcone user's preferences
 141
 142     rt-preferences-viewer --option=EmailFrequency
 143         show users who have set the EmailFrequence config option
 144
 145 =head1 DESCRIPTION
 146
 147 This script shows user settings of preferences.  If a user is using the system
 148 default, it will not be listed.  You can limit to a user name or id or to users
 149 with a particular option set.