service label localization, internals and UI, #71347
[freeside.git] / FS / FS / part_svc.pm
1 package FS::part_svc;
2
3 use base qw(FS::o2m_Common FS::Record);
4 use strict;
5 use vars qw( @ISA $DEBUG );
6 use Tie::IxHash;
7 use FS::Record qw( qsearch qsearchs fields dbh );
8 use FS::Schema qw( dbdef );
9 use FS::part_svc_column;
10 use FS::part_export;
11 use FS::export_svc;
12 use FS::cust_svc;
13 use FS::part_svc_class;
14 use FS::part_svc_msgcat;
15
16 $DEBUG = 0;
17
18 =head1 NAME
19
20 FS::part_svc - Object methods for part_svc objects
21
22 =head1 SYNOPSIS
23
24   use FS::part_svc;
25
26   $record = new FS::part_svc \%hash
27   $record = new FS::part_svc { 'column' => 'value' };
28
29   $error = $record->insert;
30   $error = $record->insert( [ 'pseudofield' ] );
31   $error = $record->insert( [ 'pseudofield' ], \%exportnums );
32
33   $error = $new_record->replace($old_record);
34   $error = $new_record->replace($old_record, '1.3-COMPAT', [ 'pseudofield' ] );
35   $error = $new_record->replace($old_record, '1.3-COMPAT', [ 'pseudofield' ], \%exportnums );
36
37   $error = $record->delete;
38
39   $error = $record->check;
40
41 =head1 DESCRIPTION
42
43 An FS::part_svc represents a service definition.  FS::part_svc inherits from
44 FS::Record.  The following fields are currently supported:
45
46 =over 4
47
48 =item svcpart - primary key (assigned automatically for new service definitions)
49
50 =item svc - text name of this service definition
51
52 =item svcdb - table used for this service.  See L<FS::svc_acct>,
53 L<FS::svc_domain>, and L<FS::svc_forward>, among others.
54
55 =item classnum - Optional service class (see L<FS::svc_class>)
56
57 =item disabled - Disabled flag, empty or `Y'
58
59 =item preserve - Preserve after cancellation, empty or 'Y'
60
61 =item selfservice_access - Access allowed to the service via self-service:
62 empty for full access, "readonly" for read-only, "hidden" to hide it entirely
63
64 =item restrict_edit_password - Require the "Provision customer service" access
65 right to change the password field, rather than just "Edit password".  Only
66 relevant to svc_acct for now.
67
68 =item has_router - Allow the service to have an L<FS::router> connected 
69 through it.  Probably only relevant to svc_broadband, svc_acct, and svc_dsl
70 for now.
71
72 =back
73
74 =head1 METHODS
75
76 =over 4
77
78 =item new HASHREF
79
80 Creates a new service definition.  To add the service definition to the
81 database, see L<"insert">.
82
83 =cut
84
85 sub table { 'part_svc'; }
86
87 =item insert [ EXTRA_FIELDS_ARRAYREF [ , EXPORTNUMS_HASHREF [ , JOB ] ] ] 
88
89 Adds this service definition to the database.  If there is an error, returns
90 the error, otherwise returns false.
91
92 The following pseudo-fields may be defined, and will be maintained in
93 the part_svc_column table appropriately (see L<FS::part_svc_column>).
94
95 =over 4
96
97 =item I<svcdb>__I<field> - Default or fixed value for I<field> in I<svcdb>.
98
99 =item I<svcdb>__I<field>_label
100
101 =item I<svcdb>__I<field>_flag - defines I<svcdb>__I<field> action: null or empty (no default), `D' for default, `F' for fixed (unchangeable), , `S' for selectable choice, `M' for manual selection from inventory, or `A' for automatic selection from inventory.  For virtual fields, can also be 'X' for excluded.
102
103 =item I<svcdb>__I<field>_required - I<field> should always have a true value
104
105 =back
106
107 If you want to add part_svc_column records for fields that do not exist as
108 fields in the I<svcdb> table, make sure to list then in 
109 EXTRA_FIELDS_ARRAYREF also.
110
111 If EXPORTNUMS_HASHREF is specified (keys are exportnums and values are
112 boolean), the appopriate export_svc records will be inserted.
113
114 TODOC: JOB
115
116 =cut
117
118 sub insert {
119   my $self = shift;
120   my @fields = ();
121   @fields = @{shift(@_)} if @_;
122   my $exportnums = shift || {};
123   my $job = '';
124   $job = shift if @_;
125
126   local $SIG{HUP} = 'IGNORE';
127   local $SIG{INT} = 'IGNORE';
128   local $SIG{QUIT} = 'IGNORE';
129   local $SIG{TERM} = 'IGNORE';
130   local $SIG{TSTP} = 'IGNORE';
131   local $SIG{PIPE} = 'IGNORE';
132
133   my $oldAutoCommit = $FS::UID::AutoCommit;
134   local $FS::UID::AutoCommit = 0;
135   my $dbh = dbh;
136
137   my $error = $self->SUPER::insert;
138   if ( $error ) {
139     $dbh->rollback if $oldAutoCommit;
140     return $error;
141   }
142
143   # add part_svc_column records
144
145   my $svcdb = $self->svcdb;
146   foreach my $field (fields($svcdb), @fields) {
147     next if $field eq 'svcnum';
148     my $prefix = $svcdb.'__';
149     if ( defined( $self->getfield($prefix.$field.'_flag'))
150       or defined($self->getfield($prefix.$field.'_required'))
151       or length($self->getfield($prefix.$field.'_label'))
152     ) {
153       my $part_svc_column = $self->part_svc_column($field);
154       my $previous = qsearchs('part_svc_column', {
155         'svcpart'    => $self->svcpart,
156         'columnname' => $field,
157       } );
158
159       my $flag  = $self->getfield($prefix.$field.'_flag');
160       my $label = $self->getfield($prefix.$field.'_label');
161       my $required = $self->getfield($prefix.$field.'_required') ? 'Y' : '';
162       if ( uc($flag) =~ /^([A-Z])$/ || $label !~ /^\s*$/ ) {
163
164         if ( uc($flag) =~ /^([A-Z])$/ ) {
165           my $parser = FS::part_svc->svc_table_fields($svcdb)->{$field}->{parse}
166                        || sub { shift };
167           $part_svc_column->setfield('columnflag', $1);
168           $part_svc_column->setfield('columnvalue',
169             &$parser($self->getfield($prefix.$field))
170           );
171         }
172
173         $part_svc_column->setfield('columnlabel', $label)
174           if $label !~ /^\s*$/;
175
176         $part_svc_column->setfield('required', $required);
177
178         if ( $previous ) {
179           $error = $part_svc_column->replace($previous);
180         } else {
181           $error = $part_svc_column->insert;
182         }
183
184       } else {
185         $error = $previous ? $previous->delete : '';
186       }
187       if ( $error ) {
188         $dbh->rollback if $oldAutoCommit;
189         return $error;
190       }
191
192     }
193   }
194
195   # add export_svc records
196   my @exportnums = grep $exportnums->{$_}, keys %$exportnums;
197   my $slice = 100/scalar(@exportnums) if @exportnums;
198   my $done = 0;
199   foreach my $exportnum ( @exportnums ) {
200     my $export_svc = new FS::export_svc ( {
201       'exportnum' => $exportnum,
202       'svcpart'   => $self->svcpart,
203       'role'      => $exportnums->{$exportnum},
204     } );
205     $error = $export_svc->insert($job, $slice*$done++, $slice);
206     if ( $error ) {
207       $dbh->rollback if $oldAutoCommit;
208       return $error;
209     }
210   }
211
212   # XXX shouldn't this update fixed values?
213
214   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
215
216   '';
217 }
218
219 =item delete
220
221 Currently unimplemented.  Set the "disabled" field instead.
222
223 =cut
224
225 sub delete {
226   return "Can't (yet?) delete service definitions.";
227 # check & make sure the svcpart isn't in cust_svc or pkg_svc (in any packages)?
228 }
229
230 =item replace OLD_RECORD [ '1.3-COMPAT' [ , EXTRA_FIELDS_ARRAYREF [ , EXPORTNUMS_HASHREF [ , JOB ] ] ] ]
231
232 Replaces OLD_RECORD with this one in the database.  If there is an error,
233 returns the error, otherwise returns false.
234
235 TODOC: 1.3-COMPAT
236
237 TODOC: EXTRA_FIELDS_ARRAYREF (same as insert method)
238
239 TODOC: JOB
240
241 =cut
242
243 sub replace {
244   my ( $new, $old ) = ( shift, shift );
245   my $compat = '';
246   my @fields = ();
247   my $exportnums;
248   my $job = '';
249   if ( @_ && $_[0] eq '1.3-COMPAT' ) {
250     shift;
251     $compat = '1.3';
252     @fields = @{shift(@_)} if @_;
253     $exportnums = @_ ? shift : '';
254     $job = shift if @_;
255   } else {
256     return 'non-1.3-COMPAT interface not yet written';
257     #not yet implemented
258   }
259
260   return "Can't change svcdb for an existing service definition!"
261     unless $old->svcdb eq $new->svcdb;
262
263   local $SIG{HUP} = 'IGNORE';
264   local $SIG{INT} = 'IGNORE';
265   local $SIG{QUIT} = 'IGNORE';
266   local $SIG{TERM} = 'IGNORE';
267   local $SIG{TSTP} = 'IGNORE';
268   local $SIG{PIPE} = 'IGNORE';
269
270   my $oldAutoCommit = $FS::UID::AutoCommit;
271   local $FS::UID::AutoCommit = 0;
272   my $dbh = dbh;
273
274   my $error = $new->SUPER::replace( $old );
275   if ( $error ) {
276     $dbh->rollback if $oldAutoCommit;
277     return $error;
278   }
279
280   if ( $compat eq '1.3' ) {
281
282    # maintain part_svc_column records
283
284     my $svcdb = $new->svcdb;
285     foreach my $field (fields($svcdb),@fields) {
286       next if $field eq 'svcnum';
287       my $prefix = $svcdb.'__';
288       if ( defined( $new->getfield($prefix.$field.'_flag'))
289         or defined($new->getfield($prefix.$field.'_required'))
290         or length($new->getfield($prefix.$field.'_label'))
291       ) {
292         my $part_svc_column = $new->part_svc_column($field);
293         my $previous = qsearchs('part_svc_column', {
294           'svcpart'    => $new->svcpart,
295           'columnname' => $field,
296         } );
297
298         my $flag  = $new->getfield($svcdb.'__'.$field.'_flag');
299         my $label = $new->getfield($svcdb.'__'.$field.'_label');
300         my $required = $new->getfield($svcdb.'__'.$field.'_required') ? 'Y' : '';
301  
302         if ( uc($flag) =~ /^([A-Z])$/ || $label !~ /^\s*$/ ) {
303
304           if ( uc($flag) =~ /^([A-Z])$/ ) {
305             $part_svc_column->setfield('columnflag', $1);
306             my $parser = FS::part_svc->svc_table_fields($svcdb)->{$field}->{parse}
307                        || sub { shift };
308             $part_svc_column->setfield('columnvalue',
309               &$parser($new->getfield($svcdb.'__'.$field))
310             );
311           } else {
312             $part_svc_column->setfield('columnflag',  '');
313             $part_svc_column->setfield('columnvalue', '');
314           }
315
316           $part_svc_column->setfield('columnlabel', $label)
317             if $label !~ /^\s*$/;
318
319           $part_svc_column->setfield('required', $required);
320
321           if ( $previous ) {
322             $error = $part_svc_column->replace($previous);
323           } else {
324             $error = $part_svc_column->insert;
325           }
326         } else {
327           $error = $previous ? $previous->delete : '';
328         }
329         if ( $error ) {
330           $dbh->rollback if $oldAutoCommit;
331           return $error;
332         }
333       }
334     }
335
336     # maintain export_svc records
337
338     if ( $exportnums ) { # hash of exportnum => role
339
340       #false laziness w/ edit/process/agent_type.cgi
341       #and, more importantly, with m2m_Common
342       my @new_export_svc = ();
343       foreach my $part_export ( qsearch('part_export', {}) ) {
344         my $exportnum = $part_export->exportnum;
345         my $hashref = {
346           'exportnum' => $exportnum,
347           'svcpart'   => $new->svcpart,
348         };
349         my $export_svc = qsearchs('export_svc', $hashref);
350
351         if ( $export_svc ) {
352           my $old_role = $export_svc->role || 1; # 1 = null in the db
353           if ( ! $exportnums->{$exportnum}
354                or $old_role ne $exportnums->{$exportnum} ) {
355
356             $error = $export_svc->delete;
357             if ( $error ) {
358               $dbh->rollback if $oldAutoCommit;
359               return $error;
360             }
361             undef $export_svc; # on a role change, force it to be reinserted
362
363           }
364         } # if $export_svc
365         if ( ! $export_svc && $exportnums->{$exportnum} ) {
366           # also applies if it's been undef'd because of role change
367           $hashref->{role} = $exportnums->{$exportnum};
368           push @new_export_svc, new FS::export_svc ( $hashref );
369         }
370
371       }
372
373       my $slice = 100/scalar(@new_export_svc) if @new_export_svc;
374       my $done = 0;
375       foreach my $export_svc (@new_export_svc) {
376         $error = $export_svc->insert($job, $slice*$done++, $slice);
377         if ( $error ) {
378           $dbh->rollback if $oldAutoCommit;
379           return $error;
380         }
381         if ( $job ) {
382           $error = $job->update_statustext( int( $slice * $done ) );
383           if ( $error ) {
384             $dbh->rollback if $oldAutoCommit;
385             return $error;
386           }
387         }
388       }
389
390     }
391
392   } else {
393     $dbh->rollback if $oldAutoCommit;
394     return 'non-1.3-COMPAT interface not yet written';
395     #not yet implemented
396   }
397
398   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
399
400   '';
401 }
402
403 =item check
404
405 Checks all fields to make sure this is a valid service definition.  If there is
406 an error, returns the error, otherwise returns false.  Called by the insert
407 and replace methods.
408
409 =cut
410
411 sub check {
412   my $self = shift;
413
414   my $error;
415   $error=
416     $self->ut_numbern('svcpart')
417     || $self->ut_text('svc')
418     || $self->ut_alpha('svcdb')
419     || $self->ut_flag('disabled')
420     || $self->ut_flag('preserve')
421     || $self->ut_enum('selfservice_access', [ '', 'hidden', 'readonly' ] )
422     || $self->ut_foreign_keyn('classnum', 'part_svc_class', 'classnum' )
423     || $self->ut_flag('restrict_edit_password')
424     || $self->ut_flag('has_router')
425 ;
426   return $error if $error;
427
428   my @fields = eval { fields( $self->svcdb ) }; #might die
429   return "Unknown svcdb: ". $self->svcdb. " (Error: $@)"
430     unless @fields;
431
432   $self->SUPER::check;
433 }
434
435 =item part_svc_column COLUMNNAME
436
437 Returns the part_svc_column object (see L<FS::part_svc_column>) for the given
438 COLUMNNAME, or a new part_svc_column object if none exists.
439
440 =cut
441
442 sub part_svc_column {
443   my( $self, $columnname) = @_;
444   $self->svcpart &&
445     qsearchs('part_svc_column',  {
446                                    'svcpart'    => $self->svcpart,
447                                    'columnname' => $columnname,
448                                  }
449   ) or new FS::part_svc_column {
450                                  'svcpart'    => $self->svcpart,
451                                  'columnname' => $columnname,
452                                };
453 }
454
455 =item all_part_svc_column
456
457 =cut
458
459 sub all_part_svc_column {
460   my $self = shift;
461   qsearch('part_svc_column', { 'svcpart' => $self->svcpart } );
462 }
463
464 =item part_export [ EXPORTTYPE ]
465
466 Returns a list of all exports (see L<FS::part_export>) for this service, or,
467 if an export type is specified, only returns exports of the given type.
468
469 =cut
470
471 sub part_export {
472   my $self = shift;
473   my %search;
474   $search{'exporttype'} = shift if @_;
475   map { $_ } #behavior of sort undefined in scalar context
476     sort { $a->weight <=> $b->weight }
477       map { qsearchs('part_export', { 'exportnum'=>$_->exportnum, %search } ) }
478         qsearch('export_svc', { 'svcpart'=>$self->svcpart } );
479 }
480
481 =item part_export_usage
482
483 Returns a list of any exports (see L<FS::part_export>) for this service that
484 are capable of reporting usage information.
485
486 =cut
487
488 sub part_export_usage {
489   my $self = shift;
490   grep $_->can('usage_sessions'), $self->part_export;
491 }
492
493 =item part_export_did
494
495 Returns a list of any exports (see L<FS::part_export>) for this service that
496 are capable of returing available DID (phone number) information.
497
498 =cut
499
500 sub part_export_did {
501   my $self = shift;
502   grep $_->can('get_dids'), $self->part_export;
503 }
504
505 =item part_export_dsl_pull
506
507 Returns a list of any exports (see L<FS::part_export>) for this service that
508 are capable of pulling/pushing DSL orders.
509
510 =cut
511
512 sub part_export_dsl_pull {
513     my $self = shift;
514     grep $_->can('dsl_pull'), $self->part_export;
515 }
516
517 =item cust_svc [ PKGPART ] 
518
519 Returns a list of associated customer services (FS::cust_svc records).
520
521 If a PKGPART is specified, returns the customer services which are contained
522 within packages of that type (see L<FS::part_pkg>).  If PKGPARTis specified as
523 B<0>, returns unlinked customer services.
524
525 =cut
526
527 sub cust_svc {
528   my $self = shift;
529
530   my $hashref = { 'svcpart' => $self->svcpart };
531
532   my( $addl_from, $extra_sql ) = ( '', '' );
533   if ( @_ ) {
534     my $pkgpart = shift;
535     if ( $pkgpart =~ /^(\d+)$/ ) {
536       $addl_from = 'LEFT JOIN cust_pkg USING ( pkgnum )';
537       $extra_sql = "AND pkgpart = $1";
538     } elsif ( $pkgpart eq '0' ) {
539       $hashref->{'pkgnum'} = '';
540     }
541   }
542
543   qsearch({
544     'table'     => 'cust_svc',
545     'addl_from' => $addl_from,
546     'hashref'   => $hashref,
547     'extra_sql' => $extra_sql,
548   });
549 }
550
551 =item num_cust_svc [ PKGPART ] 
552
553 Returns the number of associated customer services (FS::cust_svc records).
554
555 If a PKGPART is specified, returns the number of customer services which are
556 contained within packages of that type (see L<FS::part_pkg>).  If PKGPART
557 is specified as B<0>, returns the number of unlinked customer services.
558
559 =cut
560
561 sub num_cust_svc {
562   my $self = shift;
563
564   return $self->{Hash}{num_cust_svc}
565     if !@_ && exists($self->{Hash}{num_cust_svc});
566
567   my @param = ( $self->svcpart );
568
569   my( $join, $and ) = ( '', '' );
570   if ( @_ ) {
571     my $pkgpart = shift;
572     if ( $pkgpart ) {
573       $join = 'LEFT JOIN cust_pkg USING ( pkgnum )';
574       $and = 'AND pkgpart = ?';
575       push @param, $pkgpart;
576     } elsif ( $pkgpart eq '0' ) {
577       $and = 'AND pkgnum IS NULL';
578     }
579   }
580
581   my $sth = dbh->prepare(
582     "SELECT COUNT(*) FROM cust_svc $join WHERE svcpart = ? $and"
583   ) or die dbh->errstr;
584   $sth->execute(@param)
585     or die $sth->errstr;
586   $sth->fetchrow_arrayref->[0];
587 }
588
589 =item num_cust_svc_cancelled
590
591 Returns the number of associated customer services that are
592 attached to cancelled packages.
593
594 =cut
595
596 sub num_cust_svc_cancelled {
597   my $self = shift;
598   my $sth = dbh->prepare(
599     "SELECT COUNT(*) FROM cust_svc
600      LEFT JOIN cust_pkg USING ( pkgnum )
601      WHERE svcpart = ?
602      AND cust_pkg.cancel IS NOT NULL"
603   ) or die dbh->errstr;
604   $sth->execute($self->svcpart)
605     or die $sth->errstr;
606   $sth->fetchrow_arrayref->[0];
607 }
608
609 =item svc_x
610
611 Returns a list of associated FS::svc_* records.
612
613 =cut
614
615 sub svc_x {
616   my $self = shift;
617   map { $_->svc_x } $self->cust_svc;
618 }
619
620 =item svc_locale LOCALE
621
622 Returns a customer-viewable service definition label in the chosen LOCALE.
623 If there is no entry for that locale or if LOCALE is empty, returns
624 part_svc.svc.
625
626 =cut
627
628 sub svc_locale {
629   my( $self, $locale ) = @_;
630   return $self->svc unless $locale;
631   my $part_svc_msgcat = qsearchs('part_svc_msgcat', {
632     svcpart => $self->svcpart,
633     locale  => $locale
634   }) or return $self->svc;
635   $part_svc_msgcat->svc;
636 }
637
638 =back
639
640 =head1 CLASS METHODS
641
642 =over 4
643
644 =cut
645
646 my $svc_defs;
647 my $svc_info;
648 sub _svc_defs {
649
650   return $svc_defs if $svc_defs; #cache
651
652   my $conf = new FS::Conf;
653
654   #false laziness w/part_pkg.pm::plan_info
655
656   my %info;
657   foreach my $INC ( @INC ) {
658     warn "globbing $INC/FS/svc_*.pm\n" if $DEBUG;
659     foreach my $file ( glob("$INC/FS/svc_*.pm") ) {
660
661       warn "attempting to load service table info from $file\n" if $DEBUG;
662       $file =~ /\/(\w+)\.pm$/ or do {
663         warn "unrecognized file in $INC/FS/: $file\n";
664         next;
665       };
666       my $mod = $1;
667
668       if ( $mod =~ /^svc_[A-Z]/ or $mod =~ /^(svc_acct_pop|svc_export_machine)$/ ) {
669         warn "skipping FS::$mod" if $DEBUG;
670         next;
671       }
672
673       eval "use FS::$mod;";
674       if ( $@ ) {
675         die "error using FS::$mod (skipping): $@\n" if $@;
676         next;
677       }
678       unless ( UNIVERSAL::can("FS::$mod", 'table_info') ) {
679         warn "FS::$mod has no table_info method; skipping";
680         next;
681       }
682
683       my $info = "FS::$mod"->table_info;
684       unless ( keys %$info ) {
685         warn "FS::$mod->table_info doesn't return info, skipping\n";
686         next;
687       }
688       warn "got info from FS::$mod: $info\n" if $DEBUG;
689       if ( exists($info->{'disabled'}) && $info->{'disabled'} ) {
690         warn "skipping disabled service FS::$mod" if $DEBUG;
691         next;
692       }
693       $info{$mod} = $info;
694     }
695   }
696
697   tie my %svc_defs, 'Tie::IxHash', 
698     map  { $_ => $info{$_}->{'fields'} }
699     sort { $info{$a}->{'display_weight'} <=> $info{$b}->{'display_weight'} }
700     keys %info,
701   ;
702
703   tie my %svc_info, 'Tie::IxHash',
704     map  { $_ => $info{$_} }
705     sort { $info{$a}->{'display_weight'} <=> $info{$b}->{'display_weight'} }
706     keys %info,
707   ;
708     
709   $svc_info = \%svc_info; #access via svc_table_info  
710   $svc_defs = \%svc_defs; #cache
711   
712 }
713
714 =item svc_tables
715
716 Returns a list of all svc_ tables.
717
718 =cut
719
720 sub svc_tables {
721   my $class = shift;
722   my $svc_defs = $class->_svc_defs;
723   grep { defined( dbdef->table($_) ) } keys %$svc_defs;
724 }
725
726 =item svc_table_fields TABLE
727
728 Given a table name, returns a hashref of field names.  The field names
729 returned are those with additional (service-definition related) information,
730 not necessarily all database fields of the table.  Pseudo-fields may also
731 be returned (i.e. svc_acct.usergroup).
732
733 Each value of the hashref is another hashref, which can have one or more of
734 the following keys:
735
736 =over 4
737
738 =item label - Description of the field
739
740 =item def_label - Optional description of the field in the context of service definitions
741
742 =item type - Currently "text", "select", "checkbox", "textarea", "disabled", 
743 some components specified by "select-.*.html", and a bunch more...
744
745 =item disable_default - This field should not allow a default value in service definitions
746
747 =item disable_fixed - This field should not allow a fixed value in service definitions
748
749 =item disable_inventory - This field should not allow inventory values in service definitions
750
751 =item select_list - If type is "text", this can be a listref of possible values.
752
753 =item select_table - An alternative to select_list, this defines a database table with the possible choices.
754
755 =item select_key - Used with select_table, this is the field name of keys
756
757 =item select_label - Used with select_table, this is the field name of labels
758
759 =item select_allow_empty - Used with select_table, adds an empty option
760
761 =item required - This field should always have a true value (do not use with type checkbox or disabled)
762
763 =back
764
765 =cut
766
767 #maybe this should move and be a class method in svc_Common.pm
768 sub svc_table_fields {
769   my($class, $table) = @_;
770   my $svc_defs = $class->_svc_defs;
771   my $def = $svc_defs->{$table};
772
773   foreach ( grep !ref($def->{$_}), keys %$def ) {
774
775     #normalize the shortcut in %info hash
776     $def->{$_} = { 'label' => $def->{$_} };
777
778     $def->{$_}{'type'} ||= 'text';
779
780   }
781
782   $def;
783 }
784
785 =item svc_table_info TABLE
786
787 Returns table_info for TABLE from cache, or empty
788 hashref if none is found.
789
790 Caution:  caches table_info for ALL services when run;
791 access a service's table_info directly unless you know
792 you're loading them all.
793
794 Caution:  does not standardize fields into hashrefs;
795 use L</svc_table_fields> to access fields.
796
797 =cut
798
799 sub svc_table_info {
800   my $class = shift;
801   my $table = shift;
802   $class->_svc_defs; #creates cache if needed
803   return $svc_info->{$table} || {};
804 }
805
806 =back
807
808 =head1 SUBROUTINES
809
810 =over 4
811
812 =item process
813
814 Job-queue processor for web interface adds/edits
815
816 =cut
817
818 use Storable qw(thaw);
819 use Data::Dumper;
820 use MIME::Base64;
821 sub process {
822   my $job = shift;
823
824   my $param = thaw(decode_base64(shift));
825   warn Dumper($param) if $DEBUG;
826
827   my $old = qsearchs('part_svc', { 'svcpart' => $param->{'svcpart'} }) 
828     if $param->{'svcpart'};
829
830   #unmunge cgp_accessmodes (falze laziness-ish w/edit/process/svc_acct.cgi)
831   $param->{'svc_acct__cgp_accessmodes'} ||=
832     join(' ', sort
833       grep { $_ !~ /^(flag|label)$/ }
834            map { /^svc_acct__cgp_accessmodes_([\w\/]+)$/ or die "no way"; $1; }
835                grep $param->{$_},
836                     grep /^svc_acct__cgp_accessmodes_([\w\/]+)$/,
837                          keys %$param
838         );
839   
840
841   my $new = new FS::part_svc ( {
842     map {
843       $_ => $param->{$_};
844   #  } qw(svcpart svc svcdb)
845     } ( fields('part_svc'),
846         map { my $svcdb = $_;
847               my @fields = fields($svcdb);
848               push @fields, 'usergroup' if $svcdb eq 'svc_acct'
849                                         or $svcdb eq 'svc_broadband'; #kludge
850
851               map {
852                     my $f = $svcdb.'__'.$_;
853                     my $flag = $param->{ $f.'_flag' } || ''; #silence warnings
854                     if ( $flag =~ /^[MAH]$/ ) {
855                       $param->{ $f } = delete( $param->{ $f.'_classnum' } );
856                     }
857                     if ( ( $flag =~ /^[MAHS]$/ or $_ eq 'usergroup' )
858                          and ref($param->{ $f }) ) {
859                       $param->{ $f } = join(',', @{ $param->{ $f } });
860                     }
861                     ( $f, $f.'_flag', $f.'_label', $f.'_required' );
862                   }
863                   @fields;
864
865             } FS::part_svc->svc_tables()
866       )
867   } );
868   
869   my %exportnums =
870     map { $_->exportnum => ( $param->{'exportnum'.$_->exportnum} || '') }
871         qsearch('part_export', {} );
872   foreach my $exportnum (%exportnums) {
873     my $role = $param->{'exportnum'.$exportnum.'_role'};
874     # role is undef if the export has no role selector
875     if ( $exportnums{$exportnum} && $role ) {
876       $exportnums{$exportnum} = $role;
877     }
878   }
879   my $error;
880   if ( $param->{'svcpart'} ) {
881     $error = $new->replace( $old,
882                             '1.3-COMPAT',    #totally bunk, as jeff noted
883                             [ 'usergroup' ],
884                             \%exportnums,
885                             $job
886                           );
887   } else {
888     $error = $new->insert( [ 'usergroup' ],
889                            \%exportnums,
890                            $job,
891                          );
892     $param->{'svcpart'} = $new->getfield('svcpart');
893   }
894
895   $error ||= $new->process_o2m(
896     'table'   => 'part_svc_msgcat',
897     'params'  => $param,
898     'fields'  => [ 'locale', 'svc' ],
899   );
900
901   die "$error\n" if $error;
902 }
903
904 =item process_bulk_cust_svc
905
906 Job-queue processor for web interface bulk customer service changes
907
908 =cut
909
910 use Storable qw(thaw);
911 use Data::Dumper;
912 use MIME::Base64;
913 sub process_bulk_cust_svc {
914   my $job = shift;
915
916   my $param = thaw(decode_base64(shift));
917   warn Dumper($param) if $DEBUG;
918
919   local($FS::svc_Common::noexport_hack) = 1
920     if $param->{'noexport'};
921
922   my $old_part_svc =
923     qsearchs('part_svc', { 'svcpart' => $param->{'old_svcpart'} } );
924
925   die "Must select a new service definition\n" unless $param->{'new_svcpart'};
926
927   #the rest should be abstracted out to to its own subroutine?
928
929   local $SIG{HUP} = 'IGNORE';
930   local $SIG{INT} = 'IGNORE';
931   local $SIG{QUIT} = 'IGNORE';
932   local $SIG{TERM} = 'IGNORE';
933   local $SIG{TSTP} = 'IGNORE';
934   local $SIG{PIPE} = 'IGNORE';
935
936   my $oldAutoCommit = $FS::UID::AutoCommit;
937   local $FS::UID::AutoCommit = 0;
938   my $dbh = dbh;
939
940   local( $FS::cust_svc::ignore_quantity ) = 1;
941
942   my $total = $old_part_svc->num_cust_svc( $param->{'pkgpart'} );
943
944   my $n = 0;
945   foreach my $old_cust_svc ( $old_part_svc->cust_svc( $param->{'pkgpart'} ) ) {
946
947     my $new_cust_svc = new FS::cust_svc { $old_cust_svc->hash };
948
949     $new_cust_svc->svcpart( $param->{'new_svcpart'} );
950     my $error = $new_cust_svc->replace($old_cust_svc);
951     if ( $error ) {
952       $dbh->rollback if $oldAutoCommit;
953       die "$error\n" if $error;
954     }
955
956     $error = $job->update_statustext( int( 100 * ++$n / $total ) );
957     if ( $error ) {
958       $dbh->rollback if $oldAutoCommit;
959       die $error if $error;
960     }
961
962   }
963
964   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
965
966   '';
967
968 }
969
970 sub _upgrade_data {  #class method
971   my ($class, %opts) = @_;
972
973   my @part_svc_column = qsearch('part_svc_column', { 'columnname' => 'usergroup' });
974   foreach my $col ( @part_svc_column ) {
975     next if $col->columnvalue =~ /^[\d,]+$/ || !$col->columnvalue;
976     my @groupnames = split(',',$col->columnvalue);
977     my @groupnums;
978     my $error = '';
979     foreach my $groupname ( @groupnames ) {
980         my $g = qsearchs('radius_group', { 'groupname' => $groupname } );
981         unless ( $g ) {
982             $g = new FS::radius_group {
983                             'groupname' => $groupname,
984                             'description' => $groupname,
985                             };
986             $error = $g->insert;
987             die "Error inserting new radius_group for service definition group \"$groupname\": $error"
988               if $error;
989         }
990         push @groupnums, $g->groupnum;
991     }
992     $col->columnvalue(join(',',@groupnums));
993     $error = $col->replace;
994     die $error if $error;
995   }
996
997   my @badlabels = qsearch({
998     'table' => 'part_svc_column',
999     'hashref' => {},
1000     'extra_sql' => 'WHERE columnlabel IN ('.
1001       "'Descriptive label for this particular device.',".
1002       "'IP address.  Leave blank for automatic assignment.',".
1003       "'Maximum upload speed for this service in Kbps.  0 denotes unlimited.',".
1004       "'Maximum download speed for this service in Kbps.  0 denotes unlimited.')"
1005   });
1006   foreach my $col ( @badlabels ) {
1007     $col->columnlabel('');
1008     my $error = $col->replace;
1009     die $error if $error;
1010   }
1011
1012 }
1013
1014 =head1 BUGS
1015
1016 Delete is unimplemented.
1017
1018 The list of svc_* tables is no longer hardcoded, but svc_acct_pop is skipped
1019 as a special case until it is renamed.
1020
1021 all_part_svc_column methods should be documented
1022
1023 =head1 SEE ALSO
1024
1025 L<FS::Record>, L<FS::part_svc_column>, L<FS::part_pkg>, L<FS::pkg_svc>,
1026 L<FS::cust_svc>, L<FS::svc_acct>, L<FS::svc_forward>, L<FS::svc_domain>,
1027 schema.html from the base documentation.
1028
1029 =cut
1030
1031 1;
1032