FS/FS/cust_refund.pm

   1 package FS::cust_refund;
   2
   3 use strict;
   4 use base qw( FS::otaker_Mixin FS::payinfo_transaction_Mixin FS::cust_main_Mixin
   5              FS::Record );
   6 use vars qw( @encrypted_fields );
   7 use Business::CreditCard;
   8 use FS::UID qw(getotaker);
   9 use FS::Record qw( qsearch qsearchs dbh );
  10 use FS::CurrentUser;
  11 use FS::cust_credit;
  12 use FS::cust_credit_refund;
  13 use FS::cust_pay_refund;
  14 use FS::cust_main;
  15
  16 @encrypted_fields = ('payinfo');
  17 sub nohistory_fields { ('payinfo'); }
  18
  19 =head1 NAME
  20
  21 FS::cust_refund - Object method for cust_refund objects
  22
  23 =head1 SYNOPSIS
  24
  25   use FS::cust_refund;
  26
  27   $record = new FS::cust_refund \%hash;
  28   $record = new FS::cust_refund { 'column' => 'value' };
  29
  30   $error = $record->insert;
  31
  32   $error = $new_record->replace($old_record);
  33
  34   $error = $record->delete;
  35
  36   $error = $record->check;
  37
  38 =head1 DESCRIPTION
  39
  40 An FS::cust_refund represents a refund: the transfer of money to a customer;
  41 equivalent to a negative payment (see L<FS::cust_pay>).  FS::cust_refund
  42 inherits from FS::Record.  The following fields are currently supported:
  43
  44 =over 4
  45
  46 =item refundnum
  47
  48 primary key (assigned automatically for new refunds)
  49
  50 =item custnum
  51
  52 customer (see L<FS::cust_main>)
  53
  54 =item refund
  55
  56 Amount of the refund
  57
  58 =item reason
  59
  60 Reason for the refund
  61
  62 =item _date
  63
  64 specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  65 L<Time::Local> and L<Date::Parse> for conversion functions.
  66
  67 =item payby
  68
  69 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
  70
  71 =item payinfo
  72
  73 Payment Information (See L<FS::payinfo_Mixin> for data format)
  74
  75 =item paymask
  76
  77 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
  78
  79 =item paybatch
  80
  81 text field for tracking card processing
  82
  83 =item usernum
  84
  85 order taker (see L<FS::access_user>
  86
  87 =item closed
  88
  89 books closed flag, empty or `Y'
  90
  91 =back
  92
  93 =head1 METHODS
  94
  95 =over 4
  96
  97 =item new HASHREF
  98
  99 Creates a new refund.  To add the refund to the database, see L<"insert">.
 100
 101 =cut
 102
 103 sub table { 'cust_refund'; }
 104
 105 =item insert
 106
 107 Adds this refund to the database.
 108
 109 For backwards-compatibility and convenience, if the additional field crednum is
 110 defined, an FS::cust_credit_refund record for the full amount of the refund
 111 will be created.  Or (this time for convenience and consistancy), if the
 112 additional field paynum is defined, an FS::cust_pay_refund record for the full
 113 amount of the refund will be created.  In both cases, custnum is optional.
 114
 115 =cut
 116
 117 sub insert {
 118   my $self = shift;
 119
 120   local $SIG{HUP} = 'IGNORE';
 121   local $SIG{INT} = 'IGNORE';
 122   local $SIG{QUIT} = 'IGNORE';
 123   local $SIG{TERM} = 'IGNORE';
 124   local $SIG{TSTP} = 'IGNORE';
 125   local $SIG{PIPE} = 'IGNORE';
 126
 127   my $oldAutoCommit = $FS::UID::AutoCommit;
 128   local $FS::UID::AutoCommit = 0;
 129   my $dbh = dbh;
 130
 131   if ( $self->crednum ) {
 132     my $cust_credit = qsearchs('cust_credit', { 'crednum' => $self->crednum } )
 133       or do {
 134         $dbh->rollback if $oldAutoCommit;
 135         return "Unknown cust_credit.crednum: ". $self->crednum;
 136       };
 137     $self->custnum($cust_credit->custnum);
 138   } elsif ( $self->paynum ) {
 139     my $cust_pay = qsearchs('cust_pay', { 'paynum' => $self->paynum } )
 140       or do {
 141         $dbh->rollback if $oldAutoCommit;
 142         return "Unknown cust_pay.paynum: ". $self->paynum;
 143       };
 144     $self->custnum($cust_pay->custnum);
 145   }
 146
 147   my $error = $self->check;
 148   return $error if $error;
 149
 150   $error = $self->SUPER::insert;
 151   if ( $error ) {
 152     $dbh->rollback if $oldAutoCommit;
 153     return $error;
 154   }
 155
 156   if ( $self->crednum ) {
 157     my $cust_credit_refund = new FS::cust_credit_refund {
 158       'crednum'   => $self->crednum,
 159       'refundnum' => $self->refundnum,
 160       'amount'    => $self->refund,
 161       '_date'     => $self->_date,
 162     };
 163     $error = $cust_credit_refund->insert;
 164     if ( $error ) {
 165       $dbh->rollback if $oldAutoCommit;
 166       return $error;
 167     }
 168     #$self->custnum($cust_credit_refund->cust_credit->custnum);
 169   } elsif ( $self->paynum ) {
 170     my $cust_pay_refund = new FS::cust_pay_refund {
 171       'paynum'    => $self->paynum,
 172       'refundnum' => $self->refundnum,
 173       'amount'    => $self->refund,
 174       '_date'     => $self->_date,
 175     };
 176     $error = $cust_pay_refund->insert;
 177     if ( $error ) {
 178       $dbh->rollback if $oldAutoCommit;
 179       return $error;
 180     }
 181   }
 182
 183
 184   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 185
 186   '';
 187
 188 }
 189
 190 =item delete
 191
 192 Unless the closed flag is set, deletes this refund and all associated
 193 applications (see L<FS::cust_credit_refund> and L<FS::cust_pay_refund>).
 194
 195 =cut
 196
 197 sub delete {
 198   my $self = shift;
 199   return "Can't delete closed refund" if $self->closed =~ /^Y/i;
 200
 201   local $SIG{HUP} = 'IGNORE';
 202   local $SIG{INT} = 'IGNORE';
 203   local $SIG{QUIT} = 'IGNORE';
 204   local $SIG{TERM} = 'IGNORE';
 205   local $SIG{TSTP} = 'IGNORE';
 206   local $SIG{PIPE} = 'IGNORE';
 207
 208   my $oldAutoCommit = $FS::UID::AutoCommit;
 209   local $FS::UID::AutoCommit = 0;
 210   my $dbh = dbh;
 211
 212   foreach my $cust_credit_refund ( $self->cust_credit_refund ) {
 213     my $error = $cust_credit_refund->delete;
 214     if ( $error ) {
 215       $dbh->rollback if $oldAutoCommit;
 216       return $error;
 217     }
 218   }
 219
 220   foreach my $cust_pay_refund ( $self->cust_pay_refund ) {
 221     my $error = $cust_pay_refund->delete;
 222     if ( $error ) {
 223       $dbh->rollback if $oldAutoCommit;
 224       return $error;
 225     }
 226   }
 227
 228   my $error = $self->SUPER::delete(@_);
 229   if ( $error ) {
 230     $dbh->rollback if $oldAutoCommit;
 231     return $error;
 232   }
 233
 234   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 235
 236   '';
 237
 238 }
 239
 240 =item replace OLD_RECORD
 241
 242 You can, but probably shouldn't modify refunds...
 243
 244 Replaces the OLD_RECORD with this one in the database, or, if OLD_RECORD is not
 245 supplied, replaces this record.  If there is an error, returns the error,
 246 otherwise returns false.
 247
 248 =cut
 249
 250 sub replace {
 251   my $self = shift;
 252   return "Can't modify closed refund" if $self->closed =~ /^Y/i;
 253   $self->SUPER::replace(@_);
 254 }
 255
 256 =item check
 257
 258 Checks all fields to make sure this is a valid refund.  If there is an error,
 259 returns the error, otherwise returns false.  Called by the insert method.
 260
 261 =cut
 262
 263 sub check {
 264   my $self = shift;
 265
 266   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 267
 268   my $error =
 269     $self->ut_numbern('refundnum')
 270     || $self->ut_numbern('custnum')
 271     || $self->ut_money('refund')
 272     || $self->ut_alphan('otaker')
 273     || $self->ut_text('reason')
 274     || $self->ut_numbern('_date')
 275     || $self->ut_textn('paybatch')
 276     || $self->ut_enum('closed', [ '', 'Y' ])
 277   ;
 278   return $error if $error;
 279
 280   return "refund must be > 0 " if $self->refund <= 0;
 281
 282   $self->_date(time) unless $self->_date;
 283
 284   return "unknown cust_main.custnum: ". $self->custnum
 285     unless $self->crednum
 286            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 287
 288   $error = $self->payinfo_check;
 289   return $error if $error;
 290
 291   $self->SUPER::check;
 292 }
 293
 294 =item cust_credit_refund
 295
 296 Returns all applications to credits (see L<FS::cust_credit_refund>) for this
 297 refund.
 298
 299 =cut
 300
 301 sub cust_credit_refund {
 302   my $self = shift;
 303   map { $_ } #return $self->num_cust_credit_refund unless wantarray;
 304   sort { $a->_date <=> $b->_date }
 305     qsearch( 'cust_credit_refund', { 'refundnum' => $self->refundnum } )
 306   ;
 307 }
 308
 309 =item cust_pay_refund
 310
 311 Returns all applications to payments (see L<FS::cust_pay_refund>) for this
 312 refund.
 313
 314 =cut
 315
 316 sub cust_pay_refund {
 317   my $self = shift;
 318   map { $_ } #return $self->num_cust_pay_refund unless wantarray;
 319   sort { $a->_date <=> $b->_date }
 320     qsearch( 'cust_pay_refund', { 'refundnum' => $self->refundnum } )
 321   ;
 322 }
 323
 324 =item unapplied
 325
 326 Returns the amount of this refund that is still unapplied; which is
 327 amount minus all credit applications (see L<FS::cust_credit_refund>) and
 328 payment applications (see L<FS::cust_pay_refund>).
 329
 330 =cut
 331
 332 sub unapplied {
 333   my $self = shift;
 334   my $amount = $self->refund;
 335   $amount -= $_->amount foreach ( $self->cust_credit_refund );
 336   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 337   sprintf("%.2f", $amount );
 338 }
 339
 340 =back
 341
 342 =head1 CLASS METHODS
 343
 344 =over 4
 345
 346 =item unapplied_sql
 347
 348 Returns an SQL fragment to retreive the unapplied amount.
 349
 350 =cut
 351
 352 sub unapplied_sql {
 353   my ($class, $start, $end) = @_;
 354   my $credit_start = $start ? "AND cust_credit_refund._date <= $start" : '';
 355   my $credit_end   = $end   ? "AND cust_credit_refund._date > $end"   : '';
 356   my $pay_start    = $start ? "AND cust_pay_refund._date <= $start"    : '';
 357   my $pay_end      = $end   ? "AND cust_pay_refund._date > $end"      : '';
 358
 359   "refund
 360     - COALESCE(
 361                 ( SELECT SUM(amount) FROM cust_credit_refund
 362                     WHERE cust_refund.refundnum = cust_credit_refund.refundnum
 363                     $credit_start $credit_end )
 364                 ,0
 365               )
 366     - COALESCE(
 367                 ( SELECT SUM(amount) FROM cust_pay_refund
 368                     WHERE cust_refund.refundnum = cust_pay_refund.refundnum
 369                     $pay_start $pay_end )
 370                 ,0
 371               )
 372   ";
 373
 374 }
 375
 376 # Used by FS::Upgrade to migrate to a new database.
 377 sub _upgrade_data {  # class method
 378   my ($class, %opts) = @_;
 379   $class->_upgrade_otaker(%opts);
 380 }
 381
 382 =back
 383
 384 =head1 BUGS
 385
 386 Delete and replace methods.
 387
 388 =head1 SEE ALSO
 389
 390 L<FS::Record>, L<FS::cust_credit>, schema.html from the base documentation.
 391
 392 =cut
 393
 394 1;
 395