FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use FS::cust_bill;
  12 use FS::cust_bill_pkg;
  13 use FS::cust_bill_pkg_display;
  14 use FS::cust_bill_pay;
  15 use FS::cust_credit_bill;
  16 use FS::cust_tax_adjustment;
  17 use FS::tax_rate;
  18 use FS::tax_rate_location;
  19 use FS::cust_bill_pkg_tax_location;
  20 use FS::cust_bill_pkg_tax_rate_location;
  21 use FS::part_event;
  22 use FS::part_event_condition;
  23 use FS::pkg_category;
  24 use FS::cust_event_fee;
  25 use FS::Log;
  26
  27 # 1 is mostly method/subroutine entry and options
  28 # 2 traces progress of some operations
  29 # 3 is even more information including possibly sensitive data
  30 $DEBUG = 0;
  31 $me = '[FS::cust_main::Billing]';
  32
  33 install_callback FS::UID sub {
  34   $conf = new FS::Conf;
  35   #yes, need it for stuff below (prolly should be cached)
  36 };
  37
  38 =head1 NAME
  39
  40 FS::cust_main::Billing - Billing mixin for cust_main
  41
  42 =head1 SYNOPSIS
  43
  44 =head1 DESCRIPTION
  45
  46 These methods are available on FS::cust_main objects.
  47
  48 =head1 METHODS
  49
  50 =over 4
  51
  52 =item bill_and_collect
  53
  54 Cancels and suspends any packages due, generates bills, applies payments and
  55 credits, and applies collection events to run cards, send bills and notices,
  56 etc.
  57
  58 By default, warns on errors and continues with the next operation (but see the
  59 "fatal" flag below).
  60
  61 Options are passed as name-value pairs.  Currently available options are:
  62
  63 =over 4
  64
  65 =item time
  66
  67 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  68
  69  use Date::Parse;
  70  ...
  71  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  72
  73 =item invoice_time
  74
  75 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  76
  77 =item check_freq
  78
  79 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  80
  81 =item resetup
  82
  83 If set true, re-charges setup fees.
  84
  85 =item fatal
  86
  87 If set any errors prevent subsequent operations from continusing.  If set
  88 specifically to "return", returns the error (or false, if there is no error).
  89 Any other true value causes errors to die.
  90
  91 =item debug
  92
  93 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  94
  95 =item job
  96
  97 Optional FS::queue entry to receive status updates.
  98
  99 =back
 100
 101 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 102 options of those methods are also available.
 103
 104 =cut
 105
 106 sub bill_and_collect {
 107   my( $self, %options ) = @_;
 108
 109   my $log = FS::Log->new('bill_and_collect');
 110   $log->debug('start', object => $self, agentnum => $self->agentnum);
 111
 112   my $error;
 113
 114   #$options{actual_time} not $options{time} because freeside-daily -d is for
 115   #pre-printing invoices
 116
 117   $options{'actual_time'} ||= time;
 118   my $job = $options{'job'};
 119
 120   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 121                         ? day_end( $options{actual_time} )
 122                         : $options{actual_time}
 123                     );
 124
 125   $job->update_statustext('0,cleaning expired packages') if $job;
 126   $error = $self->cancel_expired_pkgs( $actual_time );
 127   if ( $error ) {
 128     $error = "Error expiring custnum ". $self->custnum. ": $error";
 129     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 130     elsif ( $options{fatal}                                ) { die    $error; }
 131     else                                                     { warn   $error; }
 132   }
 133
 134   $error = $self->suspend_adjourned_pkgs( $actual_time );
 135   if ( $error ) {
 136     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 137     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 138     elsif ( $options{fatal}                                ) { die    $error; }
 139     else                                                     { warn   $error; }
 140   }
 141
 142   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 143   if ( $error ) {
 144     $error = "Error resuming custnum ".$self->custnum. ": $error";
 145     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 146     elsif ( $options{fatal}                                ) { die    $error; }
 147     else                                                     { warn   $error; }
 148   }
 149
 150   $job->update_statustext('20,billing packages') if $job;
 151   $error = $self->bill( %options );
 152   if ( $error ) {
 153     $error = "Error billing custnum ". $self->custnum. ": $error";
 154     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 155     elsif ( $options{fatal}                                ) { die    $error; }
 156     else                                                     { warn   $error; }
 157   }
 158
 159   $job->update_statustext('50,applying payments and credits') if $job;
 160   $error = $self->apply_payments_and_credits;
 161   if ( $error ) {
 162     $error = "Error applying custnum ". $self->custnum. ": $error";
 163     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 164     elsif ( $options{fatal}                                ) { die    $error; }
 165     else                                                     { warn   $error; }
 166   }
 167
 168   $job->update_statustext('70,running collection events') if $job;
 169   unless ( $conf->exists('cancelled_cust-noevents')
 170            && ! $self->num_ncancelled_pkgs
 171   ) {
 172     $error = $self->collect( %options );
 173     if ( $error ) {
 174       $error = "Error collecting custnum ". $self->custnum. ": $error";
 175       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 176       elsif ($options{fatal}                               ) { die    $error; }
 177       else                                                   { warn   $error; }
 178     }
 179   }
 180   $job->update_statustext('100,finished') if $job;
 181   $log->debug('finish', object => $self, agentnum => $self->agentnum);
 182
 183   '';
 184
 185 }
 186
 187 sub cancel_expired_pkgs {
 188   my ( $self, $time, %options ) = @_;
 189
 190   my @cancel_pkgs = $self->ncancelled_pkgs( {
 191     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 192   } );
 193
 194   my @errors = ();
 195
 196   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 197     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 198     my $error;
 199
 200     if ( $cust_pkg->change_to_pkgnum ) {
 201
 202       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 203       if ( !$new_pkg ) {
 204         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 205                       $cust_pkg->change_to_pkgnum.'; not expiring';
 206         next CUST_PKG;
 207       }
 208       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 209                                   'unprotect_svcs'  => 1 );
 210       $error = '' if ref $error eq 'FS::cust_pkg';
 211
 212     } else { # just cancel it
 213        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 214                                            'reason_otaker' => $cpr->otaker,
 215                                            'time'          => $time,
 216                                          )
 217                                        : ()
 218                                  );
 219     }
 220     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 221   }
 222
 223   join(' / ', @errors);
 224
 225 }
 226
 227 sub suspend_adjourned_pkgs {
 228   my ( $self, $time, %options ) = @_;
 229
 230   my @susp_pkgs = $self->ncancelled_pkgs( {
 231     'extra_sql' =>
 232       " AND ( susp IS NULL OR susp = 0 )
 233         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 234               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 235             )
 236       ",
 237   } );
 238
 239   #only because there's no SQL test for is_prepaid :/
 240   @susp_pkgs =
 241     grep {     (    $_->part_pkg->is_prepaid
 242                  && $_->bill
 243                  && $_->bill < $time
 244                )
 245             || (    $_->adjourn
 246                  && $_->adjourn <= $time
 247                )
 248
 249          }
 250          @susp_pkgs;
 251
 252   my @errors = ();
 253
 254   foreach my $cust_pkg ( @susp_pkgs ) {
 255     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 256       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 257     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 258                                             'reason_otaker' => $cpr->otaker
 259                                           )
 260                                         : ()
 261                                   );
 262     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 263   }
 264
 265   join(' / ', @errors);
 266
 267 }
 268
 269 sub unsuspend_resumed_pkgs {
 270   my ( $self, $time, %options ) = @_;
 271
 272   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 273     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 274   } );
 275
 276   my @errors = ();
 277
 278   foreach my $cust_pkg ( @unsusp_pkgs ) {
 279     my $error = $cust_pkg->unsuspend( 'time' => $time );
 280     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 281   }
 282
 283   join(' / ', @errors);
 284
 285 }
 286
 287 =item bill OPTIONS
 288
 289 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 290 conjunction with the collect method by calling B<bill_and_collect>.
 291
 292 If there is an error, returns the error, otherwise returns false.
 293
 294 Options are passed as name-value pairs.  Currently available options are:
 295
 296 =over 4
 297
 298 =item resetup
 299
 300 If set true, re-charges setup fees.
 301
 302 =item recurring_only
 303
 304 If set true then only bill recurring charges, not setup, usage, one time
 305 charges, etc.
 306
 307 =item freq_override
 308
 309 If set, then override the normal frequency and look for a part_pkg_discount
 310 to take at that frequency.  This is appropriate only when the normal
 311 frequency for all packages is monthly, and is an error otherwise.  Use
 312 C<pkg_list> to limit the set of packages included in billing.
 313
 314 =item time
 315
 316 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 317
 318  use Date::Parse;
 319  ...
 320  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 321
 322 =item pkg_list
 323
 324 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 325
 326  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 327
 328 =item not_pkgpart
 329
 330 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 331
 332 =item no_prepaid
 333
 334 Do not bill prepaid packages.  Used by freeside-daily.
 335
 336 =item invoice_time
 337
 338 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 339
 340 =item cancel
 341
 342 This boolean value informs the us that the package is being cancelled.  This
 343 typically might mean not charging the normal recurring fee but only usage
 344 fees since the last billing. Setup charges may be charged.  Not all package
 345 plans support this feature (they tend to charge 0).
 346
 347 =item no_usage_reset
 348
 349 Prevent the resetting of usage limits during this call.
 350
 351 =item no_commit
 352
 353 Do not save the generated bill in the database.  Useful with return_bill
 354
 355 =item return_bill
 356
 357 A list reference on which the generated bill(s) will be returned.
 358
 359 =item invoice_terms
 360
 361 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 362 terms or the default terms are used.
 363
 364 =back
 365
 366 =cut
 367
 368 sub bill {
 369   my( $self, %options ) = @_;
 370
 371   return '' if $self->payby eq 'COMP';
 372
 373   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 374
 375   warn "$me bill customer ". $self->custnum. "\n"
 376     if $DEBUG;
 377
 378   my $time = $options{'time'} || time;
 379   my $invoice_time = $options{'invoice_time'} || $time;
 380
 381   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 382                      ? day_end( $time )
 383                      : $time
 384                  );
 385
 386   $options{'not_pkgpart'} ||= {};
 387   $options{'not_pkgpart'} = { map { $_ => 1 }
 388                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 389                             }
 390     unless ref($options{'not_pkgpart'});
 391
 392   local $SIG{HUP} = 'IGNORE';
 393   local $SIG{INT} = 'IGNORE';
 394   local $SIG{QUIT} = 'IGNORE';
 395   local $SIG{TERM} = 'IGNORE';
 396   local $SIG{TSTP} = 'IGNORE';
 397   local $SIG{PIPE} = 'IGNORE';
 398
 399   my $oldAutoCommit = $FS::UID::AutoCommit;
 400   local $FS::UID::AutoCommit = 0;
 401   my $dbh = dbh;
 402
 403   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 404     if $DEBUG;
 405
 406   $self->select_for_update; #mutex
 407
 408   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 409     if $DEBUG;
 410
 411   my $error = $self->do_cust_event(
 412     'debug'      => ( $options{'debug'} || 0 ),
 413     'time'       => $invoice_time,
 414     'check_freq' => $options{'check_freq'},
 415     'stage'      => 'pre-bill',
 416   )
 417     unless $options{no_commit};
 418   if ( $error ) {
 419     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 420     return $error;
 421   }
 422
 423   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 424     if $DEBUG;
 425
 426   #keep auto-charge and non-auto-charge line items separate
 427   my @passes = ( '', 'no_auto' );
 428
 429   my %cust_bill_pkg = map { $_ => [] } @passes;
 430
 431   ###
 432   # find the packages which are due for billing, find out how much they are
 433   # & generate invoice database.
 434   ###
 435
 436   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 437   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 438
 439   my %taxlisthash = map { $_ => {} } @passes;
 440
 441   my @precommit_hooks = ();
 442
 443   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 444
 445   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 446
 447     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 448
 449     my $part_pkg = $cust_pkg->part_pkg;
 450
 451     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 452
 453     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 454
 455     #? to avoid use of uninitialized value errors... ?
 456     $cust_pkg->setfield('bill', '')
 457       unless defined($cust_pkg->bill);
 458
 459     my $real_pkgpart = $cust_pkg->pkgpart;
 460     my %hash = $cust_pkg->hash;
 461
 462     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 463     # suffer from performance issues
 464     $options{has_hidden} = 0;
 465     my @part_pkg = $part_pkg->self_and_bill_linked;
 466     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 467
 468     # if this package was changed from another package,
 469     # and it hasn't been billed since then,
 470     # and package balances are enabled,
 471     if ( $cust_pkg->change_pkgnum
 472         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 473         and $cust_pkg->change_date <  $invoice_time
 474       and $conf->exists('pkg-balances') )
 475     {
 476       # _transfer_balance will also create the appropriate credit
 477       my @transfer_items = $self->_transfer_balance($cust_pkg);
 478       # $part_pkg[0] is the "real" part_pkg
 479       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 480                   'no_auto' : '';
 481       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 482       # treating this as recur, just because most charges are recur...
 483       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 484     }
 485
 486     foreach my $part_pkg ( @part_pkg ) {
 487
 488       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 489
 490       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 491
 492       my $next_bill = $cust_pkg->getfield('bill') || 0;
 493       my $error;
 494       # let this run once if this is the last bill upon cancellation
 495       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 496         $error =
 497           $self->_make_lines( 'part_pkg'            => $part_pkg,
 498                               'cust_pkg'            => $cust_pkg,
 499                               'precommit_hooks'     => \@precommit_hooks,
 500                               'line_items'          => $cust_bill_pkg{$pass},
 501                               'setup'               => $total_setup{$pass},
 502                               'recur'               => $total_recur{$pass},
 503                               'tax_matrix'          => $taxlisthash{$pass},
 504                               'time'                => $time,
 505                               'real_pkgpart'        => $real_pkgpart,
 506                               'options'             => \%options,
 507                             );
 508
 509         # Stop if anything goes wrong
 510         last if $error;
 511
 512         # or if we're not incrementing the bill date.
 513         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 514
 515         # or if we're letting it run only once
 516         last if $options{cancel};
 517
 518         $next_bill = $cust_pkg->getfield('bill') || 0;
 519
 520         #stop if -o was passed to freeside-daily
 521         last if $options{'one_recur'};
 522       }
 523       if ($error) {
 524         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 525         return $error;
 526       }
 527
 528     } #foreach my $part_pkg
 529
 530   } #foreach my $cust_pkg
 531
 532   #if the customer isn't on an automatic payby, everything can go on a single
 533   #invoice anyway?
 534   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 535     #merge everything into one list
 536   #}
 537
 538   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 539
 540     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 541
 542     warn "$me billing pass $pass\n"
 543            #.Dumper(\@cust_bill_pkg)."\n"
 544       if $DEBUG > 2;
 545
 546     ###
 547     # process fees
 548     ###
 549
 550     my @pending_event_fees = FS::cust_event_fee->by_cust($self->custnum,
 551       hashref => { 'billpkgnum' => '' }
 552     );
 553     warn "$me found pending fee events:\n".Dumper(\@pending_event_fees)."\n"
 554       if @pending_event_fees and $DEBUG > 1;
 555
 556     # determine whether to generate an invoice
 557     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 558
 559     foreach my $event_fee (@pending_event_fees) {
 560       $generate_bill = 1 unless $event_fee->nextbill;
 561     }
 562
 563     # don't create an invoice with no line items, or where the only line
 564     # items are fees that are supposed to be held until the next invoice
 565     next if !$generate_bill;
 566
 567     # calculate fees...
 568     my @fee_items;
 569     foreach my $event_fee (@pending_event_fees) {
 570       my $object = $event_fee->cust_event->cust_X;
 571       my $part_fee = $event_fee->part_fee;
 572       my $cust_bill;
 573       if ( $object->isa('FS::cust_main')
 574            or $object->isa('FS::cust_pkg')
 575            or $object->isa('FS::cust_pay_batch') )
 576       {
 577         # Not the real cust_bill object that will be inserted--in particular
 578         # there are no taxes yet.  If you want to charge a fee on the total
 579         # invoice amount including taxes, you have to put the fee on the next
 580         # invoice.
 581         $cust_bill = FS::cust_bill->new({
 582             'custnum'       => $self->custnum,
 583             'cust_bill_pkg' => \@cust_bill_pkg,
 584             'charged'       => ${ $total_setup{$pass} } +
 585                                ${ $total_recur{$pass} },
 586         });
 587
 588         # If this is a package event, only apply the fee to line items
 589         # from that package.
 590         if ($object->isa('FS::cust_pkg')) {
 591           $cust_bill->set('cust_bill_pkg',
 592             [ grep  { $_->pkgnum == $object->pkgnum } @cust_bill_pkg ]
 593           );
 594         }
 595
 596       } elsif ( $object->isa('FS::cust_bill') ) {
 597         # simple case: applying the fee to a previous invoice (late fee,
 598         # etc.)
 599         $cust_bill = $object;
 600       }
 601       # if the fee def belongs to a different agent, don't charge the fee.
 602       # event conditions should prevent this, but just in case they don't,
 603       # skip the fee.
 604       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 605         warn "tried to charge fee#".$part_fee->feepart .
 606              " on customer#".$self->custnum." from a different agent.\n";
 607         next;
 608       }
 609       # also skip if it's disabled
 610       next if $part_fee->disabled eq 'Y';
 611       # calculate the fee
 612       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 613       # link this so that we can clear the marker on inserting the line item
 614       $fee_item->set('cust_event_fee', $event_fee);
 615       push @fee_items, $fee_item;
 616
 617     }
 618
 619     # add fees to the invoice
 620     foreach my $fee_item (@fee_items) {
 621
 622       push @cust_bill_pkg, $fee_item;
 623       ${ $total_setup{$pass} } += $fee_item->setup;
 624       ${ $total_recur{$pass} } += $fee_item->recur;
 625
 626       my $part_fee = $fee_item->part_fee;
 627       my $fee_location = $self->ship_location; # I think?
 628
 629       my $error = $self->_handle_taxes(
 630         $taxlisthash{$pass},
 631         $fee_item,
 632         location => $fee_location
 633       );
 634       return $error if $error;
 635
 636     }
 637
 638     # XXX implementation of fees is supposed to make this go away...
 639     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 640            !$conf->exists('postal_invoice-recurring_only')
 641        )
 642     {
 643
 644       my $postal_pkg = $self->charge_postal_fee();
 645       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 646
 647         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 648         return "can't charge postal invoice fee for customer ".
 649           $self->custnum. ": $postal_pkg";
 650
 651       } elsif ( $postal_pkg ) {
 652
 653         my $real_pkgpart = $postal_pkg->pkgpart;
 654         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 655         # suffer from performance issues
 656         $options{has_hidden} = 0;
 657         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 658         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 659
 660         foreach my $part_pkg ( @part_pkg ) {
 661           my %postal_options = %options;
 662           delete $postal_options{cancel};
 663           my $error =
 664             $self->_make_lines( 'part_pkg'            => $part_pkg,
 665                                 'cust_pkg'            => $postal_pkg,
 666                                 'precommit_hooks'     => \@precommit_hooks,
 667                                 'line_items'          => \@cust_bill_pkg,
 668                                 'setup'               => $total_setup{$pass},
 669                                 'recur'               => $total_recur{$pass},
 670                                 'tax_matrix'          => $taxlisthash{$pass},
 671                                 'time'                => $time,
 672                                 'real_pkgpart'        => $real_pkgpart,
 673                                 'options'             => \%postal_options,
 674                               );
 675           if ($error) {
 676             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 677             return $error;
 678           }
 679         }
 680
 681         # it's silly to have a zero value postal_pkg, but....
 682         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 683
 684       }
 685
 686     }
 687
 688     my $listref_or_error =
 689       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 690
 691     unless ( ref( $listref_or_error ) ) {
 692       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 693       return $listref_or_error;
 694     }
 695
 696     foreach my $taxline ( @$listref_or_error ) {
 697       ${ $total_setup{$pass} } =
 698         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 699       push @cust_bill_pkg, $taxline;
 700     }
 701
 702     #add tax adjustments
 703     warn "adding tax adjustments...\n" if $DEBUG > 2;
 704     foreach my $cust_tax_adjustment (
 705       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 706                                        'billpkgnum' => '',
 707                                      }
 708              )
 709     ) {
 710
 711       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 712
 713       my $itemdesc = $cust_tax_adjustment->taxname;
 714       $itemdesc = '' if $itemdesc eq 'Tax';
 715
 716       push @cust_bill_pkg, new FS::cust_bill_pkg {
 717         'pkgnum'      => 0,
 718         'setup'       => $tax,
 719         'recur'       => 0,
 720         'sdate'       => '',
 721         'edate'       => '',
 722         'itemdesc'    => $itemdesc,
 723         'itemcomment' => $cust_tax_adjustment->comment,
 724         'cust_tax_adjustment' => $cust_tax_adjustment,
 725         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 726       };
 727
 728     }
 729
 730     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 731
 732     my @cust_bill = $self->cust_bill;
 733     my $balance = $self->balance;
 734     my $previous_bill = $cust_bill[-1] if @cust_bill;
 735     my $previous_balance = 0;
 736     if ( $previous_bill ) {
 737       $previous_balance = $previous_bill->billing_balance
 738                         + $previous_bill->charged;
 739     }
 740
 741     warn "creating the new invoice\n" if $DEBUG;
 742     #create the new invoice
 743     my $cust_bill = new FS::cust_bill ( {
 744       'custnum'             => $self->custnum,
 745       '_date'               => $invoice_time,
 746       'charged'             => $charged,
 747       'billing_balance'     => $balance,
 748       'previous_balance'    => $previous_balance,
 749       'invoice_terms'       => $options{'invoice_terms'},
 750       'cust_bill_pkg'       => \@cust_bill_pkg,
 751     } );
 752     $error = $cust_bill->insert unless $options{no_commit};
 753     if ( $error ) {
 754       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 755       return "can't create invoice for customer #". $self->custnum. ": $error";
 756     }
 757     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 758
 759   } #foreach my $pass ( keys %cust_bill_pkg )
 760
 761   foreach my $hook ( @precommit_hooks ) {
 762     eval {
 763       &{$hook}; #($self) ?
 764     } unless $options{no_commit};
 765     if ( $@ ) {
 766       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 767       return "$@ running precommit hook $hook\n";
 768     }
 769   }
 770
 771   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 772
 773   ''; #no error
 774 }
 775
 776 #discard bundled packages of 0 value
 777 sub _omit_zero_value_bundles {
 778   my @in = @_;
 779
 780   my @cust_bill_pkg = ();
 781   my @cust_bill_pkg_bundle = ();
 782   my $sum = 0;
 783   my $discount_show_always = 0;
 784
 785   foreach my $cust_bill_pkg ( @in ) {
 786
 787     $discount_show_always = ($cust_bill_pkg->get('discounts')
 788                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 789                                 && $conf->exists('discount-show-always'));
 790
 791     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 792          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 793          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 794       if $DEBUG > 0;
 795
 796     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 797       push @cust_bill_pkg, @cust_bill_pkg_bundle
 798         if $sum > 0
 799         || ($sum == 0 && (    $discount_show_always
 800                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 801                                    @cust_bill_pkg_bundle
 802                          )
 803            );
 804       @cust_bill_pkg_bundle = ();
 805       $sum = 0;
 806     }
 807
 808     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 809     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 810
 811   }
 812
 813   push @cust_bill_pkg, @cust_bill_pkg_bundle
 814     if $sum > 0
 815     || ($sum == 0 && (    $discount_show_always
 816                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 817                                @cust_bill_pkg_bundle
 818                      )
 819        );
 820
 821   warn "  _omit_zero_value_bundles: ". scalar(@in).
 822        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 823     if $DEBUG > 2;
 824
 825   (@cust_bill_pkg);
 826
 827 }
 828
 829 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 830
 831 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 832 Usually used internally by bill method B<bill>.
 833
 834 If there is an error, returns the error, otherwise returns reference to a
 835 list of line items suitable for insertion.
 836
 837 =over 4
 838
 839 =item LINEITEMREF
 840
 841 An array ref of the line items being billed.
 842
 843 =item TAXHASHREF
 844
 845 A strange beast.  The keys to this hash are internal identifiers consisting
 846 of the name of the tax object type, a space, and its unique identifier ( e.g.
 847  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 848 item in the list is the tax object.  The remaining items are either line
 849 items or floating point values (currency amounts).
 850
 851 The taxes are calculated on this entity.  Calculated exemption records are
 852 transferred to the LINEITEMREF items on the assumption that they are related.
 853
 854 Read the source.
 855
 856 =item INVOICE_TIME
 857
 858 This specifies the date appearing on the associated invoice.  Some
 859 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 860
 861 =back
 862
 863 =cut
 864
 865 sub calculate_taxes {
 866   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 867
 868   # $taxlisthash is a hashref
 869   # keys are identifiers, values are arrayrefs
 870   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 871   # then any cust_bill_pkg objects the tax applies to
 872
 873   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 874
 875   warn "$me calculate_taxes\n"
 876        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 877     if $DEBUG > 2;
 878
 879   my @tax_line_items = ();
 880
 881   # keys are tax names (as printed on invoices / itemdesc )
 882   # values are arrayrefs of taxlisthash keys (internal identifiers)
 883   my %taxname = ();
 884
 885   # keys are taxlisthash keys (internal identifiers)
 886   # values are (cumulative) amounts
 887   my %tax_amount = ();
 888
 889   # keys are taxlisthash keys (internal identifiers)
 890   # values are arrayrefs of cust_bill_pkg_tax_location hashrefs
 891   my %tax_location = ();
 892
 893   # keys are taxlisthash keys (internal identifiers)
 894   # values are arrayrefs of cust_bill_pkg_tax_rate_location hashrefs
 895   my %tax_rate_location = ();
 896
 897   # keys are taxlisthash keys (internal identifiers!)
 898   # values are arrayrefs of cust_tax_exempt_pkg objects
 899   my %tax_exemption;
 900
 901   foreach my $tax ( keys %$taxlisthash ) {
 902     # $tax is a tax identifier (intersection of a tax definition record
 903     # and a cust_bill_pkg record)
 904     my $tax_object = shift @{ $taxlisthash->{$tax} };
 905     # $tax_object is a cust_main_county or tax_rate
 906     # (with billpkgnum, pkgnum, locationnum set)
 907     # the rest of @{ $taxlisthash->{$tax} } is cust_bill_pkg component objects
 908     # (setup, recurring, usage classes)
 909     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 910     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 911     # taxline calculates the tax on all cust_bill_pkgs in the
 912     # first (arrayref) argument, and returns a hashref of 'name'
 913     # (the line item description) and 'amount'.
 914     # It also calculates exemptions and attaches them to the cust_bill_pkgs
 915     # in the argument.
 916     my $taxables = $taxlisthash->{$tax};
 917     my $exemptions = $tax_exemption{$tax} ||= [];
 918     my $taxline = $tax_object->taxline(
 919                             $taxables,
 920                             'custnum'      => $self->custnum,
 921                             'invoice_time' => $invoice_time,
 922                             'exemptions'   => $exemptions,
 923                           );
 924     return $taxline unless ref($taxline);
 925
 926     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 927
 928     if ( $tax_object->isa('FS::cust_main_county') ) {
 929       # then $taxline is a real line item
 930       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 931
 932     } else {
 933       # leave this as is for now
 934
 935       my $name   = $taxline->{'name'};
 936       my $amount = $taxline->{'amount'};
 937
 938       #warn "adding $amount as $name\n";
 939       $taxname{ $name } ||= [];
 940       push @{ $taxname{ $name } }, $tax;
 941
 942       $tax_amount{ $tax } += $amount;
 943
 944       # link records between cust_main_county/tax_rate and cust_location
 945       $tax_rate_location{ $tax } ||= [];
 946       my $taxratelocationnum =
 947         $tax_object->tax_rate_location->taxratelocationnum;
 948       push @{ $tax_rate_location{ $tax }  },
 949         {
 950           'taxnum'             => $tax_object->taxnum,
 951           'taxtype'            => ref($tax_object),
 952           'amount'             => sprintf('%.2f', $amount ),
 953           'locationtaxid'      => $tax_object->location,
 954           'taxratelocationnum' => $taxratelocationnum,
 955         };
 956     } #if ref($tax_object)...
 957   } #foreach keys %$taxlisthash
 958
 959   #consolidate and create tax line items
 960   warn "consolidating and generating...\n" if $DEBUG > 2;
 961   foreach my $taxname ( keys %taxname ) {
 962     my @cust_bill_pkg_tax_location;
 963     my @cust_bill_pkg_tax_rate_location;
 964     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
 965         'pkgnum'    => 0,
 966         'recur'     => 0,
 967         'sdate'     => '',
 968         'edate'     => '',
 969         'itemdesc'  => $taxname,
 970         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
 971         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 972     });
 973
 974     my $tax_total = 0;
 975     my %seen = ();
 976     warn "adding $taxname\n" if $DEBUG > 1;
 977     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 978       if ( ref($taxitem) eq 'FS::cust_bill_pkg' ) {
 979         # then we need to transfer the amount and the links from the
 980         # line item to the new one we're creating.
 981         $tax_total += $taxitem->setup;
 982         foreach my $link ( @{ $taxitem->get('cust_bill_pkg_tax_location') } ) {
 983           $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
 984           push @cust_bill_pkg_tax_location, $link;
 985         }
 986       } else {
 987         # the tax_rate way
 988         next if $seen{$taxitem}++;
 989         warn "adding $tax_amount{$taxitem}\n" if $DEBUG > 1;
 990         $tax_total += $tax_amount{$taxitem};
 991         push @cust_bill_pkg_tax_rate_location,
 992           map { new FS::cust_bill_pkg_tax_rate_location $_ }
 993               @{ $tax_rate_location{ $taxitem } };
 994       }
 995     }
 996     next unless $tax_total;
 997
 998     # we should really neverround this up...I guess it's okay if taxline
 999     # already returns amounts with 2 decimal places
