FS/FS/part_fee.pm

   1 package FS::part_fee;
   2
   3 use strict;
   4 use base qw( FS::o2m_Common FS::Record );
   5 use vars qw( $DEBUG );
   6 use FS::Record qw( qsearch qsearchs );
   7 use FS::pkg_class;
   8 use FS::part_pkg_taxproduct;
   9 use FS::agent;
  10 use FS::part_fee_usage;
  11
  12 $DEBUG = 0;
  13
  14 =head1 NAME
  15
  16 FS::part_fee - Object methods for part_fee records
  17
  18 =head1 SYNOPSIS
  19
  20   use FS::part_fee;
  21
  22   $record = new FS::part_fee \%hash;
  23   $record = new FS::part_fee { 'column' => 'value' };
  24
  25   $error = $record->insert;
  26
  27   $error = $new_record->replace($old_record);
  28
  29   $error = $record->delete;
  30
  31   $error = $record->check;
  32
  33 =head1 DESCRIPTION
  34
  35 An FS::part_fee object represents the definition of a fee
  36
  37 Fees are like packages, but instead of being ordered and then billed on a
  38 cycle, they are created by the operation of events and added to a single
  39 invoice.  The fee definition specifies the fee's description, how the amount
  40 is calculated (a flat fee or a percentage of the customer's balance), and
  41 how to classify the fee for tax and reporting purposes.
  42
  43 FS::part_fee inherits from FS::Record.  The following fields are currently
  44 supported:
  45
  46 =over 4
  47
  48 =item feepart - primary key
  49
  50 =item comment - a description of the fee for employee use, not shown on
  51 the invoice
  52
  53 =item disabled - 'Y' if the fee is disabled
  54
  55 =item classnum - the L<FS::pkg_class> that the fee belongs to, for reporting
  56
  57 =item taxable - 'Y' if this fee should be considered a taxable sale.
  58 Currently, taxable fees will be treated like they exist at the customer's
  59 default service location.
  60
  61 =item taxclass - the tax class the fee belongs to, as a string, for the
  62 internal tax system
  63
  64 =item taxproductnum - the tax product family the fee belongs to, for the
  65 external tax system in use, if any
  66
  67 =item pay_weight - Weight (relative to credit_weight and other package/fee
  68 definitions) that controls payment application to specific line items.
  69
  70 =item credit_weight - Weight that controls credit application to specific
  71 line items.
  72
  73 =item agentnum - the agent (L<FS::agent>) who uses this fee definition.
  74
  75 =item amount - the flat fee to charge, as a decimal amount
  76
  77 =item percent - the percentage of the base to charge (out of 100).  If both
  78 this and "amount" are specified, the fee will be the sum of the two.
  79
  80 =item basis - the method for calculating the base: currently one of "charged",
  81 "owed", or null.
  82
  83 =item minimum - the minimum fee that should be charged
  84
  85 =item maximum - the maximum fee that should be charged
  86
  87 =item limit_credit - 'Y' to set the maximum fee at the customer's credit
  88 balance, if any.
  89
  90 =item setuprecur - whether the fee should be classified as 'setup' or
  91 'recur', for reporting purposes.
  92
  93 =back
  94
  95 =head1 METHODS
  96
  97 =over 4
  98
  99 =item new HASHREF
 100
 101 Creates a new fee definition.  To add the record to the database, see
 102 L<"insert">.
 103
 104 =cut
 105
 106 sub table { 'part_fee'; }
 107
 108 =item insert
 109
 110 Adds this record to the database.  If there is an error, returns the error,
 111 otherwise returns false.
 112
 113 =item delete
 114
 115 Delete this record from the database.
 116
 117 =item replace OLD_RECORD
 118
 119 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 120 returns the error, otherwise returns false.
 121
 122 =item check
 123
 124 Checks all fields to make sure this is a valid example.  If there is
 125 an error, returns the error, otherwise returns false.  Called by the insert
 126 and replace methods.
 127
 128 =cut
 129
 130 sub check {
 131   my $self = shift;
 132
 133   $self->set('amount', 0) unless $self->amount;
 134   $self->set('percent', 0) unless $self->percent;
 135
 136   my $error =
 137     $self->ut_numbern('feepart')
 138     || $self->ut_textn('comment')
 139     || $self->ut_flag('disabled')
 140     || $self->ut_foreign_keyn('classnum', 'pkg_class', 'classnum')
 141     || $self->ut_flag('taxable')
 142     || $self->ut_textn('taxclass')
 143     || $self->ut_numbern('taxproductnum')
 144     || $self->ut_floatn('pay_weight')
 145     || $self->ut_floatn('credit_weight')
 146     || $self->ut_agentnum_acl('agentnum',
 147                               [ 'Edit global package definitions' ])
 148     || $self->ut_money('amount')
 149     || $self->ut_float('percent')
 150     || $self->ut_moneyn('minimum')
 151     || $self->ut_moneyn('maximum')
 152     || $self->ut_flag('limit_credit')
 153     || $self->ut_enum('basis', [ 'charged', 'owed', 'usage' ])
 154     || $self->ut_enum('setuprecur', [ 'setup', 'recur' ])
 155   ;
 156   return $error if $error;
 157
 158   if ( $self->get('limit_credit') ) {
 159     $self->set('maximum', '');
 160   }
 161
 162   if ( $self->get('basis') eq 'usage' ) {
 163     # to avoid confusion, don't also allow charging a percentage
 164     $self->set('percent', 0);
 165   }
 166
 167   $self->SUPER::check;
 168 }
 169
 170 =item explanation
 171
 172 Returns a string describing how this fee is calculated.
 173
 174 =cut
 175
 176 sub explanation {
 177   my $self = shift;
 178   # XXX customer currency
 179   my $money_char = FS::Conf->new->config('money_char') || '$';
 180   my $money = $money_char . '%.2f';
 181   my $percent = '%.1f%%';
 182   my $string = '';
 183   if ( $self->amount > 0 ) {
 184     $string = sprintf($money, $self->amount);
 185   }
 186   if ( $self->percent > 0 ) {
 187     if ( $string ) {
 188       $string .= " plus ";
 189     }
 190     $string .= sprintf($percent, $self->percent);
 191     $string .= ' of the ';
 192     if ( $self->basis eq 'charged' ) {
 193       $string .= 'invoice amount';
 194     } elsif ( $self->basis('owed') ) {
 195       $string .= 'unpaid invoice balance';
 196     }
 197   } elsif ( $self->basis eq 'usage' ) {
 198     if ( $string ) {
 199       $string .= " plus \n";
 200     }
 201     # append per-class descriptions
 202     $string .= join("\n", map { $_->explanation } $self->part_fee_usage);
 203   }
 204
 205   if ( $self->minimum or $self->maximum or $self->limit_credit ) {
 206     $string .= "\nbut";
 207     if ( $self->minimum ) {
 208       $string .= ' at least '.sprintf($money, $self->minimum);
 209     }
 210     if ( $self->maximum ) {
 211       $string .= ' and' if $self->minimum;
 212       $string .= ' at most '.sprintf($money, $self->maximum);
 213     }
 214     if ( $self->limit_credit ) {
 215       if ( $self->maximum ) {
 216         $string .= ", or the customer's credit balance, whichever is less.";
 217       } else {
 218         $string .= ' and' if $self->minimum;
 219         $string .= " not more than the customer's credit balance";
 220       }
 221     }
 222   }
 223   return $string;
 224 }
 225
 226 =item lineitem INVOICE
 227
 228 Given INVOICE (an L<FS::cust_bill>), returns an L<FS::cust_bill_pkg> object
 229 representing the invoice line item for the fee, with linked
 230 L<FS::cust_bill_pkg_fee> record(s) allocating the fee to the invoice or
 231 its line items, as appropriate.
 232
 233 If the fee is going to be charged on the upcoming invoice (credit card
 234 processing fees, postal invoice fees), INVOICE should be an uninserted
 235 L<FS::cust_bill> object where the 'cust_bill_pkg' property is an arrayref
 236 of the non-fee line items that will appear on the invoice.
 237
 238 =cut
 239
 240 sub lineitem {
 241   my $self = shift;
 242   my $cust_bill = shift;
 243   my $cust_main = $cust_bill->cust_main;
 244
 245   my $amount = 0 + $self->get('amount');
 246   my $total_base;  # sum of base line items
 247   my @items;       # base line items (cust_bill_pkg records)
 248   my @item_base;   # charged/owed of that item (sequential w/ @items)
 249   my @item_fee;    # fee amount of that item (sequential w/ @items)
 250   my @cust_bill_pkg_fee; # link record
 251
 252   warn "Calculating fee: ".$self->itemdesc." on ".
 253     ($cust_bill->invnum ? "invoice #".$cust_bill->invnum : "current invoice").
 254     "\n" if $DEBUG;
 255   my $basis = $self->basis;
 256
 257   # $total_base: the total charged/owed on the invoice
 258   # %item_base: billpkgnum => fraction of base amount
 259   if ( $cust_bill->invnum ) {
 260
 261     # calculate the fee on an already-inserted past invoice.  This may have
 262     # payments or credits, so if basis = owed, we need to consider those.
 263     @items = $cust_bill->cust_bill_pkg;
 264     if ( $basis ne 'usage' ) {
 265
 266       $total_base = $cust_bill->$basis; # "charged", "owed"
 267       my $basis_sql = $basis.'_sql';
 268       my $sql = 'SELECT ' . FS::cust_bill_pkg->$basis_sql .
 269                 ' FROM cust_bill_pkg WHERE billpkgnum = ?';
 270       @item_base = map { FS::Record->scalar_sql($sql, $_->billpkgnum) }
 271                     @items;
 272     }
 273   } else {
 274     # the fee applies to _this_ invoice.  It has no payments or credits, so
 275     # "charged" and "owed" basis are both just the invoice amount, and
 276     # the line item amounts (setup + recur)
 277     @items = @{ $cust_bill->get('cust_bill_pkg') };
 278     if ( $basis ne 'usage' ) {
 279       $total_base = $cust_bill->charged;
 280       @item_base = map { $_->setup + $_->recur }
 281                     @items;
 282     }
 283   }
 284
 285   if ( $basis eq 'usage' ) {
 286
 287     my %part_fee_usage = map { $_->classnum => $_ } $self->part_fee_usage;
 288
 289     foreach my $item (@items) { # cust_bill_pkg objects
 290       my $usage_fee = 0;
 291       $item->regularize_details;
 292       my $details;
 293       if ( $item->billpkgnum ) {
 294         $details = [
 295           qsearch('cust_bill_pkg_detail', { billpkgnum => $item->billpkgnum })
 296         ];
 297       } else {
 298         $details = $item->get('details') || [];
 299       }
 300       foreach my $d (@$details) {
 301         # if there's a usage fee defined for this class...
 302         next if $d->amount eq '' # not a real usage detail
 303              or $d->amount == 0  # zero charge, probably shouldn't charge fee
 304         ;
 305         my $p = $part_fee_usage{$d->classnum} or next;
 306         $usage_fee += ($d->amount * $p->percent / 100)
 307                     + $p->amount;
 308         # we'd create detail records here if we were doing that
 309       }
 310       # bypass @item_base entirely
 311       push @item_fee, $usage_fee;
 312       $amount += $usage_fee;
 313     }
 314
 315   } # if $basis eq 'usage'
 316
 317   if ( $self->minimum ne '' and $amount < $self->minimum ) {
 318     warn "Applying mininum fee\n" if $DEBUG;
 319     $amount = $self->minimum;
 320   }
 321
 322   my $maximum = $self->maximum;
 323   if ( $self->limit_credit ) {
 324     my $balance = $cust_bill->cust_main->balance;
 325     if ( $balance >= 0 ) {
 326       warn "Credit balance is zero, so fee is zero" if $DEBUG;
 327       return; # don't bother doing estimated tax, etc.
 328     } elsif ( -1 * $balance < $maximum ) {
 329       $maximum = -1 * $balance;
 330     }
 331   }
 332   if ( $maximum ne '' and $amount > $maximum ) {
 333     warn "Applying maximum fee\n" if $DEBUG;
 334     $amount = $maximum;
 335   }
 336
 337   # at this point, if the fee is zero, return nothing
 338   return if $amount < 0.005;
 339   $amount = sprintf('%.2f', $amount);
 340
 341   my $cust_bill_pkg = FS::cust_bill_pkg->new({
 342       feepart     => $self->feepart,
 343       pkgnum      => 0,
 344       # no sdate/edate, right?
 345       setup       => 0,
 346       recur       => 0,
 347   });
 348
 349   if ( $maximum and $self->taxable ) {
 350     warn "Estimating taxes on fee.\n" if $DEBUG;
 351     # then we need to estimate tax to respect the maximum
 352     # XXX currently doesn't work with external (tax_rate) taxes
 353     # or batch taxes, obviously
 354     my $taxlisthash = {};
 355     my $error = $cust_main->_handle_taxes(
 356       $taxlisthash,
 357       $cust_bill_pkg,
 358       location => $cust_main->ship_location
 359     );
 360     my $total_rate = 0;
 361     # $taxlisthash: tax identifier => [ cust_main_county, cust_bill_pkg... ]
 362     my @taxes = map { $_->[0] } values %$taxlisthash;
 363     foreach (@taxes) {
 364       $total_rate += $_->tax;
 365     }
 366     if ($total_rate > 0) {
 367       my $max_cents = $maximum * 100;
 368       my $charge_cents = sprintf('%0.f', $max_cents * 100/(100 + $total_rate));
 369       # the actual maximum that we can charge...
 370       $maximum = sprintf('%.2f', $charge_cents / 100.00);
 371       $amount = $maximum if $amount > $maximum;
 372     }
 373   } # if $maximum and $self->taxable
 374
 375   # set the amount that we'll charge
 376   $cust_bill_pkg->set( $self->setuprecur, $amount );
 377
 378   if ( $self->classnum ) {
 379     my $pkg_category = $self->pkg_class->pkg_category;
 380     $cust_bill_pkg->set('section' => $pkg_category->categoryname)
 381       if $pkg_category;
 382   }
 383
 384   # if this is a percentage fee and has line item fractions,
 385   # adjust them to be proportional and to add up correctly.
 386   if ( @item_base ) {
 387     my $cents = $amount * 100;
 388     # not necessarily the same as percent
 389     my $multiplier = $amount / $total_base;
 390     for (my $i = 0; $i < scalar(@items); $i++) {
 391       my $fee = sprintf('%.2f', $item_base[$i] * $multiplier);
 392       $item_fee[$i] = $fee;
 393       $cents -= $fee * 100;
 394     }
 395     # correct rounding error
 396     while ($cents >= 0.5 or $cents < -0.5) {
 397       foreach my $fee (@item_fee) {
 398         if ( $cents >= 0.5 ) {
 399           $fee += 0.01;
 400           $cents--;
 401         } elsif ( $cents < -0.5 ) {
 402           $fee -= 0.01;
 403           $cents++;
 404         }
 405       }
 406     }
 407   }
 408   if ( @item_fee ) {
 409     # add allocation records to the cust_bill_pkg
 410     for (my $i = 0; $i < scalar(@items); $i++) {
 411       if ( $item_fee[$i] > 0 ) {
 412         push @cust_bill_pkg_fee, FS::cust_bill_pkg_fee->new({
 413             cust_bill_pkg   => $cust_bill_pkg,
 414             base_invnum     => $cust_bill->invnum, # may be null
 415             amount          => $item_fee[$i],
 416             base_cust_bill_pkg => $items[$i], # late resolve
 417         });
 418       }
 419     }
 420   } else { # if !@item_fee
 421     # then this isn't a proportional fee, so it just applies to the
 422     # entire invoice.
 423     push @cust_bill_pkg_fee, FS::cust_bill_pkg_fee->new({
 424         cust_bill_pkg   => $cust_bill_pkg,
 425         base_invnum     => $cust_bill->invnum, # may be null
 426         amount          => $amount,
 427     });
 428   }
 429
 430   # cust_bill_pkg::insert will handle this
 431   $cust_bill_pkg->set('cust_bill_pkg_fee', \@cust_bill_pkg_fee);
 432   # avoid misbehavior by usage() and some other things
 433   $cust_bill_pkg->set('details', []);
 434
 435   return $cust_bill_pkg;
 436 }
 437
 438 =item itemdesc_locale LOCALE
 439
 440 Returns a customer-viewable description of this fee for the given locale,
 441 from the part_fee_msgcat table.  If the locale is empty or no localized fee
 442 description exists, returns part_fee.itemdesc.
 443
 444 =cut
 445
 446 sub itemdesc_locale {
 447   my ( $self, $locale ) = @_;
 448   return $self->itemdesc unless $locale;
 449   my $part_fee_msgcat = qsearchs('part_fee_msgcat', {
 450     feepart => $self->feepart,
 451     locale  => $locale,
 452   }) or return $self->itemdesc;
 453   $part_fee_msgcat->itemdesc;
 454 }
 455
 456 =item tax_rates DATA_PROVIDER, GEOCODE
 457
 458 Returns the external taxes (L<FS::tax_rate> objects) that apply to this
 459 fee, in the location specified by GEOCODE.
 460
 461 =cut
 462
 463 sub tax_rates {
 464   my $self = shift;
 465   my ($vendor, $geocode) = @_;
 466   return unless $self->taxproductnum;
 467   my $taxproduct = FS::part_pkg_taxproduct->by_key($self->taxproductnum);
 468   # cch stuff
 469   my @taxclassnums = map { $_->taxclassnum }
 470                      $taxproduct->part_pkg_taxrate($geocode);
 471   return unless @taxclassnums;
 472
 473   warn "Found taxclassnum values of ". join(',', @taxclassnums) ."\n"
 474   if $DEBUG;
 475   my $extra_sql = "AND taxclassnum IN (". join(',', @taxclassnums) . ")";
 476   my @taxes = qsearch({ 'table'     => 'tax_rate',
 477       'hashref'   => { 'geocode'     => $geocode,
 478         'data_vendor' => $vendor },
 479       'extra_sql' => $extra_sql,
 480     });
 481   warn "Found taxes ". join(',', map {$_->taxnum} @taxes) ."\n"
 482   if $DEBUG;
 483
 484   return @taxes;
 485 }
 486
 487 sub part_pkg_taxoverride {} # we don't do overrides here
 488
 489 sub has_taxproduct {
 490   my $self = shift;
 491   return ($self->taxproductnum ? 1 : 0);
 492 }
 493
 494 # stubs that will go away under 4.x
 495
 496 sub pkg_class {
 497   my $self = shift;
 498   $self->classnum
 499     ? FS::pkg_class->by_key($self->classnum)
 500     : undef;
 501 }
 502
 503 sub part_pkg_taxproduct {
 504   my $self = shift;
 505   $self->taxproductnum
 506     ? FS::part_pkg_taxproduct->by_key($self->taxproductnum)
 507     : undef;
 508 }
 509
 510 sub agent {
 511   my $self = shift;
 512   $self->agentnum
 513     ? FS::agent->by_key($self->agentnum)
 514     : undef;
 515 }
 516
 517 sub part_fee_msgcat {
 518   my $self = shift;
 519   qsearch( 'part_fee_msgcat', { feepart => $self->feepart } );
 520 }
 521
 522 sub part_fee_usage {
 523   my $self = shift;
 524   qsearch( 'part_fee_usage', { feepart => $self->feepart } );
 525 }
 526
 527 =back
 528
 529 =head1 BUGS
 530
 531 =head1 SEE ALSO
 532
 533 L<FS::Record>
 534
 535 =cut
 536
 537 1;
 538