FS/FS/quotation_pkg.pm

   1 package FS::quotation_pkg;
   2
   3 use strict;
   4 use base qw( FS::TemplateItem_Mixin FS::Record );
   5 use FS::Record qw( qsearch qsearchs dbh );
   6 use FS::part_pkg;
   7 use FS::cust_location;
   8 use FS::quotation;
   9 use FS::quotation_pkg_discount; #so its loaded when TemplateItem_Mixin needs it
  10 use List::Util qw(sum);
  11
  12 =head1 NAME
  13
  14 FS::quotation_pkg - Object methods for quotation_pkg records
  15
  16 =head1 SYNOPSIS
  17
  18   use FS::quotation_pkg;
  19
  20   $record = new FS::quotation_pkg \%hash;
  21   $record = new FS::quotation_pkg { 'column' => 'value' };
  22
  23   $error = $record->insert;
  24
  25   $error = $new_record->replace($old_record);
  26
  27   $error = $record->delete;
  28
  29   $error = $record->check;
  30
  31 =head1 DESCRIPTION
  32
  33 An FS::quotation_pkg object represents a quotation package.
  34 FS::quotation_pkg inherits from FS::Record.  The following fields are currently
  35 supported:
  36
  37 =over 4
  38
  39 =item quotationpkgnum
  40
  41 primary key
  42
  43 =item pkgpart
  44
  45 pkgpart (L<FS::part_pkg>) of the package
  46
  47 =item locationnum
  48
  49 locationnum (L<FS::cust_location>) where the package will be in service
  50
  51 =item start_date
  52
  53 expected start date for the package, as a timestamp
  54
  55 =item contract_end
  56
  57 contract end date
  58
  59 =item quantity
  60
  61 quantity
  62
  63 =item waive_setup
  64
  65 'Y' to waive the setup fee
  66
  67 =item unitsetup
  68
  69 The amount per package that will be charged in setup/one-time fees.
  70
  71 =item unitrecur
  72
  73 The amount per package that will be charged per billing cycle.
  74
  75 =back
  76
  77 =head1 METHODS
  78
  79 =over 4
  80
  81 =item new HASHREF
  82
  83 Creates a new quotation package.  To add the quotation package to the database,
  84 see L<"insert">.
  85
  86 Note that this stores the hash reference, not a distinct copy of the hash it
  87 points to.  You can ask the object for a copy with the I<hash> method.
  88
  89 =cut
  90
  91 sub table { 'quotation_pkg'; }
  92
  93 sub display_table         { 'quotation_pkg'; }
  94
  95 #forget it, just overriding cust_bill_pkg_display entirely
  96 #sub display_table_orderby { 'quotationpkgnum'; } # something else?
  97 #                                                 #  (for invoice display order)
  98
  99 sub discount_table        { 'quotation_pkg_discount'; }
 100
 101 =item insert
 102
 103 Adds this record to the database.  If there is an error, returns the error,
 104 otherwise returns false.
 105
 106 =cut
 107
 108 sub insert {
 109   my ($self, %options) = @_;
 110
 111   my $dbh = dbh;
 112   my $oldAutoCommit = $FS::UID::AutoCommit;
 113   local $FS::UID::AutoCommit = 0;
 114
 115   my $error = $self->SUPER::insert;
 116
 117   if ( !$error and $self->discountnum ) {
 118     $error = $self->insert_discount;
 119     $error .= ' (setting discount)' if $error;
 120   }
 121
 122   # update $self and any discounts with their amounts
 123   if ( !$error ) {
 124     $error = $self->estimate;
 125     $error .= ' (calculating charges)' if $error;
 126   }
 127
 128   if ( $error ) {
 129     $dbh->rollback if $oldAutoCommit;
 130     return $error;
 131   } else {
 132     $dbh->commit if $oldAutoCommit;
 133     return '';
 134   }
 135 }
 136
 137 =item delete
 138
 139 Delete this record from the database.
 140
 141 =cut
 142
 143 sub delete {
 144   my $self = shift;
 145
 146   my $dbh = dbh;
 147   my $oldAutoCommit = $FS::UID::AutoCommit;
 148   local $FS::UID::AutoCommit = 0;
 149
 150   foreach ($self->quotation_pkg_discount, $self->quotation_pkg_tax) {
 151     my $error = $_->delete;
 152     if ( $error ) {
 153       $dbh->rollback if $oldAutoCommit;
 154       return $error . ' (deleting discount)';
 155     }
 156   }
 157
 158   my $error = $self->SUPER::delete;
 159   if ( $error ) {
 160     $dbh->rollback if $oldAutoCommit;
 161     return $error;
 162   } else {
 163     $dbh->commit if $oldAutoCommit;
 164     return '';
 165   }
 166
 167 }
 168
 169 =item replace OLD_RECORD
 170
 171 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 172 returns the error, otherwise returns false.
 173
 174 =item check
 175
 176 Checks all fields to make sure this is a valid quotation package.  If there is
 177 an error, returns the error, otherwise returns false.  Called by the insert
 178 and replace methods.
 179
 180 =cut
 181
 182 sub check {
 183   my $self = shift;
 184
 185   my $error =
 186     $self->ut_numbern('quotationpkgnum')
 187     || $self->ut_foreign_key(  'quotationnum', 'quotation',    'quotationnum' )
 188     || $self->ut_foreign_key(  'pkgpart',      'part_pkg',     'pkgpart'      )
 189     || $self->ut_foreign_keyn( 'locationnum', 'cust_location', 'locationnum'  )
 190     || $self->ut_numbern('start_date')
 191     || $self->ut_numbern('contract_end')
 192     || $self->ut_numbern('quantity')
 193     || $self->ut_moneyn('unitsetup')
 194     || $self->ut_moneyn('unitrecur')
 195     || $self->ut_enum('waive_setup', [ '', 'Y'] )
 196   ;
 197
 198   if ($self->locationnum eq '') {
 199     # use the customer default
 200     my $quotation = $self->quotation;
 201     if ($quotation->custnum) {
 202       $self->set('locationnum', $quotation->cust_main->ship_locationnum);
 203     } elsif ($quotation->prospectnum) {
 204       $self->set('locationnum', $quotation->prospect_main->locationnum);
 205     } # else the quotation is invalid
 206   }
 207
 208   return $error if $error;
 209
 210   $self->SUPER::check;
 211 }
 212
 213 sub part_pkg {
 214   my $self = shift;
 215   qsearchs('part_pkg', { 'pkgpart' => $self->pkgpart } );
 216 }
 217
 218 sub desc {
 219   my $self = shift;
 220   $self->part_pkg->pkg;
 221 }
 222
 223 =item estimate
 224
 225 Update the quotation_pkg record with the estimated setup and recurring
 226 charges for the package. Returns nothing on success, or an error message
 227 on failure.
 228
 229 =cut
 230
 231 sub estimate {
 232   my $self = shift;
 233   my $part_pkg = $self->part_pkg;
 234   my $quantity = $self->quantity || 1;
 235   my ($unitsetup, $unitrecur);
 236   # calculate base fees
 237   if ( $self->waive_setup eq 'Y' || $self->{'_NO_SETUP_KLUDGE'} ) {
 238     $unitsetup = '0.00';
 239   } else {
 240     $unitsetup = $part_pkg->option('setup_fee',1) || '0.00'; # XXX 3.x only
 241   }
 242   if ( $self->{'_NO_RECUR_KLUDGE'} ) {
 243     $unitrecur = '0.00';
 244   } else {
 245     $unitrecur = $part_pkg->base_recur;
 246   }
 247
 248   #XXX add-on packages
 249
 250   $self->set('unitsetup', $unitsetup);
 251   $self->set('unitrecur', $unitrecur);
 252   my $error = $self->replace;
 253   return $error if $error;
 254
 255   # semi-duplicates calc_discount
 256   my $setup_discount = 0;
 257   my $recur_discount = 0;
 258
 259   my %setup_discounts; # quotationpkgdiscountnum => amount
 260   my %recur_discounts; # quotationpkgdiscountnum => amount
 261
 262   # XXX the order of applying discounts is ill-defined, which matters
 263   # if there are percentage and amount discounts on the same package.
 264   #
 265   # but right now there can only be one discount on any package, so
 266   # it doesn't matter
 267   foreach my $pkg_discount ($self->quotation_pkg_discount) {
 268
 269     my $discount = $pkg_discount->discount;
 270     my $this_setup_discount = 0;
 271     my $this_recur_discount = 0;
 272
 273     if ( $discount->percent > 0 ) {
 274
 275       if ( $discount->setup ) {
 276         $this_setup_discount = ($discount->percent * $unitsetup / 100);
 277       }
 278       $this_recur_discount = ($discount->percent * $unitrecur / 100);
 279
 280     } elsif ( $discount->amount > 0 ) {
 281
 282       my $discount_left = $discount->amount;
 283       if ( $discount->setup ) {
 284         if ( $discount_left > $unitsetup - $setup_discount ) {
 285           # then discount the setup to zero
 286           $discount_left -= $unitsetup - $setup_discount;
 287           $this_setup_discount = $unitsetup - $setup_discount;
 288         } else {
 289           # not enough discount to fully cover the setup
 290           $this_setup_discount = $discount_left;
 291           $discount_left = 0;
 292         }
 293       }
 294       # same logic for recur
 295       if ( $discount_left > $unitrecur - $recur_discount ) {
 296         $this_recur_discount = $unitrecur - $recur_discount;
 297       } else {
 298         $this_recur_discount = $discount_left;
 299       }
 300
 301     }
 302
 303     # increment the total discountage
 304     $setup_discount += $this_setup_discount;
 305     $recur_discount += $this_recur_discount;
 306     # and update the pkg_discount object
 307     $pkg_discount->set('setup_amount', sprintf('%.2f', $setup_discount));
 308     $pkg_discount->set('recur_amount', sprintf('%.2f', $recur_discount));
 309     my $error = $pkg_discount->replace;
 310     return $error if $error;
 311   }
 312
 313   '';
 314 }
 315
 316 =item insert_discount
 317
 318 Associates this package with a discount (see L<FS::cust_pkg_discount>,
 319 possibly inserting a new discount on the fly (see L<FS::discount>). Properties
 320 of the discount will be taken from this object.
 321
 322 =cut
 323
 324 sub insert_discount {
 325   #my ($self, %options) = @_;
 326   my $self = shift;
 327
 328   my $quotation_pkg_discount = FS::quotation_pkg_discount->new( {
 329     'quotationpkgnum' => $self->quotationpkgnum,
 330     'discountnum'     => $self->discountnum,
 331     #for the create a new discount case
 332     '_type'           => $self->discountnum__type,
 333     'amount'      => $self->discountnum_amount,
 334     'percent'     => $self->discountnum_percent,
 335     'months'      => $self->discountnum_months,
 336     'setup'       => $self->discountnum_setup,
 337   } );
 338
 339   $quotation_pkg_discount->insert;
 340 }
 341
 342 sub _item_discount {
 343   my $self = shift;
 344   my @pkg_discounts = $self->pkg_discount;
 345   return if @pkg_discounts == 0;
 346
 347   my @ext;
 348   my $d = {
 349     _is_discount    => 1,
 350     description     => $self->mt('Discount'),
 351     setup_amount    => 0,
 352     recur_amount    => 0,
 353     amount          => 0,
 354     ext_description => \@ext,
 355     # maybe should show quantity/unit discount?
 356   };
 357   foreach my $pkg_discount (@pkg_discounts) {
 358     push @ext, $pkg_discount->description;
 359     $d->{setup_amount} -= $pkg_discount->setup_amount;
 360     $d->{recur_amount} -= $pkg_discount->recur_amount;
 361   }
 362   $d->{setup_amount} *= $self->quantity || 1;
 363   $d->{recur_amount} *= $self->quantity || 1;
 364   $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
 365
 366   return $d;
 367 }
 368
 369 sub setup {
 370   my $self = shift;
 371   ($self->unitsetup - sum(0, map { $_->setup_amount } $self->pkg_discount))
 372     * ($self->quantity || 1);
 373 }
 374
 375 sub recur {
 376   my $self = shift;
 377   ($self->unitrecur - sum(0, map { $_->recur_amount } $self->pkg_discount))
 378     * ($self->quantity || 1);
 379 }
 380
 381 =item cust_bill_pkg_display [ type => TYPE ]
 382
 383 =cut
 384
 385 sub cust_bill_pkg_display {
 386   my ( $self, %opt ) = @_;
 387
 388   my $type = $opt{type} if exists $opt{type};
 389   return () if $type eq 'U'; #quotations don't have usage
 390
 391   if ( $self->get('display') ) {
 392     return ( grep { defined($type) ? ($type eq $_->type) : 1 }
 393                @{ $self->get('display') }
 394            );
 395   } else {
 396
 397     #??
 398     my $setup = $self->new($self->hashref);
 399     $setup->{'_NO_RECUR_KLUDGE'} = 1;
 400     $setup->{'type'} = 'S';
 401     my $recur = $self->new($self->hashref);
 402     $recur->{'_NO_SETUP_KLUDGE'} = 1;
 403     $recur->{'type'} = 'R';
 404
 405     if ( $type eq 'S' ) {
 406       return ($setup);
 407     } elsif ( $type eq 'R' ) {
 408       return ($recur);
 409     } else {
 410       #return ($setup, $recur);
 411       return ($self);
 412     }
 413
 414   }
 415
 416 }
 417
 418 =item cust_main
 419
 420 Returns the customer (L<FS::cust_main> object).
 421
 422 =cut
 423
 424 sub cust_main {
 425   my $self = shift;
 426   my $quotation = FS::quotation->by_key($self->quotationnum) or return '';
 427   $quotation->cust_main;
 428 }
 429
 430 sub tax_locationnum {
 431   my $self = shift;
 432   $self->locationnum;
 433 }
 434
 435 #stub for 3.x
 436
 437 sub quotation {
 438   my $self = shift;
 439   FS::quotation->by_key($self->quotationnum);
 440 }
 441
 442 sub quotation_pkg_discount {
 443   my $self = shift;
 444   qsearch('quotation_pkg_discount', { quotationpkgnum => $self->quotationpkgnum });
 445 }
 446
 447 sub quotation_pkg_tax {
 448   my $self = shift;
 449   qsearch('quotation_pkg_tax', { quotationpkgnum => $self->quotationpkgnum });
 450 }
 451
 452 sub cust_location {
 453   my $self = shift;
 454   $self->locationnum ? qsearchs('cust_location', { locationnum => $self->locationnum }) : '';
 455 }
 456
 457
 458 sub _upgrade_data {
 459   my $class = shift;
 460   my @quotation_pkg_without_location =
 461     qsearch( 'quotation_pkg', { locationnum => '' } );
 462   if (@quotation_pkg_without_location) {
 463     warn "setting default location on quotation_pkg records\n";
 464     foreach my $quotation_pkg (@quotation_pkg_without_location) {
 465       # check() will fix this
 466       my $error = $quotation_pkg->replace;
 467       if ($error) {
 468         die "quotation #".$quotation_pkg->quotationnum.": $error\n";
 469       }
 470     }
 471   }
 472   '';
 473 }
 474
 475 =back
 476
 477 =head1 BUGS
 478
 479 Doesn't support fees, or add-on packages.
 480
 481 =head1 SEE ALSO
 482
 483 L<FS::Record>, schema.html from the base documentation.
 484
 485 =cut
 486
 487 1;
 488