httemplate/search/cust_bill_pkg.cgi

   1 <& elements/search.html,
   2                  'title'       => emt('Line items'),
   3                  'name'        => emt('line items'),
   4                  'query'       => $query,
   5                  'count_query' => $count_query,
   6                  'count_addl'  => \@total_desc,
   7                  'header'      => [
   8                    @pkgnum_header,
   9                    emt('Pkg Def'),
  10                    emt('Description'),
  11                    @post_desc_header,
  12                    @peritem_desc,
  13                    emt('Invoice'),
  14                    emt('Date'),
  15                    emt('Paid'),
  16                    emt('Credited'),
  17                    FS::UI::Web::cust_header(),
  18                  ],
  19                  'fields'      => [
  20                    @pkgnum,
  21                    sub { $_[0]->pkgnum > 0
  22                            ? $_[0]->get('pkgpart')
  23                            : ''
  24                        },
  25                    'itemdesc', # is part_pkg.pkg if applicable
  26                    @post_desc,
  27                    #strikethrough or "N/A ($amount)" or something these when
  28                    # they're not applicable to pkg_tax search
  29                    @peritem_sub,
  30                    'invnum',
  31                    sub { time2str('%b %d %Y', shift->_date ) },
  32                    sub { sprintf($money_char.'%.2f', shift->get('pay_amount')) },
  33                    sub { sprintf($money_char.'%.2f', shift->get('credit_amount')) },
  34                    \&FS::UI::Web::cust_fields,
  35                  ],
  36                  'sort_fields' => [
  37                    @pkgnum_null,
  38                    '',
  39                    '',
  40                    @post_desc_null,
  41                    @peritem,
  42                    'invnum',
  43                    '_date',
  44                    '', #'pay_amount',
  45                    '', #'credit_amount',
  46                    FS::UI::Web::cust_sort_fields(),
  47                  ],
  48                  'links'       => [
  49                    @pkgnum_null,
  50                    '',
  51                    '',
  52                    @post_desc_null,
  53                    @peritem_null,
  54                    $ilink,
  55                    $ilink,
  56                    $pay_link,
  57                    $credit_link,
  58                    ( map { $_ ne 'Cust. Status' ? $clink : '' }
  59                          FS::UI::Web::cust_header()
  60                    ),
  61                  ],
  62                  #'align' => 'rlrrrc'.FS::UI::Web::cust_aligns(),
  63                  'align' => $pkgnum_align.
  64                             'rl'.
  65                             $post_desc_align.
  66                             $peritem_align.
  67                             'rcrr'.
  68                             FS::UI::Web::cust_aligns(),
  69                  'color' => [
  70                               @pkgnum_null,
  71                               '',
  72                               '',
  73                               @post_desc_null,
  74                               @peritem_null,
  75                               '',
  76                               '',
  77                               '',
  78                               '',
  79                               FS::UI::Web::cust_colors(),
  80                             ],
  81                  'style' => [
  82                               @pkgnum_null,
  83                               '',
  84                               '',
  85                               @post_desc_null,
  86                               @peritem_null,
  87                               '',
  88                               '',
  89                               '',
  90                               '',
  91                               FS::UI::Web::cust_styles(),
  92                             ],
  93 &>
  94 <%doc>
  95
  96 Output control parameters:
  97 - distribute: Boolean.  If true, recurring fees will be "prorated" for the
  98   portion of the package date range (sdate-edate) that falls within the date
  99   range of the report.  Line items will be limited to those for which this
 100   portion is > 0.  This disables filtering on invoice date.
 101
 102 - charges: 'S'etup, 'R'ecur, 'U'sage, or any string combination of those.
 103
 104 Filtering parameters:
 105 - begin, end: Date range.  Applies to invoice date, not necessarily package
 106   date range.  But see "distribute".
 107
 108 - status: Customer status (active, suspended, etc.).  This will filter on
 109   _current_ customer status, not status at the time the invoice was generated.
 110
 111 - agentnum: Filter on customer agent.
 112
 113 - refnum: Filter on customer reference source.
 114
 115 - cust_classnum: Filter on customer class.
 116
 117 - classnum: Filter on package class.
 118
 119 - report_optionnum: Filter on package report class.  Can be a single report
 120   class number or a comma-separated list (where 0 is "no report class"), or the
 121   word "multiple".
 122
 123 - use_override: Apply "classnum" and "taxclass" filtering based on the
 124   override (bundle) pkgpart, rather than always using the true pkgpart.
 125
 126 - nottax: Limit to items that are not taxes (pkgnum > 0 or feepart > 0).
 127
 128 - istax: Limit to items that are taxes (pkgnum == 0 and feepart = null).
 129
 130 - taxnum: Limit to items whose tax definition matches this taxnum.
 131   With "nottax" that means items that are subject to that tax;
 132   with "istax" it's the tax charges themselves.  Can be specified
 133   more than once to include multiple taxes.
 134
 135 - country, state, county, city: Limit to items whose tax location
 136   matches these fields.  If "nottax" it's the tax location of the package;
 137   if "istax" the location of the tax.
 138
 139 - taxname, taxnameNULL: With "nottax", limit to items whose tax location
 140   matches a tax with this name.  With "istax", limit to items that have
 141   this tax name.  taxnameNULL is equivalent to "taxname = '' OR taxname
 142   = 'Tax'".
 143
 144 - out: With "nottax", limit to items that don't match any tax definition.
 145   With "istax", find tax items that are unlinked to their tax definitions.
 146   Current Freeside (> July 2012) always creates tax links, but unlinked
 147   items may result from an incomplete upgrade of legacy data.
 148
 149 - locationtaxid: With "nottax", limit to packages matching this
 150   tax_rate_location ID; with "tax", limit to taxes generated from that
 151   location.
 152
 153 - taxclass: Filter on package taxclass.
 154
 155 - taxclassNULL: With "nottax", limit to items that would be subject to the
 156   tax with taxclass = NULL.  This doesn't necessarily mean part_pkg.taxclass
 157   is NULL; it also includes taxclasses that don't have a tax in this region.
 158
 159 - itemdesc: Limit to line items with this description.  Note that non-tax
 160   packages usually have a description of NULL.  (Deprecated.)
 161
 162 - report_group: Can contain '=' or '!=' followed by a string to limit to
 163   line items where itemdesc starts with, or doesn't start with, the string.
 164
 165 - cust_tax: Limit to customers who are tax-exempt.  If "taxname" is also
 166   specified, limit to customers who are also specifically exempt from that
 167   tax.
 168
 169 - pkg_tax: Limit to packages that are tax-exempt, and only include the
 170   exempt portion (setup, recurring, or both) when calculating totals.
 171
 172 - taxable: Limit to packages that are subject to tax, i.e. where a
 173   cust_bill_pkg_tax_location record exists.
 174
 175 - credit: Limit to line items that received a credit application.  The
 176   amount of the credit will also be shown.
 177
 178 </%doc>
 179 <%init>
 180
 181 my $curuser = $FS::CurrentUser::CurrentUser;
 182
 183 die "access denied" unless $curuser->access_right('Financial reports');
 184
 185 my $conf = new FS::Conf;
 186 my $money_char = $conf->config('money_char') || '$';
 187
 188 my @select = ( 'cust_bill_pkg.*', 'cust_bill._date' );
 189 my @total = ( 'COUNT(*)' );
 190 my @total_desc = ();
 191
 192 my @peritem = ( 'setup', 'recur' );
 193 my @peritem_desc = ( 'Setup charges', 'Recurring charges' );
 194
 195 my @pkgnum_header = ();
 196 my @pkgnum = ();
 197 my @pkgnum_null;
 198 my $pkgnum_align = '';
 199 if ( $curuser->option('show_pkgnum') ) {
 200   push @select, 'cust_bill_pkg.pkgnum';
 201   push @pkgnum_header, 'Pkg Num';
 202   push @pkgnum, sub { $_[0]->pkgnum > 0 ? $_[0]->pkgnum : '' };
 203   push @pkgnum_null, '';
 204   $pkgnum_align .= 'r';
 205 }
 206
 207 my @post_desc_header = ();
 208 my @post_desc = ();
 209 my @post_desc_null = ();
 210 my $post_desc_align = '';
 211 if ( $conf->exists('enable_taxclasses') ) {
 212   push @post_desc_header, 'Tax class';
 213   push @post_desc, 'taxclass';
 214   push @post_desc_null, '';
 215   $post_desc_align .= 'l';
 216 }
 217
 218 # used in several places
 219 my $itemdesc = 'COALESCE(cust_bill_pkg.itemdesc, part_fee.itemdesc, part_pkg.pkg, cust_bill_pkg.itemdesc)';
 220
 221 # valid in both the tax and non-tax cases
 222 my $join_cust =
 223   " LEFT JOIN cust_bill ON (cust_bill_pkg.invnum = cust_bill.invnum)".
 224   # use cust_pkg.locationnum if it exists
 225   FS::UI::Web::join_cust_main('cust_bill', 'cust_pkg');
 226
 227 #agent virtualization
 228 my $agentnums_sql =
 229   $FS::CurrentUser::CurrentUser->agentnums_sql( 'table' => 'cust_main' );
 230
 231 my @where = ( $agentnums_sql );
 232
 233 # date range
 234 my($beginning, $ending) = FS::UI::Web::parse_beginning_ending($cgi);
 235
 236 if ( $cgi->param('distribute') == 1 ) {
 237   push @where, "sdate <= $ending",
 238                "edate >  $beginning",
 239   ;
 240 } else {
 241   push @where, "cust_bill._date >= $beginning",
 242                "cust_bill._date <= $ending";
 243 }
 244
 245 # status
 246 if ( $cgi->param('status') =~ /^([a-z]+)$/ ) {
 247   push @where, FS::cust_main->cust_status_sql . " = '$1'";
 248 }
 249
 250 # agentnum
 251 if ( $cgi->param('agentnum') =~ /^(\d+)$/ ) {
 252   push @where, "cust_main.agentnum = $1";
 253 }
 254
 255 # salesnum--see below
 256 # refnum
 257 if ( $cgi->param('refnum') =~ /^(\d+)$/ ) {
 258   push @where, "cust_main.refnum = $1";
 259 }
 260
 261 # cust_classnum (false laziness w/ elements/cust_main_dayranges.html, elements/cust_pay_or_refund.html, prepaid_income.html, cust_bill_pay.html, cust_bill_pkg_referral.html, unearned_detail.html, cust_credit.html, cust_credit_refund.html, cust_main::Search::search_sql)
 262 if ( grep { $_ eq 'cust_classnum' } $cgi->param ) {
 263   my @classnums = grep /^\d*$/, $cgi->param('cust_classnum');
 264   push @where, 'COALESCE( cust_main.classnum, 0) IN ( '.
 265                    join(',', map { $_ || '0' } @classnums ).
 266                ' )'
 267     if @classnums;
 268 }
 269
 270
 271 # custnum
 272 if ( $cgi->param('custnum') =~ /^(\d+)$/ ) {
 273   push @where, "cust_main.custnum = $1";
 274 }
 275
 276 # we want the package and its definition if available
 277 my $join_pkg =
 278 ' LEFT JOIN cust_pkg      USING (pkgnum)
 279   LEFT JOIN part_pkg      USING (pkgpart)
 280   LEFT JOIN part_fee      USING (feepart)';
 281
 282 my $part_pkg = 'part_pkg';
 283 # "Separate sub-packages from parents"
 284 my $use_override = $cgi->param('use_override') ? 1 : 0;
 285 if ( $use_override ) {
 286   # still need the real part_pkg for tax applicability,
 287   # so alias this one
 288   $join_pkg .= " LEFT JOIN part_pkg AS override ON (
 289   COALESCE(cust_bill_pkg.pkgpart_override, cust_pkg.pkgpart, 0) = override.pkgpart
 290   )";
 291   $part_pkg = 'override';
 292 }
 293 push @select, "$part_pkg.pkgpart", "$part_pkg.pkg";
 294 push @select, "($itemdesc) AS itemdesc"; # available in all report modes
 295
 296 push @select, "COALESCE($part_pkg.taxclass, part_fee.taxclass) AS taxclass"
 297   if $conf->exists('enable_taxclasses');
 298
 299 # the non-tax case
 300 if ( $cgi->param('nottax') ) {
 301
 302   push @where,
 303     '(cust_bill_pkg.pkgnum > 0 OR cust_bill_pkg.feepart IS NOT NULL)';
 304
 305   my @tax_where; # will go into a subquery
 306   my @exempt_where; # will also go into a subquery
 307
 308   # classnum (of override pkgpart if applicable)
 309   # not specified: all classes
 310   # 0: empty class
 311   # N: classnum
 312   if ( grep { $_ eq 'classnum' } $cgi->param ) {
 313     my @classnums = grep /^\d+$/, $cgi->param('classnum');
 314     push @where, "COALESCE(part_fee.classnum, $part_pkg.classnum, 0) IN ( ".
 315                      join(',', @classnums ).
 316                  ' )'
 317       if @classnums;
 318   }
 319
 320   if ( grep { $_ eq 'report_optionnum' } $cgi->param ) {
 321     my $num = join(',', grep /^[\d,]+$/, $cgi->param('report_optionnum'));
 322     my $not_num = join(',', grep /^[\d,]+$/, $cgi->param('not_report_optionnum'));
 323     my $all = $cgi->param('all_report_options') ? 1 : 0;
 324     push @where, # code reuse FTW
 325       FS::Report::Table->with_report_option(
 326         report_optionnum      => $num,
 327         not_report_optionnum  => $not_num,
 328         use_override          => $use_override,
 329         all_report_options    => $all,
 330       );
 331   }
 332
 333   # taxclass
 334   if ( $cgi->param('taxclassNULL') ) {
 335     # a little different from 'taxclass' in that it applies to the
 336     # effective taxclass, not the real one
 337     push @tax_where, 'cust_main_county.taxclass IS NULL'
 338   } elsif ( $cgi->param('taxclass') ) {
 339     push @tax_where, "COALESCE(part_fee.taxclass, $part_pkg.taxclass) IN (" .
 340                  join(', ', map {dbh->quote($_)} $cgi->param('taxclass') ).
 341                  ')';
 342   }
 343
 344   if ( $cgi->param('exempt_cust') eq 'Y' ) {
 345     # tax-exempt customers
 346     push @exempt_where, "(exempt_cust = 'Y' OR exempt_cust_taxname = 'Y')";
 347
 348   } elsif ( $cgi->param('exempt_pkg') eq 'Y' ) { # non-taxable package
 349     # non-taxable package charges
 350     push @exempt_where, "(exempt_setup = 'Y' OR exempt_recur = 'Y')";
 351   }
 352   # we don't handle exempt_monthly here
 353
 354   if ( $cgi->param('taxname') ) { # specific taxname
 355       push @tax_where, 'COALESCE(cust_main_county.taxname, \'Tax\') = '.
 356                         dbh->quote($cgi->param('taxname'));
 357   }
 358
 359   # country:state:county:city:district (may be repeated)
 360   # You can also pass a big list of taxnums but that leads to huge URLs.
 361   # Note that this means "packages whose tax is in this region", not
 362   # "packages in this region".  It's meant for links from the tax report.
 363   if ( $cgi->param('region') ) {
 364     my @orwhere;
 365     foreach ( $cgi->param('region') ) {
 366       my %loc;
 367       @loc{qw(country state county city district)} =
 368         split(':', $cgi->param('region'));
 369       my $string = join(' AND ',
 370             map {
 371               if ( $loc{$_} ) {
 372                 "$_ = ".dbh->quote($loc{$_});
 373               } else {
 374                 "$_ IS NULL";
 375               }
 376             } keys(%loc)
 377       );
 378       push @orwhere, "($string)";
 379     }
 380     push @tax_where, '(' . join(' OR ', @orwhere) . ')' if @orwhere;
 381   }
 382
 383   # specific taxnums
 384   if ( $cgi->param('taxnum') =~ /^([0-9,]+)$/ ) {
 385     push @tax_where, "cust_main_county.taxnum IN ($1)";
 386   }
 387
 388   # If we're showing exempt items, we need to find those with
 389   # cust_tax_exempt_pkg records matching the selected taxes.
 390   # If we're showing taxable items, we need to find those with
 391   # cust_bill_pkg_tax_location records.  We also need to find the
 392   # exemption records so that we can show the taxable amount.
 393   # If we're showing all items, we need the union of those.
 394   # If we're showing 'out' (items that aren't region/class taxable),
 395   # then we need the set of all items minus the union of those.
 396
 397   # Always exclude cust_tax_exempt_pkg records with non-NULL creditbillpkgnum.
 398
 399   if ( $cgi->param('out') ) {
 400     # separate from the rest, in that we're not going to join cust_main_county
 401     # in the outer query
 402
 403     my @exclude = ( 'cust_tax_exempt_pkg.billpkgnum',
 404                     'cust_bill_pkg_tax_location.taxable_billpkgnum'
 405                   );
 406     foreach my $col (@exclude) {
 407       my ($table) = split(/\./, $col);
 408       my $this_where = 'WHERE ' .  join(' AND ',
 409         "$col = cust_bill_pkg.billpkgnum",
 410         @tax_where
 411       );
 412
 413       push @where,
 414       "NOT EXISTS(SELECT 1 FROM $table
 415         JOIN cust_main_county USING (taxnum)
 416         $this_where
 417       )";
 418     }
 419
 420   } else {
 421     # everything that returns things joined to a tax definition
 422
 423     my $exempt_sub;
 424     if ( @exempt_where or @tax_where or $cgi->param('taxable') ) {
 425
 426       push @exempt_where, "cust_tax_exempt_pkg.creditbillpkgnum IS NULL";
 427
 428       # process exemption restrictions, including @tax_where
 429       my $exempt_sub = 'SELECT SUM(amount) as exempt_amount, billpkgnum
 430       FROM cust_tax_exempt_pkg JOIN cust_main_county USING (taxnum)';
 431
 432       $exempt_sub .= ' WHERE '.join(' AND ', @tax_where, @exempt_where);
 433
 434       $exempt_sub .= ' GROUP BY billpkgnum';
 435
 436       $join_pkg .= " LEFT JOIN ($exempt_sub) AS item_exempt
 437       USING (billpkgnum)";
 438     }
 439
 440     # This is the only place we should attempt to show credits on here:
 441     # the total of credit applications to the line item.
 442
 443     my $credit_sub = 'SELECT SUM(amount) AS credit_amount, billpkgnum
 444     FROM cust_credit_bill_pkg GROUP BY billpkgnum';
 445
 446     $join_pkg .= " LEFT JOIN ($credit_sub) AS item_credit
 447     ON (cust_bill_pkg.billpkgnum = item_credit.billpkgnum)";
 448
 449     if ( @tax_where or $cgi->param('taxable') ) {
 450       # process tax restrictions
 451       unshift @tax_where,
 452         'cust_main_county.tax > 0';
 453
 454       my $tax_sub = "SELECT cust_bill_pkg_tax_location.taxable_billpkgnum
 455       FROM cust_bill_pkg_tax_location
 456       JOIN cust_bill_pkg AS tax_item USING (billpkgnum)
 457       JOIN cust_main_county USING (taxnum)
 458       WHERE ". join(' AND ', @tax_where).
 459       " GROUP BY taxable_billpkgnum";
 460
 461       $join_pkg .= " LEFT JOIN ($tax_sub) AS item_tax
 462       ON (item_tax.taxable_billpkgnum = cust_bill_pkg.billpkgnum)
 463       ";
 464     }
 465
 466     # now do something with that
 467     if ( $cgi->param('taxable') ) {
 468       # taxable query: needs sale amount - exempt amount
 469
 470       my $taxable = 'cust_bill_pkg.setup + cust_bill_pkg.recur '.
 471                     '- COALESCE(item_exempt.exempt_amount, 0)';
 472
 473       push @where,    'item_tax.taxable_billpkgnum IS NOT NULL';
 474       push @select,   "($taxable) AS taxable_amount";
 475       push @peritem,  'taxable_amount';
 476       push @peritem_desc, 'Taxable';
 477       push @total,    "SUM($taxable)";
 478       push @total_desc, "$money_char%.2f taxable";
 479
 480     } elsif ( $cgi->param('exempt_cust') or $cgi->param('exempt_pkg') ) {
 481
 482       push @where,    'item_exempt.billpkgnum IS NOT NULL';
 483       push @select,   'item_exempt.exempt_amount';
 484       push @peritem,  'exempt_amount';
 485       push @peritem_desc, 'Exempt';
 486       push @total,    'SUM(exempt_amount)';
 487       push @total_desc, "$money_char%.2f tax-exempt";
 488
 489     } elsif ( @tax_where ) {
 490       # union of taxable + all exempt_ cases
 491       push @where,
 492         '(item_tax.taxable_billpkgnum IS NOT NULL OR item_exempt.billpkgnum IS NOT NULL)';
 493
 494     }
 495
 496   } # handle all joins to cust_main_county
 497
 498   # setup/recur/usage separation
 499   my %charges = map { $_ => 1 } split('', $cgi->param('charges') || 'SRU');
 500
 501   if ( $charges{S} and $charges{R} and $charges{U} ) {
 502     # in this case, show discounts
 503
 504     $join_pkg .= ' JOIN (
 505     SELECT billpkgnum, COALESCE(SUM(amount), 0) AS discounted
 506       FROM cust_bill_pkg_discount RIGHT JOIN cust_bill_pkg USING (billpkgnum)
 507       GROUP BY billpkgnum
 508     ) AS _discount ON (cust_bill_pkg.billpkgnum = _discount.billpkgnum)
 509     ';
 510     push @select, '_discount.discounted';
 511
 512     push @peritem, 'discounted';
 513     push @peritem_desc, 'Discount';
 514     push @total, 'SUM(cust_bill_pkg.setup + cust_bill_pkg.recur + discounted)',
 515                  'SUM(discounted)',
 516                  'SUM(cust_bill_pkg.setup + cust_bill_pkg.recur)';
 517     push @total_desc, "$money_char%.2f gross sales",
 518                       "&minus; $money_char%.2f discounted",
 519                       "= $money_char%.2f invoiced";
 520
 521   } elsif ( $charges{R} and $charges{U} ) {
 522
 523     # hide rows with no recurring fee, and show the sum of recurring fees only
 524     push @where, 'cust_bill_pkg.recur > 0';
 525     push @total, "SUM(cust_bill_pkg.recur)";
 526     push @total_desc, "$money_char%.2f recurring";
 527
 528   } elsif ( $charges{R} and !$charges{U} ) {
 529
 530     my $recur_no_usage = FS::cust_bill_pkg->charged_sql('', '',
 531       setuprecur => 'recur', no_usage => 1);
 532     push @select, "($recur_no_usage) AS recur_no_usage";
 533     $peritem[1] = 'recur_no_usage';
 534     $peritem_desc[1] = 'Recurring charges (excluding usage)';
 535     push @total, "SUM($recur_no_usage)";
 536     push @total_desc, "$money_char%.2f recurring";
 537     if ( !$charges{S} ) {
 538       push @where, "($recur_no_usage) > 0";
 539     }
 540
 541   } elsif ( !$charges{R} and $charges{U} ) {
 542
 543     my $usage = FS::cust_bill_pkg->usage_sql();
 544     push @select, "($usage) AS _usage";
 545     # there's already a method named 'usage'
 546     $peritem[1] = '_usage';
 547     $peritem_desc[1] = 'Usage charge';
 548     push @total, "SUM($usage)";
 549     push @total_desc, "$money_char%.2f usage charges";
 550     if ( !$charges{S} ) {
 551       push @where, "($usage) > 0";
 552     }
 553
 554   } elsif ( $charges{S} ) {
 555
 556     push @where, "cust_bill_pkg.setup > 0";
 557     push @total, "SUM(cust_bill_pkg.setup)";
 558     push @total_desc, "$money_char%.2f setup";
 559
 560   } # else huh? you have to have SOME charges
 561
 562 } elsif ( $cgi->param('istax') ) {
 563
 564   # ensure that it is a tax:
 565   push @where, 'cust_bill_pkg.pkgnum = 0',
 566                'cust_bill_pkg.feepart IS NULL';
 567
 568   # We MUST NOT join cust_bill_pkg to any table that it's 1:many to.
 569   # Otherwise we get duplication of the cust_bill_pkg records,
 570   # inaccurate totals, nonsensical paging behavior, etc.
 571   # We CAN safely join it to a subquery that has unique billpkgnums, and
 572   # that's what we'll do.
 573
 574   my $tax_subquery;
 575   my @tax_where;
 576
 577   # tax location when using tax_rate_location
 578   if ( $cgi->param('vendortax') ) {
 579
 580     $tax_subquery = '
 581       SELECT billpkgnum, SUM(amount) as tax_total
 582       FROM cust_bill_pkg_tax_rate_location AS tax
 583         JOIN tax_rate_location USING (taxratelocationnum)
 584     ';
 585     foreach (qw( state county city locationtaxid)) {
 586       if ( scalar($cgi->param($_)) ) {
 587         my $place = dbh->quote( $cgi->param($_) );
 588         push @tax_where, "tax_rate_location.$_ = $place";
 589       }
 590     }
 591
 592   } else { # the internal-tax case
 593
 594     my $tax_select = 'SELECT tax.billpkgnum, SUM(tax.amount) as tax_total';
 595     my $tax_from = ' FROM cust_bill_pkg_tax_location AS tax JOIN cust_main_county USING (taxnum)';
 596
 597     # package classnum
 598     if ( grep { $_ eq 'classnum' } $cgi->param ) {
 599       my @classnums = grep /^\d*$/, $cgi->param('classnum');
 600       $tax_from .= '
 601         JOIN cust_bill_pkg AS taxed_item
 602           ON (tax.taxable_billpkgnum = taxed_item.billpkgnum)
 603         LEFT JOIN cust_pkg AS taxed_pkg ON (taxed_item.pkgnum = taxed_pkg.pkgnum)
 604         LEFT JOIN part_pkg AS taxed_part_pkg ON (taxed_pkg.pkgpart = taxed_part_pkg.pkgpart)
 605         LEFT JOIN part_fee AS taxed_part_fee ON (taxed_item.feepart = taxed_part_fee.feepart)
 606       ';
 607       push @tax_where,
 608         "COALESCE(taxed_part_pkg.classnum, taxed_part_fee.classnum,0) IN ( ".
 609                        join(',', @classnums ).
 610                    ' )'
 611         if @classnums;
 612     }
 613
 614     # taxclass
 615     if ( $cgi->param('taxclassNULL') ) {
 616       push @tax_where, 'cust_main_county.taxclass IS NULL';
 617     }
 618
 619     # taxname
 620     if ( $cgi->param('taxnameNULL') ) {
 621       push @tax_where, 'cust_main_county.taxname IS NULL OR '.
 622                    'cust_main_county.taxname = \'Tax\'';
 623     } elsif ( $cgi->param('taxname') ) {
 624       push @tax_where, 'cust_main_county.taxname = '.
 625                     dbh->quote($cgi->param('taxname'));
 626     }
 627
 628     # itemdesc, for breakdown from the vendor tax report
 629     # (is this even used? vendor tax report shouldn't use cust_bill_pkg.cgi)
 630     if ( $cgi->param('itemdesc') ) {
 631       if ( $cgi->param('itemdesc') eq 'Tax' ) {
 632         push @where, "($itemdesc = 'Tax' OR $itemdesc is null)";
 633       } else {
 634         push @where, "$itemdesc = ". dbh->quote($cgi->param('itemdesc'));
 635       }
 636     }
 637
 638     # specific taxnums (the usual way)
 639     if ( $cgi->param('taxnum') =~ /^([\d,]+)$/) {
 640       push @tax_where, "cust_main_county.taxnum IN ($1)";
 641     }
 642
 643     $tax_subquery = "$tax_select $tax_from";
 644
 645   } # end of internal-tax case
 646
 647   if (@tax_where) {
 648     $tax_subquery .= '
 649       WHERE ' . join(' AND ', map "($_)", @tax_where);
 650   }
 651   $tax_subquery .= ' GROUP BY tax.billpkgnum ';
 652
 653   # now join THAT into the main report
 654   # (inner join, so that tax line items that don't match the tax_where
 655   # conditions don't appear in the output.)
 656
 657   $join_pkg .= " JOIN ($tax_subquery) AS _istax USING (billpkgnum) ";
 658
 659   push @select, 'tax_total';
 660
 661   @peritem = ( 'setup' ); # total tax on the invoice, not just the filtered tax
 662   @peritem_desc = ( 'Tax charge' );
 663
 664   @total = ( 'COUNT(cust_bill_pkg.billpkgnum)',
 665              'SUM(cust_bill_pkg.setup)' );
 666   @total_desc = ( "$money_char%.2f total tax" );
 667
 668   if ( @tax_where ) {
 669     # then also show the filtered tax
 670     push @peritem, 'tax_total';
 671     push @peritem_desc, 'Tax in category';
 672     push @total, 'SUM(tax_total)';
 673     push @total_desc, "$money_char%.2f tax in this category";
 674     # would also be nice to include a line explaining what the category is
 675   }
 676
 677   # report group (itemdesc)
 678   if ( $cgi->param('report_group') =~ /^(=|!=) (.*)$/ ) {
 679     my ( $group_op, $group_value ) = ( $1, $2 );
 680     if ( $group_op eq '=' ) {
 681       #push @where, 'itemdesc LIKE '. dbh->quote($group_value.'%');
 682       push @where, 'itemdesc = '. dbh->quote($group_value);
 683     } elsif ( $group_op eq '!=' ) {
 684       push @where, '( itemdesc != '. dbh->quote($group_value) .' OR itemdesc IS NULL )';
 685     } else {
 686       die "guru meditation #00de: group_op $group_op\n";
 687     }
 688   }
 689
 690 } # nottax / istax
 691
 692
 693 #total payments
 694 my $pay_sub = "SELECT SUM(cust_bill_pay_pkg.amount)
 695                  FROM cust_bill_pay_pkg
 696                    WHERE cust_bill_pkg.billpkgnum = cust_bill_pay_pkg.billpkgnum
 697               ";
 698 push @select, "($pay_sub) AS pay_amount";
 699
 700 push @select, 'cust_main.custnum', FS::UI::Web::cust_sql_fields();
 701
 702 #salesnum
 703 if ( $cgi->param('salesnum') =~ /^(\d+)$/ ) {
 704
 705   my $salesnum = $1;
 706   my $sales = FS::sales->by_key($salesnum)
 707     or die "salesnum $salesnum not found";
 708
 709   my $subsearch = $sales->cust_bill_pkg_search('', '',
 710     'cust_main_sales' => ($cgi->param('cust_main_sales') ? 1 : 0),
 711     'paid'            => ($cgi->param('paid') ? 1 : 0),
 712     'classnum'        => scalar($cgi->param('classnum'))
 713   );
 714   $join_pkg .= " JOIN sales_pkg_class ON ( COALESCE(sales_pkg_class.classnum, 0) = COALESCE( part_fee.classnum, part_pkg.classnum, 0) )";
 715
 716   my $extra_sql = $subsearch->{extra_sql};
 717   $extra_sql =~ s/^WHERE//;
 718   push @where, $extra_sql;
 719
 720   $cgi->param('classnum', 0) unless $cgi->param('classnum');
 721 }
 722
 723
 724 my $where = join(' AND ', @where);
 725 $where &&= "WHERE $where";
 726
 727 my $query = {
 728   'table'     => 'cust_bill_pkg',
 729   'addl_from' => "$join_pkg $join_cust",
 730   'hashref'   => {},
 731   'select'    => join(",\n", @select ),
 732   'extra_sql' => $where,
 733   'order_by'  => 'ORDER BY cust_bill._date, cust_bill_pkg.billpkgnum',
 734 };
 735
 736 my $count_query =
 737   'SELECT ' . join(',', @total) .
 738   " FROM cust_bill_pkg $join_pkg $join_cust
 739   $where";
 740
 741 @peritem_desc = map {emt($_)} @peritem_desc;
 742 my @peritem_sub = map {
 743   my $field = $_;
 744   if ($field =~ /_text$/) { # kludge for credit reason/username fields
 745     sub {$_[0]->get($field)};
 746   } else {
 747     sub { sprintf($money_char.'%.2f', $_[0]->get($field)) }
 748   }
 749 } @peritem;
 750 my @peritem_null = map { '' } @peritem; # placeholders
 751 my $peritem_align = 'r' x scalar(@peritem);
 752
 753 my $ilink = [ "${p}view/cust_bill.cgi?", 'invnum' ];
 754 my $clink = [ "${p}view/cust_main.cgi?", 'custnum' ];
 755
 756 my $pay_link    = ''; #[, 'billpkgnum', ];
 757 my $credit_link = [ "${p}search/cust_credit_bill_pkg.html?billpkgnum=", 'billpkgnum', ];
 758
 759 warn "\n\nQUERY:\n".Dumper($query)."\n\nCOUNT_QUERY:\n$count_query\n\n"
 760   if $cgi->param('debug');
 761
 762 </%init>