httemplate/edit/process/elements/process.html

   1 <%doc>
   2
   3 Example:
   4
   5  <& elements/process.html,
   6
   7    ###
   8    # required
   9    ###
  10
  11   'table' => 'tablename',
  12
  13    #? 'primary_key' => #required when the dbdef doesn't know...???
  14    #? 'fields' => []   #""
  15
  16    ###
  17    # optional
  18    ###
  19
  20    'viewall_dir'  => '', #'search' or 'browse', defaults to 'search'
  21    'viewall_ext'  => 'html', #'cgi' or 'html', defaults to 'html'
  22    OR
  23    'redirect'     => 'view/table.cgi?', # value of primary key is appended
  24                                         # (string or coderef returning a string)
  25    OR
  26    'popup_reload' => 'Momentary success message', #will reload parent window
  27
  28    'error_redirect' => popurl(2).'edit/table.cgi?', #query string appended
  29
  30    'edit_ext' => 'html', #defaults to 'html', you might want 'cgi' while the
  31                          #naming is still inconsistent
  32
  33    'copy_on_empty'  => [ 'old_field_name', 'another_old_field', ... ],
  34
  35    'clear_on_error' => [ 'form_field1', 'form_field2', ... ],
  36
  37                   #pass an arrayref of hashrefs for multiple m2ms or m2names
  38                   #be certain you incorporate m2m_Common if you see error: param
  39
  40    'process_m2m' => { 'link_table'   => 'link_table_name',
  41                       'target_table' => 'target_table_name',
  42                       #optional (see m2m_Common::process_m2m), if not specified
  43                       # all CGI params will be passed)
  44                       'params'       =>
  45                     },
  46    'process_m2name' => { 'link_table'   => 'link_table_name',
  47                          'link_static' => { 'column' => 'value' },
  48                          'num_col' => 'column', #if column name is different in
  49                                                 #link_table than source_table
  50                          'name_col' => 'name_column',
  51                          'names_list' => [ 'list', 'names' ],
  52
  53                          'param_style' => 'link_table.value checkboxes',
  54                          #or#
  55                          'param_style' => 'name_colN values',
  56
  57
  58                        },
  59    'process_o2m' => { 'table' => table_name',
  60                       'num_col' => 'column', #if column name is different in
  61                                              #link_table than source_table
  62                       'fields' => [qw( fieldname fieldname2 )],
  63                     },
  64
  65    'process_locale' => 'fieldname', # update entries in the _msgcat table
  66
  67    'process_upload' => {
  68                          'process'  => 'misc/mytable-import.html',
  69                           # fields to pass to the back end job, besides the
  70                           # primary key of the object
  71                          'fields'   => [qw( fieldname fieldname2 )],
  72                        },
  73
  74    'skip_process' => 0, #boolean, if set true, will skip the main table
  75                         #add/edit processing and only run any linked table
  76                         #process_ items
  77
  78    #checks CGI params and whatever else before much else runs
  79    #return an error string or empty for no error
  80    'precheck_callback' => sub { my( $cgi ) = @_; },
  81
  82    #after everything's inserted
  83    'noerror_callback' => sub { my( $cgi, $object ) = @_; },
  84
  85    #supplies arguments to insert() and replace()
  86    # for use with tables that are FS::option_Common (among other things)
  87    'args_callback' => sub { my( $cgi, $object ) = @_; },
  88
  89    'debug' => 1, #turns on debugging output
  90
  91    #agent virtualization
  92    'agent_virt'       => 1,
  93    'agent_null_right' => 'Access Right Name',
  94
  95    #special bulk insert mode
  96    'bulk' => 'field',
  97
  98  &>
  99
 100 </%doc>
 101 %if ( $error ) {
 102 %
 103 %  #my $query = $m->scomp('/elements/create_uri_query');
 104 %  #$cgi->redirect("$url?$query");
 105 %  if ( length($cgi->query_string) > 1920 ) { #stupid IE 2083 URL limit
 106 %
 107 %    my $session = int(rand(4294967296)); #XXX
 108 %    my $pref = new FS::access_user_pref({
 109 %      'usernum'    => $FS::CurrentUser::CurrentUser->usernum,
 110 %      'prefname'   => "redirect$session",
 111 %      'prefvalue'  => $cgi->query_string,
 112 %      'expiration' => time + 3600, #1h?  1m?
 113 %    });
 114 %    my $pref_error = $pref->insert;
 115 %    if ( $pref_error ) {
 116 %      die "FATAL: couldn't even set redirect cookie: $pref_error".
 117 %          " attempting to set redirect$session to ". $cgi->query_string."\n";
 118 %    }
 119 %
 120 <% $cgi->redirect("$error_redirect?redirect=$session") %>
 121 %
 122 %  } else {
 123 %
 124 <% $cgi->redirect("$error_redirect?". $cgi->query_string ) %>
 125 %
 126 %  }
 127 %
 128 % #different ways of handling success
 129 %
 130 %} elsif ( $opt{'process_upload'} and @uploaded_files ) {
 131 %
 132 % # construct a form to pass all the requested fields, the
 133 %
 134 <& /elements/header.html &>
 135 <form name="UploadForm">
 136 %   my $job_fields = $opt{'process_upload'}{'fields'};
 137 %   foreach my $field ( @$job_fields ) {
 138   <input type="hidden" name="<% $field %>" value="<% $cgi->param($field) |h %>">
 139 %   }
 140 %   push @$job_fields, 'uploaded_files', $pkey;
 141 %
 142   <input type="hidden" name="uploaded_files" value="<% join(',', @uploaded_files) %>">
 143   <input type="hidden" name="<% $pkey %>" value="<% $new->get($pkey) %>">
 144 <& /elements/progress-init.html,
 145   'UploadForm',
 146   $job_fields,
 147   $fsurl . $opt{'process_upload'}{'process'},
 148   {
 149     url => $redirect,
 150     error_url => "$error_redirect?$new_pkey"
 151   },
 152 &>
 153 <input type="submit" style="display:none">
 154 </form>
 155 <script>
 156 <&| /elements/onload.js &>
 157 process();
 158 </&>
 159 </script>
 160 <& /elements/footer.html &>
 161
 162 % } elsif ( $opt{'progress_init'} ) {
 163 %   # some false laziness with the above
 164 %   my ($form_name, $job_fields) = @{ $opt{'progress_init'} };
 165 <form name="<% $form_name %>">
 166   <input type="hidden" name="<% $pkey %>" value="<% $new->get($pkey) %>">
 167 %   foreach my $field (@$job_fields) {
 168 %     next if $field eq $pkey;
 169   <input type="hidden" name="<% $field %>" value="<% $cgi->param($field) |h %>">
 170 %   }
 171 <& /elements/progress-init.html,
 172   @{ $opt{'progress_init'} }
 173 &>
 174 <input type="submit" style="display:none">
 175 </form>
 176 <script>
 177 <&| /elements/onload.js &>
 178 process();
 179 </&>
 180 </script>
 181 <& /elements/footer.html &>
 182
 183 % } elsif ( $opt{'popup_reload'} ) {
 184
 185   <% include('/elements/header-popup.html', $opt{'popup_reload'} ) %>
 186
 187   <SCRIPT TYPE="text/javascript">
 188     window.top.location.reload();
 189   </SCRIPT>
 190
 191   </BODY>
 192   </HTML>
 193
 194 %} else {
 195 <% $cgi->redirect($redirect) %>
 196 %}
 197 <%init>
 198
 199 my $me = 'process.html:';
 200
 201 my(%opt) = @_;
 202
 203 my $curuser = $FS::CurrentUser::CurrentUser;
 204
 205 my $error = '';
 206 if ( $opt{'precheck_callback'} ) {
 207   $error = &{ $opt{'precheck_callback'} }( $cgi );
 208 }
 209
 210 #false laziness w/edit.html
 211 my $table = $opt{'table'};
 212 my $class = "FS::$table";
 213 my $pkey = dbdef->table($table)->primary_key; #? $opt{'primary_key'} ||
 214 my $fields = $opt{'fields'}
 215              #|| [ grep { $_ ne $pkey } dbdef->table($table)->columns ];
 216              || [ fields($table) ];
 217
 218 my $old_pkey = $cgi->param($pkey);
 219
 220 my $old = '';
 221 if ( $old_pkey ) {
 222   $old = qsearchs({
 223     'table'   => $table,
 224     'hashref' => { $pkey => $old_pkey },
 225     'extra_sql' => ( $opt{'agent_virt'}
 226                        ? ' AND '. $curuser->agentnums_sql(
 227                                     'null_right' => $opt{'agent_null_right'}
 228                                   )
 229                        : ''
 230                    ),
 231   });
 232 }
 233
 234 my $bfield = $opt{'bulk'};
 235
 236 my %hash =
 237   map { my @entry = ( $_ => scalar($cgi->param($_)) );
 238         $opt{'value_callback'} ? ( $_ => &{ $opt{'value_callback'} }( @entry ))
 239                                : ( @entry )
 240       } grep { $_ ne $bfield } @$fields;
 241
 242 my @values = ( 1 );
 243 if ( $bfield ) {
 244   @values = $cgi->param($bfield);
 245   #warn join(',', @values);
 246 }
 247
 248 my @uploaded_files;
 249
 250 my $new;
 251 my $new_pkey = '';
 252 foreach my $value ( @values ) {
 253
 254   if ($opt{'skip_process'}) {
 255
 256     $new = $old;
 257     $new_pkey = $old_pkey;
 258
 259   } else {
 260
 261     $new = $class->new( \%hash );
 262
 263     $new->$bfield($value) if $bfield;
 264
 265     if ($old && exists($opt{'copy_on_empty'})) {
 266       foreach my $field (@{$opt{'copy_on_empty'}}) {
 267         $new->set($field, $old->get($field))
 268           unless scalar($cgi->param($field));
 269       }
 270     }
 271
 272     if ( $opt{'agent_virt'} ) {
 273
 274       if ( ! $new->agentnum
 275            && (    ! $opt{'agent_null_right'}
 276                 || ! $curuser->access_right($opt{'agent_null_right'})
 277               )
 278          )
 279       {
 280
 281         $error ||= 'Select an agent';
 282
 283       } else {
 284
 285         die "illegal agentnum"
 286           unless $curuser->agentnums_href->{$new->agentnum}
 287               or $curuser->access_right('View customers of all agents')
 288               or $opt{'agent_null_right'}
 289                  && ! $new->agentnum
 290                  && $curuser->access_right($opt{'agent_null_right'});
 291
 292       }
 293
 294     }
 295
 296     my @args = ();
 297     if ( !$error && $opt{'args_callback'} ) {
 298       @args = &{ $opt{'args_callback'} }( $cgi, $new );
 299     }
 300
 301     if ( !$error && $opt{'debug'} ) {
 302       warn "$me updating record in $table table using $class class\n";
 303       warn Dumper(\%hash);
 304       warn "with args: \n". Dumper(\@args) if @args;
 305     }
 306
 307     if ( !$error ) {
 308       if ( $old_pkey ) {
 309
 310         &{ $opt{'edit_callback'} }( $new, $old ) if $opt{'edit_callback'};
 311
 312         $error = $new->replace($old, @args);
 313       } else {
 314         $error = $new->insert(@args);
 315       }
 316       $new_pkey = $new->getfield($pkey);
 317     }
 318
 319   } #unless $opt{'skip_process'}
 320
 321   if ( !$error && $opt{'process_m2m'} ) {
 322
 323     my @process_m2m = ref($opt{'process_m2m'}) eq 'ARRAY'
 324                         ? @{ $opt{'process_m2m'} }
 325                         :  ( $opt{'process_m2m'} );
 326
 327     foreach my $process_m2m (@process_m2m) {
 328
 329       $process_m2m->{'params'} ||= scalar($cgi->Vars);
 330
 331       warn "$me processing m2m:\n". Dumper( %$process_m2m )
 332         if $opt{'debug'};
 333
 334       $error ||= $new->process_m2m( %$process_m2m );
 335     }
 336
 337   }
 338
 339   if ( !$error && $opt{'process_m2name'} ) {
 340
 341     my @process_m2name = ref($opt{'process_m2name'}) eq 'ARRAY'
 342                            ? @{ $opt{'process_m2name'} }
 343                            :  ( $opt{'process_m2name'} );
 344
 345
 346     foreach my $process_m2name (@process_m2name) {
 347
 348       if ( $opt{'debug'} ) {
 349         warn "$me processing m2name:\n". Dumper( %{ $process_m2name },
 350                                                  'params' => scalar($cgi->Vars),
 351                                                );
 352       }
 353
 354       $error = $new->process_m2name( %{ $process_m2name },
 355                                      'params' => scalar($cgi->Vars),
 356                                    );
 357     }
 358
 359   }
 360
 361   my @process_o2m;
 362   if ( $opt{'process_o2m'} ) {
 363     @process_o2m = ref($opt{'process_o2m'}) eq 'ARRAY'
 364                         ? @{ $opt{'process_o2m'} }
 365                         :  ( $opt{'process_o2m'} );
 366   }
 367   if ( $opt{'process_locale'} ) {
 368     push @process_o2m,
 369     {
 370       'table'  => $table . '_msgcat',
 371       'fields' => [ 'locale', $opt{'process_locale'} ],
 372     };
 373   }
 374
 375   if ( !$error ) {
 376
 377     foreach my $process_o2m (@process_o2m) {
 378
 379       if ( $opt{'debug'} ) {
 380         warn "$me processing o2m:\n". Dumper( %{ $process_o2m },
 381                                                  'params' => scalar($cgi->Vars),
 382                                                );
 383       }
 384
 385       $error ||= $new->process_o2m( %{ $process_o2m },
 386                                      'params' => scalar($cgi->Vars),
 387                                    );
 388     }
 389
 390   }
 391
 392
 393   if ( !$error and $opt{'process_upload'} ) {
 394     # mostly duplicates misc/file-upload.html
 395     $cgi->param('upload_fields') =~ /^([,\w]+)$/
 396       or $error = "invalid upload_fields";
 397     my $fields = $1;
 398
 399     my $dir = $FS::UID::cache_dir. "/cache.". $FS::UID::datasrc;
 400
 401     foreach my $field (split /,/, $fields) {
 402       next if $error;
 403       my $source_name = $cgi->param($field);
 404
 405       if ( $opt{'debug'} ) {
 406         warn "$me processing upload: $source_name\n";
 407       }
 408       my $fh = $cgi->upload( $field ); # if no file provided, that's fine
 409       next if !$fh;
 410
 411       my $suffix = '';
 412       if ( $source_name =~ /(\.\w+)$/ ) {
 413         $suffix = lc($1);
 414       }
 415
 416       my $sh = File::Temp->new( TEMPLATE => 'upload.XXXXXXXX',
 417                                 SUFFIX   => $suffix,
 418                                 DIR      => $dir,
 419                                 UNLINK   => 0,
 420                               )
 421         or $error ||= "can't open temporary file to store upload: $!\n";
 422       next if $error;
 423       while(<$fh>) {
 424         print $sh $_;
 425       }
 426       $sh->filename =~ m!.*/([.\w]+)$!;
 427       push @uploaded_files, "$field:$1";
 428       if ( $opt{'debug'} ) {
 429         warn "uploaded as $1\n";
 430       }
 431     }
 432   }
 433
 434   if ( $error ) {
 435
 436     $cgi->param('error', $error);
 437     if ( $opt{'clear_on_error'} && scalar(@{$opt{'clear_on_error'}}) ) {
 438       foreach my $field (@{$opt{'clear_on_error'}}) {
 439         $cgi->param($field, '')
 440       }
 441     }
 442
 443   } else {
 444
 445     if ( $opt{'noerror_callback'} ) {
 446       &{ $opt{'noerror_callback'} }( $cgi, $new );
 447     }
 448
 449   }
 450
 451   last if $error;
 452
 453 }
 454
 455 # set up redirect URLs
 456
 457 my $redirect;
 458 if ( !$error ) {
 459   $opt{'redirect'} = &{$opt{'redirect'}}($cgi, $new)
 460     if ref($opt{'redirect'}) eq 'CODE';
 461
 462   if ( $opt{'redirect'} ) {
 463
 464     $redirect = $opt{'redirect'} . $new_pkey;
 465
 466   } else {
 467
 468     my $ext = $opt{'viewall_ext'} || 'html';
 469     my $viewall_dir = $opt{'viewall_dir'} || 'search';
 470     my $viewall_url = $opt{'viewall_url'} || ($viewall_dir . "/$table.$ext");
 471
 472     $redirect = popurl(3) . $viewall_url;
 473
 474   }
 475 }
 476
 477 my $edit_ext = $opt{'edit_ext'} || 'html';
 478 my $error_redirect = $opt{'error_redirect'}
 479                      || popurl(2)."$table.$edit_ext";
 480 </%init>