FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use FS::cust_bill;
  12 use FS::cust_bill_pkg;
  13 use FS::cust_bill_pkg_display;
  14 use FS::cust_bill_pay;
  15 use FS::cust_credit_bill;
  16 use FS::cust_tax_adjustment;
  17 use FS::tax_rate;
  18 use FS::tax_rate_location;
  19 use FS::cust_bill_pkg_tax_location;
  20 use FS::cust_bill_pkg_tax_rate_location;
  21 use FS::part_event;
  22 use FS::part_event_condition;
  23 use FS::pkg_category;
  24 use FS::cust_event_fee;
  25 use FS::Log;
  26
  27 # 1 is mostly method/subroutine entry and options
  28 # 2 traces progress of some operations
  29 # 3 is even more information including possibly sensitive data
  30 $DEBUG = 0;
  31 $me = '[FS::cust_main::Billing]';
  32
  33 install_callback FS::UID sub {
  34   $conf = new FS::Conf;
  35   #yes, need it for stuff below (prolly should be cached)
  36 };
  37
  38 =head1 NAME
  39
  40 FS::cust_main::Billing - Billing mixin for cust_main
  41
  42 =head1 SYNOPSIS
  43
  44 =head1 DESCRIPTION
  45
  46 These methods are available on FS::cust_main objects.
  47
  48 =head1 METHODS
  49
  50 =over 4
  51
  52 =item bill_and_collect
  53
  54 Cancels and suspends any packages due, generates bills, applies payments and
  55 credits, and applies collection events to run cards, send bills and notices,
  56 etc.
  57
  58 By default, warns on errors and continues with the next operation (but see the
  59 "fatal" flag below).
  60
  61 Options are passed as name-value pairs.  Currently available options are:
  62
  63 =over 4
  64
  65 =item time
  66
  67 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  68
  69  use Date::Parse;
  70  ...
  71  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  72
  73 =item invoice_time
  74
  75 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  76
  77 =item check_freq
  78
  79 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  80
  81 =item resetup
  82
  83 If set true, re-charges setup fees.
  84
  85 =item fatal
  86
  87 If set any errors prevent subsequent operations from continusing.  If set
  88 specifically to "return", returns the error (or false, if there is no error).
  89 Any other true value causes errors to die.
  90
  91 =item debug
  92
  93 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  94
  95 =item job
  96
  97 Optional FS::queue entry to receive status updates.
  98
  99 =back
 100
 101 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 102 options of those methods are also available.
 103
 104 =cut
 105
 106 sub bill_and_collect {
 107   my( $self, %options ) = @_;
 108
 109   my $log = FS::Log->new('bill_and_collect');
 110   $log->debug('start', object => $self, agentnum => $self->agentnum);
 111
 112   my $error;
 113
 114   #$options{actual_time} not $options{time} because freeside-daily -d is for
 115   #pre-printing invoices
 116
 117   $options{'actual_time'} ||= time;
 118   my $job = $options{'job'};
 119
 120   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 121                         ? day_end( $options{actual_time} )
 122                         : $options{actual_time}
 123                     );
 124
 125   $job->update_statustext('0,cleaning expired packages') if $job;
 126   $error = $self->cancel_expired_pkgs( $actual_time );
 127   if ( $error ) {
 128     $error = "Error expiring custnum ". $self->custnum. ": $error";
 129     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 130     elsif ( $options{fatal}                                ) { die    $error; }
 131     else                                                     { warn   $error; }
 132   }
 133
 134   $error = $self->suspend_adjourned_pkgs( $actual_time );
 135   if ( $error ) {
 136     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 137     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 138     elsif ( $options{fatal}                                ) { die    $error; }
 139     else                                                     { warn   $error; }
 140   }
 141
 142   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 143   if ( $error ) {
 144     $error = "Error resuming custnum ".$self->custnum. ": $error";
 145     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 146     elsif ( $options{fatal}                                ) { die    $error; }
 147     else                                                     { warn   $error; }
 148   }
 149
 150   $job->update_statustext('20,billing packages') if $job;
 151   $error = $self->bill( %options );
 152   if ( $error ) {
 153     $error = "Error billing custnum ". $self->custnum. ": $error";
 154     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 155     elsif ( $options{fatal}                                ) { die    $error; }
 156     else                                                     { warn   $error; }
 157   }
 158
 159   $job->update_statustext('50,applying payments and credits') if $job;
 160   $error = $self->apply_payments_and_credits;
 161   if ( $error ) {
 162     $error = "Error applying custnum ". $self->custnum. ": $error";
 163     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 164     elsif ( $options{fatal}                                ) { die    $error; }
 165     else                                                     { warn   $error; }
 166   }
 167
 168   $job->update_statustext('70,running collection events') if $job;
 169   unless ( $conf->exists('cancelled_cust-noevents')
 170            && ! $self->num_ncancelled_pkgs
 171   ) {
 172     $error = $self->collect( %options );
 173     if ( $error ) {
 174       $error = "Error collecting custnum ". $self->custnum. ": $error";
 175       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 176       elsif ($options{fatal}                               ) { die    $error; }
 177       else                                                   { warn   $error; }
 178     }
 179   }
 180   $job->update_statustext('100,finished') if $job;
 181   $log->debug('finish', object => $self, agentnum => $self->agentnum);
 182
 183   '';
 184
 185 }
 186
 187 sub cancel_expired_pkgs {
 188   my ( $self, $time, %options ) = @_;
 189
 190   my @cancel_pkgs = $self->ncancelled_pkgs( {
 191     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 192   } );
 193
 194   my @errors = ();
 195
 196   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 197     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 198     my $error;
 199
 200     if ( $cust_pkg->change_to_pkgnum ) {
 201
 202       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 203       if ( !$new_pkg ) {
 204         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 205                       $cust_pkg->change_to_pkgnum.'; not expiring';
 206         next CUST_PKG;
 207       }
 208       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 209                                   'unprotect_svcs'  => 1 );
 210       $error = '' if ref $error eq 'FS::cust_pkg';
 211
 212     } else { # just cancel it
 213        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 214                                            'reason_otaker' => $cpr->otaker,
 215                                            'time'          => $time,
 216                                          )
 217                                        : ()
 218                                  );
 219     }
 220     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 221   }
 222
 223   join(' / ', @errors);
 224
 225 }
 226
 227 sub suspend_adjourned_pkgs {
 228   my ( $self, $time, %options ) = @_;
 229
 230   my @susp_pkgs = $self->ncancelled_pkgs( {
 231     'extra_sql' =>
 232       " AND ( susp IS NULL OR susp = 0 )
 233         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 234               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 235             )
 236       ",
 237   } );
 238
 239   #only because there's no SQL test for is_prepaid :/
 240   @susp_pkgs =
 241     grep {     (    $_->part_pkg->is_prepaid
 242                  && $_->bill
 243                  && $_->bill < $time
 244                )
 245             || (    $_->adjourn
 246                  && $_->adjourn <= $time
 247                )
 248
 249          }
 250          @susp_pkgs;
 251
 252   my @errors = ();
 253
 254   foreach my $cust_pkg ( @susp_pkgs ) {
 255     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 256       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 257     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 258                                             'reason_otaker' => $cpr->otaker
 259                                           )
 260                                         : ()
 261                                   );
 262     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 263   }
 264
 265   join(' / ', @errors);
 266
 267 }
 268
 269 sub unsuspend_resumed_pkgs {
 270   my ( $self, $time, %options ) = @_;
 271
 272   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 273     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 274   } );
 275
 276   my @errors = ();
 277
 278   foreach my $cust_pkg ( @unsusp_pkgs ) {
 279     my $error = $cust_pkg->unsuspend( 'time' => $time );
 280     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 281   }
 282
 283   join(' / ', @errors);
 284
 285 }
 286
 287 =item bill OPTIONS
 288
 289 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 290 conjunction with the collect method by calling B<bill_and_collect>.
 291
 292 If there is an error, returns the error, otherwise returns false.
 293
 294 Options are passed as name-value pairs.  Currently available options are:
 295
 296 =over 4
 297
 298 =item resetup
 299
 300 If set true, re-charges setup fees.
 301
 302 =item recurring_only
 303
 304 If set true then only bill recurring charges, not setup, usage, one time
 305 charges, etc.
 306
 307 =item freq_override
 308
 309 If set, then override the normal frequency and look for a part_pkg_discount
 310 to take at that frequency.  This is appropriate only when the normal
 311 frequency for all packages is monthly, and is an error otherwise.  Use
 312 C<pkg_list> to limit the set of packages included in billing.
 313
 314 =item time
 315
 316 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 317
 318  use Date::Parse;
 319  ...
 320  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 321
 322 =item pkg_list
 323
 324 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 325
 326  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 327
 328 =item not_pkgpart
 329
 330 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 331
 332 =item no_prepaid
 333
 334 Do not bill prepaid packages.  Used by freeside-daily.
 335
 336 =item invoice_time
 337
 338 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 339
 340 =item cancel
 341
 342 This boolean value informs the us that the package is being cancelled.  This
 343 typically might mean not charging the normal recurring fee but only usage
 344 fees since the last billing. Setup charges may be charged.  Not all package
 345 plans support this feature (they tend to charge 0).
 346
 347 =item no_usage_reset
 348
 349 Prevent the resetting of usage limits during this call.
 350
 351 =item no_commit
 352
 353 Do not save the generated bill in the database.  Useful with return_bill
 354
 355 =item return_bill
 356
 357 A list reference on which the generated bill(s) will be returned.
 358
 359 =item invoice_terms
 360
 361 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 362 terms or the default terms are used.
 363
 364 =back
 365
 366 =cut
 367
 368 sub bill {
 369   my( $self, %options ) = @_;
 370
 371   return '' if $self->payby eq 'COMP';
 372
 373   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 374
 375   warn "$me bill customer ". $self->custnum. "\n"
 376     if $DEBUG;
 377
 378   my $time = $options{'time'} || time;
 379   my $invoice_time = $options{'invoice_time'} || $time;
 380
 381   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 382                      ? day_end( $time )
 383                      : $time
 384                  );
 385
 386   $options{'not_pkgpart'} ||= {};
 387   $options{'not_pkgpart'} = { map { $_ => 1 }
 388                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 389                             }
 390     unless ref($options{'not_pkgpart'});
 391
 392   local $SIG{HUP} = 'IGNORE';
 393   local $SIG{INT} = 'IGNORE';
 394   local $SIG{QUIT} = 'IGNORE';
 395   local $SIG{TERM} = 'IGNORE';
 396   local $SIG{TSTP} = 'IGNORE';
 397   local $SIG{PIPE} = 'IGNORE';
 398
 399   my $oldAutoCommit = $FS::UID::AutoCommit;
 400   local $FS::UID::AutoCommit = 0;
 401   my $dbh = dbh;
 402
 403   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 404     if $DEBUG;
 405
 406   $self->select_for_update; #mutex
 407
 408   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 409     if $DEBUG;
 410
 411   my $error = $self->do_cust_event(
 412     'debug'      => ( $options{'debug'} || 0 ),
 413     'time'       => $invoice_time,
 414     'check_freq' => $options{'check_freq'},
 415     'stage'      => 'pre-bill',
 416   )
 417     unless $options{no_commit};
 418   if ( $error ) {
 419     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 420     return $error;
 421   }
 422
 423   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 424     if $DEBUG;
 425
 426   #keep auto-charge and non-auto-charge line items separate
 427   my @passes = ( '', 'no_auto' );
 428
 429   my %cust_bill_pkg = map { $_ => [] } @passes;
 430
 431   ###
 432   # find the packages which are due for billing, find out how much they are
 433   # & generate invoice database.
 434   ###
 435
 436   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 437   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 438
 439   my %taxlisthash = map { $_ => {} } @passes;
 440
 441   my @precommit_hooks = ();
 442
 443   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 444
 445   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 446
 447     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 448
 449     my $part_pkg = $cust_pkg->part_pkg;
 450
 451     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 452
 453     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 454
 455     #? to avoid use of uninitialized value errors... ?
 456     $cust_pkg->setfield('bill', '')
 457       unless defined($cust_pkg->bill);
 458
 459     my $real_pkgpart = $cust_pkg->pkgpart;
 460     my %hash = $cust_pkg->hash;
 461
 462     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 463     # suffer from performance issues
 464     $options{has_hidden} = 0;
 465     my @part_pkg = $part_pkg->self_and_bill_linked;
 466     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 467
 468     # if this package was changed from another package,
 469     # and it hasn't been billed since then,
 470     # and package balances are enabled,
 471     if ( $cust_pkg->change_pkgnum
 472         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 473         and $cust_pkg->change_date <  $invoice_time
 474       and $conf->exists('pkg-balances') )
 475     {
 476       # _transfer_balance will also create the appropriate credit
 477       my @transfer_items = $self->_transfer_balance($cust_pkg);
 478       # $part_pkg[0] is the "real" part_pkg
 479       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 480                   'no_auto' : '';
 481       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 482       # treating this as recur, just because most charges are recur...
 483       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 484     }
 485
 486     foreach my $part_pkg ( @part_pkg ) {
 487
 488       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 489
 490       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 491
 492       my $next_bill = $cust_pkg->getfield('bill') || 0;
 493       my $error;
 494       # let this run once if this is the last bill upon cancellation
 495       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 496         $error =
 497           $self->_make_lines( 'part_pkg'            => $part_pkg,
 498                               'cust_pkg'            => $cust_pkg,
 499                               'precommit_hooks'     => \@precommit_hooks,
 500                               'line_items'          => $cust_bill_pkg{$pass},
 501                               'setup'               => $total_setup{$pass},
 502                               'recur'               => $total_recur{$pass},
 503                               'tax_matrix'          => $taxlisthash{$pass},
 504                               'time'                => $time,
 505                               'real_pkgpart'        => $real_pkgpart,
 506                               'options'             => \%options,
 507                             );
 508
 509         # Stop if anything goes wrong
 510         last if $error;
 511
 512         # or if we're not incrementing the bill date.
 513         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 514
 515         # or if we're letting it run only once
 516         last if $options{cancel};
 517
 518         $next_bill = $cust_pkg->getfield('bill') || 0;
 519
 520         #stop if -o was passed to freeside-daily
 521         last if $options{'one_recur'};
 522       }
 523       if ($error) {
 524         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 525         return $error;
 526       }
 527
 528     } #foreach my $part_pkg
 529
 530   } #foreach my $cust_pkg
 531
 532   #if the customer isn't on an automatic payby, everything can go on a single
 533   #invoice anyway?
 534   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 535     #merge everything into one list
 536   #}
 537
 538   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 539
 540     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 541
 542     warn "$me billing pass $pass\n"
 543            #.Dumper(\@cust_bill_pkg)."\n"
 544       if $DEBUG > 2;
 545
 546     ###
 547     # process fees
 548     ###
 549
 550     my @pending_event_fees = FS::cust_event_fee->by_cust($self->custnum,
 551       hashref => { 'billpkgnum' => '' }
 552     );
 553     warn "$me found pending fee events:\n".Dumper(\@pending_event_fees)."\n"
 554       if @pending_event_fees and $DEBUG > 1;
 555
 556     # determine whether to generate an invoice
 557     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 558
 559     foreach my $event_fee (@pending_event_fees) {
 560       $generate_bill = 1 unless $event_fee->nextbill;
 561     }
 562
 563     # don't create an invoice with no line items, or where the only line
 564     # items are fees that are supposed to be held until the next invoice
 565     next if !$generate_bill;
 566
 567     # calculate fees...
 568     my @fee_items;
 569     foreach my $event_fee (@pending_event_fees) {
 570       my $object = $event_fee->cust_event->cust_X;
 571       my $part_fee = $event_fee->part_fee;
 572       my $cust_bill;
 573       if ( $object->isa('FS::cust_main')
 574            or $object->isa('FS::cust_pkg')
 575            or $object->isa('FS::cust_pay_batch') )
 576       {
 577         # Not the real cust_bill object that will be inserted--in particular
 578         # there are no taxes yet.  If you want to charge a fee on the total
 579         # invoice amount including taxes, you have to put the fee on the next
 580         # invoice.
 581         $cust_bill = FS::cust_bill->new({
 582             'custnum'       => $self->custnum,
 583             'cust_bill_pkg' => \@cust_bill_pkg,
 584             'charged'       => ${ $total_setup{$pass} } +
 585                                ${ $total_recur{$pass} },
 586         });
 587
 588         # If this is a package event, only apply the fee to line items
 589         # from that package.
 590         if ($object->isa('FS::cust_pkg')) {
 591           $cust_bill->set('cust_bill_pkg',
 592             [ grep  { $_->pkgnum == $object->pkgnum } @cust_bill_pkg ]
 593           );
 594         }
 595
 596       } elsif ( $object->isa('FS::cust_bill') ) {
 597         # simple case: applying the fee to a previous invoice (late fee,
 598         # etc.)
 599         $cust_bill = $object;
 600       }
 601       # if the fee def belongs to a different agent, don't charge the fee.
 602       # event conditions should prevent this, but just in case they don't,
 603       # skip the fee.
 604       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 605         warn "tried to charge fee#".$part_fee->feepart .
 606              " on customer#".$self->custnum." from a different agent.\n";
 607         next;
 608       }
 609       # also skip if it's disabled
 610       next if $part_fee->disabled eq 'Y';
 611       # calculate the fee
 612       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 613       # link this so that we can clear the marker on inserting the line item
 614       $fee_item->set('cust_event_fee', $event_fee);
 615       push @fee_items, $fee_item;
 616
 617     }
 618
 619     # add fees to the invoice
 620     foreach my $fee_item (@fee_items) {
 621
 622       push @cust_bill_pkg, $fee_item;
 623       ${ $total_setup{$pass} } += $fee_item->setup;
 624       ${ $total_recur{$pass} } += $fee_item->recur;
 625
 626       my $part_fee = $fee_item->part_fee;
 627       my $fee_location = $self->ship_location; # I think?
 628
 629       my $error = $self->_handle_taxes(
 630         $taxlisthash{$pass},
 631         $fee_item,
 632         location => $fee_location
 633         # probably not right to pass cancel => 1 for fees
 634       );
 635       return $error if $error;
 636
 637     }
 638
 639     # XXX implementation of fees is supposed to make this go away...
 640     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 641            !$conf->exists('postal_invoice-recurring_only')
 642        )
 643     {
 644
 645       my $postal_pkg = $self->charge_postal_fee();
 646       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 647
 648         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 649         return "can't charge postal invoice fee for customer ".
 650           $self->custnum. ": $postal_pkg";
 651
 652       } elsif ( $postal_pkg ) {
 653
 654         my $real_pkgpart = $postal_pkg->pkgpart;
 655         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 656         # suffer from performance issues
 657         $options{has_hidden} = 0;
 658         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 659         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 660
 661         foreach my $part_pkg ( @part_pkg ) {
 662           my %postal_options = %options;
 663           delete $postal_options{cancel};
 664           my $error =
 665             $self->_make_lines( 'part_pkg'            => $part_pkg,
 666                                 'cust_pkg'            => $postal_pkg,
 667                                 'precommit_hooks'     => \@precommit_hooks,
 668                                 'line_items'          => \@cust_bill_pkg,
 669                                 'setup'               => $total_setup{$pass},
 670                                 'recur'               => $total_recur{$pass},
 671                                 'tax_matrix'          => $taxlisthash{$pass},
 672                                 'time'                => $time,
 673                                 'real_pkgpart'        => $real_pkgpart,
 674                                 'options'             => \%postal_options,
 675                               );
 676           if ($error) {
 677             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 678             return $error;
 679           }
 680         }
 681
 682         # it's silly to have a zero value postal_pkg, but....
 683         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 684
 685       }
 686
 687     }
 688
 689     my $listref_or_error =
 690       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 691
 692     unless ( ref( $listref_or_error ) ) {
 693       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 694       return $listref_or_error;
 695     }
 696
 697     foreach my $taxline ( @$listref_or_error ) {
 698       ${ $total_setup{$pass} } =
 699         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 700       push @cust_bill_pkg, $taxline;
 701     }
 702
 703     #add tax adjustments
 704     warn "adding tax adjustments...\n" if $DEBUG > 2;
 705     foreach my $cust_tax_adjustment (
 706       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 707                                        'billpkgnum' => '',
 708                                      }
 709              )
 710     ) {
 711
 712       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 713
 714       my $itemdesc = $cust_tax_adjustment->taxname;
 715       $itemdesc = '' if $itemdesc eq 'Tax';
 716
 717       push @cust_bill_pkg, new FS::cust_bill_pkg {
 718         'pkgnum'      => 0,
 719         'setup'       => $tax,
 720         'recur'       => 0,
 721         'sdate'       => '',
 722         'edate'       => '',
 723         'itemdesc'    => $itemdesc,
 724         'itemcomment' => $cust_tax_adjustment->comment,
 725         'cust_tax_adjustment' => $cust_tax_adjustment,
 726         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 727       };
 728
 729     }
 730
 731     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 732
 733     my @cust_bill = $self->cust_bill;
 734     my $balance = $self->balance;
 735     my $previous_bill = $cust_bill[-1] if @cust_bill;
 736     my $previous_balance = 0;
 737     if ( $previous_bill ) {
 738       $previous_balance = $previous_bill->billing_balance
 739                         + $previous_bill->charged;
 740     }
 741
 742     warn "creating the new invoice\n" if $DEBUG;
 743     #create the new invoice
 744     my $cust_bill = new FS::cust_bill ( {
 745       'custnum'             => $self->custnum,
 746       '_date'               => $invoice_time,
 747       'charged'             => $charged,
 748       'billing_balance'     => $balance,
 749       'previous_balance'    => $previous_balance,
 750       'invoice_terms'       => $options{'invoice_terms'},
 751       'cust_bill_pkg'       => \@cust_bill_pkg,
 752     } );
 753     $error = $cust_bill->insert unless $options{no_commit};
 754     if ( $error ) {
 755       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 756       return "can't create invoice for customer #". $self->custnum. ": $error";
 757     }
 758     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 759
 760   } #foreach my $pass ( keys %cust_bill_pkg )
 761
 762   foreach my $hook ( @precommit_hooks ) {
 763     eval {
 764       &{$hook}; #($self) ?
 765     } unless $options{no_commit};
 766     if ( $@ ) {
 767       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 768       return "$@ running precommit hook $hook\n";
 769     }
 770   }
 771
 772   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 773
 774   ''; #no error
 775 }
 776
 777 #discard bundled packages of 0 value
 778 sub _omit_zero_value_bundles {
 779   my @in = @_;
 780
 781   my @cust_bill_pkg = ();
 782   my @cust_bill_pkg_bundle = ();
 783   my $sum = 0;
 784   my $discount_show_always = 0;
 785
 786   foreach my $cust_bill_pkg ( @in ) {
 787
 788     $discount_show_always = ($cust_bill_pkg->get('discounts')
 789                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 790                                 && $conf->exists('discount-show-always'));
 791
 792     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 793          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 794          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 795       if $DEBUG > 0;
 796
 797     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 798       push @cust_bill_pkg, @cust_bill_pkg_bundle
 799         if $sum > 0
 800         || ($sum == 0 && (    $discount_show_always
 801                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 802                                    @cust_bill_pkg_bundle
 803                          )
 804            );
 805       @cust_bill_pkg_bundle = ();
 806       $sum = 0;
 807     }
 808
 809     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 810     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 811
 812   }
 813
 814   push @cust_bill_pkg, @cust_bill_pkg_bundle
 815     if $sum > 0
 816     || ($sum == 0 && (    $discount_show_always
 817                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 818                                @cust_bill_pkg_bundle
 819                      )
 820        );
 821
 822   warn "  _omit_zero_value_bundles: ". scalar(@in).
 823        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 824     if $DEBUG > 2;
 825
 826   (@cust_bill_pkg);
 827
 828 }
 829
 830 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 831
 832 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 833 Usually used internally by bill method B<bill>.
 834
 835 If there is an error, returns the error, otherwise returns reference to a
 836 list of line items suitable for insertion.
 837
 838 =over 4
 839
 840 =item LINEITEMREF
 841
 842 An array ref of the line items being billed.
 843
 844 =item TAXHASHREF
 845
 846 A strange beast.  The keys to this hash are internal identifiers consisting
 847 of the name of the tax object type, a space, and its unique identifier ( e.g.
 848  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 849 item in the list is the tax object.  The remaining items are either line
 850 items or floating point values (currency amounts).
 851
 852 The taxes are calculated on this entity.  Calculated exemption records are
 853 transferred to the LINEITEMREF items on the assumption that they are related.
 854
 855 Read the source.
 856
 857 =item INVOICE_TIME
 858
 859 This specifies the date appearing on the associated invoice.  Some
 860 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 861
 862 =back
 863
 864 =cut
 865
 866 sub calculate_taxes {
 867   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 868
 869   # $taxlisthash is a hashref
 870   # keys are identifiers, values are arrayrefs
 871   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 872   # then any cust_bill_pkg objects the tax applies to
 873
 874   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 875
 876   warn "$me calculate_taxes\n"
 877        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 878     if $DEBUG > 2;
 879
 880   my @tax_line_items = ();
 881
 882   # keys are tax names (as printed on invoices / itemdesc )
 883   # values are arrayrefs of taxlisthash keys (internal identifiers)
 884   my %taxname = ();
 885
 886   # keys are taxlisthash keys (internal identifiers)
 887   # values are (cumulative) amounts
 888   my %tax_amount = ();
 889
 890   # keys are taxlisthash keys (internal identifiers)
 891   # values are arrayrefs of cust_bill_pkg_tax_location hashrefs
 892   my %tax_location = ();
 893
 894   # keys are taxlisthash keys (internal identifiers)
 895   # values are arrayrefs of cust_bill_pkg_tax_rate_location hashrefs
 896   my %tax_rate_location = ();
 897
 898   # keys are taxlisthash keys (internal identifiers!)
 899   # values are arrayrefs of cust_tax_exempt_pkg objects
 900   my %tax_exemption;
 901
 902   foreach my $tax ( keys %$taxlisthash ) {
 903     # $tax is a tax identifier (intersection of a tax definition record
 904     # and a cust_bill_pkg record)
 905     my $tax_object = shift @{ $taxlisthash->{$tax} };
 906     # $tax_object is a cust_main_county or tax_rate
 907     # (with billpkgnum, pkgnum, locationnum set)
 908     # the rest of @{ $taxlisthash->{$tax} } is cust_bill_pkg component objects
 909     # (setup, recurring, usage classes)
 910     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 911     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 912     # taxline calculates the tax on all cust_bill_pkgs in the
 913     # first (arrayref) argument, and returns a hashref of 'name'
 914     # (the line item description) and 'amount'.
 915     # It also calculates exemptions and attaches them to the cust_bill_pkgs
 916     # in the argument.
 917     my $taxables = $taxlisthash->{$tax};
 918     my $exemptions = $tax_exemption{$tax} ||= [];
 919     my $taxline = $tax_object->taxline(
 920                             $taxables,
 921                             'custnum'      => $self->custnum,
 922                             'invoice_time' => $invoice_time,
 923                             'exemptions'   => $exemptions,
 924                           );
 925     return $taxline unless ref($taxline);
 926
 927     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 928
 929     if ( $tax_object->isa('FS::cust_main_county') ) {
 930       # then $taxline is a real line item
 931       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 932
 933     } else {
 934       # leave this as is for now
 935
 936       my $name   = $taxline->{'name'};
 937       my $amount = $taxline->{'amount'};
 938
 939       #warn "adding $amount as $name\n";
 940       $taxname{ $name } ||= [];
 941       push @{ $taxname{ $name } }, $tax;
 942
 943       $tax_amount{ $tax } += $amount;
 944
 945       # link records between cust_main_county/tax_rate and cust_location
 946       $tax_rate_location{ $tax } ||= [];
 947       my $taxratelocationnum =
 948         $tax_object->tax_rate_location->taxratelocationnum;
 949       push @{ $tax_rate_location{ $tax }  },
 950         {
 951           'taxnum'             => $tax_object->taxnum,
 952           'taxtype'            => ref($tax_object),
 953           'amount'             => sprintf('%.2f', $amount ),
 954           'locationtaxid'      => $tax_object->location,
 955           'taxratelocationnum' => $taxratelocationnum,
 956         };
 957     } #if ref($tax_object)...
 958   } #foreach keys %$taxlisthash
 959
 960   #consolidate and create tax line items
 961   warn "consolidating and generating...\n" if $DEBUG > 2;
 962   foreach my $taxname ( keys %taxname ) {
 963     my @cust_bill_pkg_tax_location;
 964     my @cust_bill_pkg_tax_rate_location;
 965     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
 966         'pkgnum'    => 0,
 967         'recur'     => 0,
 968         'sdate'     => '',
 969         'edate'     => '',
 970         'itemdesc'  => $taxname,
 971         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
 972         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 973     });
 974
 975     my $tax_total = 0;
 976     my %seen = ();
 977     warn "adding $taxname\n" if $DEBUG > 1;
 978     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 979       if ( ref($taxitem) eq 'FS::cust_bill_pkg' ) {
 980         # then we need to transfer the amount and the links from the
 981         # line item to the new one we're creating.
 982         $tax_total += $taxitem->setup;
 983         foreach my $link ( @{ $taxitem->get('cust_bill_pkg_tax_location') } ) {
 984           $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
 985           push @cust_bill_pkg_tax_location, $link;
 986         }
 987       } else {
 988         # the tax_rate way
 989         next if $seen{$taxitem}++;
 990         warn "adding $tax_amount{$taxitem}\n" if $DEBUG > 1;
 991         $tax_total += $tax_amount{$taxitem};
 992         push @cust_bill_pkg_tax_rate_location,
 993           map { new FS::cust_bill_pkg_tax_rate_location $_ }
 994               @{ $tax_rate_location{ $taxitem } };
 995       }
 996     }
 997     next unless $tax_total;
 998
 999     # we should really neverround this up...I guess it's okay if taxline
