FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use Tie::RefHash;
  12 use FS::cust_bill;
  13 use FS::cust_bill_pkg;
  14 use FS::cust_bill_pkg_display;
  15 use FS::cust_bill_pay;
  16 use FS::cust_credit_bill;
  17 use FS::cust_tax_adjustment;
  18 use FS::tax_rate;
  19 use FS::tax_rate_location;
  20 use FS::cust_bill_pkg_tax_location;
  21 use FS::cust_bill_pkg_tax_rate_location;
  22 use FS::part_event;
  23 use FS::part_event_condition;
  24 use FS::pkg_category;
  25 use FS::FeeOrigin_Mixin;
  26 use FS::Log;
  27
  28 # 1 is mostly method/subroutine entry and options
  29 # 2 traces progress of some operations
  30 # 3 is even more information including possibly sensitive data
  31 $DEBUG = 0;
  32 $me = '[FS::cust_main::Billing]';
  33
  34 install_callback FS::UID sub {
  35   $conf = new FS::Conf;
  36   #yes, need it for stuff below (prolly should be cached)
  37 };
  38
  39 =head1 NAME
  40
  41 FS::cust_main::Billing - Billing mixin for cust_main
  42
  43 =head1 SYNOPSIS
  44
  45 =head1 DESCRIPTION
  46
  47 These methods are available on FS::cust_main objects.
  48
  49 =head1 METHODS
  50
  51 =over 4
  52
  53 =item bill_and_collect
  54
  55 Cancels and suspends any packages due, generates bills, applies payments and
  56 credits, and applies collection events to run cards, send bills and notices,
  57 etc.
  58
  59 By default, warns on errors and continues with the next operation (but see the
  60 "fatal" flag below).
  61
  62 Options are passed as name-value pairs.  Currently available options are:
  63
  64 =over 4
  65
  66 =item time
  67
  68 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  69
  70  use Date::Parse;
  71  ...
  72  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  73
  74 =item invoice_time
  75
  76 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  77
  78 =item check_freq
  79
  80 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  81
  82 =item resetup
  83
  84 If set true, re-charges setup fees.
  85
  86 =item fatal
  87
  88 If set any errors prevent subsequent operations from continusing.  If set
  89 specifically to "return", returns the error (or false, if there is no error).
  90 Any other true value causes errors to die.
  91
  92 =item debug
  93
  94 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  95
  96 =item job
  97
  98 Optional FS::queue entry to receive status updates.
  99
 100 =back
 101
 102 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 103 options of those methods are also available.
 104
 105 =cut
 106
 107 sub bill_and_collect {
 108   my( $self, %options ) = @_;
 109
 110   my $log = FS::Log->new('FS::cust_main::Billing::bill_and_collect');
 111   my %logopt = (object => $self);
 112   $log->debug('start', %logopt);
 113
 114   my $error;
 115
 116   #$options{actual_time} not $options{time} because freeside-daily -d is for
 117   #pre-printing invoices
 118
 119   $options{'actual_time'} ||= time;
 120   my $job = $options{'job'};
 121
 122   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 123                         ? day_end( $options{actual_time} )
 124                         : $options{actual_time}
 125                     );
 126
 127   $job->update_statustext('0,cleaning expired packages') if $job;
 128   $log->debug('canceling expired packages', %logopt);
 129   $error = $self->cancel_expired_pkgs( $actual_time );
 130   if ( $error ) {
 131     $error = "Error expiring custnum ". $self->custnum. ": $error";
 132     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 133     elsif ( $options{fatal}                                ) { die    $error; }
 134     else                                                     { warn   $error; }
 135   }
 136
 137   $log->debug('suspending adjourned packages', %logopt);
 138   $error = $self->suspend_adjourned_pkgs( $actual_time );
 139   if ( $error ) {
 140     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 141     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 142     elsif ( $options{fatal}                                ) { die    $error; }
 143     else                                                     { warn   $error; }
 144   }
 145
 146   $log->debug('unsuspending resumed packages', %logopt);
 147   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 148   if ( $error ) {
 149     $error = "Error resuming custnum ".$self->custnum. ": $error";
 150     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 151     elsif ( $options{fatal}                                ) { die    $error; }
 152     else                                                     { warn   $error; }
 153   }
 154
 155   $job->update_statustext('20,billing packages') if $job;
 156   $log->debug('billing packages', %logopt);
 157   $error = $self->bill( %options );
 158   if ( $error ) {
 159     $error = "Error billing custnum ". $self->custnum. ": $error";
 160     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 161     elsif ( $options{fatal}                                ) { die    $error; }
 162     else                                                     { warn   $error; }
 163   }
 164
 165   $job->update_statustext('50,applying payments and credits') if $job;
 166   $log->debug('applying payments and credits', %logopt);
 167   $error = $self->apply_payments_and_credits;
 168   if ( $error ) {
 169     $error = "Error applying custnum ". $self->custnum. ": $error";
 170     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 171     elsif ( $options{fatal}                                ) { die    $error; }
 172     else                                                     { warn   $error; }
 173   }
 174
 175   unless ( $conf->exists('cancelled_cust-noevents')
 176            && ! $self->num_ncancelled_pkgs
 177   ) {
 178     $job->update_statustext('70,running collection events') if $job;
 179     $log->debug('running collection events', %logopt);
 180     $error = $self->collect( %options );
 181     if ( $error ) {
 182       $error = "Error collecting custnum ". $self->custnum. ": $error";
 183       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 184       elsif ($options{fatal}                               ) { die    $error; }
 185       else                                                   { warn   $error; }
 186     }
 187   }
 188
 189   $job->update_statustext('100,finished') if $job;
 190   $log->debug('finish', %logopt);
 191
 192   '';
 193
 194 }
 195
 196 sub cancel_expired_pkgs {
 197   my ( $self, $time, %options ) = @_;
 198
 199   my @cancel_pkgs = $self->ncancelled_pkgs( {
 200     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 201   } );
 202
 203   my @errors = ();
 204
 205   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 206     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 207     my $error;
 208
 209     if ( $cust_pkg->change_to_pkgnum ) {
 210
 211       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 212       if ( !$new_pkg ) {
 213         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 214                       $cust_pkg->change_to_pkgnum.'; not expiring';
 215         next CUST_PKG;
 216       }
 217       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 218                                   'unprotect_svcs'  => 1 );
 219       $error = '' if ref $error eq 'FS::cust_pkg';
 220
 221     } else { # just cancel it
 222        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 223                                            'reason_otaker' => $cpr->otaker,
 224                                            'time'          => $time,
 225                                          )
 226                                        : ()
 227                                  );
 228     }
 229     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 230   }
 231
 232   join(' / ', @errors);
 233
 234 }
 235
 236 sub suspend_adjourned_pkgs {
 237   my ( $self, $time, %options ) = @_;
 238
 239   my @susp_pkgs = $self->ncancelled_pkgs( {
 240     'extra_sql' =>
 241       " AND ( susp IS NULL OR susp = 0 )
 242         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 243               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 244             )
 245       ",
 246   } );
 247
 248   #only because there's no SQL test for is_prepaid :/
 249   @susp_pkgs =
 250     grep {     (    $_->part_pkg->is_prepaid
 251                  && $_->bill
 252                  && $_->bill < $time
 253                )
 254             || (    $_->adjourn
 255                  && $_->adjourn <= $time
 256                )
 257
 258          }
 259          @susp_pkgs;
 260
 261   my @errors = ();
 262
 263   foreach my $cust_pkg ( @susp_pkgs ) {
 264     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 265       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 266     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 267                                             'reason_otaker' => $cpr->otaker
 268                                           )
 269                                         : ()
 270                                   );
 271     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 272   }
 273
 274   join(' / ', @errors);
 275
 276 }
 277
 278 sub unsuspend_resumed_pkgs {
 279   my ( $self, $time, %options ) = @_;
 280
 281   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 282     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 283   } );
 284
 285   my @errors = ();
 286
 287   foreach my $cust_pkg ( @unsusp_pkgs ) {
 288     my $error = $cust_pkg->unsuspend( 'time' => $time );
 289     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 290   }
 291
 292   join(' / ', @errors);
 293
 294 }
 295
 296 =item bill OPTIONS
 297
 298 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 299 conjunction with the collect method by calling B<bill_and_collect>.
 300
 301 If there is an error, returns the error, otherwise returns false.
 302
 303 Options are passed as name-value pairs.  Currently available options are:
 304
 305 =over 4
 306
 307 =item resetup
 308
 309 If set true, re-charges setup fees.
 310
 311 =item recurring_only
 312
 313 If set true then only bill recurring charges, not setup, usage, one time
 314 charges, etc.
 315
 316 =item freq_override
 317
 318 If set, then override the normal frequency and look for a part_pkg_discount
 319 to take at that frequency.  This is appropriate only when the normal
 320 frequency for all packages is monthly, and is an error otherwise.  Use
 321 C<pkg_list> to limit the set of packages included in billing.
 322
 323 =item time
 324
 325 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 326
 327  use Date::Parse;
 328  ...
 329  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 330
 331 =item pkg_list
 332
 333 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 334
 335  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 336
 337 =item not_pkgpart
 338
 339 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 340
 341 =item no_prepaid
 342
 343 Do not bill prepaid packages.  Used by freeside-daily.
 344
 345 =item invoice_time
 346
 347 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 348
 349 =item cancel
 350
 351 This boolean value informs the us that the package is being cancelled.  This
 352 typically might mean not charging the normal recurring fee but only usage
 353 fees since the last billing. Setup charges may be charged.  Not all package
 354 plans support this feature (they tend to charge 0).
 355
 356 =item no_usage_reset
 357
 358 Prevent the resetting of usage limits during this call.
 359
 360 =item no_commit
 361
 362 Do not save the generated bill in the database.  Useful with return_bill
 363
 364 =item return_bill
 365
 366 A list reference on which the generated bill(s) will be returned.
 367
 368 =item invoice_terms
 369
 370 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 371 terms or the default terms are used.
 372
 373 =back
 374
 375 =cut
 376
 377 sub bill {
 378   my( $self, %options ) = @_;
 379
 380   return '' if $self->payby eq 'COMP';
 381
 382   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 383   my $log = FS::Log->new('FS::cust_main::Billing::bill');
 384   my %logopt = (object => $self);
 385
 386   $log->debug('start', %logopt);
 387   warn "$me bill customer ". $self->custnum. "\n"
 388     if $DEBUG;
 389
 390   my $time = $options{'time'} || time;
 391   my $invoice_time = $options{'invoice_time'} || $time;
 392
 393   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 394                      ? day_end( $time )
 395                      : $time
 396                  );
 397
 398   $options{'not_pkgpart'} ||= {};
 399   $options{'not_pkgpart'} = { map { $_ => 1 }
 400                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 401                             }
 402     unless ref($options{'not_pkgpart'});
 403
 404   local $SIG{HUP} = 'IGNORE';
 405   local $SIG{INT} = 'IGNORE';
 406   local $SIG{QUIT} = 'IGNORE';
 407   local $SIG{TERM} = 'IGNORE';
 408   local $SIG{TSTP} = 'IGNORE';
 409   local $SIG{PIPE} = 'IGNORE';
 410
 411   my $oldAutoCommit = $FS::UID::AutoCommit;
 412   local $FS::UID::AutoCommit = 0;
 413   my $dbh = dbh;
 414
 415   $log->debug('acquiring lock', %logopt);
 416   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 417     if $DEBUG;
 418
 419   $self->select_for_update; #mutex
 420
 421   $log->debug('running pre-bill events', %logopt);
 422   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 423     if $DEBUG;
 424
 425   my $error = $self->do_cust_event(
 426     'debug'      => ( $options{'debug'} || 0 ),
 427     'time'       => $invoice_time,
 428     'check_freq' => $options{'check_freq'},
 429     'stage'      => 'pre-bill',
 430   )
 431     unless $options{no_commit};
 432   if ( $error ) {
 433     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 434     return $error;
 435   }
 436
 437   $log->debug('done running pre-bill events', %logopt);
 438   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 439     if $DEBUG;
 440
 441   #keep auto-charge and non-auto-charge line items separate
 442   my @passes = ( '', 'no_auto' );
 443
 444   my %cust_bill_pkg = map { $_ => [] } @passes;
 445
 446   ###
 447   # find the packages which are due for billing, find out how much they are
 448   # & generate invoice database.
 449   ###
 450
 451   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 452   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 453
 454   my %taxlisthash = map { $_ => {} } @passes;
 455
 456   my @precommit_hooks = ();
 457
 458   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 459
 460   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 461
 462     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 463
 464     my $part_pkg = $cust_pkg->part_pkg;
 465
 466     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 467
 468     $log->debug('bill package '. $cust_pkg->pkgnum, %logopt);
 469     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 470
 471     #? to avoid use of uninitialized value errors... ?
 472     $cust_pkg->setfield('bill', '')
 473       unless defined($cust_pkg->bill);
 474
 475     my $real_pkgpart = $cust_pkg->pkgpart;
 476     my %hash = $cust_pkg->hash;
 477
 478     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 479     # suffer from performance issues
 480     $options{has_hidden} = 0;
 481     my @part_pkg = $part_pkg->self_and_bill_linked;
 482     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 483
 484     # if this package was changed from another package,
 485     # and it hasn't been billed since then,
 486     # and package balances are enabled,
 487     if ( $cust_pkg->change_pkgnum
 488         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 489         and $cust_pkg->change_date <  $invoice_time
 490       and $conf->exists('pkg-balances') )
 491     {
 492       # _transfer_balance will also create the appropriate credit
 493       my @transfer_items = $self->_transfer_balance($cust_pkg);
 494       # $part_pkg[0] is the "real" part_pkg
 495       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 496                   'no_auto' : '';
 497       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 498       # treating this as recur, just because most charges are recur...
 499       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 500
 501       # currently not considering separate_bill here, as it's for
 502       # one-time charges only
 503     }
 504
 505     foreach my $part_pkg ( @part_pkg ) {
 506
 507       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 508
 509       my $pass = '';
 510       if ( $cust_pkg->separate_bill ) {
 511         # if no_auto is also set, that's fine. we just need to not have
 512         # invoices that are both auto and no_auto, and since the package
 513         # gets an invoice all to itself, it will only be one or the other.
 514         $pass = $cust_pkg->pkgnum;
 515         if (!exists $cust_bill_pkg{$pass}) { # it may not exist yet
 516           push @passes, $pass;
 517           $total_setup{$pass} = do { my $z = 0; \$z };
 518           $total_recur{$pass} = do { my $z = 0; \$z };
 519           $taxlisthash{$pass} = {};
 520           $cust_bill_pkg{$pass} = [];
 521         }
 522       } elsif ( ($cust_pkg->no_auto || $part_pkg->no_auto) ) {
 523         $pass = 'no_auto';
 524       }
 525
 526       my $next_bill = $cust_pkg->getfield('bill') || 0;
 527       my $error;
 528       # let this run once if this is the last bill upon cancellation
 529       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 530         $error =
 531           $self->_make_lines( 'part_pkg'            => $part_pkg,
 532                               'cust_pkg'            => $cust_pkg,
 533                               'precommit_hooks'     => \@precommit_hooks,
 534                               'line_items'          => $cust_bill_pkg{$pass},
 535                               'setup'               => $total_setup{$pass},
 536                               'recur'               => $total_recur{$pass},
 537                               'tax_matrix'          => $taxlisthash{$pass},
 538                               'time'                => $time,
 539                               'real_pkgpart'        => $real_pkgpart,
 540                               'options'             => \%options,
 541                             );
 542
 543         # Stop if anything goes wrong
 544         last if $error;
 545
 546         # or if we're not incrementing the bill date.
 547         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 548
 549         # or if we're letting it run only once
 550         last if $options{cancel};
 551
 552         $next_bill = $cust_pkg->getfield('bill') || 0;
 553
 554         #stop if -o was passed to freeside-daily
 555         last if $options{'one_recur'};
 556       }
 557       if ($error) {
 558         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 559         return $error;
 560       }
 561
 562     } #foreach my $part_pkg
 563
 564   } #foreach my $cust_pkg
 565
 566   foreach my $pass (@passes) { # keys %cust_bill_pkg )
 567
 568     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 569
 570     warn "$me billing pass $pass\n"
 571            #.Dumper(\@cust_bill_pkg)."\n"
 572       if $DEBUG > 2;
 573
 574     ###
 575     # process fees
 576     ###
 577
 578     my @pending_fees = FS::FeeOrigin_Mixin->by_cust($self->custnum,
 579       hashref => { 'billpkgnum' => '' }
 580     );
 581     warn "$me found pending fees:\n".Dumper(\@pending_fees)."\n"
 582       if @pending_fees and $DEBUG > 1;
 583
 584     # determine whether to generate an invoice
 585     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 586
 587     foreach my $fee (@pending_fees) {
 588       $generate_bill = 1 unless $fee->nextbill;
 589     }
 590
 591     # don't create an invoice with no line items, or where the only line
 592     # items are fees that are supposed to be held until the next invoice
 593     next if !$generate_bill;
 594
 595     # calculate fees...
 596     my @fee_items;
 597     foreach my $fee_origin (@pending_fees) {
 598       my $part_fee = $fee_origin->part_fee;
 599
 600       # check whether the fee is applicable before doing anything expensive:
 601       #
 602       # if the fee def belongs to a different agent, don't charge the fee.
 603       # event conditions should prevent this, but just in case they don't,
 604       # skip the fee.
 605       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 606         warn "tried to charge fee#".$part_fee->feepart .
 607              " on customer#".$self->custnum." from a different agent.\n";
 608         next;
 609       }
 610       # also skip if it's disabled
 611       next if $part_fee->disabled eq 'Y';
 612
 613       # Decide which invoice to base the fee on.
 614       my $cust_bill = $fee_origin->cust_bill;
 615       if (!$cust_bill) {
 616         # Then link it to the current invoice. This isn't the real cust_bill
 617         # object that will be inserted--in particular there are no taxes yet.
 618         # If you want to charge a fee on the total invoice amount including
 619         # taxes, you have to put the fee on the next invoice.
 620         $cust_bill = FS::cust_bill->new({
 621             'custnum'       => $self->custnum,
 622             'cust_bill_pkg' => \@cust_bill_pkg,
 623             'charged'       => ${ $total_setup{$pass} } +
 624                                ${ $total_recur{$pass} },
 625         });
 626
 627         # If the origin is for a specific package, then only apply the fee to
 628         # line items from that package.
 629         if ( my $cust_pkg = $fee_origin->cust_pkg ) {
 630           my @charge_fee_on_item;
 631           my $charge_fee_on_amount = 0;
 632           foreach (@cust_bill_pkg) {
 633             if ($_->pkgnum == $cust_pkg->pkgnum) {
 634               push @charge_fee_on_item, $_;
 635               $charge_fee_on_amount += $_->setup + $_->recur;
 636             }
 637           }
 638           $cust_bill->set('cust_bill_pkg', \@charge_fee_on_item);
 639           $cust_bill->set('charged', $charge_fee_on_amount);
 640         }
 641
 642       } # $cust_bill is now set
 643       # calculate the fee
 644       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 645       # link this so that we can clear the marker on inserting the line item
 646       $fee_item->set('fee_origin', $fee_origin);
 647       push @fee_items, $fee_item;
 648
 649     }
 650
 651     # add fees to the invoice
 652     foreach my $fee_item (@fee_items) {
 653
 654       push @cust_bill_pkg, $fee_item;
 655       ${ $total_setup{$pass} } += $fee_item->setup;
 656       ${ $total_recur{$pass} } += $fee_item->recur;
 657
 658       my $part_fee = $fee_item->part_fee;
 659       my $fee_location = $self->ship_location; # I think?
 660
 661       my $error = $self->_handle_taxes(
 662         $taxlisthash{$pass},
 663         $fee_item,
 664         location => $fee_location
 665         # probably not right to pass cancel => 1 for fees
 666       );
 667       return $error if $error;
 668
 669     }
 670
 671     # XXX implementation of fees is supposed to make this go away...
 672     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 673            !$conf->exists('postal_invoice-recurring_only')
 674        )
 675     {
 676
 677       my $postal_pkg = $self->charge_postal_fee();
 678       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 679
 680         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 681         return "can't charge postal invoice fee for customer ".
 682           $self->custnum. ": $postal_pkg";
 683
 684       } elsif ( $postal_pkg ) {
 685
 686         my $real_pkgpart = $postal_pkg->pkgpart;
 687         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 688         # suffer from performance issues
 689         $options{has_hidden} = 0;
 690         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 691         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 692
 693         foreach my $part_pkg ( @part_pkg ) {
 694           my %postal_options = %options;
 695           delete $postal_options{cancel};
 696           my $error =
 697             $self->_make_lines( 'part_pkg'            => $part_pkg,
 698                                 'cust_pkg'            => $postal_pkg,
 699                                 'precommit_hooks'     => \@precommit_hooks,
 700                                 'line_items'          => \@cust_bill_pkg,
 701                                 'setup'               => $total_setup{$pass},
 702                                 'recur'               => $total_recur{$pass},
 703                                 'tax_matrix'          => $taxlisthash{$pass},
 704                                 'time'                => $time,
 705                                 'real_pkgpart'        => $real_pkgpart,
 706                                 'options'             => \%postal_options,
 707                               );
 708           if ($error) {
 709             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 710             return $error;
 711           }
 712         }
 713
 714         # it's silly to have a zero value postal_pkg, but....
 715         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 716
 717       }
 718
 719     }
 720
 721     my $listref_or_error =
 722       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 723
 724     unless ( ref( $listref_or_error ) ) {
 725       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 726       return $listref_or_error;
 727     }
 728
 729     foreach my $taxline ( @$listref_or_error ) {
 730       ${ $total_setup{$pass} } =
 731         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 732       push @cust_bill_pkg, $taxline;
 733     }
 734
 735     #add tax adjustments
 736     warn "adding tax adjustments...\n" if $DEBUG > 2;
 737     foreach my $cust_tax_adjustment (
 738       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 739                                        'billpkgnum' => '',
 740                                      }
 741              )
 742     ) {
 743
 744       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 745
 746       my $itemdesc = $cust_tax_adjustment->taxname;
 747       $itemdesc = '' if $itemdesc eq 'Tax';
 748
 749       push @cust_bill_pkg, new FS::cust_bill_pkg {
 750         'pkgnum'      => 0,
 751         'setup'       => $tax,
 752         'recur'       => 0,
 753         'sdate'       => '',
 754         'edate'       => '',
 755         'itemdesc'    => $itemdesc,
 756         'itemcomment' => $cust_tax_adjustment->comment,
 757         'cust_tax_adjustment' => $cust_tax_adjustment,
 758         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 759       };
 760
 761     }
 762
 763     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 764
 765     my $balance = $self->balance;
 766
 767     my $previous_bill = qsearchs({ 'table'     => 'cust_bill',
 768                                    'hashref'   => { custnum=>$self->custnum },
 769                                    'extra_sql' => 'ORDER BY _date DESC LIMIT 1',
 770                                 });
 771     my $previous_balance =
 772       $previous_bill
 773         ? ( $previous_bill->billing_balance + $previous_bill->charged )
 774         : 0;
 775
 776     $log->debug('creating the new invoice', %logopt);
 777     warn "creating the new invoice\n" if $DEBUG;
 778     #create the new invoice
 779     my $cust_bill = new FS::cust_bill ( {
 780       'custnum'             => $self->custnum,
 781       '_date'               => $invoice_time,
 782       'charged'             => $charged,
 783       'billing_balance'     => $balance,
 784       'previous_balance'    => $previous_balance,
 785       'invoice_terms'       => $options{'invoice_terms'},
 786       'cust_bill_pkg'       => \@cust_bill_pkg,
 787     } );
 788     $error = $cust_bill->insert unless $options{no_commit};
 789     if ( $error ) {
 790       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 791       return "can't create invoice for customer #". $self->custnum. ": $error";
 792     }
 793     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 794
 795   } #foreach my $pass ( keys %cust_bill_pkg )
 796
 797   foreach my $hook ( @precommit_hooks ) {
 798     eval {
 799       &{$hook}; #($self) ?
 800     } unless $options{no_commit};
 801     if ( $@ ) {
 802       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 803       return "$@ running precommit hook $hook\n";
 804     }
 805   }
 806
 807   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 808
 809   ''; #no error
 810 }
 811
 812 #discard bundled packages of 0 value
 813 # XXX we should reconsider whether we even need this
 814 sub _omit_zero_value_bundles {
 815   my @in = @_;
 816
 817   my @out = ();
 818   my @bundle = ();
 819   my $discount_show_always = $conf->exists('discount-show-always');
 820   my $show_this = 0;
 821
 822   # Sort @in the same way we do during invoice rendering, so we can identify
 823   # bundles.  See FS::Template_Mixin::_items_nontax.
 824   @in = sort { $a->pkgnum <=> $b->pkgnum        or
 825                $a->sdate  <=> $b->sdate         or
 826                ($a->pkgpart_override ? 0 : -1)  or
 827                ($b->pkgpart_override ? 0 : 1)   or
 828                $b->hidden cmp $a->hidden        or
 829                $a->pkgpart_override <=> $b->pkgpart_override
 830              } @in;
 831
 832   # this is a pack-and-deliver pattern. every time there's a cust_bill_pkg
 833   # _without_ pkgpart_override, that's the start of the new bundle. if there's
 834   # an existing bundle, and it contains a nonzero amount (or a zero amount
 835   # that's displayable anyway), push all line items in the bundle.
 836   foreach my $cust_bill_pkg ( @in ) {
 837
 838     if (scalar(@bundle) and !$cust_bill_pkg->pkgpart_override) {
 839       # ship out this bundle and reset it
 840       if ( $show_this ) {
 841         push @out, @bundle;
 842       }
 843       @bundle = ();
 844       $show_this = 0;
 845     }
 846
 847     # add this item to the current bundle
 848     push @bundle, $cust_bill_pkg;
 849
 850     # determine if it makes the bundle displayable
 851     if (   $cust_bill_pkg->setup > 0
 852         or $cust_bill_pkg->recur > 0
 853         or $cust_bill_pkg->setup_show_zero
 854         or $cust_bill_pkg->recur_show_zero
 855         or ($discount_show_always
 856           and scalar(@{ $cust_bill_pkg->get('discounts')})
 857           )
 858     ) {
 859       $show_this++;
 860     }
 861   }
 862
 863   # last bundle
 864   if ( $show_this) {
 865     push @out, @bundle;
 866   }
 867
 868   warn "  _omit_zero_value_bundles: ". scalar(@in).
 869        '->'. scalar(@out). "\n" #. Dumper(@out). "\n"
 870     if $DEBUG > 2;
 871
 872   @out;
 873 }
 874
 875 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 876
 877 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 878 Usually used internally by bill method B<bill>.
 879
 880 If there is an error, returns the error, otherwise returns reference to a
 881 list of line items suitable for insertion.
 882
 883 =over 4
 884
 885 =item LINEITEMREF
 886
 887 An array ref of the line items being billed.
 888
 889 =item TAXHASHREF
 890
 891 A strange beast.  The keys to this hash are internal identifiers consisting
 892 of the name of the tax object type, a space, and its unique identifier ( e.g.
 893  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 894 item in the list is the tax object.  The remaining items are either line
 895 items or floating point values (currency amounts).
 896
 897 The taxes are calculated on this entity.  Calculated exemption records are
 898 transferred to the LINEITEMREF items on the assumption that they are related.
 899
 900 Read the source.
 901
 902 =item INVOICE_TIME
 903
 904 This specifies the date appearing on the associated invoice.  Some
 905 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 906
 907 =back
 908
 909 =cut
 910
 911 sub calculate_taxes {
 912   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 913
 914   # $taxlisthash is a hashref
 915   # keys are identifiers, values are arrayrefs
 916   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 917   # then a cust_bill_pkg object the tax applies to, then the charge class
 918   # on that object (setup, recur, a usage class number, or '')
 919   # For internal taxes the charge class is always undef.
 920
 921   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 922
 923   warn "$me calculate_taxes\n"
 924        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 925     if $DEBUG > 2;
 926
 927   my $custnum = $self->custnum;
 928   # The main tax accumulator.  One bin for each tax name (itemdesc).
 929   # For each subdivision of tax under this name, push a cust_bill_pkg item
 930   # for the calculated tax into the arrayref.
 931   # keys are tax names
 932   # values are arrayrefs of tax lines
 933   my %taxname = ();
 934
 935   # keys are taxlisthash keys (internal identifiers)
 936   # values are (cumulative) amounts
 937   my %tax_amount = ();
 938
 939   # keys are taxlisthash keys
 940   # values are arrayrefs of cust_tax_exempt_pkg objects
 941   my %tax_exemption;
 942
 943   # For tax on tax calculation, we need to remember which taxable items
 944   # (and charge classes) had which taxes applied to them.
 945   #
 946   # keys are cust_bill_pkg objects (taxable items)
 947   # values are hashrefs
 948   #   keys are charge classes
 949   #   values are hashrefs
 950   #     keys are taxnums (in tax_rate only; cust_main_county doesn't use this)
 951   #     values are the taxlines generated for those taxes
 952   tie my %item_has_tax, 'Tie::RefHash',
 953     map { $_ => {} } @$cust_bill_pkg;
 954
 955   foreach my $tax_id ( keys %$taxlisthash ) {
 956     # $tax_id: the identifier of the tax we are calculating in this pass
 957
 958     my $taxables = $taxlisthash->{$tax_id};
 959     my $tax_object = shift @$taxables;
 960     my $taxnum = $tax_object->taxnum;
 961     # $tax_object is a cust_main_county or tax_rate
 962     # (with billpkgnum, pkgnum, locationnum set)
 963     # the rest of @{ $taxlisthash->{$tax_id} } is cust_bill_pkg objects,
 964     # optionally followed by their charge classes.
 965     warn "found ". $tax_object->taxname. " as $tax_id\n" if $DEBUG > 2;
 966
 967     # taxline calculates the tax on all cust_bill_pkgs in the
 968     # first (arrayref) argument.
 969     #
 970     # Note that non-monthly exemptions have already been calculated and
 971     # attached to the items.  Monthly exemptions will be attached in this
 972     # step.
 973     my $exemptions = $tax_exemption{$tax_id} ||= [];
 974     if ( $tax_object->isa('FS::tax_rate') ) { # EXTERNAL TAXES
 975       # STILL have tax_rate-specific crap in here...
 976       my @taxlines = $tax_object->taxline( $taxables,
 977                               'custnum'      => $custnum,
 978                               'invoice_time' => $invoice_time,
 979                               'exemptions'   => $exemptions,
 980                               );
 981       next if !@taxlines;
 982       if (!ref $taxlines[0]) {
 983         # it's an error string
 984         warn "error evaluating $tax_id on custnum $custnum\n";
 985         return $taxlines[0];
 986       }
 987       foreach my $taxline (@taxlines) {
 988         push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 989         my $link = $taxline->get('cust_bill_pkg_tax_rate_location')->[0];
 990         my $taxable_item = $link->taxable_cust_bill_pkg;
 991         $item_has_tax{$taxable_item}{$taxline->_class}{$taxnum} = $taxline;
 992       }
 993
 994     } else { # INTERNAL TAXES
 995       # we can do this in a single taxline, because it's not stupid
 996
 997       my $taxline =  $tax_object->taxline( $taxables,
 998                         'custnum'      => $custnum,
 999                         'invoice_time' => $invoice_time,
1000                         'exemptions'   => $exemptions,
1001                       );
1002       next if !$taxline;
1003       if (!ref $taxline) {
1004         # it's an error string
1005         warn "error evaluating $tax_id on custnum $custnum\n";
1006         return $taxline;
1007       }
1008       # if the calculated tax is zero, don't even keep it
1009       next if $taxline->setup < 0.001;
1010       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1011     }
1012   }
1013   $DB::single = 1; # XXX
1014
1015   # all first-tier taxes are calculated.  now for tax on tax:
1016
1017   foreach my $taxable_item ( @$cust_bill_pkg ) {
1018     # taxes that apply to this item
1019     my $this_has_tax = $item_has_tax{$taxable_item};
1020
1021     my $location = $taxable_item->tax_location;
1022
1023     foreach my $charge_class (keys %$this_has_tax) {
1024       # taxes that apply to this item and charge class
1025       my $this_class_has_tax = $this_has_tax->{$charge_class};
1026       foreach my $taxnum (keys %$this_class_has_tax) {
1027
1028         # for each tax item that was calculated in phase 1, get the
1029         # tax definition
1030         my $tax_object = FS::tax_rate->by_key($taxnum);
1031         # and find all taxes that apply to it in this location
1032         my @tot = $tax_object->tax_on_tax( $location );
1033         next if !@tot;
1034         warn "found possible taxed taxnum $taxnum\n"
1035           if $DEBUG > 2;
1036         # Calculate ToT separately for each taxable item and class, and only
1037         # if _that class on the item_ is already taxed under the ToT.  This is
1038         # counterintuitive.
1039         # See RT#5243 and RT#36380.
1040         foreach my $tot (@tot) {
1041           my $totnum = $tot->taxnum;
1042           warn "checking taxnum $totnum which we call ". $tot->taxname ."\n"
1043             if $DEBUG > 2;
1044           # note: if the _null class_ on this item is taxed under the ToT,
1045           # then this specific class is taxed also (because null class
1046           # includes all classes) and so ToT is applicable.
1047           if (
1048                 exists $this_class_has_tax->{ $totnum }
1049              or exists $this_has_tax->{''}{ $totnum }
1050           ) {
1051
1052             warn "calculating tax on tax: taxnum $totnum on $taxnum\n"
1053               if $DEBUG;
1054             my @taxlines = $tot->taxline(
1055                               $this_class_has_tax->{ $taxnum }, # the first-stage tax
1056                               'custnum'       => $custnum,
1057                               'invoice_time'  => $invoice_time,
1058                              );
1059             next if (!@taxlines); # it didn't apply after all
1060             if (!ref($taxlines[0])) {
1061               warn "error evaluating taxnum $totnum TOT on custnum $custnum\n";
1062               return $taxlines[0];
1063             }
1064             foreach my $taxline (@taxlines) {
1065               push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1066             }
1067           } # if $has_tax
1068         } # foreach my $tot (tax-on-tax rate definition)
1069       } # foreach $taxnum (first-tier rate definition)
1070     } # foreach $charge_class
1071   } # foreach $taxable_item
1072
1073   #consolidate and create tax line items
1074   warn "consolidating and generating...\n" if $DEBUG > 2;
1075   my %final_tax_items; # taxname => item
1076   foreach my $taxname ( keys %taxname ) {
1077     my @cust_bill_pkg_tax_location;
1078     my @cust_bill_pkg_tax_rate_location;
1079     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
1080         'pkgnum'    => 0,
1081         'recur'     => 0,
1082         'sdate'     => '',
1083         'edate'     => '',
1084         'itemdesc'  => $taxname,
1085         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
1086         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
1087     });
1088
1089     my $tax_total = 0;
1090     my %seen = ();
1091     warn "adding $taxname\n" if $DEBUG > 1;
1092     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
1093       next if $taxitem->get('setup') == 0;
1094       # if ( ref($taxitem) eq 'FS::cust_bill_pkg' )  # always true
1095       # then we need to transfer the amount and the links from the
1096       # line item to the new one we're creating.
1097       $tax_total += $taxitem->setup;
1098       my @links = @{
1099         $taxitem->get('cust_bill_pkg_tax_location') ||
1100         $taxitem->get('cust_bill_pkg_tax_rate_location') ||
1101         []
1102       };
1103       foreach my $link ( @links ) {
1104         $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
1105         if ($link->isa('FS::cust_bill_pkg_tax_location')) {
1106           push @cust_bill_pkg_tax_location, $link;
1107         } elsif ($link->isa('FS::cust_bill_pkg_tax_rate_location')) {
1108           push @cust_bill_pkg_tax_rate_location, $link;
1109         }
1110       }
1111     }
1112     next unless $tax_total;
1113
1114     # we should really neverround this up...I guess it's okay if taxline
1115     # already returns amounts with 2 decimal places
1116     $tax_total = sprintf('%.2f', $tax_total );
1117     $tax_cust_bill_pkg->set('setup', $tax_total);
1118
1119     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1120                                                    'disabled'     => '',
1121                                                  },
1122                                );
1123
1124     my @display = ();
1125     if ( $pkg_category and
1126          $conf->config('invoice_latexsummary') ||
1127          $conf->config('invoice_htmlsummary')
1128        )
1129     {
1130
1131       my %hash = (  'section' => $pkg_category->categoryname );
1132       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1133
1134     }
1135     $tax_cust_bill_pkg->set('display', \@display);
1136
1137     $final_tax_items{$taxname} = $tax_cust_bill_pkg;
1138   } # foreach $taxname
1139
1140   # fix ToT backlinks for taxes that have been consolidated
1141   # (has to be done in a separate pass)
1142   foreach my $tax_item (values %final_tax_items) {
1143     foreach my $taxable_link (@{ $tax_item->cust_bill_pkg_tax_rate_location }) {
1144       my $taxed_item = $taxable_link->taxable_cust_bill_pkg;
1145       next if $taxed_item->pkgnum > 0; # primary taxes
1146       my $taxname = $taxed_item->itemdesc;
1147       $taxable_link->set('taxable_cust_bill_pkg', $final_tax_items{ $taxname });
1148     }
1149   }
1150
1151   [ values %final_tax_items ]
1152 }
1153
1154 sub _make_lines {
1155   my ($self, %params) = @_;
1156
1157   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1158
1159   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1160   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1161   my $cust_location = $cust_pkg->tax_location;
1162   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1163   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1164   my $total_setup = $params{setup} or die "no setup accumulator specified";
1165   my $total_recur = $params{recur} or die "no recur accumulator specified";
1166   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1167   my $time = $params{'time'} or die "no time specified";
1168   my (%options) = %{$params{options}};
1169
1170   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1171     # this should never happen
1172     die 'freq_override billing attempted on non-monthly package '.
1173       $cust_pkg->pkgnum;
1174   }
1175
1176   my $dbh = dbh;
1177   my $real_pkgpart = $params{real_pkgpart};
1178   my %hash = $cust_pkg->hash;
1179   my $old_cust_pkg = new FS::cust_pkg \%hash;
1180
1181   my @details = ();
1182   my $lineitems = 0;
1183
1184   $cust_pkg->pkgpart($part_pkg->pkgpart);
1185
1186   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1187                      ? day_end( $time )
1188                      : $time
1189                  );
1190
1191   ###
1192   # bill setup
1193   ###
1194
1195   my $setup = 0;
1196   my $unitsetup = 0;
1197   my @setup_discounts = ();
1198   my %setup_param = ( 'discounts'    => \@setup_discounts,
1199                       'real_pkgpart' => $params{real_pkgpart}
1200                     );
1201   # Conditions for setting setup date and charging the setup fee:
1202   # - this is not a recurring-only billing run
1203   # - and the package is not currently being canceled
1204   # - and, unless we're specifically told otherwise via 'resetup':
1205   #   - it doesn't already HAVE a setup date
1206   #   - or a start date in the future
1207   #   - and it's not suspended
1208   # - and it doesn't have an expire date in the past
1209   #
1210   # The "disable_setup_suspended" option is now obsolete; we never set the
1211   # setup date on a suspended package.
1212   if (     ! $options{recurring_only}
1213        and ! $options{cancel}
1214        and ( $options{'resetup'}
1215              || ( ! $cust_pkg->setup
1216                   && ( ! $cust_pkg->start_date
1217                        || $cust_pkg->start_date <= $cmp_time
1218                      )
1219                   && ( ! $cust_pkg->getfield('susp') )
1220               )
1221            )
1222        and ( ! $cust_pkg->expire
1223              || $cust_pkg->expire > $cmp_time )
1224      )
1225   {
1226
1227     warn "    bill setup\n" if $DEBUG > 1;
1228
1229     unless ( $cust_pkg->waive_setup ) {
1230         $lineitems++;
1231
1232         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1233         return "$@ running calc_setup for $cust_pkg\n"
1234           if $@;
1235
1236         # Only increment unitsetup here if there IS a setup fee.
1237         # prorate_defer_bill may cause calc_setup on a setup-stage package
1238         # to return zero, and the setup fee to be charged later. (This happens
1239         # when it's first billed on the prorate cutoff day. RT#31276.)
1240         if ( $setup ) {
1241           $unitsetup = $cust_pkg->base_setup()
1242                          || $setup; #XXX uuh
1243         }
1244     }
1245
1246     $cust_pkg->setfield('setup', $time)
1247       unless $cust_pkg->setup;
1248           #do need it, but it won't get written to the db
1249           #|| $cust_pkg->pkgpart != $real_pkgpart;
1250
1251     $cust_pkg->setfield('start_date', '')
1252       if $cust_pkg->start_date;
1253
1254   }
1255
1256   ###
1257   # bill recurring fee
1258   ###
1259
1260   my $recur = 0;
1261   my $unitrecur = 0;
1262   my @recur_discounts = ();
1263   my $sdate;
1264
1265   my $override_quantity;
1266
1267   # Conditions for billing the recurring fee:
1268   # - the package doesn't have a future start date
1269   # - and it's not suspended
1270   #   - unless suspend_bill is enabled on the package or package def
1271   #     - but still not, if the package is on hold
1272   #   - or it's suspended for a delayed cancellation
1273   # - and its next bill date is in the past
1274   #   - or it doesn't have a next bill date yet
1275   #   - or it's a one-time charge
1276   #   - or it's a CDR plan with the "bill_every_call" option
1277   #   - or it's being canceled
1278   # - and it doesn't have an expire date in the past (this can happen with
1279   #   advance billing)
1280   #   - again, unless it's being canceled
1281   if (     ! $cust_pkg->start_date
1282        and
1283            ( ! $cust_pkg->susp
1284                || ( $cust_pkg->susp != $cust_pkg->order_date
1285                       && (    $cust_pkg->option('suspend_bill',1)
1286                            || ( $part_pkg->option('suspend_bill', 1)
1287                                  && ! $cust_pkg->option('no_suspend_bill',1)
1288                               )
1289                          )
1290                   )
1291                || $cust_pkg->is_status_delay_cancel
1292            )
1293        and
1294             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1295          || ( $part_pkg->plan eq 'voip_cdr'
1296                && $part_pkg->option('bill_every_call')
1297             )
1298          || $options{cancel}
1299
1300        and
1301           ( ! $cust_pkg->expire
1302             || $cust_pkg->expire > $cmp_time
1303             || $options{cancel}
1304           )
1305   ) {
1306
1307     # XXX should this be a package event?  probably.  events are called
1308     # at collection time at the moment, though...
1309     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1310       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1311       #don't want to reset usage just cause we want a line item??
1312       #&& $part_pkg->pkgpart == $real_pkgpart;
1313
1314     warn "    bill recur\n" if $DEBUG > 1;
1315     $lineitems++;
1316
1317     # XXX shared with $recur_prog
1318     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1319              || $cust_pkg->setup
1320              || $time;
1321
1322     #over two params!  lets at least switch to a hashref for the rest...
1323     my $increment_next_bill = ( $part_pkg->freq ne '0'
1324                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1325                                 && !$options{cancel}
1326                               );
1327     my %param = ( %setup_param,
1328                   'precommit_hooks'     => $precommit_hooks,
1329                   'increment_next_bill' => $increment_next_bill,
1330                   'discounts'           => \@recur_discounts,
1331                   'real_pkgpart'        => $real_pkgpart,
1332                   'freq_override'       => $options{freq_override} || '',
1333                   'setup_fee'           => 0,
1334                 );
1335
1336     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1337
1338     # There may be some part_pkg for which this is wrong.  Only those
1339     # which can_discount are supported.
1340     # (the UI should prevent adding discounts to these at the moment)
1341
1342     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1343          " for pkgpart ". $cust_pkg->pkgpart.
1344          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1345       if $DEBUG > 2;
1346
1347     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1348     return "$@ running $method for $cust_pkg\n"
1349       if ( $@ );
1350
1351     if ($recur eq 'NOTHING') {
1352       # then calc_cancel (or calc_recur but that's not used) has declined to
1353       # generate a recurring lineitem at all. treat this as zero, but also
1354       # try not to generate a lineitem.
1355       $recur = 0;
1356       $lineitems--;
1357     }
1358
1359     #base_cancel???
1360     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1361
1362     if ( $param{'override_quantity'} ) {
1363       $override_quantity = $param{'override_quantity'};
1364       $unitrecur = $recur / $override_quantity;
1365     }
1366
1367     if ( $increment_next_bill ) {
1368
1369       my $next_bill;
1370
1371       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1372         # supplemental package
1373         # to keep in sync with the main package, simulate billing at
1374         # its frequency
1375         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1376         my $supp_pkg_freq = $part_pkg->freq;
1377         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1378         if ( $ratio != int($ratio) ) {
1379           # the UI should prevent setting up packages like this, but just
1380           # in case
1381           return "supplemental package period is not an integer multiple of main  package period";
1382         }
1383         $next_bill = $sdate;
1384         for (1..$ratio) {
1385           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1386         }
1387
1388       } else {
1389         # the normal case
1390       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1391       return "unparsable frequency: ".
1392         ($options{freq_override} || $part_pkg->freq)
1393         if $next_bill == -1;
1394       }
1395
1396       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1397       # only for figuring next bill date, nothing else, so, reset $sdate again
1398       # here
1399       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1400       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1401       $cust_pkg->last_bill($sdate);
1402
1403       $cust_pkg->setfield('bill', $next_bill );
1404
1405     }
1406
1407     if ( $param{'setup_fee'} ) {
1408       # Add an additional setup fee at the billing stage.
1409       # Used for prorate_defer_bill.
1410       $setup += $param{'setup_fee'};
1411       $unitsetup = $cust_pkg->base_setup();
1412       $lineitems++;
1413     }
1414
1415     if ( defined $param{'discount_left_setup'} ) {
1416         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1417             $setup -= $discount_setup;
1418         }
1419     }
1420
1421   } # end of recurring fee
1422
1423   warn "\$setup is undefined" unless defined($setup);
1424   warn "\$recur is undefined" unless defined($recur);
1425   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1426
1427   ###
1428   # If there's line items, create em cust_bill_pkg records
1429   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1430   ###
1431
1432   if ( $lineitems ) {
1433
1434     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1435       # hmm.. and if just the options are modified in some weird price plan?
1436
1437       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1438         if $DEBUG >1;
1439
1440       my $error = $cust_pkg->replace( $old_cust_pkg,
1441                                       'depend_jobnum'=>$options{depend_jobnum},
1442                                       'options' => { $cust_pkg->options },
1443                                     )
1444         unless $options{no_commit};
1445       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1446         if $error; #just in case
1447     }
1448
1449     $setup = sprintf( "%.2f", $setup );
1450     $recur = sprintf( "%.2f", $recur );
1451     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1452       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1453     }
1454     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1455       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1456     }
1457
1458     my $discount_show_always = $conf->exists('discount-show-always')
1459                                && (    ($setup == 0 && scalar(@setup_discounts))
1460                                     || ($recur == 0 && scalar(@recur_discounts))
1461                                   );
1462
1463     if (    $setup != 0
1464          || $recur != 0
1465          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1466          || $discount_show_always
1467          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1468          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1469        )
1470     {
1471
1472       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1473         if $DEBUG > 1;
1474
1475       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1476       if ( $DEBUG > 1 ) {
1477         warn "      adding customer package invoice detail: $_\n"
1478           foreach @cust_pkg_detail;
1479       }
1480       push @details, @cust_pkg_detail;
1481
1482       my $cust_bill_pkg = new FS::cust_bill_pkg {
1483         'pkgnum'    => $cust_pkg->pkgnum,
1484         'setup'     => $setup,
1485         'unitsetup' => sprintf('%.2f', $unitsetup),
1486         'recur'     => $recur,
1487         'unitrecur' => sprintf('%.2f', $unitrecur),
1488         'quantity'  => $override_quantity || $cust_pkg->quantity,
1489         'details'   => \@details,
1490         'discounts' => [ @setup_discounts, @recur_discounts ],
1491         'hidden'    => $part_pkg->hidden,
1492         'freq'      => $part_pkg->freq,
1493       };
1494
1495       if ( $part_pkg->option('prorate_defer_bill',1)
1496            and !$hash{last_bill} ) {
1497         # both preceding and upcoming, technically
1498         $cust_bill_pkg->sdate( $cust_pkg->setup );
1499         $cust_bill_pkg->edate( $cust_pkg->bill );
1500       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1501         $cust_bill_pkg->sdate( $hash{last_bill} );
1502         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1503         $cust_bill_pkg->edate( $time ) if $options{cancel};
1504       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1505         $cust_bill_pkg->sdate( $sdate );
1506         $cust_bill_pkg->edate( $cust_pkg->bill );
1507         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1508       }
1509
1510       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1511         unless $part_pkg->pkgpart == $real_pkgpart;
1512
1513       $$total_setup += $setup;
1514       $$total_recur += $recur;
1515
1516       ###
1517       # handle taxes
1518       ###
1519
1520       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg,
1521         cancel => $options{cancel} );
1522       return $error if $error;
1523
1524       $cust_bill_pkg->set_display(
1525         part_pkg     => $part_pkg,
1526         real_pkgpart => $real_pkgpart,
1527       );
1528
1529       push @$cust_bill_pkgs, $cust_bill_pkg;
1530
1531     } #if $setup != 0 || $recur != 0
1532
1533   } #if $line_items
1534
1535   '';
1536
1537 }
1538
1539 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1540
1541 Takes one argument, a cust_pkg object that is being billed.  This will
1542 be called only if the package was created by a package change, and has
1543 not been billed since the package change, and package balance tracking
1544 is enabled.  The second argument can be an alternate package number to
1545 transfer the balance from; this should not be used externally.
1546
1547 Transfers the balance from the previous package (now canceled) to
1548 this package, by crediting one package and creating an invoice item for
1549 the other.  Inserts the credit and returns the invoice item (so that it
1550 can be added to an invoice that's being built).
1551
1552 If the previous package was never billed, and was also created by a package
1553 change, then this will also transfer the balance from I<its> previous
1554 package, and so on, until reaching a package that either has been billed
1555 or was not created by a package change.
1556
1557 =cut
1558
1559 my $balance_transfer_reason;
1560
1561 sub _transfer_balance {
1562   my $self = shift;
1563   my $cust_pkg = shift;
1564   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1565   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1566
1567   my @transfers;
1568
1569   # if $from_pkg is not the first package in the chain, and it was never
1570   # billed, walk back
1571   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1572     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1573   }
1574
1575   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1576   if ( $prev_balance != 0 ) {
1577     $balance_transfer_reason ||= FS::reason->new_or_existing(
1578       'reason' => 'Package balance transfer',
1579       'type'   => 'Internal adjustment',
1580       'class'  => 'R'
1581     );
1582
1583     my $credit = FS::cust_credit->new({
1584         'custnum'   => $self->custnum,
1585         'amount'    => abs($prev_balance),
1586         'reasonnum' => $balance_transfer_reason->reasonnum,
1587         '_date'     => $cust_pkg->change_date,
1588     });
1589
1590     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1591         'setup'     => 0,
1592         'recur'     => abs($prev_balance),
1593         #'sdate'     => $from_pkg->last_bill, # not sure about this
1594         #'edate'     => $cust_pkg->change_date,
1595         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1596                                  $from_pkg->part_pkg->pkg),
1597     });
1598
1599     if ( $prev_balance > 0 ) {
1600       # credit the old package, charge the new one
1601       $credit->set('pkgnum', $from_pkgnum);
1602       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1603     } else {
1604       # the reverse
1605       $credit->set('pkgnum', $cust_pkg->pkgnum);
1606       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1607     }
1608     my $error = $credit->insert;
1609     die "error transferring package balance from #".$from_pkgnum.
1610         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1611
1612     push @transfers, $cust_bill_pkg;
1613   } # $prev_balance != 0
1614
1615   return @transfers;
1616 }
1617
1618 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1619
1620 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1621 from _make_lines.
1622
1623 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1624 this:
1625 {
1626   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1627   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1628 }
1629
1630 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1631 is always the cust_main_county or tax_rate identified by the key.
1632
1633 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1634 the 'taxline' method to calculate the amount of the tax.  This doesn't
1635 happen until calculate_taxes, though.
1636
1637 OPTIONS may include:
1638 - part_item: a part_pkg or part_fee object to be used as the package/fee
1639   definition.
1640 - location: a cust_location to be used as the billing location.
1641 - cancel: true if this package is being billed on cancellation.  This
1642   allows tax to be calculated on usage charges only.
1643
1644 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1645 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1646 the customer's default service location).
1647
1648 This method will also calculate exemptions for any taxes that apply to the
1649 line item (using the C<set_exemptions> method of L<FS::cust_bill_pkg>) and
1650 attach them.  This is the only place C<set_exemptions> is called in normal
1651 invoice processing.
1652
1653 =cut
1654
1655 sub _handle_taxes {
1656   my $self = shift;
1657   my $taxlisthash = shift;
1658   my $cust_bill_pkg = shift;
1659   my %options = @_;
1660
1661   # at this point I realize that we have enough information to infer all this
1662   # stuff, instead of passing around giant honking argument lists
1663   my $location = $options{location} || $cust_bill_pkg->tax_location;
1664   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1665
1666   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1667
1668   return if ( $self->payby eq 'COMP' ); #dubious
1669
1670   if ( $conf->exists('enable_taxproducts')
1671        && ( scalar($part_item->part_pkg_taxoverride)
1672             || $part_item->has_taxproduct
1673           )
1674      )
1675     {
1676
1677     # EXTERNAL TAX RATES (via tax_rate)
1678     my %cust_bill_pkg = ();
1679     my %taxes = ();
1680
1681     my @classes;
1682     my $usage = $cust_bill_pkg->usage || 0;
1683     push @classes, $cust_bill_pkg->usage_classes if $usage;
1684     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1685     push @classes, 'recur' if ($cust_bill_pkg->recur - $usage)
1686         and !$options{cancel};
1687     # that's better--probably don't even need $options{cancel} now
1688     # but leave it for now, just to be safe
1689     #
1690     # About $options{cancel}: This protects against charging per-line or
1691     # per-customer or other flat-rate surcharges on a package that's being
1692     # billed on cancellation (which is an out-of-cycle bill and should only
1693     # have usage charges).  See RT#29443.
1694
1695     # customer exemption is now handled in the 'taxline' method
1696     #my $exempt = $conf->exists('cust_class-tax_exempt')
1697     #               ? ( $self->cust_class ? $self->cust_class->tax : '' )
1698     #               : $self->tax;
1699     # standardize this just to be sure
1700     #$exempt = ($exempt eq 'Y') ? 'Y' : '';
1701     #
1702     #if ( !$exempt ) {
1703
1704     unless (exists $taxes{''}) {
1705       # unsure what purpose this serves, but last time I deleted something
1706       # from here just because I didn't see the point, it actually did
1707       # something important.
1708       my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1709       return $err_or_ref unless ref($err_or_ref);
1710       $taxes{''} = $err_or_ref;
1711     }
1712
1713     # NO DISINTEGRATIONS.
1714     # my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1715     #
1716     # do not call taxline() with any argument except the entire set of
1717     # cust_bill_pkgs on an invoice that are eligible for the tax.
1718
1719     # only calculate exemptions once for each tax rate, even if it's used
1720     # for multiple classes
1721     my %tax_seen = ();
1722
1723     foreach my $class (@classes) {
1724       my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1725       return $err_or_ref unless ref($err_or_ref);
1726       my @taxes = @$err_or_ref;
1727
1728       next if !@taxes;
1729
1730       foreach my $tax ( @taxes ) {
1731
1732         my $tax_id = ref( $tax ). ' '. $tax->taxnum;
1733         # $taxlisthash: keys are tax identifiers ('FS::tax_rate 123456').
1734         # Values are arrayrefs, first the tax object (cust_main_county
1735         # or tax_rate), then the cust_bill_pkg object that the
1736         # tax applies to, then the tax class (setup, recur, usage classnum).
1737         $taxlisthash->{ $tax_id } ||= [ $tax ];
1738         push @{ $taxlisthash->{ $tax_id  } }, $cust_bill_pkg, $class;
1739
1740         # determine any exemptions that apply
1741         if (!$tax_seen{$tax_id}) {
1742           $cust_bill_pkg->set_exemptions( $tax, custnum => $self->custnum );
1743           $tax_seen{$tax_id} = 1;
1744         }
1745
1746         # tax on tax will be done later, when we actually create the tax
1747         # line items
1748
1749       }
1750     }
1751
1752   } else {
1753
1754     # INTERNAL TAX RATES (cust_main_county)
1755
1756     # We fetch taxes even if the customer is completely exempt,
1757     # because we need to record that fact.
1758
1759     my @loc_keys = qw( district city county state country );
1760     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1761
1762     $taxhash{'taxclass'} = $part_item->taxclass;
1763
1764     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1765
1766     my @taxes = (); # entries are cust_main_county objects
1767     my %taxhash_elim = %taxhash;
1768     my @elim = qw( district city county state );
1769     do {
1770
1771       #first try a match with taxclass
1772       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1773
1774       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1775         #then try a match without taxclass
1776         my %no_taxclass = %taxhash_elim;
1777         $no_taxclass{ 'taxclass' } = '';
1778         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1779       }
1780
1781       $taxhash_elim{ shift(@elim) } = '';
1782
1783     } while ( !scalar(@taxes) && scalar(@elim) );
1784
1785     foreach (@taxes) {
1786       my $tax_id = 'cust_main_county '.$_->taxnum;
1787       $taxlisthash->{$tax_id} ||= [ $_ ];
1788       $cust_bill_pkg->set_exemptions($_, custnum => $self->custnum);
1789       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1790     }
1791
1792   }
1793   '';
1794 }
1795
1796 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1797
1798 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1799 or part_fee (which will define the tax eligibility of the product), CLASS is
1800 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1801 location where the service was provided (or billed, depending on
1802 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1803 can apply to this line item.
1804
1805 =cut
1806
1807 sub _gather_taxes {
1808   my $self = shift;
1809   my $part_item = shift;
1810   my $class = shift;
1811   my $location = shift;
1812
1813   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1814
1815   my $geocode = $location->geocode('cch');
1816
1817   [ $part_item->tax_rates('cch', $geocode, $class) ]
1818
1819 }
1820
1821 =item collect [ HASHREF | OPTION => VALUE ... ]
1822
1823 (Attempt to) collect money for this customer's outstanding invoices (see
1824 L<FS::cust_bill>).  Usually used after the bill method.
1825
1826 Actions are now triggered by billing events; see L<FS::part_event> and the
1827 billing events web interface.  Old-style invoice events (see
1828 L<FS::part_bill_event>) have been deprecated.
1829
1830 If there is an error, returns the error, otherwise returns false.
1831
1832 Options are passed as name-value pairs.
1833
1834 Currently available options are:
1835
1836 =over 4
1837
1838 =item invoice_time
1839
1840 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1841
1842 =item retry
1843
1844 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1845
1846 =item check_freq
1847
1848 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1849
1850 =item quiet
1851
1852 set true to surpress email card/ACH decline notices.
1853
1854 =item debug
1855
1856 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1857
1858 =back
1859
1860 # =item payby
1861 #
1862 # allows for one time override of normal customer billing method
1863
1864 =cut
1865
1866 sub collect {
1867   my( $self, %options ) = @_;
1868
1869   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1870
1871   my $invoice_time = $options{'invoice_time'} || time;
1872
1873   #put below somehow?
1874   local $SIG{HUP} = 'IGNORE';
1875   local $SIG{INT} = 'IGNORE';
1876   local $SIG{QUIT} = 'IGNORE';
1877   local $SIG{TERM} = 'IGNORE';
1878   local $SIG{TSTP} = 'IGNORE';
1879   local $SIG{PIPE} = 'IGNORE';
1880
1881   my $oldAutoCommit = $FS::UID::AutoCommit;
1882   local $FS::UID::AutoCommit = 0;
1883   my $dbh = dbh;
1884
1885   $self->select_for_update; #mutex
1886
1887   if ( $DEBUG ) {
1888     my $balance = $self->balance;
1889     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1890   }
1891
1892   if ( exists($options{'retry_card'}) ) {
1893     carp 'retry_card option passed to collect is deprecated; use retry';
1894     $options{'retry'} ||= $options{'retry_card'};
1895   }
1896   if ( exists($options{'retry'}) && $options{'retry'} ) {
1897     my $error = $self->retry_realtime;
1898     if ( $error ) {
1899       $dbh->rollback if $oldAutoCommit;
1900       return $error;
1901     }
1902   }
1903
1904   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1905
1906   #never want to roll back an event just because it returned an error
1907   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1908
1909   $self->do_cust_event(
1910     'debug'      => ( $options{'debug'} || 0 ),
1911     'time'       => $invoice_time,
1912     'check_freq' => $options{'check_freq'},
1913     'stage'      => 'collect',
1914   );
1915
1916 }
1917
1918 =item retry_realtime
1919
1920 Schedules realtime / batch  credit card / electronic check / LEC billing
1921 events for for retry.  Useful if card information has changed or manual
1922 retry is desired.  The 'collect' method must be called to actually retry
1923 the transaction.
1924
1925 Implementation details: For either this customer, or for each of this
1926 customer's open invoices, changes the status of the first "done" (with
1927 statustext error) realtime processing event to "failed".
1928
1929 =cut
1930
1931 sub retry_realtime {
1932   my $self = shift;
1933
1934   local $SIG{HUP} = 'IGNORE';
1935   local $SIG{INT} = 'IGNORE';
1936   local $SIG{QUIT} = 'IGNORE';
1937   local $SIG{TERM} = 'IGNORE';
1938   local $SIG{TSTP} = 'IGNORE';
1939   local $SIG{PIPE} = 'IGNORE';
1940
1941   my $oldAutoCommit = $FS::UID::AutoCommit;
1942   local $FS::UID::AutoCommit = 0;
1943   my $dbh = dbh;
1944
1945   #a little false laziness w/due_cust_event (not too bad, really)
1946
1947   # I guess this is always as of now?
1948   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1949   my $order = FS::part_event_condition->order_conditions_sql;
1950   my $mine =
1951   '( '
1952    . join ( ' OR ' , map {
1953     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1954     my $custnum = FS::part_event->eventtables_custnum->{$_};
1955     "( part_event.eventtable = " . dbh->quote($_)
1956     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1957     . " from $_ $cust_join"
1958     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1959    } FS::part_event->eventtables)
1960    . ') ';
1961
1962   #here is the agent virtualization
1963   my $agent_virt = " (    part_event.agentnum IS NULL
1964                        OR part_event.agentnum = ". $self->agentnum. ' )';
1965
1966   #XXX this shouldn't be hardcoded, actions should declare it...
1967   my @realtime_events = qw(
1968     cust_bill_realtime_card
1969     cust_bill_realtime_check
1970     cust_bill_realtime_lec
1971     cust_bill_batch
1972   );
1973
1974   my $is_realtime_event =
1975     ' part_event.action IN ( '.
1976         join(',', map "'$_'", @realtime_events ).
1977     ' ) ';
1978
1979   my $batch_or_statustext =
1980     "( part_event.action = 'cust_bill_batch'
1981        OR ( statustext IS NOT NULL AND statustext != '' )
1982      )";
1983
1984
1985   my @cust_event = qsearch({
1986     'table'     => 'cust_event',
1987     'select'    => 'cust_event.*',
1988     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1989     'hashref'   => { 'status' => 'done' },
1990     'extra_sql' => " AND $batch_or_statustext ".
1991                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1992   });
1993
1994   my %seen_invnum = ();
1995   foreach my $cust_event (@cust_event) {
1996
1997     #max one for the customer, one for each open invoice
1998     my $cust_X = $cust_event->cust_X;
1999     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
2000                           ? $cust_X->invnum
2001                           : 0
2002                         }++
2003          or $cust_event->part_event->eventtable eq 'cust_bill'
2004             && ! $cust_X->owed;
2005
2006     my $error = $cust_event->retry;
2007     if ( $error ) {
2008       $dbh->rollback if $oldAutoCommit;
2009       return "error scheduling event for retry: $error";
2010     }
2011
2012   }
2013
2014   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2015   '';
2016
2017 }
2018
2019 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
2020
2021 Runs billing events; see L<FS::part_event> and the billing events web
2022 interface.
2023
2024 If there is an error, returns the error, otherwise returns false.
2025
2026 Options are passed as name-value pairs.
2027
2028 Currently available options are:
2029
2030 =over 4
2031
2032 =item time
2033
2034 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
2035
2036 =item check_freq
2037
2038 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
2039
2040 =item stage
2041
2042 "collect" (the default) or "pre-bill"
2043
2044 =item quiet
2045
2046 set true to surpress email card/ACH decline notices.
2047
2048 =item debug
2049
2050 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2051
2052 =back
2053 =cut
2054
2055 # =item payby
2056 #
2057 # allows for one time override of normal customer billing method
2058
2059 # =item retry
2060 #
2061 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
2062
2063 sub do_cust_event {
2064   my( $self, %options ) = @_;
2065
2066   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2067
2068   my $time = $options{'time'} || time;
2069
2070   #put below somehow?
2071   local $SIG{HUP} = 'IGNORE';
2072   local $SIG{INT} = 'IGNORE';
2073   local $SIG{QUIT} = 'IGNORE';
2074   local $SIG{TERM} = 'IGNORE';
2075   local $SIG{TSTP} = 'IGNORE';
2076   local $SIG{PIPE} = 'IGNORE';
2077
2078   my $oldAutoCommit = $FS::UID::AutoCommit;
2079   local $FS::UID::AutoCommit = 0;
2080   my $dbh = dbh;
2081
2082   $self->select_for_update; #mutex
2083
2084   if ( $DEBUG ) {
2085     my $balance = $self->balance;
2086     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
2087   }
2088
2089 #  if ( exists($options{'retry_card'}) ) {
2090 #    carp 'retry_card option passed to collect is deprecated; use retry';
2091 #    $options{'retry'} ||= $options{'retry_card'};
2092 #  }
2093 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
2094 #    my $error = $self->retry_realtime;
2095 #    if ( $error ) {
2096 #      $dbh->rollback if $oldAutoCommit;
2097 #      return $error;
2098 #    }
2099 #  }
2100
2101   # false laziness w/pay_batch::import_results
2102
2103   my $due_cust_event = $self->due_cust_event(
2104     'debug'      => ( $options{'debug'} || 0 ),
2105     'time'       => $time,
2106     'check_freq' => $options{'check_freq'},
2107     'stage'      => ( $options{'stage'} || 'collect' ),
2108   );
2109   unless( ref($due_cust_event) ) {
2110     $dbh->rollback if $oldAutoCommit;
2111     return $due_cust_event;
2112   }
2113
2114   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2115   #never want to roll back an event just because it or a different one
2116   # returned an error
2117   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
2118
2119   foreach my $cust_event ( @$due_cust_event ) {
2120
2121     #XXX lock event
2122
2123     #re-eval event conditions (a previous event could have changed things)
2124     unless ( $cust_event->test_conditions ) {
2125       #don't leave stray "new/locked" records around
2126       my $error = $cust_event->delete;
2127       return $error if $error;
2128       next;
2129     }
2130
2131     {
2132       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
2133         if $options{'quiet'};
2134       warn "  running cust_event ". $cust_event->eventnum. "\n"
2135         if $DEBUG > 1;
2136
2137       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
2138       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
2139         #XXX wtf is this?  figure out a proper dealio with return value
2140         #from do_event
2141         return $error;
2142       }
2143     }
2144
2145   }
2146
2147   '';
2148
2149 }
2150
2151 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
2152
2153 Inserts database records for and returns an ordered listref of new events due
2154 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
2155 events are due, an empty listref is returned.  If there is an error, returns a
2156 scalar error message.
2157
2158 To actually run the events, call each event's test_condition method, and if
2159 still true, call the event's do_event method.
2160
2161 Options are passed as a hashref or as a list of name-value pairs.  Available
2162 options are:
2163
2164 =over 4
2165
2166 =item check_freq
2167
2168 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
2169
2170 =item stage
2171
2172 "collect" (the default) or "pre-bill"
2173
2174 =item time
2175
2176 "Current time" for the events.
2177
2178 =item debug
2179
2180 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2181
2182 =item eventtable
2183
2184 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2185
2186 =item objects
2187
2188 Explicitly pass the objects to be tested (typically used with eventtable).
2189
2190 =item testonly
2191
2192 Set to true to return the objects, but not actually insert them into the
2193 database.
2194
2195 =back
2196
2197 =cut
2198
2199 sub due_cust_event {
2200   my $self = shift;
2201   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2202
2203   #???
2204   #my $DEBUG = $opt{'debug'}
2205   $opt{'debug'} ||= 0; # silence some warnings
2206   local($DEBUG) = $opt{'debug'}
2207     if $opt{'debug'} > $DEBUG;
2208   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2209
2210   warn "$me due_cust_event called with options ".
2211        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2212     if $DEBUG;
2213
2214   $opt{'time'} ||= time;
2215
2216   local $SIG{HUP} = 'IGNORE';
2217   local $SIG{INT} = 'IGNORE';
2218   local $SIG{QUIT} = 'IGNORE';
2219   local $SIG{TERM} = 'IGNORE';
2220   local $SIG{TSTP} = 'IGNORE';
2221   local $SIG{PIPE} = 'IGNORE';
2222
2223   my $oldAutoCommit = $FS::UID::AutoCommit;
2224   local $FS::UID::AutoCommit = 0;
2225   my $dbh = dbh;
2226
2227   $self->select_for_update #mutex
2228     unless $opt{testonly};
2229
2230   ###
2231   # find possible events (initial search)
2232   ###
2233
2234   my @cust_event = ();
2235
2236   my @eventtable = $opt{'eventtable'}
2237                      ? ( $opt{'eventtable'} )
2238                      : FS::part_event->eventtables_runorder;
2239
2240   my $check_freq = $opt{'check_freq'} || '1d';
2241
2242   foreach my $eventtable ( @eventtable ) {
2243
2244     my @objects;
2245     if ( $opt{'objects'} ) {
2246
2247       @objects = @{ $opt{'objects'} };
2248
2249     } elsif ( $eventtable eq 'cust_main' ) {
2250
2251       @objects = ( $self );
2252
2253     } else {
2254
2255       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2256       # linkage not needed here because FS::cust_main->$eventtable will
2257       # already supply it
2258
2259       #some false laziness w/Cron::bill bill_where
2260
2261       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2262         'time' => $opt{'time'});
2263       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2264         'time'=>$opt{'time'},
2265       );
2266       $where = $where ? "AND $where" : '';
2267
2268       my $are_part_event =
2269       "EXISTS ( SELECT 1 FROM part_event $join
2270         WHERE check_freq = '$check_freq'
2271         AND eventtable = '$eventtable'
2272         AND ( disabled = '' OR disabled IS NULL )
2273         $where
2274         )
2275       ";
2276       #eofalse
2277
2278       @objects = $self->$eventtable(
2279         'addl_from' => $cm_join,
2280         'extra_sql' => " AND $are_part_event",
2281       );
2282     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2283
2284     my @e_cust_event = ();
2285
2286     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2287
2288     my $cross = "CROSS JOIN $eventtable $linkage";
2289     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2290       unless $eventtable eq 'cust_main';
2291
2292     foreach my $object ( @objects ) {
2293
2294       #this first search uses the condition_sql magic for optimization.
2295       #the more possible events we can eliminate in this step the better
2296
2297       my $cross_where = '';
2298       my $pkey = $object->primary_key;
2299       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2300
2301       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2302         'time' => $opt{'time'});
2303       my $extra_sql =
2304         FS::part_event_condition->where_conditions_sql( $eventtable,
2305                                                         'time'=>$opt{'time'}
2306                                                       );
2307       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2308
2309       $extra_sql = "AND $extra_sql" if $extra_sql;
2310
2311       #here is the agent virtualization
2312       $extra_sql .= " AND (    part_event.agentnum IS NULL
2313                             OR part_event.agentnum = ". $self->agentnum. ' )';
2314
2315       $extra_sql .= " $order";
2316
2317       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2318         if $opt{'debug'} > 2;
2319       my @part_event = qsearch( {
2320         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2321         'select'    => 'part_event.*',
2322         'table'     => 'part_event',
2323         'addl_from' => "$cross $join",
2324         'hashref'   => { 'check_freq' => $check_freq,
2325                          'eventtable' => $eventtable,
2326                          'disabled'   => '',
2327                        },
2328         'extra_sql' => "AND $cross_where $extra_sql",
2329       } );
2330
2331       if ( $DEBUG > 2 ) {
2332         my $pkey = $object->primary_key;
2333         warn "      ". scalar(@part_event).
2334              " possible events found for $eventtable ". $object->$pkey(). "\n";
2335       }
2336
2337       push @e_cust_event, map {
2338         $_->new_cust_event($object, 'time' => $opt{'time'})
2339       } @part_event;
2340
2341     }
2342
2343     warn "    ". scalar(@e_cust_event).
2344          " subtotal possible cust events found for $eventtable\n"
2345       if $DEBUG > 1;
2346
2347     push @cust_event, @e_cust_event;
2348
2349   }
2350
2351   warn "  ". scalar(@cust_event).
2352        " total possible cust events found in initial search\n"
2353     if $DEBUG; # > 1;
2354
2355
2356   ##
2357   # test stage
2358   ##
2359
2360   $opt{stage} ||= 'collect';
2361   @cust_event =
2362     grep { my $stage = $_->part_event->event_stage;
2363            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2364          }
2365          @cust_event;
2366
2367   ##
2368   # test conditions
2369   ##
2370
2371   my %unsat = ();
2372
2373   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2374                      @cust_event;
2375
2376   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2377     if $DEBUG; # > 1;
2378
2379   warn "    invalid conditions not eliminated with condition_sql:\n".
2380        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2381     if keys %unsat && $DEBUG; # > 1;
2382
2383   ##
2384   # insert
2385   ##
2386
2387   unless( $opt{testonly} ) {
2388     foreach my $cust_event ( @cust_event ) {
2389
2390       my $error = $cust_event->insert();
2391       if ( $error ) {
2392         $dbh->rollback if $oldAutoCommit;
2393         return $error;
2394       }
2395
2396     }
2397   }
2398
2399   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2400
2401   ##
2402   # return
2403   ##
2404
2405   warn "  returning events: ". Dumper(@cust_event). "\n"
2406     if $DEBUG > 2;
2407
2408   \@cust_event;
2409
2410 }
2411
2412 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2413
2414 Applies unapplied payments and credits.
2415 Payments with the no_auto_apply flag set will not be applied.
2416
2417 In most cases, this new method should be used in place of sequential
2418 apply_payments and apply_credits methods.
2419
2420 A hash of optional arguments may be passed.  Currently "manual" is supported.
2421 If true, a payment receipt is sent instead of a statement when
2422 'payment_receipt_email' configuration option is set.
2423
2424 If there is an error, returns the error, otherwise returns false.
2425
2426 =cut
2427
2428 sub apply_payments_and_credits {
2429   my( $self, %options ) = @_;
2430
2431   local $SIG{HUP} = 'IGNORE';
2432   local $SIG{INT} = 'IGNORE';
2433   local $SIG{QUIT} = 'IGNORE';
2434   local $SIG{TERM} = 'IGNORE';
2435   local $SIG{TSTP} = 'IGNORE';
2436   local $SIG{PIPE} = 'IGNORE';
2437
2438   my $oldAutoCommit = $FS::UID::AutoCommit;
2439   local $FS::UID::AutoCommit = 0;
2440   my $dbh = dbh;
2441
2442   $self->select_for_update; #mutex
2443
2444   foreach my $cust_bill ( $self->open_cust_bill ) {
2445     my $error = $cust_bill->apply_payments_and_credits(%options);
2446     if ( $error ) {
2447       $dbh->rollback if $oldAutoCommit;
2448       return "Error applying: $error";
2449     }
2450   }
2451
2452   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2453   ''; #no error
2454
2455 }
2456
2457 =item apply_credits OPTION => VALUE ...
2458
2459 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2460 to outstanding invoice balances in chronological order (or reverse
2461 chronological order if the I<order> option is set to B<newest>) and returns the
2462 value of any remaining unapplied credits available for refund (see
2463 L<FS::cust_refund>).
2464
2465 Dies if there is an error.
2466
2467 =cut
2468
2469 sub apply_credits {
2470   my $self = shift;
2471   my %opt = @_;
2472
2473   local $SIG{HUP} = 'IGNORE';
2474   local $SIG{INT} = 'IGNORE';
2475   local $SIG{QUIT} = 'IGNORE';
2476   local $SIG{TERM} = 'IGNORE';
2477   local $SIG{TSTP} = 'IGNORE';
2478   local $SIG{PIPE} = 'IGNORE';
2479
2480   my $oldAutoCommit = $FS::UID::AutoCommit;
2481   local $FS::UID::AutoCommit = 0;
2482   my $dbh = dbh;
2483
2484   $self->select_for_update; #mutex
2485
2486   unless ( $self->total_unapplied_credits ) {
2487     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2488     return 0;
2489   }
2490
2491   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2492       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2493
2494   my @invoices = $self->open_cust_bill;
2495   @invoices = sort { $b->_date <=> $a->_date } @invoices
2496     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2497
2498   if ( $conf->exists('pkg-balances') ) {
2499     # limit @credits to those w/ a pkgnum grepped from $self
2500     my %pkgnums = ();
2501     foreach my $i (@invoices) {
2502       foreach my $li ( $i->cust_bill_pkg ) {
2503         $pkgnums{$li->pkgnum} = 1;
2504       }
2505     }
2506     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2507   }
2508
2509   my $credit;
2510
2511   foreach my $cust_bill ( @invoices ) {
2512
2513     if ( !defined($credit) || $credit->credited == 0) {
2514       $credit = pop @credits or last;
2515     }
2516
2517     my $owed;
2518     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2519       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2520     } else {
2521       $owed = $cust_bill->owed;
2522     }
2523     unless ( $owed > 0 ) {
2524       push @credits, $credit;
2525       next;
2526     }
2527
2528     my $amount = min( $credit->credited, $owed );
2529
2530     my $cust_credit_bill = new FS::cust_credit_bill ( {
2531       'crednum' => $credit->crednum,
2532       'invnum'  => $cust_bill->invnum,
2533       'amount'  => $amount,
2534     } );
2535     $cust_credit_bill->pkgnum( $credit->pkgnum )
2536       if $conf->exists('pkg-balances') && $credit->pkgnum;
2537     my $error = $cust_credit_bill->insert;
2538     if ( $error ) {
2539       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2540       die $error;
2541     }
2542
2543     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2544
2545   }
2546
2547   my $total_unapplied_credits = $self->total_unapplied_credits;
2548
2549   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2550
2551   return $total_unapplied_credits;
2552 }
2553
2554 =item apply_payments  [ OPTION => VALUE ... ]
2555
2556 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2557 to outstanding invoice balances in chronological order.
2558 Payments with the no_auto_apply flag set will not be applied.
2559
2560  #and returns the value of any remaining unapplied payments.
2561
2562 A hash of optional arguments may be passed.  Currently "manual" is supported.
2563 If true, a payment receipt is sent instead of a statement when
2564 'payment_receipt_email' configuration option is set.
2565
2566 Dies if there is an error.
2567
2568 =cut
2569
2570 sub apply_payments {
2571   my( $self, %options ) = @_;
2572
2573   local $SIG{HUP} = 'IGNORE';
2574   local $SIG{INT} = 'IGNORE';
2575   local $SIG{QUIT} = 'IGNORE';
2576   local $SIG{TERM} = 'IGNORE';
2577   local $SIG{TSTP} = 'IGNORE';
2578   local $SIG{PIPE} = 'IGNORE';
2579
2580   my $oldAutoCommit = $FS::UID::AutoCommit;
2581   local $FS::UID::AutoCommit = 0;
2582   my $dbh = dbh;
2583
2584   $self->select_for_update; #mutex
2585
2586   #return 0 unless
2587
2588   my @payments = grep { !$_->no_auto_apply } $self->unapplied_cust_pay;
2589
2590   my @invoices = $self->open_cust_bill;
2591
2592   if ( $conf->exists('pkg-balances') ) {
2593     # limit @payments to those w/ a pkgnum grepped from $self
2594     my %pkgnums = ();
2595     foreach my $i (@invoices) {
2596       foreach my $li ( $i->cust_bill_pkg ) {
2597         $pkgnums{$li->pkgnum} = 1;
2598       }
2599     }
2600     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2601   }
2602
2603   my $payment;
2604
2605   foreach my $cust_bill ( @invoices ) {
2606
2607     if ( !defined($payment) || $payment->unapplied == 0 ) {
2608       $payment = pop @payments or last;
2609     }
2610
2611     my $owed;
2612     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2613       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2614     } else {
2615       $owed = $cust_bill->owed;
2616     }
2617     unless ( $owed > 0 ) {
2618       push @payments, $payment;
2619       next;
2620     }
2621
2622     my $amount = min( $payment->unapplied, $owed );
2623
2624     my $cbp = {
2625       'paynum' => $payment->paynum,
2626       'invnum' => $cust_bill->invnum,
2627       'amount' => $amount,
2628     };
2629     $cbp->{_date} = $payment->_date
2630         if $options{'manual'} && $options{'backdate_application'};
2631     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2632     $cust_bill_pay->pkgnum( $payment->pkgnum )
2633       if $conf->exists('pkg-balances') && $payment->pkgnum;
2634     my $error = $cust_bill_pay->insert(%options);
2635     if ( $error ) {
2636       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2637       die $error;
2638     }
2639
2640     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2641
2642   }
2643
2644   my $total_unapplied_payments = $self->total_unapplied_payments;
2645
2646   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2647
2648   return $total_unapplied_payments;
2649 }
2650
2651 =back
2652
2653 =head1 FLOW
2654
2655   bill_and_collect
2656
2657     cancel_expired_pkgs
2658     suspend_adjourned_pkgs
2659     unsuspend_resumed_pkgs
2660
2661     bill
2662       (do_cust_event pre-bill)
2663       _make_lines
2664         _handle_taxes
2665           (vendor-only) _gather_taxes
2666       _omit_zero_value_bundles
2667       _handle_taxes (for fees)
2668       calculate_taxes
2669
2670     apply_payments_and_credits
2671     collect
2672       do_cust_event
2673         due_cust_event
2674
2675 =head1 BUGS
2676
2677 =head1 SEE ALSO
2678
2679 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2680
2681 =cut
2682
2683 1;