FS/FS/reason.pm

   1 package FS::reason;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me );
   5 use DBIx::DBSchema;
   6 use DBIx::DBSchema::Table;
   7 use DBIx::DBSchema::Column;
   8 use FS::Record qw( qsearch qsearchs dbh dbdef );
   9 use FS::reason_type;
  10
  11 @ISA = qw(FS::Record);
  12 $DEBUG = 0;
  13 $me = '[FS::reason]';
  14
  15 =head1 NAME
  16
  17 FS::reason - Object methods for reason records
  18
  19 =head1 SYNOPSIS
  20
  21   use FS::reason;
  22
  23   $record = new FS::reason \%hash;
  24   $record = new FS::reason { 'column' => 'value' };
  25
  26   $error = $record->insert;
  27
  28   $error = $new_record->replace($old_record);
  29
  30   $error = $record->delete;
  31
  32   $error = $record->check;
  33
  34 =head1 DESCRIPTION
  35
  36 An FS::reason object represents a reason message.  FS::reason inherits from
  37 FS::Record.  The following fields are currently supported:
  38
  39 =over 4
  40
  41 =item reasonnum - primary key
  42
  43 =item reason_type - index into FS::reason_type
  44
  45 =item reason - text of the reason
  46
  47 =item disabled - 'Y' or ''
  48
  49 =item unsuspend_pkgpart - for suspension reasons only, the pkgpart (see
  50 L<FS::part_pkg>) of a package to be ordered when the package is unsuspended.
  51 Typically this will be some kind of reactivation fee.  Attaching it to
  52 a suspension reason allows the reactivation fee to be charged for some
  53 suspensions but not others. DEPRECATED.
  54
  55 =item unsuspend_hold - 'Y' or ''.  If unsuspend_pkgpart is set, this tells
  56 whether to bill the unsuspend package immediately ('') or to wait until
  57 the customer's next invoice ('Y').
  58
  59 =item unused_credit - 'Y' or ''. For suspension reasons only (for now).
  60 If enabled, the customer will be credited for their remaining time on
  61 suspension.
  62
  63 =item feepart - for suspension reasons, the feepart of a fee to be
  64 charged when a package is suspended for this reason.
  65
  66 =item fee_hold - 'Y' or ''. If feepart is set, tells whether to bill the fee
  67 immediately ('') or wait until the customer's next invoice ('Y').
  68
  69 =item fee_on_unsuspend - If feepart is set, tells whether to charge the fee
  70 on suspension ('') or unsuspension ('Y').
  71
  72 =back
  73
  74 =head1 METHODS
  75
  76 =over 4
  77
  78 =item new HASHREF
  79
  80 Creates a new reason.  To add the example to the database, see L<"insert">.
  81
  82 Note that this stores the hash reference, not a distinct copy of the hash it
  83 points to.  You can ask the object for a copy with the I<hash> method.
  84
  85 =cut
  86
  87 sub table { 'reason'; }
  88
  89 =item insert
  90
  91 Adds this record to the database.  If there is an error, returns the error,
  92 otherwise returns false.
  93
  94 =cut
  95
  96 =item delete
  97
  98 Delete this record from the database.
  99
 100 =cut
 101
 102 =item replace OLD_RECORD
 103
 104 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 105 returns the error, otherwise returns false.
 106
 107 =cut
 108
 109 =item check
 110
 111 Checks all fields to make sure this is a valid reason.  If there is
 112 an error, returns the error, otherwise returns false.  Called by the insert
 113 and replace methods.
 114
 115 =cut
 116
 117 sub check {
 118   my $self = shift;
 119
 120   my $error =
 121     $self->ut_numbern('reasonnum')
 122     || $self->ut_number('reason_type')
 123     || $self->ut_foreign_key('reason_type', 'reason_type', 'typenum')
 124     || $self->ut_text('reason')
 125   ;
 126   return $error if $error;
 127
 128   if ( $self->reasontype->class eq 'S' ) {
 129     $error = $self->ut_numbern('unsuspend_pkgpart')
 130           || $self->ut_foreign_keyn('unsuspend_pkgpart', 'part_pkg', 'pkgpart')
 131           || $self->ut_flag('unsuspend_hold')
 132           || $self->ut_flag('unused_credit')
 133           || $self->ut_foreign_keyn('feepart', 'part_fee', 'feepart')
 134           || $self->ut_flag('fee_on_unsuspend')
 135           || $self->ut_flag('fee_hold')
 136     ;
 137     return $error if $error;
 138   } else {
 139     foreach (qw(unsuspend_pkgpart unsuspend_hold unused_credit feepart
 140                 fee_on_unsuspend fee_hold)) {
 141       $self->set($_ => '');
 142     }
 143   }
 144
 145   $self->SUPER::check;
 146 }
 147
 148 =item reasontype
 149
 150 Returns the reason_type (see L<FS::reason_type>) associated with this reason.
 151
 152 =cut
 153
 154 sub reasontype {
 155   qsearchs( 'reason_type', { 'typenum' => shift->reason_type } );
 156 }
 157
 158 =item merge
 159
 160 Accepts an arrayref of reason objects, to be merged into this reason.
 161 Reasons must all have the same reason_type class as this one.
 162 Matching reasonnums will be replaced in the following tables:
 163
 164   cust_credit
 165   cust_credit_void
 166   cust_pkg_reason
 167
 168 =cut
 169
 170 sub merge {
 171   my ($self,$reasons) = @_;
 172   return "Bad input for merge" unless ref($reasons) eq 'ARRAY';
 173
 174   my $class = $self->reasontype->class;
 175
 176   local $SIG{HUP} = 'IGNORE';
 177   local $SIG{INT} = 'IGNORE';
 178   local $SIG{QUIT} = 'IGNORE';
 179   local $SIG{TERM} = 'IGNORE';
 180   local $SIG{TSTP} = 'IGNORE';
 181   local $SIG{PIPE} = 'IGNORE';
 182
 183   my $oldAutoCommit = $FS::UID::AutoCommit;
 184   local $FS::UID::AutoCommit = 0;
 185   my $dbh = dbh;
 186
 187   my $error;
 188   foreach my $reason (@$reasons) {
 189     last if $error;
 190     next if $reason->reasonnum eq $self->reasonnum;
 191     $error = "Mismatched reason type class"
 192       unless $reason->reasontype->class eq $class;
 193     foreach my $table ( qw(
 194       cust_credit
 195       cust_credit_void
 196       cust_pkg_reason
 197     )) {
 198       last if $error;
 199       my @fields = ('reasonnum');
 200       push(@fields, 'void_reasonnum') if $table eq 'cust_credit_void';
 201       foreach my $field (@fields) {
 202         last if $error;
 203         foreach my $obj ( qsearch($table,{ $field => $reason->reasonnum }) ) {
 204           last if $error;
 205           $obj->set($field,$self->reasonnum);
 206           $error = $obj->replace;
 207         }
 208       }
 209     }
 210     $error ||= $reason->delete;
 211   }
 212
 213   if ( $error ) {
 214     $dbh->rollback if $oldAutoCommit;
 215     return $error;
 216   }
 217
 218   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 219
 220   '';
 221
 222 }
 223
 224 =back
 225
 226 =head1 CLASS METHODS
 227
 228 =over 4
 229
 230 =item new_or_existing reason => REASON, type => TYPE, class => CLASS
 231
 232 Fetches the reason matching these parameters if there is one.  If not,
 233 inserts one.  Will also insert the reason type if necessary.  CLASS must
 234 be one of 'C' (cancel reasons), 'R' (credit reasons), 'S' (suspend reasons),
 235 or 'F' (refund reasons).
 236
 237 This will die if anything fails.
 238
 239 =cut
 240
 241 sub new_or_existing {
 242   my $class = shift;
 243   my %opt = @_;
 244
 245   my $error = '';
 246   my $reason_type;
 247   if ( ref $opt{type} eq 'FS::reason_type' ) {
 248     $reason_type = $opt{type};
 249   } elsif ( $opt{type} =~ /^\d+$/ ) {
 250     $reason_type = FS::reason_type->by_key($opt{type});
 251     if (!$reason_type) {
 252       die "reason_type #$opt{type} not found\n";
 253     }
 254   } else {
 255     my %hash = ('class' => $opt{'class'}, 'type' => $opt{'type'});
 256     $reason_type = qsearchs('reason_type', \%hash)
 257                       || FS::reason_type->new(\%hash);
 258
 259     $error = $reason_type->insert unless $reason_type->typenum;
 260     die "error inserting reason type: $error\n" if $error;
 261   }
 262
 263   my %hash = ('reason_type' => $reason_type->typenum,
 264               'reason' => $opt{'reason'});
 265   my $reason = qsearchs('reason', \%hash)
 266                || FS::reason->new(\%hash);
 267
 268   $error = $reason->insert unless $reason->reasonnum;
 269   die "error inserting reason: $error\n" if $error;
 270
 271   $reason;
 272 }
 273
 274 =head1 BUGS
 275
 276 =head1 SEE ALSO
 277
 278 L<FS::Record>, schema.html from the base documentation.
 279
 280 =cut
 281
 282 1;
 283