FS/FS/quotation_pkg.pm

   1 package FS::quotation_pkg;
   2
   3 use strict;
   4 use base qw( FS::TemplateItem_Mixin FS::Record );
   5 use FS::Record qw( qsearch qsearchs dbh );
   6 use FS::part_pkg;
   7 use FS::cust_location;
   8 use FS::quotation;
   9 use FS::quotation_pkg_discount; #so its loaded when TemplateItem_Mixin needs it
  10 use FS::quotation_pkg_detail;
  11 use List::Util qw(sum);
  12
  13 =head1 NAME
  14
  15 FS::quotation_pkg - Object methods for quotation_pkg records
  16
  17 =head1 SYNOPSIS
  18
  19   use FS::quotation_pkg;
  20
  21   $record = new FS::quotation_pkg \%hash;
  22   $record = new FS::quotation_pkg { 'column' => 'value' };
  23
  24   $error = $record->insert;
  25
  26   $error = $new_record->replace($old_record);
  27
  28   $error = $record->delete;
  29
  30   $error = $record->check;
  31
  32 =head1 DESCRIPTION
  33
  34 An FS::quotation_pkg object represents a quotation package.
  35 FS::quotation_pkg inherits from FS::Record.  The following fields are currently
  36 supported:
  37
  38 =over 4
  39
  40 =item quotationpkgnum
  41
  42 primary key
  43
  44 =item pkgpart
  45
  46 pkgpart (L<FS::part_pkg>) of the package
  47
  48 =item locationnum
  49
  50 locationnum (L<FS::cust_location>) where the package will be in service
  51
  52 =item start_date
  53
  54 expected start date for the package, as a timestamp
  55
  56 =item contract_end
  57
  58 contract end date
  59
  60 =item quantity
  61
  62 quantity
  63
  64 =item waive_setup
  65
  66 'Y' to waive the setup fee
  67
  68 =item unitsetup
  69
  70 The amount per package that will be charged in setup/one-time fees.
  71
  72 =item unitrecur
  73
  74 The amount per package that will be charged per billing cycle.
  75
  76 =back
  77
  78 =head1 METHODS
  79
  80 =over 4
  81
  82 =item new HASHREF
  83
  84 Creates a new quotation package.  To add the quotation package to the database,
  85 see L<"insert">.
  86
  87 Note that this stores the hash reference, not a distinct copy of the hash it
  88 points to.  You can ask the object for a copy with the I<hash> method.
  89
  90 =cut
  91
  92 sub table { 'quotation_pkg'; }
  93
  94 sub display_table         { 'quotation_pkg'; }
  95
  96 #forget it, just overriding cust_bill_pkg_display entirely
  97 #sub display_table_orderby { 'quotationpkgnum'; } # something else?
  98 #                                                 #  (for invoice display order)
  99
 100 sub discount_table        { 'quotation_pkg_discount'; }
 101 sub detail_table          { 'quotation_pkg_detail'; }
 102
 103 =item insert
 104
 105 Adds this record to the database.  If there is an error, returns the error,
 106 otherwise returns false.
 107
 108 =cut
 109
 110 sub insert {
 111   my ($self, %options) = @_;
 112
 113   my $dbh = dbh;
 114   my $oldAutoCommit = $FS::UID::AutoCommit;
 115   local $FS::UID::AutoCommit = 0;
 116
 117   my $error = $self->SUPER::insert;
 118
 119   if ( !$error and $self->discountnum ) {
 120     $error = $self->insert_discount;
 121     $error .= ' (setting discount)' if $error;
 122   }
 123
 124   # update $self and any discounts with their amounts
 125   if ( !$error ) {
 126     $error = $self->estimate;
 127     $error .= ' (calculating charges)' if $error;
 128   }
 129
 130   if ( $error ) {
 131     $dbh->rollback if $oldAutoCommit;
 132     return $error;
 133   } else {
 134     $dbh->commit if $oldAutoCommit;
 135     return '';
 136   }
 137 }
 138
 139 =item delete
 140
 141 Delete this record from the database.
 142
 143 =cut
 144
 145 sub delete {
 146   my $self = shift;
 147
 148   my $dbh = dbh;
 149   my $oldAutoCommit = $FS::UID::AutoCommit;
 150   local $FS::UID::AutoCommit = 0;
 151
 152   my $error = $self->delete_details;
 153   if ( $error ) {
 154     $dbh->rollback if $oldAutoCommit;
 155     return $error;
 156   }
 157
 158   foreach ($self->quotation_pkg_discount, $self->quotation_pkg_tax) {
 159     $error = $_->delete;
 160     if ( $error ) {
 161       $dbh->rollback if $oldAutoCommit;
 162       return $error . ' (deleting discount)';
 163     }
 164   }
 165
 166   $error = $self->SUPER::delete;
 167   if ( $error ) {
 168     $dbh->rollback if $oldAutoCommit;
 169     return $error;
 170   } else {
 171     $dbh->commit if $oldAutoCommit;
 172     return '';
 173   }
 174
 175 }
 176
 177 =item replace OLD_RECORD
 178
 179 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 180 returns the error, otherwise returns false.
 181
 182 =item check
 183
 184 Checks all fields to make sure this is a valid quotation package.  If there is
 185 an error, returns the error, otherwise returns false.  Called by the insert
 186 and replace methods.
 187
 188 =cut
 189
 190 sub check {
 191   my $self = shift;
 192
 193   my $error =
 194     $self->ut_numbern('quotationpkgnum')
 195     || $self->ut_foreign_key(  'quotationnum', 'quotation',    'quotationnum' )
 196     || $self->ut_foreign_key(  'pkgpart',      'part_pkg',     'pkgpart'      )
 197     || $self->ut_foreign_keyn( 'locationnum', 'cust_location', 'locationnum'  )
 198     || $self->ut_numbern('start_date')
 199     || $self->ut_numbern('contract_end')
 200     || $self->ut_numbern('quantity')
 201     || $self->ut_moneyn('unitsetup')
 202     || $self->ut_moneyn('unitrecur')
 203     || $self->ut_enum('waive_setup', [ '', 'Y'] )
 204   ;
 205
 206   if ($self->locationnum eq '') {
 207     # use the customer default
 208     my $quotation = $self->quotation;
 209     if ($quotation->custnum) {
 210       $self->set('locationnum', $quotation->cust_main->ship_locationnum);
 211     } elsif ($quotation->prospectnum) {
 212       # use the first non-disabled location for that prospect
 213       my $cust_location = qsearchs('cust_location',
 214         { prospectnum => $quotation->prospectnum,
 215           disabled => '' });
 216       $self->set('locationnum', $cust_location->locationnum) if $cust_location;
 217     } # else the quotation is invalid
 218   }
 219
 220   return $error if $error;
 221
 222   $self->SUPER::check;
 223 }
 224
 225 sub part_pkg {
 226   my $self = shift;
 227   qsearchs('part_pkg', { 'pkgpart' => $self->pkgpart } );
 228 }
 229
 230 sub desc {
 231   my $self = shift;
 232   $self->part_pkg->pkg;
 233 }
 234
 235 =item estimate
 236
 237 Update the quotation_pkg record with the estimated setup and recurring
 238 charges for the package. Returns nothing on success, or an error message
 239 on failure.
 240
 241 =cut
 242
 243 sub estimate {
 244   my $self = shift;
 245   my $part_pkg = $self->part_pkg;
 246   my $quantity = $self->quantity || 1;
 247   my ($unitsetup, $unitrecur);
 248   # calculate base fees
 249   if ( $self->waive_setup eq 'Y' || $self->{'_NO_SETUP_KLUDGE'} ) {
 250     $unitsetup = '0.00';
 251   } else {
 252     $unitsetup = $part_pkg->option('setup_fee',1) || '0.00'; # XXX 3.x only
 253   }
 254   if ( $self->{'_NO_RECUR_KLUDGE'} ) {
 255     $unitrecur = '0.00';
 256   } else {
 257     $unitrecur = $part_pkg->base_recur;
 258   }
 259
 260   #XXX add-on packages
 261
 262   $self->set('unitsetup', $unitsetup);
 263   $self->set('unitrecur', $unitrecur);
 264   my $error = $self->replace;
 265   return $error if $error;
 266
 267   # semi-duplicates calc_discount
 268   my $setup_discount = 0;
 269   my $recur_discount = 0;
 270
 271   my %setup_discounts; # quotationpkgdiscountnum => amount
 272   my %recur_discounts; # quotationpkgdiscountnum => amount
 273
 274   # XXX the order of applying discounts is ill-defined, which matters
 275   # if there are percentage and amount discounts on the same package.
 276   #
 277   # but right now there can only be one discount on any package, so
 278   # it doesn't matter
 279   foreach my $pkg_discount ($self->quotation_pkg_discount) {
 280
 281     my $discount = $pkg_discount->discount;
 282     my $this_setup_discount = 0;
 283     my $this_recur_discount = 0;
 284
 285     if ( $discount->percent > 0 ) {
 286
 287       if ( $discount->setup ) {
 288         $this_setup_discount = ($discount->percent * $unitsetup / 100);
 289       }
 290       $this_recur_discount = ($discount->percent * $unitrecur / 100);
 291
 292     } elsif ( $discount->amount > 0 ) {
 293
 294       my $discount_left = $discount->amount;
 295       if ( $discount->setup ) {
 296         if ( $discount_left > $unitsetup - $setup_discount ) {
 297           # then discount the setup to zero
 298           $discount_left -= $unitsetup - $setup_discount;
 299           $this_setup_discount = $unitsetup - $setup_discount;
 300         } else {
 301           # not enough discount to fully cover the setup
 302           $this_setup_discount = $discount_left;
 303           $discount_left = 0;
 304         }
 305       }
 306       # same logic for recur
 307       if ( $discount_left > $unitrecur - $recur_discount ) {
 308         $this_recur_discount = $unitrecur - $recur_discount;
 309       } else {
 310         $this_recur_discount = $discount_left;
 311       }
 312
 313     }
 314
 315     # increment the total discountage
 316     $setup_discount += $this_setup_discount;
 317     $recur_discount += $this_recur_discount;
 318     # and update the pkg_discount object
 319     $pkg_discount->set('setup_amount', sprintf('%.2f', $setup_discount));
 320     $pkg_discount->set('recur_amount', sprintf('%.2f', $recur_discount));
 321     my $error = $pkg_discount->replace;
 322     return $error if $error;
 323   }
 324
 325   '';
 326 }
 327
 328 =item insert_discount
 329
 330 Associates this package with a discount (see L<FS::cust_pkg_discount>,
 331 possibly inserting a new discount on the fly (see L<FS::discount>). Properties
 332 of the discount will be taken from this object.
 333
 334 =cut
 335
 336 sub insert_discount {
 337   #my ($self, %options) = @_;
 338   my $self = shift;
 339
 340   my $quotation_pkg_discount = FS::quotation_pkg_discount->new( {
 341     'quotationpkgnum' => $self->quotationpkgnum,
 342     'discountnum'     => $self->discountnum,
 343     #for the create a new discount case
 344     '_type'           => $self->discountnum__type,
 345     'amount'      => $self->discountnum_amount,
 346     'percent'     => $self->discountnum_percent,
 347     'months'      => $self->discountnum_months,
 348     'setup'       => $self->discountnum_setup,
 349   } );
 350
 351   $quotation_pkg_discount->insert;
 352 }
 353
 354 sub _item_discount {
 355   my $self = shift;
 356   my @pkg_discounts = $self->pkg_discount;
 357   return if @pkg_discounts == 0;
 358
 359   my @ext;
 360   my $d = {
 361     _is_discount    => 1,
 362     description     => $self->mt('Discount'),
 363     setup_amount    => 0,
 364     recur_amount    => 0,
 365     amount          => 0,
 366     ext_description => \@ext,
 367     # maybe should show quantity/unit discount?
 368   };
 369   foreach my $pkg_discount (@pkg_discounts) {
 370     push @ext, $pkg_discount->description;
 371     $d->{setup_amount} -= $pkg_discount->setup_amount;
 372     $d->{recur_amount} -= $pkg_discount->recur_amount;
 373   }
 374   $d->{setup_amount} *= $self->quantity || 1;
 375   $d->{recur_amount} *= $self->quantity || 1;
 376   $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
 377
 378   return $d;
 379 }
 380
 381 sub setup {
 382   my $self = shift;
 383   ($self->unitsetup - sum(0, map { $_->setup_amount } $self->pkg_discount))
 384     * ($self->quantity || 1);
 385 }
 386
 387 sub recur {
 388   my $self = shift;
 389   ($self->unitrecur - sum(0, map { $_->recur_amount } $self->pkg_discount))
 390     * ($self->quantity || 1);
 391 }
 392
 393 =item delete_details
 394
 395 Deletes all quotation_pkgs_details associated with this pkg (see L<FS::quotation_pkg_detail>).
 396
 397 =cut
 398
 399 sub delete_details {
 400   my $self = shift;
 401
 402   my $oldAutoCommit = $FS::UID::AutoCommit;
 403   local $FS::UID::AutoCommit = 0;
 404   my $dbh = dbh;
 405
 406   foreach my $detail ( qsearch('quotation_pkg_detail',{ 'quotationpkgnum' => $self->quotationpkgnum }) ) {
 407     my $error = $detail->delete;
 408     if ( $error ) {
 409       $dbh->rollback if $oldAutoCommit;
 410       return "error removing old detail: $error";
 411     }
 412   }
 413
 414   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 415   '';
 416
 417 }
 418
 419 =item set_details PARAM
 420
 421 Sets new quotation details for this package (see L<FS::quotation_pkg_detail>),
 422 removing existing details.
 423
 424 Recognizes the following parameters:
 425
 426 details - arrayref of strings, one for each new detail
 427
 428 copy_on_order - if true, sets copy_on_order flag on new details
 429
 430 If there is an error, returns the error, otherwise returns false.
 431
 432 =cut
 433
 434 sub set_details {
 435   my $self = shift;
 436   my %opt = @_;
 437
 438   $opt{'details'} ||= [];
 439   my @details = @{$opt{'details'}};
 440
 441   my $oldAutoCommit = $FS::UID::AutoCommit;
 442   local $FS::UID::AutoCommit = 0;
 443   my $dbh = dbh;
 444
 445   my $error = $self->delete_details;
 446   if ( $error ) {
 447     $dbh->rollback if $oldAutoCommit;
 448     return $error;
 449   }
 450
 451   foreach my $detail ( @details ) {
 452     my $quotation_pkg_detail = new FS::quotation_pkg_detail {
 453       'quotationpkgnum' => $self->quotationpkgnum,
 454       'detail' => $detail,
 455       'copy_on_order' => $opt{'copy_on_order'} ? 'Y' : '',
 456     };
 457     $error = $quotation_pkg_detail->insert;
 458     if ( $error ) {
 459       $dbh->rollback if $oldAutoCommit;
 460       return "error adding new detail: $error";
 461     }
 462   }
 463
 464   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 465   '';
 466
 467 }
 468
 469 sub details_header {
 470   return ();
 471 }
 472
 473 =item cust_bill_pkg_display [ type => TYPE ]
 474
 475 =cut
 476
 477 sub cust_bill_pkg_display {
 478   my ( $self, %opt ) = @_;
 479
 480   my $type = $opt{type} if exists $opt{type};
 481   return () if $type eq 'U'; #quotations don't have usage
 482
 483   if ( $self->get('display') ) {
 484     return ( grep { defined($type) ? ($type eq $_->type) : 1 }
 485                @{ $self->get('display') }
 486            );
 487   } else {
 488
 489     #??
 490     my $setup = $self->new($self->hashref);
 491     $setup->{'_NO_RECUR_KLUDGE'} = 1;
 492     $setup->{'type'} = 'S';
 493     my $recur = $self->new($self->hashref);
 494     $recur->{'_NO_SETUP_KLUDGE'} = 1;
 495     $recur->{'type'} = 'R';
 496
 497     if ( $type eq 'S' ) {
 498       return ($setup);
 499     } elsif ( $type eq 'R' ) {
 500       return ($recur);
 501     } else {
 502       #return ($setup, $recur);
 503       return ($self);
 504     }
 505
 506   }
 507
 508 }
 509
 510 =item cust_main
 511
 512 Returns the customer (L<FS::cust_main> object).
 513
 514 =cut
 515
 516 sub cust_main {
 517   my $self = shift;
 518   my $quotation = FS::quotation->by_key($self->quotationnum) or return '';
 519   $quotation->cust_main;
 520 }
 521
 522 sub tax_locationnum {
 523   my $self = shift;
 524   $self->locationnum;
 525 }
 526
 527 #stub for 3.x
 528
 529 sub quotation {
 530   my $self = shift;
 531   FS::quotation->by_key($self->quotationnum);
 532 }
 533
 534 sub quotation_pkg_detail {
 535   my $self = shift;
 536   sort { $a->detailnum <=> $b->detailnum }
 537     qsearch('quotation_pkg_detail', { quotationpkgnum => $self->quotationpkgnum });
 538 }
 539
 540 sub quotation_pkg_discount {
 541   my $self = shift;
 542   qsearch('quotation_pkg_discount', { quotationpkgnum => $self->quotationpkgnum });
 543 }
 544
 545 sub quotation_pkg_tax {
 546   my $self = shift;
 547   qsearch('quotation_pkg_tax', { quotationpkgnum => $self->quotationpkgnum });
 548 }
 549
 550 sub cust_location {
 551   my $self = shift;
 552   $self->locationnum ? qsearchs('cust_location', { locationnum => $self->locationnum }) : '';
 553 }
 554
 555
 556 sub _upgrade_data {
 557   my $class = shift;
 558   my @quotation_pkg_without_location =
 559     qsearch( 'quotation_pkg', { locationnum => '' } );
 560   if (@quotation_pkg_without_location) {
 561     warn "setting default location on quotation_pkg records\n";
 562     foreach my $quotation_pkg (@quotation_pkg_without_location) {
 563       # check() will fix this
 564       my $error = $quotation_pkg->replace;
 565       if ($error) {
 566         die "quotation #".$quotation_pkg->quotationnum.": $error\n";
 567       }
 568     }
 569   }
 570   '';
 571 }
 572
 573 =back
 574
 575 =head1 BUGS
 576
 577 Doesn't support fees, or add-on packages.
 578
 579 =head1 SEE ALSO
 580
 581 L<FS::Record>, schema.html from the base documentation.
 582
 583 =cut
 584
 585 1;
 586