DBSchema/Column.pm

   1 package DBIx::DBSchema::Column;
   2
   3 use strict;
   4 use vars qw($VERSION);
   5 use Carp;
   6 use DBIx::DBSchema::_util qw(_load_driver _dbh);
   7
   8 $VERSION = '0.10';
   9
  10 =head1 NAME
  11
  12 DBIx::DBSchema::Column - Column objects
  13
  14 =head1 SYNOPSIS
  15
  16   use DBIx::DBSchema::Column;
  17
  18   #named params with a hashref (preferred)
  19   $column = new DBIx::DBSchema::Column ( {
  20     'name'    => 'column_name',
  21     'type'    => 'varchar'
  22     'null'    => 'NOT NULL',
  23     'length'  => 64,
  24     'default' => '',
  25     'local'   => '',
  26   } );
  27
  28   #list
  29   $column = new DBIx::DBSchema::Column ( $name, $sql_type, $nullability, $length, $default, $local );
  30
  31   $name = $column->name;
  32   $column->name( 'name' );
  33
  34   $sql_type = $column->type;
  35   $column->type( 'sql_type' );
  36
  37   $null = $column->null;
  38   $column->null( 'NULL' );
  39   $column->null( 'NOT NULL' );
  40   $column->null( '' );
  41
  42   $length = $column->length;
  43   $column->length( '10' );
  44   $column->length( '8,2' );
  45
  46   $default = $column->default;
  47   $column->default( 'Roo' );
  48
  49   $sql_line = $column->line;
  50   $sql_line = $column->line($datasrc);
  51
  52   $sql_add_column = $column->sql_add_column;
  53   $sql_add_column = $column->sql_add_column($datasrc);
  54
  55 =head1 DESCRIPTION
  56
  57 DBIx::DBSchema::Column objects represent columns in tables (see
  58 L<DBIx::DBSchema::Table>).
  59
  60 =head1 METHODS
  61
  62 =over 4
  63
  64 =item new HASHREF
  65
  66 =item new [ name [ , type [ , null [ , length  [ , default [ , local ] ] ] ] ] ]
  67
  68 Creates a new DBIx::DBSchema::Column object.  Takes a hashref of named
  69 parameters, or a list.  B<name> is the name of the column.  B<type> is the SQL
  70 data type.  B<null> is the nullability of the column (intrepreted using Perl's
  71 rules for truth, with one exception: `NOT NULL' is false).  B<length> is the
  72 SQL length of the column.  B<default> is the default value of the column.
  73 B<local> is reserved for database-specific information.
  74
  75 Note: If you pass a scalar reference as the B<default> rather than a scalar value, it will be dereferenced and quoting will be forced off.  This can be used to pass SQL functions such as C<$now()> or explicit empty strings as C<''> as
  76 defaults.
  77
  78 =cut
  79
  80 sub new {
  81   my $proto = shift;
  82   my $class = ref($proto) || $proto;
  83
  84   my $self;
  85   if ( ref($_[0]) ) {
  86     $self = shift;
  87   } else {
  88     #carp "Old-style $class creation without named parameters is deprecated!";
  89     #croak "FATAL: old-style $class creation no longer supported;".
  90     #      " use named parameters";
  91
  92     $self = { map { $_ => shift } qw(name type null length default local) };
  93   }
  94
  95   #croak "Illegal name: ". $self->{'name'}
  96   #  if grep $self->{'name'} eq $_, @reserved_words;
  97
  98   $self->{'null'} =~ s/^NOT NULL$//i;
  99   $self->{'null'} = 'NULL' if $self->{'null'};
 100
 101   bless ($self, $class);
 102
 103 }
 104
 105 =item name [ NAME ]
 106
 107 Returns or sets the column name.
 108
 109 =cut
 110
 111 sub name {
 112   my($self,$value)=@_;
 113   if ( defined($value) ) {
 114   #croak "Illegal name: $name" if grep $name eq $_, @reserved_words;
 115     $self->{'name'} = $value;
 116   } else {
 117     $self->{'name'};
 118   }
 119 }
 120
 121 =item type [ TYPE ]
 122
 123 Returns or sets the column type.
 124
 125 =cut
 126
 127 sub type {
 128   my($self,$value)=@_;
 129   if ( defined($value) ) {
 130     $self->{'type'} = $value;
 131   } else {
 132     $self->{'type'};
 133   }
 134 }
 135
 136 =item null [ NULL ]
 137
 138 Returns or sets the column null flag (the empty string is equivalent to
 139 `NOT NULL')
 140
 141 =cut
 142
 143 sub null {
 144   my($self,$value)=@_;
 145   if ( defined($value) ) {
 146     $value =~ s/^NOT NULL$//i;
 147     $value = 'NULL' if $value;
 148     $self->{'null'} = $value;
 149   } else {
 150     $self->{'null'};
 151   }
 152 }
 153
 154 =item length [ LENGTH ]
 155
 156 Returns or sets the column length.
 157
 158 =cut
 159
 160 sub length {
 161   my($self,$value)=@_;
 162   if ( defined($value) ) {
 163     $self->{'length'} = $value;
 164   } else {
 165     $self->{'length'};
 166   }
 167 }
 168
 169 =item default [ LOCAL ]
 170
 171 Returns or sets the default value.
 172
 173 =cut
 174
 175 sub default {
 176   my($self,$value)=@_;
 177   if ( defined($value) ) {
 178     $self->{'default'} = $value;
 179   } else {
 180     $self->{'default'};
 181   }
 182 }
 183
 184
 185 =item local [ LOCAL ]
 186
 187 Returns or sets the database-specific field.
 188
 189 =cut
 190
 191 sub local {
 192   my($self,$value)=@_;
 193   if ( defined($value) ) {
 194     $self->{'local'} = $value;
 195   } else {
 196     $self->{'local'};
 197   }
 198 }
 199
 200 =item table_obj [ TABLE_OBJ ]
 201
 202 Returns or sets the table object (see L<DBIx::DBSchema::Table>).  Typically
 203 set internally when a column object is added to a table object.
 204
 205 =cut
 206
 207 sub table_obj {
 208   my($self,$value)=@_;
 209   if ( defined($value) ) {
 210     $self->{'table_obj'} = $value;
 211   } else {
 212     $self->{'table_obj'};
 213   }
 214 }
 215
 216 =item table_name
 217
 218 Returns the table name, or the empty string if this column has not yet been
 219 assigned to a table.
 220
 221 =cut
 222
 223 sub table_name {
 224   my $self = shift;
 225   $self->{'table_obj'} ? $self->{'table_obj'}->name : '';
 226 }
 227
 228 =item line [ DATABASE_HANDLE | DATA_SOURCE [ USERNAME PASSWORD [ ATTR ] ] ]
 229
 230 Returns an SQL column definition.
 231
 232 The data source can be specified by passing an open DBI database handle, or by
 233 passing the DBI data source name, username and password.
 234
 235 Although the username and password are optional, it is best to call this method
 236 with a database handle or data source including a valid username and password -
 237 a DBI connection will be opened and the quoting and type mapping will be more
 238 reliable.
 239
 240 If passed a DBI data source (or handle) such as `DBI:mysql:database' or
 241 `DBI:Pg:dbname=database', will use syntax specific to that database engine.
 242 Currently supported databases are MySQL and PostgreSQL.  Non-standard syntax
 243 for other engines (if applicable) may also be supported in the future.
 244
 245 =cut
 246
 247 sub line {
 248   my($self, $dbh) = ( shift, _dbh(@_) );
 249
 250   my $driver = $dbh ? _load_driver($dbh) : '';
 251
 252   ##
 253   # type mapping
 254   ##
 255
 256   my %typemap;
 257   %typemap = eval "\%DBIx::DBSchema::DBD::${driver}::typemap" if $driver;
 258   my $type = defined( $typemap{uc($self->type)} )
 259     ? $typemap{uc($self->type)}
 260     : $self->type;
 261
 262   ##
 263   # set default for the callback...
 264   ##
 265
 266   my $default;
 267   my $orig_default = $self->default;
 268   if ( defined($self->default) && !ref($self->default) && $self->default ne ''
 269        && ref($dbh)
 270        # false laziness: nicked from FS::Record::_quote
 271        && ( $self->default !~ /^\-?\d+(\.\d+)?$/
 272             || $type =~ /(char|binary|blob|text)$/i
 273           )
 274   ) {
 275     $default = $dbh->quote($self->default);
 276   } else {
 277     $default = ref($self->default) ? ${$self->default} : $self->default;
 278   }
 279   $self->default($default);
 280
 281   ##
 282   # callback into the database-specific driver
 283   ##
 284
 285   my $dbd = "DBIx::DBSchema::DBD::$driver";
 286   my $hashref = $dbd->column_callback( $dbh, $self->table_name, $self );
 287
 288   $self->default($orig_default);
 289
 290   $type = $hashref->{'effective_type'}
 291     if $hashref->{'effective_type'};
 292
 293   my $null = $self->null;
 294
 295   #we seem to do this for mysql/Pg/SQLite, i think this should be the default
 296   #add something to $hashref if drivers need to overrdide?
 297   $null ||= "NOT NULL";
 298
 299   $null =~ s/^NULL$// unless $hashref->{'explicit_null'};
 300
 301   $default = $hashref->{'effective_default'}
 302     if $hashref->{'effective_default'};
 303
 304   my $local = $self->local;
 305   $local = $hashref->{'effective_local'}
 306     if $hashref->{'effective_local'};
 307
 308   ##
 309   # return column line
 310   ##
 311
 312   join(' ',
 313     $self->name,
 314     $type. ( ( defined($self->length) && $self->length )
 315              ? '('.$self->length.')'
 316              : ''
 317            ),
 318     $null,
 319     ( ( defined($default) && $default ne '' )
 320       ? 'DEFAULT '. $default
 321       : ''
 322     ),
 323     ( defined($local) ? $local : ''),
 324   );
 325
 326 }
 327
 328 =item sql_add_column [ DBH ]
 329
 330 Returns a list of SQL statements to add this column to an existing table.  (To
 331 create a new table, see L<DBIx::DBSchema::Table/sql_create_table> instead.)
 332
 333 The data source can be specified by passing an open DBI database handle, or by
 334 passing the DBI data source name, username and password.
 335
 336 Although the username and password are optional, it is best to call this method
 337 with a database handle or data source including a valid username and password -
 338 a DBI connection will be opened and the quoting and type mapping will be more
 339 reliable.
 340
 341 If passed a DBI data source (or handle) such as `DBI:Pg:dbname=database', will
 342 use PostgreSQL-specific syntax.  Non-standard syntax for other engines (if
 343 applicable) may also be supported in the future.
 344
 345 =cut
 346
 347 sub sql_add_column {
 348   my($self, $dbh) = ( shift, _dbh(@_) );
 349
 350   die "$self: this column is not assigned to a table"
 351     unless $self->table_name;
 352
 353   my $driver = $dbh ? _load_driver($dbh) : '';
 354
 355   my @sql = ();
 356   my $table = $self->table_name;
 357
 358   my $dbd = "DBIx::DBSchema::DBD::$driver";
 359   my $hashref = $dbd->add_column_callback( $dbh, $table, $self );
 360
 361   my $real_type = '';
 362   if ( $hashref->{'effective_type'} ) {
 363     $real_type = $self->type;
 364     $self->type($hashref->{'effective_type'});
 365   }
 366
 367   my $real_null = undef;
 368   if ( exists($hashref->{'effective_null'}) ) {
 369     $real_null = $self->null;
 370     $self->type($hashref->{'effective_type'});
 371   }
 372
 373   push @sql, "ALTER TABLE $table ADD COLUMN ". $self->line($dbh);
 374
 375   push @sql, @{ $hashref->{'sql_after'} } if $hashref->{'sql_after'};
 376
 377   push @sql, "ALTER TABLE $table ADD PRIMARY KEY ( ".
 378              $self->table_obj->primary_key. " )"
 379     if $self->name eq $self->table_obj->primary_key;
 380
 381   $self->type($real_type) if $real_type;
 382   $self->null($real_null) if defined $real_null;
 383
 384   @sql;
 385
 386 }
 387
 388 =item sql_alter_column PROTOTYPE_COLUMN  [ DATABASE_HANDLE | DATA_SOURCE [ USERNAME PASSWORD [ ATTR ] ] ]
 389
 390 Returns a list of SQL statements to alter this column so that it is identical
 391 to the provided prototype column, also a DBIx::DBSchema::Column object.
 392
 393  #Optionally, the data source can be specified by passing an open DBI database
 394  #handle, or by passing the DBI data source name, username and password.
 395  #
 396  #If passed a DBI data source (or handle) such as `DBI:Pg:dbname=database', will
 397  #use PostgreSQL-specific syntax.  Non-standard syntax for other engines (if
 398  #applicable) may also be supported in the future.
 399  #
 400  #If not passed a data source (or handle), or if there is no driver for the
 401  #specified database, will attempt to use generic SQL syntax.
 402
 403
 404 Or should, someday.  Right now it knows how to change NOT NULL into NULL and
 405 vice-versa.
 406
 407 =cut
 408
 409 sub sql_alter_column {
 410   my( $self, $new, $dbh ) = ( shift, shift, _dbh(@_) );
 411
 412   my $table = $self->table_name;
 413   die "$self: this column is not assigned to a table"
 414     unless $table;
 415
 416   my $name = $self->name;
 417
 418   my $driver = $dbh ? _load_driver($dbh) : '';
 419
 420   my @sql = ();
 421
 422   my $dbd = "DBIx::DBSchema::DBD::$driver";
 423   my $hashref = $dbd->alter_column_callback( $dbh, $table, $self, $new );
 424
 425   # change the name...
 426
 427   # change the type...
 428
 429   if ( $hashref->{'sql_alter_null' } ) {
 430
 431     push @sql, $hashref->{'sql_alter_null'};
 432
 433   } else {
 434
 435     # change nullability from NOT NULL to NULL
 436     if ( ! $self->null && $new->null ) {
 437
 438       push @sql, "ALTER TABLE $table ALTER COLUMN $name DROP NOT NULL";
 439
 440     }
 441
 442     # change nullability from NULL to NOT NULL...
 443     # this one could be more complicated, need to set a DEFAULT value and update
 444     # the table first...
 445     if ( $self->null && ! $new->null ) {
 446
 447       push @sql, "ALTER TABLE $table ALTER COLUMN $name SET NOT NULL";
 448
 449     }
 450
 451   }
 452
 453   # change other stuff...
 454
 455   @sql;
 456
 457 }
 458 =item sql_drop_column [ DBH ]
 459
 460 Returns a list of SQL statements to drop this column from an existing table.
 461
 462 The optional database handle or DBI data source/username/password is not yet
 463 used.
 464
 465 =cut
 466
 467 sub sql_drop_column {
 468  my( $self, $dbh ) = ( shift, _dbh(@_) );
 469
 470  my $table = $self->table_name;
 471  my $name = $self->name;
 472
 473  ("ALTER TABLE $table DROP COLUMN $name"); # XXX what about indexes???
 474 }
 475
 476 =back
 477
 478 =head1 AUTHOR
 479
 480 Ivan Kohler <ivan-dbix-dbschema@420.am>
 481
 482 =head1 COPYRIGHT
 483
 484 Copyright (c) 2000-2006 Ivan Kohler
 485 Copyright (c) 2007 Freeside Internet Services, Inc.
 486 All rights reserved.
 487 This program is free software; you can redistribute it and/or modify it under
 488 the same terms as Perl itself.
 489
 490 =head1 BUGS
 491
 492 The new() method should warn that
 493 "Old-style $class creation without named parameters is deprecated!"
 494
 495 Better documentation is needed for sql_add_column
 496
 497 line() and sql_add_column() hav database-specific foo that should be abstracted
 498 into the DBIx::DBSchema:DBD:: modules.
 499
 500 =head1 SEE ALSO
 501
 502 L<DBIx::DBSchema::Table>, L<DBIx::DBSchema>, L<DBIx::DBSchema::DBD>, L<DBI>
 503
 504 =cut
 505
 506 1;
 507