FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use FS::cust_bill;
  12 use FS::cust_bill_pkg;
  13 use FS::cust_bill_pkg_display;
  14 use FS::cust_bill_pay;
  15 use FS::cust_credit_bill;
  16 use FS::cust_tax_adjustment;
  17 use FS::tax_rate;
  18 use FS::tax_rate_location;
  19 use FS::cust_bill_pkg_tax_location;
  20 use FS::cust_bill_pkg_tax_rate_location;
  21 use FS::part_event;
  22 use FS::part_event_condition;
  23 use FS::pkg_category;
  24 use FS::cust_event_fee;
  25 use FS::Log;
  26
  27 # 1 is mostly method/subroutine entry and options
  28 # 2 traces progress of some operations
  29 # 3 is even more information including possibly sensitive data
  30 $DEBUG = 0;
  31 $me = '[FS::cust_main::Billing]';
  32
  33 install_callback FS::UID sub {
  34   $conf = new FS::Conf;
  35   #yes, need it for stuff below (prolly should be cached)
  36 };
  37
  38 =head1 NAME
  39
  40 FS::cust_main::Billing - Billing mixin for cust_main
  41
  42 =head1 SYNOPSIS
  43
  44 =head1 DESCRIPTION
  45
  46 These methods are available on FS::cust_main objects.
  47
  48 =head1 METHODS
  49
  50 =over 4
  51
  52 =item bill_and_collect
  53
  54 Cancels and suspends any packages due, generates bills, applies payments and
  55 credits, and applies collection events to run cards, send bills and notices,
  56 etc.
  57
  58 By default, warns on errors and continues with the next operation (but see the
  59 "fatal" flag below).
  60
  61 Options are passed as name-value pairs.  Currently available options are:
  62
  63 =over 4
  64
  65 =item time
  66
  67 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  68
  69  use Date::Parse;
  70  ...
  71  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  72
  73 =item invoice_time
  74
  75 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  76
  77 =item check_freq
  78
  79 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  80
  81 =item resetup
  82
  83 If set true, re-charges setup fees.
  84
  85 =item fatal
  86
  87 If set any errors prevent subsequent operations from continusing.  If set
  88 specifically to "return", returns the error (or false, if there is no error).
  89 Any other true value causes errors to die.
  90
  91 =item debug
  92
  93 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  94
  95 =item job
  96
  97 Optional FS::queue entry to receive status updates.
  98
  99 =back
 100
 101 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 102 options of those methods are also available.
 103
 104 =cut
 105
 106 sub bill_and_collect {
 107   my( $self, %options ) = @_;
 108
 109   my $log = FS::Log->new('bill_and_collect');
 110   $log->debug('start', object => $self, agentnum => $self->agentnum);
 111
 112   my $error;
 113
 114   #$options{actual_time} not $options{time} because freeside-daily -d is for
 115   #pre-printing invoices
 116
 117   $options{'actual_time'} ||= time;
 118   my $job = $options{'job'};
 119
 120   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 121                         ? day_end( $options{actual_time} )
 122                         : $options{actual_time}
 123                     );
 124
 125   $job->update_statustext('0,cleaning expired packages') if $job;
 126   $error = $self->cancel_expired_pkgs( $actual_time );
 127   if ( $error ) {
 128     $error = "Error expiring custnum ". $self->custnum. ": $error";
 129     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 130     elsif ( $options{fatal}                                ) { die    $error; }
 131     else                                                     { warn   $error; }
 132   }
 133
 134   $error = $self->suspend_adjourned_pkgs( $actual_time );
 135   if ( $error ) {
 136     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 137     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 138     elsif ( $options{fatal}                                ) { die    $error; }
 139     else                                                     { warn   $error; }
 140   }
 141
 142   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 143   if ( $error ) {
 144     $error = "Error resuming custnum ".$self->custnum. ": $error";
 145     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 146     elsif ( $options{fatal}                                ) { die    $error; }
 147     else                                                     { warn   $error; }
 148   }
 149
 150   $job->update_statustext('20,billing packages') if $job;
 151   $error = $self->bill( %options );
 152   if ( $error ) {
 153     $error = "Error billing custnum ". $self->custnum. ": $error";
 154     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 155     elsif ( $options{fatal}                                ) { die    $error; }
 156     else                                                     { warn   $error; }
 157   }
 158
 159   $job->update_statustext('50,applying payments and credits') if $job;
 160   $error = $self->apply_payments_and_credits;
 161   if ( $error ) {
 162     $error = "Error applying custnum ". $self->custnum. ": $error";
 163     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 164     elsif ( $options{fatal}                                ) { die    $error; }
 165     else                                                     { warn   $error; }
 166   }
 167
 168   $job->update_statustext('70,running collection events') if $job;
 169   unless ( $conf->exists('cancelled_cust-noevents')
 170            && ! $self->num_ncancelled_pkgs
 171   ) {
 172     $error = $self->collect( %options );
 173     if ( $error ) {
 174       $error = "Error collecting custnum ". $self->custnum. ": $error";
 175       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 176       elsif ($options{fatal}                               ) { die    $error; }
 177       else                                                   { warn   $error; }
 178     }
 179   }
 180   $job->update_statustext('100,finished') if $job;
 181   $log->debug('finish', object => $self, agentnum => $self->agentnum);
 182
 183   '';
 184
 185 }
 186
 187 sub cancel_expired_pkgs {
 188   my ( $self, $time, %options ) = @_;
 189
 190   my @cancel_pkgs = $self->ncancelled_pkgs( {
 191     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 192   } );
 193
 194   my @errors = ();
 195
 196   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 197     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 198     my $error;
 199
 200     if ( $cust_pkg->change_to_pkgnum ) {
 201
 202       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 203       if ( !$new_pkg ) {
 204         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 205                       $cust_pkg->change_to_pkgnum.'; not expiring';
 206         next CUST_PKG;
 207       }
 208       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 209                                   'unprotect_svcs'  => 1 );
 210       $error = '' if ref $error eq 'FS::cust_pkg';
 211
 212     } else { # just cancel it
 213        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 214                                            'reason_otaker' => $cpr->otaker,
 215                                            'time'          => $time,
 216                                          )
 217                                        : ()
 218                                  );
 219     }
 220     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 221   }
 222
 223   join(' / ', @errors);
 224
 225 }
 226
 227 sub suspend_adjourned_pkgs {
 228   my ( $self, $time, %options ) = @_;
 229
 230   my @susp_pkgs = $self->ncancelled_pkgs( {
 231     'extra_sql' =>
 232       " AND ( susp IS NULL OR susp = 0 )
 233         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 234               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 235             )
 236       ",
 237   } );
 238
 239   #only because there's no SQL test for is_prepaid :/
 240   @susp_pkgs =
 241     grep {     (    $_->part_pkg->is_prepaid
 242                  && $_->bill
 243                  && $_->bill < $time
 244                )
 245             || (    $_->adjourn
 246                  && $_->adjourn <= $time
 247                )
 248
 249          }
 250          @susp_pkgs;
 251
 252   my @errors = ();
 253
 254   foreach my $cust_pkg ( @susp_pkgs ) {
 255     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 256       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 257     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 258                                             'reason_otaker' => $cpr->otaker
 259                                           )
 260                                         : ()
 261                                   );
 262     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 263   }
 264
 265   join(' / ', @errors);
 266
 267 }
 268
 269 sub unsuspend_resumed_pkgs {
 270   my ( $self, $time, %options ) = @_;
 271
 272   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 273     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 274   } );
 275
 276   my @errors = ();
 277
 278   foreach my $cust_pkg ( @unsusp_pkgs ) {
 279     my $error = $cust_pkg->unsuspend( 'time' => $time );
 280     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 281   }
 282
 283   join(' / ', @errors);
 284
 285 }
 286
 287 =item bill OPTIONS
 288
 289 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 290 conjunction with the collect method by calling B<bill_and_collect>.
 291
 292 If there is an error, returns the error, otherwise returns false.
 293
 294 Options are passed as name-value pairs.  Currently available options are:
 295
 296 =over 4
 297
 298 =item resetup
 299
 300 If set true, re-charges setup fees.
 301
 302 =item recurring_only
 303
 304 If set true then only bill recurring charges, not setup, usage, one time
 305 charges, etc.
 306
 307 =item freq_override
 308
 309 If set, then override the normal frequency and look for a part_pkg_discount
 310 to take at that frequency.  This is appropriate only when the normal
 311 frequency for all packages is monthly, and is an error otherwise.  Use
 312 C<pkg_list> to limit the set of packages included in billing.
 313
 314 =item time
 315
 316 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 317
 318  use Date::Parse;
 319  ...
 320  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 321
 322 =item pkg_list
 323
 324 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 325
 326  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 327
 328 =item not_pkgpart
 329
 330 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 331
 332 =item no_prepaid
 333
 334 Do not bill prepaid packages.  Used by freeside-daily.
 335
 336 =item invoice_time
 337
 338 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 339
 340 =item cancel
 341
 342 This boolean value informs the us that the package is being cancelled.  This
 343 typically might mean not charging the normal recurring fee but only usage
 344 fees since the last billing. Setup charges may be charged.  Not all package
 345 plans support this feature (they tend to charge 0).
 346
 347 =item no_usage_reset
 348
 349 Prevent the resetting of usage limits during this call.
 350
 351 =item no_commit
 352
 353 Do not save the generated bill in the database.  Useful with return_bill
 354
 355 =item return_bill
 356
 357 A list reference on which the generated bill(s) will be returned.
 358
 359 =item invoice_terms
 360
 361 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 362 terms or the default terms are used.
 363
 364 =back
 365
 366 =cut
 367
 368 sub bill {
 369   my( $self, %options ) = @_;
 370
 371   return '' if $self->payby eq 'COMP';
 372
 373   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 374
 375   warn "$me bill customer ". $self->custnum. "\n"
 376     if $DEBUG;
 377
 378   my $time = $options{'time'} || time;
 379   my $invoice_time = $options{'invoice_time'} || $time;
 380
 381   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 382                      ? day_end( $time )
 383                      : $time
 384                  );
 385
 386   $options{'not_pkgpart'} ||= {};
 387   $options{'not_pkgpart'} = { map { $_ => 1 }
 388                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 389                             }
 390     unless ref($options{'not_pkgpart'});
 391
 392   local $SIG{HUP} = 'IGNORE';
 393   local $SIG{INT} = 'IGNORE';
 394   local $SIG{QUIT} = 'IGNORE';
 395   local $SIG{TERM} = 'IGNORE';
 396   local $SIG{TSTP} = 'IGNORE';
 397   local $SIG{PIPE} = 'IGNORE';
 398
 399   my $oldAutoCommit = $FS::UID::AutoCommit;
 400   local $FS::UID::AutoCommit = 0;
 401   my $dbh = dbh;
 402
 403   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 404     if $DEBUG;
 405
 406   $self->select_for_update; #mutex
 407
 408   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 409     if $DEBUG;
 410
 411   my $error = $self->do_cust_event(
 412     'debug'      => ( $options{'debug'} || 0 ),
 413     'time'       => $invoice_time,
 414     'check_freq' => $options{'check_freq'},
 415     'stage'      => 'pre-bill',
 416   )
 417     unless $options{no_commit};
 418   if ( $error ) {
 419     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 420     return $error;
 421   }
 422
 423   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 424     if $DEBUG;
 425
 426   #keep auto-charge and non-auto-charge line items separate
 427   my @passes = ( '', 'no_auto' );
 428
 429   my %cust_bill_pkg = map { $_ => [] } @passes;
 430
 431   ###
 432   # find the packages which are due for billing, find out how much they are
 433   # & generate invoice database.
 434   ###
 435
 436   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 437   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 438
 439   my %taxlisthash = map { $_ => {} } @passes;
 440
 441   my @precommit_hooks = ();
 442
 443   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 444
 445   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 446
 447     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 448
 449     my $part_pkg = $cust_pkg->part_pkg;
 450
 451     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 452
 453     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 454
 455     #? to avoid use of uninitialized value errors... ?
 456     $cust_pkg->setfield('bill', '')
 457       unless defined($cust_pkg->bill);
 458
 459     my $real_pkgpart = $cust_pkg->pkgpart;
 460     my %hash = $cust_pkg->hash;
 461
 462     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 463     # suffer from performance issues
 464     $options{has_hidden} = 0;
 465     my @part_pkg = $part_pkg->self_and_bill_linked;
 466     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 467
 468     # if this package was changed from another package,
 469     # and it hasn't been billed since then,
 470     # and package balances are enabled,
 471     if ( $cust_pkg->change_pkgnum
 472         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 473         and $cust_pkg->change_date <  $invoice_time
 474       and $conf->exists('pkg-balances') )
 475     {
 476       # _transfer_balance will also create the appropriate credit
 477       my @transfer_items = $self->_transfer_balance($cust_pkg);
 478       # $part_pkg[0] is the "real" part_pkg
 479       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 480                   'no_auto' : '';
 481       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 482       # treating this as recur, just because most charges are recur...
 483       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 484     }
 485
 486     foreach my $part_pkg ( @part_pkg ) {
 487
 488       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 489
 490       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 491
 492       my $next_bill = $cust_pkg->getfield('bill') || 0;
 493       my $error;
 494       # let this run once if this is the last bill upon cancellation
 495       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 496         $error =
 497           $self->_make_lines( 'part_pkg'            => $part_pkg,
 498                               'cust_pkg'            => $cust_pkg,
 499                               'precommit_hooks'     => \@precommit_hooks,
 500                               'line_items'          => $cust_bill_pkg{$pass},
 501                               'setup'               => $total_setup{$pass},
 502                               'recur'               => $total_recur{$pass},
 503                               'tax_matrix'          => $taxlisthash{$pass},
 504                               'time'                => $time,
 505                               'real_pkgpart'        => $real_pkgpart,
 506                               'options'             => \%options,
 507                             );
 508
 509         # Stop if anything goes wrong
 510         last if $error;
 511
 512         # or if we're not incrementing the bill date.
 513         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 514
 515         # or if we're letting it run only once
 516         last if $options{cancel};
 517
 518         $next_bill = $cust_pkg->getfield('bill') || 0;
 519
 520         #stop if -o was passed to freeside-daily
 521         last if $options{'one_recur'};
 522       }
 523       if ($error) {
 524         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 525         return $error;
 526       }
 527
 528     } #foreach my $part_pkg
 529
 530   } #foreach my $cust_pkg
 531
 532   #if the customer isn't on an automatic payby, everything can go on a single
 533   #invoice anyway?
 534   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 535     #merge everything into one list
 536   #}
 537
 538   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 539
 540     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 541
 542     warn "$me billing pass $pass\n"
 543            #.Dumper(\@cust_bill_pkg)."\n"
 544       if $DEBUG > 2;
 545
 546     ###
 547     # process fees
 548     ###
 549
 550     my @pending_event_fees = FS::cust_event_fee->by_cust($self->custnum,
 551       hashref => { 'billpkgnum' => '' }
 552     );
 553     warn "$me found pending fee events:\n".Dumper(\@pending_event_fees)."\n"
 554       if @pending_event_fees and $DEBUG > 1;
 555
 556     # determine whether to generate an invoice
 557     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 558
 559     foreach my $event_fee (@pending_event_fees) {
 560       $generate_bill = 1 unless $event_fee->nextbill;
 561     }
 562
 563     # don't create an invoice with no line items, or where the only line
 564     # items are fees that are supposed to be held until the next invoice
 565     next if !$generate_bill;
 566
 567     # calculate fees...
 568     my @fee_items;
 569     foreach my $event_fee (@pending_event_fees) {
 570       my $object = $event_fee->cust_event->cust_X;
 571       my $part_fee = $event_fee->part_fee;
 572       my $cust_bill;
 573       if ( $object->isa('FS::cust_main')
 574            or $object->isa('FS::cust_pkg')
 575            or $object->isa('FS::cust_pay_batch') )
 576       {
 577         # Not the real cust_bill object that will be inserted--in particular
 578         # there are no taxes yet.  If you want to charge a fee on the total
 579         # invoice amount including taxes, you have to put the fee on the next
 580         # invoice.
 581         $cust_bill = FS::cust_bill->new({
 582             'custnum'       => $self->custnum,
 583             'cust_bill_pkg' => \@cust_bill_pkg,
 584             'charged'       => ${ $total_setup{$pass} } +
 585                                ${ $total_recur{$pass} },
 586         });
 587
 588         # If this is a package event, only apply the fee to line items
 589         # from that package.
 590         if ($object->isa('FS::cust_pkg')) {
 591           $cust_bill->set('cust_bill_pkg',
 592             [ grep  { $_->pkgnum == $object->pkgnum } @cust_bill_pkg ]
 593           );
 594         }
 595
 596       } elsif ( $object->isa('FS::cust_bill') ) {
 597         # simple case: applying the fee to a previous invoice (late fee,
 598         # etc.)
 599         $cust_bill = $object;
 600       }
 601       # if the fee def belongs to a different agent, don't charge the fee.
 602       # event conditions should prevent this, but just in case they don't,
 603       # skip the fee.
 604       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 605         warn "tried to charge fee#".$part_fee->feepart .
 606              " on customer#".$self->custnum." from a different agent.\n";
 607         next;
 608       }
 609       # also skip if it's disabled
 610       next if $part_fee->disabled eq 'Y';
 611       # calculate the fee
 612       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 613       # link this so that we can clear the marker on inserting the line item
 614       $fee_item->set('cust_event_fee', $event_fee);
 615       push @fee_items, $fee_item;
 616
 617     }
 618
 619     # add fees to the invoice
 620     foreach my $fee_item (@fee_items) {
 621
 622       push @cust_bill_pkg, $fee_item;
 623       ${ $total_setup{$pass} } += $fee_item->setup;
 624       ${ $total_recur{$pass} } += $fee_item->recur;
 625
 626       my $part_fee = $fee_item->part_fee;
 627       my $fee_location = $self->ship_location; # I think?
 628
 629       my $error = $self->_handle_taxes(
 630         $taxlisthash{$pass},
 631         $fee_item,
 632         location => $fee_location
 633         # probably not right to pass cancel => 1 for fees
 634       );
 635       return $error if $error;
 636
 637     }
 638
 639     # XXX implementation of fees is supposed to make this go away...
 640     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 641            !$conf->exists('postal_invoice-recurring_only')
 642        )
 643     {
 644
 645       my $postal_pkg = $self->charge_postal_fee();
 646       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 647
 648         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 649         return "can't charge postal invoice fee for customer ".
 650           $self->custnum. ": $postal_pkg";
 651
 652       } elsif ( $postal_pkg ) {
 653
 654         my $real_pkgpart = $postal_pkg->pkgpart;
 655         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 656         # suffer from performance issues
 657         $options{has_hidden} = 0;
 658         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 659         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 660
 661         foreach my $part_pkg ( @part_pkg ) {
 662           my %postal_options = %options;
 663           delete $postal_options{cancel};
 664           my $error =
 665             $self->_make_lines( 'part_pkg'            => $part_pkg,
 666                                 'cust_pkg'            => $postal_pkg,
 667                                 'precommit_hooks'     => \@precommit_hooks,
 668                                 'line_items'          => \@cust_bill_pkg,
 669                                 'setup'               => $total_setup{$pass},
 670                                 'recur'               => $total_recur{$pass},
 671                                 'tax_matrix'          => $taxlisthash{$pass},
 672                                 'time'                => $time,
 673                                 'real_pkgpart'        => $real_pkgpart,
 674                                 'options'             => \%postal_options,
 675                               );
 676           if ($error) {
 677             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 678             return $error;
 679           }
 680         }
 681
 682         # it's silly to have a zero value postal_pkg, but....
 683         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 684
 685       }
 686
 687     }
 688
 689     my $listref_or_error =
 690       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 691
 692     unless ( ref( $listref_or_error ) ) {
 693       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 694       return $listref_or_error;
 695     }
 696
 697     foreach my $taxline ( @$listref_or_error ) {
 698       ${ $total_setup{$pass} } =
 699         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 700       push @cust_bill_pkg, $taxline;
 701     }
 702
 703     #add tax adjustments
 704     warn "adding tax adjustments...\n" if $DEBUG > 2;
 705     foreach my $cust_tax_adjustment (
 706       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 707                                        'billpkgnum' => '',
 708                                      }
 709              )
 710     ) {
 711
 712       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 713
 714       my $itemdesc = $cust_tax_adjustment->taxname;
 715       $itemdesc = '' if $itemdesc eq 'Tax';
 716
 717       push @cust_bill_pkg, new FS::cust_bill_pkg {
 718         'pkgnum'      => 0,
 719         'setup'       => $tax,
 720         'recur'       => 0,
 721         'sdate'       => '',
 722         'edate'       => '',
 723         'itemdesc'    => $itemdesc,
 724         'itemcomment' => $cust_tax_adjustment->comment,
 725         'cust_tax_adjustment' => $cust_tax_adjustment,
 726         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 727       };
 728
 729     }
 730
 731     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 732
 733     my $balance = $self->balance;
 734
 735     my $previous_bill = qsearchs({ 'table'     => 'cust_bill',
 736                                    'hashref'   => { custnum=>$self->custnum },
 737                                    'extra_sql' => 'ORDER BY _date DESC LIMIT 1',
 738                                 });
 739     my $previous_balance =
 740       $previous_bill
 741         ? ( $previous_bill->billing_balance + $previous_bill->charged )
 742         : 0;
 743
 744     warn "creating the new invoice\n" if $DEBUG;
 745     #create the new invoice
 746     my $cust_bill = new FS::cust_bill ( {
 747       'custnum'             => $self->custnum,
 748       '_date'               => $invoice_time,
 749       'charged'             => $charged,
 750       'billing_balance'     => $balance,
 751       'previous_balance'    => $previous_balance,
 752       'invoice_terms'       => $options{'invoice_terms'},
 753       'cust_bill_pkg'       => \@cust_bill_pkg,
 754     } );
 755     $error = $cust_bill->insert unless $options{no_commit};
 756     if ( $error ) {
 757       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 758       return "can't create invoice for customer #". $self->custnum. ": $error";
 759     }
 760     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 761
 762   } #foreach my $pass ( keys %cust_bill_pkg )
 763
 764   foreach my $hook ( @precommit_hooks ) {
 765     eval {
 766       &{$hook}; #($self) ?
 767     } unless $options{no_commit};
 768     if ( $@ ) {
 769       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 770       return "$@ running precommit hook $hook\n";
 771     }
 772   }
 773
 774   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 775
 776   ''; #no error
 777 }
 778
 779 #discard bundled packages of 0 value
 780 sub _omit_zero_value_bundles {
 781   my @in = @_;
 782
 783   my @cust_bill_pkg = ();
 784   my @cust_bill_pkg_bundle = ();
 785   my $sum = 0;
 786   my $discount_show_always = 0;
 787
 788   foreach my $cust_bill_pkg ( @in ) {
 789
 790     $discount_show_always = ($cust_bill_pkg->get('discounts')
 791                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 792                                 && $conf->exists('discount-show-always'));
 793
 794     warn "  pkgnum ". $cust_bill_pkg->pkgnum. " sum $sum, ".
 795          "setup_show_zero ". $cust_bill_pkg->setup_show_zero.
 796          "recur_show_zero ". $cust_bill_pkg->recur_show_zero. "\n"
 797       if $DEBUG > 0;
 798
 799     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 800       push @cust_bill_pkg, @cust_bill_pkg_bundle
 801         if $sum > 0
 802         || ($sum == 0 && (    $discount_show_always
 803                            || grep {$_->recur_show_zero || $_->setup_show_zero}
 804                                    @cust_bill_pkg_bundle
 805                          )
 806            );
 807       @cust_bill_pkg_bundle = ();
 808       $sum = 0;
 809     }
 810
 811     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 812     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 813
 814   }
 815
 816   push @cust_bill_pkg, @cust_bill_pkg_bundle
 817     if $sum > 0
 818     || ($sum == 0 && (    $discount_show_always
 819                        || grep {$_->recur_show_zero || $_->setup_show_zero}
 820                                @cust_bill_pkg_bundle
 821                      )
 822        );
 823
 824   warn "  _omit_zero_value_bundles: ". scalar(@in).
 825        '->'. scalar(@cust_bill_pkg). "\n" #. Dumper(@cust_bill_pkg). "\n"
 826     if $DEBUG > 2;
 827
 828   (@cust_bill_pkg);
 829
 830 }
 831
 832 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 833
 834 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 835 Usually used internally by bill method B<bill>.
 836
 837 If there is an error, returns the error, otherwise returns reference to a
 838 list of line items suitable for insertion.
 839
 840 =over 4
 841
 842 =item LINEITEMREF
 843
 844 An array ref of the line items being billed.
 845
 846 =item TAXHASHREF
 847
 848 A strange beast.  The keys to this hash are internal identifiers consisting
 849 of the name of the tax object type, a space, and its unique identifier ( e.g.
 850  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 851 item in the list is the tax object.  The remaining items are either line
 852 items or floating point values (currency amounts).
 853
 854 The taxes are calculated on this entity.  Calculated exemption records are
 855 transferred to the LINEITEMREF items on the assumption that they are related.
 856
 857 Read the source.
 858
 859 =item INVOICE_TIME
 860
 861 This specifies the date appearing on the associated invoice.  Some
 862 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 863
 864 =back
 865
 866 =cut
 867
 868 sub calculate_taxes {
 869   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 870
 871   # $taxlisthash is a hashref
 872   # keys are identifiers, values are arrayrefs
 873   # each arrayref starts with a tax object (cust_main_county or tax_rate)
 874   # then any cust_bill_pkg objects the tax applies to
 875
 876   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 877
 878   warn "$me calculate_taxes\n"
 879        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 880     if $DEBUG > 2;
 881
 882   my @tax_line_items = ();
 883
 884   # keys are tax names (as printed on invoices / itemdesc )
 885   # values are arrayrefs of taxlisthash keys (internal identifiers)
 886   my %taxname = ();
 887
 888   # keys are taxlisthash keys (internal identifiers)
 889   # values are (cumulative) amounts
 890   my %tax_amount = ();
 891
 892   # keys are taxlisthash keys (internal identifiers)
 893   # values are arrayrefs of cust_bill_pkg_tax_location hashrefs
 894   my %tax_location = ();
 895
 896   # keys are taxlisthash keys (internal identifiers)
 897   # values are arrayrefs of cust_bill_pkg_tax_rate_location hashrefs
 898   my %tax_rate_location = ();
 899
 900   # keys are taxlisthash keys (internal identifiers!)
 901   # values are arrayrefs of cust_tax_exempt_pkg objects
 902   my %tax_exemption;
 903
 904   foreach my $tax ( keys %$taxlisthash ) {
 905     # $tax is a tax identifier (intersection of a tax definition record
 906     # and a cust_bill_pkg record)
 907     my $tax_object = shift @{ $taxlisthash->{$tax} };
 908     # $tax_object is a cust_main_county or tax_rate
 909     # (with billpkgnum, pkgnum, locationnum set)
 910     # the rest of @{ $taxlisthash->{$tax} } is cust_bill_pkg component objects
 911     # (setup, recurring, usage classes)
 912     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 913     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 914     # taxline calculates the tax on all cust_bill_pkgs in the
 915     # first (arrayref) argument, and returns a hashref of 'name'
 916     # (the line item description) and 'amount'.
 917     # It also calculates exemptions and attaches them to the cust_bill_pkgs
 918     # in the argument.
 919     my $taxables = $taxlisthash->{$tax};
 920     my $exemptions = $tax_exemption{$tax} ||= [];
 921     my $taxline = $tax_object->taxline(
 922                             $taxables,
 923                             'custnum'      => $self->custnum,
 924                             'invoice_time' => $invoice_time,
 925                             'exemptions'   => $exemptions,
 926                           );
 927     return $taxline unless ref($taxline);
 928
 929     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 930
 931     if ( $tax_object->isa('FS::cust_main_county') ) {
 932       # then $taxline is a real line item
 933       push @{ $taxname{ $taxline->itemdesc } }, $taxline;
 934
 935     } else {
 936       # leave this as is for now
 937
 938       my $name   = $taxline->{'name'};
 939       my $amount = $taxline->{'amount'};
 940
 941       #warn "adding $amount as $name\n";
 942       $taxname{ $name } ||= [];
 943       push @{ $taxname{ $name } }, $tax;
 944
 945       $tax_amount{ $tax } += $amount;
 946
 947       # link records between cust_main_county/tax_rate and cust_location
 948       $tax_rate_location{ $tax } ||= [];
 949       my $taxratelocationnum =
 950         $tax_object->tax_rate_location->taxratelocationnum;
 951       push @{ $tax_rate_location{ $tax }  },
 952         {
 953           'taxnum'             => $tax_object->taxnum,
 954           'taxtype'            => ref($tax_object),
 955           'amount'             => sprintf('%.2f', $amount ),
 956           'locationtaxid'      => $tax_object->location,
 957           'taxratelocationnum' => $taxratelocationnum,
 958         };
 959     } #if ref($tax_object)...
 960   } #foreach keys %$taxlisthash
 961
 962   #consolidate and create tax line items
 963   warn "consolidating and generating...\n" if $DEBUG > 2;
 964   foreach my $taxname ( keys %taxname ) {
 965     my @cust_bill_pkg_tax_location;
 966     my @cust_bill_pkg_tax_rate_location;
 967     my $tax_cust_bill_pkg = FS::cust_bill_pkg->new({
 968         'pkgnum'    => 0,
 969         'recur'     => 0,
 970         'sdate'     => '',
 971         'edate'     => '',
 972         'itemdesc'  => $taxname,
 973         'cust_bill_pkg_tax_location'      => \@cust_bill_pkg_tax_location,
 974         'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 975     });
 976
 977     my $tax_total = 0;
 978     my %seen = ();
 979     warn "adding $taxname\n" if $DEBUG > 1;
 980     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 981       if ( ref($taxitem) eq 'FS::cust_bill_pkg' ) {
 982         # then we need to transfer the amount and the links from the
 983         # line item to the new one we're creating.
 984         $tax_total += $taxitem->setup;
 985         foreach my $link ( @{ $taxitem->get('cust_bill_pkg_tax_location') } ) {
 986           $link->set('tax_cust_bill_pkg', $tax_cust_bill_pkg);
 987           push @cust_bill_pkg_tax_location, $link;
 988         }
 989       } else {
 990         # the tax_rate way
 991         next if $seen{$taxitem}++;
 992         warn "adding $tax_amount{$taxitem}\n" if $DEBUG > 1;
 993         $tax_total += $tax_amount{$taxitem};
 994         push @cust_bill_pkg_tax_rate_location,
 995           map { new FS::cust_bill_pkg_tax_rate_location $_ }
 996               @{ $tax_rate_location{ $taxitem } };
 997       }
 998     }
 999     next unless $tax_total;
1000
1001     # we should really neverround this up...I guess it's okay if taxline
1002     # already returns amounts with 2 decimal places
1003     $tax_total = sprintf('%.2f', $tax_total );
1004     $tax_cust_bill_pkg->set('setup', $tax_total);
1005
1006     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
1007                                                    'disabled'     => '',
1008                                                  },
1009                                );
1010
1011     my @display = ();
1012     if ( $pkg_category and
1013          $conf->config('invoice_latexsummary') ||
1014          $conf->config('invoice_htmlsummary')
1015        )
1016     {
1017
1018       my %hash = (  'section' => $pkg_category->categoryname );
1019       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1020
1021     }
1022     $tax_cust_bill_pkg->set('display', \@display);
1023
1024     push @tax_line_items, $tax_cust_bill_pkg;
1025   }
1026
1027   \@tax_line_items;
1028 }
1029
1030 sub _make_lines {
1031   my ($self, %params) = @_;
1032
1033   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1034
1035   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
1036   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
1037   my $cust_location = $cust_pkg->tax_location;
1038   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
1039   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
1040   my $total_setup = $params{setup} or die "no setup accumulator specified";
1041   my $total_recur = $params{recur} or die "no recur accumulator specified";
1042   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
1043   my $time = $params{'time'} or die "no time specified";
1044   my (%options) = %{$params{options}};
1045
1046   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
1047     # this should never happen
1048     die 'freq_override billing attempted on non-monthly package '.
1049       $cust_pkg->pkgnum;
1050   }
1051
1052   my $dbh = dbh;
1053   my $real_pkgpart = $params{real_pkgpart};
1054   my %hash = $cust_pkg->hash;
1055   my $old_cust_pkg = new FS::cust_pkg \%hash;
1056
1057   my @details = ();
1058   my $lineitems = 0;
1059
1060   $cust_pkg->pkgpart($part_pkg->pkgpart);
1061
1062   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
1063                      ? day_end( $time )
1064                      : $time
1065                  );
1066
1067   ###
1068   # bill setup
1069   ###
1070
1071   my $setup = 0;
1072   my $unitsetup = 0;
1073   my @setup_discounts = ();
1074   my %setup_param = ( 'discounts' => \@setup_discounts );
1075   if (     ! $options{recurring_only}
1076        and ! $options{cancel}
1077        and ( $options{'resetup'}
1078              || ( ! $cust_pkg->setup
1079                   && ( ! $cust_pkg->start_date
1080                        || $cust_pkg->start_date <= $cmp_time
1081                      )
1082                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
1083                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
1084                             ! $cust_pkg->getfield('susp')
1085                           )
1086                      )
1087                 )
1088            )
1089      )
1090   {
1091
1092     warn "    bill setup\n" if $DEBUG > 1;
1093
1094     unless ( $cust_pkg->waive_setup ) {
1095         $lineitems++;
1096
1097         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1098         return "$@ running calc_setup for $cust_pkg\n"
1099           if $@;
1100
1101         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
1102     }
1103
1104     $cust_pkg->setfield('setup', $time)
1105       unless $cust_pkg->setup;
1106           #do need it, but it won't get written to the db
1107           #|| $cust_pkg->pkgpart != $real_pkgpart;
1108
1109     $cust_pkg->setfield('start_date', '')
1110       if $cust_pkg->start_date;
1111
1112   }
1113
1114   ###
1115   # bill recurring fee
1116   ###
1117
1118   my $recur = 0;
1119   my $unitrecur = 0;
1120   my @recur_discounts = ();
1121   my $sdate;
1122   if (     ! $cust_pkg->start_date
1123        and
1124            ( ! $cust_pkg->susp
1125                || ( $cust_pkg->susp != $cust_pkg->order_date
1126                       && (    $cust_pkg->option('suspend_bill',1)
1127                            || ( $part_pkg->option('suspend_bill', 1)
1128                                  && ! $cust_pkg->option('no_suspend_bill',1)
1129                               )
1130                          )
1131                   )
1132            )
1133        and
1134             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1135          || ( $part_pkg->plan eq 'voip_cdr'
1136                && $part_pkg->option('bill_every_call')
1137             )
1138          || $options{cancel}
1139   ) {
1140
1141     # XXX should this be a package event?  probably.  events are called
1142     # at collection time at the moment, though...
1143     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1144       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1145       #don't want to reset usage just cause we want a line item??
1146       #&& $part_pkg->pkgpart == $real_pkgpart;
1147
1148     warn "    bill recur\n" if $DEBUG > 1;
1149     $lineitems++;
1150
1151     # XXX shared with $recur_prog
1152     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1153              || $cust_pkg->setup
1154              || $time;
1155
1156     #over two params!  lets at least switch to a hashref for the rest...
1157     my $increment_next_bill = ( $part_pkg->freq ne '0'
1158                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1159                                 && !$options{cancel}
1160                               );
1161     my %param = ( %setup_param,
1162                   'precommit_hooks'     => $precommit_hooks,
1163                   'increment_next_bill' => $increment_next_bill,
1164                   'discounts'           => \@recur_discounts,
1165                   'real_pkgpart'        => $real_pkgpart,
1166                   'freq_override'       => $options{freq_override} || '',
1167                   'setup_fee'           => 0,
1168                 );
1169
1170     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1171
1172     # There may be some part_pkg for which this is wrong.  Only those
1173     # which can_discount are supported.
1174     # (the UI should prevent adding discounts to these at the moment)
1175
1176     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1177          " for pkgpart ". $cust_pkg->pkgpart.
1178          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1179       if $DEBUG > 2;
1180
1181     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1182     return "$@ running $method for $cust_pkg\n"
1183       if ( $@ );
1184
1185     #base_cancel???
1186     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1187
1188     if ( $increment_next_bill ) {
1189
1190       my $next_bill;
1191
1192       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1193         # supplemental package
1194         # to keep in sync with the main package, simulate billing at
1195         # its frequency
1196         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1197         my $supp_pkg_freq = $part_pkg->freq;
1198         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1199         if ( $ratio != int($ratio) ) {
1200           # the UI should prevent setting up packages like this, but just
1201           # in case
1202           return "supplemental package period is not an integer multiple of main  package period";
1203         }
1204         $next_bill = $sdate;
1205         for (1..$ratio) {
1206           $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1207         }
1208
1209       } else {
1210         # the normal case
1211       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1212       return "unparsable frequency: ". $part_pkg->freq
1213         if $next_bill == -1;
1214       }
1215
1216       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1217       # only for figuring next bill date, nothing else, so, reset $sdate again
1218       # here
1219       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1220       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1221       $cust_pkg->last_bill($sdate);
1222
1223       $cust_pkg->setfield('bill', $next_bill );
1224
1225     }
1226
1227     if ( $param{'setup_fee'} ) {
1228       # Add an additional setup fee at the billing stage.
1229       # Used for prorate_defer_bill.
1230       $setup += $param{'setup_fee'};
1231       $unitsetup += $param{'setup_fee'};
1232       $lineitems++;
1233     }
1234
1235     if ( defined $param{'discount_left_setup'} ) {
1236         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1237             $setup -= $discount_setup;
1238         }
1239     }
1240
1241   }
1242
1243   warn "\$setup is undefined" unless defined($setup);
1244   warn "\$recur is undefined" unless defined($recur);
1245   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1246
1247   ###
1248   # If there's line items, create em cust_bill_pkg records
1249   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1250   ###
1251
1252   if ( $lineitems ) {
1253
1254     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1255       # hmm.. and if just the options are modified in some weird price plan?
1256
1257       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1258         if $DEBUG >1;
1259
1260       my $error = $cust_pkg->replace( $old_cust_pkg,
1261                                       'depend_jobnum'=>$options{depend_jobnum},
1262                                       'options' => { $cust_pkg->options },
1263                                     )
1264         unless $options{no_commit};
1265       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1266         if $error; #just in case
1267     }
1268
1269     $setup = sprintf( "%.2f", $setup );
1270     $recur = sprintf( "%.2f", $recur );
1271     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1272       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1273     }
1274     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1275       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1276     }
1277
1278     my $discount_show_always = $conf->exists('discount-show-always')
1279                                && (    ($setup == 0 && scalar(@setup_discounts))
1280                                     || ($recur == 0 && scalar(@recur_discounts))
1281                                   );
1282
1283     if (    $setup != 0
1284          || $recur != 0
1285          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1286          || $discount_show_always
1287          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1288          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1289        )
1290     {
1291
1292       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1293         if $DEBUG > 1;
1294
1295       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1296       if ( $DEBUG > 1 ) {
1297         warn "      adding customer package invoice detail: $_\n"
1298           foreach @cust_pkg_detail;
1299       }
1300       push @details, @cust_pkg_detail;
1301
1302       my $cust_bill_pkg = new FS::cust_bill_pkg {
1303         'pkgnum'    => $cust_pkg->pkgnum,
1304         'setup'     => $setup,
1305         'unitsetup' => $unitsetup,
1306         'recur'     => $recur,
1307         'unitrecur' => $unitrecur,
1308         'quantity'  => $cust_pkg->quantity,
1309         'details'   => \@details,
1310         'discounts' => [ @setup_discounts, @recur_discounts ],
1311         'hidden'    => $part_pkg->hidden,
1312         'freq'      => $part_pkg->freq,
1313       };
1314
1315       if ( $part_pkg->option('prorate_defer_bill',1)
1316            and !$hash{last_bill} ) {
1317         # both preceding and upcoming, technically
1318         $cust_bill_pkg->sdate( $cust_pkg->setup );
1319         $cust_bill_pkg->edate( $cust_pkg->bill );
1320       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1321         $cust_bill_pkg->sdate( $hash{last_bill} );
1322         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1323         $cust_bill_pkg->edate( $time ) if $options{cancel};
1324       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' ) {
1325         $cust_bill_pkg->sdate( $sdate );
1326         $cust_bill_pkg->edate( $cust_pkg->bill );
1327         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1328       }
1329
1330       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1331         unless $part_pkg->pkgpart == $real_pkgpart;
1332
1333       $$total_setup += $setup;
1334       $$total_recur += $recur;
1335
1336       ###
1337       # handle taxes
1338       ###
1339
1340       my $error = $self->_handle_taxes( $taxlisthash, $cust_bill_pkg,
1341         cancel => $options{cancel} );
1342       return $error if $error;
1343
1344       $cust_bill_pkg->set_display(
1345         part_pkg     => $part_pkg,
1346         real_pkgpart => $real_pkgpart,
1347       );
1348
1349       push @$cust_bill_pkgs, $cust_bill_pkg;
1350
1351     } #if $setup != 0 || $recur != 0
1352
1353   } #if $line_items
1354
1355   '';
1356
1357 }
1358
1359 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1360
1361 Takes one argument, a cust_pkg object that is being billed.  This will
1362 be called only if the package was created by a package change, and has
1363 not been billed since the package change, and package balance tracking
1364 is enabled.  The second argument can be an alternate package number to
1365 transfer the balance from; this should not be used externally.
1366
1367 Transfers the balance from the previous package (now canceled) to
1368 this package, by crediting one package and creating an invoice item for
1369 the other.  Inserts the credit and returns the invoice item (so that it
1370 can be added to an invoice that's being built).
1371
1372 If the previous package was never billed, and was also created by a package
1373 change, then this will also transfer the balance from I<its> previous
1374 package, and so on, until reaching a package that either has been billed
1375 or was not created by a package change.
1376
1377 =cut
1378
1379 my $balance_transfer_reason;
1380
1381 sub _transfer_balance {
1382   my $self = shift;
1383   my $cust_pkg = shift;
1384   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1385   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1386
1387   my @transfers;
1388
1389   # if $from_pkg is not the first package in the chain, and it was never
1390   # billed, walk back
1391   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1392     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1393   }
1394
1395   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1396   if ( $prev_balance != 0 ) {
1397     $balance_transfer_reason ||= FS::reason->new_or_existing(
1398       'reason' => 'Package balance transfer',
1399       'type'   => 'Internal adjustment',
1400       'class'  => 'R'
1401     );
1402
1403     my $credit = FS::cust_credit->new({
1404         'custnum'   => $self->custnum,
1405         'amount'    => abs($prev_balance),
1406         'reasonnum' => $balance_transfer_reason->reasonnum,
1407         '_date'     => $cust_pkg->change_date,
1408     });
1409
1410     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1411         'setup'     => 0,
1412         'recur'     => abs($prev_balance),
1413         #'sdate'     => $from_pkg->last_bill, # not sure about this
1414         #'edate'     => $cust_pkg->change_date,
1415         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1416                                  $from_pkg->part_pkg->pkg),
1417     });
1418
1419     if ( $prev_balance > 0 ) {
1420       # credit the old package, charge the new one
1421       $credit->set('pkgnum', $from_pkgnum);
1422       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1423     } else {
1424       # the reverse
1425       $credit->set('pkgnum', $cust_pkg->pkgnum);
1426       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1427     }
1428     my $error = $credit->insert;
1429     die "error transferring package balance from #".$from_pkgnum.
1430         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1431
1432     push @transfers, $cust_bill_pkg;
1433   } # $prev_balance != 0
1434
1435   return @transfers;
1436 }
1437
1438 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1439
1440 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1441 from _make_lines.
1442
1443 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1444 this:
1445 {
1446   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1447   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1448 }
1449
1450 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1451 is always the cust_main_county or tax_rate identified by the key.
1452
1453 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1454 the 'taxline' method to calculate the amount of the tax.  This doesn't
1455 happen until calculate_taxes, though.
1456
1457 OPTIONS may include:
1458 - part_item: a part_pkg or part_fee object to be used as the package/fee
1459   definition.
1460 - location: a cust_location to be used as the billing location.
1461 - cancel: true if this package is being billed on cancellation.  This
1462   allows tax to be calculated on usage charges only.
1463
1464 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1465 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1466 the customer's default service location).
1467
1468 =cut
1469
1470 sub _handle_taxes {
1471   my $self = shift;
1472   my $taxlisthash = shift;
1473   my $cust_bill_pkg = shift;
1474   my %options = @_;
1475
1476   # at this point I realize that we have enough information to infer all this
1477   # stuff, instead of passing around giant honking argument lists
1478   my $location = $options{location} || $cust_bill_pkg->tax_location;
1479   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1480
1481   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1482
1483   return if ( $self->payby eq 'COMP' ); #dubious
1484
1485   if ( $conf->exists('enable_taxproducts')
1486        && ( scalar($part_item->part_pkg_taxoverride)
1487             || $part_item->has_taxproduct
1488           )
1489      )
1490     {
1491
1492     # EXTERNAL TAX RATES (via tax_rate)
1493     my %cust_bill_pkg = ();
1494     my %taxes = ();
1495
1496     my @classes;
1497     push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1498     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1499     push @classes, 'recur' if $cust_bill_pkg->recur and !$options{cancel};
1500
1501     my $exempt = $conf->exists('cust_class-tax_exempt')
1502                    ? ( $self->cust_class ? $self->cust_class->tax : '' )
1503                    : $self->tax;
1504     # standardize this just to be sure
1505     $exempt = ($exempt eq 'Y') ? 'Y' : '';
1506
1507     if ( !$exempt ) {
1508
1509       foreach my $class (@classes) {
1510         my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1511         return $err_or_ref unless ref($err_or_ref);
1512         $taxes{$class} = $err_or_ref;
1513       }
1514
1515       unless (exists $taxes{''}) {
1516         my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1517         return $err_or_ref unless ref($err_or_ref);
1518         $taxes{''} = $err_or_ref;
1519       }
1520
1521     }
1522
1523     my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate; # grrr
1524     foreach my $key (keys %tax_cust_bill_pkg) {
1525       # $key is "setup", "recur", or a usage class name. ('' is a usage class.)
1526       # $tax_cust_bill_pkg{$key} is a cust_bill_pkg for that component of
1527       # the line item.
1528       # $taxes{$key} is an arrayref of cust_main_county or tax_rate objects that
1529       # apply to $key-class charges.
1530       my @taxes = @{ $taxes{$key} || [] };
1531       my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1532
1533       my %localtaxlisthash = ();
1534       foreach my $tax ( @taxes ) {
1535
1536         # this is the tax identifier, not the taxname
1537         my $taxname = ref( $tax ). ' '. $tax->taxnum;
1538         # $taxlisthash: keys are "setup", "recur", and usage classes.
1539         # Values are arrayrefs, first the tax object (cust_main_county
1540         # or tax_rate) and then any cust_bill_pkg objects that the
1541         # tax applies to.
1542         $taxlisthash->{ $taxname } ||= [ $tax ];
1543         push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1544
1545         $localtaxlisthash{ $taxname } ||= [ $tax ];
1546         push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1547
1548       }
1549
1550       warn "finding taxed taxes...\n" if $DEBUG > 2;
1551       foreach my $tax ( keys %localtaxlisthash ) {
1552         my $tax_object = shift @{ $localtaxlisthash{$tax} };
1553         warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1554           if $DEBUG > 2;
1555         next unless $tax_object->can('tax_on_tax');
1556
1557         foreach my $tot ( $tax_object->tax_on_tax( $location ) ) {
1558           my $totname = ref( $tot ). ' '. $tot->taxnum;
1559
1560           warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1561             if $DEBUG > 2;
1562           next unless exists( $localtaxlisthash{ $totname } ); # only increase
1563                                                                # existing taxes
1564           warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1565           # calculate the tax amount that the tax_on_tax will apply to
1566           my $hashref_or_error =
1567             $tax_object->taxline( $localtaxlisthash{$tax} );
1568           return $hashref_or_error
1569             unless ref($hashref_or_error);
1570
1571           # and append it to the list of taxable items
1572           $taxlisthash->{ $totname } ||= [ $tot ];
1573           push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1574
1575         }
1576       }
1577     }
1578
1579   } else {
1580
1581     # INTERNAL TAX RATES (cust_main_county)
1582
1583     # We fetch taxes even if the customer is completely exempt,
1584     # because we need to record that fact.
1585
1586     my @loc_keys = qw( district city county state country );
1587     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1588
1589     $taxhash{'taxclass'} = $part_item->taxclass;
1590
1591     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1592
1593     my @taxes = (); # entries are cust_main_county objects
1594     my %taxhash_elim = %taxhash;
1595     my @elim = qw( district city county state );
1596     do {
1597
1598       #first try a match with taxclass
1599       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1600
1601       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1602         #then try a match without taxclass
1603         my %no_taxclass = %taxhash_elim;
1604         $no_taxclass{ 'taxclass' } = '';
1605         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1606       }
1607
1608       $taxhash_elim{ shift(@elim) } = '';
1609
1610     } while ( !scalar(@taxes) && scalar(@elim) );
1611
1612     foreach (@taxes) {
1613       my $tax_id = 'cust_main_county '.$_->taxnum;
1614       $taxlisthash->{$tax_id} ||= [ $_ ];
1615       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1616     }
1617
1618   }
1619   '';
1620 }
1621
1622 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1623
1624 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1625 or part_fee (which will define the tax eligibility of the product), CLASS is
1626 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1627 location where the service was provided (or billed, depending on
1628 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1629 can apply to this line item.
1630
1631 =cut
1632
1633 sub _gather_taxes {
1634   my $self = shift;
1635   my $part_item = shift;
1636   my $class = shift;
1637   my $location = shift;
1638
1639   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1640
1641   my $geocode = $location->geocode('cch');
1642
1643   [ $part_item->tax_rates('cch', $geocode, $class) ]
1644
1645 }
1646
1647 =item collect [ HASHREF | OPTION => VALUE ... ]
1648
1649 (Attempt to) collect money for this customer's outstanding invoices (see
1650 L<FS::cust_bill>).  Usually used after the bill method.
1651
1652 Actions are now triggered by billing events; see L<FS::part_event> and the
1653 billing events web interface.  Old-style invoice events (see
1654 L<FS::part_bill_event>) have been deprecated.
1655
1656 If there is an error, returns the error, otherwise returns false.
1657
1658 Options are passed as name-value pairs.
1659
1660 Currently available options are:
1661
1662 =over 4
1663
1664 =item invoice_time
1665
1666 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1667
1668 =item retry
1669
1670 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1671
1672 =item check_freq
1673
1674 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1675
1676 =item quiet
1677
1678 set true to surpress email card/ACH decline notices.
1679
1680 =item debug
1681
1682 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1683
1684 =back
1685
1686 # =item payby
1687 #
1688 # allows for one time override of normal customer billing method
1689
1690 =cut
1691
1692 sub collect {
1693   my( $self, %options ) = @_;
1694
1695   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1696
1697   my $invoice_time = $options{'invoice_time'} || time;
1698
1699   #put below somehow?
1700   local $SIG{HUP} = 'IGNORE';
1701   local $SIG{INT} = 'IGNORE';
1702   local $SIG{QUIT} = 'IGNORE';
1703   local $SIG{TERM} = 'IGNORE';
1704   local $SIG{TSTP} = 'IGNORE';
1705   local $SIG{PIPE} = 'IGNORE';
1706
1707   my $oldAutoCommit = $FS::UID::AutoCommit;
1708   local $FS::UID::AutoCommit = 0;
1709   my $dbh = dbh;
1710
1711   $self->select_for_update; #mutex
1712
1713   if ( $DEBUG ) {
1714     my $balance = $self->balance;
1715     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1716   }
1717
1718   if ( exists($options{'retry_card'}) ) {
1719     carp 'retry_card option passed to collect is deprecated; use retry';
1720     $options{'retry'} ||= $options{'retry_card'};
1721   }
1722   if ( exists($options{'retry'}) && $options{'retry'} ) {
1723     my $error = $self->retry_realtime;
1724     if ( $error ) {
1725       $dbh->rollback if $oldAutoCommit;
1726       return $error;
1727     }
1728   }
1729
1730   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1731
1732   #never want to roll back an event just because it returned an error
1733   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1734
1735   $self->do_cust_event(
1736     'debug'      => ( $options{'debug'} || 0 ),
1737     'time'       => $invoice_time,
1738     'check_freq' => $options{'check_freq'},
1739     'stage'      => 'collect',
1740   );
1741
1742 }
1743
1744 =item retry_realtime
1745
1746 Schedules realtime / batch  credit card / electronic check / LEC billing
1747 events for for retry.  Useful if card information has changed or manual
1748 retry is desired.  The 'collect' method must be called to actually retry
1749 the transaction.
1750
1751 Implementation details: For either this customer, or for each of this
1752 customer's open invoices, changes the status of the first "done" (with
1753 statustext error) realtime processing event to "failed".
1754
1755 =cut
1756
1757 sub retry_realtime {
1758   my $self = shift;
1759
1760   local $SIG{HUP} = 'IGNORE';
1761   local $SIG{INT} = 'IGNORE';
1762   local $SIG{QUIT} = 'IGNORE';
1763   local $SIG{TERM} = 'IGNORE';
1764   local $SIG{TSTP} = 'IGNORE';
1765   local $SIG{PIPE} = 'IGNORE';
1766
1767   my $oldAutoCommit = $FS::UID::AutoCommit;
1768   local $FS::UID::AutoCommit = 0;
1769   my $dbh = dbh;
1770
1771   #a little false laziness w/due_cust_event (not too bad, really)
1772
1773   # I guess this is always as of now?
1774   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1775   my $order = FS::part_event_condition->order_conditions_sql;
1776   my $mine =
1777   '( '
1778    . join ( ' OR ' , map {
1779     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1780     my $custnum = FS::part_event->eventtables_custnum->{$_};
1781     "( part_event.eventtable = " . dbh->quote($_)
1782     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1783     . " from $_ $cust_join"
1784     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1785    } FS::part_event->eventtables)
1786    . ') ';
1787
1788   #here is the agent virtualization
1789   my $agent_virt = " (    part_event.agentnum IS NULL
1790                        OR part_event.agentnum = ". $self->agentnum. ' )';
1791
1792   #XXX this shouldn't be hardcoded, actions should declare it...
1793   my @realtime_events = qw(
1794     cust_bill_realtime_card
1795     cust_bill_realtime_check
1796     cust_bill_realtime_lec
1797     cust_bill_batch
1798   );
1799
1800   my $is_realtime_event =
1801     ' part_event.action IN ( '.
1802         join(',', map "'$_'", @realtime_events ).
1803     ' ) ';
1804
1805   my $batch_or_statustext =
1806     "( part_event.action = 'cust_bill_batch'
1807        OR ( statustext IS NOT NULL AND statustext != '' )
1808      )";
1809
1810
1811   my @cust_event = qsearch({
1812     'table'     => 'cust_event',
1813     'select'    => 'cust_event.*',
1814     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1815     'hashref'   => { 'status' => 'done' },
1816     'extra_sql' => " AND $batch_or_statustext ".
1817                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1818   });
1819
1820   my %seen_invnum = ();
1821   foreach my $cust_event (@cust_event) {
1822
1823     #max one for the customer, one for each open invoice
1824     my $cust_X = $cust_event->cust_X;
1825     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1826                           ? $cust_X->invnum
1827                           : 0
1828                         }++
1829          or $cust_event->part_event->eventtable eq 'cust_bill'
1830             && ! $cust_X->owed;
1831
1832     my $error = $cust_event->retry;
1833     if ( $error ) {
1834       $dbh->rollback if $oldAutoCommit;
1835       return "error scheduling event for retry: $error";
1836     }
1837
1838   }
1839
1840   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1841   '';
1842
1843 }
1844
1845 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1846
1847 Runs billing events; see L<FS::part_event> and the billing events web
1848 interface.
1849
1850 If there is an error, returns the error, otherwise returns false.
1851
1852 Options are passed as name-value pairs.
1853
1854 Currently available options are:
1855
1856 =over 4
1857
1858 =item time
1859
1860 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1861
1862 =item check_freq
1863
1864 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1865
1866 =item stage
1867
1868 "collect" (the default) or "pre-bill"
1869
1870 =item quiet
1871
1872 set true to surpress email card/ACH decline notices.
1873
1874 =item debug
1875
1876 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1877
1878 =back
1879 =cut
1880
1881 # =item payby
1882 #
1883 # allows for one time override of normal customer billing method
1884
1885 # =item retry
1886 #
1887 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1888
1889 sub do_cust_event {
1890   my( $self, %options ) = @_;
1891
1892   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1893
1894   my $time = $options{'time'} || time;
1895
1896   #put below somehow?
1897   local $SIG{HUP} = 'IGNORE';
1898   local $SIG{INT} = 'IGNORE';
1899   local $SIG{QUIT} = 'IGNORE';
1900   local $SIG{TERM} = 'IGNORE';
1901   local $SIG{TSTP} = 'IGNORE';
1902   local $SIG{PIPE} = 'IGNORE';
1903
1904   my $oldAutoCommit = $FS::UID::AutoCommit;
1905   local $FS::UID::AutoCommit = 0;
1906   my $dbh = dbh;
1907
1908   $self->select_for_update; #mutex
1909
1910   if ( $DEBUG ) {
1911     my $balance = $self->balance;
1912     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1913   }
1914
1915 #  if ( exists($options{'retry_card'}) ) {
1916 #    carp 'retry_card option passed to collect is deprecated; use retry';
1917 #    $options{'retry'} ||= $options{'retry_card'};
1918 #  }
1919 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1920 #    my $error = $self->retry_realtime;
1921 #    if ( $error ) {
1922 #      $dbh->rollback if $oldAutoCommit;
1923 #      return $error;
1924 #    }
1925 #  }
1926
1927   # false laziness w/pay_batch::import_results
1928
1929   my $due_cust_event = $self->due_cust_event(
1930     'debug'      => ( $options{'debug'} || 0 ),
1931     'time'       => $time,
1932     'check_freq' => $options{'check_freq'},
1933     'stage'      => ( $options{'stage'} || 'collect' ),
1934   );
1935   unless( ref($due_cust_event) ) {
1936     $dbh->rollback if $oldAutoCommit;
1937     return $due_cust_event;
1938   }
1939
1940   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1941   #never want to roll back an event just because it or a different one
1942   # returned an error
1943   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1944
1945   foreach my $cust_event ( @$due_cust_event ) {
1946
1947     #XXX lock event
1948
1949     #re-eval event conditions (a previous event could have changed things)
1950     unless ( $cust_event->test_conditions ) {
1951       #don't leave stray "new/locked" records around
1952       my $error = $cust_event->delete;
1953       return $error if $error;
1954       next;
1955     }
1956
1957     {
1958       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1959         if $options{'quiet'};
1960       warn "  running cust_event ". $cust_event->eventnum. "\n"
1961         if $DEBUG > 1;
1962
1963       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1964       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
1965         #XXX wtf is this?  figure out a proper dealio with return value
1966         #from do_event
1967         return $error;
1968       }
1969     }
1970
1971   }
1972
1973   '';
1974
1975 }
1976
1977 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1978
1979 Inserts database records for and returns an ordered listref of new events due
1980 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1981 events are due, an empty listref is returned.  If there is an error, returns a
1982 scalar error message.
1983
1984 To actually run the events, call each event's test_condition method, and if
1985 still true, call the event's do_event method.
1986
1987 Options are passed as a hashref or as a list of name-value pairs.  Available
1988 options are:
1989
1990 =over 4
1991
1992 =item check_freq
1993
1994 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1995
1996 =item stage
1997
1998 "collect" (the default) or "pre-bill"
1999
2000 =item time
2001
2002 "Current time" for the events.
2003
2004 =item debug
2005
2006 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2007
2008 =item eventtable
2009
2010 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2011
2012 =item objects
2013
2014 Explicitly pass the objects to be tested (typically used with eventtable).
2015
2016 =item testonly
2017
2018 Set to true to return the objects, but not actually insert them into the
2019 database.
2020
2021 =back
2022
2023 =cut
2024
2025 sub due_cust_event {
2026   my $self = shift;
2027   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2028
2029   #???
2030   #my $DEBUG = $opt{'debug'}
2031   $opt{'debug'} ||= 0; # silence some warnings
2032   local($DEBUG) = $opt{'debug'}
2033     if $opt{'debug'} > $DEBUG;
2034   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2035
2036   warn "$me due_cust_event called with options ".
2037        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2038     if $DEBUG;
2039
2040   $opt{'time'} ||= time;
2041
2042   local $SIG{HUP} = 'IGNORE';
2043   local $SIG{INT} = 'IGNORE';
2044   local $SIG{QUIT} = 'IGNORE';
2045   local $SIG{TERM} = 'IGNORE';
2046   local $SIG{TSTP} = 'IGNORE';
2047   local $SIG{PIPE} = 'IGNORE';
2048
2049   my $oldAutoCommit = $FS::UID::AutoCommit;
2050   local $FS::UID::AutoCommit = 0;
2051   my $dbh = dbh;
2052
2053   $self->select_for_update #mutex
2054     unless $opt{testonly};
2055
2056   ###
2057   # find possible events (initial search)
2058   ###
2059
2060   my @cust_event = ();
2061
2062   my @eventtable = $opt{'eventtable'}
2063                      ? ( $opt{'eventtable'} )
2064                      : FS::part_event->eventtables_runorder;
2065
2066   my $check_freq = $opt{'check_freq'} || '1d';
2067
2068   foreach my $eventtable ( @eventtable ) {
2069
2070     my @objects;
2071     if ( $opt{'objects'} ) {
2072
2073       @objects = @{ $opt{'objects'} };
2074
2075     } elsif ( $eventtable eq 'cust_main' ) {
2076
2077       @objects = ( $self );
2078
2079     } else {
2080
2081       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2082       # linkage not needed here because FS::cust_main->$eventtable will
2083       # already supply it
2084
2085       #some false laziness w/Cron::bill bill_where
2086
2087       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2088         'time' => $opt{'time'});
2089       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2090         'time'=>$opt{'time'},
2091       );
2092       $where = $where ? "AND $where" : '';
2093
2094       my $are_part_event =
2095       "EXISTS ( SELECT 1 FROM part_event $join
2096         WHERE check_freq = '$check_freq'
2097         AND eventtable = '$eventtable'
2098         AND ( disabled = '' OR disabled IS NULL )
2099         $where
2100         )
2101       ";
2102       #eofalse
2103
2104       @objects = $self->$eventtable(
2105         'addl_from' => $cm_join,
2106         'extra_sql' => " AND $are_part_event",
2107       );
2108     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2109
2110     my @e_cust_event = ();
2111
2112     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2113
2114     my $cross = "CROSS JOIN $eventtable $linkage";
2115     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2116       unless $eventtable eq 'cust_main';
2117
2118     foreach my $object ( @objects ) {
2119
2120       #this first search uses the condition_sql magic for optimization.
2121       #the more possible events we can eliminate in this step the better
2122
2123       my $cross_where = '';
2124       my $pkey = $object->primary_key;
2125       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2126
2127       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2128         'time' => $opt{'time'});
2129       my $extra_sql =
2130         FS::part_event_condition->where_conditions_sql( $eventtable,
2131                                                         'time'=>$opt{'time'}
2132                                                       );
2133       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2134
2135       $extra_sql = "AND $extra_sql" if $extra_sql;
2136
2137       #here is the agent virtualization
2138       $extra_sql .= " AND (    part_event.agentnum IS NULL
2139                             OR part_event.agentnum = ". $self->agentnum. ' )';
2140
2141       $extra_sql .= " $order";
2142
2143       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2144         if $opt{'debug'} > 2;
2145       my @part_event = qsearch( {
2146         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2147         'select'    => 'part_event.*',
2148         'table'     => 'part_event',
2149         'addl_from' => "$cross $join",
2150         'hashref'   => { 'check_freq' => $check_freq,
2151                          'eventtable' => $eventtable,
2152                          'disabled'   => '',
2153                        },
2154         'extra_sql' => "AND $cross_where $extra_sql",
2155       } );
2156
2157       if ( $DEBUG > 2 ) {
2158         my $pkey = $object->primary_key;
2159         warn "      ". scalar(@part_event).
2160              " possible events found for $eventtable ". $object->$pkey(). "\n";
2161       }
2162
2163       push @e_cust_event, map {
2164         $_->new_cust_event($object, 'time' => $opt{'time'})
2165       } @part_event;
2166
2167     }
2168
2169     warn "    ". scalar(@e_cust_event).
2170          " subtotal possible cust events found for $eventtable\n"
2171       if $DEBUG > 1;
2172
2173     push @cust_event, @e_cust_event;
2174
2175   }
2176
2177   warn "  ". scalar(@cust_event).
2178        " total possible cust events found in initial search\n"
2179     if $DEBUG; # > 1;
2180
2181
2182   ##
2183   # test stage
2184   ##
2185
2186   $opt{stage} ||= 'collect';
2187   @cust_event =
2188     grep { my $stage = $_->part_event->event_stage;
2189            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2190          }
2191          @cust_event;
2192
2193   ##
2194   # test conditions
2195   ##
2196
2197   my %unsat = ();
2198
2199   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2200                      @cust_event;
2201
2202   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2203     if $DEBUG; # > 1;
2204
2205   warn "    invalid conditions not eliminated with condition_sql:\n".
2206        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2207     if keys %unsat && $DEBUG; # > 1;
2208
2209   ##
2210   # insert
2211   ##
2212
2213   unless( $opt{testonly} ) {
2214     foreach my $cust_event ( @cust_event ) {
2215
2216       my $error = $cust_event->insert();
2217       if ( $error ) {
2218         $dbh->rollback if $oldAutoCommit;
2219         return $error;
2220       }
2221
2222     }
2223   }
2224
2225   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2226
2227   ##
2228   # return
2229   ##
2230
2231   warn "  returning events: ". Dumper(@cust_event). "\n"
2232     if $DEBUG > 2;
2233
2234   \@cust_event;
2235
2236 }
2237
2238 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2239
2240 Applies unapplied payments and credits.
2241
2242 In most cases, this new method should be used in place of sequential
2243 apply_payments and apply_credits methods.
2244
2245 A hash of optional arguments may be passed.  Currently "manual" is supported.
2246 If true, a payment receipt is sent instead of a statement when
2247 'payment_receipt_email' configuration option is set.
2248
2249 If there is an error, returns the error, otherwise returns false.
2250
2251 =cut
2252
2253 sub apply_payments_and_credits {
2254   my( $self, %options ) = @_;
2255
2256   local $SIG{HUP} = 'IGNORE';
2257   local $SIG{INT} = 'IGNORE';
2258   local $SIG{QUIT} = 'IGNORE';
2259   local $SIG{TERM} = 'IGNORE';
2260   local $SIG{TSTP} = 'IGNORE';
2261   local $SIG{PIPE} = 'IGNORE';
2262
2263   my $oldAutoCommit = $FS::UID::AutoCommit;
2264   local $FS::UID::AutoCommit = 0;
2265   my $dbh = dbh;
2266
2267   $self->select_for_update; #mutex
2268
2269   foreach my $cust_bill ( $self->open_cust_bill ) {
2270     my $error = $cust_bill->apply_payments_and_credits(%options);
2271     if ( $error ) {
2272       $dbh->rollback if $oldAutoCommit;
2273       return "Error applying: $error";
2274     }
2275   }
2276
2277   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2278   ''; #no error
2279
2280 }
2281
2282 =item apply_credits OPTION => VALUE ...
2283
2284 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2285 to outstanding invoice balances in chronological order (or reverse
2286 chronological order if the I<order> option is set to B<newest>) and returns the
2287 value of any remaining unapplied credits available for refund (see
2288 L<FS::cust_refund>).
2289
2290 Dies if there is an error.
2291
2292 =cut
2293
2294 sub apply_credits {
2295   my $self = shift;
2296   my %opt = @_;
2297
2298   local $SIG{HUP} = 'IGNORE';
2299   local $SIG{INT} = 'IGNORE';
2300   local $SIG{QUIT} = 'IGNORE';
2301   local $SIG{TERM} = 'IGNORE';
2302   local $SIG{TSTP} = 'IGNORE';
2303   local $SIG{PIPE} = 'IGNORE';
2304
2305   my $oldAutoCommit = $FS::UID::AutoCommit;
2306   local $FS::UID::AutoCommit = 0;
2307   my $dbh = dbh;
2308
2309   $self->select_for_update; #mutex
2310
2311   unless ( $self->total_unapplied_credits ) {
2312     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2313     return 0;
2314   }
2315
2316   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2317       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2318
2319   my @invoices = $self->open_cust_bill;
2320   @invoices = sort { $b->_date <=> $a->_date } @invoices
2321     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2322
2323   if ( $conf->exists('pkg-balances') ) {
2324     # limit @credits to those w/ a pkgnum grepped from $self
2325     my %pkgnums = ();
2326     foreach my $i (@invoices) {
2327       foreach my $li ( $i->cust_bill_pkg ) {
2328         $pkgnums{$li->pkgnum} = 1;
2329       }
2330     }
2331     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2332   }
2333
2334   my $credit;
2335
2336   foreach my $cust_bill ( @invoices ) {
2337
2338     if ( !defined($credit) || $credit->credited == 0) {
2339       $credit = pop @credits or last;
2340     }
2341
2342     my $owed;
2343     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2344       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2345     } else {
2346       $owed = $cust_bill->owed;
2347     }
2348     unless ( $owed > 0 ) {
2349       push @credits, $credit;
2350       next;
2351     }
2352
2353     my $amount = min( $credit->credited, $owed );
2354
2355     my $cust_credit_bill = new FS::cust_credit_bill ( {
2356       'crednum' => $credit->crednum,
2357       'invnum'  => $cust_bill->invnum,
2358       'amount'  => $amount,
2359     } );
2360     $cust_credit_bill->pkgnum( $credit->pkgnum )
2361       if $conf->exists('pkg-balances') && $credit->pkgnum;
2362     my $error = $cust_credit_bill->insert;
2363     if ( $error ) {
2364       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2365       die $error;
2366     }
2367
2368     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2369
2370   }
2371
2372   my $total_unapplied_credits = $self->total_unapplied_credits;
2373
2374   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2375
2376   return $total_unapplied_credits;
2377 }
2378
2379 =item apply_payments  [ OPTION => VALUE ... ]
2380
2381 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2382 to outstanding invoice balances in chronological order.
2383
2384  #and returns the value of any remaining unapplied payments.
2385
2386 A hash of optional arguments may be passed.  Currently "manual" is supported.
2387 If true, a payment receipt is sent instead of a statement when
2388 'payment_receipt_email' configuration option is set.
2389
2390 Dies if there is an error.
2391
2392 =cut
2393
2394 sub apply_payments {
2395   my( $self, %options ) = @_;
2396
2397   local $SIG{HUP} = 'IGNORE';
2398   local $SIG{INT} = 'IGNORE';
2399   local $SIG{QUIT} = 'IGNORE';
2400   local $SIG{TERM} = 'IGNORE';
2401   local $SIG{TSTP} = 'IGNORE';
2402   local $SIG{PIPE} = 'IGNORE';
2403
2404   my $oldAutoCommit = $FS::UID::AutoCommit;
2405   local $FS::UID::AutoCommit = 0;
2406   my $dbh = dbh;
2407
2408   $self->select_for_update; #mutex
2409
2410   #return 0 unless
2411
2412   my @payments = $self->unapplied_cust_pay;
2413
2414   my @invoices = $self->open_cust_bill;
2415
2416   if ( $conf->exists('pkg-balances') ) {
2417     # limit @payments to those w/ a pkgnum grepped from $self
2418     my %pkgnums = ();
2419     foreach my $i (@invoices) {
2420       foreach my $li ( $i->cust_bill_pkg ) {
2421         $pkgnums{$li->pkgnum} = 1;
2422       }
2423     }
2424     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2425   }
2426
2427   my $payment;
2428
2429   foreach my $cust_bill ( @invoices ) {
2430
2431     if ( !defined($payment) || $payment->unapplied == 0 ) {
2432       $payment = pop @payments or last;
2433     }
2434
2435     my $owed;
2436     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2437       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2438     } else {
2439       $owed = $cust_bill->owed;
2440     }
2441     unless ( $owed > 0 ) {
2442       push @payments, $payment;
2443       next;
2444     }
2445
2446     my $amount = min( $payment->unapplied, $owed );
2447
2448     my $cbp = {
2449       'paynum' => $payment->paynum,
2450       'invnum' => $cust_bill->invnum,
2451       'amount' => $amount,
2452     };
2453     $cbp->{_date} = $payment->_date
2454         if $options{'manual'} && $options{'backdate_application'};
2455     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2456     $cust_bill_pay->pkgnum( $payment->pkgnum )
2457       if $conf->exists('pkg-balances') && $payment->pkgnum;
2458     my $error = $cust_bill_pay->insert(%options);
2459     if ( $error ) {
2460       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2461       die $error;
2462     }
2463
2464     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2465
2466   }
2467
2468   my $total_unapplied_payments = $self->total_unapplied_payments;
2469
2470   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2471
2472   return $total_unapplied_payments;
2473 }
2474
2475 =back
2476
2477 =head1 FLOW
2478
2479   bill_and_collect
2480
2481     cancel_expired_pkgs
2482     suspend_adjourned_pkgs
2483     unsuspend_resumed_pkgs
2484
2485     bill
2486       (do_cust_event pre-bill)
2487       _make_lines
2488         _handle_taxes
2489           (vendor-only) _gather_taxes
2490       _omit_zero_value_bundles
2491       _handle_taxes (for fees)
2492       calculate_taxes
2493
2494     apply_payments_and_credits
2495     collect
2496       do_cust_event
2497         due_cust_event
2498
2499 =head1 BUGS
2500
2501 =head1 SEE ALSO
2502
2503 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2504
2505 =cut
2506
2507 1;