FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use Tie::RefHash;
  12 use FS::cust_bill;
  13 use FS::cust_bill_pkg;
  14 use FS::cust_bill_pkg_display;
  15 use FS::cust_bill_pay;
  16 use FS::cust_credit_bill;
  17 use FS::cust_tax_adjustment;
  18 use FS::tax_rate;
  19 use FS::tax_rate_location;
  20 use FS::cust_bill_pkg_tax_location;
  21 use FS::cust_bill_pkg_tax_rate_location;
  22 use FS::part_event;
  23 use FS::part_event_condition;
  24 use FS::pkg_category;
  25 use FS::FeeOrigin_Mixin;
  26 use FS::Log;
  27
  28 # 1 is mostly method/subroutine entry and options
  29 # 2 traces progress of some operations
  30 # 3 is even more information including possibly sensitive data
  31 $DEBUG = 0;
  32 $me = '[FS::cust_main::Billing]';
  33
  34 install_callback FS::UID sub {
  35   $conf = new FS::Conf;
  36   #yes, need it for stuff below (prolly should be cached)
  37 };
  38
  39 =head1 NAME
  40
  41 FS::cust_main::Billing - Billing mixin for cust_main
  42
  43 =head1 SYNOPSIS
  44
  45 =head1 DESCRIPTION
  46
  47 These methods are available on FS::cust_main objects.
  48
  49 =head1 METHODS
  50
  51 =over 4
  52
  53 =item bill_and_collect
  54
  55 Cancels and suspends any packages due, generates bills, applies payments and
  56 credits, and applies collection events to run cards, send bills and notices,
  57 etc.
  58
  59 By default, warns on errors and continues with the next operation (but see the
  60 "fatal" flag below).
  61
  62 Options are passed as name-value pairs.  Currently available options are:
  63
  64 =over 4
  65
  66 =item time
  67
  68 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  69
  70  use Date::Parse;
  71  ...
  72  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  73
  74 =item invoice_time
  75
  76 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  77
  78 =item check_freq
  79
  80 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  81
  82 =item resetup
  83
  84 If set true, re-charges setup fees.
  85
  86 =item fatal
  87
  88 If set any errors prevent subsequent operations from continusing.  If set
  89 specifically to "return", returns the error (or false, if there is no error).
  90 Any other true value causes errors to die.
  91
  92 =item debug
  93
  94 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  95
  96 =item job
  97
  98 Optional FS::queue entry to receive status updates.
  99
 100 =back
 101
 102 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 103 options of those methods are also available.
 104
 105 =cut
 106
 107 sub bill_and_collect {
 108   my( $self, %options ) = @_;
 109
 110   my $log = FS::Log->new('FS::cust_main::Billing::bill_and_collect');
 111   my %logopt = (object => $self);
 112   $log->debug('start', %logopt);
 113
 114   my $error;
 115
 116   #$options{actual_time} not $options{time} because freeside-daily -d is for
 117   #pre-printing invoices
 118
 119   $options{'actual_time'} ||= time;
 120   my $job = $options{'job'};
 121
 122   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 123                         ? day_end( $options{actual_time} )
 124                         : $options{actual_time}
 125                     );
 126
 127   $job->update_statustext('0,cleaning expired packages') if $job;
 128   $log->debug('canceling expired packages', %logopt);
 129   $error = $self->cancel_expired_pkgs( $actual_time );
 130   if ( $error ) {
 131     $error = "Error expiring custnum ". $self->custnum. ": $error";
 132     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 133     elsif ( $options{fatal}                                ) { die    $error; }
 134     else                                                     { warn   $error; }
 135   }
 136
 137   $log->debug('suspending adjourned packages', %logopt);
 138   $error = $self->suspend_adjourned_pkgs( $actual_time );
 139   if ( $error ) {
 140     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 141     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 142     elsif ( $options{fatal}                                ) { die    $error; }
 143     else                                                     { warn   $error; }
 144   }
 145
 146   $log->debug('unsuspending resumed packages', %logopt);
 147   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 148   if ( $error ) {
 149     $error = "Error resuming custnum ".$self->custnum. ": $error";
 150     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 151     elsif ( $options{fatal}                                ) { die    $error; }
 152     else                                                     { warn   $error; }
 153   }
 154
 155   $job->update_statustext('20,billing packages') if $job;
 156   $log->debug('billing packages', %logopt);
 157   $error = $self->bill( %options );
 158   if ( $error ) {
 159     $error = "Error billing custnum ". $self->custnum. ": $error";
 160     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 161     elsif ( $options{fatal}                                ) { die    $error; }
 162     else                                                     { warn   $error; }
 163   }
 164
 165   $job->update_statustext('50,applying payments and credits') if $job;
 166   $log->debug('applying payments and credits', %logopt);
 167   $error = $self->apply_payments_and_credits;
 168   if ( $error ) {
 169     $error = "Error applying custnum ". $self->custnum. ": $error";
 170     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 171     elsif ( $options{fatal}                                ) { die    $error; }
 172     else                                                     { warn   $error; }
 173   }
 174
 175   unless ( $conf->exists('cancelled_cust-noevents')
 176            && ! $self->num_ncancelled_pkgs
 177   ) {
 178     $job->update_statustext('70,running collection events') if $job;
 179     $log->debug('running collection events', %logopt);
 180     $error = $self->collect( %options );
 181     if ( $error ) {
 182       $error = "Error collecting custnum ". $self->custnum. ": $error";
 183       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 184       elsif ($options{fatal}                               ) { die    $error; }
 185       else                                                   { warn   $error; }
 186     }
 187   }
 188
 189   $job->update_statustext('100,finished') if $job;
 190   $log->debug('finish', %logopt);
 191
 192   '';
 193
 194 }
 195
 196 sub cancel_expired_pkgs {
 197   my ( $self, $time, %options ) = @_;
 198
 199   my @cancel_pkgs = $self->ncancelled_pkgs( {
 200     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 201   } );
 202
 203   my @errors = ();
 204
 205   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 206     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 207     my $error;
 208
 209     if ( $cust_pkg->change_to_pkgnum ) {
 210
 211       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 212       if ( !$new_pkg ) {
 213         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 214                       $cust_pkg->change_to_pkgnum.'; not expiring';
 215         next CUST_PKG;
 216       }
 217       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 218                                   'unprotect_svcs'  => 1 );
 219       $error = '' if ref $error eq 'FS::cust_pkg';
 220
 221     } else { # just cancel it
 222        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 223                                            'reason_otaker' => $cpr->otaker,
 224                                            'time'          => $time,
 225                                          )
 226                                        : ()
 227                                  );
 228     }
 229     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 230   }
 231
 232   join(' / ', @errors);
 233
 234 }
 235
 236 sub suspend_adjourned_pkgs {
 237   my ( $self, $time, %options ) = @_;
 238
 239   my @susp_pkgs = $self->ncancelled_pkgs( {
 240     'extra_sql' =>
 241       " AND ( susp IS NULL OR susp = 0 )
 242         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 243               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 244             )
 245       ",
 246   } );
 247
 248   #only because there's no SQL test for is_prepaid :/
 249   @susp_pkgs =
 250     grep {     (    $_->part_pkg->is_prepaid
 251                  && $_->bill
 252                  && $_->bill < $time
 253                )
 254             || (    $_->adjourn
 255                  && $_->adjourn <= $time
 256                )
 257
 258          }
 259          @susp_pkgs;
 260
 261   my @errors = ();
 262
 263   foreach my $cust_pkg ( @susp_pkgs ) {
 264     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 265       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 266     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 267                                             'reason_otaker' => $cpr->otaker
 268                                           )
 269                                         : ()
 270                                   );
 271     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 272   }
 273
 274   join(' / ', @errors);
 275
 276 }
 277
 278 sub unsuspend_resumed_pkgs {
 279   my ( $self, $time, %options ) = @_;
 280
 281   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 282     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 283   } );
 284
 285   my @errors = ();
 286
 287   foreach my $cust_pkg ( @unsusp_pkgs ) {
 288     my $error = $cust_pkg->unsuspend( 'time' => $time );
 289     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 290   }
 291
 292   join(' / ', @errors);
 293
 294 }
 295
 296 =item bill OPTIONS
 297
 298 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 299 conjunction with the collect method by calling B<bill_and_collect>.
 300
 301 If there is an error, returns the error, otherwise returns false.
 302
 303 Options are passed as name-value pairs.  Currently available options are:
 304
 305 =over 4
 306
 307 =item resetup
 308
 309 If set true, re-charges setup fees.
 310
 311 =item recurring_only
 312
 313 If set true then only bill recurring charges, not setup, usage, one time
 314 charges, etc.
 315
 316 =item freq_override
 317
 318 If set, then override the normal frequency and look for a part_pkg_discount
 319 to take at that frequency.  This is appropriate only when the normal
 320 frequency for all packages is monthly, and is an error otherwise.  Use
 321 C<pkg_list> to limit the set of packages included in billing.
 322
 323 =item time
 324
 325 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 326
 327  use Date::Parse;
 328  ...
 329  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 330
 331 =item pkg_list
 332
 333 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 334
 335  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 336
 337 =item not_pkgpart
 338
 339 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 340
 341 =item no_prepaid
 342
 343 Do not bill prepaid packages.  Used by freeside-daily.
 344
 345 =item invoice_time
 346
 347 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 348
 349 =item cancel
 350
 351 This boolean value informs the us that the package is being cancelled.  This
 352 typically might mean not charging the normal recurring fee but only usage
 353 fees since the last billing. Setup charges may be charged.  Not all package
 354 plans support this feature (they tend to charge 0).
 355
 356 =item no_usage_reset
 357
 358 Prevent the resetting of usage limits during this call.
 359
 360 =item no_commit
 361
 362 Do not save the generated bill in the database.  Useful with return_bill
 363
 364 =item return_bill
 365
 366 A list reference on which the generated bill(s) will be returned.
 367
 368 =item invoice_terms
 369
 370 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 371 terms or the default terms are used.
 372
 373 =back
 374
 375 =cut
 376
 377 sub bill {
 378   my( $self, %options ) = @_;
 379
 380   return '' if $self->payby eq 'COMP';
 381
 382   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 383   my $log = FS::Log->new('FS::cust_main::Billing::bill');
 384   my %logopt = (object => $self);
 385
 386   $log->debug('start', %logopt);
 387   warn "$me bill customer ". $self->custnum. "\n"
 388     if $DEBUG;
 389
 390   my $time = $options{'time'} || time;
 391   my $invoice_time = $options{'invoice_time'} || $time;
 392
 393   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 394                      ? day_end( $time )
 395                      : $time
 396                  );
 397
 398   $options{'not_pkgpart'} ||= {};
 399   $options{'not_pkgpart'} = { map { $_ => 1 }
 400                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 401                             }
 402     unless ref($options{'not_pkgpart'});
 403
 404   local $SIG{HUP} = 'IGNORE';
 405   local $SIG{INT} = 'IGNORE';
 406   local $SIG{QUIT} = 'IGNORE';
 407   local $SIG{TERM} = 'IGNORE';
 408   local $SIG{TSTP} = 'IGNORE';
 409   local $SIG{PIPE} = 'IGNORE';
 410
 411   my $oldAutoCommit = $FS::UID::AutoCommit;
 412   local $FS::UID::AutoCommit = 0;
 413   my $dbh = dbh;
 414
 415   $log->debug('acquiring lock', %logopt);
 416   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 417     if $DEBUG;
 418
 419   $self->select_for_update; #mutex
 420
 421   $log->debug('running pre-bill events', %logopt);
 422   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 423     if $DEBUG;
 424
 425   my $error = $self->do_cust_event(
 426     'debug'      => ( $options{'debug'} || 0 ),
 427     'time'       => $invoice_time,
 428     'check_freq' => $options{'check_freq'},
 429     'stage'      => 'pre-bill',
 430   )
 431     unless $options{no_commit};
 432   if ( $error ) {
 433     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 434     return $error;
 435   }
 436
 437   $log->debug('done running pre-bill events', %logopt);
 438   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 439     if $DEBUG;
 440
 441   #keep auto-charge and non-auto-charge line items separate
 442   my @passes = ( '', 'no_auto' );
 443
 444   my %cust_bill_pkg = map { $_ => [] } @passes;
 445
 446   ###
 447   # find the packages which are due for billing, find out how much they are
 448   # & generate invoice database.
 449   ###
 450
 451   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 452   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 453
 454   my %taxlisthash = map { $_ => {} } @passes;
 455
 456   my @precommit_hooks = ();
 457
 458   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 459
 460   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 461
 462     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 463
 464     my $part_pkg = $cust_pkg->part_pkg;
 465
 466     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 467
 468     $log->debug('bill package '. $cust_pkg->pkgnum, %logopt);
 469     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 470
 471     #? to avoid use of uninitialized value errors... ?
 472     $cust_pkg->setfield('bill', '')
 473       unless defined($cust_pkg->bill);
 474
 475     my $real_pkgpart = $cust_pkg->pkgpart;
 476     my %hash = $cust_pkg->hash;
 477
 478     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 479     # suffer from performance issues
 480     $options{has_hidden} = 0;
 481     my @part_pkg = $part_pkg->self_and_bill_linked;
 482     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 483
 484     # if this package was changed from another package,
 485     # and it hasn't been billed since then,
 486     # and package balances are enabled,
 487     if ( $cust_pkg->change_pkgnum
 488         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 489         and $cust_pkg->change_date <  $invoice_time
 490       and $conf->exists('pkg-balances') )
 491     {
 492       # _transfer_balance will also create the appropriate credit
 493       my @transfer_items = $self->_transfer_balance($cust_pkg);
 494       # $part_pkg[0] is the "real" part_pkg
 495       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 496                   'no_auto' : '';
 497       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 498       # treating this as recur, just because most charges are recur...
 499       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 500
 501       # currently not considering separate_bill here, as it's for
 502       # one-time charges only
 503     }
 504
 505     foreach my $part_pkg ( @part_pkg ) {
 506
 507       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 508
 509       my $pass = '';
 510       if ( $cust_pkg->separate_bill ) {
 511         # if no_auto is also set, that's fine. we just need to not have
 512         # invoices that are both auto and no_auto, and since the package
 513         # gets an invoice all to itself, it will only be one or the other.
 514         $pass = $cust_pkg->pkgnum;
 515         if (!exists $cust_bill_pkg{$pass}) { # it may not exist yet
 516           push @passes, $pass;
 517           $total_setup{$pass} = do { my $z = 0; \$z };
 518           $total_recur{$pass} = do { my $z = 0; \$z };
 519           $taxlisthash{$pass} = {};
 520           $cust_bill_pkg{$pass} = [];
 521         }
 522       } elsif ( ($cust_pkg->no_auto || $part_pkg->no_auto) ) {
 523         $pass = 'no_auto';
 524       }
 525
 526       my $next_bill = $cust_pkg->getfield('bill') || 0;
 527       my $error;
 528       # let this run once if this is the last bill upon cancellation
 529       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 530         $error =
 531           $self->_make_lines( 'part_pkg'            => $part_pkg,
 532                               'cust_pkg'            => $cust_pkg,
 533                               'precommit_hooks'     => \@precommit_hooks,
 534                               'line_items'          => $cust_bill_pkg{$pass},
 535                               'setup'               => $total_setup{$pass},
 536                               'recur'               => $total_recur{$pass},
 537                               'tax_matrix'          => $taxlisthash{$pass},
 538                               'time'                => $time,
 539                               'real_pkgpart'        => $real_pkgpart,
 540                               'options'             => \%options,
 541                             );
 542
 543         # Stop if anything goes wrong
 544         last if $error;
 545
 546         # or if we're not incrementing the bill date.
 547         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 548
 549         # or if we're letting it run only once
 550         last if $options{cancel};
 551
 552         $next_bill = $cust_pkg->getfield('bill') || 0;
 553
 554         #stop if -o was passed to freeside-daily
 555         last if $options{'one_recur'};
 556       }
 557       if ($error) {
 558         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 559         return $error;
 560       }
 561
 562     } #foreach my $part_pkg
 563
 564   } #foreach my $cust_pkg
 565
 566   foreach my $pass (@passes) { # keys %cust_bill_pkg )
 567
 568     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 569
 570     warn "$me billing pass $pass\n"
 571            #.Dumper(\@cust_bill_pkg)."\n"
 572       if $DEBUG > 2;
 573
 574     ###
 575     # process fees
 576     ###
 577
 578     my @pending_fees = FS::FeeOrigin_Mixin->by_cust($self->custnum,
 579       hashref => { 'billpkgnum' => '' }
 580     );
 581     warn "$me found pending fees:\n".Dumper(\@pending_fees)."\n"
 582       if @pending_fees and $DEBUG > 1;
 583
 584     # determine whether to generate an invoice
 585     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 586
 587     foreach my $fee (@pending_fees) {
 588       $generate_bill = 1 unless $fee->nextbill;
 589     }
 590
 591     # don't create an invoice with no line items, or where the only line
 592     # items are fees that are supposed to be held until the next invoice
 593     next if !$generate_bill;
 594
 595     # calculate fees...
 596     my @fee_items;
 597     foreach my $fee_origin (@pending_fees) {
 598       my $part_fee = $fee_origin->part_fee;
 599
 600       # check whether the fee is applicable before doing anything expensive:
 601       #
 602       # if the fee def belongs to a different agent, don't charge the fee.
 603       # event conditions should prevent this, but just in case they don't,
 604       # skip the fee.
 605       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 606         warn "tried to charge fee#".$part_fee->feepart .
 607              " on customer#".$self->custnum." from a different agent.\n";
 608         next;
 609       }
 610       # also skip if it's disabled
 611       next if $part_fee->disabled eq 'Y';
 612
 613       # Decide which invoice to base the fee on.
 614       my $cust_bill = $fee_origin->cust_bill;
 615       if (!$cust_bill) {
 616         # Then link it to the current invoice. This isn't the real cust_bill
 617         # object that will be inserted--in particular there are no taxes yet.
 618         # If you want to charge a fee on the total invoice amount including
 619         # taxes, you have to put the fee on the next invoice.
 620         $cust_bill = FS::cust_bill->new({
 621             'custnum'       => $self->custnum,
 622             'cust_bill_pkg' => \@cust_bill_pkg,
 623             'charged'       => ${ $total_setup{$pass} } +
 624                                ${ $total_recur{$pass} },
 625         });
 626
 627         # If the origin is for a specific package, then only apply the fee to
 628         # line items from that package.
 629         if ( my $cust_pkg = $fee_origin->cust_pkg ) {
 630           my @charge_fee_on_item;
 631           my $charge_fee_on_amount = 0;
 632           foreach (@cust_bill_pkg) {
 633             if ($_->pkgnum == $cust_pkg->pkgnum) {
 634               push @charge_fee_on_item, $_;
 635               $charge_fee_on_amount += $_->setup + $_->recur;
 636             }
 637           }
 638           $cust_bill->set('cust_bill_pkg', \@charge_fee_on_item);
 639           $cust_bill->set('charged', $charge_fee_on_amount);
 640         }
 641
 642       } # $cust_bill is now set
 643       # calculate the fee
 644       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 645       # link this so that we can clear the marker on inserting the line item
 646       $fee_item->set('fee_origin', $fee_origin);
 647       push @fee_items, $fee_item;
 648
 649     }
 650
 651     # add fees to the invoice
 652     foreach my $fee_item (@fee_items) {
 653
 654       push @cust_bill_pkg, $fee_item;
 655       ${ $total_setup{$pass} } += $fee_item->setup;
 656       ${ $total_recur{$pass} } += $fee_item->recur;
 657
 658       my $part_fee = $fee_item->part_fee;
 659       my $fee_location = $self->ship_location; # I think?
 660
 661       my $error = $self->_handle_taxes(
 662         $taxlisthash{$pass},
 663         $fee_item,
 664         location => $fee_location
 665         # probably not right to pass cancel => 1 for fees
 666       );
 667       return $error if $error;
 668
 669     }
 670
 671     # XXX implementation of fees is supposed to make this go away...
 672     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 673            !$conf->exists('postal_invoice-recurring_only')
 674        )
 675     {
 676
 677       my $postal_pkg = $self->charge_postal_fee();
 678       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 679
 680         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 681         return "can't charge postal invoice fee for customer ".
 682           $self->custnum. ": $postal_pkg";
 683
 684       } elsif ( $postal_pkg ) {
 685
 686         my $real_pkgpart = $postal_pkg->pkgpart;
 687         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 688         # suffer from performance issues
 689         $options{has_hidden} = 0;
 690         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 691         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 692
 693         foreach my $part_pkg ( @part_pkg ) {
 694           my %postal_options = %options;
 695           delete $postal_options{cancel};
 696           my $error =
 697             $self->_make_lines( 'part_pkg'            => $part_pkg,
 698                                 'cust_pkg'            => $postal_pkg,
 699                                 'precommit_hooks'     => \@precommit_hooks,
 700                                 'line_items'          => \@cust_bill_pkg,
 701                                 'setup'               => $total_setup{$pass},
 702                                 'recur'               => $total_recur{$pass},
 703                                 'tax_matrix'          => $taxlisthash{$pass},
 704                                 'time'                => $time,
 705                                 'real_pkgpart'        => $real_pkgpart,
 706                                 'options'             => \%postal_options,
 707                               );
 708           if ($error) {
 709             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 710             return $error;
 711           }
 712         }
 713
 714         # it's silly to have a zero value postal_pkg, but....
 715         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 716
 717       }
 718
 719     }
 720
 721     my $listref_or_error =
 722       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 723
 724     unless ( ref( $listref_or_error ) ) {
 725       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 726       return $listref_or_error;
 727     }
 728
 729     foreach my $taxline ( @$listref_or_error ) {
 730       ${ $total_setup{$pass} } =
 731         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 732       push @cust_bill_pkg, $taxline;
 733     }
 734
 735     #add tax adjustments
 736     warn "adding tax adjustments...\n" if $DEBUG > 2;
 737     foreach my $cust_tax_adjustment (
 738       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 739                                        'billpkgnum' => '',
 740                                      }
 741              )
 742     ) {
 743
 744       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 745
 746       my $itemdesc = $cust_tax_adjustment->taxname;
 747       $itemdesc = '' if $itemdesc eq 'Tax';
 748
 749       push @cust_bill_pkg, new FS::cust_bill_pkg {
 750         'pkgnum'      => 0,
 751         'setup'       => $tax,
 752         'recur'       => 0,
 753         'sdate'       => '',
 754         'edate'       => '',
 755         'itemdesc'    => $itemdesc,
 756         'itemcomment' => $cust_tax_adjustment->comment,
 757         'cust_tax_adjustment' => $cust_tax_adjustment,
 758         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 759       };
 760
 761     }
 762
 763     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 764
 765     my $balance = $self->balance;
 766
 767     my $previous_bill = qsearchs({ 'table'     => 'cust_bill',
 768                                    'hashref'   => { custnum=>$self->custnum },
 769                                    'extra_sql' => 'ORDER BY _date DESC LIMIT 1',
 770                                 });
 771     my $previous_balance =
 772       $previous_bill
 773         ? ( $previous_bill->billing_balance + $previous_bill->charged )
 774         : 0;
 775
 776     $log->debug('creating the new invoice', %logopt);
 777     warn "creating the new invoice\n" if $DEBUG;
 778     #create the new invoice
 779     my $cust_bill = new FS::cust_bill ( {
 780       'custnum'             => $self->custnum,
 781       '_date'               => $invoice_time,
 782       'charged'             => $charged,
 783       'billing_balance'     => $balance,
 784       'previous_balance'    => $previous_balance,
 785       'invoice_terms'       => $options{'invoice_terms'},
 786       'cust_bill_pkg'       => \@cust_bill_pkg,
 787     } );
 788     $error = $cust_bill->insert unless $options{no_commit};
 789     if ( $error ) {
 790       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 791       return "can't create invoice for customer #". $self->custnum. ": $error";
 792     }
 793     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 794
 795   } #foreach my $pass ( keys %cust_bill_pkg )
 796
 797   foreach my $hook ( @precommit_hooks ) {
 798     eval {
 799       &{$hook}; #($self) ?
 800     } unless $options{no_commit};
 801     if ( $@ ) {
 802       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 803       return "$@ running precommit hook $hook\n";
 804     }
 805   }
 806
 807   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 808
 809   ''; #no error
 810 }
 811
 812 #discard bundled packages of 0 value
 813 # XXX we should reconsider whether we even need this
 814 sub _omit_zero_value_bundles {
 815   my @in = @_;
 816
 817   my @out = ();
 818   my @bundle = ();
 819   my $discount_show_always = $conf->exists('discount-show-always');
 820   my $show_this = 0;
 821
 822   # Sort @in the same way we do during invoice rendering, so we can identify
 823   # bundles.  See FS::Template_Mixin::_items_nontax.
 824   @in = sort { $a->pkgnum <=> $b->pkgnum        or
 825                $a->sdate  <=> $b->sdate         or
 826                ($a->pkgpart_override ? 0 : -1)  or
 827                ($b->pkgpart_override ? 0 : 1)   or
 828                $b->hidden cmp $a->hidden        or
 829                $a->pkgpart_override <=> $b->pkgpart_override
 830              } @in;
 831
 832   # this is a pack-and-deliver pattern. every time there's a cust_bill_pkg
 833   # _without_ pkgpart_override, that's the start of the new bundle. if there's
 834   # an existing bundle, and it contains a nonzero amount (or a zero amount
 835   # that's displayable anyway), push all line items in the bundle.
 836   foreach my $cust_bill_pkg ( @in ) {
 837
 838     if (scalar(@bundle) and !$cust_bill_pkg->pkgpart_override) {
 839       # ship out this bundle and reset it
 840       if ( $show_this ) {
 841         push @out, @bundle;
 842       }
 843       @bundle = ();
 844       $show_this = 0;
 845     }
 846
 847     # add this item to the current bundle
 848     push @bundle, $cust_bill_pkg;
 849
 850     # determine if it makes the bundle displayable
 851     if (   $cust_bill_pkg->setup > 0
 852         or $cust_bill_pkg->recur > 0
 853         or $cust_bill_pkg->setup_show_zero
 854         or $cust_bill_pkg->recur_show_zero
 855         or ($discount_show_always
 856           and scalar(@{ $cust_bill_pkg->get('discounts')})
 857           )
 858     ) {
 859       $show_this++;
 860     }
 861   }
 862
 863   # last bundle
 864   if ( $show_this) {
 865     push @out, @bundle;
 866   }
 867
 868   warn "  _omit_zero_value_bundles: ". scalar(@in).
 869        '->'. scalar(@out). "\n" #. Dumper(@out). "\n"
 870     if $DEBUG > 2;
 871
 872   @out;
 873 }
 874
 875 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 876
 877 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 878 Usually used internally by bill method B<bill>.
 879
 880 If there is an error, returns the error, otherwise returns reference to a
 881 list of line items suitable for insertion.
 882
 883 =over 4
 884
 885 =item LINEITEMREF
 886
 887 An array ref of the line items being billed.
 888
 889 =item TAXHASHREF
 890
 891 A strange beast.  The keys to this hash are internal identifiers consisting
 892 of the name of the tax object type, a space, and its unique identifier ( e.g.
 893  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 894 item in the list is the tax object.  The remaining items are either line
 895 items or floating point values (currency amounts).
 896
 897 The taxes are calculated on this entity.  Calculated exemption records are
 898 transferred to the LINEITEMREF items on the assumption that they are related.
 899
 900 Read the source.
 901
 902 =item INVOICE_TIME
 903
 904 This specifies the date appearing on the associated invoice.  Some
 905 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 906
 907 =back
 908
 909 =cut
 910
 911 sub calculate_taxes {
 912   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 913
 914   # $taxlisthash is a hashref
 915   # keys are identifiers, values are arrayrefs
 916   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 917   # then a cust_bill_pkg object the tax applies to, then the charge class
 918   # on that object (setup, recur, a usage class number, or '')
 919   # For internal taxes the charge class is always undef.
 920
 921   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 922
 923   warn "$me calculate_taxes\n"
 924        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 925     if $DEBUG > 2;
 926
 927   my $custnum = $self->custnum;
 928   # The main tax accumulator.  One bin for each tax name (itemdesc).
 929   # For each subdivision of tax under this name, push a cust_bill_pkg item
 930   # for the calculated tax into the arrayref.
 931   # keys are tax names
 932   # values are arrayrefs of tax lines
 933   my %taxname = ();
 934
 935   # keys are taxlisthash keys (internal identifiers)
 936   # values are (cumulative) amounts
 937   my %tax_amount = ();
 938
 939   # keys are taxlisthash keys
 940   # values are arrayrefs of cust_tax_exempt_pkg objects
 941   my %tax_exemption;
 942
 943   # For tax on tax calculation, we need to remember which taxable items
 944   # (and charge classes) had which taxes applied to them.
 945   #
 946   # keys are cust_bill_pkg objects (taxable items)
 947   # values are hashrefs
 948   #   keys are charge classes
 949   #   values are hashrefs
 950   #     keys are taxnums (in tax_rate only; cust_main_county doesn't use this)
 951   #     values are the taxlines generated for those taxes
 952   tie my %item_has_tax, 'Tie::RefHash',
 953     map { $_ => {} } @$cust_bill_pkg;
 954
 955   foreach my $tax_id ( keys %$taxlisthash ) {
 956     # $tax_id: the identifier of the tax we are calculating in this pass
 957
 958     my $taxables = $taxlisthash->{$tax_id};
 959     my $tax_object = shift @$taxables;
 960     my $taxnum = $tax_object->taxnum;
 961     # $tax_object is a cust_main_county or tax_rate
 962     # (with billpkgnum, pkgnum, locationnum set)
 963     # the rest of @{ $taxlisthash->{$tax_id} } is cust_bill_pkg objects,
 964     # optionally followed by their charge classes.
 965     warn "found ". $tax_object->taxname. " as $tax_id\n" if $DEBUG > 2;
 966
 967     # taxline calculates the tax on all cust_bill_pkgs in the
 968     # first (arrayref) argument.
 969     #
 970     # Note that non-monthly exemptions have already been calculated and
 971     # attached to the items.  Monthly exemptions will be attached in this
 972     # step.
 973     my $exemptions = $tax_exemption{$tax_id} ||= [];
 974     if ( $tax_object->isa('FS::tax_rate') ) { # EXTERNAL TAXES
 975       # STILL have tax_rate-specific crap in here...
 976       my @taxlines = $tax_object->taxline( $taxables,
 977                               'custnum'      => $custnum,
 978                               'invoice_time' => $invoice_time,
 979                               'exemptions'   => $exemptions,
 980                               );
 981       next if !@taxlines;
 982       if (!ref $taxlines[0]) {
 983         # it's an error string
 984         warn "error evaluating $tax_id on custnum $custnum\n";
 985         return $taxlines[0];
 986       }
 987       foreach my $taxline (@taxlines) {
 988         push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 989         my $link = $taxline->get('cust_bill_pkg_tax_rate_location')->[0];
 990         my $taxable_item = $link->taxable_cust_bill_pkg;
 991         $item_has_tax{$taxable_item}{$taxline->_class}{$taxnum} = $taxline;
 992       }
 993
 994     } else { # INTERNAL TAXES
 995       # we can do this in a single taxline, because it's not stupid
 996
 997       my $taxline =  $tax_object->taxline( $taxables,
 998                         'custnum'      => $custnum,
 999                         'invoice_time' => $invoice_time,
1000                         'exemptions'   => $exemptions,
1001                       );
1002       next if !$taxline;
1003       if (!ref $taxline) {
1004         # it's an error string
1005         warn "error evaluating $tax_id on custnum $custnum\n";
1006         return $taxline;
1007       }
1008       # if the calculated tax is zero, don't even keep it
1009       next if $taxline->setup < 0.001;
1010       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1011     }
1012   }
1013   $DB::single = 1; # XXX
1014
1015   # all first-tier taxes are calculated.  now for tax on tax:
1016
1017   foreach my $taxable_item ( @$cust_bill_pkg ) {
1018     # taxes that apply to this item
1019     my $this_has_tax = $item_has_tax{$taxable_item};
1020
1021     my $location = $taxable_item->tax_location;
1022
1023     foreach my $charge_class (keys %$this_has_tax) {
1024       # taxes that apply to this item and charge class
1025       my $this_class_has_tax = $this_has_tax->{$charge_class};
1026       foreach my $taxnum (keys %$this_class_has_tax) {
1027
1028         # for each tax item that was calculated in phase 1, get the
1029         # tax definition
1030         my $tax_object = FS::tax_rate->by_key($taxnum);
1031         # and find all taxes that apply to it in this location
1032         my @tot = $tax_object->tax_on_tax( $location );
1033         next if !@tot;
1034         warn "found possible taxed taxnum $taxnum\n"
1035           if $DEBUG > 2;
1036         # Calculate ToT separately for each taxable item and class, and only
1037         # if _that class on the item_ is already taxed under the ToT.  This is
1038         # counterintuitive.
1039         # See RT#5243 and RT#36380.
1040         foreach my $tot (@tot) {
1041           my $totnum = $tot->taxnum;
1042           warn "checking taxnum $totnum which we call ". $tot->taxname ."\n"
1043             if $DEBUG > 2;
1044           # note: if the _null class_ on this item is taxed under the ToT,
1045           # then this specific class is taxed also (because null class
1046           # includes all classes) and so ToT is applicable.
1047           if (
1048                 exists $this_class_has_tax->{ $totnum }
1049              or exists $this_has_tax->{''}{ $totnum }
1050           ) {
1051
1052             warn "calculating tax on tax: taxnum $totnum on $taxnum\n"
1053               if $DEBUG;
1054             my @taxlines = $tot->taxline(
1055                               $this_class_has_tax->{ $taxnum }, # the first-stage tax
1056                               'custnum'       => $custnum,
1057                               'invoice_time'  => $invoice_time,
1058                              );
1059             next if (!@taxlines); # it didn't apply after all
1060             if (!ref($taxlines[0])) {
1061               warn "error evaluating taxnum $totnum TOT on custnum $custnum\n";
1062               return $taxlines[0];
1063             }
1064             foreach my $taxline (@taxlines) {
1065               push @{ $taxname{ $taxline->itemdesc } }, $taxline;
1066             }
1067           } # if $has_tax
1068         } # foreach my $tot (tax-on-tax rate definition)
1069       } # foreach $taxnum (first-tier rate definition)
1070     } # foreach $charge_class
1071   } # foreach $taxable_item
1072
1073   #consolidate and create tax line items
1074   warn "consolidating and generating...\n" if $DEBUG > 2;
1075   my %final_tax_items; # taxname => item
1076   foreach my $taxname ( keys %taxname ) {
1077     my @cust_bill_pkg_tax_location;
1078     my @cust_bill_pkg_tax_rate_location;
1079     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
1080         'pkgnum'    => 0,
1081         'recur'     => 0,
1082         'sdate'     => '',
1083         'edate'     => '',
1084         'itemdesc'  => $taxname,
1085         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
1086         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
1087     });
1088
1089     my $tax_total = 0;
1090     my %seen = ();
1091     warn "adding $taxname\n" if $DEBUG > 1;
1092     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
1093       next if $taxitem->get('setup') == 0;
1094       # if ( ref($taxitem) eq 'FS::cust_bill_pkg' )  # always true
1095       # then we need to transfer the amount and the links from the
1096       # line item to the new one we're creating.
1097       $tax_total += $taxitem->setup;
1098       my @links = @{
1099         $taxitem->get('cust_bill_pkg_tax_location') ||
1100         $taxitem->get('cust_bill_pkg_tax_rate_location') ||
1101         []
1102       };
1103       foreach my $link ( @links ) {
1104         $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
1105         if ($link->isa('FS::cust_bill_pkg_tax_location')) {
1106           push @cust_bill_pkg_tax_location, $link;
1107         } elsif ($link->isa('FS::cust_bill_pkg_tax_rate_location')) {
1108           push @cust_bill_pkg_tax_rate_location, $link;
1109         }
1110       }
1111     }
1112     next unless $tax_total;
1113
1114     # we should really neverround this up...I guess it's okay if taxline
1115     # already returns amounts with 2 decimal places
1116     $tax_total = sprintf('%.2f', $tax_total );
1117     $tax_cust_bill_pkg->set('setup', $tax_total);
1118
1119     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1120                                                    'disabled'     => '',
1121                                                  },
1122                                );
1123
1124     my @display = ();
1125     if ( $pkg_category and
1126          $conf->config('invoice_latexsummary') ||
1127          $conf->config('invoice_htmlsummary')
1128        )
1129     {
1130
1131       my %hash = (  'section' => $pkg_category->categoryname );
1132       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1133
1134     }
1135     $tax_cust_bill_pkg->set('display', \@display);
1136
1137     $final_tax_items{$taxname} = $tax_cust_bill_pkg;
1138   } # foreach $taxname
1139
1140   # fix ToT backlinks for taxes that have been consolidated
1141   # (has to be done in a separate pass)
1142   foreach my $tax_item (values %final_tax_items) {
1143     foreach my $taxable_link (@{ $tax_item->cust_bill_pkg_tax_rate_location }) {
1144       my $taxed_item = $taxable_link->taxable_cust_bill_pkg;
1145       next if $taxed_item->pkgnum > 0; # primary taxes
1146       my $taxname = $taxed_item->itemdesc;
1147       $taxable_link->set('taxable_cust_bill_pkg', $final_tax_items{ $taxname });
1148     }
1149   }
1150
1151   [ values %final_tax_items ]
1152 }
1153
1154 sub _make_lines {
1155   my ($self, %params) = @_;
1156
1157   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1158
1159   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1160   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1161   my $cust_location = $cust_pkg->tax_location;
1162   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1163   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1164   my $total_setup = $params{setup} or die "no setup accumulator specified";
1165   my $total_recur = $params{recur} or die "no recur accumulator specified";
1166   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1167   my $time = $params{'time'} or die "no time specified";
1168   my (%options) = %{$params{options}};
1169
1170   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1171     # this should never happen
1172     die 'freq_override billing attempted on non-monthly package '.
1173       $cust_pkg->pkgnum;
1174   }
1175
1176   my $dbh = dbh;
1177   my $real_pkgpart = $params{real_pkgpart};
1178   my %hash = $cust_pkg->hash;
1179   my $old_cust_pkg = new FS::cust_pkg \%hash;
1180
1181   my @details = ();
1182   my $lineitems = 0;
1183
1184   $cust_pkg->pkgpart($part_pkg->pkgpart);
1185
1186   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1187                      ? day_end( $time )
1188                      : $time
1189                  );
1190
1191   ###
1192   # bill setup
1193   ###
1194
1195   my $setup = 0;
1196   my $unitsetup = 0;
1197   my @setup_discounts = ();
1198   my %setup_param = ( 'discounts'    => \@setup_discounts,
1199                       'real_pkgpart' => $params{real_pkgpart}
1200                     );
1201   # Conditions for setting setup date and charging the setup fee:
1202   # - this is not a recurring-only billing run
1203   # - and the package is not currently being canceled
1204   # - and, unless we're specifically told otherwise via 'resetup':
1205   #   - it doesn't already HAVE a setup date
1206   #   - or a start date in the future
1207   #   - and it's not suspended
1208   # - and it doesn't have an expire date in the past
1209   #
1210   # The "disable_setup_suspended" option is now obsolete; we never set the
1211   # setup date on a suspended package.
1212   if (     ! $options{recurring_only}
1213        and ! $options{cancel}
1214        and ( $options{'resetup'}
1215              || ( ! $cust_pkg->setup
1216                   && ( ! $cust_pkg->start_date
1217                        || $cust_pkg->start_date <= $cmp_time
1218                      )
1219                   && ( ! $cust_pkg->getfield('susp') )
1220               )
1221            )
1222        and ( ! $cust_pkg->expire
1223              || $cust_pkg->expire > $cmp_time )
1224      )
1225   {
1226
1227     warn "    bill setup\n" if $DEBUG > 1;
1228
1229     unless ( $cust_pkg->waive_setup ) {
1230         $lineitems++;
1231
1232         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1233         return "$@ running calc_setup for $cust_pkg\n"
1234           if $@;
1235
1236         # Only increment unitsetup here if there IS a setup fee.
1237         # prorate_defer_bill may cause calc_setup on a setup-stage package
1238         # to return zero, and the setup fee to be charged later. (This happens
1239         # when it's first billed on the prorate cutoff day. RT#31276.)
1240         if ( $setup ) {
1241           $unitsetup = $cust_pkg->base_setup()
1242                          || $setup; #XXX uuh
1243         }
1244     }
1245
1246     $cust_pkg->setfield('setup', $time)
1247       unless $cust_pkg->setup;
1248           #do need it, but it won't get written to the db
1249           #|| $cust_pkg->pkgpart != $real_pkgpart;
1250
1251     $cust_pkg->setfield('start_date', '')
1252       if $cust_pkg->start_date;
1253
1254   }
1255
1256   ###
1257   # bill recurring fee
1258   ###
1259
1260   my $recur = 0;
1261   my $unitrecur = 0;
1262   my @recur_discounts = ();
1263   my $sdate;
1264   # Conditions for billing the recurring fee:
1265   # - the package doesn't have a future start date
1266   # - and it's not suspended
1267   #   - unless suspend_bill is enabled on the package or package def
1268   #     - but still not, if the package is on hold
1269   #   - or it's suspended for a delayed cancellation
1270   # - and its next bill date is in the past
1271   #   - or it doesn't have a next bill date yet
1272   #   - or it's a one-time charge
1273   #   - or it's a CDR plan with the "bill_every_call" option
1274   #   - or it's being canceled
1275   # - and it doesn't have an expire date in the past (this can happen with
1276   #   advance billing)
1277   #   - again, unless it's being canceled
1278   if (     ! $cust_pkg->start_date
1279        and
1280            ( ! $cust_pkg->susp
1281                || ( $cust_pkg->susp != $cust_pkg->order_date
1282                       && (    $cust_pkg->option('suspend_bill',1)
1283                            || ( $part_pkg->option('suspend_bill', 1)
1284                                  && ! $cust_pkg->option('no_suspend_bill',1)
1285                               )
1286                          )
1287                   )
1288                || $cust_pkg->is_status_delay_cancel
1289            )
1290        and
1291             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1292          || ( $part_pkg->plan eq 'voip_cdr'
1293                && $part_pkg->option('bill_every_call')
1294             )
1295          || $options{cancel}
1296
1297        and
1298           ( ! $cust_pkg->expire
1299             || $cust_pkg->expire > $cmp_time
1300             || $options{cancel}
1301           )
1302   ) {
1303
1304     # XXX should this be a package event?  probably.  events are called
1305     # at collection time at the moment, though...
1306     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1307       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1308       #don't want to reset usage just cause we want a line item??
1309       #&& $part_pkg->pkgpart == $real_pkgpart;
1310
1311     warn "    bill recur\n" if $DEBUG > 1;
1312     $lineitems++;
1313
1314     # XXX shared with $recur_prog
1315     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1316              || $cust_pkg->setup
1317              || $time;
1318
1319     #over two params!  lets at least switch to a hashref for the rest...
1320     my $increment_next_bill = ( $part_pkg->freq ne '0'
1321                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1322                                 && !$options{cancel}
1323                               );
1324     my %param = ( %setup_param,
1325                   'precommit_hooks'     => $precommit_hooks,
1326                   'increment_next_bill' => $increment_next_bill,
1327                   'discounts'           => \@recur_discounts,
1328                   'real_pkgpart'        => $real_pkgpart,
1329                   'freq_override'       => $options{freq_override} || '',
1330                   'setup_fee'           => 0,
1331                 );
1332
1333     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1334
1335     # There may be some part_pkg for which this is wrong.  Only those
1336     # which can_discount are supported.
1337     # (the UI should prevent adding discounts to these at the moment)
1338
1339     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1340          " for pkgpart ". $cust_pkg->pkgpart.
1341          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1342       if $DEBUG > 2;
1343
1344     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1345     return "$@ running $method for $cust_pkg\n"
1346       if ( $@ );
1347
1348     if ($recur eq 'NOTHING') {
1349       # then calc_cancel (or calc_recur but that's not used) has declined to
1350       # generate a recurring lineitem at all. treat this as zero, but also
1351       # try not to generate a lineitem.
1352       $recur = 0;
1353       $lineitems--;
1354     }
1355
1356     #base_cancel???
1357     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1358
1359     if ( $increment_next_bill ) {
1360
1361       my $next_bill;
1362
1363       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1364         # supplemental package
1365         # to keep in sync with the main package, simulate billing at
1366         # its frequency
1367         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1368         my $supp_pkg_freq = $part_pkg->freq;
1369         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1370         if ( $ratio != int($ratio) ) {
1371           # the UI should prevent setting up packages like this, but just
1372           # in case
1373           return "supplemental package period is not an integer multiple of main  package period";
1374         }
1375         $next_bill = $sdate;
1376         for (1..$ratio) {
1377           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1378         }
1379
1380       } else {
1381         # the normal case
1382       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1383       return "unparsable frequency: ".
1384         ($options{freq_override} || $part_pkg->freq)
1385         if $next_bill == -1;
1386       }
1387
1388       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1389       # only for figuring next bill date, nothing else, so, reset $sdate again
1390       # here
1391       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1392       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1393       $cust_pkg->last_bill($sdate);
1394
1395       $cust_pkg->setfield('bill', $next_bill );
1396
1397     }
1398
1399     if ( $param{'setup_fee'} ) {
1400       # Add an additional setup fee at the billing stage.
1401       # Used for prorate_defer_bill.
1402       $setup += $param{'setup_fee'};
1403       $unitsetup = $cust_pkg->base_setup();
1404       $lineitems++;
1405     }
1406
1407     if ( defined $param{'discount_left_setup'} ) {
1408         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1409             $setup -= $discount_setup;
1410         }
1411     }
1412
1413   }
1414
1415   warn "\$setup is undefined" unless defined($setup);
1416   warn "\$recur is undefined" unless defined($recur);
1417   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1418
1419   ###
1420   # If there's line items, create em cust_bill_pkg records
1421   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1422   ###
1423
1424   if ( $lineitems ) {
1425
1426     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1427       # hmm.. and if just the options are modified in some weird price plan?
1428
1429       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1430         if $DEBUG >1;
1431
1432       my $error = $cust_pkg->replace( $old_cust_pkg,
1433                                       'depend_jobnum'=>$options{depend_jobnum},
1434                                       'options' => { $cust_pkg->options },
1435                                     )
1436         unless $options{no_commit};
1437       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1438         if $error; #just in case
1439     }
1440
1441     $setup = sprintf( "%.2f", $setup );
1442     $recur = sprintf( "%.2f", $recur );
1443     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1444       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1445     }
1446     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1447       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1448     }
1449
1450     my $discount_show_always = $conf->exists('discount-show-always')
1451                                && (    ($setup == 0 && scalar(@setup_discounts))
1452                                     || ($recur == 0 && scalar(@recur_discounts))
1453                                   );
1454
1455     if (    $setup != 0
1456          || $recur != 0
1457          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1458          || $discount_show_always
1459          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1460          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1461        )
1462     {
1463
1464       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1465         if $DEBUG > 1;
1466
1467       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1468       if ( $DEBUG > 1 ) {
1469         warn "      adding customer package invoice detail: $_\n"
1470           foreach @cust_pkg_detail;
1471       }
1472       push @details, @cust_pkg_detail;
1473
1474       my $cust_bill_pkg = new FS::cust_bill_pkg {
1475         'pkgnum'    => $cust_pkg->pkgnum,
1476         'setup'     => $setup,
1477         'unitsetup' => $unitsetup,
1478         'recur'     => $recur,
1479         'unitrecur' => $unitrecur,
1480         'quantity'  => $cust_pkg->quantity,
1481         'details'   => \@details,
1482         'discounts' => [ @setup_discounts, @recur_discounts ],
1483         'hidden'    => $part_pkg->hidden,
1484         'freq'      => $part_pkg->freq,
1485       };
1486
1487       if ( $part_pkg->option('prorate_defer_bill',1)
1488            and !$hash{last_bill} ) {
1489         # both preceding and upcoming, technically
1490         $cust_bill_pkg->sdate( $cust_pkg->setup );
1491         $cust_bill_pkg->edate( $cust_pkg->bill );
1492       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1493         $cust_bill_pkg->sdate( $hash{last_bill} );
1494         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1495         $cust_bill_pkg->edate( $time ) if $options{cancel};
1496       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1497         $cust_bill_pkg->sdate( $sdate );
1498         $cust_bill_pkg->edate( $cust_pkg->bill );
1499         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1500       }
1501
1502       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1503         unless $part_pkg->pkgpart == $real_pkgpart;
1504
1505       $$total_setup += $setup;
1506       $$total_recur += $recur;
1507
1508       ###
1509       # handle taxes
1510       ###
1511
1512       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg,
1513         cancel => $options{cancel} );
1514       return $error if $error;
1515
1516       $cust_bill_pkg->set_display(
1517         part_pkg     => $part_pkg,
1518         real_pkgpart => $real_pkgpart,
1519       );
1520
1521       push @$cust_bill_pkgs, $cust_bill_pkg;
1522
1523     } #if $setup != 0 || $recur != 0
1524
1525   } #if $line_items
1526
1527   '';
1528
1529 }
1530
1531 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1532
1533 Takes one argument, a cust_pkg object that is being billed.  This will
1534 be called only if the package was created by a package change, and has
1535 not been billed since the package change, and package balance tracking
1536 is enabled.  The second argument can be an alternate package number to
1537 transfer the balance from; this should not be used externally.
1538
1539 Transfers the balance from the previous package (now canceled) to
1540 this package, by crediting one package and creating an invoice item for
1541 the other.  Inserts the credit and returns the invoice item (so that it
1542 can be added to an invoice that's being built).
1543
1544 If the previous package was never billed, and was also created by a package
1545 change, then this will also transfer the balance from I<its> previous
1546 package, and so on, until reaching a package that either has been billed
1547 or was not created by a package change.
1548
1549 =cut
1550
1551 my $balance_transfer_reason;
1552
1553 sub _transfer_balance {
1554   my $self = shift;
1555   my $cust_pkg = shift;
1556   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1557   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1558
1559   my @transfers;
1560
1561   # if $from_pkg is not the first package in the chain, and it was never
1562   # billed, walk back
1563   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1564     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1565   }
1566
1567   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1568   if ( $prev_balance != 0 ) {
1569     $balance_transfer_reason ||= FS::reason->new_or_existing(
1570       'reason' => 'Package balance transfer',
1571       'type'   => 'Internal adjustment',
1572       'class'  => 'R'
1573     );
1574
1575     my $credit = FS::cust_credit->new({
1576         'custnum'   => $self->custnum,
1577         'amount'    => abs($prev_balance),
1578         'reasonnum' => $balance_transfer_reason->reasonnum,
1579         '_date'     => $cust_pkg->change_date,
1580     });
1581
1582     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1583         'setup'     => 0,
1584         'recur'     => abs($prev_balance),
1585         #'sdate'     => $from_pkg->last_bill, # not sure about this
1586         #'edate'     => $cust_pkg->change_date,
1587         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1588                                  $from_pkg->part_pkg->pkg),
1589     });
1590
1591     if ( $prev_balance > 0 ) {
1592       # credit the old package, charge the new one
1593       $credit->set('pkgnum', $from_pkgnum);
1594       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1595     } else {
1596       # the reverse
1597       $credit->set('pkgnum', $cust_pkg->pkgnum);
1598       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1599     }
1600     my $error = $credit->insert;
1601     die "error transferring package balance from #".$from_pkgnum.
1602         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1603
1604     push @transfers, $cust_bill_pkg;
1605   } # $prev_balance != 0
1606
1607   return @transfers;
1608 }
1609
1610 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1611
1612 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1613 from _make_lines.
1614
1615 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1616 this:
1617 {
1618   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1619   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1620 }
1621
1622 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1623 is always the cust_main_county or tax_rate identified by the key.
1624
1625 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1626 the 'taxline' method to calculate the amount of the tax.  This doesn't
1627 happen until calculate_taxes, though.
1628
1629 OPTIONS may include:
1630 - part_item: a part_pkg or part_fee object to be used as the package/fee
1631   definition.
1632 - location: a cust_location to be used as the billing location.
1633 - cancel: true if this package is being billed on cancellation.  This
1634   allows tax to be calculated on usage charges only.
1635
1636 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1637 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1638 the customer's default service location).
1639
1640 This method will also calculate exemptions for any taxes that apply to the
1641 line item (using the C<set_exemptions> method of L<FS::cust_bill_pkg>) and
1642 attach them.  This is the only place C<set_exemptions> is called in normal
1643 invoice processing.
1644
1645 =cut
1646
1647 sub _handle_taxes {
1648   my $self = shift;
1649   my $taxlisthash = shift;
1650   my $cust_bill_pkg = shift;
1651   my %options = @_;
1652
1653   # at this point I realize that we have enough information to infer all this
1654   # stuff, instead of passing around giant honking argument lists
1655   my $location = $options{location} || $cust_bill_pkg->tax_location;
1656   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1657
1658   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1659
1660   return if ( $self->payby eq 'COMP' ); #dubious
1661
1662   if ( $conf->exists('enable_taxproducts')
1663        && ( scalar($part_item->part_pkg_taxoverride)
1664             || $part_item->has_taxproduct
1665           )
1666      )
1667     {
1668
1669     # EXTERNAL TAX RATES (via tax_rate)
1670     my %cust_bill_pkg = ();
1671     my %taxes = ();
1672
1673     my @classes;
1674     my $usage = $cust_bill_pkg->usage || 0;
1675     push @classes, $cust_bill_pkg->usage_classes if $usage;
1676     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1677     push @classes, 'recur' if ($cust_bill_pkg->recur - $usage)
1678         and !$options{cancel};
1679     # that's better--probably don't even need $options{cancel} now
1680     # but leave it for now, just to be safe
1681     #
1682     # About $options{cancel}: This protects against charging per-line or
1683     # per-customer or other flat-rate surcharges on a package that's being
1684     # billed on cancellation (which is an out-of-cycle bill and should only
1685     # have usage charges).  See RT#29443.
1686
1687     # customer exemption is now handled in the 'taxline' method
1688     #my $exempt = $conf->exists('cust_class-tax_exempt')
1689     #               ? ( $self->cust_class ? $self->cust_class->tax : '' )
1690     #               : $self->tax;
1691     # standardize this just to be sure
1692     #$exempt = ($exempt eq 'Y') ? 'Y' : '';
1693     #
1694     #if ( !$exempt ) {
1695
1696     unless (exists $taxes{''}) {
1697       # unsure what purpose this serves, but last time I deleted something
1698       # from here just because I didn't see the point, it actually did
1699       # something important.
1700       my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1701       return $err_or_ref unless ref($err_or_ref);
1702       $taxes{''} = $err_or_ref;
1703     }
1704
1705     # NO DISINTEGRATIONS.
1706     # my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1707     #
1708     # do not call taxline() with any argument except the entire set of
1709     # cust_bill_pkgs on an invoice that are eligible for the tax.
1710
1711     # only calculate exemptions once for each tax rate, even if it's used
1712     # for multiple classes
1713     my %tax_seen = ();
1714
1715     foreach my $class (@classes) {
1716       my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1717       return $err_or_ref unless ref($err_or_ref);
1718       my @taxes = @$err_or_ref;
1719
1720       next if !@taxes;
1721
1722       foreach my $tax ( @taxes ) {
1723
1724         my $tax_id = ref( $tax ). ' '. $tax->taxnum;
1725         # $taxlisthash: keys are tax identifiers ('FS::tax_rate 123456').
1726         # Values are arrayrefs, first the tax object (cust_main_county
1727         # or tax_rate), then the cust_bill_pkg object that the
1728         # tax applies to, then the tax class (setup, recur, usage classnum).
1729         $taxlisthash->{ $tax_id } ||= [ $tax ];
1730         push @{ $taxlisthash->{ $tax_id  } }, $cust_bill_pkg, $class;
1731
1732         # determine any exemptions that apply
1733         if (!$tax_seen{$tax_id}) {
1734           $cust_bill_pkg->set_exemptions( $tax, custnum => $self->custnum );
1735           $tax_seen{$tax_id} = 1;
1736         }
1737
1738         # tax on tax will be done later, when we actually create the tax
1739         # line items
1740
1741       }
1742     }
1743
1744   } else {
1745
1746     # INTERNAL TAX RATES (cust_main_county)
1747
1748     # We fetch taxes even if the customer is completely exempt,
1749     # because we need to record that fact.
1750
1751     my @loc_keys = qw( district city county state country );
1752     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1753
1754     $taxhash{'taxclass'} = $part_item->taxclass;
1755
1756     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1757
1758     my @taxes = (); # entries are cust_main_county objects
1759     my %taxhash_elim = %taxhash;
1760     my @elim = qw( district city county state );
1761     do {
1762
1763       #first try a match with taxclass
1764       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1765
1766       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1767         #then try a match without taxclass
1768         my %no_taxclass = %taxhash_elim;
1769         $no_taxclass{ 'taxclass' } = '';
1770         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1771       }
1772
1773       $taxhash_elim{ shift(@elim) } = '';
1774
1775     } while ( !scalar(@taxes) && scalar(@elim) );
1776
1777     foreach (@taxes) {
1778       my $tax_id = 'cust_main_county '.$_->taxnum;
1779       $taxlisthash->{$tax_id} ||= [ $_ ];
1780       $cust_bill_pkg->set_exemptions($_, custnum => $self->custnum);
1781       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1782     }
1783
1784   }
1785   '';
1786 }
1787
1788 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1789
1790 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1791 or part_fee (which will define the tax eligibility of the product), CLASS is
1792 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1793 location where the service was provided (or billed, depending on
1794 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1795 can apply to this line item.
1796
1797 =cut
1798
1799 sub _gather_taxes {
1800   my $self = shift;
1801   my $part_item = shift;
1802   my $class = shift;
1803   my $location = shift;
1804
1805   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1806
1807   my $geocode = $location->geocode('cch');
1808
1809   [ $part_item->tax_rates('cch', $geocode, $class) ]
1810
1811 }
1812
1813 =item collect [ HASHREF | OPTION => VALUE ... ]
1814
1815 (Attempt to) collect money for this customer's outstanding invoices (see
1816 L<FS::cust_bill>).  Usually used after the bill method.
1817
1818 Actions are now triggered by billing events; see L<FS::part_event> and the
1819 billing events web interface.  Old-style invoice events (see
1820 L<FS::part_bill_event>) have been deprecated.
1821
1822 If there is an error, returns the error, otherwise returns false.
1823
1824 Options are passed as name-value pairs.
1825
1826 Currently available options are:
1827
1828 =over 4
1829
1830 =item invoice_time
1831
1832 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1833
1834 =item retry
1835
1836 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1837
1838 =item check_freq
1839
1840 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1841
1842 =item quiet
1843
1844 set true to surpress email card/ACH decline notices.
1845
1846 =item debug
1847
1848 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1849
1850 =back
1851
1852 # =item payby
1853 #
1854 # allows for one time override of normal customer billing method
1855
1856 =cut
1857
1858 sub collect {
1859   my( $self, %options ) = @_;
1860
1861   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1862
1863   my $invoice_time = $options{'invoice_time'} || time;
1864
1865   #put below somehow?
1866   local $SIG{HUP} = 'IGNORE';
1867   local $SIG{INT} = 'IGNORE';
1868   local $SIG{QUIT} = 'IGNORE';
1869   local $SIG{TERM} = 'IGNORE';
1870   local $SIG{TSTP} = 'IGNORE';
1871   local $SIG{PIPE} = 'IGNORE';
1872
1873   my $oldAutoCommit = $FS::UID::AutoCommit;
1874   local $FS::UID::AutoCommit = 0;
1875   my $dbh = dbh;
1876
1877   $self->select_for_update; #mutex
1878
1879   if ( $DEBUG ) {
1880     my $balance = $self->balance;
1881     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1882   }
1883
1884   if ( exists($options{'retry_card'}) ) {
1885     carp 'retry_card option passed to collect is deprecated; use retry';
1886     $options{'retry'} ||= $options{'retry_card'};
1887   }
1888   if ( exists($options{'retry'}) && $options{'retry'} ) {
1889     my $error = $self->retry_realtime;
1890     if ( $error ) {
1891       $dbh->rollback if $oldAutoCommit;
1892       return $error;
1893     }
1894   }
1895
1896   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1897
1898   #never want to roll back an event just because it returned an error
1899   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1900
1901   $self->do_cust_event(
1902     'debug'      => ( $options{'debug'} || 0 ),
1903     'time'       => $invoice_time,
1904     'check_freq' => $options{'check_freq'},
1905     'stage'      => 'collect',
1906   );
1907
1908 }
1909
1910 =item retry_realtime
1911
1912 Schedules realtime / batch  credit card / electronic check / LEC billing
1913 events for for retry.  Useful if card information has changed or manual
1914 retry is desired.  The 'collect' method must be called to actually retry
1915 the transaction.
1916
1917 Implementation details: For either this customer, or for each of this
1918 customer's open invoices, changes the status of the first "done" (with
1919 statustext error) realtime processing event to "failed".
1920
1921 =cut
1922
1923 sub retry_realtime {
1924   my $self = shift;
1925
1926   local $SIG{HUP} = 'IGNORE';
1927   local $SIG{INT} = 'IGNORE';
1928   local $SIG{QUIT} = 'IGNORE';
1929   local $SIG{TERM} = 'IGNORE';
1930   local $SIG{TSTP} = 'IGNORE';
1931   local $SIG{PIPE} = 'IGNORE';
1932
1933   my $oldAutoCommit = $FS::UID::AutoCommit;
1934   local $FS::UID::AutoCommit = 0;
1935   my $dbh = dbh;
1936
1937   #a little false laziness w/due_cust_event (not too bad, really)
1938
1939   # I guess this is always as of now?
1940   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1941   my $order = FS::part_event_condition->order_conditions_sql;
1942   my $mine =
1943   '( '
1944    . join ( ' OR ' , map {
1945     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1946     my $custnum = FS::part_event->eventtables_custnum->{$_};
1947     "( part_event.eventtable = " . dbh->quote($_)
1948     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1949     . " from $_ $cust_join"
1950     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1951    } FS::part_event->eventtables)
1952    . ') ';
1953
1954   #here is the agent virtualization
1955   my $agent_virt = " (    part_event.agentnum IS NULL
1956                        OR part_event.agentnum = ". $self->agentnum. ' )';
1957
1958   #XXX this shouldn't be hardcoded, actions should declare it...
1959   my @realtime_events = qw(
1960     cust_bill_realtime_card
1961     cust_bill_realtime_check
1962     cust_bill_realtime_lec
1963     cust_bill_batch
1964   );
1965
1966   my $is_realtime_event =
1967     ' part_event.action IN ( '.
1968         join(',', map "'$_'", @realtime_events ).
1969     ' ) ';
1970
1971   my $batch_or_statustext =
1972     "( part_event.action = 'cust_bill_batch'
1973        OR ( statustext IS NOT NULL AND statustext != '' )
1974      )";
1975
1976
1977   my @cust_event = qsearch({
1978     'table'     => 'cust_event',
1979     'select'    => 'cust_event.*',
1980     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1981     'hashref'   => { 'status' => 'done' },
1982     'extra_sql' => " AND $batch_or_statustext ".
1983                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1984   });
1985
1986   my %seen_invnum = ();
1987   foreach my $cust_event (@cust_event) {
1988
1989     #max one for the customer, one for each open invoice
1990     my $cust_X = $cust_event->cust_X;
1991     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1992                           ? $cust_X->invnum
1993                           : 0
1994                         }++
1995          or $cust_event->part_event->eventtable eq 'cust_bill'
1996             && ! $cust_X->owed;
1997
1998     my $error = $cust_event->retry;
1999     if ( $error ) {
2000       $dbh->rollback if $oldAutoCommit;
2001       return "error scheduling event for retry: $error";
2002     }
2003
2004   }
2005
2006   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2007   '';
2008
2009 }
2010
2011 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
2012
2013 Runs billing events; see L<FS::part_event> and the billing events web
2014 interface.
2015
2016 If there is an error, returns the error, otherwise returns false.
2017
2018 Options are passed as name-value pairs.
2019
2020 Currently available options are:
2021
2022 =over 4
2023
2024 =item time
2025
2026 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
2027
2028 =item check_freq
2029
2030 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
2031
2032 =item stage
2033
2034 "collect" (the default) or "pre-bill"
2035
2036 =item quiet
2037
2038 set true to surpress email card/ACH decline notices.
2039
2040 =item debug
2041
2042 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2043
2044 =back
2045 =cut
2046
2047 # =item payby
2048 #
2049 # allows for one time override of normal customer billing method
2050
2051 # =item retry
2052 #
2053 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
2054
2055 sub do_cust_event {
2056   my( $self, %options ) = @_;
2057
2058   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2059
2060   my $time = $options{'time'} || time;
2061
2062   #put below somehow?
2063   local $SIG{HUP} = 'IGNORE';
2064   local $SIG{INT} = 'IGNORE';
2065   local $SIG{QUIT} = 'IGNORE';
2066   local $SIG{TERM} = 'IGNORE';
2067   local $SIG{TSTP} = 'IGNORE';
2068   local $SIG{PIPE} = 'IGNORE';
2069
2070   my $oldAutoCommit = $FS::UID::AutoCommit;
2071   local $FS::UID::AutoCommit = 0;
2072   my $dbh = dbh;
2073
2074   $self->select_for_update; #mutex
2075
2076   if ( $DEBUG ) {
2077     my $balance = $self->balance;
2078     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
2079   }
2080
2081 #  if ( exists($options{'retry_card'}) ) {
2082 #    carp 'retry_card option passed to collect is deprecated; use retry';
2083 #    $options{'retry'} ||= $options{'retry_card'};
2084 #  }
2085 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
2086 #    my $error = $self->retry_realtime;
2087 #    if ( $error ) {
2088 #      $dbh->rollback if $oldAutoCommit;
2089 #      return $error;
2090 #    }
2091 #  }
2092
2093   # false laziness w/pay_batch::import_results
2094
2095   my $due_cust_event = $self->due_cust_event(
2096     'debug'      => ( $options{'debug'} || 0 ),
2097     'time'       => $time,
2098     'check_freq' => $options{'check_freq'},
2099     'stage'      => ( $options{'stage'} || 'collect' ),
2100   );
2101   unless( ref($due_cust_event) ) {
2102     $dbh->rollback if $oldAutoCommit;
2103     return $due_cust_event;
2104   }
2105
2106   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2107   #never want to roll back an event just because it or a different one
2108   # returned an error
2109   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
2110
2111   foreach my $cust_event ( @$due_cust_event ) {
2112
2113     #XXX lock event
2114
2115     #re-eval event conditions (a previous event could have changed things)
2116     unless ( $cust_event->test_conditions ) {
2117       #don't leave stray "new/locked" records around
2118       my $error = $cust_event->delete;
2119       return $error if $error;
2120       next;
2121     }
2122
2123     {
2124       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
2125         if $options{'quiet'};
2126       warn "  running cust_event ". $cust_event->eventnum. "\n"
2127         if $DEBUG > 1;
2128
2129       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
2130       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
2131         #XXX wtf is this?  figure out a proper dealio with return value
2132         #from do_event
2133         return $error;
2134       }
2135     }
2136
2137   }
2138
2139   '';
2140
2141 }
2142
2143 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
2144
2145 Inserts database records for and returns an ordered listref of new events due
2146 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
2147 events are due, an empty listref is returned.  If there is an error, returns a
2148 scalar error message.
2149
2150 To actually run the events, call each event's test_condition method, and if
2151 still true, call the event's do_event method.
2152
2153 Options are passed as a hashref or as a list of name-value pairs.  Available
2154 options are:
2155
2156 =over 4
2157
2158 =item check_freq
2159
2160 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
2161
2162 =item stage
2163
2164 "collect" (the default) or "pre-bill"
2165
2166 =item time
2167
2168 "Current time" for the events.
2169
2170 =item debug
2171
2172 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2173
2174 =item eventtable
2175
2176 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2177
2178 =item objects
2179
2180 Explicitly pass the objects to be tested (typically used with eventtable).
2181
2182 =item testonly
2183
2184 Set to true to return the objects, but not actually insert them into the
2185 database.
2186
2187 =back
2188
2189 =cut
2190
2191 sub due_cust_event {
2192   my $self = shift;
2193   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2194
2195   #???
2196   #my $DEBUG = $opt{'debug'}
2197   $opt{'debug'} ||= 0; # silence some warnings
2198   local($DEBUG) = $opt{'debug'}
2199     if $opt{'debug'} > $DEBUG;
2200   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2201
2202   warn "$me due_cust_event called with options ".
2203        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2204     if $DEBUG;
2205
2206   $opt{'time'} ||= time;
2207
2208   local $SIG{HUP} = 'IGNORE';
2209   local $SIG{INT} = 'IGNORE';
2210   local $SIG{QUIT} = 'IGNORE';
2211   local $SIG{TERM} = 'IGNORE';
2212   local $SIG{TSTP} = 'IGNORE';
2213   local $SIG{PIPE} = 'IGNORE';
2214
2215   my $oldAutoCommit = $FS::UID::AutoCommit;
2216   local $FS::UID::AutoCommit = 0;
2217   my $dbh = dbh;
2218
2219   $self->select_for_update #mutex
2220     unless $opt{testonly};
2221
2222   ###
2223   # find possible events (initial search)
2224   ###
2225
2226   my @cust_event = ();
2227
2228   my @eventtable = $opt{'eventtable'}
2229                      ? ( $opt{'eventtable'} )
2230                      : FS::part_event->eventtables_runorder;
2231
2232   my $check_freq = $opt{'check_freq'} || '1d';
2233
2234   foreach my $eventtable ( @eventtable ) {
2235
2236     my @objects;
2237     if ( $opt{'objects'} ) {
2238
2239       @objects = @{ $opt{'objects'} };
2240
2241     } elsif ( $eventtable eq 'cust_main' ) {
2242
2243       @objects = ( $self );
2244
2245     } else {
2246
2247       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2248       # linkage not needed here because FS::cust_main->$eventtable will
2249       # already supply it
2250
2251       #some false laziness w/Cron::bill bill_where
2252
2253       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2254         'time' => $opt{'time'});
2255       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2256         'time'=>$opt{'time'},
2257       );
2258       $where = $where ? "AND $where" : '';
2259
2260       my $are_part_event =
2261       "EXISTS ( SELECT 1 FROM part_event $join
2262         WHERE check_freq = '$check_freq'
2263         AND eventtable = '$eventtable'
2264         AND ( disabled = '' OR disabled IS NULL )
2265         $where
2266         )
2267       ";
2268       #eofalse
2269
2270       @objects = $self->$eventtable(
2271         'addl_from' => $cm_join,
2272         'extra_sql' => " AND $are_part_event",
2273       );
2274     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2275
2276     my @e_cust_event = ();
2277
2278     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2279
2280     my $cross = "CROSS JOIN $eventtable $linkage";
2281     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2282       unless $eventtable eq 'cust_main';
2283
2284     foreach my $object ( @objects ) {
2285
2286       #this first search uses the condition_sql magic for optimization.
2287       #the more possible events we can eliminate in this step the better
2288
2289       my $cross_where = '';
2290       my $pkey = $object->primary_key;
2291       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2292
2293       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2294         'time' => $opt{'time'});
2295       my $extra_sql =
2296         FS::part_event_condition->where_conditions_sql( $eventtable,
2297                                                         'time'=>$opt{'time'}
2298                                                       );
2299       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2300
2301       $extra_sql = "AND $extra_sql" if $extra_sql;
2302
2303       #here is the agent virtualization
2304       $extra_sql .= " AND (    part_event.agentnum IS NULL
2305                             OR part_event.agentnum = ". $self->agentnum. ' )';
2306
2307       $extra_sql .= " $order";
2308
2309       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2310         if $opt{'debug'} > 2;
2311       my @part_event = qsearch( {
2312         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2313         'select'    => 'part_event.*',
2314         'table'     => 'part_event',
2315         'addl_from' => "$cross $join",
2316         'hashref'   => { 'check_freq' => $check_freq,
2317                          'eventtable' => $eventtable,
2318                          'disabled'   => '',
2319                        },
2320         'extra_sql' => "AND $cross_where $extra_sql",
2321       } );
2322
2323       if ( $DEBUG > 2 ) {
2324         my $pkey = $object->primary_key;
2325         warn "      ". scalar(@part_event).
2326              " possible events found for $eventtable ". $object->$pkey(). "\n";
2327       }
2328
2329       push @e_cust_event, map {
2330         $_->new_cust_event($object, 'time' => $opt{'time'})
2331       } @part_event;
2332
2333     }
2334
2335     warn "    ". scalar(@e_cust_event).
2336          " subtotal possible cust events found for $eventtable\n"
2337       if $DEBUG > 1;
2338
2339     push @cust_event, @e_cust_event;
2340
2341   }
2342
2343   warn "  ". scalar(@cust_event).
2344        " total possible cust events found in initial search\n"
2345     if $DEBUG; # > 1;
2346
2347
2348   ##
2349   # test stage
2350   ##
2351
2352   $opt{stage} ||= 'collect';
2353   @cust_event =
2354     grep { my $stage = $_->part_event->event_stage;
2355            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2356          }
2357          @cust_event;
2358
2359   ##
2360   # test conditions
2361   ##
2362
2363   my %unsat = ();
2364
2365   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2366                      @cust_event;
2367
2368   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2369     if $DEBUG; # > 1;
2370
2371   warn "    invalid conditions not eliminated with condition_sql:\n".
2372        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2373     if keys %unsat && $DEBUG; # > 1;
2374
2375   ##
2376   # insert
2377   ##
2378
2379   unless( $opt{testonly} ) {
2380     foreach my $cust_event ( @cust_event ) {
2381
2382       my $error = $cust_event->insert();
2383       if ( $error ) {
2384         $dbh->rollback if $oldAutoCommit;
2385         return $error;
2386       }
2387
2388     }
2389   }
2390
2391   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2392
2393   ##
2394   # return
2395   ##
2396
2397   warn "  returning events: ". Dumper(@cust_event). "\n"
2398     if $DEBUG > 2;
2399
2400   \@cust_event;
2401
2402 }
2403
2404 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2405
2406 Applies unapplied payments and credits.
2407 Payments with the no_auto_apply flag set will not be applied.
2408
2409 In most cases, this new method should be used in place of sequential
2410 apply_payments and apply_credits methods.
2411
2412 A hash of optional arguments may be passed.  Currently "manual" is supported.
2413 If true, a payment receipt is sent instead of a statement when
2414 'payment_receipt_email' configuration option is set.
2415
2416 If there is an error, returns the error, otherwise returns false.
2417
2418 =cut
2419
2420 sub apply_payments_and_credits {
2421   my( $self, %options ) = @_;
2422
2423   local $SIG{HUP} = 'IGNORE';
2424   local $SIG{INT} = 'IGNORE';
2425   local $SIG{QUIT} = 'IGNORE';
2426   local $SIG{TERM} = 'IGNORE';
2427   local $SIG{TSTP} = 'IGNORE';
2428   local $SIG{PIPE} = 'IGNORE';
2429
2430   my $oldAutoCommit = $FS::UID::AutoCommit;
2431   local $FS::UID::AutoCommit = 0;
2432   my $dbh = dbh;
2433
2434   $self->select_for_update; #mutex
2435
2436   foreach my $cust_bill ( $self->open_cust_bill ) {
2437     my $error = $cust_bill->apply_payments_and_credits(%options);
2438     if ( $error ) {
2439       $dbh->rollback if $oldAutoCommit;
2440       return "Error applying: $error";
2441     }
2442   }
2443
2444   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2445   ''; #no error
2446
2447 }
2448
2449 =item apply_credits OPTION => VALUE ...
2450
2451 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2452 to outstanding invoice balances in chronological order (or reverse
2453 chronological order if the I<order> option is set to B<newest>) and returns the
2454 value of any remaining unapplied credits available for refund (see
2455 L<FS::cust_refund>).
2456
2457 Dies if there is an error.
2458
2459 =cut
2460
2461 sub apply_credits {
2462   my $self = shift;
2463   my %opt = @_;
2464
2465   local $SIG{HUP} = 'IGNORE';
2466   local $SIG{INT} = 'IGNORE';
2467   local $SIG{QUIT} = 'IGNORE';
2468   local $SIG{TERM} = 'IGNORE';
2469   local $SIG{TSTP} = 'IGNORE';
2470   local $SIG{PIPE} = 'IGNORE';
2471
2472   my $oldAutoCommit = $FS::UID::AutoCommit;
2473   local $FS::UID::AutoCommit = 0;
2474   my $dbh = dbh;
2475
2476   $self->select_for_update; #mutex
2477
2478   unless ( $self->total_unapplied_credits ) {
2479     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2480     return 0;
2481   }
2482
2483   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2484       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2485
2486   my @invoices = $self->open_cust_bill;
2487   @invoices = sort { $b->_date <=> $a->_date } @invoices
2488     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2489
2490   if ( $conf->exists('pkg-balances') ) {
2491     # limit @credits to those w/ a pkgnum grepped from $self
2492     my %pkgnums = ();
2493     foreach my $i (@invoices) {
2494       foreach my $li ( $i->cust_bill_pkg ) {
2495         $pkgnums{$li->pkgnum} = 1;
2496       }
2497     }
2498     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2499   }
2500
2501   my $credit;
2502
2503   foreach my $cust_bill ( @invoices ) {
2504
2505     if ( !defined($credit) || $credit->credited == 0) {
2506       $credit = pop @credits or last;
2507     }
2508
2509     my $owed;
2510     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2511       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2512     } else {
2513       $owed = $cust_bill->owed;
2514     }
2515     unless ( $owed > 0 ) {
2516       push @credits, $credit;
2517       next;
2518     }
2519
2520     my $amount = min( $credit->credited, $owed );
2521
2522     my $cust_credit_bill = new FS::cust_credit_bill ( {
2523       'crednum' => $credit->crednum,
2524       'invnum'  => $cust_bill->invnum,
2525       'amount'  => $amount,
2526     } );
2527     $cust_credit_bill->pkgnum( $credit->pkgnum )
2528       if $conf->exists('pkg-balances') && $credit->pkgnum;
2529     my $error = $cust_credit_bill->insert;
2530     if ( $error ) {
2531       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2532       die $error;
2533     }
2534
2535     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2536
2537   }
2538
2539   my $total_unapplied_credits = $self->total_unapplied_credits;
2540
2541   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2542
2543   return $total_unapplied_credits;
2544 }
2545
2546 =item apply_payments  [ OPTION => VALUE ... ]
2547
2548 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2549 to outstanding invoice balances in chronological order.
2550 Payments with the no_auto_apply flag set will not be applied.
2551
2552  #and returns the value of any remaining unapplied payments.
2553
2554 A hash of optional arguments may be passed.  Currently "manual" is supported.
2555 If true, a payment receipt is sent instead of a statement when
2556 'payment_receipt_email' configuration option is set.
2557
2558 Dies if there is an error.
2559
2560 =cut
2561
2562 sub apply_payments {
2563   my( $self, %options ) = @_;
2564
2565   local $SIG{HUP} = 'IGNORE';
2566   local $SIG{INT} = 'IGNORE';
2567   local $SIG{QUIT} = 'IGNORE';
2568   local $SIG{TERM} = 'IGNORE';
2569   local $SIG{TSTP} = 'IGNORE';
2570   local $SIG{PIPE} = 'IGNORE';
2571
2572   my $oldAutoCommit = $FS::UID::AutoCommit;
2573   local $FS::UID::AutoCommit = 0;
2574   my $dbh = dbh;
2575
2576   $self->select_for_update; #mutex
2577
2578   #return 0 unless
2579
2580   my @payments = grep { !$_->no_auto_apply } $self->unapplied_cust_pay;
2581
2582   my @invoices = $self->open_cust_bill;
2583
2584   if ( $conf->exists('pkg-balances') ) {
2585     # limit @payments to those w/ a pkgnum grepped from $self
2586     my %pkgnums = ();
2587     foreach my $i (@invoices) {
2588       foreach my $li ( $i->cust_bill_pkg ) {
2589         $pkgnums{$li->pkgnum} = 1;
2590       }
2591     }
2592     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2593   }
2594
2595   my $payment;
2596
2597   foreach my $cust_bill ( @invoices ) {
2598
2599     if ( !defined($payment) || $payment->unapplied == 0 ) {
2600       $payment = pop @payments or last;
2601     }
2602
2603     my $owed;
2604     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2605       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2606     } else {
2607       $owed = $cust_bill->owed;
2608     }
2609     unless ( $owed > 0 ) {
2610       push @payments, $payment;
2611       next;
2612     }
2613
2614     my $amount = min( $payment->unapplied, $owed );
2615
2616     my $cbp = {
2617       'paynum' => $payment->paynum,
2618       'invnum' => $cust_bill->invnum,
2619       'amount' => $amount,
2620     };
2621     $cbp->{_date} = $payment->_date
2622         if $options{'manual'} && $options{'backdate_application'};
2623     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2624     $cust_bill_pay->pkgnum( $payment->pkgnum )
2625       if $conf->exists('pkg-balances') && $payment->pkgnum;
2626     my $error = $cust_bill_pay->insert(%options);
2627     if ( $error ) {
2628       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2629       die $error;
2630     }
2631
2632     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2633
2634   }
2635
2636   my $total_unapplied_payments = $self->total_unapplied_payments;
2637
2638   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2639
2640   return $total_unapplied_payments;
2641 }
2642
2643 =back
2644
2645 =head1 FLOW
2646
2647   bill_and_collect
2648
2649     cancel_expired_pkgs
2650     suspend_adjourned_pkgs
2651     unsuspend_resumed_pkgs
2652
2653     bill
2654       (do_cust_event pre-bill)
2655       _make_lines
2656         _handle_taxes
2657           (vendor-only) _gather_taxes
2658       _omit_zero_value_bundles
2659       _handle_taxes (for fees)
2660       calculate_taxes
2661
2662     apply_payments_and_credits
2663     collect
2664       do_cust_event
2665         due_cust_event
2666
2667 =head1 BUGS
2668
2669 =head1 SEE ALSO
2670
2671 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2672
2673 =cut
2674
2675 1;