FS/FS/msg_template.pm

   1 package FS::msg_template;
   2
   3 use strict;
   4 use base qw( FS::Record );
   5 use Text::Template;
   6 use FS::Misc qw( generate_email send_email do_print );
   7 use FS::Conf;
   8 use FS::Record qw( qsearch qsearchs );
   9 use FS::UID qw( dbh );
  10
  11 use FS::cust_main;
  12 use FS::cust_msg;
  13 use FS::template_content;
  14
  15 use Date::Format qw( time2str );
  16 use HTML::Entities qw( decode_entities encode_entities ) ;
  17 use HTML::FormatText;
  18 use HTML::TreeBuilder;
  19 use Encode;
  20
  21 use File::Temp;
  22 use IPC::Run qw(run);
  23 use vars qw( $DEBUG $conf );
  24
  25 FS::UID->install_callback( sub { $conf = new FS::Conf; } );
  26
  27 $DEBUG=0;
  28
  29 =head1 NAME
  30
  31 FS::msg_template - Object methods for msg_template records
  32
  33 =head1 SYNOPSIS
  34
  35   use FS::msg_template;
  36
  37   $record = new FS::msg_template \%hash;
  38   $record = new FS::msg_template { 'column' => 'value' };
  39
  40   $error = $record->insert;
  41
  42   $error = $new_record->replace($old_record);
  43
  44   $error = $record->delete;
  45
  46   $error = $record->check;
  47
  48 =head1 DESCRIPTION
  49
  50 An FS::msg_template object represents a customer message template.
  51 FS::msg_template inherits from FS::Record.  The following fields are currently
  52 supported:
  53
  54 =over 4
  55
  56 =item msgnum - primary key
  57
  58 =item msgname - Name of the template.  This will appear in the user interface;
  59 if it needs to be localized for some users, add it to the message catalog.
  60
  61 =item agentnum - Agent associated with this template.  Can be NULL for a
  62 global template.
  63
  64 =item mime_type - MIME type.  Defaults to text/html.
  65
  66 =item from_addr - Source email address.
  67
  68 =item disabled - disabled ('Y' or NULL).
  69
  70 =back
  71
  72 =head1 METHODS
  73
  74 =over 4
  75
  76 =item new HASHREF
  77
  78 Creates a new template.  To add the template to the database, see L<"insert">.
  79
  80 Note that this stores the hash reference, not a distinct copy of the hash it
  81 points to.  You can ask the object for a copy with the I<hash> method.
  82
  83 =cut
  84
  85 # the new method can be inherited from FS::Record, if a table method is defined
  86
  87 sub table { 'msg_template'; }
  88
  89 =item insert [ CONTENT ]
  90
  91 Adds this record to the database.  If there is an error, returns the error,
  92 otherwise returns false.
  93
  94 A default (no locale) L<FS::template_content> object will be created.  CONTENT
  95 is an optional hash containing 'subject' and 'body' for this object.
  96
  97 =cut
  98
  99 sub insert {
 100   my $self = shift;
 101   my %content = @_;
 102
 103   my $oldAutoCommit = $FS::UID::AutoCommit;
 104   local $FS::UID::AutoCommit = 0;
 105   my $dbh = dbh;
 106
 107   my $error = $self->SUPER::insert;
 108   if ( !$error ) {
 109     $content{'msgnum'} = $self->msgnum;
 110     $content{'subject'} ||= '';
 111     $content{'body'} ||= '';
 112     my $template_content = new FS::template_content (\%content);
 113     $error = $template_content->insert;
 114   }
 115
 116   if ( $error ) {
 117     $dbh->rollback if $oldAutoCommit;
 118     return $error;
 119   }
 120
 121   $dbh->commit if $oldAutoCommit;
 122   return;
 123 }
 124
 125 =item delete
 126
 127 Delete this record from the database.
 128
 129 =cut
 130
 131 # the delete method can be inherited from FS::Record
 132
 133 =item replace [ OLD_RECORD ] [ CONTENT ]
 134
 135 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 136 returns the error, otherwise returns false.
 137
 138 CONTENT is an optional hash containing 'subject', 'body', and 'locale'.  If
 139 supplied, an L<FS::template_content> object will be created (or modified, if
 140 one already exists for this locale).
 141
 142 =cut
 143
 144 sub replace {
 145   my $self = shift;
 146   my $old = ( ref($_[0]) and $_[0]->isa('FS::Record') )
 147               ? shift
 148               : $self->replace_old;
 149   my %content = @_;
 150
 151   my $oldAutoCommit = $FS::UID::AutoCommit;
 152   local $FS::UID::AutoCommit = 0;
 153   my $dbh = dbh;
 154
 155   my $error = $self->SUPER::replace($old);
 156
 157   if ( !$error and %content ) {
 158     $content{'locale'} ||= '';
 159     my $new_content = qsearchs('template_content', {
 160                         'msgnum' => $self->msgnum,
 161                         'locale' => $content{'locale'},
 162                       } );
 163     if ( $new_content ) {
 164       $new_content->subject($content{'subject'});
 165       $new_content->body($content{'body'});
 166       $error = $new_content->replace;
 167     }
 168     else {
 169       $content{'msgnum'} = $self->msgnum;
 170       $new_content = new FS::template_content \%content;
 171       $error = $new_content->insert;
 172     }
 173   }
 174
 175   if ( $error ) {
 176     $dbh->rollback if $oldAutoCommit;
 177     return $error;
 178   }
 179
 180   warn "committing FS::msg_template->replace\n" if $DEBUG and $oldAutoCommit;
 181   $dbh->commit if $oldAutoCommit;
 182   return;
 183 }
 184
 185
 186
 187 =item check
 188
 189 Checks all fields to make sure this is a valid template.  If there is
 190 an error, returns the error, otherwise returns false.  Called by the insert
 191 and replace methods.
 192
 193 =cut
 194
 195 # the check method should currently be supplied - FS::Record contains some
 196 # data checking routines
 197
 198 sub check {
 199   my $self = shift;
 200
 201   my $error =
 202     $self->ut_numbern('msgnum')
 203     || $self->ut_text('msgname')
 204     || $self->ut_foreign_keyn('agentnum', 'agent', 'agentnum')
 205     || $self->ut_textn('mime_type')
 206     || $self->ut_enum('disabled', [ '', 'Y' ] )
 207     || $self->ut_textn('from_addr')
 208   ;
 209   return $error if $error;
 210
 211   $self->mime_type('text/html') unless $self->mime_type;
 212
 213   $self->SUPER::check;
 214 }
 215
 216 =item content_locales
 217
 218 Returns a hashref of the L<FS::template_content> objects attached to
 219 this template, with the locale as key.
 220
 221 =cut
 222
 223 sub content_locales {
 224   my $self = shift;
 225   return $self->{'_content_locales'} ||= +{
 226     map { $_->locale , $_ }
 227     qsearch('template_content', { 'msgnum' => $self->msgnum })
 228   };
 229 }
 230
 231 =item prepare OPTION => VALUE
 232
 233 Fills in the template and returns a hash of the 'from' address, 'to'
 234 addresses, subject line, and body.
 235
 236 Options are passed as a list of name/value pairs:
 237
 238 =over 4
 239
 240 =item cust_main
 241
 242 Customer object (required).
 243
 244 =item object
 245
 246 Additional context object (currently, can be a cust_main, cust_pkg,
 247 cust_bill, cust_pay, cust_pay_pending, or svc_(acct, phone, broadband,
 248 domain) ).  If the object is a svc_*, its cust_pkg will be fetched and
 249 used for substitution.
 250
 251 As a special case, this may be an arrayref of two objects.  Both
 252 objects will be available for substitution, with their field names
 253 prefixed with 'new_' and 'old_' respectively.  This is used in the
 254 rt_ticket export when exporting "replace" events.
 255
 256 =item from_config
 257
 258 Configuration option to use as the source address, based on the customer's
 259 agentnum.  If unspecified (or the named option is empty), 'invoice_from'
 260 will be used.
 261
 262 The I<from_addr> field in the template takes precedence over this.
 263
 264 =item to
 265
 266 Destination address.  The default is to use the customer's
 267 invoicing_list addresses.  Multiple addresses may be comma-separated.
 268
 269 =item substitutions
 270
 271 A hash reference of additional substitutions
 272
 273 =back
 274
 275 =cut
 276
 277 sub prepare {
 278   my( $self, %opt ) = @_;
 279
 280   my $cust_main = $opt{'cust_main'} or die 'cust_main required';
 281   my $object = $opt{'object'} or die 'object required';
 282
 283   # localization
 284   my $locale = $cust_main->locale || '';
 285   warn "no locale for cust#".$cust_main->custnum."; using default content\n"
 286     if $DEBUG and !$locale;
 287   my $content = $self->content($cust_main->locale);
 288   warn "preparing template '".$self->msgname."' to cust#".$cust_main->custnum."\n"
 289     if($DEBUG);
 290
 291   my $subs = $self->substitutions;
 292
 293   ###
 294   # create substitution table
 295   ###
 296   my %hash;
 297   my @objects = ($cust_main);
 298   my @prefixes = ('');
 299   my $svc;
 300   if( ref $object ) {
 301     if( ref($object) eq 'ARRAY' ) {
 302       # [new, old], for provisioning tickets
 303       push @objects, $object->[0], $object->[1];
 304       push @prefixes, 'new_', 'old_';
 305       $svc = $object->[0] if $object->[0]->isa('FS::svc_Common');
 306     }
 307     else {
 308       push @objects, $object;
 309       push @prefixes, '';
 310       $svc = $object if $object->isa('FS::svc_Common');
 311     }
 312   }
 313   if( $svc ) {
 314     push @objects, $svc->cust_svc->cust_pkg;
 315     push @prefixes, '';
 316   }
 317
 318   foreach my $obj (@objects) {
 319     my $prefix = shift @prefixes;
 320     foreach my $name (@{ $subs->{$obj->table} }) {
 321       if(!ref($name)) {
 322         # simple case
 323         $hash{$prefix.$name} = $obj->$name();
 324       }
 325       elsif( ref($name) eq 'ARRAY' ) {
 326         # [ foo => sub { ... } ]
 327         $hash{$prefix.($name->[0])} = $name->[1]->($obj);
 328       }
 329       else {
 330         warn "bad msg_template substitution: '$name'\n";
 331         #skip it?
 332       }
 333     }
 334   }
 335
 336   if ( $opt{substitutions} ) {
 337     $hash{$_} = $opt{substitutions}->{$_} foreach keys %{$opt{substitutions}};
 338   }
 339
 340   $_ = encode_entities($_ || '') foreach values(%hash);
 341
 342   ###
 343   # clean up template
 344   ###
 345   my $subject_tmpl = new Text::Template (
 346     TYPE   => 'STRING',
 347     SOURCE => $content->subject,
 348   );
 349   my $subject = $subject_tmpl->fill_in( HASH => \%hash );
 350
 351   my $body = $content->body;
 352   my ($skin, $guts) = eviscerate($body);
 353   @$guts = map {
 354     $_ = decode_entities($_); # turn all punctuation back into itself
 355     s/\r//gs;           # remove \r's
 356     s/<br[^>]*>/\n/gsi; # and <br /> tags
 357     s/<p>/\n/gsi;       # and <p>
 358     s/<\/p>//gsi;       # and </p>
 359     s/\240/ /gs;        # and &nbsp;
 360     $_
 361   } @$guts;
 362
 363   $body = '{ use Date::Format qw(time2str); "" }';
 364   while(@$skin || @$guts) {
 365     $body .= shift(@$skin) || '';
 366     $body .= shift(@$guts) || '';
 367   }
 368
 369   ###
 370   # fill-in
 371   ###
 372
 373   my $body_tmpl = new Text::Template (
 374     TYPE          => 'STRING',
 375     SOURCE        => $body,
 376   );
 377
 378   $body = $body_tmpl->fill_in( HASH => \%hash );
 379
 380   ###
 381   # and email
 382   ###
 383
 384   my @to;
 385   if ( exists($opt{'to'}) ) {
 386     @to = split(/\s*,\s*/, $opt{'to'});
 387   }
 388   else {
 389     @to = $cust_main->invoicing_list_emailonly;
 390   }
 391   # no warning when preparing with no destination
 392
 393   my $from_addr = $self->from_addr;
 394
 395   if ( !$from_addr ) {
 396     if ( $opt{'from_config'} ) {
 397       $from_addr = scalar( $conf->config($opt{'from_config'},
 398                                          $cust_main->agentnum) );
 399     }
 400     $from_addr ||= $conf->invoice_from_full($cust_main->agentnum);
 401   }
 402 #  my @cust_msg = ();
 403 #  if ( $conf->exists('log_sent_mail') and !$opt{'preview'} ) {
 404 #    my $cust_msg = FS::cust_msg->new({
 405 #        'custnum' => $cust_main->custnum,
 406 #        'msgnum'  => $self->msgnum,
 407 #        'status'  => 'prepared',
 408 #      });
 409 #    $cust_msg->insert;
 410 #    @cust_msg = ('cust_msg' => $cust_msg);
 411 #  }
 412
 413   my $text_body = encode('UTF-8',
 414                   HTML::FormatText->new(leftmargin => 0, rightmargin => 70)
 415                       ->format( HTML::TreeBuilder->new_from_content($body) )
 416                   );
 417   (
 418     'custnum' => $cust_main->custnum,
 419     'msgnum'  => $self->msgnum,
 420     'from' => $from_addr,
 421     'to'   => \@to,
 422     'bcc'  => $self->bcc_addr || undef,
 423     'subject'   => $subject,
 424     'html_body' => $body,
 425     'text_body' => $text_body
 426   );
 427
 428 }
 429
 430 =item send OPTION => VALUE
 431
 432 Fills in the template and sends it to the customer.  Options are as for
 433 'prepare'.
 434
 435 =cut
 436
 437 # broken out from prepare() in case we want to queue the sending,
 438 # preview it, etc.
 439 sub send {
 440   my $self = shift;
 441   send_email(generate_email($self->prepare(@_)));
 442 }
 443
 444 =item render OPTION => VALUE ...
 445
 446 Fills in the template and renders it to a PDF document.  Returns the
 447 name of the PDF file.
 448
 449 Options are as for 'prepare', but 'from' and 'to' are meaningless.
 450
 451 =cut
 452
 453 # will also have options to set paper size, margins, etc.
 454
 455 sub render {
 456   my $self = shift;
 457   eval "use PDF::WebKit";
 458   die $@ if $@;
 459   my %opt = @_;
 460   my %hash = $self->prepare(%opt);
 461   my $html = $hash{'html_body'};
 462
 463   # Graphics/stylesheets should probably go in /var/www on the Freeside
 464   # machine.
 465   my $script_path = `/usr/bin/which freeside-wkhtmltopdf`;
 466   chomp $script_path;
 467   my $kit = PDF::WebKit->new(\$html); #%options
 468   # hack to use our wrapper script
 469   $kit->configure(sub { shift->wkhtmltopdf($script_path) });
 470
 471   $kit->to_pdf;
 472 }
 473
 474 =item print OPTIONS
 475
 476 Render a PDF and send it to the printer.  OPTIONS are as for 'render'.
 477
 478 =cut
 479
 480 sub print {
 481   my( $self, %opt ) = @_;
 482   do_print( [ $self->render(%opt) ], agentnum=>$opt{cust_main}->agentnum );
 483 }
 484
 485 # helper sub for package dates
 486 my $ymd = sub { $_[0] ? time2str('%Y-%m-%d', $_[0]) : '' };
 487
 488 # helper sub for money amounts
 489 my $money = sub { ($conf->money_char || '$') . sprintf('%.2f', $_[0] || 0) };
 490
 491 # helper sub for usage-related messages
 492 my $usage_warning = sub {
 493   my $svc = shift;
 494   foreach my $col (qw(seconds upbytes downbytes totalbytes)) {
 495     my $amount = $svc->$col; next if $amount eq '';
 496     my $method = $col.'_threshold';
 497     my $threshold = $svc->$method; next if $threshold eq '';
 498     return [$col, $amount, $threshold] if $amount <= $threshold;
 499     # this only returns the first one that's below threshold, if there are
 500     # several.
 501   }
 502   return ['', '', ''];
 503 };
 504
 505 #my $conf = new FS::Conf;
 506
 507 #return contexts and fill-in values
 508 # If you add anything, be sure to add a description in
 509 # httemplate/edit/msg_template.html.
 510 sub substitutions {
 511   { 'cust_main' => [qw(
 512       display_custnum agentnum agent_name
 513
 514       last first company
 515       name name_short contact contact_firstlast
 516       address1 address2 city county state zip
 517       country
 518       daytime night mobile fax
 519
 520       has_ship_address
 521       ship_name ship_name_short ship_contact ship_contact_firstlast
 522       ship_address1 ship_address2 ship_city ship_county ship_state ship_zip
 523       ship_country
 524
 525       paymask payname paytype payip
 526       num_cancelled_pkgs num_ncancelled_pkgs num_pkgs
 527       classname categoryname
 528       balance
 529       credit_limit
 530       invoicing_list_emailonly
 531       cust_status ucfirst_cust_status cust_statuscolor
 532
 533       signupdate dundate
 534       packages recurdates
 535       ),
 536       [ invoicing_email => sub { shift->invoicing_list_emailonly_scalar } ],
 537       #compatibility: obsolete ship_ fields - use the non-ship versions
 538       map (
 539         { my $field = $_;
 540           [ "ship_$field"   => sub { shift->$field } ]
 541         }
 542         qw( last first company daytime night fax )
 543       ),
 544       # ship_name, ship_name_short, ship_contact, ship_contact_firstlast
 545       # still work, though
 546       [ expdate           => sub { shift->paydate_epoch } ], #compatibility
 547       [ signupdate_ymd    => sub { $ymd->(shift->signupdate) } ],
 548       [ dundate_ymd       => sub { $ymd->(shift->dundate) } ],
 549       [ paydate_my        => sub { sprintf('%02d/%04d', shift->paydate_monthyear) } ],
 550       [ otaker_first      => sub { shift->access_user->first } ],
 551       [ otaker_last       => sub { shift->access_user->last } ],
 552       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 553       [ company_name      => sub {
 554           $conf->config('company_name', shift->agentnum)
 555         } ],
 556       [ company_address   => sub {
 557           $conf->config('company_address', shift->agentnum)
 558         } ],
 559       [ company_phonenum  => sub {
 560           $conf->config('company_phonenum', shift->agentnum)
 561         } ],
 562       [ selfservice_server_base_url => sub {
 563           $conf->config('selfservice_server-base_url') #, shift->agentnum)
 564         } ],
 565     ],
 566     # next_bill_date
 567     'cust_pkg'  => [qw(
 568       pkgnum pkg_label pkg_label_long
 569       location_label
 570       status statuscolor
 571
 572       start_date setup bill last_bill
 573       adjourn susp expire
 574       labels_short
 575       ),
 576       [ pkg               => sub { shift->part_pkg->pkg } ],
 577       [ pkg_category      => sub { shift->part_pkg->categoryname } ],
 578       [ pkg_class         => sub { shift->part_pkg->classname } ],
 579       [ cancel            => sub { shift->getfield('cancel') } ], # grrr...
 580       [ start_ymd         => sub { $ymd->(shift->getfield('start_date')) } ],
 581       [ setup_ymd         => sub { $ymd->(shift->getfield('setup')) } ],
 582       [ next_bill_ymd     => sub { $ymd->(shift->getfield('bill')) } ],
 583       [ last_bill_ymd     => sub { $ymd->(shift->getfield('last_bill')) } ],
 584       [ adjourn_ymd       => sub { $ymd->(shift->getfield('adjourn')) } ],
 585       [ susp_ymd          => sub { $ymd->(shift->getfield('susp')) } ],
 586       [ expire_ymd        => sub { $ymd->(shift->getfield('expire')) } ],
 587       [ cancel_ymd        => sub { $ymd->(shift->getfield('cancel')) } ],
 588
 589       # not necessarily correct for non-flat packages
 590       [ setup_fee         => sub { shift->part_pkg->option('setup_fee') } ],
 591       [ recur_fee         => sub { shift->part_pkg->option('recur_fee') } ],
 592
 593       [ freq_pretty       => sub { shift->part_pkg->freq_pretty } ],
 594
 595     ],
 596     'cust_bill' => [qw(
 597       invnum
 598       _date
 599       _date_pretty
 600       due_date
 601     ),
 602       [ due_date2str      => sub { shift->due_date2str('short') } ],
 603     ],
 604     #XXX not really thinking about cust_bill substitutions quite yet
 605
 606     # for welcome and limit warning messages
 607     'svc_acct' => [qw(
 608       svcnum
 609       username
 610       domain
 611       ),
 612       [ password          => sub { shift->getfield('_password') } ],
 613       [ column            => sub { &$usage_warning(shift)->[0] } ],
 614       [ amount            => sub { &$usage_warning(shift)->[1] } ],
 615       [ threshold         => sub { &$usage_warning(shift)->[2] } ],
 616     ],
 617     'svc_domain' => [qw(
 618       svcnum
 619       domain
 620       ),
 621       [ registrar         => sub {
 622           my $registrar = qsearchs('registrar',
 623             { registrarnum => shift->registrarnum} );
 624           $registrar ? $registrar->registrarname : ''
 625         }
 626       ],
 627       [ catchall          => sub {
 628           my $svc_acct = qsearchs('svc_acct', { svcnum => shift->catchall });
 629           $svc_acct ? $svc_acct->email : ''
 630         }
 631       ],
 632     ],
 633     'svc_phone' => [qw(
 634       svcnum
 635       phonenum
 636       countrycode
 637       domain
 638       )
 639     ],
 640     'svc_broadband' => [qw(
 641       svcnum
 642       speed_up
 643       speed_down
 644       ip_addr
 645       mac_addr
 646       )
 647     ],
 648     # for payment receipts
 649     'cust_pay' => [qw(
 650       paynum
 651       _date
 652       ),
 653       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 654       # overrides the one in cust_main in cases where a cust_pay is passed
 655       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 656       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 657       [ payinfo           => sub {
 658           my $cust_pay = shift;
 659           ($cust_pay->payby eq 'CARD' || $cust_pay->payby eq 'CHEK') ?
 660             $cust_pay->paymask : $cust_pay->decrypt($cust_pay->payinfo)
 661         } ],
 662     ],
 663     # for payment decline messages
 664     # try to support all cust_pay fields
 665     # 'error' is a special case, it contains the raw error from the gateway
 666     'cust_pay_pending' => [qw(
 667       _date
 668       error
 669       ),
 670       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 671       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 672       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 673       [ payinfo           => sub {
 674           my $pending = shift;
 675           ($pending->payby eq 'CARD' || $pending->payby eq 'CHEK') ?
 676             $pending->paymask : $pending->decrypt($pending->payinfo)
 677         } ],
 678     ],
 679   };
 680 }
 681
 682 =item content LOCALE
 683
 684 Returns the L<FS::template_content> object appropriate to LOCALE, if there
 685 is one.  If not, returns the one with a NULL locale.
 686
 687 =cut
 688
 689 sub content {
 690   my $self = shift;
 691   my $locale = shift;
 692   qsearchs('template_content',
 693             { 'msgnum' => $self->msgnum, 'locale' => $locale }) ||
 694   qsearchs('template_content',
 695             { 'msgnum' => $self->msgnum, 'locale' => '' });
 696 }
 697
 698 =item agent
 699
 700 Returns the L<FS::agent> object for this template.
 701
 702 =cut
 703
 704 sub agent {
 705   qsearchs('agent', { 'agentnum' => $_[0]->agentnum });
 706 }
 707
 708 sub _upgrade_data {
 709   my ($self, %opts) = @_;
 710
 711   ###
 712   # First move any historical templates in config to real message templates
 713   ###
 714
 715   my @fixes = (
 716     [ 'alerter_msgnum',  'alerter_template',   '',               '', '' ],
 717     [ 'cancel_msgnum',   'cancelmessage',      'cancelsubject',  '', '' ],
 718     [ 'decline_msgnum',  'declinetemplate',    '',               '', '' ],
 719     [ 'impending_recur_msgnum', 'impending_recur_template', '',  '', 'impending_recur_bcc' ],
 720     [ 'payment_receipt_msgnum', 'payment_receipt_email', '',     '', '' ],
 721     [ 'welcome_msgnum',  'welcome_email',      'welcome_email-subject', 'welcome_email-from', '' ],
 722     [ 'warning_msgnum',  'warning_email',      'warning_email-subject', 'warning_email-from', '' ],
 723   );
 724
 725   my @agentnums = ('', map {$_->agentnum} qsearch('agent', {}));
 726   foreach my $agentnum (@agentnums) {
 727     foreach (@fixes) {
 728       my ($newname, $oldname, $subject, $from, $bcc) = @$_;
 729       if ($conf->exists($oldname, $agentnum)) {
 730         my $new = new FS::msg_template({
 731           'msgname'   => $oldname,
 732           'agentnum'  => $agentnum,
 733           'from_addr' => ($from && $conf->config($from, $agentnum)) || '',
 734           'bcc_addr'  => ($bcc && $conf->config($from, $agentnum)) || '',
 735           'subject'   => ($subject && $conf->config($subject, $agentnum)) || '',
 736           'mime_type' => 'text/html',
 737           'body'      => join('<BR>',$conf->config($oldname, $agentnum)),
 738         });
 739         my $error = $new->insert;
 740         die $error if $error;
 741         $conf->set($newname, $new->msgnum, $agentnum);
 742         $conf->delete($oldname, $agentnum);
 743         $conf->delete($from, $agentnum) if $from;
 744         $conf->delete($subject, $agentnum) if $subject;
 745       }
 746     }
 747
 748     if ( $conf->exists('alert_expiration', $agentnum) ) {
 749       my $msgnum = $conf->exists('alerter_msgnum', $agentnum);
 750       my $template = FS::msg_template->by_key($msgnum) if $msgnum;
 751       if (!$template) {
 752         warn "template for alerter_msgnum $msgnum not found\n";
 753         next;
 754       }
 755       # this is now a set of billing events
 756       foreach my $days (30, 15, 5) {
 757         my $event = FS::part_event->new({
 758             'agentnum'    => $agentnum,
 759             'event'       => "Card expiration warning - $days days",
 760             'eventtable'  => 'cust_main',
 761             'check_freq'  => '1d',
 762             'action'      => 'notice',
 763             'disabled'    => 'Y', #initialize first
 764         });
 765         my $error = $event->insert( 'msgnum' => $msgnum );
 766         if ($error) {
 767           warn "error creating expiration alert event:\n$error\n\n";
 768           next;
 769         }
 770         # make it work like before:
 771         # only send each warning once before the card expires,
 772         # only warn active customers,
 773         # only warn customers with CARD/DCRD,
 774         # only warn customers who get email invoices
 775         my %conds = (
 776           'once_every'          => { 'run_delay' => '30d' },
 777           'cust_paydate_within' => { 'within' => $days.'d' },
 778           'cust_status'         => { 'status' => { 'active' => 1 } },
 779           'payby'               => { 'payby'  => { 'CARD' => 1,
 780                                                    'DCRD' => 1, }
 781                                    },
 782           'message_email'       => {},
 783         );
 784         foreach (keys %conds) {
 785           my $condition = FS::part_event_condition->new({
 786               'conditionname' => $_,
 787               'eventpart'     => $event->eventpart,
 788           });
 789           $error = $condition->insert( %{ $conds{$_} });
 790           if ( $error ) {
 791             warn "error creating expiration alert event:\n$error\n\n";
 792             next;
 793           }
 794         }
 795         $error = $event->initialize;
 796         if ( $error ) {
 797           warn "expiration alert event was created, but not initialized:\n$error\n\n";
 798         }
 799       } # foreach $days
 800       $conf->delete('alerter_msgnum', $agentnum);
 801       $conf->delete('alert_expiration', $agentnum);
 802
 803     } # if alerter_msgnum
 804
 805   }
 806
 807   ###
 808   # Move subject and body from msg_template to template_content
 809   ###
 810
 811   foreach my $msg_template ( qsearch('msg_template', {}) ) {
 812     if ( $msg_template->subject || $msg_template->body ) {
 813       # create new default content
 814       my %content;
 815       $content{subject} = $msg_template->subject;
 816       $msg_template->set('subject', '');
 817
 818       # work around obscure Pg/DBD bug
 819       # https://rt.cpan.org/Public/Bug/Display.html?id=60200
 820       # (though the right fix is to upgrade DBD)
 821       my $body = $msg_template->body;
 822       if ( $body =~ /^x([0-9a-f]+)$/ ) {
 823         # there should be no real message templates that look like that
 824         warn "converting template body to TEXT\n";
 825         $body = pack('H*', $1);
 826       }
 827       $content{body} = $body;
 828       $msg_template->set('body', '');
 829
 830       my $error = $msg_template->replace(%content);
 831       die $error if $error;
 832     }
 833   }
 834
 835   ###
 836   # Add new-style default templates if missing
 837   ###
 838   $self->_populate_initial_data;
 839
 840 }
 841
 842 sub _populate_initial_data { #class method
 843   #my($class, %opts) = @_;
 844   #my $class = shift;
 845
 846   eval "use FS::msg_template::InitialData;";
 847   die $@ if $@;
 848
 849   my $initial_data = FS::msg_template::InitialData->_initial_data;
 850
 851   foreach my $hash ( @$initial_data ) {
 852
 853     next if $hash->{_conf} && $conf->config( $hash->{_conf} );
 854
 855     my $msg_template = new FS::msg_template($hash);
 856     my $error = $msg_template->insert( @{ $hash->{_insert_args} || [] } );
 857     die $error if $error;
 858
 859     $conf->set( $hash->{_conf}, $msg_template->msgnum ) if $hash->{_conf};
 860
 861   }
 862
 863 }
 864
 865 sub eviscerate {
 866   # Every bit as pleasant as it sounds.
 867   #
 868   # We do this because Text::Template::Preprocess doesn't
 869   # actually work.  It runs the entire template through
 870   # the preprocessor, instead of the code segments.  Which
 871   # is a shame, because Text::Template already contains
 872   # the code to do this operation.
 873   my $body = shift;
 874   my (@outside, @inside);
 875   my $depth = 0;
 876   my $chunk = '';
 877   while($body || $chunk) {
 878     my ($first, $delim, $rest);
 879     # put all leading non-delimiters into $first
 880     ($first, $rest) =
 881         ($body =~ /^((?:\\[{}]|[^{}])*)(.*)$/s);
 882     $chunk .= $first;
 883     # put a leading delimiter into $delim if there is one
 884     ($delim, $rest) =
 885       ($rest =~ /^([{}]?)(.*)$/s);
 886
 887     if( $delim eq '{' ) {
 888       $chunk .= '{';
 889       if( $depth == 0 ) {
 890         push @outside, $chunk;
 891         $chunk = '';
 892       }
 893       $depth++;
 894     }
 895     elsif( $delim eq '}' ) {
 896       $depth--;
 897       if( $depth == 0 ) {
 898         push @inside, $chunk;
 899         $chunk = '';
 900       }
 901       $chunk .= '}';
 902     }
 903     else {
 904       # no more delimiters
 905       if( $depth == 0 ) {
 906         push @outside, $chunk . $rest;
 907       } # else ? something wrong
 908       last;
 909     }
 910     $body = $rest;
 911   }
 912   (\@outside, \@inside);
 913 }
 914
 915 =back
 916
 917 =head1 BUGS
 918
 919 =head1 SEE ALSO
 920
 921 L<FS::Record>, schema.html from the base documentation.
 922
 923 =cut
 924
 925 1;
 926