FS/FS/cust_main/Location.pm

   1 package FS::cust_main::Location;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me @location_fields );
   5 use FS::Record qw(qsearch qsearchs);
   6 use FS::UID qw(dbh);
   7 use FS::Cursor;
   8 use FS::cust_location;
   9
  10 use Carp qw(carp);
  11
  12 $DEBUG = 0;
  13 $me = '[FS::cust_main::Location]';
  14
  15 my $init = 0;
  16 BEGIN {
  17   # set up accessors for location fields
  18   if (!$init) {
  19     no strict 'refs';
  20     @location_fields =
  21       qw( address1 address2 city county state zip country district
  22         latitude longitude coord_auto censustract censusyear geocode
  23         addr_clean );
  24
  25     foreach my $f (@location_fields) {
  26       *{"FS::cust_main::Location::$f"} = sub {
  27         carp "WARNING: tried to set cust_main.$f with accessor" if (@_ > 1);
  28         shift->bill_location->$f
  29       };
  30       *{"FS::cust_main::Location::ship_$f"} = sub {
  31         carp "WARNING: tried to set cust_main.ship_$f with accessor" if (@_ > 1);
  32         shift->ship_location->$f
  33       };
  34     }
  35     $init++;
  36   }
  37 }
  38
  39 #debugging shim--probably a performance hit, so remove this at some point
  40 sub get {
  41   my $self = shift;
  42   my $field = shift;
  43   if ( $DEBUG and grep (/^(ship_)?($field)$/, @location_fields) ) {
  44     carp "WARNING: tried to get() location field $field";
  45     $self->$field;
  46   }
  47   $self->FS::Record::get($field);
  48 }
  49
  50 =head1 NAME
  51
  52 FS::cust_main::Location - Location-related methods for cust_main
  53
  54 =head1 DESCRIPTION
  55
  56 These methods are available on FS::cust_main objects;
  57
  58 =head1 METHODS
  59
  60 =over 4
  61
  62 =item bill_location
  63
  64 Returns an L<FS::cust_location> object for the customer's billing address.
  65
  66 =cut
  67
  68 sub bill_location {
  69   my $self = shift;
  70   $self->hashref->{bill_location}
  71     ||= FS::cust_location->by_key($self->bill_locationnum)
  72     # degraded mode--let the system keep running during upgrades
  73     ||  FS::cust_location->new({
  74         map { $_ => $self->get($_) } @location_fields
  75       })
  76 }
  77
  78 =item ship_location
  79
  80 Returns an L<FS::cust_location> object for the customer's service address.
  81
  82 =cut
  83
  84 sub ship_location {
  85   my $self = shift;
  86   $self->hashref->{ship_location}
  87     ||= FS::cust_location->by_key($self->ship_locationnum)
  88     ||  FS::cust_location->new({
  89         map { $_ => $self->get('ship_'.$_) || $self->get($_) } @location_fields
  90       })
  91
  92 }
  93
  94 =item location TYPE
  95
  96 An alternative way of saying "bill_location or ship_location, depending on
  97 if TYPE is 'bill' or 'ship'".
  98
  99 =cut
 100
 101 sub location {
 102   my $self = shift;
 103   return $self->bill_location if $_[0] eq 'bill';
 104   return $self->ship_location if $_[0] eq 'ship';
 105   die "bad location type '$_[0]'";
 106 }
 107
 108 =back
 109
 110 =head1 CLASS METHODS
 111
 112 =over 4
 113
 114 =item location_fields
 115
 116 Returns a list of fields found in the location objects.  All of these fields
 117 can be read (but not written) by calling them as methods on the
 118 L<FS::cust_main> object (prefixed with 'ship_' for the service address
 119 fields).
 120
 121 =cut
 122
 123 sub location_fields { @location_fields }
 124
 125 sub _upgrade_data {
 126   my $class = shift;
 127   my %opt = @_;
 128
 129   eval "use FS::contact;
 130         use FS::contact_class;
 131         use FS::contact_phone;
 132         use FS::phone_type";
 133
 134   local $FS::cust_location::import = 1;
 135   local $DEBUG = 0;
 136   my $error;
 137
 138   # Step 0: set up contact classes and phone types
 139   my $service_contact_class =
 140     qsearchs('contact_class', { classname => 'Service'})
 141     || new FS::contact_class { classname => 'Service'};
 142
 143   if ( !$service_contact_class->classnum ) {
 144     warn "Creating service contact class.\n";
 145     $error = $service_contact_class->insert;
 146     die "error creating contact class for Service: $error" if $error;
 147   }
 148   my %phone_type = ( # fudge slightly
 149     daytime => 'Work',
 150     night   => 'Home',
 151     mobile  => 'Mobile',
 152     fax     => 'Fax'
 153   );
 154   my $w = 10;
 155   foreach (keys %phone_type) {
 156     $phone_type{$_} = qsearchs('phone_type', { typename => $phone_type{$_}})
 157                       || new FS::phone_type  { typename => $phone_type{$_},
 158                                                weight   => $w };
 159     # just in case someone still doesn't have these
 160     if ( !$phone_type{$_}->phonetypenum ) {
 161       $error = $phone_type{$_}->insert;
 162       die "error creating phone type '$_': $error" if $error;
 163     }
 164   }
 165
 166   my $num_to_upgrade = FS::cust_main->count('bill_locationnum is null or ship_locationnum is null');
 167   my $num_jobs = FS::queue->count('job = \'FS::cust_main::Location::process_upgrade_location\' and status != \'failed\'');
 168   if ( $num_to_upgrade > 0 ) {
 169     warn "Need to migrate $num_to_upgrade customer locations.\n";
 170
 171     if ( $opt{queue} ) {
 172       if ( $num_jobs > 0 ) {
 173         warn "Upgrade already queued.\n";
 174       } else {
 175         warn "Scheduling upgrade.\n";
 176         my $job = FS::queue->new({ job => 'FS::cust_main::Location::process_upgrade_location' });
 177         $job->insert;
 178       }
 179     } else { #do it now
 180       process_upgrade_location();
 181     }
 182
 183   }
 184   # repair an error in earlier upgrades
 185   if (!FS::upgrade_journal->is_done('cust_location_censustract_repair')
 186        and FS::Conf->new->exists('cust_main-require_censustract') ) {
 187
 188     foreach my $cust_location (
 189       qsearch('cust_location', { 'censustract' => '' })
 190     ) {
 191       my $custnum = $cust_location->custnum;
 192       next if !$custnum; # avoid doing this for prospect locations
 193       my $address1 = $cust_location->address1;
 194       # find the last history record that had that address
 195       my $last_h = qsearchs({
 196           table     => 'h_cust_main',
 197           extra_sql => " WHERE custnum = $custnum AND address1 = ".
 198                         dbh->quote($address1) .
 199                         " AND censustract IS NOT NULL",
 200           order_by  => " ORDER BY history_date DESC LIMIT 1",
 201       });
 202       if (!$last_h) {
 203         # this is normal; just means it never had a census tract before
 204         next;
 205       }
 206       $cust_location->set('censustract' => $last_h->get('censustract'));
 207       $cust_location->set('censusyear'  => $last_h->get('censusyear'));
 208       my $error = $cust_location->replace;
 209       warn "Error setting census tract for customer #$custnum:\n  $error\n"
 210         if $error;
 211     } # foreach $cust_location
 212     FS::upgrade_journal->set_done('cust_location_censustract_repair');
 213   }
 214 }
 215
 216 sub process_upgrade_location {
 217   my $class = shift;
 218
 219   my $dbh = dbh;
 220   local $FS::cust_location::import = 1;
 221   local $FS::UID::AutoCommit = 0;
 222
 223   my $tax_prefix = 'bill_';
 224   if ( FS::Conf->new->exists('tax-ship_address') ) {
 225     $tax_prefix = 'ship_';
 226   }
 227
 228   # load some records that were created during the initial upgrade
 229   my $service_contact_class =
 230     qsearchs('contact_class', { classname => 'Service'});
 231
 232   my %phone_type = (
 233     daytime => 'Work',
 234     night   => 'Home',
 235     mobile  => 'Mobile',
 236     fax     => 'Fax'
 237   );
 238   foreach (keys %phone_type) {
 239     $phone_type{$_} = qsearchs('phone_type', { typename => $phone_type{$_}});
 240   }
 241
 242   my %opt = (
 243     tax_prefix            => $tax_prefix,
 244     service_contact_class => $service_contact_class,
 245     phone_type            => \%phone_type,
 246   );
 247
 248   my $search = FS::Cursor->new('cust_main', { bill_locationnum => '' });
 249   while (my $cust_main = $search->fetch) {
 250     my $error = $cust_main->upgrade_location(%opt);
 251     if ( $error ) {
 252       warn "cust#".$cust_main->custnum.": $error\n";
 253       $dbh->rollback;
 254     } else {
 255       # commit as we go
 256       $dbh->commit;
 257     }
 258   }
 259 }
 260
 261 sub upgrade_location { # instance method
 262   my $cust_main = shift;
 263   my %opt = @_;
 264   my $error;
 265
 266   # Step 1: extract billing and service addresses into cust_location
 267   my $custnum = $cust_main->custnum;
 268   my $bill_location = FS::cust_location->new(
 269     {
 270       custnum => $custnum,
 271       map { $_ => $cust_main->get($_) } location_fields(),
 272     }
 273   );
 274   $bill_location->set('censustract', '');
 275   $bill_location->set('censusyear', '');
 276    # properly goes with ship_location; if they're the same, will be set
 277    # on ship_location before inserting either one
 278   my $ship_location = $bill_location; # until proven otherwise
 279
 280   if ( $cust_main->get('ship_address1') ) {
 281     # detect duplicates
 282     my $same = 1;
 283     foreach (location_fields()) {
 284       if ( length($cust_main->get("ship_$_")) and
 285            $cust_main->get($_) ne $cust_main->get("ship_$_") ) {
 286         $same = 0;
 287       }
 288     }
 289
 290     if ( !$same ) {
 291       $ship_location = FS::cust_location->new(
 292         {
 293           custnum => $custnum,
 294           map { $_ => $cust_main->get("ship_$_") } location_fields()
 295         }
 296       );
 297     } # else it stays equal to $bill_location
 298
 299     # Step 2: Extract shipping address contact fields into contact
 300     my %unlike = map { $_ => 1 }
 301       grep { $cust_main->get($_) ne $cust_main->get("ship_$_") }
 302       qw( last first company daytime night fax mobile );
 303
 304     if ( %unlike ) {
 305       # then there IS a service contact
 306       my $contact = FS::contact->new({
 307         'custnum'     => $custnum,
 308         'classnum'    => $opt{service_contact_class}->classnum,
 309         'locationnum' => $ship_location->locationnum,
 310         'last'        => $cust_main->get('ship_last'),
 311         'first'       => $cust_main->get('ship_first'),
 312       });
 313       if ( !$cust_main->get('ship_last') or !$cust_main->get('ship_first') )
 314       {
 315         warn "customer $custnum has no service contact name; substituting ".
 316              "customer name\n";
 317         $contact->set('last' => $cust_main->get('last'));
 318         $contact->set('first' => $cust_main->get('first'));
 319       }
 320
 321       if ( $unlike{'company'} ) {
 322         # there's no contact.company field, but keep a record of it
 323         $contact->set(comment => 'Company: '.$cust_main->get('ship_company'));
 324       }
 325       $error = $contact->insert;
 326       return "error migrating service contact for customer $custnum: $error"
 327         if $error;
 328
 329       foreach ( grep { $unlike{$_} } qw( daytime night fax mobile ) ) {
 330         my $phone = $cust_main->get("ship_$_");
 331         next if !$phone;
 332         my $contact_phone = FS::contact_phone->new({
 333           'contactnum'    => $contact->contactnum,
 334           'phonetypenum'  => $opt{phone_type}->{$_}->phonetypenum,
 335           FS::contact::_parse_phonestring( $phone )
 336         });
 337         $error = $contact_phone->insert;
 338         return "error migrating service contact phone for customer $custnum: $error"
 339           if $error;
 340         $cust_main->set("ship_$_" => '');
 341       }
 342
 343       $cust_main->set("ship_$_" => '') foreach qw(last first company);
 344     } #if %unlike
 345   } #if ship_address1
 346
 347   # special case: should go with whichever location is used to calculate
 348   # taxes, because that's the one it originally came from
 349   if ( my $geocode = $cust_main->get('geocode') ) {
 350     $bill_location->set('geocode' => '');
 351     $ship_location->set('geocode' => '');
 352
 353     if ( $opt{tax_prefix} eq 'bill_' ) {
 354       $bill_location->set('geocode', $geocode);
 355     } elsif ( $opt{tax_prefix} eq 'ship_' ) {
 356       $ship_location->set('geocode', $geocode);
 357     }
 358   }
 359
 360   # this always goes with the ship_location (whether it's the same as
 361   # bill_location or not)
 362   $ship_location->set('censustract', $cust_main->get('censustract'));
 363   $ship_location->set('censusyear',  $cust_main->get('censusyear'));
 364
 365   $error = $bill_location->insert;
 366   return "error migrating billing address for customer $custnum: $error"
 367     if $error;
 368
 369   $cust_main->set(bill_locationnum => $bill_location->locationnum);
 370
 371   if (!$ship_location->locationnum) {
 372     $error = $ship_location->insert;
 373     return "error migrating service address for customer $custnum: $error"
 374       if $error;
 375   }
 376
 377   $cust_main->set(ship_locationnum => $ship_location->locationnum);
 378
 379   # Step 3: Wipe the migrated fields and update the cust_main
 380
 381   $cust_main->set("ship_$_" => '') foreach location_fields();
 382   $cust_main->set($_ => '') foreach location_fields();
 383
 384   $error = $cust_main->replace;
 385   return "error migrating addresses for customer $custnum: $error"
 386     if $error;
 387
 388   # Step 4: set packages at the "default service location" to ship_location
 389   my $pkg_search =
 390     FS::Cursor->new('cust_pkg', { custnum => $custnum, locationnum => '' });
 391   while (my $cust_pkg = $pkg_search->fetch) {
 392     # not a location change
 393     $cust_pkg->set('locationnum', $cust_main->ship_locationnum);
 394     $error = $cust_pkg->replace;
 395     return "error migrating package ".$cust_pkg->pkgnum.": $error"
 396       if $error;
 397   }
 398   '';
 399
 400 }
 401
 402
 403 =back
 404
 405 =cut
 406
 407 1;