FS/FS/ClientAPI/Signup.pm

   1 package FS::ClientAPI::Signup;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me );
   5 use Data::Dumper;
   6 use Tie::RefHash;
   7 use FS::Conf;
   8 use FS::Record qw(qsearch qsearchs dbdef);
   9 use FS::CGI qw(popurl);
  10 use FS::Msgcat qw(gettext);
  11 use FS::Misc qw(card_types);
  12 use FS::ClientAPI_SessionCache;
  13 use FS::agent;
  14 use FS::cust_main_county;
  15 use FS::part_pkg;
  16 use FS::svc_acct_pop;
  17 use FS::cust_main;
  18 use FS::cust_pkg;
  19 use FS::svc_acct;
  20 use FS::svc_phone;
  21 use FS::acct_snarf;
  22 use FS::queue;
  23 use FS::reg_code;
  24 use FS::payby;
  25 use FS::banned_pay;
  26 use FS::part_tag;
  27
  28 $DEBUG = 0;
  29 $me = '[FS::ClientAPI::Signup]';
  30
  31 sub clear_cache {
  32   warn "$me clear_cache called\n" if $DEBUG;
  33   my $cache = new FS::ClientAPI_SessionCache( {
  34       'namespace' => 'FS::ClientAPI::Signup',
  35   } );
  36   $cache->clear();
  37   return {};
  38 }
  39
  40 sub signup_info {
  41   my $packet = shift;
  42
  43   warn "$me signup_info called on $packet\n" if $DEBUG;
  44
  45   my $conf = new FS::Conf;
  46   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
  47
  48   my $cache = new FS::ClientAPI_SessionCache( {
  49     'namespace' => 'FS::ClientAPI::Signup',
  50   } );
  51   my $signup_info_cache = $cache->get('signup_info_cache');
  52
  53   if ( $signup_info_cache ) {
  54
  55     warn "$me loading cached signup info\n" if $DEBUG > 1;
  56
  57   } else {
  58
  59     warn "$me populating signup info cache\n" if $DEBUG > 1;
  60
  61     my $agentnum2part_pkg =
  62       {
  63         map {
  64           my $agent = $_;
  65           my $href = $agent->pkgpart_hashref;
  66           $agent->agentnum =>
  67             [
  68               map { { 'payby'       => [ $_->payby ],
  69                       'freq_pretty' => $_->freq_pretty,
  70                       'options'     => { $_->options },
  71                       %{$_->hashref}
  72                   } }
  73                 grep { $_->svcpart($svc_x)
  74                        && ( $href->{ $_->pkgpart }
  75                             || ( $_->agentnum
  76                                  && $_->agentnum == $agent->agentnum
  77                                )
  78                           )
  79                      }
  80                   qsearch( 'part_pkg', { 'disabled' => '' } )
  81             ];
  82         } qsearch('agent', { 'disabled' => '' })
  83       };
  84
  85     my $msgcat = { map { $_=>gettext($_) }
  86                        qw( passwords_dont_match invalid_card unknown_card_type
  87                            not_a empty_password illegal_or_empty_text )
  88                  };
  89     warn "msgcat: ". Dumper($msgcat). "\n" if $DEBUG > 2;
  90
  91     my $label = { map { $_ => FS::Msgcat::_gettext($_) }
  92                       qw( stateid stateid_state )
  93                 };
  94     warn "label: ". Dumper($label). "\n" if $DEBUG > 2;
  95
  96     my @agent_fields = qw( agentnum agent );
  97
  98     my @bools = qw( emailinvoiceonly security_phrase );
  99
 100     my @signup_bools = qw( no_company recommend_daytime recommend_email );
 101
 102     my @signup_server_scalars = qw( default_pkgpart default_svcpart default_domsvc );
 103
 104     my @selfservice_textareas = qw( head body_header body_footer );
 105
 106     my @selfservice_scalars = qw(
 107       body_bgcolor box_bgcolor
 108       text_color link_color vlink_color hlink_color alink_color
 109       font title_color title_align title_size menu_bgcolor menu_fontsize
 110     );
 111
 112     #XXX my @selfservice_bools = qw(
 113     #  menu_skipblanks menu_skipheadings menu_nounderline
 114     #);
 115
 116     #my $selfservice_binaries = qw(
 117     #  title_left_image title_right_image
 118     #  menu_top_image menu_body_image menu_bottom_image
 119     #);
 120
 121     $signup_info_cache = {
 122
 123       'cust_main_county' => [ map $_->hashref,
 124                                   qsearch('cust_main_county', {} )
 125                             ],
 126
 127       'agent' => [ map { my $agent = $_;
 128                          +{ map { $_ => $agent->get($_) } @agent_fields }
 129                        }
 130                        qsearch('agent', { 'disabled' => '' } )
 131                  ],
 132
 133       'part_referral' => [ map $_->hashref,
 134                                qsearch('part_referral', { 'disabled' => '' } )
 135                          ],
 136
 137       'agentnum2part_pkg' => $agentnum2part_pkg,
 138
 139       'svc_acct_pop' => [ map $_->hashref, qsearch('svc_acct_pop',{} ) ],
 140
 141       'emailinvoiceonly' => $conf->exists('emailinvoiceonly'),
 142
 143       'security_phrase' => $conf->exists('security_phrase'),
 144
 145       'nomadix' => $conf->exists('signup_server-nomadix'),
 146
 147       'payby' => [ $conf->config('signup_server-payby') ],
 148
 149       'payby_longname' => [ map { FS::payby->longname($_) }
 150                             $conf->config('signup_server-payby') ],
 151
 152       'card_types' => card_types(),
 153
 154       ( map { $_ => $conf->exists("signup-$_") } @signup_bools ),
 155
 156       ( map { $_ => scalar($conf->config("signup_server-$_")) }
 157             @signup_server_scalars
 158       ),
 159
 160       ( map { $_ => join("\n", $conf->config("selfservice-$_")) }
 161             @selfservice_textareas
 162       ),
 163       ( map { $_ => scalar($conf->config("selfservice-$_")) }
 164             @selfservice_scalars
 165       ),
 166
 167       #( map { $_ => scalar($conf->config_binary("selfservice-$_")) }
 168       #      @selfservice_binaries
 169       #),
 170
 171       'agentnum2part_pkg'  => $agentnum2part_pkg,
 172       'svc_acct_pop'       => [ map $_->hashref, qsearch('svc_acct_pop',{} ) ],
 173       'nomadix'            => $conf->exists('signup_server-nomadix'),
 174       'payby'              => [ $conf->config('signup_server-payby') ],
 175       'card_types'         => card_types(),
 176       'paytypes'           => [ @FS::cust_main::paytypes ],
 177       'cvv_enabled'        => 1,
 178       'require_cvv'        => $conf->exists('signup-require_cvv'),
 179       'stateid_enabled'    => $conf->exists('show_stateid'),
 180       'paystate_enabled'   => $conf->exists('show_bankstate'),
 181       'exempt_groups'      => [ grep /\S/, $conf->config('tax-cust_exempt-groups') ],
 182       'ship_enabled'       => 1,
 183       'msgcat'             => $msgcat,
 184       'label'              => $label,
 185       'statedefault'       => scalar($conf->config('statedefault')) || 'CA',
 186       'countrydefault'     => scalar($conf->config('countrydefault')) || 'US',
 187       'refnum'             => scalar($conf->config('signup_server-default_refnum')),
 188       'signup_service'     => $svc_x,
 189       'company_name'       => scalar($conf->config('company_name')),
 190       #per-agent?
 191       'logo'               => scalar($conf->config_binary('logo.png')),
 192       'prepaid_template_custnum' => $conf->exists('signup_server-prepaid-template-custnum'),
 193     };
 194
 195     $cache->set('signup_info_cache', $signup_info_cache);
 196
 197   }
 198
 199   my $signup_info = { %$signup_info_cache };
 200   warn "$me signup info loaded\n" if $DEBUG > 1;
 201   warn Dumper($signup_info). "\n" if $DEBUG > 2;
 202
 203   my @addl = qw( signup_server-classnum2 signup_server-classnum3 );
 204
 205   if ( grep { $conf->exists($_) } @addl ) {
 206
 207     $signup_info->{optional_packages} = [];
 208
 209     foreach my $addl ( @addl ) {
 210
 211       warn "$me adding optional package info\n" if $DEBUG > 1;
 212
 213       my $classnum = $conf->config($addl) or next;
 214
 215       my @pkgs = map { {
 216                          'freq_pretty' => $_->freq_pretty,
 217                          'options'     => { $_->options },
 218                          %{ $_->hashref }
 219                        };
 220                      }
 221                      qsearch( 'part_pkg', { classnum => $classnum } );
 222
 223       push @{$signup_info->{optional_packages}}, \@pkgs;
 224
 225       warn "$me done adding opt. package info for $classnum\n" if $DEBUG > 1;
 226
 227     }
 228
 229   }
 230
 231   my $agentnum = $packet->{'agentnum'}
 232                  || $conf->config('signup_server-default_agentnum');
 233   $agentnum =~ /^(\d*)$/ or die "illegal agentnum";
 234   $agentnum = $1;
 235
 236   my $session = '';
 237   if ( exists $packet->{'session_id'} ) {
 238
 239     warn "$me loading agent session\n" if $DEBUG > 1;
 240     my $cache = new FS::ClientAPI_SessionCache( {
 241       'namespace' => 'FS::ClientAPI::Agent',
 242     } );
 243     $session = $cache->get($packet->{'session_id'});
 244     if ( $session ) {
 245       $agentnum = $session->{'agentnum'};
 246     } else {
 247       return { 'error' => "Can't resume session" }; #better error message
 248     }
 249     warn "$me done loading agent session\n" if $DEBUG > 1;
 250
 251   } elsif ( exists $packet->{'customer_session_id'} ) {
 252
 253     warn "$me loading customer session\n" if $DEBUG > 1;
 254     my $cache = new FS::ClientAPI_SessionCache( {
 255       'namespace' => 'FS::ClientAPI::MyAccount',
 256     } );
 257     $session = $cache->get($packet->{'customer_session_id'});
 258     if ( $session ) {
 259       my $custnum = $session->{'custnum'};
 260       my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum });
 261       return { 'error' => "Can't find your customer record" } unless $cust_main;
 262       $agentnum = $cust_main->agentnum;
 263     } else {
 264       return { 'error' => "Can't resume session" }; #better error message
 265     }
 266     warn "$me done loading customer session\n" if $DEBUG > 1;
 267
 268   }
 269
 270   $signup_info->{'part_pkg'} = [];
 271
 272   if ( $packet->{'reg_code'} ) {
 273
 274     warn "$me setting package list via reg_code\n" if $DEBUG > 1;
 275
 276     $signup_info->{'part_pkg'} =
 277       [ map { { 'payby'       => [ $_->payby ],
 278                 'freq_pretty' => $_->freq_pretty,
 279                 'options'     => { $_->options },
 280                 %{$_->hashref}
 281               };
 282             }
 283           grep { $_->svcpart($svc_x) }
 284           map { $_->part_pkg }
 285             qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 286                                     'agentnum' => $agentnum,              } )
 287
 288       ];
 289
 290     $signup_info->{'error'} = 'Unknown registration code'
 291       unless @{ $signup_info->{'part_pkg'} };
 292
 293     warn "$me done setting package list via reg_code\n" if $DEBUG > 1;
 294
 295   } elsif ( $packet->{'promo_code'} ) {
 296
 297     warn "$me setting package list via promo_code\n" if $DEBUG > 1;
 298
 299     $signup_info->{'part_pkg'} =
 300       [ map { { 'payby'   => [ $_->payby ],
 301                 'freq_pretty' => $_->freq_pretty,
 302                 'options'     => { $_->options },
 303                 %{$_->hashref}
 304             } }
 305           grep { $_->svcpart($svc_x) }
 306             qsearch( 'part_pkg', { 'promo_code' => {
 307                                      op=>'ILIKE',
 308                                      value=>$packet->{'promo_code'}
 309                                    },
 310                                    'disabled'   => '',                  } )
 311       ];
 312
 313     $signup_info->{'error'} = 'Unknown promotional code'
 314       unless @{ $signup_info->{'part_pkg'} };
 315
 316     warn "$me done setting package list via promo_code\n" if $DEBUG > 1;
 317   }
 318
 319   if ( $agentnum ) {
 320
 321     warn "$me setting agent-specific payment flag\n" if $DEBUG > 1;
 322     my $agent = qsearchs('agent', { 'agentnum' => $agentnum } )
 323       or return { 'error' => "Self-service agent #$agentnum does not exist" };
 324     warn "$me has agent $agent\n" if $DEBUG > 1;
 325     my @paybys = @{ $signup_info->{'payby'} };
 326     $signup_info->{'hide_payment_fields'} = [];
 327
 328     my $gatewaynum = $conf->config('selfservice-payment_gateway');
 329     my $force_gateway;
 330     if ( $gatewaynum ) {
 331       $force_gateway = qsearchs('payment_gateway', { gatewaynum => $gatewaynum });
 332       warn "using forced gateway #$gatewaynum - " .
 333         $force_gateway->gateway_username . '@' . $force_gateway->gateway_module
 334         if $DEBUG > 1;
 335       die "configured gatewaynum $gatewaynum not found!" if !$force_gateway;
 336     }
 337     foreach my $payby (@paybys) {
 338       warn "$me checking $payby payment fields\n" if $DEBUG > 1;
 339       my $hide = 0;
 340       if ( FS::payby->realtime($payby) ) {
 341         my $gateway = $force_gateway ||
 342           $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 343                                    'nofatal' => 1,
 344                                  );
 345         if ( $gateway && $gateway->gateway_namespace
 346                     eq 'Business::OnlineThirdPartyPayment'
 347            ) {
 348           warn "$me hiding $payby payment fields\n" if $DEBUG > 1;
 349           $hide = 1;
 350         }
 351       }
 352       push @{$signup_info->{'hide_payment_fields'}}, $hide;
 353     } # foreach $payby
 354     warn "$me done setting agent-specific payment flag\n" if $DEBUG > 1;
 355
 356     warn "$me setting agent-specific package list\n" if $DEBUG > 1;
 357     $signup_info->{'part_pkg'} = $signup_info->{'agentnum2part_pkg'}{$agentnum}
 358       unless @{ $signup_info->{'part_pkg'} };
 359     warn "$me done setting agent-specific package list\n" if $DEBUG > 1;
 360
 361     warn "$me setting agent-specific adv. source list\n" if $DEBUG > 1;
 362     $signup_info->{'part_referral'} =
 363       [
 364         map { $_->hashref }
 365           qsearch( {
 366                      'table'     => 'part_referral',
 367                      'hashref'   => { 'disabled' => '' },
 368                      'extra_sql' => "AND (    agentnum = $agentnum  ".
 369                                     "      OR agentnum IS NULL    ) ",
 370                    },
 371                  )
 372       ];
 373     warn "$me done setting agent-specific adv. source list\n" if $DEBUG > 1;
 374
 375     $signup_info->{'agent_name'} = $agent->agent;
 376
 377     $signup_info->{'company_name'} = $conf->config('company_name', $agentnum);
 378
 379     #some of the above could probably be cached, too
 380
 381     my $signup_info_cache_agent = $cache->get("signup_info_cache_agent$agentnum");
 382
 383     if ( $signup_info_cache_agent ) {
 384
 385       warn "$me loading cached signup info for agentnum $agentnum\n"
 386         if $DEBUG > 1;
 387
 388     } else {
 389
 390       warn "$me populating signup info cache for agentnum $agentnum\n"
 391         if $DEBUG > 1;
 392
 393       $signup_info_cache_agent = {
 394         #( map { $_ => scalar( $conf->config($_, $agentnum) ) }
 395         #  qw( company_name ) ),
 396         ( map { $_ => scalar( $conf->config("selfservice-$_", $agentnum ) ) }
 397           qw( body_bgcolor box_bgcolor menu_bgcolor ) ),
 398         ( map { $_ => join("\n", $conf->config("selfservice-$_", $agentnum ) ) }
 399           qw( head body_header body_footer ) ),
 400         ( map { $_ => join("\n", $conf->config("signup_server-$_", $agentnum ) ) }
 401           qw( terms_of_service ) ),
 402
 403         ( map { $_ => scalar($conf->exists($_, $agentnum)) }
 404           qw(cust_main-require_phone agent-ship_address) ),
 405       };
 406
 407       if ( $signup_info_cache_agent->{'agent-ship_address'}
 408            && $agent->agent_cust_main ) {
 409
 410         my $cust_main = $agent->agent_cust_main;
 411         my $location = $cust_main->ship_location;
 412         $signup_info_cache_agent->{"ship_$_"} = $location->get($_)
 413           foreach qw( address1 city county state zip country );
 414
 415       }
 416
 417       $cache->set("signup_info_cache_agent$agentnum", $signup_info_cache_agent);
 418
 419     }
 420
 421     $signup_info->{$_} = $signup_info_cache_agent->{$_}
 422       foreach keys %$signup_info_cache_agent;
 423
 424   }
 425   # else {
 426   # delete $signup_info->{'part_pkg'};
 427   #}
 428
 429   warn "$me sorting package list\n" if $DEBUG > 1;
 430   $signup_info->{'part_pkg'} = [ sort { $a->{pkg} cmp $b->{pkg} }  # case?
 431                                       @{ $signup_info->{'part_pkg'} }
 432                                ];
 433   warn "$me done sorting package list\n" if $DEBUG > 1;
 434
 435   if ( exists $packet->{'session_id'} ) {
 436     my $agent_signup_info = { %$signup_info };
 437     delete $agent_signup_info->{agentnum2part_pkg};
 438     $agent_signup_info->{'agent'} = $session->{'agent'};
 439     return $agent_signup_info;
 440   }
 441   elsif ( exists $packet->{'keys'} ) {
 442     my @keys = @{ $packet->{'keys'} };
 443     return { map { $_ => $signup_info->{$_} } @keys };
 444   }
 445   else {
 446     return $signup_info;
 447   }
 448
 449 }
 450
 451 sub domain_select_hash {
 452   my $packet = shift;
 453
 454   my $response = {};
 455
 456   if ($packet->{pkgpart}) {
 457     my $part_pkg = qsearchs('part_pkg' => { 'pkgpart' => $packet->{pkgpart} } );
 458     #$packet->{svcpart} = $part_pkg->svcpart('svc_acct')
 459     $packet->{svcpart} = $part_pkg->svcpart
 460       if $part_pkg;
 461   }
 462
 463   if ($packet->{svcpart}) {
 464     my $part_svc = qsearchs('part_svc' => { 'svcpart' => $packet->{svcpart} } );
 465     $response->{'domsvc'} = $part_svc->part_svc_column('domsvc')->columnvalue
 466       if ($part_svc && $part_svc->part_svc_column('domsvc')->columnflag  eq 'D');
 467   }
 468
 469   $response->{'domains'}
 470     = { domain_select_hash FS::svc_acct( map { $_ => $packet->{$_} }
 471                                                  qw(svcpart pkgnum)
 472                                        ) };
 473
 474   $response;
 475 }
 476
 477 sub new_customer {
 478   my $packet = shift;
 479
 480   my $conf = new FS::Conf;
 481   my $svc_x = $conf->config('signup_server-service') || 'svc_acct';
 482
 483   if ( $svc_x eq 'svc_acct' ) {
 484
 485     #things that aren't necessary in base class, but are for signup server
 486       #return "Passwords don't match"
 487       #  if $hashref->{'_password'} ne $hashref->{'_password2'}
 488     return { 'error' => gettext('empty_password') }
 489       unless length($packet->{'_password'});
 490     # a bit inefficient for large numbers of pops
 491     return { 'error' => gettext('no_access_number_selected') }
 492       unless $packet->{'popnum'} || !scalar(qsearch('svc_acct_pop',{} ));
 493
 494   }
 495   elsif ( $svc_x eq 'svc_pbx' ) {
 496     #possibly some validation will be needed
 497   }
 498
 499   my $agentnum;
 500   if ( exists $packet->{'session_id'} ) {
 501     my $cache = new FS::ClientAPI_SessionCache( {
 502       'namespace' => 'FS::ClientAPI::Agent',
 503     } );
 504     my $session = $cache->get($packet->{'session_id'});
 505     if ( $session ) {
 506       $agentnum = $session->{'agentnum'};
 507     } else {
 508       return { 'error' => "Can't resume session" }; #better error message
 509     }
 510   } else {
 511     $agentnum = $packet->{agentnum}
 512                 || $conf->config('signup_server-default_agentnum');
 513   }
 514
 515   my ($bill_hash, $ship_hash);
 516   foreach my $f (FS::cust_main->location_fields) {
 517     # avoid having to change this in front-end code
 518     $bill_hash->{$f} = $packet->{"bill_$f"} || $packet->{$f};
 519     $ship_hash->{$f} = $packet->{"ship_$f"};
 520   }
 521
 522   #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
 523   # common that are still here and library them.
 524
 525   my %cust_main = (
 526     'agentnum' => $agentnum,
 527     'refnum'   => $packet->{refnum}
 528                   || $conf->config('signup_server-default_refnum'),
 529     'tagnum'   => [ FS::part_tag->default_tags ],
 530
 531     ( map { $_ => $packet->{$_} } qw(
 532             ss stateid stateid_state
 533
 534             payby
 535             payinfo paycvv paydate payname paystate paytype
 536             paystart_month paystart_year payissue
 537             payip
 538
 539             referral_custnum comments
 540           )
 541     ),
 542
 543   );
 544
 545   my $template_custnum = $conf->config('signup_server-prepaid-template-custnum');
 546   my $cust_main;
 547   if ( $template_custnum && $packet->{prepaid_shortform} ) {
 548
 549     my $template_cust = qsearchs('cust_main', { 'custnum' => $template_custnum } );
 550     return { 'error' => 'Configuration error' } unless $template_cust;
 551     $cust_main = new FS::cust_main ( {
 552       %cust_main,
 553       map { $_ => $template_cust->$_ } qw(
 554         last first company daytime night fax mobile
 555       ),
 556     } );
 557
 558     $bill_hash = { $template_cust->bill_location->location_hash };
 559     $ship_hash = { $template_cust->ship_location->location_hash };
 560
 561   } else {
 562
 563     $cust_main = new FS::cust_main ( {
 564       %cust_main,
 565       map { $_ => $packet->{$_} } qw(
 566         last first company daytime night fax mobile
 567         override_ban_warn
 568       ),
 569     } );
 570   }
 571
 572   my $bill_location = FS::cust_location->new($bill_hash);
 573   my $ship_location;
 574   my $agent = qsearchs('agent', { 'agentnum' => $agentnum } );
 575   if ( $conf->exists('agent-ship_address', $agentnum)
 576     && $agent->agent_custnum ) {
 577
 578     my $agent_cust_main = $agent->agent_cust_main;
 579     my $prefix = length($agent_cust_main->ship_last) ? 'ship_' : '';
 580     $ship_location = FS::cust_location->new({
 581         $agent_cust_main->ship_location->location_hash
 582     });
 583
 584   }
 585   # we don't have an equivalent of the "same" checkbox in selfservice
 586   # so is there a ship address, and if so, is it different from the billing
 587   # address?
 588   elsif ( length($ship_hash->{address1}) > 0 and
 589           grep { $bill_hash->{$_} ne $ship_hash->{$_} } keys(%$ship_hash)
 590          ) {
 591
 592     $ship_location = FS::cust_location->new( $ship_hash );
 593
 594   }
 595   else {
 596     $ship_location = $bill_location;
 597   }
 598
 599   $cust_main->set('bill_location' => $bill_location);
 600   $cust_main->set('ship_location' => $ship_location);
 601
 602   return { 'error' => "Illegal payment type" }
 603     unless grep { $_ eq $packet->{'payby'} }
 604                 $conf->config('signup_server-payby');
 605
 606   if (FS::payby->realtime($packet->{payby})
 607     and not $conf->exists('signup_server-third_party_as_card')) {
 608     my $payby = $packet->{payby};
 609
 610     my $agent = qsearchs('agent', { 'agentnum' => $agentnum });
 611     return { 'error' => "Unknown reseller" }
 612       unless $agent;
 613
 614     my $gw;
 615     my $gatewaynum = $conf->config('selfservice-payment_gateway');
 616     if ( $gatewaynum ) {
 617       $gw = qsearchs('payment_gateway', { gatewaynum => $gatewaynum });
 618       die "configured gatewaynum $gatewaynum not found!" if !$gw;
 619     }
 620     else {
 621       $gw = $agent->payment_gateway( 'method'  => FS::payby->payby2bop($payby),
 622                                      'nofatal' => 1,
 623                                     );
 624     }
 625
 626     $cust_main->payby('BILL')   # MCRD better?
 627       if $gw && $gw->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 628   }
 629
 630   return { 'error' => "CVV2 is required" }
 631     if $cust_main->payby =~ /^(CARD|DCRD)$/
 632     && ! $cust_main->paycvv
 633     && $conf->exists('signup-require_cvv');
 634
 635   $cust_main->payinfo($cust_main->daytime)
 636     if $cust_main->payby eq 'LECB' && ! $cust_main->payinfo;
 637
 638   my @invoicing_list = $packet->{'invoicing_list'}
 639                          ? split( /\s*\,\s*/, $packet->{'invoicing_list'} )
 640                          : ();
 641
 642   my %insert_options = ();
 643
 644   my @exempt_groups = grep /\S/, $conf->config('tax-cust_exempt-groups');
 645   my @tax_exempt = grep { $packet->{"tax_$_"} eq 'Y' } @exempt_groups;
 646   $insert_options{'tax_exemption'} = {
 647     map { $_ => $packet->{"tax_$_".'_num'} } @tax_exempt
 648   };
 649
 650   $packet->{'pkgpart'} =~ /^(\d+)$/ or '' =~ /^()$/;
 651   my $pkgpart = $1;
 652   return { 'error' => 'Please select a package' } unless $pkgpart; #msgcat
 653
 654   my $part_pkg =
 655     qsearchs( 'part_pkg', { 'pkgpart' => $pkgpart } )
 656       or return { 'error' => "WARNING: unknown pkgpart: $pkgpart" };
 657   my $svcpart = $part_pkg->svcpart($svc_x);
 658
 659   my $reg_code = '';
 660   if ( $packet->{'reg_code'} ) {
 661     $reg_code = qsearchs( 'reg_code', { 'code'     => $packet->{'reg_code'},
 662                                         'agentnum' => $agentnum,             } )
 663       or return { 'error' => 'Unknown registration code' };
 664   }
 665
 666   my $cust_pkg = new FS::cust_pkg ( {
 667     #later#'custnum' => $custnum,
 668     'pkgpart'    => $packet->{'pkgpart'},
 669     'promo_code' => $packet->{'promo_code'},
 670     'reg_code'   => $packet->{'reg_code'},
 671   } );
 672   #my $error = $cust_pkg->check;
 673   #return { 'error' => $error } if $error;
 674
 675   #should be all auto-magic and shit
 676   my @svc = ();
 677   if ( $svc_x eq 'svc_acct' ) {
 678
 679     my $svc = new FS::svc_acct {
 680       'svcpart'   => $svcpart,
 681       map { $_ => $packet->{$_} }
 682         qw( username _password sec_phrase popnum domsvc ),
 683     };
 684
 685     my @acct_snarf;
 686     my $snarfnum = 1;
 687     while (    exists($packet->{"snarf_machine$snarfnum"})
 688             && length($packet->{"snarf_machine$snarfnum"}) ) {
 689       my $acct_snarf = new FS::acct_snarf ( {
 690         'machine'   => $packet->{"snarf_machine$snarfnum"},
 691         'protocol'  => $packet->{"snarf_protocol$snarfnum"},
 692         'username'  => $packet->{"snarf_username$snarfnum"},
 693         '_password' => $packet->{"snarf_password$snarfnum"},
 694       } );
 695       $snarfnum++;
 696       push @acct_snarf, $acct_snarf;
 697     }
 698     $svc->child_objects( \@acct_snarf );
 699     push @svc, $svc;
 700
 701   } elsif ( $svc_x eq 'svc_phone' ) {
 702
 703     push @svc, new FS::svc_phone ( {
 704       'svcpart' => $svcpart,
 705        map { $_ => $packet->{$_} }
 706          qw( countrycode phonenum sip_password pin ),
 707     } );
 708
 709   } elsif ( $svc_x eq 'svc_pbx' ) {
 710
 711     push @svc, new FS::svc_pbx ( {
 712         'svcpart' => $svcpart,
 713         map { $_ => $packet->{$_} }
 714           qw( id title ),
 715         } );
 716
 717   } else {
 718     die "unknown signup service $svc_x";
 719   }
 720
 721   if ($packet->{'mac_addr'} && $conf->exists('signup_server-mac_addr_svcparts'))
 722   {
 723
 724     my %mac_addr_svcparts = map { $_ => 1 }
 725                             $conf->config('signup_server-mac_addr_svcparts');
 726     my @pkg_svc = grep { $_->quantity && $mac_addr_svcparts{$_->svcpart} }
 727                   $cust_pkg->part_pkg->pkg_svc;
 728
 729     return { 'error' => 'No service defined to assign mac address' }
 730       unless @pkg_svc;
 731
 732     my $svc = new FS::svc_acct {
 733       'svcpart'   => $pkg_svc[0]->svcpart, #multiple matches? alas..
 734       'username'  => $packet->{'mac_addr'},
 735       '_password' => '', #blank as requested (set passwordmin to 0)
 736     };
 737
 738     push @svc, $svc;
 739
 740   }
 741
 742   foreach my $svc ( @svc ) {
 743     my $y = $svc->setdefault; # arguably should be in new method
 744     return { 'error' => $y } if $y && !ref($y);
 745     #$error = $svc->check;
 746     #return { 'error' => $error } if $error;
 747   }
 748
 749   #setup a job dependancy to delay provisioning
 750   my $placeholder = new FS::queue ( {
 751     'job'    => 'FS::ClientAPI::Signup::__placeholder',
 752     'status' => 'locked',
 753   } );
 754   my $error = $placeholder->insert;
 755   return { 'error' => $error } if $error;
 756
 757   use Tie::RefHash;
 758   tie my %hash, 'Tie::RefHash';
 759   %hash = ( $cust_pkg => \@svc );
 760   #msgcat
 761   $error = $cust_main->insert(
 762     \%hash,
 763     \@invoicing_list,
 764     'depend_jobnum' => $placeholder->jobnum,
 765      %insert_options,
 766   );
 767   if ( $error ) {
 768     my $perror = $placeholder->delete;
 769     $error .= " (Additionally, error removing placeholder: $perror)" if $perror;
 770     return { 'error' => $error };
 771   }
 772
 773   if ( $conf->exists('signup_server-realtime') ) {
 774
 775     #warn "$me Billing customer...\n" if $Debug;
 776
 777     my $bill_error = $cust_main->bill( 'depend_jobnum'=>$placeholder->jobnum );
 778     #warn "$me error billing new customer: $bill_error"
 779     #  if $bill_error;
 780
 781     $bill_error = $cust_main->apply_payments_and_credits;
 782     #warn "$me error applying payments and credits for".
 783     #     " new customer: $bill_error"
 784     #  if $bill_error;
 785
 786     unless ( $packet->{payby} eq 'PREPAY' ) {
 787       $bill_error = $cust_main->realtime_collect(
 788          method        => FS::payby->payby2bop( $packet->{payby} ),
 789          depend_jobnum => $placeholder->jobnum,
 790          selfservice   => 1,
 791       );
 792       #warn "$me error collecting from new customer: $bill_error"
 793       #  if $bill_error;
 794     }
 795
 796     if ($bill_error && ref($bill_error) eq 'HASH') {
 797       return { 'error' => '_collect',
 798                ( map { $_ => $bill_error->{$_} }
 799                  qw(popup_url reference collectitems)
 800                ),
 801                amount => $cust_main->balance,
 802              };
 803     }
 804
 805     $bill_error = $cust_main->apply_payments_and_credits;
 806     #warn "$me error applying payments and credits for".
 807     #     " new customer: $bill_error"
 808     #  if $bill_error;
 809
 810     if ( $cust_main->balance > 0 ) {
 811
 812       #this makes sense.  credit is "un-doing" the invoice
 813       $cust_main->credit( $cust_main->balance, 'signup server decline',
 814                           'reason_type' => $conf->config('signup_credit_type'),
 815                         );
 816       $cust_main->apply_credits;
 817
 818       #should check list for errors...
 819       #$cust_main->suspend;
 820       local $FS::svc_Common::noexport_hack = 1;
 821       $cust_main->cancel('quiet'=>1);
 822
 823       my $perror = $placeholder->depended_delete;
 824       warn "error removing provisioning jobs after decline: $perror" if $perror;
 825       unless ( $perror ) {
 826         $perror = $placeholder->delete;
 827         warn "error removing placeholder after decline: $perror" if $perror;
 828       }
 829
 830       return { 'error' => '_decline' };
 831     }
 832
 833   }
 834
 835   if ( $reg_code ) {
 836     $error = $reg_code->delete;
 837     return { 'error' => $error } if $error;
 838   }
 839
 840   $error = $placeholder->delete;
 841   return { 'error' => $error } if $error;
 842
 843   if ( $conf->exists('signup-duplicate_cc-warn_hours') ) {
 844     my $hours = $conf->config('signup-duplicate_cc-warn_hours');
 845     my $ban = new FS::banned_pay $cust_main->_new_banned_pay_hashref;
 846     $ban->end_date( int( time + $hours*3600 ) );
 847     $ban->bantype('warn');
 848     $ban->reason('signup-duplicate_cc-warn_hours');
 849     $error = $ban->insert;
 850     warn "WARNING: error inserting temporary banned_pay for ".
 851          " signup-duplicate_cc-warn_hours (proceeding anyway): $error"
 852       if $error;
 853   }
 854
 855   my %return = ( 'error'          => '',
 856                  'signup_service' => $svc_x,
 857                  'custnum'        => $cust_main->custnum,
 858                );
 859
 860   if ( $svc[0] ) {
 861
 862     $return{'svcnum'} = $svc[0]->svcnum;
 863
 864     if ( $svc_x eq 'svc_acct' ) {
 865       $return{$_} = $svc[0]->$_() for qw( username _password );
 866     } elsif ( $svc_x eq 'svc_phone' ) {
 867       $return{$_} = $svc[0]->$_() for qw(countrycode phonenum sip_password pin);
 868     } elsif ( $svc_x eq 'svc_pbx' ) {
 869       #$return{$_} = $svc[0]->$_() for qw( ) #nothing yet
 870      } else {
 871       return {'error' => "configuration error: unknown signup service $svc_x"};
 872       #die "unknown signup service $svc_x";
 873       # return an error that's visible to someone somewhere
 874     }
 875
 876   }
 877
 878   return \%return;
 879
 880 }
 881
 882 sub capture_payment {
 883   my $packet = shift;
 884
 885   warn "$me capture_payment called on $packet\n" if $DEBUG;
 886
 887   ###
 888   # identify processor/gateway from called back URL
 889   ###
 890
 891   my $conf = new FS::Conf;
 892
 893   my $payment_gateway;
 894   if ( my $gwnum = $conf->config('selfservice-payment_gateway') ) {
 895     $payment_gateway = qsearchs('payment_gateway', { 'gatewaynum' => $gwnum })
 896       or die "configured gatewaynum $gwnum not found!";
 897   }
 898   else {
 899     my $url = $packet->{url};
 900
 901     $payment_gateway = qsearchs('payment_gateway',
 902         { 'gateway_callback_url' => popurl(0, $url) }
 903       );
 904     if (!$payment_gateway) {
 905
 906       my ( $processor, $login, $password, $action, @bop_options ) =
 907         $conf->config('business-onlinepayment');
 908       $action ||= 'normal authorization';
 909       pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
 910       die "No real-time processor is enabled - ".
 911           "did you set the business-onlinepayment configuration value?\n"
 912         unless $processor;
 913
 914       $payment_gateway = new FS::payment_gateway( {
 915         gateway_namespace => $conf->config('business-onlinepayment-namespace'),
 916         gateway_module    => $processor,
 917         gateway_username  => $login,
 918         gateway_password  => $password,
 919         gateway_action    => $action,
 920         options   => [ ( @bop_options ) ],
 921       });
 922     }
 923   }
 924
 925   die "No real-time third party processor is enabled - ".
 926       "did you set the business-onlinepayment configuration value?\n*"
 927     unless $payment_gateway->gateway_namespace eq 'Business::OnlineThirdPartyPayment';
 928
 929   ###
 930   # locate pending transaction
 931   ###
 932
 933   eval "use Business::OnlineThirdPartyPayment";
 934   die $@ if $@;
 935
 936   my $transaction =
 937     new Business::OnlineThirdPartyPayment( $payment_gateway->gateway_module,
 938                                            @{ [ $payment_gateway->options ] },
 939                                          );
 940
 941   my $paypendingnum = $transaction->reference($packet->{data});
 942
 943   my $cust_pay_pending =
 944     qsearchs('cust_pay_pending', { paypendingnum => $paypendingnum } );
 945
 946   unless ($cust_pay_pending) {
 947     my $bill_error = "No payment is being processed with id $paypendingnum".
 948                      "; Transaction aborted.";
 949     return { error => '_decline', bill_error => $bill_error };
 950   }
 951
 952   if ($cust_pay_pending->status ne 'thirdparty') {
 953     my $bill_error = "Payment with id $paypendingnum is not thirdparty, but ".
 954                      $cust_pay_pending->status.  "; Transaction aborted.";
 955     return { error => '_decline', bill_error => $bill_error };
 956   }
 957
 958   my $cust_main = $cust_pay_pending->cust_main;
 959   if ( $packet->{cancel} ) {
 960     # the user has chosen not to make this payment
 961     # (probably should be a separate API call, but I don't want to duplicate
 962     # all of the above...which should eventually go away)
 963     my $error = $cust_pay_pending->delete;
 964     # don't show any errors related to this; they're not meaningful
 965     warn "error canceling pending payment $paypendingnum: $error\n" if $error;
 966     return { 'error'      => '_cancel',
 967              'session_id' => $cust_pay_pending->session_id };
 968   } else {
 969     # create the payment
 970     my $bill_error =
 971       $cust_main->realtime_botpp_capture( $cust_pay_pending,
 972         %{$packet->{data}},
 973         apply => 1,
 974     );
 975
 976     return { 'error'      => ( $bill_error->{bill_error} ? '_decline' : '' ),
 977              %$bill_error,
 978            };
 979   }
 980
 981 }
 982
 983 1;