FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use Tie::RefHash;
  12 use FS::cust_bill;
  13 use FS::cust_bill_pkg;
  14 use FS::cust_bill_pkg_display;
  15 use FS::cust_bill_pay;
  16 use FS::cust_credit_bill;
  17 use FS::cust_tax_adjustment;
  18 use FS::tax_rate;
  19 use FS::tax_rate_location;
  20 use FS::cust_bill_pkg_tax_location;
  21 use FS::cust_bill_pkg_tax_rate_location;
  22 use FS::part_event;
  23 use FS::part_event_condition;
  24 use FS::pkg_category;
  25 use FS::FeeOrigin_Mixin;
  26 use FS::Log;
  27
  28 # 1 is mostly method/subroutine entry and options
  29 # 2 traces progress of some operations
  30 # 3 is even more information including possibly sensitive data
  31 $DEBUG = 0;
  32 $me = '[FS::cust_main::Billing]';
  33
  34 install_callback FS::UID sub {
  35   $conf = new FS::Conf;
  36   #yes, need it for stuff below (prolly should be cached)
  37 };
  38
  39 =head1 NAME
  40
  41 FS::cust_main::Billing - Billing mixin for cust_main
  42
  43 =head1 SYNOPSIS
  44
  45 =head1 DESCRIPTION
  46
  47 These methods are available on FS::cust_main objects.
  48
  49 =head1 METHODS
  50
  51 =over 4
  52
  53 =item bill_and_collect
  54
  55 Cancels and suspends any packages due, generates bills, applies payments and
  56 credits, and applies collection events to run cards, send bills and notices,
  57 etc.
  58
  59 By default, warns on errors and continues with the next operation (but see the
  60 "fatal" flag below).
  61
  62 Options are passed as name-value pairs.  Currently available options are:
  63
  64 =over 4
  65
  66 =item time
  67
  68 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  69
  70  use Date::Parse;
  71  ...
  72  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  73
  74 =item invoice_time
  75
  76 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  77
  78 =item check_freq
  79
  80 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  81
  82 =item resetup
  83
  84 If set true, re-charges setup fees.
  85
  86 =item fatal
  87
  88 If set any errors prevent subsequent operations from continusing.  If set
  89 specifically to "return", returns the error (or false, if there is no error).
  90 Any other true value causes errors to die.
  91
  92 =item debug
  93
  94 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  95
  96 =item job
  97
  98 Optional FS::queue entry to receive status updates.
  99
 100 =back
 101
 102 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 103 options of those methods are also available.
 104
 105 =cut
 106
 107 sub bill_and_collect {
 108   my( $self, %options ) = @_;
 109
 110   my $log = FS::Log->new('FS::cust_main::Billing::bill_and_collect');
 111   my %logopt = (object => $self);
 112   $log->debug('start', %logopt);
 113
 114   my $error;
 115
 116   #$options{actual_time} not $options{time} because freeside-daily -d is for
 117   #pre-printing invoices
 118
 119   $options{'actual_time'} ||= time;
 120   my $job = $options{'job'};
 121
 122   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 123                         ? day_end( $options{actual_time} )
 124                         : $options{actual_time}
 125                     );
 126
 127   $job->update_statustext('0,cleaning expired packages') if $job;
 128   $log->debug('canceling expired packages', %logopt);
 129   $error = $self->cancel_expired_pkgs( $actual_time );
 130   if ( $error ) {
 131     $error = "Error expiring custnum ". $self->custnum. ": $error";
 132     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 133     elsif ( $options{fatal}                                ) { die    $error; }
 134     else                                                     { warn   $error; }
 135   }
 136
 137   $log->debug('suspending adjourned packages', %logopt);
 138   $error = $self->suspend_adjourned_pkgs( $actual_time );
 139   if ( $error ) {
 140     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 141     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 142     elsif ( $options{fatal}                                ) { die    $error; }
 143     else                                                     { warn   $error; }
 144   }
 145
 146   $log->debug('unsuspending resumed packages', %logopt);
 147   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 148   if ( $error ) {
 149     $error = "Error resuming custnum ".$self->custnum. ": $error";
 150     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 151     elsif ( $options{fatal}                                ) { die    $error; }
 152     else                                                     { warn   $error; }
 153   }
 154
 155   $job->update_statustext('20,billing packages') if $job;
 156   $log->debug('billing packages', %logopt);
 157   $error = $self->bill( %options );
 158   if ( $error ) {
 159     $error = "Error billing custnum ". $self->custnum. ": $error";
 160     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 161     elsif ( $options{fatal}                                ) { die    $error; }
 162     else                                                     { warn   $error; }
 163   }
 164
 165   $job->update_statustext('50,applying payments and credits') if $job;
 166   $log->debug('applying payments and credits', %logopt);
 167   $error = $self->apply_payments_and_credits;
 168   if ( $error ) {
 169     $error = "Error applying custnum ". $self->custnum. ": $error";
 170     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 171     elsif ( $options{fatal}                                ) { die    $error; }
 172     else                                                     { warn   $error; }
 173   }
 174
 175   unless ( $conf->exists('cancelled_cust-noevents')
 176            && ! $self->num_ncancelled_pkgs
 177   ) {
 178     $job->update_statustext('70,running collection events') if $job;
 179     $log->debug('running collection events', %logopt);
 180     $error = $self->collect( %options );
 181     if ( $error ) {
 182       $error = "Error collecting custnum ". $self->custnum. ": $error";
 183       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 184       elsif ($options{fatal}                               ) { die    $error; }
 185       else                                                   { warn   $error; }
 186     }
 187   }
 188
 189   $job->update_statustext('100,finished') if $job;
 190   $log->debug('finish', %logopt);
 191
 192   '';
 193
 194 }
 195
 196 sub cancel_expired_pkgs {
 197   my ( $self, $time, %options ) = @_;
 198
 199   my @cancel_pkgs = $self->ncancelled_pkgs( {
 200     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 201   } );
 202
 203   my @errors = ();
 204
 205   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 206     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 207     my $error;
 208
 209     if ( $cust_pkg->change_to_pkgnum ) {
 210
 211       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 212       if ( !$new_pkg ) {
 213         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 214                       $cust_pkg->change_to_pkgnum.'; not expiring';
 215         next CUST_PKG;
 216       }
 217       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 218                                   'unprotect_svcs'  => 1 );
 219       $error = '' if ref $error eq 'FS::cust_pkg';
 220
 221     } else { # just cancel it
 222        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 223                                            'reason_otaker' => $cpr->otaker,
 224                                            'time'          => $time,
 225                                          )
 226                                        : ()
 227                                  );
 228     }
 229     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 230   }
 231
 232   join(' / ', @errors);
 233
 234 }
 235
 236 sub suspend_adjourned_pkgs {
 237   my ( $self, $time, %options ) = @_;
 238
 239   my @susp_pkgs = $self->ncancelled_pkgs( {
 240     'extra_sql' =>
 241       " AND ( susp IS NULL OR susp = 0 )
 242         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 243               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 244             )
 245       ",
 246   } );
 247
 248   #only because there's no SQL test for is_prepaid :/
 249   @susp_pkgs =
 250     grep {     (    $_->part_pkg->is_prepaid
 251                  && $_->bill
 252                  && $_->bill < $time
 253                )
 254             || (    $_->adjourn
 255                  && $_->adjourn <= $time
 256                )
 257
 258          }
 259          @susp_pkgs;
 260
 261   my @errors = ();
 262
 263   foreach my $cust_pkg ( @susp_pkgs ) {
 264     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 265       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 266     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 267                                             'reason_otaker' => $cpr->otaker
 268                                           )
 269                                         : ()
 270                                   );
 271     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 272   }
 273
 274   join(' / ', @errors);
 275
 276 }
 277
 278 sub unsuspend_resumed_pkgs {
 279   my ( $self, $time, %options ) = @_;
 280
 281   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 282     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 283   } );
 284
 285   my @errors = ();
 286
 287   foreach my $cust_pkg ( @unsusp_pkgs ) {
 288     my $error = $cust_pkg->unsuspend( 'time' => $time );
 289     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 290   }
 291
 292   join(' / ', @errors);
 293
 294 }
 295
 296 =item bill OPTIONS
 297
 298 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 299 conjunction with the collect method by calling B<bill_and_collect>.
 300
 301 If there is an error, returns the error, otherwise returns false.
 302
 303 Options are passed as name-value pairs.  Currently available options are:
 304
 305 =over 4
 306
 307 =item resetup
 308
 309 If set true, re-charges setup fees.
 310
 311 =item recurring_only
 312
 313 If set true then only bill recurring charges, not setup, usage, one time
 314 charges, etc.
 315
 316 =item freq_override
 317
 318 If set, then override the normal frequency and look for a part_pkg_discount
 319 to take at that frequency.  This is appropriate only when the normal
 320 frequency for all packages is monthly, and is an error otherwise.  Use
 321 C<pkg_list> to limit the set of packages included in billing.
 322
 323 =item time
 324
 325 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 326
 327  use Date::Parse;
 328  ...
 329  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 330
 331 =item pkg_list
 332
 333 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 334
 335  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 336
 337 =item not_pkgpart
 338
 339 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 340
 341 =item no_prepaid
 342
 343 Do not bill prepaid packages.  Used by freeside-daily.
 344
 345 =item invoice_time
 346
 347 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 348
 349 =item cancel
 350
 351 This boolean value informs the us that the package is being cancelled.  This
 352 typically might mean not charging the normal recurring fee but only usage
 353 fees since the last billing. Setup charges may be charged.  Not all package
 354 plans support this feature (they tend to charge 0).
 355
 356 =item no_usage_reset
 357
 358 Prevent the resetting of usage limits during this call.
 359
 360 =item no_commit
 361
 362 Do not save the generated bill in the database.  Useful with return_bill
 363
 364 =item return_bill
 365
 366 A list reference on which the generated bill(s) will be returned.
 367
 368 =item invoice_terms
 369
 370 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 371 terms or the default terms are used.
 372
 373 =back
 374
 375 =cut
 376
 377 sub bill {
 378   my( $self, %options ) = @_;
 379
 380   return '' if $self->payby eq 'COMP';
 381
 382   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 383   my $log = FS::Log->new('FS::cust_main::Billing::bill');
 384   my %logopt = (object => $self);
 385
 386   $log->debug('start', %logopt);
 387   warn "$me bill customer ". $self->custnum. "\n"
 388     if $DEBUG;
 389
 390   my $time = $options{'time'} || time;
 391   my $invoice_time = $options{'invoice_time'} || $time;
 392
 393   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 394                      ? day_end( $time )
 395                      : $time
 396                  );
 397
 398   $options{'not_pkgpart'} ||= {};
 399   $options{'not_pkgpart'} = { map { $_ => 1 }
 400                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 401                             }
 402     unless ref($options{'not_pkgpart'});
 403
 404   local $SIG{HUP} = 'IGNORE';
 405   local $SIG{INT} = 'IGNORE';
 406   local $SIG{QUIT} = 'IGNORE';
 407   local $SIG{TERM} = 'IGNORE';
 408   local $SIG{TSTP} = 'IGNORE';
 409   local $SIG{PIPE} = 'IGNORE';
 410
 411   my $oldAutoCommit = $FS::UID::AutoCommit;
 412   local $FS::UID::AutoCommit = 0;
 413   my $dbh = dbh;
 414
 415   $log->debug('acquiring lock', %logopt);
 416   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 417     if $DEBUG;
 418
 419   $self->select_for_update; #mutex
 420
 421   $log->debug('running pre-bill events', %logopt);
 422   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 423     if $DEBUG;
 424
 425   my $error = $self->do_cust_event(
 426     'debug'      => ( $options{'debug'} || 0 ),
 427     'time'       => $invoice_time,
 428     'check_freq' => $options{'check_freq'},
 429     'stage'      => 'pre-bill',
 430   )
 431     unless $options{no_commit};
 432   if ( $error ) {
 433     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 434     return $error;
 435   }
 436
 437   $log->debug('done running pre-bill events', %logopt);
 438   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 439     if $DEBUG;
 440
 441   #keep auto-charge and non-auto-charge line items separate
 442   my @passes = ( '', 'no_auto' );
 443
 444   my %cust_bill_pkg = map { $_ => [] } @passes;
 445
 446   ###
 447   # find the packages which are due for billing, find out how much they are
 448   # & generate invoice database.
 449   ###
 450
 451   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 452   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 453
 454   my %taxlisthash = map { $_ => {} } @passes;
 455
 456   my @precommit_hooks = ();
 457
 458   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 459
 460   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 461
 462     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 463
 464     my $part_pkg = $cust_pkg->part_pkg;
 465
 466     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 467
 468     $log->debug('bill package '. $cust_pkg->pkgnum, %logopt);
 469     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 470
 471     #? to avoid use of uninitialized value errors... ?
 472     $cust_pkg->setfield('bill', '')
 473       unless defined($cust_pkg->bill);
 474
 475     my $real_pkgpart = $cust_pkg->pkgpart;
 476     my %hash = $cust_pkg->hash;
 477
 478     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 479     # suffer from performance issues
 480     $options{has_hidden} = 0;
 481     my @part_pkg = $part_pkg->self_and_bill_linked;
 482     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 483
 484     # if this package was changed from another package,
 485     # and it hasn't been billed since then,
 486     # and package balances are enabled,
 487     if ( $cust_pkg->change_pkgnum
 488         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 489         and $cust_pkg->change_date <  $invoice_time
 490       and $conf->exists('pkg-balances') )
 491     {
 492       # _transfer_balance will also create the appropriate credit
 493       my @transfer_items = $self->_transfer_balance($cust_pkg);
 494       # $part_pkg[0] is the "real" part_pkg
 495       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 496                   'no_auto' : '';
 497       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 498       # treating this as recur, just because most charges are recur...
 499       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 500
 501       # currently not considering separate_bill here, as it's for
 502       # one-time charges only
 503     }
 504
 505     foreach my $part_pkg ( @part_pkg ) {
 506
 507       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 508
 509       my $pass = '';
 510       if ( $cust_pkg->separate_bill ) {
 511         # if no_auto is also set, that's fine. we just need to not have
 512         # invoices that are both auto and no_auto, and since the package
 513         # gets an invoice all to itself, it will only be one or the other.
 514         $pass = $cust_pkg->pkgnum;
 515         if (!exists $cust_bill_pkg{$pass}) { # it may not exist yet
 516           push @passes, $pass;
 517           $total_setup{$pass} = do { my $z = 0; \$z };
 518           $total_recur{$pass} = do { my $z = 0; \$z };
 519           $taxlisthash{$pass} = {};
 520           $cust_bill_pkg{$pass} = [];
 521         }
 522       } elsif ( ($cust_pkg->no_auto || $part_pkg->no_auto) ) {
 523         $pass = 'no_auto';
 524       }
 525
 526       my $next_bill = $cust_pkg->getfield('bill') || 0;
 527       my $error;
 528       # let this run once if this is the last bill upon cancellation
 529       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 530         $error =
 531           $self->_make_lines( 'part_pkg'            => $part_pkg,
 532                               'cust_pkg'            => $cust_pkg,
 533                               'precommit_hooks'     => \@precommit_hooks,
 534                               'line_items'          => $cust_bill_pkg{$pass},
 535                               'setup'               => $total_setup{$pass},
 536                               'recur'               => $total_recur{$pass},
 537                               'tax_matrix'          => $taxlisthash{$pass},
 538                               'time'                => $time,
 539                               'real_pkgpart'        => $real_pkgpart,
 540                               'options'             => \%options,
 541                             );
 542
 543         # Stop if anything goes wrong
 544         last if $error;
 545
 546         # or if we're not incrementing the bill date.
 547         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 548
 549         # or if we're letting it run only once
 550         last if $options{cancel};
 551
 552         $next_bill = $cust_pkg->getfield('bill') || 0;
 553
 554         #stop if -o was passed to freeside-daily
 555         last if $options{'one_recur'};
 556       }
 557       if ($error) {
 558         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 559         return $error;
 560       }
 561
 562     } #foreach my $part_pkg
 563
 564   } #foreach my $cust_pkg
 565
 566   foreach my $pass (@passes) { # keys %cust_bill_pkg )
 567
 568     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 569
 570     warn "$me billing pass $pass\n"
 571            #.Dumper(\@cust_bill_pkg)."\n"
 572       if $DEBUG > 2;
 573
 574     ###
 575     # process fees
 576     ###
 577
 578     my @pending_fees = FS::FeeOrigin_Mixin->by_cust($self->custnum,
 579       hashref => { 'billpkgnum' => '' }
 580     );
 581     warn "$me found pending fees:\n".Dumper(\@pending_fees)."\n"
 582       if @pending_fees and $DEBUG > 1;
 583
 584     # determine whether to generate an invoice
 585     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 586
 587     foreach my $fee (@pending_fees) {
 588       $generate_bill = 1 unless $fee->nextbill;
 589     }
 590
 591     # don't create an invoice with no line items, or where the only line
 592     # items are fees that are supposed to be held until the next invoice
 593     next if !$generate_bill;
 594
 595     # calculate fees...
 596     my @fee_items;
 597     foreach my $fee_origin (@pending_fees) {
 598       my $part_fee = $fee_origin->part_fee;
 599
 600       # check whether the fee is applicable before doing anything expensive:
 601       #
 602       # if the fee def belongs to a different agent, don't charge the fee.
 603       # event conditions should prevent this, but just in case they don't,
 604       # skip the fee.
 605       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 606         warn "tried to charge fee#".$part_fee->feepart .
 607              " on customer#".$self->custnum." from a different agent.\n";
 608         next;
 609       }
 610       # also skip if it's disabled
 611       next if $part_fee->disabled eq 'Y';
 612
 613       # Decide which invoice to base the fee on.
 614       my $cust_bill = $fee_origin->cust_bill;
 615       if (!$cust_bill) {
 616         # Then link it to the current invoice. This isn't the real cust_bill
 617         # object that will be inserted--in particular there are no taxes yet.
 618         # If you want to charge a fee on the total invoice amount including
 619         # taxes, you have to put the fee on the next invoice.
 620         $cust_bill = FS::cust_bill->new({
 621             'custnum'       => $self->custnum,
 622             'cust_bill_pkg' => \@cust_bill_pkg,
 623             'charged'       => ${ $total_setup{$pass} } +
 624                                ${ $total_recur{$pass} },
 625         });
 626
 627         # If the origin is for a specific package, then only apply the fee to
 628         # line items from that package.
 629         if ( my $cust_pkg = $fee_origin->cust_pkg ) {
 630           my @charge_fee_on_item;
 631           my $charge_fee_on_amount = 0;
 632           foreach (@cust_bill_pkg) {
 633             if ($_->pkgnum == $cust_pkg->pkgnum) {
 634               push @charge_fee_on_item, $_;
 635               $charge_fee_on_amount += $_->setup + $_->recur;
 636             }
 637           }
 638           $cust_bill->set('cust_bill_pkg', \@charge_fee_on_item);
 639           $cust_bill->set('charged', $charge_fee_on_amount);
 640         }
 641
 642       } # $cust_bill is now set
 643       # calculate the fee
 644       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 645       # link this so that we can clear the marker on inserting the line item
 646       $fee_item->set('fee_origin', $fee_origin);
 647       push @fee_items, $fee_item;
 648
 649     }
 650
 651     # add fees to the invoice
 652     foreach my $fee_item (@fee_items) {
 653
 654       push @cust_bill_pkg, $fee_item;
 655       ${ $total_setup{$pass} } += $fee_item->setup;
 656       ${ $total_recur{$pass} } += $fee_item->recur;
 657
 658       my $part_fee = $fee_item->part_fee;
 659       my $fee_location = $self->ship_location; # I think?
 660
 661       my $error = $self->_handle_taxes(
 662         $taxlisthash{$pass},
 663         $fee_item,
 664         location => $fee_location
 665         # probably not right to pass cancel => 1 for fees
 666       );
 667       return $error if $error;
 668
 669     }
 670
 671     # XXX implementation of fees is supposed to make this go away...
 672     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 673            !$conf->exists('postal_invoice-recurring_only')
 674        )
 675     {
 676
 677       my $postal_pkg = $self->charge_postal_fee();
 678       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 679
 680         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 681         return "can't charge postal invoice fee for customer ".
 682           $self->custnum. ": $postal_pkg";
 683
 684       } elsif ( $postal_pkg ) {
 685
 686         my $real_pkgpart = $postal_pkg->pkgpart;
 687         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 688         # suffer from performance issues
 689         $options{has_hidden} = 0;
 690         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 691         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 692
 693         foreach my $part_pkg ( @part_pkg ) {
 694           my %postal_options = %options;
 695           delete $postal_options{cancel};
 696           my $error =
 697             $self->_make_lines( 'part_pkg'            => $part_pkg,
 698                                 'cust_pkg'            => $postal_pkg,
 699                                 'precommit_hooks'     => \@precommit_hooks,
 700                                 'line_items'          => \@cust_bill_pkg,
 701                                 'setup'               => $total_setup{$pass},
 702                                 'recur'               => $total_recur{$pass},
 703                                 'tax_matrix'          => $taxlisthash{$pass},
 704                                 'time'                => $time,
 705                                 'real_pkgpart'        => $real_pkgpart,
 706                                 'options'             => \%postal_options,
 707                               );
 708           if ($error) {
 709             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 710             return $error;
 711           }
 712         }
 713
 714         # it's silly to have a zero value postal_pkg, but....
 715         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 716
 717       }
 718
 719     }
 720
 721     my $listref_or_error =
 722       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 723
 724     unless ( ref( $listref_or_error ) ) {
 725       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 726       return $listref_or_error;
 727     }
 728
 729     foreach my $taxline ( @$listref_or_error ) {
 730       ${ $total_setup{$pass} } =
 731         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 732       push @cust_bill_pkg, $taxline;
 733     }
 734
 735     #add tax adjustments
 736     warn "adding tax adjustments...\n" if $DEBUG > 2;
 737     foreach my $cust_tax_adjustment (
 738       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 739                                        'billpkgnum' => '',
 740                                      }
 741              )
 742     ) {
 743
 744       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 745
 746       my $itemdesc = $cust_tax_adjustment->taxname;
 747       $itemdesc = '' if $itemdesc eq 'Tax';
 748
 749       push @cust_bill_pkg, new FS::cust_bill_pkg {
 750         'pkgnum'      => 0,
 751         'setup'       => $tax,
 752         'recur'       => 0,
 753         'sdate'       => '',
 754         'edate'       => '',
 755         'itemdesc'    => $itemdesc,
 756         'itemcomment' => $cust_tax_adjustment->comment,
 757         'cust_tax_adjustment' => $cust_tax_adjustment,
 758         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 759       };
 760
 761     }
 762
 763     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 764
 765     my $balance = $self->balance;
 766
 767     my $previous_bill = qsearchs({ 'table'     => 'cust_bill',
 768                                    'hashref'   => { custnum=>$self->custnum },
 769                                    'extra_sql' => 'ORDER BY _date DESC LIMIT 1',
 770                                 });
 771     my $previous_balance =
 772       $previous_bill
 773         ? ( $previous_bill->billing_balance + $previous_bill->charged )
 774         : 0;
 775
 776     $log->debug('creating the new invoice', %logopt);
 777     warn "creating the new invoice\n" if $DEBUG;
 778     #create the new invoice
 779     my $cust_bill = new FS::cust_bill ( {
 780       'custnum'             => $self->custnum,
 781       '_date'               => $invoice_time,
 782       'charged'             => $charged,
 783       'billing_balance'     => $balance,
 784       'previous_balance'    => $previous_balance,
 785       'invoice_terms'       => $options{'invoice_terms'},
 786       'cust_bill_pkg'       => \@cust_bill_pkg,
 787     } );
 788     $error = $cust_bill->insert unless $options{no_commit};
 789     if ( $error ) {
 790       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 791       return "can't create invoice for customer #". $self->custnum. ": $error";
 792     }
 793     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 794
 795   } #foreach my $pass ( keys %cust_bill_pkg )
 796
 797   foreach my $hook ( @precommit_hooks ) {
 798     eval {
 799       &{$hook}; #($self) ?
 800     } unless $options{no_commit};
 801     if ( $@ ) {
 802       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 803       return "$@ running precommit hook $hook\n";
 804     }
 805   }
 806
 807   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 808
 809   ''; #no error
 810 }
 811
 812 #discard bundled packages of 0 value
 813 # XXX we should reconsider whether we even need this
 814 sub _omit_zero_value_bundles {
 815   my @in = @_;
 816
 817   my @out = ();
 818   my @bundle = ();
 819   my $discount_show_always = $conf->exists('discount-show-always');
 820   my $show_this = 0;
 821
 822   # Sort @in the same way we do during invoice rendering, so we can identify
 823   # bundles.  See FS::Template_Mixin::_items_nontax.
 824   @in = sort { $a->pkgnum <=> $b->pkgnum        or
 825                $a->sdate  <=> $b->sdate         or
 826                ($a->pkgpart_override ? 0 : -1)  or
 827                ($b->pkgpart_override ? 0 : 1)   or
 828                $b->hidden cmp $a->hidden        or
 829                $a->pkgpart_override <=> $b->pkgpart_override
 830              } @in;
 831
 832   # this is a pack-and-deliver pattern. every time there's a cust_bill_pkg
 833   # _without_ pkgpart_override, that's the start of the new bundle. if there's
 834   # an existing bundle, and it contains a nonzero amount (or a zero amount
 835   # that's displayable anyway), push all line items in the bundle.
 836   foreach my $cust_bill_pkg ( @in ) {
 837
 838     if (scalar(@bundle) and !$cust_bill_pkg->pkgpart_override) {
 839       # ship out this bundle and reset it
 840       if ( $show_this ) {
 841         push @out, @bundle;
 842       }
 843       @bundle = ();
 844       $show_this = 0;
 845     }
 846
 847     # add this item to the current bundle
 848     push @bundle, $cust_bill_pkg;
 849
 850     # determine if it makes the bundle displayable
 851     if (   $cust_bill_pkg->setup > 0
 852         or $cust_bill_pkg->recur > 0
 853         or $cust_bill_pkg->setup_show_zero
 854         or $cust_bill_pkg->recur_show_zero
 855         or ($discount_show_always
 856           and scalar(@{ $cust_bill_pkg->get('discounts')})
 857           )
 858     ) {
 859       $show_this++;
 860     }
 861   }
 862
 863   # last bundle
 864   if ( $show_this) {
 865     push @out, @bundle;
 866   }
 867
 868   warn "  _omit_zero_value_bundles: ". scalar(@in).
 869        '->'. scalar(@out). "\n" #. Dumper(@out). "\n"
 870     if $DEBUG > 2;
 871
 872   @out;
 873 }
 874
 875 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 876
 877 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 878 Usually used internally by bill method B<bill>.
 879
 880 If there is an error, returns the error, otherwise returns reference to a
 881 list of line items suitable for insertion.
 882
 883 =over 4
 884
 885 =item LINEITEMREF
 886
 887 An array ref of the line items being billed.
 888
 889 =item TAXHASHREF
 890
 891 A strange beast.  The keys to this hash are internal identifiers consisting
 892 of the name of the tax object type, a space, and its unique identifier ( e.g.
 893  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 894 item in the list is the tax object.  The remaining items are either line
 895 items or floating point values (currency amounts).
 896
 897 The taxes are calculated on this entity.  Calculated exemption records are
 898 transferred to the LINEITEMREF items on the assumption that they are related.
 899
 900 Read the source.
 901
 902 =item INVOICE_TIME
 903
 904 This specifies the date appearing on the associated invoice.  Some
 905 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 906
 907 =back
 908
 909 =cut
 910
 911 sub calculate_taxes {
 912   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 913
 914   # $taxlisthash is a hashref
 915   # keys are identifiers, values are arrayrefs
 916   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 917   # then a cust_bill_pkg object the tax applies to, then the charge class
 918   # on that object (setup, recur, a usage class number, or '')
 919   # For internal taxes the charge class is always undef.
 920
 921   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 922
 923   warn "$me calculate_taxes\n"
 924        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 925     if $DEBUG > 2;
 926
 927   my $custnum = $self->custnum;
 928   # The main tax accumulator.  One bin for each tax name (itemdesc).
 929   # For each subdivision of tax under this name, push a cust_bill_pkg item
 930   # for the calculated tax into the arrayref.
 931   # keys are tax names
 932   # values are arrayrefs of tax lines
 933   my %taxname = ();
 934
 935   # keys are taxlisthash keys (internal identifiers)
 936   # values are (cumulative) amounts
 937   my %tax_amount = ();
 938
 939   # keys are taxlisthash keys
 940   # values are arrayrefs of cust_tax_exempt_pkg objects
 941   my %tax_exemption;
 942
 943   # For tax on tax calculation, we need to remember which taxable items
 944   # (and charge classes) had which taxes applied to them.
 945   #
 946   # keys are cust_bill_pkg objects (taxable items)
 947   # values are hashrefs
 948   #   keys are charge classes
 949   #   values are hashrefs
 950   #     keys are taxnums (in tax_rate only; cust_main_county doesn't use this)
 951   #     values are the taxlines generated for those taxes
 952   tie my %item_has_tax, 'Tie::RefHash',
 953     map { $_ => {} } @$cust_bill_pkg;
 954
 955   foreach my $tax_id ( keys %$taxlisthash ) {
 956     # $tax_id: the identifier of the tax we are calculating in this pass
 957
 958     my $taxables = $taxlisthash->{$tax_id};
 959     my $tax_object = shift @$taxables;
 960     my $taxnum = $tax_object->taxnum;
 961     # $tax_object is a cust_main_county or tax_rate
 962     # (with billpkgnum, pkgnum, locationnum set)
 963     # the rest of @{ $taxlisthash->{$tax_id} } is cust_bill_pkg objects,
 964     # optionally followed by their charge classes.
 965     warn "found ". $tax_object->taxname. " as $tax_id\n" if $DEBUG > 2;
 966
 967     # taxline calculates the tax on all cust_bill_pkgs in the
 968     # first (arrayref) argument.
 969     #
 970     # Note that non-monthly exemptions have already been calculated and
 971     # attached to the items.  Monthly exemptions will be attached in this
 972     # step.
 973     my $exemptions = $tax_exemption{$tax_id} ||= [];
 974     if ( $tax_object->isa('FS::tax_rate') ) { # EXTERNAL TAXES
 975       # STILL have tax_rate-specific crap in here...
 976       my @taxlines = $tax_object->taxline( $taxables,
 977                               'custnum'      => $custnum,
 978                               'invoice_time' => $invoice_time,
 979                               'exemptions'   => $exemptions,
 980                               );
 981       next if !@taxlines;
 982       if (!ref $taxlines[0]) {
 983         # it's an error string
 984         warn "error evaluating $tax_id on custnum $custnum\n";
 985         return $taxlines[0];
 986       }
 987       foreach my $taxline (@taxlines) {
 988         push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 989         my $link = $taxline->get('cust_bill_pkg_tax_rate_location')->[0];
 990         my $taxable_item = $link->taxable_cust_bill_pkg;
 991         $item_has_tax{$taxable_item}{$taxline->_class}{$taxnum} = $taxline;
 992       }
 993
 994     } else { # INTERNAL TAXES
 995       # we can do this in a single taxline, because it's not stupid
 996
 997       my $taxline =  $tax_object->taxline( $taxables,
 998                         'custnum'      => $custnum,
 999                         'invoice_time' => $invoice_time,
1000                         'exemptions'   => $exemptions,
1001                       );
1002       next if !$taxline;
1003       if (!ref $taxline) {
1004         # it's an error string
1005         warn "error evaluating $tax_id on custnum $custnum\n";
1006         return $taxline;
1007       }
1008       # if the calculated tax is zero, don't even keep it
1009       next if $taxline->setup < 0.001;
1010       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1011     }
1012   }
1013   $DB::single = 1; # XXX
1014
1015   # all first-tier taxes are calculated.  now for tax on tax:
1016
1017   foreach my $taxable_item ( @$cust_bill_pkg ) {
1018     # taxes that apply to this item
1019     my $this_has_tax = $item_has_tax{$taxable_item};
1020
1021     my $location = $taxable_item->tax_location;
1022
1023     foreach my $charge_class (keys %$this_has_tax) {
1024       # taxes that apply to this item and charge class
1025       my $this_class_has_tax = $this_has_tax->{$charge_class};
1026       foreach my $taxnum (keys %$this_class_has_tax) {
1027
1028         # for each tax item that was calculated in phase 1, get the
1029         # tax definition
1030         my $tax_object = FS::tax_rate->by_key($taxnum);
1031         # and find all taxes that apply to it in this location
1032         my @tot = $tax_object->tax_on_tax( $location );
1033         next if !@tot;
1034         warn "found possible taxed taxnum $taxnum\n"
1035           if $DEBUG > 2;
1036         # Calculate ToT separately for each taxable item and class, and only
1037         # if _that class on the item_ is already taxed under the ToT.  This is
1038         # counterintuitive.
1039         # See RT#5243 and RT#36380.
1040         foreach my $tot (@tot) {
1041           my $totnum = $tot->taxnum;
1042           warn "checking taxnum $totnum which we call ". $tot->taxname ."\n"
1043             if $DEBUG > 2;
1044           # note: if the _null class_ on this item is taxed under the ToT,
1045           # then this specific class is taxed also (because null class
1046           # includes all classes) and so ToT is applicable.
1047           if (
1048                 exists $this_class_has_tax->{ $totnum }
1049              or exists $this_has_tax->{''}{ $totnum }
1050           ) {
1051
1052             warn "calculating tax on tax: taxnum $totnum on $taxnum\n"
1053               if $DEBUG;
1054             my @taxlines = $tot->taxline(
1055                               $this_class_has_tax->{ $taxnum }, # the first-stage tax
1056                               'custnum'       => $custnum,
1057                               'invoice_time'  => $invoice_time,
1058                              );
1059             next if (!@taxlines); # it didn't apply after all
1060             if (!ref($taxlines[0])) {
1061               warn "error evaluating taxnum $totnum TOT on custnum $custnum\n";
1062               return $taxlines[0];
1063             }
1064             foreach my $taxline (@taxlines) {
1065               push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1066             }
1067           } # if $has_tax
1068         } # foreach my $tot (tax-on-tax rate definition)
1069       } # foreach $taxnum (first-tier rate definition)
1070     } # foreach $charge_class
1071   } # foreach $taxable_item
1072
1073   #consolidate and create tax line items
1074   warn "consolidating and generating...\n" if $DEBUG > 2;
1075   my %final_tax_items; # taxname => item
1076   foreach my $taxname ( keys %taxname ) {
1077     my @cust_bill_pkg_tax_location;
1078     my @cust_bill_pkg_tax_rate_location;
1079     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
1080         'pkgnum'    => 0,
1081         'recur'     => 0,
1082         'sdate'     => '',
1083         'edate'     => '',
1084         'itemdesc'  => $taxname,
1085         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
1086         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
1087     });
1088
1089     my $tax_total = 0;
1090     my %seen = ();
1091     warn "adding $taxname\n" if $DEBUG > 1;
1092     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
1093       next if $taxitem->get('setup') == 0;
1094       # if ( ref($taxitem) eq 'FS::cust_bill_pkg' )  # always true
1095       # then we need to transfer the amount and the links from the
1096       # line item to the new one we're creating.
1097       $tax_total += $taxitem->setup;
1098       my @links = @{
1099         $taxitem->get('cust_bill_pkg_tax_location') ||
1100         $taxitem->get('cust_bill_pkg_tax_rate_location') ||
1101         []
1102       };
1103       foreach my $link ( @links ) {
1104         $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
1105         if ($link->isa('FS::cust_bill_pkg_tax_location')) {
1106           push @cust_bill_pkg_tax_location, $link;
1107         } elsif ($link->isa('FS::cust_bill_pkg_tax_rate_location')) {
1108           push @cust_bill_pkg_tax_rate_location, $link;
1109         }
1110       }
1111     }
1112     next unless $tax_total;
1113
1114     # we should really neverround this up...I guess it's okay if taxline
1115     # already returns amounts with 2 decimal places
1116     $tax_total = sprintf('%.2f', $tax_total );
1117     $tax_cust_bill_pkg->set('setup', $tax_total);
1118
1119     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1120                                                    'disabled'     => '',
1121                                                  },
1122                                );
1123
1124     my @display = ();
1125     if ( $pkg_category and
1126          $conf->config('invoice_latexsummary') ||
1127          $conf->config('invoice_htmlsummary')
1128        )
1129     {
1130
1131       my %hash = (  'section' => $pkg_category->categoryname );
1132       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1133
1134     }
1135     $tax_cust_bill_pkg->set('display', \@display);
1136
1137     $final_tax_items{$taxname} = $tax_cust_bill_pkg;
1138   } # foreach $taxname
1139
1140   # fix ToT backlinks for taxes that have been consolidated
1141   # (has to be done in a separate pass)
1142   foreach my $tax_item (values %final_tax_items) {
1143     foreach my $taxable_link (@{ $tax_item->cust_bill_pkg_tax_rate_location }) {
1144       my $taxed_item = $taxable_link->taxable_cust_bill_pkg;
1145       next if $taxed_item->pkgnum > 0; # primary taxes
1146       my $taxname = $taxed_item->itemdesc;
1147       $taxable_link->set('taxable_cust_bill_pkg', $final_tax_items{ $taxname });
1148     }
1149   }
1150
1151   [ values %final_tax_items ]
1152 }
1153
1154 sub _make_lines {
1155   my ($self, %params) = @_;
1156
1157   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1158
1159   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1160   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1161   my $cust_location = $cust_pkg->tax_location;
1162   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1163   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1164   my $total_setup = $params{setup} or die "no setup accumulator specified";
1165   my $total_recur = $params{recur} or die "no recur accumulator specified";
1166   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1167   my $time = $params{'time'} or die "no time specified";
1168   my (%options) = %{$params{options}};
1169
1170   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1171     # this should never happen
1172     die 'freq_override billing attempted on non-monthly package '.
1173       $cust_pkg->pkgnum;
1174   }
1175
1176   my $dbh = dbh;
1177   my $real_pkgpart = $params{real_pkgpart};
1178   my %hash = $cust_pkg->hash;
1179   my $old_cust_pkg = new FS::cust_pkg \%hash;
1180
1181   my @details = ();
1182   my $lineitems = 0;
1183
1184   $cust_pkg->pkgpart($part_pkg->pkgpart);
1185
1186   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1187                      ? day_end( $time )
1188                      : $time
1189                  );
1190
1191   ###
1192   # bill setup
1193   ###
1194
1195   my $setup = 0;
1196   my $unitsetup = 0;
1197   my @setup_discounts = ();
1198   my %setup_param = ( 'discounts'    => \@setup_discounts,
1199                       'real_pkgpart' => $params{real_pkgpart}
1200                     );
1201   # Conditions for setting setup date and charging the setup fee:
1202   # - this is not a recurring-only billing run
1203   # - and the package is not currently being canceled
1204   # - and, unless we're specifically told otherwise via 'resetup':
1205   #   - it doesn't already HAVE a setup date
1206   #   - or a start date in the future
1207   #   - and it's not suspended
1208   # - and it doesn't have an expire date in the past
1209   #
1210   # The "disable_setup_suspended" option is now obsolete; we never set the
1211   # setup date on a suspended package.
1212   if (     ! $options{recurring_only}
1213        and ! $options{cancel}
1214        and ( $options{'resetup'}
1215              || ( ! $cust_pkg->setup
1216                   && ( ! $cust_pkg->start_date
1217                        || $cust_pkg->start_date <= $cmp_time
1218                      )
1219                   && ( ! $cust_pkg->getfield('susp') )
1220               )
1221            )
1222        and ( ! $cust_pkg->expire
1223              || $cust_pkg->expire > $cmp_time )
1224      )
1225   {
1226
1227     warn "    bill setup\n" if $DEBUG > 1;
1228
1229     unless ( $cust_pkg->waive_setup ) {
1230         $lineitems++;
1231
1232         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1233         return "$@ running calc_setup for $cust_pkg\n"
1234           if $@;
1235
1236         # Only increment unitsetup here if there IS a setup fee.
1237         # prorate_defer_bill may cause calc_setup on a setup-stage package
1238         # to return zero, and the setup fee to be charged later. (This happens
1239         # when it's first billed on the prorate cutoff day. RT#31276.)
1240         if ( $setup ) {
1241           $unitsetup = $cust_pkg->base_setup()
1242                          || $setup; #XXX uuh
1243         }
1244     }
1245
1246     $cust_pkg->setfield('setup', $time)
1247       unless $cust_pkg->setup;
1248           #do need it, but it won't get written to the db
1249           #|| $cust_pkg->pkgpart != $real_pkgpart;
1250
1251     $cust_pkg->setfield('start_date', '')
1252       if $cust_pkg->start_date;
1253
1254   }
1255
1256   ###
1257   # bill recurring fee
1258   ###
1259
1260   my $recur = 0;
1261   my $unitrecur = 0;
1262   my @recur_discounts = ();
1263   my $sdate;
1264
1265   my $override_quantity;
1266
1267   # Conditions for billing the recurring fee:
1268   # - the package doesn't have a future start date
1269   # - and it's not suspended
1270   #   - unless suspend_bill is enabled on the package or package def
1271   #     - but still not, if the package is on hold
1272   #   - or it's suspended for a delayed cancellation
1273   # - and its next bill date is in the past
1274   #   - or it doesn't have a next bill date yet
1275   #   - or it's a one-time charge
1276   #   - or it's a CDR plan with the "bill_every_call" option
1277   #   - or it's being canceled
1278   # - and it doesn't have an expire date in the past (this can happen with
1279   #   advance billing)
1280   #   - again, unless it's being canceled
1281   if (     ! $cust_pkg->start_date
1282        and
1283            ( ! $cust_pkg->susp
1284                || ( $cust_pkg->susp != $cust_pkg->order_date
1285                       && (    $cust_pkg->option('suspend_bill',1)
1286                            || ( $part_pkg->option('suspend_bill', 1)
1287                                  && ! $cust_pkg->option('no_suspend_bill',1)
1288                               )
1289                          )
1290                   )
1291                || $cust_pkg->is_status_delay_cancel
1292            )
1293        and
1294             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1295          || ( $part_pkg->plan eq 'voip_cdr'
1296                && $part_pkg->option('bill_every_call')
1297             )
1298          || $options{cancel}
1299
1300        and
1301           ( ! $cust_pkg->expire
1302             || $cust_pkg->expire > $cmp_time
1303             || $options{cancel}
1304           )
1305   ) {
1306
1307     # XXX should this be a package event?  probably.  events are called
1308     # at collection time at the moment, though...
1309     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1310       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1311       #don't want to reset usage just cause we want a line item??
1312       #&& $part_pkg->pkgpart == $real_pkgpart;
1313
1314     warn "    bill recur\n" if $DEBUG > 1;
1315     $lineitems++;
1316
1317     # XXX shared with $recur_prog
1318     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1319              || $cust_pkg->setup
1320              || $time;
1321
1322     #over two params!  lets at least switch to a hashref for the rest...
1323     my $increment_next_bill = ( $part_pkg->freq ne '0'
1324                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1325                                 && !$options{cancel}
1326                               );
1327     my %param = ( %setup_param,
1328                   'precommit_hooks'     => $precommit_hooks,
1329                   'increment_next_bill' => $increment_next_bill,
1330                   'discounts'           => \@recur_discounts,
1331                   'real_pkgpart'        => $real_pkgpart,
1332                   'freq_override'       => $options{freq_override} || '',
1333                   'setup_fee'           => 0,
1334                 );
1335
1336     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1337
1338     # There may be some part_pkg for which this is wrong.  Only those
1339     # which can_discount are supported.
1340     # (the UI should prevent adding discounts to these at the moment)
1341
1342     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1343          " for pkgpart ". $cust_pkg->pkgpart.
1344          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1345       if $DEBUG > 2;
1346
1347     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1348     return "$@ running $method for $cust_pkg\n"
1349       if ( $@ );
1350
1351     if ($recur eq 'NOTHING') {
1352       # then calc_cancel (or calc_recur but that's not used) has declined to
1353       # generate a recurring lineitem at all. treat this as zero, but also
1354       # try not to generate a lineitem.
1355       $recur = 0;
1356       $lineitems--;
1357     }
1358
1359     #base_cancel???
1360     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1361
1362     if ( $param{'override_quantity'} ) {
1363       $override_quantity = $param{'override_quantity'};
1364     }
1365
1366     if ( $increment_next_bill ) {
1367
1368       my $next_bill;
1369
1370       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1371         # supplemental package
1372         # to keep in sync with the main package, simulate billing at
1373         # its frequency
1374         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1375         my $supp_pkg_freq = $part_pkg->freq;
1376         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1377         if ( $ratio != int($ratio) ) {
1378           # the UI should prevent setting up packages like this, but just
1379           # in case
1380           return "supplemental package period is not an integer multiple of main  package period";
1381         }
1382         $next_bill = $sdate;
1383         for (1..$ratio) {
1384           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1385         }
1386
1387       } else {
1388         # the normal case
1389       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1390       return "unparsable frequency: ".
1391         ($options{freq_override} || $part_pkg->freq)
1392         if $next_bill == -1;
1393       }
1394
1395       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1396       # only for figuring next bill date, nothing else, so, reset $sdate again
1397       # here
1398       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1399       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1400       $cust_pkg->last_bill($sdate);
1401
1402       $cust_pkg->setfield('bill', $next_bill );
1403
1404     }
1405
1406     if ( $param{'setup_fee'} ) {
1407       # Add an additional setup fee at the billing stage.
1408       # Used for prorate_defer_bill.
1409       $setup += $param{'setup_fee'};
1410       $unitsetup = $cust_pkg->base_setup();
1411       $lineitems++;
1412     }
1413
1414     if ( defined $param{'discount_left_setup'} ) {
1415         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1416             $setup -= $discount_setup;
1417         }
1418     }
1419
1420   } # end of recurring fee
1421
1422   warn "\$setup is undefined" unless defined($setup);
1423   warn "\$recur is undefined" unless defined($recur);
1424   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1425
1426   ###
1427   # If there's line items, create em cust_bill_pkg records
1428   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1429   ###
1430
1431   if ( $lineitems ) {
1432
1433     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1434       # hmm.. and if just the options are modified in some weird price plan?
1435
1436       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1437         if $DEBUG >1;
1438
1439       my $error = $cust_pkg->replace( $old_cust_pkg,
1440                                       'depend_jobnum'=>$options{depend_jobnum},
1441                                       'options' => { $cust_pkg->options },
1442                                     )
1443         unless $options{no_commit};
1444       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1445         if $error; #just in case
1446     }
1447
1448     $setup = sprintf( "%.2f", $setup );
1449     $recur = sprintf( "%.2f", $recur );
1450     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1451       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1452     }
1453     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1454       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1455     }
1456
1457     my $discount_show_always = $conf->exists('discount-show-always')
1458                                && (    ($setup == 0 && scalar(@setup_discounts))
1459                                     || ($recur == 0 && scalar(@recur_discounts))
1460                                   );
1461
1462     if (    $setup != 0
1463          || $recur != 0
1464          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1465          || $discount_show_always
1466          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1467          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1468        )
1469     {
1470
1471       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1472         if $DEBUG > 1;
1473
1474       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1475       if ( $DEBUG > 1 ) {
1476         warn "      adding customer package invoice detail: $_\n"
1477           foreach @cust_pkg_detail;
1478       }
1479       push @details, @cust_pkg_detail;
1480
1481       my $cust_bill_pkg = new FS::cust_bill_pkg {
1482         'pkgnum'    => $cust_pkg->pkgnum,
1483         'setup'     => $setup,
1484         'unitsetup' => sprintf('%.2f', $unitsetup),
1485         'recur'     => $recur,
1486         'unitrecur' => sprintf('%.2f', $unitrecur),
1487         'quantity'  => $override_quantity || $cust_pkg->quantity,
1488         'details'   => \@details,
1489         'discounts' => [ @setup_discounts, @recur_discounts ],
1490         'hidden'    => $part_pkg->hidden,
1491         'freq'      => $part_pkg->freq,
1492       };
1493
1494       if ( $part_pkg->option('prorate_defer_bill',1)
1495            and !$hash{last_bill} ) {
1496         # both preceding and upcoming, technically
1497         $cust_bill_pkg->sdate( $cust_pkg->setup );
1498         $cust_bill_pkg->edate( $cust_pkg->bill );
1499       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1500         $cust_bill_pkg->sdate( $hash{last_bill} );
1501         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1502         $cust_bill_pkg->edate( $time ) if $options{cancel};
1503       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1504         $cust_bill_pkg->sdate( $sdate );
1505         $cust_bill_pkg->edate( $cust_pkg->bill );
1506         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1507       }
1508
1509       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1510         unless $part_pkg->pkgpart == $real_pkgpart;
1511
1512       $$total_setup += $setup;
1513       $$total_recur += $recur;
1514
1515       ###
1516       # handle taxes
1517       ###
1518
1519       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg,
1520         cancel => $options{cancel} );
1521       return $error if $error;
1522
1523       $cust_bill_pkg->set_display(
1524         part_pkg     => $part_pkg,
1525         real_pkgpart => $real_pkgpart,
1526       );
1527
1528       push @$cust_bill_pkgs, $cust_bill_pkg;
1529
1530     } #if $setup != 0 || $recur != 0
1531
1532   } #if $line_items
1533
1534   '';
1535
1536 }
1537
1538 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1539
1540 Takes one argument, a cust_pkg object that is being billed.  This will
1541 be called only if the package was created by a package change, and has
1542 not been billed since the package change, and package balance tracking
1543 is enabled.  The second argument can be an alternate package number to
1544 transfer the balance from; this should not be used externally.
1545
1546 Transfers the balance from the previous package (now canceled) to
1547 this package, by crediting one package and creating an invoice item for
1548 the other.  Inserts the credit and returns the invoice item (so that it
1549 can be added to an invoice that's being built).
1550
1551 If the previous package was never billed, and was also created by a package
1552 change, then this will also transfer the balance from I<its> previous
1553 package, and so on, until reaching a package that either has been billed
1554 or was not created by a package change.
1555
1556 =cut
1557
1558 my $balance_transfer_reason;
1559
1560 sub _transfer_balance {
1561   my $self = shift;
1562   my $cust_pkg = shift;
1563   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1564   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1565
1566   my @transfers;
1567
1568   # if $from_pkg is not the first package in the chain, and it was never
1569   # billed, walk back
1570   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1571     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1572   }
1573
1574   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1575   if ( $prev_balance != 0 ) {
1576     $balance_transfer_reason ||= FS::reason->new_or_existing(
1577       'reason' => 'Package balance transfer',
1578       'type'   => 'Internal adjustment',
1579       'class'  => 'R'
1580     );
1581
1582     my $credit = FS::cust_credit->new({
1583         'custnum'   => $self->custnum,
1584         'amount'    => abs($prev_balance),
1585         'reasonnum' => $balance_transfer_reason->reasonnum,
1586         '_date'     => $cust_pkg->change_date,
1587     });
1588
1589     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1590         'setup'     => 0,
1591         'recur'     => abs($prev_balance),
1592         #'sdate'     => $from_pkg->last_bill, # not sure about this
1593         #'edate'     => $cust_pkg->change_date,
1594         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1595                                  $from_pkg->part_pkg->pkg),
1596     });
1597
1598     if ( $prev_balance > 0 ) {
1599       # credit the old package, charge the new one
1600       $credit->set('pkgnum', $from_pkgnum);
1601       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1602     } else {
1603       # the reverse
1604       $credit->set('pkgnum', $cust_pkg->pkgnum);
1605       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1606     }
1607     my $error = $credit->insert;
1608     die "error transferring package balance from #".$from_pkgnum.
1609         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1610
1611     push @transfers, $cust_bill_pkg;
1612   } # $prev_balance != 0
1613
1614   return @transfers;
1615 }
1616
1617 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1618
1619 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1620 from _make_lines.
1621
1622 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1623 this:
1624 {
1625   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1626   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1627 }
1628
1629 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1630 is always the cust_main_county or tax_rate identified by the key.
1631
1632 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1633 the 'taxline' method to calculate the amount of the tax.  This doesn't
1634 happen until calculate_taxes, though.
1635
1636 OPTIONS may include:
1637 - part_item: a part_pkg or part_fee object to be used as the package/fee
1638   definition.
1639 - location: a cust_location to be used as the billing location.
1640 - cancel: true if this package is being billed on cancellation.  This
1641   allows tax to be calculated on usage charges only.
1642
1643 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1644 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1645 the customer's default service location).
1646
1647 This method will also calculate exemptions for any taxes that apply to the
1648 line item (using the C<set_exemptions> method of L<FS::cust_bill_pkg>) and
1649 attach them.  This is the only place C<set_exemptions> is called in normal
1650 invoice processing.
1651
1652 =cut
1653
1654 sub _handle_taxes {
1655   my $self = shift;
1656   my $taxlisthash = shift;
1657   my $cust_bill_pkg = shift;
1658   my %options = @_;
1659
1660   # at this point I realize that we have enough information to infer all this
1661   # stuff, instead of passing around giant honking argument lists
1662   my $location = $options{location} || $cust_bill_pkg->tax_location;
1663   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1664
1665   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1666
1667   return if ( $self->payby eq 'COMP' ); #dubious
1668
1669   if ( $conf->exists('enable_taxproducts')
1670        && ( scalar($part_item->part_pkg_taxoverride)
1671             || $part_item->has_taxproduct
1672           )
1673      )
1674     {
1675
1676     # EXTERNAL TAX RATES (via tax_rate)
1677     my %cust_bill_pkg = ();
1678     my %taxes = ();
1679
1680     my @classes;
1681     my $usage = $cust_bill_pkg->usage || 0;
1682     push @classes, $cust_bill_pkg->usage_classes if $usage;
1683     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1684     push @classes, 'recur' if ($cust_bill_pkg->recur - $usage)
1685         and !$options{cancel};
1686     # that's better--probably don't even need $options{cancel} now
1687     # but leave it for now, just to be safe
1688     #
1689     # About $options{cancel}: This protects against charging per-line or
1690     # per-customer or other flat-rate surcharges on a package that's being
1691     # billed on cancellation (which is an out-of-cycle bill and should only
1692     # have usage charges).  See RT#29443.
1693
1694     # customer exemption is now handled in the 'taxline' method
1695     #my $exempt = $conf->exists('cust_class-tax_exempt')
1696     #               ? ( $self->cust_class ? $self->cust_class->tax : '' )
1697     #               : $self->tax;
1698     # standardize this just to be sure
1699     #$exempt = ($exempt eq 'Y') ? 'Y' : '';
1700     #
1701     #if ( !$exempt ) {
1702
1703     unless (exists $taxes{''}) {
1704       # unsure what purpose this serves, but last time I deleted something
1705       # from here just because I didn't see the point, it actually did
1706       # something important.
1707       my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1708       return $err_or_ref unless ref($err_or_ref);
1709       $taxes{''} = $err_or_ref;
1710     }
1711
1712     # NO DISINTEGRATIONS.
1713     # my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1714     #
1715     # do not call taxline() with any argument except the entire set of
1716     # cust_bill_pkgs on an invoice that are eligible for the tax.
1717
1718     # only calculate exemptions once for each tax rate, even if it's used
1719     # for multiple classes
1720     my %tax_seen = ();
1721
1722     foreach my $class (@classes) {
1723       my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1724       return $err_or_ref unless ref($err_or_ref);
1725       my @taxes = @$err_or_ref;
1726
1727       next if !@taxes;
1728
1729       foreach my $tax ( @taxes ) {
1730
1731         my $tax_id = ref( $tax ). ' '. $tax->taxnum;
1732         # $taxlisthash: keys are tax identifiers ('FS::tax_rate 123456').
1733         # Values are arrayrefs, first the tax object (cust_main_county
1734         # or tax_rate), then the cust_bill_pkg object that the
1735         # tax applies to, then the tax class (setup, recur, usage classnum).
1736         $taxlisthash->{ $tax_id } ||= [ $tax ];
1737         push @{ $taxlisthash->{ $tax_id  } }, $cust_bill_pkg, $class;
1738
1739         # determine any exemptions that apply
1740         if (!$tax_seen{$tax_id}) {
1741           $cust_bill_pkg->set_exemptions( $tax, custnum => $self->custnum );
1742           $tax_seen{$tax_id} = 1;
1743         }
1744
1745         # tax on tax will be done later, when we actually create the tax
1746         # line items
1747
1748       }
1749     }
1750
1751   } else {
1752
1753     # INTERNAL TAX RATES (cust_main_county)
1754
1755     # We fetch taxes even if the customer is completely exempt,
1756     # because we need to record that fact.
1757
1758     my @loc_keys = qw( district city county state country );
1759     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1760
1761     $taxhash{'taxclass'} = $part_item->taxclass;
1762
1763     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1764
1765     my @taxes = (); # entries are cust_main_county objects
1766     my %taxhash_elim = %taxhash;
1767     my @elim = qw( district city county state );
1768     do {
1769
1770       #first try a match with taxclass
1771       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1772
1773       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1774         #then try a match without taxclass
1775         my %no_taxclass = %taxhash_elim;
1776         $no_taxclass{ 'taxclass' } = '';
1777         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1778       }
1779
1780       $taxhash_elim{ shift(@elim) } = '';
1781
1782     } while ( !scalar(@taxes) && scalar(@elim) );
1783
1784     foreach (@taxes) {
1785       my $tax_id = 'cust_main_county '.$_->taxnum;
1786       $taxlisthash->{$tax_id} ||= [ $_ ];
1787       $cust_bill_pkg->set_exemptions($_, custnum => $self->custnum);
1788       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1789     }
1790
1791   }
1792   '';
1793 }
1794
1795 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1796
1797 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1798 or part_fee (which will define the tax eligibility of the product), CLASS is
1799 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1800 location where the service was provided (or billed, depending on
1801 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1802 can apply to this line item.
1803
1804 =cut
1805
1806 sub _gather_taxes {
1807   my $self = shift;
1808   my $part_item = shift;
1809   my $class = shift;
1810   my $location = shift;
1811
1812   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1813
1814   my $geocode = $location->geocode('cch');
1815
1816   [ $part_item->tax_rates('cch', $geocode, $class) ]
1817
1818 }
1819
1820 =item collect [ HASHREF | OPTION => VALUE ... ]
1821
1822 (Attempt to) collect money for this customer's outstanding invoices (see
1823 L<FS::cust_bill>).  Usually used after the bill method.
1824
1825 Actions are now triggered by billing events; see L<FS::part_event> and the
1826 billing events web interface.  Old-style invoice events (see
1827 L<FS::part_bill_event>) have been deprecated.
1828
1829 If there is an error, returns the error, otherwise returns false.
1830
1831 Options are passed as name-value pairs.
1832
1833 Currently available options are:
1834
1835 =over 4
1836
1837 =item invoice_time
1838
1839 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1840
1841 =item retry
1842
1843 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1844
1845 =item check_freq
1846
1847 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1848
1849 =item quiet
1850
1851 set true to surpress email card/ACH decline notices.
1852
1853 =item debug
1854
1855 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1856
1857 =back
1858
1859 # =item payby
1860 #
1861 # allows for one time override of normal customer billing method
1862
1863 =cut
1864
1865 sub collect {
1866   my( $self, %options ) = @_;
1867
1868   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1869
1870   my $invoice_time = $options{'invoice_time'} || time;
1871
1872   #put below somehow?
1873   local $SIG{HUP} = 'IGNORE';
1874   local $SIG{INT} = 'IGNORE';
1875   local $SIG{QUIT} = 'IGNORE';
1876   local $SIG{TERM} = 'IGNORE';
1877   local $SIG{TSTP} = 'IGNORE';
1878   local $SIG{PIPE} = 'IGNORE';
1879
1880   my $oldAutoCommit = $FS::UID::AutoCommit;
1881   local $FS::UID::AutoCommit = 0;
1882   my $dbh = dbh;
1883
1884   $self->select_for_update; #mutex
1885
1886   if ( $DEBUG ) {
1887     my $balance = $self->balance;
1888     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1889   }
1890
1891   if ( exists($options{'retry_card'}) ) {
1892     carp 'retry_card option passed to collect is deprecated; use retry';
1893     $options{'retry'} ||= $options{'retry_card'};
1894   }
1895   if ( exists($options{'retry'}) && $options{'retry'} ) {
1896     my $error = $self->retry_realtime;
1897     if ( $error ) {
1898       $dbh->rollback if $oldAutoCommit;
1899       return $error;
1900     }
1901   }
1902
1903   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1904
1905   #never want to roll back an event just because it returned an error
1906   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1907
1908   $self->do_cust_event(
1909     'debug'      => ( $options{'debug'} || 0 ),
1910     'time'       => $invoice_time,
1911     'check_freq' => $options{'check_freq'},
1912     'stage'      => 'collect',
1913   );
1914
1915 }
1916
1917 =item retry_realtime
1918
1919 Schedules realtime / batch  credit card / electronic check / LEC billing
1920 events for for retry.  Useful if card information has changed or manual
1921 retry is desired.  The 'collect' method must be called to actually retry
1922 the transaction.
1923
1924 Implementation details: For either this customer, or for each of this
1925 customer's open invoices, changes the status of the first "done" (with
1926 statustext error) realtime processing event to "failed".
1927
1928 =cut
1929
1930 sub retry_realtime {
1931   my $self = shift;
1932
1933   local $SIG{HUP} = 'IGNORE';
1934   local $SIG{INT} = 'IGNORE';
1935   local $SIG{QUIT} = 'IGNORE';
1936   local $SIG{TERM} = 'IGNORE';
1937   local $SIG{TSTP} = 'IGNORE';
1938   local $SIG{PIPE} = 'IGNORE';
1939
1940   my $oldAutoCommit = $FS::UID::AutoCommit;
1941   local $FS::UID::AutoCommit = 0;
1942   my $dbh = dbh;
1943
1944   #a little false laziness w/due_cust_event (not too bad, really)
1945
1946   # I guess this is always as of now?
1947   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1948   my $order = FS::part_event_condition->order_conditions_sql;
1949   my $mine =
1950   '( '
1951    . join ( ' OR ' , map {
1952     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1953     my $custnum = FS::part_event->eventtables_custnum->{$_};
1954     "( part_event.eventtable = " . dbh->quote($_)
1955     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1956     . " from $_ $cust_join"
1957     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1958    } FS::part_event->eventtables)
1959    . ') ';
1960
1961   #here is the agent virtualization
1962   my $agent_virt = " (    part_event.agentnum IS NULL
1963                        OR part_event.agentnum = ". $self->agentnum. ' )';
1964
1965   #XXX this shouldn't be hardcoded, actions should declare it...
1966   my @realtime_events = qw(
1967     cust_bill_realtime_card
1968     cust_bill_realtime_check
1969     cust_bill_realtime_lec
1970     cust_bill_batch
1971   );
1972
1973   my $is_realtime_event =
1974     ' part_event.action IN ( '.
1975         join(',', map "'$_'", @realtime_events ).
1976     ' ) ';
1977
1978   my $batch_or_statustext =
1979     "( part_event.action = 'cust_bill_batch'
1980        OR ( statustext IS NOT NULL AND statustext != '' )
1981      )";
1982
1983
1984   my @cust_event = qsearch({
1985     'table'     => 'cust_event',
1986     'select'    => 'cust_event.*',
1987     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1988     'hashref'   => { 'status' => 'done' },
1989     'extra_sql' => " AND $batch_or_statustext ".
1990                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1991   });
1992
1993   my %seen_invnum = ();
1994   foreach my $cust_event (@cust_event) {
1995
1996     #max one for the customer, one for each open invoice
1997     my $cust_X = $cust_event->cust_X;
1998     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1999                           ? $cust_X->invnum
2000                           : 0
2001                         }++
2002          or $cust_event->part_event->eventtable eq 'cust_bill'
2003             && ! $cust_X->owed;
2004
2005     my $error = $cust_event->retry;
2006     if ( $error ) {
2007       $dbh->rollback if $oldAutoCommit;
2008       return "error scheduling event for retry: $error";
2009     }
2010
2011   }
2012
2013   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2014   '';
2015
2016 }
2017
2018 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
2019
2020 Runs billing events; see L<FS::part_event> and the billing events web
2021 interface.
2022
2023 If there is an error, returns the error, otherwise returns false.
2024
2025 Options are passed as name-value pairs.
2026
2027 Currently available options are:
2028
2029 =over 4
2030
2031 =item time
2032
2033 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
2034
2035 =item check_freq
2036
2037 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
2038
2039 =item stage
2040
2041 "collect" (the default) or "pre-bill"
2042
2043 =item quiet
2044
2045 set true to surpress email card/ACH decline notices.
2046
2047 =item debug
2048
2049 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2050
2051 =back
2052 =cut
2053
2054 # =item payby
2055 #
2056 # allows for one time override of normal customer billing method
2057
2058 # =item retry
2059 #
2060 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
2061
2062 sub do_cust_event {
2063   my( $self, %options ) = @_;
2064
2065   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2066
2067   my $time = $options{'time'} || time;
2068
2069   #put below somehow?
2070   local $SIG{HUP} = 'IGNORE';
2071   local $SIG{INT} = 'IGNORE';
2072   local $SIG{QUIT} = 'IGNORE';
2073   local $SIG{TERM} = 'IGNORE';
2074   local $SIG{TSTP} = 'IGNORE';
2075   local $SIG{PIPE} = 'IGNORE';
2076
2077   my $oldAutoCommit = $FS::UID::AutoCommit;
2078   local $FS::UID::AutoCommit = 0;
2079   my $dbh = dbh;
2080
2081   $self->select_for_update; #mutex
2082
2083   if ( $DEBUG ) {
2084     my $balance = $self->balance;
2085     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
2086   }
2087
2088 #  if ( exists($options{'retry_card'}) ) {
2089 #    carp 'retry_card option passed to collect is deprecated; use retry';
2090 #    $options{'retry'} ||= $options{'retry_card'};
2091 #  }
2092 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
2093 #    my $error = $self->retry_realtime;
2094 #    if ( $error ) {
2095 #      $dbh->rollback if $oldAutoCommit;
2096 #      return $error;
2097 #    }
2098 #  }
2099
2100   # false laziness w/pay_batch::import_results
2101
2102   my $due_cust_event = $self->due_cust_event(
2103     'debug'      => ( $options{'debug'} || 0 ),
2104     'time'       => $time,
2105     'check_freq' => $options{'check_freq'},
2106     'stage'      => ( $options{'stage'} || 'collect' ),
2107   );
2108   unless( ref($due_cust_event) ) {
2109     $dbh->rollback if $oldAutoCommit;
2110     return $due_cust_event;
2111   }
2112
2113   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2114   #never want to roll back an event just because it or a different one
2115   # returned an error
2116   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
2117
2118   foreach my $cust_event ( @$due_cust_event ) {
2119
2120     #XXX lock event
2121
2122     #re-eval event conditions (a previous event could have changed things)
2123     unless ( $cust_event->test_conditions ) {
2124       #don't leave stray "new/locked" records around
2125       my $error = $cust_event->delete;
2126       return $error if $error;
2127       next;
2128     }
2129
2130     {
2131       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
2132         if $options{'quiet'};
2133       warn "  running cust_event ". $cust_event->eventnum. "\n"
2134         if $DEBUG > 1;
2135
2136       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
2137       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
2138         #XXX wtf is this?  figure out a proper dealio with return value
2139         #from do_event
2140         return $error;
2141       }
2142     }
2143
2144   }
2145
2146   '';
2147
2148 }
2149
2150 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
2151
2152 Inserts database records for and returns an ordered listref of new events due
2153 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
2154 events are due, an empty listref is returned.  If there is an error, returns a
2155 scalar error message.
2156
2157 To actually run the events, call each event's test_condition method, and if
2158 still true, call the event's do_event method.
2159
2160 Options are passed as a hashref or as a list of name-value pairs.  Available
2161 options are:
2162
2163 =over 4
2164
2165 =item check_freq
2166
2167 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
2168
2169 =item stage
2170
2171 "collect" (the default) or "pre-bill"
2172
2173 =item time
2174
2175 "Current time" for the events.
2176
2177 =item debug
2178
2179 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2180
2181 =item eventtable
2182
2183 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2184
2185 =item objects
2186
2187 Explicitly pass the objects to be tested (typically used with eventtable).
2188
2189 =item testonly
2190
2191 Set to true to return the objects, but not actually insert them into the
2192 database.
2193
2194 =back
2195
2196 =cut
2197
2198 sub due_cust_event {
2199   my $self = shift;
2200   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2201
2202   #???
2203   #my $DEBUG = $opt{'debug'}
2204   $opt{'debug'} ||= 0; # silence some warnings
2205   local($DEBUG) = $opt{'debug'}
2206     if $opt{'debug'} > $DEBUG;
2207   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2208
2209   warn "$me due_cust_event called with options ".
2210        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2211     if $DEBUG;
2212
2213   $opt{'time'} ||= time;
2214
2215   local $SIG{HUP} = 'IGNORE';
2216   local $SIG{INT} = 'IGNORE';
2217   local $SIG{QUIT} = 'IGNORE';
2218   local $SIG{TERM} = 'IGNORE';
2219   local $SIG{TSTP} = 'IGNORE';
2220   local $SIG{PIPE} = 'IGNORE';
2221
2222   my $oldAutoCommit = $FS::UID::AutoCommit;
2223   local $FS::UID::AutoCommit = 0;
2224   my $dbh = dbh;
2225
2226   $self->select_for_update #mutex
2227     unless $opt{testonly};
2228
2229   ###
2230   # find possible events (initial search)
2231   ###
2232
2233   my @cust_event = ();
2234
2235   my @eventtable = $opt{'eventtable'}
2236                      ? ( $opt{'eventtable'} )
2237                      : FS::part_event->eventtables_runorder;
2238
2239   my $check_freq = $opt{'check_freq'} || '1d';
2240
2241   foreach my $eventtable ( @eventtable ) {
2242
2243     my @objects;
2244     if ( $opt{'objects'} ) {
2245
2246       @objects = @{ $opt{'objects'} };
2247
2248     } elsif ( $eventtable eq 'cust_main' ) {
2249
2250       @objects = ( $self );
2251
2252     } else {
2253
2254       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2255       # linkage not needed here because FS::cust_main->$eventtable will
2256       # already supply it
2257
2258       #some false laziness w/Cron::bill bill_where
2259
2260       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2261         'time' => $opt{'time'});
2262       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2263         'time'=>$opt{'time'},
2264       );
2265       $where = $where ? "AND $where" : '';
2266
2267       my $are_part_event =
2268       "EXISTS ( SELECT 1 FROM part_event $join
2269         WHERE check_freq = '$check_freq'
2270         AND eventtable = '$eventtable'
2271         AND ( disabled = '' OR disabled IS NULL )
2272         $where
2273         )
2274       ";
2275       #eofalse
2276
2277       @objects = $self->$eventtable(
2278         'addl_from' => $cm_join,
2279         'extra_sql' => " AND $are_part_event",
2280       );
2281     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2282
2283     my @e_cust_event = ();
2284
2285     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2286
2287     my $cross = "CROSS JOIN $eventtable $linkage";
2288     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2289       unless $eventtable eq 'cust_main';
2290
2291     foreach my $object ( @objects ) {
2292
2293       #this first search uses the condition_sql magic for optimization.
2294       #the more possible events we can eliminate in this step the better
2295
2296       my $cross_where = '';
2297       my $pkey = $object->primary_key;
2298       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2299
2300       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2301         'time' => $opt{'time'});
2302       my $extra_sql =
2303         FS::part_event_condition->where_conditions_sql( $eventtable,
2304                                                         'time'=>$opt{'time'}
2305                                                       );
2306       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2307
2308       $extra_sql = "AND $extra_sql" if $extra_sql;
2309
2310       #here is the agent virtualization
2311       $extra_sql .= " AND (    part_event.agentnum IS NULL
2312                             OR part_event.agentnum = ". $self->agentnum. ' )';
2313
2314       $extra_sql .= " $order";
2315
2316       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2317         if $opt{'debug'} > 2;
2318       my @part_event = qsearch( {
2319         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2320         'select'    => 'part_event.*',
2321         'table'     => 'part_event',
2322         'addl_from' => "$cross $join",
2323         'hashref'   => { 'check_freq' => $check_freq,
2324                          'eventtable' => $eventtable,
2325                          'disabled'   => '',
2326                        },
2327         'extra_sql' => "AND $cross_where $extra_sql",
2328       } );
2329
2330       if ( $DEBUG > 2 ) {
2331         my $pkey = $object->primary_key;
2332         warn "      ". scalar(@part_event).
2333              " possible events found for $eventtable ". $object->$pkey(). "\n";
2334       }
2335
2336       push @e_cust_event, map {
2337         $_->new_cust_event($object, 'time' => $opt{'time'})
2338       } @part_event;
2339
2340     }
2341
2342     warn "    ". scalar(@e_cust_event).
2343          " subtotal possible cust events found for $eventtable\n"
2344       if $DEBUG > 1;
2345
2346     push @cust_event, @e_cust_event;
2347
2348   }
2349
2350   warn "  ". scalar(@cust_event).
2351        " total possible cust events found in initial search\n"
2352     if $DEBUG; # > 1;
2353
2354
2355   ##
2356   # test stage
2357   ##
2358
2359   $opt{stage} ||= 'collect';
2360   @cust_event =
2361     grep { my $stage = $_->part_event->event_stage;
2362            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2363          }
2364          @cust_event;
2365
2366   ##
2367   # test conditions
2368   ##
2369
2370   my %unsat = ();
2371
2372   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2373                      @cust_event;
2374
2375   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2376     if $DEBUG; # > 1;
2377
2378   warn "    invalid conditions not eliminated with condition_sql:\n".
2379        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2380     if keys %unsat && $DEBUG; # > 1;
2381
2382   ##
2383   # insert
2384   ##
2385
2386   unless( $opt{testonly} ) {
2387     foreach my $cust_event ( @cust_event ) {
2388
2389       my $error = $cust_event->insert();
2390       if ( $error ) {
2391         $dbh->rollback if $oldAutoCommit;
2392         return $error;
2393       }
2394
2395     }
2396   }
2397
2398   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2399
2400   ##
2401   # return
2402   ##
2403
2404   warn "  returning events: ". Dumper(@cust_event). "\n"
2405     if $DEBUG > 2;
2406
2407   \@cust_event;
2408
2409 }
2410
2411 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2412
2413 Applies unapplied payments and credits.
2414 Payments with the no_auto_apply flag set will not be applied.
2415
2416 In most cases, this new method should be used in place of sequential
2417 apply_payments and apply_credits methods.
2418
2419 A hash of optional arguments may be passed.  Currently "manual" is supported.
2420 If true, a payment receipt is sent instead of a statement when
2421 'payment_receipt_email' configuration option is set.
2422
2423 If there is an error, returns the error, otherwise returns false.
2424
2425 =cut
2426
2427 sub apply_payments_and_credits {
2428   my( $self, %options ) = @_;
2429
2430   local $SIG{HUP} = 'IGNORE';
2431   local $SIG{INT} = 'IGNORE';
2432   local $SIG{QUIT} = 'IGNORE';
2433   local $SIG{TERM} = 'IGNORE';
2434   local $SIG{TSTP} = 'IGNORE';
2435   local $SIG{PIPE} = 'IGNORE';
2436
2437   my $oldAutoCommit = $FS::UID::AutoCommit;
2438   local $FS::UID::AutoCommit = 0;
2439   my $dbh = dbh;
2440
2441   $self->select_for_update; #mutex
2442
2443   foreach my $cust_bill ( $self->open_cust_bill ) {
2444     my $error = $cust_bill->apply_payments_and_credits(%options);
2445     if ( $error ) {
2446       $dbh->rollback if $oldAutoCommit;
2447       return "Error applying: $error";
2448     }
2449   }
2450
2451   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2452   ''; #no error
2453
2454 }
2455
2456 =item apply_credits OPTION => VALUE ...
2457
2458 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2459 to outstanding invoice balances in chronological order (or reverse
2460 chronological order if the I<order> option is set to B<newest>) and returns the
2461 value of any remaining unapplied credits available for refund (see
2462 L<FS::cust_refund>).
2463
2464 Dies if there is an error.
2465
2466 =cut
2467
2468 sub apply_credits {
2469   my $self = shift;
2470   my %opt = @_;
2471
2472   local $SIG{HUP} = 'IGNORE';
2473   local $SIG{INT} = 'IGNORE';
2474   local $SIG{QUIT} = 'IGNORE';
2475   local $SIG{TERM} = 'IGNORE';
2476   local $SIG{TSTP} = 'IGNORE';
2477   local $SIG{PIPE} = 'IGNORE';
2478
2479   my $oldAutoCommit = $FS::UID::AutoCommit;
2480   local $FS::UID::AutoCommit = 0;
2481   my $dbh = dbh;
2482
2483   $self->select_for_update; #mutex
2484
2485   unless ( $self->total_unapplied_credits ) {
2486     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2487     return 0;
2488   }
2489
2490   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2491       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2492
2493   my @invoices = $self->open_cust_bill;
2494   @invoices = sort { $b->_date <=> $a->_date } @invoices
2495     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2496
2497   if ( $conf->exists('pkg-balances') ) {
2498     # limit @credits to those w/ a pkgnum grepped from $self
2499     my %pkgnums = ();
2500     foreach my $i (@invoices) {
2501       foreach my $li ( $i->cust_bill_pkg ) {
2502         $pkgnums{$li->pkgnum} = 1;
2503       }
2504     }
2505     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2506   }
2507
2508   my $credit;
2509
2510   foreach my $cust_bill ( @invoices ) {
2511
2512     if ( !defined($credit) || $credit->credited == 0) {
2513       $credit = pop @credits or last;
2514     }
2515
2516     my $owed;
2517     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2518       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2519     } else {
2520       $owed = $cust_bill->owed;
2521     }
2522     unless ( $owed > 0 ) {
2523       push @credits, $credit;
2524       next;
2525     }
2526
2527     my $amount = min( $credit->credited, $owed );
2528
2529     my $cust_credit_bill = new FS::cust_credit_bill ( {
2530       'crednum' => $credit->crednum,
2531       'invnum'  => $cust_bill->invnum,
2532       'amount'  => $amount,
2533     } );
2534     $cust_credit_bill->pkgnum( $credit->pkgnum )
2535       if $conf->exists('pkg-balances') && $credit->pkgnum;
2536     my $error = $cust_credit_bill->insert;
2537     if ( $error ) {
2538       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2539       die $error;
2540     }
2541
2542     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2543
2544   }
2545
2546   my $total_unapplied_credits = $self->total_unapplied_credits;
2547
2548   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2549
2550   return $total_unapplied_credits;
2551 }
2552
2553 =item apply_payments  [ OPTION => VALUE ... ]
2554
2555 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2556 to outstanding invoice balances in chronological order.
2557 Payments with the no_auto_apply flag set will not be applied.
2558
2559  #and returns the value of any remaining unapplied payments.
2560
2561 A hash of optional arguments may be passed.  Currently "manual" is supported.
2562 If true, a payment receipt is sent instead of a statement when
2563 'payment_receipt_email' configuration option is set.
2564
2565 Dies if there is an error.
2566
2567 =cut
2568
2569 sub apply_payments {
2570   my( $self, %options ) = @_;
2571
2572   local $SIG{HUP} = 'IGNORE';
2573   local $SIG{INT} = 'IGNORE';
2574   local $SIG{QUIT} = 'IGNORE';
2575   local $SIG{TERM} = 'IGNORE';
2576   local $SIG{TSTP} = 'IGNORE';
2577   local $SIG{PIPE} = 'IGNORE';
2578
2579   my $oldAutoCommit = $FS::UID::AutoCommit;
2580   local $FS::UID::AutoCommit = 0;
2581   my $dbh = dbh;
2582
2583   $self->select_for_update; #mutex
2584
2585   #return 0 unless
2586
2587   my @payments = grep { !$_->no_auto_apply } $self->unapplied_cust_pay;
2588
2589   my @invoices = $self->open_cust_bill;
2590
2591   if ( $conf->exists('pkg-balances') ) {
2592     # limit @payments to those w/ a pkgnum grepped from $self
2593     my %pkgnums = ();
2594     foreach my $i (@invoices) {
2595       foreach my $li ( $i->cust_bill_pkg ) {
2596         $pkgnums{$li->pkgnum} = 1;
2597       }
2598     }
2599     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2600   }
2601
2602   my $payment;
2603
2604   foreach my $cust_bill ( @invoices ) {
2605
2606     if ( !defined($payment) || $payment->unapplied == 0 ) {
2607       $payment = pop @payments or last;
2608     }
2609
2610     my $owed;
2611     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2612       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2613     } else {
2614       $owed = $cust_bill->owed;
2615     }
2616     unless ( $owed > 0 ) {
2617       push @payments, $payment;
2618       next;
2619     }
2620
2621     my $amount = min( $payment->unapplied, $owed );
2622
2623     my $cbp = {
2624       'paynum' => $payment->paynum,
2625       'invnum' => $cust_bill->invnum,
2626       'amount' => $amount,
2627     };
2628     $cbp->{_date} = $payment->_date
2629         if $options{'manual'} && $options{'backdate_application'};
2630     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2631     $cust_bill_pay->pkgnum( $payment->pkgnum )
2632       if $conf->exists('pkg-balances') && $payment->pkgnum;
2633     my $error = $cust_bill_pay->insert(%options);
2634     if ( $error ) {
2635       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2636       die $error;
2637     }
2638
2639     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2640
2641   }
2642
2643   my $total_unapplied_payments = $self->total_unapplied_payments;
2644
2645   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2646
2647   return $total_unapplied_payments;
2648 }
2649
2650 =back
2651
2652 =head1 FLOW
2653
2654   bill_and_collect
2655
2656     cancel_expired_pkgs
2657     suspend_adjourned_pkgs
2658     unsuspend_resumed_pkgs
2659
2660     bill
2661       (do_cust_event pre-bill)
2662       _make_lines
2663         _handle_taxes
2664           (vendor-only) _gather_taxes
2665       _omit_zero_value_bundles
2666       _handle_taxes (for fees)
2667       calculate_taxes
2668
2669     apply_payments_and_credits
2670     collect
2671       do_cust_event
2672         due_cust_event
2673
2674 =head1 BUGS
2675
2676 =head1 SEE ALSO
2677
2678 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2679
2680 =cut
2681
2682 1;