FS/FS/cust_pkg.pm

   1 package FS::cust_pkg;
   2 use base qw( FS::otaker_Mixin FS::cust_main_Mixin FS::Sales_Mixin
   3              FS::contact_Mixin FS::location_Mixin
   4              FS::m2m_Common FS::option_Common );
   5
   6 use strict;
   7 use vars qw( $disable_agentcheck $DEBUG $me $upgrade );
   8 use Carp qw(cluck);
   9 use Scalar::Util qw( blessed );
  10 use List::Util qw(min max);
  11 use Tie::IxHash;
  12 use Time::Local qw( timelocal timelocal_nocheck );
  13 use MIME::Entity;
  14 use FS::UID qw( getotaker dbh driver_name );
  15 use FS::Misc qw( send_email );
  16 use FS::Record qw( qsearch qsearchs fields );
  17 use FS::CurrentUser;
  18 use FS::cust_svc;
  19 use FS::part_pkg;
  20 use FS::cust_main;
  21 use FS::contact;
  22 use FS::cust_location;
  23 use FS::pkg_svc;
  24 use FS::cust_bill_pkg;
  25 use FS::cust_pkg_detail;
  26 use FS::cust_pkg_usage;
  27 use FS::cdr_cust_pkg_usage;
  28 use FS::cust_event;
  29 use FS::h_cust_svc;
  30 use FS::reg_code;
  31 use FS::part_svc;
  32 use FS::cust_pkg_reason;
  33 use FS::reason;
  34 use FS::cust_pkg_discount;
  35 use FS::discount;
  36 use FS::UI::Web;
  37 use FS::sales;
  38 # for modify_charge
  39 use FS::cust_credit;
  40
  41 # need to 'use' these instead of 'require' in sub { cancel, suspend, unsuspend,
  42 # setup }
  43 # because they load configuration by setting FS::UID::callback (see TODO)
  44 use FS::svc_acct;
  45 use FS::svc_domain;
  46 use FS::svc_www;
  47 use FS::svc_forward;
  48
  49 # for sending cancel emails in sub cancel
  50 use FS::Conf;
  51
  52 $DEBUG = 0;
  53 $me = '[FS::cust_pkg]';
  54
  55 $disable_agentcheck = 0;
  56
  57 $upgrade = 0; #go away after setup+start dates cleaned up for old customers
  58
  59 sub _cache {
  60   my $self = shift;
  61   my ( $hashref, $cache ) = @_;
  62   #if ( $hashref->{'pkgpart'} ) {
  63   if ( $hashref->{'pkg'} ) {
  64     # #@{ $self->{'_pkgnum'} } = ();
  65     # my $subcache = $cache->subcache('pkgpart', 'part_pkg');
  66     # $self->{'_pkgpart'} = $subcache;
  67     # #push @{ $self->{'_pkgnum'} },
  68     #   FS::part_pkg->new_or_cached($hashref, $subcache);
  69     $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  70   }
  71   if ( exists $hashref->{'svcnum'} ) {
  72     #@{ $self->{'_pkgnum'} } = ();
  73     my $subcache = $cache->subcache('svcnum', 'cust_svc', $hashref->{pkgnum});
  74     $self->{'_svcnum'} = $subcache;
  75     #push @{ $self->{'_pkgnum'} },
  76     FS::cust_svc->new_or_cached($hashref, $subcache) if $hashref->{svcnum};
  77   }
  78 }
  79
  80 =head1 NAME
  81
  82 FS::cust_pkg - Object methods for cust_pkg objects
  83
  84 =head1 SYNOPSIS
  85
  86   use FS::cust_pkg;
  87
  88   $record = new FS::cust_pkg \%hash;
  89   $record = new FS::cust_pkg { 'column' => 'value' };
  90
  91   $error = $record->insert;
  92
  93   $error = $new_record->replace($old_record);
  94
  95   $error = $record->delete;
  96
  97   $error = $record->check;
  98
  99   $error = $record->cancel;
 100
 101   $error = $record->suspend;
 102
 103   $error = $record->unsuspend;
 104
 105   $part_pkg = $record->part_pkg;
 106
 107   @labels = $record->labels;
 108
 109   $seconds = $record->seconds_since($timestamp);
 110
 111   #bulk cancel+order... perhaps slightly deprecated, only used by the bulk
 112   # cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
 113   $error = FS::cust_pkg::order( $custnum, \@pkgparts );
 114   $error = FS::cust_pkg::order( $custnum, \@pkgparts, \@remove_pkgnums ] );
 115
 116 =head1 DESCRIPTION
 117
 118 An FS::cust_pkg object represents a customer billing item.  FS::cust_pkg
 119 inherits from FS::Record.  The following fields are currently supported:
 120
 121 =over 4
 122
 123 =item pkgnum
 124
 125 Primary key (assigned automatically for new billing items)
 126
 127 =item custnum
 128
 129 Customer (see L<FS::cust_main>)
 130
 131 =item pkgpart
 132
 133 Billing item definition (see L<FS::part_pkg>)
 134
 135 =item locationnum
 136
 137 Optional link to package location (see L<FS::location>)
 138
 139 =item order_date
 140
 141 date package was ordered (also remains same on changes)
 142
 143 =item start_date
 144
 145 date
 146
 147 =item setup
 148
 149 date
 150
 151 =item bill
 152
 153 date (next bill date)
 154
 155 =item last_bill
 156
 157 last bill date
 158
 159 =item adjourn
 160
 161 date
 162
 163 =item susp
 164
 165 date
 166
 167 =item expire
 168
 169 date
 170
 171 =item contract_end
 172
 173 date
 174
 175 =item cancel
 176
 177 date
 178
 179 =item usernum
 180
 181 order taker (see L<FS::access_user>)
 182
 183 =item manual_flag
 184
 185 If this field is set to 1, disables the automatic
 186 unsuspension of this package when using the B<unsuspendauto> config option.
 187
 188 =item quantity
 189
 190 If not set, defaults to 1
 191
 192 =item change_date
 193
 194 Date of change from previous package
 195
 196 =item change_pkgnum
 197
 198 Previous pkgnum
 199
 200 =item change_pkgpart
 201
 202 Previous pkgpart
 203
 204 =item change_locationnum
 205
 206 Previous locationnum
 207
 208 =item waive_setup
 209
 210 =item main_pkgnum
 211
 212 The pkgnum of the package that this package is supplemental to, if any.
 213
 214 =item pkglinknum
 215
 216 The package link (L<FS::part_pkg_link>) that defines this supplemental
 217 package, if it is one.
 218
 219 =item change_to_pkgnum
 220
 221 The pkgnum of the package this one will be "changed to" in the future
 222 (on its expiration date).
 223
 224 =back
 225
 226 Note: setup, last_bill, bill, adjourn, susp, expire, cancel and change_date
 227 are specified as UNIX timestamps; see L<perlfunc/"time">.  Also see
 228 L<Time::Local> and L<Date::Parse> for conversion functions.
 229
 230 =head1 METHODS
 231
 232 =over 4
 233
 234 =item new HASHREF
 235
 236 Create a new billing item.  To add the item to the database, see L<"insert">.
 237
 238 =cut
 239
 240 sub table { 'cust_pkg'; }
 241 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
 242 sub cust_unlinked_msg {
 243   my $self = shift;
 244   "WARNING: can't find cust_main.custnum ". $self->custnum.
 245   ' (cust_pkg.pkgnum '. $self->pkgnum. ')';
 246 }
 247
 248 =item set_initial_timers
 249
 250 If required by the package definition, sets any automatic expire, adjourn,
 251 or contract_end timers to some number of months after the start date
 252 (or setup date, if the package has already been setup). If the package has
 253 a delayed setup fee after a period of "free days", will also set the
 254 start date to the end of that period.
 255
 256 =cut
 257
 258 sub set_initial_timers {
 259   my $self = shift;
 260   my $part_pkg = $self->part_pkg;
 261   foreach my $action ( qw(expire adjourn contract_end) ) {
 262     my $months = $part_pkg->option("${action}_months",1);
 263     if($months and !$self->get($action)) {
 264       my $start = $self->start_date || $self->setup || time;
 265       $self->set($action, $part_pkg->add_freq($start, $months) );
 266     }
 267   }
 268
 269   # if this package has "free days" and delayed setup fee, then
 270   # set start date that many days in the future.
 271   # (this should have been set in the UI, but enforce it here)
 272   if ( $part_pkg->option('free_days',1)
 273        && $part_pkg->option('delay_setup',1)
 274      )
 275   {
 276     $self->start_date( $part_pkg->default_start_date );
 277   }
 278   '';
 279 }
 280
 281 =item insert [ OPTION => VALUE ... ]
 282
 283 Adds this billing item to the database ("Orders" the item).  If there is an
 284 error, returns the error, otherwise returns false.
 285
 286 If the additional field I<promo_code> is defined instead of I<pkgpart>, it
 287 will be used to look up the package definition and agent restrictions will be
 288 ignored.
 289
 290 If the additional field I<refnum> is defined, an FS::pkg_referral record will
 291 be created and inserted.  Multiple FS::pkg_referral records can be created by
 292 setting I<refnum> to an array reference of refnums or a hash reference with
 293 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
 294 record will be created corresponding to cust_main.refnum.
 295
 296 The following options are available:
 297
 298 =over 4
 299
 300 =item change
 301
 302 If set true, supresses actions that should only be taken for new package
 303 orders.  (Currently this includes: intro periods when delay_setup is on,
 304 auto-adding a 1st start date, auto-adding expiration/adjourn/contract_end dates)
 305
 306 =item options
 307
 308 cust_pkg_option records will be created
 309
 310 =item ticket_subject
 311
 312 a ticket will be added to this customer with this subject
 313
 314 =item ticket_queue
 315
 316 an optional queue name for ticket additions
 317
 318 =item allow_pkgpart
 319
 320 Don't check the legality of the package definition.  This should be used
 321 when performing a package change that doesn't change the pkgpart (i.e.
 322 a location change).
 323
 324 =back
 325
 326 =cut
 327
 328 sub insert {
 329   my( $self, %options ) = @_;
 330
 331   my $error;
 332   $error = $self->check_pkgpart unless $options{'allow_pkgpart'};
 333   return $error if $error;
 334
 335   my $part_pkg = $self->part_pkg;
 336
 337   if ( ! $options{'change'} ) {
 338
 339     # set order date to now
 340     $self->order_date(time);
 341
 342     # if the package def says to start only on the first of the month:
 343     if ( $part_pkg->option('start_1st', 1) && !$self->start_date ) {
 344       my ($sec,$min,$hour,$mday,$mon,$year) = (localtime(time) )[0,1,2,3,4,5];
 345       $mon += 1 unless $mday == 1;
 346       until ( $mon < 12 ) { $mon -= 12; $year++; }
 347       $self->start_date( timelocal_nocheck(0,0,0,1,$mon,$year) );
 348     }
 349
 350     if ($self->susp eq 'now' or $part_pkg->start_on_hold) {
 351       # if the package was ordered on hold:
 352       # - suspend it
 353       # - don't set the start date (it will be started manually)
 354       $self->set('susp', $self->order_date);
 355       $self->set('start_date', '');
 356     } else {
 357       # set expire/adjourn/contract_end timers, and free days, if appropriate
 358       $self->set_initial_timers;
 359     }
 360   } # else this is a package change, and shouldn't have "new package" behavior
 361
 362   local $SIG{HUP} = 'IGNORE';
 363   local $SIG{INT} = 'IGNORE';
 364   local $SIG{QUIT} = 'IGNORE';
 365   local $SIG{TERM} = 'IGNORE';
 366   local $SIG{TSTP} = 'IGNORE';
 367   local $SIG{PIPE} = 'IGNORE';
 368
 369   my $oldAutoCommit = $FS::UID::AutoCommit;
 370   local $FS::UID::AutoCommit = 0;
 371   my $dbh = dbh;
 372
 373   $error = $self->SUPER::insert($options{options} ? %{$options{options}} : ());
 374   if ( $error ) {
 375     $dbh->rollback if $oldAutoCommit;
 376     return $error;
 377   }
 378
 379   $self->refnum($self->cust_main->refnum) unless $self->refnum;
 380   $self->refnum( [ $self->refnum ] ) unless ref($self->refnum);
 381   $self->process_m2m( 'link_table'   => 'pkg_referral',
 382                       'target_table' => 'part_referral',
 383                       'params'       => $self->refnum,
 384                     );
 385
 386   if ( $self->discountnum ) {
 387     my $error = $self->insert_discount();
 388     if ( $error ) {
 389       $dbh->rollback if $oldAutoCommit;
 390       return $error;
 391     }
 392   }
 393
 394   my $conf = new FS::Conf;
 395
 396   if ( $conf->config('ticket_system') && $options{ticket_subject} ) {
 397
 398     #this init stuff is still inefficient, but at least its limited to
 399     # the small number (any?) folks using ticket emailing on pkg order
 400
 401     #eval '
 402     #  use lib ( "/opt/rt3/local/lib", "/opt/rt3/lib" );
 403     #  use RT;
 404     #';
 405     #die $@ if $@;
 406     #
 407     #RT::LoadConfig();
 408     #RT::Init();
 409     use FS::TicketSystem;
 410     FS::TicketSystem->init();
 411
 412     my $q = new RT::Queue($RT::SystemUser);
 413     $q->Load($options{ticket_queue}) if $options{ticket_queue};
 414     my $t = new RT::Ticket($RT::SystemUser);
 415     my $mime = new MIME::Entity;
 416     $mime->build( Type => 'text/plain', Data => $options{ticket_subject} );
 417     $t->Create( $options{ticket_queue} ? (Queue => $q) : (),
 418                 Subject => $options{ticket_subject},
 419                 MIMEObj => $mime,
 420               );
 421     $t->AddLink( Type   => 'MemberOf',
 422                  Target => 'freeside://freeside/cust_main/'. $self->custnum,
 423                );
 424   }
 425
 426   if ($conf->config('welcome_letter') && $self->cust_main->num_pkgs == 1) {
 427     my $queue = new FS::queue {
 428       'job'     => 'FS::cust_main::queueable_print',
 429     };
 430     $error = $queue->insert(
 431       'custnum'  => $self->custnum,
 432       'template' => 'welcome_letter',
 433     );
 434
 435     if ($error) {
 436       warn "can't send welcome letter: $error";
 437     }
 438
 439   }
 440
 441   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 442   '';
 443
 444 }
 445
 446 =item delete
 447
 448 This method now works but you probably shouldn't use it.
 449
 450 You don't want to delete packages, because there would then be no record
 451 the customer ever purchased the package.  Instead, see the cancel method and
 452 hide cancelled packages.
 453
 454 =cut
 455
 456 sub delete {
 457   my $self = shift;
 458
 459   local $SIG{HUP} = 'IGNORE';
 460   local $SIG{INT} = 'IGNORE';
 461   local $SIG{QUIT} = 'IGNORE';
 462   local $SIG{TERM} = 'IGNORE';
 463   local $SIG{TSTP} = 'IGNORE';
 464   local $SIG{PIPE} = 'IGNORE';
 465
 466   my $oldAutoCommit = $FS::UID::AutoCommit;
 467   local $FS::UID::AutoCommit = 0;
 468   my $dbh = dbh;
 469
 470   foreach my $cust_pkg_discount ($self->cust_pkg_discount) {
 471     my $error = $cust_pkg_discount->delete;
 472     if ( $error ) {
 473       $dbh->rollback if $oldAutoCommit;
 474       return $error;
 475     }
 476   }
 477   #cust_bill_pkg_discount?
 478
 479   foreach my $cust_pkg_detail ($self->cust_pkg_detail) {
 480     my $error = $cust_pkg_detail->delete;
 481     if ( $error ) {
 482       $dbh->rollback if $oldAutoCommit;
 483       return $error;
 484     }
 485   }
 486
 487   foreach my $cust_pkg_reason (
 488     qsearchs( {
 489                 'table' => 'cust_pkg_reason',
 490                 'hashref' => { 'pkgnum' => $self->pkgnum },
 491               }
 492             )
 493   ) {
 494     my $error = $cust_pkg_reason->delete;
 495     if ( $error ) {
 496       $dbh->rollback if $oldAutoCommit;
 497       return $error;
 498     }
 499   }
 500
 501   #pkg_referral?
 502
 503   my $error = $self->SUPER::delete(@_);
 504   if ( $error ) {
 505     $dbh->rollback if $oldAutoCommit;
 506     return $error;
 507   }
 508
 509   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 510
 511   '';
 512
 513 }
 514
 515 =item replace [ OLD_RECORD ] [ HASHREF | OPTION => VALUE ... ]
 516
 517 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 518 returns the error, otherwise returns false.
 519
 520 Currently, custnum, setup, bill, adjourn, susp, expire, and cancel may be changed.
 521
 522 Changing pkgpart may have disasterous effects.  See the order subroutine.
 523
 524 setup and bill are normally updated by calling the bill method of a customer
 525 object (see L<FS::cust_main>).
 526
 527 suspend is normally updated by the suspend and unsuspend methods.
 528
 529 cancel is normally updated by the cancel method (and also the order subroutine
 530 in some cases).
 531
 532 Available options are:
 533
 534 =over 4
 535
 536 =item reason
 537
 538 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
 539
 540 =item reason_otaker
 541
 542 the access_user (see L<FS::access_user>) providing the reason
 543
 544 =item options
 545
 546 hashref of keys and values - cust_pkg_option records will be created, updated or removed as appopriate
 547
 548 =back
 549
 550 =cut
 551
 552 sub replace {
 553   my $new = shift;
 554
 555   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 556               ? shift
 557               : $new->replace_old;
 558
 559   my $options =
 560     ( ref($_[0]) eq 'HASH' )
 561       ? shift
 562       : { @_ };
 563
 564   #return "Can't (yet?) change pkgpart!" if $old->pkgpart != $new->pkgpart;
 565   #return "Can't change otaker!" if $old->otaker ne $new->otaker;
 566
 567   #allow this *sigh*
 568   #return "Can't change setup once it exists!"
 569   #  if $old->getfield('setup') &&
 570   #     $old->getfield('setup') != $new->getfield('setup');
 571
 572   #some logic for bill, susp, cancel?
 573
 574   local($disable_agentcheck) = 1 if $old->pkgpart == $new->pkgpart;
 575
 576   local $SIG{HUP} = 'IGNORE';
 577   local $SIG{INT} = 'IGNORE';
 578   local $SIG{QUIT} = 'IGNORE';
 579   local $SIG{TERM} = 'IGNORE';
 580   local $SIG{TSTP} = 'IGNORE';
 581   local $SIG{PIPE} = 'IGNORE';
 582
 583   my $oldAutoCommit = $FS::UID::AutoCommit;
 584   local $FS::UID::AutoCommit = 0;
 585   my $dbh = dbh;
 586
 587   foreach my $method ( qw(adjourn expire) ) {  # How many reasons?
 588     if ($options->{'reason'} && $new->$method && $old->$method ne $new->$method) {
 589       my $error = $new->insert_reason(
 590         'reason'        => $options->{'reason'},
 591         'date'          => $new->$method,
 592         'action'        => $method,
 593         'reason_otaker' => $options->{'reason_otaker'},
 594       );
 595       if ( $error ) {
 596         dbh->rollback if $oldAutoCommit;
 597         return "Error inserting cust_pkg_reason: $error";
 598       }
 599     }
 600   }
 601
 602   #save off and freeze RADIUS attributes for any associated svc_acct records
 603   my @svc_acct = ();
 604   if ( $old->part_pkg->is_prepaid || $new->part_pkg->is_prepaid ) {
 605
 606                 #also check for specific exports?
 607                 # to avoid spurious modify export events
 608     @svc_acct = map  { $_->svc_x }
 609                 grep { $_->part_svc->svcdb eq 'svc_acct' }
 610                      $old->cust_svc;
 611
 612     $_->snapshot foreach @svc_acct;
 613
 614   }
 615
 616   my $error =  $new->export_pkg_change($old)
 617             || $new->SUPER::replace( $old,
 618                                      $options->{options}
 619                                        ? $options->{options}
 620                                        : ()
 621                                    );
 622   if ( $error ) {
 623     $dbh->rollback if $oldAutoCommit;
 624     return $error;
 625   }
 626
 627   #for prepaid packages,
 628   #trigger export of new RADIUS Expiration attribute when cust_pkg.bill changes
 629   foreach my $old_svc_acct ( @svc_acct ) {
 630     my $new_svc_acct = new FS::svc_acct { $old_svc_acct->hash };
 631     my $s_error =
 632       $new_svc_acct->replace( $old_svc_acct,
 633                               'depend_jobnum' => $options->{depend_jobnum},
 634                             );
 635     if ( $s_error ) {
 636       $dbh->rollback if $oldAutoCommit;
 637       return $s_error;
 638     }
 639   }
 640
 641   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 642   '';
 643
 644 }
 645
 646 =item check
 647
 648 Checks all fields to make sure this is a valid billing item.  If there is an
 649 error, returns the error, otherwise returns false.  Called by the insert and
 650 replace methods.
 651
 652 =cut
 653
 654 sub check {
 655   my $self = shift;
 656
 657   if ( !$self->locationnum or $self->locationnum == -1 ) {
 658     $self->set('locationnum', $self->cust_main->ship_locationnum);
 659   }
 660
 661   my $error =
 662     $self->ut_numbern('pkgnum')
 663     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 664     || $self->ut_numbern('pkgpart')
 665     || $self->ut_foreign_keyn('contactnum',  'contact',       'contactnum' )
 666     || $self->ut_foreign_keyn('locationnum', 'cust_location', 'locationnum')
 667     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
 668     || $self->ut_numbern('quantity')
 669     || $self->ut_numbern('start_date')
 670     || $self->ut_numbern('setup')
 671     || $self->ut_numbern('bill')
 672     || $self->ut_numbern('susp')
 673     || $self->ut_numbern('cancel')
 674     || $self->ut_numbern('adjourn')
 675     || $self->ut_numbern('resume')
 676     || $self->ut_numbern('expire')
 677     || $self->ut_numbern('dundate')
 678     || $self->ut_flag('no_auto', [ '', 'Y' ])
 679     || $self->ut_flag('waive_setup', [ '', 'Y' ])
 680     || $self->ut_flag('separate_bill')
 681     || $self->ut_textn('agent_pkgid')
 682     || $self->ut_enum('recur_show_zero', [ '', 'Y', 'N', ])
 683     || $self->ut_enum('setup_show_zero', [ '', 'Y', 'N', ])
 684     || $self->ut_foreign_keyn('main_pkgnum', 'cust_pkg', 'pkgnum')
 685     || $self->ut_foreign_keyn('pkglinknum', 'part_pkg_link', 'pkglinknum')
 686     || $self->ut_foreign_keyn('change_to_pkgnum', 'cust_pkg', 'pkgnum')
 687   ;
 688   return $error if $error;
 689
 690   return "A package with both start date (future start) and setup date (already started) will never bill"
 691     if $self->start_date && $self->setup && ! $upgrade;
 692
 693   return "A future unsuspend date can only be set for a package with a suspend date"
 694     if $self->resume and !$self->susp and !$self->adjourn;
 695
 696   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 697
 698   if ( $self->dbdef_table->column('manual_flag') ) {
 699     $self->manual_flag('') if $self->manual_flag eq ' ';
 700     $self->manual_flag =~ /^([01]?)$/
 701       or return "Illegal manual_flag ". $self->manual_flag;
 702     $self->manual_flag($1);
 703   }
 704
 705   $self->SUPER::check;
 706 }
 707
 708 =item check_pkgpart
 709
 710 Check the pkgpart to make sure it's allowed with the reg_code and/or
 711 promo_code of the package (if present) and with the customer's agent.
 712 Called from C<insert>, unless we are doing a package change that doesn't
 713 affect pkgpart.
 714
 715 =cut
 716
 717 sub check_pkgpart {
 718   my $self = shift;
 719
 720   # my $error = $self->ut_numbern('pkgpart'); # already done
 721
 722   my $error;
 723   if ( $self->reg_code ) {
 724
 725     unless ( grep { $self->pkgpart == $_->pkgpart }
 726              map  { $_->reg_code_pkg }
 727              qsearchs( 'reg_code', { 'code'     => $self->reg_code,
 728                                      'agentnum' => $self->cust_main->agentnum })
 729            ) {
 730       return "Unknown registration code";
 731     }
 732
 733   } elsif ( $self->promo_code ) {
 734
 735     my $promo_part_pkg =
 736       qsearchs('part_pkg', {
 737         'pkgpart'    => $self->pkgpart,
 738         'promo_code' => { op=>'ILIKE', value=>$self->promo_code },
 739       } );
 740     return 'Unknown promotional code' unless $promo_part_pkg;
 741
 742   } else {
 743
 744     unless ( $disable_agentcheck ) {
 745       my $agent =
 746         qsearchs( 'agent', { 'agentnum' => $self->cust_main->agentnum } );
 747       return "agent ". $agent->agentnum. ':'. $agent->agent.
 748              " can't purchase pkgpart ". $self->pkgpart
 749         unless $agent->pkgpart_hashref->{ $self->pkgpart }
 750             || $agent->agentnum == $self->part_pkg->agentnum;
 751     }
 752
 753     $error = $self->ut_foreign_key('pkgpart', 'part_pkg', 'pkgpart' );
 754     return $error if $error;
 755
 756   }
 757
 758   '';
 759
 760 }
 761
 762 =item cancel [ OPTION => VALUE ... ]
 763
 764 Cancels and removes all services (see L<FS::cust_svc> and L<FS::part_svc>)
 765 in this package, then cancels the package itself (sets the cancel field to
 766 now).
 767
 768 Available options are:
 769
 770 =over 4
 771
 772 =item quiet - can be set true to supress email cancellation notices.
 773
 774 =item time -  can be set to cancel the package based on a specific future or
 775 historical date.  Using time ensures that the remaining amount is calculated
 776 correctly.  Note however that this is an immediate cancel and just changes
 777 the date.  You are PROBABLY looking to expire the account instead of using
 778 this.
 779
 780 =item reason - can be set to a cancellation reason (see L<FS:reason>),
 781 either a reasonnum of an existing reason, or passing a hashref will create
 782 a new reason.  The hashref should have the following keys: typenum - Reason
 783 type (see L<FS::reason_type>, reason - Text of the new reason.
 784
 785 =item date - can be set to a unix style timestamp to specify when to
 786 cancel (expire)
 787
 788 =item nobill - can be set true to skip billing if it might otherwise be done.
 789
 790 =item unused_credit - can be set to 1 to credit the remaining time, or 0 to
 791 not credit it.  This must be set (by change()) when changing the package
 792 to a different pkgpart or location, and probably shouldn't be in any other
 793 case.  If it's not set, the 'unused_credit_cancel' part_pkg option will
 794 be used.
 795
 796 =item no_delay_cancel - prevents delay_cancel behavior
 797 no matter what other options say, for use when changing packages (or any
 798 other time you're really sure you want an immediate cancel)
 799
 800 =back
 801
 802 If there is an error, returns the error, otherwise returns false.
 803
 804 =cut
 805
 806 #NOT DOCUMENTING - this should only be used when calling recursively
 807 #=item delay_cancel - for internal use, to allow proper handling of
 808 #supplemental packages when the main package is flagged to suspend
 809 #before cancelling, probably shouldn't be used otherwise (set the
 810 #corresponding package option instead)
 811
 812 sub cancel {
 813   my( $self, %options ) = @_;
 814   my $error;
 815
 816   # pass all suspend/cancel actions to the main package
 817   # (unless the pkglinknum has been removed, then the link is defunct and
 818   # this package can be canceled on its own)
 819   if ( $self->main_pkgnum and $self->pkglinknum and !$options{'from_main'} ) {
 820     return $self->main_pkg->cancel(%options);
 821   }
 822
 823   my $conf = new FS::Conf;
 824
 825   warn "cust_pkg::cancel called with options".
 826        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 827     if $DEBUG;
 828
 829   local $SIG{HUP} = 'IGNORE';
 830   local $SIG{INT} = 'IGNORE';
 831   local $SIG{QUIT} = 'IGNORE';
 832   local $SIG{TERM} = 'IGNORE';
 833   local $SIG{TSTP} = 'IGNORE';
 834   local $SIG{PIPE} = 'IGNORE';
 835
 836   my $oldAutoCommit = $FS::UID::AutoCommit;
 837   local $FS::UID::AutoCommit = 0;
 838   my $dbh = dbh;
 839
 840   my $old = $self->select_for_update;
 841
 842   if ( $old->get('cancel') || $self->get('cancel') ) {
 843     dbh->rollback if $oldAutoCommit;
 844     return "";  # no error
 845   }
 846
 847   # XXX possibly set cancel_time to the expire date?
 848   my $cancel_time = $options{'time'} || time;
 849   my $date = $options{'date'} if $options{'date'}; # expire/cancel later
 850   $date = '' if ($date && $date <= $cancel_time);      # complain instead?
 851
 852   my $delay_cancel = $options{'no_delay_cancel'} ? 0 : $options{'delay_cancel'};
 853   if ( !$date && $self->part_pkg->option('delay_cancel',1)
 854        && (($self->status eq 'active') || ($self->status eq 'suspended'))
 855        && !$options{'no_delay_cancel'}
 856   ) {
 857     my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
 858     my $expsecs = 60*60*24*$expdays;
 859     my $suspfor = $self->susp ? $cancel_time - $self->susp : 0;
 860     $expsecs = $expsecs - $suspfor if $suspfor;
 861     unless ($expsecs <= 0) { #if it's already been suspended long enough, don't re-suspend
 862       $delay_cancel = 1;
 863       $date = $cancel_time + $expsecs;
 864     }
 865   }
 866
 867   #race condition: usage could be ongoing until unprovisioned
 868   #resolved by performing a change package instead (which unprovisions) and
 869   #later cancelling
 870   if ( !$options{nobill} && !$date ) {
 871     # && $conf->exists('bill_usage_on_cancel') ) { #calc_cancel checks this
 872       my $copy = $self->new({$self->hash});
 873       my $error =
 874         $copy->cust_main->bill( 'pkg_list' => [ $copy ],
 875                                 'cancel'   => 1,
 876                                 'time'     => $cancel_time );
 877       warn "Error billing during cancel, custnum ".
 878         #$self->cust_main->custnum. ": $error"
 879         ": $error"
 880         if $error;
 881   }
 882
 883   if ( $options{'reason'} ) {
 884     $error = $self->insert_reason( 'reason' => $options{'reason'},
 885                                    'action' => $date ? 'expire' : 'cancel',
 886                                    'date'   => $date ? $date : $cancel_time,
 887                                    'reason_otaker' => $options{'reason_otaker'},
 888                                  );
 889     if ( $error ) {
 890       dbh->rollback if $oldAutoCommit;
 891       return "Error inserting cust_pkg_reason: $error";
 892     }
 893   }
 894
 895   my %svc_cancel_opt = ();
 896   $svc_cancel_opt{'date'} = $date if $date;
 897   foreach my $cust_svc (
 898     #schwartz
 899     map  { $_->[0] }
 900     sort { $a->[1] <=> $b->[1] }
 901     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; }
 902     qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
 903   ) {
 904     my $part_svc = $cust_svc->part_svc;
 905     next if ( defined($part_svc) and $part_svc->preserve );
 906     my $error = $cust_svc->cancel( %svc_cancel_opt );
 907
 908     if ( $error ) {
 909       $dbh->rollback if $oldAutoCommit;
 910       return 'Error '. ($svc_cancel_opt{'date'} ? 'expiring' : 'canceling' ).
 911              " cust_svc: $error";
 912     }
 913   }
 914
 915   unless ($date) {
 916     # credit remaining time if appropriate
 917     my $do_credit;
 918     if ( exists($options{'unused_credit'}) ) {
 919       $do_credit = $options{'unused_credit'};
 920     }
 921     else {
 922       $do_credit = $self->part_pkg->option('unused_credit_cancel', 1);
 923     }
 924     if ( $do_credit ) {
 925       my $error = $self->credit_remaining('cancel', $cancel_time);
 926       if ($error) {
 927         $dbh->rollback if $oldAutoCommit;
 928         return $error;
 929       }
 930     }
 931   } #unless $date
 932
 933   my %hash = $self->hash;
 934   if ( $date ) {
 935     $hash{'expire'} = $date;
 936     if ($delay_cancel) {
 937       # just to be sure these are clear
 938       $hash{'adjourn'} = undef;
 939       $hash{'resume'} = undef;
 940     }
 941   } else {
 942     $hash{'cancel'} = $cancel_time;
 943   }
 944   $hash{'change_custnum'} = $options{'change_custnum'};
 945
 946   # if this is a supplemental package that's lost its part_pkg_link, and it's
 947   # being canceled for real, unlink it completely
 948   if ( !$date and ! $self->pkglinknum ) {
 949     $hash{main_pkgnum} = '';
 950   }
 951
 952   my $new = new FS::cust_pkg ( \%hash );
 953   $error = $new->replace( $self, options => { $self->options } );
 954   if ( $self->change_to_pkgnum ) {
 955     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
 956     $error ||= $change_to->cancel('no_delay_cancel' => 1) || $change_to->delete;
 957   }
 958   if ( $error ) {
 959     $dbh->rollback if $oldAutoCommit;
 960     return $error;
 961   }
 962
 963   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
 964     $error = $supp_pkg->cancel(%options,
 965       'from_main' => 1,
 966       'date' => $date, #in case it got changed by delay_cancel
 967       'delay_cancel' => $delay_cancel,
 968     );
 969     if ( $error ) {
 970       $dbh->rollback if $oldAutoCommit;
 971       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
 972     }
 973   }
 974
 975   if ($delay_cancel && !$options{'from_main'}) {
 976     $error = $new->suspend(
 977       'from_cancel' => 1,
 978       'time'        => $cancel_time
 979     );
 980   }
 981
 982   unless ($date) {
 983     foreach my $usage ( $self->cust_pkg_usage ) {
 984       $error = $usage->delete;
 985       if ( $error ) {
 986         $dbh->rollback if $oldAutoCommit;
 987         return "deleting usage pools: $error";
 988       }
 989     }
 990   }
 991
 992   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 993   return '' if $date; #no errors
 994
 995   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ } $self->cust_main->invoicing_list;
 996   if ( !$options{'quiet'} &&
 997         $conf->exists('emailcancel', $self->cust_main->agentnum) &&
 998         @invoicing_list ) {
 999     my $msgnum = $conf->config('cancel_msgnum', $self->cust_main->agentnum);
1000     my $error = '';
1001     if ( $msgnum ) {
1002       my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
1003       $error = $msg_template->send( 'cust_main' => $self->cust_main,
1004                                     'object'    => $self );
1005     }
1006     else {
1007       $error = send_email(
1008         'from'    => $conf->invoice_from_full( $self->cust_main->agentnum ),
1009         'to'      => \@invoicing_list,
1010         'subject' => ( $conf->config('cancelsubject') || 'Cancellation Notice' ),
1011         'body'    => [ map "$_\n", $conf->config('cancelmessage') ],
1012         'custnum' => $self->custnum,
1013         'msgtype' => '', #admin?
1014       );
1015     }
1016     #should this do something on errors?
1017   }
1018
1019   ''; #no errors
1020
1021 }
1022
1023 =item cancel_if_expired [ NOW_TIMESTAMP ]
1024
1025 Cancels this package if its expire date has been reached.
1026
1027 =cut
1028
1029 sub cancel_if_expired {
1030   my $self = shift;
1031   my $time = shift || time;
1032   return '' unless $self->expire && $self->expire <= $time;
1033   my $error = $self->cancel;
1034   if ( $error ) {
1035     return "Error cancelling expired pkg ". $self->pkgnum. " for custnum ".
1036            $self->custnum. ": $error";
1037   }
1038   '';
1039 }
1040
1041 =item uncancel
1042
1043 "Un-cancels" this package: Orders a new package with the same custnum, pkgpart,
1044 locationnum, (other fields?).  Attempts to re-provision cancelled services
1045 using history information (errors at this stage are not fatal).
1046
1047 cust_pkg: pass a scalar reference, will be filled in with the new cust_pkg object
1048
1049 svc_fatal: service provisioning errors are fatal
1050
1051 svc_errors: pass an array reference, will be filled in with any provisioning errors
1052
1053 main_pkgnum: link the package as a supplemental package of this one.  For
1054 internal use only.
1055
1056 =cut
1057
1058 sub uncancel {
1059   my( $self, %options ) = @_;
1060
1061   #in case you try do do $uncancel-date = $cust_pkg->uncacel
1062   return '' unless $self->get('cancel');
1063
1064   if ( $self->main_pkgnum and !$options{'main_pkgnum'} ) {
1065     return $self->main_pkg->uncancel(%options);
1066   }
1067
1068   ##
1069   # Transaction-alize
1070   ##
1071
1072   local $SIG{HUP} = 'IGNORE';
1073   local $SIG{INT} = 'IGNORE';
1074   local $SIG{QUIT} = 'IGNORE';
1075   local $SIG{TERM} = 'IGNORE';
1076   local $SIG{TSTP} = 'IGNORE';
1077   local $SIG{PIPE} = 'IGNORE';
1078
1079   my $oldAutoCommit = $FS::UID::AutoCommit;
1080   local $FS::UID::AutoCommit = 0;
1081   my $dbh = dbh;
1082
1083   ##
1084   # insert the new package
1085   ##
1086
1087   my $cust_pkg = new FS::cust_pkg {
1088     last_bill       => ( $options{'last_bill'} || $self->get('last_bill') ),
1089     bill            => ( $options{'bill'}      || $self->get('bill')      ),
1090     uncancel        => time,
1091     uncancel_pkgnum => $self->pkgnum,
1092     main_pkgnum     => ($options{'main_pkgnum'} || ''),
1093     map { $_ => $self->get($_) } qw(
1094       custnum pkgpart locationnum
1095       setup
1096       susp adjourn resume expire start_date contract_end dundate
1097       change_date change_pkgpart change_locationnum
1098       manual_flag no_auto separate_bill quantity agent_pkgid
1099       recur_show_zero setup_show_zero
1100     ),
1101   };
1102
1103   my $error = $cust_pkg->insert(
1104     'change' => 1, #supresses any referral credit to a referring customer
1105     'allow_pkgpart' => 1, # allow this even if the package def is disabled
1106   );
1107   if ($error) {
1108     $dbh->rollback if $oldAutoCommit;
1109     return $error;
1110   }
1111
1112   ##
1113   # insert services
1114   ##
1115
1116   #find historical services within this timeframe before the package cancel
1117   # (incompatible with "time" option to cust_pkg->cancel?)
1118   my $fuzz = 2 * 60; #2 minutes?  too much?   (might catch separate unprovision)
1119                      #            too little? (unprovisioing export delay?)
1120   my($end, $start) = ( $self->get('cancel'), $self->get('cancel') - $fuzz );
1121   my @h_cust_svc = $self->h_cust_svc( $end, $start );
1122
1123   my @svc_errors;
1124   foreach my $h_cust_svc (@h_cust_svc) {
1125     my $h_svc_x = $h_cust_svc->h_svc_x( $end, $start );
1126     #next unless $h_svc_x; #should this happen?
1127     (my $table = $h_svc_x->table) =~ s/^h_//;
1128     require "FS/$table.pm";
1129     my $class = "FS::$table";
1130     my $svc_x = $class->new( {
1131       'pkgnum'  => $cust_pkg->pkgnum,
1132       'svcpart' => $h_cust_svc->svcpart,
1133       map { $_ => $h_svc_x->get($_) } fields($table)
1134     } );
1135
1136     # radius_usergroup
1137     if ( $h_svc_x->isa('FS::h_svc_Radius_Mixin') ) {
1138       $svc_x->usergroup( [ $h_svc_x->h_usergroup($end, $start) ] );
1139     }
1140
1141     my $svc_error = $svc_x->insert;
1142     if ( $svc_error ) {
1143       if ( $options{svc_fatal} ) {
1144         $dbh->rollback if $oldAutoCommit;
1145         return $svc_error;
1146       } else {
1147         # if we've failed to insert the svc_x object, svc_Common->insert
1148         # will have removed the cust_svc already.  if not, then both records
1149         # were inserted but we failed for some other reason (export, most
1150         # likely).  in that case, report the error and delete the records.
1151         push @svc_errors, $svc_error;
1152         my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $svc_x->svcnum });
1153         if ( $cust_svc ) {
1154           # except if export_insert failed, export_delete probably won't be
1155           # much better
1156           local $FS::svc_Common::noexport_hack = 1;
1157           my $cleanup_error = $svc_x->delete; # also deletes cust_svc
1158           if ( $cleanup_error ) { # and if THAT fails, then run away
1159             $dbh->rollback if $oldAutoCommit;
1160             return $cleanup_error;
1161           }
1162         }
1163       } # svc_fatal
1164     } # svc_error
1165   } #foreach $h_cust_svc
1166
1167   #these are pretty rare, but should handle them
1168   # - dsl_device (mac addresses)
1169   # - phone_device (mac addresses)
1170   # - dsl_note (ikano notes)
1171   # - domain_record (i.e. restore DNS information w/domains)
1172   # - inventory_item(?) (inventory w/un-cancelling service?)
1173   # - nas (svc_broaband nas stuff)
1174   #this stuff is unused in the wild afaik
1175   # - mailinglistmember
1176   # - router.svcnum?
1177   # - svc_domain.parent_svcnum?
1178   # - acct_snarf (ancient mail fetching config)
1179   # - cgp_rule (communigate)
1180   # - cust_svc_option (used by our Tron stuff)
1181   # - acct_rt_transaction (used by our time worked stuff)
1182
1183   ##
1184   # also move over any services that didn't unprovision at cancellation
1185   ##
1186
1187   foreach my $cust_svc ( qsearch('cust_svc', { pkgnum => $self->pkgnum } ) ) {
1188     $cust_svc->pkgnum( $cust_pkg->pkgnum );
1189     my $error = $cust_svc->replace;
1190     if ( $error ) {
1191       $dbh->rollback if $oldAutoCommit;
1192       return $error;
1193     }
1194   }
1195
1196   ##
1197   # Uncancel any supplemental packages, and make them supplemental to the
1198   # new one.
1199   ##
1200
1201   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1202     my $new_pkg;
1203     $error = $supp_pkg->uncancel(%options, 'main_pkgnum' => $cust_pkg->pkgnum);
1204     if ( $error ) {
1205       $dbh->rollback if $oldAutoCommit;
1206       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1207     }
1208   }
1209
1210   ##
1211   # Finish
1212   ##
1213
1214   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1215
1216   ${ $options{cust_pkg} }   = $cust_pkg   if ref($options{cust_pkg});
1217   @{ $options{svc_errors} } = @svc_errors if ref($options{svc_errors});
1218
1219   '';
1220 }
1221
1222 =item unexpire
1223
1224 Cancels any pending expiration (sets the expire field to null).
1225
1226 If there is an error, returns the error, otherwise returns false.
1227
1228 =cut
1229
1230 sub unexpire {
1231   my( $self, %options ) = @_;
1232   my $error;
1233
1234   local $SIG{HUP} = 'IGNORE';
1235   local $SIG{INT} = 'IGNORE';
1236   local $SIG{QUIT} = 'IGNORE';
1237   local $SIG{TERM} = 'IGNORE';
1238   local $SIG{TSTP} = 'IGNORE';
1239   local $SIG{PIPE} = 'IGNORE';
1240
1241   my $oldAutoCommit = $FS::UID::AutoCommit;
1242   local $FS::UID::AutoCommit = 0;
1243   my $dbh = dbh;
1244
1245   my $old = $self->select_for_update;
1246
1247   my $pkgnum = $old->pkgnum;
1248   if ( $old->get('cancel') || $self->get('cancel') ) {
1249     dbh->rollback if $oldAutoCommit;
1250     return "Can't unexpire cancelled package $pkgnum";
1251     # or at least it's pointless
1252   }
1253
1254   unless ( $old->get('expire') && $self->get('expire') ) {
1255     dbh->rollback if $oldAutoCommit;
1256     return "";  # no error
1257   }
1258
1259   my %hash = $self->hash;
1260   $hash{'expire'} = '';
1261   my $new = new FS::cust_pkg ( \%hash );
1262   $error = $new->replace( $self, options => { $self->options } );
1263   if ( $error ) {
1264     $dbh->rollback if $oldAutoCommit;
1265     return $error;
1266   }
1267
1268   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1269
1270   ''; #no errors
1271
1272 }
1273
1274 =item suspend [ OPTION => VALUE ... ]
1275
1276 Suspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1277 package, then suspends the package itself (sets the susp field to now).
1278
1279 Available options are:
1280
1281 =over 4
1282
1283 =item reason - can be set to a cancellation reason (see L<FS:reason>),
1284 either a reasonnum of an existing reason, or passing a hashref will create
1285 a new reason.  The hashref should have the following keys:
1286 - typenum - Reason type (see L<FS::reason_type>
1287 - reason - Text of the new reason.
1288
1289 =item date - can be set to a unix style timestamp to specify when to
1290 suspend (adjourn)
1291
1292 =item time - can be set to override the current time, for calculation
1293 of final invoices or unused-time credits
1294
1295 =item resume_date - can be set to a time when the package should be
1296 unsuspended.  This may be more convenient than calling C<unsuspend()>
1297 separately.
1298
1299 =item from_main - allows a supplemental package to be suspended, rather
1300 than redirecting the method call to its main package.  For internal use.
1301
1302 =item from_cancel - used when suspending from the cancel method, forces
1303 this to skip everything besides basic suspension.  For internal use.
1304
1305 =back
1306
1307 If there is an error, returns the error, otherwise returns false.
1308
1309 =cut
1310
1311 sub suspend {
1312   my( $self, %options ) = @_;
1313   my $error;
1314
1315   # pass all suspend/cancel actions to the main package
1316   if ( $self->main_pkgnum and !$options{'from_main'} ) {
1317     return $self->main_pkg->suspend(%options);
1318   }
1319
1320   local $SIG{HUP} = 'IGNORE';
1321   local $SIG{INT} = 'IGNORE';
1322   local $SIG{QUIT} = 'IGNORE';
1323   local $SIG{TERM} = 'IGNORE';
1324   local $SIG{TSTP} = 'IGNORE';
1325   local $SIG{PIPE} = 'IGNORE';
1326
1327   my $oldAutoCommit = $FS::UID::AutoCommit;
1328   local $FS::UID::AutoCommit = 0;
1329   my $dbh = dbh;
1330
1331   my $old = $self->select_for_update;
1332
1333   my $pkgnum = $old->pkgnum;
1334   if ( $old->get('cancel') || $self->get('cancel') ) {
1335     dbh->rollback if $oldAutoCommit;
1336     return "Can't suspend cancelled package $pkgnum";
1337   }
1338
1339   if ( $old->get('susp') || $self->get('susp') ) {
1340     dbh->rollback if $oldAutoCommit;
1341     return "";  # no error                     # complain on adjourn?
1342   }
1343
1344   my $suspend_time = $options{'time'} || time;
1345   my $date = $options{date} if $options{date}; # adjourn/suspend later
1346   $date = '' if ($date && $date <= $suspend_time); # complain instead?
1347
1348   if ( $date && $old->get('expire') && $old->get('expire') < $date ) {
1349     dbh->rollback if $oldAutoCommit;
1350     return "Package $pkgnum expires before it would be suspended.";
1351   }
1352
1353   # some false laziness with sub cancel
1354   if ( !$options{nobill} && !$date && !$options{'from_cancel'} &&
1355        $self->part_pkg->option('bill_suspend_as_cancel',1) ) {
1356     # kind of a kludge--'bill_suspend_as_cancel' to avoid having to
1357     # make the entire cust_main->bill path recognize 'suspend' and
1358     # 'cancel' separately.
1359     warn "Billing $pkgnum on suspension (at $suspend_time)\n" if $DEBUG;
1360     my $copy = $self->new({$self->hash});
1361     my $error =
1362       $copy->cust_main->bill( 'pkg_list' => [ $copy ],
1363                               'cancel'   => 1,
1364                               'time'     => $suspend_time );
1365     warn "Error billing during suspend, custnum ".
1366       #$self->cust_main->custnum. ": $error"
1367       ": $error"
1368       if $error;
1369   }
1370
1371   my $cust_pkg_reason;
1372   if ( $options{'reason'} ) {
1373     $error = $self->insert_reason( 'reason' => $options{'reason'},
1374                                    'action' => $date ? 'adjourn' : 'suspend',
1375                                    'date'   => $date ? $date : $suspend_time,
1376                                    'reason_otaker' => $options{'reason_otaker'},
1377                                  );
1378     if ( $error ) {
1379       dbh->rollback if $oldAutoCommit;
1380       return "Error inserting cust_pkg_reason: $error";
1381     }
1382     $cust_pkg_reason = qsearchs('cust_pkg_reason', {
1383         'date'    => $date ? $date : $suspend_time,
1384         'action'  => $date ? 'A' : 'S',
1385         'pkgnum'  => $self->pkgnum,
1386     });
1387   }
1388
1389   # if a reasonnum was passed, get the actual reason object so we can check
1390   # unused_credit
1391   # (passing a reason hashref is still allowed, but it can't be used with
1392   # the fancy behavioral options.)
1393
1394   my $reason;
1395   if ($options{'reason'} =~ /^\d+$/) {
1396     $reason = FS::reason->by_key($options{'reason'});
1397   }
1398
1399   my %hash = $self->hash;
1400   if ( $date ) {
1401     $hash{'adjourn'} = $date;
1402   } else {
1403     $hash{'susp'} = $suspend_time;
1404   }
1405
1406   my $resume_date = $options{'resume_date'} || 0;
1407   if ( $resume_date > ($date || $suspend_time) ) {
1408     $hash{'resume'} = $resume_date;
1409   }
1410
1411   $options{options} ||= {};
1412
1413   my $new = new FS::cust_pkg ( \%hash );
1414   $error = $new->replace( $self, options => { $self->options,
1415                                               %{ $options{options} },
1416                                             }
1417                         );
1418   if ( $error ) {
1419     $dbh->rollback if $oldAutoCommit;
1420     return $error;
1421   }
1422
1423   unless ( $date ) { # then we are suspending now
1424
1425     unless ($options{'from_cancel'}) {
1426       # credit remaining time if appropriate
1427       # (if required by the package def, or the suspend reason)
1428       my $unused_credit = $self->part_pkg->option('unused_credit_suspend',1)
1429                           || ( defined($reason) && $reason->unused_credit );
1430
1431       if ( $unused_credit ) {
1432         warn "crediting unused time on pkg#".$self->pkgnum."\n" if $DEBUG;
1433         my $error = $self->credit_remaining('suspend', $suspend_time);
1434         if ($error) {
1435           $dbh->rollback if $oldAutoCommit;
1436           return $error;
1437         }
1438       }
1439     }
1440
1441     my @labels = ();
1442
1443     foreach my $cust_svc (
1444       qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
1445     ) {
1446       my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1447
1448       $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1449         $dbh->rollback if $oldAutoCommit;
1450         return "Illegal svcdb value in part_svc!";
1451       };
1452       my $svcdb = $1;
1453       require "FS/$svcdb.pm";
1454
1455       my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1456       if ($svc) {
1457         $error = $svc->suspend;
1458         if ( $error ) {
1459           $dbh->rollback if $oldAutoCommit;
1460           return $error;
1461         }
1462         my( $label, $value ) = $cust_svc->label;
1463         push @labels, "$label: $value";
1464       }
1465     }
1466
1467     # suspension fees: if there is a feepart, and it's not an unsuspend fee,
1468     # and this is not a suspend-before-cancel
1469     if ( $cust_pkg_reason ) {
1470       my $reason_obj = $cust_pkg_reason->reason;
1471       if ( $reason_obj->feepart and
1472            ! $reason_obj->fee_on_unsuspend and
1473            ! $options{'from_cancel'} ) {
1474
1475         # register the need to charge a fee, cust_main->bill will do the rest
1476         warn "registering suspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1477           if $DEBUG;
1478         my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1479             'pkgreasonnum'  => $cust_pkg_reason->num,
1480             'pkgnum'        => $self->pkgnum,
1481             'feepart'       => $reason->feepart,
1482             'nextbill'      => $reason->fee_hold,
1483         });
1484         $error ||= $cust_pkg_reason_fee->insert;
1485       }
1486     }
1487
1488     my $conf = new FS::Conf;
1489     if ( $conf->config('suspend_email_admin') && !$options{'from_cancel'} ) {
1490
1491       my $error = send_email(
1492         'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1493                                    #invoice_from ??? well as good as any
1494         'to'      => $conf->config('suspend_email_admin'),
1495         'subject' => 'FREESIDE NOTIFICATION: Customer package suspended',
1496         'body'    => [
1497           "This is an automatic message from your Freeside installation\n",
1498           "informing you that the following customer package has been suspended:\n",
1499           "\n",
1500           'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1501           'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1502           ( map { "Service : $_\n" } @labels ),
1503         ],
1504         'custnum' => $self->custnum,
1505         'msgtype' => 'admin'
1506       );
1507
1508       if ( $error ) {
1509         warn "WARNING: can't send suspension admin email (suspending anyway): ".
1510              "$error\n";
1511       }
1512
1513     }
1514
1515   }
1516
1517   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1518     $error = $supp_pkg->suspend(%options, 'from_main' => 1);
1519     if ( $error ) {
1520       $dbh->rollback if $oldAutoCommit;
1521       return "suspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1522     }
1523   }
1524
1525   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1526
1527   ''; #no errors
1528 }
1529
1530 =item credit_remaining MODE TIME
1531
1532 Generate a credit for this package for the time remaining in the current
1533 billing period.  MODE is either "suspend" or "cancel" (determines the
1534 credit type).  TIME is the time of suspension/cancellation.  Both arguments
1535 are mandatory.
1536
1537 =cut
1538
1539 # Implementation note:
1540 #
1541 # If you pkgpart-change a package that has been billed, and it's set to give
1542 # credit on package change, then this method gets called and then the new
1543 # package will have no last_bill date. Therefore the customer will be credited
1544 # only once (per billing period) even if there are multiple package changes.
1545 #
1546 # If you location-change a package that has been billed, this method will NOT
1547 # be called and the new package WILL have the last bill date of the old
1548 # package.
1549 #
1550 # If the new package is then canceled within the same billing cycle,
1551 # credit_remaining needs to run calc_remain on the OLD package to determine
1552 # the amount of unused time to credit.
1553
1554 sub credit_remaining {
1555   # Add a credit for remaining service
1556   my ($self, $mode, $time) = @_;
1557   die 'credit_remaining requires suspend or cancel'
1558     unless $mode eq 'suspend' or $mode eq 'cancel';
1559   die 'no suspend/cancel time' unless $time > 0;
1560
1561   my $conf = FS::Conf->new;
1562   my $reason_type = $conf->config($mode.'_credit_type');
1563
1564   my $last_bill = $self->getfield('last_bill') || 0;
1565   my $next_bill = $self->getfield('bill') || 0;
1566   if ( $last_bill > 0         # the package has been billed
1567       and $next_bill > 0      # the package has a next bill date
1568       and $next_bill >= $time # which is in the future
1569   ) {
1570     my $remaining_value = 0;
1571
1572     my $remain_pkg = $self;
1573     $remaining_value = $remain_pkg->calc_remain('time' => $time);
1574
1575     # we may have to walk back past some package changes to get to the
1576     # one that actually has unused time
1577     while ( $remaining_value == 0 ) {
1578       if ( $remain_pkg->change_pkgnum ) {
1579         $remain_pkg = FS::cust_pkg->by_key($remain_pkg->change_pkgnum);
1580       } else {
1581         # the package has really never been billed
1582         return;
1583       }
1584       $remaining_value = $remain_pkg->calc_remain('time' => $time);
1585     }
1586
1587     if ( $remaining_value > 0 ) {
1588       warn "Crediting for $remaining_value on package ".$self->pkgnum."\n"
1589         if $DEBUG;
1590       my $error = $self->cust_main->credit(
1591         $remaining_value,
1592         'Credit for unused time on '. $self->part_pkg->pkg,
1593         'reason_type' => $reason_type,
1594       );
1595       return "Error crediting customer \$$remaining_value for unused time".
1596         " on ". $self->part_pkg->pkg. ": $error"
1597         if $error;
1598     } #if $remaining_value
1599   } #if $last_bill, etc.
1600   '';
1601 }
1602
1603 =item unsuspend [ OPTION => VALUE ... ]
1604
1605 Unsuspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1606 package, then unsuspends the package itself (clears the susp field and the
1607 adjourn field if it is in the past).  If the suspend reason includes an
1608 unsuspension package, that package will be ordered.
1609
1610 Available options are:
1611
1612 =over 4
1613
1614 =item date
1615
1616 Can be set to a date to unsuspend the package in the future (the 'resume'
1617 field).
1618
1619 =item adjust_next_bill
1620
1621 Can be set true to adjust the next bill date forward by
1622 the amount of time the account was inactive.  This was set true by default
1623 in the past (from 1.4.2 and 1.5.0pre6 through 1.7.0), but now needs to be
1624 explicitly requested with this option or in the price plan.
1625
1626 =back
1627
1628 If there is an error, returns the error, otherwise returns false.
1629
1630 =cut
1631
1632 sub unsuspend {
1633   my( $self, %opt ) = @_;
1634   my $error;
1635
1636   # pass all suspend/cancel actions to the main package
1637   if ( $self->main_pkgnum and !$opt{'from_main'} ) {
1638     return $self->main_pkg->unsuspend(%opt);
1639   }
1640
1641   local $SIG{HUP} = 'IGNORE';
1642   local $SIG{INT} = 'IGNORE';
1643   local $SIG{QUIT} = 'IGNORE';
1644   local $SIG{TERM} = 'IGNORE';
1645   local $SIG{TSTP} = 'IGNORE';
1646   local $SIG{PIPE} = 'IGNORE';
1647
1648   my $oldAutoCommit = $FS::UID::AutoCommit;
1649   local $FS::UID::AutoCommit = 0;
1650   my $dbh = dbh;
1651
1652   my $old = $self->select_for_update;
1653
1654   my $pkgnum = $old->pkgnum;
1655   if ( $old->get('cancel') || $self->get('cancel') ) {
1656     $dbh->rollback if $oldAutoCommit;
1657     return "Can't unsuspend cancelled package $pkgnum";
1658   }
1659
1660   unless ( $old->get('susp') && $self->get('susp') ) {
1661     $dbh->rollback if $oldAutoCommit;
1662     return "";  # no error                     # complain instead?
1663   }
1664
1665   # handle the case of setting a future unsuspend (resume) date
1666   # and do not continue to actually unsuspend the package
1667   my $date = $opt{'date'};
1668   if ( $date and $date > time ) { # return an error if $date <= time?
1669
1670     if ( $old->get('expire') && $old->get('expire') < $date ) {
1671       $dbh->rollback if $oldAutoCommit;
1672       return "Package $pkgnum expires before it would be unsuspended.";
1673     }
1674
1675     my $new = new FS::cust_pkg { $self->hash };
1676     $new->set('resume', $date);
1677     $error = $new->replace($self, options => $self->options);
1678
1679     if ( $error ) {
1680       $dbh->rollback if $oldAutoCommit;
1681       return $error;
1682     }
1683     else {
1684       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1685       return '';
1686     }
1687
1688   } #if $date
1689
1690   if (!$self->setup) {
1691     # then this package is being released from on-hold status
1692     $self->set_initial_timers;
1693   }
1694
1695   my @labels = ();
1696
1697   foreach my $cust_svc (
1698     qsearch('cust_svc',{'pkgnum'=> $self->pkgnum } )
1699   ) {
1700     my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1701
1702     $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1703       $dbh->rollback if $oldAutoCommit;
1704       return "Illegal svcdb value in part_svc!";
1705     };
1706     my $svcdb = $1;
1707     require "FS/$svcdb.pm";
1708
1709     my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1710     if ($svc) {
1711       $error = $svc->unsuspend;
1712       if ( $error ) {
1713         $dbh->rollback if $oldAutoCommit;
1714         return $error;
1715       }
1716       my( $label, $value ) = $cust_svc->label;
1717       push @labels, "$label: $value";
1718     }
1719
1720   }
1721
1722   my $cust_pkg_reason = $self->last_cust_pkg_reason('susp');
1723   my $reason = $cust_pkg_reason ? $cust_pkg_reason->reason : '';
1724
1725   my %hash = $self->hash;
1726   my $inactive = time - $hash{'susp'};
1727
1728   my $conf = new FS::Conf;
1729
1730   # increment next bill date if certain conditions are met:
1731   # - it was due to be billed at some point
1732   # - either the global or local config says to do this
1733   my $adjust_bill = 0;
1734   if (
1735        $inactive > 0
1736     && ( $hash{'bill'} || $hash{'setup'} )
1737     && (    $opt{'adjust_next_bill'}
1738          || $conf->exists('unsuspend-always_adjust_next_bill_date')
1739          || $self->part_pkg->option('unsuspend_adjust_bill', 1)
1740        )
1741   ) {
1742     $adjust_bill = 1;
1743   }
1744
1745   # but not if:
1746   # - the package billed during suspension
1747   # - or it was ordered on hold
1748   # - or the customer was credited for the unused time
1749
1750   if ( $self->option('suspend_bill',1)
1751       or ( $self->part_pkg->option('suspend_bill',1)
1752            and ! $self->option('no_suspend_bill',1)
1753          )
1754       or $hash{'order_date'} == $hash{'susp'}
1755   ) {
1756     $adjust_bill = 0;
1757   }
1758
1759   if ( $adjust_bill ) {
1760     if (    $self->part_pkg->option('unused_credit_suspend')
1761          or ( $reason and $reason->unused_credit ) ) {
1762       # then the customer was credited for the unused time before suspending,
1763       # so their next bill should be immediate.
1764       $hash{'bill'} = time;
1765     } else {
1766       # add the length of time suspended to the bill date
1767       $hash{'bill'} = ( $hash{'bill'} || $hash{'setup'} ) + $inactive;
1768     }
1769   }
1770
1771   $hash{'susp'} = '';
1772   $hash{'adjourn'} = '' if $hash{'adjourn'} and $hash{'adjourn'} < time;
1773   $hash{'resume'} = '' if !$hash{'adjourn'};
1774   my $new = new FS::cust_pkg ( \%hash );
1775   $error = $new->replace( $self, options => { $self->options } );
1776   if ( $error ) {
1777     $dbh->rollback if $oldAutoCommit;
1778     return $error;
1779   }
1780
1781   my $unsusp_pkg;
1782
1783   if ( $reason ) {
1784     if ( $reason->unsuspend_pkgpart ) {
1785       #warn "Suspend reason '".$reason->reason."' uses deprecated unsuspend_pkgpart feature.\n"; # in 4.x
1786       my $part_pkg = FS::part_pkg->by_key($reason->unsuspend_pkgpart)
1787         or $error = "Unsuspend package definition ".$reason->unsuspend_pkgpart.
1788                     " not found.";
1789       my $start_date = $self->cust_main->next_bill_date
1790         if $reason->unsuspend_hold;
1791
1792       if ( $part_pkg ) {
1793         $unsusp_pkg = FS::cust_pkg->new({
1794             'custnum'     => $self->custnum,
1795             'pkgpart'     => $reason->unsuspend_pkgpart,
1796             'start_date'  => $start_date,
1797             'locationnum' => $self->locationnum,
1798             # discount? probably not...
1799         });
1800
1801         $error ||= $self->cust_main->order_pkg( 'cust_pkg' => $unsusp_pkg );
1802       }
1803     }
1804     # new way, using fees
1805     if ( $reason->feepart and $reason->fee_on_unsuspend ) {
1806       # register the need to charge a fee, cust_main->bill will do the rest
1807       warn "registering unsuspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1808         if $DEBUG;
1809       my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1810           'pkgreasonnum'  => $cust_pkg_reason->num,
1811           'pkgnum'        => $self->pkgnum,
1812           'feepart'       => $reason->feepart,
1813           'nextbill'      => $reason->fee_hold,
1814       });
1815       $error ||= $cust_pkg_reason_fee->insert;
1816     }
1817
1818     if ( $error ) {
1819       $dbh->rollback if $oldAutoCommit;
1820       return $error;
1821     }
1822   }
1823
1824   if ( $conf->config('unsuspend_email_admin') ) {
1825
1826     my $error = send_email(
1827       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1828                                  #invoice_from ??? well as good as any
1829       'to'      => $conf->config('unsuspend_email_admin'),
1830       'subject' => 'FREESIDE NOTIFICATION: Customer package unsuspended',       'body'    => [
1831         "This is an automatic message from your Freeside installation\n",
1832         "informing you that the following customer package has been unsuspended:\n",
1833         "\n",
1834         'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1835         'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1836         ( map { "Service : $_\n" } @labels ),
1837         ($unsusp_pkg ?
1838           "An unsuspension fee was charged: ".
1839             $unsusp_pkg->part_pkg->pkg_comment."\n"
1840           : ''
1841         ),
1842       ],
1843       'custnum' => $self->custnum,
1844       'msgtype' => 'admin',
1845     );
1846
1847     if ( $error ) {
1848       warn "WARNING: can't send unsuspension admin email (unsuspending anyway): ".
1849            "$error\n";
1850     }
1851
1852   }
1853
1854   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1855     $error = $supp_pkg->unsuspend(%opt, 'from_main' => 1);
1856     if ( $error ) {
1857       $dbh->rollback if $oldAutoCommit;
1858       return "unsuspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1859     }
1860   }
1861
1862   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1863
1864   ''; #no errors
1865 }
1866
1867 =item unadjourn
1868
1869 Cancels any pending suspension (sets the adjourn field to null).
1870
1871 If there is an error, returns the error, otherwise returns false.
1872
1873 =cut
1874
1875 sub unadjourn {
1876   my( $self, %options ) = @_;
1877   my $error;
1878
1879   local $SIG{HUP} = 'IGNORE';
1880   local $SIG{INT} = 'IGNORE';
1881   local $SIG{QUIT} = 'IGNORE';
1882   local $SIG{TERM} = 'IGNORE';
1883   local $SIG{TSTP} = 'IGNORE';
1884   local $SIG{PIPE} = 'IGNORE';
1885
1886   my $oldAutoCommit = $FS::UID::AutoCommit;
1887   local $FS::UID::AutoCommit = 0;
1888   my $dbh = dbh;
1889
1890   my $old = $self->select_for_update;
1891
1892   my $pkgnum = $old->pkgnum;
1893   if ( $old->get('cancel') || $self->get('cancel') ) {
1894     dbh->rollback if $oldAutoCommit;
1895     return "Can't unadjourn cancelled package $pkgnum";
1896     # or at least it's pointless
1897   }
1898
1899   if ( $old->get('susp') || $self->get('susp') ) {
1900     dbh->rollback if $oldAutoCommit;
1901     return "Can't unadjourn suspended package $pkgnum";
1902     # perhaps this is arbitrary
1903   }
1904
1905   unless ( $old->get('adjourn') && $self->get('adjourn') ) {
1906     dbh->rollback if $oldAutoCommit;
1907     return "";  # no error
1908   }
1909
1910   my %hash = $self->hash;
1911   $hash{'adjourn'} = '';
1912   $hash{'resume'}  = '';
1913   my $new = new FS::cust_pkg ( \%hash );
1914   $error = $new->replace( $self, options => { $self->options } );
1915   if ( $error ) {
1916     $dbh->rollback if $oldAutoCommit;
1917     return $error;
1918   }
1919
1920   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1921
1922   ''; #no errors
1923
1924 }
1925
1926
1927 =item change HASHREF | OPTION => VALUE ...
1928
1929 Changes this package: cancels it and creates a new one, with a different
1930 pkgpart or locationnum or both.  All services are transferred to the new
1931 package (no change will be made if this is not possible).
1932
1933 Options may be passed as a list of key/value pairs or as a hash reference.
1934 Options are:
1935
1936 =over 4
1937
1938 =item locationnum
1939
1940 New locationnum, to change the location for this package.
1941
1942 =item cust_location
1943
1944 New FS::cust_location object, to create a new location and assign it
1945 to this package.
1946
1947 =item cust_main
1948
1949 New FS::cust_main object, to create a new customer and assign the new package
1950 to it.
1951
1952 =item pkgpart
1953
1954 New pkgpart (see L<FS::part_pkg>).
1955
1956 =item refnum
1957
1958 New refnum (see L<FS::part_referral>).
1959
1960 =item quantity
1961
1962 New quantity; if unspecified, the new package will have the same quantity
1963 as the old.
1964
1965 =item cust_pkg
1966
1967 "New" (existing) FS::cust_pkg object.  The package's services and other
1968 attributes will be transferred to this package.
1969
1970 =item keep_dates
1971
1972 Set to true to transfer billing dates (start_date, setup, last_bill, bill,
1973 susp, adjourn, cancel, expire, and contract_end) to the new package.
1974
1975 =item unprotect_svcs
1976
1977 Normally, change() will rollback and return an error if some services
1978 can't be transferred (also see the I<cust_pkg-change_svcpart> config option).
1979 If unprotect_svcs is true, this method will transfer as many services as
1980 it can and then unconditionally cancel the old package.
1981
1982 =back
1983
1984 At least one of locationnum, cust_location, pkgpart, refnum, cust_main, or
1985 cust_pkg must be specified (otherwise, what's the point?)
1986
1987 Returns either the new FS::cust_pkg object or a scalar error.
1988
1989 For example:
1990
1991   my $err_or_new_cust_pkg = $old_cust_pkg->change
1992
1993 =cut
1994
1995 #some false laziness w/order
1996 sub change {
1997   my $self = shift;
1998   my $opt = ref($_[0]) ? shift : { @_ };
1999
2000   my $conf = new FS::Conf;
2001
2002   # Transactionize this whole mess
2003   local $SIG{HUP} = 'IGNORE';
2004   local $SIG{INT} = 'IGNORE';
2005   local $SIG{QUIT} = 'IGNORE';
2006   local $SIG{TERM} = 'IGNORE';
2007   local $SIG{TSTP} = 'IGNORE';
2008   local $SIG{PIPE} = 'IGNORE';
2009
2010   my $oldAutoCommit = $FS::UID::AutoCommit;
2011   local $FS::UID::AutoCommit = 0;
2012   my $dbh = dbh;
2013
2014   my $error;
2015
2016   if ( $opt->{'cust_location'} ) {
2017     $error = $opt->{'cust_location'}->find_or_insert;
2018     if ( $error ) {
2019       $dbh->rollback if $oldAutoCommit;
2020       return "creating location record: $error";
2021     }
2022     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
2023   }
2024
2025   # Before going any further here: if the package is still in the pre-setup
2026   # state, it's safe to modify it in place. No need to charge/credit for
2027   # partial period, transfer services, transfer usage pools, copy invoice
2028   # details, or change any dates.
2029   if ( ! $self->setup and ! $opt->{cust_pkg} and ! $opt->{cust_main} ) {
2030     foreach ( qw( locationnum pkgpart quantity refnum salesnum ) ) {
2031       if ( length($opt->{$_}) ) {
2032         $self->set($_, $opt->{$_});
2033       }
2034     }
2035     # almost. if the new pkgpart specifies start/adjourn/expire timers,
2036     # apply those.
2037     if ( $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart ) {
2038       $self->set_initial_timers;
2039     }
2040     $error = $self->replace;
2041     if ( $error ) {
2042       $dbh->rollback if $oldAutoCommit;
2043       return "modifying package: $error";
2044     } else {
2045       $dbh->commit if $oldAutoCommit;
2046       return $self;
2047     }
2048   }
2049
2050   my %hash = ();
2051
2052   my $time = time;
2053
2054   $hash{'setup'} = $time if $self->setup;
2055
2056   $hash{'change_date'} = $time;
2057   $hash{"change_$_"}  = $self->$_()
2058     foreach qw( pkgnum pkgpart locationnum );
2059
2060   if ( $opt->{'cust_pkg'} ) {
2061     # treat changing to a package with a different pkgpart as a
2062     # pkgpart change (because it is)
2063     $opt->{'pkgpart'} = $opt->{'cust_pkg'}->pkgpart;
2064   }
2065
2066   # whether to override pkgpart checking on the new package
2067   my $same_pkgpart = 1;
2068   if ( $opt->{'pkgpart'} and ( $opt->{'pkgpart'} != $self->pkgpart ) ) {
2069     $same_pkgpart = 0;
2070   }
2071
2072   my $unused_credit = 0;
2073   my $keep_dates = $opt->{'keep_dates'};
2074
2075   # Special case.  If the pkgpart is changing, and the customer is
2076   # going to be credited for remaining time, don't keep setup, bill,
2077   # or last_bill dates, and DO pass the flag to cancel() to credit
2078   # the customer.
2079   if ( $opt->{'pkgpart'}
2080        and $opt->{'pkgpart'} != $self->pkgpart
2081        and $self->part_pkg->option('unused_credit_change', 1) ) {
2082     $unused_credit = 1;
2083     $keep_dates = 0;
2084     $hash{$_} = '' foreach qw(setup bill last_bill);
2085   }
2086
2087   if ( $keep_dates ) {
2088     foreach my $date ( qw(setup bill last_bill) ) {
2089       $hash{$date} = $self->getfield($date);
2090     }
2091   }
2092   # always keep the following dates
2093   foreach my $date (qw(order_date susp adjourn cancel expire resume
2094                     start_date contract_end)) {
2095     $hash{$date} = $self->getfield($date);
2096   }
2097
2098   # allow $opt->{'locationnum'} = '' to specifically set it to null
2099   # (i.e. customer default location)
2100   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2101
2102   # usually this doesn't matter.  the two cases where it does are:
2103   # 1. unused_credit_change + pkgpart change + setup fee on the new package
2104   # and
2105   # 2. (more importantly) changing a package before it's billed
2106   $hash{'waive_setup'} = $self->waive_setup;
2107
2108   # if this package is scheduled for a future package change, preserve that
2109   $hash{'change_to_pkgnum'} = $self->change_to_pkgnum;
2110
2111   my $custnum = $self->custnum;
2112   if ( $opt->{cust_main} ) {
2113     my $cust_main = $opt->{cust_main};
2114     unless ( $cust_main->custnum ) {
2115       my $error = $cust_main->insert( @{ $opt->{cust_main_insert_args}||[] } );
2116       if ( $error ) {
2117         $dbh->rollback if $oldAutoCommit;
2118         return "inserting customer record: $error";
2119       }
2120     }
2121     $custnum = $cust_main->custnum;
2122   }
2123
2124   $hash{'contactnum'} = $opt->{'contactnum'} if $opt->{'contactnum'};
2125
2126   my $cust_pkg;
2127   if ( $opt->{'cust_pkg'} ) {
2128     # The target package already exists; update it to show that it was
2129     # changed from this package.
2130     $cust_pkg = $opt->{'cust_pkg'};
2131
2132     # follow all the above rules for date changes, etc.
2133     foreach (keys %hash) {
2134       $cust_pkg->set($_, $hash{$_});
2135     }
2136     # except those that implement the future package change behavior
2137     foreach (qw(change_to_pkgnum start_date expire)) {
2138       $cust_pkg->set($_, '');
2139     }
2140
2141     $error = $cust_pkg->replace;
2142
2143   } else {
2144     # Create the new package.
2145     $cust_pkg = new FS::cust_pkg {
2146       custnum     => $custnum,
2147       locationnum => $opt->{'locationnum'},
2148       ( map {  $_ => ( $opt->{$_} || $self->$_() )  }
2149           qw( pkgpart quantity refnum salesnum )
2150       ),
2151       %hash,
2152     };
2153     $error = $cust_pkg->insert( 'change' => 1,
2154                                 'allow_pkgpart' => $same_pkgpart );
2155   }
2156   if ($error) {
2157     $dbh->rollback if $oldAutoCommit;
2158     return "inserting new package: $error";
2159   }
2160
2161   # Transfer services and cancel old package.
2162   # Enforce service limits only if this is a pkgpart change.
2163   local $FS::cust_svc::ignore_quantity;
2164   $FS::cust_svc::ignore_quantity = 1 if $same_pkgpart;
2165   $error = $self->transfer($cust_pkg);
2166   if ($error and $error == 0) {
2167     # $old_pkg->transfer failed.
2168     $dbh->rollback if $oldAutoCommit;
2169     return "transferring $error";
2170   }
2171
2172   if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
2173     warn "trying transfer again with change_svcpart option\n" if $DEBUG;
2174     $error = $self->transfer($cust_pkg, 'change_svcpart'=>1 );
2175     if ($error and $error == 0) {
2176       # $old_pkg->transfer failed.
2177       $dbh->rollback if $oldAutoCommit;
2178       return "converting $error";
2179     }
2180   }
2181
2182   # We set unprotect_svcs when executing a "future package change".  It's
2183   # not a user-interactive operation, so returning an error means the
2184   # package change will just fail.  Rather than have that happen, we'll
2185   # let leftover services be deleted.
2186   if ($error > 0 and !$opt->{'unprotect_svcs'}) {
2187     # Transfers were successful, but we still had services left on the old
2188     # package.  We can't change the package under this circumstances, so abort.
2189     $dbh->rollback if $oldAutoCommit;
2190     return "unable to transfer all services";
2191   }
2192
2193   #reset usage if changing pkgpart
2194   # AND usage rollover is off (otherwise adds twice, now and at package bill)
2195   if ($self->pkgpart != $cust_pkg->pkgpart) {
2196     my $part_pkg = $cust_pkg->part_pkg;
2197     $error = $part_pkg->reset_usage($cust_pkg, $part_pkg->is_prepaid
2198                                                  ? ()
2199                                                  : ( 'null' => 1 )
2200                                    )
2201       if $part_pkg->can('reset_usage') && ! $part_pkg->option('usage_rollover',1);
2202
2203     if ($error) {
2204       $dbh->rollback if $oldAutoCommit;
2205       return "setting usage values: $error";
2206     }
2207   } else {
2208     # if NOT changing pkgpart, transfer any usage pools over
2209     foreach my $usage ($self->cust_pkg_usage) {
2210       $usage->set('pkgnum', $cust_pkg->pkgnum);
2211       $error = $usage->replace;
2212       if ( $error ) {
2213         $dbh->rollback if $oldAutoCommit;
2214         return "transferring usage pools: $error";
2215       }
2216     }
2217   }
2218
2219   # transfer discounts, if we're not changing pkgpart
2220   if ( $same_pkgpart ) {
2221     foreach my $old_discount ($self->cust_pkg_discount_active) {
2222       # don't remove the old discount, we may still need to bill that package.
2223       my $new_discount = new FS::cust_pkg_discount {
2224         'pkgnum'      => $cust_pkg->pkgnum,
2225         'discountnum' => $old_discount->discountnum,
2226         'months_used' => $old_discount->months_used,
2227       };
2228       $error = $new_discount->insert;
2229       if ( $error ) {
2230         $dbh->rollback if $oldAutoCommit;
2231         return "transferring discounts: $error";
2232       }
2233     }
2234   }
2235
2236   # transfer (copy) invoice details
2237   foreach my $detail ($self->cust_pkg_detail) {
2238     my $new_detail = FS::cust_pkg_detail->new({ $detail->hash });
2239     $new_detail->set('pkgdetailnum', '');
2240     $new_detail->set('pkgnum', $cust_pkg->pkgnum);
2241     $error = $new_detail->insert;
2242     if ( $error ) {
2243       $dbh->rollback if $oldAutoCommit;
2244       return "transferring package notes: $error";
2245     }
2246   }
2247
2248   my @new_supp_pkgs;
2249
2250   if ( !$opt->{'cust_pkg'} ) {
2251     # Order any supplemental packages.
2252     my $part_pkg = $cust_pkg->part_pkg;
2253     my @old_supp_pkgs = $self->supplemental_pkgs;
2254     foreach my $link ($part_pkg->supp_part_pkg_link) {
2255       my $old;
2256       foreach (@old_supp_pkgs) {
2257         if ($_->pkgpart == $link->dst_pkgpart) {
2258           $old = $_;
2259           $_->pkgpart(0); # so that it can't match more than once
2260         }
2261         last if $old;
2262       }
2263       # false laziness with FS::cust_main::Packages::order_pkg
2264       my $new = FS::cust_pkg->new({
2265           pkgpart       => $link->dst_pkgpart,
2266           pkglinknum    => $link->pkglinknum,
2267           custnum       => $custnum,
2268           main_pkgnum   => $cust_pkg->pkgnum,
2269           locationnum   => $cust_pkg->locationnum,
2270           start_date    => $cust_pkg->start_date,
2271           order_date    => $cust_pkg->order_date,
2272           expire        => $cust_pkg->expire,
2273           adjourn       => $cust_pkg->adjourn,
2274           contract_end  => $cust_pkg->contract_end,
2275           refnum        => $cust_pkg->refnum,
2276           discountnum   => $cust_pkg->discountnum,
2277           waive_setup   => $cust_pkg->waive_setup,
2278       });
2279       if ( $old and $opt->{'keep_dates'} ) {
2280         foreach (qw(setup bill last_bill)) {
2281           $new->set($_, $old->get($_));
2282         }
2283       }
2284       $error = $new->insert( allow_pkgpart => $same_pkgpart );
2285       # transfer services
2286       if ( $old ) {
2287         $error ||= $old->transfer($new);
2288       }
2289       if ( $error and $error > 0 ) {
2290         # no reason why this should ever fail, but still...
2291         $error = "Unable to transfer all services from supplemental package ".
2292           $old->pkgnum;
2293       }
2294       if ( $error ) {
2295         $dbh->rollback if $oldAutoCommit;
2296         return $error;
2297       }
2298       push @new_supp_pkgs, $new;
2299     }
2300   } # if !$opt->{'cust_pkg'}
2301     # because if there is one, then supplemental packages would already
2302     # have been created for it.
2303
2304   #Good to go, cancel old package.  Notify 'cancel' of whether to credit
2305   #remaining time.
2306   #Don't allow billing the package (preceding period packages and/or
2307   #outstanding usage) if we are keeping dates (i.e. location changing),
2308   #because the new package will be billed for the same date range.
2309   #Supplemental packages are also canceled here.
2310
2311   # during scheduled changes, avoid canceling the package we just
2312   # changed to (duh)
2313   $self->set('change_to_pkgnum' => '');
2314
2315   $error = $self->cancel(
2316     quiet          => 1,
2317     unused_credit  => $unused_credit,
2318     nobill         => $keep_dates,
2319     change_custnum => ( $self->custnum != $custnum ? $custnum : '' ),
2320     no_delay_cancel => 1,
2321   );
2322   if ($error) {
2323     $dbh->rollback if $oldAutoCommit;
2324     return "canceling old package: $error";
2325   }
2326
2327   if ( $conf->exists('cust_pkg-change_pkgpart-bill_now') ) {
2328     #$self->cust_main
2329     my $error = $cust_pkg->cust_main->bill(
2330       'pkg_list' => [ $cust_pkg, @new_supp_pkgs ]
2331     );
2332     if ( $error ) {
2333       $dbh->rollback if $oldAutoCommit;
2334       return "billing new package: $error";
2335     }
2336   }
2337
2338   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2339
2340   $cust_pkg;
2341
2342 }
2343
2344 =item change_later OPTION => VALUE...
2345
2346 Schedule a package change for a later date.  This actually orders the new
2347 package immediately, but sets its start date for a future date, and sets
2348 the current package to expire on the same date.
2349
2350 If the package is already scheduled for a change, this can be called with
2351 'start_date' to change the scheduled date, or with pkgpart and/or
2352 locationnum to modify the package change.  To cancel the scheduled change
2353 entirely, see C<abort_change>.
2354
2355 Options include:
2356
2357 =over 4
2358
2359 =item start_date
2360
2361 The date for the package change.  Required, and must be in the future.
2362
2363 =item pkgpart
2364
2365 =item locationnum
2366
2367 =item quantity
2368
2369 The pkgpart. locationnum, and quantity of the new package, with the same
2370 meaning as in C<change>.
2371
2372 =back
2373
2374 =cut
2375
2376 sub change_later {
2377   my $self = shift;
2378   my $opt = ref($_[0]) ? shift : { @_ };
2379
2380   my $oldAutoCommit = $FS::UID::AutoCommit;
2381   local $FS::UID::AutoCommit = 0;
2382   my $dbh = dbh;
2383
2384   my $cust_main = $self->cust_main;
2385
2386   my $date = delete $opt->{'start_date'} or return 'start_date required';
2387
2388   if ( $date <= time ) {
2389     $dbh->rollback if $oldAutoCommit;
2390     return "start_date $date is in the past";
2391   }
2392
2393   my $error;
2394
2395   if ( $self->change_to_pkgnum ) {
2396     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
2397     my $new_pkgpart = $opt->{'pkgpart'}
2398         if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $change_to->pkgpart;
2399     my $new_locationnum = $opt->{'locationnum'}
2400         if $opt->{'locationnum'} and $opt->{'locationnum'} != $change_to->locationnum;
2401     my $new_quantity = $opt->{'quantity'}
2402         if $opt->{'quantity'} and $opt->{'quantity'} != $change_to->quantity;
2403     if ( $new_pkgpart or $new_locationnum or $new_quantity ) {
2404       # it hasn't been billed yet, so in principle we could just edit
2405       # it in place (w/o a package change), but that's bad form.
2406       # So change the package according to the new options...
2407       my $err_or_pkg = $change_to->change(%$opt);
2408       if ( ref $err_or_pkg ) {
2409         # Then set that package up for a future start.
2410         $self->set('change_to_pkgnum', $err_or_pkg->pkgnum);
2411         $self->set('expire', $date); # in case it's different
2412         $err_or_pkg->set('start_date', $date);
2413         $err_or_pkg->set('change_date', '');
2414         $err_or_pkg->set('change_pkgnum', '');
2415
2416         $error = $self->replace       ||
2417                  $err_or_pkg->replace ||
2418                  (($err_or_pkg->pkgnum == $change_to->pkgnum) ? '' :
2419                   $change_to->cancel('no_delay_cancel' => 1) ||
2420                   $change_to->delete);
2421       } else {
2422         $error = $err_or_pkg;
2423       }
2424     } else { # change the start date only.
2425       $self->set('expire', $date);
2426       $change_to->set('start_date', $date);
2427       $error = $self->replace || $change_to->replace;
2428     }
2429     if ( $error ) {
2430       $dbh->rollback if $oldAutoCommit;
2431       return $error;
2432     } else {
2433       $dbh->commit if $oldAutoCommit;
2434       return '';
2435     }
2436   } # if $self->change_to_pkgnum
2437
2438   my $new_pkgpart = $opt->{'pkgpart'}
2439       if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart;
2440   my $new_locationnum = $opt->{'locationnum'}
2441       if $opt->{'locationnum'} and $opt->{'locationnum'} != $self->locationnum;
2442   my $new_quantity = $opt->{'quantity'}
2443       if $opt->{'quantity'} and $opt->{'quantity'} != $self->quantity;
2444
2445   return '' unless $new_pkgpart or $new_locationnum or $new_quantity; # wouldn't do anything
2446
2447   # allow $opt->{'locationnum'} = '' to specifically set it to null
2448   # (i.e. customer default location)
2449   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2450
2451   my $new = FS::cust_pkg->new( {
2452     custnum     => $self->custnum,
2453     locationnum => $opt->{'locationnum'},
2454     start_date  => $date,
2455     map   {  $_ => ( $opt->{$_} || $self->$_() )  }
2456       qw( pkgpart quantity refnum salesnum )
2457   } );
2458   $error = $new->insert('change' => 1,
2459                         'allow_pkgpart' => ($new_pkgpart ? 0 : 1));
2460   if ( !$error ) {
2461     $self->set('change_to_pkgnum', $new->pkgnum);
2462     $self->set('expire', $date);
2463     $error = $self->replace;
2464   }
2465   if ( $error ) {
2466     $dbh->rollback if $oldAutoCommit;
2467   } else {
2468     $dbh->commit if $oldAutoCommit;
2469   }
2470
2471   $error;
2472 }
2473
2474 =item abort_change
2475
2476 Cancels a future package change scheduled by C<change_later>.
2477
2478 =cut
2479
2480 sub abort_change {
2481   my $self = shift;
2482   my $pkgnum = $self->change_to_pkgnum;
2483   my $change_to = FS::cust_pkg->by_key($pkgnum) if $pkgnum;
2484   my $error;
2485   if ( $change_to ) {
2486     $error = $change_to->cancel || $change_to->delete;
2487     return $error if $error;
2488   }
2489   $self->set('change_to_pkgnum', '');
2490   $self->set('expire', '');
2491   $self->replace;
2492 }
2493
2494 =item set_quantity QUANTITY
2495
2496 Change the package's quantity field.  This is one of the few package properties
2497 that can safely be changed without canceling and reordering the package
2498 (because it doesn't affect tax eligibility).  Returns an error or an
2499 empty string.
2500
2501 =cut
2502
2503 sub set_quantity {
2504   my $self = shift;
2505   $self = $self->replace_old; # just to make sure
2506   $self->quantity(shift);
2507   $self->replace;
2508 }
2509
2510 =item set_salesnum SALESNUM
2511
2512 Change the package's salesnum (sales person) field.  This is one of the few
2513 package properties that can safely be changed without canceling and reordering
2514 the package (because it doesn't affect tax eligibility).  Returns an error or
2515 an empty string.
2516
2517 =cut
2518
2519 sub set_salesnum {
2520   my $self = shift;
2521   $self = $self->replace_old; # just to make sure
2522   $self->salesnum(shift);
2523   $self->replace;
2524   # XXX this should probably reassign any credit that's already been given
2525 }
2526
2527 =item modify_charge OPTIONS
2528
2529 Change the properties of a one-time charge.  The following properties can
2530 be changed this way:
2531 - pkg: the package description
2532 - classnum: the package class
2533 - additional: arrayref of additional invoice details to add to this package
2534
2535 and, I<if the charge has not yet been billed>:
2536 - start_date: the date when it will be billed
2537 - amount: the setup fee to be charged
2538 - quantity: the multiplier for the setup fee
2539 - separate_bill: whether to put the charge on a separate invoice
2540
2541 If you pass 'adjust_commission' => 1, and the classnum changes, and there are
2542 commission credits linked to this charge, they will be recalculated.
2543
2544 =cut
2545
2546 sub modify_charge {
2547   my $self = shift;
2548   my %opt = @_;
2549   my $part_pkg = $self->part_pkg;
2550   my $pkgnum = $self->pkgnum;
2551
2552   my $dbh = dbh;
2553   my $oldAutoCommit = $FS::UID::AutoCommit;
2554   local $FS::UID::AutoCommit = 0;
2555
2556   return "Can't use modify_charge except on one-time charges"
2557     unless $part_pkg->freq eq '0';
2558
2559   if ( length($opt{'pkg'}) and $part_pkg->pkg ne $opt{'pkg'} ) {
2560     $part_pkg->set('pkg', $opt{'pkg'});
2561   }
2562
2563   my %pkg_opt = $part_pkg->options;
2564   my $pkg_opt_modified = 0;
2565
2566   $opt{'additional'} ||= [];
2567   my $i;
2568   my @old_additional;
2569   foreach (grep /^additional/, keys %pkg_opt) {
2570     ($i) = ($_ =~ /^additional_info(\d+)$/);
2571     $old_additional[$i] = $pkg_opt{$_} if $i;
2572     delete $pkg_opt{$_};
2573   }
2574
2575   for ( $i = 0; exists($opt{'additional'}->[$i]); $i++ ) {
2576     $pkg_opt{ "additional_info$i" } = $opt{'additional'}->[$i];
2577     if (!exists($old_additional[$i])
2578         or $old_additional[$i] ne $opt{'additional'}->[$i])
2579     {
2580       $pkg_opt_modified = 1;
2581     }
2582   }
2583   $pkg_opt_modified = 1 if (scalar(@old_additional) - 1) != $i;
2584   $pkg_opt{'additional_count'} = $i if $i > 0;
2585
2586   my $old_classnum;
2587   if ( exists($opt{'classnum'}) and $part_pkg->classnum ne $opt{'classnum'} )
2588   {
2589     # remember it
2590     $old_classnum = $part_pkg->classnum;
2591     $part_pkg->set('classnum', $opt{'classnum'});
2592   }
2593
2594   if ( !$self->get('setup') ) {
2595     # not yet billed, so allow amount, setup_cost, quantity, start_date,
2596     # and separate_bill
2597
2598     if ( exists($opt{'amount'})
2599           and $part_pkg->option('setup_fee') != $opt{'amount'}
2600           and $opt{'amount'} > 0 ) {
2601
2602       $pkg_opt{'setup_fee'} = $opt{'amount'};
2603       $pkg_opt_modified = 1;
2604     }
2605
2606     if ( exists($opt{'setup_cost'})
2607           and $part_pkg->setup_cost != $opt{'setup_cost'}
2608           and $opt{'setup_cost'} > 0 ) {
2609
2610       $part_pkg->set('setup_cost', $opt{'setup_cost'});
2611     }
2612
2613     if ( exists($opt{'quantity'})
2614           and $opt{'quantity'} != $self->quantity
2615           and $opt{'quantity'} > 0 ) {
2616
2617       $self->set('quantity', $opt{'quantity'});
2618     }
2619
2620     if ( exists($opt{'start_date'})
2621           and $opt{'start_date'} != $self->start_date ) {
2622
2623       $self->set('start_date', $opt{'start_date'});
2624     }
2625
2626     if ( exists($opt{'separate_bill'})
2627           and $opt{'separate_bill'} ne $self->separate_bill ) {
2628
2629       $self->set('separate_bill', $opt{'separate_bill'});
2630     }
2631
2632
2633   } # else simply ignore them; the UI shouldn't allow editing the fields
2634
2635   if ( exists($opt{'taxclass'})
2636           and $part_pkg->taxclass ne $opt{'taxclass'}) {
2637
2638       $part_pkg->set('taxclass', $opt{'taxclass'});
2639   }
2640
2641   my $error;
2642   if ( $part_pkg->modified or $pkg_opt_modified ) {
2643     # can we safely modify the package def?
2644     # Yes, if it's not available for purchase, and this is the only instance
2645     # of it.
2646     if ( $part_pkg->disabled
2647          and FS::cust_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 1
2648          and FS::quotation_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 0
2649        ) {
2650       $error = $part_pkg->replace( options => \%pkg_opt );
2651     } else {
2652       # clone it
2653       $part_pkg = $part_pkg->clone;
2654       $part_pkg->set('disabled' => 'Y');
2655       $error = $part_pkg->insert( options => \%pkg_opt );
2656       # and associate this as yet-unbilled package to the new package def
2657       $self->set('pkgpart' => $part_pkg->pkgpart);
2658     }
2659     if ( $error ) {
2660       $dbh->rollback if $oldAutoCommit;
2661       return $error;
2662     }
2663   }
2664
2665   if ($self->modified) { # for quantity or start_date change, or if we had
2666                          # to clone the existing package def
2667     my $error = $self->replace;
2668     return $error if $error;
2669   }
2670   if (defined $old_classnum) {
2671     # fix invoice grouping records
2672     my $old_catname = $old_classnum
2673                       ? FS::pkg_class->by_key($old_classnum)->categoryname
2674                       : '';
2675     my $new_catname = $opt{'classnum'}
2676                       ? $part_pkg->pkg_class->categoryname
2677                       : '';
2678     if ( $old_catname ne $new_catname ) {
2679       foreach my $cust_bill_pkg ($self->cust_bill_pkg) {
2680         # (there should only be one...)
2681         my @display = qsearch( 'cust_bill_pkg_display', {
2682             'billpkgnum'  => $cust_bill_pkg->billpkgnum,
2683             'section'     => $old_catname,
2684         });
2685         foreach (@display) {
2686           $_->set('section', $new_catname);
2687           $error = $_->replace;
2688           if ( $error ) {
2689             $dbh->rollback if $oldAutoCommit;
2690             return $error;
2691           }
2692         }
2693       } # foreach $cust_bill_pkg
2694     }
2695
2696     if ( $opt{'adjust_commission'} ) {
2697       # fix commission credits...tricky.
2698       foreach my $cust_event ($self->cust_event) {
2699         my $part_event = $cust_event->part_event;
2700         foreach my $table (qw(sales agent)) {
2701           my $class =
2702             "FS::part_event::Action::Mixin::credit_${table}_pkg_class";
2703           my $credit = qsearchs('cust_credit', {
2704               'eventnum' => $cust_event->eventnum,
2705           });
2706           if ( $part_event->isa($class) ) {
2707             # Yes, this results in current commission rates being applied
2708             # retroactively to a one-time charge.  For accounting purposes
2709             # there ought to be some kind of time limit on doing this.
2710             my $amount = $part_event->_calc_credit($self);
2711             if ( $credit and $credit->amount ne $amount ) {
2712               # Void the old credit.
2713               $error = $credit->void('Package class changed');
2714               if ( $error ) {
2715                 $dbh->rollback if $oldAutoCommit;
2716                 return "$error (adjusting commission credit)";
2717               }
2718             }
2719             # redo the event action to recreate the credit.
2720             local $@ = '';
2721             eval { $part_event->do_action( $self, $cust_event ) };
2722             if ( $@ ) {
2723               $dbh->rollback if $oldAutoCommit;
2724               return $@;
2725             }
2726           } # if $part_event->isa($class)
2727         } # foreach $table
2728       } # foreach $cust_event
2729     } # if $opt{'adjust_commission'}
2730   } # if defined $old_classnum
2731
2732   $dbh->commit if $oldAutoCommit;
2733   '';
2734 }
2735
2736
2737
2738 use Storable 'thaw';
2739 use MIME::Base64;
2740 use Data::Dumper;
2741 sub process_bulk_cust_pkg {
2742   my $job = shift;
2743   my $param = thaw(decode_base64(shift));
2744   warn Dumper($param) if $DEBUG;
2745
2746   my $old_part_pkg = qsearchs('part_pkg',
2747                               { pkgpart => $param->{'old_pkgpart'} });
2748   my $new_part_pkg = qsearchs('part_pkg',
2749                               { pkgpart => $param->{'new_pkgpart'} });
2750   die "Must select a new package type\n" unless $new_part_pkg;
2751   #my $keep_dates = $param->{'keep_dates'} || 0;
2752   my $keep_dates = 1; # there is no good reason to turn this off
2753
2754   local $SIG{HUP} = 'IGNORE';
2755   local $SIG{INT} = 'IGNORE';
2756   local $SIG{QUIT} = 'IGNORE';
2757   local $SIG{TERM} = 'IGNORE';
2758   local $SIG{TSTP} = 'IGNORE';
2759   local $SIG{PIPE} = 'IGNORE';
2760
2761   my $oldAutoCommit = $FS::UID::AutoCommit;
2762   local $FS::UID::AutoCommit = 0;
2763   my $dbh = dbh;
2764
2765   my @cust_pkgs = qsearch('cust_pkg', { 'pkgpart' => $param->{'old_pkgpart'} } );
2766
2767   my $i = 0;
2768   foreach my $old_cust_pkg ( @cust_pkgs ) {
2769     $i++;
2770     $job->update_statustext(int(100*$i/(scalar @cust_pkgs)));
2771     if ( $old_cust_pkg->getfield('cancel') ) {
2772       warn '[process_bulk_cust_pkg ] skipping canceled pkgnum '.
2773         $old_cust_pkg->pkgnum."\n"
2774         if $DEBUG;
2775       next;
2776     }
2777     warn '[process_bulk_cust_pkg] changing pkgnum '.$old_cust_pkg->pkgnum."\n"
2778       if $DEBUG;
2779     my $error = $old_cust_pkg->change(
2780       'pkgpart'     => $param->{'new_pkgpart'},
2781       'keep_dates'  => $keep_dates
2782     );
2783     if ( !ref($error) ) { # change returns the cust_pkg on success
2784       $dbh->rollback;
2785       die "Error changing pkgnum ".$old_cust_pkg->pkgnum.": '$error'\n";
2786     }
2787   }
2788   $dbh->commit if $oldAutoCommit;
2789   return;
2790 }
2791
2792 =item last_bill
2793
2794 Returns the last bill date, or if there is no last bill date, the setup date.
2795 Useful for billing metered services.
2796
2797 =cut
2798
2799 sub last_bill {
2800   my $self = shift;
2801   return $self->setfield('last_bill', $_[0]) if @_;
2802   return $self->getfield('last_bill') if $self->getfield('last_bill');
2803   my $cust_bill_pkg = qsearchs('cust_bill_pkg', { 'pkgnum' => $self->pkgnum,
2804                                                   'edate'  => $self->bill,  } );
2805   $cust_bill_pkg ? $cust_bill_pkg->sdate : $self->setup || 0;
2806 }
2807
2808 =item last_cust_pkg_reason ACTION
2809
2810 Returns the most recent ACTION FS::cust_pkg_reason associated with the package.
2811 Returns false if there is no reason or the package is not currenly ACTION'd
2812 ACTION is one of adjourn, susp, cancel, or expire.
2813
2814 =cut
2815
2816 sub last_cust_pkg_reason {
2817   my ( $self, $action ) = ( shift, shift );
2818   my $date = $self->get($action);
2819   qsearchs( {
2820               'table' => 'cust_pkg_reason',
2821               'hashref' => { 'pkgnum' => $self->pkgnum,
2822                              'action' => substr(uc($action), 0, 1),
2823                              'date'   => $date,
2824                            },
2825               'order_by' => 'ORDER BY num DESC LIMIT 1',
2826            } );
2827 }
2828
2829 =item last_reason ACTION
2830
2831 Returns the most recent ACTION FS::reason associated with the package.
2832 Returns false if there is no reason or the package is not currenly ACTION'd
2833 ACTION is one of adjourn, susp, cancel, or expire.
2834
2835 =cut
2836
2837 sub last_reason {
2838   my $cust_pkg_reason = shift->last_cust_pkg_reason(@_);
2839   $cust_pkg_reason->reason
2840     if $cust_pkg_reason;
2841 }
2842
2843 =item part_pkg
2844
2845 Returns the definition for this billing item, as an FS::part_pkg object (see
2846 L<FS::part_pkg>).
2847
2848 =cut
2849
2850 sub part_pkg {
2851   my $self = shift;
2852   return $self->{'_pkgpart'} if $self->{'_pkgpart'};
2853   cluck "cust_pkg->part_pkg called" if $DEBUG > 1;
2854   qsearchs( 'part_pkg', { 'pkgpart' => $self->pkgpart } );
2855 }
2856
2857 =item old_cust_pkg
2858
2859 Returns the cancelled package this package was changed from, if any.
2860
2861 =cut
2862
2863 sub old_cust_pkg {
2864   my $self = shift;
2865   return '' unless $self->change_pkgnum;
2866   qsearchs('cust_pkg', { 'pkgnum' => $self->change_pkgnum } );
2867 }
2868
2869 =item change_cust_main
2870
2871 Returns the customter this package was detached to, if any.
2872
2873 =cut
2874
2875 sub change_cust_main {
2876   my $self = shift;
2877   return '' unless $self->change_custnum;
2878   qsearchs('cust_main', { 'custnum' => $self->change_custnum } );
2879 }
2880
2881 =item calc_setup
2882
2883 Calls the I<calc_setup> of the FS::part_pkg object associated with this billing
2884 item.
2885
2886 =cut
2887
2888 sub calc_setup {
2889   my $self = shift;
2890   $self->part_pkg->calc_setup($self, @_);
2891 }
2892
2893 =item calc_recur
2894
2895 Calls the I<calc_recur> of the FS::part_pkg object associated with this billing
2896 item.
2897
2898 =cut
2899
2900 sub calc_recur {
2901   my $self = shift;
2902   $self->part_pkg->calc_recur($self, @_);
2903 }
2904
2905 =item base_recur
2906
2907 Calls the I<base_recur> of the FS::part_pkg object associated with this billing
2908 item.
2909
2910 =cut
2911
2912 sub base_recur {
2913   my $self = shift;
2914   $self->part_pkg->base_recur($self, @_);
2915 }
2916
2917 =item calc_remain
2918
2919 Calls the I<calc_remain> of the FS::part_pkg object associated with this
2920 billing item.
2921
2922 =cut
2923
2924 sub calc_remain {
2925   my $self = shift;
2926   $self->part_pkg->calc_remain($self, @_);
2927 }
2928
2929 =item calc_cancel
2930
2931 Calls the I<calc_cancel> of the FS::part_pkg object associated with this
2932 billing item.
2933
2934 =cut
2935
2936 sub calc_cancel {
2937   my $self = shift;
2938   $self->part_pkg->calc_cancel($self, @_);
2939 }
2940
2941 =item cust_bill_pkg
2942
2943 Returns any invoice line items for this package (see L<FS::cust_bill_pkg>).
2944
2945 =cut
2946
2947 sub cust_bill_pkg {
2948   my $self = shift;
2949   qsearch( 'cust_bill_pkg', { 'pkgnum' => $self->pkgnum } );
2950 }
2951
2952 =item cust_pkg_detail [ DETAILTYPE ]
2953
2954 Returns any customer package details for this package (see
2955 L<FS::cust_pkg_detail>).
2956
2957 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2958
2959 =cut
2960
2961 sub cust_pkg_detail {
2962   my $self = shift;
2963   my %hash = ( 'pkgnum' => $self->pkgnum );
2964   $hash{detailtype} = shift if @_;
2965   qsearch({
2966     'table'    => 'cust_pkg_detail',
2967     'hashref'  => \%hash,
2968     'order_by' => 'ORDER BY weight, pkgdetailnum',
2969   });
2970 }
2971
2972 =item set_cust_pkg_detail DETAILTYPE [ DETAIL, DETAIL, ... ]
2973
2974 Sets customer package details for this package (see L<FS::cust_pkg_detail>).
2975
2976 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2977
2978 If there is an error, returns the error, otherwise returns false.
2979
2980 =cut
2981
2982 sub set_cust_pkg_detail {
2983   my( $self, $detailtype, @details ) = @_;
2984
2985   local $SIG{HUP} = 'IGNORE';
2986   local $SIG{INT} = 'IGNORE';
2987   local $SIG{QUIT} = 'IGNORE';
2988   local $SIG{TERM} = 'IGNORE';
2989   local $SIG{TSTP} = 'IGNORE';
2990   local $SIG{PIPE} = 'IGNORE';
2991
2992   my $oldAutoCommit = $FS::UID::AutoCommit;
2993   local $FS::UID::AutoCommit = 0;
2994   my $dbh = dbh;
2995
2996   foreach my $current ( $self->cust_pkg_detail($detailtype) ) {
2997     my $error = $current->delete;
2998     if ( $error ) {
2999       $dbh->rollback if $oldAutoCommit;
3000       return "error removing old detail: $error";
3001     }
3002   }
3003
3004   foreach my $detail ( @details ) {
3005     my $cust_pkg_detail = new FS::cust_pkg_detail {
3006       'pkgnum'     => $self->pkgnum,
3007       'detailtype' => $detailtype,
3008       'detail'     => $detail,
3009     };
3010     my $error = $cust_pkg_detail->insert;
3011     if ( $error ) {
3012       $dbh->rollback if $oldAutoCommit;
3013       return "error adding new detail: $error";
3014     }
3015
3016   }
3017
3018   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3019   '';
3020
3021 }
3022
3023 =item cust_event
3024
3025 Returns the customer billing events (see L<FS::cust_event>) for this invoice.
3026
3027 =cut
3028
3029 #false laziness w/cust_bill.pm
3030 sub cust_event {
3031   my $self = shift;
3032   qsearch({
3033     'table'     => 'cust_event',
3034     'addl_from' => 'JOIN part_event USING ( eventpart )',
3035     'hashref'   => { 'tablenum' => $self->pkgnum },
3036     'extra_sql' => " AND eventtable = 'cust_pkg' ",
3037   });
3038 }
3039
3040 =item num_cust_event
3041
3042 Returns the number of customer billing events (see L<FS::cust_event>) for this package.
3043
3044 =cut
3045
3046 #false laziness w/cust_bill.pm
3047 sub num_cust_event {
3048   my $self = shift;
3049   my $sql = "SELECT COUNT(*) ". $self->_from_cust_event_where;
3050   $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref->[0];
3051 }
3052
3053 =item exists_cust_event
3054
3055 Returns true if there are customer billing events (see L<FS::cust_event>) for this package.  More efficient than using num_cust_event.
3056
3057 =cut
3058
3059 sub exists_cust_event {
3060   my $self = shift;
3061   my $sql = "SELECT 1 ". $self->_from_cust_event_where. " LIMIT 1";
3062   my $row = $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref;
3063   $row ? $row->[0] : '';
3064 }
3065
3066 sub _from_cust_event_where {
3067   #my $self = shift;
3068   " FROM cust_event JOIN part_event USING ( eventpart ) ".
3069   "  WHERE tablenum = ? AND eventtable = 'cust_pkg' ";
3070 }
3071
3072 sub _prep_ex {
3073   my( $self, $sql, @args ) = @_;
3074   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
3075   $sth->execute(@args)         or die $sth->errstr. " executing $sql";
3076   $sth;
3077 }
3078
3079 =item cust_svc [ SVCPART ] (old, deprecated usage)
3080
3081 =item cust_svc [ OPTION => VALUE ... ] (current usage)
3082
3083 =item cust_svc_unsorted [ OPTION => VALUE ... ]
3084
3085 Returns the services for this package, as FS::cust_svc objects (see
3086 L<FS::cust_svc>).  Available options are svcpart and svcdb.  If either is
3087 spcififed, returns only the matching services.
3088
3089 As an optimization, use the cust_svc_unsorted version if you are not displaying
3090 the results.
3091
3092 =cut
3093
3094 sub cust_svc {
3095   my $self = shift;
3096   cluck "cust_pkg->cust_svc called" if $DEBUG > 2;
3097   $self->_sort_cust_svc( $self->cust_svc_unsorted_arrayref(@_) );
3098 }
3099
3100 sub cust_svc_unsorted {
3101   my $self = shift;
3102   @{ $self->cust_svc_unsorted_arrayref(@_) };
3103 }
3104
3105 sub cust_svc_unsorted_arrayref {
3106   my $self = shift;
3107
3108   return [] unless $self->num_cust_svc(@_);
3109
3110   my %opt = ();
3111   if ( @_ && $_[0] =~ /^\d+/ ) {
3112     $opt{svcpart} = shift;
3113   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3114     %opt = %{ $_[0] };
3115   } elsif ( @_ ) {
3116     %opt = @_;
3117   }
3118
3119   my %search = (
3120     'table'   => 'cust_svc',
3121     'hashref' => { 'pkgnum' => $self->pkgnum },
3122   );
3123   if ( $opt{svcpart} ) {
3124     $search{hashref}->{svcpart} = $opt{'svcpart'};
3125   }
3126   if ( $opt{'svcdb'} ) {
3127     $search{addl_from} = ' LEFT JOIN part_svc USING ( svcpart ) ';
3128     $search{extra_sql} = ' AND svcdb = '. dbh->quote( $opt{'svcdb'} );
3129   }
3130
3131   [ qsearch(\%search) ];
3132
3133 }
3134
3135 =item overlimit [ SVCPART ]
3136
3137 Returns the services for this package which have exceeded their
3138 usage limit as FS::cust_svc objects (see L<FS::cust_svc>).  If a svcpart
3139 is specified, return only the matching services.
3140
3141 =cut
3142
3143 sub overlimit {
3144   my $self = shift;
3145   return () unless $self->num_cust_svc(@_);
3146   grep { $_->overlimit } $self->cust_svc(@_);
3147 }
3148
3149 =item h_cust_svc END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3150
3151 Returns historical services for this package created before END TIMESTAMP and
3152 (optionally) not cancelled before START_TIMESTAMP, as FS::h_cust_svc objects
3153 (see L<FS::h_cust_svc>).  If MODE is 'I' (for 'invoice'), services with the
3154 I<pkg_svc.hidden> flag will be omitted.
3155
3156 =cut
3157
3158 sub h_cust_svc {
3159   my $self = shift;
3160   warn "$me _h_cust_svc called on $self\n"
3161     if $DEBUG;
3162
3163   my ($end, $start, $mode) = @_;
3164   my @cust_svc = $self->_sort_cust_svc(
3165     [ qsearch( 'h_cust_svc',
3166       { 'pkgnum' => $self->pkgnum, },
3167       FS::h_cust_svc->sql_h_search(@_),
3168     ) ]
3169   );
3170   if ( defined($mode) && $mode eq 'I' ) {
3171     my %hidden_svcpart = map { $_->svcpart => $_->hidden } $self->part_svc;
3172     return grep { !$hidden_svcpart{$_->svcpart} } @cust_svc;
3173   } else {
3174     return @cust_svc;
3175   }
3176 }
3177
3178 sub _sort_cust_svc {
3179   my( $self, $arrayref ) = @_;
3180
3181   my $sort =
3182     sub ($$) { my ($a, $b) = @_; $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] };
3183
3184   my %pkg_svc = map { $_->svcpart => $_ }
3185                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
3186
3187   map  { $_->[0] }
3188   sort $sort
3189   map {
3190         my $pkg_svc = $pkg_svc{ $_->svcpart } || '';
3191         [ $_,
3192           $pkg_svc ? $pkg_svc->primary_svc : '',
3193           $pkg_svc ? $pkg_svc->quantity : 0,
3194         ];
3195       }
3196   @$arrayref;
3197
3198 }
3199
3200 =item num_cust_svc [ SVCPART ] (old, deprecated usage)
3201
3202 =item num_cust_svc [ OPTION => VALUE ... ] (current usage)
3203
3204 Returns the number of services for this package.  Available options are svcpart
3205 and svcdb.  If either is spcififed, returns only the matching services.
3206
3207 =cut
3208
3209 sub num_cust_svc {
3210   my $self = shift;
3211
3212   return $self->{'_num_cust_svc'}
3213     if !scalar(@_)
3214        && exists($self->{'_num_cust_svc'})
3215        && $self->{'_num_cust_svc'} =~ /\d/;
3216
3217   cluck "cust_pkg->num_cust_svc called, _num_cust_svc:".$self->{'_num_cust_svc'}
3218     if $DEBUG > 2;
3219
3220   my %opt = ();
3221   if ( @_ && $_[0] =~ /^\d+/ ) {
3222     $opt{svcpart} = shift;
3223   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3224     %opt = %{ $_[0] };
3225   } elsif ( @_ ) {
3226     %opt = @_;
3227   }
3228
3229   my $select = 'SELECT COUNT(*) FROM cust_svc ';
3230   my $where = ' WHERE pkgnum = ? ';
3231   my @param = ($self->pkgnum);
3232
3233   if ( $opt{'svcpart'} ) {
3234     $where .= ' AND svcpart = ? ';
3235     push @param, $opt{'svcpart'};
3236   }
3237   if ( $opt{'svcdb'} ) {
3238     $select .= ' LEFT JOIN part_svc USING ( svcpart ) ';
3239     $where .= ' AND svcdb = ? ';
3240     push @param, $opt{'svcdb'};
3241   }
3242
3243   my $sth = dbh->prepare("$select $where") or die  dbh->errstr;
3244   $sth->execute(@param) or die $sth->errstr;
3245   $sth->fetchrow_arrayref->[0];
3246 }
3247
3248 =item available_part_svc
3249
3250 Returns a list of FS::part_svc objects representing services included in this
3251 package but not yet provisioned.  Each FS::part_svc object also has an extra
3252 field, I<num_avail>, which specifies the number of available services.
3253
3254 =cut
3255
3256 sub available_part_svc {
3257   my $self = shift;
3258
3259   my $pkg_quantity = $self->quantity || 1;
3260
3261   grep { $_->num_avail > 0 }
3262     map {
3263           my $part_svc = $_->part_svc;
3264           $part_svc->{'Hash'}{'num_avail'} = #evil encapsulation-breaking
3265             $pkg_quantity * $_->quantity - $self->num_cust_svc($_->svcpart);
3266
3267           # more evil encapsulation breakage
3268           if($part_svc->{'Hash'}{'num_avail'} > 0) {
3269             my @exports = $part_svc->part_export_did;
3270             $part_svc->{'Hash'}{'can_get_dids'} = scalar(@exports);
3271           }
3272
3273           $part_svc;
3274         }
3275       $self->part_pkg->pkg_svc;
3276 }
3277
3278 =item part_svc [ OPTION => VALUE ... ]
3279
3280 Returns a list of FS::part_svc objects representing provisioned and available
3281 services included in this package.  Each FS::part_svc object also has the
3282 following extra fields:
3283
3284 =over 4
3285
3286 =item num_cust_svc
3287
3288 (count)
3289
3290 =item num_avail
3291
3292 (quantity - count)
3293
3294 =item cust_pkg_svc
3295
3296 (services) - array reference containing the provisioned services, as cust_svc objects
3297
3298 =back
3299
3300 Accepts two options:
3301
3302 =over 4
3303
3304 =item summarize_size
3305
3306 If true, will omit the extra cust_pkg_svc option for objects where num_cust_svc
3307 is this size or greater.
3308
3309 =item hide_discontinued
3310
3311 If true, will omit looking for services that are no longer avaialble in the
3312 package definition.
3313
3314 =back
3315
3316 =cut
3317
3318 #svcnum
3319 #label -> ($cust_svc->label)[1]
3320
3321 sub part_svc {
3322   my $self = shift;
3323   my %opt = @_;
3324
3325   my $pkg_quantity = $self->quantity || 1;
3326
3327   #XXX some sort of sort order besides numeric by svcpart...
3328   my @part_svc = sort { $a->svcpart <=> $b->svcpart } map {
3329     my $pkg_svc = $_;
3330     my $part_svc = $pkg_svc->part_svc;
3331     my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3332     $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #more evil
3333     $part_svc->{'Hash'}{'num_avail'}    =
3334       max( 0, $pkg_quantity * $pkg_svc->quantity - $num_cust_svc );
3335     $part_svc->{'Hash'}{'cust_pkg_svc'} =
3336         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : []
3337       unless exists($opt{summarize_size}) && $opt{summarize_size} > 0
3338           && $num_cust_svc >= $opt{summarize_size};
3339     $part_svc->{'Hash'}{'hidden'} = $pkg_svc->hidden;
3340     $part_svc;
3341   } $self->part_pkg->pkg_svc;
3342
3343   unless ( $opt{hide_discontinued} ) {
3344     #extras
3345     push @part_svc, map {
3346       my $part_svc = $_;
3347       my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3348       $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #speak no evail
3349       $part_svc->{'Hash'}{'num_avail'}    = 0; #0-$num_cust_svc ?
3350       $part_svc->{'Hash'}{'cust_pkg_svc'} =
3351         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : [];
3352       $part_svc;
3353     } $self->extra_part_svc;
3354   }
3355
3356   @part_svc;
3357
3358 }
3359
3360 =item extra_part_svc
3361
3362 Returns a list of FS::part_svc objects corresponding to services in this
3363 package which are still provisioned but not (any longer) available in the
3364 package definition.
3365
3366 =cut
3367
3368 sub extra_part_svc {
3369   my $self = shift;
3370
3371   my $pkgnum  = $self->pkgnum;
3372   #my $pkgpart = $self->pkgpart;
3373
3374 #  qsearch( {
3375 #    'table'     => 'part_svc',
3376 #    'hashref'   => {},
3377 #    'extra_sql' =>
3378 #      "WHERE 0 = ( SELECT COUNT(*) FROM pkg_svc
3379 #                     WHERE pkg_svc.svcpart = part_svc.svcpart
3380 #                       AND pkg_svc.pkgpart = ?
3381 #                       AND quantity > 0
3382 #                 )
3383 #        AND 0 < ( SELECT COUNT(*) FROM cust_svc
3384 #                       LEFT JOIN cust_pkg USING ( pkgnum )
3385 #                     WHERE cust_svc.svcpart = part_svc.svcpart
3386 #                       AND pkgnum = ?
3387 #                 )",
3388 #    'extra_param' => [ [$self->pkgpart=>'int'], [$self->pkgnum=>'int'] ],
3389 #  } );
3390
3391 #seems to benchmark slightly faster... (or did?)
3392
3393   my @pkgparts = map $_->pkgpart, $self->part_pkg->self_and_svc_linked;
3394   my $pkgparts = join(',', @pkgparts);
3395
3396   qsearch( {
3397     #'select'      => 'DISTINCT ON (svcpart) part_svc.*',
3398     #MySQL doesn't grok DISINCT ON
3399     'select'      => 'DISTINCT part_svc.*',
3400     'table'       => 'part_svc',
3401     'addl_from'   =>
3402       "LEFT JOIN pkg_svc  ON (     pkg_svc.svcpart   = part_svc.svcpart
3403                                AND pkg_svc.pkgpart IN ($pkgparts)
3404                                AND quantity > 0
3405                              )
3406        LEFT JOIN cust_svc ON (     cust_svc.svcpart = part_svc.svcpart )
3407        LEFT JOIN cust_pkg USING ( pkgnum )
3408       ",
3409     'hashref'     => {},
3410     'extra_sql'   => "WHERE pkgsvcnum IS NULL AND cust_pkg.pkgnum = ? ",
3411     'extra_param' => [ [$self->pkgnum=>'int'] ],
3412   } );
3413 }
3414
3415 =item status
3416
3417 Returns a short status string for this package, currently:
3418
3419 =over 4
3420
3421 =item on hold
3422
3423 =item not yet billed
3424
3425 =item one-time charge
3426
3427 =item active
3428
3429 =item suspended
3430
3431 =item cancelled
3432
3433 =back
3434
3435 =cut
3436
3437 sub status {
3438   my $self = shift;
3439
3440   my $freq = length($self->freq) ? $self->freq : $self->part_pkg->freq;
3441
3442   return 'cancelled' if $self->get('cancel');
3443   return 'on hold' if $self->susp && ! $self->setup;
3444   return 'suspended' if $self->susp;
3445   return 'not yet billed' unless $self->setup;
3446   return 'one-time charge' if $freq =~ /^(0|$)/;
3447   return 'active';
3448 }
3449
3450 =item ucfirst_status
3451
3452 Returns the status with the first character capitalized.
3453
3454 =cut
3455
3456 sub ucfirst_status {
3457   ucfirst(shift->status);
3458 }
3459
3460 =item statuses
3461
3462 Class method that returns the list of possible status strings for packages
3463 (see L<the status method|/status>).  For example:
3464
3465   @statuses = FS::cust_pkg->statuses();
3466
3467 =cut
3468
3469 tie my %statuscolor, 'Tie::IxHash',
3470   'on hold'         => 'FF00F5', #brighter purple!
3471   'not yet billed'  => '009999', #teal? cyan?
3472   'one-time charge' => '0000CC', #blue  #'000000',
3473   'active'          => '00CC00',
3474   'suspended'       => 'FF9900',
3475   'cancelled'       => 'FF0000',
3476 ;
3477
3478 sub statuses {
3479   my $self = shift; #could be class...
3480   #grep { $_ !~ /^(not yet billed)$/ } #this is a dumb status anyway
3481   #                                    # mayble split btw one-time vs. recur
3482     keys %statuscolor;
3483 }
3484
3485 sub statuscolors {
3486   #my $self = shift;
3487   \%statuscolor;
3488 }
3489
3490 =item statuscolor
3491
3492 Returns a hex triplet color string for this package's status.
3493
3494 =cut
3495
3496 sub statuscolor {
3497   my $self = shift;
3498   $statuscolor{$self->status};
3499 }
3500
3501 =item is_status_delay_cancel
3502
3503 Returns true if part_pkg has option delay_cancel,
3504 cust_pkg status is 'suspended' and expire is set
3505 to cancel package within the next day (or however
3506 many days are set in global config part_pkg-delay_cancel-days.
3507
3508 Accepts option I<part_pkg-delay_cancel-days> which should be
3509 the value of the config setting, to avoid looking it up again.
3510
3511 This is not a real status, this only meant for hacking display
3512 values, because otherwise treating the package as suspended is
3513 really the whole point of the delay_cancel option.
3514
3515 =cut
3516
3517 sub is_status_delay_cancel {
3518   my ($self,%opt) = @_;
3519   if ( $self->main_pkgnum and $self->pkglinknum ) {
3520     return $self->main_pkg->is_status_delay_cancel;
3521   }
3522   return 0 unless $self->part_pkg->option('delay_cancel',1);
3523   return 0 unless $self->status eq 'suspended';
3524   return 0 unless $self->expire;
3525   my $expdays = $opt{'part_pkg-delay_cancel-days'};
3526   unless ($expdays) {
3527     my $conf = new FS::Conf;
3528     $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
3529   }
3530   my $expsecs = 60*60*24*$expdays;
3531   return 0 unless $self->expire < time + $expsecs;
3532   return 1;
3533 }
3534
3535 =item pkg_label
3536
3537 Returns a label for this package.  (Currently "pkgnum: pkg - comment" or
3538 "pkg - comment" depending on user preference).
3539
3540 =cut
3541
3542 sub pkg_label {
3543   my $self = shift;
3544   my $label = $self->part_pkg->pkg_comment( 'nopkgpart' => 1 );
3545   $label = $self->pkgnum. ": $label"
3546     if $FS::CurrentUser::CurrentUser->option('show_pkgnum');
3547   $label;
3548 }
3549
3550 =item pkg_label_long
3551
3552 Returns a long label for this package, adding the primary service's label to
3553 pkg_label.
3554
3555 =cut
3556
3557 sub pkg_label_long {
3558   my $self = shift;
3559   my $label = $self->pkg_label;
3560   my $cust_svc = $self->primary_cust_svc;
3561   $label .= ' ('. ($cust_svc->label)[1]. ')' if $cust_svc;
3562   $label;
3563 }
3564
3565 =item pkg_locale
3566
3567 Returns a customer-localized label for this package.
3568
3569 =cut
3570
3571 sub pkg_locale {
3572   my $self = shift;
3573   $self->part_pkg->pkg_locale( $self->cust_main->locale );
3574 }
3575
3576 =item primary_cust_svc
3577
3578 Returns a primary service (as FS::cust_svc object) if one can be identified.
3579
3580 =cut
3581
3582 #for labeling purposes - might not 100% match up with part_pkg->svcpart's idea
3583
3584 sub primary_cust_svc {
3585   my $self = shift;
3586
3587   my @cust_svc = $self->cust_svc;
3588
3589   return '' unless @cust_svc; #no serivces - irrelevant then
3590
3591   return $cust_svc[0] if scalar(@cust_svc) == 1; #always return a single service
3592
3593   # primary service as specified in the package definition
3594   # or exactly one service definition with quantity one
3595   my $svcpart = $self->part_pkg->svcpart;
3596   @cust_svc = grep { $_->svcpart == $svcpart } @cust_svc;
3597   return $cust_svc[0] if scalar(@cust_svc) == 1;
3598
3599   #couldn't identify one thing..
3600   return '';
3601 }
3602
3603 =item labels
3604
3605 Returns a list of lists, calling the label method for all services
3606 (see L<FS::cust_svc>) of this billing item.
3607
3608 =cut
3609
3610 sub labels {
3611   my $self = shift;
3612   map { [ $_->label ] } $self->cust_svc;
3613 }
3614
3615 =item h_labels END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3616
3617 Like the labels method, but returns historical information on services that
3618 were active as of END_TIMESTAMP and (optionally) not cancelled before
3619 START_TIMESTAMP.  If MODE is 'I' (for 'invoice'), services with the
3620 I<pkg_svc.hidden> flag will be omitted.
3621
3622 Returns a list of lists, calling the label method for all (historical) services
3623 (see L<FS::h_cust_svc>) of this billing item.
3624
3625 =cut
3626
3627 sub h_labels {
3628   my $self = shift;
3629   warn "$me _h_labels called on $self\n"
3630     if $DEBUG;
3631   map { [ $_->label(@_) ] } $self->h_cust_svc(@_);
3632 }
3633
3634 =item labels_short
3635
3636 Like labels, except returns a simple flat list, and shortens long
3637 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3638 identical services to one line that lists the service label and the number of
3639 individual services rather than individual items.
3640
3641 =cut
3642
3643 sub labels_short {
3644   shift->_labels_short( 'labels', @_ );
3645 }
3646
3647 =item h_labels_short END_TIMESTAMP [ START_TIMESTAMP ]
3648
3649 Like h_labels, except returns a simple flat list, and shortens long
3650 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3651 identical services to one line that lists the service label and the number of
3652 individual services rather than individual items.
3653
3654 =cut
3655
3656 sub h_labels_short {
3657   shift->_labels_short( 'h_labels', @_ );
3658 }
3659
3660 sub _labels_short {
3661   my( $self, $method ) = ( shift, shift );
3662
3663   warn "$me _labels_short called on $self with $method method\n"
3664     if $DEBUG;
3665
3666   my $conf = new FS::Conf;
3667   my $max_same_services = $conf->config('cust_bill-max_same_services') || 5;
3668
3669   warn "$me _labels_short populating \%labels\n"
3670     if $DEBUG;
3671
3672   my %labels;
3673   #tie %labels, 'Tie::IxHash';
3674   push @{ $labels{$_->[0]} }, $_->[1]
3675     foreach $self->$method(@_);
3676
3677   warn "$me _labels_short populating \@labels\n"
3678     if $DEBUG;
3679
3680   my @labels;
3681   foreach my $label ( keys %labels ) {
3682     my %seen = ();
3683     my @values = grep { ! $seen{$_}++ } @{ $labels{$label} };
3684     my $num = scalar(@values);
3685     warn "$me _labels_short $num items for $label\n"
3686       if $DEBUG;
3687
3688     if ( $num > $max_same_services ) {
3689       warn "$me _labels_short   more than $max_same_services, so summarizing\n"
3690         if $DEBUG;
3691       push @labels, "$label ($num)";
3692     } else {
3693       if ( $conf->exists('cust_bill-consolidate_services') ) {
3694         warn "$me _labels_short   consolidating services\n"
3695           if $DEBUG;
3696         # push @labels, "$label: ". join(', ', @values);
3697         while ( @values ) {
3698           my $detail = "$label: ";
3699           $detail .= shift(@values). ', '
3700             while @values
3701                && ( length($detail.$values[0]) < 78 || $detail eq "$label: " );
3702           $detail =~ s/, $//;
3703           push @labels, $detail;
3704         }
3705         warn "$me _labels_short   done consolidating services\n"
3706           if $DEBUG;
3707       } else {
3708         warn "$me _labels_short   adding service data\n"
3709           if $DEBUG;
3710         push @labels, map { "$label: $_" } @values;
3711       }
3712     }
3713   }
3714
3715  @labels;
3716
3717 }
3718
3719 =item cust_main
3720
3721 Returns the parent customer object (see L<FS::cust_main>).
3722
3723 =cut
3724
3725 sub cust_main {
3726   my $self = shift;
3727   cluck 'cust_pkg->cust_main called' if $DEBUG;
3728   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
3729 }
3730
3731 =item balance
3732
3733 Returns the balance for this specific package, when using
3734 experimental package balance.
3735
3736 =cut
3737
3738 sub balance {
3739   my $self = shift;
3740   $self->cust_main->balance_pkgnum( $self->pkgnum );
3741 }
3742
3743 #these subs are in location_Mixin.pm now... unfortunately the POD doesn't mixin
3744
3745 =item cust_location
3746
3747 Returns the location object, if any (see L<FS::cust_location>).
3748
3749 =item cust_location_or_main
3750
3751 If this package is associated with a location, returns the locaiton (see
3752 L<FS::cust_location>), otherwise returns the customer (see L<FS::cust_main>).
3753
3754 =item location_label [ OPTION => VALUE ... ]
3755
3756 Returns the label of the location object (see L<FS::cust_location>).
3757
3758 =cut
3759
3760 #end of subs in location_Mixin.pm now... unfortunately the POD doesn't mixin
3761
3762 =item tax_locationnum
3763
3764 Returns the foreign key to a L<FS::cust_location> object for calculating
3765 tax on this package, as determined by the C<tax-pkg_address> and
3766 C<tax-ship_address> configuration flags.
3767
3768 =cut
3769
3770 sub tax_locationnum {
3771   my $self = shift;
3772   my $conf = FS::Conf->new;
3773   if ( $conf->exists('tax-pkg_address') ) {
3774     return $self->locationnum;
3775   }
3776   elsif ( $conf->exists('tax-ship_address') ) {
3777     return $self->cust_main->ship_locationnum;
3778   }
3779   else {
3780     return $self->cust_main->bill_locationnum;
3781   }
3782 }
3783
3784 =item tax_location
3785
3786 Returns the L<FS::cust_location> object for tax_locationnum.
3787
3788 =cut
3789
3790 sub tax_location {
3791   my $self = shift;
3792   my $conf = FS::Conf->new;
3793   if ( $conf->exists('tax-pkg_address') and $self->locationnum ) {
3794     return FS::cust_location->by_key($self->locationnum);
3795   }
3796   elsif ( $conf->exists('tax-ship_address') ) {
3797     return $self->cust_main->ship_location;
3798   }
3799   else {
3800     return $self->cust_main->bill_location;
3801   }
3802 }
3803
3804 =item seconds_since TIMESTAMP
3805
3806 Returns the number of seconds all accounts (see L<FS::svc_acct>) in this
3807 package have been online since TIMESTAMP, according to the session monitor.
3808
3809 TIMESTAMP is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
3810 L<Time::Local> and L<Date::Parse> for conversion functions.
3811
3812 =cut
3813
3814 sub seconds_since {
3815   my($self, $since) = @_;
3816   my $seconds = 0;
3817
3818   foreach my $cust_svc (
3819     grep { $_->part_svc->svcdb eq 'svc_acct' } $self->cust_svc
3820   ) {
3821     $seconds += $cust_svc->seconds_since($since);
3822   }
3823
3824   $seconds;
3825
3826 }
3827
3828 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
3829
3830 Returns the numbers of seconds all accounts (see L<FS::svc_acct>) in this
3831 package have been online between TIMESTAMP_START (inclusive) and TIMESTAMP_END
3832 (exclusive).
3833
3834 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3835 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3836 functions.
3837
3838
3839 =cut
3840
3841 sub seconds_since_sqlradacct {
3842   my($self, $start, $end) = @_;
3843
3844   my $seconds = 0;
3845
3846   foreach my $cust_svc (
3847     grep {
3848       my $part_svc = $_->part_svc;
3849       $part_svc->svcdb eq 'svc_acct'
3850         && scalar($part_svc->part_export_usage);
3851     } $self->cust_svc
3852   ) {
3853     $seconds += $cust_svc->seconds_since_sqlradacct($start, $end);
3854   }
3855
3856   $seconds;
3857
3858 }
3859
3860 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
3861
3862 Returns the sum of the given attribute for all accounts (see L<FS::svc_acct>)
3863 in this package for sessions ending between TIMESTAMP_START (inclusive) and
3864 TIMESTAMP_END
3865 (exclusive).
3866
3867 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3868 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3869 functions.
3870
3871 =cut
3872
3873 sub attribute_since_sqlradacct {
3874   my($self, $start, $end, $attrib) = @_;
3875
3876   my $sum = 0;
3877
3878   foreach my $cust_svc (
3879     grep {
3880       my $part_svc = $_->part_svc;
3881       scalar($part_svc->part_export_usage);
3882     } $self->cust_svc
3883   ) {
3884     $sum += $cust_svc->attribute_since_sqlradacct($start, $end, $attrib);
3885   }
3886
3887   $sum;
3888
3889 }
3890
3891 =item quantity
3892
3893 =cut
3894
3895 sub quantity {
3896   my( $self, $value ) = @_;
3897   if ( defined($value) ) {
3898     $self->setfield('quantity', $value);
3899   }
3900   $self->getfield('quantity') || 1;
3901 }
3902
3903 =item transfer DEST_PKGNUM | DEST_CUST_PKG, [ OPTION => VALUE ... ]
3904
3905 Transfers as many services as possible from this package to another package.
3906
3907 The destination package can be specified by pkgnum by passing an FS::cust_pkg
3908 object.  The destination package must already exist.
3909
3910 Services are moved only if the destination allows services with the correct
3911 I<svcpart> (not svcdb), unless the B<change_svcpart> option is set true.  Use
3912 this option with caution!  No provision is made for export differences
3913 between the old and new service definitions.  Probably only should be used
3914 when your exports for all service definitions of a given svcdb are identical.
3915 (attempt a transfer without it first, to move all possible svcpart-matching
3916 services)
3917
3918 Any services that can't be moved remain in the original package.
3919
3920 Returns an error, if there is one; otherwise, returns the number of services
3921 that couldn't be moved.
3922
3923 =cut
3924
3925 sub transfer {
3926   my ($self, $dest_pkgnum, %opt) = @_;
3927
3928   my $remaining = 0;
3929   my $dest;
3930   my %target;
3931
3932   if (ref ($dest_pkgnum) eq 'FS::cust_pkg') {
3933     $dest = $dest_pkgnum;
3934     $dest_pkgnum = $dest->pkgnum;
3935   } else {
3936     $dest = qsearchs('cust_pkg', { pkgnum => $dest_pkgnum });
3937   }
3938
3939   return ('Package does not exist: '.$dest_pkgnum) unless $dest;
3940
3941   foreach my $pkg_svc ( $dest->part_pkg->pkg_svc ) {
3942     $target{$pkg_svc->svcpart} = $pkg_svc->quantity * ( $dest->quantity || 1 );
3943   }
3944
3945   foreach my $cust_svc ($dest->cust_svc) {
3946     $target{$cust_svc->svcpart}--;
3947   }
3948
3949   my %svcpart2svcparts = ();
3950   if ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3951     warn "change_svcpart option received, creating alternates list\n" if $DEBUG;
3952     foreach my $svcpart ( map { $_->svcpart } $self->cust_svc ) {
3953       next if exists $svcpart2svcparts{$svcpart};
3954       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
3955       $svcpart2svcparts{$svcpart} = [
3956         map  { $_->[0] }
3957         sort { $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] }
3958         map {
3959               my $pkg_svc = qsearchs( 'pkg_svc', { 'pkgpart' => $dest->pkgpart,
3960                                                    'svcpart' => $_          } );
3961               [ $_,
3962                 $pkg_svc ? $pkg_svc->primary_svc : '',
3963                 $pkg_svc ? $pkg_svc->quantity : 0,
3964               ];
3965             }
3966
3967         grep { $_ != $svcpart }
3968         map  { $_->svcpart }
3969         qsearch('part_svc', { 'svcdb' => $part_svc->svcdb } )
3970       ];
3971       warn "alternates for svcpart $svcpart: ".
3972            join(', ', @{$svcpart2svcparts{$svcpart}}). "\n"
3973         if $DEBUG;
3974     }
3975   }
3976
3977   my $error;
3978   foreach my $cust_svc ($self->cust_svc) {
3979     my $svcnum = $cust_svc->svcnum;
3980     if($target{$cust_svc->svcpart} > 0
3981        or $FS::cust_svc::ignore_quantity) { # maybe should be a 'force' option
3982       $target{$cust_svc->svcpart}--;
3983       my $new = new FS::cust_svc { $cust_svc->hash };
3984       $new->pkgnum($dest_pkgnum);
3985       $error = $new->replace($cust_svc);
3986     } elsif ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3987       if ( $DEBUG ) {
3988         warn "looking for alternates for svcpart ". $cust_svc->svcpart. "\n";
3989         warn "alternates to consider: ".
3990              join(', ', @{$svcpart2svcparts{$cust_svc->svcpart}}). "\n";
3991       }
3992       my @alternate = grep {
3993                              warn "considering alternate svcpart $_: ".
3994                                   "$target{$_} available in new package\n"
3995                                if $DEBUG;
3996                              $target{$_} > 0;
3997                            } @{$svcpart2svcparts{$cust_svc->svcpart}};
3998       if ( @alternate ) {
3999         warn "alternate(s) found\n" if $DEBUG;
4000         my $change_svcpart = $alternate[0];
4001         $target{$change_svcpart}--;
4002         my $new = new FS::cust_svc { $cust_svc->hash };
4003         $new->svcpart($change_svcpart);
4004         $new->pkgnum($dest_pkgnum);
4005         $error = $new->replace($cust_svc);
4006       } else {
4007         $remaining++;
4008       }
4009     } else {
4010       $remaining++
4011     }
4012     if ( $error ) {
4013       my @label = $cust_svc->label;
4014       return "service $label[1]: $error";
4015     }
4016   }
4017   return $remaining;
4018 }
4019
4020 =item grab_svcnums SVCNUM, SVCNUM ...
4021
4022 Change the pkgnum for the provided services to this packages.  If there is an
4023 error, returns the error, otherwise returns false.
4024
4025 =cut
4026
4027 sub grab_svcnums {
4028   my $self = shift;
4029   my @svcnum = @_;
4030
4031   local $SIG{HUP} = 'IGNORE';
4032   local $SIG{INT} = 'IGNORE';
4033   local $SIG{QUIT} = 'IGNORE';
4034   local $SIG{TERM} = 'IGNORE';
4035   local $SIG{TSTP} = 'IGNORE';
4036   local $SIG{PIPE} = 'IGNORE';
4037
4038   my $oldAutoCommit = $FS::UID::AutoCommit;
4039   local $FS::UID::AutoCommit = 0;
4040   my $dbh = dbh;
4041
4042   foreach my $svcnum (@svcnum) {
4043     my $cust_svc = qsearchs('cust_svc', { svcnum=>$svcnum } ) or do {
4044       $dbh->rollback if $oldAutoCommit;
4045       return "unknown svcnum $svcnum";
4046     };
4047     $cust_svc->pkgnum( $self->pkgnum );
4048     my $error = $cust_svc->replace;
4049     if ( $error ) {
4050       $dbh->rollback if $oldAutoCommit;
4051       return $error;
4052     }
4053   }
4054
4055   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4056   '';
4057
4058 }
4059
4060 =item reexport
4061
4062 This method is deprecated.  See the I<depend_jobnum> option to the insert and
4063 order_pkgs methods in FS::cust_main for a better way to defer provisioning.
4064
4065 =cut
4066
4067 sub reexport {
4068   my $self = shift;
4069
4070   local $SIG{HUP} = 'IGNORE';
4071   local $SIG{INT} = 'IGNORE';
4072   local $SIG{QUIT} = 'IGNORE';
4073   local $SIG{TERM} = 'IGNORE';
4074   local $SIG{TSTP} = 'IGNORE';
4075   local $SIG{PIPE} = 'IGNORE';
4076
4077   my $oldAutoCommit = $FS::UID::AutoCommit;
4078   local $FS::UID::AutoCommit = 0;
4079   my $dbh = dbh;
4080
4081   foreach my $cust_svc ( $self->cust_svc ) {
4082     #false laziness w/svc_Common::insert
4083     my $svc_x = $cust_svc->svc_x;
4084     foreach my $part_export ( $cust_svc->part_svc->part_export ) {
4085       my $error = $part_export->export_insert($svc_x);
4086       if ( $error ) {
4087         $dbh->rollback if $oldAutoCommit;
4088         return $error;
4089       }
4090     }
4091   }
4092
4093   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4094   '';
4095
4096 }
4097
4098 =item export_pkg_change OLD_CUST_PKG
4099
4100 Calls the "pkg_change" export action for all services attached to this package.
4101
4102 =cut
4103
4104 sub export_pkg_change {
4105   my( $self, $old )  = ( shift, shift );
4106
4107   local $SIG{HUP} = 'IGNORE';
4108   local $SIG{INT} = 'IGNORE';
4109   local $SIG{QUIT} = 'IGNORE';
4110   local $SIG{TERM} = 'IGNORE';
4111   local $SIG{TSTP} = 'IGNORE';
4112   local $SIG{PIPE} = 'IGNORE';
4113
4114   my $oldAutoCommit = $FS::UID::AutoCommit;
4115   local $FS::UID::AutoCommit = 0;
4116   my $dbh = dbh;
4117
4118   foreach my $svc_x ( map $_->svc_x, $self->cust_svc ) {
4119     my $error = $svc_x->export('pkg_change', $self, $old);
4120     if ( $error ) {
4121       $dbh->rollback if $oldAutoCommit;
4122       return $error;
4123     }
4124   }
4125
4126   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4127   '';
4128
4129 }
4130
4131 =item insert_reason
4132
4133 Associates this package with a (suspension or cancellation) reason (see
4134 L<FS::cust_pkg_reason>, possibly inserting a new reason on the fly (see
4135 L<FS::reason>).
4136
4137 Available options are:
4138
4139 =over 4
4140
4141 =item reason
4142
4143 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
4144
4145 =item reason_otaker
4146
4147 the access_user (see L<FS::access_user>) providing the reason
4148
4149 =item date
4150
4151 a unix timestamp
4152
4153 =item action
4154
4155 the action (cancel, susp, adjourn, expire) associated with the reason
4156
4157 =back
4158
4159 If there is an error, returns the error, otherwise returns false.
4160
4161 =cut
4162
4163 sub insert_reason {
4164   my ($self, %options) = @_;
4165
4166   my $otaker = $options{reason_otaker} ||
4167                $FS::CurrentUser::CurrentUser->username;
4168
4169   my $reasonnum;
4170   if ( $options{'reason'} =~ /^(\d+)$/ ) {
4171
4172     $reasonnum = $1;
4173
4174   } elsif ( ref($options{'reason'}) ) {
4175
4176     return 'Enter a new reason (or select an existing one)'
4177       unless $options{'reason'}->{'reason'} !~ /^\s*$/;
4178
4179     my $reason = new FS::reason({
4180       'reason_type' => $options{'reason'}->{'typenum'},
4181       'reason'      => $options{'reason'}->{'reason'},
4182     });
4183     my $error = $reason->insert;
4184     return $error if $error;
4185
4186     $reasonnum = $reason->reasonnum;
4187
4188   } else {
4189     return "Unparseable reason: ". $options{'reason'};
4190   }
4191
4192   my $cust_pkg_reason =
4193     new FS::cust_pkg_reason({ 'pkgnum'    => $self->pkgnum,
4194                               'reasonnum' => $reasonnum,
4195                               'otaker'    => $otaker,
4196                               'action'    => substr(uc($options{'action'}),0,1),
4197                               'date'      => $options{'date'}
4198                                                ? $options{'date'}
4199                                                : time,
4200                             });
4201
4202   $cust_pkg_reason->insert;
4203 }
4204
4205 =item insert_discount
4206
4207 Associates this package with a discount (see L<FS::cust_pkg_discount>, possibly
4208 inserting a new discount on the fly (see L<FS::discount>).
4209
4210 Available options are:
4211
4212 =over 4
4213
4214 =item discountnum
4215
4216 =back
4217
4218 If there is an error, returns the error, otherwise returns false.
4219
4220 =cut
4221
4222 sub insert_discount {
4223   #my ($self, %options) = @_;
4224   my $self = shift;
4225
4226   my $cust_pkg_discount = new FS::cust_pkg_discount {
4227     'pkgnum'      => $self->pkgnum,
4228     'discountnum' => $self->discountnum,
4229     'months_used' => 0,
4230     'end_date'    => '', #XXX
4231     #for the create a new discount case
4232     '_type'       => $self->discountnum__type,
4233     'amount'      => $self->discountnum_amount,
4234     'percent'     => $self->discountnum_percent,
4235     'months'      => $self->discountnum_months,
4236     'setup'      => $self->discountnum_setup,
4237     #'disabled'    => $self->discountnum_disabled,
4238   };
4239
4240   $cust_pkg_discount->insert;
4241 }
4242
4243 =item set_usage USAGE_VALUE_HASHREF
4244
4245 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4246 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4247 upbytes, downbytes, and totalbytes are appropriate keys.
4248
4249 All svc_accts which are part of this package have their values reset.
4250
4251 =cut
4252
4253 sub set_usage {
4254   my ($self, $valueref, %opt) = @_;
4255
4256   #only svc_acct can set_usage for now
4257   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4258     my $svc_x = $cust_svc->svc_x;
4259     $svc_x->set_usage($valueref, %opt)
4260       if $svc_x->can("set_usage");
4261   }
4262 }
4263
4264 =item recharge USAGE_VALUE_HASHREF
4265
4266 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4267 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4268 upbytes, downbytes, and totalbytes are appropriate keys.
4269
4270 All svc_accts which are part of this package have their values incremented.
4271
4272 =cut
4273
4274 sub recharge {
4275   my ($self, $valueref) = @_;
4276
4277   #only svc_acct can set_usage for now
4278   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4279     my $svc_x = $cust_svc->svc_x;
4280     $svc_x->recharge($valueref)
4281       if $svc_x->can("recharge");
4282   }
4283 }
4284
4285 =item cust_pkg_discount
4286
4287 =cut
4288
4289 sub cust_pkg_discount {
4290   my $self = shift;
4291   qsearch('cust_pkg_discount', { 'pkgnum' => $self->pkgnum } );
4292 }
4293
4294 =item cust_pkg_discount_active
4295
4296 =cut
4297
4298 sub cust_pkg_discount_active {
4299   my $self = shift;
4300   grep { $_->status eq 'active' } $self->cust_pkg_discount;
4301 }
4302
4303 =item cust_pkg_usage
4304
4305 Returns a list of all voice usage counters attached to this package.
4306
4307 =cut
4308
4309 sub cust_pkg_usage {
4310   my $self = shift;
4311   qsearch('cust_pkg_usage', { pkgnum => $self->pkgnum });
4312 }
4313
4314 =item apply_usage OPTIONS
4315
4316 Takes the following options:
4317 - cdr: a call detail record (L<FS::cdr>)
4318 - rate_detail: the rate determined for this call (L<FS::rate_detail>)
4319 - minutes: the maximum number of minutes to be charged
4320
4321 Finds available usage minutes for a call of this class, and subtracts
4322 up to that many minutes from the usage pool.  If the usage pool is empty,
4323 and the C<cdr-minutes_priority> global config option is set, minutes may
4324 be taken from other calls as well.  Either way, an allocation record will
4325 be created (L<FS::cdr_cust_pkg_usage>) and this method will return the
4326 number of minutes of usage applied to the call.
4327
4328 =cut
4329
4330 sub apply_usage {
4331   my ($self, %opt) = @_;
4332   my $cdr = $opt{cdr};
4333   my $rate_detail = $opt{rate_detail};
4334   my $minutes = $opt{minutes};
4335   my $classnum = $rate_detail->classnum;
4336   my $pkgnum = $self->pkgnum;
4337   my $custnum = $self->custnum;
4338
4339   local $SIG{HUP} = 'IGNORE';
4340   local $SIG{INT} = 'IGNORE';
4341   local $SIG{QUIT} = 'IGNORE';
4342   local $SIG{TERM} = 'IGNORE';
4343   local $SIG{TSTP} = 'IGNORE';
4344   local $SIG{PIPE} = 'IGNORE';
4345
4346   my $oldAutoCommit = $FS::UID::AutoCommit;
4347   local $FS::UID::AutoCommit = 0;
4348   my $dbh = dbh;
4349   my $order = FS::Conf->new->config('cdr-minutes_priority');
4350
4351   my $is_classnum;
4352   if ( $classnum ) {
4353     $is_classnum = ' part_pkg_usage_class.classnum = '.$classnum;
4354   } else {
4355     $is_classnum = ' part_pkg_usage_class.classnum IS NULL';
4356   }
4357   my @usage_recs = qsearch({
4358       'table'     => 'cust_pkg_usage',
4359       'addl_from' => ' JOIN part_pkg_usage       USING (pkgusagepart)'.
4360                      ' JOIN cust_pkg             USING (pkgnum)'.
4361                      ' JOIN part_pkg_usage_class USING (pkgusagepart)',
4362       'select'    => 'cust_pkg_usage.*',
4363       'extra_sql' => " WHERE ( cust_pkg.pkgnum = $pkgnum OR ".
4364                      " ( cust_pkg.custnum = $custnum AND ".
4365                      " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4366                      $is_classnum . ' AND '.
4367                      " cust_pkg_usage.minutes > 0",
4368       'order_by'  => " ORDER BY priority ASC",
4369   });
4370
4371   my $orig_minutes = $minutes;
4372   my $error;
4373   while (!$error and $minutes > 0 and @usage_recs) {
4374     my $cust_pkg_usage = shift @usage_recs;
4375     $cust_pkg_usage->select_for_update;
4376     my $cdr_cust_pkg_usage = FS::cdr_cust_pkg_usage->new({
4377         pkgusagenum => $cust_pkg_usage->pkgusagenum,
4378         acctid      => $cdr->acctid,
4379         minutes     => min($cust_pkg_usage->minutes, $minutes),
4380     });
4381     $cust_pkg_usage->set('minutes',
4382       $cust_pkg_usage->minutes - $cdr_cust_pkg_usage->minutes
4383     );
4384     $error = $cust_pkg_usage->replace || $cdr_cust_pkg_usage->insert;
4385     $minutes -= $cdr_cust_pkg_usage->minutes;
4386   }
4387   if ( $order and $minutes > 0 and !$error ) {
4388     # then try to steal minutes from another call
4389     my %search = (
4390         'table'     => 'cdr_cust_pkg_usage',
4391         'addl_from' => ' JOIN cust_pkg_usage        USING (pkgusagenum)'.
4392                        ' JOIN part_pkg_usage        USING (pkgusagepart)'.
4393                        ' JOIN cust_pkg              USING (pkgnum)'.
4394                        ' JOIN part_pkg_usage_class  USING (pkgusagepart)'.
4395                        ' JOIN cdr                   USING (acctid)',
4396         'select'    => 'cdr_cust_pkg_usage.*',
4397         'extra_sql' => " WHERE cdr.freesidestatus = 'rated' AND ".
4398                        " ( cust_pkg.pkgnum = $pkgnum OR ".
4399                        " ( cust_pkg.custnum = $custnum AND ".
4400                        " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4401                        " part_pkg_usage_class.classnum = $classnum",
4402         'order_by'  => ' ORDER BY part_pkg_usage.priority ASC',
4403     );
4404     if ( $order eq 'time' ) {
4405       # find CDRs that are using minutes, but have a later startdate
4406       # than this call
4407       my $startdate = $cdr->startdate;
4408       if ($startdate !~ /^\d+$/) {
4409         die "bad cdr startdate '$startdate'";
4410       }
4411       $search{'extra_sql'} .= " AND cdr.startdate > $startdate";
4412       # minimize needless reshuffling
4413       $search{'order_by'} .= ', cdr.startdate DESC';
4414     } else {
4415       # XXX may not work correctly with rate_time schedules.  Could
4416       # fix this by storing ratedetailnum in cdr_cust_pkg_usage, I
4417       # think...
4418       $search{'addl_from'} .=
4419         ' JOIN rate_detail'.
4420         ' ON (cdr.rated_ratedetailnum = rate_detail.ratedetailnum)';
4421       if ( $order eq 'rate_high' ) {
4422         $search{'extra_sql'} .= ' AND rate_detail.min_charge < '.
4423                                 $rate_detail->min_charge;
4424         $search{'order_by'} .= ', rate_detail.min_charge ASC';
4425       } elsif ( $order eq 'rate_low' ) {
4426         $search{'extra_sql'} .= ' AND rate_detail.min_charge > '.
4427                                 $rate_detail->min_charge;
4428         $search{'order_by'} .= ', rate_detail.min_charge DESC';
4429       } else {
4430         #  this should really never happen
4431         die "invalid cdr-minutes_priority value '$order'\n";
4432       }
4433     }
4434     my @cdr_usage_recs = qsearch(\%search);
4435     my %reproc_cdrs;
4436     while (!$error and @cdr_usage_recs and $minutes > 0) {
4437       my $cdr_cust_pkg_usage = shift @cdr_usage_recs;
4438       my $cust_pkg_usage = $cdr_cust_pkg_usage->cust_pkg_usage;
4439       my $old_cdr = $cdr_cust_pkg_usage->cdr;
4440       $reproc_cdrs{$old_cdr->acctid} = $old_cdr;
4441       $cdr_cust_pkg_usage->select_for_update;
4442       $old_cdr->select_for_update;
4443       $cust_pkg_usage->select_for_update;
4444       # in case someone else stole the usage from this CDR
4445       # while waiting for the lock...
4446       next if $old_cdr->acctid != $cdr_cust_pkg_usage->acctid;
4447       # steal the usage allocation and flag the old CDR for reprocessing
4448       $cdr_cust_pkg_usage->set('acctid', $cdr->acctid);
4449       # if the allocation is more minutes than we need, adjust it...
4450       my $delta = $cdr_cust_pkg_usage->minutes - $minutes;
4451       if ( $delta > 0 ) {
4452         $cdr_cust_pkg_usage->set('minutes', $minutes);
4453         $cust_pkg_usage->set('minutes', $cust_pkg_usage->minutes + $delta);
4454         $error = $cust_pkg_usage->replace;
4455       }
4456       #warn 'CDR '.$cdr->acctid . ' stealing allocation '.$cdr_cust_pkg_usage->cdrusagenum.' from CDR '.$old_cdr->acctid."\n";
4457       $error ||= $cdr_cust_pkg_usage->replace;
4458       # deduct the stolen minutes
4459       $minutes -= $cdr_cust_pkg_usage->minutes;
4460     }
4461     # after all minute-stealing is done, reset the affected CDRs
4462     foreach (values %reproc_cdrs) {
4463       $error ||= $_->set_status('');
4464       # XXX or should we just call $cdr->rate right here?
4465       # it's not like we can create a loop this way, since the min_charge
4466       # or call time has to go monotonically in one direction.
4467       # we COULD get some very deep recursions going, though...
4468     }
4469   } # if $order and $minutes
4470   if ( $error ) {
4471     $dbh->rollback;
4472     die "error applying included minutes\npkgnum ".$self->pkgnum.", class $classnum, acctid ".$cdr->acctid."\n$error\n"
4473   } else {
4474     $dbh->commit if $oldAutoCommit;
4475     return $orig_minutes - $minutes;
4476   }
4477 }
4478
4479 =item supplemental_pkgs
4480
4481 Returns a list of all packages supplemental to this one.
4482
4483 =cut
4484
4485 sub supplemental_pkgs {
4486   my $self = shift;
4487   qsearch('cust_pkg', { 'main_pkgnum' => $self->pkgnum });
4488 }
4489
4490 =item main_pkg
4491
4492 Returns the package that this one is supplemental to, if any.
4493
4494 =cut
4495
4496 sub main_pkg {
4497   my $self = shift;
4498   if ( $self->main_pkgnum ) {
4499     return FS::cust_pkg->by_key($self->main_pkgnum);
4500   }
4501   return;
4502 }
4503
4504 =back
4505
4506 =head1 CLASS METHODS
4507
4508 =over 4
4509
4510 =item recurring_sql
4511
4512 Returns an SQL expression identifying recurring packages.
4513
4514 =cut
4515
4516 sub recurring_sql { "
4517   '0' != ( select freq from part_pkg
4518              where cust_pkg.pkgpart = part_pkg.pkgpart )
4519 "; }
4520
4521 =item onetime_sql
4522
4523 Returns an SQL expression identifying one-time packages.
4524
4525 =cut
4526
4527 sub onetime_sql { "
4528   '0' = ( select freq from part_pkg
4529             where cust_pkg.pkgpart = part_pkg.pkgpart )
4530 "; }
4531
4532 =item ordered_sql
4533
4534 Returns an SQL expression identifying ordered packages (recurring packages not
4535 yet billed).
4536
4537 =cut
4538
4539 sub ordered_sql {
4540    $_[0]->recurring_sql. " AND ". $_[0]->not_yet_billed_sql;
4541 }
4542
4543 =item active_sql
4544
4545 Returns an SQL expression identifying active packages.
4546
4547 =cut
4548
4549 sub active_sql {
4550   $_[0]->recurring_sql. "
4551   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4552   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4553   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4554 "; }
4555
4556 =item not_yet_billed_sql
4557
4558 Returns an SQL expression identifying packages which have not yet been billed.
4559
4560 =cut
4561
4562 sub not_yet_billed_sql { "
4563       ( cust_pkg.setup  IS NULL OR cust_pkg.setup  = 0 )
4564   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4565   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4566 "; }
4567
4568 =item inactive_sql
4569
4570 Returns an SQL expression identifying inactive packages (one-time packages
4571 that are otherwise unsuspended/uncancelled).
4572
4573 =cut
4574
4575 sub inactive_sql { "
4576   ". $_[0]->onetime_sql(). "
4577   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4578   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4579   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4580 "; }
4581
4582 =item on_hold_sql
4583
4584 Returns an SQL expression identifying on-hold packages.
4585
4586 =cut
4587
4588 sub on_hold_sql {
4589   #$_[0]->recurring_sql(). ' AND '.
4590   "
4591         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel  = 0 )
4592     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp   != 0
4593     AND ( cust_pkg.setup  IS     NULL  OR cust_pkg.setup   = 0 )
4594   ";
4595 }
4596
4597 =item susp_sql
4598 =item suspended_sql
4599
4600 Returns an SQL expression identifying suspended packages.
4601
4602 =cut
4603
4604 sub suspended_sql { susp_sql(@_); }
4605 sub susp_sql {
4606   #$_[0]->recurring_sql(). ' AND '.
4607   "
4608         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel = 0 )
4609     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp  != 0
4610     AND   cust_pkg.setup  IS NOT NULL AND cust_pkg.setup != 0
4611   ";
4612 }
4613
4614 =item cancel_sql
4615 =item cancelled_sql
4616
4617 Returns an SQL exprression identifying cancelled packages.
4618
4619 =cut
4620
4621 sub cancelled_sql { cancel_sql(@_); }
4622 sub cancel_sql {
4623   #$_[0]->recurring_sql(). ' AND '.
4624   "cust_pkg.cancel IS NOT NULL AND cust_pkg.cancel != 0";
4625 }
4626
4627 =item status_sql
4628
4629 Returns an SQL expression to give the package status as a string.
4630
4631 =cut
4632
4633 sub status_sql {
4634 "CASE
4635   WHEN cust_pkg.cancel IS NOT NULL THEN 'cancelled'
4636   WHEN ( cust_pkg.susp IS NOT NULL AND cust_pkg.setup IS NULL ) THEN 'on hold'
4637   WHEN cust_pkg.susp IS NOT NULL THEN 'suspended'
4638   WHEN cust_pkg.setup IS NULL THEN 'not yet billed'
4639   WHEN ".onetime_sql()." THEN 'one-time charge'
4640   ELSE 'active'
4641 END"
4642 }
4643
4644 =item search HASHREF
4645
4646 (Class method)
4647
4648 Returns a qsearch hash expression to search for parameters specified in HASHREF.
4649 Valid parameters are
4650
4651 =over 4
4652
4653 =item agentnum
4654
4655 =item status
4656
4657 on hold, active, inactive (or one-time charge), suspended, canceled (or cancelled)
4658
4659 =item magic
4660
4661 Equivalent to "status", except that "canceled"/"cancelled" will exclude
4662 packages that were changed into a new package with the same pkgpart (i.e.
4663 location or quantity changes).
4664
4665 =item custom
4666
4667  boolean selects custom packages
4668
4669 =item classnum
4670
4671 =item pkgpart
4672
4673 pkgpart or arrayref or hashref of pkgparts
4674
4675 =item setup
4676
4677 arrayref of beginning and ending epoch date
4678
4679 =item last_bill
4680
4681 arrayref of beginning and ending epoch date
4682
4683 =item bill
4684
4685 arrayref of beginning and ending epoch date
4686
4687 =item adjourn
4688
4689 arrayref of beginning and ending epoch date
4690
4691 =item susp
4692
4693 arrayref of beginning and ending epoch date
4694
4695 =item expire
4696
4697 arrayref of beginning and ending epoch date
4698
4699 =item cancel
4700
4701 arrayref of beginning and ending epoch date
4702
4703 =item query
4704
4705 pkgnum or APKG_pkgnum
4706
4707 =item cust_fields
4708
4709 a value suited to passing to FS::UI::Web::cust_header
4710
4711 =item CurrentUser
4712
4713 specifies the user for agent virtualization
4714
4715 =item fcc_line
4716
4717 boolean; if true, returns only packages with more than 0 FCC phone lines.
4718
4719 =item state, country
4720
4721 Limit to packages with a service location in the specified state and country.
4722 For FCC 477 reporting, mostly.
4723
4724 =item location_cust
4725
4726 Limit to packages whose service locations are the same as the customer's
4727 default service location.
4728
4729 =item location_nocust
4730
4731 Limit to packages whose service locations are not the customer's default
4732 service location.
4733
4734 =item location_census
4735
4736 Limit to packages whose service locations have census tracts.
4737
4738 =item location_nocensus
4739
4740 Limit to packages whose service locations do not have a census tract.
4741
4742 =item location_geocode
4743
4744 Limit to packages whose locations have geocodes.
4745
4746 =item location_geocode
4747
4748 Limit to packages whose locations do not have geocodes.
4749
4750 =item towernum
4751
4752 Limit to packages associated with a svc_broadband, associated with a sector,
4753 associated with this towernum (or any of these, if it's an arrayref) (or NO
4754 towernum, if it's zero). This is an extreme niche case.
4755
4756 =item 477part, 477rownum, date
4757
4758 Limit to packages included in a specific row of one of the FCC 477 reports.
4759 '477part' is the section name (see L<FS::Report::FCC_477> methods), 'date'
4760 is the report as-of date (completely unrelated to the package setup/bill/
4761 other date fields), and '477rownum' is the row number of the report starting
4762 with zero. Row numbers have no inherent meaning, so this is useful only
4763 for explaining a 477 report you've already run.
4764
4765 =back
4766
4767 =cut
4768
4769 sub search {
4770   my ($class, $params) = @_;
4771   my @where = ();
4772
4773   ##
4774   # parse agent
4775   ##
4776
4777   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
4778     push @where,
4779       "cust_main.agentnum = $1";
4780   }
4781
4782   ##
4783   # parse cust_status
4784   ##
4785
4786   if ( $params->{'cust_status'} =~ /^([a-z]+)$/ ) {
4787     push @where, FS::cust_main->cust_status_sql . " = '$1' ";
4788   }
4789
4790   ##
4791   # parse customer sales person
4792   ##
4793
4794   if ( $params->{'cust_main_salesnum'} =~ /^(\d+)$/ ) {
4795     push @where, ($1 > 0) ? "cust_main.salesnum = $1"
4796                           : 'cust_main.salesnum IS NULL';
4797   }
4798
4799
4800   ##
4801   # parse sales person
4802   ##
4803
4804   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
4805     push @where, ($1 > 0) ? "cust_pkg.salesnum = $1"
4806                           : 'cust_pkg.salesnum IS NULL';
4807   }
4808
4809   ##
4810   # parse custnum
4811   ##
4812
4813   if ( $params->{'custnum'} =~ /^(\d+)$/ and $1 ) {
4814     push @where,
4815       "cust_pkg.custnum = $1";
4816   }
4817
4818   ##
4819   # custbatch
4820   ##
4821
4822   if ( $params->{'pkgbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
4823     push @where,
4824       "cust_pkg.pkgbatch = '$1'";
4825   }
4826
4827   ##
4828   # parse status
4829   ##
4830
4831   if (    $params->{'magic'}  eq 'active'
4832        || $params->{'status'} eq 'active' ) {
4833
4834     push @where, FS::cust_pkg->active_sql();
4835
4836   } elsif (    $params->{'magic'}  =~ /^not[ _]yet[ _]billed$/
4837             || $params->{'status'} =~ /^not[ _]yet[ _]billed$/ ) {
4838
4839     push @where, FS::cust_pkg->not_yet_billed_sql();
4840
4841   } elsif (    $params->{'magic'}  =~ /^(one-time charge|inactive)/
4842             || $params->{'status'} =~ /^(one-time charge|inactive)/ ) {
4843
4844     push @where, FS::cust_pkg->inactive_sql();
4845
4846   } elsif (    $params->{'magic'}  =~ /^on[ _]hold$/
4847             || $params->{'status'} =~ /^on[ _]hold$/ ) {
4848
4849     push @where, FS::cust_pkg->on_hold_sql();
4850
4851
4852   } elsif (    $params->{'magic'}  eq 'suspended'
4853             || $params->{'status'} eq 'suspended'  ) {
4854
4855     push @where, FS::cust_pkg->suspended_sql();
4856
4857   } elsif (    $params->{'magic'}  =~ /^cancell?ed$/
4858             || $params->{'status'} =~ /^cancell?ed$/ ) {
4859
4860     push @where, FS::cust_pkg->cancelled_sql();
4861
4862   }
4863
4864   ### special case: "magic" is used in detail links from browse/part_pkg,
4865   # where "cancelled" has the restriction "and not replaced with a package
4866   # of the same pkgpart".  Be consistent with that.
4867   ###
4868
4869   if ( $params->{'magic'} =~ /^cancell?ed$/ ) {
4870     my $new_pkgpart = "SELECT pkgpart FROM cust_pkg AS cust_pkg_next ".
4871                       "WHERE cust_pkg_next.change_pkgnum = cust_pkg.pkgnum";
4872     # ...may not exist, if this was just canceled and not changed; in that
4873     # case give it a "new pkgpart" that never equals the old pkgpart
4874     push @where, "COALESCE(($new_pkgpart), 0) != cust_pkg.pkgpart";
4875   }
4876
4877   ###
4878   # parse package class
4879   ###
4880
4881   if ( exists($params->{'classnum'}) ) {
4882
4883     my @classnum = ();
4884     if ( ref($params->{'classnum'}) ) {
4885
4886       if ( ref($params->{'classnum'}) eq 'HASH' ) {
4887         @classnum = grep $params->{'classnum'}{$_}, keys %{ $params->{'classnum'} };
4888       } elsif ( ref($params->{'classnum'}) eq 'ARRAY' ) {
4889         @classnum = @{ $params->{'classnum'} };
4890       } else {
4891         die 'unhandled classnum ref '. $params->{'classnum'};
4892       }
4893
4894
4895     } elsif ( $params->{'classnum'} =~ /^(\d*)$/ && $1 ne '0' ) {
4896       @classnum = ( $1 );
4897     }
4898
4899     if ( @classnum ) {
4900
4901       my @c_where = ();
4902       my @nums = grep $_, @classnum;
4903       push @c_where, 'part_pkg.classnum IN ('. join(',',@nums). ')' if @nums;
4904       my $null = scalar( grep { $_ eq '' } @classnum );
4905       push @c_where, 'part_pkg.classnum IS NULL' if $null;
4906
4907       if ( scalar(@c_where) == 1 ) {
4908         push @where, @c_where;
4909       } elsif ( @c_where ) {
4910         push @where, ' ( '. join(' OR ', @c_where). ' ) ';
4911       }
4912
4913     }
4914
4915
4916   }
4917
4918   ###
4919   # parse refnum (advertising source)
4920   ###
4921
4922   if ( exists($params->{'refnum'}) ) {
4923     my @refnum;
4924     if (ref $params->{'refnum'}) {
4925       @refnum = @{ $params->{'refnum'} };
4926     } else {
4927       @refnum = ( $params->{'refnum'} );
4928     }
4929     my $in = join(',', grep /^\d+$/, @refnum);
4930     push @where, "refnum IN($in)" if length $in;
4931   }
4932
4933   ###
4934   # parse package report options
4935   ###
4936
4937   my @report_option = ();
4938   if ( exists($params->{'report_option'}) ) {
4939     if ( ref($params->{'report_option'}) eq 'ARRAY' ) {
4940       @report_option = @{ $params->{'report_option'} };
4941     } elsif ( $params->{'report_option'} =~ /^([,\d]*)$/ ) {
4942       @report_option = split(',', $1);
4943     }
4944
4945   }
4946
4947   if (@report_option) {
4948     # this will result in the empty set for the dangling comma case as it should
4949     push @where,
4950       map{ "0 < ( SELECT count(*) FROM part_pkg_option
4951                     WHERE part_pkg_option.pkgpart = part_pkg.pkgpart
4952                     AND optionname = 'report_option_$_'
4953                     AND optionvalue = '1' )"
4954          } @report_option;
4955   }
4956
4957   foreach my $any ( grep /^report_option_any/, keys %$params ) {
4958
4959     my @report_option_any = ();
4960     if ( ref($params->{$any}) eq 'ARRAY' ) {
4961       @report_option_any = @{ $params->{$any} };
4962     } elsif ( $params->{$any} =~ /^([,\d]*)$/ ) {
4963       @report_option_any = split(',', $1);
4964     }
4965
4966     if (@report_option_any) {
4967       # this will result in the empty set for the dangling comma case as it should
4968       push @where, ' ( '. join(' OR ',
4969         map{ "0 < ( SELECT count(*) FROM part_pkg_option
4970                       WHERE part_pkg_option.pkgpart = part_pkg.pkgpart
4971                       AND optionname = 'report_option_$_'
4972                       AND optionvalue = '1' )"
4973            } @report_option_any
4974       ). ' ) ';
4975     }
4976
4977   }
4978
4979   ###
4980   # parse custom
4981   ###
4982
4983   push @where,  "part_pkg.custom = 'Y'" if $params->{custom};
4984
4985   ###
4986   # parse fcc_line
4987   ###
4988
4989   push @where,  "(part_pkg.fcc_ds0s > 0 OR pkg_class.fcc_ds0s > 0)"
4990                                                         if $params->{fcc_line};
4991
4992   ###
4993   # parse censustract
4994   ###
4995
4996   if ( exists($params->{'censustract'}) ) {
4997     $params->{'censustract'} =~ /^([.\d]*)$/;
4998     my $censustract = "cust_location.censustract = '$1'";
4999     $censustract .= ' OR cust_location.censustract is NULL' unless $1;
5000     push @where,  "( $censustract )";
5001   }
5002
5003   ###
5004   # parse censustract2
5005   ###
5006   if ( exists($params->{'censustract2'})
5007        && $params->{'censustract2'} =~ /^(\d*)$/
5008      )
5009   {
5010     if ($1) {
5011       push @where, "cust_location.censustract LIKE '$1%'";
5012     } else {
5013       push @where,
5014         "( cust_location.censustract = '' OR cust_location.censustract IS NULL )";
5015     }
5016   }
5017
5018   ###
5019   # parse country/state/zip
5020   ###
5021   for (qw(state country)) { # parsing rules are the same for these
5022   if ( exists($params->{$_})
5023     && uc($params->{$_}) =~ /^([A-Z]{2})$/ )
5024     {
5025       # XXX post-2.3 only--before that, state/country may be in cust_main
5026       push @where, "cust_location.$_ = '$1'";
5027     }
5028   }
5029   if ( exists($params->{zip}) ) {
5030     push @where, "cust_location.zip = " . dbh->quote($params->{zip});
5031   }
5032
5033   ###
5034   # location_* flags
5035   ###
5036   if ( $params->{location_cust} xor $params->{location_nocust} ) {
5037     my $op = $params->{location_cust} ? '=' : '!=';
5038     push @where, "cust_location.locationnum $op cust_main.ship_locationnum";
5039   }
5040   if ( $params->{location_census} xor $params->{location_nocensus} ) {
5041     my $op = $params->{location_census} ? "IS NOT NULL" : "IS NULL";
5042     push @where, "cust_location.censustract $op";
5043   }
5044   if ( $params->{location_geocode} xor $params->{location_nogeocode} ) {
5045     my $op = $params->{location_geocode} ? "IS NOT NULL" : "IS NULL";
5046     push @where, "cust_location.geocode $op";
5047   }
5048
5049   ###
5050   # parse part_pkg
5051   ###
5052
5053   if ( ref($params->{'pkgpart'}) ) {
5054
5055     my @pkgpart = ();
5056     if ( ref($params->{'pkgpart'}) eq 'HASH' ) {
5057       @pkgpart = grep $params->{'pkgpart'}{$_}, keys %{ $params->{'pkgpart'} };
5058     } elsif ( ref($params->{'pkgpart'}) eq 'ARRAY' ) {
5059       @pkgpart = @{ $params->{'pkgpart'} };
5060     } else {
5061       die 'unhandled pkgpart ref '. $params->{'pkgpart'};
5062     }
5063
5064     @pkgpart = grep /^(\d+)$/, @pkgpart;
5065
5066     push @where, 'pkgpart IN ('. join(',', @pkgpart). ')' if scalar(@pkgpart);
5067
5068   } elsif ( $params->{'pkgpart'} =~ /^(\d+)$/ ) {
5069     push @where, "pkgpart = $1";
5070   }
5071
5072   ###
5073   # parse dates
5074   ###
5075
5076   my $orderby = '';
5077
5078   #false laziness w/report_cust_pkg.html
5079   my %disable = (
5080     'all'             => {},
5081     'one-time charge' => { 'last_bill'=>1, 'bill'=>1, 'adjourn'=>1, 'susp'=>1, 'expire'=>1, 'cancel'=>1, },
5082     'active'          => { 'susp'=>1, 'cancel'=>1 },
5083     'suspended'       => { 'cancel' => 1 },
5084     'cancelled'       => {},
5085     ''                => {},
5086   );
5087
5088   if( exists($params->{'active'} ) ) {
5089     # This overrides all the other date-related fields, and includes packages
5090     # that were active at some time during the interval.  It excludes:
5091     # - packages that were set up after the end of the interval
5092     # - packages that were canceled before the start of the interval
5093     # - packages that were suspended before the start of the interval
5094     #   and are still suspended now
5095     my($beginning, $ending) = @{$params->{'active'}};
5096     push @where,
5097       "cust_pkg.setup IS NOT NULL",
5098       "cust_pkg.setup <= $ending",
5099       "(cust_pkg.cancel IS NULL OR cust_pkg.cancel >= $beginning )",
5100       "(cust_pkg.susp   IS NULL OR cust_pkg.susp   >= $beginning )",
5101       "NOT (".FS::cust_pkg->onetime_sql . ")";
5102   }
5103   else {
5104     my $exclude_change_from = 0;
5105     my $exclude_change_to = 0;
5106
5107     foreach my $field (qw( setup last_bill bill adjourn susp expire contract_end change_date cancel )) {
5108
5109       next unless exists($params->{$field});
5110
5111       my($beginning, $ending) = @{$params->{$field}};
5112
5113       next if $beginning == 0 && $ending == 4294967295;
5114
5115       push @where,
5116         "cust_pkg.$field IS NOT NULL",
5117         "cust_pkg.$field >= $beginning",
5118         "cust_pkg.$field <= $ending";
5119
5120       $orderby ||= "ORDER BY cust_pkg.$field";
5121
5122       if ( $field eq 'setup' ) {
5123         $exclude_change_from = 1;
5124       } elsif ( $field eq 'cancel' ) {
5125         $exclude_change_to = 1;
5126       } elsif ( $field eq 'change_date' ) {
5127         # if we are given setup and change_date ranges, and the setup date
5128         # falls in _both_ ranges, then include the package whether it was
5129         # a change or not
5130         $exclude_change_from = 0;
5131       }
5132     }
5133
5134     if ($exclude_change_from) {
5135       push @where, "change_pkgnum IS NULL";
5136     }
5137     if ($exclude_change_to) {
5138       # a join might be more efficient here
5139       push @where, "NOT EXISTS(
5140         SELECT 1 FROM cust_pkg AS changed_to_pkg
5141         WHERE cust_pkg.pkgnum = changed_to_pkg.change_pkgnum
5142       )";
5143     }
5144   }
5145
5146   $orderby ||= 'ORDER BY bill';
5147
5148   ###
5149   # parse magic, legacy, etc.
5150   ###
5151
5152   if ( $params->{'magic'} &&
5153        $params->{'magic'} =~ /^(active|inactive|suspended|cancell?ed)$/
5154   ) {
5155
5156     $orderby = 'ORDER BY pkgnum';
5157
5158     if ( $params->{'pkgpart'} =~ /^(\d+)$/ ) {
5159       push @where, "pkgpart = $1";
5160     }
5161
5162   } elsif ( $params->{'query'} eq 'pkgnum' ) {
5163
5164     $orderby = 'ORDER BY pkgnum';
5165
5166   } elsif ( $params->{'query'} eq 'APKG_pkgnum' ) {
5167
5168     $orderby = 'ORDER BY pkgnum';
5169
5170     push @where, '0 < (
5171       SELECT count(*) FROM pkg_svc
5172        WHERE pkg_svc.pkgpart =  cust_pkg.pkgpart
5173          AND pkg_svc.quantity > ( SELECT count(*) FROM cust_svc
5174                                    WHERE cust_svc.pkgnum  = cust_pkg.pkgnum
5175                                      AND cust_svc.svcpart = pkg_svc.svcpart
5176                                 )
5177     )';
5178
5179   }
5180
5181   ##
5182   # parse the extremely weird 'towernum' param
5183   ##
5184
5185   if ($params->{towernum}) {
5186     my $towernum = $params->{towernum};
5187     $towernum = [ $towernum ] if !ref($towernum);
5188     my $in = join(',', grep /^\d+$/, @$towernum);
5189     if (length $in) {
5190       # inefficient, but this is an obscure feature
5191       eval "use FS::Report::Table";
5192       FS::Report::Table->_init_tower_pkg_cache; # probably does nothing
5193       push @where, "EXISTS(
5194       SELECT 1 FROM tower_pkg_cache
5195       WHERE tower_pkg_cache.pkgnum = cust_pkg.pkgnum
5196         AND tower_pkg_cache.towernum IN ($in)
5197       )"
5198     }
5199   }
5200
5201   ##
5202   # parse the 477 report drill-down options
5203   ##
5204
5205   if ($params->{'477part'} =~ /^([a-z]+)$/) {
5206     my $section = $1;
5207     my ($date, $rownum, $agentnum);
5208     if ($params->{'date'} =~ /^(\d+)$/) {
5209       $date = $1;
5210     }
5211     if ($params->{'477rownum'} =~ /^(\d+)$/) {
5212       $rownum = $1;
5213     }
5214     if ($params->{'agentnum'} =~ /^(\d+)$/) {
5215       $agentnum = $1;
5216     }
5217     if ($date and defined($rownum)) {
5218       my $report = FS::Report::FCC_477->report($section,
5219         'date'      => $date,
5220         'agentnum'  => $agentnum,
5221         'detail'    => 1
5222       );
5223       my $pkgnums = $report->{detail}->[$rownum]
5224         or die "row $rownum is past the end of the report";
5225         # '0' so that if there are no pkgnums (empty string) it will create
5226         # a valid query that returns nothing
5227       warn "PKGNUMS:\n$pkgnums\n\n"; # XXX debug
5228
5229       # and this overrides everything
5230       @where = ( "cust_pkg.pkgnum IN($pkgnums)" );
5231     } # else we're missing some params, ignore the whole business
5232   }
5233
5234   ##
5235   # setup queries, links, subs, etc. for the search
5236   ##
5237
5238   # here is the agent virtualization
5239   if ($params->{CurrentUser}) {
5240     my $access_user =
5241       qsearchs('access_user', { username => $params->{CurrentUser} });
5242
5243     if ($access_user) {
5244       push @where, $access_user->agentnums_sql('table'=>'cust_main');
5245     } else {
5246       push @where, "1=0";
5247     }
5248   } else {
5249     push @where, $FS::CurrentUser::CurrentUser->agentnums_sql('table'=>'cust_main');
5250   }
5251
5252   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
5253
5254   my $addl_from = 'LEFT JOIN part_pkg  USING ( pkgpart  ) '.
5255                   'LEFT JOIN pkg_class ON ( part_pkg.classnum = pkg_class.classnum ) '.
5256                   'LEFT JOIN cust_location USING ( locationnum ) '.
5257                   FS::UI::Web::join_cust_main('cust_pkg', 'cust_pkg');
5258
5259   my $select;
5260   my $count_query;
5261   if ( $params->{'select_zip5'} ) {
5262     my $zip = 'cust_location.zip';
5263
5264     $select = "DISTINCT substr($zip,1,5) as zip";
5265     $orderby = "ORDER BY substr($zip,1,5)";
5266     $count_query = "SELECT COUNT( DISTINCT substr($zip,1,5) )";
5267   } else {
5268     $select = join(', ',
5269                          'cust_pkg.*',
5270                          ( map "part_pkg.$_", qw( pkg freq ) ),
5271                          'pkg_class.classname',
5272                          'cust_main.custnum AS cust_main_custnum',
5273                          FS::UI::Web::cust_sql_fields(
5274                            $params->{'cust_fields'}
5275                          ),
5276                   );
5277     $count_query = 'SELECT COUNT(*)';
5278   }
5279
5280   $count_query .= " FROM cust_pkg $addl_from $extra_sql";
5281
5282   my $sql_query = {
5283     'table'       => 'cust_pkg',
5284     'hashref'     => {},
5285     'select'      => $select,
5286     'extra_sql'   => $extra_sql,
5287     'order_by'    => $orderby,
5288     'addl_from'   => $addl_from,
5289     'count_query' => $count_query,
5290   };
5291
5292 }
5293
5294 =item fcc_477_count
5295
5296 Returns a list of two package counts.  The first is a count of packages
5297 based on the supplied criteria and the second is the count of residential
5298 packages with those same criteria.  Criteria are specified as in the search
5299 method.
5300
5301 =cut
5302
5303 sub fcc_477_count {
5304   my ($class, $params) = @_;
5305
5306   my $sql_query = $class->search( $params );
5307
5308   my $count_sql = delete($sql_query->{'count_query'});
5309   $count_sql =~ s/ FROM/,count(CASE WHEN cust_main.company IS NULL OR cust_main.company = '' THEN 1 END) FROM/
5310     or die "couldn't parse count_sql";
5311
5312   my $count_sth = dbh->prepare($count_sql)
5313     or die "Error preparing $count_sql: ". dbh->errstr;
5314   $count_sth->execute
5315     or die "Error executing $count_sql: ". $count_sth->errstr;
5316   my $count_arrayref = $count_sth->fetchrow_arrayref;
5317
5318   return ( @$count_arrayref );
5319
5320 }
5321
5322 =item tax_locationnum_sql
5323
5324 Returns an SQL expression for the tax location for a package, based
5325 on the settings of 'tax-pkg_address' and 'tax-ship_address'.
5326
5327 =cut
5328
5329 sub tax_locationnum_sql {
5330   my $conf = FS::Conf->new;
5331   if ( $conf->exists('tax-pkg_address') ) {
5332     'cust_pkg.locationnum';
5333   }
5334   elsif ( $conf->exists('tax-ship_address') ) {
5335     'cust_main.ship_locationnum';
5336   }
5337   else {
5338     'cust_main.bill_locationnum';
5339   }
5340 }
5341
5342 =item location_sql
5343
5344 Returns a list: the first item is an SQL fragment identifying matching
5345 packages/customers via location (taking into account shipping and package
5346 address taxation, if enabled), and subsequent items are the parameters to
5347 substitute for the placeholders in that fragment.
5348
5349 =cut
5350
5351 sub location_sql {
5352   my($class, %opt) = @_;
5353   my $ornull = $opt{'ornull'};
5354
5355   my $conf = new FS::Conf;
5356
5357   # '?' placeholders in _location_sql_where
5358   my $x = $ornull ? 3 : 2;
5359   my @bill_param = (
5360     ('district')x3,
5361     ('city')x3,
5362     ('county')x$x,
5363     ('state')x$x,
5364     'country'
5365   );
5366
5367   my $main_where;
5368   my @main_param;
5369   if ( $conf->exists('tax-ship_address') ) {
5370
5371     $main_where = "(
5372          (     ( ship_last IS NULL     OR  ship_last  = '' )
5373            AND ". _location_sql_where('cust_main', '', $ornull ). "
5374          )
5375       OR (       ship_last IS NOT NULL AND ship_last != ''
5376            AND ". _location_sql_where('cust_main', 'ship_', $ornull ). "
5377          )
5378     )";
5379     #    AND payby != 'COMP'
5380
5381     @main_param = ( @bill_param, @bill_param );
5382
5383   } else {
5384
5385     $main_where = _location_sql_where('cust_main'); # AND payby != 'COMP'
5386     @main_param = @bill_param;
5387
5388   }
5389
5390   my $where;
5391   my @param;
5392   if ( $conf->exists('tax-pkg_address') ) {
5393
5394     my $loc_where = _location_sql_where( 'cust_location', '', $ornull );
5395
5396     $where = " (
5397                     ( cust_pkg.locationnum IS     NULL AND $main_where )
5398                  OR ( cust_pkg.locationnum IS NOT NULL AND $loc_where  )
5399                )
5400              ";
5401     @param = ( @main_param, @bill_param );
5402
5403   } else {
5404
5405     $where = $main_where;
5406     @param = @main_param;
5407
5408   }
5409
5410   ( $where, @param );
5411
5412 }
5413
5414 #subroutine, helper for location_sql
5415 sub _location_sql_where {
5416   my $table  = shift;
5417   my $prefix = @_ ? shift : '';
5418   my $ornull = @_ ? shift : '';
5419
5420 #  $ornull             = $ornull          ? " OR ( ? IS NULL AND $table.${prefix}county IS NULL ) " : '';
5421
5422   $ornull = $ornull ? ' OR ? IS NULL ' : '';
5423
5424   my $or_empty_city     = " OR ( ? = '' AND $table.${prefix}city     IS NULL )";
5425   my $or_empty_county   = " OR ( ? = '' AND $table.${prefix}county   IS NULL )";
5426   my $or_empty_state    = " OR ( ? = '' AND $table.${prefix}state    IS NULL )";
5427
5428   my $text = (driver_name =~ /^mysql/i) ? 'char' : 'text';
5429
5430 #        ( $table.${prefix}city    = ? $or_empty_city   $ornull )
5431   "
5432         ( $table.district = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5433     AND ( $table.${prefix}city     = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5434     AND ( $table.${prefix}county   = ? $or_empty_county $ornull )
5435     AND ( $table.${prefix}state    = ? $or_empty_state  $ornull )
5436     AND   $table.${prefix}country  = ?
5437   ";
5438 }
5439
5440 sub _X_show_zero {
5441   my( $self, $what ) = @_;
5442
5443   my $what_show_zero = $what. '_show_zero';
5444   length($self->$what_show_zero())
5445     ? ($self->$what_show_zero() eq 'Y')
5446     : $self->part_pkg->$what_show_zero();
5447 }
5448
5449 =head1 SUBROUTINES
5450
5451 =over 4
5452
5453 =item order CUSTNUM, PKGPARTS_ARYREF, [ REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF [ REFNUM ] ] ]
5454
5455 Bulk cancel + order subroutine.  Perhaps slightly deprecated, only used by the
5456 bulk cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
5457
5458 CUSTNUM is a customer (see L<FS::cust_main>)
5459
5460 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5461 L<FS::part_pkg>) to order for this customer.  Duplicates are of course
5462 permitted.
5463
5464 REMOVE_PKGNUMS is an optional list of pkgnums specifying the billing items to
5465 remove for this customer.  The services (see L<FS::cust_svc>) are moved to the
5466 new billing items.  An error is returned if this is not possible (see
5467 L<FS::pkg_svc>).  An empty arrayref is equivalent to not specifying this
5468 parameter.
5469
5470 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5471 newly-created cust_pkg objects.
5472
5473 REFNUM, if specified, will specify the FS::pkg_referral record to be created
5474 and inserted.  Multiple FS::pkg_referral records can be created by
5475 setting I<refnum> to an array reference of refnums or a hash reference with
5476 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
5477 record will be created corresponding to cust_main.refnum.
5478
5479 =cut
5480
5481 sub order {
5482   my ($custnum, $pkgparts, $remove_pkgnum, $return_cust_pkg, $refnum) = @_;
5483
5484   my $conf = new FS::Conf;
5485
5486   # Transactionize this whole mess
5487   local $SIG{HUP} = 'IGNORE';
5488   local $SIG{INT} = 'IGNORE';
5489   local $SIG{QUIT} = 'IGNORE';
5490   local $SIG{TERM} = 'IGNORE';
5491   local $SIG{TSTP} = 'IGNORE';
5492   local $SIG{PIPE} = 'IGNORE';
5493
5494   my $oldAutoCommit = $FS::UID::AutoCommit;
5495   local $FS::UID::AutoCommit = 0;
5496   my $dbh = dbh;
5497
5498   my $error;
5499 #  my $cust_main = qsearchs('cust_main', { custnum => $custnum });
5500 #  return "Customer not found: $custnum" unless $cust_main;
5501
5502   warn "$me order: pkgnums to remove: ". join(',', @$remove_pkgnum). "\n"
5503     if $DEBUG;
5504
5505   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5506                          @$remove_pkgnum;
5507
5508   my $change = scalar(@old_cust_pkg) != 0;
5509
5510   my %hash = ();
5511   if ( scalar(@old_cust_pkg) == 1 && scalar(@$pkgparts) == 1 ) {
5512
5513     warn "$me order: changing pkgnum ". $old_cust_pkg[0]->pkgnum.
5514          " to pkgpart ". $pkgparts->[0]. "\n"
5515       if $DEBUG;
5516
5517     my $err_or_cust_pkg =
5518       $old_cust_pkg[0]->change( 'pkgpart' => $pkgparts->[0],
5519                                 'refnum'  => $refnum,
5520                               );
5521
5522     unless (ref($err_or_cust_pkg)) {
5523       $dbh->rollback if $oldAutoCommit;
5524       return $err_or_cust_pkg;
5525     }
5526
5527     push @$return_cust_pkg, $err_or_cust_pkg;
5528     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5529     return '';
5530
5531   }
5532
5533   # Create the new packages.
5534   foreach my $pkgpart (@$pkgparts) {
5535
5536     warn "$me order: inserting pkgpart $pkgpart\n" if $DEBUG;
5537
5538     my $cust_pkg = new FS::cust_pkg { custnum => $custnum,
5539                                       pkgpart => $pkgpart,
5540                                       refnum  => $refnum,
5541                                       %hash,
5542                                     };
5543     $error = $cust_pkg->insert( 'change' => $change );
5544     push @$return_cust_pkg, $cust_pkg;
5545
5546     foreach my $link ($cust_pkg->part_pkg->supp_part_pkg_link) {
5547       my $supp_pkg = FS::cust_pkg->new({
5548           custnum => $custnum,
5549           pkgpart => $link->dst_pkgpart,
5550           refnum  => $refnum,
5551           main_pkgnum => $cust_pkg->pkgnum,
5552           %hash,
5553       });
5554       $error ||= $supp_pkg->insert( 'change' => $change );
5555       push @$return_cust_pkg, $supp_pkg;
5556     }
5557
5558     if ($error) {
5559       $dbh->rollback if $oldAutoCommit;
5560       return $error;
5561     }
5562
5563   }
5564   # $return_cust_pkg now contains refs to all of the newly
5565   # created packages.
5566
5567   # Transfer services and cancel old packages.
5568   foreach my $old_pkg (@old_cust_pkg) {
5569
5570     warn "$me order: transferring services from pkgnum ". $old_pkg->pkgnum. "\n"
5571       if $DEBUG;
5572
5573     foreach my $new_pkg (@$return_cust_pkg) {
5574       $error = $old_pkg->transfer($new_pkg);
5575       if ($error and $error == 0) {
5576         # $old_pkg->transfer failed.
5577         $dbh->rollback if $oldAutoCommit;
5578         return $error;
5579       }
5580     }
5581
5582     if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
5583       warn "trying transfer again with change_svcpart option\n" if $DEBUG;
5584       foreach my $new_pkg (@$return_cust_pkg) {
5585         $error = $old_pkg->transfer($new_pkg, 'change_svcpart'=>1 );
5586         if ($error and $error == 0) {
5587           # $old_pkg->transfer failed.
5588         $dbh->rollback if $oldAutoCommit;
5589         return $error;
5590         }
5591       }
5592     }
5593
5594     if ($error > 0) {
5595       # Transfers were successful, but we went through all of the
5596       # new packages and still had services left on the old package.
5597       # We can't cancel the package under the circumstances, so abort.
5598       $dbh->rollback if $oldAutoCommit;
5599       return "Unable to transfer all services from package ".$old_pkg->pkgnum;
5600     }
5601     $error = $old_pkg->cancel( quiet=>1, 'no_delay_cancel'=>1 );
5602     if ($error) {
5603       $dbh->rollback;
5604       return $error;
5605     }
5606   }
5607   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5608   '';
5609 }
5610
5611 =item bulk_change PKGPARTS_ARYREF, REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF ]
5612
5613 A bulk change method to change packages for multiple customers.
5614
5615 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5616 L<FS::part_pkg>) to order for each customer.  Duplicates are of course
5617 permitted.
5618
5619 REMOVE_PKGNUMS is an list of pkgnums specifying the billing items to
5620 replace.  The services (see L<FS::cust_svc>) are moved to the
5621 new billing items.  An error is returned if this is not possible (see
5622 L<FS::pkg_svc>).
5623
5624 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5625 newly-created cust_pkg objects.
5626
5627 =cut
5628
5629 sub bulk_change {
5630   my ($pkgparts, $remove_pkgnum, $return_cust_pkg) = @_;
5631
5632   # Transactionize this whole mess
5633   local $SIG{HUP} = 'IGNORE';
5634   local $SIG{INT} = 'IGNORE';
5635   local $SIG{QUIT} = 'IGNORE';
5636   local $SIG{TERM} = 'IGNORE';
5637   local $SIG{TSTP} = 'IGNORE';
5638   local $SIG{PIPE} = 'IGNORE';
5639
5640   my $oldAutoCommit = $FS::UID::AutoCommit;
5641   local $FS::UID::AutoCommit = 0;
5642   my $dbh = dbh;
5643
5644   my @errors;
5645   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5646                          @$remove_pkgnum;
5647
5648   while(scalar(@old_cust_pkg)) {
5649     my @return = ();
5650     my $custnum = $old_cust_pkg[0]->custnum;
5651     my (@remove) = map { $_->pkgnum }
5652                    grep { $_->custnum == $custnum } @old_cust_pkg;
5653     @old_cust_pkg = grep { $_->custnum != $custnum } @old_cust_pkg;
5654
5655     my $error = order $custnum, $pkgparts, \@remove, \@return;
5656
5657     push @errors, $error
5658       if $error;
5659     push @$return_cust_pkg, @return;
5660   }
5661
5662   if (scalar(@errors)) {
5663     $dbh->rollback if $oldAutoCommit;
5664     return join(' / ', @errors);
5665   }
5666
5667   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5668   '';
5669 }
5670
5671 =item forward_emails
5672
5673 Returns a hash of svcnums and corresponding email addresses
5674 for svc_acct services that can be used as source or dest
5675 for svc_forward services provisioned in this package.
5676
5677 Accepts options I<svc_forward> OR I<svcnum> for a svc_forward
5678 service;  if included, will ensure the current values of the
5679 specified service are included in the list, even if for some
5680 other reason they wouldn't be.  If called as a class method
5681 with a specified service, returns only these current values.
5682
5683 Caution: does not actually check if svc_forward services are
5684 available to be provisioned on this package.
5685
5686 =cut
5687
5688 sub forward_emails {
5689   my $self = shift;
5690   my %opt = @_;
5691
5692   #load optional service, thoroughly validated
5693   die "Use svcnum or svc_forward, not both"
5694     if $opt{'svcnum'} && $opt{'svc_forward'};
5695   my $svc_forward = $opt{'svc_forward'};
5696   $svc_forward ||= qsearchs('svc_forward',{ 'svcnum' => $opt{'svcnum'} })
5697     if $opt{'svcnum'};
5698   die "Specified service is not a forward service"
5699     if $svc_forward && (ref($svc_forward) ne 'FS::svc_forward');
5700   die "Specified service not found"
5701     if ($opt{'svcnum'} || $opt{'svc_forward'}) && !$svc_forward;
5702
5703   my %email;
5704
5705   ## everything below was basically copied from httemplate/edit/svc_forward.cgi
5706   ## with minimal refactoring, not sure why we can't just load all svc_accts for this custnum
5707
5708   #add current values from specified service, if there was one
5709   if ($svc_forward) {
5710     foreach my $method (qw( srcsvc_acct dstsvc_acct )) {
5711       my $svc_acct = $svc_forward->$method();
5712       $email{$svc_acct->svcnum} = $svc_acct->email if $svc_acct;
5713     }
5714   }
5715
5716   if (ref($self) eq 'FS::cust_pkg') {
5717
5718     #and including the rest for this customer
5719     my($u_part_svc,@u_acct_svcparts);
5720     foreach $u_part_svc ( qsearch('part_svc',{'svcdb'=>'svc_acct'}) ) {
5721       push @u_acct_svcparts,$u_part_svc->getfield('svcpart');
5722     }
5723
5724     my $custnum = $self->getfield('custnum');
5725     foreach my $i_cust_pkg ( qsearch('cust_pkg',{'custnum'=>$custnum}) ) {
5726       my $cust_pkgnum = $i_cust_pkg->getfield('pkgnum');
5727       #now find the corresponding record(s) in cust_svc (for this pkgnum!)
5728       foreach my $acct_svcpart (@u_acct_svcparts) {
5729         foreach my $i_cust_svc (
5730           qsearch( 'cust_svc', { 'pkgnum'  => $cust_pkgnum,
5731                                  'svcpart' => $acct_svcpart } )
5732         ) {
5733           my $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $i_cust_svc->svcnum } );
5734           $email{$svc_acct->svcnum} = $svc_acct->email;
5735         }
5736       }
5737     }
5738   }
5739
5740   return %email;
5741 }
5742
5743 # Used by FS::Upgrade to migrate to a new database.
5744 sub _upgrade_data {  # class method
5745   my ($class, %opts) = @_;
5746   $class->_upgrade_otaker(%opts);
5747   my @statements = (
5748     # RT#10139, bug resulting in contract_end being set when it shouldn't
5749   'UPDATE cust_pkg SET contract_end = NULL WHERE contract_end = -1',
5750     # RT#10830, bad calculation of prorate date near end of year
5751     # the date range for bill is December 2009, and we move it forward
5752     # one year if it's before the previous bill date (which it should
5753     # never be)
5754   'UPDATE cust_pkg SET bill = bill + (365*24*60*60) WHERE bill < last_bill
5755   AND bill > 1259654400 AND bill < 1262332800 AND (SELECT plan FROM part_pkg
5756   WHERE part_pkg.pkgpart = cust_pkg.pkgpart) = \'prorate\'',
5757     # RT6628, add order_date to cust_pkg
5758     'update cust_pkg set order_date = (select history_date from h_cust_pkg
5759         where h_cust_pkg.pkgnum = cust_pkg.pkgnum and
5760         history_action = \'insert\') where order_date is null',
5761   );
5762   foreach my $sql (@statements) {
5763     my $sth = dbh->prepare($sql);
5764     $sth->execute or die $sth->errstr;
5765   }
5766
5767   # RT31194: supplemental package links that are deleted don't clean up
5768   # linked records
5769   my @pkglinknums = qsearch({
5770       'select'    => 'DISTINCT cust_pkg.pkglinknum',
5771       'table'     => 'cust_pkg',
5772       'addl_from' => ' LEFT JOIN part_pkg_link USING (pkglinknum) ',
5773       'extra_sql' => ' WHERE cust_pkg.pkglinknum IS NOT NULL
5774                         AND part_pkg_link.pkglinknum IS NULL',
5775   });
5776   foreach (@pkglinknums) {
5777     my $pkglinknum = $_->pkglinknum;
5778     warn "cleaning part_pkg_link #$pkglinknum\n";
5779     my $part_pkg_link = FS::part_pkg_link->new({pkglinknum => $pkglinknum});
5780     my $error = $part_pkg_link->remove_linked;
5781     die $error if $error;
5782   }
5783 }
5784
5785 =back
5786
5787 =head1 BUGS
5788
5789 sub order is not OO.  Perhaps it should be moved to FS::cust_main and made so?
5790
5791 In sub order, the @pkgparts array (passed by reference) is clobbered.
5792
5793 Also in sub order, no money is adjusted.  Once FS::part_pkg defines a standard
5794 method to pass dates to the recur_prog expression, it should do so.
5795
5796 FS::svc_acct, FS::svc_domain, FS::svc_www, FS::svc_ip and FS::svc_forward are
5797 loaded via 'use' at compile time, rather than via 'require' in sub { setup,
5798 suspend, unsuspend, cancel } because they use %FS::UID::callback to load
5799 configuration values.  Probably need a subroutine which decides what to do
5800 based on whether or not we've fetched the user yet, rather than a hash.  See
5801 FS::UID and the TODO.
5802
5803 Now that things are transactional should the check in the insert method be
5804 moved to check ?
5805
5806 =head1 SEE ALSO
5807
5808 L<FS::Record>, L<FS::cust_main>, L<FS::part_pkg>, L<FS::cust_svc>,
5809 L<FS::pkg_svc>, schema.html from the base documentation
5810
5811 =cut
5812
5813 1;
5814