FS/FS/ClientAPI/MyAccount.pm

   1 package FS::ClientAPI::MyAccount;
   2
   3 use strict;
   4 use vars qw($cache);
   5 use subs qw(_cache);
   6 use Digest::MD5 qw(md5_hex);
   7 use Date::Format;
   8 use Business::CreditCard;
   9 use Time::Duration;
  10 use FS::CGI qw(small_custview); #doh
  11 use FS::UI::Web;
  12 use FS::UI::bytecount;
  13 use FS::Conf;
  14 use FS::Record qw(qsearch qsearchs);
  15 use FS::Msgcat qw(gettext);
  16 use FS::Misc qw(card_types);
  17 use FS::ClientAPI_SessionCache;
  18 use FS::svc_acct;
  19 use FS::svc_domain;
  20 use FS::svc_external;
  21 use FS::part_svc;
  22 use FS::cust_main;
  23 use FS::cust_bill;
  24 use FS::cust_main_county;
  25 use FS::cust_pkg;
  26 use FS::payby;
  27 use HTML::Entities;
  28
  29 #false laziness with FS::cust_main
  30 BEGIN {
  31   eval "use Time::Local;";
  32   die "Time::Local minimum version 1.05 required with Perl versions before 5.6"
  33     if $] < 5.006 && !defined($Time::Local::VERSION);
  34   eval "use Time::Local qw(timelocal_nocheck);";
  35 }
  36
  37 use vars qw( @cust_main_editable_fields );
  38 @cust_main_editable_fields = qw(
  39   first last company address1 address2 city
  40     county state zip country daytime night fax
  41   ship_first ship_last ship_company ship_address1 ship_address2 ship_city
  42     ship_state ship_zip ship_country ship_daytime ship_night ship_fax
  43   payby payinfo payname paystart_month paystart_year payissue payip
  44 );
  45
  46 use subs qw(_provision);
  47
  48 sub _cache {
  49   $cache ||= new FS::ClientAPI_SessionCache( {
  50                'namespace' => 'FS::ClientAPI::MyAccount',
  51              } );
  52 }
  53
  54 #false laziness w/FS::ClientAPI::passwd::passwd
  55 sub login {
  56   my $p = shift;
  57
  58   my $svc_domain = qsearchs('svc_domain', { 'domain' => $p->{'domain'} } )
  59     or return { error => 'Domain '. $p->{'domain'}. ' not found' };
  60
  61   my $svc_acct = qsearchs( 'svc_acct', { 'username'  => $p->{'username'},
  62                                          'domsvc'    => $svc_domain->svcnum, }
  63                          );
  64   return { error => 'User not found.' } unless $svc_acct;
  65
  66   my $conf = new FS::Conf;
  67   my $pkg_svc = $svc_acct->cust_svc->pkg_svc;
  68   return { error => 'Only primary user may log in.' }
  69     if $conf->exists('selfservice_server-primary_only')
  70        && ( ! $pkg_svc || $pkg_svc->primary_svc ne 'Y' );
  71
  72   return { error => 'Incorrect password.' }
  73     unless $svc_acct->check_password($p->{'password'});
  74
  75   my $session = {
  76     'svcnum' => $svc_acct->svcnum,
  77   };
  78
  79   my $cust_pkg = $svc_acct->cust_svc->cust_pkg;
  80   if ( $cust_pkg ) {
  81     my $cust_main = $cust_pkg->cust_main;
  82     $session->{'custnum'} = $cust_main->custnum;
  83   }
  84
  85   my $session_id;
  86   do {
  87     $session_id = md5_hex(md5_hex(time(). {}. rand(). $$))
  88   } until ( ! defined _cache->get($session_id) ); #just in case
  89
  90   _cache->set( $session_id, $session, '1 hour' );
  91
  92   return { 'error'      => '',
  93            'session_id' => $session_id,
  94          };
  95 }
  96
  97 sub logout {
  98   my $p = shift;
  99   if ( $p->{'session_id'} ) {
 100     _cache->remove($p->{'session_id'});
 101     return { 'error' => '' };
 102   } else {
 103     return { 'error' => "Can't resume session" }; #better error message
 104   }
 105 }
 106
 107 sub customer_info {
 108   my $p = shift;
 109
 110   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 111   return { 'error' => $session } if $context eq 'error';
 112
 113   my %return;
 114   if ( $custnum ) { #customer record
 115
 116     my $search = { 'custnum' => $custnum };
 117     $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 118     my $cust_main = qsearchs('cust_main', $search )
 119       or return { 'error' => "unknown custnum $custnum" };
 120
 121     $return{balance} = $cust_main->balance;
 122
 123     my @open = map {
 124                      {
 125                        invnum => $_->invnum,
 126                        date   => time2str("%b %o, %Y", $_->_date),
 127                        owed   => $_->owed,
 128                      };
 129                    } $cust_main->open_cust_bill;
 130     $return{open_invoices} = \@open;
 131
 132     my $conf = new FS::Conf;
 133     $return{small_custview} =
 134       small_custview( $cust_main, $conf->config('countrydefault') );
 135
 136     $return{name} = $cust_main->first. ' '. $cust_main->get('last');
 137
 138     for (@cust_main_editable_fields) {
 139       $return{$_} = $cust_main->get($_);
 140     }
 141
 142     if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 143       $return{payinfo} = $cust_main->paymask;
 144       @return{'month', 'year'} = $cust_main->paydate_monthyear;
 145     }
 146
 147     $return{'invoicing_list'} =
 148       join(', ', grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list );
 149     $return{'postal_invoicing'} =
 150       0 < ( grep { $_ eq 'POST' } $cust_main->invoicing_list );
 151
 152   } elsif ( $session->{'svcnum'} ) { #no customer record
 153
 154     my $svc_acct = qsearchs('svc_acct', { 'svcnum' => $session->{'svcnum'} } )
 155       or die "unknown svcnum";
 156     $return{name} = $svc_acct->email;
 157
 158   } else {
 159
 160     return { 'error' => 'Expired session' }; #XXX redirect to login w/this err!
 161
 162   }
 163
 164   return { 'error'          => '',
 165            'custnum'        => $custnum,
 166            %return,
 167          };
 168
 169 }
 170
 171 sub edit_info {
 172   my $p = shift;
 173   my $session = _cache->get($p->{'session_id'})
 174     or return { 'error' => "Can't resume session" }; #better error message
 175
 176   my $custnum = $session->{'custnum'}
 177     or return { 'error' => "no customer record" };
 178
 179   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 180     or return { 'error' => "unknown custnum $custnum" };
 181
 182   my $new = new FS::cust_main { $cust_main->hash };
 183   $new->set( $_ => $p->{$_} )
 184     foreach grep { exists $p->{$_} } @cust_main_editable_fields;
 185
 186   if ( $p->{'payby'} =~ /^(CARD|DCRD)$/ ) {
 187     $new->paydate($p->{'year'}. '-'. $p->{'month'}. '-01');
 188     if ( $new->payinfo eq $cust_main->paymask ) {
 189       $new->payinfo($cust_main->payinfo);
 190     } else {
 191       $new->paycvv($p->{'paycvv'});
 192     }
 193   }
 194
 195   my @invoicing_list;
 196   if ( exists $p->{'invoicing_list'} || exists $p->{'postal_invoicing'} ) {
 197     #false laziness with httemplate/edit/process/cust_main.cgi
 198     @invoicing_list = split( /\s*\,\s*/, $p->{'invoicing_list'} );
 199     push @invoicing_list, 'POST' if $p->{'postal_invoicing'};
 200   } else {
 201     @invoicing_list = $cust_main->invoicing_list;
 202   }
 203
 204   my $error = $new->replace($cust_main, \@invoicing_list);
 205   return { 'error' => $error } if $error;
 206   #$cust_main = $new;
 207
 208   return { 'error' => '' };
 209 }
 210
 211 sub payment_info {
 212   my $p = shift;
 213   my $session = _cache->get($p->{'session_id'})
 214     or return { 'error' => "Can't resume session" }; #better error message
 215
 216   ##
 217   #generic
 218   ##
 219
 220   use vars qw($payment_info); #cache for performance
 221   unless ( $payment_info ) {
 222
 223     my $conf = new FS::Conf;
 224     my %states = map { $_->state => 1 }
 225                    qsearch('cust_main_county', {
 226                      'country' => $conf->config('countrydefault') || 'US'
 227                    } );
 228
 229     $payment_info = {
 230
 231       #list all counties/states/countries
 232       'cust_main_county' =>
 233         [ map { $_->hashref } qsearch('cust_main_county', {}) ],
 234
 235       #shortcut for one-country folks
 236       'states' =>
 237         [ sort { $a cmp $b } keys %states ],
 238
 239       'card_types' => card_types(),
 240
 241       'paytypes' => [ @FS::cust_main::paytypes ],
 242
 243       'stateid_label' => FS::Msgcat::_gettext('stateid'),
 244       'stateid_state_label' => FS::Msgcat::_gettext('stateid_state'),
 245
 246       'show_ss'  => $conf->exists('show_ss'),
 247       'show_stateid' => $conf->exists('show_stateid'),
 248       'show_paystate' => $conf->exists('show_bankstate'),
 249     };
 250
 251   }
 252
 253   ##
 254   #customer-specific
 255   ##
 256
 257   my %return = %$payment_info;
 258
 259   my $custnum = $session->{'custnum'};
 260
 261   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 262     or return { 'error' => "unknown custnum $custnum" };
 263
 264   $return{balance} = $cust_main->balance;
 265
 266   $return{payname} = $cust_main->payname
 267                      || ( $cust_main->first. ' '. $cust_main->get('last') );
 268
 269   $return{$_} = $cust_main->get($_) for qw(address1 address2 city state zip);
 270
 271   $return{payby} = $cust_main->payby;
 272   $return{stateid_state} = $cust_main->stateid_state;
 273
 274   if ( $cust_main->payby =~ /^(CARD|DCRD)$/ ) {
 275     $return{card_type} = cardtype($cust_main->payinfo);
 276     $return{payinfo} = $cust_main->paymask;
 277
 278     @return{'month', 'year'} = $cust_main->paydate_monthyear;
 279
 280   }
 281
 282   if ( $cust_main->payby =~ /^(CHEK|DCHK)$/ ) {
 283     my ($payinfo1, $payinfo2) = split '@', $cust_main->paymask;
 284     $return{payinfo1} = $payinfo1;
 285     $return{payinfo2} = $payinfo2;
 286     $return{paytype}  = $cust_main->paytype;
 287     $return{paystate} = $cust_main->paystate;
 288
 289   }
 290
 291   #doubleclick protection
 292   my $_date = time;
 293   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
 294
 295   return { 'error' => '',
 296            %return,
 297          };
 298
 299 };
 300
 301 #some false laziness with httemplate/process/payment.cgi - look there for
 302 #ACH and CVV support stuff
 303 sub process_payment {
 304
 305   my $p = shift;
 306
 307   my $session = _cache->get($p->{'session_id'})
 308     or return { 'error' => "Can't resume session" }; #better error message
 309
 310   my %return;
 311
 312   my $custnum = $session->{'custnum'};
 313
 314   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 315     or return { 'error' => "unknown custnum $custnum" };
 316
 317   $p->{'payname'} =~ /^([\w \,\.\-\']+)$/
 318     or return { 'error' => gettext('illegal_name'). " payname: ". $p->{'payname'} };
 319   my $payname = $1;
 320
 321   $p->{'paybatch'} =~ /^([\w \!\@\#\$\%\&\(\)\-\+\;\:\'\"\,\.\?\/\=]*)$/
 322     or return { 'error' => gettext('illegal_text'). " paybatch: ". $p->{'paybatch'} };
 323   my $paybatch = $1;
 324
 325   $p->{'payby'} = 'CARD' unless exists($p->{'payby'});
 326   $p->{'payby'} =~ /^([A-Z]{4})$/
 327     or return { 'error' => "illegal_payby " . $p->{'payby'} };
 328   my $payby = $1;
 329
 330   my $payinfo;
 331   my $paycvv = '';
 332   if ( $payby eq 'CHEK' || $payby eq 'DCHK' ) {
 333
 334     $p->{'payinfo1'} =~ /^([\dx]+)$/
 335       or return { 'error' => "illegal account number ". $p->{'payinfo1'} };
 336     my $payinfo1 = $1;
 337      $p->{'payinfo2'} =~ /^([\dx]+)$/
 338       or return { 'error' => "illegal ABA/routing number ". $p->{'payinfo2'} };
 339     my $payinfo2 = $1;
 340     $payinfo = $payinfo1. '@'. $payinfo2;
 341
 342     $payinfo = $cust_main->payinfo
 343       if $cust_main->paymask eq $payinfo;
 344
 345   } elsif ( $payby eq 'CARD' || $payby eq 'DCRD' ) {
 346
 347     $payinfo = $p->{'payinfo'};
 348     $payinfo =~ s/[^\dx]//g;
 349     $payinfo =~ /^(\d{13,16})$/
 350       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 351     $payinfo = $1;
 352
 353     $payinfo = $cust_main->payinfo
 354       if $cust_main->paymask eq $payinfo;
 355
 356     validate($payinfo)
 357       or return { 'error' => gettext('invalid_card') }; # . ": ". $self->payinfo
 358     return { 'error' => gettext('unknown_card_type') }
 359       if cardtype($payinfo) eq "Unknown";
 360
 361     if ( length($p->{'paycvv'}) && $p->{'paycvv'} !~ /^\s*$/ ) {
 362       if ( cardtype($payinfo) eq 'American Express card' ) {
 363         $p->{'paycvv'} =~ /^\s*(\d{4})\s*$/
 364           or return { 'error' => "CVV2 (CID) for American Express cards is four digits." };
 365         $paycvv = $1;
 366       } else {
 367         $p->{'paycvv'} =~ /^\s*(\d{3})\s*$/
 368           or return { 'error' => "CVV2 (CVC2/CID) is three digits." };
 369         $paycvv = $1;
 370       }
 371     }
 372
 373   } else {
 374     die "unknown payby $payby";
 375   }
 376
 377   my %payby2fields = (
 378     'CARD' => [ qw( paystart_month paystart_year payissue address1 address2 city state zip payip ) ],
 379     'CHEK' => [ qw( ss paytype paystate stateid stateid_state payip ) ],
 380   );
 381
 382   my $error = $cust_main->realtime_bop( $FS::payby::payby2bop{$payby}, $p->{'amount'},
 383     'quiet'    => 1,
 384     'payinfo'  => $payinfo,
 385     'paydate'  => $p->{'year'}. '-'. $p->{'month'}. '-01',
 386     'payname'  => $payname,
 387     'paybatch' => $paybatch,
 388     'paycvv'   => $paycvv,
 389     map { $_ => $p->{$_} } @{ $payby2fields{$payby} }
 390   );
 391   return { 'error' => $error } if $error;
 392
 393   $cust_main->apply_payments;
 394
 395   if ( $p->{'save'} ) {
 396     my $new = new FS::cust_main { $cust_main->hash };
 397     if ($payby eq 'CARD' || $payby eq 'DCRD') {
 398       $new->set( $_ => $p->{$_} )
 399         foreach qw( payname paystart_month paystart_year payissue payip
 400                     address1 address2 city state zip payinfo );
 401       $new->set( 'payby' => $p->{'auto'} ? 'CARD' : 'DCRD' );
 402     } elsif ($payby eq 'CHEK' || $payby eq 'DCHK') {
 403       $new->set( $_ => $p->{$_} )
 404         foreach qw( payname payip paytype paystate
 405                     stateid stateid_state );
 406       $new->set( 'payinfo' => $payinfo );
 407       $new->set( 'payby' => $p->{'auto'} ? 'CHEK' : 'DCHK' );
 408     }
 409     $new->set( 'paydate' => $p->{'year'}. '-'. $p->{'month'}. '-01' );
 410     my $error = $new->replace($cust_main);
 411     return { 'error' => $error } if $error;
 412     $cust_main = $new;
 413   }
 414
 415   return { 'error' => '' };
 416
 417 }
 418
 419 sub process_payment_order_pkg {
 420   my $p = shift;
 421
 422   my $hr = process_payment($p);
 423   return $hr if $hr->{'error'};
 424
 425   order_pkg($p);
 426 }
 427
 428 sub process_prepay {
 429
 430   my $p = shift;
 431
 432   my $session = _cache->get($p->{'session_id'})
 433     or return { 'error' => "Can't resume session" }; #better error message
 434
 435   my %return;
 436
 437   my $custnum = $session->{'custnum'};
 438
 439   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 440     or return { 'error' => "unknown custnum $custnum" };
 441
 442   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = ( 0, 0, 0, 0, 0 );
 443   my $error = $cust_main->recharge_prepay( $p->{'prepaid_cardnum'},
 444                                            \$amount,
 445                                            \$seconds,
 446                                            \$upbytes,
 447                                            \$downbytes,
 448                                            \$totalbytes,
 449                                          );
 450
 451   return { 'error' => $error } if $error;
 452
 453   return { 'error'     => '',
 454            'amount'    => $amount,
 455            'seconds'   => $seconds,
 456            'duration'  => duration_exact($seconds),
 457            'upbytes'   => $upbytes,
 458            'upload'    => FS::UI::bytecount::bytecount_unexact($upbytes),
 459            'downbytes' => $downbytes,
 460            'download'  => FS::UI::bytecount::bytecount_unexact($downbytes),
 461            'totalbytes'=> $totalbytes,
 462            'totalload' => FS::UI::bytecount::bytecount_unexact($totalbytes),
 463          };
 464
 465 }
 466
 467 sub invoice {
 468   my $p = shift;
 469   my $session = _cache->get($p->{'session_id'})
 470     or return { 'error' => "Can't resume session" }; #better error message
 471
 472   my $custnum = $session->{'custnum'};
 473
 474   my $invnum = $p->{'invnum'};
 475
 476   my $cust_bill = qsearchs('cust_bill', { 'invnum'  => $invnum,
 477                                           'custnum' => $custnum } )
 478     or return { 'error' => "Can't find invnum" };
 479
 480   #my %return;
 481
 482   return { 'error'        => '',
 483            'invnum'       => $invnum,
 484            'invoice_text' => join('', $cust_bill->print_text ),
 485            'invoice_html' => $cust_bill->print_html,
 486          };
 487
 488 }
 489
 490 sub invoice_logo {
 491   my $p = shift;
 492
 493   #sessioning for this?  how do we get the session id to the backend invoice
 494   # template so it can add it to the link, blah
 495
 496   my $templatename = $p->{'templatename'};
 497
 498   #false laziness-ish w/view/cust_bill-logo.cgi
 499
 500   my $conf = new FS::Conf;
 501   if ( $templatename =~ /^([^\.\/]*)$/ && $conf->exists("logo_$1.png") ) {
 502     $templatename = "_$1";
 503   } else {
 504     $templatename = '';
 505   }
 506
 507   my $filename = "logo$templatename.png";
 508
 509   return { 'error'        => '',
 510            'logo'         => $conf->config_binary($filename),
 511            'content_type' => 'image/png', #should allow gif, jpg too
 512          };
 513 }
 514
 515
 516 sub list_invoices {
 517   my $p = shift;
 518   my $session = _cache->get($p->{'session_id'})
 519     or return { 'error' => "Can't resume session" }; #better error message
 520
 521   my $custnum = $session->{'custnum'};
 522
 523   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 524     or return { 'error' => "unknown custnum $custnum" };
 525
 526   my @cust_bill = $cust_main->cust_bill;
 527
 528   return  { 'error'       => '',
 529             'invoices'    =>  [ map { { 'invnum' => $_->invnum,
 530                                         '_date'  => $_->_date,
 531                                       }
 532                                     } @cust_bill
 533                               ]
 534           };
 535 }
 536
 537 sub cancel {
 538   my $p = shift;
 539   my $session = _cache->get($p->{'session_id'})
 540     or return { 'error' => "Can't resume session" }; #better error message
 541
 542   my $custnum = $session->{'custnum'};
 543
 544   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 545     or return { 'error' => "unknown custnum $custnum" };
 546
 547   my @errors = $cust_main->cancel( 'quiet'=>1 );
 548
 549   my $error = scalar(@errors) ? join(' / ', @errors) : '';
 550
 551   return { 'error' => $error };
 552
 553 }
 554
 555 sub list_pkgs {
 556   my $p = shift;
 557
 558   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 559   return { 'error' => $session } if $context eq 'error';
 560
 561   my $search = { 'custnum' => $custnum };
 562   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 563   my $cust_main = qsearchs('cust_main', $search )
 564     or return { 'error' => "unknown custnum $custnum" };
 565
 566   #return { 'cust_pkg' => [ map { $_->hashref } $cust_main->ncancelled_pkgs ] };
 567
 568   my $conf = new FS::Conf;
 569
 570   { 'svcnum'   => $session->{'svcnum'},
 571     'custnum'  => $custnum,
 572     'cust_pkg' => [ map {
 573                           { $_->hash,
 574                             $_->part_pkg->hash,
 575                             part_svc =>
 576                               [ map $_->hashref, $_->available_part_svc ],
 577                             cust_svc =>
 578                               [ map { my $ref = { $_->hash,
 579                                                   label => [ $_->label ],
 580                                                 };
 581                                       $ref->{_password} = $_->svc_x->_password
 582                                         if $context eq 'agent'
 583                                         && $conf->exists('agent-showpasswords')
 584                                         && $_->part_svc->svcdb eq 'svc_acct';
 585                                       $ref;
 586                                     } $_->cust_svc
 587                               ],
 588                           };
 589                         } $cust_main->ncancelled_pkgs
 590                   ],
 591     'small_custview' =>
 592       small_custview( $cust_main, $conf->config('countrydefault') ),
 593   };
 594
 595 }
 596
 597 sub list_svcs {
 598   my $p = shift;
 599
 600   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 601   return { 'error' => $session } if $context eq 'error';
 602
 603   my $search = { 'custnum' => $custnum };
 604   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 605   my $cust_main = qsearchs('cust_main', $search )
 606     or return { 'error' => "unknown custnum $custnum" };
 607
 608   my @cust_svc = ();
 609   #foreach my $cust_pkg ( $cust_main->ncancelled_pkgs ) {
 610   foreach my $cust_pkg ( $p->{'ncancelled'}
 611                          ? $cust_main->ncancelled_pkgs
 612                          : $cust_main->unsuspended_pkgs ) {
 613     push @cust_svc, @{[ $cust_pkg->cust_svc ]}; #@{[ ]} to force array context
 614   }
 615   @cust_svc = grep { $_->part_svc->svcdb eq $p->{'svcdb'} } @cust_svc
 616     if $p->{'svcdb'};
 617
 618   #@svc_x = sort { $a->domain cmp $b->domain || $a->username cmp $b->username }
 619   #              @svc_x;
 620
 621   {
 622     #no#'svcnum'   => $session->{'svcnum'},
 623     'custnum'  => $custnum,
 624     'svcs'     => [ map {
 625                           my $svc_x = $_->svc_x;
 626                           my($label, $value) = $_->label;
 627                           my $part_pkg = $svc_x->cust_svc->cust_pkg->part_pkg;
 628
 629                           { 'svcnum'    => $_->svcnum,
 630                             'label'     => $label,
 631                             'value'     => $value,
 632                             'username'  => $svc_x->username,
 633                             'email'     => $svc_x->email,
 634                             'seconds'   => $svc_x->seconds,
 635                             'upbytes'   => FS::UI::bytecount::display_bytecount($svc_x->upbytes),
 636                             'downbytes' => FS::UI::bytecount::display_bytecount($svc_x->downbytes),
 637                             'totalbytes'=> FS::UI::bytecount::display_bytecount($svc_x->totalbytes),
 638                             'recharge_amount' => $part_pkg->option('recharge_amount', 1),
 639                             'recharge_seconds' => $part_pkg->option('recharge_seconds', 1),
 640                             'recharge_upbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_upbytes', 1)),
 641                             'recharge_downbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_downbytes', 1)),
 642                             'recharge_totalbytes' => FS::UI::bytecount::display_bytecount($part_pkg->option('recharge_totalbytes', 1)),
 643                             # more...
 644                           };
 645                         }
 646                         @cust_svc
 647                   ],
 648   };
 649
 650 }
 651
 652 sub list_svc_usage {
 653   my $p = shift;
 654
 655   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 656   return { 'error' => $session } if $context eq 'error';
 657
 658   my $search = { 'svcnum' => $p->{'svcnum'} };
 659   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 660   my $svc_acct = qsearchs ( 'svc_acct', $search );
 661   return { 'error' => 'No service selected in list_svc_usage' }
 662     unless $svc_acct;
 663
 664   my $freq   = $svc_acct->cust_svc->cust_pkg->part_pkg->freq;
 665   my $start  = $svc_acct->cust_svc->cust_pkg->setup;
 666   #my $end    = $svc_acct->cust_svc->cust_pkg->bill; # or time?
 667   my $end    = time;
 668
 669   unless($p->{beginning}){
 670     $p->{beginning} = $svc_acct->cust_svc->cust_pkg->last_bill;
 671     $p->{ending} = $end;
 672   }
 673   my @usage = ();
 674
 675   foreach my $part_export (
 676     map { qsearch ( 'part_export', { 'exporttype' => $_ } ) }
 677     qw (sqlradius sqlradius_withdomain')
 678   ) {
 679
 680     push @usage, @ { $part_export->usage_sessions($p->{beginning},
 681                                                   $p->{ending},
 682                                                   $svc_acct)
 683                    };
 684   }
 685
 686   #kinda false laziness with FS::cust_main::bill, but perhaps
 687   #we should really change this bit to DateTime and DateTime::Duration
 688   #
 689   #change this bit to use Date::Manip? CAREFUL with timezones (see
 690   # mailing list archive)
 691   my ($nsec,$nmin,$nhour,$nmday,$nmon,$nyear) =
 692     (localtime($p->{ending}) )[0,1,2,3,4,5];
 693   my ($psec,$pmin,$phour,$pmday,$pmon,$pyear) =
 694     (localtime($p->{beginning}) )[0,1,2,3,4,5];
 695
 696   if ( $freq =~ /^\d+$/ ) {
 697     $nmon += $freq;
 698     until ( $nmon < 12 ) { $nmon -= 12; $nyear++; }
 699     $pmon -= $freq;
 700     until ( $pmon >= 0 ) { $pmon += 12; $pyear--; }
 701   } elsif ( $freq =~ /^(\d+)w$/ ) {
 702     my $weeks = $1;
 703     $nmday += $weeks * 7;
 704     $pmday -= $weeks * 7;
 705   } elsif ( $freq =~ /^(\d+)d$/ ) {
 706     my $days = $1;
 707     $nmday += $days;
 708     $pmday -= $days;
 709   } elsif ( $freq =~ /^(\d+)h$/ ) {
 710     my $hours = $1;
 711     $nhour += $hours;
 712     $phour -= $hours;
 713   } else {
 714     return { 'error' => "unparsable frequency: ". $freq };
 715   }
 716
 717   my $previous  = timelocal_nocheck($psec,$pmin,$phour,$pmday,$pmon,$pyear);
 718   my $next      = timelocal_nocheck($nsec,$nmin,$nhour,$nmday,$nmon,$nyear);
 719
 720
 721   {
 722     'error'     => '',
 723     'svcnum'    => $p->{svcnum},
 724     'beginning' => $p->{beginning},
 725     'ending'    => $p->{ending},
 726     'previous'  => ($previous > $start) ? $previous : $start,
 727     'next'      => ($next < $end) ? $next : $end,
 728     'usage'     => \@usage,
 729   };
 730 }
 731
 732 sub order_pkg {
 733   my $p = shift;
 734
 735   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 736   return { 'error' => $session } if $context eq 'error';
 737
 738   my $search = { 'custnum' => $custnum };
 739   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 740   my $cust_main = qsearchs('cust_main', $search )
 741     or return { 'error' => "unknown custnum $custnum" };
 742
 743   #false laziness w/ClientAPI/Signup.pm
 744
 745   my $cust_pkg = new FS::cust_pkg ( {
 746     'custnum' => $custnum,
 747     'pkgpart' => $p->{'pkgpart'},
 748   } );
 749   my $error = $cust_pkg->check;
 750   return { 'error' => $error } if $error;
 751
 752   my @svc = ();
 753   unless ( $p->{'svcpart'} eq 'none' ) {
 754
 755     my $svcdb;
 756     my $svcpart = '';
 757     if ( $p->{'svcpart'} =~ /^(\d+)$/ ) {
 758       $svcpart = $1;
 759       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
 760       return { 'error' => "Unknown svcpart $svcpart" } unless $part_svc;
 761       $svcdb = $part_svc->svcdb;
 762     } else {
 763       $svcdb = 'svc_acct';
 764     }
 765     $svcpart ||= $cust_pkg->part_pkg->svcpart($svcdb);
 766
 767     my %fields = (
 768       'svc_acct'     => [ qw( username domsvc _password sec_phrase popnum ) ],
 769       'svc_domain'   => [ qw( domain ) ],
 770       'svc_external' => [ qw( id title ) ],
 771     );
 772
 773     my $svc_x = "FS::$svcdb"->new( {
 774       'svcpart'   => $svcpart,
 775       map { $_ => $p->{$_} } @{$fields{$svcdb}}
 776     } );
 777
 778     if ( $svcdb eq 'svc_acct' ) {
 779       my @acct_snarf;
 780       my $snarfnum = 1;
 781       while ( length($p->{"snarf_machine$snarfnum"}) ) {
 782         my $acct_snarf = new FS::acct_snarf ( {
 783           'machine'   => $p->{"snarf_machine$snarfnum"},
 784           'protocol'  => $p->{"snarf_protocol$snarfnum"},
 785           'username'  => $p->{"snarf_username$snarfnum"},
 786           '_password' => $p->{"snarf_password$snarfnum"},
 787         } );
 788         $snarfnum++;
 789         push @acct_snarf, $acct_snarf;
 790       }
 791       $svc_x->child_objects( \@acct_snarf );
 792     }
 793
 794     my $y = $svc_x->setdefault; # arguably should be in new method
 795     return { 'error' => $y } if $y && !ref($y);
 796
 797     $error = $svc_x->check;
 798     return { 'error' => $error } if $error;
 799
 800     push @svc, $svc_x;
 801
 802   }
 803
 804   use Tie::RefHash;
 805   tie my %hash, 'Tie::RefHash';
 806   %hash = ( $cust_pkg => \@svc );
 807   #msgcat
 808   $error = $cust_main->order_pkgs( \%hash, '', 'noexport' => 1 );
 809   return { 'error' => $error } if $error;
 810
 811   my $conf = new FS::Conf;
 812   if ( $conf->exists('signup_server-realtime') ) {
 813
 814     my $bill_error = _do_bop_realtime( $cust_main );
 815
 816     if ($bill_error) {
 817       $cust_pkg->cancel('quiet'=>1);
 818       return $bill_error;
 819     } else {
 820       $cust_pkg->reexport;
 821     }
 822
 823   } else {
 824     $cust_pkg->reexport;
 825   }
 826
 827   return { error => '', pkgnum => $cust_pkg->pkgnum };
 828
 829 }
 830
 831 sub change_pkg {
 832   my $p = shift;
 833
 834   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 835   return { 'error' => $session } if $context eq 'error';
 836
 837   my $search = { 'custnum' => $custnum };
 838   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 839   my $cust_main = qsearchs('cust_main', $search )
 840     or return { 'error' => "unknown custnum $custnum" };
 841
 842   my $cust_pkg = qsearchs('cust_pkg', { 'pkgnum' => $p->{pkgnum} } )
 843     or return { 'error' => "unknown package $p->{pkgnum}" };
 844
 845   my @newpkg;
 846   my $error = FS::cust_pkg::order( $custnum,
 847                                    [$p->{pkgpart}],
 848                                    [$p->{pkgnum}],
 849                                    \@newpkg,
 850                                  );
 851
 852   my $conf = new FS::Conf;
 853   if ( $conf->exists('signup_server-realtime') ) {
 854
 855     my $bill_error = _do_bop_realtime( $cust_main );
 856
 857     if ($bill_error) {
 858       $newpkg[0]->suspend;
 859       return $bill_error;
 860     } else {
 861       $newpkg[0]->reexport;
 862     }
 863
 864   } else {
 865     $newpkg[0]->reexport;
 866   }
 867
 868   return { error => '', pkgnum => $cust_pkg->pkgnum };
 869
 870 }
 871
 872 sub order_recharge {
 873   my $p = shift;
 874
 875   my($context, $session, $custnum) = _custoragent_session_custnum($p);
 876   return { 'error' => $session } if $context eq 'error';
 877
 878   my $search = { 'custnum' => $custnum };
 879   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
 880   my $cust_main = qsearchs('cust_main', $search )
 881     or return { 'error' => "unknown custnum $custnum" };
 882
 883   my $cust_svc = qsearchs( 'cust_svc', { 'svcnum' => $p->{'svcnum'} } )
 884     or return { 'error' => "unknown service " . $p->{'svcnum'} };
 885
 886   my $svc_x = $cust_svc->svc_x;
 887   my $part_pkg = $cust_svc->cust_pkg->part_pkg;
 888
 889   my %vhash =
 890     map { $_ =~ /^recharge_(.*)$/; $1, $part_pkg->option($_, 1) }
 891     qw ( recharge_seconds recharge_upbytes recharge_downbytes
 892          recharge_totalbytes );
 893   my $amount = $part_pkg->option('recharge_amount', 1);
 894
 895   my ($l, $v, $d) = $cust_svc->label;  # blah
 896   my $pkg = "Recharge $v";
 897
 898   my $bill_error = $cust_main->charge($amount, $pkg,
 899      "time: $vhash{seconds}, up: $vhash{upbytes}," .
 900      "down: $vhash{downbytes}, total: $vhash{totalbytes}",
 901      $part_pkg->taxclass); #meh
 902
 903   my $conf = new FS::Conf;
 904   if ( $conf->exists('signup_server-realtime') && !$bill_error ) {
 905
 906     $bill_error = _do_bop_realtime( $cust_main );
 907
 908     if ($bill_error) {
 909       return $bill_error;
 910     } else {
 911       my $error = $svc_x->recharge (\%vhash);
 912       return { 'error' => $error } if $error;
 913     }
 914
 915   } else {
 916     my $error = $bill_error;
 917     $error ||= $svc_x->recharge (\%vhash);
 918     return { 'error' => $error } if $error;
 919   }
 920
 921   return { error => '', svc => $cust_svc->part_svc->svc };
 922
 923 }
 924
 925 sub _do_bop_realtime {
 926   my ($cust_main) = @_;
 927
 928     my $old_balance = $cust_main->balance;
 929
 930     my $bill_error = $cust_main->bill;
 931
 932     $cust_main->apply_payments_and_credits;
 933     $bill_error = $cust_main->collect('realtime' => 1);
 934
 935     if (    $cust_main->balance > $old_balance
 936          && $cust_main->balance > 0
 937          && $cust_main->payby !~ /^(BILL|DCRD|DCHK)$/ ) {
 938       #this makes sense.  credit is "un-doing" the invoice
 939       $cust_main->credit( sprintf("%.2f", $cust_main->balance - $old_balance ),
 940                           'self-service decline' );
 941       $cust_main->apply_credits( 'order' => 'newest' );
 942
 943       return { 'error' => '_decline', 'bill_error' => $bill_error };
 944     }
 945
 946     '';
 947 }
 948
 949 sub cancel_pkg {
 950   my $p = shift;
 951   my $session = _cache->get($p->{'session_id'})
 952     or return { 'error' => "Can't resume session" }; #better error message
 953
 954   my $custnum = $session->{'custnum'};
 955
 956   my $cust_main = qsearchs('cust_main', { 'custnum' => $custnum } )
 957     or return { 'error' => "unknown custnum $custnum" };
 958
 959   my $pkgnum = $p->{'pkgnum'};
 960
 961   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
 962                                         'pkgnum'  => $pkgnum,   } )
 963     or return { 'error' => "unknown pkgnum $pkgnum" };
 964
 965   my $error = $cust_pkg->cancel( 'quiet'=>1 );
 966   return { 'error' => $error };
 967
 968 }
 969
 970 sub provision_acct {
 971   my $p = shift;
 972
 973   return { 'error' => gettext('passwords_dont_match') }
 974     if $p->{'_password'} ne $p->{'_password2'};
 975   return { 'error' => gettext('empty_password') }
 976     unless length($p->{'_password'});
 977
 978   _provision( 'FS::svc_acct',
 979               [qw(username _password)],
 980               [qw(username _password)],
 981               $p,
 982               @_
 983             );
 984 }
 985
 986 sub provision_external {
 987   my $p = shift;
 988   #_provision( 'FS::svc_external', [qw(id title)], [qw(id title)], $p, @_ );
 989   _provision( 'FS::svc_external',
 990               [],
 991               [qw(id title)],
 992               $p,
 993               @_
 994             );
 995 }
 996
 997 sub _provision {
 998   my( $class, $fields, $return_fields, $p ) = splice(@_, 0, 4);
 999
1000   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1001   return { 'error' => $session } if $context eq 'error';
1002
1003   my $search = { 'custnum' => $custnum };
1004   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1005   my $cust_main = qsearchs('cust_main', $search )
1006     or return { 'error' => "unknown custnum $custnum" };
1007
1008   my $pkgnum = $p->{'pkgnum'};
1009
1010   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1011                                         'pkgnum'  => $pkgnum,
1012                                                                } )
1013     or return { 'error' => "unknown pkgnum $pkgnum" };
1014
1015   my $part_svc = qsearchs('part_svc', { 'svcpart' => $p->{'svcpart'} } )
1016     or return { 'error' => "unknown svcpart $p->{'svcpart'}" };
1017
1018   my $svc_x = $class->new( {
1019     'pkgnum'  => $p->{'pkgnum'},
1020     'svcpart' => $p->{'svcpart'},
1021     map { $_ => $p->{$_} } @$fields
1022   } );
1023   my $error = $svc_x->insert;
1024   $svc_x = qsearchs($svc_x->table, { 'svcnum' => $svc_x->svcnum })
1025     unless $error;
1026
1027   return { 'svc'   => $part_svc->svc,
1028            'error' => $error,
1029            map { $_ => $svc_x->get($_) } @$return_fields
1030          };
1031
1032 }
1033
1034 sub part_svc_info {
1035   my $p = shift;
1036
1037   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1038   return { 'error' => $session } if $context eq 'error';
1039
1040   my $search = { 'custnum' => $custnum };
1041   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1042   my $cust_main = qsearchs('cust_main', $search )
1043     or return { 'error' => "unknown custnum $custnum" };
1044
1045   my $pkgnum = $p->{'pkgnum'};
1046
1047   my $cust_pkg = qsearchs('cust_pkg', { 'custnum' => $custnum,
1048                                         'pkgnum'  => $pkgnum,
1049                                                                } )
1050     or return { 'error' => "unknown pkgnum $pkgnum" };
1051
1052   my $svcpart = $p->{'svcpart'};
1053
1054   my $pkg_svc = qsearchs('pkg_svc', { 'pkgpart' => $cust_pkg->pkgpart,
1055                                       'svcpart' => $svcpart,           } )
1056     or return { 'error' => "unknown svcpart $svcpart for pkgnum $pkgnum" };
1057   my $part_svc = $pkg_svc->part_svc;
1058
1059   my $conf = new FS::Conf;
1060
1061   return {
1062     'svc'     => $part_svc->svc,
1063     'svcdb'   => $part_svc->svcdb,
1064     'pkgnum'  => $pkgnum,
1065     'svcpart' => $svcpart,
1066     'custnum' => $custnum,
1067
1068     'security_phrase' => 0, #XXX !
1069     'svc_acct_pop'    => [], #XXX !
1070     'popnum'          => '',
1071     'init_popstate'   => '',
1072     'popac'           => '',
1073     'acstate'         => '',
1074
1075     'small_custview' =>
1076       small_custview( $cust_main, $conf->config('countrydefault') ),
1077
1078   };
1079
1080 }
1081
1082 sub unprovision_svc {
1083   my $p = shift;
1084
1085   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1086   return { 'error' => $session } if $context eq 'error';
1087
1088   my $search = { 'custnum' => $custnum };
1089   $search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1090   my $cust_main = qsearchs('cust_main', $search )
1091     or return { 'error' => "unknown custnum $custnum" };
1092
1093   my $svcnum = $p->{'svcnum'};
1094
1095   my $cust_svc = qsearchs('cust_svc', { 'svcnum'  => $svcnum, } )
1096     or return { 'error' => "unknown svcnum $svcnum" };
1097
1098   return { 'error' => "Service $svcnum does not belong to customer $custnum" }
1099     unless $cust_svc->cust_pkg->custnum == $custnum;
1100
1101   my $conf = new FS::Conf;
1102
1103   return { 'svc'   => $cust_svc->part_svc->svc,
1104            'error' => $cust_svc->cancel,
1105            'small_custview' =>
1106              small_custview( $cust_main, $conf->config('countrydefault') ),
1107          };
1108
1109 }
1110
1111 sub myaccount_passwd {
1112   my $p = shift;
1113   my($context, $session, $custnum) = _custoragent_session_custnum($p);
1114   return { 'error' => $session } if $context eq 'error';
1115
1116   return { 'error' => "New passwords don't match." }
1117     if $p->{'new_password'} ne $p->{'new_password2'};
1118
1119   return { 'error' => 'Enter new password' }
1120     unless length($p->{'new_password'});
1121
1122   #my $search = { 'custnum' => $custnum };
1123   #$search->{'agentnum'} = $session->{'agentnum'} if $context eq 'agent';
1124   $custnum =~ /^(\d+)$/ or die "illegal custnum";
1125   my $search = " AND custnum = $1";
1126   $search .= " AND agentnum = ". $session->{'agentnum'} if $context eq 'agent';
1127
1128   my $svc_acct = qsearchs( {
1129     'table'     => 'svc_acct',
1130     'addl_from' => 'LEFT JOIN cust_svc  USING ( svcnum  ) '.
1131                    'LEFT JOIN cust_pkg  USING ( pkgnum  ) '.
1132                    'LEFT JOIN cust_main USING ( custnum ) ',
1133     'hashref'   => { 'svcnum' => $p->{'svcnum'}, },
1134     'extra_sql' => $search, #important
1135   } )
1136     or return { 'error' => "Service not found" };
1137
1138   $svc_acct->_password($p->{'new_password'});
1139   my $error = $svc_acct->replace();
1140
1141   my($label, $value) = $svc_acct->cust_svc->label;
1142
1143   return { 'error' => $error,
1144            'label' => $label,
1145            'value' => $value,
1146          };
1147
1148 }
1149
1150 #--
1151
1152 sub _custoragent_session_custnum {
1153   my $p = shift;
1154
1155   my($context, $session, $custnum);
1156   if ( $p->{'session_id'} ) {
1157
1158     $context = 'customer';
1159     $session = _cache->get($p->{'session_id'})
1160       or return ( 'error' => "Can't resume session" ); #better error message
1161     $custnum = $session->{'custnum'};
1162
1163   } elsif ( $p->{'agent_session_id'} ) {
1164
1165     $context = 'agent';
1166     my $agent_cache = new FS::ClientAPI_SessionCache( {
1167       'namespace' => 'FS::ClientAPI::Agent',
1168     } );
1169     $session = $agent_cache->get($p->{'agent_session_id'})
1170       or return ( 'error' => "Can't resume session" ); #better error message
1171     $custnum = $p->{'custnum'};
1172
1173   } else {
1174     return ( 'error' => "Can't resume session" ); #better error message
1175   }
1176
1177   ($context, $session, $custnum);
1178
1179 }
1180
1181 1;
1182