1000     $tax_total = sprintf('%.2f', $tax_total );
1001     $tax_cust_bill_pkg->set('setup', $tax_total);
1002
1003     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1004                                                    'disabled'     => '',
1005                                                  },
1006                                );
1007
1008     my @display = ();
1009     if ( $pkg_category and
1010          $conf->config('invoice_latexsummary') ||
1011          $conf->config('invoice_htmlsummary')
1012        )
1013     {
1014
1015       my %hash = (  'section' => $pkg_category->categoryname );
1016       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1017
1018     }
1019     $tax_cust_bill_pkg->set('display', \@display);
1020
1021     push @tax_line_items, $tax_cust_bill_pkg;
1022   }
1023
1024   \@tax_line_items;
1025 }
1026
1027 sub _make_lines {
1028   my ($self, %params) = @_;
1029
1030   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1031
1032   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1033   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1034   my $cust_location = $cust_pkg->tax_location;
1035   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1036   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1037   my $total_setup = $params{setup} or die "no setup accumulator specified";
1038   my $total_recur = $params{recur} or die "no recur accumulator specified";
1039   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1040   my $time = $params{'time'} or die "no time specified";
1041   my (%options) = %{$params{options}};
1042
1043   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1044     # this should never happen
1045     die 'freq_override billing attempted on non-monthly package '.
1046       $cust_pkg->pkgnum;
1047   }
1048
1049   my $dbh = dbh;
1050   my $real_pkgpart = $params{real_pkgpart};
1051   my %hash = $cust_pkg->hash;
1052   my $old_cust_pkg = new FS::cust_pkg \%hash;
1053
1054   my @details = ();
1055   my $lineitems = 0;
1056
1057   $cust_pkg->pkgpart($part_pkg->pkgpart);
1058
1059   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1060                      ? day_end( $time )
1061                      : $time
1062                  );
1063
1064   ###
1065   # bill setup
1066   ###
1067
1068   my $setup = 0;
1069   my $unitsetup = 0;
1070   my @setup_discounts = ();
1071   my %setup_param = ( 'discounts' => \@setup_discounts );
1072   if (     ! $options{recurring_only}
1073        and ! $options{cancel}
1074        and ( $options{'resetup'}
1075              || ( ! $cust_pkg->setup
1076                   && ( ! $cust_pkg->start_date
1077                        || $cust_pkg->start_date <= $cmp_time
1078                      )
1079                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
1080                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
1081                             ! $cust_pkg->getfield('susp')
1082                           )
1083                      )
1084                 )
1085            )
1086      )
1087   {
1088
1089     warn "    bill setup\n" if $DEBUG > 1;
1090
1091     unless ( $cust_pkg->waive_setup ) {
1092         $lineitems++;
1093
1094         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1095         return "$@ running calc_setup for $cust_pkg\n"
1096           if $@;
1097
1098         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
1099     }
1100
1101     $cust_pkg->setfield('setup', $time)
1102       unless $cust_pkg->setup;
1103           #do need it, but it won't get written to the db
1104           #|| $cust_pkg->pkgpart != $real_pkgpart;
1105
1106     $cust_pkg->setfield('start_date', '')
1107       if $cust_pkg->start_date;
1108
1109   }
1110
1111   ###
1112   # bill recurring fee
1113   ###
1114
1115   my $recur = 0;
1116   my $unitrecur = 0;
1117   my @recur_discounts = ();
1118   my $sdate;
1119   if (     ! $cust_pkg->start_date
1120        and
1121            ( ! $cust_pkg->susp
1122                || ( $cust_pkg->susp != $cust_pkg->order_date
1123                       && (    $cust_pkg->option('suspend_bill',1)
1124                            || ( $part_pkg->option('suspend_bill', 1)
1125                                  && ! $cust_pkg->option('no_suspend_bill',1)
1126                               )
1127                          )
1128                   )
1129            )
1130        and
1131             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1132          || ( $part_pkg->plan eq 'voip_cdr'
1133                && $part_pkg->option('bill_every_call')
1134             )
1135          || $options{cancel}
1136   ) {
1137
1138     # XXX should this be a package event?  probably.  events are called
1139     # at collection time at the moment, though...
1140     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1141       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1142       #don't want to reset usage just cause we want a line item??
1143       #&& $part_pkg->pkgpart == $real_pkgpart;
1144
1145     warn "    bill recur\n" if $DEBUG > 1;
1146     $lineitems++;
1147
1148     # XXX shared with $recur_prog
1149     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1150              || $cust_pkg->setup
1151              || $time;
1152
1153     #over two params!  lets at least switch to a hashref for the rest...
1154     my $increment_next_bill = ( $part_pkg->freq ne '0'
1155                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1156                                 && !$options{cancel}
1157                               );
1158     my %param = ( %setup_param,
1159                   'precommit_hooks'     => $precommit_hooks,
1160                   'increment_next_bill' => $increment_next_bill,
1161                   'discounts'           => \@recur_discounts,
1162                   'real_pkgpart'        => $real_pkgpart,
1163                   'freq_override'       => $options{freq_override} || '',
1164                   'setup_fee'           => 0,
1165                 );
1166
1167     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1168
1169     # There may be some part_pkg for which this is wrong.  Only those
1170     # which can_discount are supported.
1171     # (the UI should prevent adding discounts to these at the moment)
1172
1173     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1174          " for pkgpart ". $cust_pkg->pkgpart.
1175          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1176       if $DEBUG > 2;
1177
1178     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1179     return "$@ running $method for $cust_pkg\n"
1180       if ( $@ );
1181
1182     #base_cancel???
1183     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1184
1185     if ( $increment_next_bill ) {
1186
1187       my $next_bill;
1188
1189       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1190         # supplemental package
1191         # to keep in sync with the main package, simulate billing at
1192         # its frequency
1193         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1194         my $supp_pkg_freq = $part_pkg->freq;
1195         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1196         if ( $ratio != int($ratio) ) {
1197           # the UI should prevent setting up packages like this, but just
1198           # in case
1199           return "supplemental package period is not an integer multiple of main  package period";
1200         }
1201         $next_bill = $sdate;
1202         for (1..$ratio) {
1203           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1204         }
1205
1206       } else {
1207         # the normal case
1208       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1209       return "unparsable frequency: ". $part_pkg->freq
1210         if $next_bill == -1;
1211       }
1212
1213       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1214       # only for figuring next bill date, nothing else, so, reset $sdate again
1215       # here
1216       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1217       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1218       $cust_pkg->last_bill($sdate);
1219
1220       $cust_pkg->setfield('bill', $next_bill );
1221
1222     }
1223
1224     if ( $param{'setup_fee'} ) {
1225       # Add an additional setup fee at the billing stage.
1226       # Used for prorate_defer_bill.
1227       $setup += $param{'setup_fee'};
1228       $unitsetup += $param{'setup_fee'};
1229       $lineitems++;
1230     }
1231
1232     if ( defined $param{'discount_left_setup'} ) {
1233         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1234             $setup -= $discount_setup;
1235         }
1236     }
1237
1238   }
1239
1240   warn "\$setup is undefined" unless defined($setup);
1241   warn "\$recur is undefined" unless defined($recur);
1242   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1243
1244   ###
1245   # If there's line items, create em cust_bill_pkg records
1246   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1247   ###
1248
1249   if ( $lineitems ) {
1250
1251     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1252       # hmm.. and if just the options are modified in some weird price plan?
1253
1254       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1255         if $DEBUG >1;
1256
1257       my $error = $cust_pkg->replace( $old_cust_pkg,
1258                                       'depend_jobnum'=>$options{depend_jobnum},
1259                                       'options' => { $cust_pkg->options },
1260                                     )
1261         unless $options{no_commit};
1262       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1263         if $error; #just in case
1264     }
1265
1266     $setup = sprintf( "%.2f", $setup );
1267     $recur = sprintf( "%.2f", $recur );
1268     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1269       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1270     }
1271     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1272       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1273     }
1274
1275     my $discount_show_always = $conf->exists('discount-show-always')
1276                                && (    ($setup == 0 && scalar(@setup_discounts))
1277                                     || ($recur == 0 && scalar(@recur_discounts))
1278                                   );
1279
1280     if (    $setup != 0
1281          || $recur != 0
1282          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1283          || $discount_show_always
1284          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1285          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1286        )
1287     {
1288
1289       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1290         if $DEBUG > 1;
1291
1292       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1293       if ( $DEBUG > 1 ) {
1294         warn "      adding customer package invoice detail: $_\n"
1295           foreach @cust_pkg_detail;
1296       }
1297       push @details, @cust_pkg_detail;
1298
1299       my $cust_bill_pkg = new FS::cust_bill_pkg {
1300         'pkgnum'    => $cust_pkg->pkgnum,
1301         'setup'     => $setup,
1302         'unitsetup' => $unitsetup,
1303         'recur'     => $recur,
1304         'unitrecur' => $unitrecur,
1305         'quantity'  => $cust_pkg->quantity,
1306         'details'   => \@details,
1307         'discounts' => [ @setup_discounts, @recur_discounts ],
1308         'hidden'    => $part_pkg->hidden,
1309         'freq'      => $part_pkg->freq,
1310       };
1311
1312       if ( $part_pkg->option('prorate_defer_bill',1)
1313            and !$hash{last_bill} ) {
1314         # both preceding and upcoming, technically
1315         $cust_bill_pkg->sdate( $cust_pkg->setup );
1316         $cust_bill_pkg->edate( $cust_pkg->bill );
1317       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1318         $cust_bill_pkg->sdate( $hash{last_bill} );
1319         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1320         $cust_bill_pkg->edate( $time ) if $options{cancel};
1321       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1322         $cust_bill_pkg->sdate( $sdate );
1323         $cust_bill_pkg->edate( $cust_pkg->bill );
1324         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1325       }
1326
1327       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1328         unless $part_pkg->pkgpart == $real_pkgpart;
1329
1330       $$total_setup += $setup;
1331       $$total_recur += $recur;
1332
1333       ###
1334       # handle taxes
1335       ###
1336
1337       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg );
1338       return $error if $error;
1339
1340       $cust_bill_pkg->set_display(
1341         part_pkg     => $part_pkg,
1342         real_pkgpart => $real_pkgpart,
1343       );
1344
1345       push @$cust_bill_pkgs, $cust_bill_pkg;
1346
1347     } #if $setup != 0 || $recur != 0
1348
1349   } #if $line_items
1350
1351   '';
1352
1353 }
1354
1355 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1356
1357 Takes one argument, a cust_pkg object that is being billed.  This will
1358 be called only if the package was created by a package change, and has
1359 not been billed since the package change, and package balance tracking
1360 is enabled.  The second argument can be an alternate package number to
1361 transfer the balance from; this should not be used externally.
1362
1363 Transfers the balance from the previous package (now canceled) to
1364 this package, by crediting one package and creating an invoice item for
1365 the other.  Inserts the credit and returns the invoice item (so that it
1366 can be added to an invoice that's being built).
1367
1368 If the previous package was never billed, and was also created by a package
1369 change, then this will also transfer the balance from I<its> previous
1370 package, and so on, until reaching a package that either has been billed
1371 or was not created by a package change.
1372
1373 =cut
1374
1375 my $balance_transfer_reason;
1376
1377 sub _transfer_balance {
1378   my $self = shift;
1379   my $cust_pkg = shift;
1380   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1381   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1382
1383   my @transfers;
1384
1385   # if $from_pkg is not the first package in the chain, and it was never
1386   # billed, walk back
1387   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1388     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1389   }
1390
1391   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1392   if ( $prev_balance != 0 ) {
1393     $balance_transfer_reason ||= FS::reason->new_or_existing(
1394       'reason' => 'Package balance transfer',
1395       'type'   => 'Internal adjustment',
1396       'class'  => 'R'
1397     );
1398
1399     my $credit = FS::cust_credit->new({
1400         'custnum'   => $self->custnum,
1401         'amount'    => abs($prev_balance),
1402         'reasonnum' => $balance_transfer_reason->reasonnum,
1403         '_date'     => $cust_pkg->change_date,
1404     });
1405
1406     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1407         'setup'     => 0,
1408         'recur'     => abs($prev_balance),
1409         #'sdate'     => $from_pkg->last_bill, # not sure about this
1410         #'edate'     => $cust_pkg->change_date,
1411         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1412                                  $from_pkg->part_pkg->pkg),
1413     });
1414
1415     if ( $prev_balance > 0 ) {
1416       # credit the old package, charge the new one
1417       $credit->set('pkgnum', $from_pkgnum);
1418       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1419     } else {
1420       # the reverse
1421       $credit->set('pkgnum', $cust_pkg->pkgnum);
1422       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1423     }
1424     my $error = $credit->insert;
1425     die "error transferring package balance from #".$from_pkgnum.
1426         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1427
1428     push @transfers, $cust_bill_pkg;
1429   } # $prev_balance != 0
1430
1431   return @transfers;
1432 }
1433
1434 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1435
1436 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1437 from _make_lines.
1438
1439 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1440 this:
1441 {
1442   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1443   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1444 }
1445
1446 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1447 is always the cust_main_county or tax_rate identified by the key.
1448
1449 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1450 the 'taxline' method to calculate the amount of the tax.  This doesn't
1451 happen until calculate_taxes, though.
1452
1453 OPTIONS may include:
1454 - part_item: a part_pkg or part_fee object to be used as the package/fee
1455   definition.
1456 - location: a cust_location to be used as the billing location.
1457
1458 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1459 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1460 the customer's default service location).
1461
1462 =cut
1463
1464 sub _handle_taxes {
1465   my $self = shift;
1466   my $taxlisthash = shift;
1467   my $cust_bill_pkg = shift;
1468   my %options = @_;
1469
1470   # at this point I realize that we have enough information to infer all this
1471   # stuff, instead of passing around giant honking argument lists
1472   my $location = $options{location} || $cust_bill_pkg->tax_location;
1473   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1474
1475   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1476
1477   return if ( $self->payby eq 'COMP' ); #dubious
1478
1479   if ( $conf->exists('enable_taxproducts')
1480        && ( scalar($part_item->part_pkg_taxoverride)
1481             || $part_item->has_taxproduct
1482           )
1483      )
1484     {
1485
1486     # EXTERNAL TAX RATES (via tax_rate)
1487     my %cust_bill_pkg = ();
1488     my %taxes = ();
1489
1490     my @classes;
1491     #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1492     push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1493     push @classes, 'setup' if $cust_bill_pkg->setup;
1494     push @classes, 'recur' if $cust_bill_pkg->recur;
1495
1496     my $exempt = $conf->exists('cust_class-tax_exempt')
1497                    ? ( $self->cust_class ? $self->cust_class->tax : '' )
1498                    : $self->tax;
1499     # standardize this just to be sure
1500     $exempt = ($exempt eq 'Y') ? 'Y' : '';
1501
1502     if ( !$exempt ) {
1503
1504       foreach my $class (@classes) {
1505         my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1506         return $err_or_ref unless ref($err_or_ref);
1507         $taxes{$class} = $err_or_ref;
1508       }
1509
1510       unless (exists $taxes{''}) {
1511         my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1512         return $err_or_ref unless ref($err_or_ref);
1513         $taxes{''} = $err_or_ref;
1514       }
1515
1516     }
1517
1518     my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate; # grrr
1519     foreach my $key (keys %tax_cust_bill_pkg) {
1520       # $key is "setup", "recur", or a usage class name. ('' is a usage class.)
1521       # $tax_cust_bill_pkg{$key} is a cust_bill_pkg for that component of
1522       # the line item.
1523       # $taxes{$key} is an arrayref of cust_main_county or tax_rate objects that
1524       # apply to $key-class charges.
1525       my @taxes = @{ $taxes{$key} || [] };
1526       my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1527
1528       my %localtaxlisthash = ();
1529       foreach my $tax ( @taxes ) {
1530
1531         # this is the tax identifier, not the taxname
1532         my $taxname = ref( $tax ). ' '. $tax->taxnum;
1533         # $taxlisthash: keys are "setup", "recur", and usage classes.
1534         # Values are arrayrefs, first the tax object (cust_main_county
1535         # or tax_rate) and then any cust_bill_pkg objects that the
1536         # tax applies to.
1537         $taxlisthash->{ $taxname } ||= [ $tax ];
1538         push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1539
1540         $localtaxlisthash{ $taxname } ||= [ $tax ];
1541         push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1542
1543       }
1544
1545       warn "finding taxed taxes...\n" if $DEBUG > 2;
1546       foreach my $tax ( keys %localtaxlisthash ) {
1547         my $tax_object = shift @{ $localtaxlisthash{$tax} };
1548         warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1549           if $DEBUG > 2;
1550         next unless $tax_object->can('tax_on_tax');
1551
1552         foreach my $tot ( $tax_object->tax_on_tax( $location ) ) {
1553           my $totname = ref( $tot ). ' '. $tot->taxnum;
1554
1555           warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1556             if $DEBUG > 2;
1557           next unless exists( $localtaxlisthash{ $totname } ); # only increase
1558                                                                # existing taxes
1559           warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1560           # calculate the tax amount that the tax_on_tax will apply to
1561           my $hashref_or_error =
1562             $tax_object->taxline( $localtaxlisthash{$tax} );
1563           return $hashref_or_error
1564             unless ref($hashref_or_error);
1565
1566           # and append it to the list of taxable items
1567           $taxlisthash->{ $totname } ||= [ $tot ];
1568           push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1569
1570         }
1571       }
1572     }
1573
1574   } else {
1575
1576     # INTERNAL TAX RATES (cust_main_county)
1577
1578     # We fetch taxes even if the customer is completely exempt,
1579     # because we need to record that fact.
1580
1581     my @loc_keys = qw( district city county state country );
1582     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1583
1584     $taxhash{'taxclass'} = $part_item->taxclass;
1585
1586     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1587
1588     my @taxes = (); # entries are cust_main_county objects
1589     my %taxhash_elim = %taxhash;
1590     my @elim = qw( district city county state );
1591     do {
1592
1593       #first try a match with taxclass
1594       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1595
1596       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1597         #then try a match without taxclass
1598         my %no_taxclass = %taxhash_elim;
1599         $no_taxclass{ 'taxclass' } = '';
1600         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1601       }
1602
1603       $taxhash_elim{ shift(@elim) } = '';
1604
1605     } while ( !scalar(@taxes) && scalar(@elim) );
1606
1607     foreach (@taxes) {
1608       my $tax_id = 'cust_main_county '.$_->taxnum;
1609       $taxlisthash->{$tax_id} ||= [ $_ ];
1610       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1611     }
1612
1613   }
1614   '';
1615 }
1616
1617 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1618
1619 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1620 or part_fee (which will define the tax eligibility of the product), CLASS is
1621 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1622 location where the service was provided (or billed, depending on
1623 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1624 can apply to this line item.
1625
1626 =cut
1627
1628 sub _gather_taxes {
1629   my $self = shift;
1630   my $part_item = shift;
1631   my $class = shift;
1632   my $location = shift;
1633
1634   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1635
1636   my $geocode = $location->geocode('cch');
1637
1638   [ $part_item->tax_rates('cch', $geocode, $class) ]
1639
1640 }
1641
1642 =item collect [ HASHREF | OPTION => VALUE ... ]
1643
1644 (Attempt to) collect money for this customer's outstanding invoices (see
1645 L<FS::cust_bill>).  Usually used after the bill method.
1646
1647 Actions are now triggered by billing events; see L<FS::part_event> and the
1648 billing events web interface.  Old-style invoice events (see
1649 L<FS::part_bill_event>) have been deprecated.
1650
1651 If there is an error, returns the error, otherwise returns false.
1652
1653 Options are passed as name-value pairs.
1654
1655 Currently available options are:
1656
1657 =over 4
1658
1659 =item invoice_time
1660
1661 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1662
1663 =item retry
1664
1665 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1666
1667 =item check_freq
1668
1669 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1670
1671 =item quiet
1672
1673 set true to surpress email card/ACH decline notices.
1674
1675 =item debug
1676
1677 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1678
1679 =back
1680
1681 # =item payby
1682 #
1683 # allows for one time override of normal customer billing method
1684
1685 =cut
1686
1687 sub collect {
1688   my( $self, %options ) = @_;
1689
1690   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1691
1692   my $invoice_time = $options{'invoice_time'} || time;
1693
1694   #put below somehow?
1695   local $SIG{HUP} = 'IGNORE';
1696   local $SIG{INT} = 'IGNORE';
1697   local $SIG{QUIT} = 'IGNORE';
1698   local $SIG{TERM} = 'IGNORE';
1699   local $SIG{TSTP} = 'IGNORE';
1700   local $SIG{PIPE} = 'IGNORE';
1701
1702   my $oldAutoCommit = $FS::UID::AutoCommit;
1703   local $FS::UID::AutoCommit = 0;
1704   my $dbh = dbh;
1705
1706   $self->select_for_update; #mutex
1707
1708   if ( $DEBUG ) {
1709     my $balance = $self->balance;
1710     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1711   }
1712
1713   if ( exists($options{'retry_card'}) ) {
1714     carp 'retry_card option passed to collect is deprecated; use retry';
1715     $options{'retry'} ||= $options{'retry_card'};
1716   }
1717   if ( exists($options{'retry'}) && $options{'retry'} ) {
1718     my $error = $self->retry_realtime;
1719     if ( $error ) {
1720       $dbh->rollback if $oldAutoCommit;
1721       return $error;
1722     }
1723   }
1724
1725   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1726
1727   #never want to roll back an event just because it returned an error
1728   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1729
1730   $self->do_cust_event(
1731     'debug'      => ( $options{'debug'} || 0 ),
1732     'time'       => $invoice_time,
1733     'check_freq' => $options{'check_freq'},
1734     'stage'      => 'collect',
1735   );
1736
1737 }
1738
1739 =item retry_realtime
1740
1741 Schedules realtime / batch  credit card / electronic check / LEC billing
1742 events for for retry.  Useful if card information has changed or manual
1743 retry is desired.  The 'collect' method must be called to actually retry
1744 the transaction.
1745
1746 Implementation details: For either this customer, or for each of this
1747 customer's open invoices, changes the status of the first "done" (with
1748 statustext error) realtime processing event to "failed".
1749
1750 =cut
1751
1752 sub retry_realtime {
1753   my $self = shift;
1754
1755   local $SIG{HUP} = 'IGNORE';
1756   local $SIG{INT} = 'IGNORE';
1757   local $SIG{QUIT} = 'IGNORE';
1758   local $SIG{TERM} = 'IGNORE';
1759   local $SIG{TSTP} = 'IGNORE';
1760   local $SIG{PIPE} = 'IGNORE';
1761
1762   my $oldAutoCommit = $FS::UID::AutoCommit;
1763   local $FS::UID::AutoCommit = 0;
1764   my $dbh = dbh;
1765
1766   #a little false laziness w/due_cust_event (not too bad, really)
1767
1768   my $join = FS::part_event_condition->join_conditions_sql;
1769   my $order = FS::part_event_condition->order_conditions_sql;
1770   my $mine =
1771   '( '
1772    . join ( ' OR ' , map {
1773     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1774     my $custnum = FS::part_event->eventtables_custnum->{$_};
1775     "( part_event.eventtable = " . dbh->quote($_)
1776     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1777     . " from $_ $cust_join"
1778     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1779    } FS::part_event->eventtables)
1780    . ') ';
1781
1782   #here is the agent virtualization
1783   my $agent_virt = " (    part_event.agentnum IS NULL
1784                        OR part_event.agentnum = ". $self->agentnum. ' )';
1785
1786   #XXX this shouldn't be hardcoded, actions should declare it...
1787   my @realtime_events = qw(
1788     cust_bill_realtime_card
1789     cust_bill_realtime_check
1790     cust_bill_realtime_lec
1791     cust_bill_batch
1792   );
1793
1794   my $is_realtime_event =
1795     ' part_event.action IN ( '.
1796         join(',', map "'$_'", @realtime_events ).
1797     ' ) ';
1798
1799   my $batch_or_statustext =
1800     "( part_event.action = 'cust_bill_batch'
1801        OR ( statustext IS NOT NULL AND statustext != '' )
1802      )";
1803
1804
1805   my @cust_event = qsearch({
1806     'table'     => 'cust_event',
1807     'select'    => 'cust_event.*',
1808     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1809     'hashref'   => { 'status' => 'done' },
1810     'extra_sql' => " AND $batch_or_statustext ".
1811                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1812   });
1813
1814   my %seen_invnum = ();
1815   foreach my $cust_event (@cust_event) {
1816
1817     #max one for the customer, one for each open invoice
1818     my $cust_X = $cust_event->cust_X;
1819     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1820                           ? $cust_X->invnum
1821                           : 0
1822                         }++
1823          or $cust_event->part_event->eventtable eq 'cust_bill'
1824             && ! $cust_X->owed;
1825
1826     my $error = $cust_event->retry;
1827     if ( $error ) {
1828       $dbh->rollback if $oldAutoCommit;
1829       return "error scheduling event for retry: $error";
1830     }
1831
1832   }
1833
1834   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1835   '';
1836
1837 }
1838
1839 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1840
1841 Runs billing events; see L<FS::part_event> and the billing events web
1842 interface.
1843
1844 If there is an error, returns the error, otherwise returns false.
1845
1846 Options are passed as name-value pairs.
1847
1848 Currently available options are:
1849
1850 =over 4
1851
1852 =item time
1853
1854 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1855
1856 =item check_freq
1857
1858 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1859
1860 =item stage
1861
1862 "collect" (the default) or "pre-bill"
1863
1864 =item quiet
1865
1866 set true to surpress email card/ACH decline notices.
1867
1868 =item debug
1869
1870 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1871
1872 =back
1873 =cut
1874
1875 # =item payby
1876 #
1877 # allows for one time override of normal customer billing method
1878
1879 # =item retry
1880 #
1881 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1882
1883 sub do_cust_event {
1884   my( $self, %options ) = @_;
1885
1886   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1887
1888   my $time = $options{'time'} || time;
1889
1890   #put below somehow?
1891   local $SIG{HUP} = 'IGNORE';
1892   local $SIG{INT} = 'IGNORE';
1893   local $SIG{QUIT} = 'IGNORE';
1894   local $SIG{TERM} = 'IGNORE';
1895   local $SIG{TSTP} = 'IGNORE';
1896   local $SIG{PIPE} = 'IGNORE';
1897
1898   my $oldAutoCommit = $FS::UID::AutoCommit;
1899   local $FS::UID::AutoCommit = 0;
1900   my $dbh = dbh;
1901
1902   $self->select_for_update; #mutex
1903
1904   if ( $DEBUG ) {
1905     my $balance = $self->balance;
1906     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1907   }
1908
1909 #  if ( exists($options{'retry_card'}) ) {
1910 #    carp 'retry_card option passed to collect is deprecated; use retry';
1911 #    $options{'retry'} ||= $options{'retry_card'};
1912 #  }
1913 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1914 #    my $error = $self->retry_realtime;
1915 #    if ( $error ) {
1916 #      $dbh->rollback if $oldAutoCommit;
1917 #      return $error;
1918 #    }
1919 #  }
1920
1921   # false laziness w/pay_batch::import_results
1922
1923   my $due_cust_event = $self->due_cust_event(
1924     'debug'      => ( $options{'debug'} || 0 ),
1925     'time'       => $time,
1926     'check_freq' => $options{'check_freq'},
1927     'stage'      => ( $options{'stage'} || 'collect' ),
1928   );
1929   unless( ref($due_cust_event) ) {
1930     $dbh->rollback if $oldAutoCommit;
1931     return $due_cust_event;
1932   }
1933
1934   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1935   #never want to roll back an event just because it or a different one
1936   # returned an error
1937   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1938
1939   foreach my $cust_event ( @$due_cust_event ) {
1940
1941     #XXX lock event
1942
1943     #re-eval event conditions (a previous event could have changed things)
1944     unless ( $cust_event->test_conditions ) {
1945       #don't leave stray "new/locked" records around
1946       my $error = $cust_event->delete;
1947       return $error if $error;
1948       next;
1949     }
1950
1951     {
1952       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1953         if $options{'quiet'};
1954       warn "  running cust_event ". $cust_event->eventnum. "\n"
1955         if $DEBUG > 1;
1956
1957       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1958       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
1959         #XXX wtf is this?  figure out a proper dealio with return value
1960         #from do_event
1961         return $error;
1962       }
1963     }
1964
1965   }
1966
1967   '';
1968
1969 }
1970
1971 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1972
1973 Inserts database records for and returns an ordered listref of new events due
1974 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1975 events are due, an empty listref is returned.  If there is an error, returns a
1976 scalar error message.
1977
1978 To actually run the events, call each event's test_condition method, and if
1979 still true, call the event's do_event method.
1980
1981 Options are passed as a hashref or as a list of name-value pairs.  Available
1982 options are:
1983
1984 =over 4
1985
1986 =item check_freq
1987
1988 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1989
1990 =item stage
1991
1992 "collect" (the default) or "pre-bill"
1993
1994 =item time
1995
1996 "Current time" for the events.
1997
1998 =item debug
1999
2000 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2001
2002 =item eventtable
2003
2004 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2005
2006 =item objects
2007
2008 Explicitly pass the objects to be tested (typically used with eventtable).
2009
2010 =item testonly
2011
2012 Set to true to return the objects, but not actually insert them into the
2013 database.
2014
2015 =back
2016
2017 =cut
2018
2019 sub due_cust_event {
2020   my $self = shift;
2021   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2022
2023   #???
2024   #my $DEBUG = $opt{'debug'}
2025   $opt{'debug'} ||= 0; # silence some warnings
2026   local($DEBUG) = $opt{'debug'}
2027     if $opt{'debug'} > $DEBUG;
2028   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2029
2030   warn "$me due_cust_event called with options ".
2031        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2032     if $DEBUG;
2033
2034   $opt{'time'} ||= time;
2035
2036   local $SIG{HUP} = 'IGNORE';
2037   local $SIG{INT} = 'IGNORE';
2038   local $SIG{QUIT} = 'IGNORE';
2039   local $SIG{TERM} = 'IGNORE';
2040   local $SIG{TSTP} = 'IGNORE';
2041   local $SIG{PIPE} = 'IGNORE';
2042
2043   my $oldAutoCommit = $FS::UID::AutoCommit;
2044   local $FS::UID::AutoCommit = 0;
2045   my $dbh = dbh;
2046
2047   $self->select_for_update #mutex
2048     unless $opt{testonly};
2049
2050   ###
2051   # find possible events (initial search)
2052   ###
2053
2054   my @cust_event = ();
2055
2056   my @eventtable = $opt{'eventtable'}
2057                      ? ( $opt{'eventtable'} )
2058                      : FS::part_event->eventtables_runorder;
2059
2060   my $check_freq = $opt{'check_freq'} || '1d';
2061
2062   foreach my $eventtable ( @eventtable ) {
2063
2064     my @objects;
2065     if ( $opt{'objects'} ) {
2066
2067       @objects = @{ $opt{'objects'} };
2068
2069     } elsif ( $eventtable eq 'cust_main' ) {
2070
2071       @objects = ( $self );
2072
2073     } else {
2074
2075       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2076       # linkage not needed here because FS::cust_main->$eventtable will
2077       # already supply it
2078
2079       #some false laziness w/Cron::bill bill_where
2080
2081       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
2082       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2083         'time'=>$opt{'time'},
2084       );
2085       $where = $where ? "AND $where" : '';
2086
2087       my $are_part_event =
2088       "EXISTS ( SELECT 1 FROM part_event $join
2089         WHERE check_freq = '$check_freq'
2090         AND eventtable = '$eventtable'
2091         AND ( disabled = '' OR disabled IS NULL )
2092         $where
2093         )
2094       ";
2095       #eofalse
2096
2097       @objects = $self->$eventtable(
2098         'addl_from' => $cm_join,
2099         'extra_sql' => " AND $are_part_event",
2100       );
2101     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2102
2103     my @e_cust_event = ();
2104
2105     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2106
2107     my $cross = "CROSS JOIN $eventtable $linkage";
2108     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2109       unless $eventtable eq 'cust_main';
2110
2111     foreach my $object ( @objects ) {
2112
2113       #this first search uses the condition_sql magic for optimization.
2114       #the more possible events we can eliminate in this step the better
2115
2116       my $cross_where = '';
2117       my $pkey = $object->primary_key;
2118       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2119
2120       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
2121       my $extra_sql =
2122         FS::part_event_condition->where_conditions_sql( $eventtable,
2123                                                         'time'=>$opt{'time'}
2124                                                       );
2125       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2126
2127       $extra_sql = "AND $extra_sql" if $extra_sql;
2128
2129       #here is the agent virtualization
2130       $extra_sql .= " AND (    part_event.agentnum IS NULL
2131                             OR part_event.agentnum = ". $self->agentnum. ' )';
2132
2133       $extra_sql .= " $order";
2134
2135       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2136         if $opt{'debug'} > 2;
2137       my @part_event = qsearch( {
2138         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2139         'select'    => 'part_event.*',
2140         'table'     => 'part_event',
2141         'addl_from' => "$cross $join",
2142         'hashref'   => { 'check_freq' => $check_freq,
2143                          'eventtable' => $eventtable,
2144                          'disabled'   => '',
2145                        },
2146         'extra_sql' => "AND $cross_where $extra_sql",
2147       } );
2148
2149       if ( $DEBUG > 2 ) {
2150         my $pkey = $object->primary_key;
2151         warn "      ". scalar(@part_event).
2152              " possible events found for $eventtable ". $object->$pkey(). "\n";
2153       }
2154
2155       push @e_cust_event, map {
2156         $_->new_cust_event($object, 'time' => $opt{'time'})
2157       } @part_event;
2158
2159     }
2160
2161     warn "    ". scalar(@e_cust_event).
2162          " subtotal possible cust events found for $eventtable\n"
2163       if $DEBUG > 1;
2164
2165     push @cust_event, @e_cust_event;
2166
2167   }
2168
2169   warn "  ". scalar(@cust_event).
2170        " total possible cust events found in initial search\n"
2171     if $DEBUG; # > 1;
2172
2173
2174   ##
2175   # test stage
2176   ##
2177
2178   $opt{stage} ||= 'collect';
2179   @cust_event =
2180     grep { my $stage = $_->part_event->event_stage;
2181            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2182          }
2183          @cust_event;
2184
2185   ##
2186   # test conditions
2187   ##
2188
2189   my %unsat = ();
2190
2191   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2192                      @cust_event;
2193
2194   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2195     if $DEBUG; # > 1;
2196
2197   warn "    invalid conditions not eliminated with condition_sql:\n".
2198        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2199     if keys %unsat && $DEBUG; # > 1;
2200
2201   ##
2202   # insert
2203   ##
2204
2205   unless( $opt{testonly} ) {
2206     foreach my $cust_event ( @cust_event ) {
2207
2208       my $error = $cust_event->insert();
2209       if ( $error ) {
2210         $dbh->rollback if $oldAutoCommit;
2211         return $error;
2212       }
2213
2214     }
2215   }
2216
2217   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2218
2219   ##
2220   # return
2221   ##
2222
2223   warn "  returning events: ". Dumper(@cust_event). "\n"
2224     if $DEBUG > 2;
2225
2226   \@cust_event;
2227
2228 }
2229
2230 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2231
2232 Applies unapplied payments and credits.
2233
2234 In most cases, this new method should be used in place of sequential
2235 apply_payments and apply_credits methods.
2236
2237 A hash of optional arguments may be passed.  Currently "manual" is supported.
2238 If true, a payment receipt is sent instead of a statement when
2239 'payment_receipt_email' configuration option is set.
2240
2241 If there is an error, returns the error, otherwise returns false.
2242
2243 =cut
2244
2245 sub apply_payments_and_credits {
2246   my( $self, %options ) = @_;
2247
2248   local $SIG{HUP} = 'IGNORE';
2249   local $SIG{INT} = 'IGNORE';
2250   local $SIG{QUIT} = 'IGNORE';
2251   local $SIG{TERM} = 'IGNORE';
2252   local $SIG{TSTP} = 'IGNORE';
2253   local $SIG{PIPE} = 'IGNORE';
2254
2255   my $oldAutoCommit = $FS::UID::AutoCommit;
2256   local $FS::UID::AutoCommit = 0;
2257   my $dbh = dbh;
2258
2259   $self->select_for_update; #mutex
2260
2261   foreach my $cust_bill ( $self->open_cust_bill ) {
2262     my $error = $cust_bill->apply_payments_and_credits(%options);
2263     if ( $error ) {
2264       $dbh->rollback if $oldAutoCommit;
2265       return "Error applying: $error";
2266     }
2267   }
2268
2269   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2270   ''; #no error
2271
2272 }
2273
2274 =item apply_credits OPTION => VALUE ...
2275
2276 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2277 to outstanding invoice balances in chronological order (or reverse
2278 chronological order if the I<order> option is set to B<newest>) and returns the
2279 value of any remaining unapplied credits available for refund (see
2280 L<FS::cust_refund>).
2281
2282 Dies if there is an error.
2283
2284 =cut
2285
2286 sub apply_credits {
2287   my $self = shift;
2288   my %opt = @_;
2289
2290   local $SIG{HUP} = 'IGNORE';
2291   local $SIG{INT} = 'IGNORE';
2292   local $SIG{QUIT} = 'IGNORE';
2293   local $SIG{TERM} = 'IGNORE';
2294   local $SIG{TSTP} = 'IGNORE';
2295   local $SIG{PIPE} = 'IGNORE';
2296
2297   my $oldAutoCommit = $FS::UID::AutoCommit;
2298   local $FS::UID::AutoCommit = 0;
2299   my $dbh = dbh;
2300
2301   $self->select_for_update; #mutex
2302
2303   unless ( $self->total_unapplied_credits ) {
2304     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2305     return 0;
2306   }
2307
2308   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2309       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2310
2311   my @invoices = $self->open_cust_bill;
2312   @invoices = sort { $b->_date <=> $a->_date } @invoices
2313     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2314
2315   if ( $conf->exists('pkg-balances') ) {
2316     # limit @credits to those w/ a pkgnum grepped from $self
2317     my %pkgnums = ();
2318     foreach my $i (@invoices) {
2319       foreach my $li ( $i->cust_bill_pkg ) {
2320         $pkgnums{$li->pkgnum} = 1;
2321       }
2322     }
2323     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2324   }
2325
2326   my $credit;
2327
2328   foreach my $cust_bill ( @invoices ) {
2329
2330     if ( !defined($credit) || $credit->credited == 0) {
2331       $credit = pop @credits or last;
2332     }
2333
2334     my $owed;
2335     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2336       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2337     } else {
2338       $owed = $cust_bill->owed;
2339     }
2340     unless ( $owed > 0 ) {
2341       push @credits, $credit;
2342       next;
2343     }
2344
2345     my $amount = min( $credit->credited, $owed );
2346
2347     my $cust_credit_bill = new FS::cust_credit_bill ( {
2348       'crednum' => $credit->crednum,
2349       'invnum'  => $cust_bill->invnum,
2350       'amount'  => $amount,
2351     } );
2352     $cust_credit_bill->pkgnum( $credit->pkgnum )
2353       if $conf->exists('pkg-balances') && $credit->pkgnum;
2354     my $error = $cust_credit_bill->insert;
2355     if ( $error ) {
2356       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2357       die $error;
2358     }
2359
2360     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2361
2362   }
2363
2364   my $total_unapplied_credits = $self->total_unapplied_credits;
2365
2366   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2367
2368   return $total_unapplied_credits;
2369 }
2370
2371 =item apply_payments  [ OPTION => VALUE ... ]
2372
2373 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2374 to outstanding invoice balances in chronological order.
2375
2376  #and returns the value of any remaining unapplied payments.
2377
2378 A hash of optional arguments may be passed.  Currently "manual" is supported.
2379 If true, a payment receipt is sent instead of a statement when
2380 'payment_receipt_email' configuration option is set.
2381
2382 Dies if there is an error.
2383
2384 =cut
2385
2386 sub apply_payments {
2387   my( $self, %options ) = @_;
2388
2389   local $SIG{HUP} = 'IGNORE';
2390   local $SIG{INT} = 'IGNORE';
2391   local $SIG{QUIT} = 'IGNORE';
2392   local $SIG{TERM} = 'IGNORE';
2393   local $SIG{TSTP} = 'IGNORE';
2394   local $SIG{PIPE} = 'IGNORE';
2395
2396   my $oldAutoCommit = $FS::UID::AutoCommit;
2397   local $FS::UID::AutoCommit = 0;
2398   my $dbh = dbh;
2399
2400   $self->select_for_update; #mutex
2401
2402   #return 0 unless
2403
2404   my @payments = sort { $b->_date <=> $a->_date }
2405                  grep { $_->unapplied > 0 }
2406                  $self->cust_pay;
2407
2408   my @invoices = sort { $a->_date <=> $b->_date}
2409                  grep { $_->owed > 0 }
2410                  $self->cust_bill;
2411
2412   if ( $conf->exists('pkg-balances') ) {
2413     # limit @payments to those w/ a pkgnum grepped from $self
2414     my %pkgnums = ();
2415     foreach my $i (@invoices) {
2416       foreach my $li ( $i->cust_bill_pkg ) {
2417         $pkgnums{$li->pkgnum} = 1;
2418       }
2419     }
2420     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2421   }
2422
2423   my $payment;
2424
2425   foreach my $cust_bill ( @invoices ) {
2426
2427     if ( !defined($payment) || $payment->unapplied == 0 ) {
2428       $payment = pop @payments or last;
2429     }
2430
2431     my $owed;
2432     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2433       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2434     } else {
2435       $owed = $cust_bill->owed;
2436     }
2437     unless ( $owed > 0 ) {
2438       push @payments, $payment;
2439       next;
2440     }
2441
2442     my $amount = min( $payment->unapplied, $owed );
2443
2444     my $cbp = {
2445       'paynum' => $payment->paynum,
2446       'invnum' => $cust_bill->invnum,
2447       'amount' => $amount,
2448     };
2449     $cbp->{_date} = $payment->_date
2450         if $options{'manual'} && $options{'backdate_application'};
2451     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2452     $cust_bill_pay->pkgnum( $payment->pkgnum )
2453       if $conf->exists('pkg-balances') && $payment->pkgnum;
2454     my $error = $cust_bill_pay->insert(%options);
2455     if ( $error ) {
2456       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2457       die $error;
2458     }
2459
2460     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2461
2462   }
2463
2464   my $total_unapplied_payments = $self->total_unapplied_payments;
2465
2466   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2467
2468   return $total_unapplied_payments;
2469 }
2470
2471 =back
2472
2473 =head1 FLOW
2474
2475   bill_and_collect
2476
2477     cancel_expired_pkgs
2478     suspend_adjourned_pkgs
2479     unsuspend_resumed_pkgs
2480
2481     bill
2482       (do_cust_event pre-bill)
2483       _make_lines
2484         _handle_taxes
2485           (vendor-only) _gather_taxes
2486       _omit_zero_value_bundles
2487       _handle_taxes (for fees)
2488       calculate_taxes
2489
2490     apply_payments_and_credits
2491     collect
2492       do_cust_event
2493         due_cust_event
2494
2495 =head1 BUGS
2496
2497 =head1 SEE ALSO
2498
2499 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2500
2501 =cut
2502
2503 1;