FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use Tie::RefHash;
  12 use FS::cust_bill;
  13 use FS::cust_bill_pkg;
  14 use FS::cust_bill_pkg_display;
  15 use FS::cust_bill_pay;
  16 use FS::cust_credit_bill;
  17 use FS::cust_tax_adjustment;
  18 use FS::tax_rate;
  19 use FS::tax_rate_location;
  20 use FS::cust_bill_pkg_tax_location;
  21 use FS::cust_bill_pkg_tax_rate_location;
  22 use FS::part_event;
  23 use FS::part_event_condition;
  24 use FS::pkg_category;
  25 use FS::FeeOrigin_Mixin;
  26 use FS::Log;
  27
  28 # 1 is mostly method/subroutine entry and options
  29 # 2 traces progress of some operations
  30 # 3 is even more information including possibly sensitive data
  31 $DEBUG = 0;
  32 $me = '[FS::cust_main::Billing]';
  33
  34 install_callback FS::UID sub {
  35   $conf = new FS::Conf;
  36   #yes, need it for stuff below (prolly should be cached)
  37 };
  38
  39 =head1 NAME
  40
  41 FS::cust_main::Billing - Billing mixin for cust_main
  42
  43 =head1 SYNOPSIS
  44
  45 =head1 DESCRIPTION
  46
  47 These methods are available on FS::cust_main objects.
  48
  49 =head1 METHODS
  50
  51 =over 4
  52
  53 =item bill_and_collect
  54
  55 Cancels and suspends any packages due, generates bills, applies payments and
  56 credits, and applies collection events to run cards, send bills and notices,
  57 etc.
  58
  59 By default, warns on errors and continues with the next operation (but see the
  60 "fatal" flag below).
  61
  62 Options are passed as name-value pairs.  Currently available options are:
  63
  64 =over 4
  65
  66 =item time
  67
  68 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  69
  70  use Date::Parse;
  71  ...
  72  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  73
  74 =item invoice_time
  75
  76 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  77
  78 =item check_freq
  79
  80 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  81
  82 =item resetup
  83
  84 If set true, re-charges setup fees.
  85
  86 =item fatal
  87
  88 If set any errors prevent subsequent operations from continusing.  If set
  89 specifically to "return", returns the error (or false, if there is no error).
  90 Any other true value causes errors to die.
  91
  92 =item debug
  93
  94 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  95
  96 =item job
  97
  98 Optional FS::queue entry to receive status updates.
  99
 100 =back
 101
 102 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 103 options of those methods are also available.
 104
 105 =cut
 106
 107 sub bill_and_collect {
 108   my( $self, %options ) = @_;
 109
 110   my $log = FS::Log->new('FS::cust_main::Billing::bill_and_collect');
 111   my %logopt = (object => $self);
 112   $log->debug('start', %logopt);
 113
 114   my $error;
 115
 116   #$options{actual_time} not $options{time} because freeside-daily -d is for
 117   #pre-printing invoices
 118
 119   $options{'actual_time'} ||= time;
 120   my $job = $options{'job'};
 121
 122   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 123                         ? day_end( $options{actual_time} )
 124                         : $options{actual_time}
 125                     );
 126
 127   $job->update_statustext('0,cleaning expired packages') if $job;
 128   $log->debug('canceling expired packages', %logopt);
 129   $error = $self->cancel_expired_pkgs( $actual_time );
 130   if ( $error ) {
 131     $error = "Error expiring custnum ". $self->custnum. ": $error";
 132     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 133     elsif ( $options{fatal}                                ) { die    $error; }
 134     else                                                     { warn   $error; }
 135   }
 136
 137   $log->debug('suspending adjourned packages', %logopt);
 138   $error = $self->suspend_adjourned_pkgs( $actual_time );
 139   if ( $error ) {
 140     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 141     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 142     elsif ( $options{fatal}                                ) { die    $error; }
 143     else                                                     { warn   $error; }
 144   }
 145
 146   $log->debug('unsuspending resumed packages', %logopt);
 147   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 148   if ( $error ) {
 149     $error = "Error resuming custnum ".$self->custnum. ": $error";
 150     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 151     elsif ( $options{fatal}                                ) { die    $error; }
 152     else                                                     { warn   $error; }
 153   }
 154
 155   $job->update_statustext('20,billing packages') if $job;
 156   $log->debug('billing packages', %logopt);
 157   $error = $self->bill( %options );
 158   if ( $error ) {
 159     $error = "Error billing custnum ". $self->custnum. ": $error";
 160     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 161     elsif ( $options{fatal}                                ) { die    $error; }
 162     else                                                     { warn   $error; }
 163   }
 164
 165   $job->update_statustext('50,applying payments and credits') if $job;
 166   $log->debug('applying payments and credits', %logopt);
 167   $error = $self->apply_payments_and_credits;
 168   if ( $error ) {
 169     $error = "Error applying custnum ". $self->custnum. ": $error";
 170     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 171     elsif ( $options{fatal}                                ) { die    $error; }
 172     else                                                     { warn   $error; }
 173   }
 174
 175   unless ( $conf->exists('cancelled_cust-noevents')
 176            && ! $self->num_ncancelled_pkgs
 177   ) {
 178     $job->update_statustext('70,running collection events') if $job;
 179     $log->debug('running collection events', %logopt);
 180     $error = $self->collect( %options );
 181     if ( $error ) {
 182       $error = "Error collecting custnum ". $self->custnum. ": $error";
 183       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 184       elsif ($options{fatal}                               ) { die    $error; }
 185       else                                                   { warn   $error; }
 186     }
 187   }
 188
 189   $job->update_statustext('100,finished') if $job;
 190   $log->debug('finish', %logopt);
 191
 192   '';
 193
 194 }
 195
 196 sub cancel_expired_pkgs {
 197   my ( $self, $time, %options ) = @_;
 198
 199   my @cancel_pkgs = $self->ncancelled_pkgs( {
 200     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 201   } );
 202
 203   my @errors = ();
 204
 205   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 206     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 207     my $error;
 208
 209     if ( $cust_pkg->change_to_pkgnum ) {
 210
 211       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 212       if ( !$new_pkg ) {
 213         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 214                       $cust_pkg->change_to_pkgnum.'; not expiring';
 215         next CUST_PKG;
 216       }
 217       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 218                                   'unprotect_svcs'  => 1 );
 219       $error = '' if ref $error eq 'FS::cust_pkg';
 220
 221     } else { # just cancel it
 222        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 223                                            'reason_otaker' => $cpr->otaker,
 224                                            'time'          => $time,
 225                                          )
 226                                        : ()
 227                                  );
 228     }
 229     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 230   }
 231
 232   join(' / ', @errors);
 233
 234 }
 235
 236 sub suspend_adjourned_pkgs {
 237   my ( $self, $time, %options ) = @_;
 238
 239   my @susp_pkgs = $self->ncancelled_pkgs( {
 240     'extra_sql' =>
 241       " AND ( susp IS NULL OR susp = 0 )
 242         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 243               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 244             )
 245       ",
 246   } );
 247
 248   #only because there's no SQL test for is_prepaid :/
 249   @susp_pkgs =
 250     grep {     (    $_->part_pkg->is_prepaid
 251                  && $_->bill
 252                  && $_->bill < $time
 253                )
 254             || (    $_->adjourn
 255                  && $_->adjourn <= $time
 256                )
 257
 258          }
 259          @susp_pkgs;
 260
 261   my @errors = ();
 262
 263   foreach my $cust_pkg ( @susp_pkgs ) {
 264     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 265       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 266     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 267                                             'reason_otaker' => $cpr->otaker
 268                                           )
 269                                         : ()
 270                                   );
 271     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 272   }
 273
 274   join(' / ', @errors);
 275
 276 }
 277
 278 sub unsuspend_resumed_pkgs {
 279   my ( $self, $time, %options ) = @_;
 280
 281   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 282     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 283   } );
 284
 285   my @errors = ();
 286
 287   foreach my $cust_pkg ( @unsusp_pkgs ) {
 288     my $error = $cust_pkg->unsuspend( 'time' => $time );
 289     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 290   }
 291
 292   join(' / ', @errors);
 293
 294 }
 295
 296 =item bill OPTIONS
 297
 298 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 299 conjunction with the collect method by calling B<bill_and_collect>.
 300
 301 If there is an error, returns the error, otherwise returns false.
 302
 303 Options are passed as name-value pairs.  Currently available options are:
 304
 305 =over 4
 306
 307 =item resetup
 308
 309 If set true, re-charges setup fees.
 310
 311 =item recurring_only
 312
 313 If set true then only bill recurring charges, not setup, usage, one time
 314 charges, etc.
 315
 316 =item freq_override
 317
 318 If set, then override the normal frequency and look for a part_pkg_discount
 319 to take at that frequency.  This is appropriate only when the normal
 320 frequency for all packages is monthly, and is an error otherwise.  Use
 321 C<pkg_list> to limit the set of packages included in billing.
 322
 323 =item time
 324
 325 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 326
 327  use Date::Parse;
 328  ...
 329  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 330
 331 =item pkg_list
 332
 333 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 334
 335  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 336
 337 =item not_pkgpart
 338
 339 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 340
 341 =item no_prepaid
 342
 343 Do not bill prepaid packages.  Used by freeside-daily.
 344
 345 =item invoice_time
 346
 347 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 348
 349 =item cancel
 350
 351 This boolean value informs the us that the package is being cancelled.  This
 352 typically might mean not charging the normal recurring fee but only usage
 353 fees since the last billing. Setup charges may be charged.  Not all package
 354 plans support this feature (they tend to charge 0).
 355
 356 =item no_usage_reset
 357
 358 Prevent the resetting of usage limits during this call.
 359
 360 =item no_commit
 361
 362 Do not save the generated bill in the database.  Useful with return_bill
 363
 364 =item return_bill
 365
 366 A list reference on which the generated bill(s) will be returned.
 367
 368 =item invoice_terms
 369
 370 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 371 terms or the default terms are used.
 372
 373 =back
 374
 375 =cut
 376
 377 sub bill {
 378   my( $self, %options ) = @_;
 379
 380   return '' if $self->payby eq 'COMP';
 381
 382   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 383   my $log = FS::Log->new('FS::cust_main::Billing::bill');
 384   my %logopt = (object => $self);
 385
 386   $log->debug('start', %logopt);
 387   warn "$me bill customer ". $self->custnum. "\n"
 388     if $DEBUG;
 389
 390   my $time = $options{'time'} || time;
 391   my $invoice_time = $options{'invoice_time'} || $time;
 392
 393   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 394                      ? day_end( $time )
 395                      : $time
 396                  );
 397
 398   $options{'not_pkgpart'} ||= {};
 399   $options{'not_pkgpart'} = { map { $_ => 1 }
 400                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 401                             }
 402     unless ref($options{'not_pkgpart'});
 403
 404   local $SIG{HUP} = 'IGNORE';
 405   local $SIG{INT} = 'IGNORE';
 406   local $SIG{QUIT} = 'IGNORE';
 407   local $SIG{TERM} = 'IGNORE';
 408   local $SIG{TSTP} = 'IGNORE';
 409   local $SIG{PIPE} = 'IGNORE';
 410
 411   my $oldAutoCommit = $FS::UID::AutoCommit;
 412   local $FS::UID::AutoCommit = 0;
 413   my $dbh = dbh;
 414
 415   $log->debug('acquiring lock', %logopt);
 416   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 417     if $DEBUG;
 418
 419   $self->select_for_update; #mutex
 420
 421   $log->debug('running pre-bill events', %logopt);
 422   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 423     if $DEBUG;
 424
 425   my $error = $self->do_cust_event(
 426     'debug'      => ( $options{'debug'} || 0 ),
 427     'time'       => $invoice_time,
 428     'check_freq' => $options{'check_freq'},
 429     'stage'      => 'pre-bill',
 430   )
 431     unless $options{no_commit};
 432   if ( $error ) {
 433     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 434     return $error;
 435   }
 436
 437   $log->debug('done running pre-bill events', %logopt);
 438   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 439     if $DEBUG;
 440
 441   #keep auto-charge and non-auto-charge line items separate
 442   my @passes = ( '', 'no_auto' );
 443
 444   my %cust_bill_pkg = map { $_ => [] } @passes;
 445
 446   ###
 447   # find the packages which are due for billing, find out how much they are
 448   # & generate invoice database.
 449   ###
 450
 451   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 452   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 453
 454   my %taxlisthash = map { $_ => {} } @passes;
 455
 456   my @precommit_hooks = ();
 457
 458   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 459
 460   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 461
 462     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 463
 464     my $part_pkg = $cust_pkg->part_pkg;
 465
 466     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 467
 468     $log->debug('bill package '. $cust_pkg->pkgnum, %logopt);
 469     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 470
 471     #? to avoid use of uninitialized value errors... ?
 472     $cust_pkg->setfield('bill', '')
 473       unless defined($cust_pkg->bill);
 474
 475     my $real_pkgpart = $cust_pkg->pkgpart;
 476     my %hash = $cust_pkg->hash;
 477
 478     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 479     # suffer from performance issues
 480     $options{has_hidden} = 0;
 481     my @part_pkg = $part_pkg->self_and_bill_linked;
 482     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 483
 484     # if this package was changed from another package,
 485     # and it hasn't been billed since then,
 486     # and package balances are enabled,
 487     if ( $cust_pkg->change_pkgnum
 488         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 489         and $cust_pkg->change_date <  $invoice_time
 490       and $conf->exists('pkg-balances') )
 491     {
 492       # _transfer_balance will also create the appropriate credit
 493       my @transfer_items = $self->_transfer_balance($cust_pkg);
 494       # $part_pkg[0] is the "real" part_pkg
 495       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 496                   'no_auto' : '';
 497       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 498       # treating this as recur, just because most charges are recur...
 499       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 500
 501       # currently not considering separate_bill here, as it's for
 502       # one-time charges only
 503     }
 504
 505     foreach my $part_pkg ( @part_pkg ) {
 506
 507       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 508
 509       my $pass = '';
 510       if ( $cust_pkg->separate_bill ) {
 511         # if no_auto is also set, that's fine. we just need to not have
 512         # invoices that are both auto and no_auto, and since the package
 513         # gets an invoice all to itself, it will only be one or the other.
 514         $pass = $cust_pkg->pkgnum;
 515         if (!exists $cust_bill_pkg{$pass}) { # it may not exist yet
 516           push @passes, $pass;
 517           $total_setup{$pass} = do { my $z = 0; \$z };
 518           $total_recur{$pass} = do { my $z = 0; \$z };
 519           $taxlisthash{$pass} = {};
 520           $cust_bill_pkg{$pass} = [];
 521         }
 522       } elsif ( ($cust_pkg->no_auto || $part_pkg->no_auto) ) {
 523         $pass = 'no_auto';
 524       }
 525
 526       my $next_bill = $cust_pkg->getfield('bill') || 0;
 527       my $error;
 528       # let this run once if this is the last bill upon cancellation
 529       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 530         $error =
 531           $self->_make_lines( 'part_pkg'            => $part_pkg,
 532                               'cust_pkg'            => $cust_pkg,
 533                               'precommit_hooks'     => \@precommit_hooks,
 534                               'line_items'          => $cust_bill_pkg{$pass},
 535                               'setup'               => $total_setup{$pass},
 536                               'recur'               => $total_recur{$pass},
 537                               'tax_matrix'          => $taxlisthash{$pass},
 538                               'time'                => $time,
 539                               'real_pkgpart'        => $real_pkgpart,
 540                               'options'             => \%options,
 541                             );
 542
 543         # Stop if anything goes wrong
 544         last if $error;
 545
 546         # or if we're not incrementing the bill date.
 547         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 548
 549         # or if we're letting it run only once
 550         last if $options{cancel};
 551
 552         $next_bill = $cust_pkg->getfield('bill') || 0;
 553
 554         #stop if -o was passed to freeside-daily
 555         last if $options{'one_recur'};
 556       }
 557       if ($error) {
 558         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 559         return $error;
 560       }
 561
 562     } #foreach my $part_pkg
 563
 564   } #foreach my $cust_pkg
 565
 566   foreach my $pass (@passes) { # keys %cust_bill_pkg )
 567
 568     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 569
 570     warn "$me billing pass $pass\n"
 571            #.Dumper(\@cust_bill_pkg)."\n"
 572       if $DEBUG > 2;
 573
 574     ###
 575     # process fees
 576     ###
 577
 578     my @pending_fees = FS::FeeOrigin_Mixin->by_cust($self->custnum,
 579       hashref => { 'billpkgnum' => '' }
 580     );
 581     warn "$me found pending fees:\n".Dumper(\@pending_fees)."\n"
 582       if @pending_fees and $DEBUG > 1;
 583
 584     # determine whether to generate an invoice
 585     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 586
 587     foreach my $fee (@pending_fees) {
 588       $generate_bill = 1 unless $fee->nextbill;
 589     }
 590
 591     # don't create an invoice with no line items, or where the only line
 592     # items are fees that are supposed to be held until the next invoice
 593     next if !$generate_bill;
 594
 595     # calculate fees...
 596     my @fee_items;
 597     foreach my $fee_origin (@pending_fees) {
 598       my $part_fee = $fee_origin->part_fee;
 599
 600       # check whether the fee is applicable before doing anything expensive:
 601       #
 602       # if the fee def belongs to a different agent, don't charge the fee.
 603       # event conditions should prevent this, but just in case they don't,
 604       # skip the fee.
 605       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 606         warn "tried to charge fee#".$part_fee->feepart .
 607              " on customer#".$self->custnum." from a different agent.\n";
 608         next;
 609       }
 610       # also skip if it's disabled
 611       next if $part_fee->disabled eq 'Y';
 612
 613       # Decide which invoice to base the fee on.
 614       my $cust_bill = $fee_origin->cust_bill;
 615       if (!$cust_bill) {
 616         # Then link it to the current invoice. This isn't the real cust_bill
 617         # object that will be inserted--in particular there are no taxes yet.
 618         # If you want to charge a fee on the total invoice amount including
 619         # taxes, you have to put the fee on the next invoice.
 620         $cust_bill = FS::cust_bill->new({
 621             'custnum'       => $self->custnum,
 622             'cust_bill_pkg' => \@cust_bill_pkg,
 623             'charged'       => ${ $total_setup{$pass} } +
 624                                ${ $total_recur{$pass} },
 625         });
 626
 627         # If the origin is for a specific package, then only apply the fee to
 628         # line items from that package.
 629         if ( my $cust_pkg = $fee_origin->cust_pkg ) {
 630           my @charge_fee_on_item;
 631           my $charge_fee_on_amount = 0;
 632           foreach (@cust_bill_pkg) {
 633             if ($_->pkgnum == $cust_pkg->pkgnum) {
 634               push @charge_fee_on_item, $_;
 635               $charge_fee_on_amount += $_->setup + $_->recur;
 636             }
 637           }
 638           $cust_bill->set('cust_bill_pkg', \@charge_fee_on_item);
 639           $cust_bill->set('charged', $charge_fee_on_amount);
 640         }
 641
 642       } # $cust_bill is now set
 643       # calculate the fee
 644       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 645       # link this so that we can clear the marker on inserting the line item
 646       $fee_item->set('fee_origin', $fee_origin);
 647       push @fee_items, $fee_item;
 648
 649     }
 650
 651     # add fees to the invoice
 652     foreach my $fee_item (@fee_items) {
 653
 654       push @cust_bill_pkg, $fee_item;
 655       ${ $total_setup{$pass} } += $fee_item->setup;
 656       ${ $total_recur{$pass} } += $fee_item->recur;
 657
 658       my $part_fee = $fee_item->part_fee;
 659       my $fee_location = $self->ship_location; # I think?
 660
 661       my $error = $self->_handle_taxes(
 662         $taxlisthash{$pass},
 663         $fee_item,
 664         location => $fee_location
 665         # probably not right to pass cancel => 1 for fees
 666       );
 667       return $error if $error;
 668
 669     }
 670
 671     # XXX implementation of fees is supposed to make this go away...
 672     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 673            !$conf->exists('postal_invoice-recurring_only')
 674        )
 675     {
 676
 677       my $postal_pkg = $self->charge_postal_fee();
 678       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 679
 680         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 681         return "can't charge postal invoice fee for customer ".
 682           $self->custnum. ": $postal_pkg";
 683
 684       } elsif ( $postal_pkg ) {
 685
 686         my $real_pkgpart = $postal_pkg->pkgpart;
 687         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 688         # suffer from performance issues
 689         $options{has_hidden} = 0;
 690         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 691         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 692
 693         foreach my $part_pkg ( @part_pkg ) {
 694           my %postal_options = %options;
 695           delete $postal_options{cancel};
 696           my $error =
 697             $self->_make_lines( 'part_pkg'            => $part_pkg,
 698                                 'cust_pkg'            => $postal_pkg,
 699                                 'precommit_hooks'     => \@precommit_hooks,
 700                                 'line_items'          => \@cust_bill_pkg,
 701                                 'setup'               => $total_setup{$pass},
 702                                 'recur'               => $total_recur{$pass},
 703                                 'tax_matrix'          => $taxlisthash{$pass},
 704                                 'time'                => $time,
 705                                 'real_pkgpart'        => $real_pkgpart,
 706                                 'options'             => \%postal_options,
 707                               );
 708           if ($error) {
 709             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 710             return $error;
 711           }
 712         }
 713
 714         # it's silly to have a zero value postal_pkg, but....
 715         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 716
 717       }
 718
 719     }
 720
 721     my $listref_or_error =
 722       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 723
 724     unless ( ref( $listref_or_error ) ) {
 725       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 726       return $listref_or_error;
 727     }
 728
 729     foreach my $taxline ( @$listref_or_error ) {
 730       ${ $total_setup{$pass} } =
 731         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 732       push @cust_bill_pkg, $taxline;
 733     }
 734
 735     #add tax adjustments
 736     warn "adding tax adjustments...\n" if $DEBUG > 2;
 737     foreach my $cust_tax_adjustment (
 738       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 739                                        'billpkgnum' => '',
 740                                      }
 741              )
 742     ) {
 743
 744       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 745
 746       my $itemdesc = $cust_tax_adjustment->taxname;
 747       $itemdesc = '' if $itemdesc eq 'Tax';
 748
 749       push @cust_bill_pkg, new FS::cust_bill_pkg {
 750         'pkgnum'      => 0,
 751         'setup'       => $tax,
 752         'recur'       => 0,
 753         'sdate'       => '',
 754         'edate'       => '',
 755         'itemdesc'    => $itemdesc,
 756         'itemcomment' => $cust_tax_adjustment->comment,
 757         'cust_tax_adjustment' => $cust_tax_adjustment,
 758         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 759       };
 760
 761     }
 762
 763     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 764
 765     my $balance = $self->balance;
 766
 767     my $previous_bill = qsearchs({ 'table'     => 'cust_bill',
 768                                    'hashref'   => { custnum=>$self->custnum },
 769                                    'extra_sql' => 'ORDER BY _date DESC LIMIT 1',
 770                                 });
 771     my $previous_balance =
 772       $previous_bill
 773         ? ( $previous_bill->billing_balance + $previous_bill->charged )
 774         : 0;
 775
 776     $log->debug('creating the new invoice', %logopt);
 777     warn "creating the new invoice\n" if $DEBUG;
 778     #create the new invoice
 779     my $cust_bill = new FS::cust_bill ( {
 780       'custnum'             => $self->custnum,
 781       '_date'               => $invoice_time,
 782       'charged'             => $charged,
 783       'billing_balance'     => $balance,
 784       'previous_balance'    => $previous_balance,
 785       'invoice_terms'       => $options{'invoice_terms'},
 786       'cust_bill_pkg'       => \@cust_bill_pkg,
 787     } );
 788     $error = $cust_bill->insert unless $options{no_commit};
 789     if ( $error ) {
 790       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 791       return "can't create invoice for customer #". $self->custnum. ": $error";
 792     }
 793     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 794
 795   } #foreach my $pass ( keys %cust_bill_pkg )
 796
 797   foreach my $hook ( @precommit_hooks ) {
 798     eval {
 799       &{$hook}; #($self) ?
 800     } unless $options{no_commit};
 801     if ( $@ ) {
 802       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 803       return "$@ running precommit hook $hook\n";
 804     }
 805   }
 806
 807   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 808
 809   ''; #no error
 810 }
 811
 812 #discard bundled packages of 0 value
 813 sub _omit_zero_value_bundles {
 814   my @in = @_;
 815
 816   my @cust_bill_pkg = ();
 817   my @cust_bill_pkg_bundle = ();
 818   my $sum = 0;
 819   my $discount_show_always = 0;
 820
 821   foreach my $cust_bill_pkg ( @in ) {
 822
 823     $discount_show_always = ($cust_bill_pkg->get('discounts')
 824                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 825                                 && $conf->exists('discount-show-always'));
 826
 827     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 828          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 829          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 830       if $DEBUG > 0;
 831
 832     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 833       push @cust_bill_pkg, @cust_bill_pkg_bundle
 834         if $sum > 0
 835         || ($sum == 0 && (    $discount_show_always
 836                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 837                                    @cust_bill_pkg_bundle
 838                          )
 839            );
 840       @cust_bill_pkg_bundle = ();
 841       $sum = 0;
 842     }
 843
 844     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 845     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 846
 847   }
 848
 849   push @cust_bill_pkg, @cust_bill_pkg_bundle
 850     if $sum > 0
 851     || ($sum == 0 && (    $discount_show_always
 852                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 853                                @cust_bill_pkg_bundle
 854                      )
 855        );
 856
 857   warn "  _omit_zero_value_bundles: ". scalar(@in).
 858        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 859     if $DEBUG > 2;
 860
 861   (@cust_bill_pkg);
 862
 863 }
 864
 865 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 866
 867 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 868 Usually used internally by bill method B<bill>.
 869
 870 If there is an error, returns the error, otherwise returns reference to a
 871 list of line items suitable for insertion.
 872
 873 =over 4
 874
 875 =item LINEITEMREF
 876
 877 An array ref of the line items being billed.
 878
 879 =item TAXHASHREF
 880
 881 A strange beast.  The keys to this hash are internal identifiers consisting
 882 of the name of the tax object type, a space, and its unique identifier ( e.g.
 883  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 884 item in the list is the tax object.  The remaining items are either line
 885 items or floating point values (currency amounts).
 886
 887 The taxes are calculated on this entity.  Calculated exemption records are
 888 transferred to the LINEITEMREF items on the assumption that they are related.
 889
 890 Read the source.
 891
 892 =item INVOICE_TIME
 893
 894 This specifies the date appearing on the associated invoice.  Some
 895 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 896
 897 =back
 898
 899 =cut
 900
 901 sub calculate_taxes {
 902   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 903
 904   # $taxlisthash is a hashref
 905   # keys are identifiers, values are arrayrefs
 906   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 907   # then a cust_bill_pkg object the tax applies to, then the charge class
 908   # on that object (setup, recur, a usage class number, or '')
 909   # For internal taxes the charge class is always undef.
 910
 911   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 912
 913   warn "$me calculate_taxes\n"
 914        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 915     if $DEBUG > 2;
 916
 917   # The main tax accumulator.  One bin for each tax name (itemdesc).
 918   # For each subdivision of tax under this name, push a cust_bill_pkg item
 919   # for the calculated tax into the arrayref.
 920   # keys are tax names
 921   # values are arrayrefs of tax lines
 922   my %taxname = ();
 923
 924   # keys are taxlisthash keys (internal identifiers)
 925   # values are (cumulative) amounts
 926   my %tax_amount = ();
 927
 928   # keys are taxlisthash keys
 929   # values are arrayrefs of cust_tax_exempt_pkg objects
 930   my %tax_exemption;
 931
 932   # keys are cust_bill_pkg objects (taxable items)
 933   # values are hashrefs
 934   #   keys are taxlisthash keys
 935   #   values are the taxlines generated for those taxes
 936   tie my %item_has_tax, 'Tie::RefHash',
 937     map { $_ => {} } @$cust_bill_pkg;
 938
 939   foreach my $tax_id ( keys %$taxlisthash ) {
 940     # $tax_id: the identifier of the tax we are calculating in this pass
 941
 942     my $taxables = $taxlisthash->{$tax_id};
 943     my $tax_object = shift @$taxables;
 944     # $tax_object is a cust_main_county or tax_rate
 945     # (with billpkgnum, pkgnum, locationnum set)
 946     # the rest of @{ $taxlisthash->{$tax_id} } is cust_bill_pkg objects,
 947     # optionally followed by their charge classes.
 948     warn "found ". $tax_object->taxname. " as $tax_id\n" if $DEBUG > 2;
 949
 950     # taxline calculates the tax on all cust_bill_pkgs in the
 951     # first (arrayref) argument.
 952     #
 953     # Note that non-monthly exemptions have already been calculated and
 954     # attached to the items.  Monthly exemptions will be attached in this
 955     # step.
 956     my $exemptions = $tax_exemption{$tax_id} ||= [];
 957     if ( $tax_object->isa('FS::tax_rate') ) { # EXTERNAL TAXES
 958       # STILL have tax_rate-specific crap in here...
 959       my @taxlines = $tax_object->taxline( $taxables,
 960                               'custnum'      => $self->custnum,
 961                               'invoice_time' => $invoice_time,
 962                               'exemptions'   => $exemptions,
 963                               );
 964       next if !@taxlines;
 965       if (!ref $taxlines[0]) {
 966         # it's an error string
 967         warn "error evaluating $tax_id on custnum ".$self->custnum."\n";
 968         return $taxlines[0];
 969       }
 970       foreach my $taxline (@taxlines) {
 971         push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 972         my $link = $taxline->get('cust_bill_pkg_tax_rate_location')->[0];
 973         my $taxable_item = $link->taxable_cust_bill_pkg;
 974         $item_has_tax{$taxable_item}->{$tax_id} = $taxline;
 975       }
 976     } else { # INTERNAL TAXES
 977       # we can do this in a single taxline, because it's not stupid
 978
 979       my $taxline =  $tax_object->taxline( $taxables,
 980                         'custnum'      => $self->custnum,
 981                         'invoice_time' => $invoice_time,
 982                         'exemptions'   => $exemptions,
 983                       );
 984       next if !$taxline;
 985       if (!ref $taxline) {
 986         # it's an error string
 987         warn "error evaluating $tax_id on custnum ".$self->custnum."\n";
 988         return $taxline;
 989       }
 990       # if the calculated tax is zero, don't even keep it
 991       next if $taxline->setup < 0.001;
 992       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 993     }
 994   }
 995   $DB::single = 1; # XXX
 996
 997   # all first-tier taxes are calculated.  now for tax on tax:
 998
 999   foreach my $taxable_item ( @$cust_bill_pkg ) {
1000     # taxes that apply to this item
1001     my $this_has_tax = $item_has_tax{$taxable_item};
1002
1003     my $location = $taxable_item->tax_location;
1004     foreach my $tax_id (keys %$this_has_tax) {
1005       my ($class, $taxnum) = split(' ', $tax_id);
1006       # internal taxes don't support tax_on_tax, so we don't bother with
1007       # them here.
1008       next unless $class eq 'FS::tax_rate';
1009
1010       # for each tax item that was calculated in phase 1, get the
1011       # tax definition
1012       my $tax_object = FS::tax_rate->by_key($taxnum);
1013       # and find all taxes that apply to it in this location
1014       my @tot = $tax_object->tax_on_tax( $location );
1015       next if !@tot;
1016       warn "found possible taxed taxnum $taxnum\n"
1017         if $DEBUG > 2;
1018       # Calculate ToT separately for each taxable item, and only if _that
1019       # item_ is already taxed under the ToT.  This is counterintuitive.
1020       # See RT#5243.
1021       foreach my $tot (@tot) {
1022         my $tot_id = ref($tot) . ' ' . $tot->taxnum;
1023         warn "checking taxnum ".$tot->taxnum.
1024              " which we call ". $tot->taxname ."\n"
1025           if $DEBUG > 2;
1026         if ( exists $this_has_tax->{ $tot_id } ) {
1027           warn "calculating tax on tax: taxnum ".$tot->taxnum." on $taxnum\n"
1028             if $DEBUG;
1029           my @taxlines = $tot->taxline(
1030                             $this_has_tax->{ $tax_id }, # the first-stage tax
1031                             'custnum'       => $self->custnum,
1032                             'invoice_time'  => $invoice_time,
1033                            );
1034           next if (!@taxlines); # it didn't apply after all
1035           if (!ref($taxlines[0])) {
1036             warn "error evaluating $tot_id TOT on custnum ".
1037               $self->custnum."\n";
1038             return $taxlines[0];
1039           }
1040           foreach my $taxline (@taxlines) {
1041             push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1042           }
1043         } # if $has_tax
1044       } # foreach my $tot (tax-on-tax rate definition)
1045     } # foreach $taxnum (first-tier rate definition)
1046   } # foreach $taxable_item
1047
1048   #consolidate and create tax line items
1049   warn "consolidating and generating...\n" if $DEBUG > 2;
1050   my %final_tax_items; # taxname => item
1051   foreach my $taxname ( keys %taxname ) {
1052     my @cust_bill_pkg_tax_location;
1053     my @cust_bill_pkg_tax_rate_location;
1054     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
1055         'pkgnum'    => 0,
1056         'recur'     => 0,
1057         'sdate'     => '',
1058         'edate'     => '',
1059         'itemdesc'  => $taxname,
1060         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
1061         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
1062     });
1063
1064     my $tax_total = 0;
1065     my %seen = ();
1066     warn "adding $taxname\n" if $DEBUG > 1;
1067     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
1068       next if $taxitem->get('setup') == 0;
1069       # if ( ref($taxitem) eq 'FS::cust_bill_pkg' )  # always true
1070       # then we need to transfer the amount and the links from the
1071       # line item to the new one we're creating.
1072       $tax_total += $taxitem->setup;
1073       my @links = @{
1074         $taxitem->get('cust_bill_pkg_tax_location') ||
1075         $taxitem->get('cust_bill_pkg_tax_rate_location') ||
1076         []
1077       };
1078       foreach my $link ( @links ) {
1079         $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
1080         if ($link->isa('FS::cust_bill_pkg_tax_location')) {
1081           push @cust_bill_pkg_tax_location, $link;
1082         } elsif ($link->isa('FS::cust_bill_pkg_tax_rate_location')) {
1083           push @cust_bill_pkg_tax_rate_location, $link;
1084         }
1085       }
1086     }
1087     next unless $tax_total;
1088
1089     # we should really neverround this up...I guess it's okay if taxline
1090     # already returns amounts with 2 decimal places
1091     $tax_total = sprintf('%.2f', $tax_total );
1092     $tax_cust_bill_pkg->set('setup', $tax_total);
1093
1094     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1095                                                    'disabled'     => '',
1096                                                  },
1097                                );
1098
1099     my @display = ();
1100     if ( $pkg_category and
1101          $conf->config('invoice_latexsummary') ||
1102          $conf->config('invoice_htmlsummary')
1103        )
1104     {
1105
1106       my %hash = (  'section' => $pkg_category->categoryname );
1107       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1108
1109     }
1110     $tax_cust_bill_pkg->set('display', \@display);
1111
1112     $final_tax_items{$taxname} = $tax_cust_bill_pkg;
1113   } # foreach $taxname
1114
1115   # fix ToT backlinks for taxes that have been consolidated
1116   # (has to be done in a separate pass)
1117   foreach my $tax_item (values %final_tax_items) {
1118     foreach my $taxable_link (@{ $tax_item->cust_bill_pkg_tax_rate_location }) {
1119       my $taxed_item = $taxable_link->taxable_cust_bill_pkg;
1120       next if $taxed_item->pkgnum > 0; # primary taxes
1121       my $taxname = $taxed_item->itemdesc;
1122       $taxable_link->set('taxable_cust_bill_pkg', $final_tax_items{ $taxname });
1123     }
1124   }
1125
1126   [ values %final_tax_items ]
1127 }
1128
1129 sub _make_lines {
1130   my ($self, %params) = @_;
1131
1132   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1133
1134   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1135   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1136   my $cust_location = $cust_pkg->tax_location;
1137   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1138   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1139   my $total_setup = $params{setup} or die "no setup accumulator specified";
1140   my $total_recur = $params{recur} or die "no recur accumulator specified";
1141   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1142   my $time = $params{'time'} or die "no time specified";
1143   my (%options) = %{$params{options}};
1144
1145   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1146     # this should never happen
1147     die 'freq_override billing attempted on non-monthly package '.
1148       $cust_pkg->pkgnum;
1149   }
1150
1151   my $dbh = dbh;
1152   my $real_pkgpart = $params{real_pkgpart};
1153   my %hash = $cust_pkg->hash;
1154   my $old_cust_pkg = new FS::cust_pkg \%hash;
1155
1156   my @details = ();
1157   my $lineitems = 0;
1158
1159   $cust_pkg->pkgpart($part_pkg->pkgpart);
1160
1161   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1162                      ? day_end( $time )
1163                      : $time
1164                  );
1165
1166   ###
1167   # bill setup
1168   ###
1169
1170   my $setup = 0;
1171   my $unitsetup = 0;
1172   my @setup_discounts = ();
1173   my %setup_param = ( 'discounts'    => \@setup_discounts,
1174                       'real_pkgpart' => $params{real_pkgpart}
1175                     );
1176   # Conditions for setting setup date and charging the setup fee:
1177   # - this is not a recurring-only billing run
1178   # - and the package is not currently being canceled
1179   # - and, unless we're specifically told otherwise via 'resetup':
1180   #   - it doesn't already HAVE a setup date
1181   #   - or a start date in the future
1182   #   - and it's not suspended
1183   #
1184   # The last condition used to check the "disable_setup_suspended" option but
1185   # that's obsolete. We now never set the setup date on a suspended package.
1186   if (     ! $options{recurring_only}
1187        and ! $options{cancel}
1188        and ( $options{'resetup'}
1189              || ( ! $cust_pkg->setup
1190                   && ( ! $cust_pkg->start_date
1191                        || $cust_pkg->start_date <= $cmp_time
1192                      )
1193                   && ( ! $cust_pkg->getfield('susp') )
1194               )
1195            )
1196      )
1197   {
1198
1199     warn "    bill setup\n" if $DEBUG > 1;
1200
1201     unless ( $cust_pkg->waive_setup ) {
1202         $lineitems++;
1203
1204         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1205         return "$@ running calc_setup for $cust_pkg\n"
1206           if $@;
1207
1208         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
1209     }
1210
1211     $cust_pkg->setfield('setup', $time)
1212       unless $cust_pkg->setup;
1213           #do need it, but it won't get written to the db
1214           #|| $cust_pkg->pkgpart != $real_pkgpart;
1215
1216     $cust_pkg->setfield('start_date', '')
1217       if $cust_pkg->start_date;
1218
1219   }
1220
1221   ###
1222   # bill recurring fee
1223   ###
1224
1225   my $recur = 0;
1226   my $unitrecur = 0;
1227   my @recur_discounts = ();
1228   my $sdate;
1229   if (     ! $cust_pkg->start_date
1230        and
1231            ( ! $cust_pkg->susp
1232                || ( $cust_pkg->susp != $cust_pkg->order_date
1233                       && (    $cust_pkg->option('suspend_bill',1)
1234                            || ( $part_pkg->option('suspend_bill', 1)
1235                                  && ! $cust_pkg->option('no_suspend_bill',1)
1236                               )
1237                          )
1238                   )
1239                || $cust_pkg->is_status_delay_cancel
1240            )
1241        and
1242             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1243          || ( $part_pkg->plan eq 'voip_cdr'
1244                && $part_pkg->option('bill_every_call')
1245             )
1246          || $options{cancel}
1247   ) {
1248
1249     # XXX should this be a package event?  probably.  events are called
1250     # at collection time at the moment, though...
1251     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1252       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1253       #don't want to reset usage just cause we want a line item??
1254       #&& $part_pkg->pkgpart == $real_pkgpart;
1255
1256     warn "    bill recur\n" if $DEBUG > 1;
1257     $lineitems++;
1258
1259     # XXX shared with $recur_prog
1260     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1261              || $cust_pkg->setup
1262              || $time;
1263
1264     #over two params!  lets at least switch to a hashref for the rest...
1265     my $increment_next_bill = ( $part_pkg->freq ne '0'
1266                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1267                                 && !$options{cancel}
1268                               );
1269     my %param = ( %setup_param,
1270                   'precommit_hooks'     => $precommit_hooks,
1271                   'increment_next_bill' => $increment_next_bill,
1272                   'discounts'           => \@recur_discounts,
1273                   'real_pkgpart'        => $real_pkgpart,
1274                   'freq_override'       => $options{freq_override} || '',
1275                   'setup_fee'           => 0,
1276                 );
1277
1278     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1279
1280     # There may be some part_pkg for which this is wrong.  Only those
1281     # which can_discount are supported.
1282     # (the UI should prevent adding discounts to these at the moment)
1283
1284     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1285          " for pkgpart ". $cust_pkg->pkgpart.
1286          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1287       if $DEBUG > 2;
1288
1289     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1290     return "$@ running $method for $cust_pkg\n"
1291       if ( $@ );
1292
1293     #base_cancel???
1294     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1295
1296     if ( $increment_next_bill ) {
1297
1298       my $next_bill;
1299
1300       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1301         # supplemental package
1302         # to keep in sync with the main package, simulate billing at
1303         # its frequency
1304         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1305         my $supp_pkg_freq = $part_pkg->freq;
1306         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1307         if ( $ratio != int($ratio) ) {
1308           # the UI should prevent setting up packages like this, but just
1309           # in case
1310           return "supplemental package period is not an integer multiple of main  package period";
1311         }
1312         $next_bill = $sdate;
1313         for (1..$ratio) {
1314           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1315         }
1316
1317       } else {
1318         # the normal case
1319       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1320       return "unparsable frequency: ". $part_pkg->freq
1321         if $next_bill == -1;
1322       }
1323
1324       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1325       # only for figuring next bill date, nothing else, so, reset $sdate again
1326       # here
1327       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1328       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1329       $cust_pkg->last_bill($sdate);
1330
1331       $cust_pkg->setfield('bill', $next_bill );
1332
1333     }
1334
1335     if ( $param{'setup_fee'} ) {
1336       # Add an additional setup fee at the billing stage.
1337       # Used for prorate_defer_bill.
1338       $setup += $param{'setup_fee'};
1339       $unitsetup += $param{'setup_fee'};
1340       $lineitems++;
1341     }
1342
1343     if ( defined $param{'discount_left_setup'} ) {
1344         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1345             $setup -= $discount_setup;
1346         }
1347     }
1348
1349   }
1350
1351   warn "\$setup is undefined" unless defined($setup);
1352   warn "\$recur is undefined" unless defined($recur);
1353   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1354
1355   ###
1356   # If there's line items, create em cust_bill_pkg records
1357   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1358   ###
1359
1360   if ( $lineitems ) {
1361
1362     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1363       # hmm.. and if just the options are modified in some weird price plan?
1364
1365       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1366         if $DEBUG >1;
1367
1368       my $error = $cust_pkg->replace( $old_cust_pkg,
1369                                       'depend_jobnum'=>$options{depend_jobnum},
1370                                       'options' => { $cust_pkg->options },
1371                                     )
1372         unless $options{no_commit};
1373       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1374         if $error; #just in case
1375     }
1376
1377     $setup = sprintf( "%.2f", $setup );
1378     $recur = sprintf( "%.2f", $recur );
1379     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1380       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1381     }
1382     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1383       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1384     }
1385
1386     my $discount_show_always = $conf->exists('discount-show-always')
1387                                && (    ($setup == 0 && scalar(@setup_discounts))
1388                                     || ($recur == 0 && scalar(@recur_discounts))
1389                                   );
1390
1391     if (    $setup != 0
1392          || $recur != 0
1393          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1394          || $discount_show_always
1395          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1396          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1397        )
1398     {
1399
1400       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1401         if $DEBUG > 1;
1402
1403       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1404       if ( $DEBUG > 1 ) {
1405         warn "      adding customer package invoice detail: $_\n"
1406           foreach @cust_pkg_detail;
1407       }
1408       push @details, @cust_pkg_detail;
1409
1410       my $cust_bill_pkg = new FS::cust_bill_pkg {
1411         'pkgnum'    => $cust_pkg->pkgnum,
1412         'setup'     => $setup,
1413         'unitsetup' => $unitsetup,
1414         'recur'     => $recur,
1415         'unitrecur' => $unitrecur,
1416         'quantity'  => $cust_pkg->quantity,
1417         'details'   => \@details,
1418         'discounts' => [ @setup_discounts, @recur_discounts ],
1419         'hidden'    => $part_pkg->hidden,
1420         'freq'      => $part_pkg->freq,
1421       };
1422
1423       if ( $part_pkg->option('prorate_defer_bill',1)
1424            and !$hash{last_bill} ) {
1425         # both preceding and upcoming, technically
1426         $cust_bill_pkg->sdate( $cust_pkg->setup );
1427         $cust_bill_pkg->edate( $cust_pkg->bill );
1428       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1429         $cust_bill_pkg->sdate( $hash{last_bill} );
1430         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1431         $cust_bill_pkg->edate( $time ) if $options{cancel};
1432       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1433         $cust_bill_pkg->sdate( $sdate );
1434         $cust_bill_pkg->edate( $cust_pkg->bill );
1435         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1436       }
1437
1438       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1439         unless $part_pkg->pkgpart == $real_pkgpart;
1440
1441       $$total_setup += $setup;
1442       $$total_recur += $recur;
1443
1444       ###
1445       # handle taxes
1446       ###
1447
1448       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg,
1449         cancel => $options{cancel} );
1450       return $error if $error;
1451
1452       $cust_bill_pkg->set_display(
1453         part_pkg     => $part_pkg,
1454         real_pkgpart => $real_pkgpart,
1455       );
1456
1457       push @$cust_bill_pkgs, $cust_bill_pkg;
1458
1459     } #if $setup != 0 || $recur != 0
1460
1461   } #if $line_items
1462
1463   '';
1464
1465 }
1466
1467 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1468
1469 Takes one argument, a cust_pkg object that is being billed.  This will
1470 be called only if the package was created by a package change, and has
1471 not been billed since the package change, and package balance tracking
1472 is enabled.  The second argument can be an alternate package number to
1473 transfer the balance from; this should not be used externally.
1474
1475 Transfers the balance from the previous package (now canceled) to
1476 this package, by crediting one package and creating an invoice item for
1477 the other.  Inserts the credit and returns the invoice item (so that it
1478 can be added to an invoice that's being built).
1479
1480 If the previous package was never billed, and was also created by a package
1481 change, then this will also transfer the balance from I<its> previous
1482 package, and so on, until reaching a package that either has been billed
1483 or was not created by a package change.
1484
1485 =cut
1486
1487 my $balance_transfer_reason;
1488
1489 sub _transfer_balance {
1490   my $self = shift;
1491   my $cust_pkg = shift;
1492   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1493   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1494
1495   my @transfers;
1496
1497   # if $from_pkg is not the first package in the chain, and it was never
1498   # billed, walk back
1499   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1500     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1501   }
1502
1503   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1504   if ( $prev_balance != 0 ) {
1505     $balance_transfer_reason ||= FS::reason->new_or_existing(
1506       'reason' => 'Package balance transfer',
1507       'type'   => 'Internal adjustment',
1508       'class'  => 'R'
1509     );
1510
1511     my $credit = FS::cust_credit->new({
1512         'custnum'   => $self->custnum,
1513         'amount'    => abs($prev_balance),
1514         'reasonnum' => $balance_transfer_reason->reasonnum,
1515         '_date'     => $cust_pkg->change_date,
1516     });
1517
1518     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1519         'setup'     => 0,
1520         'recur'     => abs($prev_balance),
1521         #'sdate'     => $from_pkg->last_bill, # not sure about this
1522         #'edate'     => $cust_pkg->change_date,
1523         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1524                                  $from_pkg->part_pkg->pkg),
1525     });
1526
1527     if ( $prev_balance > 0 ) {
1528       # credit the old package, charge the new one
1529       $credit->set('pkgnum', $from_pkgnum);
1530       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1531     } else {
1532       # the reverse
1533       $credit->set('pkgnum', $cust_pkg->pkgnum);
1534       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1535     }
1536     my $error = $credit->insert;
1537     die "error transferring package balance from #".$from_pkgnum.
1538         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1539
1540     push @transfers, $cust_bill_pkg;
1541   } # $prev_balance != 0
1542
1543   return @transfers;
1544 }
1545
1546 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1547
1548 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1549 from _make_lines.
1550
1551 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1552 this:
1553 {
1554   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1555   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1556 }
1557
1558 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1559 is always the cust_main_county or tax_rate identified by the key.
1560
1561 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1562 the 'taxline' method to calculate the amount of the tax.  This doesn't
1563 happen until calculate_taxes, though.
1564
1565 OPTIONS may include:
1566 - part_item: a part_pkg or part_fee object to be used as the package/fee
1567   definition.
1568 - location: a cust_location to be used as the billing location.
1569 - cancel: true if this package is being billed on cancellation.  This
1570   allows tax to be calculated on usage charges only.
1571
1572 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1573 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1574 the customer's default service location).
1575
1576 This method will also calculate exemptions for any taxes that apply to the
1577 line item (using the C<set_exemptions> method of L<FS::cust_bill_pkg>) and
1578 attach them.  This is the only place C<set_exemptions> is called in normal
1579 invoice processing.
1580
1581 =cut
1582
1583 sub _handle_taxes {
1584   my $self = shift;
1585   my $taxlisthash = shift;
1586   my $cust_bill_pkg = shift;
1587   my %options = @_;
1588
1589   # at this point I realize that we have enough information to infer all this
1590   # stuff, instead of passing around giant honking argument lists
1591   my $location = $options{location} || $cust_bill_pkg->tax_location;
1592   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1593
1594   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1595
1596   return if ( $self->payby eq 'COMP' ); #dubious
1597
1598   if ( $conf->exists('enable_taxproducts')
1599        && ( scalar($part_item->part_pkg_taxoverride)
1600             || $part_item->has_taxproduct
1601           )
1602      )
1603     {
1604
1605     # EXTERNAL TAX RATES (via tax_rate)
1606     my %cust_bill_pkg = ();
1607     my %taxes = ();
1608
1609     my @classes;
1610     my $usage = $cust_bill_pkg->usage || 0;
1611     push @classes, $cust_bill_pkg->usage_classes if $usage;
1612     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1613     push @classes, 'recur' if ($cust_bill_pkg->recur - $usage)
1614         and !$options{cancel};
1615     # that's better--probably don't even need $options{cancel} now
1616     # but leave it for now, just to be safe
1617     #
1618     # About $options{cancel}: This protects against charging per-line or
1619     # per-customer or other flat-rate surcharges on a package that's being
1620     # billed on cancellation (which is an out-of-cycle bill and should only
1621     # have usage charges).  See RT#29443.
1622
1623     # customer exemption is now handled in the 'taxline' method
1624     #my $exempt = $conf->exists('cust_class-tax_exempt')
1625     #               ? ( $self->cust_class ? $self->cust_class->tax : '' )
1626     #               : $self->tax;
1627     # standardize this just to be sure
1628     #$exempt = ($exempt eq 'Y') ? 'Y' : '';
1629     #
1630     #if ( !$exempt ) {
1631
1632     unless (exists $taxes{''}) {
1633       # unsure what purpose this serves, but last time I deleted something
1634       # from here just because I didn't see the point, it actually did
1635       # something important.
1636       my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1637       return $err_or_ref unless ref($err_or_ref);
1638       $taxes{''} = $err_or_ref;
1639     }
1640
1641     # NO DISINTEGRATIONS.
1642     # my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1643     #
1644     # do not call taxline() with any argument except the entire set of
1645     # cust_bill_pkgs on an invoice that are eligible for the tax.
1646
1647     # only calculate exemptions once for each tax rate, even if it's used
1648     # for multiple classes
1649     my %tax_seen = ();
1650
1651     foreach my $class (@classes) {
1652       my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1653       return $err_or_ref unless ref($err_or_ref);
1654       my @taxes = @$err_or_ref;
1655
1656       next if !@taxes;
1657
1658       foreach my $tax ( @taxes ) {
1659
1660         my $tax_id = ref( $tax ). ' '. $tax->taxnum;
1661         # $taxlisthash: keys are tax identifiers ('FS::tax_rate 123456').
1662         # Values are arrayrefs, first the tax object (cust_main_county
1663         # or tax_rate), then the cust_bill_pkg object that the
1664         # tax applies to, then the tax class (setup, recur, usage classnum).
1665         $taxlisthash->{ $tax_id } ||= [ $tax ];
1666         push @{ $taxlisthash->{ $tax_id  } }, $cust_bill_pkg, $class;
1667
1668         # determine any exemptions that apply
1669         if (!$tax_seen{$tax_id}) {
1670           $cust_bill_pkg->set_exemptions( $tax, custnum => $self->custnum );
1671           $tax_seen{$tax_id} = 1;
1672         }
1673
1674         # tax on tax will be done later, when we actually create the tax
1675         # line items
1676
1677       }
1678     }
1679
1680   } else {
1681
1682     # INTERNAL TAX RATES (cust_main_county)
1683
1684     # We fetch taxes even if the customer is completely exempt,
1685     # because we need to record that fact.
1686
1687     my @loc_keys = qw( district city county state country );
1688     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1689
1690     $taxhash{'taxclass'} = $part_item->taxclass;
1691
1692     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1693
1694     my @taxes = (); # entries are cust_main_county objects
1695     my %taxhash_elim = %taxhash;
1696     my @elim = qw( district city county state );
1697     do {
1698
1699       #first try a match with taxclass
1700       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1701
1702       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1703         #then try a match without taxclass
1704         my %no_taxclass = %taxhash_elim;
1705         $no_taxclass{ 'taxclass' } = '';
1706         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1707       }
1708
1709       $taxhash_elim{ shift(@elim) } = '';
1710
1711     } while ( !scalar(@taxes) && scalar(@elim) );
1712
1713     foreach (@taxes) {
1714       my $tax_id = 'cust_main_county '.$_->taxnum;
1715       $taxlisthash->{$tax_id} ||= [ $_ ];
1716       $cust_bill_pkg->set_exemptions($_, custnum => $self->custnum);
1717       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1718     }
1719
1720   }
1721   '';
1722 }
1723
1724 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1725
1726 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1727 or part_fee (which will define the tax eligibility of the product), CLASS is
1728 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1729 location where the service was provided (or billed, depending on
1730 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1731 can apply to this line item.
1732
1733 =cut
1734
1735 sub _gather_taxes {
1736   my $self = shift;
1737   my $part_item = shift;
1738   my $class = shift;
1739   my $location = shift;
1740
1741   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1742
1743   my $geocode = $location->geocode('cch');
1744
1745   [ $part_item->tax_rates('cch', $geocode, $class) ]
1746
1747 }
1748
1749 =item collect [ HASHREF | OPTION => VALUE ... ]
1750
1751 (Attempt to) collect money for this customer's outstanding invoices (see
1752 L<FS::cust_bill>).  Usually used after the bill method.
1753
1754 Actions are now triggered by billing events; see L<FS::part_event> and the
1755 billing events web interface.  Old-style invoice events (see
1756 L<FS::part_bill_event>) have been deprecated.
1757
1758 If there is an error, returns the error, otherwise returns false.
1759
1760 Options are passed as name-value pairs.
1761
1762 Currently available options are:
1763
1764 =over 4
1765
1766 =item invoice_time
1767
1768 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1769
1770 =item retry
1771
1772 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1773
1774 =item check_freq
1775
1776 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1777
1778 =item quiet
1779
1780 set true to surpress email card/ACH decline notices.
1781
1782 =item debug
1783
1784 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1785
1786 =back
1787
1788 # =item payby
1789 #
1790 # allows for one time override of normal customer billing method
1791
1792 =cut
1793
1794 sub collect {
1795   my( $self, %options ) = @_;
1796
1797   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1798
1799   my $invoice_time = $options{'invoice_time'} || time;
1800
1801   #put below somehow?
1802   local $SIG{HUP} = 'IGNORE';
1803   local $SIG{INT} = 'IGNORE';
1804   local $SIG{QUIT} = 'IGNORE';
1805   local $SIG{TERM} = 'IGNORE';
1806   local $SIG{TSTP} = 'IGNORE';
1807   local $SIG{PIPE} = 'IGNORE';
1808
1809   my $oldAutoCommit = $FS::UID::AutoCommit;
1810   local $FS::UID::AutoCommit = 0;
1811   my $dbh = dbh;
1812
1813   $self->select_for_update; #mutex
1814
1815   if ( $DEBUG ) {
1816     my $balance = $self->balance;
1817     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1818   }
1819
1820   if ( exists($options{'retry_card'}) ) {
1821     carp 'retry_card option passed to collect is deprecated; use retry';
1822     $options{'retry'} ||= $options{'retry_card'};
1823   }
1824   if ( exists($options{'retry'}) && $options{'retry'} ) {
1825     my $error = $self->retry_realtime;
1826     if ( $error ) {
1827       $dbh->rollback if $oldAutoCommit;
1828       return $error;
1829     }
1830   }
1831
1832   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1833
1834   #never want to roll back an event just because it returned an error
1835   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1836
1837   $self->do_cust_event(
1838     'debug'      => ( $options{'debug'} || 0 ),
1839     'time'       => $invoice_time,
1840     'check_freq' => $options{'check_freq'},
1841     'stage'      => 'collect',
1842   );
1843
1844 }
1845
1846 =item retry_realtime
1847
1848 Schedules realtime / batch  credit card / electronic check / LEC billing
1849 events for for retry.  Useful if card information has changed or manual
1850 retry is desired.  The 'collect' method must be called to actually retry
1851 the transaction.
1852
1853 Implementation details: For either this customer, or for each of this
1854 customer's open invoices, changes the status of the first "done" (with
1855 statustext error) realtime processing event to "failed".
1856
1857 =cut
1858
1859 sub retry_realtime {
1860   my $self = shift;
1861
1862   local $SIG{HUP} = 'IGNORE';
1863   local $SIG{INT} = 'IGNORE';
1864   local $SIG{QUIT} = 'IGNORE';
1865   local $SIG{TERM} = 'IGNORE';
1866   local $SIG{TSTP} = 'IGNORE';
1867   local $SIG{PIPE} = 'IGNORE';
1868
1869   my $oldAutoCommit = $FS::UID::AutoCommit;
1870   local $FS::UID::AutoCommit = 0;
1871   my $dbh = dbh;
1872
1873   #a little false laziness w/due_cust_event (not too bad, really)
1874
1875   # I guess this is always as of now?
1876   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1877   my $order = FS::part_event_condition->order_conditions_sql;
1878   my $mine =
1879   '( '
1880    . join ( ' OR ' , map {
1881     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1882     my $custnum = FS::part_event->eventtables_custnum->{$_};
1883     "( part_event.eventtable = " . dbh->quote($_)
1884     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1885     . " from $_ $cust_join"
1886     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1887    } FS::part_event->eventtables)
1888    . ') ';
1889
1890   #here is the agent virtualization
1891   my $agent_virt = " (    part_event.agentnum IS NULL
1892                        OR part_event.agentnum = ". $self->agentnum. ' )';
1893
1894   #XXX this shouldn't be hardcoded, actions should declare it...
1895   my @realtime_events = qw(
1896     cust_bill_realtime_card
1897     cust_bill_realtime_check
1898     cust_bill_realtime_lec
1899     cust_bill_batch
1900   );
1901
1902   my $is_realtime_event =
1903     ' part_event.action IN ( '.
1904         join(',', map "'$_'", @realtime_events ).
1905     ' ) ';
1906
1907   my $batch_or_statustext =
1908     "( part_event.action = 'cust_bill_batch'
1909        OR ( statustext IS NOT NULL AND statustext != '' )
1910      )";
1911
1912
1913   my @cust_event = qsearch({
1914     'table'     => 'cust_event',
1915     'select'    => 'cust_event.*',
1916     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1917     'hashref'   => { 'status' => 'done' },
1918     'extra_sql' => " AND $batch_or_statustext ".
1919                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1920   });
1921
1922   my %seen_invnum = ();
1923   foreach my $cust_event (@cust_event) {
1924
1925     #max one for the customer, one for each open invoice
1926     my $cust_X = $cust_event->cust_X;
1927     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1928                           ? $cust_X->invnum
1929                           : 0
1930                         }++
1931          or $cust_event->part_event->eventtable eq 'cust_bill'
1932             && ! $cust_X->owed;
1933
1934     my $error = $cust_event->retry;
1935     if ( $error ) {
1936       $dbh->rollback if $oldAutoCommit;
1937       return "error scheduling event for retry: $error";
1938     }
1939
1940   }
1941
1942   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1943   '';
1944
1945 }
1946
1947 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1948
1949 Runs billing events; see L<FS::part_event> and the billing events web
1950 interface.
1951
1952 If there is an error, returns the error, otherwise returns false.
1953
1954 Options are passed as name-value pairs.
1955
1956 Currently available options are:
1957
1958 =over 4
1959
1960 =item time
1961
1962 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1963
1964 =item check_freq
1965
1966 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1967
1968 =item stage
1969
1970 "collect" (the default) or "pre-bill"
1971
1972 =item quiet
1973
1974 set true to surpress email card/ACH decline notices.
1975
1976 =item debug
1977
1978 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1979
1980 =back
1981 =cut
1982
1983 # =item payby
1984 #
1985 # allows for one time override of normal customer billing method
1986
1987 # =item retry
1988 #
1989 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1990
1991 sub do_cust_event {
1992   my( $self, %options ) = @_;
1993
1994   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1995
1996   my $time = $options{'time'} || time;
1997
1998   #put below somehow?
1999   local $SIG{HUP} = 'IGNORE';
2000   local $SIG{INT} = 'IGNORE';
2001   local $SIG{QUIT} = 'IGNORE';
2002   local $SIG{TERM} = 'IGNORE';
2003   local $SIG{TSTP} = 'IGNORE';
2004   local $SIG{PIPE} = 'IGNORE';
2005
2006   my $oldAutoCommit = $FS::UID::AutoCommit;
2007   local $FS::UID::AutoCommit = 0;
2008   my $dbh = dbh;
2009
2010   $self->select_for_update; #mutex
2011
2012   if ( $DEBUG ) {
2013     my $balance = $self->balance;
2014     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
2015   }
2016
2017 #  if ( exists($options{'retry_card'}) ) {
2018 #    carp 'retry_card option passed to collect is deprecated; use retry';
2019 #    $options{'retry'} ||= $options{'retry_card'};
2020 #  }
2021 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
2022 #    my $error = $self->retry_realtime;
2023 #    if ( $error ) {
2024 #      $dbh->rollback if $oldAutoCommit;
2025 #      return $error;
2026 #    }
2027 #  }
2028
2029   # false laziness w/pay_batch::import_results
2030
2031   my $due_cust_event = $self->due_cust_event(
2032     'debug'      => ( $options{'debug'} || 0 ),
2033     'time'       => $time,
2034     'check_freq' => $options{'check_freq'},
2035     'stage'      => ( $options{'stage'} || 'collect' ),
2036   );
2037   unless( ref($due_cust_event) ) {
2038     $dbh->rollback if $oldAutoCommit;
2039     return $due_cust_event;
2040   }
2041
2042   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2043   #never want to roll back an event just because it or a different one
2044   # returned an error
2045   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
2046
2047   foreach my $cust_event ( @$due_cust_event ) {
2048
2049     #XXX lock event
2050
2051     #re-eval event conditions (a previous event could have changed things)
2052     unless ( $cust_event->test_conditions ) {
2053       #don't leave stray "new/locked" records around
2054       my $error = $cust_event->delete;
2055       return $error if $error;
2056       next;
2057     }
2058
2059     {
2060       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
2061         if $options{'quiet'};
2062       warn "  running cust_event ". $cust_event->eventnum. "\n"
2063         if $DEBUG > 1;
2064
2065       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
2066       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
2067         #XXX wtf is this?  figure out a proper dealio with return value
2068         #from do_event
2069         return $error;
2070       }
2071     }
2072
2073   }
2074
2075   '';
2076
2077 }
2078
2079 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
2080
2081 Inserts database records for and returns an ordered listref of new events due
2082 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
2083 events are due, an empty listref is returned.  If there is an error, returns a
2084 scalar error message.
2085
2086 To actually run the events, call each event's test_condition method, and if
2087 still true, call the event's do_event method.
2088
2089 Options are passed as a hashref or as a list of name-value pairs.  Available
2090 options are:
2091
2092 =over 4
2093
2094 =item check_freq
2095
2096 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
2097
2098 =item stage
2099
2100 "collect" (the default) or "pre-bill"
2101
2102 =item time
2103
2104 "Current time" for the events.
2105
2106 =item debug
2107
2108 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2109
2110 =item eventtable
2111
2112 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2113
2114 =item objects
2115
2116 Explicitly pass the objects to be tested (typically used with eventtable).
2117
2118 =item testonly
2119
2120 Set to true to return the objects, but not actually insert them into the
2121 database.
2122
2123 =back
2124
2125 =cut
2126
2127 sub due_cust_event {
2128   my $self = shift;
2129   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2130
2131   #???
2132   #my $DEBUG = $opt{'debug'}
2133   $opt{'debug'} ||= 0; # silence some warnings
2134   local($DEBUG) = $opt{'debug'}
2135     if $opt{'debug'} > $DEBUG;
2136   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2137
2138   warn "$me due_cust_event called with options ".
2139        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2140     if $DEBUG;
2141
2142   $opt{'time'} ||= time;
2143
2144   local $SIG{HUP} = 'IGNORE';
2145   local $SIG{INT} = 'IGNORE';
2146   local $SIG{QUIT} = 'IGNORE';
2147   local $SIG{TERM} = 'IGNORE';
2148   local $SIG{TSTP} = 'IGNORE';
2149   local $SIG{PIPE} = 'IGNORE';
2150
2151   my $oldAutoCommit = $FS::UID::AutoCommit;
2152   local $FS::UID::AutoCommit = 0;
2153   my $dbh = dbh;
2154
2155   $self->select_for_update #mutex
2156     unless $opt{testonly};
2157
2158   ###
2159   # find possible events (initial search)
2160   ###
2161
2162   my @cust_event = ();
2163
2164   my @eventtable = $opt{'eventtable'}
2165                      ? ( $opt{'eventtable'} )
2166                      : FS::part_event->eventtables_runorder;
2167
2168   my $check_freq = $opt{'check_freq'} || '1d';
2169
2170   foreach my $eventtable ( @eventtable ) {
2171
2172     my @objects;
2173     if ( $opt{'objects'} ) {
2174
2175       @objects = @{ $opt{'objects'} };
2176
2177     } elsif ( $eventtable eq 'cust_main' ) {
2178
2179       @objects = ( $self );
2180
2181     } else {
2182
2183       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2184       # linkage not needed here because FS::cust_main->$eventtable will
2185       # already supply it
2186
2187       #some false laziness w/Cron::bill bill_where
2188
2189       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2190         'time' => $opt{'time'});
2191       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2192         'time'=>$opt{'time'},
2193       );
2194       $where = $where ? "AND $where" : '';
2195
2196       my $are_part_event =
2197       "EXISTS ( SELECT 1 FROM part_event $join
2198         WHERE check_freq = '$check_freq'
2199         AND eventtable = '$eventtable'
2200         AND ( disabled = '' OR disabled IS NULL )
2201         $where
2202         )
2203       ";
2204       #eofalse
2205
2206       @objects = $self->$eventtable(
2207         'addl_from' => $cm_join,
2208         'extra_sql' => " AND $are_part_event",
2209       );
2210     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2211
2212     my @e_cust_event = ();
2213
2214     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2215
2216     my $cross = "CROSS JOIN $eventtable $linkage";
2217     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2218       unless $eventtable eq 'cust_main';
2219
2220     foreach my $object ( @objects ) {
2221
2222       #this first search uses the condition_sql magic for optimization.
2223       #the more possible events we can eliminate in this step the better
2224
2225       my $cross_where = '';
2226       my $pkey = $object->primary_key;
2227       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2228
2229       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2230         'time' => $opt{'time'});
2231       my $extra_sql =
2232         FS::part_event_condition->where_conditions_sql( $eventtable,
2233                                                         'time'=>$opt{'time'}
2234                                                       );
2235       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2236
2237       $extra_sql = "AND $extra_sql" if $extra_sql;
2238
2239       #here is the agent virtualization
2240       $extra_sql .= " AND (    part_event.agentnum IS NULL
2241                             OR part_event.agentnum = ". $self->agentnum. ' )';
2242
2243       $extra_sql .= " $order";
2244
2245       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2246         if $opt{'debug'} > 2;
2247       my @part_event = qsearch( {
2248         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2249         'select'    => 'part_event.*',
2250         'table'     => 'part_event',
2251         'addl_from' => "$cross $join",
2252         'hashref'   => { 'check_freq' => $check_freq,
2253                          'eventtable' => $eventtable,
2254                          'disabled'   => '',
2255                        },
2256         'extra_sql' => "AND $cross_where $extra_sql",
2257       } );
2258
2259       if ( $DEBUG > 2 ) {
2260         my $pkey = $object->primary_key;
2261         warn "      ". scalar(@part_event).
2262              " possible events found for $eventtable ". $object->$pkey(). "\n";
2263       }
2264
2265       push @e_cust_event, map {
2266         $_->new_cust_event($object, 'time' => $opt{'time'})
2267       } @part_event;
2268
2269     }
2270
2271     warn "    ". scalar(@e_cust_event).
2272          " subtotal possible cust events found for $eventtable\n"
2273       if $DEBUG > 1;
2274
2275     push @cust_event, @e_cust_event;
2276
2277   }
2278
2279   warn "  ". scalar(@cust_event).
2280        " total possible cust events found in initial search\n"
2281     if $DEBUG; # > 1;
2282
2283
2284   ##
2285   # test stage
2286   ##
2287
2288   $opt{stage} ||= 'collect';
2289   @cust_event =
2290     grep { my $stage = $_->part_event->event_stage;
2291            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2292          }
2293          @cust_event;
2294
2295   ##
2296   # test conditions
2297   ##
2298
2299   my %unsat = ();
2300
2301   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2302                      @cust_event;
2303
2304   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2305     if $DEBUG; # > 1;
2306
2307   warn "    invalid conditions not eliminated with condition_sql:\n".
2308        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2309     if keys %unsat && $DEBUG; # > 1;
2310
2311   ##
2312   # insert
2313   ##
2314
2315   unless( $opt{testonly} ) {
2316     foreach my $cust_event ( @cust_event ) {
2317
2318       my $error = $cust_event->insert();
2319       if ( $error ) {
2320         $dbh->rollback if $oldAutoCommit;
2321         return $error;
2322       }
2323
2324     }
2325   }
2326
2327   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2328
2329   ##
2330   # return
2331   ##
2332
2333   warn "  returning events: ". Dumper(@cust_event). "\n"
2334     if $DEBUG > 2;
2335
2336   \@cust_event;
2337
2338 }
2339
2340 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2341
2342 Applies unapplied payments and credits.
2343
2344 In most cases, this new method should be used in place of sequential
2345 apply_payments and apply_credits methods.
2346
2347 A hash of optional arguments may be passed.  Currently "manual" is supported.
2348 If true, a payment receipt is sent instead of a statement when
2349 'payment_receipt_email' configuration option is set.
2350
2351 If there is an error, returns the error, otherwise returns false.
2352
2353 =cut
2354
2355 sub apply_payments_and_credits {
2356   my( $self, %options ) = @_;
2357
2358   local $SIG{HUP} = 'IGNORE';
2359   local $SIG{INT} = 'IGNORE';
2360   local $SIG{QUIT} = 'IGNORE';
2361   local $SIG{TERM} = 'IGNORE';
2362   local $SIG{TSTP} = 'IGNORE';
2363   local $SIG{PIPE} = 'IGNORE';
2364
2365   my $oldAutoCommit = $FS::UID::AutoCommit;
2366   local $FS::UID::AutoCommit = 0;
2367   my $dbh = dbh;
2368
2369   $self->select_for_update; #mutex
2370
2371   foreach my $cust_bill ( $self->open_cust_bill ) {
2372     my $error = $cust_bill->apply_payments_and_credits(%options);
2373     if ( $error ) {
2374       $dbh->rollback if $oldAutoCommit;
2375       return "Error applying: $error";
2376     }
2377   }
2378
2379   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2380   ''; #no error
2381
2382 }
2383
2384 =item apply_credits OPTION => VALUE ...
2385
2386 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2387 to outstanding invoice balances in chronological order (or reverse
2388 chronological order if the I<order> option is set to B<newest>) and returns the
2389 value of any remaining unapplied credits available for refund (see
2390 L<FS::cust_refund>).
2391
2392 Dies if there is an error.
2393
2394 =cut
2395
2396 sub apply_credits {
2397   my $self = shift;
2398   my %opt = @_;
2399
2400   local $SIG{HUP} = 'IGNORE';
2401   local $SIG{INT} = 'IGNORE';
2402   local $SIG{QUIT} = 'IGNORE';
2403   local $SIG{TERM} = 'IGNORE';
2404   local $SIG{TSTP} = 'IGNORE';
2405   local $SIG{PIPE} = 'IGNORE';
2406
2407   my $oldAutoCommit = $FS::UID::AutoCommit;
2408   local $FS::UID::AutoCommit = 0;
2409   my $dbh = dbh;
2410
2411   $self->select_for_update; #mutex
2412
2413   unless ( $self->total_unapplied_credits ) {
2414     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2415     return 0;
2416   }
2417
2418   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2419       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2420
2421   my @invoices = $self->open_cust_bill;
2422   @invoices = sort { $b->_date <=> $a->_date } @invoices
2423     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2424
2425   if ( $conf->exists('pkg-balances') ) {
2426     # limit @credits to those w/ a pkgnum grepped from $self
2427     my %pkgnums = ();
2428     foreach my $i (@invoices) {
2429       foreach my $li ( $i->cust_bill_pkg ) {
2430         $pkgnums{$li->pkgnum} = 1;
2431       }
2432     }
2433     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2434   }
2435
2436   my $credit;
2437
2438   foreach my $cust_bill ( @invoices ) {
2439
2440     if ( !defined($credit) || $credit->credited == 0) {
2441       $credit = pop @credits or last;
2442     }
2443
2444     my $owed;
2445     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2446       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2447     } else {
2448       $owed = $cust_bill->owed;
2449     }
2450     unless ( $owed > 0 ) {
2451       push @credits, $credit;
2452       next;
2453     }
2454
2455     my $amount = min( $credit->credited, $owed );
2456
2457     my $cust_credit_bill = new FS::cust_credit_bill ( {
2458       'crednum' => $credit->crednum,
2459       'invnum'  => $cust_bill->invnum,
2460       'amount'  => $amount,
2461     } );
2462     $cust_credit_bill->pkgnum( $credit->pkgnum )
2463       if $conf->exists('pkg-balances') && $credit->pkgnum;
2464     my $error = $cust_credit_bill->insert;
2465     if ( $error ) {
2466       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2467       die $error;
2468     }
2469
2470     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2471
2472   }
2473
2474   my $total_unapplied_credits = $self->total_unapplied_credits;
2475
2476   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2477
2478   return $total_unapplied_credits;
2479 }
2480
2481 =item apply_payments  [ OPTION => VALUE ... ]
2482
2483 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2484 to outstanding invoice balances in chronological order.
2485
2486  #and returns the value of any remaining unapplied payments.
2487
2488 A hash of optional arguments may be passed.  Currently "manual" is supported.
2489 If true, a payment receipt is sent instead of a statement when
2490 'payment_receipt_email' configuration option is set.
2491
2492 Dies if there is an error.
2493
2494 =cut
2495
2496 sub apply_payments {
2497   my( $self, %options ) = @_;
2498
2499   local $SIG{HUP} = 'IGNORE';
2500   local $SIG{INT} = 'IGNORE';
2501   local $SIG{QUIT} = 'IGNORE';
2502   local $SIG{TERM} = 'IGNORE';
2503   local $SIG{TSTP} = 'IGNORE';
2504   local $SIG{PIPE} = 'IGNORE';
2505
2506   my $oldAutoCommit = $FS::UID::AutoCommit;
2507   local $FS::UID::AutoCommit = 0;
2508   my $dbh = dbh;
2509
2510   $self->select_for_update; #mutex
2511
2512   #return 0 unless
2513
2514   my @payments = $self->unapplied_cust_pay;
2515
2516   my @invoices = $self->open_cust_bill;
2517
2518   if ( $conf->exists('pkg-balances') ) {
2519     # limit @payments to those w/ a pkgnum grepped from $self
2520     my %pkgnums = ();
2521     foreach my $i (@invoices) {
2522       foreach my $li ( $i->cust_bill_pkg ) {
2523         $pkgnums{$li->pkgnum} = 1;
2524       }
2525     }
2526     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2527   }
2528
2529   my $payment;
2530
2531   foreach my $cust_bill ( @invoices ) {
2532
2533     if ( !defined($payment) || $payment->unapplied == 0 ) {
2534       $payment = pop @payments or last;
2535     }
2536
2537     my $owed;
2538     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2539       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2540     } else {
2541       $owed = $cust_bill->owed;
2542     }
2543     unless ( $owed > 0 ) {
2544       push @payments, $payment;
2545       next;
2546     }
2547
2548     my $amount = min( $payment->unapplied, $owed );
2549
2550     my $cbp = {
2551       'paynum' => $payment->paynum,
2552       'invnum' => $cust_bill->invnum,
2553       'amount' => $amount,
2554     };
2555     $cbp->{_date} = $payment->_date
2556         if $options{'manual'} && $options{'backdate_application'};
2557     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2558     $cust_bill_pay->pkgnum( $payment->pkgnum )
2559       if $conf->exists('pkg-balances') && $payment->pkgnum;
2560     my $error = $cust_bill_pay->insert(%options);
2561     if ( $error ) {
2562       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2563       die $error;
2564     }
2565
2566     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2567
2568   }
2569
2570   my $total_unapplied_payments = $self->total_unapplied_payments;
2571
2572   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2573
2574   return $total_unapplied_payments;
2575 }
2576
2577 =back
2578
2579 =head1 FLOW
2580
2581   bill_and_collect
2582
2583     cancel_expired_pkgs
2584     suspend_adjourned_pkgs
2585     unsuspend_resumed_pkgs
2586
2587     bill
2588       (do_cust_event pre-bill)
2589       _make_lines
2590         _handle_taxes
2591           (vendor-only) _gather_taxes
2592       _omit_zero_value_bundles
2593       _handle_taxes (for fees)
2594       calculate_taxes
2595
2596     apply_payments_and_credits
2597     collect
2598       do_cust_event
2599         due_cust_event
2600
2601 =head1 BUGS
2602
2603 =head1 SEE ALSO
2604
2605 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2606
2607 =cut
2608
2609 1;