FS/FS/cust_pkg.pm

   1 package FS::cust_pkg;
   2 use base qw( FS::otaker_Mixin FS::cust_main_Mixin FS::Sales_Mixin
   3              FS::contact_Mixin FS::location_Mixin
   4              FS::m2m_Common FS::option_Common );
   5
   6 use strict;
   7 use vars qw( $disable_agentcheck $DEBUG $me $upgrade );
   8 use Carp qw(cluck);
   9 use Scalar::Util qw( blessed );
  10 use List::Util qw(min max);
  11 use Tie::IxHash;
  12 use Time::Local qw( timelocal timelocal_nocheck );
  13 use MIME::Entity;
  14 use FS::UID qw( getotaker dbh driver_name );
  15 use FS::Misc qw( send_email );
  16 use FS::Record qw( qsearch qsearchs fields );
  17 use FS::CurrentUser;
  18 use FS::cust_svc;
  19 use FS::part_pkg;
  20 use FS::cust_main;
  21 use FS::contact;
  22 use FS::cust_location;
  23 use FS::pkg_svc;
  24 use FS::cust_bill_pkg;
  25 use FS::cust_pkg_detail;
  26 use FS::cust_pkg_usage;
  27 use FS::cdr_cust_pkg_usage;
  28 use FS::cust_event;
  29 use FS::h_cust_svc;
  30 use FS::reg_code;
  31 use FS::part_svc;
  32 use FS::cust_pkg_reason;
  33 use FS::reason;
  34 use FS::cust_pkg_discount;
  35 use FS::discount;
  36 use FS::UI::Web;
  37 use FS::sales;
  38 # for modify_charge
  39 use FS::cust_credit;
  40
  41 # need to 'use' these instead of 'require' in sub { cancel, suspend, unsuspend,
  42 # setup }
  43 # because they load configuration by setting FS::UID::callback (see TODO)
  44 use FS::svc_acct;
  45 use FS::svc_domain;
  46 use FS::svc_www;
  47 use FS::svc_forward;
  48
  49 # for sending cancel emails in sub cancel
  50 use FS::Conf;
  51
  52 $DEBUG = 0;
  53 $me = '[FS::cust_pkg]';
  54
  55 $disable_agentcheck = 0;
  56
  57 $upgrade = 0; #go away after setup+start dates cleaned up for old customers
  58
  59 sub _cache {
  60   my $self = shift;
  61   my ( $hashref, $cache ) = @_;
  62   #if ( $hashref->{'pkgpart'} ) {
  63   if ( $hashref->{'pkg'} ) {
  64     # #@{ $self->{'_pkgnum'} } = ();
  65     # my $subcache = $cache->subcache('pkgpart', 'part_pkg');
  66     # $self->{'_pkgpart'} = $subcache;
  67     # #push @{ $self->{'_pkgnum'} },
  68     #   FS::part_pkg->new_or_cached($hashref, $subcache);
  69     $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  70   }
  71   if ( exists $hashref->{'svcnum'} ) {
  72     #@{ $self->{'_pkgnum'} } = ();
  73     my $subcache = $cache->subcache('svcnum', 'cust_svc', $hashref->{pkgnum});
  74     $self->{'_svcnum'} = $subcache;
  75     #push @{ $self->{'_pkgnum'} },
  76     FS::cust_svc->new_or_cached($hashref, $subcache) if $hashref->{svcnum};
  77   }
  78 }
  79
  80 =head1 NAME
  81
  82 FS::cust_pkg - Object methods for cust_pkg objects
  83
  84 =head1 SYNOPSIS
  85
  86   use FS::cust_pkg;
  87
  88   $record = new FS::cust_pkg \%hash;
  89   $record = new FS::cust_pkg { 'column' => 'value' };
  90
  91   $error = $record->insert;
  92
  93   $error = $new_record->replace($old_record);
  94
  95   $error = $record->delete;
  96
  97   $error = $record->check;
  98
  99   $error = $record->cancel;
 100
 101   $error = $record->suspend;
 102
 103   $error = $record->unsuspend;
 104
 105   $part_pkg = $record->part_pkg;
 106
 107   @labels = $record->labels;
 108
 109   $seconds = $record->seconds_since($timestamp);
 110
 111   #bulk cancel+order... perhaps slightly deprecated, only used by the bulk
 112   # cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
 113   $error = FS::cust_pkg::order( $custnum, \@pkgparts );
 114   $error = FS::cust_pkg::order( $custnum, \@pkgparts, \@remove_pkgnums ] );
 115
 116 =head1 DESCRIPTION
 117
 118 An FS::cust_pkg object represents a customer billing item.  FS::cust_pkg
 119 inherits from FS::Record.  The following fields are currently supported:
 120
 121 =over 4
 122
 123 =item pkgnum
 124
 125 Primary key (assigned automatically for new billing items)
 126
 127 =item custnum
 128
 129 Customer (see L<FS::cust_main>)
 130
 131 =item pkgpart
 132
 133 Billing item definition (see L<FS::part_pkg>)
 134
 135 =item locationnum
 136
 137 Optional link to package location (see L<FS::location>)
 138
 139 =item order_date
 140
 141 date package was ordered (also remains same on changes)
 142
 143 =item start_date
 144
 145 date
 146
 147 =item setup
 148
 149 date
 150
 151 =item bill
 152
 153 date (next bill date)
 154
 155 =item last_bill
 156
 157 last bill date
 158
 159 =item adjourn
 160
 161 date
 162
 163 =item susp
 164
 165 date
 166
 167 =item expire
 168
 169 date
 170
 171 =item contract_end
 172
 173 date
 174
 175 =item cancel
 176
 177 date
 178
 179 =item usernum
 180
 181 order taker (see L<FS::access_user>)
 182
 183 =item manual_flag
 184
 185 If this field is set to 1, disables the automatic
 186 unsuspension of this package when using the B<unsuspendauto> config option.
 187
 188 =item quantity
 189
 190 If not set, defaults to 1
 191
 192 =item change_date
 193
 194 Date of change from previous package
 195
 196 =item change_pkgnum
 197
 198 Previous pkgnum
 199
 200 =item change_pkgpart
 201
 202 Previous pkgpart
 203
 204 =item change_locationnum
 205
 206 Previous locationnum
 207
 208 =item waive_setup
 209
 210 =item main_pkgnum
 211
 212 The pkgnum of the package that this package is supplemental to, if any.
 213
 214 =item pkglinknum
 215
 216 The package link (L<FS::part_pkg_link>) that defines this supplemental
 217 package, if it is one.
 218
 219 =item change_to_pkgnum
 220
 221 The pkgnum of the package this one will be "changed to" in the future
 222 (on its expiration date).
 223
 224 =back
 225
 226 Note: setup, last_bill, bill, adjourn, susp, expire, cancel and change_date
 227 are specified as UNIX timestamps; see L<perlfunc/"time">.  Also see
 228 L<Time::Local> and L<Date::Parse> for conversion functions.
 229
 230 =head1 METHODS
 231
 232 =over 4
 233
 234 =item new HASHREF
 235
 236 Create a new billing item.  To add the item to the database, see L<"insert">.
 237
 238 =cut
 239
 240 sub table { 'cust_pkg'; }
 241 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
 242 sub cust_unlinked_msg {
 243   my $self = shift;
 244   "WARNING: can't find cust_main.custnum ". $self->custnum.
 245   ' (cust_pkg.pkgnum '. $self->pkgnum. ')';
 246 }
 247
 248 =item set_initial_timers
 249
 250 If required by the package definition, sets any automatic expire, adjourn,
 251 or contract_end timers to some number of months after the start date
 252 (or setup date, if the package has already been setup). If the package has
 253 a delayed setup fee after a period of "free days", will also set the
 254 start date to the end of that period.
 255
 256 =cut
 257
 258 sub set_initial_timers {
 259   my $self = shift;
 260   my $part_pkg = $self->part_pkg;
 261   foreach my $action ( qw(expire adjourn contract_end) ) {
 262     my $months = $part_pkg->option("${action}_months",1);
 263     if($months and !$self->get($action)) {
 264       my $start = $self->start_date || $self->setup || time;
 265       $self->set($action, $part_pkg->add_freq($start, $months) );
 266     }
 267   }
 268
 269   # if this package has "free days" and delayed setup fee, then
 270   # set start date that many days in the future.
 271   # (this should have been set in the UI, but enforce it here)
 272   if ( $part_pkg->option('free_days',1)
 273        && $part_pkg->option('delay_setup',1)
 274      )
 275   {
 276     $self->start_date( $part_pkg->default_start_date );
 277   }
 278   '';
 279 }
 280
 281 =item insert [ OPTION => VALUE ... ]
 282
 283 Adds this billing item to the database ("Orders" the item).  If there is an
 284 error, returns the error, otherwise returns false.
 285
 286 If the additional field I<promo_code> is defined instead of I<pkgpart>, it
 287 will be used to look up the package definition and agent restrictions will be
 288 ignored.
 289
 290 If the additional field I<refnum> is defined, an FS::pkg_referral record will
 291 be created and inserted.  Multiple FS::pkg_referral records can be created by
 292 setting I<refnum> to an array reference of refnums or a hash reference with
 293 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
 294 record will be created corresponding to cust_main.refnum.
 295
 296 The following options are available:
 297
 298 =over 4
 299
 300 =item change
 301
 302 If set true, supresses actions that should only be taken for new package
 303 orders.  (Currently this includes: intro periods when delay_setup is on,
 304 auto-adding a 1st start date, auto-adding expiration/adjourn/contract_end dates)
 305
 306 =item options
 307
 308 cust_pkg_option records will be created
 309
 310 =item ticket_subject
 311
 312 a ticket will be added to this customer with this subject
 313
 314 =item ticket_queue
 315
 316 an optional queue name for ticket additions
 317
 318 =item allow_pkgpart
 319
 320 Don't check the legality of the package definition.  This should be used
 321 when performing a package change that doesn't change the pkgpart (i.e.
 322 a location change).
 323
 324 =back
 325
 326 =cut
 327
 328 sub insert {
 329   my( $self, %options ) = @_;
 330
 331   my $error;
 332   $error = $self->check_pkgpart unless $options{'allow_pkgpart'};
 333   return $error if $error;
 334
 335   my $part_pkg = $self->part_pkg;
 336
 337   if ( ! $options{'change'} ) {
 338
 339     # set order date to now
 340     $self->order_date(time);
 341
 342     # if the package def says to start only on the first of the month:
 343     if ( $part_pkg->option('start_1st', 1) && !$self->start_date ) {
 344       my ($sec,$min,$hour,$mday,$mon,$year) = (localtime(time) )[0,1,2,3,4,5];
 345       $mon += 1 unless $mday == 1;
 346       until ( $mon < 12 ) { $mon -= 12; $year++; }
 347       $self->start_date( timelocal_nocheck(0,0,0,1,$mon,$year) );
 348     }
 349
 350     if ($self->susp eq 'now' or $part_pkg->start_on_hold) {
 351       # if the package was ordered on hold:
 352       # - suspend it
 353       # - don't set the start date (it will be started manually)
 354       $self->set('susp', $self->order_date);
 355       $self->set('start_date', '');
 356     } else {
 357       # set expire/adjourn/contract_end timers, and free days, if appropriate
 358       $self->set_initial_timers;
 359     }
 360   } # else this is a package change, and shouldn't have "new package" behavior
 361
 362   local $SIG{HUP} = 'IGNORE';
 363   local $SIG{INT} = 'IGNORE';
 364   local $SIG{QUIT} = 'IGNORE';
 365   local $SIG{TERM} = 'IGNORE';
 366   local $SIG{TSTP} = 'IGNORE';
 367   local $SIG{PIPE} = 'IGNORE';
 368
 369   my $oldAutoCommit = $FS::UID::AutoCommit;
 370   local $FS::UID::AutoCommit = 0;
 371   my $dbh = dbh;
 372
 373   $error = $self->SUPER::insert($options{options} ? %{$options{options}} : ());
 374   if ( $error ) {
 375     $dbh->rollback if $oldAutoCommit;
 376     return $error;
 377   }
 378
 379   $self->refnum($self->cust_main->refnum) unless $self->refnum;
 380   $self->refnum( [ $self->refnum ] ) unless ref($self->refnum);
 381   $self->process_m2m( 'link_table'   => 'pkg_referral',
 382                       'target_table' => 'part_referral',
 383                       'params'       => $self->refnum,
 384                     );
 385
 386   if ( $self->discountnum ) {
 387     my $error = $self->insert_discount();
 388     if ( $error ) {
 389       $dbh->rollback if $oldAutoCommit;
 390       return $error;
 391     }
 392   }
 393
 394   my $conf = new FS::Conf;
 395
 396   if ( $conf->config('ticket_system') && $options{ticket_subject} ) {
 397
 398     #this init stuff is still inefficient, but at least its limited to
 399     # the small number (any?) folks using ticket emailing on pkg order
 400
 401     #eval '
 402     #  use lib ( "/opt/rt3/local/lib", "/opt/rt3/lib" );
 403     #  use RT;
 404     #';
 405     #die $@ if $@;
 406     #
 407     #RT::LoadConfig();
 408     #RT::Init();
 409     use FS::TicketSystem;
 410     FS::TicketSystem->init();
 411
 412     my $q = new RT::Queue($RT::SystemUser);
 413     $q->Load($options{ticket_queue}) if $options{ticket_queue};
 414     my $t = new RT::Ticket($RT::SystemUser);
 415     my $mime = new MIME::Entity;
 416     $mime->build( Type => 'text/plain', Data => $options{ticket_subject} );
 417     $t->Create( $options{ticket_queue} ? (Queue => $q) : (),
 418                 Subject => $options{ticket_subject},
 419                 MIMEObj => $mime,
 420               );
 421     $t->AddLink( Type   => 'MemberOf',
 422                  Target => 'freeside://freeside/cust_main/'. $self->custnum,
 423                );
 424   }
 425
 426   if ($conf->config('welcome_letter') && $self->cust_main->num_pkgs == 1) {
 427     my $queue = new FS::queue {
 428       'job'     => 'FS::cust_main::queueable_print',
 429     };
 430     $error = $queue->insert(
 431       'custnum'  => $self->custnum,
 432       'template' => 'welcome_letter',
 433     );
 434
 435     if ($error) {
 436       warn "can't send welcome letter: $error";
 437     }
 438
 439   }
 440
 441   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 442   '';
 443
 444 }
 445
 446 =item delete
 447
 448 This method now works but you probably shouldn't use it.
 449
 450 You don't want to delete packages, because there would then be no record
 451 the customer ever purchased the package.  Instead, see the cancel method and
 452 hide cancelled packages.
 453
 454 =cut
 455
 456 sub delete {
 457   my $self = shift;
 458
 459   local $SIG{HUP} = 'IGNORE';
 460   local $SIG{INT} = 'IGNORE';
 461   local $SIG{QUIT} = 'IGNORE';
 462   local $SIG{TERM} = 'IGNORE';
 463   local $SIG{TSTP} = 'IGNORE';
 464   local $SIG{PIPE} = 'IGNORE';
 465
 466   my $oldAutoCommit = $FS::UID::AutoCommit;
 467   local $FS::UID::AutoCommit = 0;
 468   my $dbh = dbh;
 469
 470   foreach my $cust_pkg_discount ($self->cust_pkg_discount) {
 471     my $error = $cust_pkg_discount->delete;
 472     if ( $error ) {
 473       $dbh->rollback if $oldAutoCommit;
 474       return $error;
 475     }
 476   }
 477   #cust_bill_pkg_discount?
 478
 479   foreach my $cust_pkg_detail ($self->cust_pkg_detail) {
 480     my $error = $cust_pkg_detail->delete;
 481     if ( $error ) {
 482       $dbh->rollback if $oldAutoCommit;
 483       return $error;
 484     }
 485   }
 486
 487   foreach my $cust_pkg_reason (
 488     qsearchs( {
 489                 'table' => 'cust_pkg_reason',
 490                 'hashref' => { 'pkgnum' => $self->pkgnum },
 491               }
 492             )
 493   ) {
 494     my $error = $cust_pkg_reason->delete;
 495     if ( $error ) {
 496       $dbh->rollback if $oldAutoCommit;
 497       return $error;
 498     }
 499   }
 500
 501   #pkg_referral?
 502
 503   my $error = $self->SUPER::delete(@_);
 504   if ( $error ) {
 505     $dbh->rollback if $oldAutoCommit;
 506     return $error;
 507   }
 508
 509   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 510
 511   '';
 512
 513 }
 514
 515 =item replace [ OLD_RECORD ] [ HASHREF | OPTION => VALUE ... ]
 516
 517 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 518 returns the error, otherwise returns false.
 519
 520 Currently, custnum, setup, bill, adjourn, susp, expire, and cancel may be changed.
 521
 522 Changing pkgpart may have disasterous effects.  See the order subroutine.
 523
 524 setup and bill are normally updated by calling the bill method of a customer
 525 object (see L<FS::cust_main>).
 526
 527 suspend is normally updated by the suspend and unsuspend methods.
 528
 529 cancel is normally updated by the cancel method (and also the order subroutine
 530 in some cases).
 531
 532 Available options are:
 533
 534 =over 4
 535
 536 =item reason
 537
 538 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
 539
 540 =item reason_otaker
 541
 542 the access_user (see L<FS::access_user>) providing the reason
 543
 544 =item options
 545
 546 hashref of keys and values - cust_pkg_option records will be created, updated or removed as appopriate
 547
 548 =back
 549
 550 =cut
 551
 552 sub replace {
 553   my $new = shift;
 554
 555   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 556               ? shift
 557               : $new->replace_old;
 558
 559   my $options =
 560     ( ref($_[0]) eq 'HASH' )
 561       ? shift
 562       : { @_ };
 563
 564   #return "Can't (yet?) change pkgpart!" if $old->pkgpart != $new->pkgpart;
 565   #return "Can't change otaker!" if $old->otaker ne $new->otaker;
 566
 567   #allow this *sigh*
 568   #return "Can't change setup once it exists!"
 569   #  if $old->getfield('setup') &&
 570   #     $old->getfield('setup') != $new->getfield('setup');
 571
 572   #some logic for bill, susp, cancel?
 573
 574   local($disable_agentcheck) = 1 if $old->pkgpart == $new->pkgpart;
 575
 576   local $SIG{HUP} = 'IGNORE';
 577   local $SIG{INT} = 'IGNORE';
 578   local $SIG{QUIT} = 'IGNORE';
 579   local $SIG{TERM} = 'IGNORE';
 580   local $SIG{TSTP} = 'IGNORE';
 581   local $SIG{PIPE} = 'IGNORE';
 582
 583   my $oldAutoCommit = $FS::UID::AutoCommit;
 584   local $FS::UID::AutoCommit = 0;
 585   my $dbh = dbh;
 586
 587   foreach my $method ( qw(adjourn expire) ) {  # How many reasons?
 588     if ($options->{'reason'} && $new->$method && $old->$method ne $new->$method) {
 589       my $error = $new->insert_reason(
 590         'reason'        => $options->{'reason'},
 591         'date'          => $new->$method,
 592         'action'        => $method,
 593         'reason_otaker' => $options->{'reason_otaker'},
 594       );
 595       if ( $error ) {
 596         dbh->rollback if $oldAutoCommit;
 597         return "Error inserting cust_pkg_reason: $error";
 598       }
 599     }
 600   }
 601
 602   #save off and freeze RADIUS attributes for any associated svc_acct records
 603   my @svc_acct = ();
 604   if ( $old->part_pkg->is_prepaid || $new->part_pkg->is_prepaid ) {
 605
 606                 #also check for specific exports?
 607                 # to avoid spurious modify export events
 608     @svc_acct = map  { $_->svc_x }
 609                 grep { $_->part_svc->svcdb eq 'svc_acct' }
 610                      $old->cust_svc;
 611
 612     $_->snapshot foreach @svc_acct;
 613
 614   }
 615
 616   my $error =  $new->export_pkg_change($old)
 617             || $new->SUPER::replace( $old,
 618                                      $options->{options}
 619                                        ? $options->{options}
 620                                        : ()
 621                                    );
 622   if ( $error ) {
 623     $dbh->rollback if $oldAutoCommit;
 624     return $error;
 625   }
 626
 627   #for prepaid packages,
 628   #trigger export of new RADIUS Expiration attribute when cust_pkg.bill changes
 629   foreach my $old_svc_acct ( @svc_acct ) {
 630     my $new_svc_acct = new FS::svc_acct { $old_svc_acct->hash };
 631     my $s_error =
 632       $new_svc_acct->replace( $old_svc_acct,
 633                               'depend_jobnum' => $options->{depend_jobnum},
 634                             );
 635     if ( $s_error ) {
 636       $dbh->rollback if $oldAutoCommit;
 637       return $s_error;
 638     }
 639   }
 640
 641   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 642   '';
 643
 644 }
 645
 646 =item check
 647
 648 Checks all fields to make sure this is a valid billing item.  If there is an
 649 error, returns the error, otherwise returns false.  Called by the insert and
 650 replace methods.
 651
 652 =cut
 653
 654 sub check {
 655   my $self = shift;
 656
 657   if ( !$self->locationnum or $self->locationnum == -1 ) {
 658     $self->set('locationnum', $self->cust_main->ship_locationnum);
 659   }
 660
 661   my $error =
 662     $self->ut_numbern('pkgnum')
 663     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 664     || $self->ut_numbern('pkgpart')
 665     || $self->ut_foreign_keyn('contactnum',  'contact',       'contactnum' )
 666     || $self->ut_foreign_keyn('locationnum', 'cust_location', 'locationnum')
 667     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
 668     || $self->ut_numbern('quantity')
 669     || $self->ut_numbern('start_date')
 670     || $self->ut_numbern('setup')
 671     || $self->ut_numbern('bill')
 672     || $self->ut_numbern('susp')
 673     || $self->ut_numbern('cancel')
 674     || $self->ut_numbern('adjourn')
 675     || $self->ut_numbern('resume')
 676     || $self->ut_numbern('expire')
 677     || $self->ut_numbern('dundate')
 678     || $self->ut_flag('no_auto', [ '', 'Y' ])
 679     || $self->ut_flag('waive_setup', [ '', 'Y' ])
 680     || $self->ut_flag('separate_bill')
 681     || $self->ut_textn('agent_pkgid')
 682     || $self->ut_enum('recur_show_zero', [ '', 'Y', 'N', ])
 683     || $self->ut_enum('setup_show_zero', [ '', 'Y', 'N', ])
 684     || $self->ut_foreign_keyn('main_pkgnum', 'cust_pkg', 'pkgnum')
 685     || $self->ut_foreign_keyn('pkglinknum', 'part_pkg_link', 'pkglinknum')
 686     || $self->ut_foreign_keyn('change_to_pkgnum', 'cust_pkg', 'pkgnum')
 687   ;
 688   return $error if $error;
 689
 690   return "A package with both start date (future start) and setup date (already started) will never bill"
 691     if $self->start_date && $self->setup && ! $upgrade;
 692
 693   return "A future unsuspend date can only be set for a package with a suspend date"
 694     if $self->resume and !$self->susp and !$self->adjourn;
 695
 696   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 697
 698   if ( $self->dbdef_table->column('manual_flag') ) {
 699     $self->manual_flag('') if $self->manual_flag eq ' ';
 700     $self->manual_flag =~ /^([01]?)$/
 701       or return "Illegal manual_flag ". $self->manual_flag;
 702     $self->manual_flag($1);
 703   }
 704
 705   $self->SUPER::check;
 706 }
 707
 708 =item check_pkgpart
 709
 710 Check the pkgpart to make sure it's allowed with the reg_code and/or
 711 promo_code of the package (if present) and with the customer's agent.
 712 Called from C<insert>, unless we are doing a package change that doesn't
 713 affect pkgpart.
 714
 715 =cut
 716
 717 sub check_pkgpart {
 718   my $self = shift;
 719
 720   # my $error = $self->ut_numbern('pkgpart'); # already done
 721
 722   my $error;
 723   if ( $self->reg_code ) {
 724
 725     unless ( grep { $self->pkgpart == $_->pkgpart }
 726              map  { $_->reg_code_pkg }
 727              qsearchs( 'reg_code', { 'code'     => $self->reg_code,
 728                                      'agentnum' => $self->cust_main->agentnum })
 729            ) {
 730       return "Unknown registration code";
 731     }
 732
 733   } elsif ( $self->promo_code ) {
 734
 735     my $promo_part_pkg =
 736       qsearchs('part_pkg', {
 737         'pkgpart'    => $self->pkgpart,
 738         'promo_code' => { op=>'ILIKE', value=>$self->promo_code },
 739       } );
 740     return 'Unknown promotional code' unless $promo_part_pkg;
 741
 742   } else {
 743
 744     unless ( $disable_agentcheck ) {
 745       my $agent =
 746         qsearchs( 'agent', { 'agentnum' => $self->cust_main->agentnum } );
 747       return "agent ". $agent->agentnum. ':'. $agent->agent.
 748              " can't purchase pkgpart ". $self->pkgpart
 749         unless $agent->pkgpart_hashref->{ $self->pkgpart }
 750             || $agent->agentnum == $self->part_pkg->agentnum;
 751     }
 752
 753     $error = $self->ut_foreign_key('pkgpart', 'part_pkg', 'pkgpart' );
 754     return $error if $error;
 755
 756   }
 757
 758   '';
 759
 760 }
 761
 762 =item cancel [ OPTION => VALUE ... ]
 763
 764 Cancels and removes all services (see L<FS::cust_svc> and L<FS::part_svc>)
 765 in this package, then cancels the package itself (sets the cancel field to
 766 now).
 767
 768 Available options are:
 769
 770 =over 4
 771
 772 =item quiet - can be set true to supress email cancellation notices.
 773
 774 =item time -  can be set to cancel the package based on a specific future or
 775 historical date.  Using time ensures that the remaining amount is calculated
 776 correctly.  Note however that this is an immediate cancel and just changes
 777 the date.  You are PROBABLY looking to expire the account instead of using
 778 this.
 779
 780 =item reason - can be set to a cancellation reason (see L<FS:reason>),
 781 either a reasonnum of an existing reason, or passing a hashref will create
 782 a new reason.  The hashref should have the following keys: typenum - Reason
 783 type (see L<FS::reason_type>, reason - Text of the new reason.
 784
 785 =item date - can be set to a unix style timestamp to specify when to
 786 cancel (expire)
 787
 788 =item nobill - can be set true to skip billing if it might otherwise be done.
 789
 790 =item unused_credit - can be set to 1 to credit the remaining time, or 0 to
 791 not credit it.  This must be set (by change()) when changing the package
 792 to a different pkgpart or location, and probably shouldn't be in any other
 793 case.  If it's not set, the 'unused_credit_cancel' part_pkg option will
 794 be used.
 795
 796 =item no_delay_cancel - prevents delay_cancel behavior
 797 no matter what other options say, for use when changing packages (or any
 798 other time you're really sure you want an immediate cancel)
 799
 800 =back
 801
 802 If there is an error, returns the error, otherwise returns false.
 803
 804 =cut
 805
 806 #NOT DOCUMENTING - this should only be used when calling recursively
 807 #=item delay_cancel - for internal use, to allow proper handling of
 808 #supplemental packages when the main package is flagged to suspend
 809 #before cancelling, probably shouldn't be used otherwise (set the
 810 #corresponding package option instead)
 811
 812 sub cancel {
 813   my( $self, %options ) = @_;
 814   my $error;
 815
 816   # pass all suspend/cancel actions to the main package
 817   # (unless the pkglinknum has been removed, then the link is defunct and
 818   # this package can be canceled on its own)
 819   if ( $self->main_pkgnum and $self->pkglinknum and !$options{'from_main'} ) {
 820     return $self->main_pkg->cancel(%options);
 821   }
 822
 823   my $conf = new FS::Conf;
 824
 825   warn "cust_pkg::cancel called with options".
 826        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 827     if $DEBUG;
 828
 829   local $SIG{HUP} = 'IGNORE';
 830   local $SIG{INT} = 'IGNORE';
 831   local $SIG{QUIT} = 'IGNORE';
 832   local $SIG{TERM} = 'IGNORE';
 833   local $SIG{TSTP} = 'IGNORE';
 834   local $SIG{PIPE} = 'IGNORE';
 835
 836   my $oldAutoCommit = $FS::UID::AutoCommit;
 837   local $FS::UID::AutoCommit = 0;
 838   my $dbh = dbh;
 839
 840   my $old = $self->select_for_update;
 841
 842   if ( $old->get('cancel') || $self->get('cancel') ) {
 843     dbh->rollback if $oldAutoCommit;
 844     return "";  # no error
 845   }
 846
 847   # XXX possibly set cancel_time to the expire date?
 848   my $cancel_time = $options{'time'} || time;
 849   my $date = $options{'date'} if $options{'date'}; # expire/cancel later
 850   $date = '' if ($date && $date <= $cancel_time);      # complain instead?
 851
 852   my $delay_cancel = $options{'no_delay_cancel'} ? 0 : $options{'delay_cancel'};
 853   if ( !$date && $self->part_pkg->option('delay_cancel',1)
 854        && (($self->status eq 'active') || ($self->status eq 'suspended'))
 855        && !$options{'no_delay_cancel'}
 856   ) {
 857     my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
 858     my $expsecs = 60*60*24*$expdays;
 859     my $suspfor = $self->susp ? $cancel_time - $self->susp : 0;
 860     $expsecs = $expsecs - $suspfor if $suspfor;
 861     unless ($expsecs <= 0) { #if it's already been suspended long enough, don't re-suspend
 862       $delay_cancel = 1;
 863       $date = $cancel_time + $expsecs;
 864     }
 865   }
 866
 867   #race condition: usage could be ongoing until unprovisioned
 868   #resolved by performing a change package instead (which unprovisions) and
 869   #later cancelling
 870   if ( !$options{nobill} && !$date ) {
 871     # && $conf->exists('bill_usage_on_cancel') ) { #calc_cancel checks this
 872       my $copy = $self->new({$self->hash});
 873       my $error =
 874         $copy->cust_main->bill( 'pkg_list' => [ $copy ],
 875                                 'cancel'   => 1,
 876                                 'time'     => $cancel_time );
 877       warn "Error billing during cancel, custnum ".
 878         #$self->cust_main->custnum. ": $error"
 879         ": $error"
 880         if $error;
 881   }
 882
 883   if ( $options{'reason'} ) {
 884     $error = $self->insert_reason( 'reason' => $options{'reason'},
 885                                    'action' => $date ? 'expire' : 'cancel',
 886                                    'date'   => $date ? $date : $cancel_time,
 887                                    'reason_otaker' => $options{'reason_otaker'},
 888                                  );
 889     if ( $error ) {
 890       dbh->rollback if $oldAutoCommit;
 891       return "Error inserting cust_pkg_reason: $error";
 892     }
 893   }
 894
 895   my %svc_cancel_opt = ();
 896   $svc_cancel_opt{'date'} = $date if $date;
 897   foreach my $cust_svc (
 898     #schwartz
 899     map  { $_->[0] }
 900     sort { $a->[1] <=> $b->[1] }
 901     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; }
 902     qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
 903   ) {
 904     my $part_svc = $cust_svc->part_svc;
 905     next if ( defined($part_svc) and $part_svc->preserve );
 906     my $error = $cust_svc->cancel( %svc_cancel_opt );
 907
 908     if ( $error ) {
 909       $dbh->rollback if $oldAutoCommit;
 910       return 'Error '. ($svc_cancel_opt{'date'} ? 'expiring' : 'canceling' ).
 911              " cust_svc: $error";
 912     }
 913   }
 914
 915   unless ($date) {
 916     # credit remaining time if appropriate
 917     my $do_credit;
 918     if ( exists($options{'unused_credit'}) ) {
 919       $do_credit = $options{'unused_credit'};
 920     }
 921     else {
 922       $do_credit = $self->part_pkg->option('unused_credit_cancel', 1);
 923     }
 924     if ( $do_credit ) {
 925       my $error = $self->credit_remaining('cancel', $cancel_time);
 926       if ($error) {
 927         $dbh->rollback if $oldAutoCommit;
 928         return $error;
 929       }
 930     }
 931   } #unless $date
 932
 933   my %hash = $self->hash;
 934   if ( $date ) {
 935     $hash{'expire'} = $date;
 936     if ($delay_cancel) {
 937       # just to be sure these are clear
 938       $hash{'adjourn'} = undef;
 939       $hash{'resume'} = undef;
 940     }
 941   } else {
 942     $hash{'cancel'} = $cancel_time;
 943   }
 944   $hash{'change_custnum'} = $options{'change_custnum'};
 945
 946   # if this is a supplemental package that's lost its part_pkg_link, and it's
 947   # being canceled for real, unlink it completely
 948   if ( !$date and ! $self->pkglinknum ) {
 949     $hash{main_pkgnum} = '';
 950   }
 951
 952   my $new = new FS::cust_pkg ( \%hash );
 953   $error = $new->replace( $self, options => { $self->options } );
 954   if ( $self->change_to_pkgnum ) {
 955     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
 956     $error ||= $change_to->cancel('no_delay_cancel' => 1) || $change_to->delete;
 957   }
 958   if ( $error ) {
 959     $dbh->rollback if $oldAutoCommit;
 960     return $error;
 961   }
 962
 963   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
 964     $error = $supp_pkg->cancel(%options,
 965       'from_main' => 1,
 966       'date' => $date, #in case it got changed by delay_cancel
 967       'delay_cancel' => $delay_cancel,
 968     );
 969     if ( $error ) {
 970       $dbh->rollback if $oldAutoCommit;
 971       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
 972     }
 973   }
 974
 975   if ($delay_cancel && !$options{'from_main'}) {
 976     $error = $new->suspend(
 977       'from_cancel' => 1,
 978       'time'        => $cancel_time
 979     );
 980   }
 981
 982   unless ($date) {
 983     foreach my $usage ( $self->cust_pkg_usage ) {
 984       $error = $usage->delete;
 985       if ( $error ) {
 986         $dbh->rollback if $oldAutoCommit;
 987         return "deleting usage pools: $error";
 988       }
 989     }
 990   }
 991
 992   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 993   return '' if $date; #no errors
 994
 995   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ } $self->cust_main->invoicing_list;
 996   if ( !$options{'quiet'} &&
 997         $conf->exists('emailcancel', $self->cust_main->agentnum) &&
 998         @invoicing_list ) {
 999     my $msgnum = $conf->config('cancel_msgnum', $self->cust_main->agentnum);
1000     my $error = '';
1001     if ( $msgnum ) {
1002       my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
1003       $error = $msg_template->send( 'cust_main' => $self->cust_main,
1004                                     'object'    => $self );
1005     }
1006     else {
1007       $error = send_email(
1008         'from'    => $conf->invoice_from_full( $self->cust_main->agentnum ),
1009         'to'      => \@invoicing_list,
1010         'subject' => ( $conf->config('cancelsubject') || 'Cancellation Notice' ),
1011         'body'    => [ map "$_\n", $conf->config('cancelmessage') ],
1012         'custnum' => $self->custnum,
1013         'msgtype' => '', #admin?
1014       );
1015     }
1016     #should this do something on errors?
1017   }
1018
1019   ''; #no errors
1020
1021 }
1022
1023 =item cancel_if_expired [ NOW_TIMESTAMP ]
1024
1025 Cancels this package if its expire date has been reached.
1026
1027 =cut
1028
1029 sub cancel_if_expired {
1030   my $self = shift;
1031   my $time = shift || time;
1032   return '' unless $self->expire && $self->expire <= $time;
1033   my $error = $self->cancel;
1034   if ( $error ) {
1035     return "Error cancelling expired pkg ". $self->pkgnum. " for custnum ".
1036            $self->custnum. ": $error";
1037   }
1038   '';
1039 }
1040
1041 =item uncancel
1042
1043 "Un-cancels" this package: Orders a new package with the same custnum, pkgpart,
1044 locationnum, (other fields?).  Attempts to re-provision cancelled services
1045 using history information (errors at this stage are not fatal).
1046
1047 cust_pkg: pass a scalar reference, will be filled in with the new cust_pkg object
1048
1049 svc_fatal: service provisioning errors are fatal
1050
1051 svc_errors: pass an array reference, will be filled in with any provisioning errors
1052
1053 main_pkgnum: link the package as a supplemental package of this one.  For
1054 internal use only.
1055
1056 =cut
1057
1058 sub uncancel {
1059   my( $self, %options ) = @_;
1060
1061   #in case you try do do $uncancel-date = $cust_pkg->uncacel
1062   return '' unless $self->get('cancel');
1063
1064   if ( $self->main_pkgnum and !$options{'main_pkgnum'} ) {
1065     return $self->main_pkg->uncancel(%options);
1066   }
1067
1068   ##
1069   # Transaction-alize
1070   ##
1071
1072   local $SIG{HUP} = 'IGNORE';
1073   local $SIG{INT} = 'IGNORE';
1074   local $SIG{QUIT} = 'IGNORE';
1075   local $SIG{TERM} = 'IGNORE';
1076   local $SIG{TSTP} = 'IGNORE';
1077   local $SIG{PIPE} = 'IGNORE';
1078
1079   my $oldAutoCommit = $FS::UID::AutoCommit;
1080   local $FS::UID::AutoCommit = 0;
1081   my $dbh = dbh;
1082
1083   ##
1084   # insert the new package
1085   ##
1086
1087   my $cust_pkg = new FS::cust_pkg {
1088     last_bill       => ( $options{'last_bill'} || $self->get('last_bill') ),
1089     bill            => ( $options{'bill'}      || $self->get('bill')      ),
1090     uncancel        => time,
1091     uncancel_pkgnum => $self->pkgnum,
1092     main_pkgnum     => ($options{'main_pkgnum'} || ''),
1093     map { $_ => $self->get($_) } qw(
1094       custnum pkgpart locationnum
1095       setup
1096       susp adjourn resume expire start_date contract_end dundate
1097       change_date change_pkgpart change_locationnum
1098       manual_flag no_auto separate_bill quantity agent_pkgid
1099       recur_show_zero setup_show_zero
1100     ),
1101   };
1102
1103   my $error = $cust_pkg->insert(
1104     'change' => 1, #supresses any referral credit to a referring customer
1105     'allow_pkgpart' => 1, # allow this even if the package def is disabled
1106   );
1107   if ($error) {
1108     $dbh->rollback if $oldAutoCommit;
1109     return $error;
1110   }
1111
1112   ##
1113   # insert services
1114   ##
1115
1116   #find historical services within this timeframe before the package cancel
1117   # (incompatible with "time" option to cust_pkg->cancel?)
1118   my $fuzz = 2 * 60; #2 minutes?  too much?   (might catch separate unprovision)
1119                      #            too little? (unprovisioing export delay?)
1120   my($end, $start) = ( $self->get('cancel'), $self->get('cancel') - $fuzz );
1121   my @h_cust_svc = $self->h_cust_svc( $end, $start );
1122
1123   my @svc_errors;
1124   foreach my $h_cust_svc (@h_cust_svc) {
1125     my $h_svc_x = $h_cust_svc->h_svc_x( $end, $start );
1126     #next unless $h_svc_x; #should this happen?
1127     (my $table = $h_svc_x->table) =~ s/^h_//;
1128     require "FS/$table.pm";
1129     my $class = "FS::$table";
1130     my $svc_x = $class->new( {
1131       'pkgnum'  => $cust_pkg->pkgnum,
1132       'svcpart' => $h_cust_svc->svcpart,
1133       map { $_ => $h_svc_x->get($_) } fields($table)
1134     } );
1135
1136     # radius_usergroup
1137     if ( $h_svc_x->isa('FS::h_svc_Radius_Mixin') ) {
1138       $svc_x->usergroup( [ $h_svc_x->h_usergroup($end, $start) ] );
1139     }
1140
1141     my $svc_error = $svc_x->insert;
1142     if ( $svc_error ) {
1143       if ( $options{svc_fatal} ) {
1144         $dbh->rollback if $oldAutoCommit;
1145         return $svc_error;
1146       } else {
1147         # if we've failed to insert the svc_x object, svc_Common->insert
1148         # will have removed the cust_svc already.  if not, then both records
1149         # were inserted but we failed for some other reason (export, most
1150         # likely).  in that case, report the error and delete the records.
1151         push @svc_errors, $svc_error;
1152         my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $svc_x->svcnum });
1153         if ( $cust_svc ) {
1154           # except if export_insert failed, export_delete probably won't be
1155           # much better
1156           local $FS::svc_Common::noexport_hack = 1;
1157           my $cleanup_error = $svc_x->delete; # also deletes cust_svc
1158           if ( $cleanup_error ) { # and if THAT fails, then run away
1159             $dbh->rollback if $oldAutoCommit;
1160             return $cleanup_error;
1161           }
1162         }
1163       } # svc_fatal
1164     } # svc_error
1165   } #foreach $h_cust_svc
1166
1167   #these are pretty rare, but should handle them
1168   # - dsl_device (mac addresses)
1169   # - phone_device (mac addresses)
1170   # - dsl_note (ikano notes)
1171   # - domain_record (i.e. restore DNS information w/domains)
1172   # - inventory_item(?) (inventory w/un-cancelling service?)
1173   # - nas (svc_broaband nas stuff)
1174   #this stuff is unused in the wild afaik
1175   # - mailinglistmember
1176   # - router.svcnum?
1177   # - svc_domain.parent_svcnum?
1178   # - acct_snarf (ancient mail fetching config)
1179   # - cgp_rule (communigate)
1180   # - cust_svc_option (used by our Tron stuff)
1181   # - acct_rt_transaction (used by our time worked stuff)
1182
1183   ##
1184   # also move over any services that didn't unprovision at cancellation
1185   ##
1186
1187   foreach my $cust_svc ( qsearch('cust_svc', { pkgnum => $self->pkgnum } ) ) {
1188     $cust_svc->pkgnum( $cust_pkg->pkgnum );
1189     my $error = $cust_svc->replace;
1190     if ( $error ) {
1191       $dbh->rollback if $oldAutoCommit;
1192       return $error;
1193     }
1194   }
1195
1196   ##
1197   # Uncancel any supplemental packages, and make them supplemental to the
1198   # new one.
1199   ##
1200
1201   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1202     my $new_pkg;
1203     $error = $supp_pkg->uncancel(%options, 'main_pkgnum' => $cust_pkg->pkgnum);
1204     if ( $error ) {
1205       $dbh->rollback if $oldAutoCommit;
1206       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1207     }
1208   }
1209
1210   ##
1211   # Finish
1212   ##
1213
1214   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1215
1216   ${ $options{cust_pkg} }   = $cust_pkg   if ref($options{cust_pkg});
1217   @{ $options{svc_errors} } = @svc_errors if ref($options{svc_errors});
1218
1219   '';
1220 }
1221
1222 =item unexpire
1223
1224 Cancels any pending expiration (sets the expire field to null).
1225
1226 If there is an error, returns the error, otherwise returns false.
1227
1228 =cut
1229
1230 sub unexpire {
1231   my( $self, %options ) = @_;
1232   my $error;
1233
1234   local $SIG{HUP} = 'IGNORE';
1235   local $SIG{INT} = 'IGNORE';
1236   local $SIG{QUIT} = 'IGNORE';
1237   local $SIG{TERM} = 'IGNORE';
1238   local $SIG{TSTP} = 'IGNORE';
1239   local $SIG{PIPE} = 'IGNORE';
1240
1241   my $oldAutoCommit = $FS::UID::AutoCommit;
1242   local $FS::UID::AutoCommit = 0;
1243   my $dbh = dbh;
1244
1245   my $old = $self->select_for_update;
1246
1247   my $pkgnum = $old->pkgnum;
1248   if ( $old->get('cancel') || $self->get('cancel') ) {
1249     dbh->rollback if $oldAutoCommit;
1250     return "Can't unexpire cancelled package $pkgnum";
1251     # or at least it's pointless
1252   }
1253
1254   unless ( $old->get('expire') && $self->get('expire') ) {
1255     dbh->rollback if $oldAutoCommit;
1256     return "";  # no error
1257   }
1258
1259   my %hash = $self->hash;
1260   $hash{'expire'} = '';
1261   my $new = new FS::cust_pkg ( \%hash );
1262   $error = $new->replace( $self, options => { $self->options } );
1263   if ( $error ) {
1264     $dbh->rollback if $oldAutoCommit;
1265     return $error;
1266   }
1267
1268   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1269
1270   ''; #no errors
1271
1272 }
1273
1274 =item suspend [ OPTION => VALUE ... ]
1275
1276 Suspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1277 package, then suspends the package itself (sets the susp field to now).
1278
1279 Available options are:
1280
1281 =over 4
1282
1283 =item reason - can be set to a cancellation reason (see L<FS:reason>),
1284 either a reasonnum of an existing reason, or passing a hashref will create
1285 a new reason.  The hashref should have the following keys:
1286 - typenum - Reason type (see L<FS::reason_type>
1287 - reason - Text of the new reason.
1288
1289 =item date - can be set to a unix style timestamp to specify when to
1290 suspend (adjourn)
1291
1292 =item time - can be set to override the current time, for calculation
1293 of final invoices or unused-time credits
1294
1295 =item resume_date - can be set to a time when the package should be
1296 unsuspended.  This may be more convenient than calling C<unsuspend()>
1297 separately.
1298
1299 =item from_main - allows a supplemental package to be suspended, rather
1300 than redirecting the method call to its main package.  For internal use.
1301
1302 =item from_cancel - used when suspending from the cancel method, forces
1303 this to skip everything besides basic suspension.  For internal use.
1304
1305 =back
1306
1307 If there is an error, returns the error, otherwise returns false.
1308
1309 =cut
1310
1311 sub suspend {
1312   my( $self, %options ) = @_;
1313   my $error;
1314
1315   # pass all suspend/cancel actions to the main package
1316   if ( $self->main_pkgnum and !$options{'from_main'} ) {
1317     return $self->main_pkg->suspend(%options);
1318   }
1319
1320   local $SIG{HUP} = 'IGNORE';
1321   local $SIG{INT} = 'IGNORE';
1322   local $SIG{QUIT} = 'IGNORE';
1323   local $SIG{TERM} = 'IGNORE';
1324   local $SIG{TSTP} = 'IGNORE';
1325   local $SIG{PIPE} = 'IGNORE';
1326
1327   my $oldAutoCommit = $FS::UID::AutoCommit;
1328   local $FS::UID::AutoCommit = 0;
1329   my $dbh = dbh;
1330
1331   my $old = $self->select_for_update;
1332
1333   my $pkgnum = $old->pkgnum;
1334   if ( $old->get('cancel') || $self->get('cancel') ) {
1335     dbh->rollback if $oldAutoCommit;
1336     return "Can't suspend cancelled package $pkgnum";
1337   }
1338
1339   if ( $old->get('susp') || $self->get('susp') ) {
1340     dbh->rollback if $oldAutoCommit;
1341     return "";  # no error                     # complain on adjourn?
1342   }
1343
1344   my $suspend_time = $options{'time'} || time;
1345   my $date = $options{date} if $options{date}; # adjourn/suspend later
1346   $date = '' if ($date && $date <= $suspend_time); # complain instead?
1347
1348   if ( $date && $old->get('expire') && $old->get('expire') < $date ) {
1349     dbh->rollback if $oldAutoCommit;
1350     return "Package $pkgnum expires before it would be suspended.";
1351   }
1352
1353   # some false laziness with sub cancel
1354   if ( !$options{nobill} && !$date && !$options{'from_cancel'} &&
1355        $self->part_pkg->option('bill_suspend_as_cancel',1) ) {
1356     # kind of a kludge--'bill_suspend_as_cancel' to avoid having to
1357     # make the entire cust_main->bill path recognize 'suspend' and
1358     # 'cancel' separately.
1359     warn "Billing $pkgnum on suspension (at $suspend_time)\n" if $DEBUG;
1360     my $copy = $self->new({$self->hash});
1361     my $error =
1362       $copy->cust_main->bill( 'pkg_list' => [ $copy ],
1363                               'cancel'   => 1,
1364                               'time'     => $suspend_time );
1365     warn "Error billing during suspend, custnum ".
1366       #$self->cust_main->custnum. ": $error"
1367       ": $error"
1368       if $error;
1369   }
1370
1371   my $cust_pkg_reason;
1372   if ( $options{'reason'} ) {
1373     $error = $self->insert_reason( 'reason' => $options{'reason'},
1374                                    'action' => $date ? 'adjourn' : 'suspend',
1375                                    'date'   => $date ? $date : $suspend_time,
1376                                    'reason_otaker' => $options{'reason_otaker'},
1377                                  );
1378     if ( $error ) {
1379       dbh->rollback if $oldAutoCommit;
1380       return "Error inserting cust_pkg_reason: $error";
1381     }
1382     $cust_pkg_reason = qsearchs('cust_pkg_reason', {
1383         'date'    => $date ? $date : $suspend_time,
1384         'action'  => $date ? 'A' : 'S',
1385         'pkgnum'  => $self->pkgnum,
1386     });
1387   }
1388
1389   # if a reasonnum was passed, get the actual reason object so we can check
1390   # unused_credit
1391   # (passing a reason hashref is still allowed, but it can't be used with
1392   # the fancy behavioral options.)
1393
1394   my $reason;
1395   if ($options{'reason'} =~ /^\d+$/) {
1396     $reason = FS::reason->by_key($options{'reason'});
1397   }
1398
1399   my %hash = $self->hash;
1400   if ( $date ) {
1401     $hash{'adjourn'} = $date;
1402   } else {
1403     $hash{'susp'} = $suspend_time;
1404   }
1405
1406   my $resume_date = $options{'resume_date'} || 0;
1407   if ( $resume_date > ($date || $suspend_time) ) {
1408     $hash{'resume'} = $resume_date;
1409   }
1410
1411   $options{options} ||= {};
1412
1413   my $new = new FS::cust_pkg ( \%hash );
1414   $error = $new->replace( $self, options => { $self->options,
1415                                               %{ $options{options} },
1416                                             }
1417                         );
1418   if ( $error ) {
1419     $dbh->rollback if $oldAutoCommit;
1420     return $error;
1421   }
1422
1423   unless ( $date ) { # then we are suspending now
1424
1425     unless ($options{'from_cancel'}) {
1426       # credit remaining time if appropriate
1427       # (if required by the package def, or the suspend reason)
1428       my $unused_credit = $self->part_pkg->option('unused_credit_suspend',1)
1429                           || ( defined($reason) && $reason->unused_credit );
1430
1431       if ( $unused_credit ) {
1432         warn "crediting unused time on pkg#".$self->pkgnum."\n" if $DEBUG;
1433         my $error = $self->credit_remaining('suspend', $suspend_time);
1434         if ($error) {
1435           $dbh->rollback if $oldAutoCommit;
1436           return $error;
1437         }
1438       }
1439     }
1440
1441     my @labels = ();
1442
1443     foreach my $cust_svc (
1444       qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
1445     ) {
1446       my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1447
1448       $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1449         $dbh->rollback if $oldAutoCommit;
1450         return "Illegal svcdb value in part_svc!";
1451       };
1452       my $svcdb = $1;
1453       require "FS/$svcdb.pm";
1454
1455       my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1456       if ($svc) {
1457         $error = $svc->suspend;
1458         if ( $error ) {
1459           $dbh->rollback if $oldAutoCommit;
1460           return $error;
1461         }
1462         my( $label, $value ) = $cust_svc->label;
1463         push @labels, "$label: $value";
1464       }
1465     }
1466
1467     # suspension fees: if there is a feepart, and it's not an unsuspend fee,
1468     # and this is not a suspend-before-cancel
1469     if ( $cust_pkg_reason ) {
1470       my $reason_obj = $cust_pkg_reason->reason;
1471       if ( $reason_obj->feepart and
1472            ! $reason_obj->fee_on_unsuspend and
1473            ! $options{'from_cancel'} ) {
1474
1475         # register the need to charge a fee, cust_main->bill will do the rest
1476         warn "registering suspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1477           if $DEBUG;
1478         my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1479             'pkgreasonnum'  => $cust_pkg_reason->num,
1480             'pkgnum'        => $self->pkgnum,
1481             'feepart'       => $reason->feepart,
1482             'nextbill'      => $reason->fee_hold,
1483         });
1484         $error ||= $cust_pkg_reason_fee->insert;
1485       }
1486     }
1487
1488     my $conf = new FS::Conf;
1489     if ( $conf->config('suspend_email_admin') && !$options{'from_cancel'} ) {
1490
1491       my $error = send_email(
1492         'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1493                                    #invoice_from ??? well as good as any
1494         'to'      => $conf->config('suspend_email_admin'),
1495         'subject' => 'FREESIDE NOTIFICATION: Customer package suspended',
1496         'body'    => [
1497           "This is an automatic message from your Freeside installation\n",
1498           "informing you that the following customer package has been suspended:\n",
1499           "\n",
1500           'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1501           'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1502           ( map { "Service : $_\n" } @labels ),
1503         ],
1504         'custnum' => $self->custnum,
1505         'msgtype' => 'admin'
1506       );
1507
1508       if ( $error ) {
1509         warn "WARNING: can't send suspension admin email (suspending anyway): ".
1510              "$error\n";
1511       }
1512
1513     }
1514
1515   }
1516
1517   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1518     $error = $supp_pkg->suspend(%options, 'from_main' => 1);
1519     if ( $error ) {
1520       $dbh->rollback if $oldAutoCommit;
1521       return "suspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1522     }
1523   }
1524
1525   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1526
1527   ''; #no errors
1528 }
1529
1530 =item credit_remaining MODE TIME
1531
1532 Generate a credit for this package for the time remaining in the current
1533 billing period.  MODE is either "suspend" or "cancel" (determines the
1534 credit type).  TIME is the time of suspension/cancellation.  Both arguments
1535 are mandatory.
1536
1537 =cut
1538
1539 # Implementation note:
1540 #
1541 # If you pkgpart-change a package that has been billed, and it's set to give
1542 # credit on package change, then this method gets called and then the new
1543 # package will have no last_bill date. Therefore the customer will be credited
1544 # only once (per billing period) even if there are multiple package changes.
1545 #
1546 # If you location-change a package that has been billed, this method will NOT
1547 # be called and the new package WILL have the last bill date of the old
1548 # package.
1549 #
1550 # If the new package is then canceled within the same billing cycle,
1551 # credit_remaining needs to run calc_remain on the OLD package to determine
1552 # the amount of unused time to credit.
1553
1554 sub credit_remaining {
1555   # Add a credit for remaining service
1556   my ($self, $mode, $time) = @_;
1557   die 'credit_remaining requires suspend or cancel'
1558     unless $mode eq 'suspend' or $mode eq 'cancel';
1559   die 'no suspend/cancel time' unless $time > 0;
1560
1561   my $conf = FS::Conf->new;
1562   my $reason_type = $conf->config($mode.'_credit_type');
1563
1564   my $last_bill = $self->getfield('last_bill') || 0;
1565   my $next_bill = $self->getfield('bill') || 0;
1566   if ( $last_bill > 0         # the package has been billed
1567       and $next_bill > 0      # the package has a next bill date
1568       and $next_bill >= $time # which is in the future
1569   ) {
1570     my $remaining_value = 0;
1571
1572     my $remain_pkg = $self;
1573     $remaining_value = $remain_pkg->calc_remain('time' => $time);
1574
1575     # we may have to walk back past some package changes to get to the
1576     # one that actually has unused time
1577     while ( $remaining_value == 0 ) {
1578       if ( $remain_pkg->change_pkgnum ) {
1579         $remain_pkg = FS::cust_pkg->by_key($remain_pkg->change_pkgnum);
1580       } else {
1581         # the package has really never been billed
1582         return;
1583       }
1584       $remaining_value = $remain_pkg->calc_remain('time' => $time);
1585     }
1586
1587     if ( $remaining_value > 0 ) {
1588       warn "Crediting for $remaining_value on package ".$self->pkgnum."\n"
1589         if $DEBUG;
1590       my $error = $self->cust_main->credit(
1591         $remaining_value,
1592         'Credit for unused time on '. $self->part_pkg->pkg,
1593         'reason_type' => $reason_type,
1594       );
1595       return "Error crediting customer \$$remaining_value for unused time".
1596         " on ". $self->part_pkg->pkg. ": $error"
1597         if $error;
1598     } #if $remaining_value
1599   } #if $last_bill, etc.
1600   '';
1601 }
1602
1603 =item unsuspend [ OPTION => VALUE ... ]
1604
1605 Unsuspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1606 package, then unsuspends the package itself (clears the susp field and the
1607 adjourn field if it is in the past).  If the suspend reason includes an
1608 unsuspension package, that package will be ordered.
1609
1610 Available options are:
1611
1612 =over 4
1613
1614 =item date
1615
1616 Can be set to a date to unsuspend the package in the future (the 'resume'
1617 field).
1618
1619 =item adjust_next_bill
1620
1621 Can be set true to adjust the next bill date forward by
1622 the amount of time the account was inactive.  This was set true by default
1623 in the past (from 1.4.2 and 1.5.0pre6 through 1.7.0), but now needs to be
1624 explicitly requested with this option or in the price plan.
1625
1626 =back
1627
1628 If there is an error, returns the error, otherwise returns false.
1629
1630 =cut
1631
1632 sub unsuspend {
1633   my( $self, %opt ) = @_;
1634   my $error;
1635
1636   # pass all suspend/cancel actions to the main package
1637   if ( $self->main_pkgnum and !$opt{'from_main'} ) {
1638     return $self->main_pkg->unsuspend(%opt);
1639   }
1640
1641   local $SIG{HUP} = 'IGNORE';
1642   local $SIG{INT} = 'IGNORE';
1643   local $SIG{QUIT} = 'IGNORE';
1644   local $SIG{TERM} = 'IGNORE';
1645   local $SIG{TSTP} = 'IGNORE';
1646   local $SIG{PIPE} = 'IGNORE';
1647
1648   my $oldAutoCommit = $FS::UID::AutoCommit;
1649   local $FS::UID::AutoCommit = 0;
1650   my $dbh = dbh;
1651
1652   my $old = $self->select_for_update;
1653
1654   my $pkgnum = $old->pkgnum;
1655   if ( $old->get('cancel') || $self->get('cancel') ) {
1656     $dbh->rollback if $oldAutoCommit;
1657     return "Can't unsuspend cancelled package $pkgnum";
1658   }
1659
1660   unless ( $old->get('susp') && $self->get('susp') ) {
1661     $dbh->rollback if $oldAutoCommit;
1662     return "";  # no error                     # complain instead?
1663   }
1664
1665   # handle the case of setting a future unsuspend (resume) date
1666   # and do not continue to actually unsuspend the package
1667   my $date = $opt{'date'};
1668   if ( $date and $date > time ) { # return an error if $date <= time?
1669
1670     if ( $old->get('expire') && $old->get('expire') < $date ) {
1671       $dbh->rollback if $oldAutoCommit;
1672       return "Package $pkgnum expires before it would be unsuspended.";
1673     }
1674
1675     my $new = new FS::cust_pkg { $self->hash };
1676     $new->set('resume', $date);
1677     $error = $new->replace($self, options => $self->options);
1678
1679     if ( $error ) {
1680       $dbh->rollback if $oldAutoCommit;
1681       return $error;
1682     }
1683     else {
1684       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1685       return '';
1686     }
1687
1688   } #if $date
1689
1690   if (!$self->setup) {
1691     # then this package is being released from on-hold status
1692     $self->set_initial_timers;
1693   }
1694
1695   my @labels = ();
1696
1697   foreach my $cust_svc (
1698     qsearch('cust_svc',{'pkgnum'=> $self->pkgnum } )
1699   ) {
1700     my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1701
1702     $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1703       $dbh->rollback if $oldAutoCommit;
1704       return "Illegal svcdb value in part_svc!";
1705     };
1706     my $svcdb = $1;
1707     require "FS/$svcdb.pm";
1708
1709     my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1710     if ($svc) {
1711       $error = $svc->unsuspend;
1712       if ( $error ) {
1713         $dbh->rollback if $oldAutoCommit;
1714         return $error;
1715       }
1716       my( $label, $value ) = $cust_svc->label;
1717       push @labels, "$label: $value";
1718     }
1719
1720   }
1721
1722   my $cust_pkg_reason = $self->last_cust_pkg_reason('susp');
1723   my $reason = $cust_pkg_reason ? $cust_pkg_reason->reason : '';
1724
1725   my %hash = $self->hash;
1726   my $inactive = time - $hash{'susp'};
1727
1728   my $conf = new FS::Conf;
1729
1730   # increment next bill date if certain conditions are met:
1731   # - it was due to be billed at some point
1732   # - either the global or local config says to do this
1733   my $adjust_bill = 0;
1734   if (
1735        $inactive > 0
1736     && ( $hash{'bill'} || $hash{'setup'} )
1737     && (    $opt{'adjust_next_bill'}
1738          || $conf->exists('unsuspend-always_adjust_next_bill_date')
1739          || $self->part_pkg->option('unsuspend_adjust_bill', 1)
1740        )
1741   ) {
1742     $adjust_bill = 1;
1743   }
1744
1745   # but not if:
1746   # - the package billed during suspension
1747   # - or it was ordered on hold
1748   # - or the customer was credited for the unused time
1749
1750   if ( $self->option('suspend_bill',1)
1751       or ( $self->part_pkg->option('suspend_bill',1)
1752            and ! $self->option('no_suspend_bill',1)
1753          )
1754       or $hash{'order_date'} == $hash{'susp'}
1755   ) {
1756     $adjust_bill = 0;
1757   }
1758
1759   if ( $adjust_bill ) {
1760     if (    $self->part_pkg->option('unused_credit_suspend')
1761          or ( $reason and $reason->unused_credit ) ) {
1762       # then the customer was credited for the unused time before suspending,
1763       # so their next bill should be immediate.
1764       $hash{'bill'} = time;
1765     } else {
1766       # add the length of time suspended to the bill date
1767       $hash{'bill'} = ( $hash{'bill'} || $hash{'setup'} ) + $inactive;
1768     }
1769   }
1770
1771   $hash{'susp'} = '';
1772   $hash{'adjourn'} = '' if $hash{'adjourn'} and $hash{'adjourn'} < time;
1773   $hash{'resume'} = '' if !$hash{'adjourn'};
1774   my $new = new FS::cust_pkg ( \%hash );
1775   $error = $new->replace( $self, options => { $self->options } );
1776   if ( $error ) {
1777     $dbh->rollback if $oldAutoCommit;
1778     return $error;
1779   }
1780
1781   my $unsusp_pkg;
1782
1783   if ( $reason ) {
1784     if ( $reason->unsuspend_pkgpart ) {
1785       #warn "Suspend reason '".$reason->reason."' uses deprecated unsuspend_pkgpart feature.\n"; # in 4.x
1786       my $part_pkg = FS::part_pkg->by_key($reason->unsuspend_pkgpart)
1787         or $error = "Unsuspend package definition ".$reason->unsuspend_pkgpart.
1788                     " not found.";
1789       my $start_date = $self->cust_main->next_bill_date
1790         if $reason->unsuspend_hold;
1791
1792       if ( $part_pkg ) {
1793         $unsusp_pkg = FS::cust_pkg->new({
1794             'custnum'     => $self->custnum,
1795             'pkgpart'     => $reason->unsuspend_pkgpart,
1796             'start_date'  => $start_date,
1797             'locationnum' => $self->locationnum,
1798             # discount? probably not...
1799         });
1800
1801         $error ||= $self->cust_main->order_pkg( 'cust_pkg' => $unsusp_pkg );
1802       }
1803     }
1804     # new way, using fees
1805     if ( $reason->feepart and $reason->fee_on_unsuspend ) {
1806       # register the need to charge a fee, cust_main->bill will do the rest
1807       warn "registering unsuspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1808         if $DEBUG;
1809       my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1810           'pkgreasonnum'  => $cust_pkg_reason->num,
1811           'pkgnum'        => $self->pkgnum,
1812           'feepart'       => $reason->feepart,
1813           'nextbill'      => $reason->fee_hold,
1814       });
1815       $error ||= $cust_pkg_reason_fee->insert;
1816     }
1817
1818     if ( $error ) {
1819       $dbh->rollback if $oldAutoCommit;
1820       return $error;
1821     }
1822   }
1823
1824   if ( $conf->config('unsuspend_email_admin') ) {
1825
1826     my $error = send_email(
1827       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1828                                  #invoice_from ??? well as good as any
1829       'to'      => $conf->config('unsuspend_email_admin'),
1830       'subject' => 'FREESIDE NOTIFICATION: Customer package unsuspended',       'body'    => [
1831         "This is an automatic message from your Freeside installation\n",
1832         "informing you that the following customer package has been unsuspended:\n",
1833         "\n",
1834         'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1835         'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1836         ( map { "Service : $_\n" } @labels ),
1837         ($unsusp_pkg ?
1838           "An unsuspension fee was charged: ".
1839             $unsusp_pkg->part_pkg->pkg_comment."\n"
1840           : ''
1841         ),
1842       ],
1843       'custnum' => $self->custnum,
1844       'msgtype' => 'admin',
1845     );
1846
1847     if ( $error ) {
1848       warn "WARNING: can't send unsuspension admin email (unsuspending anyway): ".
1849            "$error\n";
1850     }
1851
1852   }
1853
1854   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1855     $error = $supp_pkg->unsuspend(%opt, 'from_main' => 1);
1856     if ( $error ) {
1857       $dbh->rollback if $oldAutoCommit;
1858       return "unsuspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1859     }
1860   }
1861
1862   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1863
1864   ''; #no errors
1865 }
1866
1867 =item unadjourn
1868
1869 Cancels any pending suspension (sets the adjourn field to null).
1870
1871 If there is an error, returns the error, otherwise returns false.
1872
1873 =cut
1874
1875 sub unadjourn {
1876   my( $self, %options ) = @_;
1877   my $error;
1878
1879   local $SIG{HUP} = 'IGNORE';
1880   local $SIG{INT} = 'IGNORE';
1881   local $SIG{QUIT} = 'IGNORE';
1882   local $SIG{TERM} = 'IGNORE';
1883   local $SIG{TSTP} = 'IGNORE';
1884   local $SIG{PIPE} = 'IGNORE';
1885
1886   my $oldAutoCommit = $FS::UID::AutoCommit;
1887   local $FS::UID::AutoCommit = 0;
1888   my $dbh = dbh;
1889
1890   my $old = $self->select_for_update;
1891
1892   my $pkgnum = $old->pkgnum;
1893   if ( $old->get('cancel') || $self->get('cancel') ) {
1894     dbh->rollback if $oldAutoCommit;
1895     return "Can't unadjourn cancelled package $pkgnum";
1896     # or at least it's pointless
1897   }
1898
1899   if ( $old->get('susp') || $self->get('susp') ) {
1900     dbh->rollback if $oldAutoCommit;
1901     return "Can't unadjourn suspended package $pkgnum";
1902     # perhaps this is arbitrary
1903   }
1904
1905   unless ( $old->get('adjourn') && $self->get('adjourn') ) {
1906     dbh->rollback if $oldAutoCommit;
1907     return "";  # no error
1908   }
1909
1910   my %hash = $self->hash;
1911   $hash{'adjourn'} = '';
1912   $hash{'resume'}  = '';
1913   my $new = new FS::cust_pkg ( \%hash );
1914   $error = $new->replace( $self, options => { $self->options } );
1915   if ( $error ) {
1916     $dbh->rollback if $oldAutoCommit;
1917     return $error;
1918   }
1919
1920   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1921
1922   ''; #no errors
1923
1924 }
1925
1926
1927 =item change HASHREF | OPTION => VALUE ...
1928
1929 Changes this package: cancels it and creates a new one, with a different
1930 pkgpart or locationnum or both.  All services are transferred to the new
1931 package (no change will be made if this is not possible).
1932
1933 Options may be passed as a list of key/value pairs or as a hash reference.
1934 Options are:
1935
1936 =over 4
1937
1938 =item locationnum
1939
1940 New locationnum, to change the location for this package.
1941
1942 =item cust_location
1943
1944 New FS::cust_location object, to create a new location and assign it
1945 to this package.
1946
1947 =item cust_main
1948
1949 New FS::cust_main object, to create a new customer and assign the new package
1950 to it.
1951
1952 =item pkgpart
1953
1954 New pkgpart (see L<FS::part_pkg>).
1955
1956 =item refnum
1957
1958 New refnum (see L<FS::part_referral>).
1959
1960 =item quantity
1961
1962 New quantity; if unspecified, the new package will have the same quantity
1963 as the old.
1964
1965 =item cust_pkg
1966
1967 "New" (existing) FS::cust_pkg object.  The package's services and other
1968 attributes will be transferred to this package.
1969
1970 =item keep_dates
1971
1972 Set to true to transfer billing dates (start_date, setup, last_bill, bill,
1973 susp, adjourn, cancel, expire, and contract_end) to the new package.
1974
1975 =item unprotect_svcs
1976
1977 Normally, change() will rollback and return an error if some services
1978 can't be transferred (also see the I<cust_pkg-change_svcpart> config option).
1979 If unprotect_svcs is true, this method will transfer as many services as
1980 it can and then unconditionally cancel the old package.
1981
1982 =back
1983
1984 At least one of locationnum, cust_location, pkgpart, refnum, cust_main, or
1985 cust_pkg must be specified (otherwise, what's the point?)
1986
1987 Returns either the new FS::cust_pkg object or a scalar error.
1988
1989 For example:
1990
1991   my $err_or_new_cust_pkg = $old_cust_pkg->change
1992
1993 =cut
1994
1995 #some false laziness w/order
1996 sub change {
1997   my $self = shift;
1998   my $opt = ref($_[0]) ? shift : { @_ };
1999
2000   my $conf = new FS::Conf;
2001
2002   # Transactionize this whole mess
2003   local $SIG{HUP} = 'IGNORE';
2004   local $SIG{INT} = 'IGNORE';
2005   local $SIG{QUIT} = 'IGNORE';
2006   local $SIG{TERM} = 'IGNORE';
2007   local $SIG{TSTP} = 'IGNORE';
2008   local $SIG{PIPE} = 'IGNORE';
2009
2010   my $oldAutoCommit = $FS::UID::AutoCommit;
2011   local $FS::UID::AutoCommit = 0;
2012   my $dbh = dbh;
2013
2014   my $error;
2015
2016   if ( $opt->{'cust_location'} ) {
2017     $error = $opt->{'cust_location'}->find_or_insert;
2018     if ( $error ) {
2019       $dbh->rollback if $oldAutoCommit;
2020       return "creating location record: $error";
2021     }
2022     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
2023   }
2024
2025   # Before going any further here: if the package is still in the pre-setup
2026   # state, it's safe to modify it in place. No need to charge/credit for
2027   # partial period, transfer services, transfer usage pools, copy invoice
2028   # details, or change any dates.
2029   if ( ! $self->setup and ! $opt->{cust_pkg} and ! $opt->{cust_main} ) {
2030     foreach ( qw( locationnum pkgpart quantity refnum salesnum ) ) {
2031       if ( length($opt->{$_}) ) {
2032         $self->set($_, $opt->{$_});
2033       }
2034     }
2035     # almost. if the new pkgpart specifies start/adjourn/expire timers,
2036     # apply those.
2037     if ( $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart ) {
2038       $self->set_initial_timers;
2039     }
2040     $error = $self->replace;
2041     if ( $error ) {
2042       $dbh->rollback if $oldAutoCommit;
2043       return "modifying package: $error";
2044     } else {
2045       $dbh->commit if $oldAutoCommit;
2046       return '';
2047     }
2048   }
2049
2050   my %hash = ();
2051
2052   my $time = time;
2053
2054   $hash{'setup'} = $time if $self->setup;
2055
2056   $hash{'change_date'} = $time;
2057   $hash{"change_$_"}  = $self->$_()
2058     foreach qw( pkgnum pkgpart locationnum );
2059
2060   if ( $opt->{'cust_pkg'} ) {
2061     # treat changing to a package with a different pkgpart as a
2062     # pkgpart change (because it is)
2063     $opt->{'pkgpart'} = $opt->{'cust_pkg'}->pkgpart;
2064   }
2065
2066   # whether to override pkgpart checking on the new package
2067   my $same_pkgpart = 1;
2068   if ( $opt->{'pkgpart'} and ( $opt->{'pkgpart'} != $self->pkgpart ) ) {
2069     $same_pkgpart = 0;
2070   }
2071
2072   my $unused_credit = 0;
2073   my $keep_dates = $opt->{'keep_dates'};
2074
2075   # Special case.  If the pkgpart is changing, and the customer is
2076   # going to be credited for remaining time, don't keep setup, bill,
2077   # or last_bill dates, and DO pass the flag to cancel() to credit
2078   # the customer.
2079   if ( $opt->{'pkgpart'}
2080        and $opt->{'pkgpart'} != $self->pkgpart
2081        and $self->part_pkg->option('unused_credit_change', 1) ) {
2082     $unused_credit = 1;
2083     $keep_dates = 0;
2084     $hash{$_} = '' foreach qw(setup bill last_bill);
2085   }
2086
2087   if ( $keep_dates ) {
2088     foreach my $date ( qw(setup bill last_bill susp adjourn cancel expire
2089                           resume start_date contract_end ) ) {
2090       $hash{$date} = $self->getfield($date);
2091     }
2092   }
2093   # always keep this date, regardless of anything
2094   # (the date of the package change is in a different field)
2095   $hash{'order_date'} = $self->getfield('order_date');
2096
2097   # allow $opt->{'locationnum'} = '' to specifically set it to null
2098   # (i.e. customer default location)
2099   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2100
2101   # usually this doesn't matter.  the two cases where it does are:
2102   # 1. unused_credit_change + pkgpart change + setup fee on the new package
2103   # and
2104   # 2. (more importantly) changing a package before it's billed
2105   $hash{'waive_setup'} = $self->waive_setup;
2106
2107   # if this package is scheduled for a future package change, preserve that
2108   $hash{'change_to_pkgnum'} = $self->change_to_pkgnum;
2109
2110   my $custnum = $self->custnum;
2111   if ( $opt->{cust_main} ) {
2112     my $cust_main = $opt->{cust_main};
2113     unless ( $cust_main->custnum ) {
2114       my $error = $cust_main->insert( @{ $opt->{cust_main_insert_args}||[] } );
2115       if ( $error ) {
2116         $dbh->rollback if $oldAutoCommit;
2117         return "inserting customer record: $error";
2118       }
2119     }
2120     $custnum = $cust_main->custnum;
2121   }
2122
2123   $hash{'contactnum'} = $opt->{'contactnum'} if $opt->{'contactnum'};
2124
2125   my $cust_pkg;
2126   if ( $opt->{'cust_pkg'} ) {
2127     # The target package already exists; update it to show that it was
2128     # changed from this package.
2129     $cust_pkg = $opt->{'cust_pkg'};
2130
2131     foreach ( qw( pkgnum pkgpart locationnum ) ) {
2132       $cust_pkg->set("change_$_", $self->get($_));
2133     }
2134     $cust_pkg->set('change_date', $time);
2135     $cust_pkg->set('start_date', ''); # it's starting now
2136     # if we are crediting unused time, then create the new package as a new
2137     # package, charge its setup fee, etc. (same as an immediate change)
2138     if (! $unused_credit) {
2139       foreach my $date ( qw(setup bill last_bill susp adjourn resume
2140                             contract_end ) ) {
2141         $cust_pkg->set($date, $self->getfield($date));
2142       }
2143     }
2144     $error = $cust_pkg->replace;
2145
2146   } else {
2147     # Create the new package.
2148     $cust_pkg = new FS::cust_pkg {
2149       custnum     => $custnum,
2150       locationnum => $opt->{'locationnum'},
2151       ( map {  $_ => ( $opt->{$_} || $self->$_() )  }
2152           qw( pkgpart quantity refnum salesnum )
2153       ),
2154       %hash,
2155     };
2156     $error = $cust_pkg->insert( 'change' => 1,
2157                                 'allow_pkgpart' => $same_pkgpart );
2158   }
2159   if ($error) {
2160     $dbh->rollback if $oldAutoCommit;
2161     return "inserting new package: $error";
2162   }
2163
2164   # Transfer services and cancel old package.
2165   # Enforce service limits only if this is a pkgpart change.
2166   local $FS::cust_svc::ignore_quantity;
2167   $FS::cust_svc::ignore_quantity = 1 if $same_pkgpart;
2168   $error = $self->transfer($cust_pkg);
2169   if ($error and $error == 0) {
2170     # $old_pkg->transfer failed.
2171     $dbh->rollback if $oldAutoCommit;
2172     return "transferring $error";
2173   }
2174
2175   if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
2176     warn "trying transfer again with change_svcpart option\n" if $DEBUG;
2177     $error = $self->transfer($cust_pkg, 'change_svcpart'=>1 );
2178     if ($error and $error == 0) {
2179       # $old_pkg->transfer failed.
2180       $dbh->rollback if $oldAutoCommit;
2181       return "converting $error";
2182     }
2183   }
2184
2185   # We set unprotect_svcs when executing a "future package change".  It's
2186   # not a user-interactive operation, so returning an error means the
2187   # package change will just fail.  Rather than have that happen, we'll
2188   # let leftover services be deleted.
2189   if ($error > 0 and !$opt->{'unprotect_svcs'}) {
2190     # Transfers were successful, but we still had services left on the old
2191     # package.  We can't change the package under this circumstances, so abort.
2192     $dbh->rollback if $oldAutoCommit;
2193     return "unable to transfer all services";
2194   }
2195
2196   #reset usage if changing pkgpart
2197   # AND usage rollover is off (otherwise adds twice, now and at package bill)
2198   if ($self->pkgpart != $cust_pkg->pkgpart) {
2199     my $part_pkg = $cust_pkg->part_pkg;
2200     $error = $part_pkg->reset_usage($cust_pkg, $part_pkg->is_prepaid
2201                                                  ? ()
2202                                                  : ( 'null' => 1 )
2203                                    )
2204       if $part_pkg->can('reset_usage') && ! $part_pkg->option('usage_rollover',1);
2205
2206     if ($error) {
2207       $dbh->rollback if $oldAutoCommit;
2208       return "setting usage values: $error";
2209     }
2210   } else {
2211     # if NOT changing pkgpart, transfer any usage pools over
2212     foreach my $usage ($self->cust_pkg_usage) {
2213       $usage->set('pkgnum', $cust_pkg->pkgnum);
2214       $error = $usage->replace;
2215       if ( $error ) {
2216         $dbh->rollback if $oldAutoCommit;
2217         return "transferring usage pools: $error";
2218       }
2219     }
2220   }
2221
2222   # transfer discounts, if we're not changing pkgpart
2223   if ( $same_pkgpart ) {
2224     foreach my $old_discount ($self->cust_pkg_discount_active) {
2225       # don't remove the old discount, we may still need to bill that package.
2226       my $new_discount = new FS::cust_pkg_discount {
2227         'pkgnum'      => $cust_pkg->pkgnum,
2228         'discountnum' => $old_discount->discountnum,
2229         'months_used' => $old_discount->months_used,
2230       };
2231       $error = $new_discount->insert;
2232       if ( $error ) {
2233         $dbh->rollback if $oldAutoCommit;
2234         return "transferring discounts: $error";
2235       }
2236     }
2237   }
2238
2239   # transfer (copy) invoice details
2240   foreach my $detail ($self->cust_pkg_detail) {
2241     my $new_detail = FS::cust_pkg_detail->new({ $detail->hash });
2242     $new_detail->set('pkgdetailnum', '');
2243     $new_detail->set('pkgnum', $cust_pkg->pkgnum);
2244     $error = $new_detail->insert;
2245     if ( $error ) {
2246       $dbh->rollback if $oldAutoCommit;
2247       return "transferring package notes: $error";
2248     }
2249   }
2250
2251   my @new_supp_pkgs;
2252
2253   if ( !$opt->{'cust_pkg'} ) {
2254     # Order any supplemental packages.
2255     my $part_pkg = $cust_pkg->part_pkg;
2256     my @old_supp_pkgs = $self->supplemental_pkgs;
2257     foreach my $link ($part_pkg->supp_part_pkg_link) {
2258       my $old;
2259       foreach (@old_supp_pkgs) {
2260         if ($_->pkgpart == $link->dst_pkgpart) {
2261           $old = $_;
2262           $_->pkgpart(0); # so that it can't match more than once
2263         }
2264         last if $old;
2265       }
2266       # false laziness with FS::cust_main::Packages::order_pkg
2267       my $new = FS::cust_pkg->new({
2268           pkgpart       => $link->dst_pkgpart,
2269           pkglinknum    => $link->pkglinknum,
2270           custnum       => $custnum,
2271           main_pkgnum   => $cust_pkg->pkgnum,
2272           locationnum   => $cust_pkg->locationnum,
2273           start_date    => $cust_pkg->start_date,
2274           order_date    => $cust_pkg->order_date,
2275           expire        => $cust_pkg->expire,
2276           adjourn       => $cust_pkg->adjourn,
2277           contract_end  => $cust_pkg->contract_end,
2278           refnum        => $cust_pkg->refnum,
2279           discountnum   => $cust_pkg->discountnum,
2280           waive_setup   => $cust_pkg->waive_setup,
2281       });
2282       if ( $old and $opt->{'keep_dates'} ) {
2283         foreach (qw(setup bill last_bill)) {
2284           $new->set($_, $old->get($_));
2285         }
2286       }
2287       $error = $new->insert( allow_pkgpart => $same_pkgpart );
2288       # transfer services
2289       if ( $old ) {
2290         $error ||= $old->transfer($new);
2291       }
2292       if ( $error and $error > 0 ) {
2293         # no reason why this should ever fail, but still...
2294         $error = "Unable to transfer all services from supplemental package ".
2295           $old->pkgnum;
2296       }
2297       if ( $error ) {
2298         $dbh->rollback if $oldAutoCommit;
2299         return $error;
2300       }
2301       push @new_supp_pkgs, $new;
2302     }
2303   } # if !$opt->{'cust_pkg'}
2304     # because if there is one, then supplemental packages would already
2305     # have been created for it.
2306
2307   #Good to go, cancel old package.  Notify 'cancel' of whether to credit
2308   #remaining time.
2309   #Don't allow billing the package (preceding period packages and/or
2310   #outstanding usage) if we are keeping dates (i.e. location changing),
2311   #because the new package will be billed for the same date range.
2312   #Supplemental packages are also canceled here.
2313
2314   # during scheduled changes, avoid canceling the package we just
2315   # changed to (duh)
2316   $self->set('change_to_pkgnum' => '');
2317
2318   $error = $self->cancel(
2319     quiet          => 1,
2320     unused_credit  => $unused_credit,
2321     nobill         => $keep_dates,
2322     change_custnum => ( $self->custnum != $custnum ? $custnum : '' ),
2323     no_delay_cancel => 1,
2324   );
2325   if ($error) {
2326     $dbh->rollback if $oldAutoCommit;
2327     return "canceling old package: $error";
2328   }
2329
2330   if ( $conf->exists('cust_pkg-change_pkgpart-bill_now') ) {
2331     #$self->cust_main
2332     my $error = $cust_pkg->cust_main->bill(
2333       'pkg_list' => [ $cust_pkg, @new_supp_pkgs ]
2334     );
2335     if ( $error ) {
2336       $dbh->rollback if $oldAutoCommit;
2337       return "billing new package: $error";
2338     }
2339   }
2340
2341   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2342
2343   $cust_pkg;
2344
2345 }
2346
2347 =item change_later OPTION => VALUE...
2348
2349 Schedule a package change for a later date.  This actually orders the new
2350 package immediately, but sets its start date for a future date, and sets
2351 the current package to expire on the same date.
2352
2353 If the package is already scheduled for a change, this can be called with
2354 'start_date' to change the scheduled date, or with pkgpart and/or
2355 locationnum to modify the package change.  To cancel the scheduled change
2356 entirely, see C<abort_change>.
2357
2358 Options include:
2359
2360 =over 4
2361
2362 =item start_date
2363
2364 The date for the package change.  Required, and must be in the future.
2365
2366 =item pkgpart
2367
2368 =item locationnum
2369
2370 =item quantity
2371
2372 The pkgpart. locationnum, and quantity of the new package, with the same
2373 meaning as in C<change>.
2374
2375 =back
2376
2377 =cut
2378
2379 sub change_later {
2380   my $self = shift;
2381   my $opt = ref($_[0]) ? shift : { @_ };
2382
2383   my $oldAutoCommit = $FS::UID::AutoCommit;
2384   local $FS::UID::AutoCommit = 0;
2385   my $dbh = dbh;
2386
2387   my $cust_main = $self->cust_main;
2388
2389   my $date = delete $opt->{'start_date'} or return 'start_date required';
2390
2391   if ( $date <= time ) {
2392     $dbh->rollback if $oldAutoCommit;
2393     return "start_date $date is in the past";
2394   }
2395
2396   my $error;
2397
2398   if ( $self->change_to_pkgnum ) {
2399     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
2400     my $new_pkgpart = $opt->{'pkgpart'}
2401         if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $change_to->pkgpart;
2402     my $new_locationnum = $opt->{'locationnum'}
2403         if $opt->{'locationnum'} and $opt->{'locationnum'} != $change_to->locationnum;
2404     my $new_quantity = $opt->{'quantity'}
2405         if $opt->{'quantity'} and $opt->{'quantity'} != $change_to->quantity;
2406     if ( $new_pkgpart or $new_locationnum or $new_quantity ) {
2407       # it hasn't been billed yet, so in principle we could just edit
2408       # it in place (w/o a package change), but that's bad form.
2409       # So change the package according to the new options...
2410       my $err_or_pkg = $change_to->change(%$opt);
2411       if ( ref $err_or_pkg ) {
2412         # Then set that package up for a future start.
2413         $self->set('change_to_pkgnum', $err_or_pkg->pkgnum);
2414         $self->set('expire', $date); # in case it's different
2415         $err_or_pkg->set('start_date', $date);
2416         $err_or_pkg->set('change_date', '');
2417         $err_or_pkg->set('change_pkgnum', '');
2418
2419         $error = $self->replace       ||
2420                  $err_or_pkg->replace ||
2421                  $change_to->cancel('no_delay_cancel' => 1) ||
2422                  $change_to->delete;
2423       } else {
2424         $error = $err_or_pkg;
2425       }
2426     } else { # change the start date only.
2427       $self->set('expire', $date);
2428       $change_to->set('start_date', $date);
2429       $error = $self->replace || $change_to->replace;
2430     }
2431     if ( $error ) {
2432       $dbh->rollback if $oldAutoCommit;
2433       return $error;
2434     } else {
2435       $dbh->commit if $oldAutoCommit;
2436       return '';
2437     }
2438   } # if $self->change_to_pkgnum
2439
2440   my $new_pkgpart = $opt->{'pkgpart'}
2441       if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart;
2442   my $new_locationnum = $opt->{'locationnum'}
2443       if $opt->{'locationnum'} and $opt->{'locationnum'} != $self->locationnum;
2444   my $new_quantity = $opt->{'quantity'}
2445       if $opt->{'quantity'} and $opt->{'quantity'} != $self->quantity;
2446
2447   return '' unless $new_pkgpart or $new_locationnum or $new_quantity; # wouldn't do anything
2448
2449   # allow $opt->{'locationnum'} = '' to specifically set it to null
2450   # (i.e. customer default location)
2451   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2452
2453   my $new = FS::cust_pkg->new( {
2454     custnum     => $self->custnum,
2455     locationnum => $opt->{'locationnum'},
2456     start_date  => $date,
2457     map   {  $_ => ( $opt->{$_} || $self->$_() )  }
2458       qw( pkgpart quantity refnum salesnum )
2459   } );
2460   $error = $new->insert('change' => 1,
2461                         'allow_pkgpart' => ($new_pkgpart ? 0 : 1));
2462   if ( !$error ) {
2463     $self->set('change_to_pkgnum', $new->pkgnum);
2464     $self->set('expire', $date);
2465     $error = $self->replace;
2466   }
2467   if ( $error ) {
2468     $dbh->rollback if $oldAutoCommit;
2469   } else {
2470     $dbh->commit if $oldAutoCommit;
2471   }
2472
2473   $error;
2474 }
2475
2476 =item abort_change
2477
2478 Cancels a future package change scheduled by C<change_later>.
2479
2480 =cut
2481
2482 sub abort_change {
2483   my $self = shift;
2484   my $pkgnum = $self->change_to_pkgnum;
2485   my $change_to = FS::cust_pkg->by_key($pkgnum) if $pkgnum;
2486   my $error;
2487   if ( $change_to ) {
2488     $error = $change_to->cancel || $change_to->delete;
2489     return $error if $error;
2490   }
2491   $self->set('change_to_pkgnum', '');
2492   $self->set('expire', '');
2493   $self->replace;
2494 }
2495
2496 =item set_quantity QUANTITY
2497
2498 Change the package's quantity field.  This is one of the few package properties
2499 that can safely be changed without canceling and reordering the package
2500 (because it doesn't affect tax eligibility).  Returns an error or an
2501 empty string.
2502
2503 =cut
2504
2505 sub set_quantity {
2506   my $self = shift;
2507   $self = $self->replace_old; # just to make sure
2508   $self->quantity(shift);
2509   $self->replace;
2510 }
2511
2512 =item set_salesnum SALESNUM
2513
2514 Change the package's salesnum (sales person) field.  This is one of the few
2515 package properties that can safely be changed without canceling and reordering
2516 the package (because it doesn't affect tax eligibility).  Returns an error or
2517 an empty string.
2518
2519 =cut
2520
2521 sub set_salesnum {
2522   my $self = shift;
2523   $self = $self->replace_old; # just to make sure
2524   $self->salesnum(shift);
2525   $self->replace;
2526   # XXX this should probably reassign any credit that's already been given
2527 }
2528
2529 =item modify_charge OPTIONS
2530
2531 Change the properties of a one-time charge.  The following properties can
2532 be changed this way:
2533 - pkg: the package description
2534 - classnum: the package class
2535 - additional: arrayref of additional invoice details to add to this package
2536
2537 and, I<if the charge has not yet been billed>:
2538 - start_date: the date when it will be billed
2539 - amount: the setup fee to be charged
2540 - quantity: the multiplier for the setup fee
2541 - separate_bill: whether to put the charge on a separate invoice
2542
2543 If you pass 'adjust_commission' => 1, and the classnum changes, and there are
2544 commission credits linked to this charge, they will be recalculated.
2545
2546 =cut
2547
2548 sub modify_charge {
2549   my $self = shift;
2550   my %opt = @_;
2551   my $part_pkg = $self->part_pkg;
2552   my $pkgnum = $self->pkgnum;
2553
2554   my $dbh = dbh;
2555   my $oldAutoCommit = $FS::UID::AutoCommit;
2556   local $FS::UID::AutoCommit = 0;
2557
2558   return "Can't use modify_charge except on one-time charges"
2559     unless $part_pkg->freq eq '0';
2560
2561   if ( length($opt{'pkg'}) and $part_pkg->pkg ne $opt{'pkg'} ) {
2562     $part_pkg->set('pkg', $opt{'pkg'});
2563   }
2564
2565   my %pkg_opt = $part_pkg->options;
2566   my $pkg_opt_modified = 0;
2567
2568   $opt{'additional'} ||= [];
2569   my $i;
2570   my @old_additional;
2571   foreach (grep /^additional/, keys %pkg_opt) {
2572     ($i) = ($_ =~ /^additional_info(\d+)$/);
2573     $old_additional[$i] = $pkg_opt{$_} if $i;
2574     delete $pkg_opt{$_};
2575   }
2576
2577   for ( $i = 0; exists($opt{'additional'}->[$i]); $i++ ) {
2578     $pkg_opt{ "additional_info$i" } = $opt{'additional'}->[$i];
2579     if (!exists($old_additional[$i])
2580         or $old_additional[$i] ne $opt{'additional'}->[$i])
2581     {
2582       $pkg_opt_modified = 1;
2583     }
2584   }
2585   $pkg_opt_modified = 1 if (scalar(@old_additional) - 1) != $i;
2586   $pkg_opt{'additional_count'} = $i if $i > 0;
2587
2588   my $old_classnum;
2589   if ( exists($opt{'classnum'}) and $part_pkg->classnum ne $opt{'classnum'} )
2590   {
2591     # remember it
2592     $old_classnum = $part_pkg->classnum;
2593     $part_pkg->set('classnum', $opt{'classnum'});
2594   }
2595
2596   if ( !$self->get('setup') ) {
2597     # not yet billed, so allow amount, setup_cost, quantity, start_date,
2598     # and separate_bill
2599
2600     if ( exists($opt{'amount'})
2601           and $part_pkg->option('setup_fee') != $opt{'amount'}
2602           and $opt{'amount'} > 0 ) {
2603
2604       $pkg_opt{'setup_fee'} = $opt{'amount'};
2605       $pkg_opt_modified = 1;
2606     }
2607
2608     if ( exists($opt{'setup_cost'})
2609           and $part_pkg->setup_cost != $opt{'setup_cost'}
2610           and $opt{'setup_cost'} > 0 ) {
2611
2612       $part_pkg->set('setup_cost', $opt{'setup_cost'});
2613     }
2614
2615     if ( exists($opt{'quantity'})
2616           and $opt{'quantity'} != $self->quantity
2617           and $opt{'quantity'} > 0 ) {
2618
2619       $self->set('quantity', $opt{'quantity'});
2620     }
2621
2622     if ( exists($opt{'start_date'})
2623           and $opt{'start_date'} != $self->start_date ) {
2624
2625       $self->set('start_date', $opt{'start_date'});
2626     }
2627
2628     if ( exists($opt{'separate_bill'})
2629           and $opt{'separate_bill'} ne $self->separate_bill ) {
2630
2631       $self->set('separate_bill', $opt{'separate_bill'});
2632     }
2633
2634
2635   } # else simply ignore them; the UI shouldn't allow editing the fields
2636
2637   if ( exists($opt{'taxclass'})
2638           and $part_pkg->taxclass ne $opt{'taxclass'}) {
2639
2640       $part_pkg->set('taxclass', $opt{'taxclass'});
2641   }
2642
2643   my $error;
2644   if ( $part_pkg->modified or $pkg_opt_modified ) {
2645     # can we safely modify the package def?
2646     # Yes, if it's not available for purchase, and this is the only instance
2647     # of it.
2648     if ( $part_pkg->disabled
2649          and FS::cust_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 1
2650          and FS::quotation_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 0
2651        ) {
2652       $error = $part_pkg->replace( options => \%pkg_opt );
2653     } else {
2654       # clone it
2655       $part_pkg = $part_pkg->clone;
2656       $part_pkg->set('disabled' => 'Y');
2657       $error = $part_pkg->insert( options => \%pkg_opt );
2658       # and associate this as yet-unbilled package to the new package def
2659       $self->set('pkgpart' => $part_pkg->pkgpart);
2660     }
2661     if ( $error ) {
2662       $dbh->rollback if $oldAutoCommit;
2663       return $error;
2664     }
2665   }
2666
2667   if ($self->modified) { # for quantity or start_date change, or if we had
2668                          # to clone the existing package def
2669     my $error = $self->replace;
2670     return $error if $error;
2671   }
2672   if (defined $old_classnum) {
2673     # fix invoice grouping records
2674     my $old_catname = $old_classnum
2675                       ? FS::pkg_class->by_key($old_classnum)->categoryname
2676                       : '';
2677     my $new_catname = $opt{'classnum'}
2678                       ? $part_pkg->pkg_class->categoryname
2679                       : '';
2680     if ( $old_catname ne $new_catname ) {
2681       foreach my $cust_bill_pkg ($self->cust_bill_pkg) {
2682         # (there should only be one...)
2683         my @display = qsearch( 'cust_bill_pkg_display', {
2684             'billpkgnum'  => $cust_bill_pkg->billpkgnum,
2685             'section'     => $old_catname,
2686         });
2687         foreach (@display) {
2688           $_->set('section', $new_catname);
2689           $error = $_->replace;
2690           if ( $error ) {
2691             $dbh->rollback if $oldAutoCommit;
2692             return $error;
2693           }
2694         }
2695       } # foreach $cust_bill_pkg
2696     }
2697
2698     if ( $opt{'adjust_commission'} ) {
2699       # fix commission credits...tricky.
2700       foreach my $cust_event ($self->cust_event) {
2701         my $part_event = $cust_event->part_event;
2702         foreach my $table (qw(sales agent)) {
2703           my $class =
2704             "FS::part_event::Action::Mixin::credit_${table}_pkg_class";
2705           my $credit = qsearchs('cust_credit', {
2706               'eventnum' => $cust_event->eventnum,
2707           });
2708           if ( $part_event->isa($class) ) {
2709             # Yes, this results in current commission rates being applied
2710             # retroactively to a one-time charge.  For accounting purposes
2711             # there ought to be some kind of time limit on doing this.
2712             my $amount = $part_event->_calc_credit($self);
2713             if ( $credit and $credit->amount ne $amount ) {
2714               # Void the old credit.
2715               $error = $credit->void('Package class changed');
2716               if ( $error ) {
2717                 $dbh->rollback if $oldAutoCommit;
2718                 return "$error (adjusting commission credit)";
2719               }
2720             }
2721             # redo the event action to recreate the credit.
2722             local $@ = '';
2723             eval { $part_event->do_action( $self, $cust_event ) };
2724             if ( $@ ) {
2725               $dbh->rollback if $oldAutoCommit;
2726               return $@;
2727             }
2728           } # if $part_event->isa($class)
2729         } # foreach $table
2730       } # foreach $cust_event
2731     } # if $opt{'adjust_commission'}
2732   } # if defined $old_classnum
2733
2734   $dbh->commit if $oldAutoCommit;
2735   '';
2736 }
2737
2738
2739
2740 use Storable 'thaw';
2741 use MIME::Base64;
2742 use Data::Dumper;
2743 sub process_bulk_cust_pkg {
2744   my $job = shift;
2745   my $param = thaw(decode_base64(shift));
2746   warn Dumper($param) if $DEBUG;
2747
2748   my $old_part_pkg = qsearchs('part_pkg',
2749                               { pkgpart => $param->{'old_pkgpart'} });
2750   my $new_part_pkg = qsearchs('part_pkg',
2751                               { pkgpart => $param->{'new_pkgpart'} });
2752   die "Must select a new package type\n" unless $new_part_pkg;
2753   #my $keep_dates = $param->{'keep_dates'} || 0;
2754   my $keep_dates = 1; # there is no good reason to turn this off
2755
2756   local $SIG{HUP} = 'IGNORE';
2757   local $SIG{INT} = 'IGNORE';
2758   local $SIG{QUIT} = 'IGNORE';
2759   local $SIG{TERM} = 'IGNORE';
2760   local $SIG{TSTP} = 'IGNORE';
2761   local $SIG{PIPE} = 'IGNORE';
2762
2763   my $oldAutoCommit = $FS::UID::AutoCommit;
2764   local $FS::UID::AutoCommit = 0;
2765   my $dbh = dbh;
2766
2767   my @cust_pkgs = qsearch('cust_pkg', { 'pkgpart' => $param->{'old_pkgpart'} } );
2768
2769   my $i = 0;
2770   foreach my $old_cust_pkg ( @cust_pkgs ) {
2771     $i++;
2772     $job->update_statustext(int(100*$i/(scalar @cust_pkgs)));
2773     if ( $old_cust_pkg->getfield('cancel') ) {
2774       warn '[process_bulk_cust_pkg ] skipping canceled pkgnum '.
2775         $old_cust_pkg->pkgnum."\n"
2776         if $DEBUG;
2777       next;
2778     }
2779     warn '[process_bulk_cust_pkg] changing pkgnum '.$old_cust_pkg->pkgnum."\n"
2780       if $DEBUG;
2781     my $error = $old_cust_pkg->change(
2782       'pkgpart'     => $param->{'new_pkgpart'},
2783       'keep_dates'  => $keep_dates
2784     );
2785     if ( !ref($error) ) { # change returns the cust_pkg on success
2786       $dbh->rollback;
2787       die "Error changing pkgnum ".$old_cust_pkg->pkgnum.": '$error'\n";
2788     }
2789   }
2790   $dbh->commit if $oldAutoCommit;
2791   return;
2792 }
2793
2794 =item last_bill
2795
2796 Returns the last bill date, or if there is no last bill date, the setup date.
2797 Useful for billing metered services.
2798
2799 =cut
2800
2801 sub last_bill {
2802   my $self = shift;
2803   return $self->setfield('last_bill', $_[0]) if @_;
2804   return $self->getfield('last_bill') if $self->getfield('last_bill');
2805   my $cust_bill_pkg = qsearchs('cust_bill_pkg', { 'pkgnum' => $self->pkgnum,
2806                                                   'edate'  => $self->bill,  } );
2807   $cust_bill_pkg ? $cust_bill_pkg->sdate : $self->setup || 0;
2808 }
2809
2810 =item last_cust_pkg_reason ACTION
2811
2812 Returns the most recent ACTION FS::cust_pkg_reason associated with the package.
2813 Returns false if there is no reason or the package is not currenly ACTION'd
2814 ACTION is one of adjourn, susp, cancel, or expire.
2815
2816 =cut
2817
2818 sub last_cust_pkg_reason {
2819   my ( $self, $action ) = ( shift, shift );
2820   my $date = $self->get($action);
2821   qsearchs( {
2822               'table' => 'cust_pkg_reason',
2823               'hashref' => { 'pkgnum' => $self->pkgnum,
2824                              'action' => substr(uc($action), 0, 1),
2825                              'date'   => $date,
2826                            },
2827               'order_by' => 'ORDER BY num DESC LIMIT 1',
2828            } );
2829 }
2830
2831 =item last_reason ACTION
2832
2833 Returns the most recent ACTION FS::reason associated with the package.
2834 Returns false if there is no reason or the package is not currenly ACTION'd
2835 ACTION is one of adjourn, susp, cancel, or expire.
2836
2837 =cut
2838
2839 sub last_reason {
2840   my $cust_pkg_reason = shift->last_cust_pkg_reason(@_);
2841   $cust_pkg_reason->reason
2842     if $cust_pkg_reason;
2843 }
2844
2845 =item part_pkg
2846
2847 Returns the definition for this billing item, as an FS::part_pkg object (see
2848 L<FS::part_pkg>).
2849
2850 =cut
2851
2852 sub part_pkg {
2853   my $self = shift;
2854   return $self->{'_pkgpart'} if $self->{'_pkgpart'};
2855   cluck "cust_pkg->part_pkg called" if $DEBUG > 1;
2856   qsearchs( 'part_pkg', { 'pkgpart' => $self->pkgpart } );
2857 }
2858
2859 =item old_cust_pkg
2860
2861 Returns the cancelled package this package was changed from, if any.
2862
2863 =cut
2864
2865 sub old_cust_pkg {
2866   my $self = shift;
2867   return '' unless $self->change_pkgnum;
2868   qsearchs('cust_pkg', { 'pkgnum' => $self->change_pkgnum } );
2869 }
2870
2871 =item change_cust_main
2872
2873 Returns the customter this package was detached to, if any.
2874
2875 =cut
2876
2877 sub change_cust_main {
2878   my $self = shift;
2879   return '' unless $self->change_custnum;
2880   qsearchs('cust_main', { 'custnum' => $self->change_custnum } );
2881 }
2882
2883 =item calc_setup
2884
2885 Calls the I<calc_setup> of the FS::part_pkg object associated with this billing
2886 item.
2887
2888 =cut
2889
2890 sub calc_setup {
2891   my $self = shift;
2892   $self->part_pkg->calc_setup($self, @_);
2893 }
2894
2895 =item calc_recur
2896
2897 Calls the I<calc_recur> of the FS::part_pkg object associated with this billing
2898 item.
2899
2900 =cut
2901
2902 sub calc_recur {
2903   my $self = shift;
2904   $self->part_pkg->calc_recur($self, @_);
2905 }
2906
2907 =item base_recur
2908
2909 Calls the I<base_recur> of the FS::part_pkg object associated with this billing
2910 item.
2911
2912 =cut
2913
2914 sub base_recur {
2915   my $self = shift;
2916   $self->part_pkg->base_recur($self, @_);
2917 }
2918
2919 =item calc_remain
2920
2921 Calls the I<calc_remain> of the FS::part_pkg object associated with this
2922 billing item.
2923
2924 =cut
2925
2926 sub calc_remain {
2927   my $self = shift;
2928   $self->part_pkg->calc_remain($self, @_);
2929 }
2930
2931 =item calc_cancel
2932
2933 Calls the I<calc_cancel> of the FS::part_pkg object associated with this
2934 billing item.
2935
2936 =cut
2937
2938 sub calc_cancel {
2939   my $self = shift;
2940   $self->part_pkg->calc_cancel($self, @_);
2941 }
2942
2943 =item cust_bill_pkg
2944
2945 Returns any invoice line items for this package (see L<FS::cust_bill_pkg>).
2946
2947 =cut
2948
2949 sub cust_bill_pkg {
2950   my $self = shift;
2951   qsearch( 'cust_bill_pkg', { 'pkgnum' => $self->pkgnum } );
2952 }
2953
2954 =item cust_pkg_detail [ DETAILTYPE ]
2955
2956 Returns any customer package details for this package (see
2957 L<FS::cust_pkg_detail>).
2958
2959 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2960
2961 =cut
2962
2963 sub cust_pkg_detail {
2964   my $self = shift;
2965   my %hash = ( 'pkgnum' => $self->pkgnum );
2966   $hash{detailtype} = shift if @_;
2967   qsearch({
2968     'table'    => 'cust_pkg_detail',
2969     'hashref'  => \%hash,
2970     'order_by' => 'ORDER BY weight, pkgdetailnum',
2971   });
2972 }
2973
2974 =item set_cust_pkg_detail DETAILTYPE [ DETAIL, DETAIL, ... ]
2975
2976 Sets customer package details for this package (see L<FS::cust_pkg_detail>).
2977
2978 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
2979
2980 If there is an error, returns the error, otherwise returns false.
2981
2982 =cut
2983
2984 sub set_cust_pkg_detail {
2985   my( $self, $detailtype, @details ) = @_;
2986
2987   local $SIG{HUP} = 'IGNORE';
2988   local $SIG{INT} = 'IGNORE';
2989   local $SIG{QUIT} = 'IGNORE';
2990   local $SIG{TERM} = 'IGNORE';
2991   local $SIG{TSTP} = 'IGNORE';
2992   local $SIG{PIPE} = 'IGNORE';
2993
2994   my $oldAutoCommit = $FS::UID::AutoCommit;
2995   local $FS::UID::AutoCommit = 0;
2996   my $dbh = dbh;
2997
2998   foreach my $current ( $self->cust_pkg_detail($detailtype) ) {
2999     my $error = $current->delete;
3000     if ( $error ) {
3001       $dbh->rollback if $oldAutoCommit;
3002       return "error removing old detail: $error";
3003     }
3004   }
3005
3006   foreach my $detail ( @details ) {
3007     my $cust_pkg_detail = new FS::cust_pkg_detail {
3008       'pkgnum'     => $self->pkgnum,
3009       'detailtype' => $detailtype,
3010       'detail'     => $detail,
3011     };
3012     my $error = $cust_pkg_detail->insert;
3013     if ( $error ) {
3014       $dbh->rollback if $oldAutoCommit;
3015       return "error adding new detail: $error";
3016     }
3017
3018   }
3019
3020   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3021   '';
3022
3023 }
3024
3025 =item cust_event
3026
3027 Returns the customer billing events (see L<FS::cust_event>) for this invoice.
3028
3029 =cut
3030
3031 #false laziness w/cust_bill.pm
3032 sub cust_event {
3033   my $self = shift;
3034   qsearch({
3035     'table'     => 'cust_event',
3036     'addl_from' => 'JOIN part_event USING ( eventpart )',
3037     'hashref'   => { 'tablenum' => $self->pkgnum },
3038     'extra_sql' => " AND eventtable = 'cust_pkg' ",
3039   });
3040 }
3041
3042 =item num_cust_event
3043
3044 Returns the number of customer billing events (see L<FS::cust_event>) for this package.
3045
3046 =cut
3047
3048 #false laziness w/cust_bill.pm
3049 sub num_cust_event {
3050   my $self = shift;
3051   my $sql = "SELECT COUNT(*) ". $self->_from_cust_event_where;
3052   $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref->[0];
3053 }
3054
3055 =item exists_cust_event
3056
3057 Returns true if there are customer billing events (see L<FS::cust_event>) for this package.  More efficient than using num_cust_event.
3058
3059 =cut
3060
3061 sub exists_cust_event {
3062   my $self = shift;
3063   my $sql = "SELECT 1 ". $self->_from_cust_event_where. " LIMIT 1";
3064   my $row = $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref;
3065   $row ? $row->[0] : '';
3066 }
3067
3068 sub _from_cust_event_where {
3069   #my $self = shift;
3070   " FROM cust_event JOIN part_event USING ( eventpart ) ".
3071   "  WHERE tablenum = ? AND eventtable = 'cust_pkg' ";
3072 }
3073
3074 sub _prep_ex {
3075   my( $self, $sql, @args ) = @_;
3076   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
3077   $sth->execute(@args)         or die $sth->errstr. " executing $sql";
3078   $sth;
3079 }
3080
3081 =item cust_svc [ SVCPART ] (old, deprecated usage)
3082
3083 =item cust_svc [ OPTION => VALUE ... ] (current usage)
3084
3085 =item cust_svc_unsorted [ OPTION => VALUE ... ]
3086
3087 Returns the services for this package, as FS::cust_svc objects (see
3088 L<FS::cust_svc>).  Available options are svcpart and svcdb.  If either is
3089 spcififed, returns only the matching services.
3090
3091 As an optimization, use the cust_svc_unsorted version if you are not displaying
3092 the results.
3093
3094 =cut
3095
3096 sub cust_svc {
3097   my $self = shift;
3098   cluck "cust_pkg->cust_svc called" if $DEBUG > 2;
3099   $self->_sort_cust_svc( $self->cust_svc_unsorted_arrayref(@_) );
3100 }
3101
3102 sub cust_svc_unsorted {
3103   my $self = shift;
3104   @{ $self->cust_svc_unsorted_arrayref(@_) };
3105 }
3106
3107 sub cust_svc_unsorted_arrayref {
3108   my $self = shift;
3109
3110   return [] unless $self->num_cust_svc(@_);
3111
3112   my %opt = ();
3113   if ( @_ && $_[0] =~ /^\d+/ ) {
3114     $opt{svcpart} = shift;
3115   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3116     %opt = %{ $_[0] };
3117   } elsif ( @_ ) {
3118     %opt = @_;
3119   }
3120
3121   my %search = (
3122     'table'   => 'cust_svc',
3123     'hashref' => { 'pkgnum' => $self->pkgnum },
3124   );
3125   if ( $opt{svcpart} ) {
3126     $search{hashref}->{svcpart} = $opt{'svcpart'};
3127   }
3128   if ( $opt{'svcdb'} ) {
3129     $search{addl_from} = ' LEFT JOIN part_svc USING ( svcpart ) ';
3130     $search{extra_sql} = ' AND svcdb = '. dbh->quote( $opt{'svcdb'} );
3131   }
3132
3133   [ qsearch(\%search) ];
3134
3135 }
3136
3137 =item overlimit [ SVCPART ]
3138
3139 Returns the services for this package which have exceeded their
3140 usage limit as FS::cust_svc objects (see L<FS::cust_svc>).  If a svcpart
3141 is specified, return only the matching services.
3142
3143 =cut
3144
3145 sub overlimit {
3146   my $self = shift;
3147   return () unless $self->num_cust_svc(@_);
3148   grep { $_->overlimit } $self->cust_svc(@_);
3149 }
3150
3151 =item h_cust_svc END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3152
3153 Returns historical services for this package created before END TIMESTAMP and
3154 (optionally) not cancelled before START_TIMESTAMP, as FS::h_cust_svc objects
3155 (see L<FS::h_cust_svc>).  If MODE is 'I' (for 'invoice'), services with the
3156 I<pkg_svc.hidden> flag will be omitted.
3157
3158 =cut
3159
3160 sub h_cust_svc {
3161   my $self = shift;
3162   warn "$me _h_cust_svc called on $self\n"
3163     if $DEBUG;
3164
3165   my ($end, $start, $mode) = @_;
3166   my @cust_svc = $self->_sort_cust_svc(
3167     [ qsearch( 'h_cust_svc',
3168       { 'pkgnum' => $self->pkgnum, },
3169       FS::h_cust_svc->sql_h_search(@_),
3170     ) ]
3171   );
3172   if ( defined($mode) && $mode eq 'I' ) {
3173     my %hidden_svcpart = map { $_->svcpart => $_->hidden } $self->part_svc;
3174     return grep { !$hidden_svcpart{$_->svcpart} } @cust_svc;
3175   } else {
3176     return @cust_svc;
3177   }
3178 }
3179
3180 sub _sort_cust_svc {
3181   my( $self, $arrayref ) = @_;
3182
3183   my $sort =
3184     sub ($$) { my ($a, $b) = @_; $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] };
3185
3186   my %pkg_svc = map { $_->svcpart => $_ }
3187                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
3188
3189   map  { $_->[0] }
3190   sort $sort
3191   map {
3192         my $pkg_svc = $pkg_svc{ $_->svcpart } || '';
3193         [ $_,
3194           $pkg_svc ? $pkg_svc->primary_svc : '',
3195           $pkg_svc ? $pkg_svc->quantity : 0,
3196         ];
3197       }
3198   @$arrayref;
3199
3200 }
3201
3202 =item num_cust_svc [ SVCPART ] (old, deprecated usage)
3203
3204 =item num_cust_svc [ OPTION => VALUE ... ] (current usage)
3205
3206 Returns the number of services for this package.  Available options are svcpart
3207 and svcdb.  If either is spcififed, returns only the matching services.
3208
3209 =cut
3210
3211 sub num_cust_svc {
3212   my $self = shift;
3213
3214   return $self->{'_num_cust_svc'}
3215     if !scalar(@_)
3216        && exists($self->{'_num_cust_svc'})
3217        && $self->{'_num_cust_svc'} =~ /\d/;
3218
3219   cluck "cust_pkg->num_cust_svc called, _num_cust_svc:".$self->{'_num_cust_svc'}
3220     if $DEBUG > 2;
3221
3222   my %opt = ();
3223   if ( @_ && $_[0] =~ /^\d+/ ) {
3224     $opt{svcpart} = shift;
3225   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3226     %opt = %{ $_[0] };
3227   } elsif ( @_ ) {
3228     %opt = @_;
3229   }
3230
3231   my $select = 'SELECT COUNT(*) FROM cust_svc ';
3232   my $where = ' WHERE pkgnum = ? ';
3233   my @param = ($self->pkgnum);
3234
3235   if ( $opt{'svcpart'} ) {
3236     $where .= ' AND svcpart = ? ';
3237     push @param, $opt{'svcpart'};
3238   }
3239   if ( $opt{'svcdb'} ) {
3240     $select .= ' LEFT JOIN part_svc USING ( svcpart ) ';
3241     $where .= ' AND svcdb = ? ';
3242     push @param, $opt{'svcdb'};
3243   }
3244
3245   my $sth = dbh->prepare("$select $where") or die  dbh->errstr;
3246   $sth->execute(@param) or die $sth->errstr;
3247   $sth->fetchrow_arrayref->[0];
3248 }
3249
3250 =item available_part_svc
3251
3252 Returns a list of FS::part_svc objects representing services included in this
3253 package but not yet provisioned.  Each FS::part_svc object also has an extra
3254 field, I<num_avail>, which specifies the number of available services.
3255
3256 =cut
3257
3258 sub available_part_svc {
3259   my $self = shift;
3260
3261   my $pkg_quantity = $self->quantity || 1;
3262
3263   grep { $_->num_avail > 0 }
3264     map {
3265           my $part_svc = $_->part_svc;
3266           $part_svc->{'Hash'}{'num_avail'} = #evil encapsulation-breaking
3267             $pkg_quantity * $_->quantity - $self->num_cust_svc($_->svcpart);
3268
3269           # more evil encapsulation breakage
3270           if($part_svc->{'Hash'}{'num_avail'} > 0) {
3271             my @exports = $part_svc->part_export_did;
3272             $part_svc->{'Hash'}{'can_get_dids'} = scalar(@exports);
3273           }
3274
3275           $part_svc;
3276         }
3277       $self->part_pkg->pkg_svc;
3278 }
3279
3280 =item part_svc [ OPTION => VALUE ... ]
3281
3282 Returns a list of FS::part_svc objects representing provisioned and available
3283 services included in this package.  Each FS::part_svc object also has the
3284 following extra fields:
3285
3286 =over 4
3287
3288 =item num_cust_svc
3289
3290 (count)
3291
3292 =item num_avail
3293
3294 (quantity - count)
3295
3296 =item cust_pkg_svc
3297
3298 (services) - array reference containing the provisioned services, as cust_svc objects
3299
3300 =back
3301
3302 Accepts two options:
3303
3304 =over 4
3305
3306 =item summarize_size
3307
3308 If true, will omit the extra cust_pkg_svc option for objects where num_cust_svc
3309 is this size or greater.
3310
3311 =item hide_discontinued
3312
3313 If true, will omit looking for services that are no longer avaialble in the
3314 package definition.
3315
3316 =back
3317
3318 =cut
3319
3320 #svcnum
3321 #label -> ($cust_svc->label)[1]
3322
3323 sub part_svc {
3324   my $self = shift;
3325   my %opt = @_;
3326
3327   my $pkg_quantity = $self->quantity || 1;
3328
3329   #XXX some sort of sort order besides numeric by svcpart...
3330   my @part_svc = sort { $a->svcpart <=> $b->svcpart } map {
3331     my $pkg_svc = $_;
3332     my $part_svc = $pkg_svc->part_svc;
3333     my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3334     $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #more evil
3335     $part_svc->{'Hash'}{'num_avail'}    =
3336       max( 0, $pkg_quantity * $pkg_svc->quantity - $num_cust_svc );
3337     $part_svc->{'Hash'}{'cust_pkg_svc'} =
3338         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : []
3339       unless exists($opt{summarize_size}) && $opt{summarize_size} > 0
3340           && $num_cust_svc >= $opt{summarize_size};
3341     $part_svc->{'Hash'}{'hidden'} = $pkg_svc->hidden;
3342     $part_svc;
3343   } $self->part_pkg->pkg_svc;
3344
3345   unless ( $opt{hide_discontinued} ) {
3346     #extras
3347     push @part_svc, map {
3348       my $part_svc = $_;
3349       my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3350       $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #speak no evail
3351       $part_svc->{'Hash'}{'num_avail'}    = 0; #0-$num_cust_svc ?
3352       $part_svc->{'Hash'}{'cust_pkg_svc'} =
3353         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : [];
3354       $part_svc;
3355     } $self->extra_part_svc;
3356   }
3357
3358   @part_svc;
3359
3360 }
3361
3362 =item extra_part_svc
3363
3364 Returns a list of FS::part_svc objects corresponding to services in this
3365 package which are still provisioned but not (any longer) available in the
3366 package definition.
3367
3368 =cut
3369
3370 sub extra_part_svc {
3371   my $self = shift;
3372
3373   my $pkgnum  = $self->pkgnum;
3374   #my $pkgpart = $self->pkgpart;
3375
3376 #  qsearch( {
3377 #    'table'     => 'part_svc',
3378 #    'hashref'   => {},
3379 #    'extra_sql' =>
3380 #      "WHERE 0 = ( SELECT COUNT(*) FROM pkg_svc
3381 #                     WHERE pkg_svc.svcpart = part_svc.svcpart
3382 #                       AND pkg_svc.pkgpart = ?
3383 #                       AND quantity > 0
3384 #                 )
3385 #        AND 0 < ( SELECT COUNT(*) FROM cust_svc
3386 #                       LEFT JOIN cust_pkg USING ( pkgnum )
3387 #                     WHERE cust_svc.svcpart = part_svc.svcpart
3388 #                       AND pkgnum = ?
3389 #                 )",
3390 #    'extra_param' => [ [$self->pkgpart=>'int'], [$self->pkgnum=>'int'] ],
3391 #  } );
3392
3393 #seems to benchmark slightly faster... (or did?)
3394
3395   my @pkgparts = map $_->pkgpart, $self->part_pkg->self_and_svc_linked;
3396   my $pkgparts = join(',', @pkgparts);
3397
3398   qsearch( {
3399     #'select'      => 'DISTINCT ON (svcpart) part_svc.*',
3400     #MySQL doesn't grok DISINCT ON
3401     'select'      => 'DISTINCT part_svc.*',
3402     'table'       => 'part_svc',
3403     'addl_from'   =>
3404       "LEFT JOIN pkg_svc  ON (     pkg_svc.svcpart   = part_svc.svcpart
3405                                AND pkg_svc.pkgpart IN ($pkgparts)
3406                                AND quantity > 0
3407                              )
3408        LEFT JOIN cust_svc ON (     cust_svc.svcpart = part_svc.svcpart )
3409        LEFT JOIN cust_pkg USING ( pkgnum )
3410       ",
3411     'hashref'     => {},
3412     'extra_sql'   => "WHERE pkgsvcnum IS NULL AND cust_pkg.pkgnum = ? ",
3413     'extra_param' => [ [$self->pkgnum=>'int'] ],
3414   } );
3415 }
3416
3417 =item status
3418
3419 Returns a short status string for this package, currently:
3420
3421 =over 4
3422
3423 =item on hold
3424
3425 =item not yet billed
3426
3427 =item one-time charge
3428
3429 =item active
3430
3431 =item suspended
3432
3433 =item cancelled
3434
3435 =back
3436
3437 =cut
3438
3439 sub status {
3440   my $self = shift;
3441
3442   my $freq = length($self->freq) ? $self->freq : $self->part_pkg->freq;
3443
3444   return 'cancelled' if $self->get('cancel');
3445   return 'on hold' if $self->susp && ! $self->setup;
3446   return 'suspended' if $self->susp;
3447   return 'not yet billed' unless $self->setup;
3448   return 'one-time charge' if $freq =~ /^(0|$)/;
3449   return 'active';
3450 }
3451
3452 =item ucfirst_status
3453
3454 Returns the status with the first character capitalized.
3455
3456 =cut
3457
3458 sub ucfirst_status {
3459   ucfirst(shift->status);
3460 }
3461
3462 =item statuses
3463
3464 Class method that returns the list of possible status strings for packages
3465 (see L<the status method|/status>).  For example:
3466
3467   @statuses = FS::cust_pkg->statuses();
3468
3469 =cut
3470
3471 tie my %statuscolor, 'Tie::IxHash',
3472   'on hold'         => 'FF00F5', #brighter purple!
3473   'not yet billed'  => '009999', #teal? cyan?
3474   'one-time charge' => '0000CC', #blue  #'000000',
3475   'active'          => '00CC00',
3476   'suspended'       => 'FF9900',
3477   'cancelled'       => 'FF0000',
3478 ;
3479
3480 sub statuses {
3481   my $self = shift; #could be class...
3482   #grep { $_ !~ /^(not yet billed)$/ } #this is a dumb status anyway
3483   #                                    # mayble split btw one-time vs. recur
3484     keys %statuscolor;
3485 }
3486
3487 sub statuscolors {
3488   #my $self = shift;
3489   \%statuscolor;
3490 }
3491
3492 =item statuscolor
3493
3494 Returns a hex triplet color string for this package's status.
3495
3496 =cut
3497
3498 sub statuscolor {
3499   my $self = shift;
3500   $statuscolor{$self->status};
3501 }
3502
3503 =item is_status_delay_cancel
3504
3505 Returns true if part_pkg has option delay_cancel,
3506 cust_pkg status is 'suspended' and expire is set
3507 to cancel package within the next day (or however
3508 many days are set in global config part_pkg-delay_cancel-days.
3509
3510 This is not a real status, this only meant for hacking display
3511 values, because otherwise treating the package as suspended is
3512 really the whole point of the delay_cancel option.
3513
3514 =cut
3515
3516 sub is_status_delay_cancel {
3517   my ($self) = @_;
3518   if ( $self->main_pkgnum and $self->pkglinknum ) {
3519     return $self->main_pkg->is_status_delay_cancel;
3520   }
3521   return 0 unless $self->part_pkg->option('delay_cancel',1);
3522   return 0 unless $self->status eq 'suspended';
3523   return 0 unless $self->expire;
3524   my $conf = new FS::Conf;
3525   my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
3526   my $expsecs = 60*60*24*$expdays;
3527   return 0 unless $self->expire < time + $expsecs;
3528   return 1;
3529 }
3530
3531 =item pkg_label
3532
3533 Returns a label for this package.  (Currently "pkgnum: pkg - comment" or
3534 "pkg - comment" depending on user preference).
3535
3536 =cut
3537
3538 sub pkg_label {
3539   my $self = shift;
3540   my $label = $self->part_pkg->pkg_comment( 'nopkgpart' => 1 );
3541   $label = $self->pkgnum. ": $label"
3542     if $FS::CurrentUser::CurrentUser->option('show_pkgnum');
3543   $label;
3544 }
3545
3546 =item pkg_label_long
3547
3548 Returns a long label for this package, adding the primary service's label to
3549 pkg_label.
3550
3551 =cut
3552
3553 sub pkg_label_long {
3554   my $self = shift;
3555   my $label = $self->pkg_label;
3556   my $cust_svc = $self->primary_cust_svc;
3557   $label .= ' ('. ($cust_svc->label)[1]. ')' if $cust_svc;
3558   $label;
3559 }
3560
3561 =item pkg_locale
3562
3563 Returns a customer-localized label for this package.
3564
3565 =cut
3566
3567 sub pkg_locale {
3568   my $self = shift;
3569   $self->part_pkg->pkg_locale( $self->cust_main->locale );
3570 }
3571
3572 =item primary_cust_svc
3573
3574 Returns a primary service (as FS::cust_svc object) if one can be identified.
3575
3576 =cut
3577
3578 #for labeling purposes - might not 100% match up with part_pkg->svcpart's idea
3579
3580 sub primary_cust_svc {
3581   my $self = shift;
3582
3583   my @cust_svc = $self->cust_svc;
3584
3585   return '' unless @cust_svc; #no serivces - irrelevant then
3586
3587   return $cust_svc[0] if scalar(@cust_svc) == 1; #always return a single service
3588
3589   # primary service as specified in the package definition
3590   # or exactly one service definition with quantity one
3591   my $svcpart = $self->part_pkg->svcpart;
3592   @cust_svc = grep { $_->svcpart == $svcpart } @cust_svc;
3593   return $cust_svc[0] if scalar(@cust_svc) == 1;
3594
3595   #couldn't identify one thing..
3596   return '';
3597 }
3598
3599 =item labels
3600
3601 Returns a list of lists, calling the label method for all services
3602 (see L<FS::cust_svc>) of this billing item.
3603
3604 =cut
3605
3606 sub labels {
3607   my $self = shift;
3608   map { [ $_->label ] } $self->cust_svc;
3609 }
3610
3611 =item h_labels END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3612
3613 Like the labels method, but returns historical information on services that
3614 were active as of END_TIMESTAMP and (optionally) not cancelled before
3615 START_TIMESTAMP.  If MODE is 'I' (for 'invoice'), services with the
3616 I<pkg_svc.hidden> flag will be omitted.
3617
3618 Returns a list of lists, calling the label method for all (historical) services
3619 (see L<FS::h_cust_svc>) of this billing item.
3620
3621 =cut
3622
3623 sub h_labels {
3624   my $self = shift;
3625   warn "$me _h_labels called on $self\n"
3626     if $DEBUG;
3627   map { [ $_->label(@_) ] } $self->h_cust_svc(@_);
3628 }
3629
3630 =item labels_short
3631
3632 Like labels, except returns a simple flat list, and shortens long
3633 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3634 identical services to one line that lists the service label and the number of
3635 individual services rather than individual items.
3636
3637 =cut
3638
3639 sub labels_short {
3640   shift->_labels_short( 'labels', @_ );
3641 }
3642
3643 =item h_labels_short END_TIMESTAMP [ START_TIMESTAMP ]
3644
3645 Like h_labels, except returns a simple flat list, and shortens long
3646 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3647 identical services to one line that lists the service label and the number of
3648 individual services rather than individual items.
3649
3650 =cut
3651
3652 sub h_labels_short {
3653   shift->_labels_short( 'h_labels', @_ );
3654 }
3655
3656 sub _labels_short {
3657   my( $self, $method ) = ( shift, shift );
3658
3659   warn "$me _labels_short called on $self with $method method\n"
3660     if $DEBUG;
3661
3662   my $conf = new FS::Conf;
3663   my $max_same_services = $conf->config('cust_bill-max_same_services') || 5;
3664
3665   warn "$me _labels_short populating \%labels\n"
3666     if $DEBUG;
3667
3668   my %labels;
3669   #tie %labels, 'Tie::IxHash';
3670   push @{ $labels{$_->[0]} }, $_->[1]
3671     foreach $self->$method(@_);
3672
3673   warn "$me _labels_short populating \@labels\n"
3674     if $DEBUG;
3675
3676   my @labels;
3677   foreach my $label ( keys %labels ) {
3678     my %seen = ();
3679     my @values = grep { ! $seen{$_}++ } @{ $labels{$label} };
3680     my $num = scalar(@values);
3681     warn "$me _labels_short $num items for $label\n"
3682       if $DEBUG;
3683
3684     if ( $num > $max_same_services ) {
3685       warn "$me _labels_short   more than $max_same_services, so summarizing\n"
3686         if $DEBUG;
3687       push @labels, "$label ($num)";
3688     } else {
3689       if ( $conf->exists('cust_bill-consolidate_services') ) {
3690         warn "$me _labels_short   consolidating services\n"
3691           if $DEBUG;
3692         # push @labels, "$label: ". join(', ', @values);
3693         while ( @values ) {
3694           my $detail = "$label: ";
3695           $detail .= shift(@values). ', '
3696             while @values
3697                && ( length($detail.$values[0]) < 78 || $detail eq "$label: " );
3698           $detail =~ s/, $//;
3699           push @labels, $detail;
3700         }
3701         warn "$me _labels_short   done consolidating services\n"
3702           if $DEBUG;
3703       } else {
3704         warn "$me _labels_short   adding service data\n"
3705           if $DEBUG;
3706         push @labels, map { "$label: $_" } @values;
3707       }
3708     }
3709   }
3710
3711  @labels;
3712
3713 }
3714
3715 =item cust_main
3716
3717 Returns the parent customer object (see L<FS::cust_main>).
3718
3719 =cut
3720
3721 sub cust_main {
3722   my $self = shift;
3723   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
3724 }
3725
3726 =item balance
3727
3728 Returns the balance for this specific package, when using
3729 experimental package balance.
3730
3731 =cut
3732
3733 sub balance {
3734   my $self = shift;
3735   $self->cust_main->balance_pkgnum( $self->pkgnum );
3736 }
3737
3738 #these subs are in location_Mixin.pm now... unfortunately the POD doesn't mixin
3739
3740 =item cust_location
3741
3742 Returns the location object, if any (see L<FS::cust_location>).
3743
3744 =item cust_location_or_main
3745
3746 If this package is associated with a location, returns the locaiton (see
3747 L<FS::cust_location>), otherwise returns the customer (see L<FS::cust_main>).
3748
3749 =item location_label [ OPTION => VALUE ... ]
3750
3751 Returns the label of the location object (see L<FS::cust_location>).
3752
3753 =cut
3754
3755 #end of subs in location_Mixin.pm now... unfortunately the POD doesn't mixin
3756
3757 =item tax_locationnum
3758
3759 Returns the foreign key to a L<FS::cust_location> object for calculating
3760 tax on this package, as determined by the C<tax-pkg_address> and
3761 C<tax-ship_address> configuration flags.
3762
3763 =cut
3764
3765 sub tax_locationnum {
3766   my $self = shift;
3767   my $conf = FS::Conf->new;
3768   if ( $conf->exists('tax-pkg_address') ) {
3769     return $self->locationnum;
3770   }
3771   elsif ( $conf->exists('tax-ship_address') ) {
3772     return $self->cust_main->ship_locationnum;
3773   }
3774   else {
3775     return $self->cust_main->bill_locationnum;
3776   }
3777 }
3778
3779 =item tax_location
3780
3781 Returns the L<FS::cust_location> object for tax_locationnum.
3782
3783 =cut
3784
3785 sub tax_location {
3786   my $self = shift;
3787   my $conf = FS::Conf->new;
3788   if ( $conf->exists('tax-pkg_address') and $self->locationnum ) {
3789     return FS::cust_location->by_key($self->locationnum);
3790   }
3791   elsif ( $conf->exists('tax-ship_address') ) {
3792     return $self->cust_main->ship_location;
3793   }
3794   else {
3795     return $self->cust_main->bill_location;
3796   }
3797 }
3798
3799 =item seconds_since TIMESTAMP
3800
3801 Returns the number of seconds all accounts (see L<FS::svc_acct>) in this
3802 package have been online since TIMESTAMP, according to the session monitor.
3803
3804 TIMESTAMP is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
3805 L<Time::Local> and L<Date::Parse> for conversion functions.
3806
3807 =cut
3808
3809 sub seconds_since {
3810   my($self, $since) = @_;
3811   my $seconds = 0;
3812
3813   foreach my $cust_svc (
3814     grep { $_->part_svc->svcdb eq 'svc_acct' } $self->cust_svc
3815   ) {
3816     $seconds += $cust_svc->seconds_since($since);
3817   }
3818
3819   $seconds;
3820
3821 }
3822
3823 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
3824
3825 Returns the numbers of seconds all accounts (see L<FS::svc_acct>) in this
3826 package have been online between TIMESTAMP_START (inclusive) and TIMESTAMP_END
3827 (exclusive).
3828
3829 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3830 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3831 functions.
3832
3833
3834 =cut
3835
3836 sub seconds_since_sqlradacct {
3837   my($self, $start, $end) = @_;
3838
3839   my $seconds = 0;
3840
3841   foreach my $cust_svc (
3842     grep {
3843       my $part_svc = $_->part_svc;
3844       $part_svc->svcdb eq 'svc_acct'
3845         && scalar($part_svc->part_export_usage);
3846     } $self->cust_svc
3847   ) {
3848     $seconds += $cust_svc->seconds_since_sqlradacct($start, $end);
3849   }
3850
3851   $seconds;
3852
3853 }
3854
3855 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
3856
3857 Returns the sum of the given attribute for all accounts (see L<FS::svc_acct>)
3858 in this package for sessions ending between TIMESTAMP_START (inclusive) and
3859 TIMESTAMP_END
3860 (exclusive).
3861
3862 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
3863 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
3864 functions.
3865
3866 =cut
3867
3868 sub attribute_since_sqlradacct {
3869   my($self, $start, $end, $attrib) = @_;
3870
3871   my $sum = 0;
3872
3873   foreach my $cust_svc (
3874     grep {
3875       my $part_svc = $_->part_svc;
3876       scalar($part_svc->part_export_usage);
3877     } $self->cust_svc
3878   ) {
3879     $sum += $cust_svc->attribute_since_sqlradacct($start, $end, $attrib);
3880   }
3881
3882   $sum;
3883
3884 }
3885
3886 =item quantity
3887
3888 =cut
3889
3890 sub quantity {
3891   my( $self, $value ) = @_;
3892   if ( defined($value) ) {
3893     $self->setfield('quantity', $value);
3894   }
3895   $self->getfield('quantity') || 1;
3896 }
3897
3898 =item transfer DEST_PKGNUM | DEST_CUST_PKG, [ OPTION => VALUE ... ]
3899
3900 Transfers as many services as possible from this package to another package.
3901
3902 The destination package can be specified by pkgnum by passing an FS::cust_pkg
3903 object.  The destination package must already exist.
3904
3905 Services are moved only if the destination allows services with the correct
3906 I<svcpart> (not svcdb), unless the B<change_svcpart> option is set true.  Use
3907 this option with caution!  No provision is made for export differences
3908 between the old and new service definitions.  Probably only should be used
3909 when your exports for all service definitions of a given svcdb are identical.
3910 (attempt a transfer without it first, to move all possible svcpart-matching
3911 services)
3912
3913 Any services that can't be moved remain in the original package.
3914
3915 Returns an error, if there is one; otherwise, returns the number of services
3916 that couldn't be moved.
3917
3918 =cut
3919
3920 sub transfer {
3921   my ($self, $dest_pkgnum, %opt) = @_;
3922
3923   my $remaining = 0;
3924   my $dest;
3925   my %target;
3926
3927   if (ref ($dest_pkgnum) eq 'FS::cust_pkg') {
3928     $dest = $dest_pkgnum;
3929     $dest_pkgnum = $dest->pkgnum;
3930   } else {
3931     $dest = qsearchs('cust_pkg', { pkgnum => $dest_pkgnum });
3932   }
3933
3934   return ('Package does not exist: '.$dest_pkgnum) unless $dest;
3935
3936   foreach my $pkg_svc ( $dest->part_pkg->pkg_svc ) {
3937     $target{$pkg_svc->svcpart} = $pkg_svc->quantity * ( $dest->quantity || 1 );
3938   }
3939
3940   foreach my $cust_svc ($dest->cust_svc) {
3941     $target{$cust_svc->svcpart}--;
3942   }
3943
3944   my %svcpart2svcparts = ();
3945   if ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3946     warn "change_svcpart option received, creating alternates list\n" if $DEBUG;
3947     foreach my $svcpart ( map { $_->svcpart } $self->cust_svc ) {
3948       next if exists $svcpart2svcparts{$svcpart};
3949       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
3950       $svcpart2svcparts{$svcpart} = [
3951         map  { $_->[0] }
3952         sort { $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] }
3953         map {
3954               my $pkg_svc = qsearchs( 'pkg_svc', { 'pkgpart' => $dest->pkgpart,
3955                                                    'svcpart' => $_          } );
3956               [ $_,
3957                 $pkg_svc ? $pkg_svc->primary_svc : '',
3958                 $pkg_svc ? $pkg_svc->quantity : 0,
3959               ];
3960             }
3961
3962         grep { $_ != $svcpart }
3963         map  { $_->svcpart }
3964         qsearch('part_svc', { 'svcdb' => $part_svc->svcdb } )
3965       ];
3966       warn "alternates for svcpart $svcpart: ".
3967            join(', ', @{$svcpart2svcparts{$svcpart}}). "\n"
3968         if $DEBUG;
3969     }
3970   }
3971
3972   my $error;
3973   foreach my $cust_svc ($self->cust_svc) {
3974     my $svcnum = $cust_svc->svcnum;
3975     if($target{$cust_svc->svcpart} > 0
3976        or $FS::cust_svc::ignore_quantity) { # maybe should be a 'force' option
3977       $target{$cust_svc->svcpart}--;
3978       my $new = new FS::cust_svc { $cust_svc->hash };
3979       $new->pkgnum($dest_pkgnum);
3980       $error = $new->replace($cust_svc);
3981     } elsif ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
3982       if ( $DEBUG ) {
3983         warn "looking for alternates for svcpart ". $cust_svc->svcpart. "\n";
3984         warn "alternates to consider: ".
3985              join(', ', @{$svcpart2svcparts{$cust_svc->svcpart}}). "\n";
3986       }
3987       my @alternate = grep {
3988                              warn "considering alternate svcpart $_: ".
3989                                   "$target{$_} available in new package\n"
3990                                if $DEBUG;
3991                              $target{$_} > 0;
3992                            } @{$svcpart2svcparts{$cust_svc->svcpart}};
3993       if ( @alternate ) {
3994         warn "alternate(s) found\n" if $DEBUG;
3995         my $change_svcpart = $alternate[0];
3996         $target{$change_svcpart}--;
3997         my $new = new FS::cust_svc { $cust_svc->hash };
3998         $new->svcpart($change_svcpart);
3999         $new->pkgnum($dest_pkgnum);
4000         $error = $new->replace($cust_svc);
4001       } else {
4002         $remaining++;
4003       }
4004     } else {
4005       $remaining++
4006     }
4007     if ( $error ) {
4008       my @label = $cust_svc->label;
4009       return "service $label[1]: $error";
4010     }
4011   }
4012   return $remaining;
4013 }
4014
4015 =item grab_svcnums SVCNUM, SVCNUM ...
4016
4017 Change the pkgnum for the provided services to this packages.  If there is an
4018 error, returns the error, otherwise returns false.
4019
4020 =cut
4021
4022 sub grab_svcnums {
4023   my $self = shift;
4024   my @svcnum = @_;
4025
4026   local $SIG{HUP} = 'IGNORE';
4027   local $SIG{INT} = 'IGNORE';
4028   local $SIG{QUIT} = 'IGNORE';
4029   local $SIG{TERM} = 'IGNORE';
4030   local $SIG{TSTP} = 'IGNORE';
4031   local $SIG{PIPE} = 'IGNORE';
4032
4033   my $oldAutoCommit = $FS::UID::AutoCommit;
4034   local $FS::UID::AutoCommit = 0;
4035   my $dbh = dbh;
4036
4037   foreach my $svcnum (@svcnum) {
4038     my $cust_svc = qsearchs('cust_svc', { svcnum=>$svcnum } ) or do {
4039       $dbh->rollback if $oldAutoCommit;
4040       return "unknown svcnum $svcnum";
4041     };
4042     $cust_svc->pkgnum( $self->pkgnum );
4043     my $error = $cust_svc->replace;
4044     if ( $error ) {
4045       $dbh->rollback if $oldAutoCommit;
4046       return $error;
4047     }
4048   }
4049
4050   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4051   '';
4052
4053 }
4054
4055 =item reexport
4056
4057 This method is deprecated.  See the I<depend_jobnum> option to the insert and
4058 order_pkgs methods in FS::cust_main for a better way to defer provisioning.
4059
4060 =cut
4061
4062 sub reexport {
4063   my $self = shift;
4064
4065   local $SIG{HUP} = 'IGNORE';
4066   local $SIG{INT} = 'IGNORE';
4067   local $SIG{QUIT} = 'IGNORE';
4068   local $SIG{TERM} = 'IGNORE';
4069   local $SIG{TSTP} = 'IGNORE';
4070   local $SIG{PIPE} = 'IGNORE';
4071
4072   my $oldAutoCommit = $FS::UID::AutoCommit;
4073   local $FS::UID::AutoCommit = 0;
4074   my $dbh = dbh;
4075
4076   foreach my $cust_svc ( $self->cust_svc ) {
4077     #false laziness w/svc_Common::insert
4078     my $svc_x = $cust_svc->svc_x;
4079     foreach my $part_export ( $cust_svc->part_svc->part_export ) {
4080       my $error = $part_export->export_insert($svc_x);
4081       if ( $error ) {
4082         $dbh->rollback if $oldAutoCommit;
4083         return $error;
4084       }
4085     }
4086   }
4087
4088   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4089   '';
4090
4091 }
4092
4093 =item export_pkg_change OLD_CUST_PKG
4094
4095 Calls the "pkg_change" export action for all services attached to this package.
4096
4097 =cut
4098
4099 sub export_pkg_change {
4100   my( $self, $old )  = ( shift, shift );
4101
4102   local $SIG{HUP} = 'IGNORE';
4103   local $SIG{INT} = 'IGNORE';
4104   local $SIG{QUIT} = 'IGNORE';
4105   local $SIG{TERM} = 'IGNORE';
4106   local $SIG{TSTP} = 'IGNORE';
4107   local $SIG{PIPE} = 'IGNORE';
4108
4109   my $oldAutoCommit = $FS::UID::AutoCommit;
4110   local $FS::UID::AutoCommit = 0;
4111   my $dbh = dbh;
4112
4113   foreach my $svc_x ( map $_->svc_x, $self->cust_svc ) {
4114     my $error = $svc_x->export('pkg_change', $self, $old);
4115     if ( $error ) {
4116       $dbh->rollback if $oldAutoCommit;
4117       return $error;
4118     }
4119   }
4120
4121   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4122   '';
4123
4124 }
4125
4126 =item insert_reason
4127
4128 Associates this package with a (suspension or cancellation) reason (see
4129 L<FS::cust_pkg_reason>, possibly inserting a new reason on the fly (see
4130 L<FS::reason>).
4131
4132 Available options are:
4133
4134 =over 4
4135
4136 =item reason
4137
4138 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
4139
4140 =item reason_otaker
4141
4142 the access_user (see L<FS::access_user>) providing the reason
4143
4144 =item date
4145
4146 a unix timestamp
4147
4148 =item action
4149
4150 the action (cancel, susp, adjourn, expire) associated with the reason
4151
4152 =back
4153
4154 If there is an error, returns the error, otherwise returns false.
4155
4156 =cut
4157
4158 sub insert_reason {
4159   my ($self, %options) = @_;
4160
4161   my $otaker = $options{reason_otaker} ||
4162                $FS::CurrentUser::CurrentUser->username;
4163
4164   my $reasonnum;
4165   if ( $options{'reason'} =~ /^(\d+)$/ ) {
4166
4167     $reasonnum = $1;
4168
4169   } elsif ( ref($options{'reason'}) ) {
4170
4171     return 'Enter a new reason (or select an existing one)'
4172       unless $options{'reason'}->{'reason'} !~ /^\s*$/;
4173
4174     my $reason = new FS::reason({
4175       'reason_type' => $options{'reason'}->{'typenum'},
4176       'reason'      => $options{'reason'}->{'reason'},
4177     });
4178     my $error = $reason->insert;
4179     return $error if $error;
4180
4181     $reasonnum = $reason->reasonnum;
4182
4183   } else {
4184     return "Unparseable reason: ". $options{'reason'};
4185   }
4186
4187   my $cust_pkg_reason =
4188     new FS::cust_pkg_reason({ 'pkgnum'    => $self->pkgnum,
4189                               'reasonnum' => $reasonnum,
4190                               'otaker'    => $otaker,
4191                               'action'    => substr(uc($options{'action'}),0,1),
4192                               'date'      => $options{'date'}
4193                                                ? $options{'date'}
4194                                                : time,
4195                             });
4196
4197   $cust_pkg_reason->insert;
4198 }
4199
4200 =item insert_discount
4201
4202 Associates this package with a discount (see L<FS::cust_pkg_discount>, possibly
4203 inserting a new discount on the fly (see L<FS::discount>).
4204
4205 Available options are:
4206
4207 =over 4
4208
4209 =item discountnum
4210
4211 =back
4212
4213 If there is an error, returns the error, otherwise returns false.
4214
4215 =cut
4216
4217 sub insert_discount {
4218   #my ($self, %options) = @_;
4219   my $self = shift;
4220
4221   my $cust_pkg_discount = new FS::cust_pkg_discount {
4222     'pkgnum'      => $self->pkgnum,
4223     'discountnum' => $self->discountnum,
4224     'months_used' => 0,
4225     'end_date'    => '', #XXX
4226     #for the create a new discount case
4227     '_type'       => $self->discountnum__type,
4228     'amount'      => $self->discountnum_amount,
4229     'percent'     => $self->discountnum_percent,
4230     'months'      => $self->discountnum_months,
4231     'setup'      => $self->discountnum_setup,
4232     #'disabled'    => $self->discountnum_disabled,
4233   };
4234
4235   $cust_pkg_discount->insert;
4236 }
4237
4238 =item set_usage USAGE_VALUE_HASHREF
4239
4240 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4241 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4242 upbytes, downbytes, and totalbytes are appropriate keys.
4243
4244 All svc_accts which are part of this package have their values reset.
4245
4246 =cut
4247
4248 sub set_usage {
4249   my ($self, $valueref, %opt) = @_;
4250
4251   #only svc_acct can set_usage for now
4252   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4253     my $svc_x = $cust_svc->svc_x;
4254     $svc_x->set_usage($valueref, %opt)
4255       if $svc_x->can("set_usage");
4256   }
4257 }
4258
4259 =item recharge USAGE_VALUE_HASHREF
4260
4261 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4262 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4263 upbytes, downbytes, and totalbytes are appropriate keys.
4264
4265 All svc_accts which are part of this package have their values incremented.
4266
4267 =cut
4268
4269 sub recharge {
4270   my ($self, $valueref) = @_;
4271
4272   #only svc_acct can set_usage for now
4273   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4274     my $svc_x = $cust_svc->svc_x;
4275     $svc_x->recharge($valueref)
4276       if $svc_x->can("recharge");
4277   }
4278 }
4279
4280 =item cust_pkg_discount
4281
4282 =cut
4283
4284 sub cust_pkg_discount {
4285   my $self = shift;
4286   qsearch('cust_pkg_discount', { 'pkgnum' => $self->pkgnum } );
4287 }
4288
4289 =item cust_pkg_discount_active
4290
4291 =cut
4292
4293 sub cust_pkg_discount_active {
4294   my $self = shift;
4295   grep { $_->status eq 'active' } $self->cust_pkg_discount;
4296 }
4297
4298 =item cust_pkg_usage
4299
4300 Returns a list of all voice usage counters attached to this package.
4301
4302 =cut
4303
4304 sub cust_pkg_usage {
4305   my $self = shift;
4306   qsearch('cust_pkg_usage', { pkgnum => $self->pkgnum });
4307 }
4308
4309 =item apply_usage OPTIONS
4310
4311 Takes the following options:
4312 - cdr: a call detail record (L<FS::cdr>)
4313 - rate_detail: the rate determined for this call (L<FS::rate_detail>)
4314 - minutes: the maximum number of minutes to be charged
4315
4316 Finds available usage minutes for a call of this class, and subtracts
4317 up to that many minutes from the usage pool.  If the usage pool is empty,
4318 and the C<cdr-minutes_priority> global config option is set, minutes may
4319 be taken from other calls as well.  Either way, an allocation record will
4320 be created (L<FS::cdr_cust_pkg_usage>) and this method will return the
4321 number of minutes of usage applied to the call.
4322
4323 =cut
4324
4325 sub apply_usage {
4326   my ($self, %opt) = @_;
4327   my $cdr = $opt{cdr};
4328   my $rate_detail = $opt{rate_detail};
4329   my $minutes = $opt{minutes};
4330   my $classnum = $rate_detail->classnum;
4331   my $pkgnum = $self->pkgnum;
4332   my $custnum = $self->custnum;
4333
4334   local $SIG{HUP} = 'IGNORE';
4335   local $SIG{INT} = 'IGNORE';
4336   local $SIG{QUIT} = 'IGNORE';
4337   local $SIG{TERM} = 'IGNORE';
4338   local $SIG{TSTP} = 'IGNORE';
4339   local $SIG{PIPE} = 'IGNORE';
4340
4341   my $oldAutoCommit = $FS::UID::AutoCommit;
4342   local $FS::UID::AutoCommit = 0;
4343   my $dbh = dbh;
4344   my $order = FS::Conf->new->config('cdr-minutes_priority');
4345
4346   my $is_classnum;
4347   if ( $classnum ) {
4348     $is_classnum = ' part_pkg_usage_class.classnum = '.$classnum;
4349   } else {
4350     $is_classnum = ' part_pkg_usage_class.classnum IS NULL';
4351   }
4352   my @usage_recs = qsearch({
4353       'table'     => 'cust_pkg_usage',
4354       'addl_from' => ' JOIN part_pkg_usage       USING (pkgusagepart)'.
4355                      ' JOIN cust_pkg             USING (pkgnum)'.
4356                      ' JOIN part_pkg_usage_class USING (pkgusagepart)',
4357       'select'    => 'cust_pkg_usage.*',
4358       'extra_sql' => " WHERE ( cust_pkg.pkgnum = $pkgnum OR ".
4359                      " ( cust_pkg.custnum = $custnum AND ".
4360                      " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4361                      $is_classnum . ' AND '.
4362                      " cust_pkg_usage.minutes > 0",
4363       'order_by'  => " ORDER BY priority ASC",
4364   });
4365
4366   my $orig_minutes = $minutes;
4367   my $error;
4368   while (!$error and $minutes > 0 and @usage_recs) {
4369     my $cust_pkg_usage = shift @usage_recs;
4370     $cust_pkg_usage->select_for_update;
4371     my $cdr_cust_pkg_usage = FS::cdr_cust_pkg_usage->new({
4372         pkgusagenum => $cust_pkg_usage->pkgusagenum,
4373         acctid      => $cdr->acctid,
4374         minutes     => min($cust_pkg_usage->minutes, $minutes),
4375     });
4376     $cust_pkg_usage->set('minutes',
4377       $cust_pkg_usage->minutes - $cdr_cust_pkg_usage->minutes
4378     );
4379     $error = $cust_pkg_usage->replace || $cdr_cust_pkg_usage->insert;
4380     $minutes -= $cdr_cust_pkg_usage->minutes;
4381   }
4382   if ( $order and $minutes > 0 and !$error ) {
4383     # then try to steal minutes from another call
4384     my %search = (
4385         'table'     => 'cdr_cust_pkg_usage',
4386         'addl_from' => ' JOIN cust_pkg_usage        USING (pkgusagenum)'.
4387                        ' JOIN part_pkg_usage        USING (pkgusagepart)'.
4388                        ' JOIN cust_pkg              USING (pkgnum)'.
4389                        ' JOIN part_pkg_usage_class  USING (pkgusagepart)'.
4390                        ' JOIN cdr                   USING (acctid)',
4391         'select'    => 'cdr_cust_pkg_usage.*',
4392         'extra_sql' => " WHERE cdr.freesidestatus = 'rated' AND ".
4393                        " ( cust_pkg.pkgnum = $pkgnum OR ".
4394                        " ( cust_pkg.custnum = $custnum AND ".
4395                        " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4396                        " part_pkg_usage_class.classnum = $classnum",
4397         'order_by'  => ' ORDER BY part_pkg_usage.priority ASC',
4398     );
4399     if ( $order eq 'time' ) {
4400       # find CDRs that are using minutes, but have a later startdate
4401       # than this call
4402       my $startdate = $cdr->startdate;
4403       if ($startdate !~ /^\d+$/) {
4404         die "bad cdr startdate '$startdate'";
4405       }
4406       $search{'extra_sql'} .= " AND cdr.startdate > $startdate";
4407       # minimize needless reshuffling
4408       $search{'order_by'} .= ', cdr.startdate DESC';
4409     } else {
4410       # XXX may not work correctly with rate_time schedules.  Could
4411       # fix this by storing ratedetailnum in cdr_cust_pkg_usage, I
4412       # think...
4413       $search{'addl_from'} .=
4414         ' JOIN rate_detail'.
4415         ' ON (cdr.rated_ratedetailnum = rate_detail.ratedetailnum)';
4416       if ( $order eq 'rate_high' ) {
4417         $search{'extra_sql'} .= ' AND rate_detail.min_charge < '.
4418                                 $rate_detail->min_charge;
4419         $search{'order_by'} .= ', rate_detail.min_charge ASC';
4420       } elsif ( $order eq 'rate_low' ) {
4421         $search{'extra_sql'} .= ' AND rate_detail.min_charge > '.
4422                                 $rate_detail->min_charge;
4423         $search{'order_by'} .= ', rate_detail.min_charge DESC';
4424       } else {
4425         #  this should really never happen
4426         die "invalid cdr-minutes_priority value '$order'\n";
4427       }
4428     }
4429     my @cdr_usage_recs = qsearch(\%search);
4430     my %reproc_cdrs;
4431     while (!$error and @cdr_usage_recs and $minutes > 0) {
4432       my $cdr_cust_pkg_usage = shift @cdr_usage_recs;
4433       my $cust_pkg_usage = $cdr_cust_pkg_usage->cust_pkg_usage;
4434       my $old_cdr = $cdr_cust_pkg_usage->cdr;
4435       $reproc_cdrs{$old_cdr->acctid} = $old_cdr;
4436       $cdr_cust_pkg_usage->select_for_update;
4437       $old_cdr->select_for_update;
4438       $cust_pkg_usage->select_for_update;
4439       # in case someone else stole the usage from this CDR
4440       # while waiting for the lock...
4441       next if $old_cdr->acctid != $cdr_cust_pkg_usage->acctid;
4442       # steal the usage allocation and flag the old CDR for reprocessing
4443       $cdr_cust_pkg_usage->set('acctid', $cdr->acctid);
4444       # if the allocation is more minutes than we need, adjust it...
4445       my $delta = $cdr_cust_pkg_usage->minutes - $minutes;
4446       if ( $delta > 0 ) {
4447         $cdr_cust_pkg_usage->set('minutes', $minutes);
4448         $cust_pkg_usage->set('minutes', $cust_pkg_usage->minutes + $delta);
4449         $error = $cust_pkg_usage->replace;
4450       }
4451       #warn 'CDR '.$cdr->acctid . ' stealing allocation '.$cdr_cust_pkg_usage->cdrusagenum.' from CDR '.$old_cdr->acctid."\n";
4452       $error ||= $cdr_cust_pkg_usage->replace;
4453       # deduct the stolen minutes
4454       $minutes -= $cdr_cust_pkg_usage->minutes;
4455     }
4456     # after all minute-stealing is done, reset the affected CDRs
4457     foreach (values %reproc_cdrs) {
4458       $error ||= $_->set_status('');
4459       # XXX or should we just call $cdr->rate right here?
4460       # it's not like we can create a loop this way, since the min_charge
4461       # or call time has to go monotonically in one direction.
4462       # we COULD get some very deep recursions going, though...
4463     }
4464   } # if $order and $minutes
4465   if ( $error ) {
4466     $dbh->rollback;
4467     die "error applying included minutes\npkgnum ".$self->pkgnum.", class $classnum, acctid ".$cdr->acctid."\n$error\n"
4468   } else {
4469     $dbh->commit if $oldAutoCommit;
4470     return $orig_minutes - $minutes;
4471   }
4472 }
4473
4474 =item supplemental_pkgs
4475
4476 Returns a list of all packages supplemental to this one.
4477
4478 =cut
4479
4480 sub supplemental_pkgs {
4481   my $self = shift;
4482   qsearch('cust_pkg', { 'main_pkgnum' => $self->pkgnum });
4483 }
4484
4485 =item main_pkg
4486
4487 Returns the package that this one is supplemental to, if any.
4488
4489 =cut
4490
4491 sub main_pkg {
4492   my $self = shift;
4493   if ( $self->main_pkgnum ) {
4494     return FS::cust_pkg->by_key($self->main_pkgnum);
4495   }
4496   return;
4497 }
4498
4499 =back
4500
4501 =head1 CLASS METHODS
4502
4503 =over 4
4504
4505 =item recurring_sql
4506
4507 Returns an SQL expression identifying recurring packages.
4508
4509 =cut
4510
4511 sub recurring_sql { "
4512   '0' != ( select freq from part_pkg
4513              where cust_pkg.pkgpart = part_pkg.pkgpart )
4514 "; }
4515
4516 =item onetime_sql
4517
4518 Returns an SQL expression identifying one-time packages.
4519
4520 =cut
4521
4522 sub onetime_sql { "
4523   '0' = ( select freq from part_pkg
4524             where cust_pkg.pkgpart = part_pkg.pkgpart )
4525 "; }
4526
4527 =item ordered_sql
4528
4529 Returns an SQL expression identifying ordered packages (recurring packages not
4530 yet billed).
4531
4532 =cut
4533
4534 sub ordered_sql {
4535    $_[0]->recurring_sql. " AND ". $_[0]->not_yet_billed_sql;
4536 }
4537
4538 =item active_sql
4539
4540 Returns an SQL expression identifying active packages.
4541
4542 =cut
4543
4544 sub active_sql {
4545   $_[0]->recurring_sql. "
4546   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4547   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4548   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4549 "; }
4550
4551 =item not_yet_billed_sql
4552
4553 Returns an SQL expression identifying packages which have not yet been billed.
4554
4555 =cut
4556
4557 sub not_yet_billed_sql { "
4558       ( cust_pkg.setup  IS NULL OR cust_pkg.setup  = 0 )
4559   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4560   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4561 "; }
4562
4563 =item inactive_sql
4564
4565 Returns an SQL expression identifying inactive packages (one-time packages
4566 that are otherwise unsuspended/uncancelled).
4567
4568 =cut
4569
4570 sub inactive_sql { "
4571   ". $_[0]->onetime_sql(). "
4572   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4573   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4574   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4575 "; }
4576
4577 =item on_hold_sql
4578
4579 Returns an SQL expression identifying on-hold packages.
4580
4581 =cut
4582
4583 sub on_hold_sql {
4584   #$_[0]->recurring_sql(). ' AND '.
4585   "
4586         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel  = 0 )
4587     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp   != 0
4588     AND ( cust_pkg.setup  IS     NULL  OR cust_pkg.setup   = 0 )
4589   ";
4590 }
4591
4592 =item susp_sql
4593 =item suspended_sql
4594
4595 Returns an SQL expression identifying suspended packages.
4596
4597 =cut
4598
4599 sub suspended_sql { susp_sql(@_); }
4600 sub susp_sql {
4601   #$_[0]->recurring_sql(). ' AND '.
4602   "
4603         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel = 0 )
4604     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp  != 0
4605     AND   cust_pkg.setup  IS NOT NULL AND cust_pkg.setup != 0
4606   ";
4607 }
4608
4609 =item cancel_sql
4610 =item cancelled_sql
4611
4612 Returns an SQL exprression identifying cancelled packages.
4613
4614 =cut
4615
4616 sub cancelled_sql { cancel_sql(@_); }
4617 sub cancel_sql {
4618   #$_[0]->recurring_sql(). ' AND '.
4619   "cust_pkg.cancel IS NOT NULL AND cust_pkg.cancel != 0";
4620 }
4621
4622 =item status_sql
4623
4624 Returns an SQL expression to give the package status as a string.
4625
4626 =cut
4627
4628 sub status_sql {
4629 "CASE
4630   WHEN cust_pkg.cancel IS NOT NULL THEN 'cancelled'
4631   WHEN ( cust_pkg.susp IS NOT NULL AND cust_pkg.setup IS NULL ) THEN 'on hold'
4632   WHEN cust_pkg.susp IS NOT NULL THEN 'suspended'
4633   WHEN cust_pkg.setup IS NULL THEN 'not yet billed'
4634   WHEN ".onetime_sql()." THEN 'one-time charge'
4635   ELSE 'active'
4636 END"
4637 }
4638
4639 =item search HASHREF
4640
4641 (Class method)
4642
4643 Returns a qsearch hash expression to search for parameters specified in HASHREF.
4644 Valid parameters are
4645
4646 =over 4
4647
4648 =item agentnum
4649
4650 =item status
4651
4652 on hold, active, inactive (or one-time charge), suspended, canceled (or cancelled)
4653
4654 =item magic
4655
4656 Equivalent to "status", except that "canceled"/"cancelled" will exclude
4657 packages that were changed into a new package with the same pkgpart (i.e.
4658 location or quantity changes).
4659
4660 =item custom
4661
4662  boolean selects custom packages
4663
4664 =item classnum
4665
4666 =item pkgpart
4667
4668 pkgpart or arrayref or hashref of pkgparts
4669
4670 =item setup
4671
4672 arrayref of beginning and ending epoch date
4673
4674 =item last_bill
4675
4676 arrayref of beginning and ending epoch date
4677
4678 =item bill
4679
4680 arrayref of beginning and ending epoch date
4681
4682 =item adjourn
4683
4684 arrayref of beginning and ending epoch date
4685
4686 =item susp
4687
4688 arrayref of beginning and ending epoch date
4689
4690 =item expire
4691
4692 arrayref of beginning and ending epoch date
4693
4694 =item cancel
4695
4696 arrayref of beginning and ending epoch date
4697
4698 =item query
4699
4700 pkgnum or APKG_pkgnum
4701
4702 =item cust_fields
4703
4704 a value suited to passing to FS::UI::Web::cust_header
4705
4706 =item CurrentUser
4707
4708 specifies the user for agent virtualization
4709
4710 =item fcc_line
4711
4712 boolean; if true, returns only packages with more than 0 FCC phone lines.
4713
4714 =item state, country
4715
4716 Limit to packages with a service location in the specified state and country.
4717 For FCC 477 reporting, mostly.
4718
4719 =item location_cust
4720
4721 Limit to packages whose service locations are the same as the customer's
4722 default service location.
4723
4724 =item location_nocust
4725
4726 Limit to packages whose service locations are not the customer's default
4727 service location.
4728
4729 =item location_census
4730
4731 Limit to packages whose service locations have census tracts.
4732
4733 =item location_nocensus
4734
4735 Limit to packages whose service locations do not have a census tract.
4736
4737 =item location_geocode
4738
4739 Limit to packages whose locations have geocodes.
4740
4741 =item location_geocode
4742
4743 Limit to packages whose locations do not have geocodes.
4744
4745 =item towernum
4746
4747 Limit to packages associated with a svc_broadband, associated with a sector,
4748 associated with this towernum (or any of these, if it's an arrayref) (or NO
4749 towernum, if it's zero). This is an extreme niche case.
4750
4751 =item 477part, 477rownum, date
4752
4753 Limit to packages included in a specific row of one of the FCC 477 reports.
4754 '477part' is the section name (see L<FS::Report::FCC_477> methods), 'date'
4755 is the report as-of date (completely unrelated to the package setup/bill/
4756 other date fields), and '477rownum' is the row number of the report starting
4757 with zero. Row numbers have no inherent meaning, so this is useful only
4758 for explaining a 477 report you've already run.
4759
4760 =back
4761
4762 =cut
4763
4764 sub search {
4765   my ($class, $params) = @_;
4766   my @where = ();
4767
4768   ##
4769   # parse agent
4770   ##
4771
4772   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
4773     push @where,
4774       "cust_main.agentnum = $1";
4775   }
4776
4777   ##
4778   # parse cust_status
4779   ##
4780
4781   if ( $params->{'cust_status'} =~ /^([a-z]+)$/ ) {
4782     push @where, FS::cust_main->cust_status_sql . " = '$1' ";
4783   }
4784
4785   ##
4786   # parse customer sales person
4787   ##
4788
4789   if ( $params->{'cust_main_salesnum'} =~ /^(\d+)$/ ) {
4790     push @where, ($1 > 0) ? "cust_main.salesnum = $1"
4791                           : 'cust_main.salesnum IS NULL';
4792   }
4793
4794
4795   ##
4796   # parse sales person
4797   ##
4798
4799   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
4800     push @where, ($1 > 0) ? "cust_pkg.salesnum = $1"
4801                           : 'cust_pkg.salesnum IS NULL';
4802   }
4803
4804   ##
4805   # parse custnum
4806   ##
4807
4808   if ( $params->{'custnum'} =~ /^(\d+)$/ and $1 ) {
4809     push @where,
4810       "cust_pkg.custnum = $1";
4811   }
4812
4813   ##
4814   # custbatch
4815   ##
4816
4817   if ( $params->{'pkgbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
4818     push @where,
4819       "cust_pkg.pkgbatch = '$1'";
4820   }
4821
4822   ##
4823   # parse status
4824   ##
4825
4826   if (    $params->{'magic'}  eq 'active'
4827        || $params->{'status'} eq 'active' ) {
4828
4829     push @where, FS::cust_pkg->active_sql();
4830
4831   } elsif (    $params->{'magic'}  =~ /^not[ _]yet[ _]billed$/
4832             || $params->{'status'} =~ /^not[ _]yet[ _]billed$/ ) {
4833
4834     push @where, FS::cust_pkg->not_yet_billed_sql();
4835
4836   } elsif (    $params->{'magic'}  =~ /^(one-time charge|inactive)/
4837             || $params->{'status'} =~ /^(one-time charge|inactive)/ ) {
4838
4839     push @where, FS::cust_pkg->inactive_sql();
4840
4841   } elsif (    $params->{'magic'}  =~ /^on[ _]hold$/
4842             || $params->{'status'} =~ /^on[ _]hold$/ ) {
4843
4844     push @where, FS::cust_pkg->on_hold_sql();
4845
4846
4847   } elsif (    $params->{'magic'}  eq 'suspended'
4848             || $params->{'status'} eq 'suspended'  ) {
4849
4850     push @where, FS::cust_pkg->suspended_sql();
4851
4852   } elsif (    $params->{'magic'}  =~ /^cancell?ed$/
4853             || $params->{'status'} =~ /^cancell?ed$/ ) {
4854
4855     push @where, FS::cust_pkg->cancelled_sql();
4856
4857   }
4858
4859   ### special case: "magic" is used in detail links from browse/part_pkg,
4860   # where "cancelled" has the restriction "and not replaced with a package
4861   # of the same pkgpart".  Be consistent with that.
4862   ###
4863
4864   if ( $params->{'magic'} =~ /^cancell?ed$/ ) {
4865     my $new_pkgpart = "SELECT pkgpart FROM cust_pkg AS cust_pkg_next ".
4866                       "WHERE cust_pkg_next.change_pkgnum = cust_pkg.pkgnum";
4867     # ...may not exist, if this was just canceled and not changed; in that
4868     # case give it a "new pkgpart" that never equals the old pkgpart
4869     push @where, "COALESCE(($new_pkgpart), 0) != cust_pkg.pkgpart";
4870   }
4871
4872   ###
4873   # parse package class
4874   ###
4875
4876   if ( exists($params->{'classnum'}) ) {
4877
4878     my @classnum = ();
4879     if ( ref($params->{'classnum'}) ) {
4880
4881       if ( ref($params->{'classnum'}) eq 'HASH' ) {
4882         @classnum = grep $params->{'classnum'}{$_}, keys %{ $params->{'classnum'} };
4883       } elsif ( ref($params->{'classnum'}) eq 'ARRAY' ) {
4884         @classnum = @{ $params->{'classnum'} };
4885       } else {
4886         die 'unhandled classnum ref '. $params->{'classnum'};
4887       }
4888
4889
4890     } elsif ( $params->{'classnum'} =~ /^(\d*)$/ && $1 ne '0' ) {
4891       @classnum = ( $1 );
4892     }
4893
4894     if ( @classnum ) {
4895
4896       my @c_where = ();
4897       my @nums = grep $_, @classnum;
4898       push @c_where, 'part_pkg.classnum IN ('. join(',',@nums). ')' if @nums;
4899       my $null = scalar( grep { $_ eq '' } @classnum );
4900       push @c_where, 'part_pkg.classnum IS NULL' if $null;
4901
4902       if ( scalar(@c_where) == 1 ) {
4903         push @where, @c_where;
4904       } elsif ( @c_where ) {
4905         push @where, ' ( '. join(' OR ', @c_where). ' ) ';
4906       }
4907
4908     }
4909
4910
4911   }
4912
4913   ###
4914   # parse refnum (advertising source)
4915   ###
4916
4917   if ( exists($params->{'refnum'}) ) {
4918     my @refnum;
4919     if (ref $params->{'refnum'}) {
4920       @refnum = @{ $params->{'refnum'} };
4921     } else {
4922       @refnum = ( $params->{'refnum'} );
4923     }
4924     my $in = join(',', grep /^\d+$/, @refnum);
4925     push @where, "refnum IN($in)" if length $in;
4926   }
4927
4928   ###
4929   # parse package report options
4930   ###
4931
4932   my @report_option = ();
4933   if ( exists($params->{'report_option'}) ) {
4934     if ( ref($params->{'report_option'}) eq 'ARRAY' ) {
4935       @report_option = @{ $params->{'report_option'} };
4936     } elsif ( $params->{'report_option'} =~ /^([,\d]*)$/ ) {
4937       @report_option = split(',', $1);
4938     }
4939
4940   }
4941
4942   if (@report_option) {
4943     # this will result in the empty set for the dangling comma case as it should
4944     push @where,
4945       map{ "0 < ( SELECT count(*) FROM part_pkg_option
4946                     WHERE part_pkg_option.pkgpart = part_pkg.pkgpart
4947                     AND optionname = 'report_option_$_'
4948                     AND optionvalue = '1' )"
4949          } @report_option;
4950   }
4951
4952   foreach my $any ( grep /^report_option_any/, keys %$params ) {
4953
4954     my @report_option_any = ();
4955     if ( ref($params->{$any}) eq 'ARRAY' ) {
4956       @report_option_any = @{ $params->{$any} };
4957     } elsif ( $params->{$any} =~ /^([,\d]*)$/ ) {
4958       @report_option_any = split(',', $1);
4959     }
4960
4961     if (@report_option_any) {
4962       # this will result in the empty set for the dangling comma case as it should
4963       push @where, ' ( '. join(' OR ',
4964         map{ "0 < ( SELECT count(*) FROM part_pkg_option
4965                       WHERE part_pkg_option.pkgpart = part_pkg.pkgpart
4966                       AND optionname = 'report_option_$_'
4967                       AND optionvalue = '1' )"
4968            } @report_option_any
4969       ). ' ) ';
4970     }
4971
4972   }
4973
4974   ###
4975   # parse custom
4976   ###
4977
4978   push @where,  "part_pkg.custom = 'Y'" if $params->{custom};
4979
4980   ###
4981   # parse fcc_line
4982   ###
4983
4984   push @where,  "(part_pkg.fcc_ds0s > 0 OR pkg_class.fcc_ds0s > 0)"
4985                                                         if $params->{fcc_line};
4986
4987   ###
4988   # parse censustract
4989   ###
4990
4991   if ( exists($params->{'censustract'}) ) {
4992     $params->{'censustract'} =~ /^([.\d]*)$/;
4993     my $censustract = "cust_location.censustract = '$1'";
4994     $censustract .= ' OR cust_location.censustract is NULL' unless $1;
4995     push @where,  "( $censustract )";
4996   }
4997
4998   ###
4999   # parse censustract2
5000   ###
5001   if ( exists($params->{'censustract2'})
5002        && $params->{'censustract2'} =~ /^(\d*)$/
5003      )
5004   {
5005     if ($1) {
5006       push @where, "cust_location.censustract LIKE '$1%'";
5007     } else {
5008       push @where,
5009         "( cust_location.censustract = '' OR cust_location.censustract IS NULL )";
5010     }
5011   }
5012
5013   ###
5014   # parse country/state/zip
5015   ###
5016   for (qw(state country)) { # parsing rules are the same for these
5017   if ( exists($params->{$_})
5018     && uc($params->{$_}) =~ /^([A-Z]{2})$/ )
5019     {
5020       # XXX post-2.3 only--before that, state/country may be in cust_main
5021       push @where, "cust_location.$_ = '$1'";
5022     }
5023   }
5024   if ( exists($params->{zip}) ) {
5025     push @where, "cust_location.zip = " . dbh->quote($params->{zip});
5026   }
5027
5028   ###
5029   # location_* flags
5030   ###
5031   if ( $params->{location_cust} xor $params->{location_nocust} ) {
5032     my $op = $params->{location_cust} ? '=' : '!=';
5033     push @where, "cust_location.locationnum $op cust_main.ship_locationnum";
5034   }
5035   if ( $params->{location_census} xor $params->{location_nocensus} ) {
5036     my $op = $params->{location_census} ? "IS NOT NULL" : "IS NULL";
5037     push @where, "cust_location.censustract $op";
5038   }
5039   if ( $params->{location_geocode} xor $params->{location_nogeocode} ) {
5040     my $op = $params->{location_geocode} ? "IS NOT NULL" : "IS NULL";
5041     push @where, "cust_location.geocode $op";
5042   }
5043
5044   ###
5045   # parse part_pkg
5046   ###
5047
5048   if ( ref($params->{'pkgpart'}) ) {
5049
5050     my @pkgpart = ();
5051     if ( ref($params->{'pkgpart'}) eq 'HASH' ) {
5052       @pkgpart = grep $params->{'pkgpart'}{$_}, keys %{ $params->{'pkgpart'} };
5053     } elsif ( ref($params->{'pkgpart'}) eq 'ARRAY' ) {
5054       @pkgpart = @{ $params->{'pkgpart'} };
5055     } else {
5056       die 'unhandled pkgpart ref '. $params->{'pkgpart'};
5057     }
5058
5059     @pkgpart = grep /^(\d+)$/, @pkgpart;
5060
5061     push @where, 'pkgpart IN ('. join(',', @pkgpart). ')' if scalar(@pkgpart);
5062
5063   } elsif ( $params->{'pkgpart'} =~ /^(\d+)$/ ) {
5064     push @where, "pkgpart = $1";
5065   }
5066
5067   ###
5068   # parse dates
5069   ###
5070
5071   my $orderby = '';
5072
5073   #false laziness w/report_cust_pkg.html
5074   my %disable = (
5075     'all'             => {},
5076     'one-time charge' => { 'last_bill'=>1, 'bill'=>1, 'adjourn'=>1, 'susp'=>1, 'expire'=>1, 'cancel'=>1, },
5077     'active'          => { 'susp'=>1, 'cancel'=>1 },
5078     'suspended'       => { 'cancel' => 1 },
5079     'cancelled'       => {},
5080     ''                => {},
5081   );
5082
5083   if( exists($params->{'active'} ) ) {
5084     # This overrides all the other date-related fields, and includes packages
5085     # that were active at some time during the interval.  It excludes:
5086     # - packages that were set up after the end of the interval
5087     # - packages that were canceled before the start of the interval
5088     # - packages that were suspended before the start of the interval
5089     #   and are still suspended now
5090     my($beginning, $ending) = @{$params->{'active'}};
5091     push @where,
5092       "cust_pkg.setup IS NOT NULL",
5093       "cust_pkg.setup <= $ending",
5094       "(cust_pkg.cancel IS NULL OR cust_pkg.cancel >= $beginning )",
5095       "(cust_pkg.susp   IS NULL OR cust_pkg.susp   >= $beginning )",
5096       "NOT (".FS::cust_pkg->onetime_sql . ")";
5097   }
5098   else {
5099     my $exclude_change_from = 0;
5100     my $exclude_change_to = 0;
5101
5102     foreach my $field (qw( setup last_bill bill adjourn susp expire contract_end change_date cancel )) {
5103
5104       next unless exists($params->{$field});
5105
5106       my($beginning, $ending) = @{$params->{$field}};
5107
5108       next if $beginning == 0 && $ending == 4294967295;
5109
5110       push @where,
5111         "cust_pkg.$field IS NOT NULL",
5112         "cust_pkg.$field >= $beginning",
5113         "cust_pkg.$field <= $ending";
5114
5115       $orderby ||= "ORDER BY cust_pkg.$field";
5116
5117       if ( $field eq 'setup' ) {
5118         $exclude_change_from = 1;
5119       } elsif ( $field eq 'cancel' ) {
5120         $exclude_change_to = 1;
5121       } elsif ( $field eq 'change_date' ) {
5122         # if we are given setup and change_date ranges, and the setup date
5123         # falls in _both_ ranges, then include the package whether it was
5124         # a change or not
5125         $exclude_change_from = 0;
5126       }
5127     }
5128
5129     if ($exclude_change_from) {
5130       push @where, "change_pkgnum IS NULL";
5131     }
5132     if ($exclude_change_to) {
5133       # a join might be more efficient here
5134       push @where, "NOT EXISTS(
5135         SELECT 1 FROM cust_pkg AS changed_to_pkg
5136         WHERE cust_pkg.pkgnum = changed_to_pkg.change_pkgnum
5137       )";
5138     }
5139   }
5140
5141   $orderby ||= 'ORDER BY bill';
5142
5143   ###
5144   # parse magic, legacy, etc.
5145   ###
5146
5147   if ( $params->{'magic'} &&
5148        $params->{'magic'} =~ /^(active|inactive|suspended|cancell?ed)$/
5149   ) {
5150
5151     $orderby = 'ORDER BY pkgnum';
5152
5153     if ( $params->{'pkgpart'} =~ /^(\d+)$/ ) {
5154       push @where, "pkgpart = $1";
5155     }
5156
5157   } elsif ( $params->{'query'} eq 'pkgnum' ) {
5158
5159     $orderby = 'ORDER BY pkgnum';
5160
5161   } elsif ( $params->{'query'} eq 'APKG_pkgnum' ) {
5162
5163     $orderby = 'ORDER BY pkgnum';
5164
5165     push @where, '0 < (
5166       SELECT count(*) FROM pkg_svc
5167        WHERE pkg_svc.pkgpart =  cust_pkg.pkgpart
5168          AND pkg_svc.quantity > ( SELECT count(*) FROM cust_svc
5169                                    WHERE cust_svc.pkgnum  = cust_pkg.pkgnum
5170                                      AND cust_svc.svcpart = pkg_svc.svcpart
5171                                 )
5172     )';
5173
5174   }
5175
5176   ##
5177   # parse the extremely weird 'towernum' param
5178   ##
5179
5180   if ($params->{towernum}) {
5181     my $towernum = $params->{towernum};
5182     $towernum = [ $towernum ] if !ref($towernum);
5183     my $in = join(',', grep /^\d+$/, @$towernum);
5184     if (length $in) {
5185       # inefficient, but this is an obscure feature
5186       eval "use FS::Report::Table";
5187       FS::Report::Table->_init_tower_pkg_cache; # probably does nothing
5188       push @where, "EXISTS(
5189       SELECT 1 FROM tower_pkg_cache
5190       WHERE tower_pkg_cache.pkgnum = cust_pkg.pkgnum
5191         AND tower_pkg_cache.towernum IN ($in)
5192       )"
5193     }
5194   }
5195
5196   ##
5197   # parse the 477 report drill-down options
5198   ##
5199
5200   if ($params->{'477part'} =~ /^([a-z]+)$/) {
5201     my $section = $1;
5202     my ($date, $rownum, $agentnum);
5203     if ($params->{'date'} =~ /^(\d+)$/) {
5204       $date = $1;
5205     }
5206     if ($params->{'477rownum'} =~ /^(\d+)$/) {
5207       $rownum = $1;
5208     }
5209     if ($params->{'agentnum'} =~ /^(\d+)$/) {
5210       $agentnum = $1;
5211     }
5212     if ($date and defined($rownum)) {
5213       my $report = FS::Report::FCC_477->report($section,
5214         'date'      => $date,
5215         'agentnum'  => $agentnum,
5216         'detail'    => 1
5217       );
5218       my $pkgnums = $report->{detail}->[$rownum]
5219         or die "row $rownum is past the end of the report";
5220         # '0' so that if there are no pkgnums (empty string) it will create
5221         # a valid query that returns nothing
5222       warn "PKGNUMS:\n$pkgnums\n\n"; # XXX debug
5223
5224       # and this overrides everything
5225       @where = ( "cust_pkg.pkgnum IN($pkgnums)" );
5226     } # else we're missing some params, ignore the whole business
5227   }
5228
5229   ##
5230   # setup queries, links, subs, etc. for the search
5231   ##
5232
5233   # here is the agent virtualization
5234   if ($params->{CurrentUser}) {
5235     my $access_user =
5236       qsearchs('access_user', { username => $params->{CurrentUser} });
5237
5238     if ($access_user) {
5239       push @where, $access_user->agentnums_sql('table'=>'cust_main');
5240     } else {
5241       push @where, "1=0";
5242     }
5243   } else {
5244     push @where, $FS::CurrentUser::CurrentUser->agentnums_sql('table'=>'cust_main');
5245   }
5246
5247   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
5248
5249   my $addl_from = 'LEFT JOIN part_pkg  USING ( pkgpart  ) '.
5250                   'LEFT JOIN pkg_class ON ( part_pkg.classnum = pkg_class.classnum ) '.
5251                   'LEFT JOIN cust_location USING ( locationnum ) '.
5252                   FS::UI::Web::join_cust_main('cust_pkg', 'cust_pkg');
5253
5254   my $select;
5255   my $count_query;
5256   if ( $params->{'select_zip5'} ) {
5257     my $zip = 'cust_location.zip';
5258
5259     $select = "DISTINCT substr($zip,1,5) as zip";
5260     $orderby = "ORDER BY substr($zip,1,5)";
5261     $count_query = "SELECT COUNT( DISTINCT substr($zip,1,5) )";
5262   } else {
5263     $select = join(', ',
5264                          'cust_pkg.*',
5265                          ( map "part_pkg.$_", qw( pkg freq ) ),
5266                          'pkg_class.classname',
5267                          'cust_main.custnum AS cust_main_custnum',
5268                          FS::UI::Web::cust_sql_fields(
5269                            $params->{'cust_fields'}
5270                          ),
5271                   );
5272     $count_query = 'SELECT COUNT(*)';
5273   }
5274
5275   $count_query .= " FROM cust_pkg $addl_from $extra_sql";
5276
5277   my $sql_query = {
5278     'table'       => 'cust_pkg',
5279     'hashref'     => {},
5280     'select'      => $select,
5281     'extra_sql'   => $extra_sql,
5282     'order_by'    => $orderby,
5283     'addl_from'   => $addl_from,
5284     'count_query' => $count_query,
5285   };
5286
5287 }
5288
5289 =item fcc_477_count
5290
5291 Returns a list of two package counts.  The first is a count of packages
5292 based on the supplied criteria and the second is the count of residential
5293 packages with those same criteria.  Criteria are specified as in the search
5294 method.
5295
5296 =cut
5297
5298 sub fcc_477_count {
5299   my ($class, $params) = @_;
5300
5301   my $sql_query = $class->search( $params );
5302
5303   my $count_sql = delete($sql_query->{'count_query'});
5304   $count_sql =~ s/ FROM/,count(CASE WHEN cust_main.company IS NULL OR cust_main.company = '' THEN 1 END) FROM/
5305     or die "couldn't parse count_sql";
5306
5307   my $count_sth = dbh->prepare($count_sql)
5308     or die "Error preparing $count_sql: ". dbh->errstr;
5309   $count_sth->execute
5310     or die "Error executing $count_sql: ". $count_sth->errstr;
5311   my $count_arrayref = $count_sth->fetchrow_arrayref;
5312
5313   return ( @$count_arrayref );
5314
5315 }
5316
5317 =item tax_locationnum_sql
5318
5319 Returns an SQL expression for the tax location for a package, based
5320 on the settings of 'tax-pkg_address' and 'tax-ship_address'.
5321
5322 =cut
5323
5324 sub tax_locationnum_sql {
5325   my $conf = FS::Conf->new;
5326   if ( $conf->exists('tax-pkg_address') ) {
5327     'cust_pkg.locationnum';
5328   }
5329   elsif ( $conf->exists('tax-ship_address') ) {
5330     'cust_main.ship_locationnum';
5331   }
5332   else {
5333     'cust_main.bill_locationnum';
5334   }
5335 }
5336
5337 =item location_sql
5338
5339 Returns a list: the first item is an SQL fragment identifying matching
5340 packages/customers via location (taking into account shipping and package
5341 address taxation, if enabled), and subsequent items are the parameters to
5342 substitute for the placeholders in that fragment.
5343
5344 =cut
5345
5346 sub location_sql {
5347   my($class, %opt) = @_;
5348   my $ornull = $opt{'ornull'};
5349
5350   my $conf = new FS::Conf;
5351
5352   # '?' placeholders in _location_sql_where
5353   my $x = $ornull ? 3 : 2;
5354   my @bill_param = (
5355     ('district')x3,
5356     ('city')x3,
5357     ('county')x$x,
5358     ('state')x$x,
5359     'country'
5360   );
5361
5362   my $main_where;
5363   my @main_param;
5364   if ( $conf->exists('tax-ship_address') ) {
5365
5366     $main_where = "(
5367          (     ( ship_last IS NULL     OR  ship_last  = '' )
5368            AND ". _location_sql_where('cust_main', '', $ornull ). "
5369          )
5370       OR (       ship_last IS NOT NULL AND ship_last != ''
5371            AND ". _location_sql_where('cust_main', 'ship_', $ornull ). "
5372          )
5373     )";
5374     #    AND payby != 'COMP'
5375
5376     @main_param = ( @bill_param, @bill_param );
5377
5378   } else {
5379
5380     $main_where = _location_sql_where('cust_main'); # AND payby != 'COMP'
5381     @main_param = @bill_param;
5382
5383   }
5384
5385   my $where;
5386   my @param;
5387   if ( $conf->exists('tax-pkg_address') ) {
5388
5389     my $loc_where = _location_sql_where( 'cust_location', '', $ornull );
5390
5391     $where = " (
5392                     ( cust_pkg.locationnum IS     NULL AND $main_where )
5393                  OR ( cust_pkg.locationnum IS NOT NULL AND $loc_where  )
5394                )
5395              ";
5396     @param = ( @main_param, @bill_param );
5397
5398   } else {
5399
5400     $where = $main_where;
5401     @param = @main_param;
5402
5403   }
5404
5405   ( $where, @param );
5406
5407 }
5408
5409 #subroutine, helper for location_sql
5410 sub _location_sql_where {
5411   my $table  = shift;
5412   my $prefix = @_ ? shift : '';
5413   my $ornull = @_ ? shift : '';
5414
5415 #  $ornull             = $ornull          ? " OR ( ? IS NULL AND $table.${prefix}county IS NULL ) " : '';
5416
5417   $ornull = $ornull ? ' OR ? IS NULL ' : '';
5418
5419   my $or_empty_city     = " OR ( ? = '' AND $table.${prefix}city     IS NULL )";
5420   my $or_empty_county   = " OR ( ? = '' AND $table.${prefix}county   IS NULL )";
5421   my $or_empty_state    = " OR ( ? = '' AND $table.${prefix}state    IS NULL )";
5422
5423   my $text = (driver_name =~ /^mysql/i) ? 'char' : 'text';
5424
5425 #        ( $table.${prefix}city    = ? $or_empty_city   $ornull )
5426   "
5427         ( $table.district = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5428     AND ( $table.${prefix}city     = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5429     AND ( $table.${prefix}county   = ? $or_empty_county $ornull )
5430     AND ( $table.${prefix}state    = ? $or_empty_state  $ornull )
5431     AND   $table.${prefix}country  = ?
5432   ";
5433 }
5434
5435 sub _X_show_zero {
5436   my( $self, $what ) = @_;
5437
5438   my $what_show_zero = $what. '_show_zero';
5439   length($self->$what_show_zero())
5440     ? ($self->$what_show_zero() eq 'Y')
5441     : $self->part_pkg->$what_show_zero();
5442 }
5443
5444 =head1 SUBROUTINES
5445
5446 =over 4
5447
5448 =item order CUSTNUM, PKGPARTS_ARYREF, [ REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF [ REFNUM ] ] ]
5449
5450 Bulk cancel + order subroutine.  Perhaps slightly deprecated, only used by the
5451 bulk cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
5452
5453 CUSTNUM is a customer (see L<FS::cust_main>)
5454
5455 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5456 L<FS::part_pkg>) to order for this customer.  Duplicates are of course
5457 permitted.
5458
5459 REMOVE_PKGNUMS is an optional list of pkgnums specifying the billing items to
5460 remove for this customer.  The services (see L<FS::cust_svc>) are moved to the
5461 new billing items.  An error is returned if this is not possible (see
5462 L<FS::pkg_svc>).  An empty arrayref is equivalent to not specifying this
5463 parameter.
5464
5465 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5466 newly-created cust_pkg objects.
5467
5468 REFNUM, if specified, will specify the FS::pkg_referral record to be created
5469 and inserted.  Multiple FS::pkg_referral records can be created by
5470 setting I<refnum> to an array reference of refnums or a hash reference with
5471 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
5472 record will be created corresponding to cust_main.refnum.
5473
5474 =cut
5475
5476 sub order {
5477   my ($custnum, $pkgparts, $remove_pkgnum, $return_cust_pkg, $refnum) = @_;
5478
5479   my $conf = new FS::Conf;
5480
5481   # Transactionize this whole mess
5482   local $SIG{HUP} = 'IGNORE';
5483   local $SIG{INT} = 'IGNORE';
5484   local $SIG{QUIT} = 'IGNORE';
5485   local $SIG{TERM} = 'IGNORE';
5486   local $SIG{TSTP} = 'IGNORE';
5487   local $SIG{PIPE} = 'IGNORE';
5488
5489   my $oldAutoCommit = $FS::UID::AutoCommit;
5490   local $FS::UID::AutoCommit = 0;
5491   my $dbh = dbh;
5492
5493   my $error;
5494 #  my $cust_main = qsearchs('cust_main', { custnum => $custnum });
5495 #  return "Customer not found: $custnum" unless $cust_main;
5496
5497   warn "$me order: pkgnums to remove: ". join(',', @$remove_pkgnum). "\n"
5498     if $DEBUG;
5499
5500   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5501                          @$remove_pkgnum;
5502
5503   my $change = scalar(@old_cust_pkg) != 0;
5504
5505   my %hash = ();
5506   if ( scalar(@old_cust_pkg) == 1 && scalar(@$pkgparts) == 1 ) {
5507
5508     warn "$me order: changing pkgnum ". $old_cust_pkg[0]->pkgnum.
5509          " to pkgpart ". $pkgparts->[0]. "\n"
5510       if $DEBUG;
5511
5512     my $err_or_cust_pkg =
5513       $old_cust_pkg[0]->change( 'pkgpart' => $pkgparts->[0],
5514                                 'refnum'  => $refnum,
5515                               );
5516
5517     unless (ref($err_or_cust_pkg)) {
5518       $dbh->rollback if $oldAutoCommit;
5519       return $err_or_cust_pkg;
5520     }
5521
5522     push @$return_cust_pkg, $err_or_cust_pkg;
5523     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5524     return '';
5525
5526   }
5527
5528   # Create the new packages.
5529   foreach my $pkgpart (@$pkgparts) {
5530
5531     warn "$me order: inserting pkgpart $pkgpart\n" if $DEBUG;
5532
5533     my $cust_pkg = new FS::cust_pkg { custnum => $custnum,
5534                                       pkgpart => $pkgpart,
5535                                       refnum  => $refnum,
5536                                       %hash,
5537                                     };
5538     $error = $cust_pkg->insert( 'change' => $change );
5539     push @$return_cust_pkg, $cust_pkg;
5540
5541     foreach my $link ($cust_pkg->part_pkg->supp_part_pkg_link) {
5542       my $supp_pkg = FS::cust_pkg->new({
5543           custnum => $custnum,
5544           pkgpart => $link->dst_pkgpart,
5545           refnum  => $refnum,
5546           main_pkgnum => $cust_pkg->pkgnum,
5547           %hash,
5548       });
5549       $error ||= $supp_pkg->insert( 'change' => $change );
5550       push @$return_cust_pkg, $supp_pkg;
5551     }
5552
5553     if ($error) {
5554       $dbh->rollback if $oldAutoCommit;
5555       return $error;
5556     }
5557
5558   }
5559   # $return_cust_pkg now contains refs to all of the newly
5560   # created packages.
5561
5562   # Transfer services and cancel old packages.
5563   foreach my $old_pkg (@old_cust_pkg) {
5564
5565     warn "$me order: transferring services from pkgnum ". $old_pkg->pkgnum. "\n"
5566       if $DEBUG;
5567
5568     foreach my $new_pkg (@$return_cust_pkg) {
5569       $error = $old_pkg->transfer($new_pkg);
5570       if ($error and $error == 0) {
5571         # $old_pkg->transfer failed.
5572         $dbh->rollback if $oldAutoCommit;
5573         return $error;
5574       }
5575     }
5576
5577     if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
5578       warn "trying transfer again with change_svcpart option\n" if $DEBUG;
5579       foreach my $new_pkg (@$return_cust_pkg) {
5580         $error = $old_pkg->transfer($new_pkg, 'change_svcpart'=>1 );
5581         if ($error and $error == 0) {
5582           # $old_pkg->transfer failed.
5583         $dbh->rollback if $oldAutoCommit;
5584         return $error;
5585         }
5586       }
5587     }
5588
5589     if ($error > 0) {
5590       # Transfers were successful, but we went through all of the
5591       # new packages and still had services left on the old package.
5592       # We can't cancel the package under the circumstances, so abort.
5593       $dbh->rollback if $oldAutoCommit;
5594       return "Unable to transfer all services from package ".$old_pkg->pkgnum;
5595     }
5596     $error = $old_pkg->cancel( quiet=>1, 'no_delay_cancel'=>1 );
5597     if ($error) {
5598       $dbh->rollback;
5599       return $error;
5600     }
5601   }
5602   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5603   '';
5604 }
5605
5606 =item bulk_change PKGPARTS_ARYREF, REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF ]
5607
5608 A bulk change method to change packages for multiple customers.
5609
5610 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5611 L<FS::part_pkg>) to order for each customer.  Duplicates are of course
5612 permitted.
5613
5614 REMOVE_PKGNUMS is an list of pkgnums specifying the billing items to
5615 replace.  The services (see L<FS::cust_svc>) are moved to the
5616 new billing items.  An error is returned if this is not possible (see
5617 L<FS::pkg_svc>).
5618
5619 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5620 newly-created cust_pkg objects.
5621
5622 =cut
5623
5624 sub bulk_change {
5625   my ($pkgparts, $remove_pkgnum, $return_cust_pkg) = @_;
5626
5627   # Transactionize this whole mess
5628   local $SIG{HUP} = 'IGNORE';
5629   local $SIG{INT} = 'IGNORE';
5630   local $SIG{QUIT} = 'IGNORE';
5631   local $SIG{TERM} = 'IGNORE';
5632   local $SIG{TSTP} = 'IGNORE';
5633   local $SIG{PIPE} = 'IGNORE';
5634
5635   my $oldAutoCommit = $FS::UID::AutoCommit;
5636   local $FS::UID::AutoCommit = 0;
5637   my $dbh = dbh;
5638
5639   my @errors;
5640   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5641                          @$remove_pkgnum;
5642
5643   while(scalar(@old_cust_pkg)) {
5644     my @return = ();
5645     my $custnum = $old_cust_pkg[0]->custnum;
5646     my (@remove) = map { $_->pkgnum }
5647                    grep { $_->custnum == $custnum } @old_cust_pkg;
5648     @old_cust_pkg = grep { $_->custnum != $custnum } @old_cust_pkg;
5649
5650     my $error = order $custnum, $pkgparts, \@remove, \@return;
5651
5652     push @errors, $error
5653       if $error;
5654     push @$return_cust_pkg, @return;
5655   }
5656
5657   if (scalar(@errors)) {
5658     $dbh->rollback if $oldAutoCommit;
5659     return join(' / ', @errors);
5660   }
5661
5662   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5663   '';
5664 }
5665
5666 # Used by FS::Upgrade to migrate to a new database.
5667 sub _upgrade_data {  # class method
5668   my ($class, %opts) = @_;
5669   $class->_upgrade_otaker(%opts);
5670   my @statements = (
5671     # RT#10139, bug resulting in contract_end being set when it shouldn't
5672   'UPDATE cust_pkg SET contract_end = NULL WHERE contract_end = -1',
5673     # RT#10830, bad calculation of prorate date near end of year
5674     # the date range for bill is December 2009, and we move it forward
5675     # one year if it's before the previous bill date (which it should
5676     # never be)
5677   'UPDATE cust_pkg SET bill = bill + (365*24*60*60) WHERE bill < last_bill
5678   AND bill > 1259654400 AND bill < 1262332800 AND (SELECT plan FROM part_pkg
5679   WHERE part_pkg.pkgpart = cust_pkg.pkgpart) = \'prorate\'',
5680     # RT6628, add order_date to cust_pkg
5681     'update cust_pkg set order_date = (select history_date from h_cust_pkg
5682         where h_cust_pkg.pkgnum = cust_pkg.pkgnum and
5683         history_action = \'insert\') where order_date is null',
5684   );
5685   foreach my $sql (@statements) {
5686     my $sth = dbh->prepare($sql);
5687     $sth->execute or die $sth->errstr;
5688   }
5689
5690   # RT31194: supplemental package links that are deleted don't clean up
5691   # linked records
5692   my @pkglinknums = qsearch({
5693       'select'    => 'DISTINCT cust_pkg.pkglinknum',
5694       'table'     => 'cust_pkg',
5695       'addl_from' => ' LEFT JOIN part_pkg_link USING (pkglinknum) ',
5696       'extra_sql' => ' WHERE cust_pkg.pkglinknum IS NOT NULL
5697                         AND part_pkg_link.pkglinknum IS NULL',
5698   });
5699   foreach (@pkglinknums) {
5700     my $pkglinknum = $_->pkglinknum;
5701     warn "cleaning part_pkg_link #$pkglinknum\n";
5702     my $part_pkg_link = FS::part_pkg_link->new({pkglinknum => $pkglinknum});
5703     my $error = $part_pkg_link->remove_linked;
5704     die $error if $error;
5705   }
5706 }
5707
5708 =back
5709
5710 =head1 BUGS
5711
5712 sub order is not OO.  Perhaps it should be moved to FS::cust_main and made so?
5713
5714 In sub order, the @pkgparts array (passed by reference) is clobbered.
5715
5716 Also in sub order, no money is adjusted.  Once FS::part_pkg defines a standard
5717 method to pass dates to the recur_prog expression, it should do so.
5718
5719 FS::svc_acct, FS::svc_domain, FS::svc_www, FS::svc_ip and FS::svc_forward are
5720 loaded via 'use' at compile time, rather than via 'require' in sub { setup,
5721 suspend, unsuspend, cancel } because they use %FS::UID::callback to load
5722 configuration values.  Probably need a subroutine which decides what to do
5723 based on whether or not we've fetched the user yet, rather than a hash.  See
5724 FS::UID and the TODO.
5725
5726 Now that things are transactional should the check in the insert method be
5727 moved to check ?
5728
5729 =head1 SEE ALSO
5730
5731 L<FS::Record>, L<FS::cust_main>, L<FS::part_pkg>, L<FS::cust_svc>,
5732 L<FS::pkg_svc>, schema.html from the base documentation
5733
5734 =cut
5735
5736 1;
5737