FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::cust_bill;
  11 use FS::cust_bill_pkg;
  12 use FS::cust_bill_pkg_display;
  13 use FS::cust_bill_pay;
  14 use FS::cust_credit_bill;
  15 use FS::cust_tax_adjustment;
  16 use FS::tax_rate;
  17 use FS::tax_rate_location;
  18 use FS::cust_bill_pkg_tax_location;
  19 use FS::cust_bill_pkg_tax_rate_location;
  20 use FS::part_event;
  21 use FS::part_event_condition;
  22 use FS::pkg_category;
  23
  24 # 1 is mostly method/subroutine entry and options
  25 # 2 traces progress of some operations
  26 # 3 is even more information including possibly sensitive data
  27 $DEBUG = 0;
  28 $me = '[FS::cust_main::Billing]';
  29
  30 install_callback FS::UID sub {
  31   $conf = new FS::Conf;
  32   #yes, need it for stuff below (prolly should be cached)
  33 };
  34
  35 =head1 NAME
  36
  37 FS::cust_main::Billing - Billing mixin for cust_main
  38
  39 =head1 SYNOPSIS
  40
  41 =head1 DESCRIPTION
  42
  43 These methods are available on FS::cust_main objects.
  44
  45 =head1 METHODS
  46
  47 =over 4
  48
  49 =item bill_and_collect
  50
  51 Cancels and suspends any packages due, generates bills, applies payments and
  52 credits, and applies collection events to run cards, send bills and notices,
  53 etc.
  54
  55 By default, warns on errors and continues with the next operation (but see the
  56 "fatal" flag below).
  57
  58 Options are passed as name-value pairs.  Currently available options are:
  59
  60 =over 4
  61
  62 =item time
  63
  64 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  65
  66  use Date::Parse;
  67  ...
  68  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  69
  70 =item invoice_time
  71
  72 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  73
  74 =item check_freq
  75
  76 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  77
  78 =item resetup
  79
  80 If set true, re-charges setup fees.
  81
  82 =item fatal
  83
  84 If set any errors prevent subsequent operations from continusing.  If set
  85 specifically to "return", returns the error (or false, if there is no error).
  86 Any other true value causes errors to die.
  87
  88 =item debug
  89
  90 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  91
  92 =item job
  93
  94 Optional FS::queue entry to receive status updates.
  95
  96 =back
  97
  98 Options are passed to the B<bill> and B<collect> methods verbatim, so all
  99 options of those methods are also available.
 100
 101 =cut
 102
 103 sub bill_and_collect {
 104   my( $self, %options ) = @_;
 105
 106   my $error;
 107
 108   #$options{actual_time} not $options{time} because freeside-daily -d is for
 109   #pre-printing invoices
 110
 111   $options{'actual_time'} ||= time;
 112   my $job = $options{'job'};
 113
 114   $job->update_statustext('0,cleaning expired packages') if $job;
 115   $error = $self->cancel_expired_pkgs( $options{actual_time} );
 116   if ( $error ) {
 117     $error = "Error expiring custnum ". $self->custnum. ": $error";
 118     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 119     elsif ( $options{fatal}                                ) { die    $error; }
 120     else                                                     { warn   $error; }
 121   }
 122
 123   $error = $self->suspend_adjourned_pkgs( $options{actual_time} );
 124   if ( $error ) {
 125     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 126     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 127     elsif ( $options{fatal}                                ) { die    $error; }
 128     else                                                     { warn   $error; }
 129   }
 130
 131   $job->update_statustext('20,billing packages') if $job;
 132   $error = $self->bill( %options );
 133   if ( $error ) {
 134     $error = "Error billing custnum ". $self->custnum. ": $error";
 135     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 136     elsif ( $options{fatal}                                ) { die    $error; }
 137     else                                                     { warn   $error; }
 138   }
 139
 140   $job->update_statustext('50,applying payments and credits') if $job;
 141   $error = $self->apply_payments_and_credits;
 142   if ( $error ) {
 143     $error = "Error applying custnum ". $self->custnum. ": $error";
 144     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 145     elsif ( $options{fatal}                                ) { die    $error; }
 146     else                                                     { warn   $error; }
 147   }
 148
 149   $job->update_statustext('70,running collection events') if $job;
 150   unless ( $conf->exists('cancelled_cust-noevents')
 151            && ! $self->num_ncancelled_pkgs
 152   ) {
 153     $error = $self->collect( %options );
 154     if ( $error ) {
 155       $error = "Error collecting custnum ". $self->custnum. ": $error";
 156       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 157       elsif ($options{fatal}                               ) { die    $error; }
 158       else                                                   { warn   $error; }
 159     }
 160   }
 161   $job->update_statustext('100,finished') if $job;
 162
 163   '';
 164
 165 }
 166
 167 sub cancel_expired_pkgs {
 168   my ( $self, $time, %options ) = @_;
 169
 170   my @cancel_pkgs = $self->ncancelled_pkgs( {
 171     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 172   } );
 173
 174   my @errors = ();
 175
 176   foreach my $cust_pkg ( @cancel_pkgs ) {
 177     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 178     my $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 179                                            'reason_otaker' => $cpr->otaker
 180                                          )
 181                                        : ()
 182                                  );
 183     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 184   }
 185
 186   scalar(@errors) ? join(' / ', @errors) : '';
 187
 188 }
 189
 190 sub suspend_adjourned_pkgs {
 191   my ( $self, $time, %options ) = @_;
 192
 193   my @susp_pkgs = $self->ncancelled_pkgs( {
 194     'extra_sql' =>
 195       " AND ( susp IS NULL OR susp = 0 )
 196         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 197               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 198             )
 199       ",
 200   } );
 201
 202   #only because there's no SQL test for is_prepaid :/
 203   @susp_pkgs =
 204     grep {     (    $_->part_pkg->is_prepaid
 205                  && $_->bill
 206                  && $_->bill < $time
 207                )
 208             || (    $_->adjourn
 209                  && $_->adjourn <= $time
 210                )
 211
 212          }
 213          @susp_pkgs;
 214
 215   my @errors = ();
 216
 217   foreach my $cust_pkg ( @susp_pkgs ) {
 218     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 219       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 220     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 221                                             'reason_otaker' => $cpr->otaker
 222                                           )
 223                                         : ()
 224                                   );
 225     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 226   }
 227
 228   scalar(@errors) ? join(' / ', @errors) : '';
 229
 230 }
 231
 232 =item bill OPTIONS
 233
 234 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 235 conjunction with the collect method by calling B<bill_and_collect>.
 236
 237 If there is an error, returns the error, otherwise returns false.
 238
 239 Options are passed as name-value pairs.  Currently available options are:
 240
 241 =over 4
 242
 243 =item resetup
 244
 245 If set true, re-charges setup fees.
 246
 247 =item recurring_only
 248
 249 If set true then only bill recurring charges, not setup, usage, one time
 250 charges, etc.
 251
 252 =item freq_override
 253
 254 If set, then override the normal frequency and look for a part_pkg_discount
 255 to take at that frequency.
 256
 257 =item time
 258
 259 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 260
 261  use Date::Parse;
 262  ...
 263  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 264
 265 =item pkg_list
 266
 267 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 268
 269  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 270
 271 =item not_pkgpart
 272
 273 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 274
 275 =item invoice_time
 276
 277 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 278
 279 =item cancel
 280
 281 This boolean value informs the us that the package is being cancelled.  This
 282 typically might mean not charging the normal recurring fee but only usage
 283 fees since the last billing. Setup charges may be charged.  Not all package
 284 plans support this feature (they tend to charge 0).
 285
 286 =item no_usage_reset
 287
 288 Prevent the resetting of usage limits during this call.
 289
 290 =item no_commit
 291
 292 Do not save the generated bill in the database.  Useful with return_bill
 293
 294 =item return_bill
 295
 296 A list reference on which the generated bill(s) will be returned.
 297
 298 =item invoice_terms
 299
 300 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 301 terms or the default terms are used.
 302
 303 =back
 304
 305 =cut
 306
 307 sub bill {
 308   my( $self, %options ) = @_;
 309
 310   return '' if $self->payby eq 'COMP';
 311
 312   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 313
 314   warn "$me bill customer ". $self->custnum. "\n"
 315     if $DEBUG;
 316
 317   my $time = $options{'time'} || time;
 318   my $invoice_time = $options{'invoice_time'} || $time;
 319
 320   $options{'not_pkgpart'} ||= {};
 321   $options{'not_pkgpart'} = { map { $_ => 1 }
 322                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 323                             }
 324     unless ref($options{'not_pkgpart'});
 325
 326   local $SIG{HUP} = 'IGNORE';
 327   local $SIG{INT} = 'IGNORE';
 328   local $SIG{QUIT} = 'IGNORE';
 329   local $SIG{TERM} = 'IGNORE';
 330   local $SIG{TSTP} = 'IGNORE';
 331   local $SIG{PIPE} = 'IGNORE';
 332
 333   my $oldAutoCommit = $FS::UID::AutoCommit;
 334   local $FS::UID::AutoCommit = 0;
 335   my $dbh = dbh;
 336
 337   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 338     if $DEBUG;
 339
 340   $self->select_for_update; #mutex
 341
 342   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 343     if $DEBUG;
 344
 345   my $error = $self->do_cust_event(
 346     'debug'      => ( $options{'debug'} || 0 ),
 347     'time'       => $invoice_time,
 348     'check_freq' => $options{'check_freq'},
 349     'stage'      => 'pre-bill',
 350   )
 351     unless $options{no_commit};
 352   if ( $error ) {
 353     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 354     return $error;
 355   }
 356
 357   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 358     if $DEBUG;
 359
 360   #keep auto-charge and non-auto-charge line items separate
 361   my @passes = ( '', 'no_auto' );
 362
 363   my %cust_bill_pkg = map { $_ => [] } @passes;
 364
 365   ###
 366   # find the packages which are due for billing, find out how much they are
 367   # & generate invoice database.
 368   ###
 369
 370   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 371   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 372
 373   my %taxlisthash = map { $_ => {} } @passes;
 374
 375   my @precommit_hooks = ();
 376
 377   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 378   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 379
 380     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 381
 382     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG > 1;
 383
 384     #? to avoid use of uninitialized value errors... ?
 385     $cust_pkg->setfield('bill', '')
 386       unless defined($cust_pkg->bill);
 387
 388     #my $part_pkg = $cust_pkg->part_pkg;
 389
 390     my $real_pkgpart = $cust_pkg->pkgpart;
 391     my %hash = $cust_pkg->hash;
 392
 393     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 394     # suffer from performance issues
 395     $options{has_hidden} = 0;
 396     my @part_pkg = $cust_pkg->part_pkg->self_and_bill_linked;
 397     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 398
 399     foreach my $part_pkg ( @part_pkg ) {
 400
 401       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 402
 403       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 404
 405       my $error =
 406         $self->_make_lines( 'part_pkg'            => $part_pkg,
 407                             'cust_pkg'            => $cust_pkg,
 408                             'precommit_hooks'     => \@precommit_hooks,
 409                             'line_items'          => $cust_bill_pkg{$pass},
 410                             'setup'               => $total_setup{$pass},
 411                             'recur'               => $total_recur{$pass},
 412                             'tax_matrix'          => $taxlisthash{$pass},
 413                             'time'                => $time,
 414                             'real_pkgpart'        => $real_pkgpart,
 415                             'options'             => \%options,
 416                           );
 417       if ($error) {
 418         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 419         return $error;
 420       }
 421
 422     } #foreach my $part_pkg
 423
 424   } #foreach my $cust_pkg
 425
 426   #if the customer isn't on an automatic payby, everything can go on a single
 427   #invoice anyway?
 428   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 429     #merge everything into one list
 430   #}
 431
 432   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 433
 434     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 435
 436     next unless @cust_bill_pkg; #don't create an invoice w/o line items
 437
 438     warn "$me billing pass $pass\n"
 439            #.Dumper(\@cust_bill_pkg)."\n"
 440       if $DEBUG > 2;
 441
 442     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 443            !$conf->exists('postal_invoice-recurring_only')
 444        )
 445     {
 446
 447       my $postal_pkg = $self->charge_postal_fee();
 448       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 449
 450         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 451         return "can't charge postal invoice fee for customer ".
 452           $self->custnum. ": $postal_pkg";
 453
 454       } elsif ( $postal_pkg ) {
 455
 456         my $real_pkgpart = $postal_pkg->pkgpart;
 457         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 458         # suffer from performance issues
 459         $options{has_hidden} = 0;
 460         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 461         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 462
 463         foreach my $part_pkg ( @part_pkg ) {
 464           my %postal_options = %options;
 465           delete $postal_options{cancel};
 466           my $error =
 467             $self->_make_lines( 'part_pkg'            => $part_pkg,
 468                                 'cust_pkg'            => $postal_pkg,
 469                                 'precommit_hooks'     => \@precommit_hooks,
 470                                 'line_items'          => \@cust_bill_pkg,
 471                                 'setup'               => $total_setup{$pass},
 472                                 'recur'               => $total_recur{$pass},
 473                                 'tax_matrix'          => $taxlisthash{$pass},
 474                                 'time'                => $time,
 475                                 'real_pkgpart'        => $real_pkgpart,
 476                                 'options'             => \%postal_options,
 477                               );
 478           if ($error) {
 479             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 480             return $error;
 481           }
 482         }
 483
 484         # it's silly to have a zero value postal_pkg, but....
 485         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 486
 487       }
 488
 489     }
 490
 491     my $listref_or_error =
 492       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 493
 494     unless ( ref( $listref_or_error ) ) {
 495       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 496       return $listref_or_error;
 497     }
 498
 499     foreach my $taxline ( @$listref_or_error ) {
 500       ${ $total_setup{$pass} } =
 501         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 502       push @cust_bill_pkg, $taxline;
 503     }
 504
 505     #add tax adjustments
 506     warn "adding tax adjustments...\n" if $DEBUG > 2;
 507     foreach my $cust_tax_adjustment (
 508       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 509                                        'billpkgnum' => '',
 510                                      }
 511              )
 512     ) {
 513
 514       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 515
 516       my $itemdesc = $cust_tax_adjustment->taxname;
 517       $itemdesc = '' if $itemdesc eq 'Tax';
 518
 519       push @cust_bill_pkg, new FS::cust_bill_pkg {
 520         'pkgnum'      => 0,
 521         'setup'       => $tax,
 522         'recur'       => 0,
 523         'sdate'       => '',
 524         'edate'       => '',
 525         'itemdesc'    => $itemdesc,
 526         'itemcomment' => $cust_tax_adjustment->comment,
 527         'cust_tax_adjustment' => $cust_tax_adjustment,
 528         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 529       };
 530
 531     }
 532
 533     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 534
 535     my @cust_bill = $self->cust_bill;
 536     my $balance = $self->balance;
 537     my $previous_balance = scalar(@cust_bill)
 538                              ? ( $cust_bill[$#cust_bill]->billing_balance || 0 )
 539                              : 0;
 540
 541     $previous_balance += $cust_bill[$#cust_bill]->charged
 542       if scalar(@cust_bill);
 543     #my $balance_adjustments =
 544     #  sprintf('%.2f', $balance - $prior_prior_balance - $prior_charged);
 545
 546     warn "creating the new invoice\n" if $DEBUG;
 547     #create the new invoice
 548     my $cust_bill = new FS::cust_bill ( {
 549       'custnum'             => $self->custnum,
 550       '_date'               => $invoice_time,
 551       'charged'             => $charged,
 552       'billing_balance'     => $balance,
 553       'previous_balance'    => $previous_balance,
 554       'invoice_terms'       => $options{'invoice_terms'},
 555       'cust_bill_pkg'       => \@cust_bill_pkg,
 556     } );
 557     $error = $cust_bill->insert unless $options{no_commit};
 558     if ( $error ) {
 559       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 560       return "can't create invoice for customer #". $self->custnum. ": $error";
 561     }
 562     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 563
 564   } #foreach my $pass ( keys %cust_bill_pkg )
 565
 566   foreach my $hook ( @precommit_hooks ) {
 567     eval {
 568       &{$hook}; #($self) ?
 569     } unless $options{no_commit};
 570     if ( $@ ) {
 571       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 572       return "$@ running precommit hook $hook\n";
 573     }
 574   }
 575
 576   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 577
 578   ''; #no error
 579 }
 580
 581 #discard bundled packages of 0 value
 582 sub _omit_zero_value_bundles {
 583   my @in = @_;
 584
 585   my @cust_bill_pkg = ();
 586   my @cust_bill_pkg_bundle = ();
 587   my $sum = 0;
 588   my $discount_show_always = 0;
 589
 590   foreach my $cust_bill_pkg ( @in ) {
 591
 592     $discount_show_always = ($cust_bill_pkg->get('discounts')
 593                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 594                                 && $conf->exists('discount-show-always'));
 595
 596     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 597          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 598          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 599       if $DEBUG > 0;
 600
 601     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 602       push @cust_bill_pkg, @cust_bill_pkg_bundle
 603         if $sum > 0
 604         || ($sum == 0 && (    $discount_show_always
 605                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 606                                    @cust_bill_pkg_bundle
 607                          )
 608            );
 609       @cust_bill_pkg_bundle = ();
 610       $sum = 0;
 611     }
 612
 613     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 614     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 615
 616   }
 617
 618   push @cust_bill_pkg, @cust_bill_pkg_bundle
 619     if $sum > 0
 620     || ($sum == 0 && (    $discount_show_always
 621                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 622                                @cust_bill_pkg_bundle
 623                      )
 624        );
 625
 626   warn "  _omit_zero_value_bundles: ". scalar(@in).
 627        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 628     if $DEBUG > 2;
 629
 630   (@cust_bill_pkg);
 631
 632 }
 633
 634 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 635
 636 This is a weird one.  Perhaps it should not even be exposed.
 637
 638 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 639 Usually used internally by bill method B<bill>.
 640
 641 If there is an error, returns the error, otherwise returns reference to a
 642 list of line items suitable for insertion.
 643
 644 =over 4
 645
 646 =item LINEITEMREF
 647
 648 An array ref of the line items being billed.
 649
 650 =item TAXHASHREF
 651
 652 A strange beast.  The keys to this hash are internal identifiers consisting
 653 of the name of the tax object type, a space, and its unique identifier ( e.g.
 654  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 655 item in the list is the tax object.  The remaining items are either line
 656 items or floating point values (currency amounts).
 657
 658 The taxes are calculated on this entity.  Calculated exemption records are
 659 transferred to the LINEITEMREF items on the assumption that they are related.
 660
 661 Read the source.
 662
 663 =item INVOICE_TIME
 664
 665 This specifies the date appearing on the associated invoice.  Some
 666 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 667
 668 =back
 669
 670 =cut
 671
 672 sub calculate_taxes {
 673   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 674
 675   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 676
 677   warn "$me calculate_taxes\n"
 678        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 679     if $DEBUG > 2;
 680
 681   my @tax_line_items = ();
 682
 683   # keys are tax names (as printed on invoices / itemdesc )
 684   # values are listrefs of taxlisthash keys (internal identifiers)
 685   my %taxname = ();
 686
 687   # keys are taxlisthash keys (internal identifiers)
 688   # values are (cumulative) amounts
 689   my %tax = ();
 690
 691   # keys are taxlisthash keys (internal identifiers)
 692   # values are listrefs of cust_bill_pkg_tax_location hashrefs
 693   my %tax_location = ();
 694
 695   # keys are taxlisthash keys (internal identifiers)
 696   # values are listrefs of cust_bill_pkg_tax_rate_location hashrefs
 697   my %tax_rate_location = ();
 698
 699   foreach my $tax ( keys %$taxlisthash ) {
 700     my $tax_object = shift @{ $taxlisthash->{$tax} };
 701     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 702     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 703     my $hashref_or_error =
 704       $tax_object->taxline( $taxlisthash->{$tax},
 705                             'custnum'      => $self->custnum,
 706                             'invoice_time' => $invoice_time
 707                           );
 708     return $hashref_or_error unless ref($hashref_or_error);
 709
 710     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 711
 712     my $name   = $hashref_or_error->{'name'};
 713     my $amount = $hashref_or_error->{'amount'};
 714
 715     #warn "adding $amount as $name\n";
 716     $taxname{ $name } ||= [];
 717     push @{ $taxname{ $name } }, $tax;
 718
 719     $tax{ $tax } += $amount;
 720
 721     $tax_location{ $tax } ||= [];
 722     if ( $tax_object->get('pkgnum') || $tax_object->get('locationnum') ) {
 723       push @{ $tax_location{ $tax }  },
 724         {
 725           'taxnum'      => $tax_object->taxnum,
 726           'taxtype'     => ref($tax_object),
 727           'pkgnum'      => $tax_object->get('pkgnum'),
 728           'locationnum' => $tax_object->get('locationnum'),
 729           'amount'      => sprintf('%.2f', $amount ),
 730         };
 731     }
 732
 733     $tax_rate_location{ $tax } ||= [];
 734     if ( ref($tax_object) eq 'FS::tax_rate' ) {
 735       my $taxratelocationnum =
 736         $tax_object->tax_rate_location->taxratelocationnum;
 737       push @{ $tax_rate_location{ $tax }  },
 738         {
 739           'taxnum'             => $tax_object->taxnum,
 740           'taxtype'            => ref($tax_object),
 741           'amount'             => sprintf('%.2f', $amount ),
 742           'locationtaxid'      => $tax_object->location,
 743           'taxratelocationnum' => $taxratelocationnum,
 744         };
 745     }
 746
 747   }
 748
 749   #move the cust_tax_exempt_pkg records to the cust_bill_pkgs we will commit
 750   my %packagemap = map { $_->pkgnum => $_ } @$cust_bill_pkg;
 751   foreach my $tax ( keys %$taxlisthash ) {
 752     foreach ( @{ $taxlisthash->{$tax} }[1 ... scalar(@{ $taxlisthash->{$tax} })] ) {
 753       next unless ref($_) eq 'FS::cust_bill_pkg';
 754
 755       my @cust_tax_exempt_pkg = splice( @{ $_->_cust_tax_exempt_pkg } );
 756
 757       next unless @cust_tax_exempt_pkg; #just avoiding the prob when irrelevant?
 758       die "can't distribute tax exemptions: no line item for ".  Dumper($_).
 759           " in packagemap ". join(',', sort {$a<=>$b} keys %packagemap). "\n"
 760         unless $packagemap{$_->pkgnum};
 761
 762       push @{ $packagemap{$_->pkgnum}->_cust_tax_exempt_pkg },
 763            @cust_tax_exempt_pkg;
 764     }
 765   }
 766
 767   #consolidate and create tax line items
 768   warn "consolidating and generating...\n" if $DEBUG > 2;
 769   foreach my $taxname ( keys %taxname ) {
 770     my $tax = 0;
 771     my %seen = ();
 772     my @cust_bill_pkg_tax_location = ();
 773     my @cust_bill_pkg_tax_rate_location = ();
 774     warn "adding $taxname\n" if $DEBUG > 1;
 775     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 776       next if $seen{$taxitem}++;
 777       warn "adding $tax{$taxitem}\n" if $DEBUG > 1;
 778       $tax += $tax{$taxitem};
 779       push @cust_bill_pkg_tax_location,
 780         map { new FS::cust_bill_pkg_tax_location $_ }
 781             @{ $tax_location{ $taxitem } };
 782       push @cust_bill_pkg_tax_rate_location,
 783         map { new FS::cust_bill_pkg_tax_rate_location $_ }
 784             @{ $tax_rate_location{ $taxitem } };
 785     }
 786     next unless $tax;
 787
 788     $tax = sprintf('%.2f', $tax );
 789
 790     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
 791                                                    'disabled'     => '',
 792                                                  },
 793                                );
 794
 795     my @display = ();
 796     if ( $pkg_category and
 797          $conf->config('invoice_latexsummary') ||
 798          $conf->config('invoice_htmlsummary')
 799        )
 800     {
 801
 802       my %hash = (  'section' => $pkg_category->categoryname );
 803       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
 804
 805     }
 806
 807     push @tax_line_items, new FS::cust_bill_pkg {
 808       'pkgnum'   => 0,
 809       'setup'    => $tax,
 810       'recur'    => 0,
 811       'sdate'    => '',
 812       'edate'    => '',
 813       'itemdesc' => $taxname,
 814       'display'  => \@display,
 815       'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 816       'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 817     };
 818
 819   }
 820
 821   \@tax_line_items;
 822 }
 823
 824 sub _make_lines {
 825   my ($self, %params) = @_;
 826
 827   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 828
 829   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 830   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 831   my $precommit_hooks = $params{precommit_hooks} or die "no package specified";
 832   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 833   my $total_setup = $params{setup} or die "no setup accumulator specified";
 834   my $total_recur = $params{recur} or die "no recur accumulator specified";
 835   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
 836   my $time = $params{'time'} or die "no time specified";
 837   my (%options) = %{$params{options}};
 838
 839   my $dbh = dbh;
 840   my $real_pkgpart = $params{real_pkgpart};
 841   my %hash = $cust_pkg->hash;
 842   my $old_cust_pkg = new FS::cust_pkg \%hash;
 843
 844   my @details = ();
 845   my $lineitems = 0;
 846
 847   $cust_pkg->pkgpart($part_pkg->pkgpart);
 848
 849   ###
 850   # bill setup
 851   ###
 852
 853   my $setup = 0;
 854   my $unitsetup = 0;
 855   my @setup_discounts = ();
 856   my %setup_param = ( 'discounts' => \@setup_discounts );
 857   if (     ! $options{recurring_only}
 858        and ! $options{cancel}
 859        and ( $options{'resetup'}
 860              || ( ! $cust_pkg->setup
 861                   && ( ! $cust_pkg->start_date
 862                        || $cust_pkg->start_date <= $time
 863                      )
 864                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
 865                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
 866                             ! $cust_pkg->getfield('susp')
 867                           )
 868                      )
 869                 )
 870            )
 871      )
 872   {
 873
 874     warn "    bill setup\n" if $DEBUG > 1;
 875
 876     unless ( $cust_pkg->waive_setup ) {
 877         $lineitems++;
 878
 879         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
 880         return "$@ running calc_setup for $cust_pkg\n"
 881           if $@;
 882
 883         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
 884     }
 885
 886     $cust_pkg->setfield('setup', $time)
 887       unless $cust_pkg->setup;
 888           #do need it, but it won't get written to the db
 889           #|| $cust_pkg->pkgpart != $real_pkgpart;
 890
 891     $cust_pkg->setfield('start_date', '')
 892       if $cust_pkg->start_date;
 893
 894   }
 895
 896   ###
 897   # bill recurring fee
 898   ###
 899
 900   #XXX unit stuff here too
 901   my $recur = 0;
 902   my $unitrecur = 0;
 903   my @recur_discounts = ();
 904   my $sdate;
 905   if (     ! $cust_pkg->start_date
 906        and ( ! $cust_pkg->susp || $part_pkg->option('suspend_bill', 1) )
 907        and
 908             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $time )
 909          || ( $part_pkg->plan eq 'voip_cdr'
 910                && $part_pkg->option('bill_every_call')
 911             )
 912          || $options{cancel}
 913   ) {
 914
 915     # XXX should this be a package event?  probably.  events are called
 916     # at collection time at the moment, though...
 917     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
 918       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
 919       #don't want to reset usage just cause we want a line item??
 920       #&& $part_pkg->pkgpart == $real_pkgpart;
 921
 922     warn "    bill recur\n" if $DEBUG > 1;
 923     $lineitems++;
 924
 925     # XXX shared with $recur_prog
 926     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
 927              || $cust_pkg->setup
 928              || $time;
 929
 930     #over two params!  lets at least switch to a hashref for the rest...
 931     my $increment_next_bill = ( $part_pkg->freq ne '0'
 932                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $time
 933                                 && !$options{cancel}
 934                               );
 935     my %param = ( %setup_param,
 936                   'precommit_hooks'     => $precommit_hooks,
 937                   'increment_next_bill' => $increment_next_bill,
 938                   'discounts'           => \@recur_discounts,
 939                   'real_pkgpart'        => $real_pkgpart,
 940                   'freq_override'       => $options{freq_override} || '',
 941                 );
 942
 943     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
 944
 945     # There may be some part_pkg for which this is wrong.  Only those
 946     # which can_discount are supported.
 947     # (the UI should prevent adding discounts to these at the moment)
 948
 949     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
 950     return "$@ running $method for $cust_pkg\n"
 951       if ( $@ );
 952
 953     if ( $increment_next_bill ) {
 954
 955       my $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
 956       return "unparsable frequency: ". $part_pkg->freq
 957         if $next_bill == -1;
 958
 959       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
 960       # only for figuring next bill date, nothing else, so, reset $sdate again
 961       # here
 962       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
 963       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
 964       $cust_pkg->last_bill($sdate);
 965
 966       $cust_pkg->setfield('bill', $next_bill );
 967
 968     }
 969
 970     if ( defined $param{'discount_left_setup'} ) {
 971         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
 972             $setup -= $discount_setup;
 973         }
 974     }
 975
 976   }
 977
 978   warn "\$setup is undefined" unless defined($setup);
 979   warn "\$recur is undefined" unless defined($recur);
 980   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
 981
 982   ###
 983   # If there's line items, create em cust_bill_pkg records
 984   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
 985   ###
 986
 987   if ( $lineitems ) {
 988
 989     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
 990       # hmm.. and if just the options are modified in some weird price plan?
 991
 992       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
 993         if $DEBUG >1;
 994
 995       my $error = $cust_pkg->replace( $old_cust_pkg,
 996                                       'depend_jobnum'=>$options{depend_jobnum},
 997                                       'options' => { $cust_pkg->options },
 998                                     )
 999         unless $options{no_commit};
1000       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1001         if $error; #just in case
1002     }
1003
1004     $setup = sprintf( "%.2f", $setup );
1005     $recur = sprintf( "%.2f", $recur );
1006     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1007       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1008     }
1009     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1010       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1011     }
1012
1013     my $discount_show_always = $conf->exists('discount-show-always')
1014                                && (    ($setup == 0 && scalar(@setup_discounts))
1015                                     || ($recur == 0 && scalar(@recur_discounts))
1016                                   );
1017
1018     if (    $setup != 0
1019          || $recur != 0
1020          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1021          || $discount_show_always
1022          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1023          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1024        )
1025     {
1026
1027       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1028         if $DEBUG > 1;
1029
1030       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1031       if ( $DEBUG > 1 ) {
1032         warn "      adding customer package invoice detail: $_\n"
1033           foreach @cust_pkg_detail;
1034       }
1035       push @details, @cust_pkg_detail;
1036
1037       my $cust_bill_pkg = new FS::cust_bill_pkg {
1038         'pkgnum'    => $cust_pkg->pkgnum,
1039         'setup'     => $setup,
1040         'unitsetup' => $unitsetup,
1041         'recur'     => $recur,
1042         'unitrecur' => $unitrecur,
1043         'quantity'  => $cust_pkg->quantity,
1044         'details'   => \@details,
1045         'discounts' => [ @setup_discounts, @recur_discounts ],
1046         'hidden'    => $part_pkg->hidden,
1047         'freq'      => $part_pkg->freq,
1048       };
1049
1050       if ( $part_pkg->option('recur_temporality', 1) eq 'preceding' ) {
1051         $cust_bill_pkg->sdate( $hash{last_bill} );
1052         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1053         $cust_bill_pkg->edate( $time ) if $options{cancel};
1054       } else { #if ( $part_pkg->option('recur_temporality', 1) eq 'upcoming' ) {
1055         $cust_bill_pkg->sdate( $sdate );
1056         $cust_bill_pkg->edate( $cust_pkg->bill );
1057         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1058       }
1059
1060       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1061         unless $part_pkg->pkgpart == $real_pkgpart;
1062
1063       $$total_setup += $setup;
1064       $$total_recur += $recur;
1065
1066       ###
1067       # handle taxes
1068       ###
1069
1070       unless ( $discount_show_always ) {
1071       my $error =
1072         $self->_handle_taxes($part_pkg, $taxlisthash, $cust_bill_pkg, $cust_pkg, $options{invoice_time}, $real_pkgpart, \%options);
1073       return $error if $error;
1074       }
1075
1076       push @$cust_bill_pkgs, $cust_bill_pkg;
1077
1078     } #if $setup != 0 || $recur != 0
1079
1080   } #if $line_items
1081
1082   '';
1083
1084 }
1085
1086 sub _handle_taxes {
1087   my $self = shift;
1088   my $part_pkg = shift;
1089   my $taxlisthash = shift;
1090   my $cust_bill_pkg = shift;
1091   my $cust_pkg = shift;
1092   my $invoice_time = shift;
1093   my $real_pkgpart = shift;
1094   my $options = shift;
1095
1096   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1097
1098   my %cust_bill_pkg = ();
1099   my %taxes = ();
1100
1101   my @classes;
1102   #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1103   push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1104   push @classes, 'setup' if ($cust_bill_pkg->setup && !$options->{cancel});
1105   push @classes, 'recur' if ($cust_bill_pkg->recur && !$options->{cancel});
1106
1107   if ( $self->tax !~ /Y/i && $self->payby ne 'COMP' ) {
1108
1109     if ( $conf->exists('enable_taxproducts')
1110          && ( scalar($part_pkg->part_pkg_taxoverride)
1111               || $part_pkg->has_taxproduct
1112             )
1113        )
1114     {
1115
1116       foreach my $class (@classes) {
1117         my $err_or_ref = $self->_gather_taxes( $part_pkg, $class, $cust_pkg );
1118         return $err_or_ref unless ref($err_or_ref);
1119         $taxes{$class} = $err_or_ref;
1120       }
1121
1122       unless (exists $taxes{''}) {
1123         my $err_or_ref = $self->_gather_taxes( $part_pkg, '', $cust_pkg );
1124         return $err_or_ref unless ref($err_or_ref);
1125         $taxes{''} = $err_or_ref;
1126       }
1127
1128     } else {
1129
1130       my @loc_keys = qw( city county state country );
1131       my %taxhash;
1132       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1133         my $cust_location = $cust_pkg->cust_location;
1134         %taxhash = map { $_ => $cust_location->$_()    } @loc_keys;
1135       } else {
1136         my $prefix =
1137           ( $conf->exists('tax-ship_address') && length($self->ship_last) )
1138           ? 'ship_'
1139           : '';
1140         %taxhash = map { $_ => $self->get("$prefix$_") } @loc_keys;
1141       }
1142
1143       $taxhash{'taxclass'} = $part_pkg->taxclass;
1144
1145       my @taxes = ();
1146       my %taxhash_elim = %taxhash;
1147       my @elim = qw( city county state );
1148       do {
1149
1150         #first try a match with taxclass
1151         @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1152
1153         if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1154           #then try a match without taxclass
1155           my %no_taxclass = %taxhash_elim;
1156           $no_taxclass{ 'taxclass' } = '';
1157           @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1158         }
1159
1160         $taxhash_elim{ shift(@elim) } = '';
1161
1162       } while ( !scalar(@taxes) && scalar(@elim) );
1163
1164       @taxes = grep { ! $_->taxname or ! $self->tax_exemption($_->taxname) }
1165                     @taxes
1166         if $self->cust_main_exemption; #just to be safe
1167
1168       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1169         foreach (@taxes) {
1170           $_->set('pkgnum',      $cust_pkg->pkgnum );
1171           $_->set('locationnum', $cust_pkg->locationnum );
1172         }
1173       }
1174
1175       $taxes{''} = [ @taxes ];
1176       $taxes{'setup'} = [ @taxes ];
1177       $taxes{'recur'} = [ @taxes ];
1178       $taxes{$_} = [ @taxes ] foreach (@classes);
1179
1180       # # maybe eliminate this entirely, along with all the 0% records
1181       # unless ( @taxes ) {
1182       #   return
1183       #     "fatal: can't find tax rate for state/county/country/taxclass ".
1184       #     join('/', map $taxhash{$_}, qw(state county country taxclass) );
1185       # }
1186
1187     } #if $conf->exists('enable_taxproducts') ...
1188
1189   }
1190
1191   my @display = ();
1192   my $separate = $conf->exists('separate_usage');
1193   my $temp_pkg = new FS::cust_pkg { pkgpart => $real_pkgpart };
1194   my $usage_mandate = $temp_pkg->part_pkg->option('usage_mandate', 'Hush!');
1195   my $section = $temp_pkg->part_pkg->categoryname;
1196   if ( $separate || $section || $usage_mandate ) {
1197
1198     my %hash = ( 'section' => $section );
1199
1200     $section = $temp_pkg->part_pkg->option('usage_section', 'Hush!');
1201     my $summary = $temp_pkg->part_pkg->option('summarize_usage', 'Hush!');
1202     if ( $separate ) {
1203       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1204       push @display, new FS::cust_bill_pkg_display { type => 'R', %hash };
1205     } else {
1206       push @display, new FS::cust_bill_pkg_display
1207                        { type => '',
1208                          %hash,
1209                          ( ( $usage_mandate ) ? ( 'summary' => 'Y' ) : () ),
1210                        };
1211     }
1212
1213     if ($separate && $section && $summary) {
1214       push @display, new FS::cust_bill_pkg_display { type    => 'U',
1215                                                      summary => 'Y',
1216                                                      %hash,
1217                                                    };
1218     }
1219     if ($usage_mandate || $section && $summary) {
1220       $hash{post_total} = 'Y';
1221     }
1222
1223     if ($separate || $usage_mandate) {
1224       $hash{section} = $section if $section;
1225       push @display, new FS::cust_bill_pkg_display { type => 'U', %hash };
1226     }
1227
1228   }
1229   $cust_bill_pkg->set('display', \@display);
1230
1231   my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1232   foreach my $key (keys %tax_cust_bill_pkg) {
1233     my @taxes = @{ $taxes{$key} || [] };
1234     my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1235
1236     my %localtaxlisthash = ();
1237     foreach my $tax ( @taxes ) {
1238
1239       my $taxname = ref( $tax ). ' '. $tax->taxnum;
1240 #      $taxname .= ' pkgnum'. $cust_pkg->pkgnum.
1241 #                  ' locationnum'. $cust_pkg->locationnum
1242 #        if $conf->exists('tax-pkg_address') && $cust_pkg->locationnum;
1243
1244       $taxlisthash->{ $taxname } ||= [ $tax ];
1245       push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1246
1247       $localtaxlisthash{ $taxname } ||= [ $tax ];
1248       push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1249
1250     }
1251
1252     warn "finding taxed taxes...\n" if $DEBUG > 2;
1253     foreach my $tax ( keys %localtaxlisthash ) {
1254       my $tax_object = shift @{ $localtaxlisthash{$tax} };
1255       warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1256         if $DEBUG > 2;
1257       next unless $tax_object->can('tax_on_tax');
1258
1259       foreach my $tot ( $tax_object->tax_on_tax( $self ) ) {
1260         my $totname = ref( $tot ). ' '. $tot->taxnum;
1261
1262         warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1263           if $DEBUG > 2;
1264         next unless exists( $localtaxlisthash{ $totname } ); # only increase
1265                                                              # existing taxes
1266         warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1267         my $hashref_or_error =
1268           $tax_object->taxline( $localtaxlisthash{$tax},
1269                                 'custnum'      => $self->custnum,
1270                                 'invoice_time' => $invoice_time,
1271                               );
1272         return $hashref_or_error
1273           unless ref($hashref_or_error);
1274
1275         $taxlisthash->{ $totname } ||= [ $tot ];
1276         push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1277
1278       }
1279     }
1280
1281   }
1282
1283   '';
1284 }
1285
1286 sub _gather_taxes {
1287   my $self = shift;
1288   my $part_pkg = shift;
1289   my $class = shift;
1290   my $cust_pkg = shift;
1291
1292   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1293
1294   my $geocode;
1295   if ( $cust_pkg->locationnum && $conf->exists('tax-pkg_address') ) {
1296     $geocode = $cust_pkg->cust_location->geocode('cch');
1297   } else {
1298     $geocode = $self->geocode('cch');
1299   }
1300
1301   my @taxes = ();
1302
1303   my @taxclassnums = map { $_->taxclassnum }
1304                      $part_pkg->part_pkg_taxoverride($class);
1305
1306   unless (@taxclassnums) {
1307     @taxclassnums = map { $_->taxclassnum }
1308                     grep { $_->taxable eq 'Y' }
1309                     $part_pkg->part_pkg_taxrate('cch', $geocode, $class);
1310   }
1311   warn "Found taxclassnum values of ". join(',', @taxclassnums)
1312     if $DEBUG;
1313
1314   my $extra_sql =
1315     "AND (".
1316     join(' OR ', map { "taxclassnum = $_" } @taxclassnums ). ")";
1317
1318   @taxes = qsearch({ 'table' => 'tax_rate',
1319                      'hashref' => { 'geocode' => $geocode, },
1320                      'extra_sql' => $extra_sql,
1321                   })
1322     if scalar(@taxclassnums);
1323
1324   warn "Found taxes ".
1325        join(',', map{ ref($_). " ". $_->get($_->primary_key) } @taxes). "\n"
1326    if $DEBUG;
1327
1328   [ @taxes ];
1329
1330 }
1331
1332 =item collect [ HASHREF | OPTION => VALUE ... ]
1333
1334 (Attempt to) collect money for this customer's outstanding invoices (see
1335 L<FS::cust_bill>).  Usually used after the bill method.
1336
1337 Actions are now triggered by billing events; see L<FS::part_event> and the
1338 billing events web interface.  Old-style invoice events (see
1339 L<FS::part_bill_event>) have been deprecated.
1340
1341 If there is an error, returns the error, otherwise returns false.
1342
1343 Options are passed as name-value pairs.
1344
1345 Currently available options are:
1346
1347 =over 4
1348
1349 =item invoice_time
1350
1351 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1352
1353 =item retry
1354
1355 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1356
1357 =item check_freq
1358
1359 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1360
1361 =item quiet
1362
1363 set true to surpress email card/ACH decline notices.
1364
1365 =item debug
1366
1367 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1368
1369 =back
1370
1371 # =item payby
1372 #
1373 # allows for one time override of normal customer billing method
1374
1375 =cut
1376
1377 sub collect {
1378   my( $self, %options ) = @_;
1379
1380   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1381
1382   my $invoice_time = $options{'invoice_time'} || time;
1383
1384   #put below somehow?
1385   local $SIG{HUP} = 'IGNORE';
1386   local $SIG{INT} = 'IGNORE';
1387   local $SIG{QUIT} = 'IGNORE';
1388   local $SIG{TERM} = 'IGNORE';
1389   local $SIG{TSTP} = 'IGNORE';
1390   local $SIG{PIPE} = 'IGNORE';
1391
1392   my $oldAutoCommit = $FS::UID::AutoCommit;
1393   local $FS::UID::AutoCommit = 0;
1394   my $dbh = dbh;
1395
1396   $self->select_for_update; #mutex
1397
1398   if ( $DEBUG ) {
1399     my $balance = $self->balance;
1400     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1401   }
1402
1403   if ( exists($options{'retry_card'}) ) {
1404     carp 'retry_card option passed to collect is deprecated; use retry';
1405     $options{'retry'} ||= $options{'retry_card'};
1406   }
1407   if ( exists($options{'retry'}) && $options{'retry'} ) {
1408     my $error = $self->retry_realtime;
1409     if ( $error ) {
1410       $dbh->rollback if $oldAutoCommit;
1411       return $error;
1412     }
1413   }
1414
1415   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1416
1417   #never want to roll back an event just because it returned an error
1418   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1419
1420   $self->do_cust_event(
1421     'debug'      => ( $options{'debug'} || 0 ),
1422     'time'       => $invoice_time,
1423     'check_freq' => $options{'check_freq'},
1424     'stage'      => 'collect',
1425   );
1426
1427 }
1428
1429 =item retry_realtime
1430
1431 Schedules realtime / batch  credit card / electronic check / LEC billing
1432 events for for retry.  Useful if card information has changed or manual
1433 retry is desired.  The 'collect' method must be called to actually retry
1434 the transaction.
1435
1436 Implementation details: For either this customer, or for each of this
1437 customer's open invoices, changes the status of the first "done" (with
1438 statustext error) realtime processing event to "failed".
1439
1440 =cut
1441
1442 sub retry_realtime {
1443   my $self = shift;
1444
1445   local $SIG{HUP} = 'IGNORE';
1446   local $SIG{INT} = 'IGNORE';
1447   local $SIG{QUIT} = 'IGNORE';
1448   local $SIG{TERM} = 'IGNORE';
1449   local $SIG{TSTP} = 'IGNORE';
1450   local $SIG{PIPE} = 'IGNORE';
1451
1452   my $oldAutoCommit = $FS::UID::AutoCommit;
1453   local $FS::UID::AutoCommit = 0;
1454   my $dbh = dbh;
1455
1456   #a little false laziness w/due_cust_event (not too bad, really)
1457
1458   my $join = FS::part_event_condition->join_conditions_sql;
1459   my $order = FS::part_event_condition->order_conditions_sql;
1460   my $mine =
1461   '( '
1462    . join ( ' OR ' , map {
1463     "( part_event.eventtable = " . dbh->quote($_)
1464     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key . " from $_ where custnum = " . dbh->quote( $self->custnum ) . "))" ;
1465    } FS::part_event->eventtables)
1466    . ') ';
1467
1468   #here is the agent virtualization
1469   my $agent_virt = " (    part_event.agentnum IS NULL
1470                        OR part_event.agentnum = ". $self->agentnum. ' )';
1471
1472   #XXX this shouldn't be hardcoded, actions should declare it...
1473   my @realtime_events = qw(
1474     cust_bill_realtime_card
1475     cust_bill_realtime_check
1476     cust_bill_realtime_lec
1477     cust_bill_batch
1478   );
1479
1480   my $is_realtime_event = ' ( '. join(' OR ', map "part_event.action = '$_'",
1481                                                   @realtime_events
1482                                      ).
1483                           ' ) ';
1484
1485   my @cust_event = qsearchs({
1486     'table'     => 'cust_event',
1487     'select'    => 'cust_event.*',
1488     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1489     'hashref'   => { 'status' => 'done' },
1490     'extra_sql' => " AND statustext IS NOT NULL AND statustext != '' ".
1491                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1492   });
1493
1494   my %seen_invnum = ();
1495   foreach my $cust_event (@cust_event) {
1496
1497     #max one for the customer, one for each open invoice
1498     my $cust_X = $cust_event->cust_X;
1499     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1500                           ? $cust_X->invnum
1501                           : 0
1502                         }++
1503          or $cust_event->part_event->eventtable eq 'cust_bill'
1504             && ! $cust_X->owed;
1505
1506     my $error = $cust_event->retry;
1507     if ( $error ) {
1508       $dbh->rollback if $oldAutoCommit;
1509       return "error scheduling event for retry: $error";
1510     }
1511
1512   }
1513
1514   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1515   '';
1516
1517 }
1518
1519 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1520
1521 Runs billing events; see L<FS::part_event> and the billing events web
1522 interface.
1523
1524 If there is an error, returns the error, otherwise returns false.
1525
1526 Options are passed as name-value pairs.
1527
1528 Currently available options are:
1529
1530 =over 4
1531
1532 =item time
1533
1534 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1535
1536 =item check_freq
1537
1538 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1539
1540 =item stage
1541
1542 "collect" (the default) or "pre-bill"
1543
1544 =item quiet
1545
1546 set true to surpress email card/ACH decline notices.
1547
1548 =item debug
1549
1550 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1551
1552 =back
1553 =cut
1554
1555 # =item payby
1556 #
1557 # allows for one time override of normal customer billing method
1558
1559 # =item retry
1560 #
1561 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1562
1563 sub do_cust_event {
1564   my( $self, %options ) = @_;
1565
1566   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1567
1568   my $time = $options{'time'} || time;
1569
1570   #put below somehow?
1571   local $SIG{HUP} = 'IGNORE';
1572   local $SIG{INT} = 'IGNORE';
1573   local $SIG{QUIT} = 'IGNORE';
1574   local $SIG{TERM} = 'IGNORE';
1575   local $SIG{TSTP} = 'IGNORE';
1576   local $SIG{PIPE} = 'IGNORE';
1577
1578   my $oldAutoCommit = $FS::UID::AutoCommit;
1579   local $FS::UID::AutoCommit = 0;
1580   my $dbh = dbh;
1581
1582   $self->select_for_update; #mutex
1583
1584   if ( $DEBUG ) {
1585     my $balance = $self->balance;
1586     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1587   }
1588
1589 #  if ( exists($options{'retry_card'}) ) {
1590 #    carp 'retry_card option passed to collect is deprecated; use retry';
1591 #    $options{'retry'} ||= $options{'retry_card'};
1592 #  }
1593 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1594 #    my $error = $self->retry_realtime;
1595 #    if ( $error ) {
1596 #      $dbh->rollback if $oldAutoCommit;
1597 #      return $error;
1598 #    }
1599 #  }
1600
1601   # false laziness w/pay_batch::import_results
1602
1603   my $due_cust_event = $self->due_cust_event(
1604     'debug'      => ( $options{'debug'} || 0 ),
1605     'time'       => $time,
1606     'check_freq' => $options{'check_freq'},
1607     'stage'      => ( $options{'stage'} || 'collect' ),
1608   );
1609   unless( ref($due_cust_event) ) {
1610     $dbh->rollback if $oldAutoCommit;
1611     return $due_cust_event;
1612   }
1613
1614   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1615   #never want to roll back an event just because it or a different one
1616   # returned an error
1617   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1618
1619   foreach my $cust_event ( @$due_cust_event ) {
1620
1621     #XXX lock event
1622
1623     #re-eval event conditions (a previous event could have changed things)
1624     unless ( $cust_event->test_conditions( 'time' => $time ) ) {
1625       #don't leave stray "new/locked" records around
1626       my $error = $cust_event->delete;
1627       return $error if $error;
1628       next;
1629     }
1630
1631     {
1632       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1633         if $options{'quiet'};
1634       warn "  running cust_event ". $cust_event->eventnum. "\n"
1635         if $DEBUG > 1;
1636
1637       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1638       if ( my $error = $cust_event->do_event() ) {
1639         #XXX wtf is this?  figure out a proper dealio with return value
1640         #from do_event
1641         return $error;
1642       }
1643     }
1644
1645   }
1646
1647   '';
1648
1649 }
1650
1651 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1652
1653 Inserts database records for and returns an ordered listref of new events due
1654 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1655 events are due, an empty listref is returned.  If there is an error, returns a
1656 scalar error message.
1657
1658 To actually run the events, call each event's test_condition method, and if
1659 still true, call the event's do_event method.
1660
1661 Options are passed as a hashref or as a list of name-value pairs.  Available
1662 options are:
1663
1664 =over 4
1665
1666 =item check_freq
1667
1668 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1669
1670 =item stage
1671
1672 "collect" (the default) or "pre-bill"
1673
1674 =item time
1675
1676 "Current time" for the events.
1677
1678 =item debug
1679
1680 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1681
1682 =item eventtable
1683
1684 Only return events for the specified eventtable (by default, events of all eventtables are returned)
1685
1686 =item objects
1687
1688 Explicitly pass the objects to be tested (typically used with eventtable).
1689
1690 =item testonly
1691
1692 Set to true to return the objects, but not actually insert them into the
1693 database.
1694
1695 =back
1696
1697 =cut
1698
1699 sub due_cust_event {
1700   my $self = shift;
1701   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
1702
1703   #???
1704   #my $DEBUG = $opt{'debug'}
1705   local($DEBUG) = $opt{'debug'}
1706     if defined($opt{'debug'}) && $opt{'debug'} > $DEBUG;
1707   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1708
1709   warn "$me due_cust_event called with options ".
1710        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
1711     if $DEBUG;
1712
1713   $opt{'time'} ||= time;
1714
1715   local $SIG{HUP} = 'IGNORE';
1716   local $SIG{INT} = 'IGNORE';
1717   local $SIG{QUIT} = 'IGNORE';
1718   local $SIG{TERM} = 'IGNORE';
1719   local $SIG{TSTP} = 'IGNORE';
1720   local $SIG{PIPE} = 'IGNORE';
1721
1722   my $oldAutoCommit = $FS::UID::AutoCommit;
1723   local $FS::UID::AutoCommit = 0;
1724   my $dbh = dbh;
1725
1726   $self->select_for_update #mutex
1727     unless $opt{testonly};
1728
1729   ###
1730   # find possible events (initial search)
1731   ###
1732
1733   my @cust_event = ();
1734
1735   my @eventtable = $opt{'eventtable'}
1736                      ? ( $opt{'eventtable'} )
1737                      : FS::part_event->eventtables_runorder;
1738
1739   my $check_freq = $opt{'check_freq'} || '1d';
1740
1741   foreach my $eventtable ( @eventtable ) {
1742
1743     my @objects;
1744     if ( $opt{'objects'} ) {
1745
1746       @objects = @{ $opt{'objects'} };
1747
1748     } else {
1749
1750       #my @objects = $self->$eventtable(); # sub cust_main { @{ [ $self ] }; }
1751       if ( $eventtable eq 'cust_main' ) {
1752         @objects = ( $self );
1753       } else {
1754
1755         my $cm_join =
1756           "LEFT JOIN cust_main USING ( custnum )";
1757
1758         #some false laziness w/Cron::bill bill_where
1759
1760         my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
1761         my $where = FS::part_event_condition->where_conditions_sql($eventtable,
1762                                                            'time'=>$opt{'time'},
1763                                                                   );
1764         $where = $where ? "AND $where" : '';
1765
1766         my $are_part_event =
1767           "EXISTS ( SELECT 1 FROM part_event $join
1768                       WHERE check_freq = '$check_freq'
1769                         AND eventtable = '$eventtable'
1770                         AND ( disabled = '' OR disabled IS NULL )
1771                         $where
1772                   )
1773           ";
1774         #eofalse
1775
1776         @objects = $self->$eventtable(
1777                      'addl_from' => $cm_join,
1778                      'extra_sql' => " AND $are_part_event",
1779                    );
1780       }
1781
1782     }
1783
1784     my @e_cust_event = ();
1785
1786     my $cross = "CROSS JOIN $eventtable";
1787     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
1788       unless $eventtable eq 'cust_main';
1789
1790     foreach my $object ( @objects ) {
1791
1792       #this first search uses the condition_sql magic for optimization.
1793       #the more possible events we can eliminate in this step the better
1794
1795       my $cross_where = '';
1796       my $pkey = $object->primary_key;
1797       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
1798
1799       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
1800       my $extra_sql =
1801         FS::part_event_condition->where_conditions_sql( $eventtable,
1802                                                         'time'=>$opt{'time'}
1803                                                       );
1804       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
1805
1806       $extra_sql = "AND $extra_sql" if $extra_sql;
1807
1808       #here is the agent virtualization
1809       $extra_sql .= " AND (    part_event.agentnum IS NULL
1810                             OR part_event.agentnum = ". $self->agentnum. ' )';
1811
1812       $extra_sql .= " $order";
1813
1814       warn "searching for events for $eventtable ". $object->$pkey. "\n"
1815         if $opt{'debug'} > 2;
1816       my @part_event = qsearch( {
1817         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
1818         'select'    => 'part_event.*',
1819         'table'     => 'part_event',
1820         'addl_from' => "$cross $join",
1821         'hashref'   => { 'check_freq' => $check_freq,
1822                          'eventtable' => $eventtable,
1823                          'disabled'   => '',
1824                        },
1825         'extra_sql' => "AND $cross_where $extra_sql",
1826       } );
1827
1828       if ( $DEBUG > 2 ) {
1829         my $pkey = $object->primary_key;
1830         warn "      ". scalar(@part_event).
1831              " possible events found for $eventtable ". $object->$pkey(). "\n";
1832       }
1833
1834       push @e_cust_event, map { $_->new_cust_event($object) } @part_event;
1835
1836     }
1837
1838     warn "    ". scalar(@e_cust_event).
1839          " subtotal possible cust events found for $eventtable\n"
1840       if $DEBUG > 1;
1841
1842     push @cust_event, @e_cust_event;
1843
1844   }
1845
1846   warn "  ". scalar(@cust_event).
1847        " total possible cust events found in initial search\n"
1848     if $DEBUG; # > 1;
1849
1850
1851   ##
1852   # test stage
1853   ##
1854
1855   $opt{stage} ||= 'collect';
1856   @cust_event =
1857     grep { my $stage = $_->part_event->event_stage;
1858            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
1859          }
1860          @cust_event;
1861
1862   ##
1863   # test conditions
1864   ##
1865
1866   my %unsat = ();
1867
1868   @cust_event = grep $_->test_conditions( 'time'          => $opt{'time'},
1869                                           'stats_hashref' => \%unsat ),
1870                      @cust_event;
1871
1872   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
1873     if $DEBUG; # > 1;
1874
1875   warn "    invalid conditions not eliminated with condition_sql:\n".
1876        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
1877     if keys %unsat && $DEBUG; # > 1;
1878
1879   ##
1880   # insert
1881   ##
1882
1883   unless( $opt{testonly} ) {
1884     foreach my $cust_event ( @cust_event ) {
1885
1886       my $error = $cust_event->insert();
1887       if ( $error ) {
1888         $dbh->rollback if $oldAutoCommit;
1889         return $error;
1890       }
1891
1892     }
1893   }
1894
1895   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1896
1897   ##
1898   # return
1899   ##
1900
1901   warn "  returning events: ". Dumper(@cust_event). "\n"
1902     if $DEBUG > 2;
1903
1904   \@cust_event;
1905
1906 }
1907
1908 =item apply_payments_and_credits [ OPTION => VALUE ... ]
1909
1910 Applies unapplied payments and credits.
1911
1912 In most cases, this new method should be used in place of sequential
1913 apply_payments and apply_credits methods.
1914
1915 A hash of optional arguments may be passed.  Currently "manual" is supported.
1916 If true, a payment receipt is sent instead of a statement when
1917 'payment_receipt_email' configuration option is set.
1918
1919 If there is an error, returns the error, otherwise returns false.
1920
1921 =cut
1922
1923 sub apply_payments_and_credits {
1924   my( $self, %options ) = @_;
1925
1926   local $SIG{HUP} = 'IGNORE';
1927   local $SIG{INT} = 'IGNORE';
1928   local $SIG{QUIT} = 'IGNORE';
1929   local $SIG{TERM} = 'IGNORE';
1930   local $SIG{TSTP} = 'IGNORE';
1931   local $SIG{PIPE} = 'IGNORE';
1932
1933   my $oldAutoCommit = $FS::UID::AutoCommit;
1934   local $FS::UID::AutoCommit = 0;
1935   my $dbh = dbh;
1936
1937   $self->select_for_update; #mutex
1938
1939   foreach my $cust_bill ( $self->open_cust_bill ) {
1940     my $error = $cust_bill->apply_payments_and_credits(%options);
1941     if ( $error ) {
1942       $dbh->rollback if $oldAutoCommit;
1943       return "Error applying: $error";
1944     }
1945   }
1946
1947   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1948   ''; #no error
1949
1950 }
1951
1952 =item apply_credits OPTION => VALUE ...
1953
1954 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
1955 to outstanding invoice balances in chronological order (or reverse
1956 chronological order if the I<order> option is set to B<newest>) and returns the
1957 value of any remaining unapplied credits available for refund (see
1958 L<FS::cust_refund>).
1959
1960 Dies if there is an error.
1961
1962 =cut
1963
1964 sub apply_credits {
1965   my $self = shift;
1966   my %opt = @_;
1967
1968   local $SIG{HUP} = 'IGNORE';
1969   local $SIG{INT} = 'IGNORE';
1970   local $SIG{QUIT} = 'IGNORE';
1971   local $SIG{TERM} = 'IGNORE';
1972   local $SIG{TSTP} = 'IGNORE';
1973   local $SIG{PIPE} = 'IGNORE';
1974
1975   my $oldAutoCommit = $FS::UID::AutoCommit;
1976   local $FS::UID::AutoCommit = 0;
1977   my $dbh = dbh;
1978
1979   $self->select_for_update; #mutex
1980
1981   unless ( $self->total_unapplied_credits ) {
1982     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1983     return 0;
1984   }
1985
1986   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
1987       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
1988
1989   my @invoices = $self->open_cust_bill;
1990   @invoices = sort { $b->_date <=> $a->_date } @invoices
1991     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
1992
1993   if ( $conf->exists('pkg-balances') ) {
1994     # limit @credits to those w/ a pkgnum grepped from $self
1995     my %pkgnums = ();
1996     foreach my $i (@invoices) {
1997       foreach my $li ( $i->cust_bill_pkg ) {
1998         $pkgnums{$li->pkgnum} = 1;
1999       }
2000     }
2001     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2002   }
2003
2004   my $credit;
2005
2006   foreach my $cust_bill ( @invoices ) {
2007
2008     if ( !defined($credit) || $credit->credited == 0) {
2009       $credit = pop @credits or last;
2010     }
2011
2012     my $owed;
2013     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2014       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2015     } else {
2016       $owed = $cust_bill->owed;
2017     }
2018     unless ( $owed > 0 ) {
2019       push @credits, $credit;
2020       next;
2021     }
2022
2023     my $amount = min( $credit->credited, $owed );
2024
2025     my $cust_credit_bill = new FS::cust_credit_bill ( {
2026       'crednum' => $credit->crednum,
2027       'invnum'  => $cust_bill->invnum,
2028       'amount'  => $amount,
2029     } );
2030     $cust_credit_bill->pkgnum( $credit->pkgnum )
2031       if $conf->exists('pkg-balances') && $credit->pkgnum;
2032     my $error = $cust_credit_bill->insert;
2033     if ( $error ) {
2034       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2035       die $error;
2036     }
2037
2038     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2039
2040   }
2041
2042   my $total_unapplied_credits = $self->total_unapplied_credits;
2043
2044   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2045
2046   return $total_unapplied_credits;
2047 }
2048
2049 =item apply_payments  [ OPTION => VALUE ... ]
2050
2051 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2052 to outstanding invoice balances in chronological order.
2053
2054  #and returns the value of any remaining unapplied payments.
2055
2056 A hash of optional arguments may be passed.  Currently "manual" is supported.
2057 If true, a payment receipt is sent instead of a statement when
2058 'payment_receipt_email' configuration option is set.
2059
2060 Dies if there is an error.
2061
2062 =cut
2063
2064 sub apply_payments {
2065   my( $self, %options ) = @_;
2066
2067   local $SIG{HUP} = 'IGNORE';
2068   local $SIG{INT} = 'IGNORE';
2069   local $SIG{QUIT} = 'IGNORE';
2070   local $SIG{TERM} = 'IGNORE';
2071   local $SIG{TSTP} = 'IGNORE';
2072   local $SIG{PIPE} = 'IGNORE';
2073
2074   my $oldAutoCommit = $FS::UID::AutoCommit;
2075   local $FS::UID::AutoCommit = 0;
2076   my $dbh = dbh;
2077
2078   $self->select_for_update; #mutex
2079
2080   #return 0 unless
2081
2082   my @payments = sort { $b->_date <=> $a->_date }
2083                  grep { $_->unapplied > 0 }
2084                  $self->cust_pay;
2085
2086   my @invoices = sort { $a->_date <=> $b->_date}
2087                  grep { $_->owed > 0 }
2088                  $self->cust_bill;
2089
2090   if ( $conf->exists('pkg-balances') ) {
2091     # limit @payments to those w/ a pkgnum grepped from $self
2092     my %pkgnums = ();
2093     foreach my $i (@invoices) {
2094       foreach my $li ( $i->cust_bill_pkg ) {
2095         $pkgnums{$li->pkgnum} = 1;
2096       }
2097     }
2098     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2099   }
2100
2101   my $payment;
2102
2103   foreach my $cust_bill ( @invoices ) {
2104
2105     if ( !defined($payment) || $payment->unapplied == 0 ) {
2106       $payment = pop @payments or last;
2107     }
2108
2109     my $owed;
2110     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2111       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2112     } else {
2113       $owed = $cust_bill->owed;
2114     }
2115     unless ( $owed > 0 ) {
2116       push @payments, $payment;
2117       next;
2118     }
2119
2120     my $amount = min( $payment->unapplied, $owed );
2121
2122     my $cbp = {
2123       'paynum' => $payment->paynum,
2124       'invnum' => $cust_bill->invnum,
2125       'amount' => $amount,
2126     };
2127     $cbp->{_date} = $payment->_date
2128         if $options{'manual'} && $options{'backdate_application'};
2129     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2130     $cust_bill_pay->pkgnum( $payment->pkgnum )
2131       if $conf->exists('pkg-balances') && $payment->pkgnum;
2132     my $error = $cust_bill_pay->insert(%options);
2133     if ( $error ) {
2134       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2135       die $error;
2136     }
2137
2138     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2139
2140   }
2141
2142   my $total_unapplied_payments = $self->total_unapplied_payments;
2143
2144   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2145
2146   return $total_unapplied_payments;
2147 }
2148
2149 =back
2150
2151 =head1 BUGS
2152
2153 =head1 SEE ALSO
2154
2155 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2156
2157 =cut
2158
2159 1;