FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use Tie::RefHash;
  12 use FS::cust_bill;
  13 use FS::cust_bill_pkg;
  14 use FS::cust_bill_pkg_display;
  15 use FS::cust_bill_pay;
  16 use FS::cust_credit_bill;
  17 use FS::cust_tax_adjustment;
  18 use FS::tax_rate;
  19 use FS::tax_rate_location;
  20 use FS::cust_bill_pkg_tax_location;
  21 use FS::cust_bill_pkg_tax_rate_location;
  22 use FS::part_event;
  23 use FS::part_event_condition;
  24 use FS::pkg_category;
  25 use FS::FeeOrigin_Mixin;
  26 use FS::Log;
  27
  28 # 1 is mostly method/subroutine entry and options
  29 # 2 traces progress of some operations
  30 # 3 is even more information including possibly sensitive data
  31 $DEBUG = 0;
  32 $me = '[FS::cust_main::Billing]';
  33
  34 install_callback FS::UID sub {
  35   $conf = new FS::Conf;
  36   #yes, need it for stuff below (prolly should be cached)
  37 };
  38
  39 =head1 NAME
  40
  41 FS::cust_main::Billing - Billing mixin for cust_main
  42
  43 =head1 SYNOPSIS
  44
  45 =head1 DESCRIPTION
  46
  47 These methods are available on FS::cust_main objects.
  48
  49 =head1 METHODS
  50
  51 =over 4
  52
  53 =item bill_and_collect
  54
  55 Cancels and suspends any packages due, generates bills, applies payments and
  56 credits, and applies collection events to run cards, send bills and notices,
  57 etc.
  58
  59 By default, warns on errors and continues with the next operation (but see the
  60 "fatal" flag below).
  61
  62 Options are passed as name-value pairs.  Currently available options are:
  63
  64 =over 4
  65
  66 =item time
  67
  68 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  69
  70  use Date::Parse;
  71  ...
  72  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  73
  74 =item invoice_time
  75
  76 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  77
  78 =item check_freq
  79
  80 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  81
  82 =item resetup
  83
  84 If set true, re-charges setup fees.
  85
  86 =item fatal
  87
  88 If set any errors prevent subsequent operations from continusing.  If set
  89 specifically to "return", returns the error (or false, if there is no error).
  90 Any other true value causes errors to die.
  91
  92 =item debug
  93
  94 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  95
  96 =item job
  97
  98 Optional FS::queue entry to receive status updates.
  99
 100 =back
 101
 102 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 103 options of those methods are also available.
 104
 105 =cut
 106
 107 sub bill_and_collect {
 108   my( $self, %options ) = @_;
 109
 110   my $log = FS::Log->new('FS::cust_main::Billing::bill_and_collect');
 111   my %logopt = (object => $self);
 112   $log->debug('start', %logopt);
 113
 114   my $error;
 115
 116   #$options{actual_time} not $options{time} because freeside-daily -d is for
 117   #pre-printing invoices
 118
 119   $options{'actual_time'} ||= time;
 120   my $job = $options{'job'};
 121
 122   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 123                         ? day_end( $options{actual_time} )
 124                         : $options{actual_time}
 125                     );
 126
 127   $job->update_statustext('0,cleaning expired packages') if $job;
 128   $log->debug('canceling expired packages', %logopt);
 129   $error = $self->cancel_expired_pkgs( $actual_time );
 130   if ( $error ) {
 131     $error = "Error expiring custnum ". $self->custnum. ": $error";
 132     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 133     elsif ( $options{fatal}                                ) { die    $error; }
 134     else                                                     { warn   $error; }
 135   }
 136
 137   $log->debug('suspending adjourned packages', %logopt);
 138   $error = $self->suspend_adjourned_pkgs( $actual_time );
 139   if ( $error ) {
 140     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 141     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 142     elsif ( $options{fatal}                                ) { die    $error; }
 143     else                                                     { warn   $error; }
 144   }
 145
 146   $log->debug('unsuspending resumed packages', %logopt);
 147   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 148   if ( $error ) {
 149     $error = "Error resuming custnum ".$self->custnum. ": $error";
 150     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 151     elsif ( $options{fatal}                                ) { die    $error; }
 152     else                                                     { warn   $error; }
 153   }
 154
 155   $job->update_statustext('20,billing packages') if $job;
 156   $log->debug('billing packages', %logopt);
 157   $error = $self->bill( %options );
 158   if ( $error ) {
 159     $error = "Error billing custnum ". $self->custnum. ": $error";
 160     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 161     elsif ( $options{fatal}                                ) { die    $error; }
 162     else                                                     { warn   $error; }
 163   }
 164
 165   $job->update_statustext('50,applying payments and credits') if $job;
 166   $log->debug('applying payments and credits', %logopt);
 167   $error = $self->apply_payments_and_credits;
 168   if ( $error ) {
 169     $error = "Error applying custnum ". $self->custnum. ": $error";
 170     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 171     elsif ( $options{fatal}                                ) { die    $error; }
 172     else                                                     { warn   $error; }
 173   }
 174
 175   unless ( $conf->exists('cancelled_cust-noevents')
 176            && ! $self->num_ncancelled_pkgs
 177   ) {
 178     $job->update_statustext('70,running collection events') if $job;
 179     $log->debug('running collection events', %logopt);
 180     $error = $self->collect( %options );
 181     if ( $error ) {
 182       $error = "Error collecting custnum ". $self->custnum. ": $error";
 183       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 184       elsif ($options{fatal}                               ) { die    $error; }
 185       else                                                   { warn   $error; }
 186     }
 187   }
 188
 189   $job->update_statustext('100,finished') if $job;
 190   $log->debug('finish', %logopt);
 191
 192   '';
 193
 194 }
 195
 196 sub cancel_expired_pkgs {
 197   my ( $self, $time, %options ) = @_;
 198
 199   my @cancel_pkgs = $self->ncancelled_pkgs( {
 200     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 201   } );
 202
 203   my @errors = ();
 204
 205   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 206     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 207     my $error;
 208
 209     if ( $cust_pkg->change_to_pkgnum ) {
 210
 211       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 212       if ( !$new_pkg ) {
 213         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 214                       $cust_pkg->change_to_pkgnum.'; not expiring';
 215         next CUST_PKG;
 216       }
 217       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 218                                   'unprotect_svcs'  => 1 );
 219       $error = '' if ref $error eq 'FS::cust_pkg';
 220
 221     } else { # just cancel it
 222        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 223                                            'reason_otaker' => $cpr->otaker,
 224                                            'time'          => $time,
 225                                          )
 226                                        : ()
 227                                  );
 228     }
 229     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 230   }
 231
 232   join(' / ', @errors);
 233
 234 }
 235
 236 sub suspend_adjourned_pkgs {
 237   my ( $self, $time, %options ) = @_;
 238
 239   my @susp_pkgs = $self->ncancelled_pkgs( {
 240     'extra_sql' =>
 241       " AND ( susp IS NULL OR susp = 0 )
 242         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 243               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 244             )
 245       ",
 246   } );
 247
 248   #only because there's no SQL test for is_prepaid :/
 249   @susp_pkgs =
 250     grep {     (    $_->part_pkg->is_prepaid
 251                  && $_->bill
 252                  && $_->bill < $time
 253                )
 254             || (    $_->adjourn
 255                  && $_->adjourn <= $time
 256                )
 257
 258          }
 259          @susp_pkgs;
 260
 261   my @errors = ();
 262
 263   foreach my $cust_pkg ( @susp_pkgs ) {
 264     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 265       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 266     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 267                                             'reason_otaker' => $cpr->otaker
 268                                           )
 269                                         : ()
 270                                   );
 271     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 272   }
 273
 274   join(' / ', @errors);
 275
 276 }
 277
 278 sub unsuspend_resumed_pkgs {
 279   my ( $self, $time, %options ) = @_;
 280
 281   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 282     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 283   } );
 284
 285   my @errors = ();
 286
 287   foreach my $cust_pkg ( @unsusp_pkgs ) {
 288     my $error = $cust_pkg->unsuspend( 'time' => $time );
 289     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 290   }
 291
 292   join(' / ', @errors);
 293
 294 }
 295
 296 =item bill OPTIONS
 297
 298 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 299 conjunction with the collect method by calling B<bill_and_collect>.
 300
 301 If there is an error, returns the error, otherwise returns false.
 302
 303 Options are passed as name-value pairs.  Currently available options are:
 304
 305 =over 4
 306
 307 =item resetup
 308
 309 If set true, re-charges setup fees.
 310
 311 =item recurring_only
 312
 313 If set true then only bill recurring charges, not setup, usage, one time
 314 charges, etc.
 315
 316 =item freq_override
 317
 318 If set, then override the normal frequency and look for a part_pkg_discount
 319 to take at that frequency.  This is appropriate only when the normal
 320 frequency for all packages is monthly, and is an error otherwise.  Use
 321 C<pkg_list> to limit the set of packages included in billing.
 322
 323 =item time
 324
 325 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 326
 327  use Date::Parse;
 328  ...
 329  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 330
 331 =item pkg_list
 332
 333 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 334
 335  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 336
 337 =item not_pkgpart
 338
 339 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 340
 341 =item no_prepaid
 342
 343 Do not bill prepaid packages.  Used by freeside-daily.
 344
 345 =item invoice_time
 346
 347 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 348
 349 =item cancel
 350
 351 This boolean value informs the us that the package is being cancelled.  This
 352 typically might mean not charging the normal recurring fee but only usage
 353 fees since the last billing. Setup charges may be charged.  Not all package
 354 plans support this feature (they tend to charge 0).
 355
 356 =item no_usage_reset
 357
 358 Prevent the resetting of usage limits during this call.
 359
 360 =item no_commit
 361
 362 Do not save the generated bill in the database.  Useful with return_bill
 363
 364 =item return_bill
 365
 366 A list reference on which the generated bill(s) will be returned.
 367
 368 =item invoice_terms
 369
 370 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 371 terms or the default terms are used.
 372
 373 =back
 374
 375 =cut
 376
 377 sub bill {
 378   my( $self, %options ) = @_;
 379
 380   return '' if $self->payby eq 'COMP';
 381
 382   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 383   my $log = FS::Log->new('FS::cust_main::Billing::bill');
 384   my %logopt = (object => $self);
 385
 386   $log->debug('start', %logopt);
 387   warn "$me bill customer ". $self->custnum. "\n"
 388     if $DEBUG;
 389
 390   my $time = $options{'time'} || time;
 391   my $invoice_time = $options{'invoice_time'} || $time;
 392
 393   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 394                      ? day_end( $time )
 395                      : $time
 396                  );
 397
 398   $options{'not_pkgpart'} ||= {};
 399   $options{'not_pkgpart'} = { map { $_ => 1 }
 400                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 401                             }
 402     unless ref($options{'not_pkgpart'});
 403
 404   local $SIG{HUP} = 'IGNORE';
 405   local $SIG{INT} = 'IGNORE';
 406   local $SIG{QUIT} = 'IGNORE';
 407   local $SIG{TERM} = 'IGNORE';
 408   local $SIG{TSTP} = 'IGNORE';
 409   local $SIG{PIPE} = 'IGNORE';
 410
 411   my $oldAutoCommit = $FS::UID::AutoCommit;
 412   local $FS::UID::AutoCommit = 0;
 413   my $dbh = dbh;
 414
 415   $log->debug('acquiring lock', %logopt);
 416   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 417     if $DEBUG;
 418
 419   $self->select_for_update; #mutex
 420
 421   $log->debug('running pre-bill events', %logopt);
 422   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 423     if $DEBUG;
 424
 425   my $error = $self->do_cust_event(
 426     'debug'      => ( $options{'debug'} || 0 ),
 427     'time'       => $invoice_time,
 428     'check_freq' => $options{'check_freq'},
 429     'stage'      => 'pre-bill',
 430   )
 431     unless $options{no_commit};
 432   if ( $error ) {
 433     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 434     return $error;
 435   }
 436
 437   $log->debug('done running pre-bill events', %logopt);
 438   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 439     if $DEBUG;
 440
 441   #keep auto-charge and non-auto-charge line items separate
 442   my @passes = ( '', 'no_auto' );
 443
 444   my %cust_bill_pkg = map { $_ => [] } @passes;
 445
 446   ###
 447   # find the packages which are due for billing, find out how much they are
 448   # & generate invoice database.
 449   ###
 450
 451   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 452   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 453
 454   my %taxlisthash = map { $_ => {} } @passes;
 455
 456   my @precommit_hooks = ();
 457
 458   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 459
 460   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 461
 462     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 463
 464     my $part_pkg = $cust_pkg->part_pkg;
 465
 466     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 467
 468     $log->debug('bill package '. $cust_pkg->pkgnum, %logopt);
 469     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 470
 471     #? to avoid use of uninitialized value errors... ?
 472     $cust_pkg->setfield('bill', '')
 473       unless defined($cust_pkg->bill);
 474
 475     my $real_pkgpart = $cust_pkg->pkgpart;
 476     my %hash = $cust_pkg->hash;
 477
 478     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 479     # suffer from performance issues
 480     $options{has_hidden} = 0;
 481     my @part_pkg = $part_pkg->self_and_bill_linked;
 482     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 483
 484     # if this package was changed from another package,
 485     # and it hasn't been billed since then,
 486     # and package balances are enabled,
 487     if ( $cust_pkg->change_pkgnum
 488         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 489         and $cust_pkg->change_date <  $invoice_time
 490       and $conf->exists('pkg-balances') )
 491     {
 492       # _transfer_balance will also create the appropriate credit
 493       my @transfer_items = $self->_transfer_balance($cust_pkg);
 494       # $part_pkg[0] is the "real" part_pkg
 495       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 496                   'no_auto' : '';
 497       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 498       # treating this as recur, just because most charges are recur...
 499       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 500
 501       # currently not considering separate_bill here, as it's for
 502       # one-time charges only
 503     }
 504
 505     foreach my $part_pkg ( @part_pkg ) {
 506
 507       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 508
 509       my $pass = '';
 510       if ( $cust_pkg->separate_bill ) {
 511         # if no_auto is also set, that's fine. we just need to not have
 512         # invoices that are both auto and no_auto, and since the package
 513         # gets an invoice all to itself, it will only be one or the other.
 514         $pass = $cust_pkg->pkgnum;
 515         if (!exists $cust_bill_pkg{$pass}) { # it may not exist yet
 516           push @passes, $pass;
 517           $total_setup{$pass} = do { my $z = 0; \$z };
 518           $total_recur{$pass} = do { my $z = 0; \$z };
 519           $taxlisthash{$pass} = {};
 520           $cust_bill_pkg{$pass} = [];
 521         }
 522       } elsif ( ($cust_pkg->no_auto || $part_pkg->no_auto) ) {
 523         $pass = 'no_auto';
 524       }
 525
 526       my $next_bill = $cust_pkg->getfield('bill') || 0;
 527       my $error;
 528       # let this run once if this is the last bill upon cancellation
 529       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 530         $error =
 531           $self->_make_lines( 'part_pkg'            => $part_pkg,
 532                               'cust_pkg'            => $cust_pkg,
 533                               'precommit_hooks'     => \@precommit_hooks,
 534                               'line_items'          => $cust_bill_pkg{$pass},
 535                               'setup'               => $total_setup{$pass},
 536                               'recur'               => $total_recur{$pass},
 537                               'tax_matrix'          => $taxlisthash{$pass},
 538                               'time'                => $time,
 539                               'real_pkgpart'        => $real_pkgpart,
 540                               'options'             => \%options,
 541                             );
 542
 543         # Stop if anything goes wrong
 544         last if $error;
 545
 546         # or if we're not incrementing the bill date.
 547         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 548
 549         # or if we're letting it run only once
 550         last if $options{cancel};
 551
 552         $next_bill = $cust_pkg->getfield('bill') || 0;
 553
 554         #stop if -o was passed to freeside-daily
 555         last if $options{'one_recur'};
 556       }
 557       if ($error) {
 558         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 559         return $error;
 560       }
 561
 562     } #foreach my $part_pkg
 563
 564   } #foreach my $cust_pkg
 565
 566   foreach my $pass (@passes) { # keys %cust_bill_pkg )
 567
 568     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 569
 570     warn "$me billing pass $pass\n"
 571            #.Dumper(\@cust_bill_pkg)."\n"
 572       if $DEBUG > 2;
 573
 574     ###
 575     # process fees
 576     ###
 577
 578     my @pending_fees = FS::FeeOrigin_Mixin->by_cust($self->custnum,
 579       hashref => { 'billpkgnum' => '' }
 580     );
 581     warn "$me found pending fees:\n".Dumper(\@pending_fees)."\n"
 582       if @pending_fees and $DEBUG > 1;
 583
 584     # determine whether to generate an invoice
 585     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 586
 587     foreach my $fee (@pending_fees) {
 588       $generate_bill = 1 unless $fee->nextbill;
 589     }
 590
 591     # don't create an invoice with no line items, or where the only line
 592     # items are fees that are supposed to be held until the next invoice
 593     next if !$generate_bill;
 594
 595     # calculate fees...
 596     my @fee_items;
 597     foreach my $fee_origin (@pending_fees) {
 598       my $part_fee = $fee_origin->part_fee;
 599
 600       # check whether the fee is applicable before doing anything expensive:
 601       #
 602       # if the fee def belongs to a different agent, don't charge the fee.
 603       # event conditions should prevent this, but just in case they don't,
 604       # skip the fee.
 605       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 606         warn "tried to charge fee#".$part_fee->feepart .
 607              " on customer#".$self->custnum." from a different agent.\n";
 608         next;
 609       }
 610       # also skip if it's disabled
 611       next if $part_fee->disabled eq 'Y';
 612
 613       # Decide which invoice to base the fee on.
 614       my $cust_bill = $fee_origin->cust_bill;
 615       if (!$cust_bill) {
 616         # Then link it to the current invoice. This isn't the real cust_bill
 617         # object that will be inserted--in particular there are no taxes yet.
 618         # If you want to charge a fee on the total invoice amount including
 619         # taxes, you have to put the fee on the next invoice.
 620         $cust_bill = FS::cust_bill->new({
 621             'custnum'       => $self->custnum,
 622             'cust_bill_pkg' => \@cust_bill_pkg,
 623             'charged'       => ${ $total_setup{$pass} } +
 624                                ${ $total_recur{$pass} },
 625         });
 626
 627         # If the origin is for a specific package, then only apply the fee to
 628         # line items from that package.
 629         if ( my $cust_pkg = $fee_origin->cust_pkg ) {
 630           my @charge_fee_on_item;
 631           my $charge_fee_on_amount = 0;
 632           foreach (@cust_bill_pkg) {
 633             if ($_->pkgnum == $cust_pkg->pkgnum) {
 634               push @charge_fee_on_item, $_;
 635               $charge_fee_on_amount += $_->setup + $_->recur;
 636             }
 637           }
 638           $cust_bill->set('cust_bill_pkg', \@charge_fee_on_item);
 639           $cust_bill->set('charged', $charge_fee_on_amount);
 640         }
 641
 642       } # $cust_bill is now set
 643       # calculate the fee
 644       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 645       # link this so that we can clear the marker on inserting the line item
 646       $fee_item->set('fee_origin', $fee_origin);
 647       push @fee_items, $fee_item;
 648
 649     }
 650
 651     # add fees to the invoice
 652     foreach my $fee_item (@fee_items) {
 653
 654       push @cust_bill_pkg, $fee_item;
 655       ${ $total_setup{$pass} } += $fee_item->setup;
 656       ${ $total_recur{$pass} } += $fee_item->recur;
 657
 658       my $part_fee = $fee_item->part_fee;
 659       my $fee_location = $self->ship_location; # I think?
 660
 661       my $error = $self->_handle_taxes(
 662         $taxlisthash{$pass},
 663         $fee_item,
 664         location => $fee_location
 665         # probably not right to pass cancel => 1 for fees
 666       );
 667       return $error if $error;
 668
 669     }
 670
 671     # XXX implementation of fees is supposed to make this go away...
 672     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 673            !$conf->exists('postal_invoice-recurring_only')
 674        )
 675     {
 676
 677       my $postal_pkg = $self->charge_postal_fee();
 678       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 679
 680         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 681         return "can't charge postal invoice fee for customer ".
 682           $self->custnum. ": $postal_pkg";
 683
 684       } elsif ( $postal_pkg ) {
 685
 686         my $real_pkgpart = $postal_pkg->pkgpart;
 687         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 688         # suffer from performance issues
 689         $options{has_hidden} = 0;
 690         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 691         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 692
 693         foreach my $part_pkg ( @part_pkg ) {
 694           my %postal_options = %options;
 695           delete $postal_options{cancel};
 696           my $error =
 697             $self->_make_lines( 'part_pkg'            => $part_pkg,
 698                                 'cust_pkg'            => $postal_pkg,
 699                                 'precommit_hooks'     => \@precommit_hooks,
 700                                 'line_items'          => \@cust_bill_pkg,
 701                                 'setup'               => $total_setup{$pass},
 702                                 'recur'               => $total_recur{$pass},
 703                                 'tax_matrix'          => $taxlisthash{$pass},
 704                                 'time'                => $time,
 705                                 'real_pkgpart'        => $real_pkgpart,
 706                                 'options'             => \%postal_options,
 707                               );
 708           if ($error) {
 709             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 710             return $error;
 711           }
 712         }
 713
 714         # it's silly to have a zero value postal_pkg, but....
 715         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 716
 717       }
 718
 719     }
 720
 721     my $listref_or_error =
 722       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 723
 724     unless ( ref( $listref_or_error ) ) {
 725       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 726       return $listref_or_error;
 727     }
 728
 729     foreach my $taxline ( @$listref_or_error ) {
 730       ${ $total_setup{$pass} } =
 731         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 732       push @cust_bill_pkg, $taxline;
 733     }
 734
 735     #add tax adjustments
 736     warn "adding tax adjustments...\n" if $DEBUG > 2;
 737     foreach my $cust_tax_adjustment (
 738       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 739                                        'billpkgnum' => '',
 740                                      }
 741              )
 742     ) {
 743
 744       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 745
 746       my $itemdesc = $cust_tax_adjustment->taxname;
 747       $itemdesc = '' if $itemdesc eq 'Tax';
 748
 749       push @cust_bill_pkg, new FS::cust_bill_pkg {
 750         'pkgnum'      => 0,
 751         'setup'       => $tax,
 752         'recur'       => 0,
 753         'sdate'       => '',
 754         'edate'       => '',
 755         'itemdesc'    => $itemdesc,
 756         'itemcomment' => $cust_tax_adjustment->comment,
 757         'cust_tax_adjustment' => $cust_tax_adjustment,
 758         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 759       };
 760
 761     }
 762
 763     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 764
 765     my $balance = $self->balance;
 766
 767     my $previous_bill = qsearchs({ 'table'     => 'cust_bill',
 768                                    'hashref'   => { custnum=>$self->custnum },
 769                                    'extra_sql' => 'ORDER BY _date DESC LIMIT 1',
 770                                 });
 771     my $previous_balance =
 772       $previous_bill
 773         ? ( $previous_bill->billing_balance + $previous_bill->charged )
 774         : 0;
 775
 776     $log->debug('creating the new invoice', %logopt);
 777     warn "creating the new invoice\n" if $DEBUG;
 778     #create the new invoice
 779     my $cust_bill = new FS::cust_bill ( {
 780       'custnum'             => $self->custnum,
 781       '_date'               => $invoice_time,
 782       'charged'             => $charged,
 783       'billing_balance'     => $balance,
 784       'previous_balance'    => $previous_balance,
 785       'invoice_terms'       => $options{'invoice_terms'},
 786       'cust_bill_pkg'       => \@cust_bill_pkg,
 787     } );
 788     $error = $cust_bill->insert unless $options{no_commit};
 789     if ( $error ) {
 790       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 791       return "can't create invoice for customer #". $self->custnum. ": $error";
 792     }
 793     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 794
 795   } #foreach my $pass ( keys %cust_bill_pkg )
 796
 797   foreach my $hook ( @precommit_hooks ) {
 798     eval {
 799       &{$hook}; #($self) ?
 800     } unless $options{no_commit};
 801     if ( $@ ) {
 802       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 803       return "$@ running precommit hook $hook\n";
 804     }
 805   }
 806
 807   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 808
 809   ''; #no error
 810 }
 811
 812 #discard bundled packages of 0 value
 813 sub _omit_zero_value_bundles {
 814   my @in = @_;
 815
 816   my @cust_bill_pkg = ();
 817   my @cust_bill_pkg_bundle = ();
 818   my $sum = 0;
 819   my $discount_show_always = 0;
 820
 821   foreach my $cust_bill_pkg ( @in ) {
 822
 823     $discount_show_always = ($cust_bill_pkg->get('discounts')
 824                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 825                                 && $conf->exists('discount-show-always'));
 826
 827     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 828          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 829          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 830       if $DEBUG > 0;
 831
 832     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 833       push @cust_bill_pkg, @cust_bill_pkg_bundle
 834         if $sum > 0
 835         || ($sum == 0 && (    $discount_show_always
 836                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 837                                    @cust_bill_pkg_bundle
 838                          )
 839            );
 840       @cust_bill_pkg_bundle = ();
 841       $sum = 0;
 842     }
 843
 844     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 845     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 846
 847   }
 848
 849   push @cust_bill_pkg, @cust_bill_pkg_bundle
 850     if $sum > 0
 851     || ($sum == 0 && (    $discount_show_always
 852                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 853                                @cust_bill_pkg_bundle
 854                      )
 855        );
 856
 857   warn "  _omit_zero_value_bundles: ". scalar(@in).
 858        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 859     if $DEBUG > 2;
 860
 861   (@cust_bill_pkg);
 862
 863 }
 864
 865 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 866
 867 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 868 Usually used internally by bill method B<bill>.
 869
 870 If there is an error, returns the error, otherwise returns reference to a
 871 list of line items suitable for insertion.
 872
 873 =over 4
 874
 875 =item LINEITEMREF
 876
 877 An array ref of the line items being billed.
 878
 879 =item TAXHASHREF
 880
 881 A strange beast.  The keys to this hash are internal identifiers consisting
 882 of the name of the tax object type, a space, and its unique identifier ( e.g.
 883  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 884 item in the list is the tax object.  The remaining items are either line
 885 items or floating point values (currency amounts).
 886
 887 The taxes are calculated on this entity.  Calculated exemption records are
 888 transferred to the LINEITEMREF items on the assumption that they are related.
 889
 890 Read the source.
 891
 892 =item INVOICE_TIME
 893
 894 This specifies the date appearing on the associated invoice.  Some
 895 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 896
 897 =back
 898
 899 =cut
 900
 901 sub calculate_taxes {
 902   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 903
 904   # $taxlisthash is a hashref
 905   # keys are identifiers, values are arrayrefs
 906   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 907   # then a cust_bill_pkg object the tax applies to, then the charge class
 908   # on that object (setup, recur, a usage class number, or '')
 909   # For internal taxes the charge class is always undef.
 910
 911   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 912
 913   warn "$me calculate_taxes\n"
 914        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 915     if $DEBUG > 2;
 916
 917   my $custnum = $self->custnum;
 918   # The main tax accumulator.  One bin for each tax name (itemdesc).
 919   # For each subdivision of tax under this name, push a cust_bill_pkg item
 920   # for the calculated tax into the arrayref.
 921   # keys are tax names
 922   # values are arrayrefs of tax lines
 923   my %taxname = ();
 924
 925   # keys are taxlisthash keys (internal identifiers)
 926   # values are (cumulative) amounts
 927   my %tax_amount = ();
 928
 929   # keys are taxlisthash keys
 930   # values are arrayrefs of cust_tax_exempt_pkg objects
 931   my %tax_exemption;
 932
 933   # For tax on tax calculation, we need to remember which taxable items
 934   # (and charge classes) had which taxes applied to them.
 935   #
 936   # keys are cust_bill_pkg objects (taxable items)
 937   # values are hashrefs
 938   #   keys are charge classes
 939   #   values are hashrefs
 940   #     keys are taxnums (in tax_rate only; cust_main_county doesn't use this)
 941   #     values are the taxlines generated for those taxes
 942   tie my %item_has_tax, 'Tie::RefHash',
 943     map { $_ => {} } @$cust_bill_pkg;
 944
 945   foreach my $tax_id ( keys %$taxlisthash ) {
 946     # $tax_id: the identifier of the tax we are calculating in this pass
 947
 948     my $taxables = $taxlisthash->{$tax_id};
 949     my $tax_object = shift @$taxables;
 950     my $taxnum = $tax_object->taxnum;
 951     # $tax_object is a cust_main_county or tax_rate
 952     # (with billpkgnum, pkgnum, locationnum set)
 953     # the rest of @{ $taxlisthash->{$tax_id} } is cust_bill_pkg objects,
 954     # optionally followed by their charge classes.
 955     warn "found ". $tax_object->taxname. " as $tax_id\n" if $DEBUG > 2;
 956
 957     # taxline calculates the tax on all cust_bill_pkgs in the
 958     # first (arrayref) argument.
 959     #
 960     # Note that non-monthly exemptions have already been calculated and
 961     # attached to the items.  Monthly exemptions will be attached in this
 962     # step.
 963     my $exemptions = $tax_exemption{$tax_id} ||= [];
 964     if ( $tax_object->isa('FS::tax_rate') ) { # EXTERNAL TAXES
 965       # STILL have tax_rate-specific crap in here...
 966       my @taxlines = $tax_object->taxline( $taxables,
 967                               'custnum'      => $custnum,
 968                               'invoice_time' => $invoice_time,
 969                               'exemptions'   => $exemptions,
 970                               );
 971       next if !@taxlines;
 972       if (!ref $taxlines[0]) {
 973         # it's an error string
 974         warn "error evaluating $tax_id on custnum $custnum\n";
 975         return $taxlines[0];
 976       }
 977       foreach my $taxline (@taxlines) {
 978         push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 979         my $link = $taxline->get('cust_bill_pkg_tax_rate_location')->[0];
 980         my $taxable_item = $link->taxable_cust_bill_pkg;
 981         $item_has_tax{$taxable_item}{$taxline->_class}{$taxnum} = $taxline;
 982       }
 983
 984     } else { # INTERNAL TAXES
 985       # we can do this in a single taxline, because it's not stupid
 986
 987       my $taxline =  $tax_object->taxline( $taxables,
 988                         'custnum'      => $custnum,
 989                         'invoice_time' => $invoice_time,
 990                         'exemptions'   => $exemptions,
 991                       );
 992       next if !$taxline;
 993       if (!ref $taxline) {
 994         # it's an error string
 995         warn "error evaluating $tax_id on custnum $custnum\n";
 996         return $taxline;
 997       }
 998       # if the calculated tax is zero, don't even keep it
 999       next if $taxline->setup < 0.001;
1000       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1001     }
1002   }
1003   $DB::single = 1; # XXX
1004
1005   # all first-tier taxes are calculated.  now for tax on tax:
1006
1007   foreach my $taxable_item ( @$cust_bill_pkg ) {
1008     # taxes that apply to this item
1009     my $this_has_tax = $item_has_tax{$taxable_item};
1010
1011     my $location = $taxable_item->tax_location;
1012
1013     foreach my $charge_class (keys %$this_has_tax) {
1014       # taxes that apply to this item and charge class
1015       my $this_class_has_tax = $this_has_tax->{$charge_class};
1016       foreach my $taxnum (keys %$this_class_has_tax) {
1017
1018         # for each tax item that was calculated in phase 1, get the
1019         # tax definition
1020         my $tax_object = FS::tax_rate->by_key($taxnum);
1021         # and find all taxes that apply to it in this location
1022         my @tot = $tax_object->tax_on_tax( $location );
1023         next if !@tot;
1024         warn "found possible taxed taxnum $taxnum\n"
1025           if $DEBUG > 2;
1026         # Calculate ToT separately for each taxable item and class, and only
1027         # if _that class on the item_ is already taxed under the ToT.  This is
1028         # counterintuitive.
1029         # See RT#5243 and RT#36380.
1030         foreach my $tot (@tot) {
1031           my $totnum = $tot->taxnum;
1032           warn "checking taxnum $totnum which we call ". $tot->taxname ."\n"
1033             if $DEBUG > 2;
1034           # note: if the _null class_ on this item is taxed under the ToT,
1035           # then this specific class is taxed also (because null class
1036           # includes all classes) and so ToT is applicable.
1037           if (
1038                 exists $this_class_has_tax->{ $totnum }
1039              or exists $this_has_tax->{''}{ $totnum }
1040           ) {
1041
1042             warn "calculating tax on tax: taxnum $totnum on $taxnum\n"
1043               if $DEBUG;
1044             my @taxlines = $tot->taxline(
1045                               $this_class_has_tax->{ $taxnum }, # the first-stage tax
1046                               'custnum'       => $custnum,
1047                               'invoice_time'  => $invoice_time,
1048                              );
1049             next if (!@taxlines); # it didn't apply after all
1050             if (!ref($taxlines[0])) {
1051               warn "error evaluating taxnum $totnum TOT on custnum $custnum\n";
1052               return $taxlines[0];
1053             }
1054             foreach my $taxline (@taxlines) {
1055               push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1056             }
1057           } # if $has_tax
1058         } # foreach my $tot (tax-on-tax rate definition)
1059       } # foreach $taxnum (first-tier rate definition)
1060     } # foreach $charge_class
1061   } # foreach $taxable_item
1062
1063   #consolidate and create tax line items
1064   warn "consolidating and generating...\n" if $DEBUG > 2;
1065   my %final_tax_items; # taxname => item
1066   foreach my $taxname ( keys %taxname ) {
1067     my @cust_bill_pkg_tax_location;
1068     my @cust_bill_pkg_tax_rate_location;
1069     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
1070         'pkgnum'    => 0,
1071         'recur'     => 0,
1072         'sdate'     => '',
1073         'edate'     => '',
1074         'itemdesc'  => $taxname,
1075         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
1076         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
1077     });
1078
1079     my $tax_total = 0;
1080     my %seen = ();
1081     warn "adding $taxname\n" if $DEBUG > 1;
1082     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
1083       next if $taxitem->get('setup') == 0;
1084       # if ( ref($taxitem) eq 'FS::cust_bill_pkg' )  # always true
1085       # then we need to transfer the amount and the links from the
1086       # line item to the new one we're creating.
1087       $tax_total += $taxitem->setup;
1088       my @links = @{
1089         $taxitem->get('cust_bill_pkg_tax_location') ||
1090         $taxitem->get('cust_bill_pkg_tax_rate_location') ||
1091         []
1092       };
1093       foreach my $link ( @links ) {
1094         $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
1095         if ($link->isa('FS::cust_bill_pkg_tax_location')) {
1096           push @cust_bill_pkg_tax_location, $link;
1097         } elsif ($link->isa('FS::cust_bill_pkg_tax_rate_location')) {
1098           push @cust_bill_pkg_tax_rate_location, $link;
1099         }
1100       }
1101     }
1102     next unless $tax_total;
1103
1104     # we should really neverround this up...I guess it's okay if taxline
1105     # already returns amounts with 2 decimal places
1106     $tax_total = sprintf('%.2f', $tax_total );
1107     $tax_cust_bill_pkg->set('setup', $tax_total);
1108
1109     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1110                                                    'disabled'     => '',
1111                                                  },
1112                                );
1113
1114     my @display = ();
1115     if ( $pkg_category and
1116          $conf->config('invoice_latexsummary') ||
1117          $conf->config('invoice_htmlsummary')
1118        )
1119     {
1120
1121       my %hash = (  'section' => $pkg_category->categoryname );
1122       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1123
1124     }
1125     $tax_cust_bill_pkg->set('display', \@display);
1126
1127     $final_tax_items{$taxname} = $tax_cust_bill_pkg;
1128   } # foreach $taxname
1129
1130   # fix ToT backlinks for taxes that have been consolidated
1131   # (has to be done in a separate pass)
1132   foreach my $tax_item (values %final_tax_items) {
1133     foreach my $taxable_link (@{ $tax_item->cust_bill_pkg_tax_rate_location }) {
1134       my $taxed_item = $taxable_link->taxable_cust_bill_pkg;
1135       next if $taxed_item->pkgnum > 0; # primary taxes
1136       my $taxname = $taxed_item->itemdesc;
1137       $taxable_link->set('taxable_cust_bill_pkg', $final_tax_items{ $taxname });
1138     }
1139   }
1140
1141   [ values %final_tax_items ]
1142 }
1143
1144 sub _make_lines {
1145   my ($self, %params) = @_;
1146
1147   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1148
1149   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1150   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1151   my $cust_location = $cust_pkg->tax_location;
1152   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1153   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1154   my $total_setup = $params{setup} or die "no setup accumulator specified";
1155   my $total_recur = $params{recur} or die "no recur accumulator specified";
1156   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1157   my $time = $params{'time'} or die "no time specified";
1158   my (%options) = %{$params{options}};
1159
1160   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1161     # this should never happen
1162     die 'freq_override billing attempted on non-monthly package '.
1163       $cust_pkg->pkgnum;
1164   }
1165
1166   my $dbh = dbh;
1167   my $real_pkgpart = $params{real_pkgpart};
1168   my %hash = $cust_pkg->hash;
1169   my $old_cust_pkg = new FS::cust_pkg \%hash;
1170
1171   my @details = ();
1172   my $lineitems = 0;
1173
1174   $cust_pkg->pkgpart($part_pkg->pkgpart);
1175
1176   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1177                      ? day_end( $time )
1178                      : $time
1179                  );
1180
1181   ###
1182   # bill setup
1183   ###
1184
1185   my $setup = 0;
1186   my $unitsetup = 0;
1187   my @setup_discounts = ();
1188   my %setup_param = ( 'discounts'    => \@setup_discounts,
1189                       'real_pkgpart' => $params{real_pkgpart}
1190                     );
1191   # Conditions for setting setup date and charging the setup fee:
1192   # - this is not a recurring-only billing run
1193   # - and the package is not currently being canceled
1194   # - and, unless we're specifically told otherwise via 'resetup':
1195   #   - it doesn't already HAVE a setup date
1196   #   - or a start date in the future
1197   #   - and it's not suspended
1198   #
1199   # The last condition used to check the "disable_setup_suspended" option but
1200   # that's obsolete. We now never set the setup date on a suspended package.
1201   if (     ! $options{recurring_only}
1202        and ! $options{cancel}
1203        and ( $options{'resetup'}
1204              || ( ! $cust_pkg->setup
1205                   && ( ! $cust_pkg->start_date
1206                        || $cust_pkg->start_date <= $cmp_time
1207                      )
1208                   && ( ! $cust_pkg->getfield('susp') )
1209               )
1210            )
1211      )
1212   {
1213
1214     warn "    bill setup\n" if $DEBUG > 1;
1215
1216     unless ( $cust_pkg->waive_setup ) {
1217         $lineitems++;
1218
1219         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1220         return "$@ running calc_setup for $cust_pkg\n"
1221           if $@;
1222
1223         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
1224     }
1225
1226     $cust_pkg->setfield('setup', $time)
1227       unless $cust_pkg->setup;
1228           #do need it, but it won't get written to the db
1229           #|| $cust_pkg->pkgpart != $real_pkgpart;
1230
1231     $cust_pkg->setfield('start_date', '')
1232       if $cust_pkg->start_date;
1233
1234   }
1235
1236   ###
1237   # bill recurring fee
1238   ###
1239
1240   my $recur = 0;
1241   my $unitrecur = 0;
1242   my @recur_discounts = ();
1243   my $sdate;
1244   if (     ! $cust_pkg->start_date
1245        and
1246            ( ! $cust_pkg->susp
1247                || ( $cust_pkg->susp != $cust_pkg->order_date
1248                       && (    $cust_pkg->option('suspend_bill',1)
1249                            || ( $part_pkg->option('suspend_bill', 1)
1250                                  && ! $cust_pkg->option('no_suspend_bill',1)
1251                               )
1252                          )
1253                   )
1254                || $cust_pkg->is_status_delay_cancel
1255            )
1256        and
1257             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1258          || ( $part_pkg->plan eq 'voip_cdr'
1259                && $part_pkg->option('bill_every_call')
1260             )
1261          || $options{cancel}
1262   ) {
1263
1264     # XXX should this be a package event?  probably.  events are called
1265     # at collection time at the moment, though...
1266     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1267       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1268       #don't want to reset usage just cause we want a line item??
1269       #&& $part_pkg->pkgpart == $real_pkgpart;
1270
1271     warn "    bill recur\n" if $DEBUG > 1;
1272     $lineitems++;
1273
1274     # XXX shared with $recur_prog
1275     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1276              || $cust_pkg->setup
1277              || $time;
1278
1279     #over two params!  lets at least switch to a hashref for the rest...
1280     my $increment_next_bill = ( $part_pkg->freq ne '0'
1281                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1282                                 && !$options{cancel}
1283                               );
1284     my %param = ( %setup_param,
1285                   'precommit_hooks'     => $precommit_hooks,
1286                   'increment_next_bill' => $increment_next_bill,
1287                   'discounts'           => \@recur_discounts,
1288                   'real_pkgpart'        => $real_pkgpart,
1289                   'freq_override'       => $options{freq_override} || '',
1290                   'setup_fee'           => 0,
1291                 );
1292
1293     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1294
1295     # There may be some part_pkg for which this is wrong.  Only those
1296     # which can_discount are supported.
1297     # (the UI should prevent adding discounts to these at the moment)
1298
1299     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1300          " for pkgpart ". $cust_pkg->pkgpart.
1301          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1302       if $DEBUG > 2;
1303
1304     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1305     return "$@ running $method for $cust_pkg\n"
1306       if ( $@ );
1307
1308     if ($recur eq 'NOTHING') {
1309       # then calc_cancel (or calc_recur but that's not used) has declined to
1310       # generate a recurring lineitem at all. treat this as zero, but also
1311       # try not to generate a lineitem.
1312       $recur = 0;
1313       $lineitems--;
1314     }
1315
1316     #base_cancel???
1317     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1318
1319     if ( $increment_next_bill ) {
1320
1321       my $next_bill;
1322
1323       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1324         # supplemental package
1325         # to keep in sync with the main package, simulate billing at
1326         # its frequency
1327         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1328         my $supp_pkg_freq = $part_pkg->freq;
1329         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1330         if ( $ratio != int($ratio) ) {
1331           # the UI should prevent setting up packages like this, but just
1332           # in case
1333           return "supplemental package period is not an integer multiple of main  package period";
1334         }
1335         $next_bill = $sdate;
1336         for (1..$ratio) {
1337           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1338         }
1339
1340       } else {
1341         # the normal case
1342       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1343       return "unparsable frequency: ". $part_pkg->freq
1344         if $next_bill == -1;
1345       }
1346
1347       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1348       # only for figuring next bill date, nothing else, so, reset $sdate again
1349       # here
1350       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1351       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1352       $cust_pkg->last_bill($sdate);
1353
1354       $cust_pkg->setfield('bill', $next_bill );
1355
1356     }
1357
1358     if ( $param{'setup_fee'} ) {
1359       # Add an additional setup fee at the billing stage.
1360       # Used for prorate_defer_bill.
1361       $setup += $param{'setup_fee'};
1362       $unitsetup += $param{'setup_fee'};
1363       $lineitems++;
1364     }
1365
1366     if ( defined $param{'discount_left_setup'} ) {
1367         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1368             $setup -= $discount_setup;
1369         }
1370     }
1371
1372   }
1373
1374   warn "\$setup is undefined" unless defined($setup);
1375   warn "\$recur is undefined" unless defined($recur);
1376   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1377
1378   ###
1379   # If there's line items, create em cust_bill_pkg records
1380   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1381   ###
1382
1383   if ( $lineitems ) {
1384
1385     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1386       # hmm.. and if just the options are modified in some weird price plan?
1387
1388       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1389         if $DEBUG >1;
1390
1391       my $error = $cust_pkg->replace( $old_cust_pkg,
1392                                       'depend_jobnum'=>$options{depend_jobnum},
1393                                       'options' => { $cust_pkg->options },
1394                                     )
1395         unless $options{no_commit};
1396       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1397         if $error; #just in case
1398     }
1399
1400     $setup = sprintf( "%.2f", $setup );
1401     $recur = sprintf( "%.2f", $recur );
1402     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1403       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1404     }
1405     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1406       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1407     }
1408
1409     my $discount_show_always = $conf->exists('discount-show-always')
1410                                && (    ($setup == 0 && scalar(@setup_discounts))
1411                                     || ($recur == 0 && scalar(@recur_discounts))
1412                                   );
1413
1414     if (    $setup != 0
1415          || $recur != 0
1416          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1417          || $discount_show_always
1418          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1419          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1420        )
1421     {
1422
1423       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1424         if $DEBUG > 1;
1425
1426       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1427       if ( $DEBUG > 1 ) {
1428         warn "      adding customer package invoice detail: $_\n"
1429           foreach @cust_pkg_detail;
1430       }
1431       push @details, @cust_pkg_detail;
1432
1433       my $cust_bill_pkg = new FS::cust_bill_pkg {
1434         'pkgnum'    => $cust_pkg->pkgnum,
1435         'setup'     => $setup,
1436         'unitsetup' => $unitsetup,
1437         'recur'     => $recur,
1438         'unitrecur' => $unitrecur,
1439         'quantity'  => $cust_pkg->quantity,
1440         'details'   => \@details,
1441         'discounts' => [ @setup_discounts, @recur_discounts ],
1442         'hidden'    => $part_pkg->hidden,
1443         'freq'      => $part_pkg->freq,
1444       };
1445
1446       if ( $part_pkg->option('prorate_defer_bill',1)
1447            and !$hash{last_bill} ) {
1448         # both preceding and upcoming, technically
1449         $cust_bill_pkg->sdate( $cust_pkg->setup );
1450         $cust_bill_pkg->edate( $cust_pkg->bill );
1451       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1452         $cust_bill_pkg->sdate( $hash{last_bill} );
1453         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1454         $cust_bill_pkg->edate( $time ) if $options{cancel};
1455       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1456         $cust_bill_pkg->sdate( $sdate );
1457         $cust_bill_pkg->edate( $cust_pkg->bill );
1458         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1459       }
1460
1461       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1462         unless $part_pkg->pkgpart == $real_pkgpart;
1463
1464       $$total_setup += $setup;
1465       $$total_recur += $recur;
1466
1467       ###
1468       # handle taxes
1469       ###
1470
1471       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg,
1472         cancel => $options{cancel} );
1473       return $error if $error;
1474
1475       $cust_bill_pkg->set_display(
1476         part_pkg     => $part_pkg,
1477         real_pkgpart => $real_pkgpart,
1478       );
1479
1480       push @$cust_bill_pkgs, $cust_bill_pkg;
1481
1482     } #if $setup != 0 || $recur != 0
1483
1484   } #if $line_items
1485
1486   '';
1487
1488 }
1489
1490 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1491
1492 Takes one argument, a cust_pkg object that is being billed.  This will
1493 be called only if the package was created by a package change, and has
1494 not been billed since the package change, and package balance tracking
1495 is enabled.  The second argument can be an alternate package number to
1496 transfer the balance from; this should not be used externally.
1497
1498 Transfers the balance from the previous package (now canceled) to
1499 this package, by crediting one package and creating an invoice item for
1500 the other.  Inserts the credit and returns the invoice item (so that it
1501 can be added to an invoice that's being built).
1502
1503 If the previous package was never billed, and was also created by a package
1504 change, then this will also transfer the balance from I<its> previous
1505 package, and so on, until reaching a package that either has been billed
1506 or was not created by a package change.
1507
1508 =cut
1509
1510 my $balance_transfer_reason;
1511
1512 sub _transfer_balance {
1513   my $self = shift;
1514   my $cust_pkg = shift;
1515   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1516   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1517
1518   my @transfers;
1519
1520   # if $from_pkg is not the first package in the chain, and it was never
1521   # billed, walk back
1522   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1523     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1524   }
1525
1526   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1527   if ( $prev_balance != 0 ) {
1528     $balance_transfer_reason ||= FS::reason->new_or_existing(
1529       'reason' => 'Package balance transfer',
1530       'type'   => 'Internal adjustment',
1531       'class'  => 'R'
1532     );
1533
1534     my $credit = FS::cust_credit->new({
1535         'custnum'   => $self->custnum,
1536         'amount'    => abs($prev_balance),
1537         'reasonnum' => $balance_transfer_reason->reasonnum,
1538         '_date'     => $cust_pkg->change_date,
1539     });
1540
1541     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1542         'setup'     => 0,
1543         'recur'     => abs($prev_balance),
1544         #'sdate'     => $from_pkg->last_bill, # not sure about this
1545         #'edate'     => $cust_pkg->change_date,
1546         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1547                                  $from_pkg->part_pkg->pkg),
1548     });
1549
1550     if ( $prev_balance > 0 ) {
1551       # credit the old package, charge the new one
1552       $credit->set('pkgnum', $from_pkgnum);
1553       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1554     } else {
1555       # the reverse
1556       $credit->set('pkgnum', $cust_pkg->pkgnum);
1557       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1558     }
1559     my $error = $credit->insert;
1560     die "error transferring package balance from #".$from_pkgnum.
1561         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1562
1563     push @transfers, $cust_bill_pkg;
1564   } # $prev_balance != 0
1565
1566   return @transfers;
1567 }
1568
1569 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1570
1571 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1572 from _make_lines.
1573
1574 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1575 this:
1576 {
1577   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1578   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1579 }
1580
1581 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1582 is always the cust_main_county or tax_rate identified by the key.
1583
1584 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1585 the 'taxline' method to calculate the amount of the tax.  This doesn't
1586 happen until calculate_taxes, though.
1587
1588 OPTIONS may include:
1589 - part_item: a part_pkg or part_fee object to be used as the package/fee
1590   definition.
1591 - location: a cust_location to be used as the billing location.
1592 - cancel: true if this package is being billed on cancellation.  This
1593   allows tax to be calculated on usage charges only.
1594
1595 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1596 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1597 the customer's default service location).
1598
1599 This method will also calculate exemptions for any taxes that apply to the
1600 line item (using the C<set_exemptions> method of L<FS::cust_bill_pkg>) and
1601 attach them.  This is the only place C<set_exemptions> is called in normal
1602 invoice processing.
1603
1604 =cut
1605
1606 sub _handle_taxes {
1607   my $self = shift;
1608   my $taxlisthash = shift;
1609   my $cust_bill_pkg = shift;
1610   my %options = @_;
1611
1612   # at this point I realize that we have enough information to infer all this
1613   # stuff, instead of passing around giant honking argument lists
1614   my $location = $options{location} || $cust_bill_pkg->tax_location;
1615   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1616
1617   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1618
1619   return if ( $self->payby eq 'COMP' ); #dubious
1620
1621   if ( $conf->exists('enable_taxproducts')
1622        && ( scalar($part_item->part_pkg_taxoverride)
1623             || $part_item->has_taxproduct
1624           )
1625      )
1626     {
1627
1628     # EXTERNAL TAX RATES (via tax_rate)
1629     my %cust_bill_pkg = ();
1630     my %taxes = ();
1631
1632     my @classes;
1633     my $usage = $cust_bill_pkg->usage || 0;
1634     push @classes, $cust_bill_pkg->usage_classes if $usage;
1635     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1636     push @classes, 'recur' if ($cust_bill_pkg->recur - $usage)
1637         and !$options{cancel};
1638     # that's better--probably don't even need $options{cancel} now
1639     # but leave it for now, just to be safe
1640     #
1641     # About $options{cancel}: This protects against charging per-line or
1642     # per-customer or other flat-rate surcharges on a package that's being
1643     # billed on cancellation (which is an out-of-cycle bill and should only
1644     # have usage charges).  See RT#29443.
1645
1646     # customer exemption is now handled in the 'taxline' method
1647     #my $exempt = $conf->exists('cust_class-tax_exempt')
1648     #               ? ( $self->cust_class ? $self->cust_class->tax : '' )
1649     #               : $self->tax;
1650     # standardize this just to be sure
1651     #$exempt = ($exempt eq 'Y') ? 'Y' : '';
1652     #
1653     #if ( !$exempt ) {
1654
1655     unless (exists $taxes{''}) {
1656       # unsure what purpose this serves, but last time I deleted something
1657       # from here just because I didn't see the point, it actually did
1658       # something important.
1659       my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1660       return $err_or_ref unless ref($err_or_ref);
1661       $taxes{''} = $err_or_ref;
1662     }
1663
1664     # NO DISINTEGRATIONS.
1665     # my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1666     #
1667     # do not call taxline() with any argument except the entire set of
1668     # cust_bill_pkgs on an invoice that are eligible for the tax.
1669
1670     # only calculate exemptions once for each tax rate, even if it's used
1671     # for multiple classes
1672     my %tax_seen = ();
1673
1674     foreach my $class (@classes) {
1675       my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1676       return $err_or_ref unless ref($err_or_ref);
1677       my @taxes = @$err_or_ref;
1678
1679       next if !@taxes;
1680
1681       foreach my $tax ( @taxes ) {
1682
1683         my $tax_id = ref( $tax ). ' '. $tax->taxnum;
1684         # $taxlisthash: keys are tax identifiers ('FS::tax_rate 123456').
1685         # Values are arrayrefs, first the tax object (cust_main_county
1686         # or tax_rate), then the cust_bill_pkg object that the
1687         # tax applies to, then the tax class (setup, recur, usage classnum).
1688         $taxlisthash->{ $tax_id } ||= [ $tax ];
1689         push @{ $taxlisthash->{ $tax_id  } }, $cust_bill_pkg, $class;
1690
1691         # determine any exemptions that apply
1692         if (!$tax_seen{$tax_id}) {
1693           $cust_bill_pkg->set_exemptions( $tax, custnum => $self->custnum );
1694           $tax_seen{$tax_id} = 1;
1695         }
1696
1697         # tax on tax will be done later, when we actually create the tax
1698         # line items
1699
1700       }
1701     }
1702
1703   } else {
1704
1705     # INTERNAL TAX RATES (cust_main_county)
1706
1707     # We fetch taxes even if the customer is completely exempt,
1708     # because we need to record that fact.
1709
1710     my @loc_keys = qw( district city county state country );
1711     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1712
1713     $taxhash{'taxclass'} = $part_item->taxclass;
1714
1715     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1716
1717     my @taxes = (); # entries are cust_main_county objects
1718     my %taxhash_elim = %taxhash;
1719     my @elim = qw( district city county state );
1720     do {
1721
1722       #first try a match with taxclass
1723       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1724
1725       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1726         #then try a match without taxclass
1727         my %no_taxclass = %taxhash_elim;
1728         $no_taxclass{ 'taxclass' } = '';
1729         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1730       }
1731
1732       $taxhash_elim{ shift(@elim) } = '';
1733
1734     } while ( !scalar(@taxes) && scalar(@elim) );
1735
1736     foreach (@taxes) {
1737       my $tax_id = 'cust_main_county '.$_->taxnum;
1738       $taxlisthash->{$tax_id} ||= [ $_ ];
1739       $cust_bill_pkg->set_exemptions($_, custnum => $self->custnum);
1740       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1741     }
1742
1743   }
1744   '';
1745 }
1746
1747 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1748
1749 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1750 or part_fee (which will define the tax eligibility of the product), CLASS is
1751 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1752 location where the service was provided (or billed, depending on
1753 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1754 can apply to this line item.
1755
1756 =cut
1757
1758 sub _gather_taxes {
1759   my $self = shift;
1760   my $part_item = shift;
1761   my $class = shift;
1762   my $location = shift;
1763
1764   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1765
1766   my $geocode = $location->geocode('cch');
1767
1768   [ $part_item->tax_rates('cch', $geocode, $class) ]
1769
1770 }
1771
1772 =item collect [ HASHREF | OPTION => VALUE ... ]
1773
1774 (Attempt to) collect money for this customer's outstanding invoices (see
1775 L<FS::cust_bill>).  Usually used after the bill method.
1776
1777 Actions are now triggered by billing events; see L<FS::part_event> and the
1778 billing events web interface.  Old-style invoice events (see
1779 L<FS::part_bill_event>) have been deprecated.
1780
1781 If there is an error, returns the error, otherwise returns false.
1782
1783 Options are passed as name-value pairs.
1784
1785 Currently available options are:
1786
1787 =over 4
1788
1789 =item invoice_time
1790
1791 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1792
1793 =item retry
1794
1795 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1796
1797 =item check_freq
1798
1799 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1800
1801 =item quiet
1802
1803 set true to surpress email card/ACH decline notices.
1804
1805 =item debug
1806
1807 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1808
1809 =back
1810
1811 # =item payby
1812 #
1813 # allows for one time override of normal customer billing method
1814
1815 =cut
1816
1817 sub collect {
1818   my( $self, %options ) = @_;
1819
1820   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1821
1822   my $invoice_time = $options{'invoice_time'} || time;
1823
1824   #put below somehow?
1825   local $SIG{HUP} = 'IGNORE';
1826   local $SIG{INT} = 'IGNORE';
1827   local $SIG{QUIT} = 'IGNORE';
1828   local $SIG{TERM} = 'IGNORE';
1829   local $SIG{TSTP} = 'IGNORE';
1830   local $SIG{PIPE} = 'IGNORE';
1831
1832   my $oldAutoCommit = $FS::UID::AutoCommit;
1833   local $FS::UID::AutoCommit = 0;
1834   my $dbh = dbh;
1835
1836   $self->select_for_update; #mutex
1837
1838   if ( $DEBUG ) {
1839     my $balance = $self->balance;
1840     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1841   }
1842
1843   if ( exists($options{'retry_card'}) ) {
1844     carp 'retry_card option passed to collect is deprecated; use retry';
1845     $options{'retry'} ||= $options{'retry_card'};
1846   }
1847   if ( exists($options{'retry'}) && $options{'retry'} ) {
1848     my $error = $self->retry_realtime;
1849     if ( $error ) {
1850       $dbh->rollback if $oldAutoCommit;
1851       return $error;
1852     }
1853   }
1854
1855   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1856
1857   #never want to roll back an event just because it returned an error
1858   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1859
1860   $self->do_cust_event(
1861     'debug'      => ( $options{'debug'} || 0 ),
1862     'time'       => $invoice_time,
1863     'check_freq' => $options{'check_freq'},
1864     'stage'      => 'collect',
1865   );
1866
1867 }
1868
1869 =item retry_realtime
1870
1871 Schedules realtime / batch  credit card / electronic check / LEC billing
1872 events for for retry.  Useful if card information has changed or manual
1873 retry is desired.  The 'collect' method must be called to actually retry
1874 the transaction.
1875
1876 Implementation details: For either this customer, or for each of this
1877 customer's open invoices, changes the status of the first "done" (with
1878 statustext error) realtime processing event to "failed".
1879
1880 =cut
1881
1882 sub retry_realtime {
1883   my $self = shift;
1884
1885   local $SIG{HUP} = 'IGNORE';
1886   local $SIG{INT} = 'IGNORE';
1887   local $SIG{QUIT} = 'IGNORE';
1888   local $SIG{TERM} = 'IGNORE';
1889   local $SIG{TSTP} = 'IGNORE';
1890   local $SIG{PIPE} = 'IGNORE';
1891
1892   my $oldAutoCommit = $FS::UID::AutoCommit;
1893   local $FS::UID::AutoCommit = 0;
1894   my $dbh = dbh;
1895
1896   #a little false laziness w/due_cust_event (not too bad, really)
1897
1898   # I guess this is always as of now?
1899   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1900   my $order = FS::part_event_condition->order_conditions_sql;
1901   my $mine =
1902   '( '
1903    . join ( ' OR ' , map {
1904     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1905     my $custnum = FS::part_event->eventtables_custnum->{$_};
1906     "( part_event.eventtable = " . dbh->quote($_)
1907     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1908     . " from $_ $cust_join"
1909     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1910    } FS::part_event->eventtables)
1911    . ') ';
1912
1913   #here is the agent virtualization
1914   my $agent_virt = " (    part_event.agentnum IS NULL
1915                        OR part_event.agentnum = ". $self->agentnum. ' )';
1916
1917   #XXX this shouldn't be hardcoded, actions should declare it...
1918   my @realtime_events = qw(
1919     cust_bill_realtime_card
1920     cust_bill_realtime_check
1921     cust_bill_realtime_lec
1922     cust_bill_batch
1923   );
1924
1925   my $is_realtime_event =
1926     ' part_event.action IN ( '.
1927         join(',', map "'$_'", @realtime_events ).
1928     ' ) ';
1929
1930   my $batch_or_statustext =
1931     "( part_event.action = 'cust_bill_batch'
1932        OR ( statustext IS NOT NULL AND statustext != '' )
1933      )";
1934
1935
1936   my @cust_event = qsearch({
1937     'table'     => 'cust_event',
1938     'select'    => 'cust_event.*',
1939     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1940     'hashref'   => { 'status' => 'done' },
1941     'extra_sql' => " AND $batch_or_statustext ".
1942                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1943   });
1944
1945   my %seen_invnum = ();
1946   foreach my $cust_event (@cust_event) {
1947
1948     #max one for the customer, one for each open invoice
1949     my $cust_X = $cust_event->cust_X;
1950     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1951                           ? $cust_X->invnum
1952                           : 0
1953                         }++
1954          or $cust_event->part_event->eventtable eq 'cust_bill'
1955             && ! $cust_X->owed;
1956
1957     my $error = $cust_event->retry;
1958     if ( $error ) {
1959       $dbh->rollback if $oldAutoCommit;
1960       return "error scheduling event for retry: $error";
1961     }
1962
1963   }
1964
1965   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1966   '';
1967
1968 }
1969
1970 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1971
1972 Runs billing events; see L<FS::part_event> and the billing events web
1973 interface.
1974
1975 If there is an error, returns the error, otherwise returns false.
1976
1977 Options are passed as name-value pairs.
1978
1979 Currently available options are:
1980
1981 =over 4
1982
1983 =item time
1984
1985 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1986
1987 =item check_freq
1988
1989 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1990
1991 =item stage
1992
1993 "collect" (the default) or "pre-bill"
1994
1995 =item quiet
1996
1997 set true to surpress email card/ACH decline notices.
1998
1999 =item debug
2000
2001 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2002
2003 =back
2004 =cut
2005
2006 # =item payby
2007 #
2008 # allows for one time override of normal customer billing method
2009
2010 # =item retry
2011 #
2012 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
2013
2014 sub do_cust_event {
2015   my( $self, %options ) = @_;
2016
2017   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2018
2019   my $time = $options{'time'} || time;
2020
2021   #put below somehow?
2022   local $SIG{HUP} = 'IGNORE';
2023   local $SIG{INT} = 'IGNORE';
2024   local $SIG{QUIT} = 'IGNORE';
2025   local $SIG{TERM} = 'IGNORE';
2026   local $SIG{TSTP} = 'IGNORE';
2027   local $SIG{PIPE} = 'IGNORE';
2028
2029   my $oldAutoCommit = $FS::UID::AutoCommit;
2030   local $FS::UID::AutoCommit = 0;
2031   my $dbh = dbh;
2032
2033   $self->select_for_update; #mutex
2034
2035   if ( $DEBUG ) {
2036     my $balance = $self->balance;
2037     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
2038   }
2039
2040 #  if ( exists($options{'retry_card'}) ) {
2041 #    carp 'retry_card option passed to collect is deprecated; use retry';
2042 #    $options{'retry'} ||= $options{'retry_card'};
2043 #  }
2044 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
2045 #    my $error = $self->retry_realtime;
2046 #    if ( $error ) {
2047 #      $dbh->rollback if $oldAutoCommit;
2048 #      return $error;
2049 #    }
2050 #  }
2051
2052   # false laziness w/pay_batch::import_results
2053
2054   my $due_cust_event = $self->due_cust_event(
2055     'debug'      => ( $options{'debug'} || 0 ),
2056     'time'       => $time,
2057     'check_freq' => $options{'check_freq'},
2058     'stage'      => ( $options{'stage'} || 'collect' ),
2059   );
2060   unless( ref($due_cust_event) ) {
2061     $dbh->rollback if $oldAutoCommit;
2062     return $due_cust_event;
2063   }
2064
2065   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2066   #never want to roll back an event just because it or a different one
2067   # returned an error
2068   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
2069
2070   foreach my $cust_event ( @$due_cust_event ) {
2071
2072     #XXX lock event
2073
2074     #re-eval event conditions (a previous event could have changed things)
2075     unless ( $cust_event->test_conditions ) {
2076       #don't leave stray "new/locked" records around
2077       my $error = $cust_event->delete;
2078       return $error if $error;
2079       next;
2080     }
2081
2082     {
2083       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
2084         if $options{'quiet'};
2085       warn "  running cust_event ". $cust_event->eventnum. "\n"
2086         if $DEBUG > 1;
2087
2088       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
2089       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
2090         #XXX wtf is this?  figure out a proper dealio with return value
2091         #from do_event
2092         return $error;
2093       }
2094     }
2095
2096   }
2097
2098   '';
2099
2100 }
2101
2102 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
2103
2104 Inserts database records for and returns an ordered listref of new events due
2105 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
2106 events are due, an empty listref is returned.  If there is an error, returns a
2107 scalar error message.
2108
2109 To actually run the events, call each event's test_condition method, and if
2110 still true, call the event's do_event method.
2111
2112 Options are passed as a hashref or as a list of name-value pairs.  Available
2113 options are:
2114
2115 =over 4
2116
2117 =item check_freq
2118
2119 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
2120
2121 =item stage
2122
2123 "collect" (the default) or "pre-bill"
2124
2125 =item time
2126
2127 "Current time" for the events.
2128
2129 =item debug
2130
2131 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2132
2133 =item eventtable
2134
2135 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2136
2137 =item objects
2138
2139 Explicitly pass the objects to be tested (typically used with eventtable).
2140
2141 =item testonly
2142
2143 Set to true to return the objects, but not actually insert them into the
2144 database.
2145
2146 =back
2147
2148 =cut
2149
2150 sub due_cust_event {
2151   my $self = shift;
2152   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2153
2154   #???
2155   #my $DEBUG = $opt{'debug'}
2156   $opt{'debug'} ||= 0; # silence some warnings
2157   local($DEBUG) = $opt{'debug'}
2158     if $opt{'debug'} > $DEBUG;
2159   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2160
2161   warn "$me due_cust_event called with options ".
2162        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2163     if $DEBUG;
2164
2165   $opt{'time'} ||= time;
2166
2167   local $SIG{HUP} = 'IGNORE';
2168   local $SIG{INT} = 'IGNORE';
2169   local $SIG{QUIT} = 'IGNORE';
2170   local $SIG{TERM} = 'IGNORE';
2171   local $SIG{TSTP} = 'IGNORE';
2172   local $SIG{PIPE} = 'IGNORE';
2173
2174   my $oldAutoCommit = $FS::UID::AutoCommit;
2175   local $FS::UID::AutoCommit = 0;
2176   my $dbh = dbh;
2177
2178   $self->select_for_update #mutex
2179     unless $opt{testonly};
2180
2181   ###
2182   # find possible events (initial search)
2183   ###
2184
2185   my @cust_event = ();
2186
2187   my @eventtable = $opt{'eventtable'}
2188                      ? ( $opt{'eventtable'} )
2189                      : FS::part_event->eventtables_runorder;
2190
2191   my $check_freq = $opt{'check_freq'} || '1d';
2192
2193   foreach my $eventtable ( @eventtable ) {
2194
2195     my @objects;
2196     if ( $opt{'objects'} ) {
2197
2198       @objects = @{ $opt{'objects'} };
2199
2200     } elsif ( $eventtable eq 'cust_main' ) {
2201
2202       @objects = ( $self );
2203
2204     } else {
2205
2206       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2207       # linkage not needed here because FS::cust_main->$eventtable will
2208       # already supply it
2209
2210       #some false laziness w/Cron::bill bill_where
2211
2212       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2213         'time' => $opt{'time'});
2214       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2215         'time'=>$opt{'time'},
2216       );
2217       $where = $where ? "AND $where" : '';
2218
2219       my $are_part_event =
2220       "EXISTS ( SELECT 1 FROM part_event $join
2221         WHERE check_freq = '$check_freq'
2222         AND eventtable = '$eventtable'
2223         AND ( disabled = '' OR disabled IS NULL )
2224         $where
2225         )
2226       ";
2227       #eofalse
2228
2229       @objects = $self->$eventtable(
2230         'addl_from' => $cm_join,
2231         'extra_sql' => " AND $are_part_event",
2232       );
2233     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2234
2235     my @e_cust_event = ();
2236
2237     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2238
2239     my $cross = "CROSS JOIN $eventtable $linkage";
2240     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2241       unless $eventtable eq 'cust_main';
2242
2243     foreach my $object ( @objects ) {
2244
2245       #this first search uses the condition_sql magic for optimization.
2246       #the more possible events we can eliminate in this step the better
2247
2248       my $cross_where = '';
2249       my $pkey = $object->primary_key;
2250       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2251
2252       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2253         'time' => $opt{'time'});
2254       my $extra_sql =
2255         FS::part_event_condition->where_conditions_sql( $eventtable,
2256                                                         'time'=>$opt{'time'}
2257                                                       );
2258       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2259
2260       $extra_sql = "AND $extra_sql" if $extra_sql;
2261
2262       #here is the agent virtualization
2263       $extra_sql .= " AND (    part_event.agentnum IS NULL
2264                             OR part_event.agentnum = ". $self->agentnum. ' )';
2265
2266       $extra_sql .= " $order";
2267
2268       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2269         if $opt{'debug'} > 2;
2270       my @part_event = qsearch( {
2271         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2272         'select'    => 'part_event.*',
2273         'table'     => 'part_event',
2274         'addl_from' => "$cross $join",
2275         'hashref'   => { 'check_freq' => $check_freq,
2276                          'eventtable' => $eventtable,
2277                          'disabled'   => '',
2278                        },
2279         'extra_sql' => "AND $cross_where $extra_sql",
2280       } );
2281
2282       if ( $DEBUG > 2 ) {
2283         my $pkey = $object->primary_key;
2284         warn "      ". scalar(@part_event).
2285              " possible events found for $eventtable ". $object->$pkey(). "\n";
2286       }
2287
2288       push @e_cust_event, map {
2289         $_->new_cust_event($object, 'time' => $opt{'time'})
2290       } @part_event;
2291
2292     }
2293
2294     warn "    ". scalar(@e_cust_event).
2295          " subtotal possible cust events found for $eventtable\n"
2296       if $DEBUG > 1;
2297
2298     push @cust_event, @e_cust_event;
2299
2300   }
2301
2302   warn "  ". scalar(@cust_event).
2303        " total possible cust events found in initial search\n"
2304     if $DEBUG; # > 1;
2305
2306
2307   ##
2308   # test stage
2309   ##
2310
2311   $opt{stage} ||= 'collect';
2312   @cust_event =
2313     grep { my $stage = $_->part_event->event_stage;
2314            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2315          }
2316          @cust_event;
2317
2318   ##
2319   # test conditions
2320   ##
2321
2322   my %unsat = ();
2323
2324   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2325                      @cust_event;
2326
2327   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2328     if $DEBUG; # > 1;
2329
2330   warn "    invalid conditions not eliminated with condition_sql:\n".
2331        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2332     if keys %unsat && $DEBUG; # > 1;
2333
2334   ##
2335   # insert
2336   ##
2337
2338   unless( $opt{testonly} ) {
2339     foreach my $cust_event ( @cust_event ) {
2340
2341       my $error = $cust_event->insert();
2342       if ( $error ) {
2343         $dbh->rollback if $oldAutoCommit;
2344         return $error;
2345       }
2346
2347     }
2348   }
2349
2350   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2351
2352   ##
2353   # return
2354   ##
2355
2356   warn "  returning events: ". Dumper(@cust_event). "\n"
2357     if $DEBUG > 2;
2358
2359   \@cust_event;
2360
2361 }
2362
2363 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2364
2365 Applies unapplied payments and credits.
2366
2367 In most cases, this new method should be used in place of sequential
2368 apply_payments and apply_credits methods.
2369
2370 A hash of optional arguments may be passed.  Currently "manual" is supported.
2371 If true, a payment receipt is sent instead of a statement when
2372 'payment_receipt_email' configuration option is set.
2373
2374 If there is an error, returns the error, otherwise returns false.
2375
2376 =cut
2377
2378 sub apply_payments_and_credits {
2379   my( $self, %options ) = @_;
2380
2381   local $SIG{HUP} = 'IGNORE';
2382   local $SIG{INT} = 'IGNORE';
2383   local $SIG{QUIT} = 'IGNORE';
2384   local $SIG{TERM} = 'IGNORE';
2385   local $SIG{TSTP} = 'IGNORE';
2386   local $SIG{PIPE} = 'IGNORE';
2387
2388   my $oldAutoCommit = $FS::UID::AutoCommit;
2389   local $FS::UID::AutoCommit = 0;
2390   my $dbh = dbh;
2391
2392   $self->select_for_update; #mutex
2393
2394   foreach my $cust_bill ( $self->open_cust_bill ) {
2395     my $error = $cust_bill->apply_payments_and_credits(%options);
2396     if ( $error ) {
2397       $dbh->rollback if $oldAutoCommit;
2398       return "Error applying: $error";
2399     }
2400   }
2401
2402   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2403   ''; #no error
2404
2405 }
2406
2407 =item apply_credits OPTION => VALUE ...
2408
2409 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2410 to outstanding invoice balances in chronological order (or reverse
2411 chronological order if the I<order> option is set to B<newest>) and returns the
2412 value of any remaining unapplied credits available for refund (see
2413 L<FS::cust_refund>).
2414
2415 Dies if there is an error.
2416
2417 =cut
2418
2419 sub apply_credits {
2420   my $self = shift;
2421   my %opt = @_;
2422
2423   local $SIG{HUP} = 'IGNORE';
2424   local $SIG{INT} = 'IGNORE';
2425   local $SIG{QUIT} = 'IGNORE';
2426   local $SIG{TERM} = 'IGNORE';
2427   local $SIG{TSTP} = 'IGNORE';
2428   local $SIG{PIPE} = 'IGNORE';
2429
2430   my $oldAutoCommit = $FS::UID::AutoCommit;
2431   local $FS::UID::AutoCommit = 0;
2432   my $dbh = dbh;
2433
2434   $self->select_for_update; #mutex
2435
2436   unless ( $self->total_unapplied_credits ) {
2437     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2438     return 0;
2439   }
2440
2441   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2442       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2443
2444   my @invoices = $self->open_cust_bill;
2445   @invoices = sort { $b->_date <=> $a->_date } @invoices
2446     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2447
2448   if ( $conf->exists('pkg-balances') ) {
2449     # limit @credits to those w/ a pkgnum grepped from $self
2450     my %pkgnums = ();
2451     foreach my $i (@invoices) {
2452       foreach my $li ( $i->cust_bill_pkg ) {
2453         $pkgnums{$li->pkgnum} = 1;
2454       }
2455     }
2456     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2457   }
2458
2459   my $credit;
2460
2461   foreach my $cust_bill ( @invoices ) {
2462
2463     if ( !defined($credit) || $credit->credited == 0) {
2464       $credit = pop @credits or last;
2465     }
2466
2467     my $owed;
2468     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2469       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2470     } else {
2471       $owed = $cust_bill->owed;
2472     }
2473     unless ( $owed > 0 ) {
2474       push @credits, $credit;
2475       next;
2476     }
2477
2478     my $amount = min( $credit->credited, $owed );
2479
2480     my $cust_credit_bill = new FS::cust_credit_bill ( {
2481       'crednum' => $credit->crednum,
2482       'invnum'  => $cust_bill->invnum,
2483       'amount'  => $amount,
2484     } );
2485     $cust_credit_bill->pkgnum( $credit->pkgnum )
2486       if $conf->exists('pkg-balances') && $credit->pkgnum;
2487     my $error = $cust_credit_bill->insert;
2488     if ( $error ) {
2489       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2490       die $error;
2491     }
2492
2493     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2494
2495   }
2496
2497   my $total_unapplied_credits = $self->total_unapplied_credits;
2498
2499   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2500
2501   return $total_unapplied_credits;
2502 }
2503
2504 =item apply_payments  [ OPTION => VALUE ... ]
2505
2506 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2507 to outstanding invoice balances in chronological order.
2508
2509  #and returns the value of any remaining unapplied payments.
2510
2511 A hash of optional arguments may be passed.  Currently "manual" is supported.
2512 If true, a payment receipt is sent instead of a statement when
2513 'payment_receipt_email' configuration option is set.
2514
2515 Dies if there is an error.
2516
2517 =cut
2518
2519 sub apply_payments {
2520   my( $self, %options ) = @_;
2521
2522   local $SIG{HUP} = 'IGNORE';
2523   local $SIG{INT} = 'IGNORE';
2524   local $SIG{QUIT} = 'IGNORE';
2525   local $SIG{TERM} = 'IGNORE';
2526   local $SIG{TSTP} = 'IGNORE';
2527   local $SIG{PIPE} = 'IGNORE';
2528
2529   my $oldAutoCommit = $FS::UID::AutoCommit;
2530   local $FS::UID::AutoCommit = 0;
2531   my $dbh = dbh;
2532
2533   $self->select_for_update; #mutex
2534
2535   #return 0 unless
2536
2537   my @payments = $self->unapplied_cust_pay;
2538
2539   my @invoices = $self->open_cust_bill;
2540
2541   if ( $conf->exists('pkg-balances') ) {
2542     # limit @payments to those w/ a pkgnum grepped from $self
2543     my %pkgnums = ();
2544     foreach my $i (@invoices) {
2545       foreach my $li ( $i->cust_bill_pkg ) {
2546         $pkgnums{$li->pkgnum} = 1;
2547       }
2548     }
2549     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2550   }
2551
2552   my $payment;
2553
2554   foreach my $cust_bill ( @invoices ) {
2555
2556     if ( !defined($payment) || $payment->unapplied == 0 ) {
2557       $payment = pop @payments or last;
2558     }
2559
2560     my $owed;
2561     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2562       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2563     } else {
2564       $owed = $cust_bill->owed;
2565     }
2566     unless ( $owed > 0 ) {
2567       push @payments, $payment;
2568       next;
2569     }
2570
2571     my $amount = min( $payment->unapplied, $owed );
2572
2573     my $cbp = {
2574       'paynum' => $payment->paynum,
2575       'invnum' => $cust_bill->invnum,
2576       'amount' => $amount,
2577     };
2578     $cbp->{_date} = $payment->_date
2579         if $options{'manual'} && $options{'backdate_application'};
2580     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2581     $cust_bill_pay->pkgnum( $payment->pkgnum )
2582       if $conf->exists('pkg-balances') && $payment->pkgnum;
2583     my $error = $cust_bill_pay->insert(%options);
2584     if ( $error ) {
2585       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2586       die $error;
2587     }
2588
2589     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2590
2591   }
2592
2593   my $total_unapplied_payments = $self->total_unapplied_payments;
2594
2595   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2596
2597   return $total_unapplied_payments;
2598 }
2599
2600 =back
2601
2602 =head1 FLOW
2603
2604   bill_and_collect
2605
2606     cancel_expired_pkgs
2607     suspend_adjourned_pkgs
2608     unsuspend_resumed_pkgs
2609
2610     bill
2611       (do_cust_event pre-bill)
2612       _make_lines
2613         _handle_taxes
2614           (vendor-only) _gather_taxes
2615       _omit_zero_value_bundles
2616       _handle_taxes (for fees)
2617       calculate_taxes
2618
2619     apply_payments_and_credits
2620     collect
2621       do_cust_event
2622         due_cust_event
2623
2624 =head1 BUGS
2625
2626 =head1 SEE ALSO
2627
2628 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2629
2630 =cut
2631
2632 1;