FS/FS/cust_pkg.pm

   1 package FS::cust_pkg;
   2 use base qw( FS::otaker_Mixin FS::cust_main_Mixin FS::Sales_Mixin
   3              FS::contact_Mixin FS::location_Mixin
   4              FS::m2m_Common FS::option_Common );
   5
   6 use strict;
   7 use vars qw( $disable_agentcheck $DEBUG $me $upgrade );
   8 use Carp qw(cluck);
   9 use Scalar::Util qw( blessed );
  10 use List::Util qw(min max);
  11 use Tie::IxHash;
  12 use Time::Local qw( timelocal timelocal_nocheck );
  13 use MIME::Entity;
  14 use FS::UID qw( getotaker dbh driver_name );
  15 use FS::Misc qw( send_email );
  16 use FS::Record qw( qsearch qsearchs fields );
  17 use FS::CurrentUser;
  18 use FS::cust_svc;
  19 use FS::part_pkg;
  20 use FS::cust_main;
  21 use FS::contact;
  22 use FS::cust_location;
  23 use FS::pkg_svc;
  24 use FS::cust_bill_pkg;
  25 use FS::cust_pkg_detail;
  26 use FS::cust_pkg_usage;
  27 use FS::cdr_cust_pkg_usage;
  28 use FS::cust_event;
  29 use FS::h_cust_svc;
  30 use FS::reg_code;
  31 use FS::part_svc;
  32 use FS::cust_pkg_reason;
  33 use FS::reason;
  34 use FS::cust_pkg_discount;
  35 use FS::discount;
  36 use FS::UI::Web;
  37 use FS::sales;
  38 # for modify_charge
  39 use FS::cust_credit;
  40
  41 # need to 'use' these instead of 'require' in sub { cancel, suspend, unsuspend,
  42 # setup }
  43 # because they load configuration by setting FS::UID::callback (see TODO)
  44 use FS::svc_acct;
  45 use FS::svc_domain;
  46 use FS::svc_www;
  47 use FS::svc_forward;
  48
  49 # for sending cancel emails in sub cancel
  50 use FS::Conf;
  51
  52 $DEBUG = 0;
  53 $me = '[FS::cust_pkg]';
  54
  55 $disable_agentcheck = 0;
  56
  57 $upgrade = 0; #go away after setup+start dates cleaned up for old customers
  58
  59 sub _cache {
  60   my $self = shift;
  61   my ( $hashref, $cache ) = @_;
  62   #if ( $hashref->{'pkgpart'} ) {
  63   if ( $hashref->{'pkg'} ) {
  64     # #@{ $self->{'_pkgnum'} } = ();
  65     # my $subcache = $cache->subcache('pkgpart', 'part_pkg');
  66     # $self->{'_pkgpart'} = $subcache;
  67     # #push @{ $self->{'_pkgnum'} },
  68     #   FS::part_pkg->new_or_cached($hashref, $subcache);
  69     $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  70   }
  71   if ( exists $hashref->{'svcnum'} ) {
  72     #@{ $self->{'_pkgnum'} } = ();
  73     my $subcache = $cache->subcache('svcnum', 'cust_svc', $hashref->{pkgnum});
  74     $self->{'_svcnum'} = $subcache;
  75     #push @{ $self->{'_pkgnum'} },
  76     FS::cust_svc->new_or_cached($hashref, $subcache) if $hashref->{svcnum};
  77   }
  78 }
  79
  80 =head1 NAME
  81
  82 FS::cust_pkg - Object methods for cust_pkg objects
  83
  84 =head1 SYNOPSIS
  85
  86   use FS::cust_pkg;
  87
  88   $record = new FS::cust_pkg \%hash;
  89   $record = new FS::cust_pkg { 'column' => 'value' };
  90
  91   $error = $record->insert;
  92
  93   $error = $new_record->replace($old_record);
  94
  95   $error = $record->delete;
  96
  97   $error = $record->check;
  98
  99   $error = $record->cancel;
 100
 101   $error = $record->suspend;
 102
 103   $error = $record->unsuspend;
 104
 105   $part_pkg = $record->part_pkg;
 106
 107   @labels = $record->labels;
 108
 109   $seconds = $record->seconds_since($timestamp);
 110
 111   #bulk cancel+order... perhaps slightly deprecated, only used by the bulk
 112   # cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
 113   $error = FS::cust_pkg::order( $custnum, \@pkgparts );
 114   $error = FS::cust_pkg::order( $custnum, \@pkgparts, \@remove_pkgnums ] );
 115
 116 =head1 DESCRIPTION
 117
 118 An FS::cust_pkg object represents a customer billing item.  FS::cust_pkg
 119 inherits from FS::Record.  The following fields are currently supported:
 120
 121 =over 4
 122
 123 =item pkgnum
 124
 125 Primary key (assigned automatically for new billing items)
 126
 127 =item custnum
 128
 129 Customer (see L<FS::cust_main>)
 130
 131 =item pkgpart
 132
 133 Billing item definition (see L<FS::part_pkg>)
 134
 135 =item locationnum
 136
 137 Optional link to package location (see L<FS::location>)
 138
 139 =item order_date
 140
 141 date package was ordered (also remains same on changes)
 142
 143 =item start_date
 144
 145 date
 146
 147 =item setup
 148
 149 date
 150
 151 =item bill
 152
 153 date (next bill date)
 154
 155 =item last_bill
 156
 157 last bill date
 158
 159 =item adjourn
 160
 161 date
 162
 163 =item susp
 164
 165 date
 166
 167 =item expire
 168
 169 date
 170
 171 =item contract_end
 172
 173 date
 174
 175 =item cancel
 176
 177 date
 178
 179 =item usernum
 180
 181 order taker (see L<FS::access_user>)
 182
 183 =item manual_flag
 184
 185 If this field is set to 1, disables the automatic
 186 unsuspension of this package when using the B<unsuspendauto> config option.
 187
 188 =item quantity
 189
 190 If not set, defaults to 1
 191
 192 =item change_date
 193
 194 Date of change from previous package
 195
 196 =item change_pkgnum
 197
 198 Previous pkgnum
 199
 200 =item change_pkgpart
 201
 202 Previous pkgpart
 203
 204 =item change_locationnum
 205
 206 Previous locationnum
 207
 208 =item waive_setup
 209
 210 =item main_pkgnum
 211
 212 The pkgnum of the package that this package is supplemental to, if any.
 213
 214 =item pkglinknum
 215
 216 The package link (L<FS::part_pkg_link>) that defines this supplemental
 217 package, if it is one.
 218
 219 =item change_to_pkgnum
 220
 221 The pkgnum of the package this one will be "changed to" in the future
 222 (on its expiration date).
 223
 224 =back
 225
 226 Note: setup, last_bill, bill, adjourn, susp, expire, cancel and change_date
 227 are specified as UNIX timestamps; see L<perlfunc/"time">.  Also see
 228 L<Time::Local> and L<Date::Parse> for conversion functions.
 229
 230 =head1 METHODS
 231
 232 =over 4
 233
 234 =item new HASHREF
 235
 236 Create a new billing item.  To add the item to the database, see L<"insert">.
 237
 238 =cut
 239
 240 sub table { 'cust_pkg'; }
 241 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
 242 sub cust_unlinked_msg {
 243   my $self = shift;
 244   "WARNING: can't find cust_main.custnum ". $self->custnum.
 245   ' (cust_pkg.pkgnum '. $self->pkgnum. ')';
 246 }
 247
 248 =item set_initial_timers
 249
 250 If required by the package definition, sets any automatic expire, adjourn,
 251 or contract_end timers to some number of months after the start date
 252 (or setup date, if the package has already been setup). If the package has
 253 a delayed setup fee after a period of "free days", will also set the
 254 start date to the end of that period.
 255
 256 =cut
 257
 258 sub set_initial_timers {
 259   my $self = shift;
 260   my $part_pkg = $self->part_pkg;
 261   foreach my $action ( qw(expire adjourn contract_end) ) {
 262     my $months = $part_pkg->option("${action}_months",1);
 263     if($months and !$self->get($action)) {
 264       my $start = $self->start_date || $self->setup || time;
 265       $self->set($action, $part_pkg->add_freq($start, $months) );
 266     }
 267   }
 268
 269   # if this package has "free days" and delayed setup fee, then
 270   # set start date that many days in the future.
 271   # (this should have been set in the UI, but enforce it here)
 272   if ( $part_pkg->option('free_days',1)
 273        && $part_pkg->option('delay_setup',1)
 274      )
 275   {
 276     $self->start_date( $part_pkg->default_start_date );
 277   }
 278   '';
 279 }
 280
 281 =item insert [ OPTION => VALUE ... ]
 282
 283 Adds this billing item to the database ("Orders" the item).  If there is an
 284 error, returns the error, otherwise returns false.
 285
 286 If the additional field I<promo_code> is defined instead of I<pkgpart>, it
 287 will be used to look up the package definition and agent restrictions will be
 288 ignored.
 289
 290 If the additional field I<refnum> is defined, an FS::pkg_referral record will
 291 be created and inserted.  Multiple FS::pkg_referral records can be created by
 292 setting I<refnum> to an array reference of refnums or a hash reference with
 293 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
 294 record will be created corresponding to cust_main.refnum.
 295
 296 The following options are available:
 297
 298 =over 4
 299
 300 =item change
 301
 302 If set true, supresses actions that should only be taken for new package
 303 orders.  (Currently this includes: intro periods when delay_setup is on,
 304 auto-adding a 1st start date, auto-adding expiration/adjourn/contract_end dates)
 305
 306 =item options
 307
 308 cust_pkg_option records will be created
 309
 310 =item ticket_subject
 311
 312 a ticket will be added to this customer with this subject
 313
 314 =item ticket_queue
 315
 316 an optional queue name for ticket additions
 317
 318 =item allow_pkgpart
 319
 320 Don't check the legality of the package definition.  This should be used
 321 when performing a package change that doesn't change the pkgpart (i.e.
 322 a location change).
 323
 324 =back
 325
 326 =cut
 327
 328 sub insert {
 329   my( $self, %options ) = @_;
 330
 331   my $error;
 332   $error = $self->check_pkgpart unless $options{'allow_pkgpart'};
 333   return $error if $error;
 334
 335   my $part_pkg = $self->part_pkg;
 336
 337   if ( ! $options{'change'} ) {
 338
 339     # set order date to now
 340     $self->order_date(time);
 341
 342     # if the package def says to start only on the first of the month:
 343     if ( $part_pkg->option('start_1st', 1) && !$self->start_date ) {
 344       my ($sec,$min,$hour,$mday,$mon,$year) = (localtime(time) )[0,1,2,3,4,5];
 345       $mon += 1 unless $mday == 1;
 346       until ( $mon < 12 ) { $mon -= 12; $year++; }
 347       $self->start_date( timelocal_nocheck(0,0,0,1,$mon,$year) );
 348     }
 349
 350     if ($self->susp eq 'now' or $part_pkg->start_on_hold) {
 351       # if the package was ordered on hold:
 352       # - suspend it
 353       # - don't set the start date (it will be started manually)
 354       $self->set('susp', $self->order_date);
 355       $self->set('start_date', '');
 356     } else {
 357       # set expire/adjourn/contract_end timers, and free days, if appropriate
 358       $self->set_initial_timers;
 359     }
 360   } # else this is a package change, and shouldn't have "new package" behavior
 361
 362   local $SIG{HUP} = 'IGNORE';
 363   local $SIG{INT} = 'IGNORE';
 364   local $SIG{QUIT} = 'IGNORE';
 365   local $SIG{TERM} = 'IGNORE';
 366   local $SIG{TSTP} = 'IGNORE';
 367   local $SIG{PIPE} = 'IGNORE';
 368
 369   my $oldAutoCommit = $FS::UID::AutoCommit;
 370   local $FS::UID::AutoCommit = 0;
 371   my $dbh = dbh;
 372
 373   $error = $self->SUPER::insert($options{options} ? %{$options{options}} : ());
 374   if ( $error ) {
 375     $dbh->rollback if $oldAutoCommit;
 376     return $error;
 377   }
 378
 379   $self->refnum($self->cust_main->refnum) unless $self->refnum;
 380   $self->refnum( [ $self->refnum ] ) unless ref($self->refnum);
 381   $self->process_m2m( 'link_table'   => 'pkg_referral',
 382                       'target_table' => 'part_referral',
 383                       'params'       => $self->refnum,
 384                     );
 385
 386   if ( $self->discountnum ) {
 387     my $error = $self->insert_discount();
 388     if ( $error ) {
 389       $dbh->rollback if $oldAutoCommit;
 390       return $error;
 391     }
 392   }
 393
 394   my $conf = new FS::Conf;
 395
 396   if ( $conf->config('ticket_system') && $options{ticket_subject} ) {
 397
 398     #this init stuff is still inefficient, but at least its limited to
 399     # the small number (any?) folks using ticket emailing on pkg order
 400
 401     #eval '
 402     #  use lib ( "/opt/rt3/local/lib", "/opt/rt3/lib" );
 403     #  use RT;
 404     #';
 405     #die $@ if $@;
 406     #
 407     #RT::LoadConfig();
 408     #RT::Init();
 409     use FS::TicketSystem;
 410     FS::TicketSystem->init();
 411
 412     my $q = new RT::Queue($RT::SystemUser);
 413     $q->Load($options{ticket_queue}) if $options{ticket_queue};
 414     my $t = new RT::Ticket($RT::SystemUser);
 415     my $mime = new MIME::Entity;
 416     $mime->build( Type => 'text/plain', Data => $options{ticket_subject} );
 417     $t->Create( $options{ticket_queue} ? (Queue => $q) : (),
 418                 Subject => $options{ticket_subject},
 419                 MIMEObj => $mime,
 420               );
 421     $t->AddLink( Type   => 'MemberOf',
 422                  Target => 'freeside://freeside/cust_main/'. $self->custnum,
 423                );
 424   }
 425
 426   if ($conf->config('welcome_letter') && $self->cust_main->num_pkgs == 1) {
 427     my $queue = new FS::queue {
 428       'job'     => 'FS::cust_main::queueable_print',
 429     };
 430     $error = $queue->insert(
 431       'custnum'  => $self->custnum,
 432       'template' => 'welcome_letter',
 433     );
 434
 435     if ($error) {
 436       warn "can't send welcome letter: $error";
 437     }
 438
 439   }
 440
 441   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 442   '';
 443
 444 }
 445
 446 =item delete
 447
 448 This method now works but you probably shouldn't use it.
 449
 450 You don't want to delete packages, because there would then be no record
 451 the customer ever purchased the package.  Instead, see the cancel method and
 452 hide cancelled packages.
 453
 454 =cut
 455
 456 sub delete {
 457   my $self = shift;
 458
 459   local $SIG{HUP} = 'IGNORE';
 460   local $SIG{INT} = 'IGNORE';
 461   local $SIG{QUIT} = 'IGNORE';
 462   local $SIG{TERM} = 'IGNORE';
 463   local $SIG{TSTP} = 'IGNORE';
 464   local $SIG{PIPE} = 'IGNORE';
 465
 466   my $oldAutoCommit = $FS::UID::AutoCommit;
 467   local $FS::UID::AutoCommit = 0;
 468   my $dbh = dbh;
 469
 470   foreach my $cust_pkg_discount ($self->cust_pkg_discount) {
 471     my $error = $cust_pkg_discount->delete;
 472     if ( $error ) {
 473       $dbh->rollback if $oldAutoCommit;
 474       return $error;
 475     }
 476   }
 477   #cust_bill_pkg_discount?
 478
 479   foreach my $cust_pkg_detail ($self->cust_pkg_detail) {
 480     my $error = $cust_pkg_detail->delete;
 481     if ( $error ) {
 482       $dbh->rollback if $oldAutoCommit;
 483       return $error;
 484     }
 485   }
 486
 487   foreach my $cust_pkg_reason (
 488     qsearchs( {
 489                 'table' => 'cust_pkg_reason',
 490                 'hashref' => { 'pkgnum' => $self->pkgnum },
 491               }
 492             )
 493   ) {
 494     my $error = $cust_pkg_reason->delete;
 495     if ( $error ) {
 496       $dbh->rollback if $oldAutoCommit;
 497       return $error;
 498     }
 499   }
 500
 501   #pkg_referral?
 502
 503   my $error = $self->SUPER::delete(@_);
 504   if ( $error ) {
 505     $dbh->rollback if $oldAutoCommit;
 506     return $error;
 507   }
 508
 509   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 510
 511   '';
 512
 513 }
 514
 515 =item replace [ OLD_RECORD ] [ HASHREF | OPTION => VALUE ... ]
 516
 517 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 518 returns the error, otherwise returns false.
 519
 520 Currently, custnum, setup, bill, adjourn, susp, expire, and cancel may be changed.
 521
 522 Changing pkgpart may have disasterous effects.  See the order subroutine.
 523
 524 setup and bill are normally updated by calling the bill method of a customer
 525 object (see L<FS::cust_main>).
 526
 527 suspend is normally updated by the suspend and unsuspend methods.
 528
 529 cancel is normally updated by the cancel method (and also the order subroutine
 530 in some cases).
 531
 532 Available options are:
 533
 534 =over 4
 535
 536 =item reason
 537
 538 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
 539
 540 =item reason_otaker
 541
 542 the access_user (see L<FS::access_user>) providing the reason
 543
 544 =item options
 545
 546 hashref of keys and values - cust_pkg_option records will be created, updated or removed as appopriate
 547
 548 =back
 549
 550 =cut
 551
 552 sub replace {
 553   my $new = shift;
 554
 555   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 556               ? shift
 557               : $new->replace_old;
 558
 559   my $options =
 560     ( ref($_[0]) eq 'HASH' )
 561       ? shift
 562       : { @_ };
 563
 564   #return "Can't (yet?) change pkgpart!" if $old->pkgpart != $new->pkgpart;
 565   #return "Can't change otaker!" if $old->otaker ne $new->otaker;
 566
 567   #allow this *sigh*
 568   #return "Can't change setup once it exists!"
 569   #  if $old->getfield('setup') &&
 570   #     $old->getfield('setup') != $new->getfield('setup');
 571
 572   #some logic for bill, susp, cancel?
 573
 574   local($disable_agentcheck) = 1 if $old->pkgpart == $new->pkgpart;
 575
 576   local $SIG{HUP} = 'IGNORE';
 577   local $SIG{INT} = 'IGNORE';
 578   local $SIG{QUIT} = 'IGNORE';
 579   local $SIG{TERM} = 'IGNORE';
 580   local $SIG{TSTP} = 'IGNORE';
 581   local $SIG{PIPE} = 'IGNORE';
 582
 583   my $oldAutoCommit = $FS::UID::AutoCommit;
 584   local $FS::UID::AutoCommit = 0;
 585   my $dbh = dbh;
 586
 587   foreach my $method ( qw(adjourn expire) ) {  # How many reasons?
 588     if ($options->{'reason'} && $new->$method && $old->$method ne $new->$method) {
 589       my $error = $new->insert_reason(
 590         'reason'        => $options->{'reason'},
 591         'date'          => $new->$method,
 592         'action'        => $method,
 593         'reason_otaker' => $options->{'reason_otaker'},
 594       );
 595       if ( $error ) {
 596         dbh->rollback if $oldAutoCommit;
 597         return "Error inserting cust_pkg_reason: $error";
 598       }
 599     }
 600   }
 601
 602   #save off and freeze RADIUS attributes for any associated svc_acct records
 603   my @svc_acct = ();
 604   if ( $old->part_pkg->is_prepaid || $new->part_pkg->is_prepaid ) {
 605
 606                 #also check for specific exports?
 607                 # to avoid spurious modify export events
 608     @svc_acct = map  { $_->svc_x }
 609                 grep { $_->part_svc->svcdb eq 'svc_acct' }
 610                      $old->cust_svc;
 611
 612     $_->snapshot foreach @svc_acct;
 613
 614   }
 615
 616   my $error =  $new->export_pkg_change($old)
 617             || $new->SUPER::replace( $old,
 618                                      $options->{options}
 619                                        ? $options->{options}
 620                                        : ()
 621                                    );
 622   if ( $error ) {
 623     $dbh->rollback if $oldAutoCommit;
 624     return $error;
 625   }
 626
 627   #for prepaid packages,
 628   #trigger export of new RADIUS Expiration attribute when cust_pkg.bill changes
 629   foreach my $old_svc_acct ( @svc_acct ) {
 630     my $new_svc_acct = new FS::svc_acct { $old_svc_acct->hash };
 631     my $s_error =
 632       $new_svc_acct->replace( $old_svc_acct,
 633                               'depend_jobnum' => $options->{depend_jobnum},
 634                             );
 635     if ( $s_error ) {
 636       $dbh->rollback if $oldAutoCommit;
 637       return $s_error;
 638     }
 639   }
 640
 641   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 642   '';
 643
 644 }
 645
 646 =item check
 647
 648 Checks all fields to make sure this is a valid billing item.  If there is an
 649 error, returns the error, otherwise returns false.  Called by the insert and
 650 replace methods.
 651
 652 =cut
 653
 654 sub check {
 655   my $self = shift;
 656
 657   if ( !$self->locationnum or $self->locationnum == -1 ) {
 658     $self->set('locationnum', $self->cust_main->ship_locationnum);
 659   }
 660
 661   my $error =
 662     $self->ut_numbern('pkgnum')
 663     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 664     || $self->ut_numbern('pkgpart')
 665     || $self->ut_foreign_keyn('contactnum',  'contact',       'contactnum' )
 666     || $self->ut_foreign_keyn('locationnum', 'cust_location', 'locationnum')
 667     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
 668     || $self->ut_numbern('quantity')
 669     || $self->ut_numbern('start_date')
 670     || $self->ut_numbern('setup')
 671     || $self->ut_numbern('bill')
 672     || $self->ut_numbern('susp')
 673     || $self->ut_numbern('cancel')
 674     || $self->ut_numbern('adjourn')
 675     || $self->ut_numbern('resume')
 676     || $self->ut_numbern('expire')
 677     || $self->ut_numbern('dundate')
 678     || $self->ut_flag('no_auto', [ '', 'Y' ])
 679     || $self->ut_flag('waive_setup', [ '', 'Y' ])
 680     || $self->ut_flag('separate_bill')
 681     || $self->ut_textn('agent_pkgid')
 682     || $self->ut_enum('recur_show_zero', [ '', 'Y', 'N', ])
 683     || $self->ut_enum('setup_show_zero', [ '', 'Y', 'N', ])
 684     || $self->ut_foreign_keyn('main_pkgnum', 'cust_pkg', 'pkgnum')
 685     || $self->ut_foreign_keyn('pkglinknum', 'part_pkg_link', 'pkglinknum')
 686     || $self->ut_foreign_keyn('change_to_pkgnum', 'cust_pkg', 'pkgnum')
 687   ;
 688   return $error if $error;
 689
 690   return "A package with both start date (future start) and setup date (already started) will never bill"
 691     if $self->start_date && $self->setup && ! $upgrade;
 692
 693   return "A future unsuspend date can only be set for a package with a suspend date"
 694     if $self->resume and !$self->susp and !$self->adjourn;
 695
 696   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 697
 698   if ( $self->dbdef_table->column('manual_flag') ) {
 699     $self->manual_flag('') if $self->manual_flag eq ' ';
 700     $self->manual_flag =~ /^([01]?)$/
 701       or return "Illegal manual_flag ". $self->manual_flag;
 702     $self->manual_flag($1);
 703   }
 704
 705   $self->SUPER::check;
 706 }
 707
 708 =item check_pkgpart
 709
 710 Check the pkgpart to make sure it's allowed with the reg_code and/or
 711 promo_code of the package (if present) and with the customer's agent.
 712 Called from C<insert>, unless we are doing a package change that doesn't
 713 affect pkgpart.
 714
 715 =cut
 716
 717 sub check_pkgpart {
 718   my $self = shift;
 719
 720   # my $error = $self->ut_numbern('pkgpart'); # already done
 721
 722   my $error;
 723   if ( $self->reg_code ) {
 724
 725     unless ( grep { $self->pkgpart == $_->pkgpart }
 726              map  { $_->reg_code_pkg }
 727              qsearchs( 'reg_code', { 'code'     => $self->reg_code,
 728                                      'agentnum' => $self->cust_main->agentnum })
 729            ) {
 730       return "Unknown registration code";
 731     }
 732
 733   } elsif ( $self->promo_code ) {
 734
 735     my $promo_part_pkg =
 736       qsearchs('part_pkg', {
 737         'pkgpart'    => $self->pkgpart,
 738         'promo_code' => { op=>'ILIKE', value=>$self->promo_code },
 739       } );
 740     return 'Unknown promotional code' unless $promo_part_pkg;
 741
 742   } else {
 743
 744     unless ( $disable_agentcheck ) {
 745       my $agent =
 746         qsearchs( 'agent', { 'agentnum' => $self->cust_main->agentnum } );
 747       return "agent ". $agent->agentnum. ':'. $agent->agent.
 748              " can't purchase pkgpart ". $self->pkgpart
 749         unless $agent->pkgpart_hashref->{ $self->pkgpart }
 750             || $agent->agentnum == $self->part_pkg->agentnum;
 751     }
 752
 753     $error = $self->ut_foreign_key('pkgpart', 'part_pkg', 'pkgpart' );
 754     return $error if $error;
 755
 756   }
 757
 758   '';
 759
 760 }
 761
 762 =item cancel [ OPTION => VALUE ... ]
 763
 764 Cancels and removes all services (see L<FS::cust_svc> and L<FS::part_svc>)
 765 in this package, then cancels the package itself (sets the cancel field to
 766 now).
 767
 768 Available options are:
 769
 770 =over 4
 771
 772 =item quiet - can be set true to supress email cancellation notices.
 773
 774 =item time -  can be set to cancel the package based on a specific future or
 775 historical date.  Using time ensures that the remaining amount is calculated
 776 correctly.  Note however that this is an immediate cancel and just changes
 777 the date.  You are PROBABLY looking to expire the account instead of using
 778 this.
 779
 780 =item reason - can be set to a cancellation reason (see L<FS:reason>),
 781 either a reasonnum of an existing reason, or passing a hashref will create
 782 a new reason.  The hashref should have the following keys: typenum - Reason
 783 type (see L<FS::reason_type>, reason - Text of the new reason.
 784
 785 =item date - can be set to a unix style timestamp to specify when to
 786 cancel (expire)
 787
 788 =item nobill - can be set true to skip billing if it might otherwise be done.
 789
 790 =item unused_credit - can be set to 1 to credit the remaining time, or 0 to
 791 not credit it.  This must be set (by change()) when changing the package
 792 to a different pkgpart or location, and probably shouldn't be in any other
 793 case.  If it's not set, the 'unused_credit_cancel' part_pkg option will
 794 be used.
 795
 796 =item no_delay_cancel - prevents delay_cancel behavior
 797 no matter what other options say, for use when changing packages (or any
 798 other time you're really sure you want an immediate cancel)
 799
 800 =back
 801
 802 If there is an error, returns the error, otherwise returns false.
 803
 804 =cut
 805
 806 #NOT DOCUMENTING - this should only be used when calling recursively
 807 #=item delay_cancel - for internal use, to allow proper handling of
 808 #supplemental packages when the main package is flagged to suspend
 809 #before cancelling, probably shouldn't be used otherwise (set the
 810 #corresponding package option instead)
 811
 812 sub cancel {
 813   my( $self, %options ) = @_;
 814   my $error;
 815
 816   # pass all suspend/cancel actions to the main package
 817   # (unless the pkglinknum has been removed, then the link is defunct and
 818   # this package can be canceled on its own)
 819   if ( $self->main_pkgnum and $self->pkglinknum and !$options{'from_main'} ) {
 820     return $self->main_pkg->cancel(%options);
 821   }
 822
 823   my $conf = new FS::Conf;
 824
 825   warn "cust_pkg::cancel called with options".
 826        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 827     if $DEBUG;
 828
 829   local $SIG{HUP} = 'IGNORE';
 830   local $SIG{INT} = 'IGNORE';
 831   local $SIG{QUIT} = 'IGNORE';
 832   local $SIG{TERM} = 'IGNORE';
 833   local $SIG{TSTP} = 'IGNORE';
 834   local $SIG{PIPE} = 'IGNORE';
 835
 836   my $oldAutoCommit = $FS::UID::AutoCommit;
 837   local $FS::UID::AutoCommit = 0;
 838   my $dbh = dbh;
 839
 840   my $old = $self->select_for_update;
 841
 842   if ( $old->get('cancel') || $self->get('cancel') ) {
 843     dbh->rollback if $oldAutoCommit;
 844     return "";  # no error
 845   }
 846
 847   # XXX possibly set cancel_time to the expire date?
 848   my $cancel_time = $options{'time'} || time;
 849   my $date = $options{'date'} if $options{'date'}; # expire/cancel later
 850   $date = '' if ($date && $date <= $cancel_time);      # complain instead?
 851
 852   my $delay_cancel = $options{'no_delay_cancel'} ? 0 : $options{'delay_cancel'};
 853   if ( !$date && $self->part_pkg->option('delay_cancel',1)
 854        && (($self->status eq 'active') || ($self->status eq 'suspended'))
 855        && !$options{'no_delay_cancel'}
 856   ) {
 857     my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
 858     my $expsecs = 60*60*24*$expdays;
 859     my $suspfor = $self->susp ? $cancel_time - $self->susp : 0;
 860     $expsecs = $expsecs - $suspfor if $suspfor;
 861     unless ($expsecs <= 0) { #if it's already been suspended long enough, don't re-suspend
 862       $delay_cancel = 1;
 863       $date = $cancel_time + $expsecs;
 864     }
 865   }
 866
 867   #race condition: usage could be ongoing until unprovisioned
 868   #resolved by performing a change package instead (which unprovisions) and
 869   #later cancelling
 870   if ( !$options{nobill} && !$date ) {
 871     # && $conf->exists('bill_usage_on_cancel') ) { #calc_cancel checks this
 872       my $copy = $self->new({$self->hash});
 873       my $error =
 874         $copy->cust_main->bill( 'pkg_list' => [ $copy ],
 875                                 'cancel'   => 1,
 876                                 'time'     => $cancel_time );
 877       warn "Error billing during cancel, custnum ".
 878         #$self->cust_main->custnum. ": $error"
 879         ": $error"
 880         if $error;
 881   }
 882
 883   if ( $options{'reason'} ) {
 884     $error = $self->insert_reason( 'reason' => $options{'reason'},
 885                                    'action' => $date ? 'expire' : 'cancel',
 886                                    'date'   => $date ? $date : $cancel_time,
 887                                    'reason_otaker' => $options{'reason_otaker'},
 888                                  );
 889     if ( $error ) {
 890       dbh->rollback if $oldAutoCommit;
 891       return "Error inserting cust_pkg_reason: $error";
 892     }
 893   }
 894
 895   my %svc_cancel_opt = ();
 896   $svc_cancel_opt{'date'} = $date if $date;
 897   foreach my $cust_svc (
 898     #schwartz
 899     map  { $_->[0] }
 900     sort { $a->[1] <=> $b->[1] }
 901     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; }
 902     qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
 903   ) {
 904     my $part_svc = $cust_svc->part_svc;
 905     next if ( defined($part_svc) and $part_svc->preserve );
 906     my $error = $cust_svc->cancel( %svc_cancel_opt );
 907
 908     if ( $error ) {
 909       $dbh->rollback if $oldAutoCommit;
 910       return 'Error '. ($svc_cancel_opt{'date'} ? 'expiring' : 'canceling' ).
 911              " cust_svc: $error";
 912     }
 913   }
 914
 915   unless ($date) {
 916     # credit remaining time if appropriate
 917     my $do_credit;
 918     if ( exists($options{'unused_credit'}) ) {
 919       $do_credit = $options{'unused_credit'};
 920     }
 921     else {
 922       $do_credit = $self->part_pkg->option('unused_credit_cancel', 1);
 923     }
 924     if ( $do_credit ) {
 925       my $error = $self->credit_remaining('cancel', $cancel_time);
 926       if ($error) {
 927         $dbh->rollback if $oldAutoCommit;
 928         return $error;
 929       }
 930     }
 931   } #unless $date
 932
 933   my %hash = $self->hash;
 934   if ( $date ) {
 935     $hash{'expire'} = $date;
 936     if ($delay_cancel) {
 937       # just to be sure these are clear
 938       $hash{'adjourn'} = undef;
 939       $hash{'resume'} = undef;
 940     }
 941   } else {
 942     $hash{'cancel'} = $cancel_time;
 943   }
 944   $hash{'change_custnum'} = $options{'change_custnum'};
 945
 946   # if this is a supplemental package that's lost its part_pkg_link, and it's
 947   # being canceled for real, unlink it completely
 948   if ( !$date and ! $self->pkglinknum ) {
 949     $hash{main_pkgnum} = '';
 950   }
 951
 952   my $new = new FS::cust_pkg ( \%hash );
 953   $error = $new->replace( $self, options => { $self->options } );
 954   if ( $self->change_to_pkgnum ) {
 955     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
 956     $error ||= $change_to->cancel('no_delay_cancel' => 1) || $change_to->delete;
 957   }
 958   if ( $error ) {
 959     $dbh->rollback if $oldAutoCommit;
 960     return $error;
 961   }
 962
 963   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
 964     $error = $supp_pkg->cancel(%options,
 965       'from_main' => 1,
 966       'date' => $date, #in case it got changed by delay_cancel
 967       'delay_cancel' => $delay_cancel,
 968     );
 969     if ( $error ) {
 970       $dbh->rollback if $oldAutoCommit;
 971       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
 972     }
 973   }
 974
 975   if ($delay_cancel && !$options{'from_main'}) {
 976     $error = $new->suspend(
 977       'from_cancel' => 1,
 978       'time'        => $cancel_time
 979     );
 980   }
 981
 982   unless ($date) {
 983     foreach my $usage ( $self->cust_pkg_usage ) {
 984       $error = $usage->delete;
 985       if ( $error ) {
 986         $dbh->rollback if $oldAutoCommit;
 987         return "deleting usage pools: $error";
 988       }
 989     }
 990   }
 991
 992   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 993   return '' if $date; #no errors
 994
 995   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ } $self->cust_main->invoicing_list;
 996   if ( !$options{'quiet'} &&
 997         $conf->exists('emailcancel', $self->cust_main->agentnum) &&
 998         @invoicing_list ) {
 999     my $msgnum = $conf->config('cancel_msgnum', $self->cust_main->agentnum);
1000     my $error = '';
1001     if ( $msgnum ) {
1002       my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
1003       $error = $msg_template->send( 'cust_main' => $self->cust_main,
1004                                     'object'    => $self );
1005     }
1006     else {
1007       $error = send_email(
1008         'from'    => $conf->invoice_from_full( $self->cust_main->agentnum ),
1009         'to'      => \@invoicing_list,
1010         'subject' => ( $conf->config('cancelsubject') || 'Cancellation Notice' ),
1011         'body'    => [ map "$_\n", $conf->config('cancelmessage') ],
1012         'custnum' => $self->custnum,
1013         'msgtype' => '', #admin?
1014       );
1015     }
1016     #should this do something on errors?
1017   }
1018
1019   ''; #no errors
1020
1021 }
1022
1023 =item cancel_if_expired [ NOW_TIMESTAMP ]
1024
1025 Cancels this package if its expire date has been reached.
1026
1027 =cut
1028
1029 sub cancel_if_expired {
1030   my $self = shift;
1031   my $time = shift || time;
1032   return '' unless $self->expire && $self->expire <= $time;
1033   my $error = $self->cancel;
1034   if ( $error ) {
1035     return "Error cancelling expired pkg ". $self->pkgnum. " for custnum ".
1036            $self->custnum. ": $error";
1037   }
1038   '';
1039 }
1040
1041 =item uncancel
1042
1043 "Un-cancels" this package: Orders a new package with the same custnum, pkgpart,
1044 locationnum, (other fields?).  Attempts to re-provision cancelled services
1045 using history information (errors at this stage are not fatal).
1046
1047 cust_pkg: pass a scalar reference, will be filled in with the new cust_pkg object
1048
1049 svc_fatal: service provisioning errors are fatal
1050
1051 svc_errors: pass an array reference, will be filled in with any provisioning errors
1052
1053 main_pkgnum: link the package as a supplemental package of this one.  For
1054 internal use only.
1055
1056 =cut
1057
1058 sub uncancel {
1059   my( $self, %options ) = @_;
1060
1061   #in case you try do do $uncancel-date = $cust_pkg->uncacel
1062   return '' unless $self->get('cancel');
1063
1064   if ( $self->main_pkgnum and !$options{'main_pkgnum'} ) {
1065     return $self->main_pkg->uncancel(%options);
1066   }
1067
1068   ##
1069   # Transaction-alize
1070   ##
1071
1072   local $SIG{HUP} = 'IGNORE';
1073   local $SIG{INT} = 'IGNORE';
1074   local $SIG{QUIT} = 'IGNORE';
1075   local $SIG{TERM} = 'IGNORE';
1076   local $SIG{TSTP} = 'IGNORE';
1077   local $SIG{PIPE} = 'IGNORE';
1078
1079   my $oldAutoCommit = $FS::UID::AutoCommit;
1080   local $FS::UID::AutoCommit = 0;
1081   my $dbh = dbh;
1082
1083   ##
1084   # insert the new package
1085   ##
1086
1087   my $cust_pkg = new FS::cust_pkg {
1088     last_bill       => ( $options{'last_bill'} || $self->get('last_bill') ),
1089     bill            => ( $options{'bill'}      || $self->get('bill')      ),
1090     uncancel        => time,
1091     uncancel_pkgnum => $self->pkgnum,
1092     main_pkgnum     => ($options{'main_pkgnum'} || ''),
1093     map { $_ => $self->get($_) } qw(
1094       custnum pkgpart locationnum
1095       setup
1096       susp adjourn resume expire start_date contract_end dundate
1097       change_date change_pkgpart change_locationnum
1098       manual_flag no_auto separate_bill quantity agent_pkgid
1099       recur_show_zero setup_show_zero
1100     ),
1101   };
1102
1103   my $error = $cust_pkg->insert(
1104     'change' => 1, #supresses any referral credit to a referring customer
1105     'allow_pkgpart' => 1, # allow this even if the package def is disabled
1106   );
1107   if ($error) {
1108     $dbh->rollback if $oldAutoCommit;
1109     return $error;
1110   }
1111
1112   ##
1113   # insert services
1114   ##
1115
1116   #find historical services within this timeframe before the package cancel
1117   # (incompatible with "time" option to cust_pkg->cancel?)
1118   my $fuzz = 2 * 60; #2 minutes?  too much?   (might catch separate unprovision)
1119                      #            too little? (unprovisioing export delay?)
1120   my($end, $start) = ( $self->get('cancel'), $self->get('cancel') - $fuzz );
1121   my @h_cust_svc = $self->h_cust_svc( $end, $start );
1122
1123   my @svc_errors;
1124   foreach my $h_cust_svc (@h_cust_svc) {
1125     my $h_svc_x = $h_cust_svc->h_svc_x( $end, $start );
1126     #next unless $h_svc_x; #should this happen?
1127     (my $table = $h_svc_x->table) =~ s/^h_//;
1128     require "FS/$table.pm";
1129     my $class = "FS::$table";
1130     my $svc_x = $class->new( {
1131       'pkgnum'  => $cust_pkg->pkgnum,
1132       'svcpart' => $h_cust_svc->svcpart,
1133       map { $_ => $h_svc_x->get($_) } fields($table)
1134     } );
1135
1136     # radius_usergroup
1137     if ( $h_svc_x->isa('FS::h_svc_Radius_Mixin') ) {
1138       $svc_x->usergroup( [ $h_svc_x->h_usergroup($end, $start) ] );
1139     }
1140
1141     my $svc_error = $svc_x->insert;
1142     if ( $svc_error ) {
1143       if ( $options{svc_fatal} ) {
1144         $dbh->rollback if $oldAutoCommit;
1145         return $svc_error;
1146       } else {
1147         # if we've failed to insert the svc_x object, svc_Common->insert
1148         # will have removed the cust_svc already.  if not, then both records
1149         # were inserted but we failed for some other reason (export, most
1150         # likely).  in that case, report the error and delete the records.
1151         push @svc_errors, $svc_error;
1152         my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $svc_x->svcnum });
1153         if ( $cust_svc ) {
1154           # except if export_insert failed, export_delete probably won't be
1155           # much better
1156           local $FS::svc_Common::noexport_hack = 1;
1157           my $cleanup_error = $svc_x->delete; # also deletes cust_svc
1158           if ( $cleanup_error ) { # and if THAT fails, then run away
1159             $dbh->rollback if $oldAutoCommit;
1160             return $cleanup_error;
1161           }
1162         }
1163       } # svc_fatal
1164     } # svc_error
1165   } #foreach $h_cust_svc
1166
1167   #these are pretty rare, but should handle them
1168   # - dsl_device (mac addresses)
1169   # - phone_device (mac addresses)
1170   # - dsl_note (ikano notes)
1171   # - domain_record (i.e. restore DNS information w/domains)
1172   # - inventory_item(?) (inventory w/un-cancelling service?)
1173   # - nas (svc_broaband nas stuff)
1174   #this stuff is unused in the wild afaik
1175   # - mailinglistmember
1176   # - router.svcnum?
1177   # - svc_domain.parent_svcnum?
1178   # - acct_snarf (ancient mail fetching config)
1179   # - cgp_rule (communigate)
1180   # - cust_svc_option (used by our Tron stuff)
1181   # - acct_rt_transaction (used by our time worked stuff)
1182
1183   ##
1184   # also move over any services that didn't unprovision at cancellation
1185   ##
1186
1187   foreach my $cust_svc ( qsearch('cust_svc', { pkgnum => $self->pkgnum } ) ) {
1188     $cust_svc->pkgnum( $cust_pkg->pkgnum );
1189     my $error = $cust_svc->replace;
1190     if ( $error ) {
1191       $dbh->rollback if $oldAutoCommit;
1192       return $error;
1193     }
1194   }
1195
1196   ##
1197   # Uncancel any supplemental packages, and make them supplemental to the
1198   # new one.
1199   ##
1200
1201   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1202     my $new_pkg;
1203     $error = $supp_pkg->uncancel(%options, 'main_pkgnum' => $cust_pkg->pkgnum);
1204     if ( $error ) {
1205       $dbh->rollback if $oldAutoCommit;
1206       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1207     }
1208   }
1209
1210   ##
1211   # Finish
1212   ##
1213
1214   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1215
1216   ${ $options{cust_pkg} }   = $cust_pkg   if ref($options{cust_pkg});
1217   @{ $options{svc_errors} } = @svc_errors if ref($options{svc_errors});
1218
1219   '';
1220 }
1221
1222 =item unexpire
1223
1224 Cancels any pending expiration (sets the expire field to null).
1225
1226 If there is an error, returns the error, otherwise returns false.
1227
1228 =cut
1229
1230 sub unexpire {
1231   my( $self, %options ) = @_;
1232   my $error;
1233
1234   local $SIG{HUP} = 'IGNORE';
1235   local $SIG{INT} = 'IGNORE';
1236   local $SIG{QUIT} = 'IGNORE';
1237   local $SIG{TERM} = 'IGNORE';
1238   local $SIG{TSTP} = 'IGNORE';
1239   local $SIG{PIPE} = 'IGNORE';
1240
1241   my $oldAutoCommit = $FS::UID::AutoCommit;
1242   local $FS::UID::AutoCommit = 0;
1243   my $dbh = dbh;
1244
1245   my $old = $self->select_for_update;
1246
1247   my $pkgnum = $old->pkgnum;
1248   if ( $old->get('cancel') || $self->get('cancel') ) {
1249     dbh->rollback if $oldAutoCommit;
1250     return "Can't unexpire cancelled package $pkgnum";
1251     # or at least it's pointless
1252   }
1253
1254   unless ( $old->get('expire') && $self->get('expire') ) {
1255     dbh->rollback if $oldAutoCommit;
1256     return "";  # no error
1257   }
1258
1259   my %hash = $self->hash;
1260   $hash{'expire'} = '';
1261   my $new = new FS::cust_pkg ( \%hash );
1262   $error = $new->replace( $self, options => { $self->options } );
1263   if ( $error ) {
1264     $dbh->rollback if $oldAutoCommit;
1265     return $error;
1266   }
1267
1268   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1269
1270   ''; #no errors
1271
1272 }
1273
1274 =item suspend [ OPTION => VALUE ... ]
1275
1276 Suspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1277 package, then suspends the package itself (sets the susp field to now).
1278
1279 Available options are:
1280
1281 =over 4
1282
1283 =item reason - can be set to a cancellation reason (see L<FS:reason>),
1284 either a reasonnum of an existing reason, or passing a hashref will create
1285 a new reason.  The hashref should have the following keys:
1286 - typenum - Reason type (see L<FS::reason_type>
1287 - reason - Text of the new reason.
1288
1289 =item date - can be set to a unix style timestamp to specify when to
1290 suspend (adjourn)
1291
1292 =item time - can be set to override the current time, for calculation
1293 of final invoices or unused-time credits
1294
1295 =item resume_date - can be set to a time when the package should be
1296 unsuspended.  This may be more convenient than calling C<unsuspend()>
1297 separately.
1298
1299 =item from_main - allows a supplemental package to be suspended, rather
1300 than redirecting the method call to its main package.  For internal use.
1301
1302 =item from_cancel - used when suspending from the cancel method, forces
1303 this to skip everything besides basic suspension.  For internal use.
1304
1305 =back
1306
1307 If there is an error, returns the error, otherwise returns false.
1308
1309 =cut
1310
1311 sub suspend {
1312   my( $self, %options ) = @_;
1313   my $error;
1314
1315   # pass all suspend/cancel actions to the main package
1316   if ( $self->main_pkgnum and !$options{'from_main'} ) {
1317     return $self->main_pkg->suspend(%options);
1318   }
1319
1320   local $SIG{HUP} = 'IGNORE';
1321   local $SIG{INT} = 'IGNORE';
1322   local $SIG{QUIT} = 'IGNORE';
1323   local $SIG{TERM} = 'IGNORE';
1324   local $SIG{TSTP} = 'IGNORE';
1325   local $SIG{PIPE} = 'IGNORE';
1326
1327   my $oldAutoCommit = $FS::UID::AutoCommit;
1328   local $FS::UID::AutoCommit = 0;
1329   my $dbh = dbh;
1330
1331   my $old = $self->select_for_update;
1332
1333   my $pkgnum = $old->pkgnum;
1334   if ( $old->get('cancel') || $self->get('cancel') ) {
1335     dbh->rollback if $oldAutoCommit;
1336     return "Can't suspend cancelled package $pkgnum";
1337   }
1338
1339   if ( $old->get('susp') || $self->get('susp') ) {
1340     dbh->rollback if $oldAutoCommit;
1341     return "";  # no error                     # complain on adjourn?
1342   }
1343
1344   my $suspend_time = $options{'time'} || time;
1345   my $date = $options{date} if $options{date}; # adjourn/suspend later
1346   $date = '' if ($date && $date <= $suspend_time); # complain instead?
1347
1348   if ( $date && $old->get('expire') && $old->get('expire') < $date ) {
1349     dbh->rollback if $oldAutoCommit;
1350     return "Package $pkgnum expires before it would be suspended.";
1351   }
1352
1353   # some false laziness with sub cancel
1354   if ( !$options{nobill} && !$date && !$options{'from_cancel'} &&
1355        $self->part_pkg->option('bill_suspend_as_cancel',1) ) {
1356     # kind of a kludge--'bill_suspend_as_cancel' to avoid having to
1357     # make the entire cust_main->bill path recognize 'suspend' and
1358     # 'cancel' separately.
1359     warn "Billing $pkgnum on suspension (at $suspend_time)\n" if $DEBUG;
1360     my $copy = $self->new({$self->hash});
1361     my $error =
1362       $copy->cust_main->bill( 'pkg_list' => [ $copy ],
1363                               'cancel'   => 1,
1364                               'time'     => $suspend_time );
1365     warn "Error billing during suspend, custnum ".
1366       #$self->cust_main->custnum. ": $error"
1367       ": $error"
1368       if $error;
1369   }
1370
1371   if ( $options{'reason'} ) {
1372     $error = $self->insert_reason( 'reason' => $options{'reason'},
1373                                    'action' => $date ? 'adjourn' : 'suspend',
1374                                    'date'   => $date ? $date : $suspend_time,
1375                                    'reason_otaker' => $options{'reason_otaker'},
1376                                  );
1377     if ( $error ) {
1378       dbh->rollback if $oldAutoCommit;
1379       return "Error inserting cust_pkg_reason: $error";
1380     }
1381   }
1382
1383   # if a reasonnum was passed, get the actual reason object so we can check
1384   # unused_credit
1385   # (passing a reason hashref is still allowed, but it can't be used with
1386   # the fancy behavioral options.)
1387
1388   my $reason;
1389   if ($options{'reason'} =~ /^\d+$/) {
1390     $reason = FS::reason->by_key($options{'reason'});
1391   }
1392
1393   my %hash = $self->hash;
1394   if ( $date ) {
1395     $hash{'adjourn'} = $date;
1396   } else {
1397     $hash{'susp'} = $suspend_time;
1398   }
1399
1400   my $resume_date = $options{'resume_date'} || 0;
1401   if ( $resume_date > ($date || $suspend_time) ) {
1402     $hash{'resume'} = $resume_date;
1403   }
1404
1405   $options{options} ||= {};
1406
1407   my $new = new FS::cust_pkg ( \%hash );
1408   $error = $new->replace( $self, options => { $self->options,
1409                                               %{ $options{options} },
1410                                             }
1411                         );
1412   if ( $error ) {
1413     $dbh->rollback if $oldAutoCommit;
1414     return $error;
1415   }
1416
1417   unless ( $date ) { # then we are suspending now
1418
1419     unless ($options{'from_cancel'}) {
1420       # credit remaining time if appropriate
1421       # (if required by the package def, or the suspend reason)
1422       my $unused_credit = $self->part_pkg->option('unused_credit_suspend',1)
1423                           || ( defined($reason) && $reason->unused_credit );
1424
1425       if ( $unused_credit ) {
1426         warn "crediting unused time on pkg#".$self->pkgnum."\n" if $DEBUG;
1427         my $error = $self->credit_remaining('suspend', $suspend_time);
1428         if ($error) {
1429           $dbh->rollback if $oldAutoCommit;
1430           return $error;
1431         }
1432       }
1433     }
1434
1435     my @labels = ();
1436
1437     foreach my $cust_svc (
1438       qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
1439     ) {
1440       my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1441
1442       $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1443         $dbh->rollback if $oldAutoCommit;
1444         return "Illegal svcdb value in part_svc!";
1445       };
1446       my $svcdb = $1;
1447       require "FS/$svcdb.pm";
1448
1449       my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1450       if ($svc) {
1451         $error = $svc->suspend;
1452         if ( $error ) {
1453           $dbh->rollback if $oldAutoCommit;
1454           return $error;
1455         }
1456         my( $label, $value ) = $cust_svc->label;
1457         push @labels, "$label: $value";
1458       }
1459     }
1460
1461     my $conf = new FS::Conf;
1462     if ( $conf->config('suspend_email_admin') && !$options{'from_cancel'} ) {
1463
1464       my $error = send_email(
1465         'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1466                                    #invoice_from ??? well as good as any
1467         'to'      => $conf->config('suspend_email_admin'),
1468         'subject' => 'FREESIDE NOTIFICATION: Customer package suspended',
1469         'body'    => [
1470           "This is an automatic message from your Freeside installation\n",
1471           "informing you that the following customer package has been suspended:\n",
1472           "\n",
1473           'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1474           'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1475           ( map { "Service : $_\n" } @labels ),
1476         ],
1477         'custnum' => $self->custnum,
1478         'msgtype' => 'admin'
1479       );
1480
1481       if ( $error ) {
1482         warn "WARNING: can't send suspension admin email (suspending anyway): ".
1483              "$error\n";
1484       }
1485
1486     }
1487
1488   }
1489
1490   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1491     $error = $supp_pkg->suspend(%options, 'from_main' => 1);
1492     if ( $error ) {
1493       $dbh->rollback if $oldAutoCommit;
1494       return "suspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1495     }
1496   }
1497
1498   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1499
1500   ''; #no errors
1501 }
1502
1503 =item credit_remaining MODE TIME
1504
1505 Generate a credit for this package for the time remaining in the current
1506 billing period.  MODE is either "suspend" or "cancel" (determines the
1507 credit type).  TIME is the time of suspension/cancellation.  Both arguments
1508 are mandatory.
1509
1510 =cut
1511
1512 # Implementation note:
1513 #
1514 # If you pkgpart-change a package that has been billed, and it's set to give
1515 # credit on package change, then this method gets called and then the new
1516 # package will have no last_bill date. Therefore the customer will be credited
1517 # only once (per billing period) even if there are multiple package changes.
1518 #
1519 # If you location-change a package that has been billed, this method will NOT
1520 # be called and the new package WILL have the last bill date of the old
1521 # package.
1522 #
1523 # If the new package is then canceled within the same billing cycle,
1524 # credit_remaining needs to run calc_remain on the OLD package to determine
1525 # the amount of unused time to credit.
1526
1527 sub credit_remaining {
1528   # Add a credit for remaining service
1529   my ($self, $mode, $time) = @_;
1530   die 'credit_remaining requires suspend or cancel'
1531     unless $mode eq 'suspend' or $mode eq 'cancel';
1532   die 'no suspend/cancel time' unless $time > 0;
1533
1534   my $conf = FS::Conf->new;
1535   my $reason_type = $conf->config($mode.'_credit_type');
1536
1537   my $last_bill = $self->getfield('last_bill') || 0;
1538   my $next_bill = $self->getfield('bill') || 0;
1539   if ( $last_bill > 0         # the package has been billed
1540       and $next_bill > 0      # the package has a next bill date
1541       and $next_bill >= $time # which is in the future
1542   ) {
1543     my $remaining_value = 0;
1544
1545     my $remain_pkg = $self;
1546     $remaining_value = $remain_pkg->calc_remain('time' => $time);
1547
1548     # we may have to walk back past some package changes to get to the
1549     # one that actually has unused time
1550     while ( $remaining_value == 0 ) {
1551       if ( $remain_pkg->change_pkgnum ) {
1552         $remain_pkg = FS::cust_pkg->by_key($remain_pkg->change_pkgnum);
1553       } else {
1554         # the package has really never been billed
1555         return;
1556       }
1557       $remaining_value = $remain_pkg->calc_remain('time' => $time);
1558     }
1559
1560     if ( $remaining_value > 0 ) {
1561       warn "Crediting for $remaining_value on package ".$self->pkgnum."\n"
1562         if $DEBUG;
1563       my $error = $self->cust_main->credit(
1564         $remaining_value,
1565         'Credit for unused time on '. $self->part_pkg->pkg,
1566         'reason_type' => $reason_type,
1567       );
1568       return "Error crediting customer \$$remaining_value for unused time".
1569         " on ". $self->part_pkg->pkg. ": $error"
1570         if $error;
1571     } #if $remaining_value
1572   } #if $last_bill, etc.
1573   '';
1574 }
1575
1576 =item unsuspend [ OPTION => VALUE ... ]
1577
1578 Unsuspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1579 package, then unsuspends the package itself (clears the susp field and the
1580 adjourn field if it is in the past).  If the suspend reason includes an
1581 unsuspension package, that package will be ordered.
1582
1583 Available options are:
1584
1585 =over 4
1586
1587 =item date
1588
1589 Can be set to a date to unsuspend the package in the future (the 'resume'
1590 field).
1591
1592 =item adjust_next_bill
1593
1594 Can be set true to adjust the next bill date forward by
1595 the amount of time the account was inactive.  This was set true by default
1596 in the past (from 1.4.2 and 1.5.0pre6 through 1.7.0), but now needs to be
1597 explicitly requested with this option or in the price plan.
1598
1599 =back
1600
1601 If there is an error, returns the error, otherwise returns false.
1602
1603 =cut
1604
1605 sub unsuspend {
1606   my( $self, %opt ) = @_;
1607   my $error;
1608
1609   # pass all suspend/cancel actions to the main package
1610   if ( $self->main_pkgnum and !$opt{'from_main'} ) {
1611     return $self->main_pkg->unsuspend(%opt);
1612   }
1613
1614   local $SIG{HUP} = 'IGNORE';
1615   local $SIG{INT} = 'IGNORE';
1616   local $SIG{QUIT} = 'IGNORE';
1617   local $SIG{TERM} = 'IGNORE';
1618   local $SIG{TSTP} = 'IGNORE';
1619   local $SIG{PIPE} = 'IGNORE';
1620
1621   my $oldAutoCommit = $FS::UID::AutoCommit;
1622   local $FS::UID::AutoCommit = 0;
1623   my $dbh = dbh;
1624
1625   my $old = $self->select_for_update;
1626
1627   my $pkgnum = $old->pkgnum;
1628   if ( $old->get('cancel') || $self->get('cancel') ) {
1629     $dbh->rollback if $oldAutoCommit;
1630     return "Can't unsuspend cancelled package $pkgnum";
1631   }
1632
1633   unless ( $old->get('susp') && $self->get('susp') ) {
1634     $dbh->rollback if $oldAutoCommit;
1635     return "";  # no error                     # complain instead?
1636   }
1637
1638   # handle the case of setting a future unsuspend (resume) date
1639   # and do not continue to actually unsuspend the package
1640   my $date = $opt{'date'};
1641   if ( $date and $date > time ) { # return an error if $date <= time?
1642
1643     if ( $old->get('expire') && $old->get('expire') < $date ) {
1644       $dbh->rollback if $oldAutoCommit;
1645       return "Package $pkgnum expires before it would be unsuspended.";
1646     }
1647
1648     my $new = new FS::cust_pkg { $self->hash };
1649     $new->set('resume', $date);
1650     $error = $new->replace($self, options => $self->options);
1651
1652     if ( $error ) {
1653       $dbh->rollback if $oldAutoCommit;
1654       return $error;
1655     }
1656     else {
1657       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1658       return '';
1659     }
1660
1661   } #if $date
1662
1663   if (!$self->setup) {
1664     # then this package is being released from on-hold status
1665     $self->set_initial_timers;
1666   }
1667
1668   my @labels = ();
1669
1670   foreach my $cust_svc (
1671     qsearch('cust_svc',{'pkgnum'=> $self->pkgnum } )
1672   ) {
1673     my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1674
1675     $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1676       $dbh->rollback if $oldAutoCommit;
1677       return "Illegal svcdb value in part_svc!";
1678     };
1679     my $svcdb = $1;
1680     require "FS/$svcdb.pm";
1681
1682     my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1683     if ($svc) {
1684       $error = $svc->unsuspend;
1685       if ( $error ) {
1686         $dbh->rollback if $oldAutoCommit;
1687         return $error;
1688       }
1689       my( $label, $value ) = $cust_svc->label;
1690       push @labels, "$label: $value";
1691     }
1692
1693   }
1694
1695   my $cust_pkg_reason = $self->last_cust_pkg_reason('susp');
1696   my $reason = $cust_pkg_reason ? $cust_pkg_reason->reason : '';
1697
1698   my %hash = $self->hash;
1699   my $inactive = time - $hash{'susp'};
1700
1701   my $conf = new FS::Conf;
1702
1703   # increment next bill date if certain conditions are met:
1704   # - it was due to be billed at some point
1705   # - either the global or local config says to do this
1706   my $adjust_bill = 0;
1707   if (
1708        $inactive > 0
1709     && ( $hash{'bill'} || $hash{'setup'} )
1710     && (    $opt{'adjust_next_bill'}
1711          || $conf->exists('unsuspend-always_adjust_next_bill_date')
1712          || $self->part_pkg->option('unsuspend_adjust_bill', 1)
1713        )
1714   ) {
1715     $adjust_bill = 1;
1716   }
1717
1718   # but not if:
1719   # - the package billed during suspension
1720   # - or it was ordered on hold
1721   # - or the customer was credited for the unused time
1722
1723   if ( $self->option('suspend_bill',1)
1724       or ( $self->part_pkg->option('suspend_bill',1)
1725            and ! $self->option('no_suspend_bill',1)
1726          )
1727       or $hash{'order_date'} == $hash{'susp'}
1728   ) {
1729     $adjust_bill = 0;
1730   }
1731
1732   if ( $adjust_bill ) {
1733     if (    $self->part_pkg->option('unused_credit_suspend')
1734          or ( $reason and $reason->unused_credit ) ) {
1735       # then the customer was credited for the unused time before suspending,
1736       # so their next bill should be immediate.
1737       $hash{'bill'} = time;
1738     } else {
1739       # add the length of time suspended to the bill date
1740       $hash{'bill'} = ( $hash{'bill'} || $hash{'setup'} ) + $inactive;
1741     }
1742   }
1743
1744   $hash{'susp'} = '';
1745   $hash{'adjourn'} = '' if $hash{'adjourn'} and $hash{'adjourn'} < time;
1746   $hash{'resume'} = '' if !$hash{'adjourn'};
1747   my $new = new FS::cust_pkg ( \%hash );
1748   $error = $new->replace( $self, options => { $self->options } );
1749   if ( $error ) {
1750     $dbh->rollback if $oldAutoCommit;
1751     return $error;
1752   }
1753
1754   my $unsusp_pkg;
1755
1756   if ( $reason && $reason->unsuspend_pkgpart ) {
1757     my $part_pkg = FS::part_pkg->by_key($reason->unsuspend_pkgpart)
1758       or $error = "Unsuspend package definition ".$reason->unsuspend_pkgpart.
1759                   " not found.";
1760     my $start_date = $self->cust_main->next_bill_date
1761       if $reason->unsuspend_hold;
1762
1763     if ( $part_pkg ) {
1764       $unsusp_pkg = FS::cust_pkg->new({
1765           'custnum'     => $self->custnum,
1766           'pkgpart'     => $reason->unsuspend_pkgpart,
1767           'start_date'  => $start_date,
1768           'locationnum' => $self->locationnum,
1769           # discount? probably not...
1770       });
1771
1772       $error ||= $self->cust_main->order_pkg( 'cust_pkg' => $unsusp_pkg );
1773     }
1774
1775     if ( $error ) {
1776       $dbh->rollback if $oldAutoCommit;
1777       return $error;
1778     }
1779   }
1780
1781   if ( $conf->config('unsuspend_email_admin') ) {
1782
1783     my $error = send_email(
1784       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1785                                  #invoice_from ??? well as good as any
1786       'to'      => $conf->config('unsuspend_email_admin'),
1787       'subject' => 'FREESIDE NOTIFICATION: Customer package unsuspended',       'body'    => [
1788         "This is an automatic message from your Freeside installation\n",
1789         "informing you that the following customer package has been unsuspended:\n",
1790         "\n",
1791         'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1792         'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1793         ( map { "Service : $_\n" } @labels ),
1794         ($unsusp_pkg ?
1795           "An unsuspension fee was charged: ".
1796             $unsusp_pkg->part_pkg->pkg_comment."\n"
1797           : ''
1798         ),
1799       ],
1800       'custnum' => $self->custnum,
1801       'msgtype' => 'admin',
1802     );
1803
1804     if ( $error ) {
1805       warn "WARNING: can't send unsuspension admin email (unsuspending anyway): ".
1806            "$error\n";
1807     }
1808
1809   }
1810
1811   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1812     $error = $supp_pkg->unsuspend(%opt, 'from_main' => 1);
1813     if ( $error ) {
1814       $dbh->rollback if $oldAutoCommit;
1815       return "unsuspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1816     }
1817   }
1818
1819   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1820
1821   ''; #no errors
1822 }
1823
1824 =item unadjourn
1825
1826 Cancels any pending suspension (sets the adjourn field to null).
1827
1828 If there is an error, returns the error, otherwise returns false.
1829
1830 =cut
1831
1832 sub unadjourn {
1833   my( $self, %options ) = @_;
1834   my $error;
1835
1836   local $SIG{HUP} = 'IGNORE';
1837   local $SIG{INT} = 'IGNORE';
1838   local $SIG{QUIT} = 'IGNORE';
1839   local $SIG{TERM} = 'IGNORE';
1840   local $SIG{TSTP} = 'IGNORE';
1841   local $SIG{PIPE} = 'IGNORE';
1842
1843   my $oldAutoCommit = $FS::UID::AutoCommit;
1844   local $FS::UID::AutoCommit = 0;
1845   my $dbh = dbh;
1846
1847   my $old = $self->select_for_update;
1848
1849   my $pkgnum = $old->pkgnum;
1850   if ( $old->get('cancel') || $self->get('cancel') ) {
1851     dbh->rollback if $oldAutoCommit;
1852     return "Can't unadjourn cancelled package $pkgnum";
1853     # or at least it's pointless
1854   }
1855
1856   if ( $old->get('susp') || $self->get('susp') ) {
1857     dbh->rollback if $oldAutoCommit;
1858     return "Can't unadjourn suspended package $pkgnum";
1859     # perhaps this is arbitrary
1860   }
1861
1862   unless ( $old->get('adjourn') && $self->get('adjourn') ) {
1863     dbh->rollback if $oldAutoCommit;
1864     return "";  # no error
1865   }
1866
1867   my %hash = $self->hash;
1868   $hash{'adjourn'} = '';
1869   $hash{'resume'}  = '';
1870   my $new = new FS::cust_pkg ( \%hash );
1871   $error = $new->replace( $self, options => { $self->options } );
1872   if ( $error ) {
1873     $dbh->rollback if $oldAutoCommit;
1874     return $error;
1875   }
1876
1877   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1878
1879   ''; #no errors
1880
1881 }
1882
1883
1884 =item change HASHREF | OPTION => VALUE ...
1885
1886 Changes this package: cancels it and creates a new one, with a different
1887 pkgpart or locationnum or both.  All services are transferred to the new
1888 package (no change will be made if this is not possible).
1889
1890 Options may be passed as a list of key/value pairs or as a hash reference.
1891 Options are:
1892
1893 =over 4
1894
1895 =item locationnum
1896
1897 New locationnum, to change the location for this package.
1898
1899 =item cust_location
1900
1901 New FS::cust_location object, to create a new location and assign it
1902 to this package.
1903
1904 =item cust_main
1905
1906 New FS::cust_main object, to create a new customer and assign the new package
1907 to it.
1908
1909 =item pkgpart
1910
1911 New pkgpart (see L<FS::part_pkg>).
1912
1913 =item refnum
1914
1915 New refnum (see L<FS::part_referral>).
1916
1917 =item quantity
1918
1919 New quantity; if unspecified, the new package will have the same quantity
1920 as the old.
1921
1922 =item cust_pkg
1923
1924 "New" (existing) FS::cust_pkg object.  The package's services and other
1925 attributes will be transferred to this package.
1926
1927 =item keep_dates
1928
1929 Set to true to transfer billing dates (start_date, setup, last_bill, bill,
1930 susp, adjourn, cancel, expire, and contract_end) to the new package.
1931
1932 =item unprotect_svcs
1933
1934 Normally, change() will rollback and return an error if some services
1935 can't be transferred (also see the I<cust_pkg-change_svcpart> config option).
1936 If unprotect_svcs is true, this method will transfer as many services as
1937 it can and then unconditionally cancel the old package.
1938
1939 =back
1940
1941 At least one of locationnum, cust_location, pkgpart, refnum, cust_main, or
1942 cust_pkg must be specified (otherwise, what's the point?)
1943
1944 Returns either the new FS::cust_pkg object or a scalar error.
1945
1946 For example:
1947
1948   my $err_or_new_cust_pkg = $old_cust_pkg->change
1949
1950 =cut
1951
1952 #some false laziness w/order
1953 sub change {
1954   my $self = shift;
1955   my $opt = ref($_[0]) ? shift : { @_ };
1956
1957   my $conf = new FS::Conf;
1958
1959   # Transactionize this whole mess
1960   local $SIG{HUP} = 'IGNORE';
1961   local $SIG{INT} = 'IGNORE';
1962   local $SIG{QUIT} = 'IGNORE';
1963   local $SIG{TERM} = 'IGNORE';
1964   local $SIG{TSTP} = 'IGNORE';
1965   local $SIG{PIPE} = 'IGNORE';
1966
1967   my $oldAutoCommit = $FS::UID::AutoCommit;
1968   local $FS::UID::AutoCommit = 0;
1969   my $dbh = dbh;
1970
1971   my $error;
1972
1973   my %hash = ();
1974
1975   my $time = time;
1976
1977   $hash{'setup'} = $time if $self->setup;
1978
1979   $hash{'change_date'} = $time;
1980   $hash{"change_$_"}  = $self->$_()
1981     foreach qw( pkgnum pkgpart locationnum );
1982
1983   if ( $opt->{'cust_location'} ) {
1984     $error = $opt->{'cust_location'}->find_or_insert;
1985     if ( $error ) {
1986       $dbh->rollback if $oldAutoCommit;
1987       return "creating location record: $error";
1988     }
1989     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
1990   }
1991
1992   if ( $opt->{'cust_pkg'} ) {
1993     # treat changing to a package with a different pkgpart as a
1994     # pkgpart change (because it is)
1995     $opt->{'pkgpart'} = $opt->{'cust_pkg'}->pkgpart;
1996   }
1997
1998   # whether to override pkgpart checking on the new package
1999   my $same_pkgpart = 1;
2000   if ( $opt->{'pkgpart'} and ( $opt->{'pkgpart'} != $self->pkgpart ) ) {
2001     $same_pkgpart = 0;
2002   }
2003
2004   my $unused_credit = 0;
2005   my $keep_dates = $opt->{'keep_dates'};
2006   # Special case.  If the pkgpart is changing, and the customer is
2007   # going to be credited for remaining time, don't keep setup, bill,
2008   # or last_bill dates, and DO pass the flag to cancel() to credit
2009   # the customer.
2010   if ( $opt->{'pkgpart'}
2011        and $opt->{'pkgpart'} != $self->pkgpart
2012        and $self->part_pkg->option('unused_credit_change', 1) ) {
2013     $unused_credit = 1;
2014     $keep_dates = 0;
2015     $hash{$_} = '' foreach qw(setup bill last_bill);
2016   }
2017
2018   if ( $keep_dates ) {
2019     foreach my $date ( qw(setup bill last_bill susp adjourn cancel expire
2020                           resume start_date contract_end ) ) {
2021       $hash{$date} = $self->getfield($date);
2022     }
2023   }
2024   # always keep this date, regardless of anything
2025   # (the date of the package change is in a different field)
2026   $hash{'order_date'} = $self->getfield('order_date');
2027
2028   # allow $opt->{'locationnum'} = '' to specifically set it to null
2029   # (i.e. customer default location)
2030   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2031
2032   # usually this doesn't matter.  the two cases where it does are:
2033   # 1. unused_credit_change + pkgpart change + setup fee on the new package
2034   # and
2035   # 2. (more importantly) changing a package before it's billed
2036   $hash{'waive_setup'} = $self->waive_setup;
2037
2038   my $custnum = $self->custnum;
2039   if ( $opt->{cust_main} ) {
2040     my $cust_main = $opt->{cust_main};
2041     unless ( $cust_main->custnum ) {
2042       my $error = $cust_main->insert( @{ $opt->{cust_main_insert_args}||[] } );
2043       if ( $error ) {
2044         $dbh->rollback if $oldAutoCommit;
2045         return "inserting customer record: $error";
2046       }
2047     }
2048     $custnum = $cust_main->custnum;
2049   }
2050
2051   $hash{'contactnum'} = $opt->{'contactnum'} if $opt->{'contactnum'};
2052
2053   my $cust_pkg;
2054   if ( $opt->{'cust_pkg'} ) {
2055     # The target package already exists; update it to show that it was
2056     # changed from this package.
2057     $cust_pkg = $opt->{'cust_pkg'};
2058
2059     foreach ( qw( pkgnum pkgpart locationnum ) ) {
2060       $cust_pkg->set("change_$_", $self->get($_));
2061     }
2062     $cust_pkg->set('change_date', $time);
2063     $error = $cust_pkg->replace;
2064
2065   } else {
2066     # Create the new package.
2067     $cust_pkg = new FS::cust_pkg {
2068       custnum     => $custnum,
2069       locationnum => $opt->{'locationnum'},
2070       ( map {  $_ => ( $opt->{$_} || $self->$_() )  }
2071           qw( pkgpart quantity refnum salesnum )
2072       ),
2073       %hash,
2074     };
2075     $error = $cust_pkg->insert( 'change' => 1,
2076                                 'allow_pkgpart' => $same_pkgpart );
2077   }
2078   if ($error) {
2079     $dbh->rollback if $oldAutoCommit;
2080     return "inserting new package: $error";
2081   }
2082
2083   # Transfer services and cancel old package.
2084
2085   $error = $self->transfer($cust_pkg);
2086   if ($error and $error == 0) {
2087     # $old_pkg->transfer failed.
2088     $dbh->rollback if $oldAutoCommit;
2089     return "transferring $error";
2090   }
2091
2092   if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
2093     warn "trying transfer again with change_svcpart option\n" if $DEBUG;
2094     $error = $self->transfer($cust_pkg, 'change_svcpart'=>1 );
2095     if ($error and $error == 0) {
2096       # $old_pkg->transfer failed.
2097       $dbh->rollback if $oldAutoCommit;
2098       return "converting $error";
2099     }
2100   }
2101
2102   # We set unprotect_svcs when executing a "future package change".  It's
2103   # not a user-interactive operation, so returning an error means the
2104   # package change will just fail.  Rather than have that happen, we'll
2105   # let leftover services be deleted.
2106   if ($error > 0 and !$opt->{'unprotect_svcs'}) {
2107     # Transfers were successful, but we still had services left on the old
2108     # package.  We can't change the package under this circumstances, so abort.
2109     $dbh->rollback if $oldAutoCommit;
2110     return "unable to transfer all services";
2111   }
2112
2113   #reset usage if changing pkgpart
2114   # AND usage rollover is off (otherwise adds twice, now and at package bill)
2115   if ($self->pkgpart != $cust_pkg->pkgpart) {
2116     my $part_pkg = $cust_pkg->part_pkg;
2117     $error = $part_pkg->reset_usage($cust_pkg, $part_pkg->is_prepaid
2118                                                  ? ()
2119                                                  : ( 'null' => 1 )
2120                                    )
2121       if $part_pkg->can('reset_usage') && ! $part_pkg->option('usage_rollover',1);
2122
2123     if ($error) {
2124       $dbh->rollback if $oldAutoCommit;
2125       return "setting usage values: $error";
2126     }
2127   } else {
2128     # if NOT changing pkgpart, transfer any usage pools over
2129     foreach my $usage ($self->cust_pkg_usage) {
2130       $usage->set('pkgnum', $cust_pkg->pkgnum);
2131       $error = $usage->replace;
2132       if ( $error ) {
2133         $dbh->rollback if $oldAutoCommit;
2134         return "transferring usage pools: $error";
2135       }
2136     }
2137   }
2138
2139   # transfer discounts, if we're not changing pkgpart
2140   if ( $same_pkgpart ) {
2141     foreach my $old_discount ($self->cust_pkg_discount_active) {
2142       # don't remove the old discount, we may still need to bill that package.
2143       my $new_discount = new FS::cust_pkg_discount {
2144         'pkgnum'      => $cust_pkg->pkgnum,
2145         'discountnum' => $old_discount->discountnum,
2146         'months_used' => $old_discount->months_used,
2147       };
2148       $error = $new_discount->insert;
2149       if ( $error ) {
2150         $dbh->rollback if $oldAutoCommit;
2151         return "transferring discounts: $error";
2152       }
2153     }
2154   }
2155
2156   # transfer (copy) invoice details
2157   foreach my $detail ($self->cust_pkg_detail) {
2158     my $new_detail = FS::cust_pkg_detail->new({ $detail->hash });
2159     $new_detail->set('pkgdetailnum', '');
2160     $new_detail->set('pkgnum', $cust_pkg->pkgnum);
2161     $error = $new_detail->insert;
2162     if ( $error ) {
2163       $dbh->rollback if $oldAutoCommit;
2164       return "transferring package notes: $error";
2165     }
2166   }
2167
2168   my @new_supp_pkgs;
2169
2170   if ( !$opt->{'cust_pkg'} ) {
2171     # Order any supplemental packages.
2172     my $part_pkg = $cust_pkg->part_pkg;
2173     my @old_supp_pkgs = $self->supplemental_pkgs;
2174     foreach my $link ($part_pkg->supp_part_pkg_link) {
2175       my $old;
2176       foreach (@old_supp_pkgs) {
2177         if ($_->pkgpart == $link->dst_pkgpart) {
2178           $old = $_;
2179           $_->pkgpart(0); # so that it can't match more than once
2180         }
2181         last if $old;
2182       }
2183       # false laziness with FS::cust_main::Packages::order_pkg
2184       my $new = FS::cust_pkg->new({
2185           pkgpart       => $link->dst_pkgpart,
2186           pkglinknum    => $link->pkglinknum,
2187           custnum       => $custnum,
2188           main_pkgnum   => $cust_pkg->pkgnum,
2189           locationnum   => $cust_pkg->locationnum,
2190           start_date    => $cust_pkg->start_date,
2191           order_date    => $cust_pkg->order_date,
2192           expire        => $cust_pkg->expire,
2193           adjourn       => $cust_pkg->adjourn,
2194           contract_end  => $cust_pkg->contract_end,
2195           refnum        => $cust_pkg->refnum,
2196           discountnum   => $cust_pkg->discountnum,
2197           waive_setup   => $cust_pkg->waive_setup,
2198       });
2199       if ( $old and $opt->{'keep_dates'} ) {
2200         foreach (qw(setup bill last_bill)) {
2201           $new->set($_, $old->get($_));
2202         }
2203       }
2204       $error = $new->insert( allow_pkgpart => $same_pkgpart );
2205       # transfer services
2206       if ( $old ) {
2207         $error ||= $old->transfer($new);
2208       }
2209       if ( $error and $error > 0 ) {
2210         # no reason why this should ever fail, but still...
2211         $error = "Unable to transfer all services from supplemental package ".
2212           $old->pkgnum;
2213       }
2214       if ( $error ) {
2215         $dbh->rollback if $oldAutoCommit;
2216         return $error;
2217       }
2218       push @new_supp_pkgs, $new;
2219     }
2220   } # if !$opt->{'cust_pkg'}
2221     # because if there is one, then supplemental packages would already
2222     # have been created for it.
2223
2224   #Good to go, cancel old package.  Notify 'cancel' of whether to credit
2225   #remaining time.
2226   #Don't allow billing the package (preceding period packages and/or
2227   #outstanding usage) if we are keeping dates (i.e. location changing),
2228   #because the new package will be billed for the same date range.
2229   #Supplemental packages are also canceled here.
2230
2231   # during scheduled changes, avoid canceling the package we just
2232   # changed to (duh)
2233   $self->set('change_to_pkgnum' => '');
2234
2235   $error = $self->cancel(
2236     quiet          => 1,
2237     unused_credit  => $unused_credit,
2238     nobill         => $keep_dates,
2239     change_custnum => ( $self->custnum != $custnum ? $custnum : '' ),
2240     no_delay_cancel => 1,
2241   );
2242   if ($error) {
2243     $dbh->rollback if $oldAutoCommit;
2244     return "canceling old package: $error";
2245   }
2246
2247   if ( $conf->exists('cust_pkg-change_pkgpart-bill_now') ) {
2248     #$self->cust_main
2249     my $error = $cust_pkg->cust_main->bill(
2250       'pkg_list' => [ $cust_pkg, @new_supp_pkgs ]
2251     );
2252     if ( $error ) {
2253       $dbh->rollback if $oldAutoCommit;
2254       return "billing new package: $error";
2255     }
2256   }
2257
2258   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2259
2260   $cust_pkg;
2261
2262 }
2263
2264 =item change_later OPTION => VALUE...
2265
2266 Schedule a package change for a later date.  This actually orders the new
2267 package immediately, but sets its start date for a future date, and sets
2268 the current package to expire on the same date.
2269
2270 If the package is already scheduled for a change, this can be called with
2271 'start_date' to change the scheduled date, or with pkgpart and/or
2272 locationnum to modify the package change.  To cancel the scheduled change
2273 entirely, see C<abort_change>.
2274
2275 Options include:
2276
2277 =over 4
2278
2279 =item start_date
2280
2281 The date for the package change.  Required, and must be in the future.
2282
2283 =item pkgpart
2284
2285 =item locationnum
2286
2287 =item quantity
2288
2289 The pkgpart. locationnum, and quantity of the new package, with the same
2290 meaning as in C<change>.
2291
2292 =back
2293
2294 =cut
2295
2296 sub change_later {
2297   my $self = shift;
2298   my $opt = ref($_[0]) ? shift : { @_ };
2299
2300   my $oldAutoCommit = $FS::UID::AutoCommit;
2301   local $FS::UID::AutoCommit = 0;
2302   my $dbh = dbh;
2303
2304   my $cust_main = $self->cust_main;
2305
2306   my $date = delete $opt->{'start_date'} or return 'start_date required';
2307
2308   if ( $date <= time ) {
2309     $dbh->rollback if $oldAutoCommit;
2310     return "start_date $date is in the past";
2311   }
2312
2313   my $error;
2314
2315   if ( $self->change_to_pkgnum ) {
2316     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
2317     my $new_pkgpart = $opt->{'pkgpart'}
2318         if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $change_to->pkgpart;
2319     my $new_locationnum = $opt->{'locationnum'}
2320         if $opt->{'locationnum'} and $opt->{'locationnum'} != $change_to->locationnum;
2321     my $new_quantity = $opt->{'quantity'}
2322         if $opt->{'quantity'} and $opt->{'quantity'} != $change_to->quantity;
2323     if ( $new_pkgpart or $new_locationnum or $new_quantity ) {
2324       # it hasn't been billed yet, so in principle we could just edit
2325       # it in place (w/o a package change), but that's bad form.
2326       # So change the package according to the new options...
2327       my $err_or_pkg = $change_to->change(%$opt);
2328       if ( ref $err_or_pkg ) {
2329         # Then set that package up for a future start.
2330         $self->set('change_to_pkgnum', $err_or_pkg->pkgnum);
2331         $self->set('expire', $date); # in case it's different
2332         $err_or_pkg->set('start_date', $date);
2333         $err_or_pkg->set('change_date', '');
2334         $err_or_pkg->set('change_pkgnum', '');
2335
2336         $error = $self->replace       ||
2337                  $err_or_pkg->replace ||
2338                  $change_to->cancel('no_delay_cancel' => 1) ||
2339                  $change_to->delete;
2340       } else {
2341         $error = $err_or_pkg;
2342       }
2343     } else { # change the start date only.
2344       $self->set('expire', $date);
2345       $change_to->set('start_date', $date);
2346       $error = $self->replace || $change_to->replace;
2347     }
2348     if ( $error ) {
2349       $dbh->rollback if $oldAutoCommit;
2350       return $error;
2351     } else {
2352       $dbh->commit if $oldAutoCommit;
2353       return '';
2354     }
2355   } # if $self->change_to_pkgnum
2356
2357   my $new_pkgpart = $opt->{'pkgpart'}
2358       if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart;
2359   my $new_locationnum = $opt->{'locationnum'}
2360       if $opt->{'locationnum'} and $opt->{'locationnum'} != $self->locationnum;
2361   my $new_quantity = $opt->{'quantity'}
2362       if $opt->{'quantity'} and $opt->{'quantity'} != $self->quantity;
2363
2364   return '' unless $new_pkgpart or $new_locationnum or $new_quantity; # wouldn't do anything
2365
2366   # allow $opt->{'locationnum'} = '' to specifically set it to null
2367   # (i.e. customer default location)
2368   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2369
2370   my $new = FS::cust_pkg->new( {
2371     custnum     => $self->custnum,
2372     locationnum => $opt->{'locationnum'},
2373     start_date  => $date,
2374     map   {  $_ => ( $opt->{$_} || $self->$_() )  }
2375       qw( pkgpart quantity refnum salesnum )
2376   } );
2377   $error = $new->insert('change' => 1,
2378                         'allow_pkgpart' => ($new_pkgpart ? 0 : 1));
2379   if ( !$error ) {
2380     $self->set('change_to_pkgnum', $new->pkgnum);
2381     $self->set('expire', $date);
2382     $error = $self->replace;
2383   }
2384   if ( $error ) {
2385     $dbh->rollback if $oldAutoCommit;
2386   } else {
2387     $dbh->commit if $oldAutoCommit;
2388   }
2389
2390   $error;
2391 }
2392
2393 =item abort_change
2394
2395 Cancels a future package change scheduled by C<change_later>.
2396
2397 =cut
2398
2399 sub abort_change {
2400   my $self = shift;
2401   my $pkgnum = $self->change_to_pkgnum;
2402   my $change_to = FS::cust_pkg->by_key($pkgnum) if $pkgnum;
2403   my $error;
2404   if ( $change_to ) {
2405     $error = $change_to->cancel || $change_to->delete;
2406     return $error if $error;
2407   }
2408   $self->set('change_to_pkgnum', '');
2409   $self->set('expire', '');
2410   $self->replace;
2411 }
2412
2413 =item set_quantity QUANTITY
2414
2415 Change the package's quantity field.  This is one of the few package properties
2416 that can safely be changed without canceling and reordering the package
2417 (because it doesn't affect tax eligibility).  Returns an error or an
2418 empty string.
2419
2420 =cut
2421
2422 sub set_quantity {
2423   my $self = shift;
2424   $self = $self->replace_old; # just to make sure
2425   $self->quantity(shift);
2426   $self->replace;
2427 }
2428
2429 =item set_salesnum SALESNUM
2430
2431 Change the package's salesnum (sales person) field.  This is one of the few
2432 package properties that can safely be changed without canceling and reordering
2433 the package (because it doesn't affect tax eligibility).  Returns an error or
2434 an empty string.
2435
2436 =cut
2437
2438 sub set_salesnum {
2439   my $self = shift;
2440   $self = $self->replace_old; # just to make sure
2441   $self->salesnum(shift);
2442   $self->replace;
2443   # XXX this should probably reassign any credit that's already been given
2444 }
2445
2446 =item modify_charge OPTIONS
2447
2448 Change the properties of a one-time charge.  The following properties can
2449 be changed this way:
2450 - pkg: the package description
2451 - classnum: the package class
2452 - additional: arrayref of additional invoice details to add to this package
2453
2454 and, I<if the charge has not yet been billed>:
2455 - start_date: the date when it will be billed
2456 - amount: the setup fee to be charged
2457 - quantity: the multiplier for the setup fee
2458 - separate_bill: whether to put the charge on a separate invoice
2459
2460 If you pass 'adjust_commission' => 1, and the classnum changes, and there are
2461 commission credits linked to this charge, they will be recalculated.
2462
2463 =cut
2464
2465 sub modify_charge {
2466   my $self = shift;
2467   my %opt = @_;
2468   my $part_pkg = $self->part_pkg;
2469   my $pkgnum = $self->pkgnum;
2470
2471   my $dbh = dbh;
2472   my $oldAutoCommit = $FS::UID::AutoCommit;
2473   local $FS::UID::AutoCommit = 0;
2474
2475   return "Can't use modify_charge except on one-time charges"
2476     unless $part_pkg->freq eq '0';
2477
2478   if ( length($opt{'pkg'}) and $part_pkg->pkg ne $opt{'pkg'} ) {
2479     $part_pkg->set('pkg', $opt{'pkg'});
2480   }
2481
2482   my %pkg_opt = $part_pkg->options;
2483   my $pkg_opt_modified = 0;
2484
2485   $opt{'additional'} ||= [];
2486   my $i;
2487   my @old_additional;
2488   foreach (grep /^additional/, keys %pkg_opt) {
2489     ($i) = ($_ =~ /^additional_info(\d+)$/);
2490     $old_additional[$i] = $pkg_opt{$_} if $i;
2491     delete $pkg_opt{$_};
2492   }
2493
2494   for ( $i = 0; exists($opt{'additional'}->[$i]); $i++ ) {
2495     $pkg_opt{ "additional_info$i" } = $opt{'additional'}->[$i];
2496     if (!exists($old_additional[$i])
2497         or $old_additional[$i] ne $opt{'additional'}->[$i])
2498     {
2499       $pkg_opt_modified = 1;
2500     }
2501   }
2502   $pkg_opt_modified = 1 if (scalar(@old_additional) - 1) != $i;
2503   $pkg_opt{'additional_count'} = $i if $i > 0;
2504
2505   my $old_classnum;
2506   if ( exists($opt{'classnum'}) and $part_pkg->classnum ne $opt{'classnum'} )
2507   {
2508     # remember it
2509     $old_classnum = $part_pkg->classnum;
2510     $part_pkg->set('classnum', $opt{'classnum'});
2511   }
2512
2513   if ( !$self->get('setup') ) {
2514     # not yet billed, so allow amount, setup_cost, quantity, start_date,
2515     # and separate_bill
2516
2517     if ( exists($opt{'amount'})
2518           and $part_pkg->option('setup_fee') != $opt{'amount'}
2519           and $opt{'amount'} > 0 ) {
2520
2521       $pkg_opt{'setup_fee'} = $opt{'amount'};
2522       $pkg_opt_modified = 1;
2523     }
2524
2525     if ( exists($opt{'setup_cost'})
2526           and $part_pkg->setup_cost != $opt{'setup_cost'}
2527           and $opt{'setup_cost'} > 0 ) {
2528
2529       $part_pkg->set('setup_cost', $opt{'setup_cost'});
2530     }
2531
2532     if ( exists($opt{'quantity'})
2533           and $opt{'quantity'} != $self->quantity
2534           and $opt{'quantity'} > 0 ) {
2535
2536       $self->set('quantity', $opt{'quantity'});
2537     }
2538
2539     if ( exists($opt{'start_date'})
2540           and $opt{'start_date'} != $self->start_date ) {
2541
2542       $self->set('start_date', $opt{'start_date'});
2543     }
2544
2545     if ( exists($opt{'separate_bill'})
2546           and $opt{'separate_bill'} ne $self->separate_bill ) {
2547
2548       $self->set('separate_bill', $opt{'separate_bill'});
2549     }
2550
2551
2552   } # else simply ignore them; the UI shouldn't allow editing the fields
2553
2554   if ( exists($opt{'taxclass'})
2555           and $part_pkg->taxclass ne $opt{'taxclass'}) {
2556
2557       $part_pkg->set('taxclass', $opt{'taxclass'});
2558   }
2559
2560   my $error;
2561   if ( $part_pkg->modified or $pkg_opt_modified ) {
2562     # can we safely modify the package def?
2563     # Yes, if it's not available for purchase, and this is the only instance
2564     # of it.
2565     if ( $part_pkg->disabled
2566          and FS::cust_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 1
2567          and FS::quotation_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 0
2568        ) {
2569       $error = $part_pkg->replace( options => \%pkg_opt );
2570     } else {
2571       # clone it
2572       $part_pkg = $part_pkg->clone;
2573       $part_pkg->set('disabled' => 'Y');
2574       $error = $part_pkg->insert( options => \%pkg_opt );
2575       # and associate this as yet-unbilled package to the new package def
2576       $self->set('pkgpart' => $part_pkg->pkgpart);
2577     }
2578     if ( $error ) {
2579       $dbh->rollback if $oldAutoCommit;
2580       return $error;
2581     }
2582   }
2583
2584   if ($self->modified) { # for quantity or start_date change, or if we had
2585                          # to clone the existing package def
2586     my $error = $self->replace;
2587     return $error if $error;
2588   }
2589   if (defined $old_classnum) {
2590     # fix invoice grouping records
2591     my $old_catname = $old_classnum
2592                       ? FS::pkg_class->by_key($old_classnum)->categoryname
2593                       : '';
2594     my $new_catname = $opt{'classnum'}
2595                       ? $part_pkg->pkg_class->categoryname
2596                       : '';
2597     if ( $old_catname ne $new_catname ) {
2598       foreach my $cust_bill_pkg ($self->cust_bill_pkg) {
2599         # (there should only be one...)
2600         my @display = qsearch( 'cust_bill_pkg_display', {
2601             'billpkgnum'  => $cust_bill_pkg->billpkgnum,
2602             'section'     => $old_catname,
2603         });
2604         foreach (@display) {
2605           $_->set('section', $new_catname);
2606           $error = $_->replace;
2607           if ( $error ) {
2608             $dbh->rollback if $oldAutoCommit;
2609             return $error;
2610           }
2611         }
2612       } # foreach $cust_bill_pkg
2613     }
2614
2615     if ( $opt{'adjust_commission'} ) {
2616       # fix commission credits...tricky.
2617       foreach my $cust_event ($self->cust_event) {
2618         my $part_event = $cust_event->part_event;
2619         foreach my $table (qw(sales agent)) {
2620           my $class =
2621             "FS::part_event::Action::Mixin::credit_${table}_pkg_class";
2622           my $credit = qsearchs('cust_credit', {
2623               'eventnum' => $cust_event->eventnum,
2624           });
2625           if ( $part_event->isa($class) ) {
2626             # Yes, this results in current commission rates being applied
2627             # retroactively to a one-time charge.  For accounting purposes
2628             # there ought to be some kind of time limit on doing this.
2629             my $amount = $part_event->_calc_credit($self);
2630             if ( $credit and $credit->amount ne $amount ) {
2631               # Void the old credit.
2632               $error = $credit->void('Package class changed');
2633               if ( $error ) {
2634                 $dbh->rollback if $oldAutoCommit;
2635                 return "$error (adjusting commission credit)";
2636               }
2637             }
2638             # redo the event action to recreate the credit.
2639             local $@ = '';
2640             eval { $part_event->do_action( $self, $cust_event ) };
2641             if ( $@ ) {
2642               $dbh->rollback if $oldAutoCommit;
2643               return $@;
2644             }
2645           } # if $part_event->isa($class)
2646         } # foreach $table
2647       } # foreach $cust_event
2648     } # if $opt{'adjust_commission'}
2649   } # if defined $old_classnum
2650
2651   $dbh->commit if $oldAutoCommit;
2652   '';
2653 }
2654
2655
2656
2657 use Storable 'thaw';
2658 use MIME::Base64;
2659 use Data::Dumper;
2660 sub process_bulk_cust_pkg {
2661   my $job = shift;
2662   my $param = thaw(decode_base64(shift));
2663   warn Dumper($param) if $DEBUG;
2664
2665   my $old_part_pkg = qsearchs('part_pkg',
2666                               { pkgpart => $param->{'old_pkgpart'} });
2667   my $new_part_pkg = qsearchs('part_pkg',
2668                               { pkgpart => $param->{'new_pkgpart'} });
2669   die "Must select a new package type\n" unless $new_part_pkg;
2670   #my $keep_dates = $param->{'keep_dates'} || 0;
2671   my $keep_dates = 1; # there is no good reason to turn this off
2672
2673   local $SIG{HUP} = 'IGNORE';
2674   local $SIG{INT} = 'IGNORE';
2675   local $SIG{QUIT} = 'IGNORE';
2676   local $SIG{TERM} = 'IGNORE';
2677   local $SIG{TSTP} = 'IGNORE';
2678   local $SIG{PIPE} = 'IGNORE';
2679
2680   my $oldAutoCommit = $FS::UID::AutoCommit;
2681   local $FS::UID::AutoCommit = 0;
2682   my $dbh = dbh;
2683
2684   my @cust_pkgs = qsearch('cust_pkg', { 'pkgpart' => $param->{'old_pkgpart'} } );
2685
2686   my $i = 0;
2687   foreach my $old_cust_pkg ( @cust_pkgs ) {
2688     $i++;
2689     $job->update_statustext(int(100*$i/(scalar @cust_pkgs)));
2690     if ( $old_cust_pkg->getfield('cancel') ) {
2691       warn '[process_bulk_cust_pkg ] skipping canceled pkgnum '.
2692         $old_cust_pkg->pkgnum."\n"
2693         if $DEBUG;
2694       next;
2695     }
2696     warn '[process_bulk_cust_pkg] changing pkgnum '.$old_cust_pkg->pkgnum."\n"
2697       if $DEBUG;
2698     my $error = $old_cust_pkg->change(
2699       'pkgpart'     => $param->{'new_pkgpart'},
2700       'keep_dates'  => $keep_dates
2701     );
2702     if ( !ref($error) ) { # change returns the cust_pkg on success
2703       $dbh->rollback;
2704       die "Error changing pkgnum ".$old_cust_pkg->pkgnum.": '$error'\n";
2705     }
2706   }
2707   $dbh->commit if $oldAutoCommit;
2708   return;
2709 }
2710
2711 =item last_bill
2712
2713 Returns the last bill date, or if there is no last bill date, the setup date.
2714 Useful for billing metered services.
2715
2716 =cut
2717
2718 sub last_bill {
2719   my $self = shift;
2720   return $self->setfield('last_bill', $_[0]) if @_;
2721   return $self->getfield('last_bill') if $self->getfield('last_bill');
2722   my $cust_bill_pkg = qsearchs('cust_bill_pkg', { 'pkgnum' => $self->pkgnum,
2723                                                   'edate'  => $self->bill,  } );
2724   $cust_bill_pkg ? $cust_bill_pkg->sdate : $self->setup || 0;
2725 }
2726
2727 =item last_cust_pkg_reason ACTION
2728
2729 Returns the most recent ACTION FS::cust_pkg_reason associated with the package.
2730 Returns false if there is no reason or the package is not currenly ACTION'd
2731 ACTION is one of adjourn, susp, cancel, or expire.
2732
2733 =cut
2734
2735 sub last_cust_pkg_reason {
2736   my ( $self, $action ) = ( shift, shift );
2737   my $date = $self->get($action);
2738   qsearchs( {
2739               'table' => 'cust_pkg_reason',
2740               'hashref' => { 'pkgnum' => $self->pkgnum,
2741                              'action' => substr(uc($action), 0, 1),
2742                              'date'   => $date,
2743                            },
2744               'order_by' => 'ORDER BY num DESC LIMIT 1',
2745            } );
2746 }
2747
2748 =item last_reason ACTION
2749
2750 Returns the most recent ACTION FS::reason associated with the package.
2751 Returns false if there is no reason or the package is not currenly ACTION'd
2752 ACTION is one of adjourn, susp, cancel, or expire.
2753
2754 =cut
2755
2756 sub last_reason {
2757   my $cust_pkg_reason = shift->last_cust_pkg_reason(@_);
2758   $cust_pkg_reason->reason
2759     if $cust_pkg_reason;
2760 }
2761
2762 =item part_pkg
2763
2764 Returns the definition for this billing item, as an FS::part_pkg object (see
2765 L<FS::part_pkg>).
2766
2767 =cut
2768
2769 sub part_pkg {
2770   my $self = shift;
2771   return $self->{'_pkgpart'} if $self->{'_pkgpart'};
2772   cluck "cust_pkg->part_pkg called" if $DEBUG > 1;
2773   qsearchs( 'part_pkg', { 'pkgpart' => $self->pkgpart } );
2774 }
2775
2776 =item old_cust_pkg
2777
2778 Returns the cancelled package this package was changed from, if any.
2779
2780 =cut
2781
2782 sub old_cust_pkg {
2783   my $self = shift;
2784   return '' unless $self->change_pkgnum;
2785   qsearchs('cust_pkg', { 'pkgnum' => $self->change_pkgnum } );
2786 }
2787
2788 =item change_cust_main
2789
2790 Returns the customter this package was detached to, if any.
2791
2792 =cut
2793
2794 sub change_cust_main {
2795   my $self = shift;
2796   return '' unless $self->change_custnum;
2797   qsearchs('cust_main', { 'custnum' => $self->change_custnum } );
2798 }
2799
2800 =item calc_setup
2801
2802 Calls the I<calc_setup> of the FS::part_pkg object associated with this billing
2803 item.
2804
2805 =cut
2806
2807 sub calc_setup {
2808   my $self = shift;
2809   $self->part_pkg->calc_setup($self, @_);
2810 }
2811
2812 =item calc_recur
2813
2814 Calls the I<calc_recur> of the FS::part_pkg object associated with this billing
2815 item.
2816
2817 =cut
2818
2819 sub calc_recur {
2820   my $self = shift;
2821   $self->part_pkg->calc_recur($self, @_);
2822 }
2823
2824 =item base_recur
2825
2826 Calls the I<base_recur> of the FS::part_pkg object associated with this billing
2827 item.
2828
2829 =cut
2830
2831 sub base_recur {
2832   my $self = shift;
2833   $self->part_pkg->base_recur($self, @_);
2834 }
2835
2836 =item calc_remain
2837
2838 Calls the I<calc_remain> of the FS::part_pkg object associated with this
2839 billing item.
2840
2841 =cut
2842
2843 sub calc_remain {
2844   my $self = shift;
2845   $self->part_pkg->calc_remain($self, @_);
2846 }
2847
2848 =item calc_cancel
2849
2850 Calls the I<calc_cancel> of the FS::part_pkg object associated with this
2851 billing item.
2852
2853 =cut
2854
2855 sub calc_cancel {
2856   my $self = shift;
2857   $self->part_pkg->calc_cancel($self, @_);
2858 }
2859
2860 =item cust_bill_pkg
2861
2862 Returns any invoice line items for this package (see L<FS::cust_bill_pkg>).
2863
2864 =cut
2865
2866 sub cust_bill_pkg {
2867   my $self = shift;
2868   qsearch( 'cust_bill_pkg', { 'pkgnum' => $self->pkgnum } );
2869 }
2870
2871 =item cust_pkg_detail [ DETAILTYPE ]
2872
2873 Returns any customer package details for this package (see
2874 L<FS::cust_pkg_detail>).
2875
2876 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2877
2878 =cut
2879
2880 sub cust_pkg_detail {
2881   my $self = shift;
2882   my %hash = ( 'pkgnum' => $self->pkgnum );
2883   $hash{detailtype} = shift if @_;
2884   qsearch({
2885     'table'    => 'cust_pkg_detail',
2886     'hashref'  => \%hash,
2887     'order_by' => 'ORDER BY weight, pkgdetailnum',
2888   });
2889 }
2890
2891 =item set_cust_pkg_detail DETAILTYPE [ DETAIL, DETAIL, ... ]
2892
2893 Sets customer package details for this package (see L<FS::cust_pkg_detail>).
2894
2895 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2896
2897 If there is an error, returns the error, otherwise returns false.
2898
2899 =cut
2900
2901 sub set_cust_pkg_detail {
2902   my( $self, $detailtype, @details ) = @_;
2903
2904   local $SIG{HUP} = 'IGNORE';
2905   local $SIG{INT} = 'IGNORE';
2906   local $SIG{QUIT} = 'IGNORE';
2907   local $SIG{TERM} = 'IGNORE';
2908   local $SIG{TSTP} = 'IGNORE';
2909   local $SIG{PIPE} = 'IGNORE';
2910
2911   my $oldAutoCommit = $FS::UID::AutoCommit;
2912   local $FS::UID::AutoCommit = 0;
2913   my $dbh = dbh;
2914
2915   foreach my $current ( $self->cust_pkg_detail($detailtype) ) {
2916     my $error = $current->delete;
2917     if ( $error ) {
2918       $dbh->rollback if $oldAutoCommit;
2919       return "error removing old detail: $error";
2920     }
2921   }
2922
2923   foreach my $detail ( @details ) {
2924     my $cust_pkg_detail = new FS::cust_pkg_detail {
2925       'pkgnum'     => $self->pkgnum,
2926       'detailtype' => $detailtype,
2927       'detail'     => $detail,
2928     };
2929     my $error = $cust_pkg_detail->insert;
2930     if ( $error ) {
2931       $dbh->rollback if $oldAutoCommit;
2932       return "error adding new detail: $error";
2933     }
2934
2935   }
2936
2937   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2938   '';
2939
2940 }
2941
2942 =item cust_event
2943
2944 Returns the customer billing events (see L<FS::cust_event>) for this invoice.
2945
2946 =cut
2947
2948 #false laziness w/cust_bill.pm
2949 sub cust_event {
2950   my $self = shift;
2951   qsearch({
2952     'table'     => 'cust_event',
2953     'addl_from' => 'JOIN part_event USING ( eventpart )',
2954     'hashref'   => { 'tablenum' => $self->pkgnum },
2955     'extra_sql' => " AND eventtable = 'cust_pkg' ",
2956   });
2957 }
2958
2959 =item num_cust_event
2960
2961 Returns the number of customer billing events (see L<FS::cust_event>) for this package.
2962
2963 =cut
2964
2965 #false laziness w/cust_bill.pm
2966 sub num_cust_event {
2967   my $self = shift;
2968   my $sql = "SELECT COUNT(*) ". $self->_from_cust_event_where;
2969   $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref->[0];
2970 }
2971
2972 =item exists_cust_event
2973
2974 Returns true if there are customer billing events (see L<FS::cust_event>) for this package.  More efficient than using num_cust_event.
2975
2976 =cut
2977
2978 sub exists_cust_event {
2979   my $self = shift;
2980   my $sql = "SELECT 1 ". $self->_from_cust_event_where. " LIMIT 1";
2981   my $row = $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref;
2982   $row ? $row->[0] : '';
2983 }
2984
2985 sub _from_cust_event_where {
2986   #my $self = shift;
2987   " FROM cust_event JOIN part_event USING ( eventpart ) ".
2988   "  WHERE tablenum = ? AND eventtable = 'cust_pkg' ";
2989 }
2990
2991 sub _prep_ex {
2992   my( $self, $sql, @args ) = @_;
2993   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
2994   $sth->execute(@args)         or die $sth->errstr. " executing $sql";
2995   $sth;
2996 }
2997
2998 =item cust_svc [ SVCPART ] (old, deprecated usage)
2999
3000 =item cust_svc [ OPTION => VALUE ... ] (current usage)
3001
3002 =item cust_svc_unsorted [ OPTION => VALUE ... ]
3003
3004 Returns the services for this package, as FS::cust_svc objects (see
3005 L<FS::cust_svc>).  Available options are svcpart and svcdb.  If either is
3006 spcififed, returns only the matching services.
3007
3008 As an optimization, use the cust_svc_unsorted version if you are not displaying
3009 the results.
3010
3011 =cut
3012
3013 sub cust_svc {
3014   my $self = shift;
3015   cluck "cust_pkg->cust_svc called" if $DEBUG > 2;
3016   $self->_sort_cust_svc( $self->cust_svc_unsorted_arrayref(@_) );
3017 }
3018
3019 sub cust_svc_unsorted {
3020   my $self = shift;
3021   @{ $self->cust_svc_unsorted_arrayref(@_) };
3022 }
3023
3024 sub cust_svc_unsorted_arrayref {
3025   my $self = shift;
3026
3027   return [] unless $self->num_cust_svc(@_);
3028
3029   my %opt = ();
3030   if ( @_ && $_[0] =~ /^\d+/ ) {
3031     $opt{svcpart} = shift;
3032   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3033     %opt = %{ $_[0] };
3034   } elsif ( @_ ) {
3035     %opt = @_;
3036   }
3037
3038   my %search = (
3039     'table'   => 'cust_svc',
3040     'hashref' => { 'pkgnum' => $self->pkgnum },
3041   );
3042   if ( $opt{svcpart} ) {
3043     $search{hashref}->{svcpart} = $opt{'svcpart'};
3044   }
3045   if ( $opt{'svcdb'} ) {
3046     $search{addl_from} = ' LEFT JOIN part_svc USING ( svcpart ) ';
3047     $search{extra_sql} = ' AND svcdb = '. dbh->quote( $opt{'svcdb'} );
3048   }
3049
3050   [ qsearch(\%search) ];
3051
3052 }
3053
3054 =item overlimit [ SVCPART ]
3055
3056 Returns the services for this package which have exceeded their
3057 usage limit as FS::cust_svc objects (see L<FS::cust_svc>).  If a svcpart
3058 is specified, return only the matching services.
3059
3060 =cut
3061
3062 sub overlimit {
3063   my $self = shift;
3064   return () unless $self->num_cust_svc(@_);
3065   grep { $_->overlimit } $self->cust_svc(@_);
3066 }
3067
3068 =item h_cust_svc END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3069
3070 Returns historical services for this package created before END TIMESTAMP and
3071 (optionally) not cancelled before START_TIMESTAMP, as FS::h_cust_svc objects
3072 (see L<FS::h_cust_svc>).  If MODE is 'I' (for 'invoice'), services with the
3073 I<pkg_svc.hidden> flag will be omitted.
3074
3075 =cut
3076
3077 sub h_cust_svc {
3078   my $self = shift;
3079   warn "$me _h_cust_svc called on $self\n"
3080     if $DEBUG;
3081
3082   my ($end, $start, $mode) = @_;
3083   my @cust_svc = $self->_sort_cust_svc(
3084     [ qsearch( 'h_cust_svc',
3085       { 'pkgnum' => $self->pkgnum, },
3086       FS::h_cust_svc->sql_h_search(@_),
3087     ) ]
3088   );
3089   if ( defined($mode) && $mode eq 'I' ) {
3090     my %hidden_svcpart = map { $_->svcpart => $_->hidden } $self->part_svc;
3091     return grep { !$hidden_svcpart{$_->svcpart} } @cust_svc;
3092   } else {
3093     return @cust_svc;
3094   }
3095 }
3096
3097 sub _sort_cust_svc {
3098   my( $self, $arrayref ) = @_;
3099
3100   my $sort =
3101     sub ($$) { my ($a, $b) = @_; $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] };
3102
3103   my %pkg_svc = map { $_->svcpart => $_ }
3104                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
3105
3106   map  { $_->[0] }
3107   sort $sort
3108   map {
3109         my $pkg_svc = $pkg_svc{ $_->svcpart } || '';
3110         [ $_,
3111           $pkg_svc ? $pkg_svc->primary_svc : '',
3112           $pkg_svc ? $pkg_svc->quantity : 0,
3113         ];
3114       }
3115   @$arrayref;
3116
3117 }
3118
3119 =item num_cust_svc [ SVCPART ] (old, deprecated usage)
3120
3121 =item num_cust_svc [ OPTION => VALUE ... ] (current usage)
3122
3123 Returns the number of services for this package.  Available options are svcpart
3124 and svcdb.  If either is spcififed, returns only the matching services.
3125
3126 =cut
3127
3128 sub num_cust_svc {
3129   my $self = shift;
3130
3131   return $self->{'_num_cust_svc'}
3132     if !scalar(@_)
3133        && exists($self->{'_num_cust_svc'})
3134        && $self->{'_num_cust_svc'} =~ /\d/;
3135
3136   cluck "cust_pkg->num_cust_svc called, _num_cust_svc:".$self->{'_num_cust_svc'}
3137     if $DEBUG > 2;
3138
3139   my %opt = ();
3140   if ( @_ && $_[0] =~ /^\d+/ ) {
3141     $opt{svcpart} = shift;
3142   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3143     %opt = %{ $_[0] };
3144   } elsif ( @_ ) {
3145     %opt = @_;
3146   }
3147
3148   my $select = 'SELECT COUNT(*) FROM cust_svc ';
3149   my $where = ' WHERE pkgnum = ? ';
3150   my @param = ($self->pkgnum);
3151
3152   if ( $opt{'svcpart'} ) {
3153     $where .= ' AND svcpart = ? ';
3154     push @param, $opt{'svcpart'};
3155   }
3156   if ( $opt{'svcdb'} ) {
3157     $select .= ' LEFT JOIN part_svc USING ( svcpart ) ';
3158     $where .= ' AND svcdb = ? ';
3159     push @param, $opt{'svcdb'};
3160   }
3161
3162   my $sth = dbh->prepare("$select $where") or die  dbh->errstr;
3163   $sth->execute(@param) or die $sth->errstr;
3164   $sth->fetchrow_arrayref->[0];
3165 }
3166
3167 =item available_part_svc
3168
3169 Returns a list of FS::part_svc objects representing services included in this
3170 package but not yet provisioned.  Each FS::part_svc object also has an extra
3171 field, I<num_avail>, which specifies the number of available services.
3172
3173 =cut
3174
3175 sub available_part_svc {
3176   my $self = shift;
3177
3178   my $pkg_quantity = $self->quantity || 1;
3179
3180   grep { $_->num_avail > 0 }
3181     map {
3182           my $part_svc = $_->part_svc;
3183           $part_svc->{'Hash'}{'num_avail'} = #evil encapsulation-breaking
3184             $pkg_quantity * $_->quantity - $self->num_cust_svc($_->svcpart);
3185
3186           # more evil encapsulation breakage
3187           if($part_svc->{'Hash'}{'num_avail'} > 0) {
3188             my @exports = $part_svc->part_export_did;
3189             $part_svc->{'Hash'}{'can_get_dids'} = scalar(@exports);
3190           }
3191
3192           $part_svc;
3193         }
3194       $self->part_pkg->pkg_svc;
3195 }
3196
3197 =item part_svc [ OPTION => VALUE ... ]
3198
3199 Returns a list of FS::part_svc objects representing provisioned and available
3200 services included in this package.  Each FS::part_svc object also has the
3201 following extra fields:
3202
3203 =over 4
3204
3205 =item num_cust_svc
3206
3207 (count)
3208
3209 =item num_avail
3210
3211 (quantity - count)
3212
3213 =item cust_pkg_svc
3214
3215 (services) - array reference containing the provisioned services, as cust_svc objects
3216
3217 =back
3218
3219 Accepts two options:
3220
3221 =over 4
3222
3223 =item summarize_size
3224
3225 If true, will omit the extra cust_pkg_svc option for objects where num_cust_svc
3226 is this size or greater.
3227
3228 =item hide_discontinued
3229
3230 If true, will omit looking for services that are no longer avaialble in the
3231 package definition.
3232
3233 =back
3234
3235 =cut
3236
3237 #svcnum
3238 #label -> ($cust_svc->label)[1]
3239
3240 sub part_svc {
3241   my $self = shift;
3242   my %opt = @_;
3243
3244   my $pkg_quantity = $self->quantity || 1;
3245
3246   #XXX some sort of sort order besides numeric by svcpart...
3247   my @part_svc = sort { $a->svcpart <=> $b->svcpart } map {
3248     my $pkg_svc = $_;
3249     my $part_svc = $pkg_svc->part_svc;
3250     my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3251     $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #more evil
3252     $part_svc->{'Hash'}{'num_avail'}    =
3253       max( 0, $pkg_quantity * $pkg_svc->quantity - $num_cust_svc );
3254     $part_svc->{'Hash'}{'cust_pkg_svc'} =
3255         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : []
3256       unless exists($opt{summarize_size}) && $opt{summarize_size} > 0
3257           && $num_cust_svc >= $opt{summarize_size};
3258     $part_svc->{'Hash'}{'hidden'} = $pkg_svc->hidden;
3259     $part_svc;
3260   } $self->part_pkg->pkg_svc;
3261
3262   unless ( $opt{hide_discontinued} ) {
3263     #extras
3264     push @part_svc, map {
3265       my $part_svc = $_;
3266       my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3267       $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #speak no evail
3268       $part_svc->{'Hash'}{'num_avail'}    = 0; #0-$num_cust_svc ?
3269       $part_svc->{'Hash'}{'cust_pkg_svc'} =
3270         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : [];
3271       $part_svc;
3272     } $self->extra_part_svc;
3273   }
3274
3275   @part_svc;
3276
3277 }
3278
3279 =item extra_part_svc
3280
3281 Returns a list of FS::part_svc objects corresponding to services in this
3282 package which are still provisioned but not (any longer) available in the
3283 package definition.
3284
3285 =cut
3286
3287 sub extra_part_svc {
3288   my $self = shift;
3289
3290   my $pkgnum  = $self->pkgnum;
3291   #my $pkgpart = $self->pkgpart;
3292
3293 #  qsearch( {
3294 #    'table'     => 'part_svc',
3295 #    'hashref'   => {},
3296 #    'extra_sql' =>
3297 #      "WHERE 0 = ( SELECT COUNT(*) FROM pkg_svc
3298 #                     WHERE pkg_svc.svcpart = part_svc.svcpart
3299 #                       AND pkg_svc.pkgpart = ?
3300 #                       AND quantity > 0
3301 #                 )
3302 #        AND 0 < ( SELECT COUNT(*) FROM cust_svc
3303 #                       LEFT JOIN cust_pkg USING ( pkgnum )
3304 #                     WHERE cust_svc.svcpart = part_svc.svcpart
3305 #                       AND pkgnum = ?
3306 #                 )",
3307 #    'extra_param' => [ [$self->pkgpart=>'int'], [$self->pkgnum=>'int'] ],
3308 #  } );
3309
3310 #seems to benchmark slightly faster... (or did?)
3311
3312   my @pkgparts = map $_->pkgpart, $self->part_pkg->self_and_svc_linked;
3313   my $pkgparts = join(',', @pkgparts);
3314
3315   qsearch( {
3316     #'select'      => 'DISTINCT ON (svcpart) part_svc.*',
3317     #MySQL doesn't grok DISINCT ON
3318     'select'      => 'DISTINCT part_svc.*',
3319     'table'       => 'part_svc',
3320     'addl_from'   =>
3321       "LEFT JOIN pkg_svc  ON (     pkg_svc.svcpart   = part_svc.svcpart
3322                                AND pkg_svc.pkgpart IN ($pkgparts)
3323                                AND quantity > 0
3324                              )
3325        LEFT JOIN cust_svc ON (     cust_svc.svcpart = part_svc.svcpart )
3326        LEFT JOIN cust_pkg USING ( pkgnum )
3327       ",
3328     'hashref'     => {},
3329     'extra_sql'   => "WHERE pkgsvcnum IS NULL AND cust_pkg.pkgnum = ? ",
3330     'extra_param' => [ [$self->pkgnum=>'int'] ],
3331   } );
3332 }
3333
3334 =item status
3335
3336 Returns a short status string for this package, currently:
3337
3338 =over 4
3339
3340 =item on hold
3341
3342 =item not yet billed
3343
3344 =item one-time charge
3345
3346 =item active
3347
3348 =item suspended
3349
3350 =item cancelled
3351
3352 =back
3353
3354 =cut
3355
3356 sub status {
3357   my $self = shift;
3358
3359   my $freq = length($self->freq) ? $self->freq : $self->part_pkg->freq;
3360
3361   return 'cancelled' if $self->get('cancel');
3362   return 'on hold' if $self->susp && ! $self->setup;
3363   return 'suspended' if $self->susp;
3364   return 'not yet billed' unless $self->setup;
3365   return 'one-time charge' if $freq =~ /^(0|$)/;
3366   return 'active';
3367 }
3368
3369 =item ucfirst_status
3370
3371 Returns the status with the first character capitalized.
3372
3373 =cut
3374
3375 sub ucfirst_status {
3376   ucfirst(shift->status);
3377 }
3378
3379 =item statuses
3380
3381 Class method that returns the list of possible status strings for packages
3382 (see L<the status method|/status>).  For example:
3383
3384   @statuses = FS::cust_pkg->statuses();
3385
3386 =cut
3387
3388 tie my %statuscolor, 'Tie::IxHash',
3389   'on hold'         => 'FF00F5', #brighter purple!
3390   'not yet billed'  => '009999', #teal? cyan?
3391   'one-time charge' => '0000CC', #blue  #'000000',
3392   'active'          => '00CC00',
3393   'suspended'       => 'FF9900',
3394   'cancelled'       => 'FF0000',
3395 ;
3396
3397 sub statuses {
3398   my $self = shift; #could be class...
3399   #grep { $_ !~ /^(not yet billed)$/ } #this is a dumb status anyway
3400   #                                    # mayble split btw one-time vs. recur
3401     keys %statuscolor;
3402 }
3403
3404 sub statuscolors {
3405   #my $self = shift;
3406   \%statuscolor;
3407 }
3408
3409 =item statuscolor
3410
3411 Returns a hex triplet color string for this package's status.
3412
3413 =cut
3414
3415 sub statuscolor {
3416   my $self = shift;
3417   $statuscolor{$self->status};
3418 }
3419
3420 =item is_status_delay_cancel
3421
3422 Returns true if part_pkg has option delay_cancel,
3423 cust_pkg status is 'suspended' and expire is set
3424 to cancel package within the next day (or however
3425 many days are set in global config part_pkg-delay_cancel-days.
3426
3427 This is not a real status, this only meant for hacking display
3428 values, because otherwise treating the package as suspended is
3429 really the whole point of the delay_cancel option.
3430
3431 =cut
3432
3433 sub is_status_delay_cancel {
3434   my ($self) = @_;
3435   if ( $self->main_pkgnum and $self->pkglinknum ) {
3436     return $self->main_pkg->is_status_delay_cancel;
3437   }
3438   return 0 unless $self->part_pkg->option('delay_cancel',1);
3439   return 0 unless $self->status eq 'suspended';
3440   return 0 unless $self->expire;
3441   my $conf = new FS::Conf;
3442   my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
3443   my $expsecs = 60*60*24*$expdays;
3444   return 0 unless $self->expire < time + $expsecs;
3445   return 1;
3446 }
3447
3448 =item pkg_label
3449
3450 Returns a label for this package.  (Currently "pkgnum: pkg - comment" or
3451 "pkg - comment" depending on user preference).
3452
3453 =cut
3454
3455 sub pkg_label {
3456   my $self = shift;
3457   my $label = $self->part_pkg->pkg_comment( 'nopkgpart' => 1 );
3458   $label = $self->pkgnum. ": $label"
3459     if $FS::CurrentUser::CurrentUser->option('show_pkgnum');
3460   $label;
3461 }
3462
3463 =item pkg_label_long
3464
3465 Returns a long label for this package, adding the primary service's label to
3466 pkg_label.
3467
3468 =cut
3469
3470 sub pkg_label_long {
3471   my $self = shift;
3472   my $label = $self->pkg_label;
3473   my $cust_svc = $self->primary_cust_svc;
3474   $label .= ' ('. ($cust_svc->label)[1]. ')' if $cust_svc;
3475   $label;
3476 }
3477
3478 =item pkg_locale
3479
3480 Returns a customer-localized label for this package.
3481
3482 =cut
3483
3484 sub pkg_locale {
3485   my $self = shift;
3486   $self->part_pkg->pkg_locale( $self->cust_main->locale );
3487 }
3488
3489 =item primary_cust_svc
3490
3491 Returns a primary service (as FS::cust_svc object) if one can be identified.
3492
3493 =cut
3494
3495 #for labeling purposes - might not 100% match up with part_pkg->svcpart's idea
3496
3497 sub primary_cust_svc {
3498   my $self = shift;
3499
3500   my @cust_svc = $self->cust_svc;
3501
3502   return '' unless @cust_svc; #no serivces - irrelevant then
3503
3504   return $cust_svc[0] if scalar(@cust_svc) == 1; #always return a single service
3505
3506   # primary service as specified in the package definition
3507   # or exactly one service definition with quantity one
3508   my $svcpart = $self->part_pkg->svcpart;
3509   @cust_svc = grep { $_->svcpart == $svcpart } @cust_svc;
3510   return $cust_svc[0] if scalar(@cust_svc) == 1;
3511
3512   #couldn't identify one thing..
3513   return '';
3514 }
3515
3516 =item labels
3517
3518 Returns a list of lists, calling the label method for all services
3519 (see L<FS::cust_svc>) of this billing item.
3520
3521 =cut
3522
3523 sub labels {
3524   my $self = shift;
3525   map { [ $_->label ] } $self->cust_svc;
3526 }
3527
3528 =item h_labels END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3529
3530 Like the labels method, but returns historical information on services that
3531 were active as of END_TIMESTAMP and (optionally) not cancelled before
3532 START_TIMESTAMP.  If MODE is 'I' (for 'invoice'), services with the
3533 I<pkg_svc.hidden> flag will be omitted.
3534
3535 Returns a list of lists, calling the label method for all (historical) services
3536 (see L<FS::h_cust_svc>) of this billing item.
3537
3538 =cut
3539
3540 sub h_labels {
3541   my $self = shift;
3542   warn "$me _h_labels called on $self\n"
3543     if $DEBUG;
3544   map { [ $_->label(@_) ] } $self->h_cust_svc(@_);
3545 }
3546
3547 =item labels_short
3548
3549 Like labels, except returns a simple flat list, and shortens long
3550 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3551 identical services to one line that lists the service label and the number of
3552 individual services rather than individual items.
3553
3554 =cut
3555
3556 sub labels_short {
3557   shift->_labels_short( 'labels', @_ );
3558 }
3559
3560 =item h_labels_short END_TIMESTAMP [ START_TIMESTAMP ]
3561
3562 Like h_labels, except returns a simple flat list, and shortens long
3563 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3564 identical services to one line that lists the service label and the number of
3565 individual services rather than individual items.
3566
3567 =cut
3568
3569 sub h_labels_short {
3570   shift->_labels_short( 'h_labels', @_ );
3571 }
3572
3573 sub _labels_short {
3574   my( $self, $method ) = ( shift, shift );
3575
3576   warn "$me _labels_short called on $self with $method method\n"
3577     if $DEBUG;
3578
3579   my $conf = new FS::Conf;
3580   my $max_same_services = $conf->config('cust_bill-max_same_services') || 5;
3581
3582   warn "$me _labels_short populating \%labels\n"
3583     if $DEBUG;
3584
3585   my %labels;
3586   #tie %labels, 'Tie::IxHash';
3587   push @{ $labels{$_->[0]} }, $_->[1]
3588     foreach $self->$method(@_);
3589
3590   warn "$me _labels_short populating \@labels\n"
3591     if $DEBUG;
3592
3593   my @labels;
3594   foreach my $label ( keys %labels ) {
3595     my %seen = ();
3596     my @values = grep { ! $seen{$_}++ } @{ $labels{$label} };
3597     my $num = scalar(@values);
3598     warn "$me _labels_short $num items for $label\n"
3599       if $DEBUG;
3600
3601     if ( $num > $max_same_services ) {
3602       warn "$me _labels_short   more than $max_same_services, so summarizing\n"
3603         if $DEBUG;
3604       push @labels, "$label ($num)";
3605     } else {
3606       if ( $conf->exists('cust_bill-consolidate_services') ) {
3607         warn "$me _labels_short   consolidating services\n"
3608           if $DEBUG;
3609         # push @labels, "$label: ". join(', ', @values);
3610         while ( @values ) {
3611           my $detail = "$label: ";
3612           $detail .= shift(@values). ', '
3613             while @values
3614                && ( length($detail.$values[0]) < 78 || $detail eq "$label: " );
3615           $detail =~ s/, $//;
3616           push @labels, $detail;
3617         }
3618         warn "$me _labels_short   done consolidating services\n"
3619           if $DEBUG;
3620       } else {
3621         warn "$me _labels_short   adding service data\n"
3622           if $DEBUG;
3623         push @labels, map { "$label: $_" } @values;
3624       }
3625     }
3626   }
3627
3628  @labels;
3629
3630 }
3631
3632 =item cust_main
3633
3634 Returns the parent customer object (see L<FS::cust_main>).
3635
3636 =cut
3637
3638 sub cust_main {
3639   my $self = shift;
3640   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
3641 }
3642
3643 =item balance
3644
3645 Returns the balance for this specific package, when using
3646 experimental package balance.
3647
3648 =cut
3649
3650 sub balance {
3651   my $self = shift;
3652   $self->cust_main->balance_pkgnum( $self->pkgnum );
3653 }
3654
3655 #these subs are in location_Mixin.pm now... unfortunately the POD doesn't mixin
3656
3657 =item cust_location
3658
3659 Returns the location object, if any (see L<FS::cust_location>).
3660
3661 =item cust_location_or_main
3662
3663 If this package is associated with a location, returns the locaiton (see
3664 L<FS::cust_location>), otherwise returns the customer (see L<FS::cust_main>).
3665
3666 =item location_label [ OPTION => VALUE ... ]
3667
3668 Returns the label of the location object (see L<FS::cust_location>).
3669
3670 =cut
3671
3672 #end of subs in location_Mixin.pm now... unfortunately the POD doesn't mixin
3673
3674 =item tax_locationnum
3675
3676 Returns the foreign key to a L<FS::cust_location> object for calculating
3677 tax on this package, as determined by the C<tax-pkg_address> and
3678 C<tax-ship_address> configuration flags.
3679
3680 =cut
3681
3682 sub tax_locationnum {
3683   my $self = shift;
3684   my $conf = FS::Conf->new;
3685   if ( $conf->exists('tax-pkg_address') ) {
3686     return $self->locationnum;
3687   }
3688   elsif ( $conf->exists('tax-ship_address') ) {
3689     return $self->cust_main->ship_locationnum;
3690   }
3691   else {
3692     return $self->cust_main->bill_locationnum;
3693   }
3694 }
3695
3696 =item tax_location
3697
3698 Returns the L<FS::cust_location> object for tax_locationnum.
3699
3700 =cut
3701
3702 sub tax_location {
3703   my $self = shift;
3704   my $conf = FS::Conf->new;
3705   if ( $conf->exists('tax-pkg_address') and $self->locationnum ) {
3706     return FS::cust_location->by_key($self->locationnum);
3707   }
3708   elsif ( $conf->exists('tax-ship_address') ) {
3709     return $self->cust_main->ship_location;
3710   }
3711   else {
3712     return $self->cust_main->bill_location;
3713   }
3714 }
3715
3716 =item seconds_since TIMESTAMP
3717
3718 Returns the number of seconds all accounts (see L<FS::svc_acct>) in this
3719 package have been online since TIMESTAMP, according to the session monitor.
3720
3721 TIMESTAMP is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
3722 L<Time::Local> and L<Date::Parse> for conversion functions.
3723
3724 =cut
3725
3726 sub seconds_since {
3727   my($self, $since) = @_;
3728   my $seconds = 0;
3729
3730   foreach my $cust_svc (
3731     grep { $_->part_svc->svcdb eq 'svc_acct' } $self->cust_svc
3732   ) {
3733     $seconds += $cust_svc->seconds_since($since);
3734   }
3735
3736   $seconds;
3737
3738 }
3739
3740 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
3741
3742 Returns the numbers of seconds all accounts (see L<FS::svc_acct>) in this
3743 package have been online between TIMESTAMP_START (inclusive) and TIMESTAMP_END
3744 (exclusive).
3745
3746 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3747 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3748 functions.
3749
3750
3751 =cut
3752
3753 sub seconds_since_sqlradacct {
3754   my($self, $start, $end) = @_;
3755
3756   my $seconds = 0;
3757
3758   foreach my $cust_svc (
3759     grep {
3760       my $part_svc = $_->part_svc;
3761       $part_svc->svcdb eq 'svc_acct'
3762         && scalar($part_svc->part_export_usage);
3763     } $self->cust_svc
3764   ) {
3765     $seconds += $cust_svc->seconds_since_sqlradacct($start, $end);
3766   }
3767
3768   $seconds;
3769
3770 }
3771
3772 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
3773
3774 Returns the sum of the given attribute for all accounts (see L<FS::svc_acct>)
3775 in this package for sessions ending between TIMESTAMP_START (inclusive) and
3776 TIMESTAMP_END
3777 (exclusive).
3778
3779 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3780 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3781 functions.
3782
3783 =cut
3784
3785 sub attribute_since_sqlradacct {
3786   my($self, $start, $end, $attrib) = @_;
3787
3788   my $sum = 0;
3789
3790   foreach my $cust_svc (
3791     grep {
3792       my $part_svc = $_->part_svc;
3793       scalar($part_svc->part_export_usage);
3794     } $self->cust_svc
3795   ) {
3796     $sum += $cust_svc->attribute_since_sqlradacct($start, $end, $attrib);
3797   }
3798
3799   $sum;
3800
3801 }
3802
3803 =item quantity
3804
3805 =cut
3806
3807 sub quantity {
3808   my( $self, $value ) = @_;
3809   if ( defined($value) ) {
3810     $self->setfield('quantity', $value);
3811   }
3812   $self->getfield('quantity') || 1;
3813 }
3814
3815 =item transfer DEST_PKGNUM | DEST_CUST_PKG, [ OPTION => VALUE ... ]
3816
3817 Transfers as many services as possible from this package to another package.
3818
3819 The destination package can be specified by pkgnum by passing an FS::cust_pkg
3820 object.  The destination package must already exist.
3821
3822 Services are moved only if the destination allows services with the correct
3823 I<svcpart> (not svcdb), unless the B<change_svcpart> option is set true.  Use
3824 this option with caution!  No provision is made for export differences
3825 between the old and new service definitions.  Probably only should be used
3826 when your exports for all service definitions of a given svcdb are identical.
3827 (attempt a transfer without it first, to move all possible svcpart-matching
3828 services)
3829
3830 Any services that can't be moved remain in the original package.
3831
3832 Returns an error, if there is one; otherwise, returns the number of services
3833 that couldn't be moved.
3834
3835 =cut
3836
3837 sub transfer {
3838   my ($self, $dest_pkgnum, %opt) = @_;
3839
3840   my $remaining = 0;
3841   my $dest;
3842   my %target;
3843
3844   if (ref ($dest_pkgnum) eq 'FS::cust_pkg') {
3845     $dest = $dest_pkgnum;
3846     $dest_pkgnum = $dest->pkgnum;
3847   } else {
3848     $dest = qsearchs('cust_pkg', { pkgnum => $dest_pkgnum });
3849   }
3850
3851   return ('Package does not exist: '.$dest_pkgnum) unless $dest;
3852
3853   foreach my $pkg_svc ( $dest->part_pkg->pkg_svc ) {
3854     $target{$pkg_svc->svcpart} = $pkg_svc->quantity * ( $dest->quantity || 1 );
3855   }
3856
3857   foreach my $cust_svc ($dest->cust_svc) {
3858     $target{$cust_svc->svcpart}--;
3859   }
3860
3861   my %svcpart2svcparts = ();
3862   if ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3863     warn "change_svcpart option received, creating alternates list\n" if $DEBUG;
3864     foreach my $svcpart ( map { $_->svcpart } $self->cust_svc ) {
3865       next if exists $svcpart2svcparts{$svcpart};
3866       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
3867       $svcpart2svcparts{$svcpart} = [
3868         map  { $_->[0] }
3869         sort { $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] }
3870         map {
3871               my $pkg_svc = qsearchs( 'pkg_svc', { 'pkgpart' => $dest->pkgpart,
3872                                                    'svcpart' => $_          } );
3873               [ $_,
3874                 $pkg_svc ? $pkg_svc->primary_svc : '',
3875                 $pkg_svc ? $pkg_svc->quantity : 0,
3876               ];
3877             }
3878
3879         grep { $_ != $svcpart }
3880         map  { $_->svcpart }
3881         qsearch('part_svc', { 'svcdb' => $part_svc->svcdb } )
3882       ];
3883       warn "alternates for svcpart $svcpart: ".
3884            join(', ', @{$svcpart2svcparts{$svcpart}}). "\n"
3885         if $DEBUG;
3886     }
3887   }
3888
3889   my $error;
3890   foreach my $cust_svc ($self->cust_svc) {
3891     my $svcnum = $cust_svc->svcnum;
3892     if($target{$cust_svc->svcpart} > 0
3893        or $FS::cust_svc::ignore_quantity) { # maybe should be a 'force' option
3894       $target{$cust_svc->svcpart}--;
3895       my $new = new FS::cust_svc { $cust_svc->hash };
3896       $new->pkgnum($dest_pkgnum);
3897       $error = $new->replace($cust_svc);
3898     } elsif ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3899       if ( $DEBUG ) {
3900         warn "looking for alternates for svcpart ". $cust_svc->svcpart. "\n";
3901         warn "alternates to consider: ".
3902              join(', ', @{$svcpart2svcparts{$cust_svc->svcpart}}). "\n";
3903       }
3904       my @alternate = grep {
3905                              warn "considering alternate svcpart $_: ".
3906                                   "$target{$_} available in new package\n"
3907                                if $DEBUG;
3908                              $target{$_} > 0;
3909                            } @{$svcpart2svcparts{$cust_svc->svcpart}};
3910       if ( @alternate ) {
3911         warn "alternate(s) found\n" if $DEBUG;
3912         my $change_svcpart = $alternate[0];
3913         $target{$change_svcpart}--;
3914         my $new = new FS::cust_svc { $cust_svc->hash };
3915         $new->svcpart($change_svcpart);
3916         $new->pkgnum($dest_pkgnum);
3917         $error = $new->replace($cust_svc);
3918       } else {
3919         $remaining++;
3920       }
3921     } else {
3922       $remaining++
3923     }
3924     if ( $error ) {
3925       my @label = $cust_svc->label;
3926       return "service $label[1]: $error";
3927     }
3928   }
3929   return $remaining;
3930 }
3931
3932 =item grab_svcnums SVCNUM, SVCNUM ...
3933
3934 Change the pkgnum for the provided services to this packages.  If there is an
3935 error, returns the error, otherwise returns false.
3936
3937 =cut
3938
3939 sub grab_svcnums {
3940   my $self = shift;
3941   my @svcnum = @_;
3942
3943   local $SIG{HUP} = 'IGNORE';
3944   local $SIG{INT} = 'IGNORE';
3945   local $SIG{QUIT} = 'IGNORE';
3946   local $SIG{TERM} = 'IGNORE';
3947   local $SIG{TSTP} = 'IGNORE';
3948   local $SIG{PIPE} = 'IGNORE';
3949
3950   my $oldAutoCommit = $FS::UID::AutoCommit;
3951   local $FS::UID::AutoCommit = 0;
3952   my $dbh = dbh;
3953
3954   foreach my $svcnum (@svcnum) {
3955     my $cust_svc = qsearchs('cust_svc', { svcnum=>$svcnum } ) or do {
3956       $dbh->rollback if $oldAutoCommit;
3957       return "unknown svcnum $svcnum";
3958     };
3959     $cust_svc->pkgnum( $self->pkgnum );
3960     my $error = $cust_svc->replace;
3961     if ( $error ) {
3962       $dbh->rollback if $oldAutoCommit;
3963       return $error;
3964     }
3965   }
3966
3967   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3968   '';
3969
3970 }
3971
3972 =item reexport
3973
3974 This method is deprecated.  See the I<depend_jobnum> option to the insert and
3975 order_pkgs methods in FS::cust_main for a better way to defer provisioning.
3976
3977 =cut
3978
3979 sub reexport {
3980   my $self = shift;
3981
3982   local $SIG{HUP} = 'IGNORE';
3983   local $SIG{INT} = 'IGNORE';
3984   local $SIG{QUIT} = 'IGNORE';
3985   local $SIG{TERM} = 'IGNORE';
3986   local $SIG{TSTP} = 'IGNORE';
3987   local $SIG{PIPE} = 'IGNORE';
3988
3989   my $oldAutoCommit = $FS::UID::AutoCommit;
3990   local $FS::UID::AutoCommit = 0;
3991   my $dbh = dbh;
3992
3993   foreach my $cust_svc ( $self->cust_svc ) {
3994     #false laziness w/svc_Common::insert
3995     my $svc_x = $cust_svc->svc_x;
3996     foreach my $part_export ( $cust_svc->part_svc->part_export ) {
3997       my $error = $part_export->export_insert($svc_x);
3998       if ( $error ) {
3999         $dbh->rollback if $oldAutoCommit;
4000         return $error;
4001       }
4002     }
4003   }
4004
4005   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4006   '';
4007
4008 }
4009
4010 =item export_pkg_change OLD_CUST_PKG
4011
4012 Calls the "pkg_change" export action for all services attached to this package.
4013
4014 =cut
4015
4016 sub export_pkg_change {
4017   my( $self, $old )  = ( shift, shift );
4018
4019   local $SIG{HUP} = 'IGNORE';
4020   local $SIG{INT} = 'IGNORE';
4021   local $SIG{QUIT} = 'IGNORE';
4022   local $SIG{TERM} = 'IGNORE';
4023   local $SIG{TSTP} = 'IGNORE';
4024   local $SIG{PIPE} = 'IGNORE';
4025
4026   my $oldAutoCommit = $FS::UID::AutoCommit;
4027   local $FS::UID::AutoCommit = 0;
4028   my $dbh = dbh;
4029
4030   foreach my $svc_x ( map $_->svc_x, $self->cust_svc ) {
4031     my $error = $svc_x->export('pkg_change', $self, $old);
4032     if ( $error ) {
4033       $dbh->rollback if $oldAutoCommit;
4034       return $error;
4035     }
4036   }
4037
4038   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4039   '';
4040
4041 }
4042
4043 =item insert_reason
4044
4045 Associates this package with a (suspension or cancellation) reason (see
4046 L<FS::cust_pkg_reason>, possibly inserting a new reason on the fly (see
4047 L<FS::reason>).
4048
4049 Available options are:
4050
4051 =over 4
4052
4053 =item reason
4054
4055 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
4056
4057 =item reason_otaker
4058
4059 the access_user (see L<FS::access_user>) providing the reason
4060
4061 =item date
4062
4063 a unix timestamp
4064
4065 =item action
4066
4067 the action (cancel, susp, adjourn, expire) associated with the reason
4068
4069 =back
4070
4071 If there is an error, returns the error, otherwise returns false.
4072
4073 =cut
4074
4075 sub insert_reason {
4076   my ($self, %options) = @_;
4077
4078   my $otaker = $options{reason_otaker} ||
4079                $FS::CurrentUser::CurrentUser->username;
4080
4081   my $reasonnum;
4082   if ( $options{'reason'} =~ /^(\d+)$/ ) {
4083
4084     $reasonnum = $1;
4085
4086   } elsif ( ref($options{'reason'}) ) {
4087
4088     return 'Enter a new reason (or select an existing one)'
4089       unless $options{'reason'}->{'reason'} !~ /^\s*$/;
4090
4091     my $reason = new FS::reason({
4092       'reason_type' => $options{'reason'}->{'typenum'},
4093       'reason'      => $options{'reason'}->{'reason'},
4094     });
4095     my $error = $reason->insert;
4096     return $error if $error;
4097
4098     $reasonnum = $reason->reasonnum;
4099
4100   } else {
4101     return "Unparseable reason: ". $options{'reason'};
4102   }
4103
4104   my $cust_pkg_reason =
4105     new FS::cust_pkg_reason({ 'pkgnum'    => $self->pkgnum,
4106                               'reasonnum' => $reasonnum,
4107                               'otaker'    => $otaker,
4108                               'action'    => substr(uc($options{'action'}),0,1),
4109                               'date'      => $options{'date'}
4110                                                ? $options{'date'}
4111                                                : time,
4112                             });
4113
4114   $cust_pkg_reason->insert;
4115 }
4116
4117 =item insert_discount
4118
4119 Associates this package with a discount (see L<FS::cust_pkg_discount>, possibly
4120 inserting a new discount on the fly (see L<FS::discount>).
4121
4122 Available options are:
4123
4124 =over 4
4125
4126 =item discountnum
4127
4128 =back
4129
4130 If there is an error, returns the error, otherwise returns false.
4131
4132 =cut
4133
4134 sub insert_discount {
4135   #my ($self, %options) = @_;
4136   my $self = shift;
4137
4138   my $cust_pkg_discount = new FS::cust_pkg_discount {
4139     'pkgnum'      => $self->pkgnum,
4140     'discountnum' => $self->discountnum,
4141     'months_used' => 0,
4142     'end_date'    => '', #XXX
4143     #for the create a new discount case
4144     '_type'       => $self->discountnum__type,
4145     'amount'      => $self->discountnum_amount,
4146     'percent'     => $self->discountnum_percent,
4147     'months'      => $self->discountnum_months,
4148     'setup'      => $self->discountnum_setup,
4149     #'disabled'    => $self->discountnum_disabled,
4150   };
4151
4152   $cust_pkg_discount->insert;
4153 }
4154
4155 =item set_usage USAGE_VALUE_HASHREF
4156
4157 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4158 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4159 upbytes, downbytes, and totalbytes are appropriate keys.
4160
4161 All svc_accts which are part of this package have their values reset.
4162
4163 =cut
4164
4165 sub set_usage {
4166   my ($self, $valueref, %opt) = @_;
4167
4168   #only svc_acct can set_usage for now
4169   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4170     my $svc_x = $cust_svc->svc_x;
4171     $svc_x->set_usage($valueref, %opt)
4172       if $svc_x->can("set_usage");
4173   }
4174 }
4175
4176 =item recharge USAGE_VALUE_HASHREF
4177
4178 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4179 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4180 upbytes, downbytes, and totalbytes are appropriate keys.
4181
4182 All svc_accts which are part of this package have their values incremented.
4183
4184 =cut
4185
4186 sub recharge {
4187   my ($self, $valueref) = @_;
4188
4189   #only svc_acct can set_usage for now
4190   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4191     my $svc_x = $cust_svc->svc_x;
4192     $svc_x->recharge($valueref)
4193       if $svc_x->can("recharge");
4194   }
4195 }
4196
4197 =item cust_pkg_discount
4198
4199 =cut
4200
4201 sub cust_pkg_discount {
4202   my $self = shift;
4203   qsearch('cust_pkg_discount', { 'pkgnum' => $self->pkgnum } );
4204 }
4205
4206 =item cust_pkg_discount_active
4207
4208 =cut
4209
4210 sub cust_pkg_discount_active {
4211   my $self = shift;
4212   grep { $_->status eq 'active' } $self->cust_pkg_discount;
4213 }
4214
4215 =item cust_pkg_usage
4216
4217 Returns a list of all voice usage counters attached to this package.
4218
4219 =cut
4220
4221 sub cust_pkg_usage {
4222   my $self = shift;
4223   qsearch('cust_pkg_usage', { pkgnum => $self->pkgnum });
4224 }
4225
4226 =item apply_usage OPTIONS
4227
4228 Takes the following options:
4229 - cdr: a call detail record (L<FS::cdr>)
4230 - rate_detail: the rate determined for this call (L<FS::rate_detail>)
4231 - minutes: the maximum number of minutes to be charged
4232
4233 Finds available usage minutes for a call of this class, and subtracts
4234 up to that many minutes from the usage pool.  If the usage pool is empty,
4235 and the C<cdr-minutes_priority> global config option is set, minutes may
4236 be taken from other calls as well.  Either way, an allocation record will
4237 be created (L<FS::cdr_cust_pkg_usage>) and this method will return the
4238 number of minutes of usage applied to the call.
4239
4240 =cut
4241
4242 sub apply_usage {
4243   my ($self, %opt) = @_;
4244   my $cdr = $opt{cdr};
4245   my $rate_detail = $opt{rate_detail};
4246   my $minutes = $opt{minutes};
4247   my $classnum = $rate_detail->classnum;
4248   my $pkgnum = $self->pkgnum;
4249   my $custnum = $self->custnum;
4250
4251   local $SIG{HUP} = 'IGNORE';
4252   local $SIG{INT} = 'IGNORE';
4253   local $SIG{QUIT} = 'IGNORE';
4254   local $SIG{TERM} = 'IGNORE';
4255   local $SIG{TSTP} = 'IGNORE';
4256   local $SIG{PIPE} = 'IGNORE';
4257
4258   my $oldAutoCommit = $FS::UID::AutoCommit;
4259   local $FS::UID::AutoCommit = 0;
4260   my $dbh = dbh;
4261   my $order = FS::Conf->new->config('cdr-minutes_priority');
4262
4263   my $is_classnum;
4264   if ( $classnum ) {
4265     $is_classnum = ' part_pkg_usage_class.classnum = '.$classnum;
4266   } else {
4267     $is_classnum = ' part_pkg_usage_class.classnum IS NULL';
4268   }
4269   my @usage_recs = qsearch({
4270       'table'     => 'cust_pkg_usage',
4271       'addl_from' => ' JOIN part_pkg_usage       USING (pkgusagepart)'.
4272                      ' JOIN cust_pkg             USING (pkgnum)'.
4273                      ' JOIN part_pkg_usage_class USING (pkgusagepart)',
4274       'select'    => 'cust_pkg_usage.*',
4275       'extra_sql' => " WHERE ( cust_pkg.pkgnum = $pkgnum OR ".
4276                      " ( cust_pkg.custnum = $custnum AND ".
4277                      " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4278                      $is_classnum . ' AND '.
4279                      " cust_pkg_usage.minutes > 0",
4280       'order_by'  => " ORDER BY priority ASC",
4281   });
4282
4283   my $orig_minutes = $minutes;
4284   my $error;
4285   while (!$error and $minutes > 0 and @usage_recs) {
4286     my $cust_pkg_usage = shift @usage_recs;
4287     $cust_pkg_usage->select_for_update;
4288     my $cdr_cust_pkg_usage = FS::cdr_cust_pkg_usage->new({
4289         pkgusagenum => $cust_pkg_usage->pkgusagenum,
4290         acctid      => $cdr->acctid,
4291         minutes     => min($cust_pkg_usage->minutes, $minutes),
4292     });
4293     $cust_pkg_usage->set('minutes',
4294       $cust_pkg_usage->minutes - $cdr_cust_pkg_usage->minutes
4295     );
4296     $error = $cust_pkg_usage->replace || $cdr_cust_pkg_usage->insert;
4297     $minutes -= $cdr_cust_pkg_usage->minutes;
4298   }
4299   if ( $order and $minutes > 0 and !$error ) {
4300     # then try to steal minutes from another call
4301     my %search = (
4302         'table'     => 'cdr_cust_pkg_usage',
4303         'addl_from' => ' JOIN cust_pkg_usage        USING (pkgusagenum)'.
4304                        ' JOIN part_pkg_usage        USING (pkgusagepart)'.
4305                        ' JOIN cust_pkg              USING (pkgnum)'.
4306                        ' JOIN part_pkg_usage_class  USING (pkgusagepart)'.
4307                        ' JOIN cdr                   USING (acctid)',
4308         'select'    => 'cdr_cust_pkg_usage.*',
4309         'extra_sql' => " WHERE cdr.freesidestatus = 'rated' AND ".
4310                        " ( cust_pkg.pkgnum = $pkgnum OR ".
4311                        " ( cust_pkg.custnum = $custnum AND ".
4312                        " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4313                        " part_pkg_usage_class.classnum = $classnum",
4314         'order_by'  => ' ORDER BY part_pkg_usage.priority ASC',
4315     );
4316     if ( $order eq 'time' ) {
4317       # find CDRs that are using minutes, but have a later startdate
4318       # than this call
4319       my $startdate = $cdr->startdate;
4320       if ($startdate !~ /^\d+$/) {
4321         die "bad cdr startdate '$startdate'";
4322       }
4323       $search{'extra_sql'} .= " AND cdr.startdate > $startdate";
4324       # minimize needless reshuffling
4325       $search{'order_by'} .= ', cdr.startdate DESC';
4326     } else {
4327       # XXX may not work correctly with rate_time schedules.  Could
4328       # fix this by storing ratedetailnum in cdr_cust_pkg_usage, I
4329       # think...
4330       $search{'addl_from'} .=
4331         ' JOIN rate_detail'.
4332         ' ON (cdr.rated_ratedetailnum = rate_detail.ratedetailnum)';
4333       if ( $order eq 'rate_high' ) {
4334         $search{'extra_sql'} .= ' AND rate_detail.min_charge < '.
4335                                 $rate_detail->min_charge;
4336         $search{'order_by'} .= ', rate_detail.min_charge ASC';
4337       } elsif ( $order eq 'rate_low' ) {
4338         $search{'extra_sql'} .= ' AND rate_detail.min_charge > '.
4339                                 $rate_detail->min_charge;
4340         $search{'order_by'} .= ', rate_detail.min_charge DESC';
4341       } else {
4342         #  this should really never happen
4343         die "invalid cdr-minutes_priority value '$order'\n";
4344       }
4345     }
4346     my @cdr_usage_recs = qsearch(\%search);
4347     my %reproc_cdrs;
4348     while (!$error and @cdr_usage_recs and $minutes > 0) {
4349       my $cdr_cust_pkg_usage = shift @cdr_usage_recs;
4350       my $cust_pkg_usage = $cdr_cust_pkg_usage->cust_pkg_usage;
4351       my $old_cdr = $cdr_cust_pkg_usage->cdr;
4352       $reproc_cdrs{$old_cdr->acctid} = $old_cdr;
4353       $cdr_cust_pkg_usage->select_for_update;
4354       $old_cdr->select_for_update;
4355       $cust_pkg_usage->select_for_update;
4356       # in case someone else stole the usage from this CDR
4357       # while waiting for the lock...
4358       next if $old_cdr->acctid != $cdr_cust_pkg_usage->acctid;
4359       # steal the usage allocation and flag the old CDR for reprocessing
4360       $cdr_cust_pkg_usage->set('acctid', $cdr->acctid);
4361       # if the allocation is more minutes than we need, adjust it...
4362       my $delta = $cdr_cust_pkg_usage->minutes - $minutes;
4363       if ( $delta > 0 ) {
4364         $cdr_cust_pkg_usage->set('minutes', $minutes);
4365         $cust_pkg_usage->set('minutes', $cust_pkg_usage->minutes + $delta);
4366         $error = $cust_pkg_usage->replace;
4367       }
4368       #warn 'CDR '.$cdr->acctid . ' stealing allocation '.$cdr_cust_pkg_usage->cdrusagenum.' from CDR '.$old_cdr->acctid."\n";
4369       $error ||= $cdr_cust_pkg_usage->replace;
4370       # deduct the stolen minutes
4371       $minutes -= $cdr_cust_pkg_usage->minutes;
4372     }
4373     # after all minute-stealing is done, reset the affected CDRs
4374     foreach (values %reproc_cdrs) {
4375       $error ||= $_->set_status('');
4376       # XXX or should we just call $cdr->rate right here?
4377       # it's not like we can create a loop this way, since the min_charge
4378       # or call time has to go monotonically in one direction.
4379       # we COULD get some very deep recursions going, though...
4380     }
4381   } # if $order and $minutes
4382   if ( $error ) {
4383     $dbh->rollback;
4384     die "error applying included minutes\npkgnum ".$self->pkgnum.", class $classnum, acctid ".$cdr->acctid."\n$error\n"
4385   } else {
4386     $dbh->commit if $oldAutoCommit;
4387     return $orig_minutes - $minutes;
4388   }
4389 }
4390
4391 =item supplemental_pkgs
4392
4393 Returns a list of all packages supplemental to this one.
4394
4395 =cut
4396
4397 sub supplemental_pkgs {
4398   my $self = shift;
4399   qsearch('cust_pkg', { 'main_pkgnum' => $self->pkgnum });
4400 }
4401
4402 =item main_pkg
4403
4404 Returns the package that this one is supplemental to, if any.
4405
4406 =cut
4407
4408 sub main_pkg {
4409   my $self = shift;
4410   if ( $self->main_pkgnum ) {
4411     return FS::cust_pkg->by_key($self->main_pkgnum);
4412   }
4413   return;
4414 }
4415
4416 =back
4417
4418 =head1 CLASS METHODS
4419
4420 =over 4
4421
4422 =item recurring_sql
4423
4424 Returns an SQL expression identifying recurring packages.
4425
4426 =cut
4427
4428 sub recurring_sql { "
4429   '0' != ( select freq from part_pkg
4430              where cust_pkg.pkgpart = part_pkg.pkgpart )
4431 "; }
4432
4433 =item onetime_sql
4434
4435 Returns an SQL expression identifying one-time packages.
4436
4437 =cut
4438
4439 sub onetime_sql { "
4440   '0' = ( select freq from part_pkg
4441             where cust_pkg.pkgpart = part_pkg.pkgpart )
4442 "; }
4443
4444 =item ordered_sql
4445
4446 Returns an SQL expression identifying ordered packages (recurring packages not
4447 yet billed).
4448
4449 =cut
4450
4451 sub ordered_sql {
4452    $_[0]->recurring_sql. " AND ". $_[0]->not_yet_billed_sql;
4453 }
4454
4455 =item active_sql
4456
4457 Returns an SQL expression identifying active packages.
4458
4459 =cut
4460
4461 sub active_sql {
4462   $_[0]->recurring_sql. "
4463   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4464   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4465   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4466 "; }
4467
4468 =item not_yet_billed_sql
4469
4470 Returns an SQL expression identifying packages which have not yet been billed.
4471
4472 =cut
4473
4474 sub not_yet_billed_sql { "
4475       ( cust_pkg.setup  IS NULL OR cust_pkg.setup  = 0 )
4476   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4477   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4478 "; }
4479
4480 =item inactive_sql
4481
4482 Returns an SQL expression identifying inactive packages (one-time packages
4483 that are otherwise unsuspended/uncancelled).
4484
4485 =cut
4486
4487 sub inactive_sql { "
4488   ". $_[0]->onetime_sql(). "
4489   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4490   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4491   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4492 "; }
4493
4494 =item on_hold_sql
4495
4496 Returns an SQL expression identifying on-hold packages.
4497
4498 =cut
4499
4500 sub on_hold_sql {
4501   #$_[0]->recurring_sql(). ' AND '.
4502   "
4503         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel  = 0 )
4504     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp   != 0
4505     AND ( cust_pkg.setup  IS     NULL  OR cust_pkg.setup   = 0 )
4506   ";
4507 }
4508
4509 =item susp_sql
4510 =item suspended_sql
4511
4512 Returns an SQL expression identifying suspended packages.
4513
4514 =cut
4515
4516 sub suspended_sql { susp_sql(@_); }
4517 sub susp_sql {
4518   #$_[0]->recurring_sql(). ' AND '.
4519   "
4520         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel = 0 )
4521     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp  != 0
4522     AND   cust_pkg.setup  IS NOT NULL AND cust_pkg.setup != 0
4523   ";
4524 }
4525
4526 =item cancel_sql
4527 =item cancelled_sql
4528
4529 Returns an SQL exprression identifying cancelled packages.
4530
4531 =cut
4532
4533 sub cancelled_sql { cancel_sql(@_); }
4534 sub cancel_sql {
4535   #$_[0]->recurring_sql(). ' AND '.
4536   "cust_pkg.cancel IS NOT NULL AND cust_pkg.cancel != 0";
4537 }
4538
4539 =item status_sql
4540
4541 Returns an SQL expression to give the package status as a string.
4542
4543 =cut
4544
4545 sub status_sql {
4546 "CASE
4547   WHEN cust_pkg.cancel IS NOT NULL THEN 'cancelled'
4548   WHEN ( cust_pkg.susp IS NOT NULL AND cust_pkg.setup IS NULL ) THEN 'on hold'
4549   WHEN cust_pkg.susp IS NOT NULL THEN 'suspended'
4550   WHEN cust_pkg.setup IS NULL THEN 'not yet billed'
4551   WHEN ".onetime_sql()." THEN 'one-time charge'
4552   ELSE 'active'
4553 END"
4554 }
4555
4556 =item search HASHREF
4557
4558 (Class method)
4559
4560 Returns a qsearch hash expression to search for parameters specified in HASHREF.
4561 Valid parameters are
4562
4563 =over 4
4564
4565 =item agentnum
4566
4567 =item status
4568
4569 on hold, active, inactive (or one-time charge), suspended, canceled (or cancelled)
4570
4571 =item magic
4572
4573 Equivalent to "status", except that "canceled"/"cancelled" will exclude
4574 packages that were changed into a new package with the same pkgpart (i.e.
4575 location or quantity changes).
4576
4577 =item custom
4578
4579  boolean selects custom packages
4580
4581 =item classnum
4582
4583 =item pkgpart
4584
4585 pkgpart or arrayref or hashref of pkgparts
4586
4587 =item setup
4588
4589 arrayref of beginning and ending epoch date
4590
4591 =item last_bill
4592
4593 arrayref of beginning and ending epoch date
4594
4595 =item bill
4596
4597 arrayref of beginning and ending epoch date
4598
4599 =item adjourn
4600
4601 arrayref of beginning and ending epoch date
4602
4603 =item susp
4604
4605 arrayref of beginning and ending epoch date
4606
4607 =item expire
4608
4609 arrayref of beginning and ending epoch date
4610
4611 =item cancel
4612
4613 arrayref of beginning and ending epoch date
4614
4615 =item query
4616
4617 pkgnum or APKG_pkgnum
4618
4619 =item cust_fields
4620
4621 a value suited to passing to FS::UI::Web::cust_header
4622
4623 =item CurrentUser
4624
4625 specifies the user for agent virtualization
4626
4627 =item fcc_line
4628
4629 boolean; if true, returns only packages with more than 0 FCC phone lines.
4630
4631 =item state, country
4632
4633 Limit to packages with a service location in the specified state and country.
4634 For FCC 477 reporting, mostly.
4635
4636 =item location_cust
4637
4638 Limit to packages whose service locations are the same as the customer's
4639 default service location.
4640
4641 =item location_nocust
4642
4643 Limit to packages whose service locations are not the customer's default
4644 service location.
4645
4646 =item location_census
4647
4648 Limit to packages whose service locations have census tracts.
4649
4650 =item location_nocensus
4651
4652 Limit to packages whose service locations do not have a census tract.
4653
4654 =item location_geocode
4655
4656 Limit to packages whose locations have geocodes.
4657
4658 =item location_geocode
4659
4660 Limit to packages whose locations do not have geocodes.
4661
4662 =item towernum
4663
4664 Limit to packages associated with a svc_broadband, associated with a sector,
4665 associated with this towernum (or any of these, if it's an arrayref) (or NO
4666 towernum, if it's zero). This is an extreme niche case.
4667
4668 =item 477part, 477rownum, date
4669
4670 Limit to packages included in a specific row of one of the FCC 477 reports.
4671 '477part' is the section name (see L<FS::Report::FCC_477> methods), 'date'
4672 is the report as-of date (completely unrelated to the package setup/bill/
4673 other date fields), and '477rownum' is the row number of the report starting
4674 with zero. Row numbers have no inherent meaning, so this is useful only
4675 for explaining a 477 report you've already run.
4676
4677 =back
4678
4679 =cut
4680
4681 sub search {
4682   my ($class, $params) = @_;
4683   my @where = ();
4684
4685   ##
4686   # parse agent
4687   ##
4688
4689   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
4690     push @where,
4691       "cust_main.agentnum = $1";
4692   }
4693
4694   ##
4695   # parse cust_status
4696   ##
4697
4698   if ( $params->{'cust_status'} =~ /^([a-z]+)$/ ) {
4699     push @where, FS::cust_main->cust_status_sql . " = '$1' ";
4700   }
4701
4702   ##
4703   # parse customer sales person
4704   ##
4705
4706   if ( $params->{'cust_main_salesnum'} =~ /^(\d+)$/ ) {
4707     push @where, ($1 > 0) ? "cust_main.salesnum = $1"
4708                           : 'cust_main.salesnum IS NULL';
4709   }
4710
4711
4712   ##
4713   # parse sales person
4714   ##
4715
4716   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
4717     push @where, ($1 > 0) ? "cust_pkg.salesnum = $1"
4718                           : 'cust_pkg.salesnum IS NULL';
4719   }
4720
4721   ##
4722   # parse custnum
4723   ##
4724
4725   if ( $params->{'custnum'} =~ /^(\d+)$/ and $1 ) {
4726     push @where,
4727       "cust_pkg.custnum = $1";
4728   }
4729
4730   ##
4731   # custbatch
4732   ##
4733
4734   if ( $params->{'pkgbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
4735     push @where,
4736       "cust_pkg.pkgbatch = '$1'";
4737   }
4738
4739   ##
4740   # parse status
4741   ##
4742
4743   if (    $params->{'magic'}  eq 'active'
4744        || $params->{'status'} eq 'active' ) {
4745
4746     push @where, FS::cust_pkg->active_sql();
4747
4748   } elsif (    $params->{'magic'}  =~ /^not[ _]yet[ _]billed$/
4749             || $params->{'status'} =~ /^not[ _]yet[ _]billed$/ ) {
4750
4751     push @where, FS::cust_pkg->not_yet_billed_sql();
4752
4753   } elsif (    $params->{'magic'}  =~ /^(one-time charge|inactive)/
4754             || $params->{'status'} =~ /^(one-time charge|inactive)/ ) {
4755
4756     push @where, FS::cust_pkg->inactive_sql();
4757
4758   } elsif (    $params->{'magic'}  =~ /^on[ _]hold$/
4759             || $params->{'status'} =~ /^on[ _]hold$/ ) {
4760
4761     push @where, FS::cust_pkg->on_hold_sql();
4762
4763
4764   } elsif (    $params->{'magic'}  eq 'suspended'
4765             || $params->{'status'} eq 'suspended'  ) {
4766
4767     push @where, FS::cust_pkg->suspended_sql();
4768
4769   } elsif (    $params->{'magic'}  =~ /^cancell?ed$/
4770             || $params->{'status'} =~ /^cancell?ed$/ ) {
4771
4772     push @where, FS::cust_pkg->cancelled_sql();
4773
4774   }
4775
4776   ### special case: "magic" is used in detail links from browse/part_pkg,
4777   # where "cancelled" has the restriction "and not replaced with a package
4778   # of the same pkgpart".  Be consistent with that.
4779   ###
4780
4781   if ( $params->{'magic'} =~ /^cancell?ed$/ ) {
4782     my $new_pkgpart = "SELECT pkgpart FROM cust_pkg AS cust_pkg_next ".
4783                       "WHERE cust_pkg_next.change_pkgnum = cust_pkg.pkgnum";
4784     # ...may not exist, if this was just canceled and not changed; in that
4785     # case give it a "new pkgpart" that never equals the old pkgpart
4786     push @where, "COALESCE(($new_pkgpart), 0) != cust_pkg.pkgpart";
4787   }
4788
4789   ###
4790   # parse package class
4791   ###
4792
4793   if ( exists($params->{'classnum'}) ) {
4794
4795     my @classnum = ();
4796     if ( ref($params->{'classnum'}) ) {
4797
4798       if ( ref($params->{'classnum'}) eq 'HASH' ) {
4799         @classnum = grep $params->{'classnum'}{$_}, keys %{ $params->{'classnum'} };
4800       } elsif ( ref($params->{'classnum'}) eq 'ARRAY' ) {
4801         @classnum = @{ $params->{'classnum'} };
4802       } else {
4803         die 'unhandled classnum ref '. $params->{'classnum'};
4804       }
4805
4806
4807     } elsif ( $params->{'classnum'} =~ /^(\d*)$/ && $1 ne '0' ) {
4808       @classnum = ( $1 );
4809     }
4810
4811     if ( @classnum ) {
4812
4813       my @c_where = ();
4814       my @nums = grep $_, @classnum;
4815       push @c_where, 'part_pkg.classnum IN ('. join(',',@nums). ')' if @nums;
4816       my $null = scalar( grep { $_ eq '' } @classnum );
4817       push @c_where, 'part_pkg.classnum IS NULL' if $null;
4818
4819       if ( scalar(@c_where) == 1 ) {
4820         push @where, @c_where;
4821       } elsif ( @c_where ) {
4822         push @where, ' ( '. join(' OR ', @c_where). ' ) ';
4823       }
4824
4825     }
4826
4827
4828   }
4829
4830   ###
4831   # parse refnum (advertising source)
4832   ###
4833
4834   if ( exists($params->{'refnum'}) ) {
4835     my @refnum;
4836     if (ref $params->{'refnum'}) {
4837       @refnum = @{ $params->{'refnum'} };
4838     } else {
4839       @refnum = ( $params->{'refnum'} );
4840     }
4841     my $in = join(',', grep /^\d+$/, @refnum);
4842     push @where, "refnum IN($in)" if length $in;
4843   }
4844
4845   ###
4846   # parse package report options
4847   ###
4848
4849   my @report_option = ();
4850   if ( exists($params->{'report_option'}) ) {
4851     if ( ref($params->{'report_option'}) eq 'ARRAY' ) {
4852       @report_option = @{ $params->{'report_option'} };
4853     } elsif ( $params->{'report_option'} =~ /^([,\d]*)$/ ) {
4854       @report_option = split(',', $1);
4855     }
4856
4857   }
4858
4859   if (@report_option) {
4860     # this will result in the empty set for the dangling comma case as it should
4861     push @where,
4862       map{ "0 < ( SELECT count(*) FROM part_pkg_option
4863                     WHERE part_pkg_option.pkgpart = part_pkg.pkgpart
4864                     AND optionname = 'report_option_$_'
4865                     AND optionvalue = '1' )"
4866          } @report_option;
4867   }
4868
4869   foreach my $any ( grep /^report_option_any/, keys %$params ) {
4870
4871     my @report_option_any = ();
4872     if ( ref($params->{$any}) eq 'ARRAY' ) {
4873       @report_option_any = @{ $params->{$any} };
4874     } elsif ( $params->{$any} =~ /^([,\d]*)$/ ) {
4875       @report_option_any = split(',', $1);
4876     }
4877
4878     if (@report_option_any) {
4879       # this will result in the empty set for the dangling comma case as it should
4880       push @where, ' ( '. join(' OR ',
4881         map{ "0 < ( SELECT count(*) FROM part_pkg_option
4882                       WHERE part_pkg_option.pkgpart = part_pkg.pkgpart
4883                       AND optionname = 'report_option_$_'
4884                       AND optionvalue = '1' )"
4885            } @report_option_any
4886       ). ' ) ';
4887     }
4888
4889   }
4890
4891   ###
4892   # parse custom
4893   ###
4894
4895   push @where,  "part_pkg.custom = 'Y'" if $params->{custom};
4896
4897   ###
4898   # parse fcc_line
4899   ###
4900
4901   push @where,  "(part_pkg.fcc_ds0s > 0 OR pkg_class.fcc_ds0s > 0)"
4902                                                         if $params->{fcc_line};
4903
4904   ###
4905   # parse censustract
4906   ###
4907
4908   if ( exists($params->{'censustract'}) ) {
4909     $params->{'censustract'} =~ /^([.\d]*)$/;
4910     my $censustract = "cust_location.censustract = '$1'";
4911     $censustract .= ' OR cust_location.censustract is NULL' unless $1;
4912     push @where,  "( $censustract )";
4913   }
4914
4915   ###
4916   # parse censustract2
4917   ###
4918   if ( exists($params->{'censustract2'})
4919        && $params->{'censustract2'} =~ /^(\d*)$/
4920      )
4921   {
4922     if ($1) {
4923       push @where, "cust_location.censustract LIKE '$1%'";
4924     } else {
4925       push @where,
4926         "( cust_location.censustract = '' OR cust_location.censustract IS NULL )";
4927     }
4928   }
4929
4930   ###
4931   # parse country/state/zip
4932   ###
4933   for (qw(state country)) { # parsing rules are the same for these
4934   if ( exists($params->{$_})
4935     && uc($params->{$_}) =~ /^([A-Z]{2})$/ )
4936     {
4937       # XXX post-2.3 only--before that, state/country may be in cust_main
4938       push @where, "cust_location.$_ = '$1'";
4939     }
4940   }
4941   if ( exists($params->{zip}) ) {
4942     push @where, "cust_location.zip = " . dbh->quote($params->{zip});
4943   }
4944
4945   ###
4946   # location_* flags
4947   ###
4948   if ( $params->{location_cust} xor $params->{location_nocust} ) {
4949     my $op = $params->{location_cust} ? '=' : '!=';
4950     push @where, "cust_location.locationnum $op cust_main.ship_locationnum";
4951   }
4952   if ( $params->{location_census} xor $params->{location_nocensus} ) {
4953     my $op = $params->{location_census} ? "IS NOT NULL" : "IS NULL";
4954     push @where, "cust_location.censustract $op";
4955   }
4956   if ( $params->{location_geocode} xor $params->{location_nogeocode} ) {
4957     my $op = $params->{location_geocode} ? "IS NOT NULL" : "IS NULL";
4958     push @where, "cust_location.geocode $op";
4959   }
4960
4961   ###
4962   # parse part_pkg
4963   ###
4964
4965   if ( ref($params->{'pkgpart'}) ) {
4966
4967     my @pkgpart = ();
4968     if ( ref($params->{'pkgpart'}) eq 'HASH' ) {
4969       @pkgpart = grep $params->{'pkgpart'}{$_}, keys %{ $params->{'pkgpart'} };
4970     } elsif ( ref($params->{'pkgpart'}) eq 'ARRAY' ) {
4971       @pkgpart = @{ $params->{'pkgpart'} };
4972     } else {
4973       die 'unhandled pkgpart ref '. $params->{'pkgpart'};
4974     }
4975
4976     @pkgpart = grep /^(\d+)$/, @pkgpart;
4977
4978     push @where, 'pkgpart IN ('. join(',', @pkgpart). ')' if scalar(@pkgpart);
4979
4980   } elsif ( $params->{'pkgpart'} =~ /^(\d+)$/ ) {
4981     push @where, "pkgpart = $1";
4982   }
4983
4984   ###
4985   # parse dates
4986   ###
4987
4988   my $orderby = '';
4989
4990   #false laziness w/report_cust_pkg.html
4991   my %disable = (
4992     'all'             => {},
4993     'one-time charge' => { 'last_bill'=>1, 'bill'=>1, 'adjourn'=>1, 'susp'=>1, 'expire'=>1, 'cancel'=>1, },
4994     'active'          => { 'susp'=>1, 'cancel'=>1 },
4995     'suspended'       => { 'cancel' => 1 },
4996     'cancelled'       => {},
4997     ''                => {},
4998   );
4999
5000   if( exists($params->{'active'} ) ) {
5001     # This overrides all the other date-related fields, and includes packages
5002     # that were active at some time during the interval.  It excludes:
5003     # - packages that were set up after the end of the interval
5004     # - packages that were canceled before the start of the interval
5005     # - packages that were suspended before the start of the interval
5006     #   and are still suspended now
5007     my($beginning, $ending) = @{$params->{'active'}};
5008     push @where,
5009       "cust_pkg.setup IS NOT NULL",
5010       "cust_pkg.setup <= $ending",
5011       "(cust_pkg.cancel IS NULL OR cust_pkg.cancel >= $beginning )",
5012       "(cust_pkg.susp   IS NULL OR cust_pkg.susp   >= $beginning )",
5013       "NOT (".FS::cust_pkg->onetime_sql . ")";
5014   }
5015   else {
5016     my $exclude_change_from = 0;
5017     my $exclude_change_to = 0;
5018
5019     foreach my $field (qw( setup last_bill bill adjourn susp expire contract_end change_date cancel )) {
5020
5021       next unless exists($params->{$field});
5022
5023       my($beginning, $ending) = @{$params->{$field}};
5024
5025       next if $beginning == 0 && $ending == 4294967295;
5026
5027       push @where,
5028         "cust_pkg.$field IS NOT NULL",
5029         "cust_pkg.$field >= $beginning",
5030         "cust_pkg.$field <= $ending";
5031
5032       $orderby ||= "ORDER BY cust_pkg.$field";
5033
5034       if ( $field eq 'setup' ) {
5035         $exclude_change_from = 1;
5036       } elsif ( $field eq 'cancel' ) {
5037         $exclude_change_to = 1;
5038       } elsif ( $field eq 'change_date' ) {
5039         # if we are given setup and change_date ranges, and the setup date
5040         # falls in _both_ ranges, then include the package whether it was
5041         # a change or not
5042         $exclude_change_from = 0;
5043       }
5044     }
5045
5046     if ($exclude_change_from) {
5047       push @where, "change_pkgnum IS NULL";
5048     }
5049     if ($exclude_change_to) {
5050       # a join might be more efficient here
5051       push @where, "NOT EXISTS(
5052         SELECT 1 FROM cust_pkg AS changed_to_pkg
5053         WHERE cust_pkg.pkgnum = changed_to_pkg.change_pkgnum
5054       )";
5055     }
5056   }
5057
5058   $orderby ||= 'ORDER BY bill';
5059
5060   ###
5061   # parse magic, legacy, etc.
5062   ###
5063
5064   if ( $params->{'magic'} &&
5065        $params->{'magic'} =~ /^(active|inactive|suspended|cancell?ed)$/
5066   ) {
5067
5068     $orderby = 'ORDER BY pkgnum';
5069
5070     if ( $params->{'pkgpart'} =~ /^(\d+)$/ ) {
5071       push @where, "pkgpart = $1";
5072     }
5073
5074   } elsif ( $params->{'query'} eq 'pkgnum' ) {
5075
5076     $orderby = 'ORDER BY pkgnum';
5077
5078   } elsif ( $params->{'query'} eq 'APKG_pkgnum' ) {
5079
5080     $orderby = 'ORDER BY pkgnum';
5081
5082     push @where, '0 < (
5083       SELECT count(*) FROM pkg_svc
5084        WHERE pkg_svc.pkgpart =  cust_pkg.pkgpart
5085          AND pkg_svc.quantity > ( SELECT count(*) FROM cust_svc
5086                                    WHERE cust_svc.pkgnum  = cust_pkg.pkgnum
5087                                      AND cust_svc.svcpart = pkg_svc.svcpart
5088                                 )
5089     )';
5090
5091   }
5092
5093   ##
5094   # parse the extremely weird 'towernum' param
5095   ##
5096
5097   if ($params->{towernum}) {
5098     my $towernum = $params->{towernum};
5099     $towernum = [ $towernum ] if !ref($towernum);
5100     my $in = join(',', grep /^\d+$/, @$towernum);
5101     if (length $in) {
5102       # inefficient, but this is an obscure feature
5103       eval "use FS::Report::Table";
5104       FS::Report::Table->_init_tower_pkg_cache; # probably does nothing
5105       push @where, "EXISTS(
5106       SELECT 1 FROM tower_pkg_cache
5107       WHERE tower_pkg_cache.pkgnum = cust_pkg.pkgnum
5108         AND tower_pkg_cache.towernum IN ($in)
5109       )"
5110     }
5111   }
5112
5113   ##
5114   # parse the 477 report drill-down options
5115   ##
5116
5117   if ($params->{'477part'} =~ /^([a-z]+)$/) {
5118     my $section = $1;
5119     my ($date, $rownum, $agentnum);
5120     if ($params->{'date'} =~ /^(\d+)$/) {
5121       $date = $1;
5122     }
5123     if ($params->{'477rownum'} =~ /^(\d+)$/) {
5124       $rownum = $1;
5125     }
5126     if ($params->{'agentnum'} =~ /^(\d+)$/) {
5127       $agentnum = $1;
5128     }
5129     if ($date and defined($rownum)) {
5130       my $report = FS::Report::FCC_477->report($section,
5131         'date'      => $date,
5132         'agentnum'  => $agentnum,
5133         'detail'    => 1
5134       );
5135       my $pkgnums = $report->{detail}->[$rownum]
5136         or die "row $rownum is past the end of the report";
5137         # '0' so that if there are no pkgnums (empty string) it will create
5138         # a valid query that returns nothing
5139       warn "PKGNUMS:\n$pkgnums\n\n"; # XXX debug
5140
5141       # and this overrides everything
5142       @where = ( "cust_pkg.pkgnum IN($pkgnums)" );
5143     } # else we're missing some params, ignore the whole business
5144   }
5145
5146   ##
5147   # setup queries, links, subs, etc. for the search
5148   ##
5149
5150   # here is the agent virtualization
5151   if ($params->{CurrentUser}) {
5152     my $access_user =
5153       qsearchs('access_user', { username => $params->{CurrentUser} });
5154
5155     if ($access_user) {
5156       push @where, $access_user->agentnums_sql('table'=>'cust_main');
5157     } else {
5158       push @where, "1=0";
5159     }
5160   } else {
5161     push @where, $FS::CurrentUser::CurrentUser->agentnums_sql('table'=>'cust_main');
5162   }
5163
5164   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
5165
5166   my $addl_from = 'LEFT JOIN part_pkg  USING ( pkgpart  ) '.
5167                   'LEFT JOIN pkg_class ON ( part_pkg.classnum = pkg_class.classnum ) '.
5168                   'LEFT JOIN cust_location USING ( locationnum ) '.
5169                   FS::UI::Web::join_cust_main('cust_pkg', 'cust_pkg');
5170
5171   my $select;
5172   my $count_query;
5173   if ( $params->{'select_zip5'} ) {
5174     my $zip = 'cust_location.zip';
5175
5176     $select = "DISTINCT substr($zip,1,5) as zip";
5177     $orderby = "ORDER BY substr($zip,1,5)";
5178     $count_query = "SELECT COUNT( DISTINCT substr($zip,1,5) )";
5179   } else {
5180     $select = join(', ',
5181                          'cust_pkg.*',
5182                          ( map "part_pkg.$_", qw( pkg freq ) ),
5183                          'pkg_class.classname',
5184                          'cust_main.custnum AS cust_main_custnum',
5185                          FS::UI::Web::cust_sql_fields(
5186                            $params->{'cust_fields'}
5187                          ),
5188                   );
5189     $count_query = 'SELECT COUNT(*)';
5190   }
5191
5192   $count_query .= " FROM cust_pkg $addl_from $extra_sql";
5193
5194   my $sql_query = {
5195     'table'       => 'cust_pkg',
5196     'hashref'     => {},
5197     'select'      => $select,
5198     'extra_sql'   => $extra_sql,
5199     'order_by'    => $orderby,
5200     'addl_from'   => $addl_from,
5201     'count_query' => $count_query,
5202   };
5203
5204 }
5205
5206 =item fcc_477_count
5207
5208 Returns a list of two package counts.  The first is a count of packages
5209 based on the supplied criteria and the second is the count of residential
5210 packages with those same criteria.  Criteria are specified as in the search
5211 method.
5212
5213 =cut
5214
5215 sub fcc_477_count {
5216   my ($class, $params) = @_;
5217
5218   my $sql_query = $class->search( $params );
5219
5220   my $count_sql = delete($sql_query->{'count_query'});
5221   $count_sql =~ s/ FROM/,count(CASE WHEN cust_main.company IS NULL OR cust_main.company = '' THEN 1 END) FROM/
5222     or die "couldn't parse count_sql";
5223
5224   my $count_sth = dbh->prepare($count_sql)
5225     or die "Error preparing $count_sql: ". dbh->errstr;
5226   $count_sth->execute
5227     or die "Error executing $count_sql: ". $count_sth->errstr;
5228   my $count_arrayref = $count_sth->fetchrow_arrayref;
5229
5230   return ( @$count_arrayref );
5231
5232 }
5233
5234 =item tax_locationnum_sql
5235
5236 Returns an SQL expression for the tax location for a package, based
5237 on the settings of 'tax-pkg_address' and 'tax-ship_address'.
5238
5239 =cut
5240
5241 sub tax_locationnum_sql {
5242   my $conf = FS::Conf->new;
5243   if ( $conf->exists('tax-pkg_address') ) {
5244     'cust_pkg.locationnum';
5245   }
5246   elsif ( $conf->exists('tax-ship_address') ) {
5247     'cust_main.ship_locationnum';
5248   }
5249   else {
5250     'cust_main.bill_locationnum';
5251   }
5252 }
5253
5254 =item location_sql
5255
5256 Returns a list: the first item is an SQL fragment identifying matching
5257 packages/customers via location (taking into account shipping and package
5258 address taxation, if enabled), and subsequent items are the parameters to
5259 substitute for the placeholders in that fragment.
5260
5261 =cut
5262
5263 sub location_sql {
5264   my($class, %opt) = @_;
5265   my $ornull = $opt{'ornull'};
5266
5267   my $conf = new FS::Conf;
5268
5269   # '?' placeholders in _location_sql_where
5270   my $x = $ornull ? 3 : 2;
5271   my @bill_param = (
5272     ('district')x3,
5273     ('city')x3,
5274     ('county')x$x,
5275     ('state')x$x,
5276     'country'
5277   );
5278
5279   my $main_where;
5280   my @main_param;
5281   if ( $conf->exists('tax-ship_address') ) {
5282
5283     $main_where = "(
5284          (     ( ship_last IS NULL     OR  ship_last  = '' )
5285            AND ". _location_sql_where('cust_main', '', $ornull ). "
5286          )
5287       OR (       ship_last IS NOT NULL AND ship_last != ''
5288            AND ". _location_sql_where('cust_main', 'ship_', $ornull ). "
5289          )
5290     )";
5291     #    AND payby != 'COMP'
5292
5293     @main_param = ( @bill_param, @bill_param );
5294
5295   } else {
5296
5297     $main_where = _location_sql_where('cust_main'); # AND payby != 'COMP'
5298     @main_param = @bill_param;
5299
5300   }
5301
5302   my $where;
5303   my @param;
5304   if ( $conf->exists('tax-pkg_address') ) {
5305
5306     my $loc_where = _location_sql_where( 'cust_location', '', $ornull );
5307
5308     $where = " (
5309                     ( cust_pkg.locationnum IS     NULL AND $main_where )
5310                  OR ( cust_pkg.locationnum IS NOT NULL AND $loc_where  )
5311                )
5312              ";
5313     @param = ( @main_param, @bill_param );
5314
5315   } else {
5316
5317     $where = $main_where;
5318     @param = @main_param;
5319
5320   }
5321
5322   ( $where, @param );
5323
5324 }
5325
5326 #subroutine, helper for location_sql
5327 sub _location_sql_where {
5328   my $table  = shift;
5329   my $prefix = @_ ? shift : '';
5330   my $ornull = @_ ? shift : '';
5331
5332 #  $ornull             = $ornull          ? " OR ( ? IS NULL AND $table.${prefix}county IS NULL ) " : '';
5333
5334   $ornull = $ornull ? ' OR ? IS NULL ' : '';
5335
5336   my $or_empty_city     = " OR ( ? = '' AND $table.${prefix}city     IS NULL )";
5337   my $or_empty_county   = " OR ( ? = '' AND $table.${prefix}county   IS NULL )";
5338   my $or_empty_state    = " OR ( ? = '' AND $table.${prefix}state    IS NULL )";
5339
5340   my $text = (driver_name =~ /^mysql/i) ? 'char' : 'text';
5341
5342 #        ( $table.${prefix}city    = ? $or_empty_city   $ornull )
5343   "
5344         ( $table.district = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5345     AND ( $table.${prefix}city     = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5346     AND ( $table.${prefix}county   = ? $or_empty_county $ornull )
5347     AND ( $table.${prefix}state    = ? $or_empty_state  $ornull )
5348     AND   $table.${prefix}country  = ?
5349   ";
5350 }
5351
5352 sub _X_show_zero {
5353   my( $self, $what ) = @_;
5354
5355   my $what_show_zero = $what. '_show_zero';
5356   length($self->$what_show_zero())
5357     ? ($self->$what_show_zero() eq 'Y')
5358     : $self->part_pkg->$what_show_zero();
5359 }
5360
5361 =head1 SUBROUTINES
5362
5363 =over 4
5364
5365 =item order CUSTNUM, PKGPARTS_ARYREF, [ REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF [ REFNUM ] ] ]
5366
5367 Bulk cancel + order subroutine.  Perhaps slightly deprecated, only used by the
5368 bulk cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
5369
5370 CUSTNUM is a customer (see L<FS::cust_main>)
5371
5372 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5373 L<FS::part_pkg>) to order for this customer.  Duplicates are of course
5374 permitted.
5375
5376 REMOVE_PKGNUMS is an optional list of pkgnums specifying the billing items to
5377 remove for this customer.  The services (see L<FS::cust_svc>) are moved to the
5378 new billing items.  An error is returned if this is not possible (see
5379 L<FS::pkg_svc>).  An empty arrayref is equivalent to not specifying this
5380 parameter.
5381
5382 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5383 newly-created cust_pkg objects.
5384
5385 REFNUM, if specified, will specify the FS::pkg_referral record to be created
5386 and inserted.  Multiple FS::pkg_referral records can be created by
5387 setting I<refnum> to an array reference of refnums or a hash reference with
5388 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
5389 record will be created corresponding to cust_main.refnum.
5390
5391 =cut
5392
5393 sub order {
5394   my ($custnum, $pkgparts, $remove_pkgnum, $return_cust_pkg, $refnum) = @_;
5395
5396   my $conf = new FS::Conf;
5397
5398   # Transactionize this whole mess
5399   local $SIG{HUP} = 'IGNORE';
5400   local $SIG{INT} = 'IGNORE';
5401   local $SIG{QUIT} = 'IGNORE';
5402   local $SIG{TERM} = 'IGNORE';
5403   local $SIG{TSTP} = 'IGNORE';
5404   local $SIG{PIPE} = 'IGNORE';
5405
5406   my $oldAutoCommit = $FS::UID::AutoCommit;
5407   local $FS::UID::AutoCommit = 0;
5408   my $dbh = dbh;
5409
5410   my $error;
5411 #  my $cust_main = qsearchs('cust_main', { custnum => $custnum });
5412 #  return "Customer not found: $custnum" unless $cust_main;
5413
5414   warn "$me order: pkgnums to remove: ". join(',', @$remove_pkgnum). "\n"
5415     if $DEBUG;
5416
5417   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5418                          @$remove_pkgnum;
5419
5420   my $change = scalar(@old_cust_pkg) != 0;
5421
5422   my %hash = ();
5423   if ( scalar(@old_cust_pkg) == 1 && scalar(@$pkgparts) == 1 ) {
5424
5425     warn "$me order: changing pkgnum ". $old_cust_pkg[0]->pkgnum.
5426          " to pkgpart ". $pkgparts->[0]. "\n"
5427       if $DEBUG;
5428
5429     my $err_or_cust_pkg =
5430       $old_cust_pkg[0]->change( 'pkgpart' => $pkgparts->[0],
5431                                 'refnum'  => $refnum,
5432                               );
5433
5434     unless (ref($err_or_cust_pkg)) {
5435       $dbh->rollback if $oldAutoCommit;
5436       return $err_or_cust_pkg;
5437     }
5438
5439     push @$return_cust_pkg, $err_or_cust_pkg;
5440     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5441     return '';
5442
5443   }
5444
5445   # Create the new packages.
5446   foreach my $pkgpart (@$pkgparts) {
5447
5448     warn "$me order: inserting pkgpart $pkgpart\n" if $DEBUG;
5449
5450     my $cust_pkg = new FS::cust_pkg { custnum => $custnum,
5451                                       pkgpart => $pkgpart,
5452                                       refnum  => $refnum,
5453                                       %hash,
5454                                     };
5455     $error = $cust_pkg->insert( 'change' => $change );
5456     push @$return_cust_pkg, $cust_pkg;
5457
5458     foreach my $link ($cust_pkg->part_pkg->supp_part_pkg_link) {
5459       my $supp_pkg = FS::cust_pkg->new({
5460           custnum => $custnum,
5461           pkgpart => $link->dst_pkgpart,
5462           refnum  => $refnum,
5463           main_pkgnum => $cust_pkg->pkgnum,
5464           %hash,
5465       });
5466       $error ||= $supp_pkg->insert( 'change' => $change );
5467       push @$return_cust_pkg, $supp_pkg;
5468     }
5469
5470     if ($error) {
5471       $dbh->rollback if $oldAutoCommit;
5472       return $error;
5473     }
5474
5475   }
5476   # $return_cust_pkg now contains refs to all of the newly
5477   # created packages.
5478
5479   # Transfer services and cancel old packages.
5480   foreach my $old_pkg (@old_cust_pkg) {
5481
5482     warn "$me order: transferring services from pkgnum ". $old_pkg->pkgnum. "\n"
5483       if $DEBUG;
5484
5485     foreach my $new_pkg (@$return_cust_pkg) {
5486       $error = $old_pkg->transfer($new_pkg);
5487       if ($error and $error == 0) {
5488         # $old_pkg->transfer failed.
5489         $dbh->rollback if $oldAutoCommit;
5490         return $error;
5491       }
5492     }
5493
5494     if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
5495       warn "trying transfer again with change_svcpart option\n" if $DEBUG;
5496       foreach my $new_pkg (@$return_cust_pkg) {
5497         $error = $old_pkg->transfer($new_pkg, 'change_svcpart'=>1 );
5498         if ($error and $error == 0) {
5499           # $old_pkg->transfer failed.
5500         $dbh->rollback if $oldAutoCommit;
5501         return $error;
5502         }
5503       }
5504     }
5505
5506     if ($error > 0) {
5507       # Transfers were successful, but we went through all of the
5508       # new packages and still had services left on the old package.
5509       # We can't cancel the package under the circumstances, so abort.
5510       $dbh->rollback if $oldAutoCommit;
5511       return "Unable to transfer all services from package ".$old_pkg->pkgnum;
5512     }
5513     $error = $old_pkg->cancel( quiet=>1, 'no_delay_cancel'=>1 );
5514     if ($error) {
5515       $dbh->rollback;
5516       return $error;
5517     }
5518   }
5519   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5520   '';
5521 }
5522
5523 =item bulk_change PKGPARTS_ARYREF, REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF ]
5524
5525 A bulk change method to change packages for multiple customers.
5526
5527 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5528 L<FS::part_pkg>) to order for each customer.  Duplicates are of course
5529 permitted.
5530
5531 REMOVE_PKGNUMS is an list of pkgnums specifying the billing items to
5532 replace.  The services (see L<FS::cust_svc>) are moved to the
5533 new billing items.  An error is returned if this is not possible (see
5534 L<FS::pkg_svc>).
5535
5536 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5537 newly-created cust_pkg objects.
5538
5539 =cut
5540
5541 sub bulk_change {
5542   my ($pkgparts, $remove_pkgnum, $return_cust_pkg) = @_;
5543
5544   # Transactionize this whole mess
5545   local $SIG{HUP} = 'IGNORE';
5546   local $SIG{INT} = 'IGNORE';
5547   local $SIG{QUIT} = 'IGNORE';
5548   local $SIG{TERM} = 'IGNORE';
5549   local $SIG{TSTP} = 'IGNORE';
5550   local $SIG{PIPE} = 'IGNORE';
5551
5552   my $oldAutoCommit = $FS::UID::AutoCommit;
5553   local $FS::UID::AutoCommit = 0;
5554   my $dbh = dbh;
5555
5556   my @errors;
5557   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5558                          @$remove_pkgnum;
5559
5560   while(scalar(@old_cust_pkg)) {
5561     my @return = ();
5562     my $custnum = $old_cust_pkg[0]->custnum;
5563     my (@remove) = map { $_->pkgnum }
5564                    grep { $_->custnum == $custnum } @old_cust_pkg;
5565     @old_cust_pkg = grep { $_->custnum != $custnum } @old_cust_pkg;
5566
5567     my $error = order $custnum, $pkgparts, \@remove, \@return;
5568
5569     push @errors, $error
5570       if $error;
5571     push @$return_cust_pkg, @return;
5572   }
5573
5574   if (scalar(@errors)) {
5575     $dbh->rollback if $oldAutoCommit;
5576     return join(' / ', @errors);
5577   }
5578
5579   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5580   '';
5581 }
5582
5583 # Used by FS::Upgrade to migrate to a new database.
5584 sub _upgrade_data {  # class method
5585   my ($class, %opts) = @_;
5586   $class->_upgrade_otaker(%opts);
5587   my @statements = (
5588     # RT#10139, bug resulting in contract_end being set when it shouldn't
5589   'UPDATE cust_pkg SET contract_end = NULL WHERE contract_end = -1',
5590     # RT#10830, bad calculation of prorate date near end of year
5591     # the date range for bill is December 2009, and we move it forward
5592     # one year if it's before the previous bill date (which it should
5593     # never be)
5594   'UPDATE cust_pkg SET bill = bill + (365*24*60*60) WHERE bill < last_bill
5595   AND bill > 1259654400 AND bill < 1262332800 AND (SELECT plan FROM part_pkg
5596   WHERE part_pkg.pkgpart = cust_pkg.pkgpart) = \'prorate\'',
5597     # RT6628, add order_date to cust_pkg
5598     'update cust_pkg set order_date = (select history_date from h_cust_pkg
5599         where h_cust_pkg.pkgnum = cust_pkg.pkgnum and
5600         history_action = \'insert\') where order_date is null',
5601   );
5602   foreach my $sql (@statements) {
5603     my $sth = dbh->prepare($sql);
5604     $sth->execute or die $sth->errstr;
5605   }
5606
5607   # RT31194: supplemental package links that are deleted don't clean up
5608   # linked records
5609   my @pkglinknums = qsearch({
5610       'select'    => 'DISTINCT cust_pkg.pkglinknum',
5611       'table'     => 'cust_pkg',
5612       'addl_from' => ' LEFT JOIN part_pkg_link USING (pkglinknum) ',
5613       'extra_sql' => ' WHERE cust_pkg.pkglinknum IS NOT NULL
5614                         AND part_pkg_link.pkglinknum IS NULL',
5615   });
5616   foreach (@pkglinknums) {
5617     my $pkglinknum = $_->pkglinknum;
5618     warn "cleaning part_pkg_link #$pkglinknum\n";
5619     my $part_pkg_link = FS::part_pkg_link->new({pkglinknum => $pkglinknum});
5620     my $error = $part_pkg_link->remove_linked;
5621     die $error if $error;
5622   }
5623 }
5624
5625 =back
5626
5627 =head1 BUGS
5628
5629 sub order is not OO.  Perhaps it should be moved to FS::cust_main and made so?
5630
5631 In sub order, the @pkgparts array (passed by reference) is clobbered.
5632
5633 Also in sub order, no money is adjusted.  Once FS::part_pkg defines a standard
5634 method to pass dates to the recur_prog expression, it should do so.
5635
5636 FS::svc_acct, FS::svc_domain, FS::svc_www, FS::svc_ip and FS::svc_forward are
5637 loaded via 'use' at compile time, rather than via 'require' in sub { setup,
5638 suspend, unsuspend, cancel } because they use %FS::UID::callback to load
5639 configuration values.  Probably need a subroutine which decides what to do
5640 based on whether or not we've fetched the user yet, rather than a hash.  See
5641 FS::UID and the TODO.
5642
5643 Now that things are transactional should the check in the insert method be
5644 moved to check ?
5645
5646 =head1 SEE ALSO
5647
5648 L<FS::Record>, L<FS::cust_main>, L<FS::part_pkg>, L<FS::cust_svc>,
5649 L<FS::pkg_svc>, schema.html from the base documentation
5650
5651 =cut
5652
5653 1;
5654