FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use Tie::RefHash;
  12 use FS::cust_bill;
  13 use FS::cust_bill_pkg;
  14 use FS::cust_bill_pkg_display;
  15 use FS::cust_bill_pay;
  16 use FS::cust_credit_bill;
  17 use FS::cust_tax_adjustment;
  18 use FS::tax_rate;
  19 use FS::tax_rate_location;
  20 use FS::cust_bill_pkg_tax_location;
  21 use FS::cust_bill_pkg_tax_rate_location;
  22 use FS::part_event;
  23 use FS::part_event_condition;
  24 use FS::pkg_category;
  25 use FS::FeeOrigin_Mixin;
  26 use FS::Log;
  27
  28 # 1 is mostly method/subroutine entry and options
  29 # 2 traces progress of some operations
  30 # 3 is even more information including possibly sensitive data
  31 $DEBUG = 0;
  32 $me = '[FS::cust_main::Billing]';
  33
  34 install_callback FS::UID sub {
  35   $conf = new FS::Conf;
  36   #yes, need it for stuff below (prolly should be cached)
  37 };
  38
  39 =head1 NAME
  40
  41 FS::cust_main::Billing - Billing mixin for cust_main
  42
  43 =head1 SYNOPSIS
  44
  45 =head1 DESCRIPTION
  46
  47 These methods are available on FS::cust_main objects.
  48
  49 =head1 METHODS
  50
  51 =over 4
  52
  53 =item bill_and_collect
  54
  55 Cancels and suspends any packages due, generates bills, applies payments and
  56 credits, and applies collection events to run cards, send bills and notices,
  57 etc.
  58
  59 By default, warns on errors and continues with the next operation (but see the
  60 "fatal" flag below).
  61
  62 Options are passed as name-value pairs.  Currently available options are:
  63
  64 =over 4
  65
  66 =item time
  67
  68 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  69
  70  use Date::Parse;
  71  ...
  72  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  73
  74 =item invoice_time
  75
  76 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  77
  78 =item check_freq
  79
  80 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  81
  82 =item resetup
  83
  84 If set true, re-charges setup fees.
  85
  86 =item fatal
  87
  88 If set any errors prevent subsequent operations from continusing.  If set
  89 specifically to "return", returns the error (or false, if there is no error).
  90 Any other true value causes errors to die.
  91
  92 =item debug
  93
  94 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  95
  96 =item job
  97
  98 Optional FS::queue entry to receive status updates.
  99
 100 =back
 101
 102 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 103 options of those methods are also available.
 104
 105 =cut
 106
 107 sub bill_and_collect {
 108   my( $self, %options ) = @_;
 109
 110   my $log = FS::Log->new('FS::cust_main::Billing::bill_and_collect');
 111   my %logopt = (object => $self);
 112   $log->debug('start', %logopt);
 113
 114   my $error;
 115
 116   #$options{actual_time} not $options{time} because freeside-daily -d is for
 117   #pre-printing invoices
 118
 119   $options{'actual_time'} ||= time;
 120   my $job = $options{'job'};
 121
 122   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 123                         ? day_end( $options{actual_time} )
 124                         : $options{actual_time}
 125                     );
 126
 127   $job->update_statustext('0,cleaning expired packages') if $job;
 128   $log->debug('canceling expired packages', %logopt);
 129   $error = $self->cancel_expired_pkgs( $actual_time );
 130   if ( $error ) {
 131     $error = "Error expiring custnum ". $self->custnum. ": $error";
 132     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 133     elsif ( $options{fatal}                                ) { die    $error; }
 134     else                                                     { warn   $error; }
 135   }
 136
 137   $log->debug('suspending adjourned packages', %logopt);
 138   $error = $self->suspend_adjourned_pkgs( $actual_time );
 139   if ( $error ) {
 140     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 141     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 142     elsif ( $options{fatal}                                ) { die    $error; }
 143     else                                                     { warn   $error; }
 144   }
 145
 146   $log->debug('unsuspending resumed packages', %logopt);
 147   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 148   if ( $error ) {
 149     $error = "Error resuming custnum ".$self->custnum. ": $error";
 150     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 151     elsif ( $options{fatal}                                ) { die    $error; }
 152     else                                                     { warn   $error; }
 153   }
 154
 155   $job->update_statustext('20,billing packages') if $job;
 156   $log->debug('billing packages', %logopt);
 157   $error = $self->bill( %options );
 158   if ( $error ) {
 159     $error = "Error billing custnum ". $self->custnum. ": $error";
 160     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 161     elsif ( $options{fatal}                                ) { die    $error; }
 162     else                                                     { warn   $error; }
 163   }
 164
 165   $job->update_statustext('50,applying payments and credits') if $job;
 166   $log->debug('applying payments and credits', %logopt);
 167   $error = $self->apply_payments_and_credits;
 168   if ( $error ) {
 169     $error = "Error applying custnum ". $self->custnum. ": $error";
 170     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 171     elsif ( $options{fatal}                                ) { die    $error; }
 172     else                                                     { warn   $error; }
 173   }
 174
 175   unless ( $conf->exists('cancelled_cust-noevents')
 176            && ! $self->num_ncancelled_pkgs
 177   ) {
 178     $job->update_statustext('70,running collection events') if $job;
 179     $log->debug('running collection events', %logopt);
 180     $error = $self->collect( %options );
 181     if ( $error ) {
 182       $error = "Error collecting custnum ". $self->custnum. ": $error";
 183       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 184       elsif ($options{fatal}                               ) { die    $error; }
 185       else                                                   { warn   $error; }
 186     }
 187   }
 188
 189   $job->update_statustext('100,finished') if $job;
 190   $log->debug('finish', %logopt);
 191
 192   '';
 193
 194 }
 195
 196 sub cancel_expired_pkgs {
 197   my ( $self, $time, %options ) = @_;
 198
 199   my @cancel_pkgs = $self->ncancelled_pkgs( {
 200     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 201   } );
 202
 203   my @errors = ();
 204
 205   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 206     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 207     my $error;
 208
 209     if ( $cust_pkg->change_to_pkgnum ) {
 210
 211       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 212       if ( !$new_pkg ) {
 213         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 214                       $cust_pkg->change_to_pkgnum.'; not expiring';
 215         next CUST_PKG;
 216       }
 217       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 218                                   'unprotect_svcs'  => 1 );
 219       $error = '' if ref $error eq 'FS::cust_pkg';
 220
 221     } else { # just cancel it
 222        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 223                                            'reason_otaker' => $cpr->otaker,
 224                                            'time'          => $time,
 225                                          )
 226                                        : ()
 227                                  );
 228     }
 229     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 230   }
 231
 232   join(' / ', @errors);
 233
 234 }
 235
 236 sub suspend_adjourned_pkgs {
 237   my ( $self, $time, %options ) = @_;
 238
 239   my @susp_pkgs = $self->ncancelled_pkgs( {
 240     'extra_sql' =>
 241       " AND ( susp IS NULL OR susp = 0 )
 242         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 243               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 244             )
 245       ",
 246   } );
 247
 248   #only because there's no SQL test for is_prepaid :/
 249   @susp_pkgs =
 250     grep {     (    $_->part_pkg->is_prepaid
 251                  && $_->bill
 252                  && $_->bill < $time
 253                )
 254             || (    $_->adjourn
 255                  && $_->adjourn <= $time
 256                )
 257
 258          }
 259          @susp_pkgs;
 260
 261   my @errors = ();
 262
 263   foreach my $cust_pkg ( @susp_pkgs ) {
 264     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 265       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 266     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 267                                             'reason_otaker' => $cpr->otaker
 268                                           )
 269                                         : ()
 270                                   );
 271     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 272   }
 273
 274   join(' / ', @errors);
 275
 276 }
 277
 278 sub unsuspend_resumed_pkgs {
 279   my ( $self, $time, %options ) = @_;
 280
 281   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 282     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 283   } );
 284
 285   my @errors = ();
 286
 287   foreach my $cust_pkg ( @unsusp_pkgs ) {
 288     my $error = $cust_pkg->unsuspend( 'time' => $time );
 289     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 290   }
 291
 292   join(' / ', @errors);
 293
 294 }
 295
 296 =item bill OPTIONS
 297
 298 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 299 conjunction with the collect method by calling B<bill_and_collect>.
 300
 301 If there is an error, returns the error, otherwise returns false.
 302
 303 Options are passed as name-value pairs.  Currently available options are:
 304
 305 =over 4
 306
 307 =item resetup
 308
 309 If set true, re-charges setup fees.
 310
 311 =item recurring_only
 312
 313 If set true then only bill recurring charges, not setup, usage, one time
 314 charges, etc.
 315
 316 =item freq_override
 317
 318 If set, then override the normal frequency and look for a part_pkg_discount
 319 to take at that frequency.  This is appropriate only when the normal
 320 frequency for all packages is monthly, and is an error otherwise.  Use
 321 C<pkg_list> to limit the set of packages included in billing.
 322
 323 =item time
 324
 325 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 326
 327  use Date::Parse;
 328  ...
 329  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 330
 331 =item pkg_list
 332
 333 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 334
 335  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 336
 337 =item not_pkgpart
 338
 339 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 340
 341 =item no_prepaid
 342
 343 Do not bill prepaid packages.  Used by freeside-daily.
 344
 345 =item invoice_time
 346
 347 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 348
 349 =item cancel
 350
 351 This boolean value informs the us that the package is being cancelled.  This
 352 typically might mean not charging the normal recurring fee but only usage
 353 fees since the last billing. Setup charges may be charged.  Not all package
 354 plans support this feature (they tend to charge 0).
 355
 356 =item no_usage_reset
 357
 358 Prevent the resetting of usage limits during this call.
 359
 360 =item no_commit
 361
 362 Do not save the generated bill in the database.  Useful with return_bill
 363
 364 =item return_bill
 365
 366 A list reference on which the generated bill(s) will be returned.
 367
 368 =item invoice_terms
 369
 370 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 371 terms or the default terms are used.
 372
 373 =back
 374
 375 =cut
 376
 377 sub bill {
 378   my( $self, %options ) = @_;
 379
 380   return '' if $self->payby eq 'COMP';
 381
 382   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 383   my $log = FS::Log->new('FS::cust_main::Billing::bill');
 384   my %logopt = (object => $self);
 385
 386   $log->debug('start', %logopt);
 387   warn "$me bill customer ". $self->custnum. "\n"
 388     if $DEBUG;
 389
 390   my $time = $options{'time'} || time;
 391   my $invoice_time = $options{'invoice_time'} || $time;
 392
 393   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 394                      ? day_end( $time )
 395                      : $time
 396                  );
 397
 398   $options{'not_pkgpart'} ||= {};
 399   $options{'not_pkgpart'} = { map { $_ => 1 }
 400                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 401                             }
 402     unless ref($options{'not_pkgpart'});
 403
 404   local $SIG{HUP} = 'IGNORE';
 405   local $SIG{INT} = 'IGNORE';
 406   local $SIG{QUIT} = 'IGNORE';
 407   local $SIG{TERM} = 'IGNORE';
 408   local $SIG{TSTP} = 'IGNORE';
 409   local $SIG{PIPE} = 'IGNORE';
 410
 411   my $oldAutoCommit = $FS::UID::AutoCommit;
 412   local $FS::UID::AutoCommit = 0;
 413   my $dbh = dbh;
 414
 415   $log->debug('acquiring lock', %logopt);
 416   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 417     if $DEBUG;
 418
 419   $self->select_for_update; #mutex
 420
 421   $log->debug('running pre-bill events', %logopt);
 422   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 423     if $DEBUG;
 424
 425   my $error = $self->do_cust_event(
 426     'debug'      => ( $options{'debug'} || 0 ),
 427     'time'       => $invoice_time,
 428     'check_freq' => $options{'check_freq'},
 429     'stage'      => 'pre-bill',
 430   )
 431     unless $options{no_commit};
 432   if ( $error ) {
 433     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 434     return $error;
 435   }
 436
 437   $log->debug('done running pre-bill events', %logopt);
 438   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 439     if $DEBUG;
 440
 441   #keep auto-charge and non-auto-charge line items separate
 442   my @passes = ( '', 'no_auto' );
 443
 444   my %cust_bill_pkg = map { $_ => [] } @passes;
 445
 446   ###
 447   # find the packages which are due for billing, find out how much they are
 448   # & generate invoice database.
 449   ###
 450
 451   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 452   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 453
 454   my %taxlisthash = map { $_ => {} } @passes;
 455
 456   my @precommit_hooks = ();
 457
 458   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 459
 460   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 461
 462     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 463
 464     my $part_pkg = $cust_pkg->part_pkg;
 465
 466     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 467
 468     $log->debug('bill package '. $cust_pkg->pkgnum, %logopt);
 469     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 470
 471     #? to avoid use of uninitialized value errors... ?
 472     $cust_pkg->setfield('bill', '')
 473       unless defined($cust_pkg->bill);
 474
 475     my $real_pkgpart = $cust_pkg->pkgpart;
 476     my %hash = $cust_pkg->hash;
 477
 478     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 479     # suffer from performance issues
 480     $options{has_hidden} = 0;
 481     my @part_pkg = $part_pkg->self_and_bill_linked;
 482     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 483
 484     # if this package was changed from another package,
 485     # and it hasn't been billed since then,
 486     # and package balances are enabled,
 487     if ( $cust_pkg->change_pkgnum
 488         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 489         and $cust_pkg->change_date <  $invoice_time
 490       and $conf->exists('pkg-balances') )
 491     {
 492       # _transfer_balance will also create the appropriate credit
 493       my @transfer_items = $self->_transfer_balance($cust_pkg);
 494       # $part_pkg[0] is the "real" part_pkg
 495       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 496                   'no_auto' : '';
 497       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 498       # treating this as recur, just because most charges are recur...
 499       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 500
 501       # currently not considering separate_bill here, as it's for
 502       # one-time charges only
 503     }
 504
 505     foreach my $part_pkg ( @part_pkg ) {
 506
 507       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 508
 509       my $pass = '';
 510       if ( $cust_pkg->separate_bill ) {
 511         # if no_auto is also set, that's fine. we just need to not have
 512         # invoices that are both auto and no_auto, and since the package
 513         # gets an invoice all to itself, it will only be one or the other.
 514         $pass = $cust_pkg->pkgnum;
 515         if (!exists $cust_bill_pkg{$pass}) { # it may not exist yet
 516           push @passes, $pass;
 517           $total_setup{$pass} = do { my $z = 0; \$z };
 518           $total_recur{$pass} = do { my $z = 0; \$z };
 519           $taxlisthash{$pass} = {};
 520           $cust_bill_pkg{$pass} = [];
 521         }
 522       } elsif ( ($cust_pkg->no_auto || $part_pkg->no_auto) ) {
 523         $pass = 'no_auto';
 524       }
 525
 526       my $next_bill = $cust_pkg->getfield('bill') || 0;
 527       my $error;
 528       # let this run once if this is the last bill upon cancellation
 529       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 530         $error =
 531           $self->_make_lines( 'part_pkg'            => $part_pkg,
 532                               'cust_pkg'            => $cust_pkg,
 533                               'precommit_hooks'     => \@precommit_hooks,
 534                               'line_items'          => $cust_bill_pkg{$pass},
 535                               'setup'               => $total_setup{$pass},
 536                               'recur'               => $total_recur{$pass},
 537                               'tax_matrix'          => $taxlisthash{$pass},
 538                               'time'                => $time,
 539                               'real_pkgpart'        => $real_pkgpart,
 540                               'options'             => \%options,
 541                             );
 542
 543         # Stop if anything goes wrong
 544         last if $error;
 545
 546         # or if we're not incrementing the bill date.
 547         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 548
 549         # or if we're letting it run only once
 550         last if $options{cancel};
 551
 552         $next_bill = $cust_pkg->getfield('bill') || 0;
 553
 554         #stop if -o was passed to freeside-daily
 555         last if $options{'one_recur'};
 556       }
 557       if ($error) {
 558         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 559         return $error;
 560       }
 561
 562     } #foreach my $part_pkg
 563
 564   } #foreach my $cust_pkg
 565
 566   foreach my $pass (@passes) { # keys %cust_bill_pkg )
 567
 568     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 569
 570     warn "$me billing pass $pass\n"
 571            #.Dumper(\@cust_bill_pkg)."\n"
 572       if $DEBUG > 2;
 573
 574     ###
 575     # process fees
 576     ###
 577
 578     my @pending_fees = FS::FeeOrigin_Mixin->by_cust($self->custnum,
 579       hashref => { 'billpkgnum' => '' }
 580     );
 581     warn "$me found pending fees:\n".Dumper(\@pending_fees)."\n"
 582       if @pending_fees and $DEBUG > 1;
 583
 584     # determine whether to generate an invoice
 585     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 586
 587     foreach my $fee (@pending_fees) {
 588       $generate_bill = 1 unless $fee->nextbill;
 589     }
 590
 591     # don't create an invoice with no line items, or where the only line
 592     # items are fees that are supposed to be held until the next invoice
 593     next if !$generate_bill;
 594
 595     # calculate fees...
 596     my @fee_items;
 597     foreach my $fee_origin (@pending_fees) {
 598       my $part_fee = $fee_origin->part_fee;
 599
 600       # check whether the fee is applicable before doing anything expensive:
 601       #
 602       # if the fee def belongs to a different agent, don't charge the fee.
 603       # event conditions should prevent this, but just in case they don't,
 604       # skip the fee.
 605       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 606         warn "tried to charge fee#".$part_fee->feepart .
 607              " on customer#".$self->custnum." from a different agent.\n";
 608         next;
 609       }
 610       # also skip if it's disabled
 611       next if $part_fee->disabled eq 'Y';
 612
 613       # Decide which invoice to base the fee on.
 614       my $cust_bill = $fee_origin->cust_bill;
 615       if (!$cust_bill) {
 616         # Then link it to the current invoice. This isn't the real cust_bill
 617         # object that will be inserted--in particular there are no taxes yet.
 618         # If you want to charge a fee on the total invoice amount including
 619         # taxes, you have to put the fee on the next invoice.
 620         $cust_bill = FS::cust_bill->new({
 621             'custnum'       => $self->custnum,
 622             'cust_bill_pkg' => \@cust_bill_pkg,
 623             'charged'       => ${ $total_setup{$pass} } +
 624                                ${ $total_recur{$pass} },
 625         });
 626
 627         # If the origin is for a specific package, then only apply the fee to
 628         # line items from that package.
 629         if ( my $cust_pkg = $fee_origin->cust_pkg ) {
 630           my @charge_fee_on_item;
 631           my $charge_fee_on_amount = 0;
 632           foreach (@cust_bill_pkg) {
 633             if ($_->pkgnum == $cust_pkg->pkgnum) {
 634               push @charge_fee_on_item, $_;
 635               $charge_fee_on_amount += $_->setup + $_->recur;
 636             }
 637           }
 638           $cust_bill->set('cust_bill_pkg', \@charge_fee_on_item);
 639           $cust_bill->set('charged', $charge_fee_on_amount);
 640         }
 641
 642       } # $cust_bill is now set
 643       # calculate the fee
 644       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 645       # link this so that we can clear the marker on inserting the line item
 646       $fee_item->set('fee_origin', $fee_origin);
 647       push @fee_items, $fee_item;
 648
 649     }
 650
 651     # add fees to the invoice
 652     foreach my $fee_item (@fee_items) {
 653
 654       push @cust_bill_pkg, $fee_item;
 655       ${ $total_setup{$pass} } += $fee_item->setup;
 656       ${ $total_recur{$pass} } += $fee_item->recur;
 657
 658       my $part_fee = $fee_item->part_fee;
 659       my $fee_location = $self->ship_location; # I think?
 660
 661       my $error = $self->_handle_taxes(
 662         $taxlisthash{$pass},
 663         $fee_item,
 664         location => $fee_location
 665         # probably not right to pass cancel => 1 for fees
 666       );
 667       return $error if $error;
 668
 669     }
 670
 671     # XXX implementation of fees is supposed to make this go away...
 672     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 673            !$conf->exists('postal_invoice-recurring_only')
 674        )
 675     {
 676
 677       my $postal_pkg = $self->charge_postal_fee();
 678       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 679
 680         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 681         return "can't charge postal invoice fee for customer ".
 682           $self->custnum. ": $postal_pkg";
 683
 684       } elsif ( $postal_pkg ) {
 685
 686         my $real_pkgpart = $postal_pkg->pkgpart;
 687         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 688         # suffer from performance issues
 689         $options{has_hidden} = 0;
 690         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 691         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 692
 693         foreach my $part_pkg ( @part_pkg ) {
 694           my %postal_options = %options;
 695           delete $postal_options{cancel};
 696           my $error =
 697             $self->_make_lines( 'part_pkg'            => $part_pkg,
 698                                 'cust_pkg'            => $postal_pkg,
 699                                 'precommit_hooks'     => \@precommit_hooks,
 700                                 'line_items'          => \@cust_bill_pkg,
 701                                 'setup'               => $total_setup{$pass},
 702                                 'recur'               => $total_recur{$pass},
 703                                 'tax_matrix'          => $taxlisthash{$pass},
 704                                 'time'                => $time,
 705                                 'real_pkgpart'        => $real_pkgpart,
 706                                 'options'             => \%postal_options,
 707                               );
 708           if ($error) {
 709             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 710             return $error;
 711           }
 712         }
 713
 714         # it's silly to have a zero value postal_pkg, but....
 715         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 716
 717       }
 718
 719     }
 720
 721     my $listref_or_error =
 722       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 723
 724     unless ( ref( $listref_or_error ) ) {
 725       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 726       return $listref_or_error;
 727     }
 728
 729     foreach my $taxline ( @$listref_or_error ) {
 730       ${ $total_setup{$pass} } =
 731         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 732       push @cust_bill_pkg, $taxline;
 733     }
 734
 735     #add tax adjustments
 736     warn "adding tax adjustments...\n" if $DEBUG > 2;
 737     foreach my $cust_tax_adjustment (
 738       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 739                                        'billpkgnum' => '',
 740                                      }
 741              )
 742     ) {
 743
 744       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 745
 746       my $itemdesc = $cust_tax_adjustment->taxname;
 747       $itemdesc = '' if $itemdesc eq 'Tax';
 748
 749       push @cust_bill_pkg, new FS::cust_bill_pkg {
 750         'pkgnum'      => 0,
 751         'setup'       => $tax,
 752         'recur'       => 0,
 753         'sdate'       => '',
 754         'edate'       => '',
 755         'itemdesc'    => $itemdesc,
 756         'itemcomment' => $cust_tax_adjustment->comment,
 757         'cust_tax_adjustment' => $cust_tax_adjustment,
 758         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 759       };
 760
 761     }
 762
 763     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 764
 765     my $balance = $self->balance;
 766
 767     my $previous_bill = qsearchs({ 'table'     => 'cust_bill',
 768                                    'hashref'   => { custnum=>$self->custnum },
 769                                    'extra_sql' => 'ORDER BY _date DESC LIMIT 1',
 770                                 });
 771     my $previous_balance =
 772       $previous_bill
 773         ? ( $previous_bill->billing_balance + $previous_bill->charged )
 774         : 0;
 775
 776     $log->debug('creating the new invoice', %logopt);
 777     warn "creating the new invoice\n" if $DEBUG;
 778     #create the new invoice
 779     my $cust_bill = new FS::cust_bill ( {
 780       'custnum'             => $self->custnum,
 781       '_date'               => $invoice_time,
 782       'charged'             => $charged,
 783       'billing_balance'     => $balance,
 784       'previous_balance'    => $previous_balance,
 785       'invoice_terms'       => $options{'invoice_terms'},
 786       'cust_bill_pkg'       => \@cust_bill_pkg,
 787     } );
 788     $error = $cust_bill->insert unless $options{no_commit};
 789     if ( $error ) {
 790       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 791       return "can't create invoice for customer #". $self->custnum. ": $error";
 792     }
 793     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 794
 795   } #foreach my $pass ( keys %cust_bill_pkg )
 796
 797   foreach my $hook ( @precommit_hooks ) {
 798     eval {
 799       &{$hook}; #($self) ?
 800     } unless $options{no_commit};
 801     if ( $@ ) {
 802       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 803       return "$@ running precommit hook $hook\n";
 804     }
 805   }
 806
 807   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 808
 809   ''; #no error
 810 }
 811
 812 #discard bundled packages of 0 value
 813 sub _omit_zero_value_bundles {
 814   my @in = @_;
 815
 816   my @cust_bill_pkg = ();
 817   my @cust_bill_pkg_bundle = ();
 818   my $sum = 0;
 819   my $discount_show_always = 0;
 820
 821   foreach my $cust_bill_pkg ( @in ) {
 822
 823     $discount_show_always = ($cust_bill_pkg->get('discounts')
 824                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 825                                 && $conf->exists('discount-show-always'));
 826
 827     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 828          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 829          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 830       if $DEBUG > 0;
 831
 832     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 833       push @cust_bill_pkg, @cust_bill_pkg_bundle
 834         if $sum > 0
 835         || ($sum == 0 && (    $discount_show_always
 836                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 837                                    @cust_bill_pkg_bundle
 838                          )
 839            );
 840       @cust_bill_pkg_bundle = ();
 841       $sum = 0;
 842     }
 843
 844     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 845     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 846
 847   }
 848
 849   push @cust_bill_pkg, @cust_bill_pkg_bundle
 850     if $sum > 0
 851     || ($sum == 0 && (    $discount_show_always
 852                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 853                                @cust_bill_pkg_bundle
 854                      )
 855        );
 856
 857   warn "  _omit_zero_value_bundles: ". scalar(@in).
 858        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 859     if $DEBUG > 2;
 860
 861   (@cust_bill_pkg);
 862
 863 }
 864
 865 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 866
 867 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 868 Usually used internally by bill method B<bill>.
 869
 870 If there is an error, returns the error, otherwise returns reference to a
 871 list of line items suitable for insertion.
 872
 873 =over 4
 874
 875 =item LINEITEMREF
 876
 877 An array ref of the line items being billed.
 878
 879 =item TAXHASHREF
 880
 881 A strange beast.  The keys to this hash are internal identifiers consisting
 882 of the name of the tax object type, a space, and its unique identifier ( e.g.
 883  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 884 item in the list is the tax object.  The remaining items are either line
 885 items or floating point values (currency amounts).
 886
 887 The taxes are calculated on this entity.  Calculated exemption records are
 888 transferred to the LINEITEMREF items on the assumption that they are related.
 889
 890 Read the source.
 891
 892 =item INVOICE_TIME
 893
 894 This specifies the date appearing on the associated invoice.  Some
 895 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 896
 897 =back
 898
 899 =cut
 900
 901 sub calculate_taxes {
 902   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 903
 904   # $taxlisthash is a hashref
 905   # keys are identifiers, values are arrayrefs
 906   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 907   # then a cust_bill_pkg object the tax applies to, then the charge class
 908   # on that object (setup, recur, a usage class number, or '')
 909   # For internal taxes the charge class is always undef.
 910
 911   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 912
 913   warn "$me calculate_taxes\n"
 914        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 915     if $DEBUG > 2;
 916
 917   my $custnum = $self->custnum;
 918   # The main tax accumulator.  One bin for each tax name (itemdesc).
 919   # For each subdivision of tax under this name, push a cust_bill_pkg item
 920   # for the calculated tax into the arrayref.
 921   # keys are tax names
 922   # values are arrayrefs of tax lines
 923   my %taxname = ();
 924
 925   # keys are taxlisthash keys (internal identifiers)
 926   # values are (cumulative) amounts
 927   my %tax_amount = ();
 928
 929   # keys are taxlisthash keys
 930   # values are arrayrefs of cust_tax_exempt_pkg objects
 931   my %tax_exemption;
 932
 933   # For tax on tax calculation, we need to remember which taxable items
 934   # (and charge classes) had which taxes applied to them.
 935   #
 936   # keys are cust_bill_pkg objects (taxable items)
 937   # values are hashrefs
 938   #   keys are charge classes
 939   #   values are hashrefs
 940   #     keys are taxnums (in tax_rate only; cust_main_county doesn't use this)
 941   #     values are the taxlines generated for those taxes
 942   tie my %item_has_tax, 'Tie::RefHash',
 943     map { $_ => {} } @$cust_bill_pkg;
 944
 945   foreach my $tax_id ( keys %$taxlisthash ) {
 946     # $tax_id: the identifier of the tax we are calculating in this pass
 947
 948     my $taxables = $taxlisthash->{$tax_id};
 949     my $tax_object = shift @$taxables;
 950     my $taxnum = $tax_object->taxnum;
 951     # $tax_object is a cust_main_county or tax_rate
 952     # (with billpkgnum, pkgnum, locationnum set)
 953     # the rest of @{ $taxlisthash->{$tax_id} } is cust_bill_pkg objects,
 954     # optionally followed by their charge classes.
 955     warn "found ". $tax_object->taxname. " as $tax_id\n" if $DEBUG > 2;
 956
 957     # taxline calculates the tax on all cust_bill_pkgs in the
 958     # first (arrayref) argument.
 959     #
 960     # Note that non-monthly exemptions have already been calculated and
 961     # attached to the items.  Monthly exemptions will be attached in this
 962     # step.
 963     my $exemptions = $tax_exemption{$tax_id} ||= [];
 964     if ( $tax_object->isa('FS::tax_rate') ) { # EXTERNAL TAXES
 965       # STILL have tax_rate-specific crap in here...
 966       my @taxlines = $tax_object->taxline( $taxables,
 967                               'custnum'      => $custnum,
 968                               'invoice_time' => $invoice_time,
 969                               'exemptions'   => $exemptions,
 970                               );
 971       next if !@taxlines;
 972       if (!ref $taxlines[0]) {
 973         # it's an error string
 974         warn "error evaluating $tax_id on custnum $custnum\n";
 975         return $taxlines[0];
 976       }
 977       foreach my $taxline (@taxlines) {
 978         push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 979         my $link = $taxline->get('cust_bill_pkg_tax_rate_location')->[0];
 980         my $taxable_item = $link->taxable_cust_bill_pkg;
 981         $item_has_tax{$taxable_item}{$taxline->_class}{$taxnum} = $taxline;
 982       }
 983
 984     } else { # INTERNAL TAXES
 985       # we can do this in a single taxline, because it's not stupid
 986
 987       my $taxline =  $tax_object->taxline( $taxables,
 988                         'custnum'      => $custnum,
 989                         'invoice_time' => $invoice_time,
 990                         'exemptions'   => $exemptions,
 991                       );
 992       next if !$taxline;
 993       if (!ref $taxline) {
 994         # it's an error string
 995         warn "error evaluating $tax_id on custnum $custnum\n";
 996         return $taxline;
 997       }
 998       # if the calculated tax is zero, don't even keep it
 999       next if $taxline->setup < 0.001;
1000       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1001     }
1002   }
1003   $DB::single = 1; # XXX
1004
1005   # all first-tier taxes are calculated.  now for tax on tax:
1006
1007   foreach my $taxable_item ( @$cust_bill_pkg ) {
1008     # taxes that apply to this item
1009     my $this_has_tax = $item_has_tax{$taxable_item};
1010
1011     my $location = $taxable_item->tax_location;
1012
1013     foreach my $charge_class (keys %$this_has_tax) {
1014       # taxes that apply to this item and charge class
1015       my $this_class_has_tax = $this_has_tax->{$charge_class};
1016       foreach my $taxnum (keys %$this_class_has_tax) {
1017
1018         # for each tax item that was calculated in phase 1, get the
1019         # tax definition
1020         my $tax_object = FS::tax_rate->by_key($taxnum);
1021         # and find all taxes that apply to it in this location
1022         my @tot = $tax_object->tax_on_tax( $location );
1023         next if !@tot;
1024         warn "found possible taxed taxnum $taxnum\n"
1025           if $DEBUG > 2;
1026         # Calculate ToT separately for each taxable item and class, and only
1027         # if _that class on the item_ is already taxed under the ToT.  This is
1028         # counterintuitive.
1029         # See RT#5243 and RT#36380.
1030         foreach my $tot (@tot) {
1031           my $totnum = $tot->taxnum;
1032           warn "checking taxnum $totnum which we call ". $tot->taxname ."\n"
1033             if $DEBUG > 2;
1034           # note: if the _null class_ on this item is taxed under the ToT,
1035           # then this specific class is taxed also (because null class
1036           # includes all classes) and so ToT is applicable.
1037           if (
1038                 exists $this_class_has_tax->{ $totnum }
1039              or exists $this_has_tax->{''}{ $totnum }
1040           ) {
1041
1042             warn "calculating tax on tax: taxnum $totnum on $taxnum\n"
1043               if $DEBUG;
1044             my @taxlines = $tot->taxline(
1045                               $this_class_has_tax->{ $taxnum }, # the first-stage tax
1046                               'custnum'       => $custnum,
1047                               'invoice_time'  => $invoice_time,
1048                              );
1049             next if (!@taxlines); # it didn't apply after all
1050             if (!ref($taxlines[0])) {
1051               warn "error evaluating taxnum $totnum TOT on custnum $custnum\n";
1052               return $taxlines[0];
1053             }
1054             foreach my $taxline (@taxlines) {
1055               push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1056             }
1057           } # if $has_tax
1058         } # foreach my $tot (tax-on-tax rate definition)
1059       } # foreach $taxnum (first-tier rate definition)
1060     } # foreach $charge_class
1061   } # foreach $taxable_item
1062
1063   #consolidate and create tax line items
1064   warn "consolidating and generating...\n" if $DEBUG > 2;
1065   my %final_tax_items; # taxname => item
1066   foreach my $taxname ( keys %taxname ) {
1067     my @cust_bill_pkg_tax_location;
1068     my @cust_bill_pkg_tax_rate_location;
1069     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
1070         'pkgnum'    => 0,
1071         'recur'     => 0,
1072         'sdate'     => '',
1073         'edate'     => '',
1074         'itemdesc'  => $taxname,
1075         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
1076         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
1077     });
1078
1079     my $tax_total = 0;
1080     my %seen = ();
1081     warn "adding $taxname\n" if $DEBUG > 1;
1082     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
1083       next if $taxitem->get('setup') == 0;
1084       # if ( ref($taxitem) eq 'FS::cust_bill_pkg' )  # always true
1085       # then we need to transfer the amount and the links from the
1086       # line item to the new one we're creating.
1087       $tax_total += $taxitem->setup;
1088       my @links = @{
1089         $taxitem->get('cust_bill_pkg_tax_location') ||
1090         $taxitem->get('cust_bill_pkg_tax_rate_location') ||
1091         []
1092       };
1093       foreach my $link ( @links ) {
1094         $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
1095         if ($link->isa('FS::cust_bill_pkg_tax_location')) {
1096           push @cust_bill_pkg_tax_location, $link;
1097         } elsif ($link->isa('FS::cust_bill_pkg_tax_rate_location')) {
1098           push @cust_bill_pkg_tax_rate_location, $link;
1099         }
1100       }
1101     }
1102     next unless $tax_total;
1103
1104     # we should really neverround this up...I guess it's okay if taxline
1105     # already returns amounts with 2 decimal places
1106     $tax_total = sprintf('%.2f', $tax_total );
1107     $tax_cust_bill_pkg->set('setup', $tax_total);
1108
1109     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1110                                                    'disabled'     => '',
1111                                                  },
1112                                );
1113
1114     my @display = ();
1115     if ( $pkg_category and
1116          $conf->config('invoice_latexsummary') ||
1117          $conf->config('invoice_htmlsummary')
1118        )
1119     {
1120
1121       my %hash = (  'section' => $pkg_category->categoryname );
1122       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1123
1124     }
1125     $tax_cust_bill_pkg->set('display', \@display);
1126
1127     $final_tax_items{$taxname} = $tax_cust_bill_pkg;
1128   } # foreach $taxname
1129
1130   # fix ToT backlinks for taxes that have been consolidated
1131   # (has to be done in a separate pass)
1132   foreach my $tax_item (values %final_tax_items) {
1133     foreach my $taxable_link (@{ $tax_item->cust_bill_pkg_tax_rate_location }) {
1134       my $taxed_item = $taxable_link->taxable_cust_bill_pkg;
1135       next if $taxed_item->pkgnum > 0; # primary taxes
1136       my $taxname = $taxed_item->itemdesc;
1137       $taxable_link->set('taxable_cust_bill_pkg', $final_tax_items{ $taxname });
1138     }
1139   }
1140
1141   [ values %final_tax_items ]
1142 }
1143
1144 sub _make_lines {
1145   my ($self, %params) = @_;
1146
1147   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1148
1149   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1150   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1151   my $cust_location = $cust_pkg->tax_location;
1152   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1153   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1154   my $total_setup = $params{setup} or die "no setup accumulator specified";
1155   my $total_recur = $params{recur} or die "no recur accumulator specified";
1156   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1157   my $time = $params{'time'} or die "no time specified";
1158   my (%options) = %{$params{options}};
1159
1160   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1161     # this should never happen
1162     die 'freq_override billing attempted on non-monthly package '.
1163       $cust_pkg->pkgnum;
1164   }
1165
1166   my $dbh = dbh;
1167   my $real_pkgpart = $params{real_pkgpart};
1168   my %hash = $cust_pkg->hash;
1169   my $old_cust_pkg = new FS::cust_pkg \%hash;
1170
1171   my @details = ();
1172   my $lineitems = 0;
1173
1174   $cust_pkg->pkgpart($part_pkg->pkgpart);
1175
1176   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1177                      ? day_end( $time )
1178                      : $time
1179                  );
1180
1181   ###
1182   # bill setup
1183   ###
1184
1185   my $setup = 0;
1186   my $unitsetup = 0;
1187   my @setup_discounts = ();
1188   my %setup_param = ( 'discounts'    => \@setup_discounts,
1189                       'real_pkgpart' => $params{real_pkgpart}
1190                     );
1191   # Conditions for setting setup date and charging the setup fee:
1192   # - this is not a recurring-only billing run
1193   # - and the package is not currently being canceled
1194   # - and, unless we're specifically told otherwise via 'resetup':
1195   #   - it doesn't already HAVE a setup date
1196   #   - or a start date in the future
1197   #   - and it's not suspended
1198   #
1199   # The last condition used to check the "disable_setup_suspended" option but
1200   # that's obsolete. We now never set the setup date on a suspended package.
1201   if (     ! $options{recurring_only}
1202        and ! $options{cancel}
1203        and ( $options{'resetup'}
1204              || ( ! $cust_pkg->setup
1205                   && ( ! $cust_pkg->start_date
1206                        || $cust_pkg->start_date <= $cmp_time
1207                      )
1208                   && ( ! $cust_pkg->getfield('susp') )
1209               )
1210            )
1211      )
1212   {
1213
1214     warn "    bill setup\n" if $DEBUG > 1;
1215
1216     unless ( $cust_pkg->waive_setup ) {
1217         $lineitems++;
1218
1219         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1220         return "$@ running calc_setup for $cust_pkg\n"
1221           if $@;
1222
1223         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
1224     }
1225
1226     $cust_pkg->setfield('setup', $time)
1227       unless $cust_pkg->setup;
1228           #do need it, but it won't get written to the db
1229           #|| $cust_pkg->pkgpart != $real_pkgpart;
1230
1231     $cust_pkg->setfield('start_date', '')
1232       if $cust_pkg->start_date;
1233
1234   }
1235
1236   ###
1237   # bill recurring fee
1238   ###
1239
1240   my $recur = 0;
1241   my $unitrecur = 0;
1242   my @recur_discounts = ();
1243   my $sdate;
1244   if (     ! $cust_pkg->start_date
1245        and
1246            ( ! $cust_pkg->susp
1247                || ( $cust_pkg->susp != $cust_pkg->order_date
1248                       && (    $cust_pkg->option('suspend_bill',1)
1249                            || ( $part_pkg->option('suspend_bill', 1)
1250                                  && ! $cust_pkg->option('no_suspend_bill',1)
1251                               )
1252                          )
1253                   )
1254                || $cust_pkg->is_status_delay_cancel
1255            )
1256        and
1257             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1258          || ( $part_pkg->plan eq 'voip_cdr'
1259                && $part_pkg->option('bill_every_call')
1260             )
1261          || $options{cancel}
1262   ) {
1263
1264     # XXX should this be a package event?  probably.  events are called
1265     # at collection time at the moment, though...
1266     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1267       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1268       #don't want to reset usage just cause we want a line item??
1269       #&& $part_pkg->pkgpart == $real_pkgpart;
1270
1271     warn "    bill recur\n" if $DEBUG > 1;
1272     $lineitems++;
1273
1274     # XXX shared with $recur_prog
1275     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1276              || $cust_pkg->setup
1277              || $time;
1278
1279     #over two params!  lets at least switch to a hashref for the rest...
1280     my $increment_next_bill = ( $part_pkg->freq ne '0'
1281                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1282                                 && !$options{cancel}
1283                               );
1284     my %param = ( %setup_param,
1285                   'precommit_hooks'     => $precommit_hooks,
1286                   'increment_next_bill' => $increment_next_bill,
1287                   'discounts'           => \@recur_discounts,
1288                   'real_pkgpart'        => $real_pkgpart,
1289                   'freq_override'       => $options{freq_override} || '',
1290                   'setup_fee'           => 0,
1291                 );
1292
1293     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1294
1295     # There may be some part_pkg for which this is wrong.  Only those
1296     # which can_discount are supported.
1297     # (the UI should prevent adding discounts to these at the moment)
1298
1299     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1300          " for pkgpart ". $cust_pkg->pkgpart.
1301          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1302       if $DEBUG > 2;
1303
1304     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1305     return "$@ running $method for $cust_pkg\n"
1306       if ( $@ );
1307
1308     #base_cancel???
1309     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1310
1311     if ( $increment_next_bill ) {
1312
1313       my $next_bill;
1314
1315       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1316         # supplemental package
1317         # to keep in sync with the main package, simulate billing at
1318         # its frequency
1319         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1320         my $supp_pkg_freq = $part_pkg->freq;
1321         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1322         if ( $ratio != int($ratio) ) {
1323           # the UI should prevent setting up packages like this, but just
1324           # in case
1325           return "supplemental package period is not an integer multiple of main  package period";
1326         }
1327         $next_bill = $sdate;
1328         for (1..$ratio) {
1329           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1330         }
1331
1332       } else {
1333         # the normal case
1334       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1335       return "unparsable frequency: ". $part_pkg->freq
1336         if $next_bill == -1;
1337       }
1338
1339       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1340       # only for figuring next bill date, nothing else, so, reset $sdate again
1341       # here
1342       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1343       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1344       $cust_pkg->last_bill($sdate);
1345
1346       $cust_pkg->setfield('bill', $next_bill );
1347
1348     }
1349
1350     if ( $param{'setup_fee'} ) {
1351       # Add an additional setup fee at the billing stage.
1352       # Used for prorate_defer_bill.
1353       $setup += $param{'setup_fee'};
1354       $unitsetup += $param{'setup_fee'};
1355       $lineitems++;
1356     }
1357
1358     if ( defined $param{'discount_left_setup'} ) {
1359         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1360             $setup -= $discount_setup;
1361         }
1362     }
1363
1364   }
1365
1366   warn "\$setup is undefined" unless defined($setup);
1367   warn "\$recur is undefined" unless defined($recur);
1368   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1369
1370   ###
1371   # If there's line items, create em cust_bill_pkg records
1372   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1373   ###
1374
1375   if ( $lineitems ) {
1376
1377     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1378       # hmm.. and if just the options are modified in some weird price plan?
1379
1380       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1381         if $DEBUG >1;
1382
1383       my $error = $cust_pkg->replace( $old_cust_pkg,
1384                                       'depend_jobnum'=>$options{depend_jobnum},
1385                                       'options' => { $cust_pkg->options },
1386                                     )
1387         unless $options{no_commit};
1388       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1389         if $error; #just in case
1390     }
1391
1392     $setup = sprintf( "%.2f", $setup );
1393     $recur = sprintf( "%.2f", $recur );
1394     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1395       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1396     }
1397     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1398       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1399     }
1400
1401     my $discount_show_always = $conf->exists('discount-show-always')
1402                                && (    ($setup == 0 && scalar(@setup_discounts))
1403                                     || ($recur == 0 && scalar(@recur_discounts))
1404                                   );
1405
1406     if (    $setup != 0
1407          || $recur != 0
1408          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1409          || $discount_show_always
1410          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1411          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1412        )
1413     {
1414
1415       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1416         if $DEBUG > 1;
1417
1418       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1419       if ( $DEBUG > 1 ) {
1420         warn "      adding customer package invoice detail: $_\n"
1421           foreach @cust_pkg_detail;
1422       }
1423       push @details, @cust_pkg_detail;
1424
1425       my $cust_bill_pkg = new FS::cust_bill_pkg {
1426         'pkgnum'    => $cust_pkg->pkgnum,
1427         'setup'     => $setup,
1428         'unitsetup' => $unitsetup,
1429         'recur'     => $recur,
1430         'unitrecur' => $unitrecur,
1431         'quantity'  => $cust_pkg->quantity,
1432         'details'   => \@details,
1433         'discounts' => [ @setup_discounts, @recur_discounts ],
1434         'hidden'    => $part_pkg->hidden,
1435         'freq'      => $part_pkg->freq,
1436       };
1437
1438       if ( $part_pkg->option('prorate_defer_bill',1)
1439            and !$hash{last_bill} ) {
1440         # both preceding and upcoming, technically
1441         $cust_bill_pkg->sdate( $cust_pkg->setup );
1442         $cust_bill_pkg->edate( $cust_pkg->bill );
1443       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1444         $cust_bill_pkg->sdate( $hash{last_bill} );
1445         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1446         $cust_bill_pkg->edate( $time ) if $options{cancel};
1447       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1448         $cust_bill_pkg->sdate( $sdate );
1449         $cust_bill_pkg->edate( $cust_pkg->bill );
1450         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1451       }
1452
1453       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1454         unless $part_pkg->pkgpart == $real_pkgpart;
1455
1456       $$total_setup += $setup;
1457       $$total_recur += $recur;
1458
1459       ###
1460       # handle taxes
1461       ###
1462
1463       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg,
1464         cancel => $options{cancel} );
1465       return $error if $error;
1466
1467       $cust_bill_pkg->set_display(
1468         part_pkg     => $part_pkg,
1469         real_pkgpart => $real_pkgpart,
1470       );
1471
1472       push @$cust_bill_pkgs, $cust_bill_pkg;
1473
1474     } #if $setup != 0 || $recur != 0
1475
1476   } #if $line_items
1477
1478   '';
1479
1480 }
1481
1482 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1483
1484 Takes one argument, a cust_pkg object that is being billed.  This will
1485 be called only if the package was created by a package change, and has
1486 not been billed since the package change, and package balance tracking
1487 is enabled.  The second argument can be an alternate package number to
1488 transfer the balance from; this should not be used externally.
1489
1490 Transfers the balance from the previous package (now canceled) to
1491 this package, by crediting one package and creating an invoice item for
1492 the other.  Inserts the credit and returns the invoice item (so that it
1493 can be added to an invoice that's being built).
1494
1495 If the previous package was never billed, and was also created by a package
1496 change, then this will also transfer the balance from I<its> previous
1497 package, and so on, until reaching a package that either has been billed
1498 or was not created by a package change.
1499
1500 =cut
1501
1502 my $balance_transfer_reason;
1503
1504 sub _transfer_balance {
1505   my $self = shift;
1506   my $cust_pkg = shift;
1507   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1508   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1509
1510   my @transfers;
1511
1512   # if $from_pkg is not the first package in the chain, and it was never
1513   # billed, walk back
1514   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1515     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1516   }
1517
1518   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1519   if ( $prev_balance != 0 ) {
1520     $balance_transfer_reason ||= FS::reason->new_or_existing(
1521       'reason' => 'Package balance transfer',
1522       'type'   => 'Internal adjustment',
1523       'class'  => 'R'
1524     );
1525
1526     my $credit = FS::cust_credit->new({
1527         'custnum'   => $self->custnum,
1528         'amount'    => abs($prev_balance),
1529         'reasonnum' => $balance_transfer_reason->reasonnum,
1530         '_date'     => $cust_pkg->change_date,
1531     });
1532
1533     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1534         'setup'     => 0,
1535         'recur'     => abs($prev_balance),
1536         #'sdate'     => $from_pkg->last_bill, # not sure about this
1537         #'edate'     => $cust_pkg->change_date,
1538         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1539                                  $from_pkg->part_pkg->pkg),
1540     });
1541
1542     if ( $prev_balance > 0 ) {
1543       # credit the old package, charge the new one
1544       $credit->set('pkgnum', $from_pkgnum);
1545       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1546     } else {
1547       # the reverse
1548       $credit->set('pkgnum', $cust_pkg->pkgnum);
1549       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1550     }
1551     my $error = $credit->insert;
1552     die "error transferring package balance from #".$from_pkgnum.
1553         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1554
1555     push @transfers, $cust_bill_pkg;
1556   } # $prev_balance != 0
1557
1558   return @transfers;
1559 }
1560
1561 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1562
1563 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1564 from _make_lines.
1565
1566 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1567 this:
1568 {
1569   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1570   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1571 }
1572
1573 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1574 is always the cust_main_county or tax_rate identified by the key.
1575
1576 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1577 the 'taxline' method to calculate the amount of the tax.  This doesn't
1578 happen until calculate_taxes, though.
1579
1580 OPTIONS may include:
1581 - part_item: a part_pkg or part_fee object to be used as the package/fee
1582   definition.
1583 - location: a cust_location to be used as the billing location.
1584 - cancel: true if this package is being billed on cancellation.  This
1585   allows tax to be calculated on usage charges only.
1586
1587 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1588 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1589 the customer's default service location).
1590
1591 This method will also calculate exemptions for any taxes that apply to the
1592 line item (using the C<set_exemptions> method of L<FS::cust_bill_pkg>) and
1593 attach them.  This is the only place C<set_exemptions> is called in normal
1594 invoice processing.
1595
1596 =cut
1597
1598 sub _handle_taxes {
1599   my $self = shift;
1600   my $taxlisthash = shift;
1601   my $cust_bill_pkg = shift;
1602   my %options = @_;
1603
1604   # at this point I realize that we have enough information to infer all this
1605   # stuff, instead of passing around giant honking argument lists
1606   my $location = $options{location} || $cust_bill_pkg->tax_location;
1607   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1608
1609   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1610
1611   return if ( $self->payby eq 'COMP' ); #dubious
1612
1613   if ( $conf->exists('enable_taxproducts')
1614        && ( scalar($part_item->part_pkg_taxoverride)
1615             || $part_item->has_taxproduct
1616           )
1617      )
1618     {
1619
1620     # EXTERNAL TAX RATES (via tax_rate)
1621     my %cust_bill_pkg = ();
1622     my %taxes = ();
1623
1624     my @classes;
1625     my $usage = $cust_bill_pkg->usage || 0;
1626     push @classes, $cust_bill_pkg->usage_classes if $usage;
1627     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1628     push @classes, 'recur' if ($cust_bill_pkg->recur - $usage)
1629         and !$options{cancel};
1630     # that's better--probably don't even need $options{cancel} now
1631     # but leave it for now, just to be safe
1632     #
1633     # About $options{cancel}: This protects against charging per-line or
1634     # per-customer or other flat-rate surcharges on a package that's being
1635     # billed on cancellation (which is an out-of-cycle bill and should only
1636     # have usage charges).  See RT#29443.
1637
1638     # customer exemption is now handled in the 'taxline' method
1639     #my $exempt = $conf->exists('cust_class-tax_exempt')
1640     #               ? ( $self->cust_class ? $self->cust_class->tax : '' )
1641     #               : $self->tax;
1642     # standardize this just to be sure
1643     #$exempt = ($exempt eq 'Y') ? 'Y' : '';
1644     #
1645     #if ( !$exempt ) {
1646
1647     unless (exists $taxes{''}) {
1648       # unsure what purpose this serves, but last time I deleted something
1649       # from here just because I didn't see the point, it actually did
1650       # something important.
1651       my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1652       return $err_or_ref unless ref($err_or_ref);
1653       $taxes{''} = $err_or_ref;
1654     }
1655
1656     # NO DISINTEGRATIONS.
1657     # my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1658     #
1659     # do not call taxline() with any argument except the entire set of
1660     # cust_bill_pkgs on an invoice that are eligible for the tax.
1661
1662     # only calculate exemptions once for each tax rate, even if it's used
1663     # for multiple classes
1664     my %tax_seen = ();
1665
1666     foreach my $class (@classes) {
1667       my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1668       return $err_or_ref unless ref($err_or_ref);
1669       my @taxes = @$err_or_ref;
1670
1671       next if !@taxes;
1672
1673       foreach my $tax ( @taxes ) {
1674
1675         my $tax_id = ref( $tax ). ' '. $tax->taxnum;
1676         # $taxlisthash: keys are tax identifiers ('FS::tax_rate 123456').
1677         # Values are arrayrefs, first the tax object (cust_main_county
1678         # or tax_rate), then the cust_bill_pkg object that the
1679         # tax applies to, then the tax class (setup, recur, usage classnum).
1680         $taxlisthash->{ $tax_id } ||= [ $tax ];
1681         push @{ $taxlisthash->{ $tax_id  } }, $cust_bill_pkg, $class;
1682
1683         # determine any exemptions that apply
1684         if (!$tax_seen{$tax_id}) {
1685           $cust_bill_pkg->set_exemptions( $tax, custnum => $self->custnum );
1686           $tax_seen{$tax_id} = 1;
1687         }
1688
1689         # tax on tax will be done later, when we actually create the tax
1690         # line items
1691
1692       }
1693     }
1694
1695   } else {
1696
1697     # INTERNAL TAX RATES (cust_main_county)
1698
1699     # We fetch taxes even if the customer is completely exempt,
1700     # because we need to record that fact.
1701
1702     my @loc_keys = qw( district city county state country );
1703     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1704
1705     $taxhash{'taxclass'} = $part_item->taxclass;
1706
1707     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1708
1709     my @taxes = (); # entries are cust_main_county objects
1710     my %taxhash_elim = %taxhash;
1711     my @elim = qw( district city county state );
1712     do {
1713
1714       #first try a match with taxclass
1715       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1716
1717       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1718         #then try a match without taxclass
1719         my %no_taxclass = %taxhash_elim;
1720         $no_taxclass{ 'taxclass' } = '';
1721         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1722       }
1723
1724       $taxhash_elim{ shift(@elim) } = '';
1725
1726     } while ( !scalar(@taxes) && scalar(@elim) );
1727
1728     foreach (@taxes) {
1729       my $tax_id = 'cust_main_county '.$_->taxnum;
1730       $taxlisthash->{$tax_id} ||= [ $_ ];
1731       $cust_bill_pkg->set_exemptions($_, custnum => $self->custnum);
1732       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1733     }
1734
1735   }
1736   '';
1737 }
1738
1739 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1740
1741 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1742 or part_fee (which will define the tax eligibility of the product), CLASS is
1743 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1744 location where the service was provided (or billed, depending on
1745 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1746 can apply to this line item.
1747
1748 =cut
1749
1750 sub _gather_taxes {
1751   my $self = shift;
1752   my $part_item = shift;
1753   my $class = shift;
1754   my $location = shift;
1755
1756   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1757
1758   my $geocode = $location->geocode('cch');
1759
1760   [ $part_item->tax_rates('cch', $geocode, $class) ]
1761
1762 }
1763
1764 =item collect [ HASHREF | OPTION => VALUE ... ]
1765
1766 (Attempt to) collect money for this customer's outstanding invoices (see
1767 L<FS::cust_bill>).  Usually used after the bill method.
1768
1769 Actions are now triggered by billing events; see L<FS::part_event> and the
1770 billing events web interface.  Old-style invoice events (see
1771 L<FS::part_bill_event>) have been deprecated.
1772
1773 If there is an error, returns the error, otherwise returns false.
1774
1775 Options are passed as name-value pairs.
1776
1777 Currently available options are:
1778
1779 =over 4
1780
1781 =item invoice_time
1782
1783 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1784
1785 =item retry
1786
1787 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1788
1789 =item check_freq
1790
1791 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1792
1793 =item quiet
1794
1795 set true to surpress email card/ACH decline notices.
1796
1797 =item debug
1798
1799 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1800
1801 =back
1802
1803 # =item payby
1804 #
1805 # allows for one time override of normal customer billing method
1806
1807 =cut
1808
1809 sub collect {
1810   my( $self, %options ) = @_;
1811
1812   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1813
1814   my $invoice_time = $options{'invoice_time'} || time;
1815
1816   #put below somehow?
1817   local $SIG{HUP} = 'IGNORE';
1818   local $SIG{INT} = 'IGNORE';
1819   local $SIG{QUIT} = 'IGNORE';
1820   local $SIG{TERM} = 'IGNORE';
1821   local $SIG{TSTP} = 'IGNORE';
1822   local $SIG{PIPE} = 'IGNORE';
1823
1824   my $oldAutoCommit = $FS::UID::AutoCommit;
1825   local $FS::UID::AutoCommit = 0;
1826   my $dbh = dbh;
1827
1828   $self->select_for_update; #mutex
1829
1830   if ( $DEBUG ) {
1831     my $balance = $self->balance;
1832     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1833   }
1834
1835   if ( exists($options{'retry_card'}) ) {
1836     carp 'retry_card option passed to collect is deprecated; use retry';
1837     $options{'retry'} ||= $options{'retry_card'};
1838   }
1839   if ( exists($options{'retry'}) && $options{'retry'} ) {
1840     my $error = $self->retry_realtime;
1841     if ( $error ) {
1842       $dbh->rollback if $oldAutoCommit;
1843       return $error;
1844     }
1845   }
1846
1847   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1848
1849   #never want to roll back an event just because it returned an error
1850   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1851
1852   $self->do_cust_event(
1853     'debug'      => ( $options{'debug'} || 0 ),
1854     'time'       => $invoice_time,
1855     'check_freq' => $options{'check_freq'},
1856     'stage'      => 'collect',
1857   );
1858
1859 }
1860
1861 =item retry_realtime
1862
1863 Schedules realtime / batch  credit card / electronic check / LEC billing
1864 events for for retry.  Useful if card information has changed or manual
1865 retry is desired.  The 'collect' method must be called to actually retry
1866 the transaction.
1867
1868 Implementation details: For either this customer, or for each of this
1869 customer's open invoices, changes the status of the first "done" (with
1870 statustext error) realtime processing event to "failed".
1871
1872 =cut
1873
1874 sub retry_realtime {
1875   my $self = shift;
1876
1877   local $SIG{HUP} = 'IGNORE';
1878   local $SIG{INT} = 'IGNORE';
1879   local $SIG{QUIT} = 'IGNORE';
1880   local $SIG{TERM} = 'IGNORE';
1881   local $SIG{TSTP} = 'IGNORE';
1882   local $SIG{PIPE} = 'IGNORE';
1883
1884   my $oldAutoCommit = $FS::UID::AutoCommit;
1885   local $FS::UID::AutoCommit = 0;
1886   my $dbh = dbh;
1887
1888   #a little false laziness w/due_cust_event (not too bad, really)
1889
1890   # I guess this is always as of now?
1891   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1892   my $order = FS::part_event_condition->order_conditions_sql;
1893   my $mine =
1894   '( '
1895    . join ( ' OR ' , map {
1896     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1897     my $custnum = FS::part_event->eventtables_custnum->{$_};
1898     "( part_event.eventtable = " . dbh->quote($_)
1899     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1900     . " from $_ $cust_join"
1901     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1902    } FS::part_event->eventtables)
1903    . ') ';
1904
1905   #here is the agent virtualization
1906   my $agent_virt = " (    part_event.agentnum IS NULL
1907                        OR part_event.agentnum = ". $self->agentnum. ' )';
1908
1909   #XXX this shouldn't be hardcoded, actions should declare it...
1910   my @realtime_events = qw(
1911     cust_bill_realtime_card
1912     cust_bill_realtime_check
1913     cust_bill_realtime_lec
1914     cust_bill_batch
1915   );
1916
1917   my $is_realtime_event =
1918     ' part_event.action IN ( '.
1919         join(',', map "'$_'", @realtime_events ).
1920     ' ) ';
1921
1922   my $batch_or_statustext =
1923     "( part_event.action = 'cust_bill_batch'
1924        OR ( statustext IS NOT NULL AND statustext != '' )
1925      )";
1926
1927
1928   my @cust_event = qsearch({
1929     'table'     => 'cust_event',
1930     'select'    => 'cust_event.*',
1931     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1932     'hashref'   => { 'status' => 'done' },
1933     'extra_sql' => " AND $batch_or_statustext ".
1934                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1935   });
1936
1937   my %seen_invnum = ();
1938   foreach my $cust_event (@cust_event) {
1939
1940     #max one for the customer, one for each open invoice
1941     my $cust_X = $cust_event->cust_X;
1942     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1943                           ? $cust_X->invnum
1944                           : 0
1945                         }++
1946          or $cust_event->part_event->eventtable eq 'cust_bill'
1947             && ! $cust_X->owed;
1948
1949     my $error = $cust_event->retry;
1950     if ( $error ) {
1951       $dbh->rollback if $oldAutoCommit;
1952       return "error scheduling event for retry: $error";
1953     }
1954
1955   }
1956
1957   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1958   '';
1959
1960 }
1961
1962 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1963
1964 Runs billing events; see L<FS::part_event> and the billing events web
1965 interface.
1966
1967 If there is an error, returns the error, otherwise returns false.
1968
1969 Options are passed as name-value pairs.
1970
1971 Currently available options are:
1972
1973 =over 4
1974
1975 =item time
1976
1977 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1978
1979 =item check_freq
1980
1981 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1982
1983 =item stage
1984
1985 "collect" (the default) or "pre-bill"
1986
1987 =item quiet
1988
1989 set true to surpress email card/ACH decline notices.
1990
1991 =item debug
1992
1993 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1994
1995 =back
1996 =cut
1997
1998 # =item payby
1999 #
2000 # allows for one time override of normal customer billing method
2001
2002 # =item retry
2003 #
2004 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
2005
2006 sub do_cust_event {
2007   my( $self, %options ) = @_;
2008
2009   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2010
2011   my $time = $options{'time'} || time;
2012
2013   #put below somehow?
2014   local $SIG{HUP} = 'IGNORE';
2015   local $SIG{INT} = 'IGNORE';
2016   local $SIG{QUIT} = 'IGNORE';
2017   local $SIG{TERM} = 'IGNORE';
2018   local $SIG{TSTP} = 'IGNORE';
2019   local $SIG{PIPE} = 'IGNORE';
2020
2021   my $oldAutoCommit = $FS::UID::AutoCommit;
2022   local $FS::UID::AutoCommit = 0;
2023   my $dbh = dbh;
2024
2025   $self->select_for_update; #mutex
2026
2027   if ( $DEBUG ) {
2028     my $balance = $self->balance;
2029     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
2030   }
2031
2032 #  if ( exists($options{'retry_card'}) ) {
2033 #    carp 'retry_card option passed to collect is deprecated; use retry';
2034 #    $options{'retry'} ||= $options{'retry_card'};
2035 #  }
2036 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
2037 #    my $error = $self->retry_realtime;
2038 #    if ( $error ) {
2039 #      $dbh->rollback if $oldAutoCommit;
2040 #      return $error;
2041 #    }
2042 #  }
2043
2044   # false laziness w/pay_batch::import_results
2045
2046   my $due_cust_event = $self->due_cust_event(
2047     'debug'      => ( $options{'debug'} || 0 ),
2048     'time'       => $time,
2049     'check_freq' => $options{'check_freq'},
2050     'stage'      => ( $options{'stage'} || 'collect' ),
2051   );
2052   unless( ref($due_cust_event) ) {
2053     $dbh->rollback if $oldAutoCommit;
2054     return $due_cust_event;
2055   }
2056
2057   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2058   #never want to roll back an event just because it or a different one
2059   # returned an error
2060   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
2061
2062   foreach my $cust_event ( @$due_cust_event ) {
2063
2064     #XXX lock event
2065
2066     #re-eval event conditions (a previous event could have changed things)
2067     unless ( $cust_event->test_conditions ) {
2068       #don't leave stray "new/locked" records around
2069       my $error = $cust_event->delete;
2070       return $error if $error;
2071       next;
2072     }
2073
2074     {
2075       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
2076         if $options{'quiet'};
2077       warn "  running cust_event ". $cust_event->eventnum. "\n"
2078         if $DEBUG > 1;
2079
2080       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
2081       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
2082         #XXX wtf is this?  figure out a proper dealio with return value
2083         #from do_event
2084         return $error;
2085       }
2086     }
2087
2088   }
2089
2090   '';
2091
2092 }
2093
2094 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
2095
2096 Inserts database records for and returns an ordered listref of new events due
2097 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
2098 events are due, an empty listref is returned.  If there is an error, returns a
2099 scalar error message.
2100
2101 To actually run the events, call each event's test_condition method, and if
2102 still true, call the event's do_event method.
2103
2104 Options are passed as a hashref or as a list of name-value pairs.  Available
2105 options are:
2106
2107 =over 4
2108
2109 =item check_freq
2110
2111 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
2112
2113 =item stage
2114
2115 "collect" (the default) or "pre-bill"
2116
2117 =item time
2118
2119 "Current time" for the events.
2120
2121 =item debug
2122
2123 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2124
2125 =item eventtable
2126
2127 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2128
2129 =item objects
2130
2131 Explicitly pass the objects to be tested (typically used with eventtable).
2132
2133 =item testonly
2134
2135 Set to true to return the objects, but not actually insert them into the
2136 database.
2137
2138 =back
2139
2140 =cut
2141
2142 sub due_cust_event {
2143   my $self = shift;
2144   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2145
2146   #???
2147   #my $DEBUG = $opt{'debug'}
2148   $opt{'debug'} ||= 0; # silence some warnings
2149   local($DEBUG) = $opt{'debug'}
2150     if $opt{'debug'} > $DEBUG;
2151   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2152
2153   warn "$me due_cust_event called with options ".
2154        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2155     if $DEBUG;
2156
2157   $opt{'time'} ||= time;
2158
2159   local $SIG{HUP} = 'IGNORE';
2160   local $SIG{INT} = 'IGNORE';
2161   local $SIG{QUIT} = 'IGNORE';
2162   local $SIG{TERM} = 'IGNORE';
2163   local $SIG{TSTP} = 'IGNORE';
2164   local $SIG{PIPE} = 'IGNORE';
2165
2166   my $oldAutoCommit = $FS::UID::AutoCommit;
2167   local $FS::UID::AutoCommit = 0;
2168   my $dbh = dbh;
2169
2170   $self->select_for_update #mutex
2171     unless $opt{testonly};
2172
2173   ###
2174   # find possible events (initial search)
2175   ###
2176
2177   my @cust_event = ();
2178
2179   my @eventtable = $opt{'eventtable'}
2180                      ? ( $opt{'eventtable'} )
2181                      : FS::part_event->eventtables_runorder;
2182
2183   my $check_freq = $opt{'check_freq'} || '1d';
2184
2185   foreach my $eventtable ( @eventtable ) {
2186
2187     my @objects;
2188     if ( $opt{'objects'} ) {
2189
2190       @objects = @{ $opt{'objects'} };
2191
2192     } elsif ( $eventtable eq 'cust_main' ) {
2193
2194       @objects = ( $self );
2195
2196     } else {
2197
2198       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2199       # linkage not needed here because FS::cust_main->$eventtable will
2200       # already supply it
2201
2202       #some false laziness w/Cron::bill bill_where
2203
2204       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2205         'time' => $opt{'time'});
2206       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2207         'time'=>$opt{'time'},
2208       );
2209       $where = $where ? "AND $where" : '';
2210
2211       my $are_part_event =
2212       "EXISTS ( SELECT 1 FROM part_event $join
2213         WHERE check_freq = '$check_freq'
2214         AND eventtable = '$eventtable'
2215         AND ( disabled = '' OR disabled IS NULL )
2216         $where
2217         )
2218       ";
2219       #eofalse
2220
2221       @objects = $self->$eventtable(
2222         'addl_from' => $cm_join,
2223         'extra_sql' => " AND $are_part_event",
2224       );
2225     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2226
2227     my @e_cust_event = ();
2228
2229     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2230
2231     my $cross = "CROSS JOIN $eventtable $linkage";
2232     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2233       unless $eventtable eq 'cust_main';
2234
2235     foreach my $object ( @objects ) {
2236
2237       #this first search uses the condition_sql magic for optimization.
2238       #the more possible events we can eliminate in this step the better
2239
2240       my $cross_where = '';
2241       my $pkey = $object->primary_key;
2242       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2243
2244       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2245         'time' => $opt{'time'});
2246       my $extra_sql =
2247         FS::part_event_condition->where_conditions_sql( $eventtable,
2248                                                         'time'=>$opt{'time'}
2249                                                       );
2250       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2251
2252       $extra_sql = "AND $extra_sql" if $extra_sql;
2253
2254       #here is the agent virtualization
2255       $extra_sql .= " AND (    part_event.agentnum IS NULL
2256                             OR part_event.agentnum = ". $self->agentnum. ' )';
2257
2258       $extra_sql .= " $order";
2259
2260       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2261         if $opt{'debug'} > 2;
2262       my @part_event = qsearch( {
2263         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2264         'select'    => 'part_event.*',
2265         'table'     => 'part_event',
2266         'addl_from' => "$cross $join",
2267         'hashref'   => { 'check_freq' => $check_freq,
2268                          'eventtable' => $eventtable,
2269                          'disabled'   => '',
2270                        },
2271         'extra_sql' => "AND $cross_where $extra_sql",
2272       } );
2273
2274       if ( $DEBUG > 2 ) {
2275         my $pkey = $object->primary_key;
2276         warn "      ". scalar(@part_event).
2277              " possible events found for $eventtable ". $object->$pkey(). "\n";
2278       }
2279
2280       push @e_cust_event, map {
2281         $_->new_cust_event($object, 'time' => $opt{'time'})
2282       } @part_event;
2283
2284     }
2285
2286     warn "    ". scalar(@e_cust_event).
2287          " subtotal possible cust events found for $eventtable\n"
2288       if $DEBUG > 1;
2289
2290     push @cust_event, @e_cust_event;
2291
2292   }
2293
2294   warn "  ". scalar(@cust_event).
2295        " total possible cust events found in initial search\n"
2296     if $DEBUG; # > 1;
2297
2298
2299   ##
2300   # test stage
2301   ##
2302
2303   $opt{stage} ||= 'collect';
2304   @cust_event =
2305     grep { my $stage = $_->part_event->event_stage;
2306            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2307          }
2308          @cust_event;
2309
2310   ##
2311   # test conditions
2312   ##
2313
2314   my %unsat = ();
2315
2316   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2317                      @cust_event;
2318
2319   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2320     if $DEBUG; # > 1;
2321
2322   warn "    invalid conditions not eliminated with condition_sql:\n".
2323        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2324     if keys %unsat && $DEBUG; # > 1;
2325
2326   ##
2327   # insert
2328   ##
2329
2330   unless( $opt{testonly} ) {
2331     foreach my $cust_event ( @cust_event ) {
2332
2333       my $error = $cust_event->insert();
2334       if ( $error ) {
2335         $dbh->rollback if $oldAutoCommit;
2336         return $error;
2337       }
2338
2339     }
2340   }
2341
2342   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2343
2344   ##
2345   # return
2346   ##
2347
2348   warn "  returning events: ". Dumper(@cust_event). "\n"
2349     if $DEBUG > 2;
2350
2351   \@cust_event;
2352
2353 }
2354
2355 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2356
2357 Applies unapplied payments and credits.
2358
2359 In most cases, this new method should be used in place of sequential
2360 apply_payments and apply_credits methods.
2361
2362 A hash of optional arguments may be passed.  Currently "manual" is supported.
2363 If true, a payment receipt is sent instead of a statement when
2364 'payment_receipt_email' configuration option is set.
2365
2366 If there is an error, returns the error, otherwise returns false.
2367
2368 =cut
2369
2370 sub apply_payments_and_credits {
2371   my( $self, %options ) = @_;
2372
2373   local $SIG{HUP} = 'IGNORE';
2374   local $SIG{INT} = 'IGNORE';
2375   local $SIG{QUIT} = 'IGNORE';
2376   local $SIG{TERM} = 'IGNORE';
2377   local $SIG{TSTP} = 'IGNORE';
2378   local $SIG{PIPE} = 'IGNORE';
2379
2380   my $oldAutoCommit = $FS::UID::AutoCommit;
2381   local $FS::UID::AutoCommit = 0;
2382   my $dbh = dbh;
2383
2384   $self->select_for_update; #mutex
2385
2386   foreach my $cust_bill ( $self->open_cust_bill ) {
2387     my $error = $cust_bill->apply_payments_and_credits(%options);
2388     if ( $error ) {
2389       $dbh->rollback if $oldAutoCommit;
2390       return "Error applying: $error";
2391     }
2392   }
2393
2394   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2395   ''; #no error
2396
2397 }
2398
2399 =item apply_credits OPTION => VALUE ...
2400
2401 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2402 to outstanding invoice balances in chronological order (or reverse
2403 chronological order if the I<order> option is set to B<newest>) and returns the
2404 value of any remaining unapplied credits available for refund (see
2405 L<FS::cust_refund>).
2406
2407 Dies if there is an error.
2408
2409 =cut
2410
2411 sub apply_credits {
2412   my $self = shift;
2413   my %opt = @_;
2414
2415   local $SIG{HUP} = 'IGNORE';
2416   local $SIG{INT} = 'IGNORE';
2417   local $SIG{QUIT} = 'IGNORE';
2418   local $SIG{TERM} = 'IGNORE';
2419   local $SIG{TSTP} = 'IGNORE';
2420   local $SIG{PIPE} = 'IGNORE';
2421
2422   my $oldAutoCommit = $FS::UID::AutoCommit;
2423   local $FS::UID::AutoCommit = 0;
2424   my $dbh = dbh;
2425
2426   $self->select_for_update; #mutex
2427
2428   unless ( $self->total_unapplied_credits ) {
2429     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2430     return 0;
2431   }
2432
2433   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2434       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2435
2436   my @invoices = $self->open_cust_bill;
2437   @invoices = sort { $b->_date <=> $a->_date } @invoices
2438     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2439
2440   if ( $conf->exists('pkg-balances') ) {
2441     # limit @credits to those w/ a pkgnum grepped from $self
2442     my %pkgnums = ();
2443     foreach my $i (@invoices) {
2444       foreach my $li ( $i->cust_bill_pkg ) {
2445         $pkgnums{$li->pkgnum} = 1;
2446       }
2447     }
2448     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2449   }
2450
2451   my $credit;
2452
2453   foreach my $cust_bill ( @invoices ) {
2454
2455     if ( !defined($credit) || $credit->credited == 0) {
2456       $credit = pop @credits or last;
2457     }
2458
2459     my $owed;
2460     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2461       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2462     } else {
2463       $owed = $cust_bill->owed;
2464     }
2465     unless ( $owed > 0 ) {
2466       push @credits, $credit;
2467       next;
2468     }
2469
2470     my $amount = min( $credit->credited, $owed );
2471
2472     my $cust_credit_bill = new FS::cust_credit_bill ( {
2473       'crednum' => $credit->crednum,
2474       'invnum'  => $cust_bill->invnum,
2475       'amount'  => $amount,
2476     } );
2477     $cust_credit_bill->pkgnum( $credit->pkgnum )
2478       if $conf->exists('pkg-balances') && $credit->pkgnum;
2479     my $error = $cust_credit_bill->insert;
2480     if ( $error ) {
2481       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2482       die $error;
2483     }
2484
2485     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2486
2487   }
2488
2489   my $total_unapplied_credits = $self->total_unapplied_credits;
2490
2491   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2492
2493   return $total_unapplied_credits;
2494 }
2495
2496 =item apply_payments  [ OPTION => VALUE ... ]
2497
2498 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2499 to outstanding invoice balances in chronological order.
2500
2501  #and returns the value of any remaining unapplied payments.
2502
2503 A hash of optional arguments may be passed.  Currently "manual" is supported.
2504 If true, a payment receipt is sent instead of a statement when
2505 'payment_receipt_email' configuration option is set.
2506
2507 Dies if there is an error.
2508
2509 =cut
2510
2511 sub apply_payments {
2512   my( $self, %options ) = @_;
2513
2514   local $SIG{HUP} = 'IGNORE';
2515   local $SIG{INT} = 'IGNORE';
2516   local $SIG{QUIT} = 'IGNORE';
2517   local $SIG{TERM} = 'IGNORE';
2518   local $SIG{TSTP} = 'IGNORE';
2519   local $SIG{PIPE} = 'IGNORE';
2520
2521   my $oldAutoCommit = $FS::UID::AutoCommit;
2522   local $FS::UID::AutoCommit = 0;
2523   my $dbh = dbh;
2524
2525   $self->select_for_update; #mutex
2526
2527   #return 0 unless
2528
2529   my @payments = $self->unapplied_cust_pay;
2530
2531   my @invoices = $self->open_cust_bill;
2532
2533   if ( $conf->exists('pkg-balances') ) {
2534     # limit @payments to those w/ a pkgnum grepped from $self
2535     my %pkgnums = ();
2536     foreach my $i (@invoices) {
2537       foreach my $li ( $i->cust_bill_pkg ) {
2538         $pkgnums{$li->pkgnum} = 1;
2539       }
2540     }
2541     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2542   }
2543
2544   my $payment;
2545
2546   foreach my $cust_bill ( @invoices ) {
2547
2548     if ( !defined($payment) || $payment->unapplied == 0 ) {
2549       $payment = pop @payments or last;
2550     }
2551
2552     my $owed;
2553     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2554       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2555     } else {
2556       $owed = $cust_bill->owed;
2557     }
2558     unless ( $owed > 0 ) {
2559       push @payments, $payment;
2560       next;
2561     }
2562
2563     my $amount = min( $payment->unapplied, $owed );
2564
2565     my $cbp = {
2566       'paynum' => $payment->paynum,
2567       'invnum' => $cust_bill->invnum,
2568       'amount' => $amount,
2569     };
2570     $cbp->{_date} = $payment->_date
2571         if $options{'manual'} && $options{'backdate_application'};
2572     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2573     $cust_bill_pay->pkgnum( $payment->pkgnum )
2574       if $conf->exists('pkg-balances') && $payment->pkgnum;
2575     my $error = $cust_bill_pay->insert(%options);
2576     if ( $error ) {
2577       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2578       die $error;
2579     }
2580
2581     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2582
2583   }
2584
2585   my $total_unapplied_payments = $self->total_unapplied_payments;
2586
2587   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2588
2589   return $total_unapplied_payments;
2590 }
2591
2592 =back
2593
2594 =head1 FLOW
2595
2596   bill_and_collect
2597
2598     cancel_expired_pkgs
2599     suspend_adjourned_pkgs
2600     unsuspend_resumed_pkgs
2601
2602     bill
2603       (do_cust_event pre-bill)
2604       _make_lines
2605         _handle_taxes
2606           (vendor-only) _gather_taxes
2607       _omit_zero_value_bundles
2608       _handle_taxes (for fees)
2609       calculate_taxes
2610
2611     apply_payments_and_credits
2612     collect
2613       do_cust_event
2614         due_cust_event
2615
2616 =head1 BUGS
2617
2618 =head1 SEE ALSO
2619
2620 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2621
2622 =cut
2623
2624 1;