FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::cust_bill;
  11 use FS::cust_bill_pkg;
  12 use FS::cust_bill_pkg_display;
  13 use FS::cust_bill_pay;
  14 use FS::cust_credit_bill;
  15 use FS::cust_tax_adjustment;
  16 use FS::tax_rate;
  17 use FS::tax_rate_location;
  18 use FS::cust_bill_pkg_tax_location;
  19 use FS::cust_bill_pkg_tax_rate_location;
  20 use FS::part_event;
  21 use FS::part_event_condition;
  22 use FS::pkg_category;
  23
  24 # 1 is mostly method/subroutine entry and options
  25 # 2 traces progress of some operations
  26 # 3 is even more information including possibly sensitive data
  27 $DEBUG = 0;
  28 $me = '[FS::cust_main::Billing]';
  29
  30 install_callback FS::UID sub {
  31   $conf = new FS::Conf;
  32   #yes, need it for stuff below (prolly should be cached)
  33 };
  34
  35 =head1 NAME
  36
  37 FS::cust_main::Billing - Billing mixin for cust_main
  38
  39 =head1 SYNOPSIS
  40
  41 =head1 DESCRIPTION
  42
  43 These methods are available on FS::cust_main objects.
  44
  45 =head1 METHODS
  46
  47 =over 4
  48
  49 =item bill_and_collect
  50
  51 Cancels and suspends any packages due, generates bills, applies payments and
  52 credits, and applies collection events to run cards, send bills and notices,
  53 etc.
  54
  55 By default, warns on errors and continues with the next operation (but see the
  56 "fatal" flag below).
  57
  58 Options are passed as name-value pairs.  Currently available options are:
  59
  60 =over 4
  61
  62 =item time
  63
  64 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  65
  66  use Date::Parse;
  67  ...
  68  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  69
  70 =item invoice_time
  71
  72 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  73
  74 =item check_freq
  75
  76 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  77
  78 =item resetup
  79
  80 If set true, re-charges setup fees.
  81
  82 =item fatal
  83
  84 If set any errors prevent subsequent operations from continusing.  If set
  85 specifically to "return", returns the error (or false, if there is no error).
  86 Any other true value causes errors to die.
  87
  88 =item debug
  89
  90 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  91
  92 =item job
  93
  94 Optional FS::queue entry to receive status updates.
  95
  96 =back
  97
  98 Options are passed to the B<bill> and B<collect> methods verbatim, so all
  99 options of those methods are also available.
 100
 101 =cut
 102
 103 sub bill_and_collect {
 104   my( $self, %options ) = @_;
 105
 106   my $error;
 107
 108   #$options{actual_time} not $options{time} because freeside-daily -d is for
 109   #pre-printing invoices
 110
 111   $options{'actual_time'} ||= time;
 112   my $job = $options{'job'};
 113
 114   $job->update_statustext('0,cleaning expired packages') if $job;
 115   $error = $self->cancel_expired_pkgs( $options{actual_time} );
 116   if ( $error ) {
 117     $error = "Error expiring custnum ". $self->custnum. ": $error";
 118     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 119     elsif ( $options{fatal}                                ) { die    $error; }
 120     else                                                     { warn   $error; }
 121   }
 122
 123   $error = $self->suspend_adjourned_pkgs( $options{actual_time} );
 124   if ( $error ) {
 125     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 126     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 127     elsif ( $options{fatal}                                ) { die    $error; }
 128     else                                                     { warn   $error; }
 129   }
 130
 131   $job->update_statustext('20,billing packages') if $job;
 132   $error = $self->bill( %options );
 133   if ( $error ) {
 134     $error = "Error billing custnum ". $self->custnum. ": $error";
 135     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 136     elsif ( $options{fatal}                                ) { die    $error; }
 137     else                                                     { warn   $error; }
 138   }
 139
 140   $job->update_statustext('50,applying payments and credits') if $job;
 141   $error = $self->apply_payments_and_credits;
 142   if ( $error ) {
 143     $error = "Error applying custnum ". $self->custnum. ": $error";
 144     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 145     elsif ( $options{fatal}                                ) { die    $error; }
 146     else                                                     { warn   $error; }
 147   }
 148
 149   $job->update_statustext('70,running collection events') if $job;
 150   unless ( $conf->exists('cancelled_cust-noevents')
 151            && ! $self->num_ncancelled_pkgs
 152   ) {
 153     $error = $self->collect( %options );
 154     if ( $error ) {
 155       $error = "Error collecting custnum ". $self->custnum. ": $error";
 156       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 157       elsif ($options{fatal}                               ) { die    $error; }
 158       else                                                   { warn   $error; }
 159     }
 160   }
 161   $job->update_statustext('100,finished') if $job;
 162
 163   '';
 164
 165 }
 166
 167 sub cancel_expired_pkgs {
 168   my ( $self, $time, %options ) = @_;
 169
 170   my @cancel_pkgs = $self->ncancelled_pkgs( {
 171     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 172   } );
 173
 174   my @errors = ();
 175
 176   foreach my $cust_pkg ( @cancel_pkgs ) {
 177     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 178     my $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 179                                            'reason_otaker' => $cpr->otaker
 180                                          )
 181                                        : ()
 182                                  );
 183     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 184   }
 185
 186   scalar(@errors) ? join(' / ', @errors) : '';
 187
 188 }
 189
 190 sub suspend_adjourned_pkgs {
 191   my ( $self, $time, %options ) = @_;
 192
 193   my @susp_pkgs = $self->ncancelled_pkgs( {
 194     'extra_sql' =>
 195       " AND ( susp IS NULL OR susp = 0 )
 196         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 197               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 198             )
 199       ",
 200   } );
 201
 202   #only because there's no SQL test for is_prepaid :/
 203   @susp_pkgs =
 204     grep {     (    $_->part_pkg->is_prepaid
 205                  && $_->bill
 206                  && $_->bill < $time
 207                )
 208             || (    $_->adjourn
 209                  && $_->adjourn <= $time
 210                )
 211
 212          }
 213          @susp_pkgs;
 214
 215   my @errors = ();
 216
 217   foreach my $cust_pkg ( @susp_pkgs ) {
 218     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 219       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 220     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 221                                             'reason_otaker' => $cpr->otaker
 222                                           )
 223                                         : ()
 224                                   );
 225     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 226   }
 227
 228   scalar(@errors) ? join(' / ', @errors) : '';
 229
 230 }
 231
 232 =item bill OPTIONS
 233
 234 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 235 conjunction with the collect method by calling B<bill_and_collect>.
 236
 237 If there is an error, returns the error, otherwise returns false.
 238
 239 Options are passed as name-value pairs.  Currently available options are:
 240
 241 =over 4
 242
 243 =item resetup
 244
 245 If set true, re-charges setup fees.
 246
 247 =item recurring_only
 248
 249 If set true then only bill recurring charges, not setup, usage, one time
 250 charges, etc.
 251
 252 =item freq_override
 253
 254 If set, then override the normal frequency and look for a part_pkg_discount
 255 to take at that frequency.
 256
 257 =item time
 258
 259 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 260
 261  use Date::Parse;
 262  ...
 263  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 264
 265 =item pkg_list
 266
 267 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 268
 269  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 270
 271 =item not_pkgpart
 272
 273 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 274
 275 =item invoice_time
 276
 277 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 278
 279 =item cancel
 280
 281 This boolean value informs the us that the package is being cancelled.  This
 282 typically might mean not charging the normal recurring fee but only usage
 283 fees since the last billing. Setup charges may be charged.  Not all package
 284 plans support this feature (they tend to charge 0).
 285
 286 =item no_usage_reset
 287
 288 Prevent the resetting of usage limits during this call.
 289
 290 =item no_commit
 291
 292 Do not save the generated bill in the database.  Useful with return_bill
 293
 294 =item return_bill
 295
 296 A list reference on which the generated bill(s) will be returned.
 297
 298 =item invoice_terms
 299
 300 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 301 terms or the default terms are used.
 302
 303 =back
 304
 305 =cut
 306
 307 sub bill {
 308   my( $self, %options ) = @_;
 309
 310   return '' if $self->payby eq 'COMP';
 311
 312   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 313
 314   warn "$me bill customer ". $self->custnum. "\n"
 315     if $DEBUG;
 316
 317   my $time = $options{'time'} || time;
 318   my $invoice_time = $options{'invoice_time'} || $time;
 319
 320   $options{'not_pkgpart'} ||= {};
 321   $options{'not_pkgpart'} = { map { $_ => 1 }
 322                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 323                             }
 324     unless ref($options{'not_pkgpart'});
 325
 326   local $SIG{HUP} = 'IGNORE';
 327   local $SIG{INT} = 'IGNORE';
 328   local $SIG{QUIT} = 'IGNORE';
 329   local $SIG{TERM} = 'IGNORE';
 330   local $SIG{TSTP} = 'IGNORE';
 331   local $SIG{PIPE} = 'IGNORE';
 332
 333   my $oldAutoCommit = $FS::UID::AutoCommit;
 334   local $FS::UID::AutoCommit = 0;
 335   my $dbh = dbh;
 336
 337   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 338     if $DEBUG;
 339
 340   $self->select_for_update; #mutex
 341
 342   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 343     if $DEBUG;
 344
 345   my $error = $self->do_cust_event(
 346     'debug'      => ( $options{'debug'} || 0 ),
 347     'time'       => $invoice_time,
 348     'check_freq' => $options{'check_freq'},
 349     'stage'      => 'pre-bill',
 350   )
 351     unless $options{no_commit};
 352   if ( $error ) {
 353     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 354     return $error;
 355   }
 356
 357   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 358     if $DEBUG;
 359
 360   #keep auto-charge and non-auto-charge line items separate
 361   my @passes = ( '', 'no_auto' );
 362
 363   my %cust_bill_pkg = map { $_ => [] } @passes;
 364
 365   ###
 366   # find the packages which are due for billing, find out how much they are
 367   # & generate invoice database.
 368   ###
 369
 370   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 371   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 372
 373   my %taxlisthash = map { $_ => {} } @passes;
 374
 375   my @precommit_hooks = ();
 376
 377   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 378   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 379
 380     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 381
 382     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG > 1;
 383
 384     #? to avoid use of uninitialized value errors... ?
 385     $cust_pkg->setfield('bill', '')
 386       unless defined($cust_pkg->bill);
 387
 388     #my $part_pkg = $cust_pkg->part_pkg;
 389
 390     my $real_pkgpart = $cust_pkg->pkgpart;
 391     my %hash = $cust_pkg->hash;
 392
 393     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 394     # suffer from performance issues
 395     $options{has_hidden} = 0;
 396     my @part_pkg = $cust_pkg->part_pkg->self_and_bill_linked;
 397     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 398
 399     foreach my $part_pkg ( @part_pkg ) {
 400
 401       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 402
 403       my $pass = ($cust_pkg->no_auto || $part_pkg->no_auto) ? 'no_auto' : '';
 404
 405       my $error =
 406         $self->_make_lines( 'part_pkg'            => $part_pkg,
 407                             'cust_pkg'            => $cust_pkg,
 408                             'precommit_hooks'     => \@precommit_hooks,
 409                             'line_items'          => $cust_bill_pkg{$pass},
 410                             'setup'               => $total_setup{$pass},
 411                             'recur'               => $total_recur{$pass},
 412                             'tax_matrix'          => $taxlisthash{$pass},
 413                             'time'                => $time,
 414                             'real_pkgpart'        => $real_pkgpart,
 415                             'options'             => \%options,
 416                           );
 417       if ($error) {
 418         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 419         return $error;
 420       }
 421
 422     } #foreach my $part_pkg
 423
 424   } #foreach my $cust_pkg
 425
 426   #if the customer isn't on an automatic payby, everything can go on a single
 427   #invoice anyway?
 428   #if ( $cust_main->payby !~ /^(CARD|CHEK)$/ ) {
 429     #merge everything into one list
 430   #}
 431
 432   foreach my $pass (@passes) { # keys %cust_bill_pkg ) {
 433
 434     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 435
 436     next unless @cust_bill_pkg; #don't create an invoice w/o line items
 437
 438     warn "$me billing pass $pass\n"
 439            #.Dumper(\@cust_bill_pkg)."\n"
 440       if $DEBUG > 2;
 441
 442     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 443            !$conf->exists('postal_invoice-recurring_only')
 444        )
 445     {
 446
 447       my $postal_pkg = $self->charge_postal_fee();
 448       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 449
 450         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 451         return "can't charge postal invoice fee for customer ".
 452           $self->custnum. ": $postal_pkg";
 453
 454       } elsif ( $postal_pkg ) {
 455
 456         my $real_pkgpart = $postal_pkg->pkgpart;
 457         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 458         # suffer from performance issues
 459         $options{has_hidden} = 0;
 460         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 461         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 462
 463         foreach my $part_pkg ( @part_pkg ) {
 464           my %postal_options = %options;
 465           delete $postal_options{cancel};
 466           my $error =
 467             $self->_make_lines( 'part_pkg'            => $part_pkg,
 468                                 'cust_pkg'            => $postal_pkg,
 469                                 'precommit_hooks'     => \@precommit_hooks,
 470                                 'line_items'          => \@cust_bill_pkg,
 471                                 'setup'               => $total_setup{$pass},
 472                                 'recur'               => $total_recur{$pass},
 473                                 'tax_matrix'          => $taxlisthash{$pass},
 474                                 'time'                => $time,
 475                                 'real_pkgpart'        => $real_pkgpart,
 476                                 'options'             => \%postal_options,
 477                               );
 478           if ($error) {
 479             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 480             return $error;
 481           }
 482         }
 483
 484         # it's silly to have a zero value postal_pkg, but....
 485         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 486
 487       }
 488
 489     }
 490
 491     my $listref_or_error =
 492       $self->calculate_taxes( \@cust_bill_pkg, $taxlisthash{$pass}, $invoice_time);
 493
 494     unless ( ref( $listref_or_error ) ) {
 495       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 496       return $listref_or_error;
 497     }
 498
 499     foreach my $taxline ( @$listref_or_error ) {
 500       ${ $total_setup{$pass} } =
 501         sprintf('%.2f', ${ $total_setup{$pass} } + $taxline->setup );
 502       push @cust_bill_pkg, $taxline;
 503     }
 504
 505     #add tax adjustments
 506     warn "adding tax adjustments...\n" if $DEBUG > 2;
 507     foreach my $cust_tax_adjustment (
 508       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 509                                        'billpkgnum' => '',
 510                                      }
 511              )
 512     ) {
 513
 514       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 515
 516       my $itemdesc = $cust_tax_adjustment->taxname;
 517       $itemdesc = '' if $itemdesc eq 'Tax';
 518
 519       push @cust_bill_pkg, new FS::cust_bill_pkg {
 520         'pkgnum'      => 0,
 521         'setup'       => $tax,
 522         'recur'       => 0,
 523         'sdate'       => '',
 524         'edate'       => '',
 525         'itemdesc'    => $itemdesc,
 526         'itemcomment' => $cust_tax_adjustment->comment,
 527         'cust_tax_adjustment' => $cust_tax_adjustment,
 528         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 529       };
 530
 531     }
 532
 533     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 534
 535     my @cust_bill = $self->cust_bill;
 536     my $balance = $self->balance;
 537     my $previous_balance = scalar(@cust_bill)
 538                              ? ( $cust_bill[$#cust_bill]->billing_balance || 0 )
 539                              : 0;
 540
 541     $previous_balance += $cust_bill[$#cust_bill]->charged
 542       if scalar(@cust_bill);
 543     #my $balance_adjustments =
 544     #  sprintf('%.2f', $balance - $prior_prior_balance - $prior_charged);
 545
 546     warn "creating the new invoice\n" if $DEBUG;
 547     #create the new invoice
 548     my $cust_bill = new FS::cust_bill ( {
 549       'custnum'             => $self->custnum,
 550       '_date'               => $invoice_time,
 551       'charged'             => $charged,
 552       'billing_balance'     => $balance,
 553       'previous_balance'    => $previous_balance,
 554       'invoice_terms'       => $options{'invoice_terms'},
 555       'cust_bill_pkg'       => \@cust_bill_pkg,
 556     } );
 557     $error = $cust_bill->insert unless $options{no_commit};
 558     if ( $error ) {
 559       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 560       return "can't create invoice for customer #". $self->custnum. ": $error";
 561     }
 562     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 563
 564   } #foreach my $pass ( keys %cust_bill_pkg )
 565
 566   foreach my $hook ( @precommit_hooks ) {
 567     eval {
 568       &{$hook}; #($self) ?
 569     } unless $options{no_commit};
 570     if ( $@ ) {
 571       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 572       return "$@ running precommit hook $hook\n";
 573     }
 574   }
 575
 576   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 577
 578   ''; #no error
 579 }
 580
 581 #discard bundled packages of 0 value
 582 sub _omit_zero_value_bundles {
 583
 584   my @cust_bill_pkg = ();
 585   my @cust_bill_pkg_bundle = ();
 586   my $sum = 0;
 587   my $discount_show_always = 0;
 588
 589   foreach my $cust_bill_pkg ( @_ ) {
 590     $discount_show_always = ($cust_bill_pkg->get('discounts')
 591                                 && scalar(@{$cust_bill_pkg->get('discounts')})
 592                                 && $conf->exists('discount-show-always'));
 593     if (scalar(@cust_bill_pkg_bundle) && !$cust_bill_pkg->pkgpart_override) {
 594       push @cust_bill_pkg, @cust_bill_pkg_bundle
 595                         if ($sum > 0 || ($sum == 0 && $discount_show_always));
 596       @cust_bill_pkg_bundle = ();
 597       $sum = 0;
 598     }
 599     $sum += $cust_bill_pkg->setup + $cust_bill_pkg->recur;
 600     push @cust_bill_pkg_bundle, $cust_bill_pkg;
 601   }
 602   push @cust_bill_pkg, @cust_bill_pkg_bundle
 603                         if ($sum > 0 || ($sum == 0 && $discount_show_always));
 604
 605   (@cust_bill_pkg);
 606
 607 }
 608
 609 =item calculate_taxes LINEITEMREF TAXHASHREF INVOICE_TIME
 610
 611 This is a weird one.  Perhaps it should not even be exposed.
 612
 613 Generates tax line items (see L<FS::cust_bill_pkg>) for this customer.
 614 Usually used internally by bill method B<bill>.
 615
 616 If there is an error, returns the error, otherwise returns reference to a
 617 list of line items suitable for insertion.
 618
 619 =over 4
 620
 621 =item LINEITEMREF
 622
 623 An array ref of the line items being billed.
 624
 625 =item TAXHASHREF
 626
 627 A strange beast.  The keys to this hash are internal identifiers consisting
 628 of the name of the tax object type, a space, and its unique identifier ( e.g.
 629  'cust_main_county 23' ).  The values of the hash are listrefs.  The first
 630 item in the list is the tax object.  The remaining items are either line
 631 items or floating point values (currency amounts).
 632
 633 The taxes are calculated on this entity.  Calculated exemption records are
 634 transferred to the LINEITEMREF items on the assumption that they are related.
 635
 636 Read the source.
 637
 638 =item INVOICE_TIME
 639
 640 This specifies the date appearing on the associated invoice.  Some
 641 jurisdictions (i.e. Texas) have tax exemptions which are date sensitive.
 642
 643 =back
 644
 645 =cut
 646
 647 sub calculate_taxes {
 648   my ($self, $cust_bill_pkg, $taxlisthash, $invoice_time) = @_;
 649
 650   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 651
 652   warn "$me calculate_taxes\n"
 653        #.Dumper($self, $cust_bill_pkg, $taxlisthash, $invoice_time). "\n"
 654     if $DEBUG > 2;
 655
 656   my @tax_line_items = ();
 657
 658   # keys are tax names (as printed on invoices / itemdesc )
 659   # values are listrefs of taxlisthash keys (internal identifiers)
 660   my %taxname = ();
 661
 662   # keys are taxlisthash keys (internal identifiers)
 663   # values are (cumulative) amounts
 664   my %tax = ();
 665
 666   # keys are taxlisthash keys (internal identifiers)
 667   # values are listrefs of cust_bill_pkg_tax_location hashrefs
 668   my %tax_location = ();
 669
 670   # keys are taxlisthash keys (internal identifiers)
 671   # values are listrefs of cust_bill_pkg_tax_rate_location hashrefs
 672   my %tax_rate_location = ();
 673
 674   foreach my $tax ( keys %$taxlisthash ) {
 675     my $tax_object = shift @{ $taxlisthash->{$tax} };
 676     warn "found ". $tax_object->taxname. " as $tax\n" if $DEBUG > 2;
 677     warn " ". join('/', @{ $taxlisthash->{$tax} } ). "\n" if $DEBUG > 2;
 678     my $hashref_or_error =
 679       $tax_object->taxline( $taxlisthash->{$tax},
 680                             'custnum'      => $self->custnum,
 681                             'invoice_time' => $invoice_time
 682                           );
 683     return $hashref_or_error unless ref($hashref_or_error);
 684
 685     unshift @{ $taxlisthash->{$tax} }, $tax_object;
 686
 687     my $name   = $hashref_or_error->{'name'};
 688     my $amount = $hashref_or_error->{'amount'};
 689
 690     #warn "adding $amount as $name\n";
 691     $taxname{ $name } ||= [];
 692     push @{ $taxname{ $name } }, $tax;
 693
 694     $tax{ $tax } += $amount;
 695
 696     $tax_location{ $tax } ||= [];
 697     if ( $tax_object->get('pkgnum') || $tax_object->get('locationnum') ) {
 698       push @{ $tax_location{ $tax }  },
 699         {
 700           'taxnum'      => $tax_object->taxnum,
 701           'taxtype'     => ref($tax_object),
 702           'pkgnum'      => $tax_object->get('pkgnum'),
 703           'locationnum' => $tax_object->get('locationnum'),
 704           'amount'      => sprintf('%.2f', $amount ),
 705         };
 706     }
 707
 708     $tax_rate_location{ $tax } ||= [];
 709     if ( ref($tax_object) eq 'FS::tax_rate' ) {
 710       my $taxratelocationnum =
 711         $tax_object->tax_rate_location->taxratelocationnum;
 712       push @{ $tax_rate_location{ $tax }  },
 713         {
 714           'taxnum'             => $tax_object->taxnum,
 715           'taxtype'            => ref($tax_object),
 716           'amount'             => sprintf('%.2f', $amount ),
 717           'locationtaxid'      => $tax_object->location,
 718           'taxratelocationnum' => $taxratelocationnum,
 719         };
 720     }
 721
 722   }
 723
 724   #move the cust_tax_exempt_pkg records to the cust_bill_pkgs we will commit
 725   my %packagemap = map { $_->pkgnum => $_ } @$cust_bill_pkg;
 726   foreach my $tax ( keys %$taxlisthash ) {
 727     foreach ( @{ $taxlisthash->{$tax} }[1 ... scalar(@{ $taxlisthash->{$tax} })] ) {
 728       next unless ref($_) eq 'FS::cust_bill_pkg';
 729
 730       my @cust_tax_exempt_pkg = splice( @{ $_->_cust_tax_exempt_pkg } );
 731
 732       next unless @cust_tax_exempt_pkg; #just avoiding the prob when irrelevant?
 733       die "can't distribute tax exemptions: no line item for ".  Dumper($_).
 734           " in packagemap ". join(',', sort {$a<=>$b} keys %packagemap). "\n"
 735         unless $packagemap{$_->pkgnum};
 736
 737       push @{ $packagemap{$_->pkgnum}->_cust_tax_exempt_pkg },
 738            @cust_tax_exempt_pkg;
 739     }
 740   }
 741
 742   #consolidate and create tax line items
 743   warn "consolidating and generating...\n" if $DEBUG > 2;
 744   foreach my $taxname ( keys %taxname ) {
 745     my $tax = 0;
 746     my %seen = ();
 747     my @cust_bill_pkg_tax_location = ();
 748     my @cust_bill_pkg_tax_rate_location = ();
 749     warn "adding $taxname\n" if $DEBUG > 1;
 750     foreach my $taxitem ( @{ $taxname{$taxname} } ) {
 751       next if $seen{$taxitem}++;
 752       warn "adding $tax{$taxitem}\n" if $DEBUG > 1;
 753       $tax += $tax{$taxitem};
 754       push @cust_bill_pkg_tax_location,
 755         map { new FS::cust_bill_pkg_tax_location $_ }
 756             @{ $tax_location{ $taxitem } };
 757       push @cust_bill_pkg_tax_rate_location,
 758         map { new FS::cust_bill_pkg_tax_rate_location $_ }
 759             @{ $tax_rate_location{ $taxitem } };
 760     }
 761     next unless $tax;
 762
 763     $tax = sprintf('%.2f', $tax );
 764
 765     my $pkg_category = qsearchs( 'pkg_category', { 'categoryname' => $taxname,
 766                                                    'disabled'     => '',
 767                                                  },
 768                                );
 769
 770     my @display = ();
 771     if ( $pkg_category and
 772          $conf->config('invoice_latexsummary') ||
 773          $conf->config('invoice_htmlsummary')
 774        )
 775     {
 776
 777       my %hash = (  'section' => $pkg_category->categoryname );
 778       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
 779
 780     }
 781
 782     push @tax_line_items, new FS::cust_bill_pkg {
 783       'pkgnum'   => 0,
 784       'setup'    => $tax,
 785       'recur'    => 0,
 786       'sdate'    => '',
 787       'edate'    => '',
 788       'itemdesc' => $taxname,
 789       'display'  => \@display,
 790       'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 791       'cust_bill_pkg_tax_rate_location' => \@cust_bill_pkg_tax_rate_location,
 792     };
 793
 794   }
 795
 796   \@tax_line_items;
 797 }
 798
 799 sub _make_lines {
 800   my ($self, %params) = @_;
 801
 802   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 803
 804   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 805   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 806   my $precommit_hooks = $params{precommit_hooks} or die "no package specified";
 807   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 808   my $total_setup = $params{setup} or die "no setup accumulator specified";
 809   my $total_recur = $params{recur} or die "no recur accumulator specified";
 810   my $taxlisthash = $params{tax_matrix} or die "no tax accumulator specified";
 811   my $time = $params{'time'} or die "no time specified";
 812   my (%options) = %{$params{options}};
 813
 814   my $dbh = dbh;
 815   my $real_pkgpart = $params{real_pkgpart};
 816   my %hash = $cust_pkg->hash;
 817   my $old_cust_pkg = new FS::cust_pkg \%hash;
 818
 819   my @details = ();
 820   my @discounts = ();
 821   my $lineitems = 0;
 822
 823   $cust_pkg->pkgpart($part_pkg->pkgpart);
 824
 825   ###
 826   # bill setup
 827   ###
 828
 829   my $setup = 0;
 830   my $unitsetup = 0;
 831   if (     ! $options{recurring_only}
 832        and ! $options{cancel}
 833        and ( $options{'resetup'}
 834              || ( ! $cust_pkg->setup
 835                   && ( ! $cust_pkg->start_date
 836                        || $cust_pkg->start_date <= $time
 837                      )
 838                   && ( ! $conf->exists('disable_setup_suspended_pkgs')
 839                        || ( $conf->exists('disable_setup_suspended_pkgs') &&
 840                             ! $cust_pkg->getfield('susp')
 841                           )
 842                      )
 843                 )
 844            )
 845      )
 846   {
 847
 848     warn "    bill setup\n" if $DEBUG > 1;
 849     $lineitems++;
 850
 851     $setup = eval { $cust_pkg->calc_setup( $time, \@details ) };
 852     return "$@ running calc_setup for $cust_pkg\n"
 853       if $@;
 854
 855     $unitsetup = $cust_pkg->part_pkg->unit_setup || $setup; #XXX uuh
 856
 857     $cust_pkg->setfield('setup', $time)
 858       unless $cust_pkg->setup;
 859           #do need it, but it won't get written to the db
 860           #|| $cust_pkg->pkgpart != $real_pkgpart;
 861
 862     $cust_pkg->setfield('start_date', '')
 863       if $cust_pkg->start_date;
 864
 865   }
 866
 867   ###
 868   # bill recurring fee
 869   ###
 870
 871   #XXX unit stuff here too
 872   my $recur = 0;
 873   my $unitrecur = 0;
 874   my $sdate;
 875   if (     ! $cust_pkg->start_date
 876        and ( ! $cust_pkg->susp || $part_pkg->option('suspend_bill', 1) )
 877        and
 878             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $time )
 879          || ( $part_pkg->plan eq 'voip_cdr'
 880                && $part_pkg->option('bill_every_call')
 881             )
 882          || $options{cancel}
 883   ) {
 884
 885     # XXX should this be a package event?  probably.  events are called
 886     # at collection time at the moment, though...
 887     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
 888       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
 889       #don't want to reset usage just cause we want a line item??
 890       #&& $part_pkg->pkgpart == $real_pkgpart;
 891
 892     warn "    bill recur\n" if $DEBUG > 1;
 893     $lineitems++;
 894
 895     # XXX shared with $recur_prog
 896     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
 897              || $cust_pkg->setup
 898              || $time;
 899
 900     #over two params!  lets at least switch to a hashref for the rest...
 901     my $increment_next_bill = ( $part_pkg->freq ne '0'
 902                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $time
 903                                 && !$options{cancel}
 904                               );
 905     my %param = ( 'precommit_hooks'     => $precommit_hooks,
 906                   'increment_next_bill' => $increment_next_bill,
 907                   'discounts'           => \@discounts,
 908                   'real_pkgpart'        => $real_pkgpart,
 909                   'freq_override'       => $options{freq_override} || '',
 910                 );
 911
 912     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
 913
 914     # There may be some part_pkg for which this is wrong.  Only those
 915     # which can_discount are supported.
 916     # (the UI should prevent adding discounts to these at the moment)
 917
 918     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
 919     return "$@ running $method for $cust_pkg\n"
 920       if ( $@ );
 921
 922     if ( $increment_next_bill ) {
 923
 924       my $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
 925       return "unparsable frequency: ". $part_pkg->freq
 926         if $next_bill == -1;
 927
 928       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
 929       # only for figuring next bill date, nothing else, so, reset $sdate again
 930       # here
 931       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
 932       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
 933       $cust_pkg->last_bill($sdate);
 934
 935       $cust_pkg->setfield('bill', $next_bill );
 936
 937     }
 938
 939   }
 940
 941   warn "\$setup is undefined" unless defined($setup);
 942   warn "\$recur is undefined" unless defined($recur);
 943   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
 944
 945   ###
 946   # If there's line items, create em cust_bill_pkg records
 947   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
 948   ###
 949
 950   if ( $lineitems ) {
 951
 952     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
 953       # hmm.. and if just the options are modified in some weird price plan?
 954
 955       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
 956         if $DEBUG >1;
 957
 958       my $error = $cust_pkg->replace( $old_cust_pkg,
 959                                       'depend_jobnum'=>$options{depend_jobnum},
 960                                       'options' => { $cust_pkg->options },
 961                                     )
 962         unless $options{no_commit};
 963       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
 964         if $error; #just in case
 965     }
 966
 967     $setup = sprintf( "%.2f", $setup );
 968     $recur = sprintf( "%.2f", $recur );
 969     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
 970       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
 971     }
 972     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
 973       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
 974     }
 975
 976     my $discount_show_always = ($recur == 0 && scalar(@discounts)
 977                                 && $conf->exists('discount-show-always'));
 978
 979     if ( $setup != 0 ||
 980          $recur != 0 ||
 981          (!$part_pkg->hidden && $options{has_hidden}) || #include some $0 lines
 982          $discount_show_always )
 983     {
 984
 985       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
 986         if $DEBUG > 1;
 987
 988       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
 989       if ( $DEBUG > 1 ) {
 990         warn "      adding customer package invoice detail: $_\n"
 991           foreach @cust_pkg_detail;
 992       }
 993       push @details, @cust_pkg_detail;
 994
 995       my $cust_bill_pkg = new FS::cust_bill_pkg {
 996         'pkgnum'    => $cust_pkg->pkgnum,
 997         'setup'     => $setup,
 998         'unitsetup' => $unitsetup,
 999         'recur'     => $recur,
1000         'unitrecur' => $unitrecur,
1001         'quantity'  => $cust_pkg->quantity,
1002         'details'   => \@details,
1003         'discounts' => \@discounts,
1004         'hidden'    => $part_pkg->hidden,
1005         'freq'      => $part_pkg->freq,
1006       };
1007
1008       if ( $part_pkg->option('recur_temporality', 1) eq 'preceding' ) {
1009         $cust_bill_pkg->sdate( $hash{last_bill} );
1010         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1011         $cust_bill_pkg->edate( $time ) if $options{cancel};
1012       } else { #if ( $part_pkg->option('recur_temporality', 1) eq 'upcoming' ) {
1013         $cust_bill_pkg->sdate( $sdate );
1014         $cust_bill_pkg->edate( $cust_pkg->bill );
1015         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1016       }
1017
1018       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1019         unless $part_pkg->pkgpart == $real_pkgpart;
1020
1021       $$total_setup += $setup;
1022       $$total_recur += $recur;
1023
1024       ###
1025       # handle taxes
1026       ###
1027
1028       unless ( $discount_show_always ) {
1029       my $error =
1030         $self->_handle_taxes($part_pkg, $taxlisthash, $cust_bill_pkg, $cust_pkg, $options{invoice_time}, $real_pkgpart, \%options);
1031       return $error if $error;
1032       }
1033
1034       push @$cust_bill_pkgs, $cust_bill_pkg;
1035
1036     } #if $setup != 0 || $recur != 0
1037
1038   } #if $line_items
1039
1040   '';
1041
1042 }
1043
1044 sub _handle_taxes {
1045   my $self = shift;
1046   my $part_pkg = shift;
1047   my $taxlisthash = shift;
1048   my $cust_bill_pkg = shift;
1049   my $cust_pkg = shift;
1050   my $invoice_time = shift;
1051   my $real_pkgpart = shift;
1052   my $options = shift;
1053
1054   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1055
1056   my %cust_bill_pkg = ();
1057   my %taxes = ();
1058
1059   my @classes;
1060   #push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->type eq 'U';
1061   push @classes, $cust_bill_pkg->usage_classes if $cust_bill_pkg->usage;
1062   push @classes, 'setup' if ($cust_bill_pkg->setup && !$options->{cancel});
1063   push @classes, 'recur' if ($cust_bill_pkg->recur && !$options->{cancel});
1064
1065   if ( $self->tax !~ /Y/i && $self->payby ne 'COMP' ) {
1066
1067     if ( $conf->exists('enable_taxproducts')
1068          && ( scalar($part_pkg->part_pkg_taxoverride)
1069               || $part_pkg->has_taxproduct
1070             )
1071        )
1072     {
1073
1074       foreach my $class (@classes) {
1075         my $err_or_ref = $self->_gather_taxes( $part_pkg, $class, $cust_pkg );
1076         return $err_or_ref unless ref($err_or_ref);
1077         $taxes{$class} = $err_or_ref;
1078       }
1079
1080       unless (exists $taxes{''}) {
1081         my $err_or_ref = $self->_gather_taxes( $part_pkg, '', $cust_pkg );
1082         return $err_or_ref unless ref($err_or_ref);
1083         $taxes{''} = $err_or_ref;
1084       }
1085
1086     } else {
1087
1088       my @loc_keys = qw( city county state country );
1089       my %taxhash;
1090       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1091         my $cust_location = $cust_pkg->cust_location;
1092         %taxhash = map { $_ => $cust_location->$_()    } @loc_keys;
1093       } else {
1094         my $prefix =
1095           ( $conf->exists('tax-ship_address') && length($self->ship_last) )
1096           ? 'ship_'
1097           : '';
1098         %taxhash = map { $_ => $self->get("$prefix$_") } @loc_keys;
1099       }
1100
1101       $taxhash{'taxclass'} = $part_pkg->taxclass;
1102
1103       my @taxes = ();
1104       my %taxhash_elim = %taxhash;
1105       my @elim = qw( city county state );
1106       do {
1107
1108         #first try a match with taxclass
1109         @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1110
1111         if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1112           #then try a match without taxclass
1113           my %no_taxclass = %taxhash_elim;
1114           $no_taxclass{ 'taxclass' } = '';
1115           @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1116         }
1117
1118         $taxhash_elim{ shift(@elim) } = '';
1119
1120       } while ( !scalar(@taxes) && scalar(@elim) );
1121
1122       @taxes = grep { ! $_->taxname or ! $self->tax_exemption($_->taxname) }
1123                     @taxes
1124         if $self->cust_main_exemption; #just to be safe
1125
1126       if ( $conf->exists('tax-pkg_address') && $cust_pkg->locationnum ) {
1127         foreach (@taxes) {
1128           $_->set('pkgnum',      $cust_pkg->pkgnum );
1129           $_->set('locationnum', $cust_pkg->locationnum );
1130         }
1131       }
1132
1133       $taxes{''} = [ @taxes ];
1134       $taxes{'setup'} = [ @taxes ];
1135       $taxes{'recur'} = [ @taxes ];
1136       $taxes{$_} = [ @taxes ] foreach (@classes);
1137
1138       # # maybe eliminate this entirely, along with all the 0% records
1139       # unless ( @taxes ) {
1140       #   return
1141       #     "fatal: can't find tax rate for state/county/country/taxclass ".
1142       #     join('/', map $taxhash{$_}, qw(state county country taxclass) );
1143       # }
1144
1145     } #if $conf->exists('enable_taxproducts') ...
1146
1147   }
1148
1149   my @display = ();
1150   my $separate = $conf->exists('separate_usage');
1151   my $temp_pkg = new FS::cust_pkg { pkgpart => $real_pkgpart };
1152   my $usage_mandate = $temp_pkg->part_pkg->option('usage_mandate', 'Hush!');
1153   my $section = $temp_pkg->part_pkg->categoryname;
1154   if ( $separate || $section || $usage_mandate ) {
1155
1156     my %hash = ( 'section' => $section );
1157
1158     $section = $temp_pkg->part_pkg->option('usage_section', 'Hush!');
1159     my $summary = $temp_pkg->part_pkg->option('summarize_usage', 'Hush!');
1160     if ( $separate ) {
1161       push @display, new FS::cust_bill_pkg_display { type => 'S', %hash };
1162       push @display, new FS::cust_bill_pkg_display { type => 'R', %hash };
1163     } else {
1164       push @display, new FS::cust_bill_pkg_display
1165                        { type => '',
1166                          %hash,
1167                          ( ( $usage_mandate ) ? ( 'summary' => 'Y' ) : () ),
1168                        };
1169     }
1170
1171     if ($separate && $section && $summary) {
1172       push @display, new FS::cust_bill_pkg_display { type    => 'U',
1173                                                      summary => 'Y',
1174                                                      %hash,
1175                                                    };
1176     }
1177     if ($usage_mandate || $section && $summary) {
1178       $hash{post_total} = 'Y';
1179     }
1180
1181     if ($separate || $usage_mandate) {
1182       $hash{section} = $section if ($separate || $usage_mandate);
1183       push @display, new FS::cust_bill_pkg_display { type => 'U', %hash };
1184     }
1185
1186   }
1187   $cust_bill_pkg->set('display', \@display);
1188
1189   my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1190   foreach my $key (keys %tax_cust_bill_pkg) {
1191     my @taxes = @{ $taxes{$key} || [] };
1192     my $tax_cust_bill_pkg = $tax_cust_bill_pkg{$key};
1193
1194     my %localtaxlisthash = ();
1195     foreach my $tax ( @taxes ) {
1196
1197       my $taxname = ref( $tax ). ' '. $tax->taxnum;
1198 #      $taxname .= ' pkgnum'. $cust_pkg->pkgnum.
1199 #                  ' locationnum'. $cust_pkg->locationnum
1200 #        if $conf->exists('tax-pkg_address') && $cust_pkg->locationnum;
1201
1202       $taxlisthash->{ $taxname } ||= [ $tax ];
1203       push @{ $taxlisthash->{ $taxname  } }, $tax_cust_bill_pkg;
1204
1205       $localtaxlisthash{ $taxname } ||= [ $tax ];
1206       push @{ $localtaxlisthash{ $taxname  } }, $tax_cust_bill_pkg;
1207
1208     }
1209
1210     warn "finding taxed taxes...\n" if $DEBUG > 2;
1211     foreach my $tax ( keys %localtaxlisthash ) {
1212       my $tax_object = shift @{ $localtaxlisthash{$tax} };
1213       warn "found possible taxed tax ". $tax_object->taxname. " we call $tax\n"
1214         if $DEBUG > 2;
1215       next unless $tax_object->can('tax_on_tax');
1216
1217       foreach my $tot ( $tax_object->tax_on_tax( $self ) ) {
1218         my $totname = ref( $tot ). ' '. $tot->taxnum;
1219
1220         warn "checking $totname which we call ". $tot->taxname. " as applicable\n"
1221           if $DEBUG > 2;
1222         next unless exists( $localtaxlisthash{ $totname } ); # only increase
1223                                                              # existing taxes
1224         warn "adding $totname to taxed taxes\n" if $DEBUG > 2;
1225         my $hashref_or_error =
1226           $tax_object->taxline( $localtaxlisthash{$tax},
1227                                 'custnum'      => $self->custnum,
1228                                 'invoice_time' => $invoice_time,
1229                               );
1230         return $hashref_or_error
1231           unless ref($hashref_or_error);
1232
1233         $taxlisthash->{ $totname } ||= [ $tot ];
1234         push @{ $taxlisthash->{ $totname  } }, $hashref_or_error->{amount};
1235
1236       }
1237     }
1238
1239   }
1240
1241   '';
1242 }
1243
1244 sub _gather_taxes {
1245   my $self = shift;
1246   my $part_pkg = shift;
1247   my $class = shift;
1248   my $cust_pkg = shift;
1249
1250   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1251
1252   my $geocode;
1253   if ( $cust_pkg->locationnum && $conf->exists('tax-pkg_address') ) {
1254     $geocode = $cust_pkg->cust_location->geocode('cch');
1255   } else {
1256     $geocode = $self->geocode('cch');
1257   }
1258
1259   my @taxes = ();
1260
1261   my @taxclassnums = map { $_->taxclassnum }
1262                      $part_pkg->part_pkg_taxoverride($class);
1263
1264   unless (@taxclassnums) {
1265     @taxclassnums = map { $_->taxclassnum }
1266                     grep { $_->taxable eq 'Y' }
1267                     $part_pkg->part_pkg_taxrate('cch', $geocode, $class);
1268   }
1269   warn "Found taxclassnum values of ". join(',', @taxclassnums)
1270     if $DEBUG;
1271
1272   my $extra_sql =
1273     "AND (".
1274     join(' OR ', map { "taxclassnum = $_" } @taxclassnums ). ")";
1275
1276   @taxes = qsearch({ 'table' => 'tax_rate',
1277                      'hashref' => { 'geocode' => $geocode, },
1278                      'extra_sql' => $extra_sql,
1279                   })
1280     if scalar(@taxclassnums);
1281
1282   warn "Found taxes ".
1283        join(',', map{ ref($_). " ". $_->get($_->primary_key) } @taxes). "\n"
1284    if $DEBUG;
1285
1286   [ @taxes ];
1287
1288 }
1289
1290 =item collect [ HASHREF | OPTION => VALUE ... ]
1291
1292 (Attempt to) collect money for this customer's outstanding invoices (see
1293 L<FS::cust_bill>).  Usually used after the bill method.
1294
1295 Actions are now triggered by billing events; see L<FS::part_event> and the
1296 billing events web interface.  Old-style invoice events (see
1297 L<FS::part_bill_event>) have been deprecated.
1298
1299 If there is an error, returns the error, otherwise returns false.
1300
1301 Options are passed as name-value pairs.
1302
1303 Currently available options are:
1304
1305 =over 4
1306
1307 =item invoice_time
1308
1309 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1310
1311 =item retry
1312
1313 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1314
1315 =item check_freq
1316
1317 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1318
1319 =item quiet
1320
1321 set true to surpress email card/ACH decline notices.
1322
1323 =item debug
1324
1325 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1326
1327 =back
1328
1329 # =item payby
1330 #
1331 # allows for one time override of normal customer billing method
1332
1333 =cut
1334
1335 sub collect {
1336   my( $self, %options ) = @_;
1337
1338   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1339
1340   my $invoice_time = $options{'invoice_time'} || time;
1341
1342   #put below somehow?
1343   local $SIG{HUP} = 'IGNORE';
1344   local $SIG{INT} = 'IGNORE';
1345   local $SIG{QUIT} = 'IGNORE';
1346   local $SIG{TERM} = 'IGNORE';
1347   local $SIG{TSTP} = 'IGNORE';
1348   local $SIG{PIPE} = 'IGNORE';
1349
1350   my $oldAutoCommit = $FS::UID::AutoCommit;
1351   local $FS::UID::AutoCommit = 0;
1352   my $dbh = dbh;
1353
1354   $self->select_for_update; #mutex
1355
1356   if ( $DEBUG ) {
1357     my $balance = $self->balance;
1358     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1359   }
1360
1361   if ( exists($options{'retry_card'}) ) {
1362     carp 'retry_card option passed to collect is deprecated; use retry';
1363     $options{'retry'} ||= $options{'retry_card'};
1364   }
1365   if ( exists($options{'retry'}) && $options{'retry'} ) {
1366     my $error = $self->retry_realtime;
1367     if ( $error ) {
1368       $dbh->rollback if $oldAutoCommit;
1369       return $error;
1370     }
1371   }
1372
1373   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1374
1375   #never want to roll back an event just because it returned an error
1376   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1377
1378   $self->do_cust_event(
1379     'debug'      => ( $options{'debug'} || 0 ),
1380     'time'       => $invoice_time,
1381     'check_freq' => $options{'check_freq'},
1382     'stage'      => 'collect',
1383   );
1384
1385 }
1386
1387 =item retry_realtime
1388
1389 Schedules realtime / batch  credit card / electronic check / LEC billing
1390 events for for retry.  Useful if card information has changed or manual
1391 retry is desired.  The 'collect' method must be called to actually retry
1392 the transaction.
1393
1394 Implementation details: For either this customer, or for each of this
1395 customer's open invoices, changes the status of the first "done" (with
1396 statustext error) realtime processing event to "failed".
1397
1398 =cut
1399
1400 sub retry_realtime {
1401   my $self = shift;
1402
1403   local $SIG{HUP} = 'IGNORE';
1404   local $SIG{INT} = 'IGNORE';
1405   local $SIG{QUIT} = 'IGNORE';
1406   local $SIG{TERM} = 'IGNORE';
1407   local $SIG{TSTP} = 'IGNORE';
1408   local $SIG{PIPE} = 'IGNORE';
1409
1410   my $oldAutoCommit = $FS::UID::AutoCommit;
1411   local $FS::UID::AutoCommit = 0;
1412   my $dbh = dbh;
1413
1414   #a little false laziness w/due_cust_event (not too bad, really)
1415
1416   my $join = FS::part_event_condition->join_conditions_sql;
1417   my $order = FS::part_event_condition->order_conditions_sql;
1418   my $mine =
1419   '( '
1420    . join ( ' OR ' , map {
1421     "( part_event.eventtable = " . dbh->quote($_)
1422     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key . " from $_ where custnum = " . dbh->quote( $self->custnum ) . "))" ;
1423    } FS::part_event->eventtables)
1424    . ') ';
1425
1426   #here is the agent virtualization
1427   my $agent_virt = " (    part_event.agentnum IS NULL
1428                        OR part_event.agentnum = ". $self->agentnum. ' )';
1429
1430   #XXX this shouldn't be hardcoded, actions should declare it...
1431   my @realtime_events = qw(
1432     cust_bill_realtime_card
1433     cust_bill_realtime_check
1434     cust_bill_realtime_lec
1435     cust_bill_batch
1436   );
1437
1438   my $is_realtime_event = ' ( '. join(' OR ', map "part_event.action = '$_'",
1439                                                   @realtime_events
1440                                      ).
1441                           ' ) ';
1442
1443   my @cust_event = qsearchs({
1444     'table'     => 'cust_event',
1445     'select'    => 'cust_event.*',
1446     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1447     'hashref'   => { 'status' => 'done' },
1448     'extra_sql' => " AND statustext IS NOT NULL AND statustext != '' ".
1449                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1450   });
1451
1452   my %seen_invnum = ();
1453   foreach my $cust_event (@cust_event) {
1454
1455     #max one for the customer, one for each open invoice
1456     my $cust_X = $cust_event->cust_X;
1457     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1458                           ? $cust_X->invnum
1459                           : 0
1460                         }++
1461          or $cust_event->part_event->eventtable eq 'cust_bill'
1462             && ! $cust_X->owed;
1463
1464     my $error = $cust_event->retry;
1465     if ( $error ) {
1466       $dbh->rollback if $oldAutoCommit;
1467       return "error scheduling event for retry: $error";
1468     }
1469
1470   }
1471
1472   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1473   '';
1474
1475 }
1476
1477 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1478
1479 Runs billing events; see L<FS::part_event> and the billing events web
1480 interface.
1481
1482 If there is an error, returns the error, otherwise returns false.
1483
1484 Options are passed as name-value pairs.
1485
1486 Currently available options are:
1487
1488 =over 4
1489
1490 =item time
1491
1492 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1493
1494 =item check_freq
1495
1496 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1497
1498 =item stage
1499
1500 "collect" (the default) or "pre-bill"
1501
1502 =item quiet
1503
1504 set true to surpress email card/ACH decline notices.
1505
1506 =item debug
1507
1508 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1509
1510 =back
1511 =cut
1512
1513 # =item payby
1514 #
1515 # allows for one time override of normal customer billing method
1516
1517 # =item retry
1518 #
1519 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1520
1521 sub do_cust_event {
1522   my( $self, %options ) = @_;
1523
1524   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1525
1526   my $time = $options{'time'} || time;
1527
1528   #put below somehow?
1529   local $SIG{HUP} = 'IGNORE';
1530   local $SIG{INT} = 'IGNORE';
1531   local $SIG{QUIT} = 'IGNORE';
1532   local $SIG{TERM} = 'IGNORE';
1533   local $SIG{TSTP} = 'IGNORE';
1534   local $SIG{PIPE} = 'IGNORE';
1535
1536   my $oldAutoCommit = $FS::UID::AutoCommit;
1537   local $FS::UID::AutoCommit = 0;
1538   my $dbh = dbh;
1539
1540   $self->select_for_update; #mutex
1541
1542   if ( $DEBUG ) {
1543     my $balance = $self->balance;
1544     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1545   }
1546
1547 #  if ( exists($options{'retry_card'}) ) {
1548 #    carp 'retry_card option passed to collect is deprecated; use retry';
1549 #    $options{'retry'} ||= $options{'retry_card'};
1550 #  }
1551 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1552 #    my $error = $self->retry_realtime;
1553 #    if ( $error ) {
1554 #      $dbh->rollback if $oldAutoCommit;
1555 #      return $error;
1556 #    }
1557 #  }
1558
1559   # false laziness w/pay_batch::import_results
1560
1561   my $due_cust_event = $self->due_cust_event(
1562     'debug'      => ( $options{'debug'} || 0 ),
1563     'time'       => $time,
1564     'check_freq' => $options{'check_freq'},
1565     'stage'      => ( $options{'stage'} || 'collect' ),
1566   );
1567   unless( ref($due_cust_event) ) {
1568     $dbh->rollback if $oldAutoCommit;
1569     return $due_cust_event;
1570   }
1571
1572   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1573   #never want to roll back an event just because it or a different one
1574   # returned an error
1575   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1576
1577   foreach my $cust_event ( @$due_cust_event ) {
1578
1579     #XXX lock event
1580
1581     #re-eval event conditions (a previous event could have changed things)
1582     unless ( $cust_event->test_conditions( 'time' => $time ) ) {
1583       #don't leave stray "new/locked" records around
1584       my $error = $cust_event->delete;
1585       return $error if $error;
1586       next;
1587     }
1588
1589     {
1590       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1591         if $options{'quiet'};
1592       warn "  running cust_event ". $cust_event->eventnum. "\n"
1593         if $DEBUG > 1;
1594
1595       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1596       if ( my $error = $cust_event->do_event() ) {
1597         #XXX wtf is this?  figure out a proper dealio with return value
1598         #from do_event
1599         return $error;
1600       }
1601     }
1602
1603   }
1604
1605   '';
1606
1607 }
1608
1609 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1610
1611 Inserts database records for and returns an ordered listref of new events due
1612 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1613 events are due, an empty listref is returned.  If there is an error, returns a
1614 scalar error message.
1615
1616 To actually run the events, call each event's test_condition method, and if
1617 still true, call the event's do_event method.
1618
1619 Options are passed as a hashref or as a list of name-value pairs.  Available
1620 options are:
1621
1622 =over 4
1623
1624 =item check_freq
1625
1626 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1627
1628 =item stage
1629
1630 "collect" (the default) or "pre-bill"
1631
1632 =item time
1633
1634 "Current time" for the events.
1635
1636 =item debug
1637
1638 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1639
1640 =item eventtable
1641
1642 Only return events for the specified eventtable (by default, events of all eventtables are returned)
1643
1644 =item objects
1645
1646 Explicitly pass the objects to be tested (typically used with eventtable).
1647
1648 =item testonly
1649
1650 Set to true to return the objects, but not actually insert them into the
1651 database.
1652
1653 =back
1654
1655 =cut
1656
1657 sub due_cust_event {
1658   my $self = shift;
1659   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
1660
1661   #???
1662   #my $DEBUG = $opt{'debug'}
1663   local($DEBUG) = $opt{'debug'}
1664     if defined($opt{'debug'}) && $opt{'debug'} > $DEBUG;
1665   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1666
1667   warn "$me due_cust_event called with options ".
1668        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
1669     if $DEBUG;
1670
1671   $opt{'time'} ||= time;
1672
1673   local $SIG{HUP} = 'IGNORE';
1674   local $SIG{INT} = 'IGNORE';
1675   local $SIG{QUIT} = 'IGNORE';
1676   local $SIG{TERM} = 'IGNORE';
1677   local $SIG{TSTP} = 'IGNORE';
1678   local $SIG{PIPE} = 'IGNORE';
1679
1680   my $oldAutoCommit = $FS::UID::AutoCommit;
1681   local $FS::UID::AutoCommit = 0;
1682   my $dbh = dbh;
1683
1684   $self->select_for_update #mutex
1685     unless $opt{testonly};
1686
1687   ###
1688   # find possible events (initial search)
1689   ###
1690
1691   my @cust_event = ();
1692
1693   my @eventtable = $opt{'eventtable'}
1694                      ? ( $opt{'eventtable'} )
1695                      : FS::part_event->eventtables_runorder;
1696
1697   my $check_freq = $opt{'check_freq'} || '1d';
1698
1699   foreach my $eventtable ( @eventtable ) {
1700
1701     my @objects;
1702     if ( $opt{'objects'} ) {
1703
1704       @objects = @{ $opt{'objects'} };
1705
1706     } else {
1707
1708       #my @objects = $self->$eventtable(); # sub cust_main { @{ [ $self ] }; }
1709       if ( $eventtable eq 'cust_main' ) {
1710         @objects = ( $self );
1711       } else {
1712
1713         my $cm_join =
1714           "LEFT JOIN cust_main USING ( custnum )";
1715
1716         #some false laziness w/Cron::bill bill_where
1717
1718         my $join  = FS::part_event_condition->join_conditions_sql( $eventtable);
1719         my $where = FS::part_event_condition->where_conditions_sql($eventtable,
1720                                                            'time'=>$opt{'time'},
1721                                                                   );
1722         $where = $where ? "AND $where" : '';
1723
1724         my $are_part_event =
1725           "EXISTS ( SELECT 1 FROM part_event $join
1726                       WHERE check_freq = '$check_freq'
1727                         AND eventtable = '$eventtable'
1728                         AND ( disabled = '' OR disabled IS NULL )
1729                         $where
1730                   )
1731           ";
1732         #eofalse
1733
1734         @objects = $self->$eventtable(
1735                      'addl_from' => $cm_join,
1736                      'extra_sql' => " AND $are_part_event",
1737                    );
1738       }
1739
1740     }
1741
1742     my @e_cust_event = ();
1743
1744     my $cross = "CROSS JOIN $eventtable";
1745     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
1746       unless $eventtable eq 'cust_main';
1747
1748     foreach my $object ( @objects ) {
1749
1750       #this first search uses the condition_sql magic for optimization.
1751       #the more possible events we can eliminate in this step the better
1752
1753       my $cross_where = '';
1754       my $pkey = $object->primary_key;
1755       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
1756
1757       my $join = FS::part_event_condition->join_conditions_sql( $eventtable );
1758       my $extra_sql =
1759         FS::part_event_condition->where_conditions_sql( $eventtable,
1760                                                         'time'=>$opt{'time'}
1761                                                       );
1762       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
1763
1764       $extra_sql = "AND $extra_sql" if $extra_sql;
1765
1766       #here is the agent virtualization
1767       $extra_sql .= " AND (    part_event.agentnum IS NULL
1768                             OR part_event.agentnum = ". $self->agentnum. ' )';
1769
1770       $extra_sql .= " $order";
1771
1772       warn "searching for events for $eventtable ". $object->$pkey. "\n"
1773         if $opt{'debug'} > 2;
1774       my @part_event = qsearch( {
1775         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
1776         'select'    => 'part_event.*',
1777         'table'     => 'part_event',
1778         'addl_from' => "$cross $join",
1779         'hashref'   => { 'check_freq' => $check_freq,
1780                          'eventtable' => $eventtable,
1781                          'disabled'   => '',
1782                        },
1783         'extra_sql' => "AND $cross_where $extra_sql",
1784       } );
1785
1786       if ( $DEBUG > 2 ) {
1787         my $pkey = $object->primary_key;
1788         warn "      ". scalar(@part_event).
1789              " possible events found for $eventtable ". $object->$pkey(). "\n";
1790       }
1791
1792       push @e_cust_event, map { $_->new_cust_event($object) } @part_event;
1793
1794     }
1795
1796     warn "    ". scalar(@e_cust_event).
1797          " subtotal possible cust events found for $eventtable\n"
1798       if $DEBUG > 1;
1799
1800     push @cust_event, @e_cust_event;
1801
1802   }
1803
1804   warn "  ". scalar(@cust_event).
1805        " total possible cust events found in initial search\n"
1806     if $DEBUG; # > 1;
1807
1808
1809   ##
1810   # test stage
1811   ##
1812
1813   $opt{stage} ||= 'collect';
1814   @cust_event =
1815     grep { my $stage = $_->part_event->event_stage;
1816            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
1817          }
1818          @cust_event;
1819
1820   ##
1821   # test conditions
1822   ##
1823
1824   my %unsat = ();
1825
1826   @cust_event = grep $_->test_conditions( 'time'          => $opt{'time'},
1827                                           'stats_hashref' => \%unsat ),
1828                      @cust_event;
1829
1830   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
1831     if $DEBUG; # > 1;
1832
1833   warn "    invalid conditions not eliminated with condition_sql:\n".
1834        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
1835     if keys %unsat && $DEBUG; # > 1;
1836
1837   ##
1838   # insert
1839   ##
1840
1841   unless( $opt{testonly} ) {
1842     foreach my $cust_event ( @cust_event ) {
1843
1844       my $error = $cust_event->insert();
1845       if ( $error ) {
1846         $dbh->rollback if $oldAutoCommit;
1847         return $error;
1848       }
1849
1850     }
1851   }
1852
1853   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1854
1855   ##
1856   # return
1857   ##
1858
1859   warn "  returning events: ". Dumper(@cust_event). "\n"
1860     if $DEBUG > 2;
1861
1862   \@cust_event;
1863
1864 }
1865
1866 =item apply_payments_and_credits [ OPTION => VALUE ... ]
1867
1868 Applies unapplied payments and credits.
1869
1870 In most cases, this new method should be used in place of sequential
1871 apply_payments and apply_credits methods.
1872
1873 A hash of optional arguments may be passed.  Currently "manual" is supported.
1874 If true, a payment receipt is sent instead of a statement when
1875 'payment_receipt_email' configuration option is set.
1876
1877 If there is an error, returns the error, otherwise returns false.
1878
1879 =cut
1880
1881 sub apply_payments_and_credits {
1882   my( $self, %options ) = @_;
1883
1884   local $SIG{HUP} = 'IGNORE';
1885   local $SIG{INT} = 'IGNORE';
1886   local $SIG{QUIT} = 'IGNORE';
1887   local $SIG{TERM} = 'IGNORE';
1888   local $SIG{TSTP} = 'IGNORE';
1889   local $SIG{PIPE} = 'IGNORE';
1890
1891   my $oldAutoCommit = $FS::UID::AutoCommit;
1892   local $FS::UID::AutoCommit = 0;
1893   my $dbh = dbh;
1894
1895   $self->select_for_update; #mutex
1896
1897   foreach my $cust_bill ( $self->open_cust_bill ) {
1898     my $error = $cust_bill->apply_payments_and_credits(%options);
1899     if ( $error ) {
1900       $dbh->rollback if $oldAutoCommit;
1901       return "Error applying: $error";
1902     }
1903   }
1904
1905   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1906   ''; #no error
1907
1908 }
1909
1910 =item apply_credits OPTION => VALUE ...
1911
1912 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
1913 to outstanding invoice balances in chronological order (or reverse
1914 chronological order if the I<order> option is set to B<newest>) and returns the
1915 value of any remaining unapplied credits available for refund (see
1916 L<FS::cust_refund>).
1917
1918 Dies if there is an error.
1919
1920 =cut
1921
1922 sub apply_credits {
1923   my $self = shift;
1924   my %opt = @_;
1925
1926   local $SIG{HUP} = 'IGNORE';
1927   local $SIG{INT} = 'IGNORE';
1928   local $SIG{QUIT} = 'IGNORE';
1929   local $SIG{TERM} = 'IGNORE';
1930   local $SIG{TSTP} = 'IGNORE';
1931   local $SIG{PIPE} = 'IGNORE';
1932
1933   my $oldAutoCommit = $FS::UID::AutoCommit;
1934   local $FS::UID::AutoCommit = 0;
1935   my $dbh = dbh;
1936
1937   $self->select_for_update; #mutex
1938
1939   unless ( $self->total_unapplied_credits ) {
1940     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1941     return 0;
1942   }
1943
1944   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
1945       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
1946
1947   my @invoices = $self->open_cust_bill;
1948   @invoices = sort { $b->_date <=> $a->_date } @invoices
1949     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
1950
1951   if ( $conf->exists('pkg-balances') ) {
1952     # limit @credits to those w/ a pkgnum grepped from $self
1953     my %pkgnums = ();
1954     foreach my $i (@invoices) {
1955       foreach my $li ( $i->cust_bill_pkg ) {
1956         $pkgnums{$li->pkgnum} = 1;
1957       }
1958     }
1959     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
1960   }
1961
1962   my $credit;
1963
1964   foreach my $cust_bill ( @invoices ) {
1965
1966     if ( !defined($credit) || $credit->credited == 0) {
1967       $credit = pop @credits or last;
1968     }
1969
1970     my $owed;
1971     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
1972       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
1973     } else {
1974       $owed = $cust_bill->owed;
1975     }
1976     unless ( $owed > 0 ) {
1977       push @credits, $credit;
1978       next;
1979     }
1980
1981     my $amount = min( $credit->credited, $owed );
1982
1983     my $cust_credit_bill = new FS::cust_credit_bill ( {
1984       'crednum' => $credit->crednum,
1985       'invnum'  => $cust_bill->invnum,
1986       'amount'  => $amount,
1987     } );
1988     $cust_credit_bill->pkgnum( $credit->pkgnum )
1989       if $conf->exists('pkg-balances') && $credit->pkgnum;
1990     my $error = $cust_credit_bill->insert;
1991     if ( $error ) {
1992       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
1993       die $error;
1994     }
1995
1996     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
1997
1998   }
1999
2000   my $total_unapplied_credits = $self->total_unapplied_credits;
2001
2002   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2003
2004   return $total_unapplied_credits;
2005 }
2006
2007 =item apply_payments  [ OPTION => VALUE ... ]
2008
2009 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2010 to outstanding invoice balances in chronological order.
2011
2012  #and returns the value of any remaining unapplied payments.
2013
2014 A hash of optional arguments may be passed.  Currently "manual" is supported.
2015 If true, a payment receipt is sent instead of a statement when
2016 'payment_receipt_email' configuration option is set.
2017
2018 Dies if there is an error.
2019
2020 =cut
2021
2022 sub apply_payments {
2023   my( $self, %options ) = @_;
2024
2025   local $SIG{HUP} = 'IGNORE';
2026   local $SIG{INT} = 'IGNORE';
2027   local $SIG{QUIT} = 'IGNORE';
2028   local $SIG{TERM} = 'IGNORE';
2029   local $SIG{TSTP} = 'IGNORE';
2030   local $SIG{PIPE} = 'IGNORE';
2031
2032   my $oldAutoCommit = $FS::UID::AutoCommit;
2033   local $FS::UID::AutoCommit = 0;
2034   my $dbh = dbh;
2035
2036   $self->select_for_update; #mutex
2037
2038   #return 0 unless
2039
2040   my @payments = sort { $b->_date <=> $a->_date }
2041                  grep { $_->unapplied > 0 }
2042                  $self->cust_pay;
2043
2044   my @invoices = sort { $a->_date <=> $b->_date}
2045                  grep { $_->owed > 0 }
2046                  $self->cust_bill;
2047
2048   if ( $conf->exists('pkg-balances') ) {
2049     # limit @payments to those w/ a pkgnum grepped from $self
2050     my %pkgnums = ();
2051     foreach my $i (@invoices) {
2052       foreach my $li ( $i->cust_bill_pkg ) {
2053         $pkgnums{$li->pkgnum} = 1;
2054       }
2055     }
2056     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2057   }
2058
2059   my $payment;
2060
2061   foreach my $cust_bill ( @invoices ) {
2062
2063     if ( !defined($payment) || $payment->unapplied == 0 ) {
2064       $payment = pop @payments or last;
2065     }
2066
2067     my $owed;
2068     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2069       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2070     } else {
2071       $owed = $cust_bill->owed;
2072     }
2073     unless ( $owed > 0 ) {
2074       push @payments, $payment;
2075       next;
2076     }
2077
2078     my $amount = min( $payment->unapplied, $owed );
2079
2080     my $cust_bill_pay = new FS::cust_bill_pay ( {
2081       'paynum' => $payment->paynum,
2082       'invnum' => $cust_bill->invnum,
2083       'amount' => $amount,
2084     } );
2085     $cust_bill_pay->pkgnum( $payment->pkgnum )
2086       if $conf->exists('pkg-balances') && $payment->pkgnum;
2087     my $error = $cust_bill_pay->insert(%options);
2088     if ( $error ) {
2089       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2090       die $error;
2091     }
2092
2093     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2094
2095   }
2096
2097   my $total_unapplied_payments = $self->total_unapplied_payments;
2098
2099   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2100
2101   return $total_unapplied_payments;
2102 }
2103
2104 =back
2105
2106 =head1 BUGS
2107
2108 =head1 SEE ALSO
2109
2110 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2111
2112 =cut
2113
2114 1;