1000     # already returns amounts with 2 decimal places
1001     $tax_total = sprintf('%.2f', $tax_total );
1002     $tax_cust_bill_pkg->set('setup', $tax_total);
1003
1004     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1005                                                    'disabled'     => '',
1006                                                  },
1007                                );
1008
1009     my @display = ();
1010     if ( $pkg_category and
1011          $conf->config('invoice_latexsummary') ||
1012          $conf->config('invoice_htmlsummary')
1013        )
1014     {
1015
1016       my %hash = (  'section' => $pkg_category->categoryname );
1017       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1018
1019     }
1020     $tax_cust_bill_pkg->set('display', \@display);
1021
1022     push @tax_line_items, $tax_cust_bill_pkg;
1023   }
1024
1025   \@tax_line_items;
1026 }
1027
1028 sub _make_lines {
1029   my ($self, %params) = @_;
1030
1031   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1032
1033   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1034   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1035   my $cust_location = $cust_pkg->tax_location;
1036   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1037   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1038   my $total_setup = $params{setup} or die "no setup accumulator specified";
1039   my $total_recur = $params{recur} or die "no recur accumulator specified";
1040   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1041   my $time = $params{'time'} or die "no time specified";
1042   my (%options) = %{$params{options}};
1043
1044   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1045     # this should never happen
1046     die 'freq_override billing attempted on non-monthly package '.
1047       $cust_pkg->pkgnum;
1048   }
1049
1050   my $dbh = dbh;
1051   my $real_pkgpart = $params{real_pkgpart};
1052   my %hash = $cust_pkg->hash;
1053   my $old_cust_pkg = new FS::cust_pkg \%hash;
1054
1055   my @details = ();
1056   my $lineitems = 0;
1057
1058   $cust_pkg->pkgpart($part_pkg->pkgpart);
1059
1060   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1061                      ? day_end( $time )
1062                      : $time
1063                  );
1064
1065   ###
1066   # bill setup
1067   ###
1068
1069   my $setup = 0;
1070   my $unitsetup = 0;
1071   my @setup_discounts = ();
1072   my %setup_param = ( 'discounts' => \@setup_discounts );
1073   if (     ! $options{recurring_only}
1074        and ! $options{cancel}
1075        and ( $options{'resetup'}
1076              || ( ! $cust_pkg->setup
1077                   && ( ! $cust_pkg->start_date
1078                        || $cust_pkg->start_date <= $cmp_time
1079                      )
1080                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
1081                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
1082                             ! $cust_pkg->getfield('susp')
1083                           )
1084                      )
1085                 )
1086            )
1087      )
1088   {
1089
1090     warn "    bill setup\n" if $DEBUG > 1;
1091
1092     unless ( $cust_pkg->waive_setup ) {
1093         $lineitems++;
1094
1095         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1096         return "$@ running calc_setup for $cust_pkg\n"
1097           if $@;
1098
1099         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
1100     }
1101
1102     $cust_pkg->setfield('setup', $time)
1103       unless $cust_pkg->setup;
1104           #do need it, but it won't get written to the db
1105           #|| $cust_pkg->pkgpart != $real_pkgpart;
1106
1107     $cust_pkg->setfield('start_date', '')
1108       if $cust_pkg->start_date;
1109
1110   }
1111
1112   ###
1113   # bill recurring fee
1114   ###
1115
1116   my $recur = 0;
1117   my $unitrecur = 0;
1118   my @recur_discounts = ();
1119   my $sdate;
1120   if (     ! $cust_pkg->start_date
1121        and
1122            ( ! $cust_pkg->susp
1123                || ( $cust_pkg->susp != $cust_pkg->order_date
1124                       && (    $cust_pkg->option('suspend_bill',1)
1125                            || ( $part_pkg->option('suspend_bill', 1)
1126                                  && ! $cust_pkg->option('no_suspend_bill',1)
1127                               )
1128                          )
1129                   )
1130            )
1131        and
1132             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1133          || ( $part_pkg->plan eq 'voip_cdr'
1134                && $part_pkg->option('bill_every_call')
1135             )
1136          || $options{cancel}
1137   ) {
1138
1139     # XXX should this be a package event?  probably.  events are called
1140     # at collection time at the moment, though...
1141     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1142       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1143       #don't want to reset usage just cause we want a line item??
1144       #&& $part_pkg->pkgpart == $real_pkgpart;
1145
1146     warn "    bill recur\n" if $DEBUG > 1;
1147     $lineitems++;
1148
1149     # XXX shared with $recur_prog
1150     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1151              || $cust_pkg->setup
1152              || $time;
1153
1154     #over two params!  lets at least switch to a hashref for the rest...
1155     my $increment_next_bill = ( $part_pkg->freq ne '0'
1156                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1157                                 && !$options{cancel}
1158                               );
1159     my %param = ( %setup_param,
1160                   'precommit_hooks'     => $precommit_hooks,
1161                   'increment_next_bill' => $increment_next_bill,
1162                   'discounts'           => \@recur_discounts,
1163                   'real_pkgpart'        => $real_pkgpart,
1164                   'freq_override'       => $options{freq_override} || '',
1165                   'setup_fee'           => 0,
1166                 );
1167
1168     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1169
1170     # There may be some part_pkg for which this is wrong.  Only those
1171     # which can_discount are supported.
1172     # (the UI should prevent adding discounts to these at the moment)
1173
1174     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1175          " for pkgpart ". $cust_pkg->pkgpart.
1176          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1177       if $DEBUG > 2;
1178
1179     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1180     return "$@ running $method for $cust_pkg\n"
1181       if ( $@ );
1182
1183     #base_cancel???
1184     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1185
1186     if ( $increment_next_bill ) {
1187
1188       my $next_bill;
1189
1190       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1191         # supplemental package
1192         # to keep in sync with the main package, simulate billing at
1193         # its frequency
1194         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1195         my $supp_pkg_freq = $part_pkg->freq;
1196         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1197         if ( $ratio != int($ratio) ) {
1198           # the UI should prevent setting up packages like this, but just
1199           # in case
1200           return "supplemental package period is not an integer multiple of main  package period";
1201         }
1202         $next_bill = $sdate;
1203         for (1..$ratio) {
1204           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1205         }
1206
1207       } else {
1208         # the normal case
1209       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1210       return "unparsable frequency: ". $part_pkg->freq
1211         if $next_bill == -1;
1212       }
1213
1214       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1215       # only for figuring next bill date, nothing else, so, reset $sdate again
1216       # here
1217       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1218       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1219       $cust_pkg->last_bill($sdate);
1220
1221       $cust_pkg->setfield('bill', $next_bill );
1222
1223     }
1224
1225     if ( $param{'setup_fee'} ) {
1226       # Add an additional setup fee at the billing stage.
1227       # Used for prorate_defer_bill.
1228       $setup += $param{'setup_fee'};
1229       $unitsetup += $param{'setup_fee'};
1230       $lineitems++;
1231     }
1232
1233     if ( defined $param{'discount_left_setup'} ) {
1234         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1235             $setup -= $discount_setup;
1236         }
1237     }
1238
1239   }
1240
1241   warn "\$setup is undefined" unless defined($setup);
1242   warn "\$recur is undefined" unless defined($recur);
1243   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1244
1245   ###
1246   # If there's line items, create em cust_bill_pkg records
1247   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1248   ###
1249
1250   if ( $lineitems ) {
1251
1252     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1253       # hmm.. and if just the options are modified in some weird price plan?
1254
1255       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1256         if $DEBUG >1;
1257
1258       my $error = $cust_pkg->replace( $old_cust_pkg,
1259                                       'depend_jobnum'=>$options{depend_jobnum},
1260                                       'options' => { $cust_pkg->options },
1261                                     )
1262         unless $options{no_commit};
1263       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1264         if $error; #just in case
1265     }
1266
1267     $setup = sprintf( "%.2f", $setup );
1268     $recur = sprintf( "%.2f", $recur );
1269     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1270       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1271     }
1272     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1273       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1274     }
1275
1276     my $discount_show_always = $conf->exists('discount-show-always')
1277                                && (    ($setup == 0 && scalar(@setup_discounts))
1278                                     || ($recur == 0 && scalar(@recur_discounts))
1279                                   );
1280
1281     if (    $setup != 0
1282          || $recur != 0
1283          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1284          || $discount_show_always
1285          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1286          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1287        )
1288     {
1289
1290       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1291         if $DEBUG > 1;
1292
1293       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1294       if ( $DEBUG > 1 ) {
1295         warn "      adding customer package invoice detail: $_\n"
1296           foreach @cust_pkg_detail;
1297       }
1298       push @details, @cust_pkg_detail;
1299
1300       my $cust_bill_pkg = new FS::cust_bill_pkg {
1301         'pkgnum'    => $cust_pkg->pkgnum,
1302         'setup'     => $setup,
1303         'unitsetup' => $unitsetup,
1304         'recur'     => $recur,
1305         'unitrecur' => $unitrecur,
1306         'quantity'  => $cust_pkg->quantity,
1307         'details'   => \@details,
1308         'discounts' => [ @setup_discounts, @recur_discounts ],
1309         'hidden'    => $part_pkg->hidden,
1310         'freq'      => $part_pkg->freq,
1311       };
1312
1313       if ( $part_pkg->option('prorate_defer_bill',1)
1314            and !$hash{last_bill} ) {
1315         # both preceding and upcoming, technically
1316         $cust_bill_pkg->sdate( $cust_pkg->setup );
1317         $cust_bill_pkg->edate( $cust_pkg->bill );
1318       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1319         $cust_bill_pkg->sdate( $hash{last_bill} );
1320         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1321         $cust_bill_pkg->edate( $time ) if $options{cancel};
1322       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1323         $cust_bill_pkg->sdate( $sdate );
1324         $cust_bill_pkg->edate( $cust_pkg->bill );
1325         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1326       }
1327
1328       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1329         unless $part_pkg->pkgpart == $real_pkgpart;
1330
1331       $$total_setup += $setup;
1332       $$total_recur += $recur;
1333
1334       ###
1335       # handle taxes
1336       ###
1337
1338       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg,
1339         cancel => $options{cancel} );
1340       return $error if $error;
1341
1342       $cust_bill_pkg->set_display(
1343         part_pkg     => $part_pkg,
1344         real_pkgpart => $real_pkgpart,
1345       );
1346
1347       push @$cust_bill_pkgs, $cust_bill_pkg;
1348
1349     } #if $setup != 0 || $recur != 0
1350
1351   } #if $line_items
1352
1353   '';
1354
1355 }
1356
1357 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1358
1359 Takes one argument, a cust_pkg object that is being billed.  This will
1360 be called only if the package was created by a package change, and has
1361 not been billed since the package change, and package balance tracking
1362 is enabled.  The second argument can be an alternate package number to
1363 transfer the balance from; this should not be used externally.
1364
1365 Transfers the balance from the previous package (now canceled) to
1366 this package, by crediting one package and creating an invoice item for
1367 the other.  Inserts the credit and returns the invoice item (so that it
1368 can be added to an invoice that's being built).
1369
1370 If the previous package was never billed, and was also created by a package
1371 change, then this will also transfer the balance from I<its> previous
1372 package, and so on, until reaching a package that either has been billed
1373 or was not created by a package change.
1374
1375 =cut
1376
1377 my $balance_transfer_reason;
1378
1379 sub _transfer_balance {
1380   my $self = shift;
1381   my $cust_pkg = shift;
1382   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1383   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1384
1385   my @transfers;
1386
1387   # if $from_pkg is not the first package in the chain, and it was never
1388   # billed, walk back
1389   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1390     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1391   }
1392
1393   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1394   if ( $prev_balance != 0 ) {
1395     $balance_transfer_reason ||= FS::reason->new_or_existing(
1396       'reason' => 'Package balance transfer',
1397       'type'   => 'Internal adjustment',
1398       'class'  => 'R'
1399     );
1400
1401     my $credit = FS::cust_credit->new({
1402         'custnum'   => $self->custnum,
1403         'amount'    => abs($prev_balance),
1404         'reasonnum' => $balance_transfer_reason->reasonnum,
1405         '_date'     => $cust_pkg->change_date,
1406     });
1407
1408     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1409         'setup'     => 0,
1410         'recur'     => abs($prev_balance),
1411         #'sdate'     => $from_pkg->last_bill, # not sure about this
1412         #'edate'     => $cust_pkg->change_date,
1413         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1414                                  $from_pkg->part_pkg->pkg),
1415     });
1416
1417     if ( $prev_balance > 0 ) {
1418       # credit the old package, charge the new one
1419       $credit->set('pkgnum', $from_pkgnum);
1420       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1421     } else {
1422       # the reverse
1423       $credit->set('pkgnum', $cust_pkg->pkgnum);
1424       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1425     }
1426     my $error = $credit->insert;
1427     die "error transferring package balance from #".$from_pkgnum.
1428         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1429
1430     push @transfers, $cust_bill_pkg;
1431   } # $prev_balance != 0
1432
1433   return @transfers;
1434 }
1435
1436 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1437
1438 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1439 from _make_lines.
1440
1441 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1442 this:
1443 {
1444   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1445   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1446 }
1447
1448 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1449 is always the cust_main_county or tax_rate identified by the key.
1450
1451 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1452 the 'taxline' method to calculate the amount of the tax.  This doesn't
1453 happen until calculate_taxes, though.
1454
1455 OPTIONS may include:
1456 - part_item: a part_pkg or part_fee object to be used as the package/fee
1457   definition.
1458 - location: a cust_location to be used as the billing location.
1459 - cancel: true if this package is being billed on cancellation.  This
1460   allows tax to be calculated on usage charges only.
1461
1462 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1463 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1464 the customer's default service location).
1465
1466 =cut
1467
1468 sub _handle_taxes {
1469   my $self = shift;
1470   my $taxlisthash = shift;
1471   my $cust_bill_pkg = shift;
1472   my %options = @_;
1473
1474   # at this point I realize that we have enough information to infer all this
1475   # stuff, instead of passing around giant honking argument lists
1476   my $location = $options{location} || $cust_bill_pkg->tax_location;
1477   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1478
1479   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1480
1481   return if ( $self->payby eq 'COMP' ); #dubious
1482
1483   if ( $conf->exists('enable_taxproducts')
1484        && ( scalar($part_item->part_pkg_taxoverride)
1485             || $part_item->has_taxproduct
1486           )
1487      )
1488     {
1489
1490     # EXTERNAL TAX RATES (via tax_rate)
1491     my %cust_bill_pkg = ();
1492     my %taxes = ();
1493
1494     my @classes;
1495     push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1496     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1497     push @classes, 'recur' if $cust_bill_pkg->recur and !$options{cancel};
1498
1499     my $exempt = $conf->exists('cust_class-tax_exempt')
1500                    ? ( $self->cust_class ? $self->cust_class->tax : '' )
1501                    : $self->tax;
1502     # standardize this just to be sure
1503     $exempt = ($exempt eq 'Y') ? 'Y' : '';
1504
1505     if ( !$exempt ) {
1506
1507       foreach my $class (@classes) {
1508         my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1509         return $err_or_ref unless ref($err_or_ref);
1510         $taxes{$class} = $err_or_ref;
1511       }
1512
1513       unless (exists $taxes{''}) {
1514         my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1515         return $err_or_ref unless ref($err_or_ref);
1516         $taxes{''} = $err_or_ref;
1517       }
1518
1519     }
1520
1521     my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate; # grrr
1522     foreach my $key (keys %tax_cust_bill_pkg) {
1523       # $key is "setup", "recur", or a usage class name. ('' is a usage class.)
1524       # $tax_cust_bill_pkg{$key} is a cust_bill_pkg for that component of
1525       # the line item.
1526       # $taxes{$key} is an arrayref of cust_main_county or tax_rate objects that
1527       # apply to $key-class charges.
1528       my @taxes = @{ $taxes{$key} || [] };
1529       my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1530
1531       my %localtaxlisthash = ();
1532       foreach my $tax ( @taxes ) {
1533
1534         # this is the tax identifier, not the taxname
1535         my $taxname = ref( $tax ). ' '. $tax->taxnum;
1536         # $taxlisthash: keys are "setup", "recur", and usage classes.
1537         # Values are arrayrefs, first the tax object (cust_main_county
1538         # or tax_rate) and then any cust_bill_pkg objects that the
1539         # tax applies to.
1540         $taxlisthash->{ $taxname } ||= [ $tax ];
1541         push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1542
1543         $localtaxlisthash{ $taxname } ||= [ $tax ];
1544         push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1545
1546       }
1547
1548       warn "finding taxed taxes...\n" if $DEBUG > 2;
1549       foreach my $tax ( keys %localtaxlisthash ) {
1550         my $tax_object = shift @{ $localtaxlisthash{$tax} };
1551         warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1552           if $DEBUG > 2;
1553         next unless $tax_object->can('tax_on_tax');
1554
1555         foreach my $tot ( $tax_object->tax_on_tax( $location ) ) {
1556           my $totname = ref( $tot ). ' '. $tot->taxnum;
1557
1558           warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1559             if $DEBUG > 2;
1560           next unless exists( $localtaxlisthash{ $totname } ); # only increase
1561                                                                # existing taxes
1562           warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1563           # calculate the tax amount that the tax_on_tax will apply to
1564           my $hashref_or_error =
1565             $tax_object->taxline( $localtaxlisthash{$tax} );
1566           return $hashref_or_error
1567             unless ref($hashref_or_error);
1568
1569           # and append it to the list of taxable items
1570           $taxlisthash->{ $totname } ||= [ $tot ];
1571           push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1572
1573         }
1574       }
1575     }
1576
1577   } else {
1578
1579     # INTERNAL TAX RATES (cust_main_county)
1580
1581     # We fetch taxes even if the customer is completely exempt,
1582     # because we need to record that fact.
1583
1584     my @loc_keys = qw( district city county state country );
1585     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1586
1587     $taxhash{'taxclass'} = $part_item->taxclass;
1588
1589     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1590
1591     my @taxes = (); # entries are cust_main_county objects
1592     my %taxhash_elim = %taxhash;
1593     my @elim = qw( district city county state );
1594     do {
1595
1596       #first try a match with taxclass
1597       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1598
1599       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1600         #then try a match without taxclass
1601         my %no_taxclass = %taxhash_elim;
1602         $no_taxclass{ 'taxclass' } = '';
1603         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1604       }
1605
1606       $taxhash_elim{ shift(@elim) } = '';
1607
1608     } while ( !scalar(@taxes) && scalar(@elim) );
1609
1610     foreach (@taxes) {
1611       my $tax_id = 'cust_main_county '.$_->taxnum;
1612       $taxlisthash->{$tax_id} ||= [ $_ ];
1613       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1614     }
1615
1616   }
1617   '';
1618 }
1619
1620 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1621
1622 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1623 or part_fee (which will define the tax eligibility of the product), CLASS is
1624 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1625 location where the service was provided (or billed, depending on
1626 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1627 can apply to this line item.
1628
1629 =cut
1630
1631 sub _gather_taxes {
1632   my $self = shift;
1633   my $part_item = shift;
1634   my $class = shift;
1635   my $location = shift;
1636
1637   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1638
1639   my $geocode = $location->geocode('cch');
1640
1641   [ $part_item->tax_rates('cch', $geocode, $class) ]
1642
1643 }
1644
1645 =item collect [ HASHREF | OPTION => VALUE ... ]
1646
1647 (Attempt to) collect money for this customer's outstanding invoices (see
1648 L<FS::cust_bill>).  Usually used after the bill method.
1649
1650 Actions are now triggered by billing events; see L<FS::part_event> and the
1651 billing events web interface.  Old-style invoice events (see
1652 L<FS::part_bill_event>) have been deprecated.
1653
1654 If there is an error, returns the error, otherwise returns false.
1655
1656 Options are passed as name-value pairs.
1657
1658 Currently available options are:
1659
1660 =over 4
1661
1662 =item invoice_time
1663
1664 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1665
1666 =item retry
1667
1668 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1669
1670 =item check_freq
1671
1672 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1673
1674 =item quiet
1675
1676 set true to surpress email card/ACH decline notices.
1677
1678 =item debug
1679
1680 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1681
1682 =back
1683
1684 # =item payby
1685 #
1686 # allows for one time override of normal customer billing method
1687
1688 =cut
1689
1690 sub collect {
1691   my( $self, %options ) = @_;
1692
1693   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1694
1695   my $invoice_time = $options{'invoice_time'} || time;
1696
1697   #put below somehow?
1698   local $SIG{HUP} = 'IGNORE';
1699   local $SIG{INT} = 'IGNORE';
1700   local $SIG{QUIT} = 'IGNORE';
1701   local $SIG{TERM} = 'IGNORE';
1702   local $SIG{TSTP} = 'IGNORE';
1703   local $SIG{PIPE} = 'IGNORE';
1704
1705   my $oldAutoCommit = $FS::UID::AutoCommit;
1706   local $FS::UID::AutoCommit = 0;
1707   my $dbh = dbh;
1708
1709   $self->select_for_update; #mutex
1710
1711   if ( $DEBUG ) {
1712     my $balance = $self->balance;
1713     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1714   }
1715
1716   if ( exists($options{'retry_card'}) ) {
1717     carp 'retry_card option passed to collect is deprecated; use retry';
1718     $options{'retry'} ||= $options{'retry_card'};
1719   }
1720   if ( exists($options{'retry'}) && $options{'retry'} ) {
1721     my $error = $self->retry_realtime;
1722     if ( $error ) {
1723       $dbh->rollback if $oldAutoCommit;
1724       return $error;
1725     }
1726   }
1727
1728   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1729
1730   #never want to roll back an event just because it returned an error
1731   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1732
1733   $self->do_cust_event(
1734     'debug'      => ( $options{'debug'} || 0 ),
1735     'time'       => $invoice_time,
1736     'check_freq' => $options{'check_freq'},
1737     'stage'      => 'collect',
1738   );
1739
1740 }
1741
1742 =item retry_realtime
1743
1744 Schedules realtime / batch  credit card / electronic check / LEC billing
1745 events for for retry.  Useful if card information has changed or manual
1746 retry is desired.  The 'collect' method must be called to actually retry
1747 the transaction.
1748
1749 Implementation details: For either this customer, or for each of this
1750 customer's open invoices, changes the status of the first "done" (with
1751 statustext error) realtime processing event to "failed".
1752
1753 =cut
1754
1755 sub retry_realtime {
1756   my $self = shift;
1757
1758   local $SIG{HUP} = 'IGNORE';
1759   local $SIG{INT} = 'IGNORE';
1760   local $SIG{QUIT} = 'IGNORE';
1761   local $SIG{TERM} = 'IGNORE';
1762   local $SIG{TSTP} = 'IGNORE';
1763   local $SIG{PIPE} = 'IGNORE';
1764
1765   my $oldAutoCommit = $FS::UID::AutoCommit;
1766   local $FS::UID::AutoCommit = 0;
1767   my $dbh = dbh;
1768
1769   #a little false laziness w/due_cust_event (not too bad, really)
1770
1771   # I guess this is always as of now?
1772   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1773   my $order = FS::part_event_condition->order_conditions_sql;
1774   my $mine =
1775   '( '
1776    . join ( ' OR ' , map {
1777     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1778     my $custnum = FS::part_event->eventtables_custnum->{$_};
1779     "( part_event.eventtable = " . dbh->quote($_)
1780     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1781     . " from $_ $cust_join"
1782     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1783    } FS::part_event->eventtables)
1784    . ') ';
1785
1786   #here is the agent virtualization
1787   my $agent_virt = " (    part_event.agentnum IS NULL
1788                        OR part_event.agentnum = ". $self->agentnum. ' )';
1789
1790   #XXX this shouldn't be hardcoded, actions should declare it...
1791   my @realtime_events = qw(
1792     cust_bill_realtime_card
1793     cust_bill_realtime_check
1794     cust_bill_realtime_lec
1795     cust_bill_batch
1796   );
1797
1798   my $is_realtime_event =
1799     ' part_event.action IN ( '.
1800         join(',', map "'$_'", @realtime_events ).
1801     ' ) ';
1802
1803   my $batch_or_statustext =
1804     "( part_event.action = 'cust_bill_batch'
1805        OR ( statustext IS NOT NULL AND statustext != '' )
1806      )";
1807
1808
1809   my @cust_event = qsearch({
1810     'table'     => 'cust_event',
1811     'select'    => 'cust_event.*',
1812     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1813     'hashref'   => { 'status' => 'done' },
1814     'extra_sql' => " AND $batch_or_statustext ".
1815                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1816   });
1817
1818   my %seen_invnum = ();
1819   foreach my $cust_event (@cust_event) {
1820
1821     #max one for the customer, one for each open invoice
1822     my $cust_X = $cust_event->cust_X;
1823     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1824                           ? $cust_X->invnum
1825                           : 0
1826                         }++
1827          or $cust_event->part_event->eventtable eq 'cust_bill'
1828             && ! $cust_X->owed;
1829
1830     my $error = $cust_event->retry;
1831     if ( $error ) {
1832       $dbh->rollback if $oldAutoCommit;
1833       return "error scheduling event for retry: $error";
1834     }
1835
1836   }
1837
1838   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1839   '';
1840
1841 }
1842
1843 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1844
1845 Runs billing events; see L<FS::part_event> and the billing events web
1846 interface.
1847
1848 If there is an error, returns the error, otherwise returns false.
1849
1850 Options are passed as name-value pairs.
1851
1852 Currently available options are:
1853
1854 =over 4
1855
1856 =item time
1857
1858 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1859
1860 =item check_freq
1861
1862 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1863
1864 =item stage
1865
1866 "collect" (the default) or "pre-bill"
1867
1868 =item quiet
1869
1870 set true to surpress email card/ACH decline notices.
1871
1872 =item debug
1873
1874 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1875
1876 =back
1877 =cut
1878
1879 # =item payby
1880 #
1881 # allows for one time override of normal customer billing method
1882
1883 # =item retry
1884 #
1885 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1886
1887 sub do_cust_event {
1888   my( $self, %options ) = @_;
1889
1890   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1891
1892   my $time = $options{'time'} || time;
1893
1894   #put below somehow?
1895   local $SIG{HUP} = 'IGNORE';
1896   local $SIG{INT} = 'IGNORE';
1897   local $SIG{QUIT} = 'IGNORE';
1898   local $SIG{TERM} = 'IGNORE';
1899   local $SIG{TSTP} = 'IGNORE';
1900   local $SIG{PIPE} = 'IGNORE';
1901
1902   my $oldAutoCommit = $FS::UID::AutoCommit;
1903   local $FS::UID::AutoCommit = 0;
1904   my $dbh = dbh;
1905
1906   $self->select_for_update; #mutex
1907
1908   if ( $DEBUG ) {
1909     my $balance = $self->balance;
1910     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1911   }
1912
1913 #  if ( exists($options{'retry_card'}) ) {
1914 #    carp 'retry_card option passed to collect is deprecated; use retry';
1915 #    $options{'retry'} ||= $options{'retry_card'};
1916 #  }
1917 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1918 #    my $error = $self->retry_realtime;
1919 #    if ( $error ) {
1920 #      $dbh->rollback if $oldAutoCommit;
1921 #      return $error;
1922 #    }
1923 #  }
1924
1925   # false laziness w/pay_batch::import_results
1926
1927   my $due_cust_event = $self->due_cust_event(
1928     'debug'      => ( $options{'debug'} || 0 ),
1929     'time'       => $time,
1930     'check_freq' => $options{'check_freq'},
1931     'stage'      => ( $options{'stage'} || 'collect' ),
1932   );
1933   unless( ref($due_cust_event) ) {
1934     $dbh->rollback if $oldAutoCommit;
1935     return $due_cust_event;
1936   }
1937
1938   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1939   #never want to roll back an event just because it or a different one
1940   # returned an error
1941   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1942
1943   foreach my $cust_event ( @$due_cust_event ) {
1944
1945     #XXX lock event
1946
1947     #re-eval event conditions (a previous event could have changed things)
1948     unless ( $cust_event->test_conditions ) {
1949       #don't leave stray "new/locked" records around
1950       my $error = $cust_event->delete;
1951       return $error if $error;
1952       next;
1953     }
1954
1955     {
1956       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1957         if $options{'quiet'};
1958       warn "  running cust_event ". $cust_event->eventnum. "\n"
1959         if $DEBUG > 1;
1960
1961       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1962       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
1963         #XXX wtf is this?  figure out a proper dealio with return value
1964         #from do_event
1965         return $error;
1966       }
1967     }
1968
1969   }
1970
1971   '';
1972
1973 }
1974
1975 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1976
1977 Inserts database records for and returns an ordered listref of new events due
1978 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1979 events are due, an empty listref is returned.  If there is an error, returns a
1980 scalar error message.
1981
1982 To actually run the events, call each event's test_condition method, and if
1983 still true, call the event's do_event method.
1984
1985 Options are passed as a hashref or as a list of name-value pairs.  Available
1986 options are:
1987
1988 =over 4
1989
1990 =item check_freq
1991
1992 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1993
1994 =item stage
1995
1996 "collect" (the default) or "pre-bill"
1997
1998 =item time
1999
2000 "Current time" for the events.
2001
2002 =item debug
2003
2004 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2005
2006 =item eventtable
2007
2008 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2009
2010 =item objects
2011
2012 Explicitly pass the objects to be tested (typically used with eventtable).
2013
2014 =item testonly
2015
2016 Set to true to return the objects, but not actually insert them into the
2017 database.
2018
2019 =back
2020
2021 =cut
2022
2023 sub due_cust_event {
2024   my $self = shift;
2025   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2026
2027   #???
2028   #my $DEBUG = $opt{'debug'}
2029   $opt{'debug'} ||= 0; # silence some warnings
2030   local($DEBUG) = $opt{'debug'}
2031     if $opt{'debug'} > $DEBUG;
2032   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2033
2034   warn "$me due_cust_event called with options ".
2035        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2036     if $DEBUG;
2037
2038   $opt{'time'} ||= time;
2039
2040   local $SIG{HUP} = 'IGNORE';
2041   local $SIG{INT} = 'IGNORE';
2042   local $SIG{QUIT} = 'IGNORE';
2043   local $SIG{TERM} = 'IGNORE';
2044   local $SIG{TSTP} = 'IGNORE';
2045   local $SIG{PIPE} = 'IGNORE';
2046
2047   my $oldAutoCommit = $FS::UID::AutoCommit;
2048   local $FS::UID::AutoCommit = 0;
2049   my $dbh = dbh;
2050
2051   $self->select_for_update #mutex
2052     unless $opt{testonly};
2053
2054   ###
2055   # find possible events (initial search)
2056   ###
2057
2058   my @cust_event = ();
2059
2060   my @eventtable = $opt{'eventtable'}
2061                      ? ( $opt{'eventtable'} )
2062                      : FS::part_event->eventtables_runorder;
2063
2064   my $check_freq = $opt{'check_freq'} || '1d';
2065
2066   foreach my $eventtable ( @eventtable ) {
2067
2068     my @objects;
2069     if ( $opt{'objects'} ) {
2070
2071       @objects = @{ $opt{'objects'} };
2072
2073     } elsif ( $eventtable eq 'cust_main' ) {
2074
2075       @objects = ( $self );
2076
2077     } else {
2078
2079       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2080       # linkage not needed here because FS::cust_main->$eventtable will
2081       # already supply it
2082
2083       #some false laziness w/Cron::bill bill_where
2084
2085       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2086         'time' => $opt{'time'});
2087       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2088         'time'=>$opt{'time'},
2089       );
2090       $where = $where ? "AND $where" : '';
2091
2092       my $are_part_event =
2093       "EXISTS ( SELECT 1 FROM part_event $join
2094         WHERE check_freq = '$check_freq'
2095         AND eventtable = '$eventtable'
2096         AND ( disabled = '' OR disabled IS NULL )
2097         $where
2098         )
2099       ";
2100       #eofalse
2101
2102       @objects = $self->$eventtable(
2103         'addl_from' => $cm_join,
2104         'extra_sql' => " AND $are_part_event",
2105       );
2106     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2107
2108     my @e_cust_event = ();
2109
2110     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2111
2112     my $cross = "CROSS JOIN $eventtable $linkage";
2113     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2114       unless $eventtable eq 'cust_main';
2115
2116     foreach my $object ( @objects ) {
2117
2118       #this first search uses the condition_sql magic for optimization.
2119       #the more possible events we can eliminate in this step the better
2120
2121       my $cross_where = '';
2122       my $pkey = $object->primary_key;
2123       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2124
2125       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2126         'time' => $opt{'time'});
2127       my $extra_sql =
2128         FS::part_event_condition->where_conditions_sql( $eventtable,
2129                                                         'time'=>$opt{'time'}
2130                                                       );
2131       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2132
2133       $extra_sql = "AND $extra_sql" if $extra_sql;
2134
2135       #here is the agent virtualization
2136       $extra_sql .= " AND (    part_event.agentnum IS NULL
2137                             OR part_event.agentnum = ". $self->agentnum. ' )';
2138
2139       $extra_sql .= " $order";
2140
2141       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2142         if $opt{'debug'} > 2;
2143       my @part_event = qsearch( {
2144         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2145         'select'    => 'part_event.*',
2146         'table'     => 'part_event',
2147         'addl_from' => "$cross $join",
2148         'hashref'   => { 'check_freq' => $check_freq,
2149                          'eventtable' => $eventtable,
2150                          'disabled'   => '',
2151                        },
2152         'extra_sql' => "AND $cross_where $extra_sql",
2153       } );
2154
2155       if ( $DEBUG > 2 ) {
2156         my $pkey = $object->primary_key;
2157         warn "      ". scalar(@part_event).
2158              " possible events found for $eventtable ". $object->$pkey(). "\n";
2159       }
2160
2161       push @e_cust_event, map {
2162         $_->new_cust_event($object, 'time' => $opt{'time'})
2163       } @part_event;
2164
2165     }
2166
2167     warn "    ". scalar(@e_cust_event).
2168          " subtotal possible cust events found for $eventtable\n"
2169       if $DEBUG > 1;
2170
2171     push @cust_event, @e_cust_event;
2172
2173   }
2174
2175   warn "  ". scalar(@cust_event).
2176        " total possible cust events found in initial search\n"
2177     if $DEBUG; # > 1;
2178
2179
2180   ##
2181   # test stage
2182   ##
2183
2184   $opt{stage} ||= 'collect';
2185   @cust_event =
2186     grep { my $stage = $_->part_event->event_stage;
2187            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2188          }
2189          @cust_event;
2190
2191   ##
2192   # test conditions
2193   ##
2194
2195   my %unsat = ();
2196
2197   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2198                      @cust_event;
2199
2200   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2201     if $DEBUG; # > 1;
2202
2203   warn "    invalid conditions not eliminated with condition_sql:\n".
2204        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2205     if keys %unsat && $DEBUG; # > 1;
2206
2207   ##
2208   # insert
2209   ##
2210
2211   unless( $opt{testonly} ) {
2212     foreach my $cust_event ( @cust_event ) {
2213
2214       my $error = $cust_event->insert();
2215       if ( $error ) {
2216         $dbh->rollback if $oldAutoCommit;
2217         return $error;
2218       }
2219
2220     }
2221   }
2222
2223   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2224
2225   ##
2226   # return
2227   ##
2228
2229   warn "  returning events: ". Dumper(@cust_event). "\n"
2230     if $DEBUG > 2;
2231
2232   \@cust_event;
2233
2234 }
2235
2236 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2237
2238 Applies unapplied payments and credits.
2239
2240 In most cases, this new method should be used in place of sequential
2241 apply_payments and apply_credits methods.
2242
2243 A hash of optional arguments may be passed.  Currently "manual" is supported.
2244 If true, a payment receipt is sent instead of a statement when
2245 'payment_receipt_email' configuration option is set.
2246
2247 If there is an error, returns the error, otherwise returns false.
2248
2249 =cut
2250
2251 sub apply_payments_and_credits {
2252   my( $self, %options ) = @_;
2253
2254   local $SIG{HUP} = 'IGNORE';
2255   local $SIG{INT} = 'IGNORE';
2256   local $SIG{QUIT} = 'IGNORE';
2257   local $SIG{TERM} = 'IGNORE';
2258   local $SIG{TSTP} = 'IGNORE';
2259   local $SIG{PIPE} = 'IGNORE';
2260
2261   my $oldAutoCommit = $FS::UID::AutoCommit;
2262   local $FS::UID::AutoCommit = 0;
2263   my $dbh = dbh;
2264
2265   $self->select_for_update; #mutex
2266
2267   foreach my $cust_bill ( $self->open_cust_bill ) {
2268     my $error = $cust_bill->apply_payments_and_credits(%options);
2269     if ( $error ) {
2270       $dbh->rollback if $oldAutoCommit;
2271       return "Error applying: $error";
2272     }
2273   }
2274
2275   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2276   ''; #no error
2277
2278 }
2279
2280 =item apply_credits OPTION => VALUE ...
2281
2282 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2283 to outstanding invoice balances in chronological order (or reverse
2284 chronological order if the I<order> option is set to B<newest>) and returns the
2285 value of any remaining unapplied credits available for refund (see
2286 L<FS::cust_refund>).
2287
2288 Dies if there is an error.
2289
2290 =cut
2291
2292 sub apply_credits {
2293   my $self = shift;
2294   my %opt = @_;
2295
2296   local $SIG{HUP} = 'IGNORE';
2297   local $SIG{INT} = 'IGNORE';
2298   local $SIG{QUIT} = 'IGNORE';
2299   local $SIG{TERM} = 'IGNORE';
2300   local $SIG{TSTP} = 'IGNORE';
2301   local $SIG{PIPE} = 'IGNORE';
2302
2303   my $oldAutoCommit = $FS::UID::AutoCommit;
2304   local $FS::UID::AutoCommit = 0;
2305   my $dbh = dbh;
2306
2307   $self->select_for_update; #mutex
2308
2309   unless ( $self->total_unapplied_credits ) {
2310     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2311     return 0;
2312   }
2313
2314   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2315       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2316
2317   my @invoices = $self->open_cust_bill;
2318   @invoices = sort { $b->_date <=> $a->_date } @invoices
2319     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2320
2321   if ( $conf->exists('pkg-balances') ) {
2322     # limit @credits to those w/ a pkgnum grepped from $self
2323     my %pkgnums = ();
2324     foreach my $i (@invoices) {
2325       foreach my $li ( $i->cust_bill_pkg ) {
2326         $pkgnums{$li->pkgnum} = 1;
2327       }
2328     }
2329     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2330   }
2331
2332   my $credit;
2333
2334   foreach my $cust_bill ( @invoices ) {
2335
2336     if ( !defined($credit) || $credit->credited == 0) {
2337       $credit = pop @credits or last;
2338     }
2339
2340     my $owed;
2341     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2342       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2343     } else {
2344       $owed = $cust_bill->owed;
2345     }
2346     unless ( $owed > 0 ) {
2347       push @credits, $credit;
2348       next;
2349     }
2350
2351     my $amount = min( $credit->credited, $owed );
2352
2353     my $cust_credit_bill = new FS::cust_credit_bill ( {
2354       'crednum' => $credit->crednum,
2355       'invnum'  => $cust_bill->invnum,
2356       'amount'  => $amount,
2357     } );
2358     $cust_credit_bill->pkgnum( $credit->pkgnum )
2359       if $conf->exists('pkg-balances') && $credit->pkgnum;
2360     my $error = $cust_credit_bill->insert;
2361     if ( $error ) {
2362       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2363       die $error;
2364     }
2365
2366     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2367
2368   }
2369
2370   my $total_unapplied_credits = $self->total_unapplied_credits;
2371
2372   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2373
2374   return $total_unapplied_credits;
2375 }
2376
2377 =item apply_payments  [ OPTION => VALUE ... ]
2378
2379 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2380 to outstanding invoice balances in chronological order.
2381
2382  #and returns the value of any remaining unapplied payments.
2383
2384 A hash of optional arguments may be passed.  Currently "manual" is supported.
2385 If true, a payment receipt is sent instead of a statement when
2386 'payment_receipt_email' configuration option is set.
2387
2388 Dies if there is an error.
2389
2390 =cut
2391
2392 sub apply_payments {
2393   my( $self, %options ) = @_;
2394
2395   local $SIG{HUP} = 'IGNORE';
2396   local $SIG{INT} = 'IGNORE';
2397   local $SIG{QUIT} = 'IGNORE';
2398   local $SIG{TERM} = 'IGNORE';
2399   local $SIG{TSTP} = 'IGNORE';
2400   local $SIG{PIPE} = 'IGNORE';
2401
2402   my $oldAutoCommit = $FS::UID::AutoCommit;
2403   local $FS::UID::AutoCommit = 0;
2404   my $dbh = dbh;
2405
2406   $self->select_for_update; #mutex
2407
2408   #return 0 unless
2409
2410   my @payments = sort { $b->_date <=> $a->_date }
2411                  grep { $_->unapplied > 0 }
2412                  $self->cust_pay;
2413
2414   my @invoices = sort { $a->_date <=> $b->_date}
2415                  grep { $_->owed > 0 }
2416                  $self->cust_bill;
2417
2418   if ( $conf->exists('pkg-balances') ) {
2419     # limit @payments to those w/ a pkgnum grepped from $self
2420     my %pkgnums = ();
2421     foreach my $i (@invoices) {
2422       foreach my $li ( $i->cust_bill_pkg ) {
2423         $pkgnums{$li->pkgnum} = 1;
2424       }
2425     }
2426     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2427   }
2428
2429   my $payment;
2430
2431   foreach my $cust_bill ( @invoices ) {
2432
2433     if ( !defined($payment) || $payment->unapplied == 0 ) {
2434       $payment = pop @payments or last;
2435     }
2436
2437     my $owed;
2438     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2439       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2440     } else {
2441       $owed = $cust_bill->owed;
2442     }
2443     unless ( $owed > 0 ) {
2444       push @payments, $payment;
2445       next;
2446     }
2447
2448     my $amount = min( $payment->unapplied, $owed );
2449
2450     my $cbp = {
2451       'paynum' => $payment->paynum,
2452       'invnum' => $cust_bill->invnum,
2453       'amount' => $amount,
2454     };
2455     $cbp->{_date} = $payment->_date
2456         if $options{'manual'} && $options{'backdate_application'};
2457     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2458     $cust_bill_pay->pkgnum( $payment->pkgnum )
2459       if $conf->exists('pkg-balances') && $payment->pkgnum;
2460     my $error = $cust_bill_pay->insert(%options);
2461     if ( $error ) {
2462       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2463       die $error;
2464     }
2465
2466     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2467
2468   }
2469
2470   my $total_unapplied_payments = $self->total_unapplied_payments;
2471
2472   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2473
2474   return $total_unapplied_payments;
2475 }
2476
2477 =back
2478
2479 =head1 FLOW
2480
2481   bill_and_collect
2482
2483     cancel_expired_pkgs
2484     suspend_adjourned_pkgs
2485     unsuspend_resumed_pkgs
2486
2487     bill
2488       (do_cust_event pre-bill)
2489       _make_lines
2490         _handle_taxes
2491           (vendor-only) _gather_taxes
2492       _omit_zero_value_bundles
2493       _handle_taxes (for fees)
2494       calculate_taxes
2495
2496     apply_payments_and_credits
2497     collect
2498       do_cust_event
2499         due_cust_event
2500
2501 =head1 BUGS
2502
2503 =head1 SEE ALSO
2504
2505 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2506
2507 =cut
2508
2509 1;