FS/FS/ClientAPI/Signup.pm

   1 package FS::ClientAPI::Signup;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me );
   5 use subs qw( _myaccount_cache );
   6 use Data::Dumper;
   7 use Tie::RefHash;
   8 use Digest::SHA qw(sha512_hex);
   9 use FS::Conf;
  10 use FS::Record qw(qsearch qsearchs dbdef);
  11 use FS::CGI qw(popurl);
  12 use FS::Msgcat qw(gettext);
  13 use FS::Misc qw(card_types);
  14 use FS::ClientAPI_SessionCache;
  15 use FS::agent;
  16 use FS::cust_main_county;
  17 use FS::part_pkg;
  18 use FS::svc_acct_pop;
  19 use FS::cust_main;
  20 use FS::cust_pkg;
  21 use FS::svc_acct;
  22 use FS::svc_phone;
  23 use FS::acct_snarf;
  24 use FS::queue;
  25 use FS::reg_code;
  26 use FS::payby;
  27 use FS::banned_pay;
  28 use FS::part_tag;
  29
  30 $DEBUG = 1;
  31 $me = '[FS::ClientAPI::Signup]';
  32
  33 sub clear_cache {
  34   warn "$me clear_cache called\n" if $DEBUG;
  35   my $cache = new FS::ClientAPI_SessionCache( {
  36       'namespace' => 'FS::ClientAPI::Signup',
  37   } );
  38   $cache->clear();
  39   return {};
  40 }
  41
  42 sub signup_info {
  43   my $packet = shift;
  44
  45   warn "$me signup_info called on $packet\n" if $DEBUG;
  46
  47   my $conf = new FS::Conf;
  48   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
  49
  50   my $cache = new FS::ClientAPI_SessionCache( {
  51     'namespace' => 'FS::ClientAPI::Signup',
  52   } );
  53   my $signup_info_cache = $cache->get('signup_info_cache');
  54
  55   if ( $signup_info_cache ) {
  56
  57     warn "$me loading cached signup info\n" if $DEBUG > 1;
  58
  59   } else {
  60
  61     warn "$me populating signup info cache\n" if $DEBUG > 1;
  62
  63     my $agentnum2part_pkg =
  64       {
  65         map {
  66           my $agent = $_;
  67           my $href = $agent->pkgpart_hashref;
  68           $agent->agentnum =>
  69             [
  70               map { { 'payby'       => [ $_->payby ],
  71                       'freq_pretty' => $_->freq_pretty,
  72                       'options'     => { $_->options },
  73                       %{$_->hashref}
  74                   } }
  75                 grep { $_->svcpart($svc_x)
  76                        && ( $href->{ $_->pkgpart }
  77                             || ( $_->agentnum
  78                                  && $_->agentnum == $agent->agentnum
  79                                )
  80                           )
  81                      }
  82                   qsearch( 'part_pkg', { 'disabled' => '' } )
  83             ];
  84         } qsearch('agent', { 'disabled' => '' })
  85       };
  86
  87     my $msgcat = { map { $_=>gettext($_) }
  88                        qw( passwords_dont_match invalid_card unknown_card_type
  89                            not_a empty_password illegal_or_empty_text )
  90                  };
  91     warn "msgcat: ". Dumper($msgcat). "\n" if $DEBUG > 2;
  92
  93     my $label = { map { $_ => FS::Msgcat::_gettext($_) }
  94                       qw( stateid stateid_state )
  95                 };
  96     warn "label: ". Dumper($label). "\n" if $DEBUG > 2;
  97
  98     my @agent_fields = qw( agentnum agent );
  99
 100     my @bools = qw( emailinvoiceonly security_phrase );
 101
 102     my @signup_bools = qw( no_company recommend_daytime recommend_email );
 103
 104     my @signup_server_scalars = qw( default_pkgpart default_svcpart default_domsvc );
 105
 106     my @selfservice_textareas = qw( head body_header body_footer );
 107
 108     my @selfservice_scalars = qw(
 109       body_bgcolor box_bgcolor
 110       text_color link_color vlink_color hlink_color alink_color
 111       font title_color title_align title_size menu_bgcolor menu_fontsize
 112     );
 113
 114     #XXX my @selfservice_bools = qw(
 115     #  menu_skipblanks menu_skipheadings menu_nounderline
 116     #);
 117
 118     #my $selfservice_binaries = qw(
 119     #  title_left_image title_right_image
 120     #  menu_top_image menu_body_image menu_bottom_image
 121     #);
 122
 123     $signup_info_cache = {
 124
 125       'cust_main_county' => [ map $_->hashref,
 126                                   qsearch('cust_main_county', {} )
 127                             ],
 128
 129       'agent' => [ map { my $agent = $_;
 130                          +{ map { $_ => $agent->get($_) } @agent_fields }
 131                        }
 132                        qsearch('agent', { 'disabled' => '' } )
 133                  ],
 134
 135       'part_referral' => [ map $_->hashref,
 136                                qsearch('part_referral', { 'disabled' => '' } )
 137                          ],
 138
 139       'agentnum2part_pkg' => $agentnum2part_pkg,
 140
 141       'svc_acct_pop' => [ map $_->hashref, qsearch('svc_acct_pop',{} ) ],
 142
 143       'emailinvoiceonly' => $conf->exists('emailinvoiceonly'),
 144
 145       'security_phrase' => $conf->exists('security_phrase'),
 146
 147       'nomadix' => $conf->exists('signup_server-nomadix'),
 148
 149       'payby' => [ $conf->config('signup_server-payby') ],
 150
 151       'payby_longname' => [ map { FS::payby->longname($_) }
 152                             $conf->config('signup_server-payby') ],
 153
 154       'card_types' => card_types(),
 155
 156       ( map { $_ => $conf->exists("signup-$_") } @signup_bools ),
 157
 158       ( map { $_ => scalar($conf->config("signup_server-$_")) }
 159             @signup_server_scalars
 160       ),
 161
 162       ( map { $_ => join("\n", $conf->config("selfservice-$_")) }
 163             @selfservice_textareas
 164       ),
 165       ( map { $_ => scalar($conf->config("selfservice-$_")) }
 166             @selfservice_scalars
 167       ),
 168
 169       #( map { $_ => scalar($conf->config_binary("selfservice-$_")) }
 170       #      @selfservice_binaries
 171       #),
 172
 173       'agentnum2part_pkg'  => $agentnum2part_pkg,
 174       'svc_acct_pop'       => [ map $_->hashref, qsearch('svc_acct_pop',{} ) ],
 175       'nomadix'            => $conf->exists('signup_server-nomadix'),
 176       'payby'              => [ $conf->config('signup_server-payby') ],
 177       'card_types'         => card_types(),
 178       'paytypes'           => [ @FS::cust_main::paytypes ],
 179       'cvv_enabled'        => 1,
 180       'require_cvv'        => $conf->exists('signup-require_cvv'),
 181       'stateid_enabled'    => $conf->exists('show_stateid'),
 182       'paystate_enabled'   => $conf->exists('show_bankstate'),
 183       'exempt_groups'      => [ grep /\S/, $conf->config('tax-cust_exempt-groups') ],
 184       'ship_enabled'       => 1,
 185       'msgcat'             => $msgcat,
 186       'label'              => $label,
 187       'statedefault'       => scalar($conf->config('statedefault')) || 'CA',
 188       'countrydefault'     => scalar($conf->config('countrydefault')) || 'US',
 189       'refnum'             => scalar($conf->config('signup_server-default_refnum')),
 190       'signup_service'     => $svc_x,
 191       'company_name'       => scalar($conf->config('company_name')),
 192       #per-agent?
 193       'logo'               => scalar($conf->config_binary('logo.png')),
 194       'prepaid_template_custnum' => $conf->exists('signup_server-prepaid-template-custnum'),
 195     };
 196
 197     $cache->set('signup_info_cache', $signup_info_cache);
 198
 199   }
 200
 201   my $signup_info = { %$signup_info_cache };
 202   warn "$me signup info loaded\n" if $DEBUG > 1;
 203   warn Dumper($signup_info). "\n" if $DEBUG > 2;
 204
 205   my @addl = qw( signup_server-classnum2 signup_server-classnum3 );
 206
 207   if ( grep { $conf->exists($_) } @addl ) {
 208
 209     $signup_info->{optional_packages} = [];
 210
 211     foreach my $addl ( @addl ) {
 212
 213       warn "$me adding optional package info\n" if $DEBUG > 1;
 214
 215       my $classnum = $conf->config($addl) or next;
 216
 217       my @pkgs = map { {
 218                          'freq_pretty' => $_->freq_pretty,
 219                          'options'     => { $_->options },
 220                          %{ $_->hashref }
 221                        };
 222                      }
 223                      qsearch( 'part_pkg', { classnum => $classnum } );
 224
 225       push @{$signup_info->{optional_packages}}, \@pkgs;
 226
 227       warn "$me done adding opt. package info for $classnum\n" if $DEBUG > 1;
 228
 229     }
 230
 231   }
 232
 233   my $agentnum = $packet->{'agentnum'}
 234                  || $conf->config('signup_server-default_agentnum');
 235   $agentnum =~ /^(\d*)$/ or die "illegal agentnum";
 236   $agentnum = $1;
 237
 238   my $session = '';
 239   if ( exists $packet->{'session_id'} ) {
 240
 241     warn "$me loading agent session\n" if $DEBUG > 1;
 242     my $cache = new FS::ClientAPI_SessionCache( {
 243       'namespace' => 'FS::ClientAPI::Agent',
 244     } );
 245     $session = $cache->get($packet->{'session_id'});
 246     if ( $session ) {
 247       $agentnum = $session->{'agentnum'};
 248     } else {
 249       return { 'error' => "Can't resume session" }; #better error message
 250     }
 251     warn "$me done loading agent session\n" if $DEBUG > 1;
 252
 253   } elsif ( exists $packet->{'customer_session_id'} ) {
 254
 255     warn "$me loading customer session\n" if $DEBUG > 1;
 256     my $cache = new FS::ClientAPI_SessionCache( {
 257       'namespace' => 'FS::ClientAPI::MyAccount',
 258     } );
 259     $session = $cache->get($packet->{'customer_session_id'});
 260     if ( $session ) {
 261       my $custnum = $session->{'custnum'};
 262       my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum });
 263       return { 'error' => "Can't find your customer record" } unless $cust_main;
 264       $agentnum = $cust_main->agentnum;
 265     } else {
 266       return { 'error' => "Can't resume session" }; #better error message
 267     }
 268     warn "$me done loading customer session\n" if $DEBUG > 1;
 269
 270   }
 271
 272   $signup_info->{'part_pkg'} = [];
 273
 274   if ( $packet->{'reg_code'} ) {
 275
 276     warn "$me setting package list via reg_code\n" if $DEBUG > 1;
 277
 278     $signup_info->{'part_pkg'} =
 279       [ map { { 'payby'       => [ $_->payby ],
 280                 'freq_pretty' => $_->freq_pretty,
 281                 'options'     => { $_->options },
 282                 %{$_->hashref}
 283               };
 284             }
 285           grep { $_->svcpart($svc_x) }
 286           map { $_->part_pkg }
 287             qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 288                                     'agentnum' => $agentnum,              } )
 289
 290       ];
 291
 292     $signup_info->{'error'} = 'Unknown registration code'
 293       unless @{ $signup_info->{'part_pkg'} };
 294
 295     warn "$me done setting package list via reg_code\n" if $DEBUG > 1;
 296
 297   } elsif ( $packet->{'promo_code'} ) {
 298
 299     warn "$me setting package list via promo_code\n" if $DEBUG > 1;
 300
 301     $signup_info->{'part_pkg'} =
 302       [ map { { 'payby'   => [ $_->payby ],
 303                 'freq_pretty' => $_->freq_pretty,
 304                 'options'     => { $_->options },
 305                 %{$_->hashref}
 306             } }
 307           grep { $_->svcpart($svc_x) }
 308             qsearch( 'part_pkg', { 'promo_code' => {
 309                                      op=>'ILIKE',
 310                                      value=>$packet->{'promo_code'}
 311                                    },
 312                                    'disabled'   => '',                  } )
 313       ];
 314
 315     $signup_info->{'error'} = 'Unknown promotional code'
 316       unless @{ $signup_info->{'part_pkg'} };
 317
 318     warn "$me done setting package list via promo_code\n" if $DEBUG > 1;
 319   }
 320
 321   if ( $agentnum ) {
 322
 323     warn "$me setting agent-specific payment flag\n" if $DEBUG > 1;
 324     my $agent = qsearchs('agent', { 'agentnum' => $agentnum } )
 325       or return { 'error' => "Self-service agent #$agentnum does not exist" };
 326     warn "$me has agent $agent\n" if $DEBUG > 1;
 327     my @paybys = @{ $signup_info->{'payby'} };
 328     $signup_info->{'hide_payment_fields'} = [];
 329
 330     my $gatewaynum = $conf->config('selfservice-payment_gateway');
 331     my $force_gateway;
 332     if ( $gatewaynum ) {
 333       $force_gateway = qsearchs('payment_gateway', { gatewaynum => $gatewaynum });
 334       warn "using forced gateway #$gatewaynum - " .
 335         $force_gateway->gateway_username . '@' . $force_gateway->gateway_module
 336         if $DEBUG > 1;
 337       die "configured gatewaynum $gatewaynum not found!" if !$force_gateway;
 338     }
 339     foreach my $payby (@paybys) {
 340       warn "$me checking $payby payment fields\n" if $DEBUG > 1;
 341       my $hide = 0;
 342       if ( FS::payby->realtime($payby) ) {
 343         my $gateway = $force_gateway ||
 344           $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 345                                    'nofatal' => 1,
 346                                  );
 347         if ( $gateway && $gateway->gateway_namespace
 348                     eq 'Business::OnlineThirdPartyPayment'
 349            ) {
 350           warn "$me hiding $payby payment fields\n" if $DEBUG > 1;
 351           $hide = 1;
 352         }
 353       }
 354       push @{$signup_info->{'hide_payment_fields'}}, $hide;
 355     } # foreach $payby
 356     warn "$me done setting agent-specific payment flag\n" if $DEBUG > 1;
 357
 358     warn "$me setting agent-specific package list\n" if $DEBUG > 1;
 359     $signup_info->{'part_pkg'} = $signup_info->{'agentnum2part_pkg'}{$agentnum}
 360       unless @{ $signup_info->{'part_pkg'} };
 361     warn "$me done setting agent-specific package list\n" if $DEBUG > 1;
 362
 363     warn "$me setting agent-specific adv. source list\n" if $DEBUG > 1;
 364     $signup_info->{'part_referral'} =
 365       [
 366         map { $_->hashref }
 367           qsearch( {
 368                      'table'     => 'part_referral',
 369                      'hashref'   => { 'disabled' => '' },
 370                      'extra_sql' => "AND (    agentnum = $agentnum  ".
 371                                     "      OR agentnum IS NULL    ) ",
 372                    },
 373                  )
 374       ];
 375     warn "$me done setting agent-specific adv. source list\n" if $DEBUG > 1;
 376
 377     $signup_info->{'agent_name'} = $agent->agent;
 378
 379     $signup_info->{'company_name'} = $conf->config('company_name', $agentnum);
 380
 381     #some of the above could probably be cached, too
 382
 383     my $signup_info_cache_agent = $cache->get("signup_info_cache_agent$agentnum");
 384
 385     if ( $signup_info_cache_agent ) {
 386
 387       warn "$me loading cached signup info for agentnum $agentnum\n"
 388         if $DEBUG > 1;
 389
 390     } else {
 391
 392       warn "$me populating signup info cache for agentnum $agentnum\n"
 393         if $DEBUG > 1;
 394
 395       $signup_info_cache_agent = {
 396         #( map { $_ => scalar( $conf->config($_, $agentnum) ) }
 397         #  qw( company_name ) ),
 398         ( map { $_ => scalar( $conf->config("selfservice-$_", $agentnum ) ) }
 399           qw( body_bgcolor box_bgcolor menu_bgcolor ) ),
 400         ( map { $_ => join("\n", $conf->config("selfservice-$_", $agentnum ) ) }
 401           qw( head body_header body_footer ) ),
 402         ( map { $_ => join("\n", $conf->config("signup_server-$_", $agentnum ) ) }
 403           qw( terms_of_service ) ),
 404
 405         ( map { $_ => scalar($conf->exists($_, $agentnum)) }
 406           qw(cust_main-require_phone agent-ship_address) ),
 407       };
 408
 409       if ( $signup_info_cache_agent->{'agent-ship_address'}
 410            && $agent->agent_cust_main ) {
 411
 412         my $cust_main = $agent->agent_cust_main;
 413         my $location = $cust_main->ship_location;
 414         $signup_info_cache_agent->{"ship_$_"} = $location->get($_)
 415           foreach qw( address1 city county state zip country );
 416
 417       }
 418
 419       $cache->set("signup_info_cache_agent$agentnum", $signup_info_cache_agent);
 420
 421     }
 422
 423     $signup_info->{$_} = $signup_info_cache_agent->{$_}
 424       foreach keys %$signup_info_cache_agent;
 425
 426   }
 427   # else {
 428   # delete $signup_info->{'part_pkg'};
 429   #}
 430
 431   warn "$me sorting package list\n" if $DEBUG > 1;
 432   $signup_info->{'part_pkg'} = [ sort { $a->{pkg} cmp $b->{pkg} }  # case?
 433                                       @{ $signup_info->{'part_pkg'} }
 434                                ];
 435   warn "$me done sorting package list\n" if $DEBUG > 1;
 436
 437   if ( exists $packet->{'session_id'} ) {
 438     my $agent_signup_info = { %$signup_info };
 439     delete $agent_signup_info->{agentnum2part_pkg};
 440     $agent_signup_info->{'agent'} = $session->{'agent'};
 441     return $agent_signup_info;
 442   }
 443   elsif ( exists $packet->{'keys'} ) {
 444     my @keys = @{ $packet->{'keys'} };
 445     return { map { $_ => $signup_info->{$_} } @keys };
 446   }
 447   else {
 448     return $signup_info;
 449   }
 450
 451 }
 452
 453 sub domain_select_hash {
 454   my $packet = shift;
 455
 456   my $response = {};
 457
 458   if ($packet->{pkgpart}) {
 459     my $part_pkg = qsearchs('part_pkg' => { 'pkgpart' => $packet->{pkgpart} } );
 460     #$packet->{svcpart} = $part_pkg->svcpart('svc_acct')
 461     $packet->{svcpart} = $part_pkg->svcpart
 462       if $part_pkg;
 463   }
 464
 465   if ($packet->{svcpart}) {
 466     my $part_svc = qsearchs('part_svc' => { 'svcpart' => $packet->{svcpart} } );
 467     $response->{'domsvc'} = $part_svc->part_svc_column('domsvc')->columnvalue
 468       if ($part_svc && $part_svc->part_svc_column('domsvc')->columnflag  eq 'D');
 469   }
 470
 471   $response->{'domains'}
 472     = { domain_select_hash FS::svc_acct( map { $_ => $packet->{$_} }
 473                                                  qw(svcpart pkgnum)
 474                                        ) };
 475
 476   $response;
 477 }
 478
 479 sub new_customer {
 480   my $packet = shift;
 481
 482   my $conf = new FS::Conf;
 483   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
 484
 485   if ( $svc_x eq 'svc_acct' ) {
 486
 487     #things that aren't necessary in base class, but are for signup server
 488       #return "Passwords don't match"
 489       #  if $hashref->{'_password'} ne $hashref->{'_password2'}
 490     return { 'error' => gettext('empty_password') }
 491       unless length($packet->{'_password'});
 492     # a bit inefficient for large numbers of pops
 493     return { 'error' => gettext('no_access_number_selected') }
 494       unless $packet->{'popnum'} || !scalar(qsearch('svc_acct_pop',{} ));
 495
 496   }
 497   elsif ( $svc_x eq 'svc_pbx' ) {
 498     #possibly some validation will be needed
 499   }
 500
 501   my $agentnum;
 502   if ( exists $packet->{'session_id'} ) {
 503     my $cache = new FS::ClientAPI_SessionCache( {
 504       'namespace' => 'FS::ClientAPI::Agent',
 505     } );
 506     my $session = $cache->get($packet->{'session_id'});
 507     if ( $session ) {
 508       $agentnum = $session->{'agentnum'};
 509     } else {
 510       return { 'error' => "Can't resume session" }; #better error message
 511     }
 512   } else {
 513     $agentnum = $packet->{agentnum}
 514                 || $conf->config('signup_server-default_agentnum');
 515   }
 516
 517   my ($bill_hash, $ship_hash);
 518   foreach my $f (FS::cust_main->location_fields) {
 519     # avoid having to change this in front-end code
 520     $bill_hash->{$f} = $packet->{"bill_$f"} || $packet->{$f};
 521     $ship_hash->{$f} = $packet->{"ship_$f"};
 522   }
 523
 524   #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
 525   # common that are still here and library them.
 526
 527   my %cust_main = (
 528     'agentnum' => $agentnum,
 529     'refnum'   => $packet->{refnum}
 530                   || $conf->config('signup_server-default_refnum'),
 531     'tagnum'   => [ FS::part_tag->default_tags ],
 532
 533     ( map { $_ => $packet->{$_} } qw(
 534             salesnum
 535             ss stateid stateid_state
 536
 537             payby
 538             payinfo paycvv paydate payname paystate paytype
 539             paystart_month paystart_year payissue
 540             payip
 541
 542             referral_custnum comments
 543           )
 544     ),
 545
 546   );
 547
 548   my $template_custnum = $conf->config('signup_server-prepaid-template-custnum');
 549   my $cust_main;
 550   if ( $template_custnum && $packet->{prepaid_shortform} ) {
 551
 552     my $template_cust = qsearchs('cust_main', { 'custnum' => $template_custnum } );
 553     return { 'error' => 'Configuration error' } unless $template_cust;
 554     $cust_main = new FS::cust_main ( {
 555       %cust_main,
 556       map { $_ => $template_cust->$_ } qw(
 557         last first company daytime night fax mobile
 558       ),
 559     } );
 560
 561     $bill_hash = { $template_cust->bill_location->location_hash };
 562     $ship_hash = { $template_cust->ship_location->location_hash };
 563
 564   } else {
 565
 566     $cust_main = new FS::cust_main ( {
 567       %cust_main,
 568       map { $_ => $packet->{$_} } qw(
 569         last first company daytime night fax mobile
 570         override_ban_warn
 571       ),
 572     } );
 573   }
 574
 575   my $bill_location = FS::cust_location->new($bill_hash);
 576   my $ship_location;
 577   my $agent = qsearchs('agent', { 'agentnum' => $agentnum } );
 578   if ( $conf->exists('agent-ship_address', $agentnum)
 579     && $agent->agent_custnum ) {
 580
 581     my $agent_cust_main = $agent->agent_cust_main;
 582     my $prefix = length($agent_cust_main->ship_last) ? 'ship_' : '';
 583     $ship_location = FS::cust_location->new({
 584         $agent_cust_main->ship_location->location_hash
 585     });
 586
 587   }
 588   # we don't have an equivalent of the "same" checkbox in selfservice
 589   # so is there a ship address, and if so, is it different from the billing
 590   # address?
 591   elsif ( length($ship_hash->{address1}) > 0 and
 592           grep { $bill_hash->{$_} ne $ship_hash->{$_} } keys(%$ship_hash)
 593          ) {
 594
 595     $ship_location = FS::cust_location->new( $ship_hash );
 596
 597   }
 598   else {
 599     $ship_location = $bill_location;
 600   }
 601
 602   $cust_main->set('bill_location' => $bill_location);
 603   $cust_main->set('ship_location' => $ship_location);
 604
 605   return { 'error' => "Illegal payment type" }
 606     unless grep { $_ eq $packet->{'payby'} }
 607                 $conf->config('signup_server-payby');
 608
 609   if (FS::payby->realtime($packet->{payby})
 610     and not $conf->exists('signup_server-third_party_as_card')) {
 611     my $payby = $packet->{payby};
 612
 613     my $agent = qsearchs('agent', { 'agentnum' => $agentnum });
 614     return { 'error' => "Unknown reseller" }
 615       unless $agent;
 616
 617     my $gw;
 618     my $gatewaynum = $conf->config('selfservice-payment_gateway');
 619     if ( $gatewaynum ) {
 620       $gw = qsearchs('payment_gateway', { gatewaynum => $gatewaynum });
 621       die "configured gatewaynum $gatewaynum not found!" if !$gw;
 622     }
 623     else {
 624       $gw = $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 625                                      'nofatal' => 1,
 626                                     );
 627     }
 628
 629     $cust_main->payby('BILL')   # MCRD better?  no, that's for something else
 630       if $gw && $gw->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 631   }
 632
 633   return { 'error' => "CVV2 is required" }
 634     if $cust_main->payby =~ /^(CARD|DCRD)$/
 635     && ! $cust_main->paycvv
 636     && $conf->exists('signup-require_cvv');
 637
 638   $cust_main->payinfo($cust_main->daytime)
 639     if $cust_main->payby eq 'LECB' && ! $cust_main->payinfo;
 640
 641   my @invoicing_list = $packet->{'invoicing_list'}
 642                          ? split( /\s*\,\s*/, $packet->{'invoicing_list'} )
 643                          : ();
 644
 645   my %insert_options = ();
 646
 647   my @exempt_groups = grep /\S/, $conf->config('tax-cust_exempt-groups');
 648   my @tax_exempt = grep { $packet->{"tax_$_"} eq 'Y' } @exempt_groups;
 649   $insert_options{'tax_exemption'} = {
 650     map { $_ => $packet->{"tax_$_".'_num'} } @tax_exempt
 651   };
 652
 653   $packet->{'pkgpart'} =~ /^(\d+)$/ or '' =~ /^()$/;
 654   my $pkgpart = $1;
 655   return { 'error' => 'Please select a package' } unless $pkgpart; #msgcat
 656
 657   my $part_pkg =
 658     qsearchs( 'part_pkg', { 'pkgpart' => $pkgpart } )
 659       or return { 'error' => "WARNING: unknown pkgpart: $pkgpart" };
 660   my $svcpart = $part_pkg->svcpart($svc_x);
 661
 662   my $reg_code = '';
 663   if ( $packet->{'reg_code'} ) {
 664     $reg_code = qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 665                                         'agentnum' => $agentnum,             } )
 666       or return { 'error' => 'Unknown registration code' };
 667   }
 668
 669   my $cust_pkg = new FS::cust_pkg ( {
 670     #later#'custnum' => $custnum,
 671     'pkgpart'    => $packet->{'pkgpart'},
 672     'promo_code' => $packet->{'promo_code'},
 673     'reg_code'   => $packet->{'reg_code'},
 674   } );
 675   #my $error = $cust_pkg->check;
 676   #return { 'error' => $error } if $error;
 677
 678   #should be all auto-magic and shit
 679   my @svc = ();
 680   if ( $svc_x eq 'svc_acct' ) {
 681
 682     my $svc = new FS::svc_acct {
 683       'svcpart'   => $svcpart,
 684       map { $_ => $packet->{$_} }
 685         qw( username _password sec_phrase popnum domsvc ),
 686     };
 687
 688     my @acct_snarf;
 689     my $snarfnum = 1;
 690     while (    exists($packet->{"snarf_machine$snarfnum"})
 691             && length($packet->{"snarf_machine$snarfnum"}) ) {
 692       my $acct_snarf = new FS::acct_snarf ( {
 693         'machine'   => $packet->{"snarf_machine$snarfnum"},
 694         'protocol'  => $packet->{"snarf_protocol$snarfnum"},
 695         'username'  => $packet->{"snarf_username$snarfnum"},
 696         '_password' => $packet->{"snarf_password$snarfnum"},
 697       } );
 698       $snarfnum++;
 699       push @acct_snarf, $acct_snarf;
 700     }
 701     $svc->child_objects( \@acct_snarf );
 702     push @svc, $svc;
 703
 704   } elsif ( $svc_x eq 'svc_phone' ) {
 705
 706     push @svc, new FS::svc_phone ( {
 707       'svcpart' => $svcpart,
 708        map { $_ => $packet->{$_} }
 709          qw( countrycode phonenum sip_password pin ),
 710     } );
 711
 712   } elsif ( $svc_x eq 'svc_pbx' ) {
 713
 714     push @svc, new FS::svc_pbx ( {
 715         'svcpart' => $svcpart,
 716         map { $_ => $packet->{$_} }
 717           qw( id title ),
 718         } );
 719
 720   } else {
 721     die "unknown signup service $svc_x";
 722   }
 723
 724   if ($packet->{'mac_addr'} && $conf->exists('signup_server-mac_addr_svcparts'))
 725   {
 726
 727     my %mac_addr_svcparts = map { $_ => 1 }
 728                             $conf->config('signup_server-mac_addr_svcparts');
 729     my @pkg_svc = grep { $_->quantity && $mac_addr_svcparts{$_->svcpart} }
 730                   $cust_pkg->part_pkg->pkg_svc;
 731
 732     return { 'error' => 'No service defined to assign mac address' }
 733       unless @pkg_svc;
 734
 735     my $svc = new FS::svc_acct {
 736       'svcpart'   => $pkg_svc[0]->svcpart, #multiple matches? alas..
 737       'username'  => $packet->{'mac_addr'},
 738       '_password' => '', #blank as requested (set passwordmin to 0)
 739     };
 740
 741     push @svc, $svc;
 742
 743   }
 744
 745   foreach my $svc ( @svc ) {
 746     my $y = $svc->setdefault; # arguably should be in new method
 747     return { 'error' => $y } if $y && !ref($y);
 748     #$error = $svc->check;
 749     #return { 'error' => $error } if $error;
 750   }
 751
 752   #setup a job dependancy to delay provisioning
 753   my $placeholder = new FS::queue ( {
 754     'job'    => 'FS::ClientAPI::Signup::__placeholder',
 755     'status' => 'locked',
 756   } );
 757   my $error = $placeholder->insert;
 758   return { 'error' => $error } if $error;
 759
 760   use Tie::RefHash;
 761   tie my %hash, 'Tie::RefHash';
 762   %hash = ( $cust_pkg => \@svc );
 763   #msgcat
 764   $error = $cust_main->insert(
 765     \%hash,
 766     \@invoicing_list,
 767     'depend_jobnum' => $placeholder->jobnum,
 768      %insert_options,
 769   );
 770   if ( $error ) {
 771     my $perror = $placeholder->delete;
 772     $error .= " (Additionally, error removing placeholder: $perror)" if $perror;
 773     return { 'error' => $error };
 774   }
 775
 776   if ( $conf->exists('signup_server-realtime') ) {
 777
 778     #warn "$me Billing customer...\n" if $Debug;
 779
 780     my $bill_error = $cust_main->bill( 'depend_jobnum'=>$placeholder->jobnum );
 781     #warn "$me error billing new customer: $bill_error"
 782     #  if $bill_error;
 783
 784     $bill_error = $cust_main->apply_payments_and_credits;
 785     #warn "$me error applying payments and credits for".
 786     #     " new customer: $bill_error"
 787     #  if $bill_error;
 788
 789     unless ( $packet->{payby} eq 'PREPAY' ) {
 790       $bill_error = $cust_main->realtime_collect(
 791          method        => FS::payby->payby2bop( $packet->{payby} ),
 792          depend_jobnum => $placeholder->jobnum,
 793          selfservice   => 1,
 794       );
 795       #warn "$me error collecting from new customer: $bill_error"
 796       #  if $bill_error;
 797     }
 798
 799     if ($bill_error && ref($bill_error) eq 'HASH') {
 800       return { 'error' => '_collect',
 801                ( map { $_ => $bill_error->{$_} }
 802                  qw(popup_url reference collectitems)
 803                ),
 804                amount => $cust_main->balance,
 805              };
 806     }
 807
 808     $bill_error = $cust_main->apply_payments_and_credits;
 809     #warn "$me error applying payments and credits for".
 810     #     " new customer: $bill_error"
 811     #  if $bill_error;
 812
 813     if ( $cust_main->balance > 0 ) {
 814
 815       #this makes sense.  credit is "un-doing" the invoice
 816       $cust_main->credit( $cust_main->balance, 'signup server decline',
 817                           'reason_type' => $conf->config('signup_credit_type'),
 818                         );
 819       $cust_main->apply_credits;
 820
 821       #should check list for errors...
 822       #$cust_main->suspend;
 823       local $FS::svc_Common::noexport_hack = 1;
 824       $cust_main->cancel('quiet'=>1);
 825
 826       my $perror = $placeholder->depended_delete;
 827       warn "error removing provisioning jobs after decline: $perror" if $perror;
 828       unless ( $perror ) {
 829         $perror = $placeholder->delete;
 830         warn "error removing placeholder after decline: $perror" if $perror;
 831       }
 832
 833       return { 'error' => '_decline' };
 834     }
 835
 836   }
 837
 838   if ( $reg_code ) {
 839     $error = $reg_code->delete;
 840     return { 'error' => $error } if $error;
 841   }
 842
 843   $error = $placeholder->delete;
 844   return { 'error' => $error } if $error;
 845
 846   if ( $conf->exists('signup-duplicate_cc-warn_hours') ) {
 847     my $hours = $conf->config('signup-duplicate_cc-warn_hours');
 848     my $ban = new FS::banned_pay $cust_main->_new_banned_pay_hashref;
 849     $ban->end_date( int( time + $hours*3600 ) );
 850     $ban->bantype('warn');
 851     $ban->reason('signup-duplicate_cc-warn_hours');
 852     $error = $ban->insert;
 853     warn "WARNING: error inserting temporary banned_pay for ".
 854          " signup-duplicate_cc-warn_hours (proceeding anyway): $error"
 855       if $error;
 856   }
 857
 858   my %return = ( 'error'          => '',
 859                  'signup_service' => $svc_x,
 860                  'custnum'        => $cust_main->custnum,
 861                );
 862
 863   if ( $svc[0] ) {
 864
 865     $return{'svcnum'} = $svc[0]->svcnum;
 866
 867     if ( $svc_x eq 'svc_acct' ) {
 868       $return{$_} = $svc[0]->$_() for qw( username _password );
 869     } elsif ( $svc_x eq 'svc_phone' ) {
 870       $return{$_} = $svc[0]->$_() for qw(countrycode phonenum sip_password pin);
 871     } elsif ( $svc_x eq 'svc_pbx' ) {
 872       #$return{$_} = $svc[0]->$_() for qw( ) #nothing yet
 873      } else {
 874       return {'error' => "configuration error: unknown signup service $svc_x"};
 875       #die "unknown signup service $svc_x";
 876       # return an error that's visible to someone somewhere
 877     }
 878
 879   }
 880
 881   return \%return;
 882
 883 }
 884
 885 #false laziness w/ above
 886 # fresh restart to support "free account" portals with 3.x/4.x-style
 887 #  addressless accounts
 888 # and a contact (for self-service login)
 889 sub new_customer_minimal {
 890   my $packet = shift;
 891
 892   my $conf = new FS::Conf;
 893   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
 894
 895   if ( $svc_x eq 'svc_acct' ) {
 896
 897     #things that aren't necessary in base class, but are for signup server
 898       #return "Passwords don't match"
 899       #  if $hashref->{'_password'} ne $hashref->{'_password2'}
 900     return { 'error' => gettext('empty_password') }
 901       unless length($packet->{'_password'});
 902     # a bit inefficient for large numbers of pops
 903     return { 'error' => gettext('no_access_number_selected') }
 904       unless $packet->{'popnum'} || !scalar(qsearch('svc_acct_pop',{} ));
 905
 906   }
 907   elsif ( $svc_x eq 'svc_pbx' ) {
 908     #possibly some validation will be needed
 909   }
 910
 911   my $agentnum;
 912   if ( exists $packet->{'session_id'} ) {
 913     my $cache = new FS::ClientAPI_SessionCache( {
 914       'namespace' => 'FS::ClientAPI::Agent',
 915     } );
 916     my $session = $cache->get($packet->{'session_id'});
 917     if ( $session ) {
 918       $agentnum = $session->{'agentnum'};
 919     } else {
 920       return { 'error' => "Can't resume session" }; #better error message
 921     }
 922   } else {
 923     $agentnum = $packet->{agentnum}
 924                 || $conf->config('signup_server-default_agentnum');
 925   }
 926
 927   #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
 928   # common that are still here and library them.
 929
 930   my $cust_main = new FS::cust_main ( {
 931       'agentnum' => $agentnum,
 932       'refnum'   => $packet->{refnum}
 933                     || $conf->config('signup_server-default_refnum'),
 934       'tagnum'   => [ FS::part_tag->default_tags ],
 935
 936       map { $_ => $packet->{$_} } qw(
 937         salesnum
 938         last first company daytime night fax mobile
 939         ss
 940       ),
 941
 942   } );
 943
 944   if ( grep length($packet->{$_}), FS::cust_main->location_fields ) {
 945     my $bill_hash;
 946     foreach my $f (FS::cust_main->location_fields) {
 947       $bill_hash->{$f} =  $packet->{$f};
 948     }
 949     my $bill_location = FS::cust_location->new($bill_hash);
 950     $cust_main->set('bill_location' => $bill_location);
 951     $cust_main->set('ship_location' => $bill_location);
 952   }
 953
 954   my @invoicing_list = $packet->{'invoicing_list'}
 955                          ? split( /\s*\,\s*/, $packet->{'invoicing_list'} )
 956                          : ();
 957
 958   use Tie::RefHash;
 959   tie my %hash, 'Tie::RefHash', ();
 960   my @svc = ();
 961
 962   $packet->{'pkgpart'} =~ /^(\d+)$/ or '' =~ /^()$/;
 963   my $pkgpart = $1;
 964
 965   if ( $pkgpart ) {
 966
 967     my $part_pkg =
 968       qsearchs( 'part_pkg', { 'pkgpart' => $pkgpart } )
 969         or return { 'error' => "WARNING: unknown pkgpart: $pkgpart" };
 970     my $svcpart = $part_pkg->svcpart($svc_x);
 971
 972     my $cust_pkg = new FS::cust_pkg ( {
 973       #later#'custnum' => $custnum,
 974       'pkgpart'    => $packet->{'pkgpart'},
 975     } );
 976     #my $error = $cust_pkg->check;
 977     #return { 'error' => $error } if $error;
 978
 979     #should be all auto-magic and shit
 980     if ( $svc_x eq 'svc_acct' ) {
 981
 982       my $svc = new FS::svc_acct {
 983         'svcpart'   => $svcpart,
 984         map { $_ => $packet->{$_} }
 985           qw( username _password sec_phrase popnum domsvc ),
 986       };
 987
 988       push @svc, $svc;
 989
 990     } elsif ( $svc_x eq 'svc_phone' ) {
 991
 992       push @svc, new FS::svc_phone ( {
 993         'svcpart' => $svcpart,
 994          map { $_ => $packet->{$_} }
 995            qw( countrycode phonenum sip_password pin ),
 996       } );
 997
 998     } elsif ( $svc_x eq 'svc_pbx' ) {
 999
1000       push @svc, new FS::svc_pbx ( {
1001           'svcpart' => $svcpart,
1002           map { $_ => $packet->{$_} }
1003             qw( id title ),
1004           } );
1005
1006     } else {
1007       die "unknown signup service $svc_x";
1008     }
1009
1010     foreach my $svc ( @svc ) {
1011       my $y = $svc->setdefault; # arguably should be in new method
1012       return { 'error' => $y } if $y && !ref($y);
1013       #$error = $svc->check;
1014       #return { 'error' => $error } if $error;
1015     }
1016
1017     use Tie::RefHash;
1018     tie my %hash, 'Tie::RefHash';
1019     $hash{ $cust_pkg } = \@svc;
1020
1021   }
1022
1023   my %opt = ();
1024   if ( $invoicing_list[0] && $packet->{'_password'} ) {
1025     $opt{'contact'} = [
1026       new FS::contact { 'first'        => $cust_main->first,
1027                         'last'         => $cust_main->get('last'),
1028                         '_password'    => $packet->{'_password'},
1029                         'emailaddress' => $invoicing_list[0],
1030                         'selfservice_access' => 'Y',
1031                       }
1032     ];
1033   }
1034
1035   my $error = $cust_main->insert(
1036     \%hash,
1037     \@invoicing_list,
1038     %opt,
1039   );
1040   return { 'error' => $error } if $error;
1041
1042   my $session = { 'custnum' => $cust_main->custnum };
1043
1044   my $session_id;
1045   do {
1046     $session_id = sha512_hex(time(). {}. rand(). $$)
1047   } until ( ! defined _myaccount_cache->get($session_id) ); #just in case
1048
1049   _myaccount_cache->set( $session_id, $session, '1 hour' ); # 1 hour?
1050
1051   my %return = ( 'error'          => '',
1052                  'signup_service' => $svc_x,
1053                  'custnum'        => $cust_main->custnum,
1054                  'session_id'     => $session_id,
1055                );
1056
1057   if ( $svc[0] ) {
1058
1059     $return{'svcnum'} = $svc[0]->svcnum;
1060
1061     if ( $svc_x eq 'svc_acct' ) {
1062       $return{$_} = $svc[0]->$_() for qw( username _password );
1063     } elsif ( $svc_x eq 'svc_phone' ) {
1064       $return{$_} = $svc[0]->$_() for qw(countrycode phonenum sip_password pin);
1065     } elsif ( $svc_x eq 'svc_pbx' ) {
1066       #$return{$_} = $svc[0]->$_() for qw( ) #nothing yet
1067      } else {
1068       return {'error' => "configuration error: unknown signup service $svc_x"};
1069       #die "unknown signup service $svc_x";
1070       # return an error that's visible to someone somewhere
1071     }
1072
1073   }
1074
1075   return \%return;
1076
1077 }
1078
1079 use vars qw( $myaccount_cache );
1080 sub _myaccount_cache {
1081   $myaccount_cache ||= new FS::ClientAPI_SessionCache( {
1082                          'namespace' => 'FS::ClientAPI::MyAccount',
1083                        } );
1084 }
1085
1086 sub capture_payment {
1087   my $packet = shift;
1088
1089   warn "$me capture_payment called on $packet\n" if $DEBUG;
1090
1091   ###
1092   # identify processor/gateway from called back URL
1093   ###
1094
1095   my $conf = new FS::Conf;
1096
1097   my $payment_gateway;
1098   if ( my $gwnum = $conf->config('selfservice-payment_gateway') ) {
1099     $payment_gateway = qsearchs('payment_gateway', { 'gatewaynum' => $gwnum })
1100       or die "configured gatewaynum $gwnum not found!";
1101   }
1102   else {
1103     my $url = $packet->{url};
1104
1105     $payment_gateway = qsearchs('payment_gateway',
1106         { 'gateway_callback_url' => popurl(0, $url) }
1107       );
1108     if (!$payment_gateway) {
1109
1110       my ( $processor, $login, $password, $action, @bop_options ) =
1111         $conf->config('business-onlinepayment');
1112       $action ||= 'normal authorization';
1113       pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
1114       die "No real-time processor is enabled - ".
1115           "did you set the business-onlinepayment configuration value?\n"
1116         unless $processor;
1117
1118       $payment_gateway = new FS::payment_gateway( {
1119         gateway_namespace => $conf->config('business-onlinepayment-namespace'),
1120         gateway_module    => $processor,
1121         gateway_username  => $login,
1122         gateway_password  => $password,
1123         gateway_action    => $action,
1124         options   => [ ( @bop_options ) ],
1125       });
1126     }
1127   }
1128
1129   die "No real-time third party processor is enabled - ".
1130       "did you set the business-onlinepayment configuration value?\n*"
1131     unless $payment_gateway->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
1132
1133   ###
1134   # locate pending transaction
1135   ###
1136
1137   eval "use Business::OnlineThirdPartyPayment";
1138   die $@ if $@;
1139
1140   my $transaction =
1141     new Business::OnlineThirdPartyPayment( $payment_gateway->gateway_module,
1142                                            @{ [ $payment_gateway->options ] },
1143                                          );
1144
1145   my $paypendingnum = $transaction->reference($packet->{data});
1146
1147   my $cust_pay_pending =
1148     qsearchs('cust_pay_pending', { paypendingnum => $paypendingnum } );
1149
1150   unless ($cust_pay_pending) {
1151     my $bill_error = "No payment is being processed with id $paypendingnum".
1152                      "; Transaction aborted.";
1153     return { error => '_decline', bill_error => $bill_error };
1154   }
1155
1156   if ($cust_pay_pending->status ne 'thirdparty') {
1157     my $bill_error = "Payment with id $paypendingnum is not thirdparty, but ".
1158                      $cust_pay_pending->status.  "; Transaction aborted.";
1159     return { error => '_decline', bill_error => $bill_error };
1160   }
1161
1162   my $cust_main = $cust_pay_pending->cust_main;
1163   if ( $packet->{cancel} ) {
1164     # the user has chosen not to make this payment
1165     # (probably should be a separate API call, but I don't want to duplicate
1166     # all of the above...which should eventually go away)
1167     my $error = $cust_pay_pending->delete;
1168     # don't show any errors related to this; they're not meaningful
1169     warn "error canceling pending payment $paypendingnum: $error\n" if $error;
1170     return { 'error'      => '_cancel',
1171              'session_id' => $cust_pay_pending->session_id };
1172   } else {
1173     # create the payment
1174     my $bill_error =
1175       $cust_main->realtime_botpp_capture( $cust_pay_pending,
1176         %{$packet->{data}},
1177         apply => 1,
1178     );
1179
1180     return { 'error'      => ( $bill_error->{bill_error} ? '_decline' : '' ),
1181              %$bill_error,
1182            };
1183   }
1184
1185 }
1186
1187 1;