FS/FS/cust_pkg.pm

   1 package FS::cust_pkg;
   2 use base qw( FS::otaker_Mixin FS::cust_main_Mixin FS::Sales_Mixin
   3              FS::contact_Mixin FS::location_Mixin
   4              FS::m2m_Common FS::option_Common );
   5
   6 use strict;
   7 use vars qw( $disable_agentcheck $DEBUG $me $upgrade );
   8 use Carp qw(cluck);
   9 use Scalar::Util qw( blessed );
  10 use List::Util qw(min max);
  11 use Tie::IxHash;
  12 use Time::Local qw( timelocal timelocal_nocheck );
  13 use MIME::Entity;
  14 use FS::UID qw( getotaker dbh driver_name );
  15 use FS::Misc qw( send_email );
  16 use FS::Record qw( qsearch qsearchs fields );
  17 use FS::CurrentUser;
  18 use FS::cust_svc;
  19 use FS::part_pkg;
  20 use FS::cust_main;
  21 use FS::contact;
  22 use FS::cust_location;
  23 use FS::pkg_svc;
  24 use FS::cust_bill_pkg;
  25 use FS::cust_pkg_detail;
  26 use FS::cust_pkg_usage;
  27 use FS::cdr_cust_pkg_usage;
  28 use FS::cust_event;
  29 use FS::h_cust_svc;
  30 use FS::reg_code;
  31 use FS::part_svc;
  32 use FS::cust_pkg_reason;
  33 use FS::reason;
  34 use FS::cust_pkg_discount;
  35 use FS::discount;
  36 use FS::UI::Web;
  37 use FS::sales;
  38 # for modify_charge
  39 use FS::cust_credit;
  40
  41 # need to 'use' these instead of 'require' in sub { cancel, suspend, unsuspend,
  42 # setup }
  43 # because they load configuration by setting FS::UID::callback (see TODO)
  44 use FS::svc_acct;
  45 use FS::svc_domain;
  46 use FS::svc_www;
  47 use FS::svc_forward;
  48
  49 # for sending cancel emails in sub cancel
  50 use FS::Conf;
  51
  52 $DEBUG = 0;
  53 $me = '[FS::cust_pkg]';
  54
  55 $disable_agentcheck = 0;
  56
  57 $upgrade = 0; #go away after setup+start dates cleaned up for old customers
  58
  59 sub _cache {
  60   my $self = shift;
  61   my ( $hashref, $cache ) = @_;
  62   #if ( $hashref->{'pkgpart'} ) {
  63   if ( $hashref->{'pkg'} ) {
  64     # #@{ $self->{'_pkgnum'} } = ();
  65     # my $subcache = $cache->subcache('pkgpart', 'part_pkg');
  66     # $self->{'_pkgpart'} = $subcache;
  67     # #push @{ $self->{'_pkgnum'} },
  68     #   FS::part_pkg->new_or_cached($hashref, $subcache);
  69     $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  70   }
  71   if ( exists $hashref->{'svcnum'} ) {
  72     #@{ $self->{'_pkgnum'} } = ();
  73     my $subcache = $cache->subcache('svcnum', 'cust_svc', $hashref->{pkgnum});
  74     $self->{'_svcnum'} = $subcache;
  75     #push @{ $self->{'_pkgnum'} },
  76     FS::cust_svc->new_or_cached($hashref, $subcache) if $hashref->{svcnum};
  77   }
  78 }
  79
  80 =head1 NAME
  81
  82 FS::cust_pkg - Object methods for cust_pkg objects
  83
  84 =head1 SYNOPSIS
  85
  86   use FS::cust_pkg;
  87
  88   $record = new FS::cust_pkg \%hash;
  89   $record = new FS::cust_pkg { 'column' => 'value' };
  90
  91   $error = $record->insert;
  92
  93   $error = $new_record->replace($old_record);
  94
  95   $error = $record->delete;
  96
  97   $error = $record->check;
  98
  99   $error = $record->cancel;
 100
 101   $error = $record->suspend;
 102
 103   $error = $record->unsuspend;
 104
 105   $part_pkg = $record->part_pkg;
 106
 107   @labels = $record->labels;
 108
 109   $seconds = $record->seconds_since($timestamp);
 110
 111   #bulk cancel+order... perhaps slightly deprecated, only used by the bulk
 112   # cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
 113   $error = FS::cust_pkg::order( $custnum, \@pkgparts );
 114   $error = FS::cust_pkg::order( $custnum, \@pkgparts, \@remove_pkgnums ] );
 115
 116 =head1 DESCRIPTION
 117
 118 An FS::cust_pkg object represents a customer billing item.  FS::cust_pkg
 119 inherits from FS::Record.  The following fields are currently supported:
 120
 121 =over 4
 122
 123 =item pkgnum
 124
 125 Primary key (assigned automatically for new billing items)
 126
 127 =item custnum
 128
 129 Customer (see L<FS::cust_main>)
 130
 131 =item pkgpart
 132
 133 Billing item definition (see L<FS::part_pkg>)
 134
 135 =item locationnum
 136
 137 Optional link to package location (see L<FS::location>)
 138
 139 =item order_date
 140
 141 date package was ordered (also remains same on changes)
 142
 143 =item start_date
 144
 145 date
 146
 147 =item setup
 148
 149 date
 150
 151 =item bill
 152
 153 date (next bill date)
 154
 155 =item last_bill
 156
 157 last bill date
 158
 159 =item adjourn
 160
 161 date
 162
 163 =item susp
 164
 165 date
 166
 167 =item expire
 168
 169 date
 170
 171 =item contract_end
 172
 173 date
 174
 175 =item cancel
 176
 177 date
 178
 179 =item usernum
 180
 181 order taker (see L<FS::access_user>)
 182
 183 =item manual_flag
 184
 185 If this field is set to 1, disables the automatic
 186 unsuspension of this package when using the B<unsuspendauto> config option.
 187
 188 =item quantity
 189
 190 If not set, defaults to 1
 191
 192 =item change_date
 193
 194 Date of change from previous package
 195
 196 =item change_pkgnum
 197
 198 Previous pkgnum
 199
 200 =item change_pkgpart
 201
 202 Previous pkgpart
 203
 204 =item change_locationnum
 205
 206 Previous locationnum
 207
 208 =item waive_setup
 209
 210 =item main_pkgnum
 211
 212 The pkgnum of the package that this package is supplemental to, if any.
 213
 214 =item pkglinknum
 215
 216 The package link (L<FS::part_pkg_link>) that defines this supplemental
 217 package, if it is one.
 218
 219 =item change_to_pkgnum
 220
 221 The pkgnum of the package this one will be "changed to" in the future
 222 (on its expiration date).
 223
 224 =back
 225
 226 Note: setup, last_bill, bill, adjourn, susp, expire, cancel and change_date
 227 are specified as UNIX timestamps; see L<perlfunc/"time">.  Also see
 228 L<Time::Local> and L<Date::Parse> for conversion functions.
 229
 230 =head1 METHODS
 231
 232 =over 4
 233
 234 =item new HASHREF
 235
 236 Create a new billing item.  To add the item to the database, see L<"insert">.
 237
 238 =cut
 239
 240 sub table { 'cust_pkg'; }
 241 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
 242 sub cust_unlinked_msg {
 243   my $self = shift;
 244   "WARNING: can't find cust_main.custnum ". $self->custnum.
 245   ' (cust_pkg.pkgnum '. $self->pkgnum. ')';
 246 }
 247
 248 =item set_initial_timers
 249
 250 If required by the package definition, sets any automatic expire, adjourn,
 251 or contract_end timers to some number of months after the start date
 252 (or setup date, if the package has already been setup). If the package has
 253 a delayed setup fee after a period of "free days", will also set the
 254 start date to the end of that period.
 255
 256 =cut
 257
 258 sub set_initial_timers {
 259   my $self = shift;
 260   my $part_pkg = $self->part_pkg;
 261   foreach my $action ( qw(expire adjourn contract_end) ) {
 262     my $months = $part_pkg->option("${action}_months",1);
 263     if($months and !$self->get($action)) {
 264       my $start = $self->start_date || $self->setup || time;
 265       $self->set($action, $part_pkg->add_freq($start, $months) );
 266     }
 267   }
 268
 269   # if this package has "free days" and delayed setup fee, then
 270   # set start date that many days in the future.
 271   # (this should have been set in the UI, but enforce it here)
 272   if ( $part_pkg->option('free_days',1)
 273        && $part_pkg->option('delay_setup',1)
 274      )
 275   {
 276     $self->start_date( $part_pkg->default_start_date );
 277   }
 278   '';
 279 }
 280
 281 =item insert [ OPTION => VALUE ... ]
 282
 283 Adds this billing item to the database ("Orders" the item).  If there is an
 284 error, returns the error, otherwise returns false.
 285
 286 If the additional field I<promo_code> is defined instead of I<pkgpart>, it
 287 will be used to look up the package definition and agent restrictions will be
 288 ignored.
 289
 290 If the additional field I<refnum> is defined, an FS::pkg_referral record will
 291 be created and inserted.  Multiple FS::pkg_referral records can be created by
 292 setting I<refnum> to an array reference of refnums or a hash reference with
 293 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
 294 record will be created corresponding to cust_main.refnum.
 295
 296 The following options are available:
 297
 298 =over 4
 299
 300 =item change
 301
 302 If set true, supresses actions that should only be taken for new package
 303 orders.  (Currently this includes: intro periods when delay_setup is on,
 304 auto-adding a 1st start date, auto-adding expiration/adjourn/contract_end dates)
 305
 306 =item options
 307
 308 cust_pkg_option records will be created
 309
 310 =item ticket_subject
 311
 312 a ticket will be added to this customer with this subject
 313
 314 =item ticket_queue
 315
 316 an optional queue name for ticket additions
 317
 318 =item allow_pkgpart
 319
 320 Don't check the legality of the package definition.  This should be used
 321 when performing a package change that doesn't change the pkgpart (i.e.
 322 a location change).
 323
 324 =back
 325
 326 =cut
 327
 328 sub insert {
 329   my( $self, %options ) = @_;
 330
 331   my $error;
 332   $error = $self->check_pkgpart unless $options{'allow_pkgpart'};
 333   return $error if $error;
 334
 335   my $part_pkg = $self->part_pkg;
 336
 337   if ( ! $options{'change'} ) {
 338
 339     # set order date to now
 340     $self->order_date(time);
 341
 342     # if the package def says to start only on the first of the month:
 343     if ( $part_pkg->option('start_1st', 1) && !$self->start_date ) {
 344       my ($sec,$min,$hour,$mday,$mon,$year) = (localtime(time) )[0,1,2,3,4,5];
 345       $mon += 1 unless $mday == 1;
 346       until ( $mon < 12 ) { $mon -= 12; $year++; }
 347       $self->start_date( timelocal_nocheck(0,0,0,1,$mon,$year) );
 348     }
 349
 350     if ($self->susp eq 'now' or $part_pkg->start_on_hold) {
 351       # if the package was ordered on hold:
 352       # - suspend it
 353       # - don't set the start date (it will be started manually)
 354       $self->set('susp', $self->order_date);
 355       $self->set('start_date', '');
 356     } else {
 357       # set expire/adjourn/contract_end timers, and free days, if appropriate
 358       $self->set_initial_timers;
 359     }
 360   } # else this is a package change, and shouldn't have "new package" behavior
 361
 362   local $SIG{HUP} = 'IGNORE';
 363   local $SIG{INT} = 'IGNORE';
 364   local $SIG{QUIT} = 'IGNORE';
 365   local $SIG{TERM} = 'IGNORE';
 366   local $SIG{TSTP} = 'IGNORE';
 367   local $SIG{PIPE} = 'IGNORE';
 368
 369   my $oldAutoCommit = $FS::UID::AutoCommit;
 370   local $FS::UID::AutoCommit = 0;
 371   my $dbh = dbh;
 372
 373   $error = $self->SUPER::insert($options{options} ? %{$options{options}} : ());
 374   if ( $error ) {
 375     $dbh->rollback if $oldAutoCommit;
 376     return $error;
 377   }
 378
 379   $self->refnum($self->cust_main->refnum) unless $self->refnum;
 380   $self->refnum( [ $self->refnum ] ) unless ref($self->refnum);
 381   $self->process_m2m( 'link_table'   => 'pkg_referral',
 382                       'target_table' => 'part_referral',
 383                       'params'       => $self->refnum,
 384                     );
 385
 386   if ( $self->discountnum ) {
 387     my $error = $self->insert_discount();
 388     if ( $error ) {
 389       $dbh->rollback if $oldAutoCommit;
 390       return $error;
 391     }
 392   }
 393
 394   my $conf = new FS::Conf;
 395
 396   if ( $conf->config('ticket_system') && $options{ticket_subject} ) {
 397
 398     #this init stuff is still inefficient, but at least its limited to
 399     # the small number (any?) folks using ticket emailing on pkg order
 400
 401     #eval '
 402     #  use lib ( "/opt/rt3/local/lib", "/opt/rt3/lib" );
 403     #  use RT;
 404     #';
 405     #die $@ if $@;
 406     #
 407     #RT::LoadConfig();
 408     #RT::Init();
 409     use FS::TicketSystem;
 410     FS::TicketSystem->init();
 411
 412     my $q = new RT::Queue($RT::SystemUser);
 413     $q->Load($options{ticket_queue}) if $options{ticket_queue};
 414     my $t = new RT::Ticket($RT::SystemUser);
 415     my $mime = new MIME::Entity;
 416     $mime->build( Type => 'text/plain', Data => $options{ticket_subject} );
 417     $t->Create( $options{ticket_queue} ? (Queue => $q) : (),
 418                 Subject => $options{ticket_subject},
 419                 MIMEObj => $mime,
 420               );
 421     $t->AddLink( Type   => 'MemberOf',
 422                  Target => 'freeside://freeside/cust_main/'. $self->custnum,
 423                );
 424   }
 425
 426   if ($conf->config('welcome_letter') && $self->cust_main->num_pkgs == 1) {
 427     my $queue = new FS::queue {
 428       'job'     => 'FS::cust_main::queueable_print',
 429     };
 430     $error = $queue->insert(
 431       'custnum'  => $self->custnum,
 432       'template' => 'welcome_letter',
 433     );
 434
 435     if ($error) {
 436       warn "can't send welcome letter: $error";
 437     }
 438
 439   }
 440
 441   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 442   '';
 443
 444 }
 445
 446 =item delete
 447
 448 This method now works but you probably shouldn't use it.
 449
 450 You don't want to delete packages, because there would then be no record
 451 the customer ever purchased the package.  Instead, see the cancel method and
 452 hide cancelled packages.
 453
 454 =cut
 455
 456 sub delete {
 457   my $self = shift;
 458
 459   local $SIG{HUP} = 'IGNORE';
 460   local $SIG{INT} = 'IGNORE';
 461   local $SIG{QUIT} = 'IGNORE';
 462   local $SIG{TERM} = 'IGNORE';
 463   local $SIG{TSTP} = 'IGNORE';
 464   local $SIG{PIPE} = 'IGNORE';
 465
 466   my $oldAutoCommit = $FS::UID::AutoCommit;
 467   local $FS::UID::AutoCommit = 0;
 468   my $dbh = dbh;
 469
 470   foreach my $cust_pkg_discount ($self->cust_pkg_discount) {
 471     my $error = $cust_pkg_discount->delete;
 472     if ( $error ) {
 473       $dbh->rollback if $oldAutoCommit;
 474       return $error;
 475     }
 476   }
 477   #cust_bill_pkg_discount?
 478
 479   foreach my $cust_pkg_detail ($self->cust_pkg_detail) {
 480     my $error = $cust_pkg_detail->delete;
 481     if ( $error ) {
 482       $dbh->rollback if $oldAutoCommit;
 483       return $error;
 484     }
 485   }
 486
 487   foreach my $cust_pkg_reason (
 488     qsearchs( {
 489                 'table' => 'cust_pkg_reason',
 490                 'hashref' => { 'pkgnum' => $self->pkgnum },
 491               }
 492             )
 493   ) {
 494     my $error = $cust_pkg_reason->delete;
 495     if ( $error ) {
 496       $dbh->rollback if $oldAutoCommit;
 497       return $error;
 498     }
 499   }
 500
 501   #pkg_referral?
 502
 503   my $error = $self->SUPER::delete(@_);
 504   if ( $error ) {
 505     $dbh->rollback if $oldAutoCommit;
 506     return $error;
 507   }
 508
 509   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 510
 511   '';
 512
 513 }
 514
 515 =item replace [ OLD_RECORD ] [ HASHREF | OPTION => VALUE ... ]
 516
 517 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 518 returns the error, otherwise returns false.
 519
 520 Currently, custnum, setup, bill, adjourn, susp, expire, and cancel may be changed.
 521
 522 Changing pkgpart may have disasterous effects.  See the order subroutine.
 523
 524 setup and bill are normally updated by calling the bill method of a customer
 525 object (see L<FS::cust_main>).
 526
 527 suspend is normally updated by the suspend and unsuspend methods.
 528
 529 cancel is normally updated by the cancel method (and also the order subroutine
 530 in some cases).
 531
 532 Available options are:
 533
 534 =over 4
 535
 536 =item reason
 537
 538 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
 539
 540 =item reason_otaker
 541
 542 the access_user (see L<FS::access_user>) providing the reason
 543
 544 =item options
 545
 546 hashref of keys and values - cust_pkg_option records will be created, updated or removed as appopriate
 547
 548 =back
 549
 550 =cut
 551
 552 sub replace {
 553   my $new = shift;
 554
 555   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 556               ? shift
 557               : $new->replace_old;
 558
 559   my $options =
 560     ( ref($_[0]) eq 'HASH' )
 561       ? shift
 562       : { @_ };
 563
 564   #return "Can't (yet?) change pkgpart!" if $old->pkgpart != $new->pkgpart;
 565   #return "Can't change otaker!" if $old->otaker ne $new->otaker;
 566
 567   #allow this *sigh*
 568   #return "Can't change setup once it exists!"
 569   #  if $old->getfield('setup') &&
 570   #     $old->getfield('setup') != $new->getfield('setup');
 571
 572   #some logic for bill, susp, cancel?
 573
 574   local($disable_agentcheck) = 1 if $old->pkgpart == $new->pkgpart;
 575
 576   local $SIG{HUP} = 'IGNORE';
 577   local $SIG{INT} = 'IGNORE';
 578   local $SIG{QUIT} = 'IGNORE';
 579   local $SIG{TERM} = 'IGNORE';
 580   local $SIG{TSTP} = 'IGNORE';
 581   local $SIG{PIPE} = 'IGNORE';
 582
 583   my $oldAutoCommit = $FS::UID::AutoCommit;
 584   local $FS::UID::AutoCommit = 0;
 585   my $dbh = dbh;
 586
 587   foreach my $method ( qw(adjourn expire) ) {  # How many reasons?
 588     if ($options->{'reason'} && $new->$method && $old->$method ne $new->$method) {
 589       my $error = $new->insert_reason(
 590         'reason'        => $options->{'reason'},
 591         'date'          => $new->$method,
 592         'action'        => $method,
 593         'reason_otaker' => $options->{'reason_otaker'},
 594       );
 595       if ( $error ) {
 596         dbh->rollback if $oldAutoCommit;
 597         return "Error inserting cust_pkg_reason: $error";
 598       }
 599     }
 600   }
 601
 602   #save off and freeze RADIUS attributes for any associated svc_acct records
 603   my @svc_acct = ();
 604   if ( $old->part_pkg->is_prepaid || $new->part_pkg->is_prepaid ) {
 605
 606                 #also check for specific exports?
 607                 # to avoid spurious modify export events
 608     @svc_acct = map  { $_->svc_x }
 609                 grep { $_->part_svc->svcdb eq 'svc_acct' }
 610                      $old->cust_svc;
 611
 612     $_->snapshot foreach @svc_acct;
 613
 614   }
 615
 616   my $error =  $new->export_pkg_change($old)
 617             || $new->SUPER::replace( $old,
 618                                      $options->{options}
 619                                        ? $options->{options}
 620                                        : ()
 621                                    );
 622   if ( $error ) {
 623     $dbh->rollback if $oldAutoCommit;
 624     return $error;
 625   }
 626
 627   #for prepaid packages,
 628   #trigger export of new RADIUS Expiration attribute when cust_pkg.bill changes
 629   foreach my $old_svc_acct ( @svc_acct ) {
 630     my $new_svc_acct = new FS::svc_acct { $old_svc_acct->hash };
 631     my $s_error =
 632       $new_svc_acct->replace( $old_svc_acct,
 633                               'depend_jobnum' => $options->{depend_jobnum},
 634                             );
 635     if ( $s_error ) {
 636       $dbh->rollback if $oldAutoCommit;
 637       return $s_error;
 638     }
 639   }
 640
 641   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 642   '';
 643
 644 }
 645
 646 =item check
 647
 648 Checks all fields to make sure this is a valid billing item.  If there is an
 649 error, returns the error, otherwise returns false.  Called by the insert and
 650 replace methods.
 651
 652 =cut
 653
 654 sub check {
 655   my $self = shift;
 656
 657   if ( !$self->locationnum or $self->locationnum == -1 ) {
 658     $self->set('locationnum', $self->cust_main->ship_locationnum);
 659   }
 660
 661   my $error =
 662     $self->ut_numbern('pkgnum')
 663     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 664     || $self->ut_numbern('pkgpart')
 665     || $self->ut_foreign_keyn('contactnum',  'contact',       'contactnum' )
 666     || $self->ut_foreign_keyn('locationnum', 'cust_location', 'locationnum')
 667     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
 668     || $self->ut_numbern('quantity')
 669     || $self->ut_numbern('start_date')
 670     || $self->ut_numbern('setup')
 671     || $self->ut_numbern('bill')
 672     || $self->ut_numbern('susp')
 673     || $self->ut_numbern('cancel')
 674     || $self->ut_numbern('adjourn')
 675     || $self->ut_numbern('resume')
 676     || $self->ut_numbern('expire')
 677     || $self->ut_numbern('dundate')
 678     || $self->ut_flag('no_auto', [ '', 'Y' ])
 679     || $self->ut_flag('waive_setup', [ '', 'Y' ])
 680     || $self->ut_flag('separate_bill')
 681     || $self->ut_textn('agent_pkgid')
 682     || $self->ut_enum('recur_show_zero', [ '', 'Y', 'N', ])
 683     || $self->ut_enum('setup_show_zero', [ '', 'Y', 'N', ])
 684     || $self->ut_foreign_keyn('main_pkgnum', 'cust_pkg', 'pkgnum')
 685     || $self->ut_foreign_keyn('pkglinknum', 'part_pkg_link', 'pkglinknum')
 686     || $self->ut_foreign_keyn('change_to_pkgnum', 'cust_pkg', 'pkgnum')
 687   ;
 688   return $error if $error;
 689
 690   return "A package with both start date (future start) and setup date (already started) will never bill"
 691     if $self->start_date && $self->setup && ! $upgrade;
 692
 693   return "A future unsuspend date can only be set for a package with a suspend date"
 694     if $self->resume and !$self->susp and !$self->adjourn;
 695
 696   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 697
 698   if ( $self->dbdef_table->column('manual_flag') ) {
 699     $self->manual_flag('') if $self->manual_flag eq ' ';
 700     $self->manual_flag =~ /^([01]?)$/
 701       or return "Illegal manual_flag ". $self->manual_flag;
 702     $self->manual_flag($1);
 703   }
 704
 705   $self->SUPER::check;
 706 }
 707
 708 =item check_pkgpart
 709
 710 Check the pkgpart to make sure it's allowed with the reg_code and/or
 711 promo_code of the package (if present) and with the customer's agent.
 712 Called from C<insert>, unless we are doing a package change that doesn't
 713 affect pkgpart.
 714
 715 =cut
 716
 717 sub check_pkgpart {
 718   my $self = shift;
 719
 720   # my $error = $self->ut_numbern('pkgpart'); # already done
 721
 722   my $error;
 723   if ( $self->reg_code ) {
 724
 725     unless ( grep { $self->pkgpart == $_->pkgpart }
 726              map  { $_->reg_code_pkg }
 727              qsearchs( 'reg_code', { 'code'     => $self->reg_code,
 728                                      'agentnum' => $self->cust_main->agentnum })
 729            ) {
 730       return "Unknown registration code";
 731     }
 732
 733   } elsif ( $self->promo_code ) {
 734
 735     my $promo_part_pkg =
 736       qsearchs('part_pkg', {
 737         'pkgpart'    => $self->pkgpart,
 738         'promo_code' => { op=>'ILIKE', value=>$self->promo_code },
 739       } );
 740     return 'Unknown promotional code' unless $promo_part_pkg;
 741
 742   } else {
 743
 744     unless ( $disable_agentcheck ) {
 745       my $agent =
 746         qsearchs( 'agent', { 'agentnum' => $self->cust_main->agentnum } );
 747       return "agent ". $agent->agentnum. ':'. $agent->agent.
 748              " can't purchase pkgpart ". $self->pkgpart
 749         unless $agent->pkgpart_hashref->{ $self->pkgpart }
 750             || $agent->agentnum == $self->part_pkg->agentnum;
 751     }
 752
 753     $error = $self->ut_foreign_key('pkgpart', 'part_pkg', 'pkgpart' );
 754     return $error if $error;
 755
 756   }
 757
 758   '';
 759
 760 }
 761
 762 =item cancel [ OPTION => VALUE ... ]
 763
 764 Cancels and removes all services (see L<FS::cust_svc> and L<FS::part_svc>)
 765 in this package, then cancels the package itself (sets the cancel field to
 766 now).
 767
 768 Available options are:
 769
 770 =over 4
 771
 772 =item quiet - can be set true to supress email cancellation notices.
 773
 774 =item time -  can be set to cancel the package based on a specific future or
 775 historical date.  Using time ensures that the remaining amount is calculated
 776 correctly.  Note however that this is an immediate cancel and just changes
 777 the date.  You are PROBABLY looking to expire the account instead of using
 778 this.
 779
 780 =item reason - can be set to a cancellation reason (see L<FS:reason>),
 781 either a reasonnum of an existing reason, or passing a hashref will create
 782 a new reason.  The hashref should have the following keys: typenum - Reason
 783 type (see L<FS::reason_type>, reason - Text of the new reason.
 784
 785 =item date - can be set to a unix style timestamp to specify when to
 786 cancel (expire)
 787
 788 =item nobill - can be set true to skip billing if it might otherwise be done.
 789
 790 =item unused_credit - can be set to 1 to credit the remaining time, or 0 to
 791 not credit it.  This must be set (by change()) when changing the package
 792 to a different pkgpart or location, and probably shouldn't be in any other
 793 case.  If it's not set, the 'unused_credit_cancel' part_pkg option will
 794 be used.
 795
 796 =item no_delay_cancel - prevents delay_cancel behavior
 797 no matter what other options say, for use when changing packages (or any
 798 other time you're really sure you want an immediate cancel)
 799
 800 =back
 801
 802 If there is an error, returns the error, otherwise returns false.
 803
 804 =cut
 805
 806 #NOT DOCUMENTING - this should only be used when calling recursively
 807 #=item delay_cancel - for internal use, to allow proper handling of
 808 #supplemental packages when the main package is flagged to suspend
 809 #before cancelling, probably shouldn't be used otherwise (set the
 810 #corresponding package option instead)
 811
 812 sub cancel {
 813   my( $self, %options ) = @_;
 814   my $error;
 815
 816   # pass all suspend/cancel actions to the main package
 817   # (unless the pkglinknum has been removed, then the link is defunct and
 818   # this package can be canceled on its own)
 819   if ( $self->main_pkgnum and $self->pkglinknum and !$options{'from_main'} ) {
 820     return $self->main_pkg->cancel(%options);
 821   }
 822
 823   my $conf = new FS::Conf;
 824
 825   warn "cust_pkg::cancel called with options".
 826        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 827     if $DEBUG;
 828
 829   local $SIG{HUP} = 'IGNORE';
 830   local $SIG{INT} = 'IGNORE';
 831   local $SIG{QUIT} = 'IGNORE';
 832   local $SIG{TERM} = 'IGNORE';
 833   local $SIG{TSTP} = 'IGNORE';
 834   local $SIG{PIPE} = 'IGNORE';
 835
 836   my $oldAutoCommit = $FS::UID::AutoCommit;
 837   local $FS::UID::AutoCommit = 0;
 838   my $dbh = dbh;
 839
 840   my $old = $self->select_for_update;
 841
 842   if ( $old->get('cancel') || $self->get('cancel') ) {
 843     dbh->rollback if $oldAutoCommit;
 844     return "";  # no error
 845   }
 846
 847   # XXX possibly set cancel_time to the expire date?
 848   my $cancel_time = $options{'time'} || time;
 849   my $date = $options{'date'} if $options{'date'}; # expire/cancel later
 850   $date = '' if ($date && $date <= $cancel_time);      # complain instead?
 851
 852   my $delay_cancel = $options{'no_delay_cancel'} ? 0 : $options{'delay_cancel'};
 853   if ( !$date && $self->part_pkg->option('delay_cancel',1)
 854        && (($self->status eq 'active') || ($self->status eq 'suspended'))
 855        && !$options{'no_delay_cancel'}
 856   ) {
 857     my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
 858     my $expsecs = 60*60*24*$expdays;
 859     my $suspfor = $self->susp ? $cancel_time - $self->susp : 0;
 860     $expsecs = $expsecs - $suspfor if $suspfor;
 861     unless ($expsecs <= 0) { #if it's already been suspended long enough, don't re-suspend
 862       $delay_cancel = 1;
 863       $date = $cancel_time + $expsecs;
 864     }
 865   }
 866
 867   #race condition: usage could be ongoing until unprovisioned
 868   #resolved by performing a change package instead (which unprovisions) and
 869   #later cancelling
 870   if ( !$options{nobill} && !$date ) {
 871     # && $conf->exists('bill_usage_on_cancel') ) { #calc_cancel checks this
 872       my $copy = $self->new({$self->hash});
 873       my $error =
 874         $copy->cust_main->bill( 'pkg_list' => [ $copy ],
 875                                 'cancel'   => 1,
 876                                 'time'     => $cancel_time );
 877       warn "Error billing during cancel, custnum ".
 878         #$self->cust_main->custnum. ": $error"
 879         ": $error"
 880         if $error;
 881   }
 882
 883   if ( $options{'reason'} ) {
 884     $error = $self->insert_reason( 'reason' => $options{'reason'},
 885                                    'action' => $date ? 'expire' : 'cancel',
 886                                    'date'   => $date ? $date : $cancel_time,
 887                                    'reason_otaker' => $options{'reason_otaker'},
 888                                  );
 889     if ( $error ) {
 890       dbh->rollback if $oldAutoCommit;
 891       return "Error inserting cust_pkg_reason: $error";
 892     }
 893   }
 894
 895   my %svc_cancel_opt = ();
 896   $svc_cancel_opt{'date'} = $date if $date;
 897   foreach my $cust_svc (
 898     #schwartz
 899     map  { $_->[0] }
 900     sort { $a->[1] <=> $b->[1] }
 901     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; }
 902     qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
 903   ) {
 904     my $part_svc = $cust_svc->part_svc;
 905     next if ( defined($part_svc) and $part_svc->preserve );
 906     my $error = $cust_svc->cancel( %svc_cancel_opt );
 907
 908     if ( $error ) {
 909       $dbh->rollback if $oldAutoCommit;
 910       return 'Error '. ($svc_cancel_opt{'date'} ? 'expiring' : 'canceling' ).
 911              " cust_svc: $error";
 912     }
 913   }
 914
 915   unless ($date) {
 916     # credit remaining time if appropriate
 917     my $do_credit;
 918     if ( exists($options{'unused_credit'}) ) {
 919       $do_credit = $options{'unused_credit'};
 920     }
 921     else {
 922       $do_credit = $self->part_pkg->option('unused_credit_cancel', 1);
 923     }
 924     if ( $do_credit ) {
 925       my $error = $self->credit_remaining('cancel', $cancel_time);
 926       if ($error) {
 927         $dbh->rollback if $oldAutoCommit;
 928         return $error;
 929       }
 930     }
 931   } #unless $date
 932
 933   my %hash = $self->hash;
 934   if ( $date ) {
 935     $hash{'expire'} = $date;
 936     if ($delay_cancel) {
 937       # just to be sure these are clear
 938       $hash{'adjourn'} = undef;
 939       $hash{'resume'} = undef;
 940     }
 941   } else {
 942     $hash{'cancel'} = $cancel_time;
 943   }
 944   $hash{'change_custnum'} = $options{'change_custnum'};
 945
 946   # if this is a supplemental package that's lost its part_pkg_link, and it's
 947   # being canceled for real, unlink it completely
 948   if ( !$date and ! $self->pkglinknum ) {
 949     $hash{main_pkgnum} = '';
 950   }
 951
 952   my $new = new FS::cust_pkg ( \%hash );
 953   $error = $new->replace( $self, options => { $self->options } );
 954   if ( $self->change_to_pkgnum ) {
 955     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
 956     $error ||= $change_to->cancel('no_delay_cancel' => 1) || $change_to->delete;
 957   }
 958   if ( $error ) {
 959     $dbh->rollback if $oldAutoCommit;
 960     return $error;
 961   }
 962
 963   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
 964     $error = $supp_pkg->cancel(%options,
 965       'from_main' => 1,
 966       'date' => $date, #in case it got changed by delay_cancel
 967       'delay_cancel' => $delay_cancel,
 968     );
 969     if ( $error ) {
 970       $dbh->rollback if $oldAutoCommit;
 971       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
 972     }
 973   }
 974
 975   if ($delay_cancel && !$options{'from_main'}) {
 976     $error = $new->suspend(
 977       'from_cancel' => 1,
 978       'time'        => $cancel_time
 979     );
 980   }
 981
 982   unless ($date) {
 983     foreach my $usage ( $self->cust_pkg_usage ) {
 984       $error = $usage->delete;
 985       if ( $error ) {
 986         $dbh->rollback if $oldAutoCommit;
 987         return "deleting usage pools: $error";
 988       }
 989     }
 990   }
 991
 992   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 993   return '' if $date; #no errors
 994
 995   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ } $self->cust_main->invoicing_list;
 996   if ( !$options{'quiet'} &&
 997         $conf->exists('emailcancel', $self->cust_main->agentnum) &&
 998         @invoicing_list ) {
 999     my $msgnum = $conf->config('cancel_msgnum', $self->cust_main->agentnum);
1000     my $error = '';
1001     if ( $msgnum ) {
1002       my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
1003       $error = $msg_template->send( 'cust_main' => $self->cust_main,
1004                                     'object'    => $self );
1005     }
1006     else {
1007       $error = send_email(
1008         'from'    => $conf->invoice_from_full( $self->cust_main->agentnum ),
1009         'to'      => \@invoicing_list,
1010         'subject' => ( $conf->config('cancelsubject') || 'Cancellation Notice' ),
1011         'body'    => [ map "$_\n", $conf->config('cancelmessage') ],
1012         'custnum' => $self->custnum,
1013         'msgtype' => '', #admin?
1014       );
1015     }
1016     #should this do something on errors?
1017   }
1018
1019   ''; #no errors
1020
1021 }
1022
1023 =item cancel_if_expired [ NOW_TIMESTAMP ]
1024
1025 Cancels this package if its expire date has been reached.
1026
1027 =cut
1028
1029 sub cancel_if_expired {
1030   my $self = shift;
1031   my $time = shift || time;
1032   return '' unless $self->expire && $self->expire <= $time;
1033   my $error = $self->cancel;
1034   if ( $error ) {
1035     return "Error cancelling expired pkg ". $self->pkgnum. " for custnum ".
1036            $self->custnum. ": $error";
1037   }
1038   '';
1039 }
1040
1041 =item uncancel
1042
1043 "Un-cancels" this package: Orders a new package with the same custnum, pkgpart,
1044 locationnum, (other fields?).  Attempts to re-provision cancelled services
1045 using history information (errors at this stage are not fatal).
1046
1047 cust_pkg: pass a scalar reference, will be filled in with the new cust_pkg object
1048
1049 svc_fatal: service provisioning errors are fatal
1050
1051 svc_errors: pass an array reference, will be filled in with any provisioning errors
1052
1053 main_pkgnum: link the package as a supplemental package of this one.  For
1054 internal use only.
1055
1056 =cut
1057
1058 sub uncancel {
1059   my( $self, %options ) = @_;
1060
1061   #in case you try do do $uncancel-date = $cust_pkg->uncacel
1062   return '' unless $self->get('cancel');
1063
1064   if ( $self->main_pkgnum and !$options{'main_pkgnum'} ) {
1065     return $self->main_pkg->uncancel(%options);
1066   }
1067
1068   ##
1069   # Transaction-alize
1070   ##
1071
1072   local $SIG{HUP} = 'IGNORE';
1073   local $SIG{INT} = 'IGNORE';
1074   local $SIG{QUIT} = 'IGNORE';
1075   local $SIG{TERM} = 'IGNORE';
1076   local $SIG{TSTP} = 'IGNORE';
1077   local $SIG{PIPE} = 'IGNORE';
1078
1079   my $oldAutoCommit = $FS::UID::AutoCommit;
1080   local $FS::UID::AutoCommit = 0;
1081   my $dbh = dbh;
1082
1083   ##
1084   # insert the new package
1085   ##
1086
1087   my $cust_pkg = new FS::cust_pkg {
1088     last_bill       => ( $options{'last_bill'} || $self->get('last_bill') ),
1089     bill            => ( $options{'bill'}      || $self->get('bill')      ),
1090     uncancel        => time,
1091     uncancel_pkgnum => $self->pkgnum,
1092     main_pkgnum     => ($options{'main_pkgnum'} || ''),
1093     map { $_ => $self->get($_) } qw(
1094       custnum pkgpart locationnum
1095       setup
1096       susp adjourn resume expire start_date contract_end dundate
1097       change_date change_pkgpart change_locationnum
1098       manual_flag no_auto separate_bill quantity agent_pkgid
1099       recur_show_zero setup_show_zero
1100     ),
1101   };
1102
1103   my $error = $cust_pkg->insert(
1104     'change' => 1, #supresses any referral credit to a referring customer
1105     'allow_pkgpart' => 1, # allow this even if the package def is disabled
1106   );
1107   if ($error) {
1108     $dbh->rollback if $oldAutoCommit;
1109     return $error;
1110   }
1111
1112   ##
1113   # insert services
1114   ##
1115
1116   #find historical services within this timeframe before the package cancel
1117   # (incompatible with "time" option to cust_pkg->cancel?)
1118   my $fuzz = 2 * 60; #2 minutes?  too much?   (might catch separate unprovision)
1119                      #            too little? (unprovisioing export delay?)
1120   my($end, $start) = ( $self->get('cancel'), $self->get('cancel') - $fuzz );
1121   my @h_cust_svc = $self->h_cust_svc( $end, $start );
1122
1123   my @svc_errors;
1124   foreach my $h_cust_svc (@h_cust_svc) {
1125     my $h_svc_x = $h_cust_svc->h_svc_x( $end, $start );
1126     #next unless $h_svc_x; #should this happen?
1127     (my $table = $h_svc_x->table) =~ s/^h_//;
1128     require "FS/$table.pm";
1129     my $class = "FS::$table";
1130     my $svc_x = $class->new( {
1131       'pkgnum'  => $cust_pkg->pkgnum,
1132       'svcpart' => $h_cust_svc->svcpart,
1133       map { $_ => $h_svc_x->get($_) } fields($table)
1134     } );
1135
1136     # radius_usergroup
1137     if ( $h_svc_x->isa('FS::h_svc_Radius_Mixin') ) {
1138       $svc_x->usergroup( [ $h_svc_x->h_usergroup($end, $start) ] );
1139     }
1140
1141     my $svc_error = $svc_x->insert;
1142     if ( $svc_error ) {
1143       if ( $options{svc_fatal} ) {
1144         $dbh->rollback if $oldAutoCommit;
1145         return $svc_error;
1146       } else {
1147         # if we've failed to insert the svc_x object, svc_Common->insert
1148         # will have removed the cust_svc already.  if not, then both records
1149         # were inserted but we failed for some other reason (export, most
1150         # likely).  in that case, report the error and delete the records.
1151         push @svc_errors, $svc_error;
1152         my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $svc_x->svcnum });
1153         if ( $cust_svc ) {
1154           # except if export_insert failed, export_delete probably won't be
1155           # much better
1156           local $FS::svc_Common::noexport_hack = 1;
1157           my $cleanup_error = $svc_x->delete; # also deletes cust_svc
1158           if ( $cleanup_error ) { # and if THAT fails, then run away
1159             $dbh->rollback if $oldAutoCommit;
1160             return $cleanup_error;
1161           }
1162         }
1163       } # svc_fatal
1164     } # svc_error
1165   } #foreach $h_cust_svc
1166
1167   #these are pretty rare, but should handle them
1168   # - dsl_device (mac addresses)
1169   # - phone_device (mac addresses)
1170   # - dsl_note (ikano notes)
1171   # - domain_record (i.e. restore DNS information w/domains)
1172   # - inventory_item(?) (inventory w/un-cancelling service?)
1173   # - nas (svc_broaband nas stuff)
1174   #this stuff is unused in the wild afaik
1175   # - mailinglistmember
1176   # - router.svcnum?
1177   # - svc_domain.parent_svcnum?
1178   # - acct_snarf (ancient mail fetching config)
1179   # - cgp_rule (communigate)
1180   # - cust_svc_option (used by our Tron stuff)
1181   # - acct_rt_transaction (used by our time worked stuff)
1182
1183   ##
1184   # also move over any services that didn't unprovision at cancellation
1185   ##
1186
1187   foreach my $cust_svc ( qsearch('cust_svc', { pkgnum => $self->pkgnum } ) ) {
1188     $cust_svc->pkgnum( $cust_pkg->pkgnum );
1189     my $error = $cust_svc->replace;
1190     if ( $error ) {
1191       $dbh->rollback if $oldAutoCommit;
1192       return $error;
1193     }
1194   }
1195
1196   ##
1197   # Uncancel any supplemental packages, and make them supplemental to the
1198   # new one.
1199   ##
1200
1201   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1202     my $new_pkg;
1203     $error = $supp_pkg->uncancel(%options, 'main_pkgnum' => $cust_pkg->pkgnum);
1204     if ( $error ) {
1205       $dbh->rollback if $oldAutoCommit;
1206       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1207     }
1208   }
1209
1210   ##
1211   # Finish
1212   ##
1213
1214   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1215
1216   ${ $options{cust_pkg} }   = $cust_pkg   if ref($options{cust_pkg});
1217   @{ $options{svc_errors} } = @svc_errors if ref($options{svc_errors});
1218
1219   '';
1220 }
1221
1222 =item unexpire
1223
1224 Cancels any pending expiration (sets the expire field to null).
1225
1226 If there is an error, returns the error, otherwise returns false.
1227
1228 =cut
1229
1230 sub unexpire {
1231   my( $self, %options ) = @_;
1232   my $error;
1233
1234   local $SIG{HUP} = 'IGNORE';
1235   local $SIG{INT} = 'IGNORE';
1236   local $SIG{QUIT} = 'IGNORE';
1237   local $SIG{TERM} = 'IGNORE';
1238   local $SIG{TSTP} = 'IGNORE';
1239   local $SIG{PIPE} = 'IGNORE';
1240
1241   my $oldAutoCommit = $FS::UID::AutoCommit;
1242   local $FS::UID::AutoCommit = 0;
1243   my $dbh = dbh;
1244
1245   my $old = $self->select_for_update;
1246
1247   my $pkgnum = $old->pkgnum;
1248   if ( $old->get('cancel') || $self->get('cancel') ) {
1249     dbh->rollback if $oldAutoCommit;
1250     return "Can't unexpire cancelled package $pkgnum";
1251     # or at least it's pointless
1252   }
1253
1254   unless ( $old->get('expire') && $self->get('expire') ) {
1255     dbh->rollback if $oldAutoCommit;
1256     return "";  # no error
1257   }
1258
1259   my %hash = $self->hash;
1260   $hash{'expire'} = '';
1261   my $new = new FS::cust_pkg ( \%hash );
1262   $error = $new->replace( $self, options => { $self->options } );
1263   if ( $error ) {
1264     $dbh->rollback if $oldAutoCommit;
1265     return $error;
1266   }
1267
1268   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1269
1270   ''; #no errors
1271
1272 }
1273
1274 =item suspend [ OPTION => VALUE ... ]
1275
1276 Suspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1277 package, then suspends the package itself (sets the susp field to now).
1278
1279 Available options are:
1280
1281 =over 4
1282
1283 =item reason - can be set to a cancellation reason (see L<FS:reason>),
1284 either a reasonnum of an existing reason, or passing a hashref will create
1285 a new reason.  The hashref should have the following keys:
1286 - typenum - Reason type (see L<FS::reason_type>
1287 - reason - Text of the new reason.
1288
1289 =item date - can be set to a unix style timestamp to specify when to
1290 suspend (adjourn)
1291
1292 =item time - can be set to override the current time, for calculation
1293 of final invoices or unused-time credits
1294
1295 =item resume_date - can be set to a time when the package should be
1296 unsuspended.  This may be more convenient than calling C<unsuspend()>
1297 separately.
1298
1299 =item from_main - allows a supplemental package to be suspended, rather
1300 than redirecting the method call to its main package.  For internal use.
1301
1302 =item from_cancel - used when suspending from the cancel method, forces
1303 this to skip everything besides basic suspension.  For internal use.
1304
1305 =back
1306
1307 If there is an error, returns the error, otherwise returns false.
1308
1309 =cut
1310
1311 sub suspend {
1312   my( $self, %options ) = @_;
1313   my $error;
1314
1315   # pass all suspend/cancel actions to the main package
1316   if ( $self->main_pkgnum and !$options{'from_main'} ) {
1317     return $self->main_pkg->suspend(%options);
1318   }
1319
1320   local $SIG{HUP} = 'IGNORE';
1321   local $SIG{INT} = 'IGNORE';
1322   local $SIG{QUIT} = 'IGNORE';
1323   local $SIG{TERM} = 'IGNORE';
1324   local $SIG{TSTP} = 'IGNORE';
1325   local $SIG{PIPE} = 'IGNORE';
1326
1327   my $oldAutoCommit = $FS::UID::AutoCommit;
1328   local $FS::UID::AutoCommit = 0;
1329   my $dbh = dbh;
1330
1331   my $old = $self->select_for_update;
1332
1333   my $pkgnum = $old->pkgnum;
1334   if ( $old->get('cancel') || $self->get('cancel') ) {
1335     dbh->rollback if $oldAutoCommit;
1336     return "Can't suspend cancelled package $pkgnum";
1337   }
1338
1339   if ( $old->get('susp') || $self->get('susp') ) {
1340     dbh->rollback if $oldAutoCommit;
1341     return "";  # no error                     # complain on adjourn?
1342   }
1343
1344   my $suspend_time = $options{'time'} || time;
1345   my $date = $options{date} if $options{date}; # adjourn/suspend later
1346   $date = '' if ($date && $date <= $suspend_time); # complain instead?
1347
1348   if ( $date && $old->get('expire') && $old->get('expire') < $date ) {
1349     dbh->rollback if $oldAutoCommit;
1350     return "Package $pkgnum expires before it would be suspended.";
1351   }
1352
1353   # some false laziness with sub cancel
1354   if ( !$options{nobill} && !$date && !$options{'from_cancel'} &&
1355        $self->part_pkg->option('bill_suspend_as_cancel',1) ) {
1356     # kind of a kludge--'bill_suspend_as_cancel' to avoid having to
1357     # make the entire cust_main->bill path recognize 'suspend' and
1358     # 'cancel' separately.
1359     warn "Billing $pkgnum on suspension (at $suspend_time)\n" if $DEBUG;
1360     my $copy = $self->new({$self->hash});
1361     my $error =
1362       $copy->cust_main->bill( 'pkg_list' => [ $copy ],
1363                               'cancel'   => 1,
1364                               'time'     => $suspend_time );
1365     warn "Error billing during suspend, custnum ".
1366       #$self->cust_main->custnum. ": $error"
1367       ": $error"
1368       if $error;
1369   }
1370
1371   my $cust_pkg_reason;
1372   if ( $options{'reason'} ) {
1373     $error = $self->insert_reason( 'reason' => $options{'reason'},
1374                                    'action' => $date ? 'adjourn' : 'suspend',
1375                                    'date'   => $date ? $date : $suspend_time,
1376                                    'reason_otaker' => $options{'reason_otaker'},
1377                                  );
1378     if ( $error ) {
1379       dbh->rollback if $oldAutoCommit;
1380       return "Error inserting cust_pkg_reason: $error";
1381     }
1382     $cust_pkg_reason = qsearchs('cust_pkg_reason', {
1383         'date'    => $date ? $date : $suspend_time,
1384         'action'  => $date ? 'A' : 'S',
1385         'pkgnum'  => $self->pkgnum,
1386     });
1387   }
1388
1389   # if a reasonnum was passed, get the actual reason object so we can check
1390   # unused_credit
1391   # (passing a reason hashref is still allowed, but it can't be used with
1392   # the fancy behavioral options.)
1393
1394   my $reason;
1395   if ($options{'reason'} =~ /^\d+$/) {
1396     $reason = FS::reason->by_key($options{'reason'});
1397   }
1398
1399   my %hash = $self->hash;
1400   if ( $date ) {
1401     $hash{'adjourn'} = $date;
1402   } else {
1403     $hash{'susp'} = $suspend_time;
1404   }
1405
1406   my $resume_date = $options{'resume_date'} || 0;
1407   if ( $resume_date > ($date || $suspend_time) ) {
1408     $hash{'resume'} = $resume_date;
1409   }
1410
1411   $options{options} ||= {};
1412
1413   my $new = new FS::cust_pkg ( \%hash );
1414   $error = $new->replace( $self, options => { $self->options,
1415                                               %{ $options{options} },
1416                                             }
1417                         );
1418   if ( $error ) {
1419     $dbh->rollback if $oldAutoCommit;
1420     return $error;
1421   }
1422
1423   unless ( $date ) { # then we are suspending now
1424
1425     unless ($options{'from_cancel'}) {
1426       # credit remaining time if appropriate
1427       # (if required by the package def, or the suspend reason)
1428       my $unused_credit = $self->part_pkg->option('unused_credit_suspend',1)
1429                           || ( defined($reason) && $reason->unused_credit );
1430
1431       if ( $unused_credit ) {
1432         warn "crediting unused time on pkg#".$self->pkgnum."\n" if $DEBUG;
1433         my $error = $self->credit_remaining('suspend', $suspend_time);
1434         if ($error) {
1435           $dbh->rollback if $oldAutoCommit;
1436           return $error;
1437         }
1438       }
1439     }
1440
1441     my @labels = ();
1442
1443     foreach my $cust_svc (
1444       qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
1445     ) {
1446       my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1447
1448       $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1449         $dbh->rollback if $oldAutoCommit;
1450         return "Illegal svcdb value in part_svc!";
1451       };
1452       my $svcdb = $1;
1453       require "FS/$svcdb.pm";
1454
1455       my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1456       if ($svc) {
1457         $error = $svc->suspend;
1458         if ( $error ) {
1459           $dbh->rollback if $oldAutoCommit;
1460           return $error;
1461         }
1462         my( $label, $value ) = $cust_svc->label;
1463         push @labels, "$label: $value";
1464       }
1465     }
1466
1467     # suspension fees: if there is a feepart, and it's not an unsuspend fee,
1468     # and this is not a suspend-before-cancel
1469     if ( $cust_pkg_reason ) {
1470       my $reason_obj = $cust_pkg_reason->reason;
1471       if ( $reason_obj->feepart and
1472            ! $reason_obj->fee_on_unsuspend and
1473            ! $options{'from_cancel'} ) {
1474
1475         # register the need to charge a fee, cust_main->bill will do the rest
1476         warn "registering suspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1477           if $DEBUG;
1478         my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1479             'pkgreasonnum'  => $cust_pkg_reason->num,
1480             'pkgnum'        => $self->pkgnum,
1481             'feepart'       => $reason->feepart,
1482             'nextbill'      => $reason->fee_hold,
1483         });
1484         $error ||= $cust_pkg_reason_fee->insert;
1485       }
1486     }
1487
1488     my $conf = new FS::Conf;
1489     if ( $conf->config('suspend_email_admin') && !$options{'from_cancel'} ) {
1490
1491       my $error = send_email(
1492         'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1493                                    #invoice_from ??? well as good as any
1494         'to'      => $conf->config('suspend_email_admin'),
1495         'subject' => 'FREESIDE NOTIFICATION: Customer package suspended',
1496         'body'    => [
1497           "This is an automatic message from your Freeside installation\n",
1498           "informing you that the following customer package has been suspended:\n",
1499           "\n",
1500           'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1501           'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1502           ( map { "Service : $_\n" } @labels ),
1503         ],
1504         'custnum' => $self->custnum,
1505         'msgtype' => 'admin'
1506       );
1507
1508       if ( $error ) {
1509         warn "WARNING: can't send suspension admin email (suspending anyway): ".
1510              "$error\n";
1511       }
1512
1513     }
1514
1515   }
1516
1517   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1518     $error = $supp_pkg->suspend(%options, 'from_main' => 1);
1519     if ( $error ) {
1520       $dbh->rollback if $oldAutoCommit;
1521       return "suspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1522     }
1523   }
1524
1525   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1526
1527   ''; #no errors
1528 }
1529
1530 =item credit_remaining MODE TIME
1531
1532 Generate a credit for this package for the time remaining in the current
1533 billing period.  MODE is either "suspend" or "cancel" (determines the
1534 credit type).  TIME is the time of suspension/cancellation.  Both arguments
1535 are mandatory.
1536
1537 =cut
1538
1539 # Implementation note:
1540 #
1541 # If you pkgpart-change a package that has been billed, and it's set to give
1542 # credit on package change, then this method gets called and then the new
1543 # package will have no last_bill date. Therefore the customer will be credited
1544 # only once (per billing period) even if there are multiple package changes.
1545 #
1546 # If you location-change a package that has been billed, this method will NOT
1547 # be called and the new package WILL have the last bill date of the old
1548 # package.
1549 #
1550 # If the new package is then canceled within the same billing cycle,
1551 # credit_remaining needs to run calc_remain on the OLD package to determine
1552 # the amount of unused time to credit.
1553
1554 sub credit_remaining {
1555   # Add a credit for remaining service
1556   my ($self, $mode, $time) = @_;
1557   die 'credit_remaining requires suspend or cancel'
1558     unless $mode eq 'suspend' or $mode eq 'cancel';
1559   die 'no suspend/cancel time' unless $time > 0;
1560
1561   my $conf = FS::Conf->new;
1562   my $reason_type = $conf->config($mode.'_credit_type');
1563
1564   my $last_bill = $self->getfield('last_bill') || 0;
1565   my $next_bill = $self->getfield('bill') || 0;
1566   if ( $last_bill > 0         # the package has been billed
1567       and $next_bill > 0      # the package has a next bill date
1568       and $next_bill >= $time # which is in the future
1569   ) {
1570     my $remaining_value = 0;
1571
1572     my $remain_pkg = $self;
1573     $remaining_value = $remain_pkg->calc_remain('time' => $time);
1574
1575     # we may have to walk back past some package changes to get to the
1576     # one that actually has unused time
1577     while ( $remaining_value == 0 ) {
1578       if ( $remain_pkg->change_pkgnum ) {
1579         $remain_pkg = FS::cust_pkg->by_key($remain_pkg->change_pkgnum);
1580       } else {
1581         # the package has really never been billed
1582         return;
1583       }
1584       $remaining_value = $remain_pkg->calc_remain('time' => $time);
1585     }
1586
1587     if ( $remaining_value > 0 ) {
1588       warn "Crediting for $remaining_value on package ".$self->pkgnum."\n"
1589         if $DEBUG;
1590       my $error = $self->cust_main->credit(
1591         $remaining_value,
1592         'Credit for unused time on '. $self->part_pkg->pkg,
1593         'reason_type' => $reason_type,
1594       );
1595       return "Error crediting customer \$$remaining_value for unused time".
1596         " on ". $self->part_pkg->pkg. ": $error"
1597         if $error;
1598     } #if $remaining_value
1599   } #if $last_bill, etc.
1600   '';
1601 }
1602
1603 =item unsuspend [ OPTION => VALUE ... ]
1604
1605 Unsuspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1606 package, then unsuspends the package itself (clears the susp field and the
1607 adjourn field if it is in the past).  If the suspend reason includes an
1608 unsuspension package, that package will be ordered.
1609
1610 Available options are:
1611
1612 =over 4
1613
1614 =item date
1615
1616 Can be set to a date to unsuspend the package in the future (the 'resume'
1617 field).
1618
1619 =item adjust_next_bill
1620
1621 Can be set true to adjust the next bill date forward by
1622 the amount of time the account was inactive.  This was set true by default
1623 in the past (from 1.4.2 and 1.5.0pre6 through 1.7.0), but now needs to be
1624 explicitly requested with this option or in the price plan.
1625
1626 =back
1627
1628 If there is an error, returns the error, otherwise returns false.
1629
1630 =cut
1631
1632 sub unsuspend {
1633   my( $self, %opt ) = @_;
1634   my $error;
1635
1636   # pass all suspend/cancel actions to the main package
1637   if ( $self->main_pkgnum and !$opt{'from_main'} ) {
1638     return $self->main_pkg->unsuspend(%opt);
1639   }
1640
1641   local $SIG{HUP} = 'IGNORE';
1642   local $SIG{INT} = 'IGNORE';
1643   local $SIG{QUIT} = 'IGNORE';
1644   local $SIG{TERM} = 'IGNORE';
1645   local $SIG{TSTP} = 'IGNORE';
1646   local $SIG{PIPE} = 'IGNORE';
1647
1648   my $oldAutoCommit = $FS::UID::AutoCommit;
1649   local $FS::UID::AutoCommit = 0;
1650   my $dbh = dbh;
1651
1652   my $old = $self->select_for_update;
1653
1654   my $pkgnum = $old->pkgnum;
1655   if ( $old->get('cancel') || $self->get('cancel') ) {
1656     $dbh->rollback if $oldAutoCommit;
1657     return "Can't unsuspend cancelled package $pkgnum";
1658   }
1659
1660   unless ( $old->get('susp') && $self->get('susp') ) {
1661     $dbh->rollback if $oldAutoCommit;
1662     return "";  # no error                     # complain instead?
1663   }
1664
1665   # handle the case of setting a future unsuspend (resume) date
1666   # and do not continue to actually unsuspend the package
1667   my $date = $opt{'date'};
1668   if ( $date and $date > time ) { # return an error if $date <= time?
1669
1670     if ( $old->get('expire') && $old->get('expire') < $date ) {
1671       $dbh->rollback if $oldAutoCommit;
1672       return "Package $pkgnum expires before it would be unsuspended.";
1673     }
1674
1675     my $new = new FS::cust_pkg { $self->hash };
1676     $new->set('resume', $date);
1677     $error = $new->replace($self, options => $self->options);
1678
1679     if ( $error ) {
1680       $dbh->rollback if $oldAutoCommit;
1681       return $error;
1682     }
1683     else {
1684       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1685       return '';
1686     }
1687
1688   } #if $date
1689
1690   if (!$self->setup) {
1691     # then this package is being released from on-hold status
1692     $self->set_initial_timers;
1693   }
1694
1695   my @labels = ();
1696
1697   foreach my $cust_svc (
1698     qsearch('cust_svc',{'pkgnum'=> $self->pkgnum } )
1699   ) {
1700     my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1701
1702     $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1703       $dbh->rollback if $oldAutoCommit;
1704       return "Illegal svcdb value in part_svc!";
1705     };
1706     my $svcdb = $1;
1707     require "FS/$svcdb.pm";
1708
1709     my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1710     if ($svc) {
1711       $error = $svc->unsuspend;
1712       if ( $error ) {
1713         $dbh->rollback if $oldAutoCommit;
1714         return $error;
1715       }
1716       my( $label, $value ) = $cust_svc->label;
1717       push @labels, "$label: $value";
1718     }
1719
1720   }
1721
1722   my $cust_pkg_reason = $self->last_cust_pkg_reason('susp');
1723   my $reason = $cust_pkg_reason ? $cust_pkg_reason->reason : '';
1724
1725   my %hash = $self->hash;
1726   my $inactive = time - $hash{'susp'};
1727
1728   my $conf = new FS::Conf;
1729
1730   # increment next bill date if certain conditions are met:
1731   # - it was due to be billed at some point
1732   # - either the global or local config says to do this
1733   my $adjust_bill = 0;
1734   if (
1735        $inactive > 0
1736     && ( $hash{'bill'} || $hash{'setup'} )
1737     && (    $opt{'adjust_next_bill'}
1738          || $conf->exists('unsuspend-always_adjust_next_bill_date')
1739          || $self->part_pkg->option('unsuspend_adjust_bill', 1)
1740        )
1741   ) {
1742     $adjust_bill = 1;
1743   }
1744
1745   # but not if:
1746   # - the package billed during suspension
1747   # - or it was ordered on hold
1748   # - or the customer was credited for the unused time
1749
1750   if ( $self->option('suspend_bill',1)
1751       or ( $self->part_pkg->option('suspend_bill',1)
1752            and ! $self->option('no_suspend_bill',1)
1753          )
1754       or $hash{'order_date'} == $hash{'susp'}
1755   ) {
1756     $adjust_bill = 0;
1757   }
1758
1759   if ( $adjust_bill ) {
1760     if (    $self->part_pkg->option('unused_credit_suspend')
1761          or ( $reason and $reason->unused_credit ) ) {
1762       # then the customer was credited for the unused time before suspending,
1763       # so their next bill should be immediate.
1764       $hash{'bill'} = time;
1765     } else {
1766       # add the length of time suspended to the bill date
1767       $hash{'bill'} = ( $hash{'bill'} || $hash{'setup'} ) + $inactive;
1768     }
1769   }
1770
1771   $hash{'susp'} = '';
1772   $hash{'adjourn'} = '' if $hash{'adjourn'} and $hash{'adjourn'} < time;
1773   $hash{'resume'} = '' if !$hash{'adjourn'};
1774   my $new = new FS::cust_pkg ( \%hash );
1775   $error = $new->replace( $self, options => { $self->options } );
1776   if ( $error ) {
1777     $dbh->rollback if $oldAutoCommit;
1778     return $error;
1779   }
1780
1781   my $unsusp_pkg;
1782
1783   if ( $reason ) {
1784     if ( $reason->unsuspend_pkgpart ) {
1785       #warn "Suspend reason '".$reason->reason."' uses deprecated unsuspend_pkgpart feature.\n"; # in 4.x
1786       my $part_pkg = FS::part_pkg->by_key($reason->unsuspend_pkgpart)
1787         or $error = "Unsuspend package definition ".$reason->unsuspend_pkgpart.
1788                     " not found.";
1789       my $start_date = $self->cust_main->next_bill_date
1790         if $reason->unsuspend_hold;
1791
1792       if ( $part_pkg ) {
1793         $unsusp_pkg = FS::cust_pkg->new({
1794             'custnum'     => $self->custnum,
1795             'pkgpart'     => $reason->unsuspend_pkgpart,
1796             'start_date'  => $start_date,
1797             'locationnum' => $self->locationnum,
1798             # discount? probably not...
1799         });
1800
1801         $error ||= $self->cust_main->order_pkg( 'cust_pkg' => $unsusp_pkg );
1802       }
1803     }
1804     # new way, using fees
1805     if ( $reason->feepart and $reason->fee_on_unsuspend ) {
1806       # register the need to charge a fee, cust_main->bill will do the rest
1807       warn "registering unsuspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1808         if $DEBUG;
1809       my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1810           'pkgreasonnum'  => $cust_pkg_reason->num,
1811           'pkgnum'        => $self->pkgnum,
1812           'feepart'       => $reason->feepart,
1813           'nextbill'      => $reason->fee_hold,
1814       });
1815       $error ||= $cust_pkg_reason_fee->insert;
1816     }
1817
1818     if ( $error ) {
1819       $dbh->rollback if $oldAutoCommit;
1820       return $error;
1821     }
1822   }
1823
1824   if ( $conf->config('unsuspend_email_admin') ) {
1825
1826     my $error = send_email(
1827       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1828                                  #invoice_from ??? well as good as any
1829       'to'      => $conf->config('unsuspend_email_admin'),
1830       'subject' => 'FREESIDE NOTIFICATION: Customer package unsuspended',       'body'    => [
1831         "This is an automatic message from your Freeside installation\n",
1832         "informing you that the following customer package has been unsuspended:\n",
1833         "\n",
1834         'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1835         'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1836         ( map { "Service : $_\n" } @labels ),
1837         ($unsusp_pkg ?
1838           "An unsuspension fee was charged: ".
1839             $unsusp_pkg->part_pkg->pkg_comment."\n"
1840           : ''
1841         ),
1842       ],
1843       'custnum' => $self->custnum,
1844       'msgtype' => 'admin',
1845     );
1846
1847     if ( $error ) {
1848       warn "WARNING: can't send unsuspension admin email (unsuspending anyway): ".
1849            "$error\n";
1850     }
1851
1852   }
1853
1854   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1855     $error = $supp_pkg->unsuspend(%opt, 'from_main' => 1);
1856     if ( $error ) {
1857       $dbh->rollback if $oldAutoCommit;
1858       return "unsuspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1859     }
1860   }
1861
1862   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1863
1864   ''; #no errors
1865 }
1866
1867 =item unadjourn
1868
1869 Cancels any pending suspension (sets the adjourn field to null).
1870
1871 If there is an error, returns the error, otherwise returns false.
1872
1873 =cut
1874
1875 sub unadjourn {
1876   my( $self, %options ) = @_;
1877   my $error;
1878
1879   local $SIG{HUP} = 'IGNORE';
1880   local $SIG{INT} = 'IGNORE';
1881   local $SIG{QUIT} = 'IGNORE';
1882   local $SIG{TERM} = 'IGNORE';
1883   local $SIG{TSTP} = 'IGNORE';
1884   local $SIG{PIPE} = 'IGNORE';
1885
1886   my $oldAutoCommit = $FS::UID::AutoCommit;
1887   local $FS::UID::AutoCommit = 0;
1888   my $dbh = dbh;
1889
1890   my $old = $self->select_for_update;
1891
1892   my $pkgnum = $old->pkgnum;
1893   if ( $old->get('cancel') || $self->get('cancel') ) {
1894     dbh->rollback if $oldAutoCommit;
1895     return "Can't unadjourn cancelled package $pkgnum";
1896     # or at least it's pointless
1897   }
1898
1899   if ( $old->get('susp') || $self->get('susp') ) {
1900     dbh->rollback if $oldAutoCommit;
1901     return "Can't unadjourn suspended package $pkgnum";
1902     # perhaps this is arbitrary
1903   }
1904
1905   unless ( $old->get('adjourn') && $self->get('adjourn') ) {
1906     dbh->rollback if $oldAutoCommit;
1907     return "";  # no error
1908   }
1909
1910   my %hash = $self->hash;
1911   $hash{'adjourn'} = '';
1912   $hash{'resume'}  = '';
1913   my $new = new FS::cust_pkg ( \%hash );
1914   $error = $new->replace( $self, options => { $self->options } );
1915   if ( $error ) {
1916     $dbh->rollback if $oldAutoCommit;
1917     return $error;
1918   }
1919
1920   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1921
1922   ''; #no errors
1923
1924 }
1925
1926
1927 =item change HASHREF | OPTION => VALUE ...
1928
1929 Changes this package: cancels it and creates a new one, with a different
1930 pkgpart or locationnum or both.  All services are transferred to the new
1931 package (no change will be made if this is not possible).
1932
1933 Options may be passed as a list of key/value pairs or as a hash reference.
1934 Options are:
1935
1936 =over 4
1937
1938 =item locationnum
1939
1940 New locationnum, to change the location for this package.
1941
1942 =item cust_location
1943
1944 New FS::cust_location object, to create a new location and assign it
1945 to this package.
1946
1947 =item cust_main
1948
1949 New FS::cust_main object, to create a new customer and assign the new package
1950 to it.
1951
1952 =item pkgpart
1953
1954 New pkgpart (see L<FS::part_pkg>).
1955
1956 =item refnum
1957
1958 New refnum (see L<FS::part_referral>).
1959
1960 =item quantity
1961
1962 New quantity; if unspecified, the new package will have the same quantity
1963 as the old.
1964
1965 =item cust_pkg
1966
1967 "New" (existing) FS::cust_pkg object.  The package's services and other
1968 attributes will be transferred to this package.
1969
1970 =item keep_dates
1971
1972 Set to true to transfer billing dates (start_date, setup, last_bill, bill,
1973 susp, adjourn, cancel, expire, and contract_end) to the new package.
1974
1975 =item unprotect_svcs
1976
1977 Normally, change() will rollback and return an error if some services
1978 can't be transferred (also see the I<cust_pkg-change_svcpart> config option).
1979 If unprotect_svcs is true, this method will transfer as many services as
1980 it can and then unconditionally cancel the old package.
1981
1982 =back
1983
1984 At least one of locationnum, cust_location, pkgpart, refnum, cust_main, or
1985 cust_pkg must be specified (otherwise, what's the point?)
1986
1987 Returns either the new FS::cust_pkg object or a scalar error.
1988
1989 For example:
1990
1991   my $err_or_new_cust_pkg = $old_cust_pkg->change
1992
1993 =cut
1994
1995 #some false laziness w/order
1996 sub change {
1997   my $self = shift;
1998   my $opt = ref($_[0]) ? shift : { @_ };
1999
2000   my $conf = new FS::Conf;
2001
2002   # Transactionize this whole mess
2003   local $SIG{HUP} = 'IGNORE';
2004   local $SIG{INT} = 'IGNORE';
2005   local $SIG{QUIT} = 'IGNORE';
2006   local $SIG{TERM} = 'IGNORE';
2007   local $SIG{TSTP} = 'IGNORE';
2008   local $SIG{PIPE} = 'IGNORE';
2009
2010   my $oldAutoCommit = $FS::UID::AutoCommit;
2011   local $FS::UID::AutoCommit = 0;
2012   my $dbh = dbh;
2013
2014   my $error;
2015
2016   if ( $opt->{'cust_location'} ) {
2017     $error = $opt->{'cust_location'}->find_or_insert;
2018     if ( $error ) {
2019       $dbh->rollback if $oldAutoCommit;
2020       return "creating location record: $error";
2021     }
2022     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
2023   }
2024
2025   # Before going any further here: if the package is still in the pre-setup
2026   # state, it's safe to modify it in place. No need to charge/credit for
2027   # partial period, transfer services, transfer usage pools, copy invoice
2028   # details, or change any dates.
2029   if ( ! $self->setup and ! $opt->{cust_pkg} and ! $opt->{cust_main} ) {
2030     foreach ( qw( locationnum pkgpart quantity refnum salesnum ) ) {
2031       if ( length($opt->{$_}) ) {
2032         $self->set($_, $opt->{$_});
2033       }
2034     }
2035     # almost. if the new pkgpart specifies start/adjourn/expire timers,
2036     # apply those.
2037     if ( $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart ) {
2038       $self->set_initial_timers;
2039     }
2040     $error = $self->replace;
2041     if ( $error ) {
2042       $dbh->rollback if $oldAutoCommit;
2043       return "modifying package: $error";
2044     } else {
2045       $dbh->commit if $oldAutoCommit;
2046       return '';
2047     }
2048   }
2049
2050   my %hash = ();
2051
2052   my $time = time;
2053
2054   $hash{'setup'} = $time if $self->setup;
2055
2056   $hash{'change_date'} = $time;
2057   $hash{"change_$_"}  = $self->$_()
2058     foreach qw( pkgnum pkgpart locationnum );
2059
2060   if ( $opt->{'cust_pkg'} ) {
2061     # treat changing to a package with a different pkgpart as a
2062     # pkgpart change (because it is)
2063     $opt->{'pkgpart'} = $opt->{'cust_pkg'}->pkgpart;
2064   }
2065
2066   # whether to override pkgpart checking on the new package
2067   my $same_pkgpart = 1;
2068   if ( $opt->{'pkgpart'} and ( $opt->{'pkgpart'} != $self->pkgpart ) ) {
2069     $same_pkgpart = 0;
2070   }
2071
2072   my $unused_credit = 0;
2073   my $keep_dates = $opt->{'keep_dates'};
2074
2075   # Special case.  If the pkgpart is changing, and the customer is
2076   # going to be credited for remaining time, don't keep setup, bill,
2077   # or last_bill dates, and DO pass the flag to cancel() to credit
2078   # the customer.
2079   if ( $opt->{'pkgpart'}
2080        and $opt->{'pkgpart'} != $self->pkgpart
2081        and $self->part_pkg->option('unused_credit_change', 1) ) {
2082     $unused_credit = 1;
2083     $keep_dates = 0;
2084     $hash{$_} = '' foreach qw(setup bill last_bill);
2085   }
2086
2087   if ( $keep_dates ) {
2088     foreach my $date ( qw(setup bill last_bill) ) {
2089       $hash{$date} = $self->getfield($date);
2090     }
2091   }
2092   # always keep the following dates
2093   foreach my $date (qw(order_date susp adjourn cancel expire resume
2094                     start_date contract_end)) {
2095     $hash{$date} = $self->getfield($date);
2096   }
2097
2098   # allow $opt->{'locationnum'} = '' to specifically set it to null
2099   # (i.e. customer default location)
2100   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2101
2102   # usually this doesn't matter.  the two cases where it does are:
2103   # 1. unused_credit_change + pkgpart change + setup fee on the new package
2104   # and
2105   # 2. (more importantly) changing a package before it's billed
2106   $hash{'waive_setup'} = $self->waive_setup;
2107
2108   # if this package is scheduled for a future package change, preserve that
2109   $hash{'change_to_pkgnum'} = $self->change_to_pkgnum;
2110
2111   my $custnum = $self->custnum;
2112   if ( $opt->{cust_main} ) {
2113     my $cust_main = $opt->{cust_main};
2114     unless ( $cust_main->custnum ) {
2115       my $error = $cust_main->insert( @{ $opt->{cust_main_insert_args}||[] } );
2116       if ( $error ) {
2117         $dbh->rollback if $oldAutoCommit;
2118         return "inserting customer record: $error";
2119       }
2120     }
2121     $custnum = $cust_main->custnum;
2122   }
2123
2124   $hash{'contactnum'} = $opt->{'contactnum'} if $opt->{'contactnum'};
2125
2126   my $cust_pkg;
2127   if ( $opt->{'cust_pkg'} ) {
2128     # The target package already exists; update it to show that it was
2129     # changed from this package.
2130     $cust_pkg = $opt->{'cust_pkg'};
2131
2132     # follow all the above rules for date changes, etc.
2133     foreach (keys %hash) {
2134       $cust_pkg->set($_, $hash{$_});
2135     }
2136     # except those that implement the future package change behavior
2137     foreach (qw(change_to_pkgnum start_date expire)) {
2138       $cust_pkg->set($_, '');
2139     }
2140
2141     $error = $cust_pkg->replace;
2142
2143   } else {
2144     # Create the new package.
2145     $cust_pkg = new FS::cust_pkg {
2146       custnum     => $custnum,
2147       locationnum => $opt->{'locationnum'},
2148       ( map {  $_ => ( $opt->{$_} || $self->$_() )  }
2149           qw( pkgpart quantity refnum salesnum )
2150       ),
2151       %hash,
2152     };
2153     $error = $cust_pkg->insert( 'change' => 1,
2154                                 'allow_pkgpart' => $same_pkgpart );
2155   }
2156   if ($error) {
2157     $dbh->rollback if $oldAutoCommit;
2158     return "inserting new package: $error";
2159   }
2160
2161   # Transfer services and cancel old package.
2162   # Enforce service limits only if this is a pkgpart change.
2163   local $FS::cust_svc::ignore_quantity;
2164   $FS::cust_svc::ignore_quantity = 1 if $same_pkgpart;
2165   $error = $self->transfer($cust_pkg);
2166   if ($error and $error == 0) {
2167     # $old_pkg->transfer failed.
2168     $dbh->rollback if $oldAutoCommit;
2169     return "transferring $error";
2170   }
2171
2172   if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
2173     warn "trying transfer again with change_svcpart option\n" if $DEBUG;
2174     $error = $self->transfer($cust_pkg, 'change_svcpart'=>1 );
2175     if ($error and $error == 0) {
2176       # $old_pkg->transfer failed.
2177       $dbh->rollback if $oldAutoCommit;
2178       return "converting $error";
2179     }
2180   }
2181
2182   # We set unprotect_svcs when executing a "future package change".  It's
2183   # not a user-interactive operation, so returning an error means the
2184   # package change will just fail.  Rather than have that happen, we'll
2185   # let leftover services be deleted.
2186   if ($error > 0 and !$opt->{'unprotect_svcs'}) {
2187     # Transfers were successful, but we still had services left on the old
2188     # package.  We can't change the package under this circumstances, so abort.
2189     $dbh->rollback if $oldAutoCommit;
2190     return "unable to transfer all services";
2191   }
2192
2193   #reset usage if changing pkgpart
2194   # AND usage rollover is off (otherwise adds twice, now and at package bill)
2195   if ($self->pkgpart != $cust_pkg->pkgpart) {
2196     my $part_pkg = $cust_pkg->part_pkg;
2197     $error = $part_pkg->reset_usage($cust_pkg, $part_pkg->is_prepaid
2198                                                  ? ()
2199                                                  : ( 'null' => 1 )
2200                                    )
2201       if $part_pkg->can('reset_usage') && ! $part_pkg->option('usage_rollover',1);
2202
2203     if ($error) {
2204       $dbh->rollback if $oldAutoCommit;
2205       return "setting usage values: $error";
2206     }
2207   } else {
2208     # if NOT changing pkgpart, transfer any usage pools over
2209     foreach my $usage ($self->cust_pkg_usage) {
2210       $usage->set('pkgnum', $cust_pkg->pkgnum);
2211       $error = $usage->replace;
2212       if ( $error ) {
2213         $dbh->rollback if $oldAutoCommit;
2214         return "transferring usage pools: $error";
2215       }
2216     }
2217   }
2218
2219   # transfer discounts, if we're not changing pkgpart
2220   if ( $same_pkgpart ) {
2221     foreach my $old_discount ($self->cust_pkg_discount_active) {
2222       # don't remove the old discount, we may still need to bill that package.
2223       my $new_discount = new FS::cust_pkg_discount {
2224         'pkgnum'      => $cust_pkg->pkgnum,
2225         'discountnum' => $old_discount->discountnum,
2226         'months_used' => $old_discount->months_used,
2227       };
2228       $error = $new_discount->insert;
2229       if ( $error ) {
2230         $dbh->rollback if $oldAutoCommit;
2231         return "transferring discounts: $error";
2232       }
2233     }
2234   }
2235
2236   # transfer (copy) invoice details
2237   foreach my $detail ($self->cust_pkg_detail) {
2238     my $new_detail = FS::cust_pkg_detail->new({ $detail->hash });
2239     $new_detail->set('pkgdetailnum', '');
2240     $new_detail->set('pkgnum', $cust_pkg->pkgnum);
2241     $error = $new_detail->insert;
2242     if ( $error ) {
2243       $dbh->rollback if $oldAutoCommit;
2244       return "transferring package notes: $error";
2245     }
2246   }
2247
2248   my @new_supp_pkgs;
2249
2250   if ( !$opt->{'cust_pkg'} ) {
2251     # Order any supplemental packages.
2252     my $part_pkg = $cust_pkg->part_pkg;
2253     my @old_supp_pkgs = $self->supplemental_pkgs;
2254     foreach my $link ($part_pkg->supp_part_pkg_link) {
2255       my $old;
2256       foreach (@old_supp_pkgs) {
2257         if ($_->pkgpart == $link->dst_pkgpart) {
2258           $old = $_;
2259           $_->pkgpart(0); # so that it can't match more than once
2260         }
2261         last if $old;
2262       }
2263       # false laziness with FS::cust_main::Packages::order_pkg
2264       my $new = FS::cust_pkg->new({
2265           pkgpart       => $link->dst_pkgpart,
2266           pkglinknum    => $link->pkglinknum,
2267           custnum       => $custnum,
2268           main_pkgnum   => $cust_pkg->pkgnum,
2269           locationnum   => $cust_pkg->locationnum,
2270           start_date    => $cust_pkg->start_date,
2271           order_date    => $cust_pkg->order_date,
2272           expire        => $cust_pkg->expire,
2273           adjourn       => $cust_pkg->adjourn,
2274           contract_end  => $cust_pkg->contract_end,
2275           refnum        => $cust_pkg->refnum,
2276           discountnum   => $cust_pkg->discountnum,
2277           waive_setup   => $cust_pkg->waive_setup,
2278       });
2279       if ( $old and $opt->{'keep_dates'} ) {
2280         foreach (qw(setup bill last_bill)) {
2281           $new->set($_, $old->get($_));
2282         }
2283       }
2284       $error = $new->insert( allow_pkgpart => $same_pkgpart );
2285       # transfer services
2286       if ( $old ) {
2287         $error ||= $old->transfer($new);
2288       }
2289       if ( $error and $error > 0 ) {
2290         # no reason why this should ever fail, but still...
2291         $error = "Unable to transfer all services from supplemental package ".
2292           $old->pkgnum;
2293       }
2294       if ( $error ) {
2295         $dbh->rollback if $oldAutoCommit;
2296         return $error;
2297       }
2298       push @new_supp_pkgs, $new;
2299     }
2300   } # if !$opt->{'cust_pkg'}
2301     # because if there is one, then supplemental packages would already
2302     # have been created for it.
2303
2304   #Good to go, cancel old package.  Notify 'cancel' of whether to credit
2305   #remaining time.
2306   #Don't allow billing the package (preceding period packages and/or
2307   #outstanding usage) if we are keeping dates (i.e. location changing),
2308   #because the new package will be billed for the same date range.
2309   #Supplemental packages are also canceled here.
2310
2311   # during scheduled changes, avoid canceling the package we just
2312   # changed to (duh)
2313   $self->set('change_to_pkgnum' => '');
2314
2315   $error = $self->cancel(
2316     quiet          => 1,
2317     unused_credit  => $unused_credit,
2318     nobill         => $keep_dates,
2319     change_custnum => ( $self->custnum != $custnum ? $custnum : '' ),
2320     no_delay_cancel => 1,
2321   );
2322   if ($error) {
2323     $dbh->rollback if $oldAutoCommit;
2324     return "canceling old package: $error";
2325   }
2326
2327   if ( $conf->exists('cust_pkg-change_pkgpart-bill_now') ) {
2328     #$self->cust_main
2329     my $error = $cust_pkg->cust_main->bill(
2330       'pkg_list' => [ $cust_pkg, @new_supp_pkgs ]
2331     );
2332     if ( $error ) {
2333       $dbh->rollback if $oldAutoCommit;
2334       return "billing new package: $error";
2335     }
2336   }
2337
2338   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2339
2340   $cust_pkg;
2341
2342 }
2343
2344 =item change_later OPTION => VALUE...
2345
2346 Schedule a package change for a later date.  This actually orders the new
2347 package immediately, but sets its start date for a future date, and sets
2348 the current package to expire on the same date.
2349
2350 If the package is already scheduled for a change, this can be called with
2351 'start_date' to change the scheduled date, or with pkgpart and/or
2352 locationnum to modify the package change.  To cancel the scheduled change
2353 entirely, see C<abort_change>.
2354
2355 Options include:
2356
2357 =over 4
2358
2359 =item start_date
2360
2361 The date for the package change.  Required, and must be in the future.
2362
2363 =item pkgpart
2364
2365 =item locationnum
2366
2367 =item quantity
2368
2369 The pkgpart. locationnum, and quantity of the new package, with the same
2370 meaning as in C<change>.
2371
2372 =back
2373
2374 =cut
2375
2376 sub change_later {
2377   my $self = shift;
2378   my $opt = ref($_[0]) ? shift : { @_ };
2379
2380   my $oldAutoCommit = $FS::UID::AutoCommit;
2381   local $FS::UID::AutoCommit = 0;
2382   my $dbh = dbh;
2383
2384   my $cust_main = $self->cust_main;
2385
2386   my $date = delete $opt->{'start_date'} or return 'start_date required';
2387
2388   if ( $date <= time ) {
2389     $dbh->rollback if $oldAutoCommit;
2390     return "start_date $date is in the past";
2391   }
2392
2393   my $error;
2394
2395   if ( $self->change_to_pkgnum ) {
2396     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
2397     my $new_pkgpart = $opt->{'pkgpart'}
2398         if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $change_to->pkgpart;
2399     my $new_locationnum = $opt->{'locationnum'}
2400         if $opt->{'locationnum'} and $opt->{'locationnum'} != $change_to->locationnum;
2401     my $new_quantity = $opt->{'quantity'}
2402         if $opt->{'quantity'} and $opt->{'quantity'} != $change_to->quantity;
2403     if ( $new_pkgpart or $new_locationnum or $new_quantity ) {
2404       # it hasn't been billed yet, so in principle we could just edit
2405       # it in place (w/o a package change), but that's bad form.
2406       # So change the package according to the new options...
2407       my $err_or_pkg = $change_to->change(%$opt);
2408       if ( ref $err_or_pkg ) {
2409         # Then set that package up for a future start.
2410         $self->set('change_to_pkgnum', $err_or_pkg->pkgnum);
2411         $self->set('expire', $date); # in case it's different
2412         $err_or_pkg->set('start_date', $date);
2413         $err_or_pkg->set('change_date', '');
2414         $err_or_pkg->set('change_pkgnum', '');
2415
2416         $error = $self->replace       ||
2417                  $err_or_pkg->replace ||
2418                  $change_to->cancel('no_delay_cancel' => 1) ||
2419                  $change_to->delete;
2420       } else {
2421         $error = $err_or_pkg;
2422       }
2423     } else { # change the start date only.
2424       $self->set('expire', $date);
2425       $change_to->set('start_date', $date);
2426       $error = $self->replace || $change_to->replace;
2427     }
2428     if ( $error ) {
2429       $dbh->rollback if $oldAutoCommit;
2430       return $error;
2431     } else {
2432       $dbh->commit if $oldAutoCommit;
2433       return '';
2434     }
2435   } # if $self->change_to_pkgnum
2436
2437   my $new_pkgpart = $opt->{'pkgpart'}
2438       if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart;
2439   my $new_locationnum = $opt->{'locationnum'}
2440       if $opt->{'locationnum'} and $opt->{'locationnum'} != $self->locationnum;
2441   my $new_quantity = $opt->{'quantity'}
2442       if $opt->{'quantity'} and $opt->{'quantity'} != $self->quantity;
2443
2444   return '' unless $new_pkgpart or $new_locationnum or $new_quantity; # wouldn't do anything
2445
2446   # allow $opt->{'locationnum'} = '' to specifically set it to null
2447   # (i.e. customer default location)
2448   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2449
2450   my $new = FS::cust_pkg->new( {
2451     custnum     => $self->custnum,
2452     locationnum => $opt->{'locationnum'},
2453     start_date  => $date,
2454     map   {  $_ => ( $opt->{$_} || $self->$_() )  }
2455       qw( pkgpart quantity refnum salesnum )
2456   } );
2457   $error = $new->insert('change' => 1,
2458                         'allow_pkgpart' => ($new_pkgpart ? 0 : 1));
2459   if ( !$error ) {
2460     $self->set('change_to_pkgnum', $new->pkgnum);
2461     $self->set('expire', $date);
2462     $error = $self->replace;
2463   }
2464   if ( $error ) {
2465     $dbh->rollback if $oldAutoCommit;
2466   } else {
2467     $dbh->commit if $oldAutoCommit;
2468   }
2469
2470   $error;
2471 }
2472
2473 =item abort_change
2474
2475 Cancels a future package change scheduled by C<change_later>.
2476
2477 =cut
2478
2479 sub abort_change {
2480   my $self = shift;
2481   my $pkgnum = $self->change_to_pkgnum;
2482   my $change_to = FS::cust_pkg->by_key($pkgnum) if $pkgnum;
2483   my $error;
2484   if ( $change_to ) {
2485     $error = $change_to->cancel || $change_to->delete;
2486     return $error if $error;
2487   }
2488   $self->set('change_to_pkgnum', '');
2489   $self->set('expire', '');
2490   $self->replace;
2491 }
2492
2493 =item set_quantity QUANTITY
2494
2495 Change the package's quantity field.  This is one of the few package properties
2496 that can safely be changed without canceling and reordering the package
2497 (because it doesn't affect tax eligibility).  Returns an error or an
2498 empty string.
2499
2500 =cut
2501
2502 sub set_quantity {
2503   my $self = shift;
2504   $self = $self->replace_old; # just to make sure
2505   $self->quantity(shift);
2506   $self->replace;
2507 }
2508
2509 =item set_salesnum SALESNUM
2510
2511 Change the package's salesnum (sales person) field.  This is one of the few
2512 package properties that can safely be changed without canceling and reordering
2513 the package (because it doesn't affect tax eligibility).  Returns an error or
2514 an empty string.
2515
2516 =cut
2517
2518 sub set_salesnum {
2519   my $self = shift;
2520   $self = $self->replace_old; # just to make sure
2521   $self->salesnum(shift);
2522   $self->replace;
2523   # XXX this should probably reassign any credit that's already been given
2524 }
2525
2526 =item modify_charge OPTIONS
2527
2528 Change the properties of a one-time charge.  The following properties can
2529 be changed this way:
2530 - pkg: the package description
2531 - classnum: the package class
2532 - additional: arrayref of additional invoice details to add to this package
2533
2534 and, I<if the charge has not yet been billed>:
2535 - start_date: the date when it will be billed
2536 - amount: the setup fee to be charged
2537 - quantity: the multiplier for the setup fee
2538 - separate_bill: whether to put the charge on a separate invoice
2539
2540 If you pass 'adjust_commission' => 1, and the classnum changes, and there are
2541 commission credits linked to this charge, they will be recalculated.
2542
2543 =cut
2544
2545 sub modify_charge {
2546   my $self = shift;
2547   my %opt = @_;
2548   my $part_pkg = $self->part_pkg;
2549   my $pkgnum = $self->pkgnum;
2550
2551   my $dbh = dbh;
2552   my $oldAutoCommit = $FS::UID::AutoCommit;
2553   local $FS::UID::AutoCommit = 0;
2554
2555   return "Can't use modify_charge except on one-time charges"
2556     unless $part_pkg->freq eq '0';
2557
2558   if ( length($opt{'pkg'}) and $part_pkg->pkg ne $opt{'pkg'} ) {
2559     $part_pkg->set('pkg', $opt{'pkg'});
2560   }
2561
2562   my %pkg_opt = $part_pkg->options;
2563   my $pkg_opt_modified = 0;
2564
2565   $opt{'additional'} ||= [];
2566   my $i;
2567   my @old_additional;
2568   foreach (grep /^additional/, keys %pkg_opt) {
2569     ($i) = ($_ =~ /^additional_info(\d+)$/);
2570     $old_additional[$i] = $pkg_opt{$_} if $i;
2571     delete $pkg_opt{$_};
2572   }
2573
2574   for ( $i = 0; exists($opt{'additional'}->[$i]); $i++ ) {
2575     $pkg_opt{ "additional_info$i" } = $opt{'additional'}->[$i];
2576     if (!exists($old_additional[$i])
2577         or $old_additional[$i] ne $opt{'additional'}->[$i])
2578     {
2579       $pkg_opt_modified = 1;
2580     }
2581   }
2582   $pkg_opt_modified = 1 if (scalar(@old_additional) - 1) != $i;
2583   $pkg_opt{'additional_count'} = $i if $i > 0;
2584
2585   my $old_classnum;
2586   if ( exists($opt{'classnum'}) and $part_pkg->classnum ne $opt{'classnum'} )
2587   {
2588     # remember it
2589     $old_classnum = $part_pkg->classnum;
2590     $part_pkg->set('classnum', $opt{'classnum'});
2591   }
2592
2593   if ( !$self->get('setup') ) {
2594     # not yet billed, so allow amount, setup_cost, quantity, start_date,
2595     # and separate_bill
2596
2597     if ( exists($opt{'amount'})
2598           and $part_pkg->option('setup_fee') != $opt{'amount'}
2599           and $opt{'amount'} > 0 ) {
2600
2601       $pkg_opt{'setup_fee'} = $opt{'amount'};
2602       $pkg_opt_modified = 1;
2603     }
2604
2605     if ( exists($opt{'setup_cost'})
2606           and $part_pkg->setup_cost != $opt{'setup_cost'}
2607           and $opt{'setup_cost'} > 0 ) {
2608
2609       $part_pkg->set('setup_cost', $opt{'setup_cost'});
2610     }
2611
2612     if ( exists($opt{'quantity'})
2613           and $opt{'quantity'} != $self->quantity
2614           and $opt{'quantity'} > 0 ) {
2615
2616       $self->set('quantity', $opt{'quantity'});
2617     }
2618
2619     if ( exists($opt{'start_date'})
2620           and $opt{'start_date'} != $self->start_date ) {
2621
2622       $self->set('start_date', $opt{'start_date'});
2623     }
2624
2625     if ( exists($opt{'separate_bill'})
2626           and $opt{'separate_bill'} ne $self->separate_bill ) {
2627
2628       $self->set('separate_bill', $opt{'separate_bill'});
2629     }
2630
2631
2632   } # else simply ignore them; the UI shouldn't allow editing the fields
2633
2634   if ( exists($opt{'taxclass'})
2635           and $part_pkg->taxclass ne $opt{'taxclass'}) {
2636
2637       $part_pkg->set('taxclass', $opt{'taxclass'});
2638   }
2639
2640   my $error;
2641   if ( $part_pkg->modified or $pkg_opt_modified ) {
2642     # can we safely modify the package def?
2643     # Yes, if it's not available for purchase, and this is the only instance
2644     # of it.
2645     if ( $part_pkg->disabled
2646          and FS::cust_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 1
2647          and FS::quotation_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 0
2648        ) {
2649       $error = $part_pkg->replace( options => \%pkg_opt );
2650     } else {
2651       # clone it
2652       $part_pkg = $part_pkg->clone;
2653       $part_pkg->set('disabled' => 'Y');
2654       $error = $part_pkg->insert( options => \%pkg_opt );
2655       # and associate this as yet-unbilled package to the new package def
2656       $self->set('pkgpart' => $part_pkg->pkgpart);
2657     }
2658     if ( $error ) {
2659       $dbh->rollback if $oldAutoCommit;
2660       return $error;
2661     }
2662   }
2663
2664   if ($self->modified) { # for quantity or start_date change, or if we had
2665                          # to clone the existing package def
2666     my $error = $self->replace;
2667     return $error if $error;
2668   }
2669   if (defined $old_classnum) {
2670     # fix invoice grouping records
2671     my $old_catname = $old_classnum
2672                       ? FS::pkg_class->by_key($old_classnum)->categoryname
2673                       : '';
2674     my $new_catname = $opt{'classnum'}
2675                       ? $part_pkg->pkg_class->categoryname
2676                       : '';
2677     if ( $old_catname ne $new_catname ) {
2678       foreach my $cust_bill_pkg ($self->cust_bill_pkg) {
2679         # (there should only be one...)
2680         my @display = qsearch( 'cust_bill_pkg_display', {
2681             'billpkgnum'  => $cust_bill_pkg->billpkgnum,
2682             'section'     => $old_catname,
2683         });
2684         foreach (@display) {
2685           $_->set('section', $new_catname);
2686           $error = $_->replace;
2687           if ( $error ) {
2688             $dbh->rollback if $oldAutoCommit;
2689             return $error;
2690           }
2691         }
2692       } # foreach $cust_bill_pkg
2693     }
2694
2695     if ( $opt{'adjust_commission'} ) {
2696       # fix commission credits...tricky.
2697       foreach my $cust_event ($self->cust_event) {
2698         my $part_event = $cust_event->part_event;
2699         foreach my $table (qw(sales agent)) {
2700           my $class =
2701             "FS::part_event::Action::Mixin::credit_${table}_pkg_class";
2702           my $credit = qsearchs('cust_credit', {
2703               'eventnum' => $cust_event->eventnum,
2704           });
2705           if ( $part_event->isa($class) ) {
2706             # Yes, this results in current commission rates being applied
2707             # retroactively to a one-time charge.  For accounting purposes
2708             # there ought to be some kind of time limit on doing this.
2709             my $amount = $part_event->_calc_credit($self);
2710             if ( $credit and $credit->amount ne $amount ) {
2711               # Void the old credit.
2712               $error = $credit->void('Package class changed');
2713               if ( $error ) {
2714                 $dbh->rollback if $oldAutoCommit;
2715                 return "$error (adjusting commission credit)";
2716               }
2717             }
2718             # redo the event action to recreate the credit.
2719             local $@ = '';
2720             eval { $part_event->do_action( $self, $cust_event ) };
2721             if ( $@ ) {
2722               $dbh->rollback if $oldAutoCommit;
2723               return $@;
2724             }
2725           } # if $part_event->isa($class)
2726         } # foreach $table
2727       } # foreach $cust_event
2728     } # if $opt{'adjust_commission'}
2729   } # if defined $old_classnum
2730
2731   $dbh->commit if $oldAutoCommit;
2732   '';
2733 }
2734
2735
2736
2737 use Storable 'thaw';
2738 use MIME::Base64;
2739 use Data::Dumper;
2740 sub process_bulk_cust_pkg {
2741   my $job = shift;
2742   my $param = thaw(decode_base64(shift));
2743   warn Dumper($param) if $DEBUG;
2744
2745   my $old_part_pkg = qsearchs('part_pkg',
2746                               { pkgpart => $param->{'old_pkgpart'} });
2747   my $new_part_pkg = qsearchs('part_pkg',
2748                               { pkgpart => $param->{'new_pkgpart'} });
2749   die "Must select a new package type\n" unless $new_part_pkg;
2750   #my $keep_dates = $param->{'keep_dates'} || 0;
2751   my $keep_dates = 1; # there is no good reason to turn this off
2752
2753   local $SIG{HUP} = 'IGNORE';
2754   local $SIG{INT} = 'IGNORE';
2755   local $SIG{QUIT} = 'IGNORE';
2756   local $SIG{TERM} = 'IGNORE';
2757   local $SIG{TSTP} = 'IGNORE';
2758   local $SIG{PIPE} = 'IGNORE';
2759
2760   my $oldAutoCommit = $FS::UID::AutoCommit;
2761   local $FS::UID::AutoCommit = 0;
2762   my $dbh = dbh;
2763
2764   my @cust_pkgs = qsearch('cust_pkg', { 'pkgpart' => $param->{'old_pkgpart'} } );
2765
2766   my $i = 0;
2767   foreach my $old_cust_pkg ( @cust_pkgs ) {
2768     $i++;
2769     $job->update_statustext(int(100*$i/(scalar @cust_pkgs)));
2770     if ( $old_cust_pkg->getfield('cancel') ) {
2771       warn '[process_bulk_cust_pkg ] skipping canceled pkgnum '.
2772         $old_cust_pkg->pkgnum."\n"
2773         if $DEBUG;
2774       next;
2775     }
2776     warn '[process_bulk_cust_pkg] changing pkgnum '.$old_cust_pkg->pkgnum."\n"
2777       if $DEBUG;
2778     my $error = $old_cust_pkg->change(
2779       'pkgpart'     => $param->{'new_pkgpart'},
2780       'keep_dates'  => $keep_dates
2781     );
2782     if ( !ref($error) ) { # change returns the cust_pkg on success
2783       $dbh->rollback;
2784       die "Error changing pkgnum ".$old_cust_pkg->pkgnum.": '$error'\n";
2785     }
2786   }
2787   $dbh->commit if $oldAutoCommit;
2788   return;
2789 }
2790
2791 =item last_bill
2792
2793 Returns the last bill date, or if there is no last bill date, the setup date.
2794 Useful for billing metered services.
2795
2796 =cut
2797
2798 sub last_bill {
2799   my $self = shift;
2800   return $self->setfield('last_bill', $_[0]) if @_;
2801   return $self->getfield('last_bill') if $self->getfield('last_bill');
2802   my $cust_bill_pkg = qsearchs('cust_bill_pkg', { 'pkgnum' => $self->pkgnum,
2803                                                   'edate'  => $self->bill,  } );
2804   $cust_bill_pkg ? $cust_bill_pkg->sdate : $self->setup || 0;
2805 }
2806
2807 =item last_cust_pkg_reason ACTION
2808
2809 Returns the most recent ACTION FS::cust_pkg_reason associated with the package.
2810 Returns false if there is no reason or the package is not currenly ACTION'd
2811 ACTION is one of adjourn, susp, cancel, or expire.
2812
2813 =cut
2814
2815 sub last_cust_pkg_reason {
2816   my ( $self, $action ) = ( shift, shift );
2817   my $date = $self->get($action);
2818   qsearchs( {
2819               'table' => 'cust_pkg_reason',
2820               'hashref' => { 'pkgnum' => $self->pkgnum,
2821                              'action' => substr(uc($action), 0, 1),
2822                              'date'   => $date,
2823                            },
2824               'order_by' => 'ORDER BY num DESC LIMIT 1',
2825            } );
2826 }
2827
2828 =item last_reason ACTION
2829
2830 Returns the most recent ACTION FS::reason associated with the package.
2831 Returns false if there is no reason or the package is not currenly ACTION'd
2832 ACTION is one of adjourn, susp, cancel, or expire.
2833
2834 =cut
2835
2836 sub last_reason {
2837   my $cust_pkg_reason = shift->last_cust_pkg_reason(@_);
2838   $cust_pkg_reason->reason
2839     if $cust_pkg_reason;
2840 }
2841
2842 =item part_pkg
2843
2844 Returns the definition for this billing item, as an FS::part_pkg object (see
2845 L<FS::part_pkg>).
2846
2847 =cut
2848
2849 sub part_pkg {
2850   my $self = shift;
2851   return $self->{'_pkgpart'} if $self->{'_pkgpart'};
2852   cluck "cust_pkg->part_pkg called" if $DEBUG > 1;
2853   qsearchs( 'part_pkg', { 'pkgpart' => $self->pkgpart } );
2854 }
2855
2856 =item old_cust_pkg
2857
2858 Returns the cancelled package this package was changed from, if any.
2859
2860 =cut
2861
2862 sub old_cust_pkg {
2863   my $self = shift;
2864   return '' unless $self->change_pkgnum;
2865   qsearchs('cust_pkg', { 'pkgnum' => $self->change_pkgnum } );
2866 }
2867
2868 =item change_cust_main
2869
2870 Returns the customter this package was detached to, if any.
2871
2872 =cut
2873
2874 sub change_cust_main {
2875   my $self = shift;
2876   return '' unless $self->change_custnum;
2877   qsearchs('cust_main', { 'custnum' => $self->change_custnum } );
2878 }
2879
2880 =item calc_setup
2881
2882 Calls the I<calc_setup> of the FS::part_pkg object associated with this billing
2883 item.
2884
2885 =cut
2886
2887 sub calc_setup {
2888   my $self = shift;
2889   $self->part_pkg->calc_setup($self, @_);
2890 }
2891
2892 =item calc_recur
2893
2894 Calls the I<calc_recur> of the FS::part_pkg object associated with this billing
2895 item.
2896
2897 =cut
2898
2899 sub calc_recur {
2900   my $self = shift;
2901   $self->part_pkg->calc_recur($self, @_);
2902 }
2903
2904 =item base_recur
2905
2906 Calls the I<base_recur> of the FS::part_pkg object associated with this billing
2907 item.
2908
2909 =cut
2910
2911 sub base_recur {
2912   my $self = shift;
2913   $self->part_pkg->base_recur($self, @_);
2914 }
2915
2916 =item calc_remain
2917
2918 Calls the I<calc_remain> of the FS::part_pkg object associated with this
2919 billing item.
2920
2921 =cut
2922
2923 sub calc_remain {
2924   my $self = shift;
2925   $self->part_pkg->calc_remain($self, @_);
2926 }
2927
2928 =item calc_cancel
2929
2930 Calls the I<calc_cancel> of the FS::part_pkg object associated with this
2931 billing item.
2932
2933 =cut
2934
2935 sub calc_cancel {
2936   my $self = shift;
2937   $self->part_pkg->calc_cancel($self, @_);
2938 }
2939
2940 =item cust_bill_pkg
2941
2942 Returns any invoice line items for this package (see L<FS::cust_bill_pkg>).
2943
2944 =cut
2945
2946 sub cust_bill_pkg {
2947   my $self = shift;
2948   qsearch( 'cust_bill_pkg', { 'pkgnum' => $self->pkgnum } );
2949 }
2950
2951 =item cust_pkg_detail [ DETAILTYPE ]
2952
2953 Returns any customer package details for this package (see
2954 L<FS::cust_pkg_detail>).
2955
2956 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2957
2958 =cut
2959
2960 sub cust_pkg_detail {
2961   my $self = shift;
2962   my %hash = ( 'pkgnum' => $self->pkgnum );
2963   $hash{detailtype} = shift if @_;
2964   qsearch({
2965     'table'    => 'cust_pkg_detail',
2966     'hashref'  => \%hash,
2967     'order_by' => 'ORDER BY weight, pkgdetailnum',
2968   });
2969 }
2970
2971 =item set_cust_pkg_detail DETAILTYPE [ DETAIL, DETAIL, ... ]
2972
2973 Sets customer package details for this package (see L<FS::cust_pkg_detail>).
2974
2975 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2976
2977 If there is an error, returns the error, otherwise returns false.
2978
2979 =cut
2980
2981 sub set_cust_pkg_detail {
2982   my( $self, $detailtype, @details ) = @_;
2983
2984   local $SIG{HUP} = 'IGNORE';
2985   local $SIG{INT} = 'IGNORE';
2986   local $SIG{QUIT} = 'IGNORE';
2987   local $SIG{TERM} = 'IGNORE';
2988   local $SIG{TSTP} = 'IGNORE';
2989   local $SIG{PIPE} = 'IGNORE';
2990
2991   my $oldAutoCommit = $FS::UID::AutoCommit;
2992   local $FS::UID::AutoCommit = 0;
2993   my $dbh = dbh;
2994
2995   foreach my $current ( $self->cust_pkg_detail($detailtype) ) {
2996     my $error = $current->delete;
2997     if ( $error ) {
2998       $dbh->rollback if $oldAutoCommit;
2999       return "error removing old detail: $error";
3000     }
3001   }
3002
3003   foreach my $detail ( @details ) {
3004     my $cust_pkg_detail = new FS::cust_pkg_detail {
3005       'pkgnum'     => $self->pkgnum,
3006       'detailtype' => $detailtype,
3007       'detail'     => $detail,
3008     };
3009     my $error = $cust_pkg_detail->insert;
3010     if ( $error ) {
3011       $dbh->rollback if $oldAutoCommit;
3012       return "error adding new detail: $error";
3013     }
3014
3015   }
3016
3017   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3018   '';
3019
3020 }
3021
3022 =item cust_event
3023
3024 Returns the customer billing events (see L<FS::cust_event>) for this invoice.
3025
3026 =cut
3027
3028 #false laziness w/cust_bill.pm
3029 sub cust_event {
3030   my $self = shift;
3031   qsearch({
3032     'table'     => 'cust_event',
3033     'addl_from' => 'JOIN part_event USING ( eventpart )',
3034     'hashref'   => { 'tablenum' => $self->pkgnum },
3035     'extra_sql' => " AND eventtable = 'cust_pkg' ",
3036   });
3037 }
3038
3039 =item num_cust_event
3040
3041 Returns the number of customer billing events (see L<FS::cust_event>) for this package.
3042
3043 =cut
3044
3045 #false laziness w/cust_bill.pm
3046 sub num_cust_event {
3047   my $self = shift;
3048   my $sql = "SELECT COUNT(*) ". $self->_from_cust_event_where;
3049   $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref->[0];
3050 }
3051
3052 =item exists_cust_event
3053
3054 Returns true if there are customer billing events (see L<FS::cust_event>) for this package.  More efficient than using num_cust_event.
3055
3056 =cut
3057
3058 sub exists_cust_event {
3059   my $self = shift;
3060   my $sql = "SELECT 1 ". $self->_from_cust_event_where. " LIMIT 1";
3061   my $row = $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref;
3062   $row ? $row->[0] : '';
3063 }
3064
3065 sub _from_cust_event_where {
3066   #my $self = shift;
3067   " FROM cust_event JOIN part_event USING ( eventpart ) ".
3068   "  WHERE tablenum = ? AND eventtable = 'cust_pkg' ";
3069 }
3070
3071 sub _prep_ex {
3072   my( $self, $sql, @args ) = @_;
3073   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
3074   $sth->execute(@args)         or die $sth->errstr. " executing $sql";
3075   $sth;
3076 }
3077
3078 =item cust_svc [ SVCPART ] (old, deprecated usage)
3079
3080 =item cust_svc [ OPTION => VALUE ... ] (current usage)
3081
3082 =item cust_svc_unsorted [ OPTION => VALUE ... ]
3083
3084 Returns the services for this package, as FS::cust_svc objects (see
3085 L<FS::cust_svc>).  Available options are svcpart and svcdb.  If either is
3086 spcififed, returns only the matching services.
3087
3088 As an optimization, use the cust_svc_unsorted version if you are not displaying
3089 the results.
3090
3091 =cut
3092
3093 sub cust_svc {
3094   my $self = shift;
3095   cluck "cust_pkg->cust_svc called" if $DEBUG > 2;
3096   $self->_sort_cust_svc( $self->cust_svc_unsorted_arrayref(@_) );
3097 }
3098
3099 sub cust_svc_unsorted {
3100   my $self = shift;
3101   @{ $self->cust_svc_unsorted_arrayref(@_) };
3102 }
3103
3104 sub cust_svc_unsorted_arrayref {
3105   my $self = shift;
3106
3107   return [] unless $self->num_cust_svc(@_);
3108
3109   my %opt = ();
3110   if ( @_ && $_[0] =~ /^\d+/ ) {
3111     $opt{svcpart} = shift;
3112   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3113     %opt = %{ $_[0] };
3114   } elsif ( @_ ) {
3115     %opt = @_;
3116   }
3117
3118   my %search = (
3119     'table'   => 'cust_svc',
3120     'hashref' => { 'pkgnum' => $self->pkgnum },
3121   );
3122   if ( $opt{svcpart} ) {
3123     $search{hashref}->{svcpart} = $opt{'svcpart'};
3124   }
3125   if ( $opt{'svcdb'} ) {
3126     $search{addl_from} = ' LEFT JOIN part_svc USING ( svcpart ) ';
3127     $search{extra_sql} = ' AND svcdb = '. dbh->quote( $opt{'svcdb'} );
3128   }
3129
3130   [ qsearch(\%search) ];
3131
3132 }
3133
3134 =item overlimit [ SVCPART ]
3135
3136 Returns the services for this package which have exceeded their
3137 usage limit as FS::cust_svc objects (see L<FS::cust_svc>).  If a svcpart
3138 is specified, return only the matching services.
3139
3140 =cut
3141
3142 sub overlimit {
3143   my $self = shift;
3144   return () unless $self->num_cust_svc(@_);
3145   grep { $_->overlimit } $self->cust_svc(@_);
3146 }
3147
3148 =item h_cust_svc END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3149
3150 Returns historical services for this package created before END TIMESTAMP and
3151 (optionally) not cancelled before START_TIMESTAMP, as FS::h_cust_svc objects
3152 (see L<FS::h_cust_svc>).  If MODE is 'I' (for 'invoice'), services with the
3153 I<pkg_svc.hidden> flag will be omitted.
3154
3155 =cut
3156
3157 sub h_cust_svc {
3158   my $self = shift;
3159   warn "$me _h_cust_svc called on $self\n"
3160     if $DEBUG;
3161
3162   my ($end, $start, $mode) = @_;
3163   my @cust_svc = $self->_sort_cust_svc(
3164     [ qsearch( 'h_cust_svc',
3165       { 'pkgnum' => $self->pkgnum, },
3166       FS::h_cust_svc->sql_h_search(@_),
3167     ) ]
3168   );
3169   if ( defined($mode) && $mode eq 'I' ) {
3170     my %hidden_svcpart = map { $_->svcpart => $_->hidden } $self->part_svc;
3171     return grep { !$hidden_svcpart{$_->svcpart} } @cust_svc;
3172   } else {
3173     return @cust_svc;
3174   }
3175 }
3176
3177 sub _sort_cust_svc {
3178   my( $self, $arrayref ) = @_;
3179
3180   my $sort =
3181     sub ($$) { my ($a, $b) = @_; $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] };
3182
3183   my %pkg_svc = map { $_->svcpart => $_ }
3184                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
3185
3186   map  { $_->[0] }
3187   sort $sort
3188   map {
3189         my $pkg_svc = $pkg_svc{ $_->svcpart } || '';
3190         [ $_,
3191           $pkg_svc ? $pkg_svc->primary_svc : '',
3192           $pkg_svc ? $pkg_svc->quantity : 0,
3193         ];
3194       }
3195   @$arrayref;
3196
3197 }
3198
3199 =item num_cust_svc [ SVCPART ] (old, deprecated usage)
3200
3201 =item num_cust_svc [ OPTION => VALUE ... ] (current usage)
3202
3203 Returns the number of services for this package.  Available options are svcpart
3204 and svcdb.  If either is spcififed, returns only the matching services.
3205
3206 =cut
3207
3208 sub num_cust_svc {
3209   my $self = shift;
3210
3211   return $self->{'_num_cust_svc'}
3212     if !scalar(@_)
3213        && exists($self->{'_num_cust_svc'})
3214        && $self->{'_num_cust_svc'} =~ /\d/;
3215
3216   cluck "cust_pkg->num_cust_svc called, _num_cust_svc:".$self->{'_num_cust_svc'}
3217     if $DEBUG > 2;
3218
3219   my %opt = ();
3220   if ( @_ && $_[0] =~ /^\d+/ ) {
3221     $opt{svcpart} = shift;
3222   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3223     %opt = %{ $_[0] };
3224   } elsif ( @_ ) {
3225     %opt = @_;
3226   }
3227
3228   my $select = 'SELECT COUNT(*) FROM cust_svc ';
3229   my $where = ' WHERE pkgnum = ? ';
3230   my @param = ($self->pkgnum);
3231
3232   if ( $opt{'svcpart'} ) {
3233     $where .= ' AND svcpart = ? ';
3234     push @param, $opt{'svcpart'};
3235   }
3236   if ( $opt{'svcdb'} ) {
3237     $select .= ' LEFT JOIN part_svc USING ( svcpart ) ';
3238     $where .= ' AND svcdb = ? ';
3239     push @param, $opt{'svcdb'};
3240   }
3241
3242   my $sth = dbh->prepare("$select $where") or die  dbh->errstr;
3243   $sth->execute(@param) or die $sth->errstr;
3244   $sth->fetchrow_arrayref->[0];
3245 }
3246
3247 =item available_part_svc
3248
3249 Returns a list of FS::part_svc objects representing services included in this
3250 package but not yet provisioned.  Each FS::part_svc object also has an extra
3251 field, I<num_avail>, which specifies the number of available services.
3252
3253 =cut
3254
3255 sub available_part_svc {
3256   my $self = shift;
3257
3258   my $pkg_quantity = $self->quantity || 1;
3259
3260   grep { $_->num_avail > 0 }
3261     map {
3262           my $part_svc = $_->part_svc;
3263           $part_svc->{'Hash'}{'num_avail'} = #evil encapsulation-breaking
3264             $pkg_quantity * $_->quantity - $self->num_cust_svc($_->svcpart);
3265
3266           # more evil encapsulation breakage
3267           if($part_svc->{'Hash'}{'num_avail'} > 0) {
3268             my @exports = $part_svc->part_export_did;
3269             $part_svc->{'Hash'}{'can_get_dids'} = scalar(@exports);
3270           }
3271
3272           $part_svc;
3273         }
3274       $self->part_pkg->pkg_svc;
3275 }
3276
3277 =item part_svc [ OPTION => VALUE ... ]
3278
3279 Returns a list of FS::part_svc objects representing provisioned and available
3280 services included in this package.  Each FS::part_svc object also has the
3281 following extra fields:
3282
3283 =over 4
3284
3285 =item num_cust_svc
3286
3287 (count)
3288
3289 =item num_avail
3290
3291 (quantity - count)
3292
3293 =item cust_pkg_svc
3294
3295 (services) - array reference containing the provisioned services, as cust_svc objects
3296
3297 =back
3298
3299 Accepts two options:
3300
3301 =over 4
3302
3303 =item summarize_size
3304
3305 If true, will omit the extra cust_pkg_svc option for objects where num_cust_svc
3306 is this size or greater.
3307
3308 =item hide_discontinued
3309
3310 If true, will omit looking for services that are no longer avaialble in the
3311 package definition.
3312
3313 =back
3314
3315 =cut
3316
3317 #svcnum
3318 #label -> ($cust_svc->label)[1]
3319
3320 sub part_svc {
3321   my $self = shift;
3322   my %opt = @_;
3323
3324   my $pkg_quantity = $self->quantity || 1;
3325
3326   #XXX some sort of sort order besides numeric by svcpart...
3327   my @part_svc = sort { $a->svcpart <=> $b->svcpart } map {
3328     my $pkg_svc = $_;
3329     my $part_svc = $pkg_svc->part_svc;
3330     my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3331     $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #more evil
3332     $part_svc->{'Hash'}{'num_avail'}    =
3333       max( 0, $pkg_quantity * $pkg_svc->quantity - $num_cust_svc );
3334     $part_svc->{'Hash'}{'cust_pkg_svc'} =
3335         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : []
3336       unless exists($opt{summarize_size}) && $opt{summarize_size} > 0
3337           && $num_cust_svc >= $opt{summarize_size};
3338     $part_svc->{'Hash'}{'hidden'} = $pkg_svc->hidden;
3339     $part_svc;
3340   } $self->part_pkg->pkg_svc;
3341
3342   unless ( $opt{hide_discontinued} ) {
3343     #extras
3344     push @part_svc, map {
3345       my $part_svc = $_;
3346       my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3347       $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #speak no evail
3348       $part_svc->{'Hash'}{'num_avail'}    = 0; #0-$num_cust_svc ?
3349       $part_svc->{'Hash'}{'cust_pkg_svc'} =
3350         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : [];
3351       $part_svc;
3352     } $self->extra_part_svc;
3353   }
3354
3355   @part_svc;
3356
3357 }
3358
3359 =item extra_part_svc
3360
3361 Returns a list of FS::part_svc objects corresponding to services in this
3362 package which are still provisioned but not (any longer) available in the
3363 package definition.
3364
3365 =cut
3366
3367 sub extra_part_svc {
3368   my $self = shift;
3369
3370   my $pkgnum  = $self->pkgnum;
3371   #my $pkgpart = $self->pkgpart;
3372
3373 #  qsearch( {
3374 #    'table'     => 'part_svc',
3375 #    'hashref'   => {},
3376 #    'extra_sql' =>
3377 #      "WHERE 0 = ( SELECT COUNT(*) FROM pkg_svc
3378 #                     WHERE pkg_svc.svcpart = part_svc.svcpart
3379 #                       AND pkg_svc.pkgpart = ?
3380 #                       AND quantity > 0
3381 #                 )
3382 #        AND 0 < ( SELECT COUNT(*) FROM cust_svc
3383 #                       LEFT JOIN cust_pkg USING ( pkgnum )
3384 #                     WHERE cust_svc.svcpart = part_svc.svcpart
3385 #                       AND pkgnum = ?
3386 #                 )",
3387 #    'extra_param' => [ [$self->pkgpart=>'int'], [$self->pkgnum=>'int'] ],
3388 #  } );
3389
3390 #seems to benchmark slightly faster... (or did?)
3391
3392   my @pkgparts = map $_->pkgpart, $self->part_pkg->self_and_svc_linked;
3393   my $pkgparts = join(',', @pkgparts);
3394
3395   qsearch( {
3396     #'select'      => 'DISTINCT ON (svcpart) part_svc.*',
3397     #MySQL doesn't grok DISINCT ON
3398     'select'      => 'DISTINCT part_svc.*',
3399     'table'       => 'part_svc',
3400     'addl_from'   =>
3401       "LEFT JOIN pkg_svc  ON (     pkg_svc.svcpart   = part_svc.svcpart
3402                                AND pkg_svc.pkgpart IN ($pkgparts)
3403                                AND quantity > 0
3404                              )
3405        LEFT JOIN cust_svc ON (     cust_svc.svcpart = part_svc.svcpart )
3406        LEFT JOIN cust_pkg USING ( pkgnum )
3407       ",
3408     'hashref'     => {},
3409     'extra_sql'   => "WHERE pkgsvcnum IS NULL AND cust_pkg.pkgnum = ? ",
3410     'extra_param' => [ [$self->pkgnum=>'int'] ],
3411   } );
3412 }
3413
3414 =item status
3415
3416 Returns a short status string for this package, currently:
3417
3418 =over 4
3419
3420 =item on hold
3421
3422 =item not yet billed
3423
3424 =item one-time charge
3425
3426 =item active
3427
3428 =item suspended
3429
3430 =item cancelled
3431
3432 =back
3433
3434 =cut
3435
3436 sub status {
3437   my $self = shift;
3438
3439   my $freq = length($self->freq) ? $self->freq : $self->part_pkg->freq;
3440
3441   return 'cancelled' if $self->get('cancel');
3442   return 'on hold' if $self->susp && ! $self->setup;
3443   return 'suspended' if $self->susp;
3444   return 'not yet billed' unless $self->setup;
3445   return 'one-time charge' if $freq =~ /^(0|$)/;
3446   return 'active';
3447 }
3448
3449 =item ucfirst_status
3450
3451 Returns the status with the first character capitalized.
3452
3453 =cut
3454
3455 sub ucfirst_status {
3456   ucfirst(shift->status);
3457 }
3458
3459 =item statuses
3460
3461 Class method that returns the list of possible status strings for packages
3462 (see L<the status method|/status>).  For example:
3463
3464   @statuses = FS::cust_pkg->statuses();
3465
3466 =cut
3467
3468 tie my %statuscolor, 'Tie::IxHash',
3469   'on hold'         => 'FF00F5', #brighter purple!
3470   'not yet billed'  => '009999', #teal? cyan?
3471   'one-time charge' => '0000CC', #blue  #'000000',
3472   'active'          => '00CC00',
3473   'suspended'       => 'FF9900',
3474   'cancelled'       => 'FF0000',
3475 ;
3476
3477 sub statuses {
3478   my $self = shift; #could be class...
3479   #grep { $_ !~ /^(not yet billed)$/ } #this is a dumb status anyway
3480   #                                    # mayble split btw one-time vs. recur
3481     keys %statuscolor;
3482 }
3483
3484 sub statuscolors {
3485   #my $self = shift;
3486   \%statuscolor;
3487 }
3488
3489 =item statuscolor
3490
3491 Returns a hex triplet color string for this package's status.
3492
3493 =cut
3494
3495 sub statuscolor {
3496   my $self = shift;
3497   $statuscolor{$self->status};
3498 }
3499
3500 =item is_status_delay_cancel
3501
3502 Returns true if part_pkg has option delay_cancel,
3503 cust_pkg status is 'suspended' and expire is set
3504 to cancel package within the next day (or however
3505 many days are set in global config part_pkg-delay_cancel-days.
3506
3507 This is not a real status, this only meant for hacking display
3508 values, because otherwise treating the package as suspended is
3509 really the whole point of the delay_cancel option.
3510
3511 =cut
3512
3513 sub is_status_delay_cancel {
3514   my ($self) = @_;
3515   if ( $self->main_pkgnum and $self->pkglinknum ) {
3516     return $self->main_pkg->is_status_delay_cancel;
3517   }
3518   return 0 unless $self->part_pkg->option('delay_cancel',1);
3519   return 0 unless $self->status eq 'suspended';
3520   return 0 unless $self->expire;
3521   my $conf = new FS::Conf;
3522   my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
3523   my $expsecs = 60*60*24*$expdays;
3524   return 0 unless $self->expire < time + $expsecs;
3525   return 1;
3526 }
3527
3528 =item pkg_label
3529
3530 Returns a label for this package.  (Currently "pkgnum: pkg - comment" or
3531 "pkg - comment" depending on user preference).
3532
3533 =cut
3534
3535 sub pkg_label {
3536   my $self = shift;
3537   my $label = $self->part_pkg->pkg_comment( 'nopkgpart' => 1 );
3538   $label = $self->pkgnum. ": $label"
3539     if $FS::CurrentUser::CurrentUser->option('show_pkgnum');
3540   $label;
3541 }
3542
3543 =item pkg_label_long
3544
3545 Returns a long label for this package, adding the primary service's label to
3546 pkg_label.
3547
3548 =cut
3549
3550 sub pkg_label_long {
3551   my $self = shift;
3552   my $label = $self->pkg_label;
3553   my $cust_svc = $self->primary_cust_svc;
3554   $label .= ' ('. ($cust_svc->label)[1]. ')' if $cust_svc;
3555   $label;
3556 }
3557
3558 =item pkg_locale
3559
3560 Returns a customer-localized label for this package.
3561
3562 =cut
3563
3564 sub pkg_locale {
3565   my $self = shift;
3566   $self->part_pkg->pkg_locale( $self->cust_main->locale );
3567 }
3568
3569 =item primary_cust_svc
3570
3571 Returns a primary service (as FS::cust_svc object) if one can be identified.
3572
3573 =cut
3574
3575 #for labeling purposes - might not 100% match up with part_pkg->svcpart's idea
3576
3577 sub primary_cust_svc {
3578   my $self = shift;
3579
3580   my @cust_svc = $self->cust_svc;
3581
3582   return '' unless @cust_svc; #no serivces - irrelevant then
3583
3584   return $cust_svc[0] if scalar(@cust_svc) == 1; #always return a single service
3585
3586   # primary service as specified in the package definition
3587   # or exactly one service definition with quantity one
3588   my $svcpart = $self->part_pkg->svcpart;
3589   @cust_svc = grep { $_->svcpart == $svcpart } @cust_svc;
3590   return $cust_svc[0] if scalar(@cust_svc) == 1;
3591
3592   #couldn't identify one thing..
3593   return '';
3594 }
3595
3596 =item labels
3597
3598 Returns a list of lists, calling the label method for all services
3599 (see L<FS::cust_svc>) of this billing item.
3600
3601 =cut
3602
3603 sub labels {
3604   my $self = shift;
3605   map { [ $_->label ] } $self->cust_svc;
3606 }
3607
3608 =item h_labels END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3609
3610 Like the labels method, but returns historical information on services that
3611 were active as of END_TIMESTAMP and (optionally) not cancelled before
3612 START_TIMESTAMP.  If MODE is 'I' (for 'invoice'), services with the
3613 I<pkg_svc.hidden> flag will be omitted.
3614
3615 Returns a list of lists, calling the label method for all (historical) services
3616 (see L<FS::h_cust_svc>) of this billing item.
3617
3618 =cut
3619
3620 sub h_labels {
3621   my $self = shift;
3622   warn "$me _h_labels called on $self\n"
3623     if $DEBUG;
3624   map { [ $_->label(@_) ] } $self->h_cust_svc(@_);
3625 }
3626
3627 =item labels_short
3628
3629 Like labels, except returns a simple flat list, and shortens long
3630 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3631 identical services to one line that lists the service label and the number of
3632 individual services rather than individual items.
3633
3634 =cut
3635
3636 sub labels_short {
3637   shift->_labels_short( 'labels', @_ );
3638 }
3639
3640 =item h_labels_short END_TIMESTAMP [ START_TIMESTAMP ]
3641
3642 Like h_labels, except returns a simple flat list, and shortens long
3643 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3644 identical services to one line that lists the service label and the number of
3645 individual services rather than individual items.
3646
3647 =cut
3648
3649 sub h_labels_short {
3650   shift->_labels_short( 'h_labels', @_ );
3651 }
3652
3653 sub _labels_short {
3654   my( $self, $method ) = ( shift, shift );
3655
3656   warn "$me _labels_short called on $self with $method method\n"
3657     if $DEBUG;
3658
3659   my $conf = new FS::Conf;
3660   my $max_same_services = $conf->config('cust_bill-max_same_services') || 5;
3661
3662   warn "$me _labels_short populating \%labels\n"
3663     if $DEBUG;
3664
3665   my %labels;
3666   #tie %labels, 'Tie::IxHash';
3667   push @{ $labels{$_->[0]} }, $_->[1]
3668     foreach $self->$method(@_);
3669
3670   warn "$me _labels_short populating \@labels\n"
3671     if $DEBUG;
3672
3673   my @labels;
3674   foreach my $label ( keys %labels ) {
3675     my %seen = ();
3676     my @values = grep { ! $seen{$_}++ } @{ $labels{$label} };
3677     my $num = scalar(@values);
3678     warn "$me _labels_short $num items for $label\n"
3679       if $DEBUG;
3680
3681     if ( $num > $max_same_services ) {
3682       warn "$me _labels_short   more than $max_same_services, so summarizing\n"
3683         if $DEBUG;
3684       push @labels, "$label ($num)";
3685     } else {
3686       if ( $conf->exists('cust_bill-consolidate_services') ) {
3687         warn "$me _labels_short   consolidating services\n"
3688           if $DEBUG;
3689         # push @labels, "$label: ". join(', ', @values);
3690         while ( @values ) {
3691           my $detail = "$label: ";
3692           $detail .= shift(@values). ', '
3693             while @values
3694                && ( length($detail.$values[0]) < 78 || $detail eq "$label: " );
3695           $detail =~ s/, $//;
3696           push @labels, $detail;
3697         }
3698         warn "$me _labels_short   done consolidating services\n"
3699           if $DEBUG;
3700       } else {
3701         warn "$me _labels_short   adding service data\n"
3702           if $DEBUG;
3703         push @labels, map { "$label: $_" } @values;
3704       }
3705     }
3706   }
3707
3708  @labels;
3709
3710 }
3711
3712 =item cust_main
3713
3714 Returns the parent customer object (see L<FS::cust_main>).
3715
3716 =cut
3717
3718 sub cust_main {
3719   my $self = shift;
3720   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
3721 }
3722
3723 =item balance
3724
3725 Returns the balance for this specific package, when using
3726 experimental package balance.
3727
3728 =cut
3729
3730 sub balance {
3731   my $self = shift;
3732   $self->cust_main->balance_pkgnum( $self->pkgnum );
3733 }
3734
3735 #these subs are in location_Mixin.pm now... unfortunately the POD doesn't mixin
3736
3737 =item cust_location
3738
3739 Returns the location object, if any (see L<FS::cust_location>).
3740
3741 =item cust_location_or_main
3742
3743 If this package is associated with a location, returns the locaiton (see
3744 L<FS::cust_location>), otherwise returns the customer (see L<FS::cust_main>).
3745
3746 =item location_label [ OPTION => VALUE ... ]
3747
3748 Returns the label of the location object (see L<FS::cust_location>).
3749
3750 =cut
3751
3752 #end of subs in location_Mixin.pm now... unfortunately the POD doesn't mixin
3753
3754 =item tax_locationnum
3755
3756 Returns the foreign key to a L<FS::cust_location> object for calculating
3757 tax on this package, as determined by the C<tax-pkg_address> and
3758 C<tax-ship_address> configuration flags.
3759
3760 =cut
3761
3762 sub tax_locationnum {
3763   my $self = shift;
3764   my $conf = FS::Conf->new;
3765   if ( $conf->exists('tax-pkg_address') ) {
3766     return $self->locationnum;
3767   }
3768   elsif ( $conf->exists('tax-ship_address') ) {
3769     return $self->cust_main->ship_locationnum;
3770   }
3771   else {
3772     return $self->cust_main->bill_locationnum;
3773   }
3774 }
3775
3776 =item tax_location
3777
3778 Returns the L<FS::cust_location> object for tax_locationnum.
3779
3780 =cut
3781
3782 sub tax_location {
3783   my $self = shift;
3784   my $conf = FS::Conf->new;
3785   if ( $conf->exists('tax-pkg_address') and $self->locationnum ) {
3786     return FS::cust_location->by_key($self->locationnum);
3787   }
3788   elsif ( $conf->exists('tax-ship_address') ) {
3789     return $self->cust_main->ship_location;
3790   }
3791   else {
3792     return $self->cust_main->bill_location;
3793   }
3794 }
3795
3796 =item seconds_since TIMESTAMP
3797
3798 Returns the number of seconds all accounts (see L<FS::svc_acct>) in this
3799 package have been online since TIMESTAMP, according to the session monitor.
3800
3801 TIMESTAMP is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
3802 L<Time::Local> and L<Date::Parse> for conversion functions.
3803
3804 =cut
3805
3806 sub seconds_since {
3807   my($self, $since) = @_;
3808   my $seconds = 0;
3809
3810   foreach my $cust_svc (
3811     grep { $_->part_svc->svcdb eq 'svc_acct' } $self->cust_svc
3812   ) {
3813     $seconds += $cust_svc->seconds_since($since);
3814   }
3815
3816   $seconds;
3817
3818 }
3819
3820 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
3821
3822 Returns the numbers of seconds all accounts (see L<FS::svc_acct>) in this
3823 package have been online between TIMESTAMP_START (inclusive) and TIMESTAMP_END
3824 (exclusive).
3825
3826 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3827 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3828 functions.
3829
3830
3831 =cut
3832
3833 sub seconds_since_sqlradacct {
3834   my($self, $start, $end) = @_;
3835
3836   my $seconds = 0;
3837
3838   foreach my $cust_svc (
3839     grep {
3840       my $part_svc = $_->part_svc;
3841       $part_svc->svcdb eq 'svc_acct'
3842         && scalar($part_svc->part_export_usage);
3843     } $self->cust_svc
3844   ) {
3845     $seconds += $cust_svc->seconds_since_sqlradacct($start, $end);
3846   }
3847
3848   $seconds;
3849
3850 }
3851
3852 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
3853
3854 Returns the sum of the given attribute for all accounts (see L<FS::svc_acct>)
3855 in this package for sessions ending between TIMESTAMP_START (inclusive) and
3856 TIMESTAMP_END
3857 (exclusive).
3858
3859 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3860 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3861 functions.
3862
3863 =cut
3864
3865 sub attribute_since_sqlradacct {
3866   my($self, $start, $end, $attrib) = @_;
3867
3868   my $sum = 0;
3869
3870   foreach my $cust_svc (
3871     grep {
3872       my $part_svc = $_->part_svc;
3873       scalar($part_svc->part_export_usage);
3874     } $self->cust_svc
3875   ) {
3876     $sum += $cust_svc->attribute_since_sqlradacct($start, $end, $attrib);
3877   }
3878
3879   $sum;
3880
3881 }
3882
3883 =item quantity
3884
3885 =cut
3886
3887 sub quantity {
3888   my( $self, $value ) = @_;
3889   if ( defined($value) ) {
3890     $self->setfield('quantity', $value);
3891   }
3892   $self->getfield('quantity') || 1;
3893 }
3894
3895 =item transfer DEST_PKGNUM | DEST_CUST_PKG, [ OPTION => VALUE ... ]
3896
3897 Transfers as many services as possible from this package to another package.
3898
3899 The destination package can be specified by pkgnum by passing an FS::cust_pkg
3900 object.  The destination package must already exist.
3901
3902 Services are moved only if the destination allows services with the correct
3903 I<svcpart> (not svcdb), unless the B<change_svcpart> option is set true.  Use
3904 this option with caution!  No provision is made for export differences
3905 between the old and new service definitions.  Probably only should be used
3906 when your exports for all service definitions of a given svcdb are identical.
3907 (attempt a transfer without it first, to move all possible svcpart-matching
3908 services)
3909
3910 Any services that can't be moved remain in the original package.
3911
3912 Returns an error, if there is one; otherwise, returns the number of services
3913 that couldn't be moved.
3914
3915 =cut
3916
3917 sub transfer {
3918   my ($self, $dest_pkgnum, %opt) = @_;
3919
3920   my $remaining = 0;
3921   my $dest;
3922   my %target;
3923
3924   if (ref ($dest_pkgnum) eq 'FS::cust_pkg') {
3925     $dest = $dest_pkgnum;
3926     $dest_pkgnum = $dest->pkgnum;
3927   } else {
3928     $dest = qsearchs('cust_pkg', { pkgnum => $dest_pkgnum });
3929   }
3930
3931   return ('Package does not exist: '.$dest_pkgnum) unless $dest;
3932
3933   foreach my $pkg_svc ( $dest->part_pkg->pkg_svc ) {
3934     $target{$pkg_svc->svcpart} = $pkg_svc->quantity * ( $dest->quantity || 1 );
3935   }
3936
3937   foreach my $cust_svc ($dest->cust_svc) {
3938     $target{$cust_svc->svcpart}--;
3939   }
3940
3941   my %svcpart2svcparts = ();
3942   if ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3943     warn "change_svcpart option received, creating alternates list\n" if $DEBUG;
3944     foreach my $svcpart ( map { $_->svcpart } $self->cust_svc ) {
3945       next if exists $svcpart2svcparts{$svcpart};
3946       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
3947       $svcpart2svcparts{$svcpart} = [
3948         map  { $_->[0] }
3949         sort { $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] }
3950         map {
3951               my $pkg_svc = qsearchs( 'pkg_svc', { 'pkgpart' => $dest->pkgpart,
3952                                                    'svcpart' => $_          } );
3953               [ $_,
3954                 $pkg_svc ? $pkg_svc->primary_svc : '',
3955                 $pkg_svc ? $pkg_svc->quantity : 0,
3956               ];
3957             }
3958
3959         grep { $_ != $svcpart }
3960         map  { $_->svcpart }
3961         qsearch('part_svc', { 'svcdb' => $part_svc->svcdb } )
3962       ];
3963       warn "alternates for svcpart $svcpart: ".
3964            join(', ', @{$svcpart2svcparts{$svcpart}}). "\n"
3965         if $DEBUG;
3966     }
3967   }
3968
3969   my $error;
3970   foreach my $cust_svc ($self->cust_svc) {
3971     my $svcnum = $cust_svc->svcnum;
3972     if($target{$cust_svc->svcpart} > 0
3973        or $FS::cust_svc::ignore_quantity) { # maybe should be a 'force' option
3974       $target{$cust_svc->svcpart}--;
3975       my $new = new FS::cust_svc { $cust_svc->hash };
3976       $new->pkgnum($dest_pkgnum);
3977       $error = $new->replace($cust_svc);
3978     } elsif ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3979       if ( $DEBUG ) {
3980         warn "looking for alternates for svcpart ". $cust_svc->svcpart. "\n";
3981         warn "alternates to consider: ".
3982              join(', ', @{$svcpart2svcparts{$cust_svc->svcpart}}). "\n";
3983       }
3984       my @alternate = grep {
3985                              warn "considering alternate svcpart $_: ".
3986                                   "$target{$_} available in new package\n"
3987                                if $DEBUG;
3988                              $target{$_} > 0;
3989                            } @{$svcpart2svcparts{$cust_svc->svcpart}};
3990       if ( @alternate ) {
3991         warn "alternate(s) found\n" if $DEBUG;
3992         my $change_svcpart = $alternate[0];
3993         $target{$change_svcpart}--;
3994         my $new = new FS::cust_svc { $cust_svc->hash };
3995         $new->svcpart($change_svcpart);
3996         $new->pkgnum($dest_pkgnum);
3997         $error = $new->replace($cust_svc);
3998       } else {
3999         $remaining++;
4000       }
4001     } else {
4002       $remaining++
4003     }
4004     if ( $error ) {
4005       my @label = $cust_svc->label;
4006       return "service $label[1]: $error";
4007     }
4008   }
4009   return $remaining;
4010 }
4011
4012 =item grab_svcnums SVCNUM, SVCNUM ...
4013
4014 Change the pkgnum for the provided services to this packages.  If there is an
4015 error, returns the error, otherwise returns false.
4016
4017 =cut
4018
4019 sub grab_svcnums {
4020   my $self = shift;
4021   my @svcnum = @_;
4022
4023   local $SIG{HUP} = 'IGNORE';
4024   local $SIG{INT} = 'IGNORE';
4025   local $SIG{QUIT} = 'IGNORE';
4026   local $SIG{TERM} = 'IGNORE';
4027   local $SIG{TSTP} = 'IGNORE';
4028   local $SIG{PIPE} = 'IGNORE';
4029
4030   my $oldAutoCommit = $FS::UID::AutoCommit;
4031   local $FS::UID::AutoCommit = 0;
4032   my $dbh = dbh;
4033
4034   foreach my $svcnum (@svcnum) {
4035     my $cust_svc = qsearchs('cust_svc', { svcnum=>$svcnum } ) or do {
4036       $dbh->rollback if $oldAutoCommit;
4037       return "unknown svcnum $svcnum";
4038     };
4039     $cust_svc->pkgnum( $self->pkgnum );
4040     my $error = $cust_svc->replace;
4041     if ( $error ) {
4042       $dbh->rollback if $oldAutoCommit;
4043       return $error;
4044     }
4045   }
4046
4047   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4048   '';
4049
4050 }
4051
4052 =item reexport
4053
4054 This method is deprecated.  See the I<depend_jobnum> option to the insert and
4055 order_pkgs methods in FS::cust_main for a better way to defer provisioning.
4056
4057 =cut
4058
4059 sub reexport {
4060   my $self = shift;
4061
4062   local $SIG{HUP} = 'IGNORE';
4063   local $SIG{INT} = 'IGNORE';
4064   local $SIG{QUIT} = 'IGNORE';
4065   local $SIG{TERM} = 'IGNORE';
4066   local $SIG{TSTP} = 'IGNORE';
4067   local $SIG{PIPE} = 'IGNORE';
4068
4069   my $oldAutoCommit = $FS::UID::AutoCommit;
4070   local $FS::UID::AutoCommit = 0;
4071   my $dbh = dbh;
4072
4073   foreach my $cust_svc ( $self->cust_svc ) {
4074     #false laziness w/svc_Common::insert
4075     my $svc_x = $cust_svc->svc_x;
4076     foreach my $part_export ( $cust_svc->part_svc->part_export ) {
4077       my $error = $part_export->export_insert($svc_x);
4078       if ( $error ) {
4079         $dbh->rollback if $oldAutoCommit;
4080         return $error;
4081       }
4082     }
4083   }
4084
4085   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4086   '';
4087
4088 }
4089
4090 =item export_pkg_change OLD_CUST_PKG
4091
4092 Calls the "pkg_change" export action for all services attached to this package.
4093
4094 =cut
4095
4096 sub export_pkg_change {
4097   my( $self, $old )  = ( shift, shift );
4098
4099   local $SIG{HUP} = 'IGNORE';
4100   local $SIG{INT} = 'IGNORE';
4101   local $SIG{QUIT} = 'IGNORE';
4102   local $SIG{TERM} = 'IGNORE';
4103   local $SIG{TSTP} = 'IGNORE';
4104   local $SIG{PIPE} = 'IGNORE';
4105
4106   my $oldAutoCommit = $FS::UID::AutoCommit;
4107   local $FS::UID::AutoCommit = 0;
4108   my $dbh = dbh;
4109
4110   foreach my $svc_x ( map $_->svc_x, $self->cust_svc ) {
4111     my $error = $svc_x->export('pkg_change', $self, $old);
4112     if ( $error ) {
4113       $dbh->rollback if $oldAutoCommit;
4114       return $error;
4115     }
4116   }
4117
4118   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4119   '';
4120
4121 }
4122
4123 =item insert_reason
4124
4125 Associates this package with a (suspension or cancellation) reason (see
4126 L<FS::cust_pkg_reason>, possibly inserting a new reason on the fly (see
4127 L<FS::reason>).
4128
4129 Available options are:
4130
4131 =over 4
4132
4133 =item reason
4134
4135 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
4136
4137 =item reason_otaker
4138
4139 the access_user (see L<FS::access_user>) providing the reason
4140
4141 =item date
4142
4143 a unix timestamp
4144
4145 =item action
4146
4147 the action (cancel, susp, adjourn, expire) associated with the reason
4148
4149 =back
4150
4151 If there is an error, returns the error, otherwise returns false.
4152
4153 =cut
4154
4155 sub insert_reason {
4156   my ($self, %options) = @_;
4157
4158   my $otaker = $options{reason_otaker} ||
4159                $FS::CurrentUser::CurrentUser->username;
4160
4161   my $reasonnum;
4162   if ( $options{'reason'} =~ /^(\d+)$/ ) {
4163
4164     $reasonnum = $1;
4165
4166   } elsif ( ref($options{'reason'}) ) {
4167
4168     return 'Enter a new reason (or select an existing one)'
4169       unless $options{'reason'}->{'reason'} !~ /^\s*$/;
4170
4171     my $reason = new FS::reason({
4172       'reason_type' => $options{'reason'}->{'typenum'},
4173       'reason'      => $options{'reason'}->{'reason'},
4174     });
4175     my $error = $reason->insert;
4176     return $error if $error;
4177
4178     $reasonnum = $reason->reasonnum;
4179
4180   } else {
4181     return "Unparseable reason: ". $options{'reason'};
4182   }
4183
4184   my $cust_pkg_reason =
4185     new FS::cust_pkg_reason({ 'pkgnum'    => $self->pkgnum,
4186                               'reasonnum' => $reasonnum,
4187                               'otaker'    => $otaker,
4188                               'action'    => substr(uc($options{'action'}),0,1),
4189                               'date'      => $options{'date'}
4190                                                ? $options{'date'}
4191                                                : time,
4192                             });
4193
4194   $cust_pkg_reason->insert;
4195 }
4196
4197 =item insert_discount
4198
4199 Associates this package with a discount (see L<FS::cust_pkg_discount>, possibly
4200 inserting a new discount on the fly (see L<FS::discount>).
4201
4202 Available options are:
4203
4204 =over 4
4205
4206 =item discountnum
4207
4208 =back
4209
4210 If there is an error, returns the error, otherwise returns false.
4211
4212 =cut
4213
4214 sub insert_discount {
4215   #my ($self, %options) = @_;
4216   my $self = shift;
4217
4218   my $cust_pkg_discount = new FS::cust_pkg_discount {
4219     'pkgnum'      => $self->pkgnum,
4220     'discountnum' => $self->discountnum,
4221     'months_used' => 0,
4222     'end_date'    => '', #XXX
4223     #for the create a new discount case
4224     '_type'       => $self->discountnum__type,
4225     'amount'      => $self->discountnum_amount,
4226     'percent'     => $self->discountnum_percent,
4227     'months'      => $self->discountnum_months,
4228     'setup'      => $self->discountnum_setup,
4229     #'disabled'    => $self->discountnum_disabled,
4230   };
4231
4232   $cust_pkg_discount->insert;
4233 }
4234
4235 =item set_usage USAGE_VALUE_HASHREF
4236
4237 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4238 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4239 upbytes, downbytes, and totalbytes are appropriate keys.
4240
4241 All svc_accts which are part of this package have their values reset.
4242
4243 =cut
4244
4245 sub set_usage {
4246   my ($self, $valueref, %opt) = @_;
4247
4248   #only svc_acct can set_usage for now
4249   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4250     my $svc_x = $cust_svc->svc_x;
4251     $svc_x->set_usage($valueref, %opt)
4252       if $svc_x->can("set_usage");
4253   }
4254 }
4255
4256 =item recharge USAGE_VALUE_HASHREF
4257
4258 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4259 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4260 upbytes, downbytes, and totalbytes are appropriate keys.
4261
4262 All svc_accts which are part of this package have their values incremented.
4263
4264 =cut
4265
4266 sub recharge {
4267   my ($self, $valueref) = @_;
4268
4269   #only svc_acct can set_usage for now
4270   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4271     my $svc_x = $cust_svc->svc_x;
4272     $svc_x->recharge($valueref)
4273       if $svc_x->can("recharge");
4274   }
4275 }
4276
4277 =item cust_pkg_discount
4278
4279 =cut
4280
4281 sub cust_pkg_discount {
4282   my $self = shift;
4283   qsearch('cust_pkg_discount', { 'pkgnum' => $self->pkgnum } );
4284 }
4285
4286 =item cust_pkg_discount_active
4287
4288 =cut
4289
4290 sub cust_pkg_discount_active {
4291   my $self = shift;
4292   grep { $_->status eq 'active' } $self->cust_pkg_discount;
4293 }
4294
4295 =item cust_pkg_usage
4296
4297 Returns a list of all voice usage counters attached to this package.
4298
4299 =cut
4300
4301 sub cust_pkg_usage {
4302   my $self = shift;
4303   qsearch('cust_pkg_usage', { pkgnum => $self->pkgnum });
4304 }
4305
4306 =item apply_usage OPTIONS
4307
4308 Takes the following options:
4309 - cdr: a call detail record (L<FS::cdr>)
4310 - rate_detail: the rate determined for this call (L<FS::rate_detail>)
4311 - minutes: the maximum number of minutes to be charged
4312
4313 Finds available usage minutes for a call of this class, and subtracts
4314 up to that many minutes from the usage pool.  If the usage pool is empty,
4315 and the C<cdr-minutes_priority> global config option is set, minutes may
4316 be taken from other calls as well.  Either way, an allocation record will
4317 be created (L<FS::cdr_cust_pkg_usage>) and this method will return the
4318 number of minutes of usage applied to the call.
4319
4320 =cut
4321
4322 sub apply_usage {
4323   my ($self, %opt) = @_;
4324   my $cdr = $opt{cdr};
4325   my $rate_detail = $opt{rate_detail};
4326   my $minutes = $opt{minutes};
4327   my $classnum = $rate_detail->classnum;
4328   my $pkgnum = $self->pkgnum;
4329   my $custnum = $self->custnum;
4330
4331   local $SIG{HUP} = 'IGNORE';
4332   local $SIG{INT} = 'IGNORE';
4333   local $SIG{QUIT} = 'IGNORE';
4334   local $SIG{TERM} = 'IGNORE';
4335   local $SIG{TSTP} = 'IGNORE';
4336   local $SIG{PIPE} = 'IGNORE';
4337
4338   my $oldAutoCommit = $FS::UID::AutoCommit;
4339   local $FS::UID::AutoCommit = 0;
4340   my $dbh = dbh;
4341   my $order = FS::Conf->new->config('cdr-minutes_priority');
4342
4343   my $is_classnum;
4344   if ( $classnum ) {
4345     $is_classnum = ' part_pkg_usage_class.classnum = '.$classnum;
4346   } else {
4347     $is_classnum = ' part_pkg_usage_class.classnum IS NULL';
4348   }
4349   my @usage_recs = qsearch({
4350       'table'     => 'cust_pkg_usage',
4351       'addl_from' => ' JOIN part_pkg_usage       USING (pkgusagepart)'.
4352                      ' JOIN cust_pkg             USING (pkgnum)'.
4353                      ' JOIN part_pkg_usage_class USING (pkgusagepart)',
4354       'select'    => 'cust_pkg_usage.*',
4355       'extra_sql' => " WHERE ( cust_pkg.pkgnum = $pkgnum OR ".
4356                      " ( cust_pkg.custnum = $custnum AND ".
4357                      " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4358                      $is_classnum . ' AND '.
4359                      " cust_pkg_usage.minutes > 0",
4360       'order_by'  => " ORDER BY priority ASC",
4361   });
4362
4363   my $orig_minutes = $minutes;
4364   my $error;
4365   while (!$error and $minutes > 0 and @usage_recs) {
4366     my $cust_pkg_usage = shift @usage_recs;
4367     $cust_pkg_usage->select_for_update;
4368     my $cdr_cust_pkg_usage = FS::cdr_cust_pkg_usage->new({
4369         pkgusagenum => $cust_pkg_usage->pkgusagenum,
4370         acctid      => $cdr->acctid,
4371         minutes     => min($cust_pkg_usage->minutes, $minutes),
4372     });
4373     $cust_pkg_usage->set('minutes',
4374       $cust_pkg_usage->minutes - $cdr_cust_pkg_usage->minutes
4375     );
4376     $error = $cust_pkg_usage->replace || $cdr_cust_pkg_usage->insert;
4377     $minutes -= $cdr_cust_pkg_usage->minutes;
4378   }
4379   if ( $order and $minutes > 0 and !$error ) {
4380     # then try to steal minutes from another call
4381     my %search = (
4382         'table'     => 'cdr_cust_pkg_usage',
4383         'addl_from' => ' JOIN cust_pkg_usage        USING (pkgusagenum)'.
4384                        ' JOIN part_pkg_usage        USING (pkgusagepart)'.
4385                        ' JOIN cust_pkg              USING (pkgnum)'.
4386                        ' JOIN part_pkg_usage_class  USING (pkgusagepart)'.
4387                        ' JOIN cdr                   USING (acctid)',
4388         'select'    => 'cdr_cust_pkg_usage.*',
4389         'extra_sql' => " WHERE cdr.freesidestatus = 'rated' AND ".
4390                        " ( cust_pkg.pkgnum = $pkgnum OR ".
4391                        " ( cust_pkg.custnum = $custnum AND ".
4392                        " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4393                        " part_pkg_usage_class.classnum = $classnum",
4394         'order_by'  => ' ORDER BY part_pkg_usage.priority ASC',
4395     );
4396     if ( $order eq 'time' ) {
4397       # find CDRs that are using minutes, but have a later startdate
4398       # than this call
4399       my $startdate = $cdr->startdate;
4400       if ($startdate !~ /^\d+$/) {
4401         die "bad cdr startdate '$startdate'";
4402       }
4403       $search{'extra_sql'} .= " AND cdr.startdate > $startdate";
4404       # minimize needless reshuffling
4405       $search{'order_by'} .= ', cdr.startdate DESC';
4406     } else {
4407       # XXX may not work correctly with rate_time schedules.  Could
4408       # fix this by storing ratedetailnum in cdr_cust_pkg_usage, I
4409       # think...
4410       $search{'addl_from'} .=
4411         ' JOIN rate_detail'.
4412         ' ON (cdr.rated_ratedetailnum = rate_detail.ratedetailnum)';
4413       if ( $order eq 'rate_high' ) {
4414         $search{'extra_sql'} .= ' AND rate_detail.min_charge < '.
4415                                 $rate_detail->min_charge;
4416         $search{'order_by'} .= ', rate_detail.min_charge ASC';
4417       } elsif ( $order eq 'rate_low' ) {
4418         $search{'extra_sql'} .= ' AND rate_detail.min_charge > '.
4419                                 $rate_detail->min_charge;
4420         $search{'order_by'} .= ', rate_detail.min_charge DESC';
4421       } else {
4422         #  this should really never happen
4423         die "invalid cdr-minutes_priority value '$order'\n";
4424       }
4425     }
4426     my @cdr_usage_recs = qsearch(\%search);
4427     my %reproc_cdrs;
4428     while (!$error and @cdr_usage_recs and $minutes > 0) {
4429       my $cdr_cust_pkg_usage = shift @cdr_usage_recs;
4430       my $cust_pkg_usage = $cdr_cust_pkg_usage->cust_pkg_usage;
4431       my $old_cdr = $cdr_cust_pkg_usage->cdr;
4432       $reproc_cdrs{$old_cdr->acctid} = $old_cdr;
4433       $cdr_cust_pkg_usage->select_for_update;
4434       $old_cdr->select_for_update;
4435       $cust_pkg_usage->select_for_update;
4436       # in case someone else stole the usage from this CDR
4437       # while waiting for the lock...
4438       next if $old_cdr->acctid != $cdr_cust_pkg_usage->acctid;
4439       # steal the usage allocation and flag the old CDR for reprocessing
4440       $cdr_cust_pkg_usage->set('acctid', $cdr->acctid);
4441       # if the allocation is more minutes than we need, adjust it...
4442       my $delta = $cdr_cust_pkg_usage->minutes - $minutes;
4443       if ( $delta > 0 ) {
4444         $cdr_cust_pkg_usage->set('minutes', $minutes);
4445         $cust_pkg_usage->set('minutes', $cust_pkg_usage->minutes + $delta);
4446         $error = $cust_pkg_usage->replace;
4447       }
4448       #warn 'CDR '.$cdr->acctid . ' stealing allocation '.$cdr_cust_pkg_usage->cdrusagenum.' from CDR '.$old_cdr->acctid."\n";
4449       $error ||= $cdr_cust_pkg_usage->replace;
4450       # deduct the stolen minutes
4451       $minutes -= $cdr_cust_pkg_usage->minutes;
4452     }
4453     # after all minute-stealing is done, reset the affected CDRs
4454     foreach (values %reproc_cdrs) {
4455       $error ||= $_->set_status('');
4456       # XXX or should we just call $cdr->rate right here?
4457       # it's not like we can create a loop this way, since the min_charge
4458       # or call time has to go monotonically in one direction.
4459       # we COULD get some very deep recursions going, though...
4460     }
4461   } # if $order and $minutes
4462   if ( $error ) {
4463     $dbh->rollback;
4464     die "error applying included minutes\npkgnum ".$self->pkgnum.", class $classnum, acctid ".$cdr->acctid."\n$error\n"
4465   } else {
4466     $dbh->commit if $oldAutoCommit;
4467     return $orig_minutes - $minutes;
4468   }
4469 }
4470
4471 =item supplemental_pkgs
4472
4473 Returns a list of all packages supplemental to this one.
4474
4475 =cut
4476
4477 sub supplemental_pkgs {
4478   my $self = shift;
4479   qsearch('cust_pkg', { 'main_pkgnum' => $self->pkgnum });
4480 }
4481
4482 =item main_pkg
4483
4484 Returns the package that this one is supplemental to, if any.
4485
4486 =cut
4487
4488 sub main_pkg {
4489   my $self = shift;
4490   if ( $self->main_pkgnum ) {
4491     return FS::cust_pkg->by_key($self->main_pkgnum);
4492   }
4493   return;
4494 }
4495
4496 =back
4497
4498 =head1 CLASS METHODS
4499
4500 =over 4
4501
4502 =item recurring_sql
4503
4504 Returns an SQL expression identifying recurring packages.
4505
4506 =cut
4507
4508 sub recurring_sql { "
4509   '0' != ( select freq from part_pkg
4510              where cust_pkg.pkgpart = part_pkg.pkgpart )
4511 "; }
4512
4513 =item onetime_sql
4514
4515 Returns an SQL expression identifying one-time packages.
4516
4517 =cut
4518
4519 sub onetime_sql { "
4520   '0' = ( select freq from part_pkg
4521             where cust_pkg.pkgpart = part_pkg.pkgpart )
4522 "; }
4523
4524 =item ordered_sql
4525
4526 Returns an SQL expression identifying ordered packages (recurring packages not
4527 yet billed).
4528
4529 =cut
4530
4531 sub ordered_sql {
4532    $_[0]->recurring_sql. " AND ". $_[0]->not_yet_billed_sql;
4533 }
4534
4535 =item active_sql
4536
4537 Returns an SQL expression identifying active packages.
4538
4539 =cut
4540
4541 sub active_sql {
4542   $_[0]->recurring_sql. "
4543   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4544   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4545   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4546 "; }
4547
4548 =item not_yet_billed_sql
4549
4550 Returns an SQL expression identifying packages which have not yet been billed.
4551
4552 =cut
4553
4554 sub not_yet_billed_sql { "
4555       ( cust_pkg.setup  IS NULL OR cust_pkg.setup  = 0 )
4556   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4557   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4558 "; }
4559
4560 =item inactive_sql
4561
4562 Returns an SQL expression identifying inactive packages (one-time packages
4563 that are otherwise unsuspended/uncancelled).
4564
4565 =cut
4566
4567 sub inactive_sql { "
4568   ". $_[0]->onetime_sql(). "
4569   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4570   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4571   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4572 "; }
4573
4574 =item on_hold_sql
4575
4576 Returns an SQL expression identifying on-hold packages.
4577
4578 =cut
4579
4580 sub on_hold_sql {
4581   #$_[0]->recurring_sql(). ' AND '.
4582   "
4583         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel  = 0 )
4584     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp   != 0
4585     AND ( cust_pkg.setup  IS     NULL  OR cust_pkg.setup   = 0 )
4586   ";
4587 }
4588
4589 =item susp_sql
4590 =item suspended_sql
4591
4592 Returns an SQL expression identifying suspended packages.
4593
4594 =cut
4595
4596 sub suspended_sql { susp_sql(@_); }
4597 sub susp_sql {
4598   #$_[0]->recurring_sql(). ' AND '.
4599   "
4600         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel = 0 )
4601     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp  != 0
4602     AND   cust_pkg.setup  IS NOT NULL AND cust_pkg.setup != 0
4603   ";
4604 }
4605
4606 =item cancel_sql
4607 =item cancelled_sql
4608
4609 Returns an SQL exprression identifying cancelled packages.
4610
4611 =cut
4612
4613 sub cancelled_sql { cancel_sql(@_); }
4614 sub cancel_sql {
4615   #$_[0]->recurring_sql(). ' AND '.
4616   "cust_pkg.cancel IS NOT NULL AND cust_pkg.cancel != 0";
4617 }
4618
4619 =item status_sql
4620
4621 Returns an SQL expression to give the package status as a string.
4622
4623 =cut
4624
4625 sub status_sql {
4626 "CASE
4627   WHEN cust_pkg.cancel IS NOT NULL THEN 'cancelled'
4628   WHEN ( cust_pkg.susp IS NOT NULL AND cust_pkg.setup IS NULL ) THEN 'on hold'
4629   WHEN cust_pkg.susp IS NOT NULL THEN 'suspended'
4630   WHEN cust_pkg.setup IS NULL THEN 'not yet billed'
4631   WHEN ".onetime_sql()." THEN 'one-time charge'
4632   ELSE 'active'
4633 END"
4634 }
4635
4636 =item search HASHREF
4637
4638 (Class method)
4639
4640 Returns a qsearch hash expression to search for parameters specified in HASHREF.
4641 Valid parameters are
4642
4643 =over 4
4644
4645 =item agentnum
4646
4647 =item status
4648
4649 on hold, active, inactive (or one-time charge), suspended, canceled (or cancelled)
4650
4651 =item magic
4652
4653 Equivalent to "status", except that "canceled"/"cancelled" will exclude
4654 packages that were changed into a new package with the same pkgpart (i.e.
4655 location or quantity changes).
4656
4657 =item custom
4658
4659  boolean selects custom packages
4660
4661 =item classnum
4662
4663 =item pkgpart
4664
4665 pkgpart or arrayref or hashref of pkgparts
4666
4667 =item setup
4668
4669 arrayref of beginning and ending epoch date
4670
4671 =item last_bill
4672
4673 arrayref of beginning and ending epoch date
4674
4675 =item bill
4676
4677 arrayref of beginning and ending epoch date
4678
4679 =item adjourn
4680
4681 arrayref of beginning and ending epoch date
4682
4683 =item susp
4684
4685 arrayref of beginning and ending epoch date
4686
4687 =item expire
4688
4689 arrayref of beginning and ending epoch date
4690
4691 =item cancel
4692
4693 arrayref of beginning and ending epoch date
4694
4695 =item query
4696
4697 pkgnum or APKG_pkgnum
4698
4699 =item cust_fields
4700
4701 a value suited to passing to FS::UI::Web::cust_header
4702
4703 =item CurrentUser
4704
4705 specifies the user for agent virtualization
4706
4707 =item fcc_line
4708
4709 boolean; if true, returns only packages with more than 0 FCC phone lines.
4710
4711 =item state, country
4712
4713 Limit to packages with a service location in the specified state and country.
4714 For FCC 477 reporting, mostly.
4715
4716 =item location_cust
4717
4718 Limit to packages whose service locations are the same as the customer's
4719 default service location.
4720
4721 =item location_nocust
4722
4723 Limit to packages whose service locations are not the customer's default
4724 service location.
4725
4726 =item location_census
4727
4728 Limit to packages whose service locations have census tracts.
4729
4730 =item location_nocensus
4731
4732 Limit to packages whose service locations do not have a census tract.
4733
4734 =item location_geocode
4735
4736 Limit to packages whose locations have geocodes.
4737
4738 =item location_geocode
4739
4740 Limit to packages whose locations do not have geocodes.
4741
4742 =item towernum
4743
4744 Limit to packages associated with a svc_broadband, associated with a sector,
4745 associated with this towernum (or any of these, if it's an arrayref) (or NO
4746 towernum, if it's zero). This is an extreme niche case.
4747
4748 =item 477part, 477rownum, date
4749
4750 Limit to packages included in a specific row of one of the FCC 477 reports.
4751 '477part' is the section name (see L<FS::Report::FCC_477> methods), 'date'
4752 is the report as-of date (completely unrelated to the package setup/bill/
4753 other date fields), and '477rownum' is the row number of the report starting
4754 with zero. Row numbers have no inherent meaning, so this is useful only
4755 for explaining a 477 report you've already run.
4756
4757 =back
4758
4759 =cut
4760
4761 sub search {
4762   my ($class, $params) = @_;
4763   my @where = ();
4764
4765   ##
4766   # parse agent
4767   ##
4768
4769   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
4770     push @where,
4771       "cust_main.agentnum = $1";
4772   }
4773
4774   ##
4775   # parse cust_status
4776   ##
4777
4778   if ( $params->{'cust_status'} =~ /^([a-z]+)$/ ) {
4779     push @where, FS::cust_main->cust_status_sql . " = '$1' ";
4780   }
4781
4782   ##
4783   # parse customer sales person
4784   ##
4785
4786   if ( $params->{'cust_main_salesnum'} =~ /^(\d+)$/ ) {
4787     push @where, ($1 > 0) ? "cust_main.salesnum = $1"
4788                           : 'cust_main.salesnum IS NULL';
4789   }
4790
4791
4792   ##
4793   # parse sales person
4794   ##
4795
4796   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
4797     push @where, ($1 > 0) ? "cust_pkg.salesnum = $1"
4798                           : 'cust_pkg.salesnum IS NULL';
4799   }
4800
4801   ##
4802   # parse custnum
4803   ##
4804
4805   if ( $params->{'custnum'} =~ /^(\d+)$/ and $1 ) {
4806     push @where,
4807       "cust_pkg.custnum = $1";
4808   }
4809
4810   ##
4811   # custbatch
4812   ##
4813
4814   if ( $params->{'pkgbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
4815     push @where,
4816       "cust_pkg.pkgbatch = '$1'";
4817   }
4818
4819   ##
4820   # parse status
4821   ##
4822
4823   if (    $params->{'magic'}  eq 'active'
4824        || $params->{'status'} eq 'active' ) {
4825
4826     push @where, FS::cust_pkg->active_sql();
4827
4828   } elsif (    $params->{'magic'}  =~ /^not[ _]yet[ _]billed$/
4829             || $params->{'status'} =~ /^not[ _]yet[ _]billed$/ ) {
4830
4831     push @where, FS::cust_pkg->not_yet_billed_sql();
4832
4833   } elsif (    $params->{'magic'}  =~ /^(one-time charge|inactive)/
4834             || $params->{'status'} =~ /^(one-time charge|inactive)/ ) {
4835
4836     push @where, FS::cust_pkg->inactive_sql();
4837
4838   } elsif (    $params->{'magic'}  =~ /^on[ _]hold$/
4839             || $params->{'status'} =~ /^on[ _]hold$/ ) {
4840
4841     push @where, FS::cust_pkg->on_hold_sql();
4842
4843
4844   } elsif (    $params->{'magic'}  eq 'suspended'
4845             || $params->{'status'} eq 'suspended'  ) {
4846
4847     push @where, FS::cust_pkg->suspended_sql();
4848
4849   } elsif (    $params->{'magic'}  =~ /^cancell?ed$/
4850             || $params->{'status'} =~ /^cancell?ed$/ ) {
4851
4852     push @where, FS::cust_pkg->cancelled_sql();
4853
4854   }
4855
4856   ### special case: "magic" is used in detail links from browse/part_pkg,
4857   # where "cancelled" has the restriction "and not replaced with a package
4858   # of the same pkgpart".  Be consistent with that.
4859   ###
4860
4861   if ( $params->{'magic'} =~ /^cancell?ed$/ ) {
4862     my $new_pkgpart = "SELECT pkgpart FROM cust_pkg AS cust_pkg_next ".
4863                       "WHERE cust_pkg_next.change_pkgnum = cust_pkg.pkgnum";
4864     # ...may not exist, if this was just canceled and not changed; in that
4865     # case give it a "new pkgpart" that never equals the old pkgpart
4866     push @where, "COALESCE(($new_pkgpart), 0) != cust_pkg.pkgpart";
4867   }
4868
4869   ###
4870   # parse package class
4871   ###
4872
4873   if ( exists($params->{'classnum'}) ) {
4874
4875     my @classnum = ();
4876     if ( ref($params->{'classnum'}) ) {
4877
4878       if ( ref($params->{'classnum'}) eq 'HASH' ) {
4879         @classnum = grep $params->{'classnum'}{$_}, keys %{ $params->{'classnum'} };
4880       } elsif ( ref($params->{'classnum'}) eq 'ARRAY' ) {
4881         @classnum = @{ $params->{'classnum'} };
4882       } else {
4883         die 'unhandled classnum ref '. $params->{'classnum'};
4884       }
4885
4886
4887     } elsif ( $params->{'classnum'} =~ /^(\d*)$/ && $1 ne '0' ) {
4888       @classnum = ( $1 );
4889     }
4890
4891     if ( @classnum ) {
4892
4893       my @c_where = ();
4894       my @nums = grep $_, @classnum;
4895       push @c_where, 'part_pkg.classnum IN ('. join(',',@nums). ')' if @nums;
4896       my $null = scalar( grep { $_ eq '' } @classnum );
4897       push @c_where, 'part_pkg.classnum IS NULL' if $null;
4898
4899       if ( scalar(@c_where) == 1 ) {
4900         push @where, @c_where;
4901       } elsif ( @c_where ) {
4902         push @where, ' ( '. join(' OR ', @c_where). ' ) ';
4903       }
4904
4905     }
4906
4907
4908   }
4909
4910   ###
4911   # parse refnum (advertising source)
4912   ###
4913
4914   if ( exists($params->{'refnum'}) ) {
4915     my @refnum;
4916     if (ref $params->{'refnum'}) {
4917       @refnum = @{ $params->{'refnum'} };
4918     } else {
4919       @refnum = ( $params->{'refnum'} );
4920     }
4921     my $in = join(',', grep /^\d+$/, @refnum);
4922     push @where, "refnum IN($in)" if length $in;
4923   }
4924
4925   ###
4926   # parse package report options
4927   ###
4928
4929   my @report_option = ();
4930   if ( exists($params->{'report_option'}) ) {
4931     if ( ref($params->{'report_option'}) eq 'ARRAY' ) {
4932       @report_option = @{ $params->{'report_option'} };
4933     } elsif ( $params->{'report_option'} =~ /^([,\d]*)$/ ) {
4934       @report_option = split(',', $1);
4935     }
4936
4937   }
4938
4939   if (@report_option) {
4940     # this will result in the empty set for the dangling comma case as it should
4941     push @where,
4942       map{ "0 < ( SELECT count(*) FROM part_pkg_option
4943                     WHERE part_pkg_option.pkgpart = part_pkg.pkgpart
4944                     AND optionname = 'report_option_$_'
4945                     AND optionvalue = '1' )"
4946          } @report_option;
4947   }
4948
4949   foreach my $any ( grep /^report_option_any/, keys %$params ) {
4950
4951     my @report_option_any = ();
4952     if ( ref($params->{$any}) eq 'ARRAY' ) {
4953       @report_option_any = @{ $params->{$any} };
4954     } elsif ( $params->{$any} =~ /^([,\d]*)$/ ) {
4955       @report_option_any = split(',', $1);
4956     }
4957
4958     if (@report_option_any) {
4959       # this will result in the empty set for the dangling comma case as it should
4960       push @where, ' ( '. join(' OR ',
4961         map{ "0 < ( SELECT count(*) FROM part_pkg_option
4962                       WHERE part_pkg_option.pkgpart = part_pkg.pkgpart
4963                       AND optionname = 'report_option_$_'
4964                       AND optionvalue = '1' )"
4965            } @report_option_any
4966       ). ' ) ';
4967     }
4968
4969   }
4970
4971   ###
4972   # parse custom
4973   ###
4974
4975   push @where,  "part_pkg.custom = 'Y'" if $params->{custom};
4976
4977   ###
4978   # parse fcc_line
4979   ###
4980
4981   push @where,  "(part_pkg.fcc_ds0s > 0 OR pkg_class.fcc_ds0s > 0)"
4982                                                         if $params->{fcc_line};
4983
4984   ###
4985   # parse censustract
4986   ###
4987
4988   if ( exists($params->{'censustract'}) ) {
4989     $params->{'censustract'} =~ /^([.\d]*)$/;
4990     my $censustract = "cust_location.censustract = '$1'";
4991     $censustract .= ' OR cust_location.censustract is NULL' unless $1;
4992     push @where,  "( $censustract )";
4993   }
4994
4995   ###
4996   # parse censustract2
4997   ###
4998   if ( exists($params->{'censustract2'})
4999        && $params->{'censustract2'} =~ /^(\d*)$/
5000      )
5001   {
5002     if ($1) {
5003       push @where, "cust_location.censustract LIKE '$1%'";
5004     } else {
5005       push @where,
5006         "( cust_location.censustract = '' OR cust_location.censustract IS NULL )";
5007     }
5008   }
5009
5010   ###
5011   # parse country/state/zip
5012   ###
5013   for (qw(state country)) { # parsing rules are the same for these
5014   if ( exists($params->{$_})
5015     && uc($params->{$_}) =~ /^([A-Z]{2})$/ )
5016     {
5017       # XXX post-2.3 only--before that, state/country may be in cust_main
5018       push @where, "cust_location.$_ = '$1'";
5019     }
5020   }
5021   if ( exists($params->{zip}) ) {
5022     push @where, "cust_location.zip = " . dbh->quote($params->{zip});
5023   }
5024
5025   ###
5026   # location_* flags
5027   ###
5028   if ( $params->{location_cust} xor $params->{location_nocust} ) {
5029     my $op = $params->{location_cust} ? '=' : '!=';
5030     push @where, "cust_location.locationnum $op cust_main.ship_locationnum";
5031   }
5032   if ( $params->{location_census} xor $params->{location_nocensus} ) {
5033     my $op = $params->{location_census} ? "IS NOT NULL" : "IS NULL";
5034     push @where, "cust_location.censustract $op";
5035   }
5036   if ( $params->{location_geocode} xor $params->{location_nogeocode} ) {
5037     my $op = $params->{location_geocode} ? "IS NOT NULL" : "IS NULL";
5038     push @where, "cust_location.geocode $op";
5039   }
5040
5041   ###
5042   # parse part_pkg
5043   ###
5044
5045   if ( ref($params->{'pkgpart'}) ) {
5046
5047     my @pkgpart = ();
5048     if ( ref($params->{'pkgpart'}) eq 'HASH' ) {
5049       @pkgpart = grep $params->{'pkgpart'}{$_}, keys %{ $params->{'pkgpart'} };
5050     } elsif ( ref($params->{'pkgpart'}) eq 'ARRAY' ) {
5051       @pkgpart = @{ $params->{'pkgpart'} };
5052     } else {
5053       die 'unhandled pkgpart ref '. $params->{'pkgpart'};
5054     }
5055
5056     @pkgpart = grep /^(\d+)$/, @pkgpart;
5057
5058     push @where, 'pkgpart IN ('. join(',', @pkgpart). ')' if scalar(@pkgpart);
5059
5060   } elsif ( $params->{'pkgpart'} =~ /^(\d+)$/ ) {
5061     push @where, "pkgpart = $1";
5062   }
5063
5064   ###
5065   # parse dates
5066   ###
5067
5068   my $orderby = '';
5069
5070   #false laziness w/report_cust_pkg.html
5071   my %disable = (
5072     'all'             => {},
5073     'one-time charge' => { 'last_bill'=>1, 'bill'=>1, 'adjourn'=>1, 'susp'=>1, 'expire'=>1, 'cancel'=>1, },
5074     'active'          => { 'susp'=>1, 'cancel'=>1 },
5075     'suspended'       => { 'cancel' => 1 },
5076     'cancelled'       => {},
5077     ''                => {},
5078   );
5079
5080   if( exists($params->{'active'} ) ) {
5081     # This overrides all the other date-related fields, and includes packages
5082     # that were active at some time during the interval.  It excludes:
5083     # - packages that were set up after the end of the interval
5084     # - packages that were canceled before the start of the interval
5085     # - packages that were suspended before the start of the interval
5086     #   and are still suspended now
5087     my($beginning, $ending) = @{$params->{'active'}};
5088     push @where,
5089       "cust_pkg.setup IS NOT NULL",
5090       "cust_pkg.setup <= $ending",
5091       "(cust_pkg.cancel IS NULL OR cust_pkg.cancel >= $beginning )",
5092       "(cust_pkg.susp   IS NULL OR cust_pkg.susp   >= $beginning )",
5093       "NOT (".FS::cust_pkg->onetime_sql . ")";
5094   }
5095   else {
5096     my $exclude_change_from = 0;
5097     my $exclude_change_to = 0;
5098
5099     foreach my $field (qw( setup last_bill bill adjourn susp expire contract_end change_date cancel )) {
5100
5101       next unless exists($params->{$field});
5102
5103       my($beginning, $ending) = @{$params->{$field}};
5104
5105       next if $beginning == 0 && $ending == 4294967295;
5106
5107       push @where,
5108         "cust_pkg.$field IS NOT NULL",
5109         "cust_pkg.$field >= $beginning",
5110         "cust_pkg.$field <= $ending";
5111
5112       $orderby ||= "ORDER BY cust_pkg.$field";
5113
5114       if ( $field eq 'setup' ) {
5115         $exclude_change_from = 1;
5116       } elsif ( $field eq 'cancel' ) {
5117         $exclude_change_to = 1;
5118       } elsif ( $field eq 'change_date' ) {
5119         # if we are given setup and change_date ranges, and the setup date
5120         # falls in _both_ ranges, then include the package whether it was
5121         # a change or not
5122         $exclude_change_from = 0;
5123       }
5124     }
5125
5126     if ($exclude_change_from) {
5127       push @where, "change_pkgnum IS NULL";
5128     }
5129     if ($exclude_change_to) {
5130       # a join might be more efficient here
5131       push @where, "NOT EXISTS(
5132         SELECT 1 FROM cust_pkg AS changed_to_pkg
5133         WHERE cust_pkg.pkgnum = changed_to_pkg.change_pkgnum
5134       )";
5135     }
5136   }
5137
5138   $orderby ||= 'ORDER BY bill';
5139
5140   ###
5141   # parse magic, legacy, etc.
5142   ###
5143
5144   if ( $params->{'magic'} &&
5145        $params->{'magic'} =~ /^(active|inactive|suspended|cancell?ed)$/
5146   ) {
5147
5148     $orderby = 'ORDER BY pkgnum';
5149
5150     if ( $params->{'pkgpart'} =~ /^(\d+)$/ ) {
5151       push @where, "pkgpart = $1";
5152     }
5153
5154   } elsif ( $params->{'query'} eq 'pkgnum' ) {
5155
5156     $orderby = 'ORDER BY pkgnum';
5157
5158   } elsif ( $params->{'query'} eq 'APKG_pkgnum' ) {
5159
5160     $orderby = 'ORDER BY pkgnum';
5161
5162     push @where, '0 < (
5163       SELECT count(*) FROM pkg_svc
5164        WHERE pkg_svc.pkgpart =  cust_pkg.pkgpart
5165          AND pkg_svc.quantity > ( SELECT count(*) FROM cust_svc
5166                                    WHERE cust_svc.pkgnum  = cust_pkg.pkgnum
5167                                      AND cust_svc.svcpart = pkg_svc.svcpart
5168                                 )
5169     )';
5170
5171   }
5172
5173   ##
5174   # parse the extremely weird 'towernum' param
5175   ##
5176
5177   if ($params->{towernum}) {
5178     my $towernum = $params->{towernum};
5179     $towernum = [ $towernum ] if !ref($towernum);
5180     my $in = join(',', grep /^\d+$/, @$towernum);
5181     if (length $in) {
5182       # inefficient, but this is an obscure feature
5183       eval "use FS::Report::Table";
5184       FS::Report::Table->_init_tower_pkg_cache; # probably does nothing
5185       push @where, "EXISTS(
5186       SELECT 1 FROM tower_pkg_cache
5187       WHERE tower_pkg_cache.pkgnum = cust_pkg.pkgnum
5188         AND tower_pkg_cache.towernum IN ($in)
5189       )"
5190     }
5191   }
5192
5193   ##
5194   # parse the 477 report drill-down options
5195   ##
5196
5197   if ($params->{'477part'} =~ /^([a-z]+)$/) {
5198     my $section = $1;
5199     my ($date, $rownum, $agentnum);
5200     if ($params->{'date'} =~ /^(\d+)$/) {
5201       $date = $1;
5202     }
5203     if ($params->{'477rownum'} =~ /^(\d+)$/) {
5204       $rownum = $1;
5205     }
5206     if ($params->{'agentnum'} =~ /^(\d+)$/) {
5207       $agentnum = $1;
5208     }
5209     if ($date and defined($rownum)) {
5210       my $report = FS::Report::FCC_477->report($section,
5211         'date'      => $date,
5212         'agentnum'  => $agentnum,
5213         'detail'    => 1
5214       );
5215       my $pkgnums = $report->{detail}->[$rownum]
5216         or die "row $rownum is past the end of the report";
5217         # '0' so that if there are no pkgnums (empty string) it will create
5218         # a valid query that returns nothing
5219       warn "PKGNUMS:\n$pkgnums\n\n"; # XXX debug
5220
5221       # and this overrides everything
5222       @where = ( "cust_pkg.pkgnum IN($pkgnums)" );
5223     } # else we're missing some params, ignore the whole business
5224   }
5225
5226   ##
5227   # setup queries, links, subs, etc. for the search
5228   ##
5229
5230   # here is the agent virtualization
5231   if ($params->{CurrentUser}) {
5232     my $access_user =
5233       qsearchs('access_user', { username => $params->{CurrentUser} });
5234
5235     if ($access_user) {
5236       push @where, $access_user->agentnums_sql('table'=>'cust_main');
5237     } else {
5238       push @where, "1=0";
5239     }
5240   } else {
5241     push @where, $FS::CurrentUser::CurrentUser->agentnums_sql('table'=>'cust_main');
5242   }
5243
5244   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
5245
5246   my $addl_from = 'LEFT JOIN part_pkg  USING ( pkgpart  ) '.
5247                   'LEFT JOIN pkg_class ON ( part_pkg.classnum = pkg_class.classnum ) '.
5248                   'LEFT JOIN cust_location USING ( locationnum ) '.
5249                   FS::UI::Web::join_cust_main('cust_pkg', 'cust_pkg');
5250
5251   my $select;
5252   my $count_query;
5253   if ( $params->{'select_zip5'} ) {
5254     my $zip = 'cust_location.zip';
5255
5256     $select = "DISTINCT substr($zip,1,5) as zip";
5257     $orderby = "ORDER BY substr($zip,1,5)";
5258     $count_query = "SELECT COUNT( DISTINCT substr($zip,1,5) )";
5259   } else {
5260     $select = join(', ',
5261                          'cust_pkg.*',
5262                          ( map "part_pkg.$_", qw( pkg freq ) ),
5263                          'pkg_class.classname',
5264                          'cust_main.custnum AS cust_main_custnum',
5265                          FS::UI::Web::cust_sql_fields(
5266                            $params->{'cust_fields'}
5267                          ),
5268                   );
5269     $count_query = 'SELECT COUNT(*)';
5270   }
5271
5272   $count_query .= " FROM cust_pkg $addl_from $extra_sql";
5273
5274   my $sql_query = {
5275     'table'       => 'cust_pkg',
5276     'hashref'     => {},
5277     'select'      => $select,
5278     'extra_sql'   => $extra_sql,
5279     'order_by'    => $orderby,
5280     'addl_from'   => $addl_from,
5281     'count_query' => $count_query,
5282   };
5283
5284 }
5285
5286 =item fcc_477_count
5287
5288 Returns a list of two package counts.  The first is a count of packages
5289 based on the supplied criteria and the second is the count of residential
5290 packages with those same criteria.  Criteria are specified as in the search
5291 method.
5292
5293 =cut
5294
5295 sub fcc_477_count {
5296   my ($class, $params) = @_;
5297
5298   my $sql_query = $class->search( $params );
5299
5300   my $count_sql = delete($sql_query->{'count_query'});
5301   $count_sql =~ s/ FROM/,count(CASE WHEN cust_main.company IS NULL OR cust_main.company = '' THEN 1 END) FROM/
5302     or die "couldn't parse count_sql";
5303
5304   my $count_sth = dbh->prepare($count_sql)
5305     or die "Error preparing $count_sql: ". dbh->errstr;
5306   $count_sth->execute
5307     or die "Error executing $count_sql: ". $count_sth->errstr;
5308   my $count_arrayref = $count_sth->fetchrow_arrayref;
5309
5310   return ( @$count_arrayref );
5311
5312 }
5313
5314 =item tax_locationnum_sql
5315
5316 Returns an SQL expression for the tax location for a package, based
5317 on the settings of 'tax-pkg_address' and 'tax-ship_address'.
5318
5319 =cut
5320
5321 sub tax_locationnum_sql {
5322   my $conf = FS::Conf->new;
5323   if ( $conf->exists('tax-pkg_address') ) {
5324     'cust_pkg.locationnum';
5325   }
5326   elsif ( $conf->exists('tax-ship_address') ) {
5327     'cust_main.ship_locationnum';
5328   }
5329   else {
5330     'cust_main.bill_locationnum';
5331   }
5332 }
5333
5334 =item location_sql
5335
5336 Returns a list: the first item is an SQL fragment identifying matching
5337 packages/customers via location (taking into account shipping and package
5338 address taxation, if enabled), and subsequent items are the parameters to
5339 substitute for the placeholders in that fragment.
5340
5341 =cut
5342
5343 sub location_sql {
5344   my($class, %opt) = @_;
5345   my $ornull = $opt{'ornull'};
5346
5347   my $conf = new FS::Conf;
5348
5349   # '?' placeholders in _location_sql_where
5350   my $x = $ornull ? 3 : 2;
5351   my @bill_param = (
5352     ('district')x3,
5353     ('city')x3,
5354     ('county')x$x,
5355     ('state')x$x,
5356     'country'
5357   );
5358
5359   my $main_where;
5360   my @main_param;
5361   if ( $conf->exists('tax-ship_address') ) {
5362
5363     $main_where = "(
5364          (     ( ship_last IS NULL     OR  ship_last  = '' )
5365            AND ". _location_sql_where('cust_main', '', $ornull ). "
5366          )
5367       OR (       ship_last IS NOT NULL AND ship_last != ''
5368            AND ". _location_sql_where('cust_main', 'ship_', $ornull ). "
5369          )
5370     )";
5371     #    AND payby != 'COMP'
5372
5373     @main_param = ( @bill_param, @bill_param );
5374
5375   } else {
5376
5377     $main_where = _location_sql_where('cust_main'); # AND payby != 'COMP'
5378     @main_param = @bill_param;
5379
5380   }
5381
5382   my $where;
5383   my @param;
5384   if ( $conf->exists('tax-pkg_address') ) {
5385
5386     my $loc_where = _location_sql_where( 'cust_location', '', $ornull );
5387
5388     $where = " (
5389                     ( cust_pkg.locationnum IS     NULL AND $main_where )
5390                  OR ( cust_pkg.locationnum IS NOT NULL AND $loc_where  )
5391                )
5392              ";
5393     @param = ( @main_param, @bill_param );
5394
5395   } else {
5396
5397     $where = $main_where;
5398     @param = @main_param;
5399
5400   }
5401
5402   ( $where, @param );
5403
5404 }
5405
5406 #subroutine, helper for location_sql
5407 sub _location_sql_where {
5408   my $table  = shift;
5409   my $prefix = @_ ? shift : '';
5410   my $ornull = @_ ? shift : '';
5411
5412 #  $ornull             = $ornull          ? " OR ( ? IS NULL AND $table.${prefix}county IS NULL ) " : '';
5413
5414   $ornull = $ornull ? ' OR ? IS NULL ' : '';
5415
5416   my $or_empty_city     = " OR ( ? = '' AND $table.${prefix}city     IS NULL )";
5417   my $or_empty_county   = " OR ( ? = '' AND $table.${prefix}county   IS NULL )";
5418   my $or_empty_state    = " OR ( ? = '' AND $table.${prefix}state    IS NULL )";
5419
5420   my $text = (driver_name =~ /^mysql/i) ? 'char' : 'text';
5421
5422 #        ( $table.${prefix}city    = ? $or_empty_city   $ornull )
5423   "
5424         ( $table.district = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5425     AND ( $table.${prefix}city     = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5426     AND ( $table.${prefix}county   = ? $or_empty_county $ornull )
5427     AND ( $table.${prefix}state    = ? $or_empty_state  $ornull )
5428     AND   $table.${prefix}country  = ?
5429   ";
5430 }
5431
5432 sub _X_show_zero {
5433   my( $self, $what ) = @_;
5434
5435   my $what_show_zero = $what. '_show_zero';
5436   length($self->$what_show_zero())
5437     ? ($self->$what_show_zero() eq 'Y')
5438     : $self->part_pkg->$what_show_zero();
5439 }
5440
5441 =head1 SUBROUTINES
5442
5443 =over 4
5444
5445 =item order CUSTNUM, PKGPARTS_ARYREF, [ REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF [ REFNUM ] ] ]
5446
5447 Bulk cancel + order subroutine.  Perhaps slightly deprecated, only used by the
5448 bulk cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
5449
5450 CUSTNUM is a customer (see L<FS::cust_main>)
5451
5452 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5453 L<FS::part_pkg>) to order for this customer.  Duplicates are of course
5454 permitted.
5455
5456 REMOVE_PKGNUMS is an optional list of pkgnums specifying the billing items to
5457 remove for this customer.  The services (see L<FS::cust_svc>) are moved to the
5458 new billing items.  An error is returned if this is not possible (see
5459 L<FS::pkg_svc>).  An empty arrayref is equivalent to not specifying this
5460 parameter.
5461
5462 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5463 newly-created cust_pkg objects.
5464
5465 REFNUM, if specified, will specify the FS::pkg_referral record to be created
5466 and inserted.  Multiple FS::pkg_referral records can be created by
5467 setting I<refnum> to an array reference of refnums or a hash reference with
5468 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
5469 record will be created corresponding to cust_main.refnum.
5470
5471 =cut
5472
5473 sub order {
5474   my ($custnum, $pkgparts, $remove_pkgnum, $return_cust_pkg, $refnum) = @_;
5475
5476   my $conf = new FS::Conf;
5477
5478   # Transactionize this whole mess
5479   local $SIG{HUP} = 'IGNORE';
5480   local $SIG{INT} = 'IGNORE';
5481   local $SIG{QUIT} = 'IGNORE';
5482   local $SIG{TERM} = 'IGNORE';
5483   local $SIG{TSTP} = 'IGNORE';
5484   local $SIG{PIPE} = 'IGNORE';
5485
5486   my $oldAutoCommit = $FS::UID::AutoCommit;
5487   local $FS::UID::AutoCommit = 0;
5488   my $dbh = dbh;
5489
5490   my $error;
5491 #  my $cust_main = qsearchs('cust_main', { custnum => $custnum });
5492 #  return "Customer not found: $custnum" unless $cust_main;
5493
5494   warn "$me order: pkgnums to remove: ". join(',', @$remove_pkgnum). "\n"
5495     if $DEBUG;
5496
5497   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5498                          @$remove_pkgnum;
5499
5500   my $change = scalar(@old_cust_pkg) != 0;
5501
5502   my %hash = ();
5503   if ( scalar(@old_cust_pkg) == 1 && scalar(@$pkgparts) == 1 ) {
5504
5505     warn "$me order: changing pkgnum ". $old_cust_pkg[0]->pkgnum.
5506          " to pkgpart ". $pkgparts->[0]. "\n"
5507       if $DEBUG;
5508
5509     my $err_or_cust_pkg =
5510       $old_cust_pkg[0]->change( 'pkgpart' => $pkgparts->[0],
5511                                 'refnum'  => $refnum,
5512                               );
5513
5514     unless (ref($err_or_cust_pkg)) {
5515       $dbh->rollback if $oldAutoCommit;
5516       return $err_or_cust_pkg;
5517     }
5518
5519     push @$return_cust_pkg, $err_or_cust_pkg;
5520     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5521     return '';
5522
5523   }
5524
5525   # Create the new packages.
5526   foreach my $pkgpart (@$pkgparts) {
5527
5528     warn "$me order: inserting pkgpart $pkgpart\n" if $DEBUG;
5529
5530     my $cust_pkg = new FS::cust_pkg { custnum => $custnum,
5531                                       pkgpart => $pkgpart,
5532                                       refnum  => $refnum,
5533                                       %hash,
5534                                     };
5535     $error = $cust_pkg->insert( 'change' => $change );
5536     push @$return_cust_pkg, $cust_pkg;
5537
5538     foreach my $link ($cust_pkg->part_pkg->supp_part_pkg_link) {
5539       my $supp_pkg = FS::cust_pkg->new({
5540           custnum => $custnum,
5541           pkgpart => $link->dst_pkgpart,
5542           refnum  => $refnum,
5543           main_pkgnum => $cust_pkg->pkgnum,
5544           %hash,
5545       });
5546       $error ||= $supp_pkg->insert( 'change' => $change );
5547       push @$return_cust_pkg, $supp_pkg;
5548     }
5549
5550     if ($error) {
5551       $dbh->rollback if $oldAutoCommit;
5552       return $error;
5553     }
5554
5555   }
5556   # $return_cust_pkg now contains refs to all of the newly
5557   # created packages.
5558
5559   # Transfer services and cancel old packages.
5560   foreach my $old_pkg (@old_cust_pkg) {
5561
5562     warn "$me order: transferring services from pkgnum ". $old_pkg->pkgnum. "\n"
5563       if $DEBUG;
5564
5565     foreach my $new_pkg (@$return_cust_pkg) {
5566       $error = $old_pkg->transfer($new_pkg);
5567       if ($error and $error == 0) {
5568         # $old_pkg->transfer failed.
5569         $dbh->rollback if $oldAutoCommit;
5570         return $error;
5571       }
5572     }
5573
5574     if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
5575       warn "trying transfer again with change_svcpart option\n" if $DEBUG;
5576       foreach my $new_pkg (@$return_cust_pkg) {
5577         $error = $old_pkg->transfer($new_pkg, 'change_svcpart'=>1 );
5578         if ($error and $error == 0) {
5579           # $old_pkg->transfer failed.
5580         $dbh->rollback if $oldAutoCommit;
5581         return $error;
5582         }
5583       }
5584     }
5585
5586     if ($error > 0) {
5587       # Transfers were successful, but we went through all of the
5588       # new packages and still had services left on the old package.
5589       # We can't cancel the package under the circumstances, so abort.
5590       $dbh->rollback if $oldAutoCommit;
5591       return "Unable to transfer all services from package ".$old_pkg->pkgnum;
5592     }
5593     $error = $old_pkg->cancel( quiet=>1, 'no_delay_cancel'=>1 );
5594     if ($error) {
5595       $dbh->rollback;
5596       return $error;
5597     }
5598   }
5599   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5600   '';
5601 }
5602
5603 =item bulk_change PKGPARTS_ARYREF, REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF ]
5604
5605 A bulk change method to change packages for multiple customers.
5606
5607 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5608 L<FS::part_pkg>) to order for each customer.  Duplicates are of course
5609 permitted.
5610
5611 REMOVE_PKGNUMS is an list of pkgnums specifying the billing items to
5612 replace.  The services (see L<FS::cust_svc>) are moved to the
5613 new billing items.  An error is returned if this is not possible (see
5614 L<FS::pkg_svc>).
5615
5616 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5617 newly-created cust_pkg objects.
5618
5619 =cut
5620
5621 sub bulk_change {
5622   my ($pkgparts, $remove_pkgnum, $return_cust_pkg) = @_;
5623
5624   # Transactionize this whole mess
5625   local $SIG{HUP} = 'IGNORE';
5626   local $SIG{INT} = 'IGNORE';
5627   local $SIG{QUIT} = 'IGNORE';
5628   local $SIG{TERM} = 'IGNORE';
5629   local $SIG{TSTP} = 'IGNORE';
5630   local $SIG{PIPE} = 'IGNORE';
5631
5632   my $oldAutoCommit = $FS::UID::AutoCommit;
5633   local $FS::UID::AutoCommit = 0;
5634   my $dbh = dbh;
5635
5636   my @errors;
5637   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5638                          @$remove_pkgnum;
5639
5640   while(scalar(@old_cust_pkg)) {
5641     my @return = ();
5642     my $custnum = $old_cust_pkg[0]->custnum;
5643     my (@remove) = map { $_->pkgnum }
5644                    grep { $_->custnum == $custnum } @old_cust_pkg;
5645     @old_cust_pkg = grep { $_->custnum != $custnum } @old_cust_pkg;
5646
5647     my $error = order $custnum, $pkgparts, \@remove, \@return;
5648
5649     push @errors, $error
5650       if $error;
5651     push @$return_cust_pkg, @return;
5652   }
5653
5654   if (scalar(@errors)) {
5655     $dbh->rollback if $oldAutoCommit;
5656     return join(' / ', @errors);
5657   }
5658
5659   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5660   '';
5661 }
5662
5663 # Used by FS::Upgrade to migrate to a new database.
5664 sub _upgrade_data {  # class method
5665   my ($class, %opts) = @_;
5666   $class->_upgrade_otaker(%opts);
5667   my @statements = (
5668     # RT#10139, bug resulting in contract_end being set when it shouldn't
5669   'UPDATE cust_pkg SET contract_end = NULL WHERE contract_end = -1',
5670     # RT#10830, bad calculation of prorate date near end of year
5671     # the date range for bill is December 2009, and we move it forward
5672     # one year if it's before the previous bill date (which it should
5673     # never be)
5674   'UPDATE cust_pkg SET bill = bill + (365*24*60*60) WHERE bill < last_bill
5675   AND bill > 1259654400 AND bill < 1262332800 AND (SELECT plan FROM part_pkg
5676   WHERE part_pkg.pkgpart = cust_pkg.pkgpart) = \'prorate\'',
5677     # RT6628, add order_date to cust_pkg
5678     'update cust_pkg set order_date = (select history_date from h_cust_pkg
5679         where h_cust_pkg.pkgnum = cust_pkg.pkgnum and
5680         history_action = \'insert\') where order_date is null',
5681   );
5682   foreach my $sql (@statements) {
5683     my $sth = dbh->prepare($sql);
5684     $sth->execute or die $sth->errstr;
5685   }
5686
5687   # RT31194: supplemental package links that are deleted don't clean up
5688   # linked records
5689   my @pkglinknums = qsearch({
5690       'select'    => 'DISTINCT cust_pkg.pkglinknum',
5691       'table'     => 'cust_pkg',
5692       'addl_from' => ' LEFT JOIN part_pkg_link USING (pkglinknum) ',
5693       'extra_sql' => ' WHERE cust_pkg.pkglinknum IS NOT NULL
5694                         AND part_pkg_link.pkglinknum IS NULL',
5695   });
5696   foreach (@pkglinknums) {
5697     my $pkglinknum = $_->pkglinknum;
5698     warn "cleaning part_pkg_link #$pkglinknum\n";
5699     my $part_pkg_link = FS::part_pkg_link->new({pkglinknum => $pkglinknum});
5700     my $error = $part_pkg_link->remove_linked;
5701     die $error if $error;
5702   }
5703 }
5704
5705 =back
5706
5707 =head1 BUGS
5708
5709 sub order is not OO.  Perhaps it should be moved to FS::cust_main and made so?
5710
5711 In sub order, the @pkgparts array (passed by reference) is clobbered.
5712
5713 Also in sub order, no money is adjusted.  Once FS::part_pkg defines a standard
5714 method to pass dates to the recur_prog expression, it should do so.
5715
5716 FS::svc_acct, FS::svc_domain, FS::svc_www, FS::svc_ip and FS::svc_forward are
5717 loaded via 'use' at compile time, rather than via 'require' in sub { setup,
5718 suspend, unsuspend, cancel } because they use %FS::UID::callback to load
5719 configuration values.  Probably need a subroutine which decides what to do
5720 based on whether or not we've fetched the user yet, rather than a hash.  See
5721 FS::UID and the TODO.
5722
5723 Now that things are transactional should the check in the insert method be
5724 moved to check ?
5725
5726 =head1 SEE ALSO
5727
5728 L<FS::Record>, L<FS::cust_main>, L<FS::part_pkg>, L<FS::cust_svc>,
5729 L<FS::pkg_svc>, schema.html from the base documentation
5730
5731 =cut
5732
5733 1;
5734