FS/FS/msg_template.pm

   1 package FS::msg_template;
   2
   3 use strict;
   4 use base qw( FS::Record );
   5 use Text::Template;
   6 use FS::Misc qw( generate_email send_email do_print );
   7 use FS::Conf;
   8 use FS::Record qw( qsearch qsearchs );
   9 use FS::UID qw( dbh );
  10
  11 use FS::cust_main;
  12 use FS::cust_msg;
  13 use FS::template_content;
  14
  15 use Date::Format qw( time2str );
  16 use HTML::Entities qw( decode_entities encode_entities ) ;
  17 use HTML::FormatText;
  18 use HTML::TreeBuilder;
  19 use Encode;
  20
  21 use File::Temp;
  22 use IPC::Run qw(run);
  23 use vars qw( $DEBUG $conf );
  24
  25 FS::UID->install_callback( sub { $conf = new FS::Conf; } );
  26
  27 $DEBUG=0;
  28
  29 =head1 NAME
  30
  31 FS::msg_template - Object methods for msg_template records
  32
  33 =head1 SYNOPSIS
  34
  35   use FS::msg_template;
  36
  37   $record = new FS::msg_template \%hash;
  38   $record = new FS::msg_template { 'column' => 'value' };
  39
  40   $error = $record->insert;
  41
  42   $error = $new_record->replace($old_record);
  43
  44   $error = $record->delete;
  45
  46   $error = $record->check;
  47
  48 =head1 DESCRIPTION
  49
  50 An FS::msg_template object represents a customer message template.
  51 FS::msg_template inherits from FS::Record.  The following fields are currently
  52 supported:
  53
  54 =over 4
  55
  56 =item msgnum - primary key
  57
  58 =item msgname - Name of the template.  This will appear in the user interface;
  59 if it needs to be localized for some users, add it to the message catalog.
  60
  61 =item agentnum - Agent associated with this template.  Can be NULL for a
  62 global template.
  63
  64 =item mime_type - MIME type.  Defaults to text/html.
  65
  66 =item from_addr - Source email address.
  67
  68 =item disabled - disabled ('Y' or NULL).
  69
  70 =back
  71
  72 =head1 METHODS
  73
  74 =over 4
  75
  76 =item new HASHREF
  77
  78 Creates a new template.  To add the template to the database, see L<"insert">.
  79
  80 Note that this stores the hash reference, not a distinct copy of the hash it
  81 points to.  You can ask the object for a copy with the I<hash> method.
  82
  83 =cut
  84
  85 # the new method can be inherited from FS::Record, if a table method is defined
  86
  87 sub table { 'msg_template'; }
  88
  89 =item insert [ CONTENT ]
  90
  91 Adds this record to the database.  If there is an error, returns the error,
  92 otherwise returns false.
  93
  94 A default (no locale) L<FS::template_content> object will be created.  CONTENT
  95 is an optional hash containing 'subject' and 'body' for this object.
  96
  97 =cut
  98
  99 sub insert {
 100   my $self = shift;
 101   my %content = @_;
 102
 103   my $oldAutoCommit = $FS::UID::AutoCommit;
 104   local $FS::UID::AutoCommit = 0;
 105   my $dbh = dbh;
 106
 107   my $error = $self->SUPER::insert;
 108   if ( !$error ) {
 109     $content{'msgnum'} = $self->msgnum;
 110     $content{'subject'} ||= '';
 111     $content{'body'} ||= '';
 112     my $template_content = new FS::template_content (\%content);
 113     $error = $template_content->insert;
 114   }
 115
 116   if ( $error ) {
 117     $dbh->rollback if $oldAutoCommit;
 118     return $error;
 119   }
 120
 121   $dbh->commit if $oldAutoCommit;
 122   return;
 123 }
 124
 125 =item delete
 126
 127 Delete this record from the database.
 128
 129 =cut
 130
 131 # the delete method can be inherited from FS::Record
 132
 133 =item replace [ OLD_RECORD ] [ CONTENT ]
 134
 135 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 136 returns the error, otherwise returns false.
 137
 138 CONTENT is an optional hash containing 'subject', 'body', and 'locale'.  If
 139 supplied, an L<FS::template_content> object will be created (or modified, if
 140 one already exists for this locale).
 141
 142 =cut
 143
 144 sub replace {
 145   my $self = shift;
 146   my $old = ( ref($_[0]) and $_[0]->isa('FS::Record') )
 147               ? shift
 148               : $self->replace_old;
 149   my %content = @_;
 150
 151   my $oldAutoCommit = $FS::UID::AutoCommit;
 152   local $FS::UID::AutoCommit = 0;
 153   my $dbh = dbh;
 154
 155   my $error = $self->SUPER::replace($old);
 156
 157   if ( !$error and %content ) {
 158     $content{'locale'} ||= '';
 159     my $new_content = qsearchs('template_content', {
 160                         'msgnum' => $self->msgnum,
 161                         'locale' => $content{'locale'},
 162                       } );
 163     if ( $new_content ) {
 164       $new_content->subject($content{'subject'});
 165       $new_content->body($content{'body'});
 166       $error = $new_content->replace;
 167     }
 168     else {
 169       $content{'msgnum'} = $self->msgnum;
 170       $new_content = new FS::template_content \%content;
 171       $error = $new_content->insert;
 172     }
 173   }
 174
 175   if ( $error ) {
 176     $dbh->rollback if $oldAutoCommit;
 177     return $error;
 178   }
 179
 180   warn "committing FS::msg_template->replace\n" if $DEBUG and $oldAutoCommit;
 181   $dbh->commit if $oldAutoCommit;
 182   return;
 183 }
 184
 185
 186
 187 =item check
 188
 189 Checks all fields to make sure this is a valid template.  If there is
 190 an error, returns the error, otherwise returns false.  Called by the insert
 191 and replace methods.
 192
 193 =cut
 194
 195 # the check method should currently be supplied - FS::Record contains some
 196 # data checking routines
 197
 198 sub check {
 199   my $self = shift;
 200
 201   my $error =
 202     $self->ut_numbern('msgnum')
 203     || $self->ut_text('msgname')
 204     || $self->ut_foreign_keyn('agentnum', 'agent', 'agentnum')
 205     || $self->ut_textn('mime_type')
 206     || $self->ut_enum('disabled', [ '', 'Y' ] )
 207     || $self->ut_textn('from_addr')
 208   ;
 209   return $error if $error;
 210
 211   $self->mime_type('text/html') unless $self->mime_type;
 212
 213   $self->SUPER::check;
 214 }
 215
 216 =item content_locales
 217
 218 Returns a hashref of the L<FS::template_content> objects attached to
 219 this template, with the locale as key.
 220
 221 =cut
 222
 223 sub content_locales {
 224   my $self = shift;
 225   return $self->{'_content_locales'} ||= +{
 226     map { $_->locale , $_ }
 227     qsearch('template_content', { 'msgnum' => $self->msgnum })
 228   };
 229 }
 230
 231 =item prepare OPTION => VALUE
 232
 233 Fills in the template and returns a hash of the 'from' address, 'to'
 234 addresses, subject line, and body.
 235
 236 Options are passed as a list of name/value pairs:
 237
 238 =over 4
 239
 240 =item cust_main
 241
 242 Customer object (required).
 243
 244 =item object
 245
 246 Additional context object (currently, can be a cust_main, cust_pkg,
 247 cust_bill, cust_pay, cust_pay_pending, or svc_(acct, phone, broadband,
 248 domain) ).  If the object is a svc_*, its cust_pkg will be fetched and
 249 used for substitution.
 250
 251 As a special case, this may be an arrayref of two objects.  Both
 252 objects will be available for substitution, with their field names
 253 prefixed with 'new_' and 'old_' respectively.  This is used in the
 254 rt_ticket export when exporting "replace" events.
 255
 256 =item from_config
 257
 258 Configuration option to use as the source address, based on the customer's
 259 agentnum.  If unspecified (or the named option is empty), 'invoice_from'
 260 will be used.
 261
 262 The I<from_addr> field in the template takes precedence over this.
 263
 264 =item to
 265
 266 Destination address.  The default is to use the customer's
 267 invoicing_list addresses.  Multiple addresses may be comma-separated.
 268
 269 =item substitutions
 270
 271 A hash reference of additional substitutions
 272
 273 =back
 274
 275 =cut
 276
 277 sub prepare {
 278   my( $self, %opt ) = @_;
 279
 280   my $cust_main = $opt{'cust_main'} or die 'cust_main required';
 281   my $object = $opt{'object'} or die 'object required';
 282
 283   # localization
 284   my $locale = $cust_main->locale || '';
 285   warn "no locale for cust#".$cust_main->custnum."; using default content\n"
 286     if $DEBUG and !$locale;
 287   my $content = $self->content($cust_main->locale);
 288   warn "preparing template '".$self->msgname."' to cust#".$cust_main->custnum."\n"
 289     if($DEBUG);
 290
 291   my $subs = $self->substitutions;
 292
 293   ###
 294   # create substitution table
 295   ###
 296   my %hash;
 297   my @objects = ($cust_main);
 298   my @prefixes = ('');
 299   my $svc;
 300   if( ref $object ) {
 301     if( ref($object) eq 'ARRAY' ) {
 302       # [new, old], for provisioning tickets
 303       push @objects, $object->[0], $object->[1];
 304       push @prefixes, 'new_', 'old_';
 305       $svc = $object->[0] if $object->[0]->isa('FS::svc_Common');
 306     }
 307     else {
 308       push @objects, $object;
 309       push @prefixes, '';
 310       $svc = $object if $object->isa('FS::svc_Common');
 311     }
 312   }
 313   if( $svc ) {
 314     push @objects, $svc->cust_svc->cust_pkg;
 315     push @prefixes, '';
 316   }
 317
 318   foreach my $obj (@objects) {
 319     my $prefix = shift @prefixes;
 320     foreach my $name (@{ $subs->{$obj->table} }) {
 321       if(!ref($name)) {
 322         # simple case
 323         $hash{$prefix.$name} = $obj->$name();
 324       }
 325       elsif( ref($name) eq 'ARRAY' ) {
 326         # [ foo => sub { ... } ]
 327         $hash{$prefix.($name->[0])} = $name->[1]->($obj);
 328       }
 329       else {
 330         warn "bad msg_template substitution: '$name'\n";
 331         #skip it?
 332       }
 333     }
 334   }
 335
 336   if ( $opt{substitutions} ) {
 337     $hash{$_} = $opt{substitutions}->{$_} foreach keys %{$opt{substitutions}};
 338   }
 339
 340   $_ = encode_entities($_ || '') foreach values(%hash);
 341
 342   ###
 343   # clean up template
 344   ###
 345   my $subject_tmpl = new Text::Template (
 346     TYPE   => 'STRING',
 347     SOURCE => $content->subject,
 348   );
 349   my $subject = $subject_tmpl->fill_in( HASH => \%hash );
 350
 351   my $body = $content->body;
 352   my ($skin, $guts) = eviscerate($body);
 353   @$guts = map {
 354     $_ = decode_entities($_); # turn all punctuation back into itself
 355     s/\r//gs;           # remove \r's
 356     s/<br[^>]*>/\n/gsi; # and <br /> tags
 357     s/<p>/\n/gsi;       # and <p>
 358     s/<\/p>//gsi;       # and </p>
 359     s/\240/ /gs;        # and &nbsp;
 360     $_
 361   } @$guts;
 362
 363   $body = '{ use Date::Format qw(time2str); "" }';
 364   while(@$skin || @$guts) {
 365     $body .= shift(@$skin) || '';
 366     $body .= shift(@$guts) || '';
 367   }
 368
 369   ###
 370   # fill-in
 371   ###
 372
 373   my $body_tmpl = new Text::Template (
 374     TYPE          => 'STRING',
 375     SOURCE        => $body,
 376   );
 377
 378   $body = $body_tmpl->fill_in( HASH => \%hash );
 379
 380   ###
 381   # and email
 382   ###
 383
 384   my @to;
 385   if ( exists($opt{'to'}) ) {
 386     @to = split(/\s*,\s*/, $opt{'to'});
 387   }
 388   else {
 389     @to = $cust_main->invoicing_list_emailonly;
 390   }
 391   # no warning when preparing with no destination
 392
 393   my $from_addr = $self->from_addr;
 394
 395   if ( !$from_addr ) {
 396     if ( $opt{'from_config'} ) {
 397       $from_addr = scalar( $conf->config($opt{'from_config'},
 398                                          $cust_main->agentnum) );
 399     }
 400     $from_addr ||= $conf->invoice_from_full($cust_main->agentnum);
 401   }
 402 #  my @cust_msg = ();
 403 #  if ( $conf->exists('log_sent_mail') and !$opt{'preview'} ) {
 404 #    my $cust_msg = FS::cust_msg->new({
 405 #        'custnum' => $cust_main->custnum,
 406 #        'msgnum'  => $self->msgnum,
 407 #        'status'  => 'prepared',
 408 #      });
 409 #    $cust_msg->insert;
 410 #    @cust_msg = ('cust_msg' => $cust_msg);
 411 #  }
 412
 413   my $text_body = encode('UTF-8',
 414                   HTML::FormatText->new(leftmargin => 0, rightmargin => 70)
 415                       ->format( HTML::TreeBuilder->new_from_content($body) )
 416                   );
 417   (
 418     'custnum' => $cust_main->custnum,
 419     'msgnum'  => $self->msgnum,
 420     'from' => $from_addr,
 421     'to'   => \@to,
 422     'bcc'  => $self->bcc_addr || undef,
 423     'subject'   => $subject,
 424     'html_body' => $body,
 425     'text_body' => $text_body,
 426   );
 427
 428 }
 429
 430 =item send OPTION => VALUE
 431
 432 Fills in the template and sends it to the customer.  Options are as for
 433 'prepare', plus 'attach', a L<MIME::Entity> (or arrayref of them) to attach
 434 to the message.
 435
 436 =cut
 437
 438 # broken out from prepare() in case we want to queue the sending,
 439 # preview it, etc.
 440 sub send {
 441   my $self = shift;
 442   my %opt = @_;
 443
 444   my %email = generate_email($self->prepare(%opt));
 445   if ( $opt{'attach'} ) {
 446     my @attach;
 447     if (ref($opt{'attach'}) eq 'ARRAY') {
 448       @attach = @{ $opt{'attach'} };
 449     } else {
 450       @attach = $opt{'attach'};
 451     }
 452     push @{ $email{mimeparts} }, @attach;
 453   }
 454
 455   send_email(%email);
 456 }
 457
 458 =item render OPTION => VALUE ...
 459
 460 Fills in the template and renders it to a PDF document.  Returns the
 461 name of the PDF file.
 462
 463 Options are as for 'prepare', but 'from' and 'to' are meaningless.
 464
 465 =cut
 466
 467 # will also have options to set paper size, margins, etc.
 468
 469 sub render {
 470   my $self = shift;
 471   eval "use PDF::WebKit";
 472   die $@ if $@;
 473   my %opt = @_;
 474   my %hash = $self->prepare(%opt);
 475   my $html = $hash{'html_body'};
 476
 477   # Graphics/stylesheets should probably go in /var/www on the Freeside
 478   # machine.
 479   my $script_path = `/usr/bin/which freeside-wkhtmltopdf`;
 480   chomp $script_path;
 481   my $kit = PDF::WebKit->new(\$html); #%options
 482   # hack to use our wrapper script
 483   $kit->configure(sub { shift->wkhtmltopdf($script_path) });
 484
 485   $kit->to_pdf;
 486 }
 487
 488 =item print OPTIONS
 489
 490 Render a PDF and send it to the printer.  OPTIONS are as for 'render'.
 491
 492 =cut
 493
 494 sub print {
 495   my( $self, %opt ) = @_;
 496   do_print( [ $self->render(%opt) ], agentnum=>$opt{cust_main}->agentnum );
 497 }
 498
 499 # helper sub for package dates
 500 my $ymd = sub { $_[0] ? time2str('%Y-%m-%d', $_[0]) : '' };
 501
 502 # helper sub for money amounts
 503 my $money = sub { ($conf->money_char || '$') . sprintf('%.2f', $_[0] || 0) };
 504
 505 # helper sub for usage-related messages
 506 my $usage_warning = sub {
 507   my $svc = shift;
 508   foreach my $col (qw(seconds upbytes downbytes totalbytes)) {
 509     my $amount = $svc->$col; next if $amount eq '';
 510     my $method = $col.'_threshold';
 511     my $threshold = $svc->$method; next if $threshold eq '';
 512     return [$col, $amount, $threshold] if $amount <= $threshold;
 513     # this only returns the first one that's below threshold, if there are
 514     # several.
 515   }
 516   return ['', '', ''];
 517 };
 518
 519 #my $conf = new FS::Conf;
 520
 521 #return contexts and fill-in values
 522 # If you add anything, be sure to add a description in
 523 # httemplate/edit/msg_template.html.
 524 sub substitutions {
 525   my $payinfo_sub = sub {
 526     my $obj = shift;
 527     ($obj->payby eq 'CARD' || $obj->payby eq 'CHEK')
 528     ? $obj->paymask
 529     : $obj->decrypt($obj->payinfo)
 530   };
 531   my $payinfo_end = sub {
 532     my $obj = shift;
 533     my $payinfo = &$payinfo_sub($obj);
 534     substr($payinfo, -4);
 535   };
 536   { 'cust_main' => [qw(
 537       display_custnum agentnum agent_name
 538
 539       last first company
 540       name name_short contact contact_firstlast
 541       address1 address2 city county state zip
 542       country
 543       daytime night mobile fax
 544
 545       has_ship_address
 546       ship_name ship_name_short ship_contact ship_contact_firstlast
 547       ship_address1 ship_address2 ship_city ship_county ship_state ship_zip
 548       ship_country
 549
 550       paymask payname paytype payip
 551       num_cancelled_pkgs num_ncancelled_pkgs num_pkgs
 552       classname categoryname
 553       balance
 554       credit_limit
 555       invoicing_list_emailonly
 556       cust_status ucfirst_cust_status cust_statuscolor
 557
 558       signupdate dundate
 559       packages recurdates
 560       ),
 561       [ invoicing_email => sub { shift->invoicing_list_emailonly_scalar } ],
 562       #compatibility: obsolete ship_ fields - use the non-ship versions
 563       map (
 564         { my $field = $_;
 565           [ "ship_$field"   => sub { shift->$field } ]
 566         }
 567         qw( last first company daytime night fax )
 568       ),
 569       # ship_name, ship_name_short, ship_contact, ship_contact_firstlast
 570       # still work, though
 571       [ expdate           => sub { shift->paydate_epoch } ], #compatibility
 572       [ signupdate_ymd    => sub { $ymd->(shift->signupdate) } ],
 573       [ dundate_ymd       => sub { $ymd->(shift->dundate) } ],
 574       [ paydate_my        => sub { sprintf('%02d/%04d', shift->paydate_monthyear) } ],
 575       [ otaker_first      => sub { shift->access_user->first } ],
 576       [ otaker_last       => sub { shift->access_user->last } ],
 577       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 578       [ company_name      => sub {
 579           $conf->config('company_name', shift->agentnum)
 580         } ],
 581       [ company_address   => sub {
 582           $conf->config('company_address', shift->agentnum)
 583         } ],
 584       [ company_phonenum  => sub {
 585           $conf->config('company_phonenum', shift->agentnum)
 586         } ],
 587       [ selfservice_server_base_url => sub {
 588           $conf->config('selfservice_server-base_url') #, shift->agentnum)
 589         } ],
 590     ],
 591     # next_bill_date
 592     'cust_pkg'  => [qw(
 593       pkgnum pkg_label pkg_label_long
 594       location_label
 595       status statuscolor
 596
 597       start_date setup bill last_bill
 598       adjourn susp expire
 599       labels_short
 600       ),
 601       [ pkg               => sub { shift->part_pkg->pkg } ],
 602       [ pkg_category      => sub { shift->part_pkg->categoryname } ],
 603       [ pkg_class         => sub { shift->part_pkg->classname } ],
 604       [ cancel            => sub { shift->getfield('cancel') } ], # grrr...
 605       [ start_ymd         => sub { $ymd->(shift->getfield('start_date')) } ],
 606       [ setup_ymd         => sub { $ymd->(shift->getfield('setup')) } ],
 607       [ next_bill_ymd     => sub { $ymd->(shift->getfield('bill')) } ],
 608       [ last_bill_ymd     => sub { $ymd->(shift->getfield('last_bill')) } ],
 609       [ adjourn_ymd       => sub { $ymd->(shift->getfield('adjourn')) } ],
 610       [ susp_ymd          => sub { $ymd->(shift->getfield('susp')) } ],
 611       [ expire_ymd        => sub { $ymd->(shift->getfield('expire')) } ],
 612       [ cancel_ymd        => sub { $ymd->(shift->getfield('cancel')) } ],
 613
 614       # not necessarily correct for non-flat packages
 615       [ setup_fee         => sub { shift->part_pkg->option('setup_fee') } ],
 616       [ recur_fee         => sub { shift->part_pkg->option('recur_fee') } ],
 617
 618       [ freq_pretty       => sub { shift->part_pkg->freq_pretty } ],
 619
 620     ],
 621     'cust_bill' => [qw(
 622       invnum
 623       _date
 624       _date_pretty
 625       due_date
 626     ),
 627       [ due_date2str      => sub { shift->due_date2str('short') } ],
 628     ],
 629     #XXX not really thinking about cust_bill substitutions quite yet
 630
 631     # for welcome and limit warning messages
 632     'svc_acct' => [qw(
 633       svcnum
 634       username
 635       domain
 636       ),
 637       [ password          => sub { shift->getfield('_password') } ],
 638       [ column            => sub { &$usage_warning(shift)->[0] } ],
 639       [ amount            => sub { &$usage_warning(shift)->[1] } ],
 640       [ threshold         => sub { &$usage_warning(shift)->[2] } ],
 641     ],
 642     'svc_domain' => [qw(
 643       svcnum
 644       domain
 645       ),
 646       [ registrar         => sub {
 647           my $registrar = qsearchs('registrar',
 648             { registrarnum => shift->registrarnum} );
 649           $registrar ? $registrar->registrarname : ''
 650         }
 651       ],
 652       [ catchall          => sub {
 653           my $svc_acct = qsearchs('svc_acct', { svcnum => shift->catchall });
 654           $svc_acct ? $svc_acct->email : ''
 655         }
 656       ],
 657     ],
 658     'svc_phone' => [qw(
 659       svcnum
 660       phonenum
 661       countrycode
 662       domain
 663       )
 664     ],
 665     'svc_broadband' => [qw(
 666       svcnum
 667       speed_up
 668       speed_down
 669       ip_addr
 670       mac_addr
 671       )
 672     ],
 673     # for payment receipts
 674     'cust_pay' => [qw(
 675       paynum
 676       _date
 677       ),
 678       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 679       # overrides the one in cust_main in cases where a cust_pay is passed
 680       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 681       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 682       [ 'payinfo' => $payinfo_sub ],
 683       [ 'payinfo_end' => $payinfo_end ],
 684     ],
 685     # for refund receipts
 686     'cust_refund' => [
 687       'refundnum',
 688       [ refund            => sub { sprintf("%.2f", shift->refund) } ],
 689       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 690       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 691       [ 'payinfo' => $payinfo_sub ],
 692       [ 'payinfo_end' => $payinfo_end ],
 693     ],
 694     # for payment decline messages
 695     # try to support all cust_pay fields
 696     # 'error' is a special case, it contains the raw error from the gateway
 697     'cust_pay_pending' => [qw(
 698       _date
 699       error
 700       ),
 701       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 702       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 703       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 704       [ 'payinfo' => $payinfo_sub ],
 705       [ 'payinfo_end' => $payinfo_end ],
 706     ],
 707   };
 708 }
 709
 710 =item content LOCALE
 711
 712 Returns the L<FS::template_content> object appropriate to LOCALE, if there
 713 is one.  If not, returns the one with a NULL locale.
 714
 715 =cut
 716
 717 sub content {
 718   my $self = shift;
 719   my $locale = shift;
 720   qsearchs('template_content',
 721             { 'msgnum' => $self->msgnum, 'locale' => $locale }) ||
 722   qsearchs('template_content',
 723             { 'msgnum' => $self->msgnum, 'locale' => '' });
 724 }
 725
 726 =item agent
 727
 728 Returns the L<FS::agent> object for this template.
 729
 730 =cut
 731
 732 sub agent {
 733   qsearchs('agent', { 'agentnum' => $_[0]->agentnum });
 734 }
 735
 736 sub _upgrade_data {
 737   my ($self, %opts) = @_;
 738
 739   ###
 740   # First move any historical templates in config to real message templates
 741   ###
 742
 743   my @fixes = (
 744     [ 'alerter_msgnum',  'alerter_template',   '',               '', '' ],
 745     [ 'cancel_msgnum',   'cancelmessage',      'cancelsubject',  '', '' ],
 746     [ 'decline_msgnum',  'declinetemplate',    '',               '', '' ],
 747     [ 'impending_recur_msgnum', 'impending_recur_template', '',  '', 'impending_recur_bcc' ],
 748     [ 'payment_receipt_msgnum', 'payment_receipt_email', '',     '', '' ],
 749     [ 'welcome_msgnum',  'welcome_email',      'welcome_email-subject', 'welcome_email-from', '' ],
 750     [ 'warning_msgnum',  'warning_email',      'warning_email-subject', 'warning_email-from', '' ],
 751   );
 752
 753   my @agentnums = ('', map {$_->agentnum} qsearch('agent', {}));
 754   foreach my $agentnum (@agentnums) {
 755     foreach (@fixes) {
 756       my ($newname, $oldname, $subject, $from, $bcc) = @$_;
 757       if ($conf->exists($oldname, $agentnum)) {
 758         my $new = new FS::msg_template({
 759           'msgname'   => $oldname,
 760           'agentnum'  => $agentnum,
 761           'from_addr' => ($from && $conf->config($from, $agentnum)) || '',
 762           'bcc_addr'  => ($bcc && $conf->config($from, $agentnum)) || '',
 763           'subject'   => ($subject && $conf->config($subject, $agentnum)) || '',
 764           'mime_type' => 'text/html',
 765           'body'      => join('<BR>',$conf->config($oldname, $agentnum)),
 766         });
 767         my $error = $new->insert;
 768         die $error if $error;
 769         $conf->set($newname, $new->msgnum, $agentnum);
 770         $conf->delete($oldname, $agentnum);
 771         $conf->delete($from, $agentnum) if $from;
 772         $conf->delete($subject, $agentnum) if $subject;
 773       }
 774     }
 775
 776     if ( $conf->exists('alert_expiration', $agentnum) ) {
 777       my $msgnum = $conf->exists('alerter_msgnum', $agentnum);
 778       my $template = FS::msg_template->by_key($msgnum) if $msgnum;
 779       if (!$template) {
 780         warn "template for alerter_msgnum $msgnum not found\n";
 781         next;
 782       }
 783       # this is now a set of billing events
 784       foreach my $days (30, 15, 5) {
 785         my $event = FS::part_event->new({
 786             'agentnum'    => $agentnum,
 787             'event'       => "Card expiration warning - $days days",
 788             'eventtable'  => 'cust_main',
 789             'check_freq'  => '1d',
 790             'action'      => 'notice',
 791             'disabled'    => 'Y', #initialize first
 792         });
 793         my $error = $event->insert( 'msgnum' => $msgnum );
 794         if ($error) {
 795           warn "error creating expiration alert event:\n$error\n\n";
 796           next;
 797         }
 798         # make it work like before:
 799         # only send each warning once before the card expires,
 800         # only warn active customers,
 801         # only warn customers with CARD/DCRD,
 802         # only warn customers who get email invoices
 803         my %conds = (
 804           'once_every'          => { 'run_delay' => '30d' },
 805           'cust_paydate_within' => { 'within' => $days.'d' },
 806           'cust_status'         => { 'status' => { 'active' => 1 } },
 807           'payby'               => { 'payby'  => { 'CARD' => 1,
 808                                                    'DCRD' => 1, }
 809                                    },
 810           'message_email'       => {},
 811         );
 812         foreach (keys %conds) {
 813           my $condition = FS::part_event_condition->new({
 814               'conditionname' => $_,
 815               'eventpart'     => $event->eventpart,
 816           });
 817           $error = $condition->insert( %{ $conds{$_} });
 818           if ( $error ) {
 819             warn "error creating expiration alert event:\n$error\n\n";
 820             next;
 821           }
 822         }
 823         $error = $event->initialize;
 824         if ( $error ) {
 825           warn "expiration alert event was created, but not initialized:\n$error\n\n";
 826         }
 827       } # foreach $days
 828       $conf->delete('alerter_msgnum', $agentnum);
 829       $conf->delete('alert_expiration', $agentnum);
 830
 831     } # if alerter_msgnum
 832
 833   }
 834
 835   ###
 836   # Move subject and body from msg_template to template_content
 837   ###
 838
 839   foreach my $msg_template ( qsearch('msg_template', {}) ) {
 840     if ( $msg_template->subject || $msg_template->body ) {
 841       # create new default content
 842       my %content;
 843       $content{subject} = $msg_template->subject;
 844       $msg_template->set('subject', '');
 845
 846       # work around obscure Pg/DBD bug
 847       # https://rt.cpan.org/Public/Bug/Display.html?id=60200
 848       # (though the right fix is to upgrade DBD)
 849       my $body = $msg_template->body;
 850       if ( $body =~ /^x([0-9a-f]+)$/ ) {
 851         # there should be no real message templates that look like that
 852         warn "converting template body to TEXT\n";
 853         $body = pack('H*', $1);
 854       }
 855       $content{body} = $body;
 856       $msg_template->set('body', '');
 857
 858       my $error = $msg_template->replace(%content);
 859       die $error if $error;
 860     }
 861   }
 862
 863   ###
 864   # Add new-style default templates if missing
 865   ###
 866   $self->_populate_initial_data;
 867
 868 }
 869
 870 sub _populate_initial_data { #class method
 871   #my($class, %opts) = @_;
 872   #my $class = shift;
 873
 874   eval "use FS::msg_template::InitialData;";
 875   die $@ if $@;
 876
 877   my $initial_data = FS::msg_template::InitialData->_initial_data;
 878
 879   foreach my $hash ( @$initial_data ) {
 880
 881     next if $hash->{_conf} && $conf->config( $hash->{_conf} );
 882
 883     my $msg_template = new FS::msg_template($hash);
 884     my $error = $msg_template->insert( @{ $hash->{_insert_args} || [] } );
 885     die $error if $error;
 886
 887     $conf->set( $hash->{_conf}, $msg_template->msgnum ) if $hash->{_conf};
 888
 889   }
 890
 891 }
 892
 893 sub eviscerate {
 894   # Every bit as pleasant as it sounds.
 895   #
 896   # We do this because Text::Template::Preprocess doesn't
 897   # actually work.  It runs the entire template through
 898   # the preprocessor, instead of the code segments.  Which
 899   # is a shame, because Text::Template already contains
 900   # the code to do this operation.
 901   my $body = shift;
 902   my (@outside, @inside);
 903   my $depth = 0;
 904   my $chunk = '';
 905   while($body || $chunk) {
 906     my ($first, $delim, $rest);
 907     # put all leading non-delimiters into $first
 908     ($first, $rest) =
 909         ($body =~ /^((?:\\[{}]|[^{}])*)(.*)$/s);
 910     $chunk .= $first;
 911     # put a leading delimiter into $delim if there is one
 912     ($delim, $rest) =
 913       ($rest =~ /^([{}]?)(.*)$/s);
 914
 915     if( $delim eq '{' ) {
 916       $chunk .= '{';
 917       if( $depth == 0 ) {
 918         push @outside, $chunk;
 919         $chunk = '';
 920       }
 921       $depth++;
 922     }
 923     elsif( $delim eq '}' ) {
 924       $depth--;
 925       if( $depth == 0 ) {
 926         push @inside, $chunk;
 927         $chunk = '';
 928       }
 929       $chunk .= '}';
 930     }
 931     else {
 932       # no more delimiters
 933       if( $depth == 0 ) {
 934         push @outside, $chunk . $rest;
 935       } # else ? something wrong
 936       last;
 937     }
 938     $body = $rest;
 939   }
 940   (\@outside, \@inside);
 941 }
 942
 943 =back
 944
 945 =head1 BUGS
 946
 947 =head1 SEE ALSO
 948
 949 L<FS::Record>, schema.html from the base documentation.
 950
 951 =cut
 952
 953 1;
 954