FS/FS/cust_main_county.pm

   1 package FS::cust_main_county;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $conf
   5              @cust_main_county %cust_main_county $countyflag ); # $cityflag );
   6 use Exporter;
   7 use FS::Record qw( qsearch qsearchs dbh );
   8 use FS::cust_bill_pkg;
   9 use FS::cust_bill;
  10 use FS::cust_pkg;
  11 use FS::part_pkg;
  12 use FS::cust_tax_exempt;
  13 use FS::cust_tax_exempt_pkg;
  14
  15 @ISA = qw( FS::Record );
  16 @EXPORT_OK = qw( regionselector );
  17
  18 @cust_main_county = ();
  19 $countyflag = '';
  20 #$cityflag = '';
  21
  22 #ask FS::UID to run this stuff for us later
  23 $FS::UID::callback{'FS::cust_main_county'} = sub {
  24   $conf = new FS::Conf;
  25 };
  26
  27 =head1 NAME
  28
  29 FS::cust_main_county - Object methods for cust_main_county objects
  30
  31 =head1 SYNOPSIS
  32
  33   use FS::cust_main_county;
  34
  35   $record = new FS::cust_main_county \%hash;
  36   $record = new FS::cust_main_county { 'column' => 'value' };
  37
  38   $error = $record->insert;
  39
  40   $error = $new_record->replace($old_record);
  41
  42   $error = $record->delete;
  43
  44   $error = $record->check;
  45
  46   ($county_html, $state_html, $country_html) =
  47     FS::cust_main_county::regionselector( $county, $state, $country );
  48
  49 =head1 DESCRIPTION
  50
  51 An FS::cust_main_county object represents a tax rate, defined by locale.
  52 FS::cust_main_county inherits from FS::Record.  The following fields are
  53 currently supported:
  54
  55 =over 4
  56
  57 =item taxnum - primary key (assigned automatically for new tax rates)
  58
  59 =item district - tax district (optional)
  60
  61 =item city
  62
  63 =item county
  64
  65 =item state
  66
  67 =item country
  68
  69 =item tax - percentage
  70
  71 =item taxclass
  72
  73 =item exempt_amount
  74
  75 =item taxname - if defined, printed on invoices instead of "Tax"
  76
  77 =item setuptax - if 'Y', this tax does not apply to setup fees
  78
  79 =item recurtax - if 'Y', this tax does not apply to recurring fees
  80
  81 =back
  82
  83 =head1 METHODS
  84
  85 =over 4
  86
  87 =item new HASHREF
  88
  89 Creates a new tax rate.  To add the tax rate to the database, see L<"insert">.
  90
  91 =cut
  92
  93 sub table { 'cust_main_county'; }
  94
  95 =item insert
  96
  97 Adds this tax rate to the database.  If there is an error, returns the error,
  98 otherwise returns false.
  99
 100 =item delete
 101
 102 Deletes this tax rate from the database.  If there is an error, returns the
 103 error, otherwise returns false.
 104
 105 =item replace OLD_RECORD
 106
 107 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 108 returns the error, otherwise returns false.
 109
 110 =item check
 111
 112 Checks all fields to make sure this is a valid tax rate.  If there is an error,
 113 returns the error, otherwise returns false.  Called by the insert and replace
 114 methods.
 115
 116 =cut
 117
 118 sub check {
 119   my $self = shift;
 120
 121   $self->exempt_amount(0) unless $self->exempt_amount;
 122
 123   $self->ut_numbern('taxnum')
 124     || $self->ut_alphan('district')
 125     || $self->ut_textn('city')
 126     || $self->ut_textn('county')
 127     || $self->ut_anything('state')
 128     || $self->ut_text('country')
 129     || $self->ut_float('tax')
 130     || $self->ut_textn('taxclass') # ...
 131     || $self->ut_money('exempt_amount')
 132     || $self->ut_textn('taxname')
 133     || $self->ut_enum('setuptax', [ '', 'Y' ] )
 134     || $self->ut_enum('recurtax', [ '', 'Y' ] )
 135     || $self->SUPER::check
 136     ;
 137
 138 }
 139
 140 =item label OPTIONS
 141
 142 Returns a label looking like "Anytown, Alameda County, CA, US".
 143
 144 If the taxname field is set, it will look like
 145 "CA Sales Tax (Anytown, Alameda County, CA, US)".
 146
 147 If the taxclass is set, then it will be
 148 "Anytown, Alameda County, CA, US (International)".
 149
 150 OPTIONS may contain "with_taxclass", "with_city", and "with_district" to show
 151 those fields.  It may also contain "out", in which case, if this region
 152 (district+city+county+state+country) contains no non-zero taxes, the label
 153 will read "Out of taxable region(s)".
 154
 155 =cut
 156
 157 sub label {
 158   my ($self, %opt) = @_;
 159   if ( $opt{'out'}
 160        and $self->tax == 0
 161        and !defined(qsearchs('cust_main_county', {
 162            'district' => $self->district,
 163            'city'     => $self->city,
 164            'county'   => $self->county,
 165            'state'    => $self->state,
 166            'country'  => $self->country,
 167            'tax'  => { op => '>', value => 0 },
 168         })) )
 169   {
 170     return 'Out of taxable region(s)';
 171   }
 172   my $label = $self->country;
 173   $label = $self->state.", $label" if $self->state;
 174   $label = $self->county." County, $label" if $self->county;
 175   if ($opt{with_city}) {
 176     $label = $self->city.", $label" if $self->city;
 177     if ($opt{with_district} and $self->district) {
 178       $label = $self->district . ", $label";
 179     }
 180   }
 181   # ugly labels when taxclass and taxname are both non-null...
 182   # but this is how the tax report does it
 183   if ($opt{with_taxclass}) {
 184     $label = "$label (".$self->taxclass.')' if $self->taxclass;
 185   }
 186   $label = $self->taxname." ($label)" if $self->taxname;
 187
 188   $label;
 189 }
 190
 191 =item sql_taxclass_sameregion
 192
 193 Returns an SQL WHERE fragment or the empty string to search for entries
 194 with different tax classes.
 195
 196 =cut
 197
 198 #hmm, description above could be better...
 199
 200 sub sql_taxclass_sameregion {
 201   my $self = shift;
 202
 203   my $same_query = 'SELECT DISTINCT taxclass FROM cust_main_county '.
 204                    ' WHERE taxnum != ? AND country = ?';
 205   my @same_param = ( 'taxnum', 'country' );
 206   foreach my $opt_field (qw( state county )) {
 207     if ( $self->$opt_field() ) {
 208       $same_query .= " AND $opt_field = ?";
 209       push @same_param, $opt_field;
 210     } else {
 211       $same_query .= " AND $opt_field IS NULL";
 212     }
 213   }
 214
 215   my @taxclasses = $self->_list_sql( \@same_param, $same_query );
 216
 217   return '' unless scalar(@taxclasses);
 218
 219   '( taxclass IS NULL OR ( '.  #only if !$self->taxclass ??
 220      join(' AND ', map { 'taxclass != '.dbh->quote($_) } @taxclasses ).
 221   ' ) ) ';
 222 }
 223
 224 sub _list_sql {
 225   my( $self, $param, $sql ) = @_;
 226   my $sth = dbh->prepare($sql) or die dbh->errstr;
 227   $sth->execute( map $self->$_(), @$param )
 228     or die "Unexpected error executing statement $sql: ". $sth->errstr;
 229   map $_->[0], @{ $sth->fetchall_arrayref };
 230 }
 231
 232 =item taxline TAXABLES_ARRAYREF, [ OPTION => VALUE ... ]
 233
 234 Takes an arrayref of L<FS::cust_bill_pkg> objects representing taxable
 235 line items, and returns a new L<FS::cust_bill_pkg> object representing
 236 the tax on them under this tax rate.
 237
 238 This will have a pseudo-field, "cust_bill_pkg_tax_location", containing
 239 an arrayref of L<FS::cust_bill_pkg_tax_location> objects.  Each of these
 240 will in turn have a "taxable_cust_bill_pkg" pseudo-field linking it to one
 241 of the taxable items.  All of these links must be resolved as the objects
 242 are inserted.
 243
 244 Options may include 'custnum' and 'invoice_time' in case the cust_bill_pkg
 245 objects belong to an invoice that hasn't been inserted yet.
 246
 247 Options may include 'exemptions', an arrayref of L<FS::cust_tax_exempt_pkg>
 248 objects belonging to the same customer, to be counted against the monthly
 249 tax exemption limit if there is one.
 250
 251 =cut
 252
 253 # XXX change tax_rate.pm to work like this
 254
 255 sub taxline {
 256   my( $self, $taxables, %opt ) = @_;
 257   $taxables = [ $taxables ] unless ref($taxables) eq 'ARRAY';
 258   # remove any charge class identifiers; they're not supported here
 259   @$taxables = grep { ref $_ } @$taxables;
 260
 261   return 'taxline called with no line items' unless @$taxables;
 262
 263   local $SIG{HUP} = 'IGNORE';
 264   local $SIG{INT} = 'IGNORE';
 265   local $SIG{QUIT} = 'IGNORE';
 266   local $SIG{TERM} = 'IGNORE';
 267   local $SIG{TSTP} = 'IGNORE';
 268   local $SIG{PIPE} = 'IGNORE';
 269
 270   my $oldAutoCommit = $FS::UID::AutoCommit;
 271   local $FS::UID::AutoCommit = 0;
 272   my $dbh = dbh;
 273
 274   my $name = $self->taxname || 'Tax';
 275   my $taxable_cents = 0;
 276   my $tax_cents = 0;
 277
 278   my $cust_bill = $taxables->[0]->cust_bill;
 279   my $custnum   = $cust_bill ? $cust_bill->custnum : $opt{'custnum'};
 280   my $invoice_time = $cust_bill ? $cust_bill->_date : $opt{'invoice_time'};
 281   my $cust_main = FS::cust_main->by_key($custnum) if $custnum > 0;
 282   if (!$cust_main) {
 283     # better way to handle this?  should we just assume that it's taxable?
 284     die "unable to calculate taxes for an unknown customer\n";
 285   }
 286
 287   # Gather any exemptions that are already attached to these cust_bill_pkgs
 288   # so that we can deduct them from the customer's monthly limit.
 289   my @existing_exemptions = @{ $opt{'exemptions'} };
 290   push @existing_exemptions, @{ $_->cust_tax_exempt_pkg }
 291     for @$taxables;
 292
 293   my $tax_item = FS::cust_bill_pkg->new({
 294       'pkgnum'    => 0,
 295       'recur'     => 0,
 296       'sdate'     => '',
 297       'edate'     => '',
 298       'itemdesc'  => $name,
 299   });
 300   my @tax_location;
 301
 302   foreach my $cust_bill_pkg (@$taxables) {
 303
 304     my $taxable_charged = $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 305     foreach ( grep { $_->taxnum == $self->taxnum }
 306               @{ $cust_bill_pkg->cust_tax_exempt_pkg }
 307     ) {
 308       # deal with exemptions that have been set on this line item, and
 309       # pertain to this tax def
 310       $taxable_charged -= $_->amount;
 311     }
 312
 313     my $locationnum = $cust_bill_pkg->tax_locationnum;
 314
 315     ### Monthly capped exemptions ###
 316     if ( $self->exempt_amount && $self->exempt_amount > 0
 317       and $taxable_charged > 0 ) {
 318       # If the billing period extends across multiple calendar months,
 319       # there may be several months of exemption available.
 320       my $sdate = $cust_bill_pkg->sdate || $invoice_time;
 321       my $start_month = (localtime($sdate))[4] + 1;
 322       my $start_year  = (localtime($sdate))[5] + 1900;
 323       my $edate = $cust_bill_pkg->edate || $invoice_time;
 324       my $end_month   = (localtime($edate))[4] + 1;
 325       my $end_year    = (localtime($edate))[5] + 1900;
 326
 327       # If the partial last month + partial first month <= one month,
 328       # don't use the exemption in the last month
 329       # (unless the last month is also the first month, e.g. one-time
 330       # charges)
 331       if ( (localtime($sdate))[3] >= (localtime($edate))[3]
 332            and ($start_month != $end_month or $start_year != $end_year)
 333       ) {
 334         $end_month--;
 335         if ( $end_month == 0 ) {
 336           $end_year--;
 337           $end_month = 12;
 338         }
 339       }
 340
 341       # number of months of exemption available
 342       my $freq = ($end_month - $start_month) +
 343                  ($end_year  - $start_year) * 12 +
 344                  1;
 345
 346       # divide equally among all of them
 347       my $permonth = sprintf('%.2f', $taxable_charged / $freq);
 348
 349       #call the whole thing off if this customer has any old
 350       #exemption records...
 351       my @cust_tax_exempt =
 352         qsearch( 'cust_tax_exempt' => { custnum=> $custnum } );
 353       if ( @cust_tax_exempt ) {
 354         $dbh->rollback if $oldAutoCommit;
 355         return
 356           'this customer still has old-style tax exemption records; '.
 357           'run bin/fs-migrate-cust_tax_exempt?';
 358       }
 359
 360       my ($mon, $year) = ($start_month, $start_year);
 361       while ($taxable_charged > 0.005 and
 362              ($year < $end_year or
 363                ($year == $end_year and $mon <= $end_month)
 364              )
 365       ) {
 366
 367         # find the sum of the exemption used by this customer, for this tax,
 368         # in this month
 369         my $sql = "
 370           SELECT SUM(amount)
 371             FROM cust_tax_exempt_pkg
 372               LEFT JOIN cust_bill_pkg USING ( billpkgnum )
 373               LEFT JOIN cust_bill     USING ( invnum     )
 374             WHERE custnum = ?
 375               AND taxnum  = ?
 376               AND year    = ?
 377               AND month   = ?
 378               AND exempt_monthly = 'Y'
 379         ";
 380         my $sth = dbh->prepare($sql) or do {
 381           $dbh->rollback if $oldAutoCommit;
 382           return "fatal: can't lookup existing exemption: ". dbh->errstr;
 383         };
 384         $sth->execute(
 385           $custnum,
 386           $self->taxnum,
 387           $year,
 388           $mon,
 389         ) or do {
 390           $dbh->rollback if $oldAutoCommit;
 391           return "fatal: can't lookup existing exemption: ". dbh->errstr;
 392         };
 393         my $existing_exemption = $sth->fetchrow_arrayref->[0] || 0;
 394
 395         # add any exemption we're already using for another line item
 396         foreach ( grep { $_->taxnum == $self->taxnum &&
 397                          $_->exempt_monthly eq 'Y'   &&
 398                          $_->month  == $mon          &&
 399                          $_->year   == $year
 400                        } @existing_exemptions
 401                 )
 402         {
 403           $existing_exemption += $_->amount;
 404         }
 405
 406         my $remaining_exemption =
 407           $self->exempt_amount - $existing_exemption;
 408         if ( $remaining_exemption > 0 ) {
 409           my $addl = $remaining_exemption > $permonth
 410             ? $permonth
 411             : $remaining_exemption;
 412           $addl = $taxable_charged if $addl > $taxable_charged;
 413
 414           my $new_exemption =
 415             FS::cust_tax_exempt_pkg->new({
 416               amount          => sprintf('%.2f', $addl),
 417               exempt_monthly  => 'Y',
 418               year            => $year,
 419               month           => $mon,
 420               taxnum          => $self->taxnum,
 421               taxtype         => ref($self)
 422             });
 423           $taxable_charged -= $addl;
 424
 425           # create a record of it
 426           push @{ $cust_bill_pkg->cust_tax_exempt_pkg }, $new_exemption;
 427           # and allow it to be counted against the limit for other packages
 428           push @existing_exemptions, $new_exemption;
 429         }
 430         # if they're using multiple months of exemption for a multi-month
 431         # package, then record the exemptions in separate months
 432         $mon++;
 433         if ( $mon > 12 ) {
 434           $mon -= 12;
 435           $year++;
 436         }
 437
 438       }
 439     } # if exempt_amount
 440
 441     $taxable_charged = sprintf( "%.2f", $taxable_charged);
 442     next if $taxable_charged == 0;
 443
 444     my $this_tax_cents = int($taxable_charged * $self->tax);
 445     my $location = FS::cust_bill_pkg_tax_location->new({
 446         'taxnum'      => $self->taxnum,
 447         'taxtype'     => ref($self),
 448         'cents'       => $this_tax_cents,
 449         'pkgnum'      => $cust_bill_pkg->pkgnum,
 450         'locationnum' => $locationnum,
 451         'taxable_cust_bill_pkg' => $cust_bill_pkg,
 452         'tax_cust_bill_pkg'     => $tax_item,
 453     });
 454     push @tax_location, $location;
 455
 456     $taxable_cents += $taxable_charged;
 457     $tax_cents += $this_tax_cents;
 458   } #foreach $cust_bill_pkg
 459
 460   # now round and distribute
 461   my $extra_cents = sprintf('%.2f', $taxable_cents * $self->tax / 100) * 100
 462                     - $tax_cents;
 463   # make sure we have an integer
 464   $extra_cents = sprintf('%.0f', $extra_cents);
 465   if ( $extra_cents < 0 ) {
 466     die "nonsense extra_cents value $extra_cents";
 467   }
 468   $tax_cents += $extra_cents;
 469   my $i = 0;
 470   foreach (@tax_location) { # can never require more than a single pass, yes?
 471     my $cents = $_->get('cents');
 472     if ( $extra_cents > 0 ) {
 473       $cents++;
 474       $extra_cents--;
 475     }
 476     $_->set('amount', sprintf('%.2f', $cents/100));
 477   }
 478   $tax_item->set('setup' => sprintf('%.2f', $tax_cents / 100));
 479   $tax_item->set('cust_bill_pkg_tax_location', \@tax_location);
 480
 481   return $tax_item;
 482 }
 483
 484 =back
 485
 486 =head1 SUBROUTINES
 487
 488 =over 4
 489
 490 =item regionselector [ COUNTY STATE COUNTRY [ PREFIX [ ONCHANGE [ DISABLED ] ] ] ]
 491
 492 =cut
 493
 494 sub regionselector {
 495   my ( $selected_county, $selected_state, $selected_country,
 496        $prefix, $onchange, $disabled ) = @_;
 497
 498   $prefix = '' unless defined $prefix;
 499
 500   $countyflag = 0;
 501
 502 #  unless ( @cust_main_county ) { #cache
 503     @cust_main_county = qsearch('cust_main_county', {} );
 504     foreach my $c ( @cust_main_county ) {
 505       $countyflag=1 if $c->county;
 506       #push @{$cust_main_county{$c->country}{$c->state}}, $c->county;
 507       $cust_main_county{$c->country}{$c->state}{$c->county} = 1;
 508     }
 509 #  }
 510   $countyflag=1 if $selected_county;
 511
 512   my $script_html = <<END;
 513     <SCRIPT>
 514     function opt(what,value,text) {
 515       var optionName = new Option(text, value, false, false);
 516       var length = what.length;
 517       what.options[length] = optionName;
 518     }
 519     function ${prefix}country_changed(what) {
 520       country = what.options[what.selectedIndex].text;
 521       for ( var i = what.form.${prefix}state.length; i >= 0; i-- )
 522           what.form.${prefix}state.options[i] = null;
 523 END
 524       #what.form.${prefix}state.options[0] = new Option('', '', false, true);
 525
 526   foreach my $country ( sort keys %cust_main_county ) {
 527     $script_html .= "\nif ( country == \"$country\" ) {\n";
 528     foreach my $state ( sort keys %{$cust_main_county{$country}} ) {
 529       ( my $dstate = $state ) =~ s/[\n\r]//g;
 530       my $text = $dstate || '(n/a)';
 531       $script_html .= qq!opt(what.form.${prefix}state, "$dstate", "$text");\n!;
 532     }
 533     $script_html .= "}\n";
 534   }
 535
 536   $script_html .= <<END;
 537     }
 538     function ${prefix}state_changed(what) {
 539 END
 540
 541   if ( $countyflag ) {
 542     $script_html .= <<END;
 543       state = what.options[what.selectedIndex].text;
 544       country = what.form.${prefix}country.options[what.form.${prefix}country.selectedIndex].text;
 545       for ( var i = what.form.${prefix}county.length; i >= 0; i-- )
 546           what.form.${prefix}county.options[i] = null;
 547 END
 548
 549     foreach my $country ( sort keys %cust_main_county ) {
 550       $script_html .= "\nif ( country == \"$country\" ) {\n";
 551       foreach my $state ( sort keys %{$cust_main_county{$country}} ) {
 552         $script_html .= "\nif ( state == \"$state\" ) {\n";
 553           #foreach my $county ( sort @{$cust_main_county{$country}{$state}} ) {
 554           foreach my $county ( sort keys %{$cust_main_county{$country}{$state}} ) {
 555             my $text = $county || '(n/a)';
 556             $script_html .=
 557               qq!opt(what.form.${prefix}county, "$county", "$text");\n!;
 558           }
 559         $script_html .= "}\n";
 560       }
 561       $script_html .= "}\n";
 562     }
 563   }
 564
 565   $script_html .= <<END;
 566     }
 567     </SCRIPT>
 568 END
 569
 570   my $county_html = $script_html;
 571   if ( $countyflag ) {
 572     $county_html .= qq!<SELECT NAME="${prefix}county" onChange="$onchange" $disabled>!;
 573     $county_html .= '</SELECT>';
 574   } else {
 575     $county_html .=
 576       qq!<INPUT TYPE="hidden" NAME="${prefix}county" VALUE="$selected_county">!;
 577   }
 578
 579   my $state_html = qq!<SELECT NAME="${prefix}state" !.
 580                    qq!onChange="${prefix}state_changed(this); $onchange" $disabled>!;
 581   foreach my $state ( sort keys %{ $cust_main_county{$selected_country} } ) {
 582     my $text = $state || '(n/a)';
 583     my $selected = $state eq $selected_state ? 'SELECTED' : '';
 584     $state_html .= qq(\n<OPTION $selected VALUE="$state">$text</OPTION>);
 585   }
 586   $state_html .= '</SELECT>';
 587
 588   $state_html .= '</SELECT>';
 589
 590   my $country_html = qq!<SELECT NAME="${prefix}country" !.
 591                      qq!onChange="${prefix}country_changed(this); $onchange" $disabled>!;
 592   my $countrydefault = $conf->config('countrydefault') || 'US';
 593   foreach my $country (
 594     sort { ($b eq $countrydefault) <=> ($a eq $countrydefault) or $a cmp $b }
 595       keys %cust_main_county
 596   ) {
 597     my $selected = $country eq $selected_country ? ' SELECTED' : '';
 598     $country_html .= qq(\n<OPTION$selected VALUE="$country">$country</OPTION>");
 599   }
 600   $country_html .= '</SELECT>';
 601
 602   ($county_html, $state_html, $country_html);
 603
 604 }
 605
 606 =back
 607
 608 =head1 BUGS
 609
 610 regionselector?  putting web ui components in here?  they should probably live
 611 somewhere else...
 612
 613 =head1 SEE ALSO
 614
 615 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill>, schema.html from the base
 616 documentation.
 617
 618 =cut
 619
 620 1;
 621