FS/FS/Template_Mixin.pm

   1 package FS::Template_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me
   5              $money_char
   6              $date_format
   7            );
   8              # but NOT $conf
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use List::Util qw(sum); #can't import first, it conflicts with cust_main.first
  11 use Date::Format;
  12 use Date::Language;
  13 use Text::Template 1.20;
  14 use File::Temp 0.14;
  15 use HTML::Entities;
  16 use Locale::Country;
  17 use Cwd;
  18 use FS::UID;
  19 use FS::Misc qw( send_email );
  20 use FS::Record qw( qsearch qsearchs );
  21 use FS::Conf;
  22 use FS::Misc qw( generate_ps generate_pdf );
  23 use FS::pkg_category;
  24 use FS::pkg_class;
  25 use FS::invoice_mode;
  26 use FS::L10N;
  27
  28 $DEBUG = 0;
  29 $me = '[FS::Template_Mixin]';
  30 FS::UID->install_callback( sub {
  31   my $conf = new FS::Conf; #global
  32   $money_char  = $conf->config('money_char')  || '$';
  33   $date_format = $conf->config('date_format') || '%x'; #/YY
  34 } );
  35
  36 =item conf [ MODE ]
  37
  38 Returns a configuration handle (L<FS::Conf>) set to the customer's locale.
  39
  40 If the "mode" pseudo-field is set on the object, the configuration handle
  41 will be an L<FS::invoice_conf> for that invoice mode (and the customer's
  42 locale).
  43
  44 =cut
  45
  46 sub conf {
  47   my $self = shift;
  48   my $mode = $self->get('mode');
  49   if ($self->{_conf} and !defined($mode)) {
  50     return $self->{_conf};
  51   }
  52
  53   my $cust_main = $self->cust_main;
  54   my $locale = $cust_main ? $cust_main->locale : '';
  55   my $conf;
  56   if ( $mode ) {
  57     if ( ref $mode and $mode->isa('FS::invoice_mode') ) {
  58       $mode = $mode->modenum;
  59     } elsif ( $mode =~ /\D/ ) {
  60       die "invalid invoice mode $mode";
  61     }
  62     $conf = qsearchs('invoice_conf', { modenum => $mode, locale => $locale });
  63     if (!$conf) {
  64       $conf = qsearchs('invoice_conf', { modenum => $mode, locale => '' });
  65       # it doesn't have a locale, but system conf still might
  66       $conf->set('locale' => $locale) if $conf;
  67     }
  68   }
  69   # if $mode is unspecified, or if there is no invoice_conf matching this mode
  70   # and locale, then use the system config only (but with the locale)
  71   $conf ||= FS::Conf->new({ 'locale' => $locale });
  72   # cache it
  73   return $self->{_conf} = $conf;
  74 }
  75
  76 =item print_text OPTIONS
  77
  78 Returns an text invoice, as a list of lines.
  79
  80 Options can be passed as a hash.
  81
  82 I<time>, if specified, is used to control the printing of overdue messages.  The
  83 default is now.  It isn't the date of the invoice; that's the `_date' field.
  84 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  85 L<Time::Local> and L<Date::Parse> for conversion functions.
  86
  87 I<template>, if specified, is the name of a suffix for alternate invoices.
  88
  89 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
  90
  91 =cut
  92
  93 sub print_text {
  94   my $self = shift;
  95   my %params;
  96   if ( ref($_[0]) ) {
  97     %params = %{ shift() };
  98   } else {
  99     %params = @_;
 100   }
 101
 102   $params{'format'} = 'template'; # for some reason
 103
 104   $self->print_generic( %params );
 105 }
 106
 107 =item print_latex HASHREF
 108
 109 Internal method - returns a filename of a filled-in LaTeX template for this
 110 invoice (Note: add ".tex" to get the actual filename), and a filename of
 111 an associated logo (with the .eps extension included).
 112
 113 See print_ps and print_pdf for methods that return PostScript and PDF output.
 114
 115 Options can be passed as a hash.
 116
 117 I<time>, if specified, is used to control the printing of overdue messages.  The
 118 default is now.  It isn't the date of the invoice; that's the `_date' field.
 119 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 120 L<Time::Local> and L<Date::Parse> for conversion functions.
 121
 122 I<template>, if specified, is the name of a suffix for alternate invoices.
 123 This is strongly deprecated; see L<FS::invoice_conf> for the right way to
 124 customize invoice templates for different purposes.
 125
 126 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
 127
 128 =cut
 129
 130 sub print_latex {
 131   my $self = shift;
 132   my %params;
 133
 134   if ( ref($_[0]) ) {
 135     %params = %{ shift() };
 136   } else {
 137     %params = @_;
 138   }
 139
 140   $params{'format'} = 'latex';
 141   my $conf = $self->conf;
 142
 143   # this needs to go away
 144   my $template = $params{'template'};
 145   # and this especially
 146   $template ||= $self->_agent_template
 147     if $self->can('_agent_template');
 148
 149   my $pkey = $self->primary_key;
 150   my $tmp_template = $self->table. '.'. $self->$pkey. '.XXXXXXXX';
 151
 152   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 153   my $lh = new File::Temp(
 154     TEMPLATE => $tmp_template,
 155     DIR      => $dir,
 156     SUFFIX   => '.eps',
 157     UNLINK   => 0,
 158   ) or die "can't open temp file: $!\n";
 159
 160   my $agentnum = $self->agentnum;
 161
 162   if ( $template && $conf->exists("logo_${template}.eps", $agentnum) ) {
 163     print $lh $conf->config_binary("logo_${template}.eps", $agentnum)
 164       or die "can't write temp file: $!\n";
 165   } else {
 166     print $lh $conf->config_binary('logo.eps', $agentnum)
 167       or die "can't write temp file: $!\n";
 168   }
 169   close $lh;
 170   $params{'logo_file'} = $lh->filename;
 171
 172   if( $conf->exists('invoice-barcode')
 173         && $self->can('invoice_barcode')
 174         && $self->invnum ) { # don't try to barcode statements
 175       my $png_file = $self->invoice_barcode($dir);
 176       my $eps_file = $png_file;
 177       $eps_file =~ s/\.png$/.eps/g;
 178       $png_file =~ /(barcode.*png)/;
 179       $png_file = $1;
 180       $eps_file =~ /(barcode.*eps)/;
 181       $eps_file = $1;
 182
 183       my $curr_dir = cwd();
 184       chdir($dir);
 185       # after painfuly long experimentation, it was determined that sam2p won't
 186       # accept : and other chars in the path, no matter how hard I tried to
 187       # escape them, hence the chdir (and chdir back, just to be safe)
 188       system('sam2p', '-j:quiet', $png_file, 'EPS:', $eps_file ) == 0
 189         or die "sam2p failed: $!\n";
 190       unlink($png_file);
 191       chdir($curr_dir);
 192
 193       $params{'barcode_file'} = $eps_file;
 194   }
 195
 196   my @filled_in = $self->print_generic( %params );
 197
 198   my $fh = new File::Temp( TEMPLATE => $tmp_template,
 199                            DIR      => $dir,
 200                            SUFFIX   => '.tex',
 201                            UNLINK   => 0,
 202                          ) or die "can't open temp file: $!\n";
 203   binmode($fh, ':utf8'); # language support
 204   print $fh join('', @filled_in );
 205   close $fh;
 206
 207   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
 208   return ($1, $params{'logo_file'}, $params{'barcode_file'});
 209
 210 }
 211
 212 sub agentnum {
 213   my $self = shift;
 214   my $cust_main = $self->cust_main;
 215   $cust_main ? $cust_main->agentnum : $self->prospect_main->agentnum;
 216 }
 217
 218 =item print_generic OPTION => VALUE ...
 219
 220 Internal method - returns a filled-in template for this invoice as a scalar.
 221
 222 See print_ps and print_pdf for methods that return PostScript and PDF output.
 223
 224 Required options
 225
 226 =over 4
 227
 228 =item format
 229
 230 The B<format> option is required and should be set to html, latex (print and PDF) or template (plaintext).
 231
 232 =back
 233
 234 Additional options
 235
 236 =over 4
 237
 238 =item notice_name
 239
 240 Overrides "Invoice" as the name of the sent document.
 241
 242 =item today
 243
 244 Used to control the printing of overdue messages.  The
 245 default is now.  It isn't the date of the invoice; that's the `_date' field.
 246 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 247 L<Time::Local> and L<Date::Parse> for conversion functions.
 248
 249 =item logo_file
 250
 251 Logo file (path to temporary EPS file on the local filesystem)
 252
 253 =item cid
 254
 255 CID for inline (emailed) images (logo)
 256
 257 =item locale
 258
 259 Override customer's locale
 260
 261 =item unsquelch_cdr
 262
 263 Overrides any per customer cdr squelching when true
 264
 265 =item no_number
 266
 267 Supress the (invoice, quotation, statement, etc.) number
 268
 269 =item no_date
 270
 271 Supress the date
 272
 273 =item no_coupon
 274
 275 Supress the payment coupon
 276
 277 =item barcode_file
 278
 279 Barcode file (path to temporary EPS file on the local filesystem)
 280
 281 =item barcode_img
 282
 283 Flag indicating the barcode image should be a link (normal HTML dipaly)
 284
 285 =item barcode_cid
 286
 287 Barcode CID for inline (emailed) images
 288
 289 =item preref_callback
 290
 291 Coderef run for each line item, code should return HTML to be displayed
 292 before that line item (quotations only)
 293
 294 =item template
 295
 296 Dprecated.  Used as a suffix for a configuration template.  Please
 297 don't use this, it deprecated in favor of more flexible alternatives.
 298
 299 =back
 300
 301 =cut
 302
 303 #what's with all the sprintf('%10.2f')'s in here?  will it cause any
 304 # (alignment in text invoice?) problems to change them all to '%.2f' ?
 305 # yes: fixed width/plain text printing will be borked
 306 sub print_generic {
 307   my( $self, %params ) = @_;
 308   my $conf = $self->conf;
 309
 310   my $today = $params{today} ? $params{today} : time;
 311   warn "$me print_generic called on $self with suffix $params{template}\n"
 312     if $DEBUG;
 313
 314   my $format = $params{format};
 315   die "Unknown format: $format"
 316     unless $format =~ /^(latex|html|template)$/;
 317
 318   my $cust_main = $self->cust_main || $self->prospect_main;
 319   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 320     unless $cust_main->payname
 321         && $cust_main->payby !~ /^(CARD|DCRD|CHEK|DCHK)$/;
 322
 323   my $locale = $params{'locale'} || $cust_main->locale;
 324
 325   my %delimiters = ( 'latex'    => [ '[@--', '--@]' ],
 326                      'html'     => [ '<%=', '%>' ],
 327                      'template' => [ '{', '}' ],
 328                    );
 329
 330   warn "$me print_generic creating template\n"
 331     if $DEBUG > 1;
 332
 333   # set the notice name here, and nowhere else.
 334   my $notice_name =  $params{notice_name}
 335                   || $conf->config('notice_name')
 336                   || $self->notice_name;
 337
 338   #create the template
 339   my $template = $params{template} ? $params{template} : $self->_agent_template;
 340   my $templatefile = $self->template_conf. $format;
 341   $templatefile .= "_$template"
 342     if length($template) && $conf->exists($templatefile."_$template");
 343
 344   # the base template
 345   my @invoice_template = map "$_\n", $conf->config($templatefile)
 346     or die "cannot load config data $templatefile";
 347
 348   if ( $format eq 'latex' && grep { /^%%Detail/ } @invoice_template ) {
 349     #change this to a die when the old code is removed
 350     # it's been almost ten years, changing it to a die on the next release.
 351     warn "old-style invoice template $templatefile; ".
 352          "patch with conf/invoice_latex.diff or use new conf/invoice_latex*\n";
 353          #$old_latex = 'true';
 354          #@invoice_template = _translate_old_latex_format(@invoice_template);
 355   }
 356
 357   warn "$me print_generic creating T:T object\n"
 358     if $DEBUG > 1;
 359
 360   my $text_template = new Text::Template(
 361     TYPE => 'ARRAY',
 362     SOURCE => \@invoice_template,
 363     DELIMITERS => $delimiters{$format},
 364   );
 365
 366   warn "$me print_generic compiling T:T object\n"
 367     if $DEBUG > 1;
 368
 369   $text_template->compile()
 370     or die "Can't compile $templatefile: $Text::Template::ERROR\n";
 371
 372
 373   # additional substitution could possibly cause breakage in existing templates
 374   my %convert_maps = (
 375     'latex' => {
 376                  'notes'         => sub { map "$_", @_ },
 377                  'footer'        => sub { map "$_", @_ },
 378                  'smallfooter'   => sub { map "$_", @_ },
 379                  'returnaddress' => sub { map "$_", @_ },
 380                  'coupon'        => sub { map "$_", @_ },
 381                  'summary'       => sub { map "$_", @_ },
 382                },
 383     'html'  => {
 384                  'notes' =>
 385                    sub {
 386                      map {
 387                        s/%%(.*)$/<!-- $1 -->/g;
 388                        s/\\section\*\{\\textsc\{(.)(.*)\}\}/<p><b><font size="+1">$1<\/font>\U$2<\/b>/g;
 389                        s/\\begin\{enumerate\}/<ol>/g;
 390                        s/\\item /  <li>/g;
 391                        s/\\end\{enumerate\}/<\/ol>/g;
 392                        s/\\textbf\{(.*)\}/<b>$1<\/b>/g;
 393                        s/\\\\\*/<br>/g;
 394                        s/\\dollar ?/\$/g;
 395                        s/\\#/#/g;
 396                        s/~/&nbsp;/g;
 397                        $_;
 398                      }  @_
 399                    },
 400                  'footer' =>
 401                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 402                  'smallfooter' =>
 403                    sub { map { s/~/&nbsp;/g; s/\\\\\*?\s*$/<BR>/; $_; } @_ },
 404                  'returnaddress' =>
 405                    sub {
 406                      map {
 407                        s/~/&nbsp;/g;
 408                        s/\\\\\*?\s*$/<BR>/;
 409                        s/\\hyphenation\{[\w\s\-]+}//;
 410                        s/\\([&])/$1/g;
 411                        $_;
 412                      }  @_
 413                    },
 414                  'coupon'        => sub { "" },
 415                  'summary'       => sub { "" },
 416                },
 417     'template' => {
 418                  'notes' =>
 419                    sub {
 420                      map {
 421                        s/%%.*$//g;
 422                        s/\\section\*\{\\textsc\{(.*)\}\}/\U$1/g;
 423                        s/\\begin\{enumerate\}//g;
 424                        s/\\item /  * /g;
 425                        s/\\end\{enumerate\}//g;
 426                        s/\\textbf\{(.*)\}/$1/g;
 427                        s/\\\\\*/ /;
 428                        s/\\dollar ?/\$/g;
 429                        $_;
 430                      }  @_
 431                    },
 432                  'footer' =>
 433                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 434                  'smallfooter' =>
 435                    sub { map { s/~/ /g; s/\\\\\*?\s*$/\n/; $_; } @_ },
 436                  'returnaddress' =>
 437                    sub {
 438                      map {
 439                        s/~/ /g;
 440                        s/\\\\\*?\s*$/\n/;             # dubious
 441                        s/\\hyphenation\{[\w\s\-]+}//;
 442                        $_;
 443                      }  @_
 444                    },
 445                  'coupon'        => sub { "" },
 446                  'summary'       => sub { "" },
 447                },
 448   );
 449
 450
 451   # hashes for differing output formats
 452   my %nbsps = ( 'latex'    => '~',
 453                 'html'     => '',    # '&nbps;' would be nice
 454                 'template' => '',    # not used
 455               );
 456   my $nbsp = $nbsps{$format};
 457
 458   my %escape_functions = ( 'latex'    => \&_latex_escape,
 459                            'html'     => \&_html_escape_nbsp,#\&encode_entities,
 460                            'template' => sub { shift },
 461                          );
 462   my $escape_function = $escape_functions{$format};
 463   my $escape_function_nonbsp = ($format eq 'html')
 464                                  ? \&_html_escape : $escape_function;
 465
 466   my %newline_tokens = (  'latex'     => '\\\\',
 467                           'html'      => '<br>',
 468                           'template'  => "\n",
 469                         );
 470   my $newline_token = $newline_tokens{$format};
 471
 472   warn "$me generating template variables\n"
 473     if $DEBUG > 1;
 474
 475   # generate template variables
 476   my $returnaddress;
 477
 478   if (
 479          defined( $conf->config_orbase( "invoice_${format}returnaddress",
 480                                         $template
 481                                       )
 482                 )
 483        && length( $conf->config_orbase( "invoice_${format}returnaddress",
 484                                         $template
 485                                       )
 486                 )
 487   ) {
 488
 489     $returnaddress = join("\n",
 490       $conf->config_orbase("invoice_${format}returnaddress", $template)
 491     );
 492
 493   } elsif ( grep /\S/,
 494             $conf->config_orbase('invoice_latexreturnaddress', $template) ) {
 495
 496     my $convert_map = $convert_maps{$format}{'returnaddress'};
 497     $returnaddress =
 498       join( "\n",
 499             &$convert_map( $conf->config_orbase( "invoice_latexreturnaddress",
 500                                                  $template
 501                                                )
 502                          )
 503           );
 504   } elsif ( grep /\S/, $conf->config('company_address', $cust_main->agentnum) ) {
 505
 506     my $convert_map = $convert_maps{$format}{'returnaddress'};
 507     $returnaddress = join( "\n", &$convert_map(
 508                                    map { s/( {2,})/'~' x length($1)/eg;
 509                                          s/$/\\\\\*/;
 510                                          $_
 511                                        }
 512                                      ( $conf->config('company_name', $cust_main->agentnum),
 513                                        $conf->config('company_address', $cust_main->agentnum),
 514                                      )
 515                                  )
 516                      );
 517
 518   } else {
 519
 520     my $warning = "Couldn't find a return address; ".
 521                   "do you need to set the company_address configuration value?";
 522     warn "$warning\n";
 523     $returnaddress = $nbsp;
 524     #$returnaddress = $warning;
 525
 526   }
 527
 528   warn "$me generating invoice data\n"
 529     if $DEBUG > 1;
 530
 531   my $agentnum = $cust_main->agentnum;
 532
 533   my %invoice_data = (
 534
 535     #invoice from info
 536     'company_name'    => scalar( $conf->config('company_name', $agentnum) ),
 537     'company_address' => join("\n", $conf->config('company_address', $agentnum) ). "\n",
 538     'company_phonenum'=> scalar( $conf->config('company_phonenum', $agentnum) ),
 539     'returnaddress'   => $returnaddress,
 540     'agent'           => &$escape_function($cust_main->agent->agent),
 541
 542     #invoice/quotation info
 543     'no_number'       => $params{'no_number'},
 544     'invnum'          => ( $params{'no_number'} ? '' : $self->invnum ),
 545     'quotationnum'    => $self->quotationnum,
 546     'no_date'         => $params{'no_date'},
 547     '_date'           => ( $params{'no_date'} ? '' : $self->_date ),
 548       # workaround for inconsistent behavior in the early plain text
 549       # templates; see RT#28271
 550     'date'            => ( $params{'no_date'}
 551                              ? ''
 552                              : ($format eq 'template'
 553                                ? $self->_date
 554                                : $self->time2str_local('long', $self->_date, $format)
 555                                )
 556                          ),
 557     'today'           => $self->time2str_local('long', $today, $format),
 558     'terms'           => $self->terms,
 559     'template'        => $template, #params{'template'},
 560     'notice_name'     => $notice_name, # escape?
 561     'current_charges' => sprintf("%.2f", $self->charged),
 562     'duedate'         => $self->due_date2str('rdate'), #date_format?
 563
 564     #customer info
 565     'custnum'         => $cust_main->display_custnum,
 566     'prospectnum'     => $cust_main->prospectnum,
 567     'agent_custid'    => &$escape_function($cust_main->agent_custid),
 568     ( map { $_ => &$escape_function($cust_main->$_()) } qw(
 569       payname company address1 address2 city state zip fax
 570     )),
 571
 572     #global config
 573     'ship_enable'     => $cust_main->invoice_ship_address || $conf->exists('invoice-ship_address'),
 574     'unitprices'      => $conf->exists('invoice-unitprice'),
 575     'smallernotes'    => $conf->exists('invoice-smallernotes'),
 576     'smallerfooter'   => $conf->exists('invoice-smallerfooter'),
 577     'balance_due_below_line' => $conf->exists('balance_due_below_line'),
 578
 579     #layout info -- would be fancy to calc some of this and bury the template
 580     #               here in the code
 581     'topmargin'             => scalar($conf->config('invoice_latextopmargin', $agentnum)),
 582     'headsep'               => scalar($conf->config('invoice_latexheadsep', $agentnum)),
 583     'textheight'            => scalar($conf->config('invoice_latextextheight', $agentnum)),
 584     'extracouponspace'      => scalar($conf->config('invoice_latexextracouponspace', $agentnum)),
 585     'couponfootsep'         => scalar($conf->config('invoice_latexcouponfootsep', $agentnum)),
 586     'verticalreturnaddress' => $conf->exists('invoice_latexverticalreturnaddress', $agentnum),
 587     'addresssep'            => scalar($conf->config('invoice_latexaddresssep', $agentnum)),
 588     'amountenclosedsep'     => scalar($conf->config('invoice_latexcouponamountenclosedsep', $agentnum)),
 589     'coupontoaddresssep'    => scalar($conf->config('invoice_latexcoupontoaddresssep', $agentnum)),
 590     'addcompanytoaddress'   => $conf->exists('invoice_latexcouponaddcompanytoaddress', $agentnum),
 591
 592     # better hang on to conf_dir for a while (for old templates)
 593     'conf_dir'        => "$FS::UID::conf_dir/conf.$FS::UID::datasrc",
 594
 595     #these are only used when doing paged plaintext
 596     'page'            => 1,
 597     'total_pages'     => 1,
 598
 599   );
 600
 601   #localization
 602   $invoice_data{'emt'} = sub { &$escape_function($self->mt(@_)) };
 603   # prototype here to silence warnings
 604   $invoice_data{'time2str'} = sub ($;$$) { $self->time2str_local(@_, $format) };
 605
 606   my $min_sdate = 999999999999;
 607   my $max_edate = 0;
 608   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 609     next unless $cust_bill_pkg->pkgnum > 0;
 610     $min_sdate = $cust_bill_pkg->sdate
 611       if length($cust_bill_pkg->sdate) && $cust_bill_pkg->sdate < $min_sdate;
 612     $max_edate = $cust_bill_pkg->edate
 613       if length($cust_bill_pkg->edate) && $cust_bill_pkg->edate > $max_edate;
 614   }
 615
 616   $invoice_data{'bill_period'} = '';
 617   $invoice_data{'bill_period'} =
 618       $self->time2str_local('%e %h', $min_sdate, $format)
 619       . " to " .
 620       $self->time2str_local('%e %h', $max_edate, $format)
 621     if ($max_edate != 0 && $min_sdate != 999999999999);
 622
 623   $invoice_data{finance_section} = '';
 624   if ( $conf->config('finance_pkgclass') ) {
 625     my $pkg_class =
 626       qsearchs('pkg_class', { classnum => $conf->config('finance_pkgclass') });
 627     $invoice_data{finance_section} = $pkg_class->categoryname;
 628   }
 629   $invoice_data{finance_amount} = '0.00';
 630   $invoice_data{finance_section} ||= 'Finance Charges'; #avoid config confusion
 631
 632   my $countrydefault = $conf->config('countrydefault') || 'US';
 633   foreach ( qw( address1 address2 city state zip country fax) ){
 634     my $method = 'ship_'.$_;
 635     $invoice_data{"ship_$_"} = $escape_function->($cust_main->$method);
 636   }
 637   if ( length($cust_main->ship_company) ) {
 638     $invoice_data{'ship_company'} = $escape_function->($cust_main->ship_company);
 639   } else {
 640     $invoice_data{'ship_company'} = $escape_function->($cust_main->company);
 641   }
 642   $invoice_data{'ship_contact'} = $escape_function->($cust_main->contact);
 643   $invoice_data{'ship_country'} = ''
 644     if ( $invoice_data{'ship_country'} eq $countrydefault );
 645
 646   $invoice_data{'cid'} = $params{'cid'}
 647     if $params{'cid'};
 648
 649   if ( $cust_main->country eq $countrydefault ) {
 650     $invoice_data{'country'} = '';
 651   } else {
 652     $invoice_data{'country'} = &$escape_function(code2country($cust_main->country));
 653   }
 654
 655   my @address = ();
 656   $invoice_data{'address'} = \@address;
 657   push @address,
 658     $cust_main->payname.
 659       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
 660         ? " (P.O. #". $cust_main->payinfo. ")"
 661         : ''
 662       )
 663   ;
 664   push @address, $cust_main->company
 665     if $cust_main->company;
 666   push @address, $cust_main->address1;
 667   push @address, $cust_main->address2
 668     if $cust_main->address2;
 669   push @address,
 670     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 671   push @address, $invoice_data{'country'}
 672     if $invoice_data{'country'};
 673   push @address, ''
 674     while (scalar(@address) < 5);
 675
 676   $invoice_data{'logo_file'} = $params{'logo_file'}
 677     if $params{'logo_file'};
 678   $invoice_data{'barcode_file'} = $params{'barcode_file'}
 679     if $params{'barcode_file'};
 680   $invoice_data{'barcode_img'} = $params{'barcode_img'}
 681     if $params{'barcode_img'};
 682   $invoice_data{'barcode_cid'} = $params{'barcode_cid'}
 683     if $params{'barcode_cid'};
 684
 685   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 686 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 687   #my $balance_due = $self->owed + $pr_total - $cr_total;
 688   my $balance_due = $self->owed + $pr_total;
 689
 690   # the sum of amount owed on all invoices
 691   # (this is used in the summary & on the payment coupon)
 692   $invoice_data{'balance'} = sprintf("%.2f", $balance_due);
 693
 694   # flag telling this invoice to have a first-page summary
 695   my $summarypage = '';
 696
 697   if ( $self->custnum && $self->invnum ) {
 698     # XXX should be an FS::cust_bill method to set the defaults, instead
 699     # of checking the type here
 700
 701     # info from customer's last invoice before this one, for some
 702     # summary formats
 703     $invoice_data{'last_bill'} = {};
 704
 705     my $last_bill = $self->previous_bill;
 706     if ( $last_bill ) {
 707
 708       # "balance_date_range" unfortunately is unsuitable for this, since it
 709       # cares about application dates.  We want to know the sum of all
 710       # _top-level transactions_ dated before the last invoice.
 711       my @sql =
 712         map "$_ WHERE _date <= ? AND custnum = ?", (
 713           "SELECT      COALESCE( SUM(charged), 0 ) FROM cust_bill",
 714           "SELECT -1 * COALESCE( SUM(amount),  0 ) FROM cust_credit",
 715           "SELECT -1 * COALESCE( SUM(paid),    0 ) FROM cust_pay",
 716           "SELECT      COALESCE( SUM(refund),  0 ) FROM cust_refund",
 717         );
 718
 719       # the customer's current balance immediately after generating the last
 720       # bill
 721
 722       my $last_bill_balance = $last_bill->charged;
 723       foreach (@sql) {
 724         my $delta = FS::Record->scalar_sql(
 725           $_,
 726           $last_bill->_date - 1,
 727           $self->custnum,
 728         );
 729         $last_bill_balance += $delta;
 730       }
 731
 732       $last_bill_balance = sprintf("%.2f", $last_bill_balance);
 733
 734       warn sprintf("LAST BILL: INVNUM %d, DATE %s, BALANCE %.2f\n\n",
 735         $last_bill->invnum,
 736         $self->time2str_local('%D', $last_bill->_date),
 737         $last_bill_balance
 738       ) if $DEBUG > 0;
 739       # ("true_previous_balance" is a terrible name, but at least it's no
 740       # longer stored in the database)
 741       $invoice_data{'true_previous_balance'} = $last_bill_balance;
 742
 743       # the change in balance from immediately after that invoice
 744       # to immediately before this one
 745       my $before_this_bill_balance = 0;
 746       foreach (@sql) {
 747         my $delta = FS::Record->scalar_sql(
 748           $_,
 749           $self->_date - 1,
 750           $self->custnum,
 751         );
 752         $before_this_bill_balance += $delta;
 753       }
 754       $invoice_data{'balance_adjustments'} =
 755         sprintf("%.2f", $last_bill_balance - $before_this_bill_balance);
 756
 757       warn sprintf("BALANCE ADJUSTMENTS: %.2f\n\n",
 758                    $invoice_data{'balance_adjustments'}
 759       ) if $DEBUG > 0;
 760
 761       # the sum of amount owed on all previous invoices
 762       # ($pr_total is used elsewhere but not as $previous_balance)
 763       $invoice_data{'previous_balance'} = sprintf("%.2f", $pr_total);
 764
 765       $invoice_data{'last_bill'}{'_date'} = $last_bill->_date; #unformatted
 766       my (@payments, @credits);
 767       # for formats that itemize previous payments
 768       foreach my $cust_pay ( qsearch('cust_pay', {
 769                               'custnum' => $self->custnum,
 770                               '_date'   => { op => '>=',
 771                                              value => $last_bill->_date }
 772                              } ) )
 773       {
 774         next if $cust_pay->_date > $self->_date;
 775         push @payments, {
 776             '_date'       => $cust_pay->_date,
 777             'date'        => $self->time2str_local('long', $cust_pay->_date, $format),
 778             'payinfo'     => $cust_pay->payby_payinfo_pretty,
 779             'amount'      => sprintf('%.2f', $cust_pay->paid),
 780         };
 781         # not concerned about applications
 782       }
 783       foreach my $cust_credit ( qsearch('cust_credit', {
 784                               'custnum' => $self->custnum,
 785                               '_date'   => { op => '>=',
 786                                              value => $last_bill->_date }
 787                              } ) )
 788       {
 789         next if $cust_credit->_date > $self->_date;
 790         push @credits, {
 791             '_date'       => $cust_credit->_date,
 792             'date'        => $self->time2str_local('long', $cust_credit->_date, $format),
 793             'creditreason'=> $cust_credit->reason,
 794             'amount'      => sprintf('%.2f', $cust_credit->amount),
 795         };
 796       }
 797       $invoice_data{'previous_payments'} = \@payments;
 798       $invoice_data{'previous_credits'}  = \@credits;
 799     } else {
 800       # there is no $last_bill
 801       $invoice_data{'true_previous_balance'} =
 802       $invoice_data{'balance_adjustments'}   =
 803       $invoice_data{'previous_balance'}      = '0.00';
 804       $invoice_data{'previous_payments'} = [];
 805       $invoice_data{'previous_credits'} = [];
 806     }
 807
 808     if ( $conf->exists('invoice_usesummary', $agentnum) ) {
 809       $invoice_data{'summarypage'} = $summarypage = 1;
 810     }
 811
 812   } # if this is an invoice
 813
 814   warn "$me substituting variables in notes, footer, smallfooter\n"
 815     if $DEBUG > 1;
 816
 817   my $tc = $self->template_conf;
 818   my @include = ( [ $tc,        'notes' ],
 819                   [ 'invoice_', 'footer' ],
 820                   [ 'invoice_', 'smallfooter', ],
 821                   [ 'invoice_', 'watermark' ],
 822                 );
 823   push @include, [ $tc,        'coupon', ]
 824     unless $params{'no_coupon'};
 825
 826   foreach my $i (@include) {
 827
 828     # load the configuration for this sub-template
 829
 830     my($base, $include) = @$i;
 831
 832     my $inc_file = $conf->key_orbase("$base$format$include", $template);
 833
 834     my @inc_src = $conf->config($inc_file, $agentnum);
 835     if (!@inc_src) {
 836       my $converter = $convert_maps{$format}{$include};
 837       if ( $converter ) {
 838         # then attempt to convert LaTeX to the requested format
 839         $inc_file = $conf->key_orbase($base.'latex'.$include, $template);
 840         @inc_src = &$converter( $conf->config($inc_file, $agentnum) );
 841         foreach (@inc_src) {
 842           # this isn't included in the convert_maps
 843           my ($open, $close) = @{ $delimiters{$format} };
 844           s/\[\@--/$open/g;
 845           s/--\@\]/$close/g;
 846         }
 847       }
 848     } # else @inc_src is empty and that's fine
 849
 850     # make a Text::Template out of it
 851
 852     my $inc_tt = new Text::Template (
 853       TYPE       => 'ARRAY',
 854       SOURCE     => [ map "$_\n", @inc_src ],
 855       DELIMITERS => $delimiters{$format},
 856     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
 857
 858     unless ( $inc_tt->compile() ) {
 859       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
 860       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
 861       die $error;
 862     }
 863
 864     # fill in variables
 865
 866     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
 867
 868     $invoice_data{$include} =~ s/\n+$//
 869       if ($format eq 'latex');
 870   }
 871
 872   # let invoices use either of these as needed
 873   $invoice_data{'po_num'} = ($cust_main->payby eq 'BILL')
 874     ? $cust_main->payinfo : '';
 875   $invoice_data{'po_line'} =
 876     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 877       ? &$escape_function($self->mt("Purchase Order #").$cust_main->payinfo)
 878       : $nbsp;
 879
 880   my %money_chars = ( 'latex'    => '',
 881                       'html'     => $conf->config('money_char') || '$',
 882                       'template' => '',
 883                     );
 884   my $money_char = $money_chars{$format};
 885
 886   # extremely dubious
 887   my %other_money_chars = ( 'latex'    => '\dollar ',#XXX should be a config too
 888                             'html'     => $conf->config('money_char') || '$',
 889                             'template' => '',
 890                           );
 891   my $other_money_char = $other_money_chars{$format};
 892   $invoice_data{'dollar'} = $other_money_char;
 893
 894   my %minus_signs = ( 'latex'    => '$-$',
 895                       'html'     => '&minus;',
 896                       'template' => '- ' );
 897   my $minus = $minus_signs{$format};
 898
 899   my @detail_items = ();
 900   my @total_items = ();
 901   my @buf = ();
 902   my @sections = ();
 903
 904   $invoice_data{'detail_items'} = \@detail_items;
 905   $invoice_data{'total_items'} = \@total_items;
 906   $invoice_data{'buf'} = \@buf;
 907   $invoice_data{'sections'} = \@sections;
 908
 909   warn "$me generating sections\n"
 910     if $DEBUG > 1;
 911
 912   my $unsquelched = $params{unsquelch_cdr} || $cust_main->squelch_cdr ne 'Y';
 913   my $multisection = $conf->exists($tc.'sections', $cust_main->agentnum) ||
 914                      $conf->exists($tc.'sections_by_location', $cust_main->agentnum);
 915   $invoice_data{'multisection'} = $multisection;
 916   my $late_sections;
 917   my $extra_sections = [];
 918   my $extra_lines = ();
 919
 920   # default section ('Charges')
 921   my $default_section = { 'description' => '',
 922                           'subtotal'    => '',
 923                           'no_subtotal' => 1,
 924                         };
 925
 926   # Previous Charges section
 927   # subtotal is the first return value from $self->previous
 928   my $previous_section;
 929   # if the invoice has major sections, or if we're summarizing previous
 930   # charges with a single line, or if we've been specifically told to put them
 931   # in a section, create a section for previous charges:
 932   if ( $multisection or
 933        $conf->exists('previous_balance-summary_only') or
 934        $conf->exists('previous_balance-section') ) {
 935
 936     $previous_section =  { 'description' => $self->mt('Previous Charges'),
 937                            'subtotal'    => $other_money_char.
 938                                             sprintf('%.2f', $pr_total),
 939                            'summarized'  => '', #why? $summarypage ? 'Y' : '',
 940                          };
 941     $previous_section->{posttotal} = '0 / 30 / 60 / 90 days overdue '.
 942       join(' / ', map { $cust_main->balance_date_range(@$_) }
 943                   $self->_prior_month30s
 944           )
 945       if $conf->exists('invoice_include_aging');
 946
 947   } else {
 948     # otherwise put them in the main section
 949     $previous_section = $default_section;
 950   }
 951
 952   my $adjust_section = {
 953     'description'    => $self->mt('Credits, Payments, and Adjustments'),
 954     'adjust_section' => 1,
 955     'subtotal'       => 0,   # adjusted below
 956   };
 957   my $adjust_weight = _pkg_category($adjust_section->{description})
 958                         ? _pkg_category($adjust_section->{description})->weight
 959                         : 0;
 960   $adjust_section->{'summarized'} = ''; #why? $summarypage && !$adjust_weight ? 'Y' : '';
 961   # Note: 'sort_weight' here is actually a flag telling whether there is an
 962   # explicit package category for the adjust section. If so, certain behavior
 963   # happens.
 964   $adjust_section->{'sort_weight'} = $adjust_weight;
 965
 966
 967   if ( $multisection ) {
 968     ($extra_sections, $extra_lines) =
 969       $self->_items_extra_usage_sections($escape_function_nonbsp, $format)
 970       if $conf->exists('usage_class_as_a_section', $cust_main->agentnum)
 971       && $self->can('_items_extra_usage_sections');
 972
 973     push @$extra_sections, $adjust_section if $adjust_section->{sort_weight};
 974
 975     push @detail_items, @$extra_lines if $extra_lines;
 976
 977     # the code is written so that both methods can be used together, but
 978     # we haven't yet changed the template to take advantage of that, so for
 979     # now, treat them as mutually exclusive.
 980     my %section_method = ( by_category => 1 );
 981     if ( $conf->config($tc.'sections_method') eq 'location' ) {
 982       %section_method = ( by_location => 1 );
 983     }
 984     my ($early, $late) =
 985       $self->_items_sections( 'summary' => $summarypage,
 986                               'escape'  => $escape_function_nonbsp,
 987                               'extra_sections' => $extra_sections,
 988                               'format'  => $format,
 989                               %section_method
 990                             );
 991     push @sections, @$early;
 992     $late_sections = $late;
 993
 994     if (    $conf->exists('svc_phone_sections')
 995          && $self->can('_items_svc_phone_sections')
 996        )
 997     {
 998       my ($phone_sections, $phone_lines) =
 999         $self->_items_svc_phone_sections($escape_function_nonbsp, $format);
1000       push @{$late_sections}, @$phone_sections;
1001       push @detail_items, @$phone_lines;
1002     }
1003     if ( $conf->exists('voip-cust_accountcode_cdr')
1004          && $cust_main->accountcode_cdr
1005          && $self->can('_items_accountcode_cdr')
1006        )
1007     {
1008       my ($accountcode_section, $accountcode_lines) =
1009         $self->_items_accountcode_cdr($escape_function_nonbsp,$format);
1010       if ( scalar(@$accountcode_lines) ) {
1011           push @{$late_sections}, $accountcode_section;
1012           push @detail_items, @$accountcode_lines;
1013       }
1014     }
1015   } else {# not multisection
1016     # make a default section
1017     push @sections, $default_section;
1018     # and calculate the finance charge total, since it won't get done otherwise.
1019     # and the default section total
1020     # XXX possibly finance_pkgclass should not be used in this manner?
1021     my @finance_charges;
1022     my @charges;
1023     foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
1024       if ( $invoice_data{finance_section} and
1025         grep { $_->section eq $invoice_data{finance_section} }
1026            $cust_bill_pkg->cust_bill_pkg_display ) {
1027         # I think these are always setup fees, but just to be sure...
1028         push @finance_charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1029       } else {
1030         push @charges, $cust_bill_pkg->recur + $cust_bill_pkg->setup;
1031       }
1032     }
1033     $invoice_data{finance_amount} =
1034       sprintf('%.2f', sum( @finance_charges ) || 0);
1035     $default_section->{subtotal} = $other_money_char.
1036                                     sprintf('%.2f', sum( @charges ) || 0);
1037   }
1038
1039   # start setting up summary subtotals
1040   my @summary_subtotals;
1041   my $method = $conf->config('summary_subtotals_method');
1042   if ( $method and $method ne $conf->config($tc.'sections_method') ) {
1043     # then re-section them by the correct method
1044     my %section_method = ( by_category => 1 );
1045     if ( $conf->config('summary_subtotals_method') eq 'location' ) {
1046       %section_method = ( by_location => 1 );
1047     }
1048     my ($early, $late) =
1049       $self->_items_sections( 'summary' => $summarypage,
1050                               'escape'  => $escape_function_nonbsp,
1051                               'extra_sections' => $extra_sections,
1052                               'format'  => $format,
1053                               %section_method
1054                             );
1055     foreach ( @$early ) {
1056       next if $_->{subtotal} == 0;
1057       $_->{subtotal} = $other_money_char.sprintf('%.2f', $_->{subtotal});
1058       push @summary_subtotals, $_;
1059     }
1060   } else {
1061     # subtotal sectioning is the same as for the actual invoice sections
1062     @summary_subtotals = @sections;
1063   }
1064
1065   # Hereafter, push sections to both @sections and @summary_subtotals
1066   # if they belong in both places (e.g. tax section).  Late sections are
1067   # never in @summary_subtotals.
1068
1069   # previous invoice balances in the Previous Charges section if there
1070   # is one, otherwise in the main detail section
1071   # (except if summary_only is enabled, don't show them at all)
1072   if ( $self->can('_items_previous') &&
1073        $self->enable_previous &&
1074        ! $conf->exists('previous_balance-summary_only') ) {
1075
1076     warn "$me adding previous balances\n"
1077       if $DEBUG > 1;
1078
1079     foreach my $line_item ( $self->_items_previous ) {
1080
1081       my $detail = {
1082         ref             => $line_item->{'pkgnum'},
1083         pkgpart         => $line_item->{'pkgpart'},
1084         #quantity        => 1, # not really correct
1085         section         => $previous_section, # which might be $default_section
1086         description     => &$escape_function($line_item->{'description'}),
1087         ext_description => [ map { &$escape_function($_) }
1088                              @{ $line_item->{'ext_description'} || [] }
1089                            ],
1090         amount          => $money_char . $line_item->{'amount'},
1091         product_code    => $line_item->{'pkgpart'} || 'N/A',
1092       };
1093
1094       push @detail_items, $detail;
1095       push @buf, [ $detail->{'description'},
1096                    $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1097                  ];
1098     }
1099
1100   }
1101
1102   if ( @pr_cust_bill && $self->enable_previous ) {
1103     push @buf, ['','-----------'];
1104     push @buf, [ $self->mt('Total Previous Balance'),
1105                  $money_char. sprintf("%10.2f", $pr_total) ];
1106     push @buf, ['',''];
1107   }
1108
1109   if ( $conf->exists('svc_phone-did-summary') && $self->can('_did_summary') ) {
1110       warn "$me adding DID summary\n"
1111         if $DEBUG > 1;
1112
1113       my ($didsummary,$minutes) = $self->_did_summary;
1114       my $didsummary_desc = 'DID Activity Summary (since last invoice)';
1115       push @detail_items,
1116        { 'description' => $didsummary_desc,
1117            'ext_description' => [ $didsummary, $minutes ],
1118        };
1119   }
1120
1121   foreach my $section (@sections, @$late_sections) {
1122
1123     # begin some normalization
1124     $section->{'subtotal'} = $section->{'amount'}
1125       if $multisection
1126          && !exists($section->{subtotal})
1127          && exists($section->{amount});
1128
1129     $invoice_data{finance_amount} = sprintf('%.2f', $section->{'subtotal'} )
1130       if ( $invoice_data{finance_section} &&
1131            $section->{'description'} eq $invoice_data{finance_section} );
1132
1133     $section->{'subtotal'} = $other_money_char.
1134                              sprintf('%.2f', $section->{'subtotal'})
1135       if $multisection;
1136
1137     # continue some normalization
1138     $section->{'amount'}   = $section->{'subtotal'}
1139       if $multisection;
1140
1141
1142     if ( $section->{'description'} ) {
1143       push @buf, ( [ &$escape_function($section->{'description'}), '' ],
1144                    [ '', '' ],
1145                  );
1146     }
1147
1148     warn "$me   setting options\n"
1149       if $DEBUG > 1;
1150
1151     my %options = ();
1152     $options{'section'} = $section if $multisection;
1153     $options{'format'} = $format;
1154     $options{'escape_function'} = $escape_function;
1155     $options{'no_usage'} = 1 unless $unsquelched;
1156     $options{'unsquelched'} = $unsquelched;
1157     $options{'summary_page'} = $summarypage;
1158     $options{'skip_usage'} =
1159       scalar(@$extra_sections) && !grep{$section == $_} @$extra_sections;
1160     $options{'preref_callback'} = $params{'preref_callback'};
1161
1162     warn "$me   searching for line items\n"
1163       if $DEBUG > 1;
1164
1165     foreach my $line_item ( $self->_items_pkg(%options),
1166                             $self->_items_fee(%options) ) {
1167
1168       warn "$me     adding line item ".
1169            join(', ', map "$_=>".$line_item->{$_}, keys %$line_item). "\n"
1170         if $DEBUG > 1;
1171
1172       push @buf, ( [ $line_item->{'description'},
1173                      $money_char. sprintf("%10.2f", $line_item->{'amount'}),
1174                    ],
1175                    map { [ " ". $_, '' ] } @{$line_item->{'ext_description'}},
1176                  );
1177
1178       $line_item->{'ref'} = $line_item->{'pkgnum'};
1179       $line_item->{'product_code'} = $line_item->{'pkgpart'} || 'N/A'; # mt()?
1180       $line_item->{'section'} = $section;
1181       $line_item->{'description'} = &$escape_function($line_item->{'description'});
1182       $line_item->{'amount'} = $money_char.$line_item->{'amount'};
1183
1184       if ( length($line_item->{'unit_amount'}) ) {
1185         $line_item->{'unit_amount'} = $money_char.$line_item->{'unit_amount'};
1186       }
1187       $line_item->{'ext_description'} ||= [];
1188
1189       push @detail_items, $line_item;
1190     }
1191
1192     if ( $section->{'description'} ) {
1193       push @buf, ( ['','-----------'],
1194                    [ $section->{'description'}. ' sub-total',
1195                       $section->{'subtotal'} # already formatted this
1196                    ],
1197                    [ '', '' ],
1198                    [ '', '' ],
1199                  );
1200     }
1201
1202   }
1203
1204   $invoice_data{current_less_finance} =
1205     sprintf('%.2f', $self->charged - $invoice_data{finance_amount} );
1206
1207   # if there's anything in the Previous Charges section, prepend it to the list
1208   if ( $pr_total and $previous_section ne $default_section ) {
1209     unshift @sections, $previous_section;
1210     # but not @summary_subtotals
1211   }
1212
1213   warn "$me adding taxes\n"
1214     if $DEBUG > 1;
1215
1216   # create a tax section if we don't yet have one
1217   my $tax_description = 'Taxes, Surcharges, and Fees';
1218   my $tax_section =
1219     List::Util::first { $_->{description} eq $tax_description } @sections;
1220   if (!$tax_section) {
1221     $tax_section = { 'description' => $tax_description };
1222     push @sections, $tax_section if $multisection;
1223   }
1224   $tax_section->{tax_section} = 1; # mark this section as containing taxes
1225   # if this is an existing tax section, we're merging the tax items into it.
1226   # grab the taxtotal that's already there, strip the money symbol if any
1227   my $taxtotal = $tax_section->{'subtotal'} || 0;
1228   $taxtotal =~ s/^\Q$other_money_char\E//;
1229
1230   # this does nothing
1231   #my $tax_weight = _pkg_category($tax_section->{description})
1232   #                      ? _pkg_category($tax_section->{description})->weight
1233   #                      : 0;
1234   #$tax_section->{'summarized'} = ''; #why? $summarypage && !$tax_weight ? 'Y' : '';
1235   #$tax_section->{'sort_weight'} = $tax_weight;
1236
1237   my @items_tax = $self->_items_tax;
1238   foreach my $tax ( @items_tax ) {
1239
1240     $taxtotal += $tax->{'amount'};
1241
1242     my $description = &$escape_function( $tax->{'description'} );
1243     my $amount      = sprintf( '%.2f', $tax->{'amount'} );
1244
1245     if ( $multisection ) {
1246
1247       push @detail_items, {
1248         ext_description => [],
1249         ref          => '',
1250         quantity     => '',
1251         description  => $description,
1252         amount       => $money_char. $amount,
1253         product_code => '',
1254         section      => $tax_section,
1255       };
1256
1257     } else {
1258
1259       push @total_items, {
1260         'total_item'   => $description,
1261         'total_amount' => $other_money_char. $amount,
1262       };
1263
1264     }
1265
1266     push @buf,[ $description,
1267                 $money_char. $amount,
1268               ];
1269
1270   }
1271
1272   if ( @items_tax ) {
1273     my $total = {};
1274     $total->{'total_item'} = $self->mt('Sub-total');
1275     $total->{'total_amount'} =
1276       $other_money_char. sprintf('%.2f', $self->charged - $taxtotal );
1277
1278     if ( $multisection ) {
1279       if ( $taxtotal > 0 ) {
1280         $tax_section->{'subtotal'} = $other_money_char.
1281                                      sprintf('%.2f', $taxtotal);
1282         $tax_section->{'pretotal'} = 'New charges sub-total '.
1283                                      $total->{'total_amount'};
1284         $tax_section->{'description'} = $self->mt($tax_description);
1285
1286         # append it if it's not already there
1287         if ( !grep $tax_section, @sections ) {
1288           push @sections, $tax_section;
1289           push @summary_subtotals, $tax_section;
1290         }
1291       }
1292
1293     } else {
1294       unshift @total_items, $total;
1295     }
1296   }
1297   $invoice_data{'taxtotal'} = sprintf('%.2f', $taxtotal);
1298
1299   ###
1300   # Totals
1301   ###
1302
1303   my %embolden_functions = (
1304     'latex'    => sub { return '\textbf{'. shift(). '}' },
1305     'html'     => sub { return '<b>'. shift(). '</b>' },
1306     'template' => sub { shift },
1307   );
1308   my $embolden_function = $embolden_functions{$format};
1309
1310   if ( $multisection ) {
1311
1312     if ( $adjust_section->{'sort_weight'} ) {
1313       $adjust_section->{'posttotal'} = $self->mt('Balance Forward').' '.
1314         $other_money_char.  sprintf("%.2f", ($self->billing_balance || 0) );
1315     } else{
1316       $adjust_section->{'pretotal'} = $self->mt('New charges total').' '.
1317         $other_money_char.  sprintf('%.2f', $self->charged );
1318     }
1319
1320   }
1321
1322   if ( $self->can('_items_total') ) { # should always be true now
1323
1324     # even for multisection, need plain text version
1325
1326     my @new_total_items = $self->_items_total;
1327
1328     push @buf,['','-----------'];
1329
1330     foreach ( @new_total_items ) {
1331       my ($item, $amount) = ($_->{'total_item'}, $_->{'total_amount'});
1332       $_->{'total_item'}   = &$embolden_function( $item );
1333       $_->{'total_amount'} = &$embolden_function( $other_money_char.$amount );
1334       # but if it's multisection, don't append to @total_items. the adjust
1335       # section has all this stuff
1336       push @total_items, $_ if !$multisection;
1337       push @buf, [ $item, $money_char.sprintf('%10.2f',$amount) ];
1338     }
1339
1340     push @buf, [ '', '' ];
1341
1342     # if we're showing previous invoices, also show previous
1343     # credits and payments
1344     if ( $self->enable_previous
1345           and $self->can('_items_credits')
1346           and $self->can('_items_payments') )
1347       {
1348
1349       # credits
1350       my $credittotal = 0;
1351       foreach my $credit (
1352         $self->_items_credits( 'template' => $template, 'trim_len' => 40 )
1353       ) {
1354
1355         my $total;
1356         $total->{'total_item'} = &$escape_function($credit->{'description'});
1357         $credittotal += $credit->{'amount'};
1358         $total->{'total_amount'} = $minus.$other_money_char.$credit->{'amount'};
1359         if ( $multisection ) {
1360           push @detail_items, {
1361             ext_description => [],
1362             ref          => '',
1363             quantity     => '',
1364             description  => &$escape_function($credit->{'description'}),
1365             amount       => $money_char . $credit->{'amount'},
1366             product_code => '',
1367             section      => $adjust_section,
1368           };
1369         } else {
1370           push @total_items, $total;
1371         }
1372
1373       }
1374       $invoice_data{'credittotal'} = sprintf('%.2f', $credittotal);
1375
1376       #credits (again)
1377       foreach my $credit (
1378         $self->_items_credits( 'template' => $template, 'trim_len'=>32 )
1379       ) {
1380         push @buf, [ $credit->{'description'}, $money_char.$credit->{'amount'} ];
1381       }
1382
1383       # payments
1384       my $paymenttotal = 0;
1385       foreach my $payment (
1386         $self->_items_payments( 'template' => $template )
1387       ) {
1388         my $total = {};
1389         $total->{'total_item'} = &$escape_function($payment->{'description'});
1390         $paymenttotal += $payment->{'amount'};
1391         $total->{'total_amount'} = $minus.$other_money_char.$payment->{'amount'};
1392         if ( $multisection ) {
1393           push @detail_items, {
1394             ext_description => [],
1395             ref          => '',
1396             quantity     => '',
1397             description  => &$escape_function($payment->{'description'}),
1398             amount       => $money_char . $payment->{'amount'},
1399             product_code => '',
1400             section      => $adjust_section,
1401           };
1402         }else{
1403           push @total_items, $total;
1404         }
1405         push @buf, [ $payment->{'description'},
1406                      $money_char. sprintf("%10.2f", $payment->{'amount'}),
1407                    ];
1408       }
1409       $invoice_data{'paymenttotal'} = sprintf('%.2f', $paymenttotal);
1410
1411       if ( $multisection ) {
1412         $adjust_section->{'subtotal'} = $other_money_char.
1413                                         sprintf('%.2f', $credittotal + $paymenttotal);
1414
1415         #why this? because {sort_weight} forces the adjust_section to appear
1416         #in @extra_sections instead of @sections. obviously.
1417         push @sections, $adjust_section
1418           unless $adjust_section->{sort_weight};
1419         # do not summarize; adjustments there are shown according to
1420         # different rules
1421       }
1422
1423       # create Balance Due message
1424       {
1425         my $total;
1426         $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1427         $total->{'total_amount'} =
1428           &$embolden_function(
1429             $other_money_char. sprintf('%.2f', #why? $summarypage
1430                                                #  ? $self->charged +
1431                                                #    $self->billing_balance
1432                                                #  :
1433                                                    $self->owed + $pr_total
1434                                       )
1435           );
1436         if ( $multisection && !$adjust_section->{sort_weight} ) {
1437           $adjust_section->{'posttotal'} = $total->{'total_item'}. ' '.
1438                                            $total->{'total_amount'};
1439         } else {
1440           push @total_items, $total;
1441         }
1442         push @buf,['','-----------'];
1443         push @buf,[$self->balance_due_msg, $money_char.
1444           sprintf("%10.2f", $balance_due ) ];
1445       }
1446
1447       if ( $conf->exists('previous_balance-show_credit')
1448           and $cust_main->balance < 0 ) {
1449         my $credit_total = {
1450           'total_item'    => &$embolden_function($self->credit_balance_msg),
1451           'total_amount'  => &$embolden_function(
1452             $other_money_char. sprintf('%.2f', -$cust_main->balance)
1453           ),
1454         };
1455         if ( $multisection ) {
1456           $adjust_section->{'posttotal'} .= $newline_token .
1457             $credit_total->{'total_item'} . ' ' . $credit_total->{'total_amount'};
1458         }
1459         else {
1460           push @total_items, $credit_total;
1461         }
1462         push @buf,['','-----------'];
1463         push @buf,[$self->credit_balance_msg, $money_char.
1464           sprintf("%10.2f", -$cust_main->balance ) ];
1465       }
1466     }
1467
1468   } #end of default total adding ! can('_items_total')
1469
1470   if ( $multisection ) {
1471     if (    $conf->exists('svc_phone_sections')
1472          && $self->can('_items_svc_phone_sections')
1473        )
1474     {
1475       my $total;
1476       $total->{'total_item'} = &$embolden_function($self->balance_due_msg);
1477       $total->{'total_amount'} =
1478         &$embolden_function(
1479           $other_money_char. sprintf('%.2f', $self->owed + $pr_total)
1480         );
1481       my $last_section = pop @sections;
1482       $last_section->{'posttotal'} = $total->{'total_item'}. ' '.
1483                                      $total->{'total_amount'};
1484       push @sections, $last_section;
1485     }
1486     push @sections, @$late_sections
1487       if $unsquelched;
1488   }
1489
1490   # make a discounts-available section, even without multisection
1491   if ( $conf->exists('discount-show_available')
1492        and my @discounts_avail = $self->_items_discounts_avail ) {
1493     my $discount_section = {
1494       'description' => $self->mt('Discounts Available'),
1495       'subtotal'    => '',
1496       'no_subtotal' => 1,
1497     };
1498
1499     push @sections, $discount_section; # do not summarize
1500     push @detail_items, map { +{
1501         'ref'         => '', #should this be something else?
1502         'section'     => $discount_section,
1503         'description' => &$escape_function( $_->{description} ),
1504         'amount'      => $money_char . &$escape_function( $_->{amount} ),
1505         'ext_description' => [ &$escape_function($_->{ext_description}) || () ],
1506     } } @discounts_avail;
1507   }
1508
1509   # not adding any more sections after this
1510   $invoice_data{summary_subtotals} = \@summary_subtotals;
1511
1512   # usage subtotals
1513   if ( $conf->exists('usage_class_summary')
1514        and $self->can('_items_usage_class_summary') ) {
1515     my @usage_subtotals = $self->_items_usage_class_summary(escape => $escape_function);
1516     if ( @usage_subtotals ) {
1517       unshift @sections, $usage_subtotals[0]->{section}; # do not summarize
1518       unshift @detail_items, @usage_subtotals;
1519     }
1520   }
1521
1522   # invoice history "section" (not really a section)
1523   # not to be included in any subtotals, completely independent of
1524   # everything...
1525   if ( $conf->exists('previous_invoice_history') and $cust_main->isa('FS::cust_main') ) {
1526     my %history;
1527     my %monthorder;
1528     foreach my $cust_bill ( $cust_main->cust_bill ) {
1529       # XXX hardcoded format, and currently only 'charged'; add other fields
1530       # if they become necessary
1531       my $date = $self->time2str_local('%b %Y', $cust_bill->_date);
1532       $history{$date} ||= 0;
1533       $history{$date} += $cust_bill->charged;
1534       # just so we have a numeric sort key
1535       $monthorder{$date} ||= $cust_bill->_date;
1536     }
1537     my @sorted_months = sort { $monthorder{$a} <=> $monthorder{$b} }
1538                         keys %history;
1539     my @sorted_amounts = map { sprintf('%.2f', $history{$_}) } @sorted_months;
1540     $invoice_data{monthly_history} = [ \@sorted_months, \@sorted_amounts ];
1541   }
1542
1543   # service locations: another option for template customization
1544   my %location_info;
1545   foreach my $item (@detail_items) {
1546     if ( $item->{locationnum} ) {
1547       $location_info{ $item->{locationnum} } ||= {
1548         FS::cust_location->by_key( $item->{locationnum} )->location_hash
1549       };
1550     }
1551   }
1552   $invoice_data{location_info} = \%location_info;
1553
1554   # debugging hook: call this with 'diag' => 1 to just get a hash of
1555   # the invoice variables
1556   return \%invoice_data if ( $params{'diag'} );
1557
1558   # All sections and items are built; now fill in templates.
1559   my @includelist = ();
1560   push @includelist, 'summary' if $summarypage;
1561   foreach my $include ( @includelist ) {
1562
1563     my $inc_file = $conf->key_orbase("invoice_${format}$include", $template);
1564     my @inc_src;
1565
1566     if ( length( $conf->config($inc_file, $agentnum) ) ) {
1567
1568       @inc_src = $conf->config($inc_file, $agentnum);
1569
1570     } else {
1571
1572       $inc_file = $conf->key_orbase("invoice_latex$include", $template);
1573
1574       my $convert_map = $convert_maps{$format}{$include};
1575
1576       @inc_src = map { s/\[\@--/$delimiters{$format}[0]/g;
1577                        s/--\@\]/$delimiters{$format}[1]/g;
1578                        $_;
1579                      }
1580                  &$convert_map( $conf->config($inc_file, $agentnum) );
1581
1582     }
1583
1584     my $inc_tt = new Text::Template (
1585       TYPE       => 'ARRAY',
1586       SOURCE     => [ map "$_\n", @inc_src ],
1587       DELIMITERS => $delimiters{$format},
1588     ) or die "Can't create new Text::Template object: $Text::Template::ERROR";
1589
1590     unless ( $inc_tt->compile() ) {
1591       my $error = "Can't compile $inc_file template: $Text::Template::ERROR\n";
1592       warn $error. "Template:\n". join('', map "$_\n", @inc_src);
1593       die $error;
1594     }
1595
1596     $invoice_data{$include} = $inc_tt->fill_in( HASH => \%invoice_data );
1597
1598     $invoice_data{$include} =~ s/\n+$//
1599       if ($format eq 'latex');
1600   }
1601
1602   $invoice_lines = 0;
1603   my $wasfunc = 0;
1604   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
1605     /invoice_lines\((\d*)\)/;
1606     $invoice_lines += $1 || scalar(@buf);
1607     $wasfunc=1;
1608   }
1609   die "no invoice_lines() functions in template?"
1610     if ( $format eq 'template' && !$wasfunc );
1611
1612   if ($format eq 'template') {
1613
1614     if ( $invoice_lines ) {
1615       $invoice_data{'total_pages'} = int( scalar(@buf) / $invoice_lines );
1616       $invoice_data{'total_pages'}++
1617         if scalar(@buf) % $invoice_lines;
1618     }
1619
1620     #setup subroutine for the template
1621     $invoice_data{invoice_lines} = sub {
1622       my $lines = shift || scalar(@buf);
1623       map {
1624         scalar(@buf)
1625           ? shift @buf
1626           : [ '', '' ];
1627       }
1628       ( 1 .. $lines );
1629     };
1630
1631     my $lines;
1632     my @collect;
1633     while (@buf) {
1634       push @collect, split("\n",
1635         $text_template->fill_in( HASH => \%invoice_data )
1636       );
1637       $invoice_data{'page'}++;
1638     }
1639     map "$_\n", @collect;
1640
1641   } else { # this is where we actually create the invoice
1642
1643     warn "filling in template for invoice ". $self->invnum. "\n"
1644       if $DEBUG;
1645     warn join("\n", map " $_ => ". $invoice_data{$_}, keys %invoice_data). "\n"
1646       if $DEBUG > 1;
1647
1648     $text_template->fill_in(HASH => \%invoice_data);
1649   }
1650 }
1651
1652 sub notice_name { '('.shift->table.')'; }
1653
1654 sub template_conf { 'invoice_'; }
1655
1656 # helper routine for generating date ranges
1657 sub _prior_month30s {
1658   my $self = shift;
1659   my @ranges = (
1660    [ 1,       2592000 ], # 0-30 days ago
1661    [ 2592000, 5184000 ], # 30-60 days ago
1662    [ 5184000, 7776000 ], # 60-90 days ago
1663    [ 7776000, 0       ], # 90+   days ago
1664   );
1665
1666   map { [ $_->[0] ? $self->_date - $_->[0] - 1 : '',
1667           $_->[1] ? $self->_date - $_->[1] - 1 : '',
1668       ] }
1669   @ranges;
1670 }
1671
1672 =item print_ps HASHREF | [ TIME [ , TEMPLATE ] ]
1673
1674 Returns an postscript invoice, as a scalar.
1675
1676 Options can be passed as a hashref (recommended) or as a list of time, template
1677 and then any key/value pairs for any other options.
1678
1679 I<time> an optional value used to control the printing of overdue messages.  The
1680 default is now.  It isn't the date of the invoice; that's the `_date' field.
1681 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1682 L<Time::Local> and L<Date::Parse> for conversion functions.
1683
1684 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1685
1686 =cut
1687
1688 sub print_ps {
1689   my $self = shift;
1690
1691   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1692   my $ps = generate_ps($file);
1693   unlink($logofile);
1694   unlink($barcodefile) if $barcodefile;
1695
1696   $ps;
1697 }
1698
1699 =item print_pdf HASHREF | [ TIME [ , TEMPLATE ] ]
1700
1701 Returns an PDF invoice, as a scalar.
1702
1703 Options can be passed as a hashref (recommended) or as a list of time, template
1704 and then any key/value pairs for any other options.
1705
1706 I<time> an optional value used to control the printing of overdue messages.  The
1707 default is now.  It isn't the date of the invoice; that's the `_date' field.
1708 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1709 L<Time::Local> and L<Date::Parse> for conversion functions.
1710
1711 I<template>, if specified, is the name of a suffix for alternate invoices.
1712
1713 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1714
1715 =cut
1716
1717 sub print_pdf {
1718   my $self = shift;
1719
1720   my ($file, $logofile, $barcodefile) = $self->print_latex(@_);
1721   my $pdf = generate_pdf($file);
1722   unlink($logofile);
1723   unlink($barcodefile) if $barcodefile;
1724
1725   $pdf;
1726 }
1727
1728 =item print_html HASHREF | [ TIME [ , TEMPLATE [ , CID ] ] ]
1729
1730 Returns an HTML invoice, as a scalar.
1731
1732 I<time> an optional value used to control the printing of overdue messages.  The
1733 default is now.  It isn't the date of the invoice; that's the `_date' field.
1734 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
1735 L<Time::Local> and L<Date::Parse> for conversion functions.
1736
1737 I<template>, if specified, is the name of a suffix for alternate invoices.
1738
1739 I<notice_name>, if specified, overrides "Invoice" as the name of the sent document (templates from 10/2009 or newer required)
1740
1741 I<cid> is a MIME Content-ID used to create a "cid:" URL for the logo image, used
1742 when emailing the invoice as part of a multipart/related MIME email.
1743
1744 =cut
1745
1746 sub print_html {
1747   my $self = shift;
1748   my %params;
1749   if ( ref($_[0]) ) {
1750     %params = %{ shift() };
1751   } else {
1752     %params = @_;
1753   }
1754   $params{'format'} = 'html';
1755
1756   $self->print_generic( %params );
1757 }
1758
1759 # quick subroutine for print_latex
1760 #
1761 # There are ten characters that LaTeX treats as special characters, which
1762 # means that they do not simply typeset themselves:
1763 #      # $ % & ~ _ ^ \ { }
1764 #
1765 # TeX ignores blanks following an escaped character; if you want a blank (as
1766 # in "10% of ..."), you have to "escape" the blank as well ("10\%\ of ...").
1767
1768 sub _latex_escape {
1769   my $value = shift;
1770   $value =~ s/([#\$%&~_\^{}])( )?/"\\$1". ( ( defined($2) && length($2) ) ? "\\$2" : '' )/ge;
1771   $value =~ s/([<>])/\$$1\$/g;
1772   $value;
1773 }
1774
1775 sub _html_escape {
1776   my $value = shift;
1777   encode_entities($value);
1778   $value;
1779 }
1780
1781 sub _html_escape_nbsp {
1782   my $value = _html_escape(shift);
1783   $value =~ s/ +/&nbsp;/g;
1784   $value;
1785 }
1786
1787 #utility methods for print_*
1788
1789 sub _translate_old_latex_format {
1790   warn "_translate_old_latex_format called\n"
1791     if $DEBUG;
1792
1793   my @template = ();
1794   while ( @_ ) {
1795     my $line = shift;
1796
1797     if ( $line =~ /^%%Detail\s*$/ ) {
1798
1799       push @template, q![@--!,
1800                       q!  foreach my $_tr_line (@detail_items) {!,
1801                       q!    if ( scalar ($_tr_item->{'ext_description'} ) ) {!,
1802                       q!      $_tr_line->{'description'} .= !,
1803                       q!        "\\tabularnewline\n~~".!,
1804                       q!        join( "\\tabularnewline\n~~",!,
1805                       q!          @{$_tr_line->{'ext_description'}}!,
1806                       q!        );!,
1807                       q!    }!;
1808
1809       while ( ( my $line_item_line = shift )
1810               !~ /^%%EndDetail\s*$/                            ) {
1811         $line_item_line =~ s/'/\\'/g;    # nice LTS
1812         $line_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1813         $line_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1814         push @template, "    \$OUT .= '$line_item_line';";
1815       }
1816
1817       push @template, '}',
1818                       '--@]';
1819       #' doh, gvim
1820     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
1821
1822       push @template, '[@--',
1823                       '  foreach my $_tr_line (@total_items) {';
1824
1825       while ( ( my $total_item_line = shift )
1826               !~ /^%%EndTotalDetails\s*$/                      ) {
1827         $total_item_line =~ s/'/\\'/g;    # nice LTS
1828         $total_item_line =~ s/\\/\\\\/g;  # escape quotes and backslashes
1829         $total_item_line =~ s/\$(\w+)/'. \$_tr_line->{$1}. '/g;
1830         push @template, "    \$OUT .= '$total_item_line';";
1831       }
1832
1833       push @template, '}',
1834                       '--@]';
1835
1836     } else {
1837       $line =~ s/\$(\w+)/[\@-- \$$1 --\@]/g;
1838       push @template, $line;
1839     }
1840
1841   }
1842
1843   if ($DEBUG) {
1844     warn "$_\n" foreach @template;
1845   }
1846
1847   (@template);
1848 }
1849
1850 =item terms
1851
1852 =cut
1853
1854 sub terms {
1855   my $self = shift;
1856   my $conf = $self->conf;
1857
1858   #check for an invoice-specific override
1859   return $self->invoice_terms if $self->invoice_terms;
1860
1861   #check for a customer- specific override
1862   my $cust_main = $self->cust_main;
1863   return $cust_main->invoice_terms if $cust_main && $cust_main->invoice_terms;
1864
1865   my $agentnum = '';
1866   if ( $cust_main ) {
1867     $agentnum = $cust_main->agentnum;
1868   } elsif ( my $prospect_main = $self->prospect_main ) {
1869     $agentnum = $prospect_main->agentnum;
1870   }
1871
1872   #use configured default
1873   $conf->config('invoice_default_terms', $agentnum) || '';
1874 }
1875
1876 =item due_date
1877
1878 =cut
1879
1880 sub due_date {
1881   my $self = shift;
1882   my $duedate = '';
1883   if ( $self->terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1884     $duedate = $self->_date() + ( $1 * 86400 );
1885   }
1886   $duedate;
1887 }
1888
1889 =item due_date2str
1890
1891 =cut
1892
1893 sub due_date2str {
1894   my $self = shift;
1895   $self->due_date ? $self->time2str_local(shift, $self->due_date) : '';
1896 }
1897
1898 =item balance_due_msg
1899
1900 =cut
1901
1902 sub balance_due_msg {
1903   my $self = shift;
1904   my $msg = $self->mt('Balance Due');
1905   return $msg unless $self->terms; # huh?
1906   if ( !$self->conf->exists('invoice_show_prior_due_date')
1907        or $self->conf->exists('invoice_sections') ) {
1908     # if enabled, the due date is shown with Total New Charges (see
1909     # _items_total) and not here
1910     # (yes, or if invoice_sections is enabled; this is just for compatibility)
1911     if ( $self->due_date ) {
1912       $msg .= ' - ' . $self->mt('Please pay by'). ' '.
1913         $self->due_date2str('short');
1914     } elsif ( $self->terms ) {
1915       $msg .= ' - '. $self->mt($self->terms);
1916     }
1917   }
1918   $msg;
1919 }
1920
1921 =item balance_due_date
1922
1923 =cut
1924
1925 sub balance_due_date {
1926   my $self = shift;
1927   my $conf = $self->conf;
1928   my $duedate = '';
1929   my $terms = $self->terms;
1930   if ( $terms =~ /^\s*Net\s*(\d+)\s*$/ ) {
1931     $duedate = $self->time2str_local('rdate', $self->_date + ($1*86400) );
1932   }
1933   $duedate;
1934 }
1935
1936 sub credit_balance_msg {
1937   my $self = shift;
1938   $self->mt('Credit Balance Remaining')
1939 }
1940
1941 =item _date_pretty
1942
1943 Returns a string with the date, for example: "3/20/2008", localized for the
1944 customer.  Use _date_pretty_unlocalized for non-end-customer display use.
1945
1946 =cut
1947
1948 sub _date_pretty {
1949   my $self = shift;
1950   $self->time2str_local('short', $self->_date);
1951 }
1952
1953 =item _date_pretty_unlocalized
1954
1955 Returns a string with the date, for example: "3/20/2008", in the format
1956 configured for the back-office.  Use _date_pretty for end-customer display use.
1957
1958 =cut
1959
1960 sub _date_pretty_unlocalized {
1961   my $self = shift;
1962   time2str($date_format, $self->_date);
1963 }
1964
1965 =item email HASHREF
1966
1967 Emails this template.
1968
1969 Options are passed as a hashref.  Available options:
1970
1971 =over 4
1972
1973 =item from
1974
1975 If specified, overrides the default From: address.
1976
1977 =item notice_name
1978
1979 If specified, overrides the name of the sent document ("Invoice" or "Quotation")
1980
1981 =item template
1982
1983 (Deprecated) If specified, is the name of a suffix for alternate template files.
1984
1985 =back
1986
1987 Options accepted by generate_email can also be used.
1988
1989 =cut
1990
1991 sub email {
1992   my $self = shift;
1993   my $opt = shift || {};
1994   if ($opt and !ref($opt)) {
1995     die ref($self). '->email called with positional parameters';
1996   }
1997
1998   return if $self->hide;
1999
2000   my $error = send_email(
2001     $self->generate_email(
2002       'subject'     => $self->email_subject($opt->{template}),
2003       %$opt, # template, etc.
2004     )
2005   );
2006
2007   die "can't email: $error\n" if $error;
2008 }
2009
2010 =item generate_email OPTION => VALUE ...
2011
2012 Options:
2013
2014 =over 4
2015
2016 =item from
2017
2018 sender address, required
2019
2020 =item template
2021
2022 alternate template name, optional
2023
2024 =item subject
2025
2026 email subject, optional
2027
2028 =item notice_name
2029
2030 notice name instead of "Invoice", optional
2031
2032 =back
2033
2034 Returns an argument list to be passed to L<FS::Misc::send_email>.
2035
2036 =cut
2037
2038 use MIME::Entity;
2039
2040 sub generate_email {
2041
2042   my $self = shift;
2043   my %args = @_;
2044   my $conf = $self->conf;
2045
2046   my $me = '[FS::Template_Mixin::generate_email]';
2047
2048   my %return = (
2049     'from'      => $args{'from'},
2050     'subject'   => ($args{'subject'} || $self->email_subject),
2051     'custnum'   => $self->custnum,
2052     'msgtype'   => 'invoice',
2053   );
2054
2055   $args{'unsquelch_cdr'} = $conf->exists('voip-cdr_email');
2056
2057   my $cust_main = $self->cust_main;
2058
2059   if (ref($args{'to'}) eq 'ARRAY') {
2060     $return{'to'} = $args{'to'};
2061   } elsif ( $cust_main ) {
2062     $return{'to'} = [ $cust_main->invoicing_list_emailonly ];
2063   }
2064
2065   my $tc = $self->template_conf;
2066
2067   my @text; # array of lines
2068   my $html; # a big string
2069   my @related_parts; # will contain the text/HTML alternative, and images
2070   my $related; # will contain the multipart/related object
2071
2072   if ( $conf->exists($tc. 'email_pdf') ) {
2073     if ( my $msgnum = $conf->config($tc.'email_pdf_msgnum') ) {
2074
2075       warn "$me using '${tc}email_pdf_msgnum' in multipart message"
2076         if $DEBUG;
2077
2078       my $msg_template = FS::msg_template->by_key($msgnum)
2079         or die "${tc}email_pdf_msgnum $msgnum not found\n";
2080       my %prepared = $msg_template->prepare(
2081         cust_main => $self->cust_main,
2082         object    => $self
2083       );
2084
2085       @text = split(/(?=\n)/, $prepared{'text_body'});
2086       $html = $prepared{'html_body'};
2087
2088     } elsif ( my @note = $conf->config($tc.'email_pdf_note') ) {
2089
2090       warn "$me using '${tc}email_pdf_note' in multipart message"
2091         if $DEBUG;
2092       @text = $conf->config($tc.'email_pdf_note');
2093       $html = join('<BR>', @text);
2094
2095     } # else use the plain text invoice
2096   }
2097
2098   if (!@text) {
2099
2100     if ( $conf->config($tc.'template') ) {
2101
2102       warn "$me generating plain text invoice"
2103         if $DEBUG;
2104
2105       # 'print_text' argument is no longer used
2106       @text = $self->print_text(\%args);
2107
2108     } else {
2109
2110       warn "$me no plain text version exists; sending empty message body"
2111         if $DEBUG;
2112
2113     }
2114
2115   }
2116
2117   my $text_part = build MIME::Entity (
2118     'Type'        => 'text/plain',
2119     'Encoding'    => 'quoted-printable',
2120     'Charset'     => 'UTF-8',
2121     #'Encoding'    => '7bit',
2122     'Data'        => \@text,
2123     'Disposition' => 'inline',
2124   );
2125
2126   if (!$html) {
2127
2128     if ( $conf->exists($tc.'html') ) {
2129       warn "$me generating HTML invoice"
2130         if $DEBUG;
2131
2132       $args{'from'} =~ /\@([\w\.\-]+)/;
2133       my $from = $1 || 'example.com';
2134       my $content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2135
2136       my $logo;
2137       my $agentnum = $cust_main ? $cust_main->agentnum
2138                                 : $self->prospect_main->agentnum;
2139       if ( defined($args{'template'}) && length($args{'template'})
2140            && $conf->exists( 'logo_'. $args{'template'}. '.png', $agentnum )
2141          )
2142       {
2143         $logo = 'logo_'. $args{'template'}. '.png';
2144       } else {
2145         $logo = "logo.png";
2146       }
2147       my $image_data = $conf->config_binary( $logo, $agentnum);
2148
2149       push @related_parts, build MIME::Entity
2150         'Type'       => 'image/png',
2151         'Encoding'   => 'base64',
2152         'Data'       => $image_data,
2153         'Filename'   => 'logo.png',
2154         'Content-ID' => "<$content_id>",
2155       ;
2156
2157       if ( ref($self) eq 'FS::cust_bill' && $conf->exists('invoice-barcode') ) {
2158         my $barcode_content_id = join('.', rand()*(2**32), $$, time). "\@$from";
2159         push @related_parts, build MIME::Entity
2160           'Type'       => 'image/png',
2161           'Encoding'   => 'base64',
2162           'Data'       => $self->invoice_barcode(0),
2163           'Filename'   => 'barcode.png',
2164           'Content-ID' => "<$barcode_content_id>",
2165         ;
2166         $args{'barcode_cid'} = $barcode_content_id;
2167       }
2168
2169       $html = $self->print_html({ 'cid'=>$content_id, %args });
2170     }
2171
2172   }
2173
2174   if ( $html ) {
2175
2176     warn "$me creating HTML/text multipart message"
2177       if $DEBUG;
2178
2179     $return{'nobody'} = 1;
2180
2181     my $alternative = build MIME::Entity
2182       'Type'        => 'multipart/alternative',
2183       #'Encoding'    => '7bit',
2184       'Disposition' => 'inline'
2185     ;
2186
2187     if ( @text ) {
2188       $alternative->add_part($text_part);
2189     }
2190
2191     $alternative->attach(
2192       'Type'        => 'text/html',
2193       'Encoding'    => 'quoted-printable',
2194       'Data'        => [ '<html>',
2195                          '  <head>',
2196                          '    <title>',
2197                          '      '. encode_entities($return{'subject'}),
2198                          '    </title>',
2199                          '  </head>',
2200                          '  <body bgcolor="#e8e8e8">',
2201                          $html,
2202                          '  </body>',
2203                          '</html>',
2204                        ],
2205       'Disposition' => 'inline',
2206       #'Filename'    => 'invoice.pdf',
2207     );
2208
2209     unshift @related_parts, $alternative;
2210
2211     $related = build MIME::Entity 'Type'     => 'multipart/related',
2212                                   'Encoding' => '7bit';
2213
2214     #false laziness w/Misc::send_email
2215     $related->head->replace('Content-type',
2216       $related->mime_type.
2217       '; boundary="'. $related->head->multipart_boundary. '"'.
2218       '; type=multipart/alternative'
2219     );
2220
2221     $related->add_part($_) foreach @related_parts;
2222
2223   }
2224
2225   my @otherparts = ();
2226   if ( ref($self) eq 'FS::cust_bill' && $cust_main->email_csv_cdr ) {
2227
2228     push @otherparts, build MIME::Entity
2229       'Type'        => 'text/csv',
2230       'Encoding'    => '7bit',
2231       'Data'        => [ map { "$_\n" }
2232                            $self->call_details('prepend_billed_number' => 1)
2233                        ],
2234       'Disposition' => 'attachment',
2235       'Filename'    => 'usage-'. $self->invnum. '.csv',
2236     ;
2237
2238   }
2239
2240   if ( $conf->exists($tc.'email_pdf') ) {
2241
2242     #attaching pdf too:
2243     # multipart/mixed
2244     #   multipart/related
2245     #     multipart/alternative
2246     #       text/plain
2247     #       text/html
2248     #     image/png
2249     #   application/pdf
2250
2251     my $pdf = build MIME::Entity $self->mimebuild_pdf(\%args);
2252     push @otherparts, $pdf;
2253   }
2254
2255   if (@otherparts) {
2256     $return{'content-type'} = 'multipart/mixed'; # of the outer container
2257     if ( $html ) {
2258       $return{'mimeparts'} = [ $related, @otherparts ];
2259       $return{'type'} = 'multipart/related'; # of the first part
2260     } else {
2261       $return{'mimeparts'} = [ $text_part, @otherparts ];
2262       $return{'type'} = 'text/plain';
2263     }
2264   } elsif ( $html ) { # no PDF or CSV, strip the outer container
2265     $return{'mimeparts'} = \@related_parts;
2266     $return{'content-type'} = 'multipart/related';
2267     $return{'type'} = 'multipart/alternative';
2268   } else { # no HTML either
2269     $return{'body'} = \@text;
2270     $return{'content-type'} = 'text/plain';
2271   }
2272
2273   %return;
2274
2275 }
2276
2277 =item mimebuild_pdf
2278
2279 Returns a list suitable for passing to MIME::Entity->build(), representing
2280 this invoice as PDF attachment.
2281
2282 =cut
2283
2284 sub mimebuild_pdf {
2285   my $self = shift;
2286   (
2287     'Type'        => 'application/pdf',
2288     'Encoding'    => 'base64',
2289     'Data'        => [ $self->print_pdf(@_) ],
2290     'Disposition' => 'attachment',
2291     'Filename'    => 'invoice-'. $self->invnum. '.pdf',
2292   );
2293 }
2294
2295 =item _items_sections OPTIONS
2296
2297 Generate section information for all items appearing on this invoice.
2298 This will only be called for multi-section invoices.
2299
2300 For each line item (L<FS::cust_bill_pkg> record), this will fetch all
2301 related display records (L<FS::cust_bill_pkg_display>) and organize
2302 them into two groups ("early" and "late" according to whether they come
2303 before or after the total), then into sections.  A subtotal is calculated
2304 for each section.
2305
2306 Section descriptions are returned in sort weight order.  Each consists
2307 of a hash containing:
2308
2309 description: the package category name, escaped
2310 subtotal: the total charges in that section
2311 tax_section: a flag indicating that the section contains only tax charges
2312 summarized: same as tax_section, for some reason
2313 sort_weight: the package category's sort weight
2314
2315 If 'condense' is set on the display record, it also contains everything
2316 returned from C<_condense_section()>, i.e. C<_condensed_foo_generator>
2317 coderefs to generate parts of the invoice.  This is not advised.
2318
2319 The method returns two arrayrefs, one of "early" sections and one of "late"
2320 sections.
2321
2322 OPTIONS may include:
2323
2324 by_location: a flag to divide the invoice into sections by location.
2325 Each section hash will have a 'location' element containing a hashref of
2326 the location fields (see L<FS::cust_location>).  The section description
2327 will be the location label, but the template can use any of the location
2328 fields to create a suitable label.
2329
2330 by_category: a flag to divide the invoice into sections using display
2331 records (see L<FS::cust_bill_pkg_display>).  This is the "traditional"
2332 behavior.  Each section hash will have a 'category' element containing
2333 the section name from the display record (which probably equals the
2334 category name of the package, but may not in some cases).
2335
2336 summary: a flag indicating that this is a summary-format invoice.
2337 Turning this on has the following effects:
2338 - Ignores display items with the 'summary' flag.
2339 - Places all sections in the "early" group even if they have post_total.
2340 - Creates sections for all non-disabled package categories, even if they
2341 have no charges on this invoice, as well as a section with no name.
2342
2343 escape: an escape function to use for section titles.
2344
2345 extra_sections: an arrayref of additional sections to return after the
2346 sorted list.  If there are any of these, section subtotals exclude
2347 usage charges.
2348
2349 format: 'latex', 'html', or 'template' (i.e. text).  Not used, but
2350 passed through to C<_condense_section()>.
2351
2352 =cut
2353
2354 use vars qw(%pkg_category_cache);
2355 sub _items_sections {
2356   my $self = shift;
2357   my %opt = @_;
2358
2359   my $escape = $opt{escape};
2360   my @extra_sections = @{ $opt{extra_sections} || [] };
2361
2362   # $subtotal{$locationnum}{$categoryname} = amount.
2363   # if we're not using by_location, $locationnum is undef.
2364   # if we're not using by_category, you guessed it, $categoryname is undef.
2365   # if we're not using either one, we shouldn't be here in the first place...
2366   my %subtotal = ();
2367   my %late_subtotal = ();
2368   my %not_tax = ();
2369
2370   # About tax items + multisection invoices:
2371   # If either invoice_*summary option is enabled, AND there is a
2372   # package category with the name of the tax, then there will be
2373   # a display record assigning the tax item to that category.
2374   #
2375   # However, the taxes are always placed in the "Taxes, Surcharges,
2376   # and Fees" section regardless of that.  The only effect of the
2377   # display record is to create a subtotal for the summary page.
2378
2379   # cache these
2380   my $pkg_hash = $self->cust_pkg_hash;
2381
2382   foreach my $cust_bill_pkg ( $self->cust_bill_pkg )
2383   {
2384
2385       my $usage = $cust_bill_pkg->usage;
2386
2387       my $locationnum;
2388       if ( $opt{by_location} ) {
2389         if ( $cust_bill_pkg->pkgnum ) {
2390           $locationnum = $pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum;
2391         } else {
2392           $locationnum = '';
2393         }
2394       } else {
2395         $locationnum = undef;
2396       }
2397
2398       # as in _items_cust_pkg, if a line item has no display records,
2399       # cust_bill_pkg_display() returns a default record for it
2400
2401       foreach my $display ($cust_bill_pkg->cust_bill_pkg_display) {
2402         next if ( $display->summary && $opt{summary} );
2403
2404         my $section = $display->section;
2405         my $type    = $display->type;
2406         # Set $section = undef if we're sectioning by location and this
2407         # line item _has_ a location (i.e. isn't a fee).
2408         $section = undef if $locationnum;
2409
2410         # set this flag if the section is not tax-only
2411         $not_tax{$locationnum}{$section} = 1
2412           if $cust_bill_pkg->pkgnum  or $cust_bill_pkg->feepart;
2413
2414         # there's actually a very important piece of logic buried in here:
2415         # incrementing $late_subtotal{$section} CREATES
2416         # $late_subtotal{$section}.  keys(%late_subtotal) is later used
2417         # to define the list of late sections, and likewise keys(%subtotal).
2418         # When _items_cust_bill_pkg is called to generate line items for
2419         # real, it will be called with 'section' => $section for each
2420         # of these.
2421         if ( $display->post_total && !$opt{summary} ) {
2422           if (! $type || $type eq 'S') {
2423             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2424               if $cust_bill_pkg->setup != 0
2425               || $cust_bill_pkg->setup_show_zero;
2426           }
2427
2428           if (! $type) {
2429             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur
2430               if $cust_bill_pkg->recur != 0
2431               || $cust_bill_pkg->recur_show_zero;
2432           }
2433
2434           if ($type && $type eq 'R') {
2435             $late_subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2436               if $cust_bill_pkg->recur != 0
2437               || $cust_bill_pkg->recur_show_zero;
2438           }
2439
2440           if ($type && $type eq 'U') {
2441             $late_subtotal{$locationnum}{$section} += $usage
2442               unless scalar(@extra_sections);
2443           }
2444
2445         } else { # it's a pre-total (normal) section
2446
2447           # skip tax items unless they're explicitly included in a section
2448           next if $cust_bill_pkg->pkgnum == 0 and
2449                   ! $cust_bill_pkg->feepart   and
2450                   ! $section;
2451
2452           if ( $type eq 'S' ) {
2453             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2454               if $cust_bill_pkg->setup != 0
2455               || $cust_bill_pkg->setup_show_zero;
2456           } elsif ( $type eq 'R' ) {
2457             $subtotal{$locationnum}{$section} += $cust_bill_pkg->recur - $usage
2458               if $cust_bill_pkg->recur != 0
2459               || $cust_bill_pkg->recur_show_zero;
2460           } elsif ( $type eq 'U' ) {
2461             $subtotal{$locationnum}{$section} += $usage
2462               unless scalar(@extra_sections);
2463           } elsif ( !$type ) {
2464             $subtotal{$locationnum}{$section} += $cust_bill_pkg->setup
2465                                                + $cust_bill_pkg->recur;
2466           }
2467
2468         }
2469
2470       }
2471
2472   }
2473
2474   %pkg_category_cache = ();
2475
2476   # summary invoices need subtotals for all non-disabled package categories,
2477   # even if they're zero
2478   # but currently assume that there are no location sections, or at least
2479   # that the summary page doesn't care about them
2480   if ( $opt{summary} ) {
2481     foreach my $category (qsearch('pkg_category', {disabled => ''})) {
2482       $subtotal{''}{$category->categoryname} ||= 0;
2483     }
2484     $subtotal{''}{''} ||= 0;
2485   }
2486
2487   my @sections;
2488   foreach my $post_total (0,1) {
2489     my @these;
2490     my $s = $post_total ? \%late_subtotal : \%subtotal;
2491     foreach my $locationnum (keys %$s) {
2492       foreach my $sectionname (keys %{ $s->{$locationnum} }) {
2493         my $section = {
2494                         'subtotal'    => $s->{$locationnum}{$sectionname},
2495                         'post_total'  => $post_total,
2496                         'sort_weight' => 0,
2497                       };
2498         if ( $locationnum ) {
2499           $section->{'locationnum'} = $locationnum;
2500           my $location = FS::cust_location->by_key($locationnum);
2501           $section->{'description'} = &{ $escape }($location->location_label);
2502           # Better ideas? This will roughly group them by proximity,
2503           # which alpha sorting on any of the address fields won't.
2504           # Sorting by locationnum is meaningless.
2505           # We have to sort on _something_ or the order may change
2506           # randomly from one invoice to the next, which will confuse
2507           # people.
2508           $section->{'sort_weight'} = sprintf('%012s',$location->zip) .
2509                                       $locationnum;
2510           $section->{'location'} = {
2511             label_prefix => &{ $escape }($location->label_prefix),
2512             map { $_ => &{ $escape }($location->get($_)) }
2513               $location->fields
2514           };
2515         } else {
2516           $section->{'category'} = $sectionname;
2517           $section->{'description'} = &{ $escape }($sectionname);
2518           if ( _pkg_category($sectionname) ) {
2519             $section->{'sort_weight'} = _pkg_category($sectionname)->weight;
2520             if ( _pkg_category($sectionname)->condense ) {
2521               $section = { %$section, $self->_condense_section($opt{format}) };
2522             }
2523           }
2524         }
2525         if ( !$post_total and !$not_tax{$locationnum}{$sectionname} ) {
2526           # then it's a tax-only section
2527           $section->{'summarized'} = 'Y';
2528           $section->{'tax_section'} = 'Y';
2529         }
2530         push @these, $section;
2531       } # foreach $sectionname
2532     } #foreach $locationnum
2533     push @these, @extra_sections if $post_total == 0;
2534     # need an alpha sort for location sections, because postal codes can
2535     # be non-numeric
2536     $sections[ $post_total ] = [ sort {
2537       $opt{'by_location'} ?
2538         ($a->{sort_weight} cmp $b->{sort_weight}) :
2539         ($a->{sort_weight} <=> $b->{sort_weight})
2540       } @these ];
2541   } #foreach $post_total
2542
2543   return @sections; # early, late
2544 }
2545
2546 #helper subs for above
2547
2548 sub cust_pkg_hash {
2549   my $self = shift;
2550   $self->{cust_pkg} ||= { map { $_->pkgnum => $_ } $self->cust_pkg };
2551 }
2552
2553 sub _pkg_category {
2554   my $categoryname = shift;
2555   $pkg_category_cache{$categoryname} ||=
2556     qsearchs( 'pkg_category', { 'categoryname' => $categoryname } );
2557 }
2558
2559 my %condensed_format = (
2560   'label' => [ qw( Description Qty Amount ) ],
2561   'fields' => [
2562                 sub { shift->{description} },
2563                 sub { shift->{quantity} },
2564                 sub { my($href, %opt) = @_;
2565                       ($opt{dollar} || ''). $href->{amount};
2566                     },
2567               ],
2568   'align'  => [ qw( l r r ) ],
2569   'span'   => [ qw( 5 1 1 ) ],            # unitprices?
2570   'width'  => [ qw( 10.7cm 1.4cm 1.6cm ) ],   # don't like this
2571 );
2572
2573 sub _condense_section {
2574   my ( $self, $format ) = ( shift, shift );
2575   ( 'condensed' => 1,
2576     map { my $method = "_condensed_$_"; $_ => $self->$method($format) }
2577       qw( description_generator
2578           header_generator
2579           total_generator
2580           total_line_generator
2581         )
2582   );
2583 }
2584
2585 sub _condensed_generator_defaults {
2586   my ( $self, $format ) = ( shift, shift );
2587   return ( \%condensed_format, ' ', ' ', ' ', sub { shift } );
2588 }
2589
2590 my %html_align = (
2591   'c' => 'center',
2592   'l' => 'left',
2593   'r' => 'right',
2594 );
2595
2596 sub _condensed_header_generator {
2597   my ( $self, $format ) = ( shift, shift );
2598
2599   my ( $f, $prefix, $suffix, $separator, $column ) =
2600     _condensed_generator_defaults($format);
2601
2602   if ($format eq 'latex') {
2603     $prefix = "\\hline\n\\rule{0pt}{2.5ex}\n\\makebox[1.4cm]{}&\n";
2604     $suffix = "\\\\\n\\hline";
2605     $separator = "&\n";
2606     $column =
2607       sub { my ($d,$a,$s,$w) = @_;
2608             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2609           };
2610   } elsif ( $format eq 'html' ) {
2611     $prefix = '<th></th>';
2612     $suffix = '';
2613     $separator = '';
2614     $column =
2615       sub { my ($d,$a,$s,$w) = @_;
2616             return qq!<th align="$html_align{$a}">$d</th>!;
2617       };
2618   }
2619
2620   sub {
2621     my @args = @_;
2622     my @result = ();
2623
2624     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2625       push @result,
2626         &{$column}( map { $f->{$_}->[$i] } qw(label align span width) );
2627     }
2628
2629     $prefix. join($separator, @result). $suffix;
2630   };
2631
2632 }
2633
2634 sub _condensed_description_generator {
2635   my ( $self, $format ) = ( shift, shift );
2636
2637   my ( $f, $prefix, $suffix, $separator, $column ) =
2638     _condensed_generator_defaults($format);
2639
2640   my $money_char = '$';
2641   if ($format eq 'latex') {
2642     $prefix = "\\hline\n\\multicolumn{1}{c}{\\rule{0pt}{2.5ex}~} &\n";
2643     $suffix = '\\\\';
2644     $separator = " & \n";
2645     $column =
2646       sub { my ($d,$a,$s,$w) = @_;
2647             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{\\textbf{$d}}}";
2648           };
2649     $money_char = '\\dollar';
2650   }elsif ( $format eq 'html' ) {
2651     $prefix = '"><td align="center"></td>';
2652     $suffix = '';
2653     $separator = '';
2654     $column =
2655       sub { my ($d,$a,$s,$w) = @_;
2656             return qq!<td align="$html_align{$a}">$d</td>!;
2657       };
2658     #$money_char = $conf->config('money_char') || '$';
2659     $money_char = '';  # this is madness
2660   }
2661
2662   sub {
2663     #my @args = @_;
2664     my $href = shift;
2665     my @result = ();
2666
2667     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2668       my $dollar = '';
2669       $dollar = $money_char if $i == scalar(@{$f->{label}})-1;
2670       push @result,
2671         &{$column}( &{$f->{fields}->[$i]}($href, 'dollar' => $dollar),
2672                     map { $f->{$_}->[$i] } qw(align span width)
2673                   );
2674     }
2675
2676     $prefix. join( $separator, @result ). $suffix;
2677   };
2678
2679 }
2680
2681 sub _condensed_total_generator {
2682   my ( $self, $format ) = ( shift, shift );
2683
2684   my ( $f, $prefix, $suffix, $separator, $column ) =
2685     _condensed_generator_defaults($format);
2686   my $style = '';
2687
2688   if ($format eq 'latex') {
2689     $prefix = "& ";
2690     $suffix = "\\\\\n";
2691     $separator = " & \n";
2692     $column =
2693       sub { my ($d,$a,$s,$w) = @_;
2694             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2695           };
2696   }elsif ( $format eq 'html' ) {
2697     $prefix = '';
2698     $suffix = '';
2699     $separator = '';
2700     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2701     $column =
2702       sub { my ($d,$a,$s,$w) = @_;
2703             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2704       };
2705   }
2706
2707
2708   sub {
2709     my @args = @_;
2710     my @result = ();
2711
2712     #  my $r = &{$f->{fields}->[$i]}(@args);
2713     #  $r .= ' Total' unless $i;
2714
2715     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2716       push @result,
2717         &{$column}( &{$f->{fields}->[$i]}(@args). ($i ? '' : ' Total'),
2718                     map { $f->{$_}->[$i] } qw(align span width)
2719                   );
2720     }
2721
2722     $prefix. join( $separator, @result ). $suffix;
2723   };
2724
2725 }
2726
2727 =item total_line_generator FORMAT
2728
2729 Returns a coderef used for generation of invoice total line items for this
2730 usage_class.  FORMAT is either html or latex
2731
2732 =cut
2733
2734 # should not be used: will have issues with hash element names (description vs
2735 # total_item and amount vs total_amount -- another array of functions?
2736
2737 sub _condensed_total_line_generator {
2738   my ( $self, $format ) = ( shift, shift );
2739
2740   my ( $f, $prefix, $suffix, $separator, $column ) =
2741     _condensed_generator_defaults($format);
2742   my $style = '';
2743
2744   if ($format eq 'latex') {
2745     $prefix = "& ";
2746     $suffix = "\\\\\n";
2747     $separator = " & \n";
2748     $column =
2749       sub { my ($d,$a,$s,$w) = @_;
2750             return "\\multicolumn{$s}{$a}{\\makebox[$w][$a]{$d}}";
2751           };
2752   }elsif ( $format eq 'html' ) {
2753     $prefix = '';
2754     $suffix = '';
2755     $separator = '';
2756     $style = 'border-top: 3px solid #000000;border-bottom: 3px solid #000000;';
2757     $column =
2758       sub { my ($d,$a,$s,$w) = @_;
2759             return qq!<td align="$html_align{$a}" style="$style">$d</td>!;
2760       };
2761   }
2762
2763
2764   sub {
2765     my @args = @_;
2766     my @result = ();
2767
2768     foreach  (my $i = 0; $f->{label}->[$i]; $i++) {
2769       push @result,
2770         &{$column}( &{$f->{fields}->[$i]}(@args),
2771                     map { $f->{$_}->[$i] } qw(align span width)
2772                   );
2773     }
2774
2775     $prefix. join( $separator, @result ). $suffix;
2776   };
2777
2778 }
2779
2780 =item _items_pkg [ OPTIONS ]
2781
2782 Return line item hashes for each package item on this invoice. Nearly
2783 equivalent to
2784
2785 $self->_items_cust_bill_pkg([ $self->cust_bill_pkg ])
2786
2787 OPTIONS are passed through to _items_cust_bill_pkg, and should include
2788 'format' and 'escape_function' at minimum.
2789
2790 To produce items for a specific invoice section, OPTIONS should include
2791 'section', a hashref containing 'category' and/or 'locationnum' keys.
2792
2793 'section' may also contain a key named 'condensed'. If this is present
2794 and has a true value, _items_pkg will try to merge identical items into items
2795 with 'quantity' equal to the number of items (not the sum of their separate
2796 quantities, for some reason).
2797
2798 =cut
2799
2800 sub _items_nontax {
2801   my $self = shift;
2802   # The order of these is important.  Bundled line items will be merged into
2803   # the most recent non-hidden item, so it needs to be the one with:
2804   # - the same pkgnum
2805   # - the same start date
2806   # - no pkgpart_override
2807   #
2808   # So: sort by pkgnum,
2809   # then by sdate
2810   # then sort the base line item before any overrides
2811   # then sort hidden before non-hidden add-ons
2812   # then sort by override pkgpart (for consistency)
2813   sort { $a->pkgnum <=> $b->pkgnum        or
2814          $a->sdate  <=> $b->sdate         or
2815          ($a->pkgpart_override ? 0 : -1)  or
2816          ($b->pkgpart_override ? 0 : 1)   or
2817          $b->hidden cmp $a->hidden        or
2818          $a->pkgpart_override <=> $b->pkgpart_override
2819        }
2820   # and of course exclude taxes and fees
2821   grep { $_->pkgnum > 0 } $self->cust_bill_pkg;
2822 }
2823
2824 sub _items_fee {
2825   my $self = shift;
2826   my %options = @_;
2827   my @cust_bill_pkg = grep { $_->feepart } $self->cust_bill_pkg;
2828   my $escape_function = $options{escape_function};
2829
2830   my @items;
2831   foreach my $cust_bill_pkg (@cust_bill_pkg) {
2832     # cache this, so we don't look it up again in every section
2833     my $part_fee = $cust_bill_pkg->get('part_fee')
2834        || $cust_bill_pkg->part_fee;
2835     $cust_bill_pkg->set('part_fee', $part_fee);
2836     if (!$part_fee) {
2837       #die "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n"; # might make more sense
2838       warn "fee definition not found for line item #".$cust_bill_pkg->billpkgnum."\n";
2839       next;
2840     }
2841     if ( exists($options{section}) and exists($options{section}{category}) )
2842     {
2843       my $categoryname = $options{section}{category};
2844       # then filter for items that have that section
2845       if ( $part_fee->categoryname ne $categoryname ) {
2846         warn "skipping fee '".$part_fee->itemdesc."'--not in section $categoryname\n" if $DEBUG;
2847         next;
2848       }
2849     } # otherwise include them all in the main section
2850     # XXX what to do when sectioning by location?
2851
2852     my @ext_desc;
2853     my %base_invnums; # invnum => invoice date
2854     foreach ($cust_bill_pkg->cust_bill_pkg_fee) {
2855       if ($_->base_invnum) {
2856         # XXX what if base_bill has been voided?
2857         my $base_bill = FS::cust_bill->by_key($_->base_invnum);
2858         my $base_date = $self->time2str_local('short', $base_bill->_date)
2859           if $base_bill;
2860         $base_invnums{$_->base_invnum} = $base_date || '';
2861       }
2862     }
2863     foreach (sort keys(%base_invnums)) {
2864       next if $_ == $self->invnum;
2865       # per convention, we must escape ext_description lines
2866       push @ext_desc,
2867         &{$escape_function}(
2868           $self->mt('from invoice #[_1] on [_2]', $_, $base_invnums{$_})
2869         );
2870     }
2871     my $desc = $part_fee->itemdesc_locale($self->cust_main->locale);
2872     # but not escape the base description line
2873
2874     push @items,
2875       { feepart     => $cust_bill_pkg->feepart,
2876         amount      => sprintf('%.2f', $cust_bill_pkg->setup + $cust_bill_pkg->recur),
2877         description => $desc,
2878         ext_description => \@ext_desc
2879         # sdate/edate?
2880       };
2881   }
2882   @items;
2883 }
2884
2885 sub _items_pkg {
2886   my $self = shift;
2887   my %options = @_;
2888
2889   warn "$me _items_pkg searching for all package line items\n"
2890     if $DEBUG > 1;
2891
2892   my @cust_bill_pkg = $self->_items_nontax;
2893
2894   warn "$me _items_pkg filtering line items\n"
2895     if $DEBUG > 1;
2896   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2897
2898   if ($options{section} && $options{section}->{condensed}) {
2899
2900     warn "$me _items_pkg condensing section\n"
2901       if $DEBUG > 1;
2902
2903     my %itemshash = ();
2904     local $Storable::canonical = 1;
2905     foreach ( @items ) {
2906       my $item = { %$_ };
2907       delete $item->{ref};
2908       delete $item->{ext_description};
2909       my $key = freeze($item);
2910       $itemshash{$key} ||= 0;
2911       $itemshash{$key} ++; # += $item->{quantity};
2912     }
2913     @items = sort { $a->{description} cmp $b->{description} }
2914              map { my $i = thaw($_);
2915                    $i->{quantity} = $itemshash{$_};
2916                    $i->{amount} =
2917                      sprintf( "%.2f", $i->{quantity} * $i->{amount} );#unit_amount
2918                    $i;
2919                  }
2920              keys %itemshash;
2921   }
2922
2923   warn "$me _items_pkg returning ". scalar(@items). " items\n"
2924     if $DEBUG > 1;
2925
2926   @items;
2927 }
2928
2929 sub _taxsort {
2930   return 0 unless $a->itemdesc cmp $b->itemdesc;
2931   return -1 if $b->itemdesc eq 'Tax';
2932   return 1 if $a->itemdesc eq 'Tax';
2933   return -1 if $b->itemdesc eq 'Other surcharges';
2934   return 1 if $a->itemdesc eq 'Other surcharges';
2935   $a->itemdesc cmp $b->itemdesc;
2936 }
2937
2938 sub _items_tax {
2939   my $self = shift;
2940   my @cust_bill_pkg = sort _taxsort grep { ! $_->pkgnum and ! $_->feepart }
2941     $self->cust_bill_pkg;
2942   my @items = $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
2943
2944   if ( $self->conf->exists('always_show_tax') ) {
2945     my $itemdesc = $self->conf->config('always_show_tax') || 'Tax';
2946     if (0 == grep { $_->{description} eq $itemdesc } @items) {
2947       push @items,
2948         { 'description' => $itemdesc,
2949           'amount'      => 0.00 };
2950     }
2951   }
2952   @items;
2953 }
2954
2955 =item _items_cust_bill_pkg CUST_BILL_PKGS OPTIONS
2956
2957 Takes an arrayref of L<FS::cust_bill_pkg> objects, and returns a
2958 list of hashrefs describing the line items they generate on the invoice.
2959
2960 OPTIONS may include:
2961
2962 format: the invoice format.
2963
2964 escape_function: the function used to escape strings.
2965
2966 DEPRECATED? (expensive, mostly unused?)
2967 format_function: the function used to format CDRs.
2968
2969 section: a hashref containing 'category' and/or 'locationnum'; if this
2970 is present, only returns line items that belong to that category and/or
2971 location (whichever is defined).
2972
2973 multisection: a flag indicating that this is a multisection invoice,
2974 which does something complicated.
2975
2976 preref_callback: coderef run for each line item, code should return HTML to be
2977 displayed before that line item (quotations only)
2978
2979 Returns a list of hashrefs, each of which may contain:
2980
2981 pkgnum, description, amount, unit_amount, quantity, pkgpart, _is_setup, and
2982 ext_description, which is an arrayref of detail lines to show below
2983 the package line.
2984
2985 =cut
2986
2987 sub _items_cust_bill_pkg {
2988   my $self = shift;
2989   my $conf = $self->conf;
2990   my $cust_bill_pkgs = shift;
2991   my %opt = @_;
2992
2993   my $format = $opt{format} || '';
2994   my $escape_function = $opt{escape_function} || sub { shift };
2995   my $format_function = $opt{format_function} || '';
2996   my $no_usage = $opt{no_usage} || '';
2997   my $unsquelched = $opt{unsquelched} || ''; #unused
2998   my ($section, $locationnum, $category);
2999   if ( $opt{section} ) {
3000     $category = $opt{section}->{category};
3001     $locationnum = $opt{section}->{locationnum};
3002   }
3003   my $summary_page = $opt{summary_page} || ''; #unused
3004   my $multisection = defined($category) || defined($locationnum);
3005   my $discount_show_always = 0;
3006
3007   my $maxlength = $conf->config('cust_bill-latex_lineitem_maxlength') || 40;
3008
3009   my $cust_main = $self->cust_main;#for per-agent cust_bill-line_item-ate_style
3010
3011   # for location labels: use default location on the invoice date
3012   my $default_locationnum;
3013   if ( $self->custnum ) {
3014     my $h_cust_main;
3015     my @h_search = FS::h_cust_main->sql_h_search($self->_date);
3016     $h_cust_main = qsearchs({
3017         'table'     => 'h_cust_main',
3018         'hashref'   => { custnum => $self->custnum },
3019         'extra_sql' => $h_search[1],
3020         'addl_from' => $h_search[3],
3021     }) || $cust_main;
3022     $default_locationnum = $h_cust_main->ship_locationnum;
3023   } elsif ( $self->prospectnum ) {
3024     my $cust_location = qsearchs('cust_location',
3025       { prospectnum => $self->prospectnum,
3026         disabled => '' });
3027     $default_locationnum = $cust_location->locationnum if $cust_location;
3028   }
3029
3030   my @b = (); # accumulator for the line item hashes that we'll return
3031   my ($s, $r, $u, $d) = ( undef, undef, undef, undef );
3032             # the 'current' line item hashes for setup, recur, usage, discount
3033   foreach my $cust_bill_pkg ( @$cust_bill_pkgs )
3034   {
3035     # if the current line item is waiting to go out, and the one we're about
3036     # to start is not bundled, then push out the current one and start a new
3037     # one.
3038     foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3039       if ( $_ && !$cust_bill_pkg->hidden ) {
3040         $_->{amount}      = sprintf( "%.2f", $_->{amount} );
3041         $_->{amount}      =~ s/^\-0\.00$/0.00/;
3042         if (exists($_->{unit_amount})) {
3043           $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3044         }
3045         push @b, { %$_ }
3046           if $_->{amount} != 0
3047           || $discount_show_always
3048           || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3049           || (   $_->{_is_setup} && $_->{setup_show_zero} )
3050         ;
3051         $_ = undef;
3052       }
3053     }
3054
3055     if ( $locationnum ) {
3056       # this is a location section; skip packages that aren't at this
3057       # service location.
3058       next if $cust_bill_pkg->pkgnum == 0; # skips fees...
3059       next if $self->cust_pkg_hash->{ $cust_bill_pkg->pkgnum }->locationnum
3060               != $locationnum;
3061     }
3062
3063     # Consider display records for this item to determine if it belongs
3064     # in this section.  Note that if there are no display records, there
3065     # will be a default pseudo-record that includes all charge types
3066     # and has no section name.
3067     my @cust_bill_pkg_display = $cust_bill_pkg->can('cust_bill_pkg_display')
3068                                   ? $cust_bill_pkg->cust_bill_pkg_display
3069                                   : ( $cust_bill_pkg );
3070
3071     warn "$me _items_cust_bill_pkg considering cust_bill_pkg ".
3072          $cust_bill_pkg->billpkgnum. ", pkgnum ". $cust_bill_pkg->pkgnum. "\n"
3073       if $DEBUG > 1;
3074
3075     if ( defined($category) ) {
3076       # then this is a package category section; process all display records
3077       # that belong to this section.
3078       @cust_bill_pkg_display = grep { $_->section eq $category }
3079                                 @cust_bill_pkg_display;
3080     } else {
3081       # otherwise, process all display records that aren't usage summaries
3082       # (I don't think there should be usage summaries if you aren't using
3083       # category sections, but this is the historical behavior)
3084       @cust_bill_pkg_display = grep { !$_->summary }
3085                                 @cust_bill_pkg_display;
3086     }
3087
3088     my $classname = ''; # package class name, will fill in later
3089
3090     foreach my $display (@cust_bill_pkg_display) {
3091
3092       warn "$me _items_cust_bill_pkg considering cust_bill_pkg_display ".
3093            $display->billpkgdisplaynum. "\n"
3094         if $DEBUG > 1;
3095
3096       my $type = $display->type;
3097
3098       my $desc = $cust_bill_pkg->desc( $cust_main ? $cust_main->locale : '' );
3099       $desc = substr($desc, 0, $maxlength). '...'
3100         if $format eq 'latex' && length($desc) > $maxlength;
3101
3102       my %details_opt = ( 'format'          => $format,
3103                           'escape_function' => $escape_function,
3104                           'format_function' => $format_function,
3105                           'no_usage'        => $opt{'no_usage'},
3106                         );
3107
3108       if ( ref($cust_bill_pkg) eq 'FS::quotation_pkg' ) {
3109         # XXX this should be pulled out into quotation_pkg
3110
3111         warn "$me _items_cust_bill_pkg cust_bill_pkg is quotation_pkg\n"
3112           if $DEBUG > 1;
3113         # quotation_pkgs are never fees, so don't worry about the case where
3114         # part_pkg is undefined
3115
3116         # and I guess they're never bundled either?
3117         if ( $cust_bill_pkg->setup != 0 ) {
3118           my $description = $desc;
3119           $description .= ' Setup'
3120             if $cust_bill_pkg->recur != 0
3121             || $discount_show_always
3122             || $cust_bill_pkg->recur_show_zero;
3123           #push @b, {
3124           # keep it consistent, please
3125           $s = {
3126             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3127             'description' => $description,
3128             'amount'      => sprintf("%.2f", $cust_bill_pkg->setup),
3129             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitsetup),
3130             'quantity'    => $cust_bill_pkg->quantity,
3131             'preref_html' => ( $opt{preref_callback}
3132                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3133                                  : ''
3134                              ),
3135           };
3136         }
3137         if ( $cust_bill_pkg->recur != 0 ) {
3138           #push @b, {
3139           $r = {
3140             'pkgnum'      => $cust_bill_pkg->pkgpart, #so it displays in Ref
3141             'description' => "$desc (". $cust_bill_pkg->part_pkg->freq_pretty.")",
3142             'amount'      => sprintf("%.2f", $cust_bill_pkg->recur),
3143             'unit_amount' => sprintf("%.2f", $cust_bill_pkg->unitrecur),
3144             'quantity'    => $cust_bill_pkg->quantity,
3145            'preref_html'  => ( $opt{preref_callback}
3146                                  ? &{ $opt{preref_callback} }( $cust_bill_pkg )
3147                                  : ''
3148                              ),
3149           };
3150         }
3151
3152       } elsif ( $cust_bill_pkg->pkgnum > 0 ) {
3153         # a "normal" package line item (not a quotation, not a fee, not a tax)
3154
3155         warn "$me _items_cust_bill_pkg cust_bill_pkg is non-tax\n"
3156           if $DEBUG > 1;
3157
3158         my $cust_pkg = $cust_bill_pkg->cust_pkg;
3159         my $part_pkg = $cust_pkg->part_pkg;
3160
3161         # which pkgpart to show for display purposes?
3162         my $pkgpart = $cust_bill_pkg->pkgpart_override || $cust_pkg->pkgpart;
3163
3164         # start/end dates for invoice formats that do nonstandard
3165         # things with them
3166         my %item_dates = ();
3167         %item_dates = map { $_ => $cust_bill_pkg->$_ } ('sdate', 'edate')
3168           unless $part_pkg->option('disable_line_item_date_ranges',1);
3169
3170         # not normally used, but pass this to the template anyway
3171         $classname = $part_pkg->classname;
3172
3173         if (    (!$type || $type eq 'S')
3174              && (    $cust_bill_pkg->setup != 0
3175                   || $cust_bill_pkg->setup_show_zero
3176                 )
3177            )
3178          {
3179
3180           warn "$me _items_cust_bill_pkg adding setup\n"
3181             if $DEBUG > 1;
3182
3183           my $description = $desc;
3184           $description .= ' Setup'
3185             if $cust_bill_pkg->recur != 0
3186             || $discount_show_always
3187             || $cust_bill_pkg->recur_show_zero;
3188
3189           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3190                                                               $self->agentnum )
3191             if $part_pkg->is_prepaid #for prepaid, "display the validity period
3192                                      # triggered by the recurring charge freq
3193                                      # (RT#26274)
3194             && $cust_bill_pkg->recur == 0
3195             && ! $cust_bill_pkg->recur_show_zero;
3196
3197           my @d = ();
3198           my $svc_label;
3199
3200           # always pass the svc_label through to the template, even if
3201           # not displaying it as an ext_description
3202           my @svc_labels = map &{$escape_function}($_),
3203                       $cust_pkg->h_labels_short($self->_date, undef, 'I');
3204
3205           $svc_label = $svc_labels[0];
3206
3207           unless ( $cust_pkg->part_pkg->hide_svc_detail
3208                 || $cust_bill_pkg->hidden )
3209           {
3210
3211             push @d, @svc_labels
3212               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3213             # show the location label if it's not the customer's default
3214             # location, and we're not grouping items by location already
3215             if ( $cust_pkg->locationnum != $default_locationnum
3216                   and !defined($locationnum) ) {
3217               my $loc = $cust_pkg->location_label;
3218               $loc = substr($loc, 0, $maxlength). '...'
3219                 if $format eq 'latex' && length($loc) > $maxlength;
3220               push @d, &{$escape_function}($loc);
3221             }
3222
3223           } #unless hiding service details
3224
3225           push @d, $cust_bill_pkg->details(%details_opt)
3226             if $cust_bill_pkg->recur == 0;
3227
3228           if ( $cust_bill_pkg->hidden ) {
3229             $s->{amount}      += $cust_bill_pkg->setup;
3230             $s->{unit_amount} += $cust_bill_pkg->unitsetup;
3231             push @{ $s->{ext_description} }, @d;
3232           } else {
3233             $s = {
3234               _is_setup       => 1,
3235               description     => $description,
3236               pkgpart         => $pkgpart,
3237               pkgnum          => $cust_bill_pkg->pkgnum,
3238               amount          => $cust_bill_pkg->setup,
3239               setup_show_zero => $cust_bill_pkg->setup_show_zero,
3240               unit_amount     => $cust_bill_pkg->unitsetup,
3241               quantity        => $cust_bill_pkg->quantity,
3242               ext_description => \@d,
3243               svc_label       => ($svc_label || ''),
3244               locationnum     => $cust_pkg->locationnum, # sure, why not?
3245             };
3246           };
3247
3248         }
3249
3250         if (    ( !$type || $type eq 'R' || $type eq 'U' )
3251              && (
3252                      $cust_bill_pkg->recur != 0
3253                   || $cust_bill_pkg->setup == 0
3254                   || $discount_show_always
3255                   || $cust_bill_pkg->recur_show_zero
3256                 )
3257            )
3258         {
3259
3260           warn "$me _items_cust_bill_pkg adding recur/usage\n"
3261             if $DEBUG > 1;
3262
3263           my $is_summary = $display->summary;
3264           my $description = $desc;
3265           if ( $type eq 'U' and defined($r) ) {
3266             # don't just show the same description as the recur line
3267             $description = $self->mt('Usage charges');
3268           }
3269
3270           my $part_pkg = $cust_pkg->part_pkg;
3271
3272           $description .= $cust_bill_pkg->time_period_pretty( $part_pkg,
3273                                                               $self->agentnum );
3274
3275           my @d = ();
3276           my @seconds = (); # for display of usage info
3277           my $svc_label = '';
3278
3279           #at least until cust_bill_pkg has "past" ranges in addition to
3280           #the "future" sdate/edate ones... see #3032
3281           my @dates = ( $self->_date );
3282           my $prev = $cust_bill_pkg->previous_cust_bill_pkg;
3283           push @dates, $prev->sdate if $prev;
3284           push @dates, undef if !$prev;
3285
3286           my @svc_labels = map &{$escape_function}($_),
3287                       $cust_pkg->h_labels_short(@dates, 'I');
3288           $svc_label = $svc_labels[0];
3289
3290           # show service labels, unless...
3291                     # the package is set not to display them
3292           unless ( $part_pkg->hide_svc_detail
3293                     # or this is a tax-like line item
3294                 || $cust_bill_pkg->itemdesc
3295                     # or this is a hidden (bundled) line item
3296                 || $cust_bill_pkg->hidden
3297                     # or this is a usage summary line
3298                 || $is_summary && $type && $type eq 'U'
3299                     # or this is a usage line and there's a recurring line
3300                     # for the package in the same section (which will
3301                     # have service labels already)
3302                 || ($type eq 'U' and defined($r))
3303               )
3304           {
3305
3306             warn "$me _items_cust_bill_pkg adding service details\n"
3307               if $DEBUG > 1;
3308
3309             push @d, @svc_labels
3310               unless $cust_bill_pkg->pkgpart_override; #don't redisplay services
3311             warn "$me _items_cust_bill_pkg done adding service details\n"
3312               if $DEBUG > 1;
3313
3314             # show the location label if it's not the customer's default
3315             # location, and we're not grouping items by location already
3316             if ( $cust_pkg->locationnum != $default_locationnum
3317                   and !defined($locationnum) ) {
3318               my $loc = $cust_pkg->location_label;
3319               $loc = substr($loc, 0, $maxlength). '...'
3320                 if $format eq 'latex' && length($loc) > $maxlength;
3321               push @d, &{$escape_function}($loc);
3322             }
3323
3324             # Display of seconds_since_sqlradacct:
3325             # On the invoice, when processing @detail_items, look for a field
3326             # named 'seconds'.  This will contain total seconds for each
3327             # service, in the same order as @ext_description.  For services
3328             # that don't support this it will show undef.
3329             if ( $conf->exists('svc_acct-usage_seconds')
3330                  and ! $cust_bill_pkg->pkgpart_override ) {
3331               foreach my $cust_svc (
3332                   $cust_pkg->h_cust_svc(@dates, 'I')
3333                 ) {
3334
3335                 # eval because not having any part_export_usage exports
3336                 # is a fatal error, last_bill/_date because that's how
3337                 # sqlradius_hour billing does it
3338                 my $sec = eval {
3339                   $cust_svc->seconds_since_sqlradacct($dates[1] || 0, $dates[0]);
3340                 };
3341                 push @seconds, $sec;
3342               }
3343             } #if svc_acct-usage_seconds
3344
3345           } # if we are showing service labels
3346
3347           unless ( $is_summary ) {
3348             warn "$me _items_cust_bill_pkg adding details\n"
3349               if $DEBUG > 1;
3350
3351             #instead of omitting details entirely in this case (unwanted side
3352             # effects), just omit CDRs
3353             $details_opt{'no_usage'} = 1
3354               if $type && $type eq 'R';
3355
3356             push @d, $cust_bill_pkg->details(%details_opt);
3357           }
3358
3359           warn "$me _items_cust_bill_pkg calculating amount\n"
3360             if $DEBUG > 1;
3361
3362           my $amount = 0;
3363           if (!$type) {
3364             $amount = $cust_bill_pkg->recur;
3365           } elsif ($type eq 'R') {
3366             $amount = $cust_bill_pkg->recur - $cust_bill_pkg->usage;
3367           } elsif ($type eq 'U') {
3368             $amount = $cust_bill_pkg->usage;
3369           }
3370
3371           if ( !$type || $type eq 'R' ) {
3372
3373             warn "$me _items_cust_bill_pkg adding recur\n"
3374               if $DEBUG > 1;
3375
3376             my $unit_amount =
3377               ( $cust_bill_pkg->unitrecur > 0 ) ? $cust_bill_pkg->unitrecur
3378                                                 : $amount;
3379
3380             if ( $cust_bill_pkg->hidden ) {
3381               $r->{amount}      += $amount;
3382               $r->{unit_amount} += $unit_amount;
3383               push @{ $r->{ext_description} }, @d;
3384             } else {
3385               $r = {
3386                 description     => $description,
3387                 pkgpart         => $pkgpart,
3388                 pkgnum          => $cust_bill_pkg->pkgnum,
3389                 amount          => $amount,
3390                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3391                 unit_amount     => $unit_amount,
3392                 quantity        => $cust_bill_pkg->quantity,
3393                 %item_dates,
3394                 ext_description => \@d,
3395                 svc_label       => ($svc_label || ''),
3396                 locationnum     => $cust_pkg->locationnum,
3397               };
3398               $r->{'seconds'} = \@seconds if grep {defined $_} @seconds;
3399             }
3400
3401           } else {  # $type eq 'U'
3402
3403             warn "$me _items_cust_bill_pkg adding usage\n"
3404               if $DEBUG > 1;
3405
3406             if ( $cust_bill_pkg->hidden and defined($u) ) {
3407               # if this is a hidden package and there's already a usage
3408               # line for the bundle, add this package's total amount and
3409               # usage details to it
3410               $u->{amount}      += $amount;
3411               push @{ $u->{ext_description} }, @d;
3412             } elsif ( $amount ) {
3413               # create a new usage line
3414               $u = {
3415                 description     => $description,
3416                 pkgpart         => $pkgpart,
3417                 pkgnum          => $cust_bill_pkg->pkgnum,
3418                 amount          => $amount,
3419                 usage_item      => 1,
3420                 recur_show_zero => $cust_bill_pkg->recur_show_zero,
3421                 %item_dates,
3422                 ext_description => \@d,
3423                 locationnum     => $cust_pkg->locationnum,
3424               };
3425             } # else this has no usage, so don't create a usage section
3426           }
3427
3428         } # recurring or usage with recurring charge
3429
3430       } else { # taxes and fees
3431
3432         warn "$me _items_cust_bill_pkg cust_bill_pkg is tax\n"
3433           if $DEBUG > 1;
3434
3435         # items of this kind should normally not have sdate/edate.
3436         push @b, {
3437           'description' => $desc,
3438           'amount'      => sprintf('%.2f', $cust_bill_pkg->setup
3439                                            + $cust_bill_pkg->recur)
3440         };
3441
3442       } # if quotation / package line item / other line item
3443
3444       # decide whether to show active discounts here
3445       if (
3446           # case 1: we are showing a single line for the package
3447           ( !$type )
3448           # case 2: we are showing a setup line for a package that has
3449           # no base recurring fee
3450           or ( $type eq 'S' and $cust_bill_pkg->unitrecur == 0 )
3451           # case 3: we are showing a recur line for a package that has
3452           # a base recurring fee
3453           or ( $type eq 'R' and $cust_bill_pkg->unitrecur > 0 )
3454       ) {
3455
3456         my $item_discount = $cust_bill_pkg->_item_discount;
3457         if ( $item_discount ) {
3458           # $item_discount->{amount} is negative
3459
3460           if ( $d and $cust_bill_pkg->hidden ) {
3461             $d->{amount}      += $item_discount->{amount};
3462           } else {
3463             $d = $item_discount;
3464             $_ = &{$escape_function}($_) foreach @{ $d->{ext_description} };
3465           }
3466
3467           # update the active line (before the discount) to show the
3468           # original price (whether this is a hidden line or not)
3469           #
3470           # quotation discounts keep track of setup and recur; invoice
3471           # discounts currently don't
3472           if ( exists $item_discount->{setup_amount} ) {
3473
3474             $s->{amount} -= $item_discount->{setup_amount} if $s;
3475             $r->{amount} -= $item_discount->{recur_amount} if $r;
3476
3477           } else {
3478
3479             # $active_line is the line item hashref for the line that will
3480             # show the original price
3481             # (use the recur or single line for the package, unless we're
3482             # showing a setup line for a package with no recurring fee)
3483             my $active_line = $r;
3484             if ( $type eq 'S' ) {
3485               $active_line = $s;
3486             }
3487             $active_line->{amount} -= $item_discount->{amount};
3488
3489           }
3490
3491         } # if there are any discounts
3492       } # if this is an appropriate place to show discounts
3493
3494     } # foreach $display
3495
3496     $discount_show_always = ($cust_bill_pkg->cust_bill_pkg_discount
3497                                 && $conf->exists('discount-show-always'));
3498
3499   }
3500
3501   foreach ( $s, $r, ($opt{skip_usage} ? () : $u ), $d ) {
3502     if ( $_  ) {
3503       $_->{amount}      = sprintf( "%.2f", $_->{amount} ),
3504         if exists($_->{amount});
3505       $_->{amount}      =~ s/^\-0\.00$/0.00/;
3506       if (exists($_->{unit_amount})) {
3507         $_->{unit_amount} = sprintf( "%.2f", $_->{unit_amount} );
3508       }
3509
3510       push @b, { %$_ }
3511         if $_->{amount} != 0
3512         || $discount_show_always
3513         || ( ! $_->{_is_setup} && $_->{recur_show_zero} )
3514         || (   $_->{_is_setup} && $_->{setup_show_zero} )
3515     }
3516   }
3517
3518   warn "$me _items_cust_bill_pkg done considering cust_bill_pkgs\n"
3519     if $DEBUG > 1;
3520
3521   @b;
3522
3523 }
3524
3525 =item _items_discounts_avail
3526
3527 Returns an array of line item hashrefs representing available term discounts
3528 for this invoice.  This makes the same assumptions that apply to term
3529 discounts in general: that the package is billed monthly, at a flat rate,
3530 with no usage charges.  A prorated first month will be handled, as will
3531 a setup fee if the discount is allowed to apply to setup fees.
3532
3533 =cut
3534
3535 sub _items_discounts_avail {
3536   my $self = shift;
3537
3538   #maybe move this method from cust_bill when quotations support discount_plans
3539   return () unless $self->can('discount_plans');
3540   my %plans = $self->discount_plans;
3541
3542   my $list_pkgnums = 0; # if any packages are not eligible for all discounts
3543   $list_pkgnums = grep { $_->list_pkgnums } values %plans;
3544
3545   map {
3546     my $months = $_;
3547     my $plan = $plans{$months};
3548
3549     my $term_total = sprintf('%.2f', $plan->discounted_total);
3550     my $percent = sprintf('%.0f',
3551                           100 * (1 - $term_total / $plan->base_total) );
3552     my $permonth = sprintf('%.2f', $term_total / $months);
3553     my $detail = $self->mt('discount on item'). ' '.
3554                  join(', ', map { "#$_" } $plan->pkgnums)
3555       if $list_pkgnums;
3556
3557     # discounts for non-integer months don't work anyway
3558     $months = sprintf("%d", $months);
3559
3560     +{
3561       description => $self->mt('Save [_1]% by paying for [_2] months',
3562                                 $percent, $months),
3563       amount      => $self->mt('[_1] ([_2] per month)',
3564                                 $term_total, $money_char.$permonth),
3565       ext_description => ($detail || ''),
3566     }
3567   } #map
3568   sort { $b <=> $a } keys %plans;
3569
3570 }
3571
3572 1;