FS/FS/reason.pm

   1 package FS::reason;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $me );
   5 use DBIx::DBSchema;
   6 use DBIx::DBSchema::Table;
   7 use DBIx::DBSchema::Column;
   8 use FS::Record qw( qsearch qsearchs dbh dbdef );
   9 use FS::reason_type;
  10
  11 @ISA = qw(FS::Record);
  12 $DEBUG = 0;
  13 $me = '[FS::reason]';
  14
  15 =head1 NAME
  16
  17 FS::reason - Object methods for reason records
  18
  19 =head1 SYNOPSIS
  20
  21   use FS::reason;
  22
  23   $record = new FS::reason \%hash;
  24   $record = new FS::reason { 'column' => 'value' };
  25
  26   $error = $record->insert;
  27
  28   $error = $new_record->replace($old_record);
  29
  30   $error = $record->delete;
  31
  32   $error = $record->check;
  33
  34 =head1 DESCRIPTION
  35
  36 An FS::reason object represents a reason message.  FS::reason inherits from
  37 FS::Record.  The following fields are currently supported:
  38
  39 =over 4
  40
  41 =item reasonnum - primary key
  42
  43 =item reason_type - index into FS::reason_type
  44
  45 =item reason - text of the reason
  46
  47 =item disabled - 'Y' or ''
  48
  49 =item unsuspend_pkgpart - for suspension reasons only, the pkgpart (see
  50 L<FS::part_pkg>) of a package to be ordered when the package is unsuspended.
  51 Typically this will be some kind of reactivation fee.  Attaching it to
  52 a suspension reason allows the reactivation fee to be charged for some
  53 suspensions but not others. DEPRECATED.
  54
  55 =item unsuspend_hold - 'Y' or ''.  If unsuspend_pkgpart is set, this tells
  56 whether to bill the unsuspend package immediately ('') or to wait until
  57 the customer's next invoice ('Y').
  58
  59 =item unused_credit - 'Y' or ''. For suspension or cancellation reasons.
  60 If enabled, the customer will be credited for their remaining time on
  61 suspension.
  62
  63 =item feepart - for suspension reasons, the feepart of a fee to be
  64 charged when a package is suspended for this reason.
  65
  66 =item fee_hold - 'Y' or ''. If feepart is set, tells whether to bill the fee
  67 immediately ('') or wait until the customer's next invoice ('Y').
  68
  69 =item fee_on_unsuspend - If feepart is set, tells whether to charge the fee
  70 on suspension ('') or unsuspension ('Y').
  71
  72 =back
  73
  74 =head1 METHODS
  75
  76 =over 4
  77
  78 =item new HASHREF
  79
  80 Creates a new reason.  To add the example to the database, see L<"insert">.
  81
  82 Note that this stores the hash reference, not a distinct copy of the hash it
  83 points to.  You can ask the object for a copy with the I<hash> method.
  84
  85 =cut
  86
  87 sub table { 'reason'; }
  88
  89 =item insert
  90
  91 Adds this record to the database.  If there is an error, returns the error,
  92 otherwise returns false.
  93
  94 =cut
  95
  96 =item delete
  97
  98 Delete this record from the database.
  99
 100 =cut
 101
 102 =item replace OLD_RECORD
 103
 104 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 105 returns the error, otherwise returns false.
 106
 107 =cut
 108
 109 =item check
 110
 111 Checks all fields to make sure this is a valid reason.  If there is
 112 an error, returns the error, otherwise returns false.  Called by the insert
 113 and replace methods.
 114
 115 =cut
 116
 117 sub check {
 118   my $self = shift;
 119
 120   my $error =
 121     $self->ut_numbern('reasonnum')
 122     || $self->ut_number('reason_type')
 123     || $self->ut_foreign_key('reason_type', 'reason_type', 'typenum')
 124     || $self->ut_text('reason')
 125   ;
 126   return $error if $error;
 127
 128   my $class = $self->reasontype->class;
 129
 130   if ( $class eq 'S' ) {
 131     $error = $self->ut_numbern('unsuspend_pkgpart')
 132           || $self->ut_foreign_keyn('unsuspend_pkgpart', 'part_pkg', 'pkgpart')
 133           || $self->ut_flag('unsuspend_hold')
 134           || $self->ut_foreign_keyn('feepart', 'part_fee', 'feepart')
 135           || $self->ut_flag('fee_on_unsuspend')
 136           || $self->ut_flag('fee_hold')
 137     ;
 138     return $error if $error;
 139   } else {
 140     foreach (qw(unsuspend_pkgpart unsuspend_hold feepart
 141                 fee_on_unsuspend fee_hold)) {
 142       $self->set($_ => '');
 143     }
 144   }
 145
 146   if ( $class eq 'S' or $class eq 'C' ) {
 147     $error = $self->ut_flag('unused_credit');
 148   } else {
 149     $self->set('unused_credit', '');
 150   }
 151
 152   $self->SUPER::check;
 153 }
 154
 155 =item reasontype
 156
 157 Returns the reason_type (see L<FS::reason_type>) associated with this reason.
 158
 159 =cut
 160
 161 sub reasontype {
 162   qsearchs( 'reason_type', { 'typenum' => shift->reason_type } );
 163 }
 164
 165 =item merge
 166
 167 Accepts an arrayref of reason objects, to be merged into this reason.
 168 Reasons must all have the same reason_type class as this one.
 169 Matching reasonnums will be replaced in the following tables:
 170
 171   cust_credit
 172   cust_credit_void
 173   cust_pkg_reason
 174
 175 =cut
 176
 177 sub merge {
 178   my ($self,$reasons) = @_;
 179   return "Bad input for merge" unless ref($reasons) eq 'ARRAY';
 180
 181   my $class = $self->reasontype->class;
 182
 183   local $SIG{HUP} = 'IGNORE';
 184   local $SIG{INT} = 'IGNORE';
 185   local $SIG{QUIT} = 'IGNORE';
 186   local $SIG{TERM} = 'IGNORE';
 187   local $SIG{TSTP} = 'IGNORE';
 188   local $SIG{PIPE} = 'IGNORE';
 189
 190   my $oldAutoCommit = $FS::UID::AutoCommit;
 191   local $FS::UID::AutoCommit = 0;
 192   my $dbh = dbh;
 193
 194   my $error;
 195   foreach my $reason (@$reasons) {
 196     last if $error;
 197     next if $reason->reasonnum eq $self->reasonnum;
 198     $error = "Mismatched reason type class"
 199       unless $reason->reasontype->class eq $class;
 200     foreach my $table ( qw(
 201       cust_credit
 202       cust_credit_void
 203       cust_pkg_reason
 204     )) {
 205       last if $error;
 206       my @fields = ('reasonnum');
 207       push(@fields, 'void_reasonnum') if $table eq 'cust_credit_void';
 208       foreach my $field (@fields) {
 209         last if $error;
 210         foreach my $obj ( qsearch($table,{ $field => $reason->reasonnum }) ) {
 211           last if $error;
 212           $obj->set($field,$self->reasonnum);
 213           $error = $obj->replace;
 214         }
 215       }
 216     }
 217     $error ||= $reason->delete;
 218   }
 219
 220   if ( $error ) {
 221     $dbh->rollback if $oldAutoCommit;
 222     return $error;
 223   }
 224
 225   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 226
 227   '';
 228
 229 }
 230
 231 =back
 232
 233 =head1 CLASS METHODS
 234
 235 =over 4
 236
 237 =item new_or_existing reason => REASON, type => TYPE, class => CLASS
 238
 239 Fetches the reason matching these parameters if there is one.  If not,
 240 inserts one.  Will also insert the reason type if necessary.  CLASS must
 241 be one of 'C' (cancel reasons), 'R' (credit reasons), 'S' (suspend reasons),
 242 or 'F' (refund reasons).
 243
 244 This will die if anything fails.
 245
 246 =cut
 247
 248 sub new_or_existing {
 249   my $class = shift;
 250   my %opt = @_;
 251
 252   my $error = '';
 253   my $reason_type;
 254   if ( ref $opt{type} eq 'FS::reason_type' ) {
 255     $reason_type = $opt{type};
 256   } elsif ( $opt{type} =~ /^\d+$/ ) {
 257     $reason_type = FS::reason_type->by_key($opt{type});
 258     if (!$reason_type) {
 259       die "reason_type #$opt{type} not found\n";
 260     }
 261   } else {
 262     my %hash = ('class' => $opt{'class'}, 'type' => $opt{'type'});
 263     $reason_type = qsearchs('reason_type', \%hash)
 264                       || FS::reason_type->new(\%hash);
 265
 266     $error = $reason_type->insert unless $reason_type->typenum;
 267     die "error inserting reason type: $error\n" if $error;
 268   }
 269
 270   my %hash = ('reason_type' => $reason_type->typenum,
 271               'reason' => $opt{'reason'});
 272   my $reason = qsearchs('reason', \%hash)
 273                || FS::reason->new(\%hash);
 274
 275   $error = $reason->insert unless $reason->reasonnum;
 276   die "error inserting reason: $error\n" if $error;
 277
 278   $reason;
 279 }
 280
 281 =head1 BUGS
 282
 283 =head1 SEE ALSO
 284
 285 L<FS::Record>, schema.html from the base documentation.
 286
 287 =cut
 288
 289 1;
 290