FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::cust_bill;
  11 use FS::cust_bill_pkg;
  12 use FS::cust_bill_pkg_display;
  13 use FS::cust_bill_pay;
  14 use FS::cust_credit_bill;
  15 use FS::cust_tax_adjustment;
  16 use FS::tax_rate;
  17 use FS::tax_rate_location;
  18 use FS::cust_bill_pkg_tax_location;
  19 use FS::cust_bill_pkg_tax_rate_location;
  20 use FS::part_event;
  21 use FS::part_event_condition;
  22 use FS::pkg_category;
  23
  24 # 1 is mostly method/subroutine entry and options
  25 # 2 traces progress of some operations
  26 # 3 is even more information including possibly sensitive data
  27 $DEBUG = 0;
  28 $me = '[FS::cust_main::Billing]';
  29
  30 install_callback FS::UID sub {
  31   $conf = new FS::Conf;
  32   #yes, need it for stuff below (prolly should be cached)
  33 };
  34
  35 =head1 NAME
  36
  37 FS::cust_main::Billing - Billing mixin for cust_main
  38
  39 =head1 SYNOPSIS
  40
  41 =head1 DESCRIPTION
  42
  43 These methods are available on FS::cust_main objects.
  44
  45 =head1 METHODS
  46
  47 =over 4
  48
  49 =item bill_and_collect
  50
  51 Cancels and suspends any packages due, generates bills, applies payments and
  52 credits, and applies collection events to run cards, send bills and notices,
  53 etc.
  54
  55 By default, warns on errors and continues with the next operation (but see the
  56 "fatal" flag below).
  57
  58 Options are passed as name-value pairs.  Currently available options are:
  59
  60 =over 4
  61
  62 =item time
  63
  64 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  65
  66  use Date::Parse;
  67  ...
  68  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  69
  70 =item invoice_time
  71
  72 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  73
  74 =item check_freq
  75
  76 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  77
  78 =item resetup
  79
  80 If set true, re-charges setup fees.
  81
  82 =item fatal
  83
  84 If set any errors prevent subsequent operations from continusing.  If set
  85 specifically to "return", returns the error (or false, if there is no error).
  86 Any other true value causes errors to die.
  87
  88 =item debug
  89
  90 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  91
  92 =item job
  93
  94 Optional FS::queue entry to receive status updates.
  95
  96 =back
  97
  98 Options are passed to the B<bill> and B<collect> methods verbatim, so all
  99 options of those methods are also available.
 100
 101 =cut
 102
 103 sub bill_and_collect {
 104   my( $self, %options ) = @_;
 105
 106   my $error;
 107
 108   #$options{actual_time} not $options{time} because freeside-daily -d is for
 109   #pre-printing invoices
 110
 111   $options{'actual_time'} ||= time;
 112   my $job = $options{'job'};
 113
 114   $job->update_statustext('0,cleaning expired packages') if $job;
 115   $error = $self->cancel_expired_pkgs( $options{actual_time} );
 116   if ( $error ) {
 117     $error = "Error expiring custnum ". $self->custnum. ": $error";
 118     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 119     elsif ( $options{fatal}                                ) { die    $error; }
 120     else                                                     { warn   $error; }
 121   }
 122
 123   $error = $self->suspend_adjourned_pkgs( $options{actual_time} );
 124   if ( $error ) {
 125     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 126     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 127     elsif ( $options{fatal}                                ) { die    $error; }
 128     else                                                     { warn   $error; }
 129   }
 130
 131   $job->update_statustext('20,billing packages') if $job;
 132   $error = $self->bill( %options );
 133   if ( $error ) {
 134     $error = "Error billing custnum ". $self->custnum. ": $error";
 135     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 136     elsif ( $options{fatal}                                ) { die    $error; }
 137     else                                                     { warn   $error; }
 138   }
 139
 140   $job->update_statustext('50,applying payments and credits') if $job;
 141   $error = $self->apply_payments_and_credits;
 142   if ( $error ) {
 143     $error = "Error applying custnum ". $self->custnum. ": $error";
 144     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 145     elsif ( $options{fatal}                                ) { die    $error; }
 146     else                                                     { warn   $error; }
 147   }
 148
 149   $job->update_statustext('70,running collection events') if $job;
 150   unless ( $conf->exists('cancelled_cust-noevents')
 151            && ! $self->num_ncancelled_pkgs
 152   ) {
 153     $error = $self->collect( %options );
 154     if ( $error ) {
 155       $error = "Error collecting custnum ". $self->custnum. ": $error";
 156       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 157       elsif ($options{fatal}                               ) { die    $error; }
 158       else                                                   { warn   $error; }
 159     }
 160   }
 161   $job->update_statustext('100,finished') if $job;
 162
 163   '';
 164
 165 }
 166
 167 sub cancel_expired_pkgs {
 168   my ( $self, $time, %options ) = @_;
 169
 170   my @cancel_pkgs = $self->ncancelled_pkgs( {
 171     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 172   } );
 173
 174   my @errors = ();
 175
 176   foreach my $cust_pkg ( @cancel_pkgs ) {
 177     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 178     my $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 179                                            'reason_otaker' => $cpr->otaker
 180                                          )
 181                                        : ()
 182                                  );
 183     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 184   }
 185
 186   scalar(@errors) ? join(' / ', @errors) : '';
 187
 188 }
 189
 190 sub suspend_adjourned_pkgs {
 191   my ( $self, $time, %options ) = @_;
 192
 193   my @susp_pkgs = $self->ncancelled_pkgs( {
 194     'extra_sql' =>
 195       " AND ( susp IS NULL OR susp = 0 )
 196         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 197               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 198             )
 199       ",
 200   } );
 201
 202   #only because there's no SQL test for is_prepaid :/
 203   @susp_pkgs =
 204     grep {     (    $_->part_pkg->is_prepaid
 205                  && $_->bill
 206                  && $_->bill < $time
 207                )
 208             || (    $_->adjourn
 209                  && $_->adjourn <= $time
 210                )
 211
 212          }
 213          @susp_pkgs;
 214
 215   my @errors = ();
 216
 217   foreach my $cust_pkg ( @susp_pkgs ) {
 218     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 219       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 220     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 221                                             'reason_otaker' => $cpr->otaker
 222                                           )
 223                                         : ()
 224                                   );
 225     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 226   }
 227
 228   scalar(@errors) ? join(' / ', @errors) : '';
 229
 230 }
 231
 232 =item bill OPTIONS
 233
 234 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 235 conjunction with the collect method by calling B<bill_and_collect>.
 236
 237 If there is an error, returns the error, otherwise returns false.
 238
 239 Options are passed as name-value pairs.  Currently available options are:
 240
 241 =over 4
 242
 243 =item resetup
 244
 245 If set true, re-charges setup fees.
 246
 247 =item recurring_only
 248
 249 If set true then only bill recurring charges, not setup, usage, one time
 250 charges, etc.
 251
 252 =item freq_override
 253
 254 If set, then override the normal frequency and look for a part_pkg_discount
 255 to take at that frequency.
 256
 257 =item time
 258
 259 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 260
 261  use Date::Parse;
 262  ...
 263  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 264
 265 =item pkg_list
 266
 267 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 268
 269  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 270
 271 =item not_pkgpart
 272
 273 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 274
 275 =item invoice_time
 276
 277 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 278
 279 =item cancel
 280
 281 This boolean value informs the us that the package is being cancelled.  This
 282 typically might mean not charging the normal recurring fee but only usage
 283 fees since the last billing. Setup charges may be charged.  Not all package
 284 plans support this feature (they tend to charge 0).
 285
 286 =item no_usage_reset
 287
 288 Prevent the resetting of usage limits during this call.
 289
 290 =item no_commit
 291
 292 Do not save the generated bill in the database.  Useful with return_bill
 293
 294 =item return_bill
 295
 296 A list reference on which the generated bill(s) will be returned.
 297
 298 =item invoice_terms
 299
 300 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 301 terms or the default terms are used.
 302
 303 =back
 304
 305 =cut
 306
 307 sub bill {
 308   my( $self, %options ) = @_;
 309
 310   return '' if $self->payby eq 'COMP';
 311
 312   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 313
 314   warn "$me bill customer ". $self->custnum. "\n"
 315     if $DEBUG;
 316
 317   my $time = $options{'time'} || time;
 318   my $invoice_time = $options{'invoice_time'} || $time;
 319
 320   $options{'not_pkgpart'} ||= {};
 321   $options{'not_pkgpart'} = { map { $_ => 1 }
 322                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 323                             }
 324     unless ref($options{'not_pkgpart'});
 325
 326   local $SIG{HUP} = 'IGNORE';
 327   local $SIG{INT} = 'IGNORE';
 328   local $SIG{QUIT} = 'IGNORE';
 329   local $SIG{TERM} = 'IGNORE';
 330   local $SIG{TSTP} = 'IGNORE';
 331   local $SIG{PIPE} = 'IGNORE';
 332
 333   my $oldAutoCommit = $FS::UID::AutoCommit;
 334   local $FS::UID::AutoCommit = 0;
 335   my $dbh = dbh;
 336
 337   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 338     if $DEBUG;
 339
 340   $self->select_for_update; #mutex
 341
 342   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 343     if $DEBUG;
 344
 345   my $error = $self->do_cust_event(
 346     'debug'      => ( $options{'debug'} || 0 ),
 347     'time'       => $invoice_time,
 348     'check_freq' => $options{'check_freq'},
 349     'stage'      => 'pre-bill',
 350   )
 351     unless $options{no_commit};
 352   if ( $error ) {
 353     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 354     return $error;
 355   }
 356
 357   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 358     if $DEBUG;
 359
 360   #keep auto-charge and non-auto-charge line items separate
 361   my @passes = ( '', 'no_auto' );
 362
 363   my %cust_bill_pkg = map { $_ => [] } @passes;
 364
 365   ###
 366   # find the packages which are due for billing, find out how much they are
 367   # & generate invoice database.
 368   ###
 369
 370   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 371   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 372
 373   my %taxlisthash = map { $_ => {} } @passes;
 374
 375   my @precommit_hooks = ();
 376
 377   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 378   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 379
 380     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 381
 382     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG > 1;
 383
 384     #? to avoid use of uninitialized value errors... ?
 385     $cust_pkg->setfield('bill', '')
 386       unless defined($cust_pkg->bill);
 387
 388     #my $part_pkg = $cust_pkg->part_pkg;
 389
 390     my $real_pkgpart = $cust_pkg->pkgpart;
 391     my %hash = $cust_pkg->hash;
 392
 393     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 394     # suffer from performance issues
 395     $options{has_hidden} = 0;
 396     my @part_pkg = $cust_pkg->part_pkg->self_and_bill_linked;
 397     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 398
 399     foreach my $part_pkg ( @part_pkg ) {
 400
 401       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 402
 403       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 404
 405       my $error =
 406         $self->_make_lines( 'part_pkg'            => $part_pkg,
 407                             'cust_pkg'            => $cust_pkg,
 408                             'precommit_hooks'     => \@precommit_hooks,
 409                             'line_items'          => $cust_bill_pkg{$pass},
 410                             'setup'               => $total_setup{$pass},
 411                             'recur'               => $total_recur{$pass},
 412                             'tax_matrix'          => $taxlisthash{$pass},
 413                             'time'                => $time,
 414                             'real_pkgpart'        => $real_pkgpart,
 415                             'options'             => \%options,
 416                           );
 417       if ($error) {
 418         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 419         return $error;
 420       }
 421
 422     } #foreach my $part_pkg
 423
 424   } #foreach my $cust_pkg
 425
 426   #if the customer isn't on an automatic payby, everything can go on a single
 427   #invoice anyway?
 428   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 429     #merge everything into one list
 430   #}
 431
 432   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 433
 434     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 435
 436     next unless @cust_bill_pkg; #don't create an invoice w/o line items
 437
 438     warn "$me billing pass $pass\n"
 439            #.Dumper(\@cust_bill_pkg)."\n"
 440       if $DEBUG > 2;
 441
 442     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 443            !$conf->exists('postal_invoice-recurring_only')
 444        )
 445     {
 446
 447       my $postal_pkg = $self->charge_postal_fee();
 448       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 449
 450         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 451         return "can't charge postal invoice fee for customer ".
 452           $self->custnum. ": $postal_pkg";
 453
 454       } elsif ( $postal_pkg ) {
 455
 456         my $real_pkgpart = $postal_pkg->pkgpart;
 457         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 458         # suffer from performance issues
 459         $options{has_hidden} = 0;
 460         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 461         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 462
 463         foreach my $part_pkg ( @part_pkg ) {
 464           my %postal_options = %options;
 465           delete $postal_options{cancel};
 466           my $error =
 467             $self->_make_lines( 'part_pkg'            => $part_pkg,
 468                                 'cust_pkg'            => $postal_pkg,
 469                                 'precommit_hooks'     => \@precommit_hooks,
 470                                 'line_items'          => \@cust_bill_pkg,
 471                                 'setup'               => $total_setup{$pass},
 472                                 'recur'               => $total_recur{$pass},
 473                                 'tax_matrix'          => $taxlisthash{$pass},
 474                                 'time'                => $time,
 475                                 'real_pkgpart'        => $real_pkgpart,
 476                                 'options'             => \%postal_options,
 477                               );
 478           if ($error) {
 479             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 480             return $error;
 481           }
 482         }
 483
 484         # it's silly to have a zero value postal_pkg, but....
 485         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 486
 487       }
 488
 489     }
 490
 491     my $listref_or_error =
 492       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 493
 494     unless ( ref( $listref_or_error ) ) {
 495       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 496       return $listref_or_error;
 497     }
 498
 499     foreach my $taxline ( @$listref_or_error ) {
 500       ${ $total_setup{$pass} } =
 501         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 502       push @cust_bill_pkg, $taxline;
 503     }
 504
 505     #add tax adjustments
 506     warn "adding tax adjustments...\n" if $DEBUG > 2;
 507     foreach my $cust_tax_adjustment (
 508       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 509                                        'billpkgnum' => '',
 510                                      }
 511              )
 512     ) {
 513
 514       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 515
 516       my $itemdesc = $cust_tax_adjustment->taxname;
 517       $itemdesc = '' if $itemdesc eq 'Tax';
 518
 519       push @cust_bill_pkg, new FS::cust_bill_pkg {
 520         'pkgnum'      => 0,
 521         'setup'       => $tax,
 522         'recur'       => 0,
 523         'sdate'       => '',
 524         'edate'       => '',
 525         'itemdesc'    => $itemdesc,
 526         'itemcomment' => $cust_tax_adjustment->comment,
 527         'cust_tax_adjustment' => $cust_tax_adjustment,
 528         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 529       };
 530
 531     }
 532
 533     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 534
 535     my @cust_bill = $self->cust_bill;
 536     my $balance = $self->balance;
 537     my $previous_balance = scalar(@cust_bill)
 538                              ? ( $cust_bill[$#cust_bill]->billing_balance || 0 )
 539                              : 0;
 540
 541     $previous_balance += $cust_bill[$#cust_bill]->charged
 542       if scalar(@cust_bill);
 543     #my $balance_adjustments =
 544     #  sprintf('%.2f', $balance - $prior_prior_balance - $prior_charged);
 545
 546     warn "creating the new invoice\n" if $DEBUG;
 547     #create the new invoice
 548     my $cust_bill = new FS::cust_bill ( {
 549       'custnum'             => $self->custnum,
 550       '_date'               => $invoice_time,
 551       'charged'             => $charged,
 552       'billing_balance'     => $balance,
 553       'previous_balance'    => $previous_balance,
 554       'invoice_terms'       => $options{'invoice_terms'},
 555       'cust_bill_pkg'       => \@cust_bill_pkg,
 556     } );
 557     $error = $cust_bill->insert unless $options{no_commit};
 558     if ( $error ) {
 559       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 560       return "can't create invoice for customer #". $self->custnum. ": $error";
 561     }
 562     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 563
 564   } #foreach my $pass ( keys %cust_bill_pkg )
 565
 566   foreach my $hook ( @precommit_hooks ) {
 567     eval {
 568       &{$hook}; #($self) ?
 569     } unless $options{no_commit};
 570     if ( $@ ) {
 571       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 572       return "$@ running precommit hook $hook\n";
 573     }
 574   }
 575
 576   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 577
 578   ''; #no error
 579 }
 580
 581 #discard bundled packages of 0 value
 582 sub _omit_zero_value_bundles {
 583
 584   my @cust_bill_pkg = ();
 585   my @cust_bill_pkg_bundle = ();
 586   my $sum = 0;
 587   my $discount_show_always = 0;
 588
 589   foreach my $cust_bill_pkg ( @_ ) {
 590     $discount_show_always = ($cust_bill_pkg->get('discounts')
 591                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 592                                 && $conf->exists('discount-show-always'));
 593     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 594       push @cust_bill_pkg, @cust_bill_pkg_bundle
 595                         if ($sum > 0 || ($sum == 0 && $discount_show_always));
 596       @cust_bill_pkg_bundle = ();
 597       $sum = 0;
 598     }
 599     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 600     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 601   }
 602   push @cust_bill_pkg, @cust_bill_pkg_bundle
 603                         if ($sum > 0 || ($sum == 0 && $discount_show_always));
 604
 605   (@cust_bill_pkg);
 606
 607 }
 608
 609 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 610
 611 This is a weird one.  Perhaps it should not even be exposed.
 612
 613 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 614 Usually used internally by bill method B<bill>.
 615
 616 If there is an error, returns the error, otherwise returns reference to a
 617 list of line items suitable for insertion.
 618
 619 =over 4
 620
 621 =item LINEITEMREF
 622
 623 An array ref of the line items being billed.
 624
 625 =item TAXHASHREF
 626
 627 A strange beast.  The keys to this hash are internal identifiers consisting
 628 of the name of the tax object type, a space, and its unique identifier ( e.g.
 629  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 630 item in the list is the tax object.  The remaining items are either line
 631 items or floating point values (currency amounts).
 632
 633 The taxes are calculated on this entity.  Calculated exemption records are
 634 transferred to the LINEITEMREF items on the assumption that they are related.
 635
 636 Read the source.
 637
 638 =item INVOICE_TIME
 639
 640 This specifies the date appearing on the associated invoice.  Some
 641 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 642
 643 =back
 644
 645 =cut
 646
 647 sub calculate_taxes {
 648   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 649
 650   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 651
 652   warn "$me calculate_taxes\n"
 653        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 654     if $DEBUG > 2;
 655
 656   my @tax_line_items = ();
 657
 658   # keys are tax names (as printed on invoices / itemdesc )
 659   # values are listrefs of taxlisthash keys (internal identifiers)
 660   my %taxname = ();
 661
 662   # keys are taxlisthash keys (internal identifiers)
 663   # values are (cumulative) amounts
 664   my %tax = ();
 665
 666   # keys are taxlisthash keys (internal identifiers)
 667   # values are listrefs of cust_bill_pkg_tax_location hashrefs
 668   my %tax_location = ();
 669
 670   # keys are taxlisthash keys (internal identifiers)
 671   # values are listrefs of cust_bill_pkg_tax_rate_location hashrefs
 672   my %tax_rate_location = ();
 673
 674   foreach my $tax ( keys %$taxlisthash ) {
 675     my $tax_object = shift @{ $taxlisthash->{$tax} };
 676     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 677     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 678     my $hashref_or_error =
 679       $tax_object->taxline( $taxlisthash->{$tax},
 680                             'custnum'      => $self->custnum,
 681                             'invoice_time' => $invoice_time
 682                           );
 683     return $hashref_or_error unless ref($hashref_or_error);
 684
 685     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 686
 687     my $name   = $hashref_or_error->{'name'};
 688     my $amount = $hashref_or_error->{'amount'};
 689
 690     #warn "adding $amount as $name\n";
 691     $taxname{ $name } ||= [];
 692     push @{ $taxname{ $name } }, $tax;
 693
 694     $tax{ $tax } += $amount;
 695
 696     $tax_location{ $tax } ||= [];
 697     if ( $tax_object->get('pkgnum') || $tax_object->get('locationnum') ) {
 698       push @{ $tax_location{ $tax }  },
 699         {
 700           'taxnum'      => $tax_object->taxnum,
 701           'taxtype'     => ref($tax_object),
 702           'pkgnum'      => $tax_object->get('pkgnum'),
 703           'locationnum' => $tax_object->get('locationnum'),
 704           'amount'      => sprintf('%.2f', $amount ),
 705         };
 706     }
 707
 708     $tax_rate_location{ $tax } ||= [];
 709     if ( ref($tax_object) eq 'FS::tax_rate' ) {
 710       my $taxratelocationnum =
 711         $tax_object->tax_rate_location->taxratelocationnum;
 712       push @{ $tax_rate_location{ $tax }  },
 713         {
 714           'taxnum'             => $tax_object->taxnum,
 715           'taxtype'            => ref($tax_object),
 716           'amount'             => sprintf('%.2f', $amount ),
 717           'locationtaxid'      => $tax_object->location,
 718           'taxratelocationnum' => $taxratelocationnum,
 719         };
 720     }
 721
 722   }
 723
 724   #move the cust_tax_exempt_pkg records to the cust_bill_pkgs we will commit
 725   my %packagemap = map { $_->pkgnum => $_ } @$cust_bill_pkg;
 726   foreach my $tax ( keys %$taxlisthash ) {
 727     foreach ( @{ $taxlisthash->{$tax} }[1 ... scalar(@{ $taxlisthash->{$tax} })] ) {
 728       next unless ref($_) eq 'FS::cust_bill_pkg';
 729
 730       my @cust_tax_exempt_pkg = splice( @{ $_->_cust_tax_exempt_pkg } );
 731
 732       next unless @cust_tax_exempt_pkg; #just avoiding the prob when irrelevant?
 733       die "can't distribute tax exemptions: no line item for ".  Dumper($_).
 734           " in packagemap ". join(',', sort {$a<=>$b} keys %packagemap). "\n"
 735         unless $packagemap{$_->pkgnum};
 736
 737       push @{ $packagemap{$_->pkgnum}->_cust_tax_exempt_pkg },
 738            @cust_tax_exempt_pkg;
 739     }
 740   }
 741
 742   #consolidate and create tax line items
 743   warn "consolidating and generating...\n" if $DEBUG > 2;
 744   foreach my $taxname ( keys %taxname ) {
 745     my $tax = 0;
 746     my %seen = ();
 747     my @cust_bill_pkg_tax_location = ();
 748     my @cust_bill_pkg_tax_rate_location = ();
 749     warn "adding $taxname\n" if $DEBUG > 1;
 750     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 751       next if $seen{$taxitem}++;
 752       warn "adding $tax{$taxitem}\n" if $DEBUG > 1;
 753       $tax += $tax{$taxitem};
 754       push @cust_bill_pkg_tax_location,
 755         map { new FS::cust_bill_pkg_tax_location $_ }
 756             @{ $tax_location{ $taxitem } };
 757       push @cust_bill_pkg_tax_rate_location,
 758         map { new FS::cust_bill_pkg_tax_rate_location $_ }
 759             @{ $tax_rate_location{ $taxitem } };
 760     }
 761     next unless $tax;
 762
 763     $tax = sprintf('%.2f', $tax );
 764
 765     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
 766                                                    'disabled'     => '',
 767                                                  },
 768                                );
 769
 770     my @display = ();
 771     if ( $pkg_category and
 772          $conf->config('invoice_latexsummary') ||
 773          $conf->config('invoice_htmlsummary')
 774        )
 775     {
 776
 777       my %hash = (  'section' => $pkg_category->categoryname );
 778       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
 779
 780     }
 781
 782     push @tax_line_items, new FS::cust_bill_pkg {
 783       'pkgnum'   => 0,
 784       'setup'    => $tax,
 785       'recur'    => 0,
 786       'sdate'    => '',
 787       'edate'    => '',
 788       'itemdesc' => $taxname,
 789       'display'  => \@display,
 790       'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 791       'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 792     };
 793
 794   }
 795
 796   \@tax_line_items;
 797 }
 798
 799 sub _make_lines {
 800   my ($self, %params) = @_;
 801
 802   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 803
 804   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 805   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 806   my $precommit_hooks = $params{precommit_hooks} or die "no package specified";
 807   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 808   my $total_setup = $params{setup} or die "no setup accumulator specified";
 809   my $total_recur = $params{recur} or die "no recur accumulator specified";
 810   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
 811   my $time = $params{'time'} or die "no time specified";
 812   my (%options) = %{$params{options}};
 813
 814   my $dbh = dbh;
 815   my $real_pkgpart = $params{real_pkgpart};
 816   my %hash = $cust_pkg->hash;
 817   my $old_cust_pkg = new FS::cust_pkg \%hash;
 818
 819   my @details = ();
 820   my @discounts = ();
 821   my $lineitems = 0;
 822
 823   $cust_pkg->pkgpart($part_pkg->pkgpart);
 824
 825   ###
 826   # bill setup
 827   ###
 828
 829   my $setup = 0;
 830   my $unitsetup = 0;
 831   my %setup_param = ();
 832   if (     ! $options{recurring_only}
 833        and ! $options{cancel}
 834        and ( $options{'resetup'}
 835              || ( ! $cust_pkg->setup
 836                   && ( ! $cust_pkg->start_date
 837                        || $cust_pkg->start_date <= $time
 838                      )
 839                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
 840                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
 841                             ! $cust_pkg->getfield('susp')
 842                           )
 843                      )
 844                 )
 845            )
 846      )
 847   {
 848
 849     warn "    bill setup\n" if $DEBUG > 1;
 850
 851     unless ( $cust_pkg->waive_setup ) {
 852         $lineitems++;
 853
 854         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
 855         return "$@ running calc_setup for $cust_pkg\n"
 856           if $@;
 857
 858         $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
 859     }
 860
 861     $cust_pkg->setfield('setup', $time)
 862       unless $cust_pkg->setup;
 863           #do need it, but it won't get written to the db
 864           #|| $cust_pkg->pkgpart != $real_pkgpart;
 865
 866     $cust_pkg->setfield('start_date', '')
 867       if $cust_pkg->start_date;
 868
 869   }
 870
 871   ###
 872   # bill recurring fee
 873   ###
 874
 875   #XXX unit stuff here too
 876   my $recur = 0;
 877   my $unitrecur = 0;
 878   my $sdate;
 879   if (     ! $cust_pkg->start_date
 880        and ( ! $cust_pkg->susp || $part_pkg->option('suspend_bill', 1) )
 881        and
 882             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $time )
 883          || ( $part_pkg->plan eq 'voip_cdr'
 884                && $part_pkg->option('bill_every_call')
 885             )
 886          || $options{cancel}
 887   ) {
 888
 889     # XXX should this be a package event?  probably.  events are called
 890     # at collection time at the moment, though...
 891     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
 892       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
 893       #don't want to reset usage just cause we want a line item??
 894       #&& $part_pkg->pkgpart == $real_pkgpart;
 895
 896     warn "    bill recur\n" if $DEBUG > 1;
 897     $lineitems++;
 898
 899     # XXX shared with $recur_prog
 900     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
 901              || $cust_pkg->setup
 902              || $time;
 903
 904     #over two params!  lets at least switch to a hashref for the rest...
 905     my $increment_next_bill = ( $part_pkg->freq ne '0'
 906                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $time
 907                                 && !$options{cancel}
 908                               );
 909     my %param = ( 'precommit_hooks'     => $precommit_hooks,
 910                   'increment_next_bill' => $increment_next_bill,
 911                   'discounts'           => \@discounts,
 912                   'real_pkgpart'        => $real_pkgpart,
 913                   'freq_override'       => $options{freq_override} || '',
 914                   %setup_param,
 915                 );
 916
 917     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
 918
 919     # There may be some part_pkg for which this is wrong.  Only those
 920     # which can_discount are supported.
 921     # (the UI should prevent adding discounts to these at the moment)
 922
 923     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
 924     return "$@ running $method for $cust_pkg\n"
 925       if ( $@ );
 926
 927     if ( $increment_next_bill ) {
 928
 929       my $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
 930       return "unparsable frequency: ". $part_pkg->freq
 931         if $next_bill == -1;
 932
 933       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
 934       # only for figuring next bill date, nothing else, so, reset $sdate again
 935       # here
 936       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
 937       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
 938       $cust_pkg->last_bill($sdate);
 939
 940       $cust_pkg->setfield('bill', $next_bill );
 941
 942     }
 943
 944     if ( defined $param{'discount_left_setup'} ) {
 945         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
 946             $setup -= $discount_setup;
 947         }
 948     }
 949
 950   }
 951
 952   warn "\$setup is undefined" unless defined($setup);
 953   warn "\$recur is undefined" unless defined($recur);
 954   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
 955
 956   ###
 957   # If there's line items, create em cust_bill_pkg records
 958   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
 959   ###
 960
 961   if ( $lineitems ) {
 962
 963     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
 964       # hmm.. and if just the options are modified in some weird price plan?
 965
 966       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
 967         if $DEBUG >1;
 968
 969       my $error = $cust_pkg->replace( $old_cust_pkg,
 970                                       'depend_jobnum'=>$options{depend_jobnum},
 971                                       'options' => { $cust_pkg->options },
 972                                     )
 973         unless $options{no_commit};
 974       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
 975         if $error; #just in case
 976     }
 977
 978     $setup = sprintf( "%.2f", $setup );
 979     $recur = sprintf( "%.2f", $recur );
 980     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
 981       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
 982     }
 983     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
 984       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
 985     }
 986
 987     my $discount_show_always = ($recur == 0 && scalar(@discounts)
 988                                 && $conf->exists('discount-show-always'));
 989
 990     if ( $setup != 0 ||
 991          $recur != 0 ||
 992          (!$part_pkg->hidden && $options{has_hidden}) || #include some $0 lines
 993          $discount_show_always )
 994     {
 995
 996       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
 997         if $DEBUG > 1;
 998
 999       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1000       if ( $DEBUG > 1 ) {
1001         warn "      adding customer package invoice detail: $_\n"
1002           foreach @cust_pkg_detail;
1003       }
1004       push @details, @cust_pkg_detail;
1005
1006       my $cust_bill_pkg = new FS::cust_bill_pkg {
1007         'pkgnum'    => $cust_pkg->pkgnum,
1008         'setup'     => $setup,
1009         'unitsetup' => $unitsetup,
1010         'recur'     => $recur,
1011         'unitrecur' => $unitrecur,
1012         'quantity'  => $cust_pkg->quantity,
1013         'details'   => \@details,
1014         'discounts' => \@discounts,
1015         'hidden'    => $part_pkg->hidden,
1016         'freq'      => $part_pkg->freq,
1017       };
1018
1019       if ( $part_pkg->option('recur_temporality', 1) eq 'preceding' ) {
1020         $cust_bill_pkg->sdate( $hash{last_bill} );
1021         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1022         $cust_bill_pkg->edate( $time ) if $options{cancel};
1023       } else { #if ( $part_pkg->option('recur_temporality', 1) eq 'upcoming' ) {
1024         $cust_bill_pkg->sdate( $sdate );
1025         $cust_bill_pkg->edate( $cust_pkg->bill );
1026         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1027       }
1028
1029       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1030         unless $part_pkg->pkgpart == $real_pkgpart;
1031
1032       $$total_setup += $setup;
1033       $$total_recur += $recur;
1034
1035       ###
1036       # handle taxes
1037       ###
1038
1039       unless ( $discount_show_always ) {
1040       my $error =
1041         $self->_handle_taxes($part_pkg, $taxlisthash, $cust_bill_pkg, $cust_pkg, $options{invoice_time}, $real_pkgpart, \%options);
1042       return $error if $error;
1043       }
1044
1045       push @$cust_bill_pkgs, $cust_bill_pkg;
1046
1047     } #if $setup != 0 || $recur != 0
1048
1049   } #if $line_items
1050
1051   '';
1052
1053 }
1054
1055 sub _handle_taxes {
1056   my $self = shift;
1057   my $part_pkg = shift;
1058   my $taxlisthash = shift;
1059   my $cust_bill_pkg = shift;
1060   my $cust_pkg = shift;
1061   my $invoice_time = shift;
1062   my $real_pkgpart = shift;
1063   my $options = shift;
1064
1065   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1066
1067   my %cust_bill_pkg = ();
1068   my %taxes = ();
1069
1070   my @classes;
1071   #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1072   push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1073   push @classes, 'setup' if ($cust_bill_pkg->setup && !$options->{cancel});
1074   push @classes, 'recur' if ($cust_bill_pkg->recur && !$options->{cancel});
1075
1076   if ( $self->tax !~ /Y/i && $self->payby ne 'COMP' ) {
1077
1078     if ( $conf->exists('enable_taxproducts')
1079          && ( scalar($part_pkg->part_pkg_taxoverride)
1080               || $part_pkg->has_taxproduct
1081             )
1082        )
1083     {
1084
1085       foreach my $class (@classes) {
1086         my $err_or_ref = $self->_gather_taxes( $part_pkg, $class, $cust_pkg );
1087         return $err_or_ref unless ref($err_or_ref);
1088         $taxes{$class} = $err_or_ref;
1089       }
1090
1091       unless (exists $taxes{''}) {
1092         my $err_or_ref = $self->_gather_taxes( $part_pkg, '', $cust_pkg );
1093         return $err_or_ref unless ref($err_or_ref);
1094         $taxes{''} = $err_or_ref;
1095       }
1096
1097     } else {
1098
1099       my @loc_keys = qw( city county state country );
1100       my %taxhash;
1101       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1102         my $cust_location = $cust_pkg->cust_location;
1103         %taxhash = map { $_ => $cust_location->$_()    } @loc_keys;
1104       } else {
1105         my $prefix =
1106           ( $conf->exists('tax-ship_address') && length($self->ship_last) )
1107           ? 'ship_'
1108           : '';
1109         %taxhash = map { $_ => $self->get("$prefix$_") } @loc_keys;
1110       }
1111
1112       $taxhash{'taxclass'} = $part_pkg->taxclass;
1113
1114       my @taxes = ();
1115       my %taxhash_elim = %taxhash;
1116       my @elim = qw( city county state );
1117       do {
1118
1119         #first try a match with taxclass
1120         @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1121
1122         if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1123           #then try a match without taxclass
1124           my %no_taxclass = %taxhash_elim;
1125           $no_taxclass{ 'taxclass' } = '';
1126           @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1127         }
1128
1129         $taxhash_elim{ shift(@elim) } = '';
1130
1131       } while ( !scalar(@taxes) && scalar(@elim) );
1132
1133       @taxes = grep { ! $_->taxname or ! $self->tax_exemption($_->taxname) }
1134                     @taxes
1135         if $self->cust_main_exemption; #just to be safe
1136
1137       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1138         foreach (@taxes) {
1139           $_->set('pkgnum',      $cust_pkg->pkgnum );
1140           $_->set('locationnum', $cust_pkg->locationnum );
1141         }
1142       }
1143
1144       $taxes{''} = [ @taxes ];
1145       $taxes{'setup'} = [ @taxes ];
1146       $taxes{'recur'} = [ @taxes ];
1147       $taxes{$_} = [ @taxes ] foreach (@classes);
1148
1149       # # maybe eliminate this entirely, along with all the 0% records
1150       # unless ( @taxes ) {
1151       #   return
1152       #     "fatal: can't find tax rate for state/county/country/taxclass ".
1153       #     join('/', map $taxhash{$_}, qw(state county country taxclass) );
1154       # }
1155
1156     } #if $conf->exists('enable_taxproducts') ...
1157
1158   }
1159
1160   my @display = ();
1161   my $separate = $conf->exists('separate_usage');
1162   my $temp_pkg = new FS::cust_pkg { pkgpart => $real_pkgpart };
1163   my $usage_mandate = $temp_pkg->part_pkg->option('usage_mandate', 'Hush!');
1164   my $section = $temp_pkg->part_pkg->categoryname;
1165   if ( $separate || $section || $usage_mandate ) {
1166
1167     my %hash = ( 'section' => $section );
1168
1169     $section = $temp_pkg->part_pkg->option('usage_section', 'Hush!');
1170     my $summary = $temp_pkg->part_pkg->option('summarize_usage', 'Hush!');
1171     if ( $separate ) {
1172       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1173       push @display, new FS::cust_bill_pkg_display { type => 'R', %hash };
1174     } else {
1175       push @display, new FS::cust_bill_pkg_display
1176                        { type => '',
1177                          %hash,
1178                          ( ( $usage_mandate ) ? ( 'summary' => 'Y' ) : () ),
1179                        };
1180     }
1181
1182     if ($separate && $section && $summary) {
1183       push @display, new FS::cust_bill_pkg_display { type    => 'U',
1184                                                      summary => 'Y',
1185                                                      %hash,
1186                                                    };
1187     }
1188     if ($usage_mandate || $section && $summary) {
1189       $hash{post_total} = 'Y';
1190     }
1191
1192     if ($separate || $usage_mandate) {
1193       $hash{section} = $section if ($separate || $usage_mandate);
1194       push @display, new FS::cust_bill_pkg_display { type => 'U', %hash };
1195     }
1196
1197   }
1198   $cust_bill_pkg->set('display', \@display);
1199
1200   my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1201   foreach my $key (keys %tax_cust_bill_pkg) {
1202     my @taxes = @{ $taxes{$key} || [] };
1203     my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1204
1205     my %localtaxlisthash = ();
1206     foreach my $tax ( @taxes ) {
1207
1208       my $taxname = ref( $tax ). ' '. $tax->taxnum;
1209 #      $taxname .= ' pkgnum'. $cust_pkg->pkgnum.
1210 #                  ' locationnum'. $cust_pkg->locationnum
1211 #        if $conf->exists('tax-pkg_address') && $cust_pkg->locationnum;
1212
1213       $taxlisthash->{ $taxname } ||= [ $tax ];
1214       push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1215
1216       $localtaxlisthash{ $taxname } ||= [ $tax ];
1217       push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1218
1219     }
1220
1221     warn "finding taxed taxes...\n" if $DEBUG > 2;
1222     foreach my $tax ( keys %localtaxlisthash ) {
1223       my $tax_object = shift @{ $localtaxlisthash{$tax} };
1224       warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1225         if $DEBUG > 2;
1226       next unless $tax_object->can('tax_on_tax');
1227
1228       foreach my $tot ( $tax_object->tax_on_tax( $self ) ) {
1229         my $totname = ref( $tot ). ' '. $tot->taxnum;
1230
1231         warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1232           if $DEBUG > 2;
1233         next unless exists( $localtaxlisthash{ $totname } ); # only increase
1234                                                              # existing taxes
1235         warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1236         my $hashref_or_error =
1237           $tax_object->taxline( $localtaxlisthash{$tax},
1238                                 'custnum'      => $self->custnum,
1239                                 'invoice_time' => $invoice_time,
1240                               );
1241         return $hashref_or_error
1242           unless ref($hashref_or_error);
1243
1244         $taxlisthash->{ $totname } ||= [ $tot ];
1245         push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1246
1247       }
1248     }
1249
1250   }
1251
1252   '';
1253 }
1254
1255 sub _gather_taxes {
1256   my $self = shift;
1257   my $part_pkg = shift;
1258   my $class = shift;
1259   my $cust_pkg = shift;
1260
1261   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1262
1263   my $geocode;
1264   if ( $cust_pkg->locationnum && $conf->exists('tax-pkg_address') ) {
1265     $geocode = $cust_pkg->cust_location->geocode('cch');
1266   } else {
1267     $geocode = $self->geocode('cch');
1268   }
1269
1270   my @taxes = ();
1271
1272   my @taxclassnums = map { $_->taxclassnum }
1273                      $part_pkg->part_pkg_taxoverride($class);
1274
1275   unless (@taxclassnums) {
1276     @taxclassnums = map { $_->taxclassnum }
1277                     grep { $_->taxable eq 'Y' }
1278                     $part_pkg->part_pkg_taxrate('cch', $geocode, $class);
1279   }
1280   warn "Found taxclassnum values of ". join(',', @taxclassnums)
1281     if $DEBUG;
1282
1283   my $extra_sql =
1284     "AND (".
1285     join(' OR ', map { "taxclassnum = $_" } @taxclassnums ). ")";
1286
1287   @taxes = qsearch({ 'table' => 'tax_rate',
1288                      'hashref' => { 'geocode' => $geocode, },
1289                      'extra_sql' => $extra_sql,
1290                   })
1291     if scalar(@taxclassnums);
1292
1293   warn "Found taxes ".
1294        join(',', map{ ref($_). " ". $_->get($_->primary_key) } @taxes). "\n"
1295    if $DEBUG;
1296
1297   [ @taxes ];
1298
1299 }
1300
1301 =item collect [ HASHREF | OPTION => VALUE ... ]
1302
1303 (Attempt to) collect money for this customer's outstanding invoices (see
1304 L<FS::cust_bill>).  Usually used after the bill method.
1305
1306 Actions are now triggered by billing events; see L<FS::part_event> and the
1307 billing events web interface.  Old-style invoice events (see
1308 L<FS::part_bill_event>) have been deprecated.
1309
1310 If there is an error, returns the error, otherwise returns false.
1311
1312 Options are passed as name-value pairs.
1313
1314 Currently available options are:
1315
1316 =over 4
1317
1318 =item invoice_time
1319
1320 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1321
1322 =item retry
1323
1324 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1325
1326 =item check_freq
1327
1328 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1329
1330 =item quiet
1331
1332 set true to surpress email card/ACH decline notices.
1333
1334 =item debug
1335
1336 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1337
1338 =back
1339
1340 # =item payby
1341 #
1342 # allows for one time override of normal customer billing method
1343
1344 =cut
1345
1346 sub collect {
1347   my( $self, %options ) = @_;
1348
1349   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1350
1351   my $invoice_time = $options{'invoice_time'} || time;
1352
1353   #put below somehow?
1354   local $SIG{HUP} = 'IGNORE';
1355   local $SIG{INT} = 'IGNORE';
1356   local $SIG{QUIT} = 'IGNORE';
1357   local $SIG{TERM} = 'IGNORE';
1358   local $SIG{TSTP} = 'IGNORE';
1359   local $SIG{PIPE} = 'IGNORE';
1360
1361   my $oldAutoCommit = $FS::UID::AutoCommit;
1362   local $FS::UID::AutoCommit = 0;
1363   my $dbh = dbh;
1364
1365   $self->select_for_update; #mutex
1366
1367   if ( $DEBUG ) {
1368     my $balance = $self->balance;
1369     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1370   }
1371
1372   if ( exists($options{'retry_card'}) ) {
1373     carp 'retry_card option passed to collect is deprecated; use retry';
1374     $options{'retry'} ||= $options{'retry_card'};
1375   }
1376   if ( exists($options{'retry'}) && $options{'retry'} ) {
1377     my $error = $self->retry_realtime;
1378     if ( $error ) {
1379       $dbh->rollback if $oldAutoCommit;
1380       return $error;
1381     }
1382   }
1383
1384   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1385
1386   #never want to roll back an event just because it returned an error
1387   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1388
1389   $self->do_cust_event(
1390     'debug'      => ( $options{'debug'} || 0 ),
1391     'time'       => $invoice_time,
1392     'check_freq' => $options{'check_freq'},
1393     'stage'      => 'collect',
1394   );
1395
1396 }
1397
1398 =item retry_realtime
1399
1400 Schedules realtime / batch  credit card / electronic check / LEC billing
1401 events for for retry.  Useful if card information has changed or manual
1402 retry is desired.  The 'collect' method must be called to actually retry
1403 the transaction.
1404
1405 Implementation details: For either this customer, or for each of this
1406 customer's open invoices, changes the status of the first "done" (with
1407 statustext error) realtime processing event to "failed".
1408
1409 =cut
1410
1411 sub retry_realtime {
1412   my $self = shift;
1413
1414   local $SIG{HUP} = 'IGNORE';
1415   local $SIG{INT} = 'IGNORE';
1416   local $SIG{QUIT} = 'IGNORE';
1417   local $SIG{TERM} = 'IGNORE';
1418   local $SIG{TSTP} = 'IGNORE';
1419   local $SIG{PIPE} = 'IGNORE';
1420
1421   my $oldAutoCommit = $FS::UID::AutoCommit;
1422   local $FS::UID::AutoCommit = 0;
1423   my $dbh = dbh;
1424
1425   #a little false laziness w/due_cust_event (not too bad, really)
1426
1427   my $join = FS::part_event_condition->join_conditions_sql;
1428   my $order = FS::part_event_condition->order_conditions_sql;
1429   my $mine =
1430   '( '
1431    . join ( ' OR ' , map {
1432     "( part_event.eventtable = " . dbh->quote($_)
1433     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key . " from $_ where custnum = " . dbh->quote( $self->custnum ) . "))" ;
1434    } FS::part_event->eventtables)
1435    . ') ';
1436
1437   #here is the agent virtualization
1438   my $agent_virt = " (    part_event.agentnum IS NULL
1439                        OR part_event.agentnum = ". $self->agentnum. ' )';
1440
1441   #XXX this shouldn't be hardcoded, actions should declare it...
1442   my @realtime_events = qw(
1443     cust_bill_realtime_card
1444     cust_bill_realtime_check
1445     cust_bill_realtime_lec
1446     cust_bill_batch
1447   );
1448
1449   my $is_realtime_event = ' ( '. join(' OR ', map "part_event.action = '$_'",
1450                                                   @realtime_events
1451                                      ).
1452                           ' ) ';
1453
1454   my @cust_event = qsearchs({
1455     'table'     => 'cust_event',
1456     'select'    => 'cust_event.*',
1457     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1458     'hashref'   => { 'status' => 'done' },
1459     'extra_sql' => " AND statustext IS NOT NULL AND statustext != '' ".
1460                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1461   });
1462
1463   my %seen_invnum = ();
1464   foreach my $cust_event (@cust_event) {
1465
1466     #max one for the customer, one for each open invoice
1467     my $cust_X = $cust_event->cust_X;
1468     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1469                           ? $cust_X->invnum
1470                           : 0
1471                         }++
1472          or $cust_event->part_event->eventtable eq 'cust_bill'
1473             && ! $cust_X->owed;
1474
1475     my $error = $cust_event->retry;
1476     if ( $error ) {
1477       $dbh->rollback if $oldAutoCommit;
1478       return "error scheduling event for retry: $error";
1479     }
1480
1481   }
1482
1483   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1484   '';
1485
1486 }
1487
1488 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1489
1490 Runs billing events; see L<FS::part_event> and the billing events web
1491 interface.
1492
1493 If there is an error, returns the error, otherwise returns false.
1494
1495 Options are passed as name-value pairs.
1496
1497 Currently available options are:
1498
1499 =over 4
1500
1501 =item time
1502
1503 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1504
1505 =item check_freq
1506
1507 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1508
1509 =item stage
1510
1511 "collect" (the default) or "pre-bill"
1512
1513 =item quiet
1514
1515 set true to surpress email card/ACH decline notices.
1516
1517 =item debug
1518
1519 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1520
1521 =back
1522 =cut
1523
1524 # =item payby
1525 #
1526 # allows for one time override of normal customer billing method
1527
1528 # =item retry
1529 #
1530 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1531
1532 sub do_cust_event {
1533   my( $self, %options ) = @_;
1534
1535   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1536
1537   my $time = $options{'time'} || time;
1538
1539   #put below somehow?
1540   local $SIG{HUP} = 'IGNORE';
1541   local $SIG{INT} = 'IGNORE';
1542   local $SIG{QUIT} = 'IGNORE';
1543   local $SIG{TERM} = 'IGNORE';
1544   local $SIG{TSTP} = 'IGNORE';
1545   local $SIG{PIPE} = 'IGNORE';
1546
1547   my $oldAutoCommit = $FS::UID::AutoCommit;
1548   local $FS::UID::AutoCommit = 0;
1549   my $dbh = dbh;
1550
1551   $self->select_for_update; #mutex
1552
1553   if ( $DEBUG ) {
1554     my $balance = $self->balance;
1555     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1556   }
1557
1558 #  if ( exists($options{'retry_card'}) ) {
1559 #    carp 'retry_card option passed to collect is deprecated; use retry';
1560 #    $options{'retry'} ||= $options{'retry_card'};
1561 #  }
1562 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1563 #    my $error = $self->retry_realtime;
1564 #    if ( $error ) {
1565 #      $dbh->rollback if $oldAutoCommit;
1566 #      return $error;
1567 #    }
1568 #  }
1569
1570   # false laziness w/pay_batch::import_results
1571
1572   my $due_cust_event = $self->due_cust_event(
1573     'debug'      => ( $options{'debug'} || 0 ),
1574     'time'       => $time,
1575     'check_freq' => $options{'check_freq'},
1576     'stage'      => ( $options{'stage'} || 'collect' ),
1577   );
1578   unless( ref($due_cust_event) ) {
1579     $dbh->rollback if $oldAutoCommit;
1580     return $due_cust_event;
1581   }
1582
1583   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1584   #never want to roll back an event just because it or a different one
1585   # returned an error
1586   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1587
1588   foreach my $cust_event ( @$due_cust_event ) {
1589
1590     #XXX lock event
1591
1592     #re-eval event conditions (a previous event could have changed things)
1593     unless ( $cust_event->test_conditions( 'time' => $time ) ) {
1594       #don't leave stray "new/locked" records around
1595       my $error = $cust_event->delete;
1596       return $error if $error;
1597       next;
1598     }
1599
1600     {
1601       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1602         if $options{'quiet'};
1603       warn "  running cust_event ". $cust_event->eventnum. "\n"
1604         if $DEBUG > 1;
1605
1606       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1607       if ( my $error = $cust_event->do_event() ) {
1608         #XXX wtf is this?  figure out a proper dealio with return value
1609         #from do_event
1610         return $error;
1611       }
1612     }
1613
1614   }
1615
1616   '';
1617
1618 }
1619
1620 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1621
1622 Inserts database records for and returns an ordered listref of new events due
1623 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1624 events are due, an empty listref is returned.  If there is an error, returns a
1625 scalar error message.
1626
1627 To actually run the events, call each event's test_condition method, and if
1628 still true, call the event's do_event method.
1629
1630 Options are passed as a hashref or as a list of name-value pairs.  Available
1631 options are:
1632
1633 =over 4
1634
1635 =item check_freq
1636
1637 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1638
1639 =item stage
1640
1641 "collect" (the default) or "pre-bill"
1642
1643 =item time
1644
1645 "Current time" for the events.
1646
1647 =item debug
1648
1649 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1650
1651 =item eventtable
1652
1653 Only return events for the specified eventtable (by default, events of all eventtables are returned)
1654
1655 =item objects
1656
1657 Explicitly pass the objects to be tested (typically used with eventtable).
1658
1659 =item testonly
1660
1661 Set to true to return the objects, but not actually insert them into the
1662 database.
1663
1664 =back
1665
1666 =cut
1667
1668 sub due_cust_event {
1669   my $self = shift;
1670   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
1671
1672   #???
1673   #my $DEBUG = $opt{'debug'}
1674   local($DEBUG) = $opt{'debug'}
1675     if defined($opt{'debug'}) && $opt{'debug'} > $DEBUG;
1676   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1677
1678   warn "$me due_cust_event called with options ".
1679        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
1680     if $DEBUG;
1681
1682   $opt{'time'} ||= time;
1683
1684   local $SIG{HUP} = 'IGNORE';
1685   local $SIG{INT} = 'IGNORE';
1686   local $SIG{QUIT} = 'IGNORE';
1687   local $SIG{TERM} = 'IGNORE';
1688   local $SIG{TSTP} = 'IGNORE';
1689   local $SIG{PIPE} = 'IGNORE';
1690
1691   my $oldAutoCommit = $FS::UID::AutoCommit;
1692   local $FS::UID::AutoCommit = 0;
1693   my $dbh = dbh;
1694
1695   $self->select_for_update #mutex
1696     unless $opt{testonly};
1697
1698   ###
1699   # find possible events (initial search)
1700   ###
1701
1702   my @cust_event = ();
1703
1704   my @eventtable = $opt{'eventtable'}
1705                      ? ( $opt{'eventtable'} )
1706                      : FS::part_event->eventtables_runorder;
1707
1708   my $check_freq = $opt{'check_freq'} || '1d';
1709
1710   foreach my $eventtable ( @eventtable ) {
1711
1712     my @objects;
1713     if ( $opt{'objects'} ) {
1714
1715       @objects = @{ $opt{'objects'} };
1716
1717     } else {
1718
1719       #my @objects = $self->$eventtable(); # sub cust_main { @{ [ $self ] }; }
1720       if ( $eventtable eq 'cust_main' ) {
1721         @objects = ( $self );
1722       } else {
1723
1724         my $cm_join =
1725           "LEFT JOIN cust_main USING ( custnum )";
1726
1727         #some false laziness w/Cron::bill bill_where
1728
1729         my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
1730         my $where = FS::part_event_condition->where_conditions_sql($eventtable,
1731                                                            'time'=>$opt{'time'},
1732                                                                   );
1733         $where = $where ? "AND $where" : '';
1734
1735         my $are_part_event =
1736           "EXISTS ( SELECT 1 FROM part_event $join
1737                       WHERE check_freq = '$check_freq'
1738                         AND eventtable = '$eventtable'
1739                         AND ( disabled = '' OR disabled IS NULL )
1740                         $where
1741                   )
1742           ";
1743         #eofalse
1744
1745         @objects = $self->$eventtable(
1746                      'addl_from' => $cm_join,
1747                      'extra_sql' => " AND $are_part_event",
1748                    );
1749       }
1750
1751     }
1752
1753     my @e_cust_event = ();
1754
1755     my $cross = "CROSS JOIN $eventtable";
1756     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
1757       unless $eventtable eq 'cust_main';
1758
1759     foreach my $object ( @objects ) {
1760
1761       #this first search uses the condition_sql magic for optimization.
1762       #the more possible events we can eliminate in this step the better
1763
1764       my $cross_where = '';
1765       my $pkey = $object->primary_key;
1766       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
1767
1768       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
1769       my $extra_sql =
1770         FS::part_event_condition->where_conditions_sql( $eventtable,
1771                                                         'time'=>$opt{'time'}
1772                                                       );
1773       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
1774
1775       $extra_sql = "AND $extra_sql" if $extra_sql;
1776
1777       #here is the agent virtualization
1778       $extra_sql .= " AND (    part_event.agentnum IS NULL
1779                             OR part_event.agentnum = ". $self->agentnum. ' )';
1780
1781       $extra_sql .= " $order";
1782
1783       warn "searching for events for $eventtable ". $object->$pkey. "\n"
1784         if $opt{'debug'} > 2;
1785       my @part_event = qsearch( {
1786         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
1787         'select'    => 'part_event.*',
1788         'table'     => 'part_event',
1789         'addl_from' => "$cross $join",
1790         'hashref'   => { 'check_freq' => $check_freq,
1791                          'eventtable' => $eventtable,
1792                          'disabled'   => '',
1793                        },
1794         'extra_sql' => "AND $cross_where $extra_sql",
1795       } );
1796
1797       if ( $DEBUG > 2 ) {
1798         my $pkey = $object->primary_key;
1799         warn "      ". scalar(@part_event).
1800              " possible events found for $eventtable ". $object->$pkey(). "\n";
1801       }
1802
1803       push @e_cust_event, map { $_->new_cust_event($object) } @part_event;
1804
1805     }
1806
1807     warn "    ". scalar(@e_cust_event).
1808          " subtotal possible cust events found for $eventtable\n"
1809       if $DEBUG > 1;
1810
1811     push @cust_event, @e_cust_event;
1812
1813   }
1814
1815   warn "  ". scalar(@cust_event).
1816        " total possible cust events found in initial search\n"
1817     if $DEBUG; # > 1;
1818
1819
1820   ##
1821   # test stage
1822   ##
1823
1824   $opt{stage} ||= 'collect';
1825   @cust_event =
1826     grep { my $stage = $_->part_event->event_stage;
1827            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
1828          }
1829          @cust_event;
1830
1831   ##
1832   # test conditions
1833   ##
1834
1835   my %unsat = ();
1836
1837   @cust_event = grep $_->test_conditions( 'time'          => $opt{'time'},
1838                                           'stats_hashref' => \%unsat ),
1839                      @cust_event;
1840
1841   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
1842     if $DEBUG; # > 1;
1843
1844   warn "    invalid conditions not eliminated with condition_sql:\n".
1845        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
1846     if keys %unsat && $DEBUG; # > 1;
1847
1848   ##
1849   # insert
1850   ##
1851
1852   unless( $opt{testonly} ) {
1853     foreach my $cust_event ( @cust_event ) {
1854
1855       my $error = $cust_event->insert();
1856       if ( $error ) {
1857         $dbh->rollback if $oldAutoCommit;
1858         return $error;
1859       }
1860
1861     }
1862   }
1863
1864   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1865
1866   ##
1867   # return
1868   ##
1869
1870   warn "  returning events: ". Dumper(@cust_event). "\n"
1871     if $DEBUG > 2;
1872
1873   \@cust_event;
1874
1875 }
1876
1877 =item apply_payments_and_credits [ OPTION => VALUE ... ]
1878
1879 Applies unapplied payments and credits.
1880
1881 In most cases, this new method should be used in place of sequential
1882 apply_payments and apply_credits methods.
1883
1884 A hash of optional arguments may be passed.  Currently "manual" is supported.
1885 If true, a payment receipt is sent instead of a statement when
1886 'payment_receipt_email' configuration option is set.
1887
1888 If there is an error, returns the error, otherwise returns false.
1889
1890 =cut
1891
1892 sub apply_payments_and_credits {
1893   my( $self, %options ) = @_;
1894
1895   local $SIG{HUP} = 'IGNORE';
1896   local $SIG{INT} = 'IGNORE';
1897   local $SIG{QUIT} = 'IGNORE';
1898   local $SIG{TERM} = 'IGNORE';
1899   local $SIG{TSTP} = 'IGNORE';
1900   local $SIG{PIPE} = 'IGNORE';
1901
1902   my $oldAutoCommit = $FS::UID::AutoCommit;
1903   local $FS::UID::AutoCommit = 0;
1904   my $dbh = dbh;
1905
1906   $self->select_for_update; #mutex
1907
1908   foreach my $cust_bill ( $self->open_cust_bill ) {
1909     my $error = $cust_bill->apply_payments_and_credits(%options);
1910     if ( $error ) {
1911       $dbh->rollback if $oldAutoCommit;
1912       return "Error applying: $error";
1913     }
1914   }
1915
1916   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1917   ''; #no error
1918
1919 }
1920
1921 =item apply_credits OPTION => VALUE ...
1922
1923 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
1924 to outstanding invoice balances in chronological order (or reverse
1925 chronological order if the I<order> option is set to B<newest>) and returns the
1926 value of any remaining unapplied credits available for refund (see
1927 L<FS::cust_refund>).
1928
1929 Dies if there is an error.
1930
1931 =cut
1932
1933 sub apply_credits {
1934   my $self = shift;
1935   my %opt = @_;
1936
1937   local $SIG{HUP} = 'IGNORE';
1938   local $SIG{INT} = 'IGNORE';
1939   local $SIG{QUIT} = 'IGNORE';
1940   local $SIG{TERM} = 'IGNORE';
1941   local $SIG{TSTP} = 'IGNORE';
1942   local $SIG{PIPE} = 'IGNORE';
1943
1944   my $oldAutoCommit = $FS::UID::AutoCommit;
1945   local $FS::UID::AutoCommit = 0;
1946   my $dbh = dbh;
1947
1948   $self->select_for_update; #mutex
1949
1950   unless ( $self->total_unapplied_credits ) {
1951     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1952     return 0;
1953   }
1954
1955   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
1956       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
1957
1958   my @invoices = $self->open_cust_bill;
1959   @invoices = sort { $b->_date <=> $a->_date } @invoices
1960     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
1961
1962   if ( $conf->exists('pkg-balances') ) {
1963     # limit @credits to those w/ a pkgnum grepped from $self
1964     my %pkgnums = ();
1965     foreach my $i (@invoices) {
1966       foreach my $li ( $i->cust_bill_pkg ) {
1967         $pkgnums{$li->pkgnum} = 1;
1968       }
1969     }
1970     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
1971   }
1972
1973   my $credit;
1974
1975   foreach my $cust_bill ( @invoices ) {
1976
1977     if ( !defined($credit) || $credit->credited == 0) {
1978       $credit = pop @credits or last;
1979     }
1980
1981     my $owed;
1982     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
1983       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
1984     } else {
1985       $owed = $cust_bill->owed;
1986     }
1987     unless ( $owed > 0 ) {
1988       push @credits, $credit;
1989       next;
1990     }
1991
1992     my $amount = min( $credit->credited, $owed );
1993
1994     my $cust_credit_bill = new FS::cust_credit_bill ( {
1995       'crednum' => $credit->crednum,
1996       'invnum'  => $cust_bill->invnum,
1997       'amount'  => $amount,
1998     } );
1999     $cust_credit_bill->pkgnum( $credit->pkgnum )
2000       if $conf->exists('pkg-balances') && $credit->pkgnum;
2001     my $error = $cust_credit_bill->insert;
2002     if ( $error ) {
2003       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2004       die $error;
2005     }
2006
2007     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2008
2009   }
2010
2011   my $total_unapplied_credits = $self->total_unapplied_credits;
2012
2013   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2014
2015   return $total_unapplied_credits;
2016 }
2017
2018 =item apply_payments  [ OPTION => VALUE ... ]
2019
2020 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2021 to outstanding invoice balances in chronological order.
2022
2023  #and returns the value of any remaining unapplied payments.
2024
2025 A hash of optional arguments may be passed.  Currently "manual" is supported.
2026 If true, a payment receipt is sent instead of a statement when
2027 'payment_receipt_email' configuration option is set.
2028
2029 Dies if there is an error.
2030
2031 =cut
2032
2033 sub apply_payments {
2034   my( $self, %options ) = @_;
2035
2036   local $SIG{HUP} = 'IGNORE';
2037   local $SIG{INT} = 'IGNORE';
2038   local $SIG{QUIT} = 'IGNORE';
2039   local $SIG{TERM} = 'IGNORE';
2040   local $SIG{TSTP} = 'IGNORE';
2041   local $SIG{PIPE} = 'IGNORE';
2042
2043   my $oldAutoCommit = $FS::UID::AutoCommit;
2044   local $FS::UID::AutoCommit = 0;
2045   my $dbh = dbh;
2046
2047   $self->select_for_update; #mutex
2048
2049   #return 0 unless
2050
2051   my @payments = sort { $b->_date <=> $a->_date }
2052                  grep { $_->unapplied > 0 }
2053                  $self->cust_pay;
2054
2055   my @invoices = sort { $a->_date <=> $b->_date}
2056                  grep { $_->owed > 0 }
2057                  $self->cust_bill;
2058
2059   if ( $conf->exists('pkg-balances') ) {
2060     # limit @payments to those w/ a pkgnum grepped from $self
2061     my %pkgnums = ();
2062     foreach my $i (@invoices) {
2063       foreach my $li ( $i->cust_bill_pkg ) {
2064         $pkgnums{$li->pkgnum} = 1;
2065       }
2066     }
2067     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2068   }
2069
2070   my $payment;
2071
2072   foreach my $cust_bill ( @invoices ) {
2073
2074     if ( !defined($payment) || $payment->unapplied == 0 ) {
2075       $payment = pop @payments or last;
2076     }
2077
2078     my $owed;
2079     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2080       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2081     } else {
2082       $owed = $cust_bill->owed;
2083     }
2084     unless ( $owed > 0 ) {
2085       push @payments, $payment;
2086       next;
2087     }
2088
2089     my $amount = min( $payment->unapplied, $owed );
2090
2091     my $cust_bill_pay = new FS::cust_bill_pay ( {
2092       'paynum' => $payment->paynum,
2093       'invnum' => $cust_bill->invnum,
2094       'amount' => $amount,
2095     } );
2096     $cust_bill_pay->pkgnum( $payment->pkgnum )
2097       if $conf->exists('pkg-balances') && $payment->pkgnum;
2098     my $error = $cust_bill_pay->insert(%options);
2099     if ( $error ) {
2100       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2101       die $error;
2102     }
2103
2104     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2105
2106   }
2107
2108   my $total_unapplied_payments = $self->total_unapplied_payments;
2109
2110   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2111
2112   return $total_unapplied_payments;
2113 }
2114
2115 =back
2116
2117 =head1 BUGS
2118
2119 =head1 SEE ALSO
2120
2121 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2122
2123 =cut
2124
2125 1;