FS/FS/svc_hardware.pm

   1 package FS::svc_hardware;
   2
   3 use strict;
   4 use base qw( FS::svc_Common );
   5 use vars qw( $conf );
   6 use FS::Record qw( qsearch qsearchs );
   7 use FS::hardware_type;
   8 use FS::hardware_status;
   9 use FS::Conf;
  10
  11 FS::UID->install_callback(sub { $conf = FS::Conf->new; });
  12
  13 =head1 NAME
  14
  15 FS::svc_hardware - Object methods for svc_hardware records
  16
  17 =head1 SYNOPSIS
  18
  19   use FS::svc_hardware;
  20
  21   $record = new FS::svc_hardware \%hash;
  22   $record = new FS::svc_hardware { 'column' => 'value' };
  23
  24   $error = $record->insert;
  25
  26   $error = $new_record->replace($old_record);
  27
  28   $error = $record->delete;
  29
  30   $error = $record->check;
  31
  32 =head1 DESCRIPTION
  33
  34 An FS::svc_hardware object represents an equipment installation, such as
  35 a wireless broadband receiver, satellite antenna, or DVR.  FS::svc_hardware
  36 inherits from FS::svc_Common.
  37
  38 The following fields are currently supported:
  39
  40 =over 4
  41
  42 =item svcnum - Primary key
  43
  44 =item typenum - Device type number (see L<FS::hardware_type>)
  45
  46 =item ip_addr - IP address
  47
  48 =item hw_addr - Hardware address
  49
  50 =item serial - Serial number
  51
  52 =item smartcard - Smartcard number, for devices that use a smartcard
  53
  54 =item statusnum - Service status (see L<FS::hardware_status>)
  55
  56 =item note - Installation notes: location on property, physical access, etc.
  57
  58 =back
  59
  60 =head1 METHODS
  61
  62 =over 4
  63
  64 =item new HASHREF
  65
  66 Creates a new svc_hardware object.
  67
  68 =cut
  69
  70 sub table { 'svc_hardware'; }
  71
  72 sub table_info {
  73   my %opts = ( 'type' => 'text', 'disable_select' => 1 );
  74   {
  75     'name'           => 'Hardware', #?
  76     'name_plural'    => 'Hardware',
  77     'display_weight' => 59,
  78     'cancel_weight'  => 86,
  79     'manual_require' => 1,
  80     'fields' => {
  81       'svcnum'    => { label => 'Service' },
  82       'typenum'   => { label => 'Device type',
  83                        type  => 'select-hardware',
  84                        disable_select    => 1,
  85                        disable_fixed     => 1,
  86                        disable_default   => 1,
  87                        disable_inventory => 1,
  88                        required => 1,
  89                      },
  90       'serial'    => { label => 'Serial number', %opts },
  91       'hw_addr'   => { label => 'Hardware address', %opts },
  92       'ip_addr'   => { label => 'IP address', %opts },
  93       'smartcard' => { label => 'Smartcard #', %opts },
  94       'statusnum' => { label => 'Service status',
  95                        type  => 'select',
  96                        select_table => 'hardware_status',
  97                        select_key   => 'statusnum',
  98                        select_label => 'label',
  99                        disable_inventory => 1,
 100                      },
 101       'note'      => { label => 'Installation notes', %opts },
 102     }
 103   }
 104 }
 105
 106 sub search_sql {
 107   my ($class, $string) = @_;
 108   my @where = ();
 109
 110   if ( $string =~ /^[\d\.:]+$/ ) {
 111     # if the string isn't an IP address, this will waste several seconds
 112     # attempting a DNS lookup.  so try to filter those out.
 113     my $ip = NetAddr::IP->new($string);
 114     if ( $ip ) {
 115       push @where, $class->search_sql_field('ip_addr', $ip->addr);
 116     }
 117   }
 118
 119   if ( $string =~ /^(\w+)$/ ) {
 120     push @where, 'LOWER(svc_hardware.serial) LIKE \'%'.lc($string).'%\'';
 121   }
 122
 123   if ( $string =~ /^([0-9A-Fa-f]|\W)+$/ ) {
 124     my $hex = uc($string);
 125     $hex =~ s/\W//g;
 126     push @where, 'svc_hardware.hw_addr LIKE \'%'.$hex.'%\'';
 127   }
 128
 129   if ( @where ) {
 130     '(' . join(' OR ', @where) . ')';
 131   } else {
 132     '1 = 0'; #false
 133   }
 134 }
 135
 136 sub label {
 137   my $self = shift;
 138   my @label = ();
 139   if (my $type = $self->hardware_type) {
 140     push @label, 'Type:' . $type->description;
 141   }
 142   if (my $ser = $self->serial) {
 143     push @label, 'Serial#' . $ser;
 144   }
 145   if (my $mac = $self->display_hw_addr) {
 146     push @label, 'MAC:'. $mac;
 147   }
 148   return join(', ', @label);
 149 }
 150
 151 =item insert
 152
 153 Adds this record to the database.  If there is an error, returns the error,
 154 otherwise returns false.
 155
 156 =item delete
 157
 158 Delete this record from the database.
 159
 160 =item replace OLD_RECORD
 161
 162 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 163 returns the error, otherwise returns false.
 164
 165 # the replace method can be inherited from FS::Record
 166
 167 =item check
 168
 169 Checks all fields to make sure this is a valid service.  If there is
 170 an error, returns the error, otherwise returns false.  Called by the insert
 171 and replace methods.
 172
 173 =cut
 174
 175 sub check {
 176   my $self = shift;
 177   my $conf = FS::Conf->new;
 178
 179   my $x = $self->setfixed;
 180   return $x unless ref $x;
 181
 182   my $hw_addr = $self->getfield('hw_addr');
 183   $hw_addr = join('', split(/[_\W]/, $hw_addr));
 184   if ( $conf->exists('svc_hardware-check_mac_addr') ) {
 185     $hw_addr = uc($hw_addr);
 186     $hw_addr =~ /^[0-9A-F]{12}$/
 187       or return "Illegal (MAC address) '".$self->getfield('hw_addr')."'";
 188   }
 189   $self->setfield('hw_addr', $hw_addr);
 190
 191   my $error =
 192     $self->ut_numbern('svcnum')
 193     || $self->ut_foreign_key('typenum', 'hardware_type', 'typenum')
 194     || $self->ut_ip46n('ip_addr')
 195     || $self->ut_alphan('hw_addr')
 196     || $self->ut_alphan('serial')
 197     || $self->ut_alphan('smartcard')
 198     || $self->ut_foreign_keyn('statusnum', 'hardware_status', 'statusnum')
 199     || $self->ut_anything('note')
 200   ;
 201   return $error if $error;
 202
 203   if ( !length($self->getfield('hw_addr'))
 204         and !length($self->getfield('serial')) ) {
 205     return 'Serial number or hardware address required';
 206   }
 207
 208   $self->SUPER::check;
 209 }
 210
 211 =item hardware_type
 212
 213 Returns the L<FS::hardware_type> object associated with this installation.
 214
 215 =cut
 216
 217 sub hardware_type {
 218   my $self = shift;
 219   return qsearchs('hardware_type', { 'typenum' => $self->typenum });
 220 }
 221
 222 =item status_label
 223
 224 Returns the 'label' field of the L<FS::hardware_status> object associated
 225 with this installation.
 226
 227 =cut
 228
 229 sub status_label {
 230   my $self = shift;
 231   my $status = qsearchs('hardware_status', { 'statusnum' => $self->statusnum })
 232     or return '';
 233   $status->label;
 234 }
 235
 236 =item display_hw_addr
 237
 238 Returns the 'hw_addr' field, formatted as a MAC address if the
 239 'svc_hardware-check_mac_addr' option is enabled.
 240
 241 =cut
 242
 243 sub display_hw_addr {
 244   my $self = shift;
 245   ($conf->exists('svc_hardware-check_mac_addr') ?
 246     join(':', $self->hw_addr =~ /../g) : $self->hw_addr)
 247 }
 248
 249 =back
 250
 251 =head1 SEE ALSO
 252
 253 L<FS::Record>, L<FS::svc_Common>, schema.html from the base documentation.
 254
 255 =cut
 256
 257 1;
 258