FS/FS/cust_event.pm

   1 package FS::cust_event;
   2
   3 use strict;
   4 use base qw( FS::cust_main_Mixin FS::Record );
   5 use vars qw( @ISA $DEBUG $me );
   6 use Carp qw( croak confess );
   7 use FS::Record qw( qsearch qsearchs dbdef );
   8 use FS::part_event;
   9 #for cust_X
  10 use FS::cust_main;
  11 use FS::cust_pkg;
  12 use FS::cust_bill;
  13 use FS::cust_pay;
  14 use FS::svc_acct;
  15
  16 $DEBUG = 1;
  17 $me = '[FS::cust_event]';
  18
  19 =head1 NAME
  20
  21 FS::cust_event - Object methods for cust_event records
  22
  23 =head1 SYNOPSIS
  24
  25   use FS::cust_event;
  26
  27   $record = new FS::cust_event \%hash;
  28   $record = new FS::cust_event { 'column' => 'value' };
  29
  30   $error = $record->insert;
  31
  32   $error = $new_record->replace($old_record);
  33
  34   $error = $record->delete;
  35
  36   $error = $record->check;
  37
  38 =head1 DESCRIPTION
  39
  40 An FS::cust_event object represents an completed event.  FS::cust_event
  41 inherits from FS::Record.  The following fields are currently supported:
  42
  43 =over 4
  44
  45 =item eventnum - primary key
  46
  47 =item eventpart - event definition (see L<FS::part_event>)
  48
  49 =item tablenum - customer, package or invoice, depending on the value of part_event.eventtable (see L<FS::cust_main>, L<FS::cust_pkg>, and L<FS::cust_bill>)
  50
  51 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  52 L<Time::Local> and L<Date::Parse> for conversion functions.
  53
  54 =item status - event status: B<new>, B<locked>, B<done> or B<failed>.  Note: B<done> indicates the event is complete and should not be retried (statustext may still be set to an optional message), while B<failed> indicates the event failed and should be retried.
  55
  56 =item statustext - additional status detail (i.e. error or progress message)
  57
  58 =item no_action - 'Y' if the event action wasn't performed. Some actions
  59 contain an internal check to see if the action is going to be impossible (for
  60 example, emailing a notice to a customer who has no email address), and if so,
  61 won't attempt the action. It shouldn't be reported as a failure because
  62 there's no need to retry it. However, the action should set no_action = 'Y'
  63 so that there's a record.
  64
  65 =back
  66
  67 =head1 METHODS
  68
  69 =over 4
  70
  71 =item new HASHREF
  72
  73 Creates a new completed invoice event.  To add the compelted invoice event to
  74 the database, see L<"insert">.
  75
  76 Note that this stores the hash reference, not a distinct copy of the hash it
  77 points to.  You can ask the object for a copy with the I<hash> method.
  78
  79 =cut
  80
  81 # the new method can be inherited from FS::Record, if a table method is defined
  82
  83 sub table { 'cust_event'; }
  84
  85 sub cust_linked { $_[0]->cust_main_custnum; }
  86 sub cust_unlinked_msg {
  87   my $self = shift;
  88   "WARNING: can't find cust_main.custnum ". $self->custnum;
  89   #' (cust_bill.invnum '. $self->invnum. ')';
  90 }
  91 sub custnum {
  92   my $self = shift;
  93   $self->cust_main_custnum(@_) || $self->SUPER::custnum(@_);
  94 }
  95
  96 =item insert
  97
  98 Adds this record to the database.  If there is an error, returns the error,
  99 otherwise returns false.
 100
 101 =cut
 102
 103 # the insert method can be inherited from FS::Record
 104
 105 =item delete
 106
 107 Delete this record from the database.
 108
 109 =cut
 110
 111 # the delete method can be inherited from FS::Record
 112
 113 =item replace OLD_RECORD
 114
 115 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 116 returns the error, otherwise returns false.
 117
 118 =cut
 119
 120 # the replace method can be inherited from FS::Record
 121
 122 =item check
 123
 124 Checks all fields to make sure this is a valid completed invoice event.  If
 125 there is an error, returns the error, otherwise returns false.  Called by the
 126 insert and replace methods.
 127
 128 =cut
 129
 130 # the check method should currently be supplied - FS::Record contains some
 131 # data checking routines
 132
 133 sub check {
 134   my $self = shift;
 135
 136   my $error = $self->ut_numbern('eventnum')
 137     || $self->ut_foreign_key('eventpart', 'part_event', 'eventpart')
 138   ;
 139   return $error if $error;
 140
 141   my $eventtable = $self->part_event->eventtable;
 142   my $dbdef_eventtable = dbdef->table( $eventtable );
 143
 144   $error =
 145        $self->ut_foreign_key( 'tablenum',
 146                               $eventtable,
 147                               $dbdef_eventtable->primary_key
 148                             )
 149     || $self->ut_number('_date')
 150     || $self->ut_enum('status', [qw( new locked done failed initial)])
 151     || $self->ut_anything('statustext')
 152     || $self->ut_flag('no_action')
 153   ;
 154   return $error if $error;
 155
 156   $self->SUPER::check;
 157 }
 158
 159 =item part_event
 160
 161 Returns the event definition (see L<FS::part_event>) for this completed event.
 162
 163 =cut
 164
 165 sub part_event {
 166   my $self = shift;
 167   qsearchs( 'part_event', { 'eventpart' => $self->eventpart } );
 168 }
 169
 170 =item cust_X
 171
 172 Returns the customer, package, invoice or batched payment (see
 173 L<FS::cust_main>, L<FS::cust_pkg>, L<FS::cust_bill> or L<FS::cust_pay_batch>)
 174 for this completed invoice event.
 175
 176 =cut
 177
 178 sub cust_bill {
 179   croak "FS::cust_event::cust_bill called";
 180 }
 181
 182 sub cust_X {
 183   my $self = shift;
 184   my $eventtable = $self->part_event->eventtable;
 185   my $dbdef_table = dbdef->table( $eventtable );
 186   my $primary_key = $dbdef_table->primary_key;
 187   qsearchs( $eventtable, { $primary_key => $self->tablenum } );
 188 }
 189
 190 =item test_conditions [ OPTION => VALUE ... ]
 191
 192 Tests conditions for this event, returns true if all conditions are satisfied,
 193 false otherwise.
 194
 195 =cut
 196
 197 sub test_conditions {
 198   my( $self, %opt ) = @_;
 199   my $part_event = $self->part_event;
 200   my $object = $self->cust_X;
 201   my @conditions = $part_event->part_event_condition;
 202   $opt{'cust_event'} = $self;
 203   $opt{'time'} = $self->_date
 204       or die "test_conditions called without cust_event._date\n";
 205     # this MUST be set, or all hell breaks loose in event conditions.
 206     # it MUST be in the same time as in the cust_event object, or
 207     # future time-dependent events will trigger incorrectly.
 208
 209   #no unsatisfied conditions
 210   #! grep ! $_->condition( $object, %opt ), @conditions;
 211   my @unsatisfied = grep ! $_->condition( $object, %opt ), @conditions;
 212
 213   if ( $opt{'stats_hashref'} ) {
 214     foreach my $unsat (@unsatisfied) {
 215       $opt{'stats_hashref'}->{$unsat->conditionname}++;
 216     }
 217   }
 218
 219   ! @unsatisfied;
 220 }
 221
 222 =item do_event
 223
 224 Runs the event action.
 225
 226 =cut
 227
 228 sub do_event {
 229   my $self = shift;
 230   my %opt = @_; # currently only 'time'
 231   my $time = $opt{'time'} || time;
 232
 233   my $part_event = $self->part_event;
 234
 235   my $object = $self->cust_X;
 236   my $obj_pkey = $object->primary_key;
 237   my $for = "for ". $object->table. " ". $object->$obj_pkey();
 238   warn "running cust_event ". $self->eventnum.
 239        " (". $part_event->action. ") $for\n"
 240     if $DEBUG;
 241
 242   my $error;
 243   {
 244     local $SIG{__DIE__}; # don't want Mason __DIE__ handler active
 245     $error = eval { $part_event->do_action($object, $self); };
 246   }
 247
 248   my $status = '';
 249   my $statustext = '';
 250   if ( $@ ) {
 251     $status = 'failed';
 252     #$statustext = $@;
 253     $statustext = "Error running ". $part_event->action. " action: $@";
 254   } elsif ( $error ) {
 255     $status = 'done';
 256     if ( $error eq 'N/A' ) {
 257       # archaic way to indicate no-op completion of spool_csv (and maybe
 258       # other events)?
 259       $self->no_action('Y');
 260     } else {
 261       $statustext = $error;
 262     }
 263   } else {
 264     $status = 'done';
 265   }
 266
 267   #replace or add myself
 268   $self->_date($time);
 269   $self->status($status);
 270   $self->statustext($statustext);
 271
 272   $error = $self->eventnum ? $self->replace : $self->insert;
 273   if ( $error ) {
 274     #this is why we need that locked state...
 275     my $e = 'WARNING: Event run but database not updated - '.
 276             'error replacing or inserting cust_event '. $self->eventnum.
 277             " $for: $error\n";
 278     warn $e;
 279     return $e;
 280   }
 281
 282   '';
 283
 284 }
 285
 286 =item retry
 287
 288 Changes the status of this event from B<done> to B<failed>, allowing it to be
 289 retried.
 290
 291 =cut
 292
 293 sub retry {
 294   my $self = shift;
 295   return '' unless $self->status eq 'done';
 296   my $old = ref($self)->new( { $self->hash } );
 297   $self->status('failed');
 298   $self->replace($old);
 299 }
 300
 301 #=item retryable
 302 #
 303 #Changes the statustext of this event to B<retriable>, rendering it
 304 #retriable (should retry be called).
 305 #
 306 #=cut
 307
 308 sub retriable {
 309   confess "cust_event->retriable called";
 310   my $self = shift;
 311   return '' unless $self->status eq 'done';
 312   my $old = ref($self)->new( { $self->hash } );
 313   $self->statustext('retriable');
 314   $self->replace($old);
 315 }
 316
 317 =item join_sql
 318
 319 =cut
 320
 321 sub join_sql {
 322   #my $class = shift;
 323
 324   "
 325        JOIN part_event USING ( eventpart )
 326   LEFT JOIN cust_bill ON ( eventtable = 'cust_bill' AND tablenum = invnum  )
 327   LEFT JOIN cust_pkg  ON ( eventtable = 'cust_pkg'  AND tablenum = pkgnum  )
 328   LEFT JOIN cust_pay  ON ( eventtable = 'cust_pay'  AND tablenum = paynum  )
 329   LEFT JOIN cust_svc  ON ( eventtable = 'svc_acct'  AND tablenum = svcnum  )
 330   LEFT JOIN cust_pkg AS cust_pkg_for_svc ON ( cust_svc.pkgnum = cust_pkg_for_svc.pkgnum )
 331   LEFT JOIN cust_main ON (
 332        ( eventtable = 'cust_main' AND tablenum = cust_main.custnum )
 333     OR ( eventtable = 'cust_bill' AND cust_bill.custnum = cust_main.custnum )
 334     OR ( eventtable = 'cust_pkg'  AND cust_pkg.custnum  = cust_main.custnum )
 335     OR ( eventtable = 'cust_pay'  AND cust_pay.custnum  = cust_main.custnum )
 336     OR ( eventtable = 'svc_acct'  AND cust_pkg_for_svc.custnum  = cust_main.custnum )
 337   )
 338   ";
 339
 340 }
 341
 342 =item search_sql_where HASHREF
 343
 344 Class method which returns an SQL WHERE fragment to search for parameters
 345 specified in HASHREF.  Valid parameters are
 346
 347 =over 4
 348
 349 =item agentnum
 350
 351 =item custnum
 352
 353 =item invnum
 354
 355 =item pkgnum
 356
 357 =item svcnum
 358
 359 =item failed
 360
 361 =item beginning
 362
 363 =item ending
 364
 365 =item payby
 366
 367 =item
 368
 369 =back
 370
 371 =cut
 372
 373 #Note: validates all passed-in data; i.e. safe to use with unchecked CGI params.
 374 #sub
 375
 376 sub search_sql_where {
 377   my($class, $param) = @_;
 378   if ( $DEBUG ) {
 379     warn "$me search_sql_where called with params: \n".
 380          join("\n", map { "  $_: ". $param->{$_} } keys %$param ). "\n";
 381   }
 382
 383   my @search = $class->cust_search_sql($param);
 384
 385   #eventpart
 386   my @eventpart = ref($param->{'eventpart'})
 387                     ? @{ $param->{'eventpart'} }
 388                     : split(',', $param->{'eventpart'});
 389   @eventpart = grep /^(\d+)$/, @eventpart;
 390   if ( @eventpart ) {
 391     push @search, 'eventpart IN ('. join(',', @eventpart). ')';
 392   }
 393
 394   if ( $param->{'beginning'} =~ /^(\d+)$/ ) {
 395     push @search, "cust_event._date >= $1";
 396   }
 397   if ( $param->{'ending'} =~ /^(\d+)$/ ) {
 398     push @search, "cust_event._date <= $1";
 399   }
 400
 401   #if ( $param->{'failed'} ) {
 402   #  push @search, "statustext != ''",
 403   #                "statustext IS NOT NULL",
 404   #                "statustext != 'N/A'";
 405   #}
 406   # huh?
 407
 408   my @event_status = ref($param->{'event_status'})
 409                     ? @{ $param->{'event_status'} }
 410                     : split(',', $param->{'event_status'});
 411   if ( @event_status ) {
 412     my @status;
 413
 414     my ($done_Y, $done_N, $done_S);
 415     # done_Y: action was taken
 416     # done_N: action was not taken
 417     # done_S: status message returned
 418     foreach (@event_status) {
 419       if ($_ eq 'done_Y') {
 420         $done_Y = 1;
 421       } elsif ( $_ eq 'done_N' ) {
 422         $done_N = 1;
 423       } elsif ( $_ eq 'done_S' ) {
 424         $done_S = 1;
 425       } else {
 426         push @status, $_;
 427       }
 428     }
 429     if ( $done_Y or $done_N or $done_S ) {
 430       push @status, 'done';
 431     }
 432     if ( @status ) {
 433       push @search, "cust_event.status IN(" .
 434                     join(',', map "'$_'", @status) .
 435                     ')';
 436     }
 437
 438     # done_S status should include only those where statustext is not null,
 439     # and done_Y should include only those where it is.
 440     if ( $done_Y and $done_N and $done_S ) {
 441       # then not necessary
 442     } else {
 443       my @done_status;
 444       if ( $done_Y ) {
 445         push @done_status, "(cust_event.no_action IS NULL AND cust_event.statustext IS NULL)";
 446       }
 447       if ( $done_N ) {
 448         push @done_status, "(cust_event.no_action = 'Y')";
 449       }
 450       if ( $done_S ) {
 451         push @done_status, "(cust_event.no_action IS NULL AND cust_event.statustext IS NOT NULL)";
 452       }
 453       push @search, join(' OR ', @done_status) if @done_status;
 454     }
 455
 456   } # event_status
 457
 458   # always hide initialization
 459   push @search, 'cust_event.status != \'initial\'';
 460
 461   if ( $param->{'custnum'} =~ /^(\d+)$/ ) {
 462     push @search, "cust_main.custnum = '$1'";
 463   }
 464
 465   if ( $param->{'invnum'} =~ /^(\d+)$/ ) {
 466     push @search, "part_event.eventtable = 'cust_bill'",
 467                   "tablenum = '$1'";
 468   }
 469
 470   if ( $param->{'pkgnum'} =~ /^(\d+)$/ ) {
 471     push @search, "part_event.eventtable = 'cust_pkg'",
 472                   "tablenum = '$1'";
 473   }
 474
 475   if ( $param->{'paynum'} =~ /^(\d+)$/ ) {
 476     push @search, "part_event.eventtable = 'cust_pay'",
 477                   "tablenum = '$1'";
 478   }
 479
 480   if ( $param->{'svcnum'} =~ /^(\d+)$/ ) {
 481     push @search, "part_event.eventtable = 'svc_acct'",
 482                   "tablenum = '$1'";
 483   }
 484
 485   my $where = 'WHERE '. join(' AND ', @search );
 486
 487   join(' AND ', @search );
 488
 489 }
 490
 491 =back
 492
 493 =head1 SUBROUTINES
 494
 495 =over 4
 496
 497 =item reprint
 498
 499 =cut
 500
 501 sub process_reprint {
 502   process_re_X('print', @_);
 503 }
 504
 505 =item reemail
 506
 507 =cut
 508
 509 sub process_reemail {
 510   process_re_X('email', @_);
 511 }
 512
 513 =item refax
 514
 515 =cut
 516
 517 sub process_refax {
 518   process_re_X('fax', @_);
 519 }
 520
 521 use Storable qw(thaw);
 522 use Data::Dumper;
 523 use MIME::Base64;
 524 sub process_re_X {
 525   my( $method, $job ) = ( shift, shift );
 526
 527   my $param = thaw(decode_base64(shift));
 528   warn Dumper($param) if $DEBUG;
 529
 530   re_X(
 531     $method,
 532     $param,
 533     $job,
 534   );
 535
 536 }
 537
 538 sub re_X {
 539   my($method, $param, $job) = @_;
 540
 541   my $search_sql = FS::cust_event->search_sql_where($param);
 542
 543   #maybe not...?  we do want the "re-" action to match the search more closely
 544   #            # yuck!  hardcoded *AND* sequential scans!
 545   #my $where = " WHERE action LIKE 'cust_bill_send%' ".
 546   #           ( $search_sql ? " AND $search_sql" : "" );
 547
 548   my $where = ( $search_sql ? " WHERE $search_sql" : "" );
 549
 550   my @cust_event = qsearch({
 551     'table'     => 'cust_event',
 552     'addl_from' => FS::cust_event->join_sql(),
 553     'hashref'   => {},
 554     'extra_sql' => $where,
 555   });
 556
 557   warn "$me re_X found ". scalar(@cust_event). " events\n"
 558     if $DEBUG;
 559
 560   my( $num, $last, $min_sec ) = (0, time, 5); #progresbar foo
 561   foreach my $cust_event ( @cust_event ) {
 562
 563     my $cust_X = $cust_event->cust_X; # cust_bill
 564     next unless $cust_X->can($method);
 565
 566     my $part_event = $cust_event->part_event;
 567     my $template = $part_event->templatename
 568                    || $cust_X->agent_template;
 569     my $modenum = $part_event->option('modenum') || '';
 570     my $invoice_from = $part_event->option('agent_invoice_from') || '';
 571     $cust_X->set('mode' => $modenum);
 572     $cust_X->$method( { template => $template,
 573                         modenum  => $modenum,
 574                         from     => $invoice_from,
 575                     } );
 576
 577     if ( $job ) { #progressbar foo
 578       $num++;
 579       if ( time - $min_sec > $last ) {
 580         my $error = $job->update_statustext(
 581           int( 100 * $num / scalar(@cust_event) )
 582         );
 583         die $error if $error;
 584         $last = time;
 585       }
 586     }
 587
 588   }
 589
 590   #this doesn't work, but it would be nice
 591   #if ( $job ) { #progressbar foo
 592   #  my $error = $job->update_statustext(
 593   #    scalar(@cust_event). " invoices re-${method}ed"
 594   #  );
 595   #  die $error if $error;
 596   #}
 597
 598 }
 599
 600 =back
 601
 602 =head1 SEE ALSO
 603
 604 L<FS::part_event>, L<FS::cust_bill>, L<FS::Record>, schema.html from the
 605 base documentation.
 606
 607 =cut
 608
 609 1;
 610