+ my $error = $self->replace;
+ if ( $old_status eq 'rated' and $status ne 'done' ) {
+ # deallocate any usage
+ foreach (qsearch('cdr_cust_pkg_usage', {acctid => $self->acctid})) {
+ my $cust_pkg_usage = $_->cust_pkg_usage;
+ $cust_pkg_usage->set('minutes', $cust_pkg_usage->minutes + $_->minutes);
+ $error ||= $cust_pkg_usage->replace || $_->delete;
+ }
+ }
+ $error;
+}
+
+=item set_status_and_rated_price STATUS RATED_PRICE [ SVCNUM [ OPTION => VALUE ... ] ]
+
+Sets the status and rated price.
+
+Available options are: inbound, rated_pretty_dst, rated_regionname,
+rated_seconds, rated_minutes, rated_granularity, rated_ratedetailnum,
+rated_classnum, rated_ratename.
+
+If there is an error, returns the error, otherwise returns false.
+
+=cut
+
+sub set_status_and_rated_price {
+ my($self, $status, $rated_price, $svcnum, %opt) = @_;
+
+ if ($opt{'inbound'}) {
+
+ my $term = $self->cdr_termination( 1 ); #1: inbound
+ my $error;
+ if ( $term ) {
+ warn "replacing existing cdr status (".$self->acctid.")\n" if $term;
+ $error = $term->delete;
+ return $error if $error;
+ }
+ $term = FS::cdr_termination->new({
+ acctid => $self->acctid,
+ termpart => 1,
+ rated_price => $rated_price,
+ status => $status,
+ });
+ $term->rated_seconds($opt{rated_seconds}) if exists($opt{rated_seconds});
+ $term->rated_minutes($opt{rated_minutes}) if exists($opt{rated_minutes});
+ $term->svcnum($svcnum) if $svcnum;
+ return $term->insert;
+
+ } else {
+
+ $self->freesidestatus($status);
+ $self->rated_price($rated_price);
+ $self->$_($opt{$_})
+ foreach grep exists($opt{$_}), map "rated_$_",
+ qw( pretty_dst regionname seconds minutes granularity
+ ratedetailnum classnum ratename );
+ $self->svcnum($svcnum) if $svcnum;
+ return $self->replace();
+
+ }
+}
+
+=item parse_number [ OPTION => VALUE ... ]
+
+Returns two scalars, the countrycode and the rest of the number.
+
+Options are passed as name-value pairs. Currently available options are:
+
+=over 4
+
+=item column
+
+The column containing the number to be parsed. Defaults to dst.
+
+=item international_prefix
+
+The digits for international dialing. Defaults to '011' The value '+' is
+always recognized.
+
+=item domestic_prefix
+
+The digits for domestic long distance dialing. Defaults to '1'
+
+=back
+
+=cut
+
+sub parse_number {
+ my ($self, %options) = @_;
+
+ my $field = $options{column} || 'dst';
+ my $intl = $options{international_prefix} || '011';
+ my $countrycode = '';
+ my $number = $self->$field();
+
+ my $to_or_from = 'concerning';
+ $to_or_from = 'from' if $field eq 'src';
+ $to_or_from = 'to' if $field eq 'dst';
+ warn "parsing call $to_or_from $number\n" if $DEBUG;
+
+ #remove non-phone# stuff and whitespace
+ $number =~ s/\s//g;
+# my $proto = '';
+# $dest =~ s/^(\w+):// and $proto = $1; #sip:
+# my $siphost = '';
+# $dest =~ s/\@(.*)$// and $siphost = $1; # @10.54.32.1, @sip.example.com
+
+ if ( $number =~ /^$intl(((\d)(\d))(\d))(\d+)$/
+ || $number =~ /^\+(((\d)(\d))(\d))(\d+)$/
+ )
+ {
+
+ my( $three, $two, $one, $u1, $u2, $rest ) = ( $1,$2,$3,$4,$5,$6 );
+ #first look for 1 digit country code
+ if ( qsearch('rate_prefix', { 'countrycode' => $one } ) ) {
+ $countrycode = $one;
+ $number = $u1.$u2.$rest;
+ } elsif ( qsearch('rate_prefix', { 'countrycode' => $two } ) ) { #or 2
+ $countrycode = $two;
+ $number = $u2.$rest;
+ } else { #3 digit country code
+ $countrycode = $three;
+ $number = $rest;
+ }
+
+ } else {
+ my $domestic_prefix =
+ exists($options{domestic_prefix}) ? $options{domestic_prefix} : '';
+ $countrycode = length($domestic_prefix) ? $domestic_prefix : '1';
+ $number =~ s/^$countrycode//;# if length($number) > 10;
+ }
+
+ return($countrycode, $number);
+
+}
+
+=item rate [ OPTION => VALUE ... ]
+
+Rates this CDR according and sets the status to 'rated'.
+
+Available options are: part_pkg, svcnum, plan_included_min,
+detail_included_min_hashref.
+
+part_pkg is required.
+
+If svcnum is specified, will also associate this CDR with the specified svcnum.
+
+plan_included_min should be set to a scalar reference of the number of
+included minutes and will be decremented by the rated minutes of this
+CDR.
+
+detail_included_min_hashref should be set to an empty hashref at the
+start of a month's rating and then preserved across CDRs.
+
+=cut
+
+sub rate {
+ my( $self, %opt ) = @_;
+ my $part_pkg = $opt{'part_pkg'} or return "No part_pkg specified";
+
+ if ( $DEBUG > 1 ) {
+ warn "rating CDR $self\n".
+ join('', map { " $_ => ". $self->{$_}. "\n" } keys %$self );
+ }
+
+ my $rating_method = $part_pkg->option_cacheable('rating_method') || 'prefix';
+ my $method = "rate_$rating_method";
+ $self->$method(%opt);
+}
+
+#here?
+our %interval_cache = (); # for timed rates
+
+sub rate_prefix {
+ my( $self, %opt ) = @_;
+ my $part_pkg = $opt{'part_pkg'} or return "No part_pkg specified";
+ my $cust_pkg = $opt{'cust_pkg'};
+
+ my $da_rewrote = 0;
+ # this will result in those CDRs being marked as done... is that
+ # what we want?
+ my @dirass = ();
+ if ( $part_pkg->option_cacheable('411_rewrite') ) {
+ my $dirass = $part_pkg->option_cacheable('411_rewrite');
+ $dirass =~ s/\s//g;
+ @dirass = split(',', $dirass);
+ }
+
+ if ( length($self->dst) && grep { $self->dst eq $_ } @dirass ) {
+ $self->dst('411');
+ $da_rewrote = 1;
+ }
+
+ my $reason = $part_pkg->check_chargable( $self,
+ 'da_rewrote' => $da_rewrote,
+ );
+ if ( $reason ) {
+ warn "not charging for CDR ($reason)\n" if $DEBUG;
+ return $self->set_status_and_rated_price( 'skipped',
+ 0,
+ $opt{'svcnum'},
+ );
+ }
+
+ if ( $part_pkg->option_cacheable('skip_same_customer')
+ and ! $self->is_tollfree ) {
+ my ($dst_countrycode, $dst_number) = $self->parse_number(
+ column => 'dst',
+ international_prefix => $part_pkg->option_cacheable('international_prefix'),
+ domestic_prefix => $part_pkg->option_cacheable('domestic_prefix'),
+ );
+ my $dst_same_cust = FS::Record->scalar_sql(
+ 'SELECT COUNT(svc_phone.svcnum) AS count '.
+ 'FROM cust_pkg ' .
+ 'JOIN cust_svc USING (pkgnum) ' .
+ 'JOIN svc_phone USING (svcnum) ' .
+ 'WHERE svc_phone.countrycode = ' . dbh->quote($dst_countrycode) .
+ ' AND svc_phone.phonenum = ' . dbh->quote($dst_number) .
+ ' AND cust_pkg.custnum = ' . $cust_pkg->custnum,
+ );
+ if ( $dst_same_cust > 0 ) {
+ warn "not charging for CDR (same source and destination customer)\n" if $DEBUG;
+ return $self->set_status_and_rated_price( 'skipped',
+ 0,
+ $opt{'svcnum'},
+ );
+ }
+ }
+
+
+
+
+ ###
+ # look up rate details based on called station id
+ # (or calling station id for toll free calls)
+ ###
+
+ my $eff_ratenum = $self->is_tollfree('accountcode')
+ ? $part_pkg->option_cacheable('accountcode_tollfree_ratenum')
+ : '';
+
+ my( $to_or_from, $column );
+ if(
+ ( $self->is_tollfree
+ && ! $part_pkg->option_cacheable('disable_tollfree')
+ )
+ or ( $eff_ratenum
+ && $part_pkg->option_cacheable('accountcode_tollfree_field') eq 'src'
+ )
+ )
+ { #tollfree call
+ $to_or_from = 'from';
+ $column = 'src';
+ } else { #regular call
+ $to_or_from = 'to';
+ $column = 'dst';
+ }
+
+ #determine the country code
+ my ($countrycode, $number) = $self->parse_number(
+ column => $column,
+ international_prefix => $part_pkg->option_cacheable('international_prefix'),
+ domestic_prefix => $part_pkg->option_cacheable('domestic_prefix'),
+ );
+
+ warn "rating call $to_or_from +$countrycode $number\n" if $DEBUG;
+ my $pretty_dst = "+$countrycode $number";
+ #asterisks here causes inserting the detail to barf, so:
+ $pretty_dst =~ s/\*//g;
+
+ my $ratename = '';
+ my $intrastate_ratenum = $part_pkg->option_cacheable('intrastate_ratenum');
+ if ( $intrastate_ratenum && !$self->is_tollfree ) {
+ $ratename = 'Interstate'; #until proven otherwise
+ # this is relatively easy only because:
+ # -assume all numbers are valid NANP numbers NOT in a fully-qualified format
+ # -disregard toll-free
+ # -disregard private or unknown numbers
+ # -there is exactly one record in rate_prefix for a given NPANXX
+ # -default to interstate if we can't find one or both of the prefixes
+ my (undef, $dstprefix) = $self->parse_number(
+ column => 'dst',
+ international_prefix => $part_pkg->option_cacheable('international_prefix'),
+ domestic_prefix => $part_pkg->option_cacheable('domestic_prefix'),
+ );
+ $dstprefix =~ /^(\d{6})/;
+ $dstprefix = qsearchs('rate_prefix', { 'countrycode' => '1',
+ 'npa' => $1,
+ }) || '';
+ my (undef, $srcprefix) = $self->parse_number(
+ column => 'src',
+ international_prefix => $part_pkg->option_cacheable('international_prefix'),
+ domestic_prefix => $part_pkg->option_cacheable('domestic_prefix'),
+ );
+ $srcprefix =~ /^(\d{6})/;
+ $srcprefix = qsearchs('rate_prefix', { 'countrycode' => '1',
+ 'npa' => $1,
+ }) || '';
+ if ($srcprefix && $dstprefix
+ && $srcprefix->state && $dstprefix->state
+ && $srcprefix->state eq $dstprefix->state) {
+ $eff_ratenum = $intrastate_ratenum;
+ $ratename = 'Intrastate'; # XXX possibly just use the ratename?
+ }
+ }
+
+ $eff_ratenum ||= $part_pkg->option_cacheable('ratenum');
+ my $rate = qsearchs('rate', { 'ratenum' => $eff_ratenum })
+ or die "ratenum $eff_ratenum not found!";
+
+ my @ltime = localtime($self->startdate);
+ my $weektime = $ltime[0] +
+ $ltime[1]*60 + #minutes
+ $ltime[2]*3600 + #hours
+ $ltime[6]*86400; #days since sunday
+ # if there's no timed rate_detail for this time/region combination,
+ # dest_detail returns the default. There may still be a timed rate
+ # that applies after the starttime of the call, so be careful...
+ my $rate_detail = $rate->dest_detail({ 'countrycode' => $countrycode,
+ 'phonenum' => $number,
+ 'weektime' => $weektime,
+ 'cdrtypenum' => $self->cdrtypenum,
+ });
+
+ unless ( $rate_detail ) {
+
+ if ( $part_pkg->option_cacheable('ignore_unrateable') ) {
+
+ if ( $part_pkg->option_cacheable('ignore_unrateable') == 2 ) {
+ # mark the CDR as unrateable
+ return $self->set_status_and_rated_price(
+ 'failed',
+ '',
+ $opt{'svcnum'},
+ );
+ } elsif ( $part_pkg->option_cacheable('ignore_unrateable') == 1 ) {
+ # warn and continue
+ warn "no rate_detail found for CDR.acctid: ". $self->acctid.
+ "; skipping\n";
+ return '';
+
+ } else {
+ die "unknown ignore_unrateable, pkgpart ". $part_pkg->pkgpart;
+ }
+
+ } else {
+
+ die "FATAL: no rate_detail found in ".
+ $rate->ratenum. ":". $rate->ratename. " rate plan ".
+ "for +$countrycode $number (CDR acctid ". $self->acctid. "); ".
+ "add a rate or set ignore_unrateable flag on the package def\n";
+ }
+
+ }
+
+ my $rate_region = $rate_detail->dest_region;
+ my $regionnum = $rate_region->regionnum;
+ warn " found rate for regionnum $regionnum ".
+ "and rate detail $rate_detail\n"
+ if $DEBUG;
+
+ if ( !exists($interval_cache{$regionnum}) ) {
+ my @intervals = (
+ sort { $a->stime <=> $b->stime }
+ map { $_->rate_time->intervals }
+ qsearch({ 'table' => 'rate_detail',
+ 'hashref' => { 'ratenum' => $rate->ratenum },
+ 'extra_sql' => 'AND ratetimenum IS NOT NULL',
+ })
+ );
+ $interval_cache{$regionnum} = \@intervals;
+ warn " cached ".scalar(@intervals)." interval(s)\n"
+ if $DEBUG;
+ }
+
+ ###
+ # find the price and add detail to the invoice
+ ###
+
+ # About this section:
+ # We don't round _anything_ (except granularizing)
+ # until the final $charge = sprintf("%.2f"...).
+
+ my $seconds_left = $part_pkg->option_cacheable('use_duration')
+ ? $self->duration
+ : $self->billsec;
+
+ #no, do this later so it respects (group) included minutes
+ # # charge for the first (conn_sec) seconds
+ # my $seconds = min($seconds_left, $rate_detail->conn_sec);
+ # $seconds_left -= $seconds;
+ # $weektime += $seconds;
+ # my $charge = $rate_detail->conn_charge;
+ my $seconds = 0;
+ my $charge = 0;
+ my $connection_charged = 0;
+
+ my $etime;
+ while($seconds_left) {
+ my $ratetimenum = $rate_detail->ratetimenum; # may be empty
+
+ # find the end of the current rate interval
+ if(@{ $interval_cache{$regionnum} } == 0) {
+ # There are no timed rates in this group, so just stay
+ # in the default rate_detail for the entire duration.
+ # Set an "end" of 1 past the end of the current call.
+ $etime = $weektime + $seconds_left + 1;
+ }
+ elsif($ratetimenum) {
+ # This is a timed rate, so go to the etime of this interval.
+ # If it's followed by another timed rate, the stime of that
+ # interval should match the etime of this one.
+ my $interval = $rate_detail->rate_time->contains($weektime);
+ $etime = $interval->etime;
+ }
+ else {
+ # This is a default rate, so use the stime of the next
+ # interval in the sequence.
+ my $next_int = first { $_->stime > $weektime }
+ @{ $interval_cache{$regionnum} };
+ if ($next_int) {
+ $etime = $next_int->stime;
+ }
+ else {
+ # weektime is near the end of the week, so decrement
+ # it by a full week and use the stime of the first
+ # interval.
+ $weektime -= (3600*24*7);
+ $etime = $interval_cache{$regionnum}->[0]->stime;
+ }
+ }
+
+ my $charge_sec = min($seconds_left, $etime - $weektime);
+
+ $seconds_left -= $charge_sec;
+
+ my $granularity = $rate_detail->sec_granularity;
+
+ my $minutes;
+ if ( $granularity ) { # charge per minute
+ # Round up to the nearest $granularity
+ if ( $charge_sec and $charge_sec % $granularity ) {
+ $charge_sec += $granularity - ($charge_sec % $granularity);
+ }
+ $minutes = $charge_sec / 60; #don't round this
+ }
+ else { # per call
+ $minutes = 1;
+ $seconds_left = 0;
+ }
+
+ $seconds += $charge_sec;
+
+ if ( $rate_detail->min_included ) {
+ # the old, kind of deprecated way to do this:
+ #
+ # The rate detail itself has included minutes. We MUST have a place
+ # to track them.
+ my $included_min = $opt{'detail_included_min_hashref'}
+ or return "unable to rate CDR: rate detail has included minutes, but ".
+ "no detail_included_min_hashref provided.\n";
+
+ # by default, set the included minutes for this region/time to
+ # what's in the rate_detail
+ $included_min->{$regionnum}{$ratetimenum} = $rate_detail->min_included
+ unless exists $included_min->{$regionnum}{$ratetimenum};
+
+ if ( $included_min->{$regionnum}{$ratetimenum} >= $minutes ) {
+ $charge_sec = 0;
+ $included_min->{$regionnum}{$ratetimenum} -= $minutes;
+ } else {
+ $charge_sec -= ($included_min->{$regionnum}{$ratetimenum} * 60);
+ $included_min->{$regionnum}{$ratetimenum} = 0;
+ }
+ } elsif ( $opt{plan_included_min} && ${ $opt{plan_included_min} } > 0 ) {
+ # The package definition has included minutes, but only for in-group
+ # rate details. Decrement them if this is an in-group call.
+ if ( $rate_detail->region_group ) {
+ if ( ${ $opt{'plan_included_min'} } >= $minutes ) {
+ $charge_sec = 0;
+ ${ $opt{'plan_included_min'} } -= $minutes;
+ } else {
+ $charge_sec -= (${ $opt{'plan_included_min'} } * 60);
+ ${ $opt{'plan_included_min'} } = 0;
+ }
+ }
+ } else {
+ # the new way!
+ my $applied_min = $cust_pkg->apply_usage(
+ 'cdr' => $self,
+ 'rate_detail' => $rate_detail,
+ 'minutes' => $minutes
+ );
+ # for now, usage pools deal only in whole minutes
+ $charge_sec -= $applied_min * 60;
+ }
+
+ if ( $charge_sec > 0 ) {
+
+ #NOW do connection charges here... right?
+ #my $conn_seconds = min($seconds_left, $rate_detail->conn_sec);
+ my $conn_seconds = 0;
+ unless ( $connection_charged++ ) { #only one connection charge
+ $conn_seconds = min($charge_sec, $rate_detail->conn_sec);
+ $seconds_left -= $conn_seconds;
+ $weektime += $conn_seconds;
+ $charge += $rate_detail->conn_charge;
+ }
+
+ #should preserve (display?) this
+ if ( $granularity == 0 ) { # per call rate
+ $charge += $rate_detail->min_charge;
+ } else {
+ my $charge_min = ( $charge_sec - $conn_seconds ) / 60;
+ $charge += ($rate_detail->min_charge * $charge_min) if $charge_min > 0; #still not rounded
+ }
+
+ }
+
+ # choose next rate_detail
+ $rate_detail = $rate->dest_detail({ 'countrycode' => $countrycode,
+ 'phonenum' => $number,
+ 'weektime' => $etime,
+ 'cdrtypenum' => $self->cdrtypenum })
+ if($seconds_left);
+ # we have now moved forward to $etime
+ $weektime = $etime;
+
+ } #while $seconds_left
+
+ # this is why we need regionnum/rate_region....
+ warn " (rate region $rate_region)\n" if $DEBUG;
+
+ # NOW round it.
+ my $rounding = $part_pkg->option_cacheable('rounding') || 2;
+ my $sprintformat = '%.'. $rounding. 'f';
+ my $roundup = 10**(-3-$rounding);
+ my $price = sprintf($sprintformat, $charge + $roundup);
+
+ $self->set_status_and_rated_price(
+ 'rated',
+ $price,
+ $opt{'svcnum'},
+ 'rated_pretty_dst' => $pretty_dst,
+ 'rated_regionname' => $rate_region->regionname,
+ 'rated_seconds' => $seconds,
+ 'rated_granularity' => $rate_detail->sec_granularity, #$granularity
+ 'rated_ratedetailnum' => $rate_detail->ratedetailnum,
+ 'rated_classnum' => $rate_detail->classnum, #rated_ratedetailnum?
+ 'rated_ratename' => $ratename, #not rate_detail - Intrastate/Interstate
+ );
+
+}
+
+sub rate_upstream_simple {
+ my( $self, %opt ) = @_;
+
+ $self->set_status_and_rated_price(
+ 'rated',
+ sprintf('%.3f', $self->upstream_price),
+ $opt{'svcnum'},
+ 'rated_classnum' => $self->calltypenum,
+ 'rated_seconds' => $self->billsec,
+ # others? upstream_*_regionname => rated_regionname is possible
+ );
+}
+
+sub rate_single_price {
+ my( $self, %opt ) = @_;
+ my $part_pkg = $opt{'part_pkg'} or return "No part_pkg specified";
+
+ # a little false laziness w/abov
+ # $rate_detail = new FS::rate_detail({sec_granularity => ... }) ?
+
+ my $granularity = length($part_pkg->option_cacheable('sec_granularity'))
+ ? $part_pkg->option_cacheable('sec_granularity')
+ : 60;
+
+ my $seconds = $part_pkg->option_cacheable('use_duration')
+ ? $self->duration
+ : $self->billsec;
+
+ $seconds += $granularity - ( $seconds % $granularity )
+ if $seconds # don't granular-ize 0 billsec calls (bills them)
+ && $granularity # 0 is per call
+ && $seconds % $granularity;
+ my $minutes = $granularity ? ($seconds / 60) : 1;
+
+ my $charge_min = $minutes;
+
+ ${$opt{plan_included_min}} -= $minutes;
+ if ( ${$opt{plan_included_min}} > 0 ) {
+ $charge_min = 0;
+ } else {
+ $charge_min = 0 - ${$opt{plan_included_min}};
+ ${$opt{plan_included_min}} = 0;
+ }
+
+ my $charge =
+ sprintf('%.4f', ( $part_pkg->option_cacheable('min_charge') * $charge_min )
+ + 0.0000000001 ); #so 1.00005 rounds to 1.0001
+
+ $self->set_status_and_rated_price(
+ 'rated',
+ $charge,
+ $opt{'svcnum'},
+ 'rated_granularity' => $granularity,
+ 'rated_seconds' => $seconds,
+ );
+
+}
+
+=item rate_cost
+
+Rates an already-rated CDR according to the cost fields from the rate plan.
+
+Returns the amount.
+
+=cut
+
+sub rate_cost {
+ my $self = shift;
+
+ return 0 unless $self->rated_ratedetailnum;
+
+ my $rate_detail =
+ qsearchs('rate_detail', { 'ratedetailnum' => $self->rated_ratedetailnum } );
+
+ return $rate_detail->min_cost if $self->rated_granularity == 0;
+
+ my $minutes = $self->rated_seconds / 60;
+ my $charge = $rate_detail->conn_cost + $minutes * $rate_detail->min_cost;
+
+ sprintf('%.2f', $charge + .00001 );
+
+}
+
+=item cdr_termination [ TERMPART ]
+
+=cut
+
+sub cdr_termination {
+ my $self = shift;
+
+ if ( scalar(@_) && $_[0] ) {
+ my $termpart = shift;
+
+ qsearchs('cdr_termination', { acctid => $self->acctid,
+ termpart => $termpart,
+ }
+ );
+
+ } else {
+
+ qsearch('cdr_termination', { acctid => $self->acctid, } );
+
+ }
+
projects / freeside.git / blobdiff