FS/FS/part_svc.pm

   1 package FS::part_svc;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG );
   5 use Tie::IxHash;
   6 use FS::Record qw( qsearch qsearchs fields dbh );
   7 use FS::Schema qw( dbdef );
   8 use FS::part_svc_column;
   9 use FS::part_export;
  10 use FS::export_svc;
  11 use FS::cust_svc;
  12
  13 @ISA = qw(FS::Record);
  14
  15 $DEBUG = 0;
  16
  17 =head1 NAME
  18
  19 FS::part_svc - Object methods for part_svc objects
  20
  21 =head1 SYNOPSIS
  22
  23   use FS::part_svc;
  24
  25   $record = new FS::part_svc \%hash
  26   $record = new FS::part_svc { 'column' => 'value' };
  27
  28   $error = $record->insert;
  29   $error = $record->insert( [ 'pseudofield' ] );
  30   $error = $record->insert( [ 'pseudofield' ], \%exportnums );
  31
  32   $error = $new_record->replace($old_record);
  33   $error = $new_record->replace($old_record, '1.3-COMPAT', [ 'pseudofield' ] );
  34   $error = $new_record->replace($old_record, '1.3-COMPAT', [ 'pseudofield' ], \%exportnums );
  35
  36   $error = $record->delete;
  37
  38   $error = $record->check;
  39
  40 =head1 DESCRIPTION
  41
  42 An FS::part_svc represents a service definition.  FS::part_svc inherits from
  43 FS::Record.  The following fields are currently supported:
  44
  45 =over 4
  46
  47 =item svcpart - primary key (assigned automatically for new service definitions)
  48
  49 =item svc - text name of this service definition
  50
  51 =item svcdb - table used for this service.  See L<FS::svc_acct>,
  52 L<FS::svc_domain>, and L<FS::svc_forward>, among others.
  53
  54 =item disabled - Disabled flag, empty or `Y'
  55
  56 =item preserve - Preserve after cancellation, empty or 'Y'
  57
  58 =back
  59
  60 =head1 METHODS
  61
  62 =over 4
  63
  64 =item new HASHREF
  65
  66 Creates a new service definition.  To add the service definition to the
  67 database, see L<"insert">.
  68
  69 =cut
  70
  71 sub table { 'part_svc'; }
  72
  73 =item insert [ EXTRA_FIELDS_ARRAYREF [ , EXPORTNUMS_HASHREF [ , JOB ] ] ]
  74
  75 Adds this service definition to the database.  If there is an error, returns
  76 the error, otherwise returns false.
  77
  78 The following pseudo-fields may be defined, and will be maintained in
  79 the part_svc_column table appropriately (see L<FS::part_svc_column>).
  80
  81 =over 4
  82
  83 =item I<svcdb>__I<field> - Default or fixed value for I<field> in I<svcdb>.
  84
  85 =item I<svcdb>__I<field>_flag - defines I<svcdb>__I<field> action: null or empty (no default), `D' for default, `F' for fixed (unchangeable), `M' for manual selection from inventory, or `A' for automatic selection from inventory.  For virtual fields, can also be 'X' for excluded.
  86
  87 =back
  88
  89 If you want to add part_svc_column records for fields that do not exist as
  90 (real or virtual) fields in the I<svcdb> table, make sure to list then in
  91 EXTRA_FIELDS_ARRAYREF also.
  92
  93 If EXPORTNUMS_HASHREF is specified (keys are exportnums and values are
  94 boolean), the appopriate export_svc records will be inserted.
  95
  96 TODOC: JOB
  97
  98 =cut
  99
 100 sub insert {
 101   my $self = shift;
 102   my @fields = ();
 103   my @exportnums = ();
 104   @fields = @{shift(@_)} if @_;
 105   if ( @_ ) {
 106     my $exportnums = shift;
 107     @exportnums = grep $exportnums->{$_}, keys %$exportnums;
 108   }
 109   my $job = '';
 110   $job = shift if @_;
 111
 112   local $SIG{HUP} = 'IGNORE';
 113   local $SIG{INT} = 'IGNORE';
 114   local $SIG{QUIT} = 'IGNORE';
 115   local $SIG{TERM} = 'IGNORE';
 116   local $SIG{TSTP} = 'IGNORE';
 117   local $SIG{PIPE} = 'IGNORE';
 118
 119   my $oldAutoCommit = $FS::UID::AutoCommit;
 120   local $FS::UID::AutoCommit = 0;
 121   my $dbh = dbh;
 122
 123   my $error = $self->SUPER::insert;
 124   if ( $error ) {
 125     $dbh->rollback if $oldAutoCommit;
 126     return $error;
 127   }
 128
 129   # add part_svc_column records
 130
 131   my $svcdb = $self->svcdb;
 132 #  my @rows = map { /^${svcdb}__(.*)$/; $1 }
 133 #    grep ! /_flag$/,
 134 #      grep /^${svcdb}__/,
 135 #        fields('part_svc');
 136   foreach my $field (
 137     grep { $_ ne 'svcnum'
 138            && ( defined( $self->getfield($svcdb.'__'.$_.'_flag') )
 139                 || $self->getfield($svcdb.'__'.$_.'_label') !~ /^\s*$/ )
 140          } (fields($svcdb), @fields)
 141   ) {
 142     my $part_svc_column = $self->part_svc_column($field);
 143     my $previous = qsearchs('part_svc_column', {
 144       'svcpart'    => $self->svcpart,
 145       'columnname' => $field,
 146     } );
 147
 148     my $flag  = $self->getfield($svcdb.'__'.$field.'_flag');
 149     my $label = $self->getfield($svcdb.'__'.$field.'_label');
 150     if ( uc($flag) =~ /^([A-Z])$/ || $label !~ /^\s*$/ ) {
 151
 152       if ( uc($flag) =~ /^([A-Z])$/ ) {
 153         my $parser = FS::part_svc->svc_table_fields($svcdb)->{$field}->{parse}
 154                      || sub { shift };
 155         $part_svc_column->setfield('columnflag', $1);
 156         $part_svc_column->setfield('columnvalue',
 157           &$parser($self->getfield($svcdb.'__'.$field))
 158         );
 159       }
 160
 161       $part_svc_column->setfield('columnlabel', $label)
 162         if $label !~ /^\s*$/;
 163
 164       if ( $previous ) {
 165         $error = $part_svc_column->replace($previous);
 166       } else {
 167         $error = $part_svc_column->insert;
 168       }
 169
 170     } else {
 171       $error = $previous ? $previous->delete : '';
 172     }
 173     if ( $error ) {
 174       $dbh->rollback if $oldAutoCommit;
 175       return $error;
 176     }
 177
 178   }
 179
 180   # add export_svc records
 181   my $slice = 100/scalar(@exportnums) if @exportnums;
 182   my $done = 0;
 183   foreach my $exportnum ( @exportnums ) {
 184     my $export_svc = new FS::export_svc ( {
 185       'exportnum' => $exportnum,
 186       'svcpart'   => $self->svcpart,
 187     } );
 188     $error = $export_svc->insert($job, $slice*$done++, $slice);
 189     if ( $error ) {
 190       $dbh->rollback if $oldAutoCommit;
 191       return $error;
 192     }
 193   }
 194
 195   # XXX shouldn't this update fixed values?
 196
 197   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 198
 199   '';
 200 }
 201
 202 =item delete
 203
 204 Currently unimplemented.  Set the "disabled" field instead.
 205
 206 =cut
 207
 208 sub delete {
 209   return "Can't (yet?) delete service definitions.";
 210 # check & make sure the svcpart isn't in cust_svc or pkg_svc (in any packages)?
 211 }
 212
 213 =item replace OLD_RECORD [ '1.3-COMPAT' [ , EXTRA_FIELDS_ARRAYREF [ , EXPORTNUMS_HASHREF [ , JOB ] ] ] ]
 214
 215 Replaces OLD_RECORD with this one in the database.  If there is an error,
 216 returns the error, otherwise returns false.
 217
 218 TODOC: 1.3-COMPAT
 219
 220 TODOC: EXTRA_FIELDS_ARRAYREF (same as insert method)
 221
 222 TODOC: JOB
 223
 224 =cut
 225
 226 sub replace {
 227   my ( $new, $old ) = ( shift, shift );
 228   my $compat = '';
 229   my @fields = ();
 230   my $exportnums;
 231   my $job = '';
 232   if ( @_ && $_[0] eq '1.3-COMPAT' ) {
 233     shift;
 234     $compat = '1.3';
 235     @fields = @{shift(@_)} if @_;
 236     $exportnums = @_ ? shift : '';
 237     $job = shift if @_;
 238   } else {
 239     return 'non-1.3-COMPAT interface not yet written';
 240     #not yet implemented
 241   }
 242
 243   return "Can't change svcdb for an existing service definition!"
 244     unless $old->svcdb eq $new->svcdb;
 245
 246   local $SIG{HUP} = 'IGNORE';
 247   local $SIG{INT} = 'IGNORE';
 248   local $SIG{QUIT} = 'IGNORE';
 249   local $SIG{TERM} = 'IGNORE';
 250   local $SIG{TSTP} = 'IGNORE';
 251   local $SIG{PIPE} = 'IGNORE';
 252
 253   my $oldAutoCommit = $FS::UID::AutoCommit;
 254   local $FS::UID::AutoCommit = 0;
 255   my $dbh = dbh;
 256
 257   my $error = $new->SUPER::replace( $old );
 258   if ( $error ) {
 259     $dbh->rollback if $oldAutoCommit;
 260     return $error;
 261   }
 262
 263   if ( $compat eq '1.3' ) {
 264
 265    # maintain part_svc_column records
 266
 267     my $svcdb = $new->svcdb;
 268     foreach my $field (
 269       grep { $_ ne 'svcnum'
 270              && ( defined( $new->getfield($svcdb.'__'.$_.'_flag') )
 271                   || $new->getfield($svcdb.'__'.$_.'_label') !~ /^\s*$/ )
 272            } (fields($svcdb),@fields)
 273     ) {
 274
 275       my $part_svc_column = $new->part_svc_column($field);
 276       my $previous = qsearchs('part_svc_column', {
 277         'svcpart'    => $new->svcpart,
 278         'columnname' => $field,
 279       } );
 280
 281       my $flag  = $new->getfield($svcdb.'__'.$field.'_flag');
 282       my $label = $new->getfield($svcdb.'__'.$field.'_label');
 283
 284       if ( uc($flag) =~ /^([A-Z])$/ || $label !~ /^\s*$/ ) {
 285
 286         if ( uc($flag) =~ /^([A-Z])$/ ) {
 287           $part_svc_column->setfield('columnflag', $1);
 288           my $parser = FS::part_svc->svc_table_fields($svcdb)->{$field}->{parse}
 289                      || sub { shift };
 290           $part_svc_column->setfield('columnvalue',
 291             &$parser($new->getfield($svcdb.'__'.$field))
 292           );
 293         } else {
 294           $part_svc_column->setfield('columnflag',  '');
 295           $part_svc_column->setfield('columnvalue', '');
 296         }
 297
 298         $part_svc_column->setfield('columnlabel', $label)
 299           if $label !~ /^\s*$/;
 300
 301         if ( $previous ) {
 302           $error = $part_svc_column->replace($previous);
 303         } else {
 304           $error = $part_svc_column->insert;
 305         }
 306       } else {
 307         $error = $previous ? $previous->delete : '';
 308       }
 309       if ( $error ) {
 310         $dbh->rollback if $oldAutoCommit;
 311         return $error;
 312       }
 313     }
 314
 315     # maintain export_svc records
 316
 317     if ( $exportnums ) {
 318
 319       #false laziness w/ edit/process/agent_type.cgi
 320       my @new_export_svc = ();
 321       foreach my $part_export ( qsearch('part_export', {}) ) {
 322         my $exportnum = $part_export->exportnum;
 323         my $hashref = {
 324           'exportnum' => $exportnum,
 325           'svcpart'   => $new->svcpart,
 326         };
 327         my $export_svc = qsearchs('export_svc', $hashref);
 328
 329         if ( $export_svc && ! $exportnums->{$exportnum} ) {
 330           $error = $export_svc->delete;
 331           if ( $error ) {
 332             $dbh->rollback if $oldAutoCommit;
 333             return $error;
 334           }
 335         } elsif ( ! $export_svc && $exportnums->{$exportnum} ) {
 336           push @new_export_svc, new FS::export_svc ( $hashref );
 337         }
 338
 339       }
 340
 341       my $slice = 100/scalar(@new_export_svc) if @new_export_svc;
 342       my $done = 0;
 343       foreach my $export_svc (@new_export_svc) {
 344         $error = $export_svc->insert($job, $slice*$done++, $slice);
 345         if ( $error ) {
 346           $dbh->rollback if $oldAutoCommit;
 347           return $error;
 348         }
 349         if ( $job ) {
 350           $error = $job->update_statustext( int( $slice * $done ) );
 351           if ( $error ) {
 352             $dbh->rollback if $oldAutoCommit;
 353             return $error;
 354           }
 355         }
 356       }
 357
 358     }
 359
 360   } else {
 361     $dbh->rollback if $oldAutoCommit;
 362     return 'non-1.3-COMPAT interface not yet written';
 363     #not yet implemented
 364   }
 365
 366   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 367
 368   '';
 369 }
 370
 371 =item check
 372
 373 Checks all fields to make sure this is a valid service definition.  If there is
 374 an error, returns the error, otherwise returns false.  Called by the insert
 375 and replace methods.
 376
 377 =cut
 378
 379 sub check {
 380   my $self = shift;
 381
 382   my $error;
 383   $error=
 384     $self->ut_numbern('svcpart')
 385     || $self->ut_text('svc')
 386     || $self->ut_alpha('svcdb')
 387     || $self->ut_enum('disabled', [ '', 'Y' ] )
 388     || $self->ut_enum('preserve', [ '', 'Y' ] )
 389     || $self->ut_enum('selfservice_access', [ '', 'hidden', 'readonly' ] )
 390   ;
 391   return $error if $error;
 392
 393   my @fields = eval { fields( $self->svcdb ) }; #might die
 394   return "Unknown svcdb: ". $self->svcdb. " (Error: $@)"
 395     unless @fields;
 396
 397   $self->SUPER::check;
 398 }
 399
 400 =item part_svc_column COLUMNNAME
 401
 402 Returns the part_svc_column object (see L<FS::part_svc_column>) for the given
 403 COLUMNNAME, or a new part_svc_column object if none exists.
 404
 405 =cut
 406
 407 sub part_svc_column {
 408   my( $self, $columnname) = @_;
 409   $self->svcpart &&
 410     qsearchs('part_svc_column',  {
 411                                    'svcpart'    => $self->svcpart,
 412                                    'columnname' => $columnname,
 413                                  }
 414   ) or new FS::part_svc_column {
 415                                  'svcpart'    => $self->svcpart,
 416                                  'columnname' => $columnname,
 417                                };
 418 }
 419
 420 =item all_part_svc_column
 421
 422 =cut
 423
 424 sub all_part_svc_column {
 425   my $self = shift;
 426   qsearch('part_svc_column', { 'svcpart' => $self->svcpart } );
 427 }
 428
 429 =item part_export [ EXPORTTYPE ]
 430
 431 Returns a list of all exports (see L<FS::part_export>) for this service, or,
 432 if an export type is specified, only returns exports of the given type.
 433
 434 =cut
 435
 436 sub part_export {
 437   my $self = shift;
 438   my %search;
 439   $search{'exporttype'} = shift if @_;
 440   map { $_ } #behavior of sort undefined in scalar context
 441     sort { $a->weight <=> $b->weight }
 442       map { qsearchs('part_export', { 'exportnum'=>$_->exportnum, %search } ) }
 443         qsearch('export_svc', { 'svcpart'=>$self->svcpart } );
 444 }
 445
 446 =item part_export_usage
 447
 448 Returns a list of any exports (see L<FS::part_export>) for this service that
 449 are capable of reporting usage information.
 450
 451 =cut
 452
 453 sub part_export_usage {
 454   my $self = shift;
 455   grep $_->can('usage_sessions'), $self->part_export;
 456 }
 457
 458 =item part_export_did
 459
 460 Returns a list of any exports (see L<FS::part_export>) for this service that
 461 are capable of returing available DID (phone number) information.
 462
 463 =cut
 464
 465 sub part_export_did {
 466   my $self = shift;
 467   grep $_->can('get_dids'), $self->part_export;
 468 }
 469
 470 =item part_export_dsl_pull
 471
 472 Returns a list of any exports (see L<FS::part_export>) for this service that
 473 are capable of pulling/pushing DSL orders.
 474
 475 =cut
 476
 477 sub part_export_dsl_pull {
 478     my $self = shift;
 479     grep $_->can('dsl_pull'), $self->part_export;
 480 }
 481
 482 =item cust_svc [ PKGPART ]
 483
 484 Returns a list of associated customer services (FS::cust_svc records).
 485
 486 If a PKGPART is specified, returns the customer services which are contained
 487 within packages of that type (see L<FS::part_pkg>).  If PKGPARTis specified as
 488 B<0>, returns unlinked customer services.
 489
 490 =cut
 491
 492 sub cust_svc {
 493   my $self = shift;
 494
 495   my $hashref = { 'svcpart' => $self->svcpart };
 496
 497   my( $addl_from, $extra_sql ) = ( '', '' );
 498   if ( @_ ) {
 499     my $pkgpart = shift;
 500     if ( $pkgpart =~ /^(\d+)$/ ) {
 501       $addl_from = 'LEFT JOIN cust_pkg USING ( pkgnum )';
 502       $extra_sql = "AND pkgpart = $1";
 503     } elsif ( $pkgpart eq '0' ) {
 504       $hashref->{'pkgnum'} = '';
 505     }
 506   }
 507
 508   qsearch({
 509     'table'     => 'cust_svc',
 510     'addl_from' => $addl_from,
 511     'hashref'   => $hashref,
 512     'extra_sql' => $extra_sql,
 513   });
 514 }
 515
 516 =item num_cust_svc [ PKGPART ]
 517
 518 Returns the number of associated customer services (FS::cust_svc records).
 519
 520 If a PKGPART is specified, returns the number of customer services which are
 521 contained within packages of that type (see L<FS::part_pkg>).  If PKGPART
 522 is specified as B<0>, returns the number of unlinked customer services.
 523
 524 =cut
 525
 526 sub num_cust_svc {
 527   my $self = shift;
 528
 529   my @param = ( $self->svcpart );
 530
 531   my( $join, $and ) = ( '', '' );
 532   if ( @_ ) {
 533     my $pkgpart = shift;
 534     if ( $pkgpart ) {
 535       $join = 'LEFT JOIN cust_pkg USING ( pkgnum )';
 536       $and = 'AND pkgpart = ?';
 537       push @param, $pkgpart;
 538     } elsif ( $pkgpart eq '0' ) {
 539       $and = 'AND pkgnum IS NULL';
 540     }
 541   }
 542
 543   my $sth = dbh->prepare(
 544     "SELECT COUNT(*) FROM cust_svc $join WHERE svcpart = ? $and"
 545   ) or die dbh->errstr;
 546   $sth->execute(@param)
 547     or die $sth->errstr;
 548   $sth->fetchrow_arrayref->[0];
 549 }
 550
 551 =item svc_x
 552
 553 Returns a list of associated FS::svc_* records.
 554
 555 =cut
 556
 557 sub svc_x {
 558   my $self = shift;
 559   map { $_->svc_x } $self->cust_svc;
 560 }
 561
 562 =back
 563
 564 =head1 CLASS METHODS
 565
 566 =over 4
 567
 568 =cut
 569
 570 my $svc_defs;
 571 sub _svc_defs {
 572
 573   return $svc_defs if $svc_defs; #cache
 574
 575   my $conf = new FS::Conf;
 576
 577   #false laziness w/part_pkg.pm::plan_info
 578
 579   my %info;
 580   foreach my $INC ( @INC ) {
 581     warn "globbing $INC/FS/svc_*.pm\n" if $DEBUG;
 582     foreach my $file ( glob("$INC/FS/svc_*.pm") ) {
 583
 584       warn "attempting to load service table info from $file\n" if $DEBUG;
 585       $file =~ /\/(\w+)\.pm$/ or do {
 586         warn "unrecognized file in $INC/FS/: $file\n";
 587         next;
 588       };
 589       my $mod = $1;
 590
 591       if ( $mod =~ /^svc_[A-Z]/ or $mod =~ /^svc_acct_pop$/ ) {
 592         warn "skipping FS::$mod" if $DEBUG;
 593         next;
 594       }
 595
 596       eval "use FS::$mod;";
 597       if ( $@ ) {
 598         die "error using FS::$mod (skipping): $@\n" if $@;
 599         next;
 600       }
 601       unless ( UNIVERSAL::can("FS::$mod", 'table_info') ) {
 602         warn "FS::$mod has no table_info method; skipping";
 603         next;
 604       }
 605
 606       my $info = "FS::$mod"->table_info;
 607       unless ( keys %$info ) {
 608         warn "FS::$mod->table_info doesn't return info, skipping\n";
 609         next;
 610       }
 611       warn "got info from FS::$mod: $info\n" if $DEBUG;
 612       if ( exists($info->{'disabled'}) && $info->{'disabled'} ) {
 613         warn "skipping disabled service FS::$mod" if $DEBUG;
 614         next;
 615       }
 616       $info{$mod} = $info;
 617     }
 618   }
 619
 620   tie my %svc_defs, 'Tie::IxHash',
 621     map  { $_ => $info{$_}->{'fields'} }
 622     sort { $info{$a}->{'display_weight'} <=> $info{$b}->{'display_weight'} }
 623     keys %info,
 624   ;
 625
 626   # yuck.  maybe this won't be so bad when virtual fields become real fields
 627   my %vfields;
 628   foreach my $svcdb (grep dbdef->table($_), keys %svc_defs ) {
 629     eval "use FS::$svcdb;";
 630     my $self = "FS::$svcdb"->new;
 631     $vfields{$svcdb} = {};
 632     foreach my $field ($self->virtual_fields) { # svc_Common::virtual_fields with a null svcpart returns all of them
 633       my $pvf = $self->pvf($field);
 634       my @list = $pvf->list;
 635       if (scalar @list) {
 636         $svc_defs{$svcdb}->{$field} = { desc        => $pvf->label,
 637                                         type        => 'select',
 638                                         select_list => \@list };
 639       } else {
 640         $svc_defs{$svcdb}->{$field} = $pvf->label;
 641       } #endif
 642       $vfields{$svcdb}->{$field} = $pvf;
 643       warn "\$vfields{$svcdb}->{$field} = $pvf"
 644         if $DEBUG;
 645     } #next $field
 646   } #next $svcdb
 647
 648   $svc_defs = \%svc_defs; #cache
 649
 650 }
 651
 652 =item svc_tables
 653
 654 Returns a list of all svc_ tables.
 655
 656 =cut
 657
 658 sub svc_tables {
 659   my $class = shift;
 660   my $svc_defs = $class->_svc_defs;
 661   grep { defined( dbdef->table($_) ) } keys %$svc_defs;
 662 }
 663
 664 =item svc_table_fields TABLE
 665
 666 Given a table name, returns a hashref of field names.  The field names
 667 returned are those with additional (service-definition related) information,
 668 not necessarily all database fields of the table.  Pseudo-fields may also
 669 be returned (i.e. svc_acct.usergroup).
 670
 671 Each value of the hashref is another hashref, which can have one or more of
 672 the following keys:
 673
 674 =over 4
 675
 676 =item label - Description of the field
 677
 678 =item def_label - Optional description of the field in the context of service definitions
 679
 680 =item type - Currently "text", "select", "checkbox", "textarea", "disabled",
 681 some components specified by "select-.*.html", and a bunch more...
 682
 683 =item disable_default - This field should not allow a default value in service definitions
 684
 685 =item disable_fixed - This field should not allow a fixed value in service definitions
 686
 687 =item disable_inventory - This field should not allow inventory values in service definitions
 688
 689 =item select_list - If type is "text", this can be a listref of possible values.
 690
 691 =item select_table - An alternative to select_list, this defines a database table with the possible choices.
 692
 693 =item select_key - Used with select_table, this is the field name of keys
 694
 695 =item select_label - Used with select_table, this is the field name of labels
 696
 697 =back
 698
 699 =cut
 700
 701 #maybe this should move and be a class method in svc_Common.pm
 702 sub svc_table_fields {
 703   my($class, $table) = @_;
 704   my $svc_defs = $class->_svc_defs;
 705   my $def = $svc_defs->{$table};
 706
 707   foreach ( grep !ref($def->{$_}), keys %$def ) {
 708
 709     #normalize the shortcut in %info hash
 710     $def->{$_} = { 'label' => $def->{$_} };
 711
 712     $def->{$_}{'type'} ||= 'text';
 713
 714   }
 715
 716   $def;
 717 }
 718
 719 =back
 720
 721 =head1 SUBROUTINES
 722
 723 =over 4
 724
 725 =item process
 726
 727 Job-queue processor for web interface adds/edits
 728
 729 =cut
 730
 731 use Storable qw(thaw);
 732 use Data::Dumper;
 733 use MIME::Base64;
 734 sub process {
 735   my $job = shift;
 736
 737   my $param = thaw(decode_base64(shift));
 738   warn Dumper($param) if $DEBUG;
 739
 740   my $old = qsearchs('part_svc', { 'svcpart' => $param->{'svcpart'} })
 741     if $param->{'svcpart'};
 742
 743   #unmunge cgp_accessmodes (falze laziness-ish w/edit/process/svc_acct.cgi)
 744   $param->{'svc_acct__cgp_accessmodes'} ||=
 745     join(' ', sort
 746       grep { $_ !~ /^(flag|label)$/ }
 747            map { /^svc_acct__cgp_accessmodes_([\w\/]+)$/ or die "no way"; $1; }
 748                grep $param->{$_},
 749                     grep /^svc_acct__cgp_accessmodes_([\w\/]+)$/,
 750                          keys %$param
 751         );
 752
 753
 754   my $new = new FS::part_svc ( {
 755     map {
 756       $_ => $param->{$_};
 757   #  } qw(svcpart svc svcdb)
 758     } ( fields('part_svc'),
 759         map { my $svcdb = $_;
 760               my @fields = fields($svcdb);
 761               push @fields, 'usergroup' if $svcdb eq 'svc_acct'
 762                                         or $svcdb eq 'svc_broadband'; #kludge
 763
 764               map {
 765                     my $f = $svcdb.'__'.$_;
 766                     my $flag = $param->{ $f.'_flag' } || ''; #silence warnings
 767                     if ( $flag =~ /^[MAH]$/ ) {
 768                       $param->{ $f } = delete( $param->{ $f.'_classnum' } );
 769                     }
 770                     if ( $flag =~ /^S$/
 771                           or $_ eq 'usergroup' ) {
 772                       $param->{ $f } = ref($param->{ $f })
 773                                          ? join(',', @{$param->{ $f }} )
 774                                          : $param->{ $f };
 775                     }
 776                     ( $f, $f.'_flag', $f.'_label' );
 777                   }
 778                   @fields;
 779
 780             } FS::part_svc->svc_tables()
 781       )
 782   } );
 783
 784   my %exportnums =
 785     map { $_->exportnum => ( $param->{'exportnum'.$_->exportnum} || '') }
 786         qsearch('part_export', {} );
 787
 788   my $error;
 789   if ( $param->{'svcpart'} ) {
 790     $error = $new->replace( $old,
 791                             '1.3-COMPAT',    #totally bunk, as jeff noted
 792                             [ 'usergroup' ],
 793                             \%exportnums,
 794                             $job
 795                           );
 796   } else {
 797     $error = $new->insert( [ 'usergroup' ],
 798                            \%exportnums,
 799                            $job,
 800                          );
 801     $param->{'svcpart'} = $new->getfield('svcpart');
 802   }
 803
 804   die "$error\n" if $error;
 805 }
 806
 807 =item process_bulk_cust_svc
 808
 809 Job-queue processor for web interface bulk customer service changes
 810
 811 =cut
 812
 813 use Storable qw(thaw);
 814 use Data::Dumper;
 815 use MIME::Base64;
 816 sub process_bulk_cust_svc {
 817   my $job = shift;
 818
 819   my $param = thaw(decode_base64(shift));
 820   warn Dumper($param) if $DEBUG;
 821
 822   local($FS::svc_Common::noexport_hack) = 1
 823     if $param->{'noexport'};
 824
 825   my $old_part_svc =
 826     qsearchs('part_svc', { 'svcpart' => $param->{'old_svcpart'} } );
 827
 828   die "Must select a new service definition\n" unless $param->{'new_svcpart'};
 829
 830   #the rest should be abstracted out to to its own subroutine?
 831
 832   local $SIG{HUP} = 'IGNORE';
 833   local $SIG{INT} = 'IGNORE';
 834   local $SIG{QUIT} = 'IGNORE';
 835   local $SIG{TERM} = 'IGNORE';
 836   local $SIG{TSTP} = 'IGNORE';
 837   local $SIG{PIPE} = 'IGNORE';
 838
 839   my $oldAutoCommit = $FS::UID::AutoCommit;
 840   local $FS::UID::AutoCommit = 0;
 841   my $dbh = dbh;
 842
 843   local( $FS::cust_svc::ignore_quantity ) = 1;
 844
 845   my $total = $old_part_svc->num_cust_svc( $param->{'pkgpart'} );
 846
 847   my $n = 0;
 848   foreach my $old_cust_svc ( $old_part_svc->cust_svc( $param->{'pkgpart'} ) ) {
 849
 850     my $new_cust_svc = new FS::cust_svc { $old_cust_svc->hash };
 851
 852     $new_cust_svc->svcpart( $param->{'new_svcpart'} );
 853     my $error = $new_cust_svc->replace($old_cust_svc);
 854     if ( $error ) {
 855       $dbh->rollback if $oldAutoCommit;
 856       die "$error\n" if $error;
 857     }
 858
 859     $error = $job->update_statustext( int( 100 * ++$n / $total ) );
 860     if ( $error ) {
 861       $dbh->rollback if $oldAutoCommit;
 862       die $error if $error;
 863     }
 864
 865   }
 866
 867   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 868
 869   '';
 870
 871 }
 872
 873 sub _upgrade_data {  #class method
 874   my ($class, %opts) = @_;
 875
 876   my @part_svc_column = qsearch('part_svc_column', { 'columnname' => 'usergroup' });
 877   foreach my $col ( @part_svc_column ) {
 878     next if $col->columnvalue =~ /^[\d,]+$/ || !$col->columnvalue;
 879     my @groupnames = split(',',$col->columnvalue);
 880     my @groupnums;
 881     my $error = '';
 882     foreach my $groupname ( @groupnames ) {
 883         my $g = qsearchs('radius_group', { 'groupname' => $groupname } );
 884         unless ( $g ) {
 885             $g = new FS::radius_group {
 886                             'groupname' => $groupname,
 887                             'description' => $groupname,
 888                             };
 889             $error = $g->insert;
 890             die "Error inserting new radius_group for service definition group \"$groupname\": $error"
 891               if $error;
 892         }
 893         push @groupnums, $g->groupnum;
 894     }
 895     $col->columnvalue(join(',',@groupnums));
 896     $error = $col->replace;
 897     die $error if $error;
 898   }
 899
 900   my @badlabels = qsearch({
 901     'table' => 'part_svc_column',
 902     'hashref' => {},
 903     'extra_sql' => 'WHERE columnlabel IN ('.
 904       "'Descriptive label for this particular device.',".
 905       "'IP address.  Leave blank for automatic assignment.',".
 906       "'Maximum upload speed for this service in Kbps.  0 denotes unlimited.',".
 907       "'Maximum download speed for this service in Kbps.  0 denotes unlimited.')"
 908   });
 909   foreach my $col ( @badlabels ) {
 910     $col->columnlabel('');
 911     my $error = $col->replace;
 912     die $error if $error;
 913   }
 914
 915 }
 916
 917 =head1 BUGS
 918
 919 Delete is unimplemented.
 920
 921 The list of svc_* tables is no longer hardcoded, but svc_acct_pop is skipped
 922 as a special case until it is renamed.
 923
 924 all_part_svc_column methods should be documented
 925
 926 =head1 SEE ALSO
 927
 928 L<FS::Record>, L<FS::part_svc_column>, L<FS::part_pkg>, L<FS::pkg_svc>,
 929 L<FS::cust_svc>, L<FS::svc_acct>, L<FS::svc_forward>, L<FS::svc_domain>,
 930 schema.html from the base documentation.
 931
 932 =cut
 933
 934 1;
 935