FS/FS/quotation_pkg.pm

   1 package FS::quotation_pkg;
   2 use base qw( FS::TemplateItem_Mixin FS::Record );
   3
   4 use strict;
   5 use FS::Record qw( qsearchs dbh ); #qsearch
   6 use FS::part_pkg;
   7 use FS::quotation_pkg_discount; #so its loaded when TemplateItem_Mixin needs it
   8 use List::Util qw(sum);
   9
  10 =head1 NAME
  11
  12 FS::quotation_pkg - Object methods for quotation_pkg records
  13
  14 =head1 SYNOPSIS
  15
  16   use FS::quotation_pkg;
  17
  18   $record = new FS::quotation_pkg \%hash;
  19   $record = new FS::quotation_pkg { 'column' => 'value' };
  20
  21   $error = $record->insert;
  22
  23   $error = $new_record->replace($old_record);
  24
  25   $error = $record->delete;
  26
  27   $error = $record->check;
  28
  29 =head1 DESCRIPTION
  30
  31 An FS::quotation_pkg object represents a quotation package.
  32 FS::quotation_pkg inherits from FS::Record.  The following fields are currently
  33 supported:
  34
  35 =over 4
  36
  37 =item quotationpkgnum
  38
  39 primary key
  40
  41 =item pkgpart
  42
  43 pkgpart (L<FS::part_pkg>) of the package
  44
  45 =item locationnum
  46
  47 locationnum (L<FS::cust_location>) where the package will be in service
  48
  49 =item start_date
  50
  51 expected start date for the package, as a timestamp
  52
  53 =item contract_end
  54
  55 contract end date
  56
  57 =item quantity
  58
  59 quantity
  60
  61 =item waive_setup
  62
  63 'Y' to waive the setup fee
  64
  65 =item unitsetup
  66
  67 The amount per package that will be charged in setup/one-time fees.
  68
  69 =item unitrecur
  70
  71 The amount per package that will be charged per billing cycle.
  72
  73 =back
  74
  75 =head1 METHODS
  76
  77 =over 4
  78
  79 =item new HASHREF
  80
  81 Creates a new quotation package.  To add the quotation package to the database,
  82 see L<"insert">.
  83
  84 Note that this stores the hash reference, not a distinct copy of the hash it
  85 points to.  You can ask the object for a copy with the I<hash> method.
  86
  87 =cut
  88
  89 sub table { 'quotation_pkg'; }
  90
  91 sub display_table         { 'quotation_pkg'; }
  92
  93 #forget it, just overriding cust_bill_pkg_display entirely
  94 #sub display_table_orderby { 'quotationpkgnum'; } # something else?
  95 #                                                 #  (for invoice display order)
  96
  97 sub discount_table        { 'quotation_pkg_discount'; }
  98
  99 =item insert
 100
 101 Adds this record to the database.  If there is an error, returns the error,
 102 otherwise returns false.
 103
 104 =cut
 105
 106 sub insert {
 107   my ($self, %options) = @_;
 108
 109   my $dbh = dbh;
 110   my $oldAutoCommit = $FS::UID::AutoCommit;
 111   local $FS::UID::AutoCommit = 0;
 112
 113   my $error = $self->SUPER::insert;
 114
 115   if ( !$error and $self->discountnum ) {
 116     $error = $self->insert_discount;
 117     $error .= ' (setting discount)' if $error;
 118   }
 119
 120   # update $self and any discounts with their amounts
 121   if ( !$error ) {
 122     $error = $self->estimate;
 123     $error .= ' (calculating charges)' if $error;
 124   }
 125
 126   if ( $error ) {
 127     $dbh->rollback if $oldAutoCommit;
 128     return $error;
 129   } else {
 130     $dbh->commit if $oldAutoCommit;
 131     return '';
 132   }
 133 }
 134
 135 =item delete
 136
 137 Delete this record from the database.
 138
 139 =cut
 140
 141 sub delete {
 142   my $self = shift;
 143
 144   my $dbh = dbh;
 145   my $oldAutoCommit = $FS::UID::AutoCommit;
 146   local $FS::UID::AutoCommit = 0;
 147
 148   foreach ($self->quotation_pkg_discount, $self->quotation_pkg_tax) {
 149     my $error = $_->delete;
 150     if ( $error ) {
 151       $dbh->rollback if $oldAutoCommit;
 152       return $error . ' (deleting discount)';
 153     }
 154   }
 155
 156   my $error = $self->SUPER::delete;
 157   if ( $error ) {
 158     $dbh->rollback if $oldAutoCommit;
 159     return $error;
 160   } else {
 161     $dbh->commit if $oldAutoCommit;
 162     return '';
 163   }
 164
 165 }
 166
 167 =item replace OLD_RECORD
 168
 169 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 170 returns the error, otherwise returns false.
 171
 172 =item check
 173
 174 Checks all fields to make sure this is a valid quotation package.  If there is
 175 an error, returns the error, otherwise returns false.  Called by the insert
 176 and replace methods.
 177
 178 =cut
 179
 180 sub check {
 181   my $self = shift;
 182
 183   my $error =
 184     $self->ut_numbern('quotationpkgnum')
 185     || $self->ut_foreign_key(  'quotationnum', 'quotation',    'quotationnum' )
 186     || $self->ut_foreign_key(  'pkgpart',      'part_pkg',     'pkgpart'      )
 187     || $self->ut_foreign_keyn( 'locationnum', 'cust_location', 'locationnum'  )
 188     || $self->ut_numbern('start_date')
 189     || $self->ut_numbern('contract_end')
 190     || $self->ut_numbern('quantity')
 191     || $self->ut_moneyn('unitsetup')
 192     || $self->ut_moneyn('unitrecur')
 193     || $self->ut_enum('waive_setup', [ '', 'Y'] )
 194   ;
 195
 196   return $error if $error;
 197
 198   $self->SUPER::check;
 199 }
 200
 201 #it looks redundant with a v4.x+ auto-generated method, but need to override
 202 # FS::TemplateItem_Mixin's version
 203 sub part_pkg {
 204   my $self = shift;
 205   qsearchs('part_pkg', { 'pkgpart' => $self->pkgpart } );
 206 }
 207
 208 sub desc {
 209   my $self = shift;
 210   $self->part_pkg->pkg;
 211 }
 212
 213 =item estimate
 214
 215 Update the quotation_pkg record with the estimated setup and recurring
 216 charges for the package. Returns nothing on success, or an error message
 217 on failure.
 218
 219 =cut
 220
 221 sub estimate {
 222   my $self = shift;
 223   my $part_pkg = $self->part_pkg;
 224   my $quantity = $self->quantity || 1;
 225   my ($unitsetup, $unitrecur);
 226   # calculate base fees
 227   if ( $self->waive_setup eq 'Y' || $self->{'_NO_SETUP_KLUDGE'} ) {
 228     $unitsetup = '0.00';
 229   } else {
 230     $unitsetup = $part_pkg->base_setup;
 231   }
 232   if ( $self->{'_NO_RECUR_KLUDGE'} ) {
 233     $unitrecur = '0.00';
 234   } else {
 235     $unitrecur = $part_pkg->base_recur;
 236   }
 237
 238   #XXX add-on packages
 239
 240   $self->set('unitsetup', $unitsetup);
 241   $self->set('unitrecur', $unitrecur);
 242   my $error = $self->replace;
 243   return $error if $error;
 244
 245   # semi-duplicates calc_discount
 246   my $setup_discount = 0;
 247   my $recur_discount = 0;
 248
 249   my %setup_discounts; # quotationpkgdiscountnum => amount
 250   my %recur_discounts; # quotationpkgdiscountnum => amount
 251
 252   # XXX the order of applying discounts is ill-defined, which matters
 253   # if there are percentage and amount discounts on the same package.
 254   #
 255   # but right now there can only be one discount on any package, so
 256   # it doesn't matter
 257   foreach my $pkg_discount ($self->quotation_pkg_discount) {
 258
 259     my $discount = $pkg_discount->discount;
 260     my $this_setup_discount = 0;
 261     my $this_recur_discount = 0;
 262
 263     if ( $discount->percent > 0 ) {
 264
 265       if ( $discount->setup ) {
 266         $this_setup_discount = ($discount->percent * $unitsetup / 100);
 267       }
 268       $this_recur_discount = ($discount->percent * $unitrecur / 100);
 269
 270     } elsif ( $discount->amount > 0 ) {
 271
 272       my $discount_left = $discount->amount;
 273       if ( $discount->setup ) {
 274         if ( $discount_left > $unitsetup - $setup_discount ) {
 275           # then discount the setup to zero
 276           $discount_left -= $unitsetup - $setup_discount;
 277           $this_setup_discount = $unitsetup - $setup_discount;
 278         } else {
 279           # not enough discount to fully cover the setup
 280           $this_setup_discount = $discount_left;
 281           $discount_left = 0;
 282         }
 283       }
 284       # same logic for recur
 285       if ( $discount_left > $unitrecur - $recur_discount ) {
 286         $this_recur_discount = $unitrecur - $recur_discount;
 287       } else {
 288         $this_recur_discount = $discount_left;
 289       }
 290
 291     }
 292
 293     # increment the total discountage
 294     $setup_discount += $this_setup_discount;
 295     $recur_discount += $this_recur_discount;
 296     # and update the pkg_discount object
 297     $pkg_discount->set('setup_amount', sprintf('%.2f', $setup_discount));
 298     $pkg_discount->set('recur_amount', sprintf('%.2f', $recur_discount));
 299     my $error = $pkg_discount->replace;
 300     return $error if $error;
 301   }
 302
 303   '';
 304 }
 305
 306 =item insert_discount
 307
 308 Associates this package with a discount (see L<FS::cust_pkg_discount>,
 309 possibly inserting a new discount on the fly (see L<FS::discount>). Properties
 310 of the discount will be taken from this object.
 311
 312 =cut
 313
 314 sub insert_discount {
 315   #my ($self, %options) = @_;
 316   my $self = shift;
 317
 318   my $quotation_pkg_discount = FS::quotation_pkg_discount->new( {
 319     'quotationpkgnum' => $self->quotationpkgnum,
 320     'discountnum'     => $self->discountnum,
 321     #for the create a new discount case
 322     '_type'           => $self->discountnum__type,
 323     'amount'      => $self->discountnum_amount,
 324     'percent'     => $self->discountnum_percent,
 325     'months'      => $self->discountnum_months,
 326     'setup'       => $self->discountnum_setup,
 327   } );
 328
 329   $quotation_pkg_discount->insert;
 330 }
 331
 332 sub _item_discount {
 333   my $self = shift;
 334   my @pkg_discounts = $self->pkg_discount;
 335   return if @pkg_discounts == 0;
 336
 337   my @ext;
 338   my $d = {
 339     _is_discount    => 1,
 340     description     => $self->mt('Discount'),
 341     setup_amount    => 0,
 342     recur_amount    => 0,
 343     amount          => 0,
 344     ext_description => \@ext,
 345     # maybe should show quantity/unit discount?
 346   };
 347   foreach my $pkg_discount (@pkg_discounts) {
 348     push @ext, $pkg_discount->description;
 349     $d->{setup_amount} -= $pkg_discount->setup_amount;
 350     $d->{recur_amount} -= $pkg_discount->recur_amount;
 351   }
 352   $d->{setup_amount} *= $self->quantity || 1;
 353   $d->{recur_amount} *= $self->quantity || 1;
 354   $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
 355
 356   return $d;
 357 }
 358
 359 sub setup {
 360   my $self = shift;
 361   ($self->unitsetup - sum(0, map { $_->setup_amount } $self->pkg_discount))
 362     * ($self->quantity || 1);
 363 }
 364
 365 sub recur {
 366   my $self = shift;
 367   ($self->unitrecur - sum(0, map { $_->recur_amount } $self->pkg_discount))
 368     * ($self->quantity || 1);
 369 }
 370
 371 =item part_pkg_currency_option OPTIONNAME
 372
 373 Returns a two item list consisting of the currency of this quotation's customer
 374 or prospect, if any, and a value for the provided option.  If the customer or
 375 prospect has a currency, the value is the option value the given name and the
 376 currency (see L<FS::part_pkg_currency>).  Otherwise, if the customer or
 377 prospect has no currency, is the regular option value for the given name (see
 378 L<FS::part_pkg_option>).
 379
 380 =cut
 381
 382 #false laziness w/cust_pkg->part_pkg_currency_option
 383 sub part_pkg_currency_option {
 384   my( $self, $optionname ) = @_;
 385   my $part_pkg = $self->part_pkg;
 386   my $prospect_or_customer = $self->cust_main || $self->prospect_main;
 387   if ( my $currency = $prospect_or_customer->currency ) {
 388     ($currency, $part_pkg->part_pkg_currency_option($currency, $optionname) );
 389   } else {
 390     ('', $part_pkg->option($optionname) );
 391   }
 392 }
 393
 394
 395 =item cust_bill_pkg_display [ type => TYPE ]
 396
 397 =cut
 398
 399 sub cust_bill_pkg_display {
 400   my ( $self, %opt ) = @_;
 401
 402   my $type = $opt{type} if exists $opt{type};
 403   return () if $type eq 'U'; #quotations don't have usage
 404
 405   if ( $self->get('display') ) {
 406     return ( grep { defined($type) ? ($type eq $_->type) : 1 }
 407                @{ $self->get('display') }
 408            );
 409   } else {
 410
 411     #??
 412     my $setup = $self->new($self->hashref);
 413     $setup->{'_NO_RECUR_KLUDGE'} = 1;
 414     $setup->{'type'} = 'S';
 415     my $recur = $self->new($self->hashref);
 416     $recur->{'_NO_SETUP_KLUDGE'} = 1;
 417     $recur->{'type'} = 'R';
 418
 419     if ( $type eq 'S' ) {
 420 sub tax_locationnum {
 421   my $self = shift;
 422   $self->locationnum;
 423 }
 424
 425       return ($setup);
 426     } elsif ( $type eq 'R' ) {
 427       return ($recur);
 428     } else {
 429       #return ($setup, $recur);
 430       return ($self);
 431     }
 432
 433   }
 434
 435 }
 436
 437 =item cust_main
 438
 439 Returns the customer (L<FS::cust_main> object).
 440
 441 =cut
 442
 443 sub cust_main {
 444   my $self = shift;
 445   my $quotation = $self->quotation or return '';
 446   $quotation->cust_main;
 447 }
 448
 449 =item prospect_main
 450
 451 Returns the prospect (L<FS::prospect_main> object).
 452
 453 =cut
 454
 455 sub prospect_main {
 456   my $self = shift;
 457   my $quotation = $self->quotation or return '';
 458   $quotation->prospect_main;
 459 }
 460
 461 =back
 462
 463 =head1 BUGS
 464
 465 Doesn't support fees, or add-on packages.
 466
 467 =head1 SEE ALSO
 468
 469 L<FS::Record>, schema.html from the base documentation.
 470
 471 =cut
 472
 473 1;
 474